FS/FS/part_export.pm

   1 package FS::part_export;
   2
   3 use strict;
   4 use vars qw( @ISA );
   5 use FS::Record qw( qsearch qsearchs dbh );
   6 use FS::part_svc;
   7 use FS::part_export_option;
   8
   9 @ISA = qw(FS::Record);
  10
  11 =head1 NAME
  12
  13 FS::part_export - Object methods for part_export records
  14
  15 =head1 SYNOPSIS
  16
  17   use FS::part_export;
  18
  19   $record = new FS::part_export \%hash;
  20   $record = new FS::part_export { 'column' => 'value' };
  21
  22   ($new_record, $options) = $template_recored->clone( $svcpart );
  23
  24   $error = $record->insert( { 'option' => 'value' } );
  25   $error = $record->insert( \%options );
  26
  27   $error = $new_record->replace($old_record);
  28
  29   $error = $record->delete;
  30
  31   $error = $record->check;
  32
  33 =head1 DESCRIPTION
  34
  35 An FS::part_export object represents an export of Freeside data to an external
  36 provisioning system.  FS::part_export inherits from FS::Record.  The following
  37 fields are currently supported:
  38
  39 =over 4
  40
  41 =item exportnum - primary key
  42
  43 =item svcpart - Service definition (see L<FS::part_svc>) to which this export applies
  44
  45 =item machine - Machine name
  46
  47 =item exporttype - Export type
  48
  49 =item nodomain - blank or "Y" : usernames are exported to this service with no domain
  50
  51 =back
  52
  53 =head1 METHODS
  54
  55 =over 4
  56
  57 =item new HASHREF
  58
  59 Creates a new export.  To add the export to the database, see L<"insert">.
  60
  61 Note that this stores the hash reference, not a distinct copy of the hash it
  62 points to.  You can ask the object for a copy with the I<hash> method.
  63
  64 =cut
  65
  66 # the new method can be inherited from FS::Record, if a table method is defined
  67
  68 sub table { 'part_export'; }
  69
  70 =item clone SVCPART
  71
  72 An alternate constructor.  Creates a new export by duplicating an existing
  73 export.  The given svcpart is assigned to the new export.
  74
  75 Returns a list consisting of the new export object and a hashref of options.
  76
  77 =cut
  78
  79 sub clone {
  80   my $self = shift;
  81   my $class = ref($self);
  82   my %hash = $self->hash;
  83   $hash{'exportnum'} = '';
  84   $hash{'svcpart'} = shift;
  85   ( $class->new( \%hash ),
  86     { map { $_->optionname => $_->optionvalue }
  87         qsearch('part_export_option', { 'exportnum' => $self->exportnum } )
  88     }
  89   );
  90 }
  91
  92 =item insert HASHREF
  93
  94 Adds this record to the database.  If there is an error, returns the error,
  95 otherwise returns false.
  96
  97 If a hash reference of options is supplied, part_export_option records are
  98 created (see L<FS::part_export_option>).
  99
 100 =cut
 101
 102 #false laziness w/queue.pm
 103 sub insert {
 104   my $self = shift;
 105   my $options = shift;
 106   local $SIG{HUP} = 'IGNORE';
 107   local $SIG{INT} = 'IGNORE';
 108   local $SIG{QUIT} = 'IGNORE';
 109   local $SIG{TERM} = 'IGNORE';
 110   local $SIG{TSTP} = 'IGNORE';
 111   local $SIG{PIPE} = 'IGNORE';
 112
 113   my $oldAutoCommit = $FS::UID::AutoCommit;
 114   local $FS::UID::AutoCommit = 0;
 115   my $dbh = dbh;
 116
 117   my $error = $self->SUPER::insert;
 118   if ( $error ) {
 119     $dbh->rollback if $oldAutoCommit;
 120     return $error;
 121   }
 122
 123   foreach my $optionname ( keys %{$options} ) {
 124     my $part_export_option = new FS::part_export_option ( {
 125       'exportnum'   => $self->exportnum,
 126       'optionname'  => $optionname,
 127       'optionvalue' => $options->{$optionname},
 128     } );
 129     $error = $part_export_option->insert;
 130     if ( $error ) {
 131       $dbh->rollback if $oldAutoCommit;
 132       return $error;
 133     }
 134   }
 135
 136   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 137
 138   '';
 139
 140 };
 141
 142 =item delete
 143
 144 Delete this record from the database.
 145
 146 =cut
 147
 148 #foreign keys would make this much less tedious... grr dumb mysql
 149 sub delete {
 150   my $self = shift;
 151   local $SIG{HUP} = 'IGNORE';
 152   local $SIG{INT} = 'IGNORE';
 153   local $SIG{QUIT} = 'IGNORE';
 154   local $SIG{TERM} = 'IGNORE';
 155   local $SIG{TSTP} = 'IGNORE';
 156   local $SIG{PIPE} = 'IGNORE';
 157
 158   my $oldAutoCommit = $FS::UID::AutoCommit;
 159   local $FS::UID::AutoCommit = 0;
 160   my $dbh = dbh;
 161
 162   my $error = $self->SUPER::delete;
 163   if ( $error ) {
 164     $dbh->rollback if $oldAutoCommit;
 165     return $error;
 166   }
 167
 168   foreach my $part_export_option ( $self->part_export_option ) {
 169     my $error = $part_export_option->delete;
 170     if ( $error ) {
 171       $dbh->rollback if $oldAutoCommit;
 172       return $error;
 173     }
 174   }
 175
 176   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 177
 178   '';
 179
 180 }
 181
 182 =item replace OLD_RECORD HASHREF
 183
 184 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 185 returns the error, otherwise returns false.
 186
 187 If a hash reference of options is supplied, part_export_option records are
 188 created or modified (see L<FS::part_export_option>).
 189
 190 =cut
 191
 192 sub replace {
 193   my $self = shift;
 194   my $old = shift;
 195   my $options = shift;
 196   local $SIG{HUP} = 'IGNORE';
 197   local $SIG{INT} = 'IGNORE';
 198   local $SIG{QUIT} = 'IGNORE';
 199   local $SIG{TERM} = 'IGNORE';
 200   local $SIG{TSTP} = 'IGNORE';
 201   local $SIG{PIPE} = 'IGNORE';
 202
 203   my $oldAutoCommit = $FS::UID::AutoCommit;
 204   local $FS::UID::AutoCommit = 0;
 205   my $dbh = dbh;
 206
 207   my $error = $self->SUPER::replace($old);
 208   if ( $error ) {
 209     $dbh->rollback if $oldAutoCommit;
 210     return $error;
 211   }
 212
 213   foreach my $optionname ( keys %{$options} ) {
 214     my $old = qsearchs( 'part_export_option', {
 215         'exportnum'   => $self->exportnum,
 216         'optionname'  => $optionname,
 217     } );
 218     my $new = new FS::part_export_option ( {
 219         'exportnum'   => $self->exportnum,
 220         'optionname'  => $optionname,
 221         'optionvalue' => $options->{$optionname},
 222     } );
 223     $new->optionnum($old->optionnum) if $old;
 224     my $error = $old ? $new->replace($old) : $new->insert;
 225     if ( $error ) {
 226       $dbh->rollback if $oldAutoCommit;
 227       return $error;
 228     }
 229   }
 230
 231   #remove extraneous old options
 232   foreach my $opt (
 233     grep { !exists $options->{$_->optionname} } $old->part_export_option
 234   ) {
 235     my $error = $opt->delete;
 236     if ( $error ) {
 237       $dbh->rollback if $oldAutoCommit;
 238       return $error;
 239     }
 240   }
 241
 242   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 243
 244   '';
 245
 246 };
 247
 248 =item check
 249
 250 Checks all fields to make sure this is a valid export.  If there is
 251 an error, returns the error, otherwise returns false.  Called by the insert
 252 and replace methods.
 253
 254 =cut
 255
 256 sub check {
 257   my $self = shift;
 258   my $error =
 259     $self->ut_numbern('exportnum')
 260     || $self->ut_domain('machine')
 261     || $self->ut_number('svcpart')
 262     || $self->ut_alpha('exporttype')
 263   ;
 264   return $error if $error;
 265
 266   return "Unknown svcpart: ". $self->svcpart
 267     unless qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
 268
 269   $self->machine =~ /^([\w\-\.]*)$/
 270     or return "Illegal machine: ". $self->machine;
 271   $self->machine($1);
 272
 273   $self->nodomain =~ /^(Y?)$/ or return "Illegal nodomain: ". $self->nodomain;
 274   $self->nodomain($1);
 275
 276   #check exporttype?
 277
 278   ''; #no error
 279 }
 280
 281 =item part_svc
 282
 283 Returns the service definition (see L<FS::part_svc>) for this export.
 284
 285 =cut
 286
 287 sub part_svc {
 288   my $self = shift;
 289   qsearchs('part_svc', { svcpart => $self->svcpart } );
 290 }
 291
 292 =item part_export_option
 293
 294 Returns all options as FS::part_export_option objects (see
 295 L<FS::part_export_option>).
 296
 297 =cut
 298
 299 sub part_export_option {
 300   my $self = shift;
 301   qsearch('part_export_option', { 'exportnum' => $self->exportnum } );
 302 }
 303
 304 =item options
 305
 306 Returns a list of option names and values suitable for assigning to a hash.
 307
 308 =cut
 309
 310 sub options {
 311   my $self = shift;
 312   map { $_->optionname => $_->optionvalue } $self->part_export_option;
 313 }
 314
 315 =item option OPTIONNAME
 316
 317 Returns the option value for the given name, or the empty string.
 318
 319 =cut
 320
 321 sub option {
 322   my $self = shift;
 323   my $part_export_option =
 324     qsearchs('part_export_option', {
 325       exportnum  => $self->exportnum,
 326       optionname => shift,
 327   } );
 328   $part_export_option ? $part_export_option->optionvalue : '';
 329 }
 330
 331 =item rebless
 332
 333 Reblesses the object into the FS::part_export::EXPORTTYPE class, where
 334 EXPORTTYPE is the object's I<exporttype> field.  There should be better docs
 335 on how to create new exports (and they should live in their own files and be
 336 autoloaded-on-demand), but until then, see L</NEW EXPORT CLASSES>.
 337
 338 =cut
 339
 340 sub rebless {
 341   my $self = shift;
 342   my $exporttype = $self->exporttype;
 343   my $class = ref($self);
 344   bless($self, $class."::$exporttype");
 345 }
 346
 347 =item export_insert SVC_OBJECT
 348
 349 =cut
 350
 351 sub export_insert {
 352   my $self = shift;
 353   $self->rebless;
 354   $self->_export_insert(@_);
 355 }
 356
 357 #sub AUTOLOAD {
 358 #  my $self = shift;
 359 #  $self->rebless;
 360 #  my $method = $AUTOLOAD;
 361 #  #$method =~ s/::(\w+)$/::_$1/; #infinite loop prevention
 362 #  $method =~ s/::(\w+)$/_$1/; #infinite loop prevention
 363 #  $self->$method(@_);
 364 #}
 365
 366 =item export_replace NEW OLD
 367
 368 =cut
 369
 370 sub export_replace {
 371   my $self = shift;
 372   $self->rebless;
 373   $self->_export_replace(@_);
 374 }
 375
 376 =item export_delete
 377
 378 =cut
 379
 380 sub export_delete {
 381   my $self = shift;
 382   $self->rebless;
 383   $self->_export_delete(@_);
 384 }
 385
 386 =back
 387
 388 =cut
 389
 390 #infostreet
 391
 392 package FS::part_export::infostreet;
 393 use vars qw(@ISA);
 394 @ISA = qw(FS::part_export);
 395
 396 sub _export_insert {
 397   my( $self, $svc_acct ) = (shift, shift);
 398   $self->infostreet_queue( $svc_acct->svcnum,
 399     'createUser', $svc_acct->username, $svc_acct->password );
 400 }
 401
 402 sub _export_replace {
 403   my( $self, $new, $old ) = (shift, shift, shift);
 404   return "can't change username with InfoStreet"
 405     if $old->username ne $new->username;
 406   return '' unless $old->_password ne $new->_password;
 407   $self->infostreet_queue( $new->svcnum,
 408     'passwd', $new->username, $new->password );
 409 }
 410
 411 sub _export_delete {
 412   my( $self, $svc_acct ) = (shift, shift);
 413   $self->infostreet_queue( $svc_acct->svcnum,
 414     'purgeAccount,releaseUsername', $svc_acct->username );
 415 }
 416
 417 sub infostreet_queue {
 418   my( $self, $svcnum, $method ) = (shift, shift, shift);
 419   my $queue = new FS::queue {
 420     'svcnum' => $svcnum,
 421     'job'    => 'FS::part_export::infostreet::infostreet_command',
 422   };
 423   $queue->insert(
 424     $self->option('url'),
 425     $self->option('login'),
 426     $self->option('password'),
 427     $self->option('groupID'),
 428     $method,
 429     @_,
 430   );
 431 }
 432
 433 sub infostreet_command { #subroutine, not method
 434   my($url, $username, $password, $groupID, $method, @args) = @_;
 435
 436   #quelle hack
 437   if ( $method =~ /,/ ) {
 438     foreach my $part ( split(/,\s*/, $method) ) {
 439       infostreet_command($url, $username, $password, $groupID, $part, @args);
 440     }
 441     return;
 442   }
 443
 444   eval "use Frontier::Client;";
 445
 446   my $conn = Frontier::Client->new( url => $url );
 447   my $key_result = $conn->call( 'authenticate', $username, $password, $groupID);
 448   my %key_result = _infostreet_parse($key_result);
 449   die $key_result{error} unless $key_result{success};
 450   my $key = $key_result{data};
 451
 452   my $result = $conn->call($method, $key, @args);
 453   my %result = _infostreet_parse($result);
 454   die $result{error} unless $result{success};
 455
 456 }
 457
 458 sub _infostreet_parse { #subroutine, not method
 459   my $arg = shift;
 460   map {
 461     my $value = $arg->{$_};
 462     #warn ref($value);
 463     $value = $value->value()
 464       if ref($value) && $value->isa('Frontier::RPC2::DataType');
 465     $_=>$value;
 466   } keys %$arg;
 467 }
 468
 469 #sqlradius
 470
 471 package FS::part_export::sqlradius;
 472 use vars qw(@ISA);
 473 @ISA = qw(FS::part_export);
 474
 475 sub _export_insert {
 476   my($self, $svc_acct) = (shift, shift);
 477   $self->sqlradius_queue( $svc_acct->svcnum, 'insert',
 478     'reply', $svc_acct->username, $svc_acct->radius_reply );
 479   $self->sqlradius_queue( $svc_acct->svcnum, 'insert',
 480     'check', $svc_acct->username, $svc_acct->radius_check );
 481 }
 482
 483 sub _export_replace {
 484   my( $self, $new, $old ) = (shift, shift, shift);
 485
 486   #return "can't (yet) change username with sqlradius"
 487   #  if $old->username ne $new->username;
 488   if ( $old->username ne $new->username ) {
 489     my $error = $self->sqlradius_queue( $new->svcnum, 'rename',
 490       $new->username, $old->username );
 491     return $error if $error;
 492   }
 493
 494   foreach my $table (qw(reply check)) {
 495     my $method = "radius_$table";
 496     my %new = $new->$method;
 497     my %old = $old->$method;
 498     if ( grep { !exists $old{$_} #new attributes
 499                 || $new{$_} ne $old{$_} #changed
 500               } keys %new
 501     ) {
 502       my $error = $self->sqlradius_queue( $new->svcnum, 'insert',
 503         $table, $new->username, %new );
 504       return $error if $error;
 505     }
 506
 507     my @del = grep { !exists $new{$_} } keys %old;
 508     if ( @del ) {
 509       my $error = $self->sqlradius_queue( $new->svcnum, 'attrib_delete',
 510         $table, $new->username, @del );
 511       return $error if $error;
 512     }
 513   }
 514
 515   '';
 516 }
 517
 518 sub _export_delete {
 519   my( $self, $svc_acct ) = (shift, shift);
 520   $self->sqlradius_queue( $svc_acct->svcnum, 'delete',
 521     $svc_acct->username );
 522 }
 523
 524 sub sqlradius_queue {
 525   my( $self, $svcnum, $method ) = (shift, shift, shift);
 526   my $queue = new FS::queue {
 527     'svcnum' => $svcnum,
 528     'job'    => "FS::part_export::sqlradius::sqlradius_$method",
 529   };
 530   $queue->insert(
 531     $self->option('datasrc'),
 532     $self->option('username'),
 533     $self->option('password'),
 534     @_,
 535   );
 536 }
 537
 538 sub sqlradius_insert { #subroutine, not method
 539   my $dbh = sqlradius_connect(shift, shift, shift);
 540   my( $replycheck, $username, %attributes ) = @_;
 541
 542   foreach my $attribute ( keys %attributes ) {
 543     my $u_sth = $dbh->prepare(
 544       "UPDATE rad$replycheck SET Value = ? WHERE UserName = ? AND Attribute = ?"    ) or die $dbh->errstr;
 545     my $i_sth = $dbh->prepare(
 546       "INSERT INTO rad$replycheck ( id, UserName, Attribute, Value ) ".
 547         "VALUES ( ?, ?, ?, ? )" )
 548       or die $dbh->errstr;
 549     $u_sth->execute($attributes{$attribute}, $username, $attribute) > 0
 550       or $i_sth->execute( '', $username, $attribute, $attributes{$attribute} )
 551         or die "can't insert into rad$replycheck table: ". $i_sth->errstr;
 552   }
 553   $dbh->disconnect;
 554 }
 555
 556 sub sqlradius_rename { #subroutine, not method
 557   my $dbh = sqlradius_connect(shift, shift, shift);
 558   my($new_username, $old_username) = @_;
 559   foreach my $table (qw(radreply radcheck)) {
 560     my $sth = $dbh->prepare("UPDATE $table SET Username = ? WHERE UserName = ?")
 561       or die $dbh->errstr;
 562     $sth->execute($new_username, $old_username)
 563       or die "can't update $table: ". $sth->errstr;
 564   }
 565   $dbh->disconnect;
 566 }
 567
 568 sub sqlradius_attrib_delete { #subroutine, not method
 569   my $dbh = sqlradius_connect(shift, shift, shift);
 570   my( $replycheck, $username, @attrib ) = @_;
 571
 572   foreach my $attribute ( @attrib ) {
 573     my $sth = $dbh->prepare(
 574         "DELETE FROM rad$replycheck WHERE UserName = ? AND Attribute = ?" )
 575       or die $dbh->errstr;
 576     $sth->execute($username,$attribute)
 577       or die "can't delete from rad$replycheck table: ". $sth->errstr;
 578   }
 579   $dbh->disconnect;
 580 }
 581
 582 sub sqlradius_delete { #subroutine, not method
 583   my $dbh = sqlradius_connect(shift, shift, shift);
 584   my $username = shift;
 585
 586   foreach my $table (qw( radcheck radreply )) {
 587     my $sth = $dbh->prepare( "DELETE FROM $table WHERE UserName = ?" );
 588     $sth->execute($username)
 589       or die "can't delete from $table table: ". $sth->errstr;
 590   }
 591   $dbh->disconnect;
 592 }
 593
 594 sub sqlradius_connect {
 595   #my($datasrc, $username, $password) = @_;
 596   #DBI->connect($datasrc, $username, $password) or die $DBI::errstr;
 597   DBI->connect(@_) or die $DBI::errstr;
 598 }
 599
 600 =head1 NEW EXPORT CLASSES
 601
 602   #myexport
 603
 604   package FS::part_export::myexport;
 605   use vars qw(@ISA);
 606   @ISA = qw(FS::part_export);
 607
 608   sub _export_insert {
 609     my($self, $svc_something) = (shift, shift);
 610     $self->myexport_queue( $svc_acct->svcnum, 'insert',
 611       $svc_something->username, $svc_something->password );
 612   }
 613
 614   sub _export_replace {
 615     my( $self, $new, $old ) = (shift, shift, shift);
 616     #return "can't change username with myexport"
 617     #  if $old->username ne $new->username;
 618     #return '' unless $old->_password ne $new->_password;
 619     $self->myexport_queue( $new->svcnum,
 620       'replace', $new->username, $new->password );
 621   }
 622
 623   sub _export_delete {
 624     my( $self, $svc_something ) = (shift, shift);
 625     $self->myexport_queue( $svc_acct->svcnum,
 626       'delete', $svc_something->username );
 627   }
 628
 629   #a good idea to queue anything that could fail or take any time
 630   sub myexport_queue {
 631     my( $self, $svcnum, $method ) = (shift, shift, shift);
 632     my $queue = new FS::queue {
 633       'svcnum' => $svcnum,
 634       'job'    => "FS::part_export::myexport::myexport_$method",
 635     };
 636     $queue->insert( @_ );
 637   }
 638
 639   sub myexport_insert { #subroutine, not method
 640   }
 641   sub myexport_replace { #subroutine, not method
 642   }
 643   sub myexport_delete { #subroutine, not method
 644   }
 645
 646 =head1 BUGS
 647
 648 Probably.
 649
 650 Hmm, export code has wound up in here.  Move those sub-classes out into their
 651 own files, at least.  Also hmm... cust_export class (not necessarily a
 652 database table...) ... ?
 653
 654 =head1 SEE ALSO
 655
 656 L<FS::part_export_option>, L<FS::part_svc>, L<FS::svc_acct>, L<FS::svc_domain>,
 657 L<FS::svc_forward>, L<FS::Record>, schema.html from the base documentation.
 658
 659 =cut
 660
 661 1;
 662