FS/FS/part_export/a2billing.pm

   1 package FS::part_export::a2billing;
   2
   3 use strict;
   4 use vars qw(@ISA @EXPORT_OK $DEBUG %info %options);
   5 use Exporter;
   6 use Tie::IxHash;
   7 use FS::Record qw( qsearch qsearchs str2time_sql );
   8 use FS::part_export;
   9 use FS::svc_acct;
  10 use FS::svc_phone;
  11 use Locale::Country qw(country_code2code);
  12 use Date::Format qw(time2str);
  13 use Carp qw( cluck );
  14
  15 @ISA = qw(FS::part_export);
  16
  17 $DEBUG = 0;
  18
  19 tie %options, 'Tie::IxHash',
  20   'datasrc'     => { label=>'DBI data source ' },
  21   'username'    => { label=>'Database username' },
  22   'password'    => { label=>'Database password' },
  23   'didgroup'    => { label=>'DID group ID', default=>1 },
  24   'credit'      => { label=>'Default credit limit' },
  25   'billtype'    => {label=>'Billing type',
  26                     type => 'select',
  27                     options => ['Dial Out Rate', 'Free']
  28                   },
  29   'debug'       => { label=>'Enable debugging', type=>'checkbox' }
  30 ;
  31
  32 my $notes = <<'END';
  33 <p>Real-time export to the backend database of an <a
  34 href="http://www.asterisk2billing.org">Asterisk2Billing</a> billing server.
  35 This is both a svc_acct and a svc_phone export, and needs to be attached
  36 to both a svc_acct and svc_phone definition within the same package.</p>
  37 <ul>
  38 <li>When you set up this export, it will create 'svcnum' fields in the
  39 cc_card and cc_did tables in the A2Billing database to store the
  40 service numbers of svc_acct and svc_phone records.  The database username
  41 must have ALTER TABLE privileges.</li>
  42 <li><i>DBI data source</i> should look like<br>
  43 <b>dbi:mysql:host=</b><i>hostname</i><b>;database=</b><i>dbname</i>
  44 </li>
  45 END
  46
  47 %info = (
  48   'svc'      => ['svc_acct', 'svc_phone'],
  49   'desc'     => 'Export to Asterisk2Billing database',
  50   'options'  => \%options,
  51   'nodomain' => 'Y',
  52   'no_machine' => 1,
  53   'notes'    => $notes
  54 );
  55
  56 sub dbh {
  57   my $self = shift;
  58   $self->{dbh} ||= DBI->connect(
  59                       $self->option('datasrc'),
  60                       $self->option('username'),
  61                       $self->option('password')
  62                       ) or die $DBI::errstr;
  63
  64   $self->{dbh}->trace(1, '%%%FREESIDE_LOG%%%/a2b_exportlog.'.$self->exportnum)
  65     if $DEBUG;
  66
  67   $self->{dbh};
  68 }
  69
  70 # hook insert/replace, because we need to make some changes to the
  71 # database when the export is created
  72 sub insert {
  73   my $self = shift;
  74   my $error = $self->SUPER::insert(@_);
  75   return $error if $error;
  76   if ( $self->option('datasrc') ) {
  77     my $error;
  78     foreach (qw(cc_card cc_did)) {
  79       $self->dbh->do("ALTER TABLE $_ ADD COLUMN svcnum int")
  80         or $error = $self->dbh->errstr;
  81       $error = '' if $error =~ /Duplicate column name/; # harmless
  82       return "Error preparing a2billing database: $error\n" if $error;
  83     }
  84   }
  85   '';
  86 }
  87
  88 sub replace {
  89   my $new = shift;
  90   my $old = shift || $new->replace_old;
  91   my $old_datasrc = $old->option('datasrc');
  92   my $error = $new->SUPER::replace($old, @_);
  93   return $error if $error;
  94
  95   if ($new->option('datasrc') and $new->option('datasrc') ne $old_datasrc) {
  96     my $dbh = $new->a2b_connect;
  97     my $error;
  98     foreach (qw(cc_card cc_did)) {
  99       $new->dbh->do("ALTER TABLE $_ ADD COLUMN svcnum int")
 100         or $error = $new->dbh->errstr;
 101       $error = '' if $error =~ /Duplicate column name/; # harmless
 102       return "Error preparing a2billing database: $error\n" if $error;
 103     }
 104   }
 105   '';
 106 }
 107
 108 sub export_insert {
 109   my $self = shift;
 110   my $svc = shift;
 111   my $cust_pkg = $svc->cust_svc->cust_pkg;
 112   my $cust_main = $cust_pkg->cust_main;
 113   my $location = $cust_pkg->cust_location;
 114   my $part_pkg = $cust_pkg->part_pkg;
 115
 116   my $error;
 117   $DEBUG ||= $self->option('debug');
 118
 119   # 3-letter UN country code
 120   my $country3 = uc(country_code2code($location->country, 'alpha2' => 'alpha3'));
 121
 122   my $dbh = $self->a2b_connect;
 123
 124   if ( $svc->isa('FS::svc_acct') ) {
 125     # export to cc_card (customer identity) and cc_sip_buddies (SIP extension)
 126
 127     my $username = $svc->username;
 128
 129     my %cc_card = (
 130       svcnum    => $svc->svcnum,
 131       username  => $username,
 132       useralias => $username,
 133       uipass    => $svc->_password,
 134       creditlimit    => $cust_main->credit_limit || $self->option('credit') || 0,
 135       tariff    => $part_pkg->option('a2billing_tariff'),
 136       status    => 1,
 137       lastname  => $cust_main->last, # $svc->finger?
 138       firstname => $cust_main->first,
 139       address   => $location->address1 .
 140                   ($location->address2 ? ', '.$location->address2 : ''),
 141       city      => $location->city,
 142       state     => $location->state,
 143       country   => $country3,
 144       zipcode   => $location->zip,
 145       simultaccess  => $part_pkg->option('a2billing_simultaccess'),
 146       typepaid  => $part_pkg->option('a2billing_type'),
 147       email_notification => $cust_main->invoicing_list_emailonly_scalar,
 148       notify_email => ($cust_main->invoicing_list_emailonly_scalar ? 1 : 0),
 149       credit_notification => $cust_main->credit_limit || $self->option('credit') || 0,
 150       sip_buddy => 1,
 151       company_name => $cust_main->company,
 152       activated => 't',
 153     );
 154     warn "creating A2B cc_card record for $username\n" if $DEBUG;
 155     $error = $self->a2b_insert_or_replace('cc_card', 'svcnum', \%cc_card);
 156     return "Error creating A2Billing customer identity: $error" if $error;
 157
 158     my $fullcontact = '';
 159     if ( $svc->ip_addr ) {
 160       $fullcontact = "sip:$username\@".$svc->ip_addr;
 161     }
 162
 163     my $cc_card_id = $self->a2b_find('cc_card', 'svcnum', $svc->svcnum);
 164     # these are the fields we know about; some of them might need to be
 165     # export options eventually, and there are a lot more fields in the table
 166     my %cc_sip_buddy = (
 167       id_cc_card      => $cc_card_id,
 168       name            => $username,
 169       accountcode     => $username,
 170       regexten        => $username,
 171       amaflags        => 'billing',
 172       context         => 'a2billing',
 173       host            => 'dynamic',
 174       port            => 5060,
 175       secret          => $svc->_password,
 176       username        => $username,
 177       allow           => 'ulaw,alaw,gsm,g729',
 178       ipaddr          => ($svc->slipip || ''),
 179       fullcontact     => $fullcontact,
 180     );
 181     warn "creating A2B cc_sip_buddies record for $username\n" if $DEBUG;
 182     $error = $self->a2b_insert_or_replace('cc_sip_buddies', 'id_cc_card',
 183                                           \%cc_sip_buddy);
 184     return "Error creating A2Billing SIP extension: $error" if $error;
 185
 186     # then, if there are any DIDs on the package, set them up
 187     foreach ( $self->_linked_svcs($svc, 'svc_phone') ) {
 188       warn "triggering export of svc_phone #".$_->svcnum."\n" if $DEBUG;
 189       $error = $self->export_insert($_->svc_x);
 190       return $error if $error;
 191     }
 192     return '';
 193
 194   } elsif ( $svc->isa('FS::svc_phone') ) {
 195     # find the linked svc_acct
 196     my $svc_acct;
 197     foreach ($self->_linked_svcs($svc, 'svc_acct')) {
 198       $svc_acct = $_->svc_x;
 199       last;
 200     }
 201     if ( !$svc_acct ) {
 202       # it hasn't been created yet, so just exit.
 203       # this service will be exported later.
 204       warn "no linked svc_acct; deferring phone number export\n" if $DEBUG;
 205       return '';
 206     }
 207     # find the card and sip_buddies records
 208     my $cc_card_id = $self->a2b_find('cc_card', 'svcnum', $svc_acct->svcnum);
 209     my $cc_sip_buddies_id = $self->a2b_find('cc_sip_buddies', 'id_cc_card', $cc_card_id);
 210     if (!$cc_card_id or !$cc_sip_buddies_id) {
 211       warn "When exporting svc_phone #".$svc->svcnum.", svc_acct #".$svc_acct->svcnum." was not found in A2Billing.\n";
 212       if ( $FS::svc_Common::noexport_hack ) {
 213         # recursion protection
 214         return "During export of linked DID#".$svc->phonenum.", svc_acct #".$svc_acct->svcnum." was not found in A2Billing.";
 215       }
 216       return $svc_acct->export_insert; # which will call back to here when
 217                                        # it's done
 218     }
 219
 220     # Create the DID.
 221     my $cc_country_id = $self->a2b_find('cc_country', 'countrycode', $country3);
 222     my %cc_did = (
 223       svcnum          => $svc->svcnum,
 224       id_cc_didgroup  => $self->option('didgroup'),
 225       id_cc_country   => $cc_country_id,
 226       iduser          => $cc_card_id,
 227       did             => $svc->phonenum,
 228       billingtype     => ($self->option('billtype') eq 'Dial Out Rate' ? 2 : 3),
 229       activated       => 1,
 230     );
 231
 232     # use 'did' as the key here so that if the DID already exists, we
 233     # link it to this customer.
 234     $error = $self->a2b_insert_or_replace('cc_did', 'did', \%cc_did);
 235     return "Error creating A2Billing DID record: $error" if $error;
 236
 237     my $cc_did_id = $self->a2b_find('cc_did', 'svcnum', $svc->svcnum);
 238
 239     my $destination = 'SIP/user-'. $svc_acct->username. '@'. $svc->sip_server. "!". $svc->phonenum;
 240     my %cc_did_destination = (
 241       destination     => $destination,
 242       priority        => 1,
 243       id_cc_card      => $cc_card_id,
 244       id_cc_did       => $cc_did_id,
 245       validated       => 1,
 246       voip_call       => 1,
 247     );
 248
 249     # and if there's already a destination, change it to point to
 250     # this customer's SIP extension
 251     $error = $self->a2b_insert_or_replace('cc_did_destination', 'id_cc_did',
 252                                           \%cc_did_destination);
 253     return "Error linking A2Billing DID record to customer: $error" if $error;
 254
 255     my %cc_did_use = (
 256       id_cc_card      => $cc_card_id,
 257       id_did          => $cc_did_id,
 258       activated       => 1,
 259       month_payed     => 1, # it's the default in the A2Billing code, I think
 260     );
 261     # and change the in-use record, too
 262     my $id_use = $self->a2b_find('cc_did_use',
 263       id_did          => $cc_did_id,
 264       activated       => 1,
 265     );
 266     if ( $id_use ) {
 267       $error = $self->a2b_insert_or_replace('cc_did_use', 'id',
 268         { id          => $id_use,
 269           releasedate => time2str('%Y-%m-%d %H:%M:%S', time),
 270           activated   => 0
 271         }
 272       );
 273       return "Error closing existing A2Billing DID assignment record: $error"
 274         if $error;
 275
 276       # and do an update instead of an insert
 277       $cc_did_use{id} = $id_use;
 278     }
 279
 280     $error = $self->a2b_insert_or_replace('cc_did_use', 'id', \%cc_did_use);
 281     return "Error creating A2Billing DID use record: $error" if $error;
 282
 283   } # if $svc->isa(...)
 284   '';
 285 }
 286
 287 sub export_delete {
 288   my $self = shift;
 289   my $svc = shift;
 290
 291   my $error;
 292   $DEBUG ||= $self->option('debug');
 293
 294   if ( $svc->isa('FS::svc_acct') ) {
 295
 296     # first remove the DID links
 297     foreach ($self->_linked_svcs($svc, 'svc_phone')) {
 298       warn "triggering export of svc_phone #".$_->svcnum."\n" if $DEBUG;
 299       $error = $self->export_delete($_->svc_x);
 300       return $error if $error;
 301     }
 302
 303     # a2billing never deletes a card, just sets status = 0.
 304     # though we also need to remove the svcnum, since that svcnum is no
 305     # longer valid.
 306     my $cc_card_id = $self->a2b_find('cc_card', 'svcnum', $svc->svcnum);
 307     if (!$cc_card_id) {
 308       warn "tried to remove svc_acct #".$svc->svcnum." from A2Billing, but couldn't find it.\n";
 309       # which is not really a problem.
 310       return '';
 311     }
 312     warn "deactivating A2B cc_card record #$cc_card_id\n" if $DEBUG;
 313     $error = $self->a2b_insert_or_replace('cc_card', 'id', {
 314         id        => $cc_card_id,
 315         status    => 0,
 316         activated => 0,
 317         svcnum    => 0,
 318     });
 319     return $error if $error;
 320
 321   } elsif ( $svc->isa('FS::svc_phone') ) {
 322
 323     my $cc_did_id = $self->a2b_find('cc_did', 'svcnum', $svc->svcnum);
 324     if ( $cc_did_id ) {
 325       warn "deactivating DID ".$svc->phonenum."\n" if $DEBUG;
 326       $error = $self->a2b_insert_or_replace('cc_did', 'id',
 327         { id        => $cc_did_id,
 328           activated => 0,
 329           iduser    => 0,
 330           svcnum    => 0,
 331         }
 332       );
 333       return $error if $error;
 334     } else {
 335       warn "tried to remove svc_phone #".$svc->svcnum." from A2Billing, but couldn't find it.\n";
 336       return '';
 337     }
 338
 339     my $cc_did_destination_id = $self->a2b_find('cc_did_destination',
 340       'id_cc_did', $cc_did_id,
 341       'activated', 1
 342     );
 343     if ( $cc_did_destination_id ) {
 344       warn "unlinking DID ".$svc->phonenum." from customer\n" if $DEBUG;
 345       $error = $self->a2b_delete('cc_did_destination', $cc_did_destination_id);
 346       return $error if $error;
 347     } else {
 348       warn "no cc_did_destination found for cc_did #$cc_did_id\n";
 349     }
 350
 351     my $cc_did_use_id = $self->a2b_find('cc_did_use',
 352       'id_did', $cc_did_id,
 353       'activated', 1
 354     );
 355     if ( $cc_did_use_id ) {
 356       warn "closing DID assignment\n" if $DEBUG;
 357       $error = $self->a2b_insert_or_replace('cc_did_use', 'id',
 358         { id          => $cc_did_use_id,
 359           releasedate => time2str('%Y-%m-%d %H:%M:%S', time),
 360           activated   => 0
 361         }
 362       );
 363       return "Error closing existing A2Billing DID assignment record: $error"
 364         if $error;
 365     } else {
 366       warn "no cc_did_use found for cc_did #$cc_did_id\n";
 367     }
 368
 369   }
 370   '';
 371 }
 372
 373 sub export_replace {
 374   my $self = shift;
 375   my $new = shift;
 376   my $old = shift || $self->replace_old;
 377
 378   my $error;
 379   $DEBUG ||= $self->option('debug');
 380
 381   if ( $new->isa('FS::svc_acct') ) {
 382
 383     my $cc_card_id = $self->a2b_find('cc_card', 'svcnum', $new->svcnum);
 384     if ( $cc_card_id and $new->username ne $old->username ) {
 385       # If the username is changing and any DIDs are provisioned, we need to
 386       # change their destinations.  To do this, we unlink them.  This will
 387       # close their did_use records, delete their cc_did_destinations, and
 388       # set their cc_dids to inactive.
 389       foreach ($self->_linked_svcs($new, 'svc_phone')) {
 390         warn "triggering export of svc_phone #".$_->svcnum."\n" if $DEBUG;
 391         $error = $self->export_delete($_->svc_x);
 392         return $error if $error;
 393       }
 394     }
 395
 396     # export_insert will replace the record with the same svcnum, if there
 397     # is one, and then re-export all existing DIDs (which is convenient since
 398     # we just unlinked them).
 399     $error = $self->export_insert($new);
 400     return $error if $error;
 401
 402   } elsif ( $new->isa('FS::svc_phone') ) {
 403
 404     # if the phone number has changed, need to create a new DID.
 405     if ( $new->phonenum ne $old->phonenum ) {
 406       # deactivate/unlink/close the old DID
 407       # and create/link the new one
 408       $error = $self->export_delete($old)
 409             || $self->export_insert($new);
 410       return $error if $error;
 411     }
 412     # otherwise we don't care
 413   }
 414
 415   '';
 416 }
 417
 418 sub export_suspend {
 419   my $self = shift;
 420   my $svc = shift;
 421
 422   my $error;
 423   $DEBUG ||= $self->option('debug');
 424
 425   if ( $svc->isa('FS::svc_acct') ) {
 426     $error = $self->a2b_insert_or_replace('cc_card', 'svcnum',
 427       { svcnum    => $svc->svcnum,
 428         status    => 6, # "SUSPENDED FOR UNDERPAYMENT"
 429         activated => 0, # still used in some places, grrr
 430       }
 431     );
 432   } elsif ( $svc->isa('FS::svc_phone') ) {
 433     # deactivate the DID
 434     $error = $self->a2b_insert_or_replace('cc_did', 'svcnum',
 435       { svcnum    => $svc->svcnum,
 436         activated => 0,
 437       }
 438     );
 439   }
 440   $error || '';
 441 }
 442
 443 sub export_unsuspend {
 444   my $self = shift;
 445   my $svc = shift;
 446
 447   my $error;
 448   $DEBUG ||= $self->option('debug');
 449
 450   if ( $svc->isa('FS::svc_acct') ) {
 451     $error = $self->a2b_insert_or_replace('cc_card', 'svcnum',
 452       { svcnum    => $svc->svcnum,
 453         status    => 1, #"ACTIVE"
 454         activated => 1,
 455       }
 456     );
 457   } elsif ( $svc->isa('FS::svc_phone') ) {
 458     $error = $self->a2b_insert_or_replace('cc_did', 'svcnum',
 459       { svcnum    => $svc->svcnum,
 460         activated => 1,
 461       }
 462     );
 463   }
 464   $error || '';
 465 }
 466
 467 =item a2b_insert_or_replace TABLE KEY HASHREF
 468
 469 Create a record in TABLE with the values in HASHREF.  If there's already one
 470 that matches on the KEY field, update the existing record instead of creating
 471 a new one.  Pass an empty KEY to just insert the record without checking.
 472
 473 =cut
 474
 475 sub a2b_insert_or_replace {
 476   my $self = shift;
 477   my $table = shift;
 478   my $key = shift;
 479   my $hashref = shift;
 480
 481   if ( $key ) {
 482     my $id = $self->a2b_find($table, $key, $hashref->{$key});
 483     if ( $id ) {
 484       my $sql = "UPDATE $table SET " .
 485                 join(', ', map { "$_ = ?" } keys(%$hashref)) .
 486                 " WHERE id = ?";
 487       $self->dbh->do($sql, {}, values(%$hashref), $id)
 488         or return $self->dbh->errstr;
 489       return '';
 490     }
 491   }
 492   # no key, or no existing record
 493   my $sql = "INSERT INTO $table (".  join(', ', keys(%$hashref)) . ")" .
 494             " VALUES (" . join(', ', map { '?' } keys(%$hashref)) . ")";
 495   $self->dbh->do($sql, {}, values(%$hashref))
 496     or return $self->dbh->errstr;
 497   return '';
 498 }
 499
 500 =item a2b_delete TABLE ID
 501
 502 Remove the record with id ID from TABLE.
 503
 504 =cut
 505
 506 sub a2b_delete {
 507   my $self = shift;
 508   my ($table, $id) = @_;
 509   my $sql = "DELETE FROM $table WHERE id = ?";
 510   $self->dbh->do($sql, {}, $id)
 511     or return $self->dbh->errstr;
 512   return '';
 513 }
 514
 515 =item a2b_find TABLE KEY VALUE [ KEY VALUE ... ]
 516
 517 Search TABLE for a row where KEY equals VALUE, and return its "id" field.
 518
 519 =cut
 520
 521 sub a2b_find {
 522   my $self = shift;
 523   my ($table, %params) = @_;
 524   my $sql = "SELECT id FROM $table WHERE " .
 525     join(' AND ', map { "$_ = ?" } keys(%params));
 526   my ($id) = $self->dbh->selectrow_array($sql, {}, values(%params));
 527   die $self->dbh->errstr if $self->dbh->errstr;
 528   $id || '';
 529 }
 530
 531 # find services on the same package that are exportable with this export
 532 # and are of a specified svcdb
 533 #
 534 # just to avoid repeating myself
 535 sub _linked_svcs {
 536   my ($self, $svc, $svcdb) = @_;
 537   # index the svcparts that belong to the a2billing export
 538   my $export_svcparts = $self->{export_svcparts} ||=
 539     { map { $_->svcpart => $_->part_svc->svcdb }
 540       $self->export_svc
 541     };
 542
 543   my $pkgnum = $svc->cust_svc->pkgnum;
 544   my @svcs = qsearch('cust_svc', { pkgnum => $pkgnum });
 545   grep { $export_svcparts->{$_->svcpart} eq $svcdb } @svcs;
 546 }
 547
 548 1;