FS/FS/part_event.pm

   1 package FS::part_event;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG );
   5 use Carp qw(confess);
   6 use FS::Record qw( dbh qsearch qsearchs );
   7 use FS::option_Common;
   8 use FS::m2name_Common;
   9 use FS::Conf;
  10 use FS::part_event_option;
  11 use FS::part_event_condition;
  12 use FS::cust_event;
  13 use FS::agent;
  14
  15 @ISA = qw( FS::m2name_Common FS::option_Common ); # FS::Record );
  16 $DEBUG = 0;
  17
  18 =head1 NAME
  19
  20 FS::part_event - Object methods for part_event records
  21
  22 =head1 SYNOPSIS
  23
  24   use FS::part_event;
  25
  26   $record = new FS::part_event \%hash;
  27   $record = new FS::part_event { 'column' => 'value' };
  28
  29   $error = $record->insert( { 'option' => 'value' } );
  30   $error = $record->insert( \%options );
  31
  32   $error = $new_record->replace($old_record);
  33
  34   $error = $record->delete;
  35
  36   $error = $record->check;
  37
  38   $error = $record->do_event( $direct_object );
  39
  40 =head1 DESCRIPTION
  41
  42 An FS::part_event object represents an event definition - a billing, collection
  43 or other callback which is triggered when certain customer, invoice, package or
  44 other conditions are met.  FS::part_event inherits from FS::Record.  The
  45 following fields are currently supported:
  46
  47 =over 4
  48
  49 =item eventpart - primary key
  50
  51 =item agentnum - Optional agentnum (see L<FS::agent>)
  52
  53 =item event - event name
  54
  55 =item eventtable - table name against which this event is triggered; currently "cust_bill" (the traditional invoice events), "cust_main" (customer events) or "cust_pkg (package events)
  56
  57 =item check_freq - how often events of this type are checked; currently "1d" (daily) and "1m" (monthly) are recognized.  Note that the apprioriate freeside-daily and/or freeside-monthly cron job needs to be in place.
  58
  59 =item weight - ordering for events
  60
  61 =item action - event action (like part_bill_event.plan - eventcode plan)
  62
  63 =item disabled - Disabled flag, empty or `Y'
  64
  65 =back
  66
  67 =head1 METHODS
  68
  69 =over 4
  70
  71 =item new HASHREF
  72
  73 Creates a new invoice event definition.  To add the invoice event definition to
  74 the database, see L<"insert">.
  75
  76 Note that this stores the hash reference, not a distinct copy of the hash it
  77 points to.  You can ask the object for a copy with the I<hash> method.
  78
  79 =cut
  80
  81 # the new method can be inherited from FS::Record, if a table method is defined
  82
  83 sub table { 'part_event'; }
  84
  85 =item insert [ HASHREF ]
  86
  87 Adds this record to the database.  If there is an error, returns the error,
  88 otherwise returns false.
  89
  90 If a list or hash reference of options is supplied, part_export_option records
  91 are created (see L<FS::part_event_option>).
  92
  93 =cut
  94
  95 # the insert method can be inherited from FS::Record
  96
  97 =item delete
  98
  99 Delete this record from the database.
 100
 101 =cut
 102
 103 # the delete method can be inherited from FS::Record
 104
 105 =item replace OLD_RECORD [ HASHREF | OPTION => VALUE ... ]
 106
 107 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 108 returns the error, otherwise returns false.
 109
 110 If a list or hash reference of options is supplied, part_event_option
 111 records are created or modified (see L<FS::part_event_option>).
 112
 113 =cut
 114
 115 # the replace method can be inherited from FS::Record
 116
 117 =item check
 118
 119 Checks all fields to make sure this is a valid invoice event definition.  If
 120 there is an error, returns the error, otherwise returns false.  Called by the
 121 insert and replace methods.
 122
 123 =cut
 124
 125 # the check method should currently be supplied - FS::Record contains some
 126 # data checking routines
 127
 128 sub check {
 129   my $self = shift;
 130
 131   $self->weight(0) unless $self->weight;
 132
 133   my $error =
 134        $self->ut_numbern('eventpart')
 135     || $self->ut_text('event')
 136     || $self->ut_enum('eventtable', [ 'cust_bill', 'cust_main', 'cust_pkg' ] )
 137     || $self->ut_enum('check_freq', [ '1d', '1m' ])
 138     || $self->ut_number('weight')
 139     || $self->ut_alpha('action')
 140     || $self->ut_enum('disabled', [ '', 'Y' ] )
 141     || $self->ut_agentnum_acl('agentnum', 'Edit global billing events')
 142   ;
 143   return $error if $error;
 144
 145   #XXX check action to make sure a module exists?
 146   # well it'll die in _rebless...
 147
 148   $self->SUPER::check;
 149 }
 150
 151 =item _rebless
 152
 153 Reblesses the object into the FS::part_event::Action::ACTION class, where
 154 ACTION is the object's I<action> field.
 155
 156 =cut
 157
 158 sub _rebless {
 159   my $self = shift;
 160   my $action = $self->action or return $self;
 161   #my $class = ref($self). "::$action";
 162   my $class = "FS::part_event::Action::$action";
 163   eval "use $class";
 164   die $@ if $@;
 165   bless($self, $class); # unless $@;
 166   $self;
 167 }
 168
 169 =item part_event_condition
 170
 171 Returns the conditions associated with this event, as FS::part_event_condition
 172 objects (see L<FS::part_event_condition>)
 173
 174 =cut
 175
 176 sub part_event_condition {
 177   my $self = shift;
 178   qsearch( 'part_event_condition', { 'eventpart' => $self->eventpart } );
 179 }
 180
 181 =item new_cust_event OBJECT
 182
 183 Creates a new customer event (see L<FS::cust_event>) for the provided object.
 184
 185 =cut
 186
 187 sub new_cust_event {
 188   my( $self, $object ) = @_;
 189
 190   confess "**** $object is not a ". $self->eventtable
 191     if ref($object) ne "FS::". $self->eventtable;
 192
 193   my $pkey = $object->primary_key;
 194
 195   new FS::cust_event {
 196     'eventpart' => $self->eventpart,
 197     'tablenum'  => $object->$pkey(),
 198     '_date'     => time, #i think we always want the real "now" here.
 199     'status'    => 'new',
 200   };
 201 }
 202
 203 #surely this doesn't work
 204 sub reasontext { confess "part_event->reasontext deprecated"; }
 205 #=item reasontext
 206 #
 207 #Returns the text of any reason associated with this event.
 208 #
 209 #=cut
 210 #
 211 #sub reasontext {
 212 #  my $self = shift;
 213 #  my $r = qsearchs('reason', { 'reasonnum' => $self->reason });
 214 #  if ($r){
 215 #    $r->reason;
 216 #  }else{
 217 #    '';
 218 #  }
 219 #}
 220
 221 =item agent
 222
 223 Returns the associated agent for this event, if any, as an FS::agent object.
 224
 225 =cut
 226
 227 sub agent {
 228   my $self = shift;
 229   qsearchs('agent', { 'agentnum' => $self->agentnum } );
 230 }
 231
 232 =item templatename
 233
 234 Returns the alternate invoice template name, if any, or false if there is
 235 no alternate template for this event.
 236
 237 =cut
 238
 239 sub templatename {
 240
 241   my $self = shift;
 242   if (    $self->action   =~ /^cust_bill_send_(alternate|agent)$/
 243           && (    $self->option('agent_templatename')
 244                || $self->option('templatename')       )
 245      )
 246   {
 247        $self->option('agent_templatename')
 248     || $self->option('templatename');
 249
 250   } else {
 251     '';
 252   }
 253 }
 254
 255 =back
 256
 257 =head1 CLASS METHODS
 258
 259 =over 4
 260
 261 =item eventtable_labels
 262
 263 Returns a hash reference of labels for eventtable values,
 264 i.e. 'cust_main'=>'Customer'
 265
 266 =cut
 267
 268 sub eventtable_labels {
 269   #my $class = shift;
 270
 271   tie my %hash, 'Tie::IxHash',
 272     'cust_pkg'       => 'Package',
 273     'cust_bill'      => 'Invoice',
 274     'cust_main'      => 'Customer',
 275     'cust_pay_batch' => 'Batch payment',
 276   ;
 277
 278   \%hash
 279 }
 280
 281 =item eventtable_pkey_sql
 282
 283 Returns a hash reference of full SQL primary key names for eventtable values,
 284 i.e. 'cust_main'=>'cust_main.custnum'
 285
 286 =cut
 287
 288 sub eventtable_pkey_sql {
 289   #my $class = shift;
 290
 291   my %hash = (
 292     'cust_main'      => 'cust_main.custnum',
 293     'cust_bill'      => 'cust_bill.invnum',
 294     'cust_pkg'       => 'cust_pkg.pkgnum',
 295     'cust_pay_batch' => 'cust_pay_batch.paybatchnum',
 296   );
 297
 298   \%hash;
 299 }
 300
 301
 302 =item eventtables
 303
 304 Returns a list of eventtable values (default ordering; suited for display).
 305
 306 =cut
 307
 308 sub eventtables {
 309   my $class = shift;
 310   my $eventtables = $class->eventtable_labels;
 311   keys %$eventtables;
 312 }
 313
 314 =item eventtables_runorder
 315
 316 Returns a list of eventtable values (run order).
 317
 318 =cut
 319
 320 sub eventtables_runorder {
 321   shift->eventtables; #same for now
 322 }
 323
 324 =item check_freq_labels
 325
 326 Returns a hash reference of labels for check_freq values,
 327 i.e. '1d'=>'daily'
 328
 329 =cut
 330
 331 sub check_freq_labels {
 332   #my $class = shift;
 333
 334   #Tie::IxHash??
 335   {
 336     '1d' => 'daily',
 337     '1m' => 'monthly',
 338   };
 339 }
 340
 341 =item actions [ EVENTTABLE ]
 342
 343 Return information about the available actions.  If an eventtable is specified,
 344 only return information about actions available for that eventtable.
 345
 346 Information is returned as key-value pairs.  Keys are event names.  Values are
 347 hashrefs with the following keys:
 348
 349 =over 4
 350
 351 =item description
 352
 353 =item eventtable_hashref
 354
 355 =item option_fields
 356
 357 =item default_weight
 358
 359 =item deprecated
 360
 361 =back
 362
 363 See L<FS::part_event::Action> for more information.
 364
 365 =cut
 366
 367 #false laziness w/part_event_condition.pm
 368 #some false laziness w/part_export & part_pkg
 369 my %actions;
 370 foreach my $INC ( @INC ) {
 371   foreach my $file ( glob("$INC/FS/part_event/Action/*.pm") ) {
 372     warn "attempting to load Action from $file\n" if $DEBUG;
 373     $file =~ /\/(\w+)\.pm$/ or do {
 374       warn "unrecognized file in $INC/FS/part_event/Action/: $file\n";
 375       next;
 376     };
 377     my $mod = $1;
 378     eval "use FS::part_event::Action::$mod;";
 379     if ( $@ ) {
 380       die "error using FS::part_event::Action::$mod (skipping): $@\n" if $@;
 381       #warn "error using FS::part_event::Action::$mod (skipping): $@\n" if $@;
 382       #next;
 383     }
 384     $actions{$mod} = {
 385       ( map { $_ => "FS::part_event::Action::$mod"->$_() }
 386             qw( description eventtable_hashref default_weight deprecated )
 387             #option_fields_hashref
 388       ),
 389       'option_fields' => [ "FS::part_event::Action::$mod"->option_fields() ],
 390     };
 391   }
 392 }
 393
 394 sub actions {
 395   my( $class, $eventtable ) = @_;
 396   (
 397     map  { $_ => $actions{$_} }
 398     sort { $actions{$a}->{'default_weight'}<=>$actions{$b}->{'default_weight'} }
 399     $class->all_actions( $eventtable )
 400   );
 401
 402 }
 403
 404 =item all_actions [ EVENTTABLE ]
 405
 406 Returns a list of just the action names
 407
 408 =cut
 409
 410 sub all_actions {
 411   my ( $class, $eventtable ) = @_;
 412
 413   grep { !$eventtable || $actions{$_}->{'eventtable_hashref'}{$eventtable} }
 414        keys %actions
 415 }
 416
 417 =back
 418
 419 =head1 SEE ALSO
 420
 421 L<FS::part_event_option>, L<FS::part_event_condition>, L<FS::cust_main>,
 422 L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_bill_event>, L<FS::Record>,
 423 schema.html from the base documentation.
 424
 425 =cut
 426
 427 1;
 428