FS/FS/msg_template.pm

   1 package FS::msg_template;
   2 use base qw( FS::Record );
   3
   4 use strict;
   5 use vars qw( $DEBUG $conf );
   6
   7 use Date::Format qw( time2str );
   8 use File::Temp;
   9 use IPC::Run qw(run);
  10 use Text::Template;
  11
  12 use HTML::Entities qw( decode_entities encode_entities ) ;
  13 use HTML::FormatText;
  14 use HTML::TreeBuilder;
  15 use Encode;
  16
  17 use FS::Misc qw( generate_email send_email do_print );
  18 use FS::Conf;
  19 use FS::Record qw( qsearch qsearchs );
  20 use FS::UID qw( dbh );
  21
  22 use FS::cust_main;
  23 use FS::cust_msg;
  24 use FS::template_content;
  25
  26 FS::UID->install_callback( sub { $conf = new FS::Conf; } );
  27
  28 $DEBUG=0;
  29
  30 =head1 NAME
  31
  32 FS::msg_template - Object methods for msg_template records
  33
  34 =head1 SYNOPSIS
  35
  36   use FS::msg_template;
  37
  38   $record = new FS::msg_template \%hash;
  39   $record = new FS::msg_template { 'column' => 'value' };
  40
  41   $error = $record->insert;
  42
  43   $error = $new_record->replace($old_record);
  44
  45   $error = $record->delete;
  46
  47   $error = $record->check;
  48
  49 =head1 DESCRIPTION
  50
  51 An FS::msg_template object represents a customer message template.
  52 FS::msg_template inherits from FS::Record.  The following fields are currently
  53 supported:
  54
  55 =over 4
  56
  57 =item msgnum - primary key
  58
  59 =item msgname - Name of the template.  This will appear in the user interface;
  60 if it needs to be localized for some users, add it to the message catalog.
  61
  62 =item agentnum - Agent associated with this template.  Can be NULL for a
  63 global template.
  64
  65 =item mime_type - MIME type.  Defaults to text/html.
  66
  67 =item from_addr - Source email address.
  68
  69 =item disabled - disabled ('Y' or NULL).
  70
  71 =back
  72
  73 =head1 METHODS
  74
  75 =over 4
  76
  77 =item new HASHREF
  78
  79 Creates a new template.  To add the template to the database, see L<"insert">.
  80
  81 Note that this stores the hash reference, not a distinct copy of the hash it
  82 points to.  You can ask the object for a copy with the I<hash> method.
  83
  84 =cut
  85
  86 # the new method can be inherited from FS::Record, if a table method is defined
  87
  88 sub table { 'msg_template'; }
  89
  90 =item insert [ CONTENT ]
  91
  92 Adds this record to the database.  If there is an error, returns the error,
  93 otherwise returns false.
  94
  95 A default (no locale) L<FS::template_content> object will be created.  CONTENT
  96 is an optional hash containing 'subject' and 'body' for this object.
  97
  98 =cut
  99
 100 sub insert {
 101   my $self = shift;
 102   my %content = @_;
 103
 104   my $oldAutoCommit = $FS::UID::AutoCommit;
 105   local $FS::UID::AutoCommit = 0;
 106   my $dbh = dbh;
 107
 108   my $error = $self->SUPER::insert;
 109   if ( !$error ) {
 110     $content{'msgnum'} = $self->msgnum;
 111     $content{'subject'} ||= '';
 112     $content{'body'} ||= '';
 113     my $template_content = new FS::template_content (\%content);
 114     $error = $template_content->insert;
 115   }
 116
 117   if ( $error ) {
 118     $dbh->rollback if $oldAutoCommit;
 119     return $error;
 120   }
 121
 122   $dbh->commit if $oldAutoCommit;
 123   return;
 124 }
 125
 126 =item delete
 127
 128 Delete this record from the database.
 129
 130 =cut
 131
 132 # the delete method can be inherited from FS::Record
 133
 134 =item replace [ OLD_RECORD ] [ CONTENT ]
 135
 136 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 137 returns the error, otherwise returns false.
 138
 139 CONTENT is an optional hash containing 'subject', 'body', and 'locale'.  If
 140 supplied, an L<FS::template_content> object will be created (or modified, if
 141 one already exists for this locale).
 142
 143 =cut
 144
 145 sub replace {
 146   my $self = shift;
 147   my $old = ( ref($_[0]) and $_[0]->isa('FS::Record') )
 148               ? shift
 149               : $self->replace_old;
 150   my %content = @_;
 151
 152   my $oldAutoCommit = $FS::UID::AutoCommit;
 153   local $FS::UID::AutoCommit = 0;
 154   my $dbh = dbh;
 155
 156   my $error = $self->SUPER::replace($old);
 157
 158   if ( !$error and %content ) {
 159     $content{'locale'} ||= '';
 160     my $new_content = qsearchs('template_content', {
 161                         'msgnum' => $self->msgnum,
 162                         'locale' => $content{'locale'},
 163                       } );
 164     if ( $new_content ) {
 165       $new_content->subject($content{'subject'});
 166       $new_content->body($content{'body'});
 167       $error = $new_content->replace;
 168     }
 169     else {
 170       $content{'msgnum'} = $self->msgnum;
 171       $new_content = new FS::template_content \%content;
 172       $error = $new_content->insert;
 173     }
 174   }
 175
 176   if ( $error ) {
 177     $dbh->rollback if $oldAutoCommit;
 178     return $error;
 179   }
 180
 181   warn "committing FS::msg_template->replace\n" if $DEBUG and $oldAutoCommit;
 182   $dbh->commit if $oldAutoCommit;
 183   return;
 184 }
 185
 186
 187
 188 =item check
 189
 190 Checks all fields to make sure this is a valid template.  If there is
 191 an error, returns the error, otherwise returns false.  Called by the insert
 192 and replace methods.
 193
 194 =cut
 195
 196 # the check method should currently be supplied - FS::Record contains some
 197 # data checking routines
 198
 199 sub check {
 200   my $self = shift;
 201
 202   my $error =
 203     $self->ut_numbern('msgnum')
 204     || $self->ut_text('msgname')
 205     || $self->ut_foreign_keyn('agentnum', 'agent', 'agentnum')
 206     || $self->ut_textn('mime_type')
 207     || $self->ut_enum('disabled', [ '', 'Y' ] )
 208     || $self->ut_textn('from_addr')
 209   ;
 210   return $error if $error;
 211
 212   $self->mime_type('text/html') unless $self->mime_type;
 213
 214   $self->SUPER::check;
 215 }
 216
 217 =item content_locales
 218
 219 Returns a hashref of the L<FS::template_content> objects attached to
 220 this template, with the locale as key.
 221
 222 =cut
 223
 224 sub content_locales {
 225   my $self = shift;
 226   return $self->{'_content_locales'} ||= +{
 227     map { $_->locale , $_ }
 228     qsearch('template_content', { 'msgnum' => $self->msgnum })
 229   };
 230 }
 231
 232 =item prepare OPTION => VALUE
 233
 234 Fills in the template and returns a hash of the 'from' address, 'to'
 235 addresses, subject line, and body.
 236
 237 Options are passed as a list of name/value pairs:
 238
 239 =over 4
 240
 241 =item cust_main
 242
 243 Customer object (required).
 244
 245 =item object
 246
 247 Additional context object (currently, can be a cust_main, cust_pkg,
 248 cust_bill, cust_pay, cust_pay_pending, or svc_(acct, phone, broadband,
 249 domain) ).  If the object is a svc_*, its cust_pkg will be fetched and
 250 used for substitution.
 251
 252 As a special case, this may be an arrayref of two objects.  Both
 253 objects will be available for substitution, with their field names
 254 prefixed with 'new_' and 'old_' respectively.  This is used in the
 255 rt_ticket export when exporting "replace" events.
 256
 257 =item from_config
 258
 259 Configuration option to use as the source address, based on the customer's
 260 agentnum.  If unspecified (or the named option is empty), 'invoice_from'
 261 will be used.
 262
 263 The I<from_addr> field in the template takes precedence over this.
 264
 265 =item to
 266
 267 Destination address.  The default is to use the customer's
 268 invoicing_list addresses.  Multiple addresses may be comma-separated.
 269
 270 =item substitutions
 271
 272 A hash reference of additional substitutions
 273
 274 =back
 275
 276 =cut
 277
 278 sub prepare {
 279   my( $self, %opt ) = @_;
 280
 281   my $cust_main = $opt{'cust_main'} or die 'cust_main required';
 282   my $object = $opt{'object'} or die 'object required';
 283
 284   # localization
 285   my $locale = $cust_main->locale || '';
 286   warn "no locale for cust#".$cust_main->custnum."; using default content\n"
 287     if $DEBUG and !$locale;
 288   my $content = $self->content($cust_main->locale);
 289   warn "preparing template '".$self->msgname."' to cust#".$cust_main->custnum."\n"
 290     if($DEBUG);
 291
 292   my $subs = $self->substitutions;
 293
 294   ###
 295   # create substitution table
 296   ###
 297   my %hash;
 298   my @objects = ($cust_main);
 299   my @prefixes = ('');
 300   my $svc;
 301   if( ref $object ) {
 302     if( ref($object) eq 'ARRAY' ) {
 303       # [new, old], for provisioning tickets
 304       push @objects, $object->[0], $object->[1];
 305       push @prefixes, 'new_', 'old_';
 306       $svc = $object->[0] if $object->[0]->isa('FS::svc_Common');
 307     }
 308     else {
 309       push @objects, $object;
 310       push @prefixes, '';
 311       $svc = $object if $object->isa('FS::svc_Common');
 312     }
 313   }
 314   if( $svc ) {
 315     push @objects, $svc->cust_svc->cust_pkg;
 316     push @prefixes, '';
 317   }
 318
 319   foreach my $obj (@objects) {
 320     my $prefix = shift @prefixes;
 321     foreach my $name (@{ $subs->{$obj->table} }) {
 322       if(!ref($name)) {
 323         # simple case
 324         $hash{$prefix.$name} = $obj->$name();
 325       }
 326       elsif( ref($name) eq 'ARRAY' ) {
 327         # [ foo => sub { ... } ]
 328         $hash{$prefix.($name->[0])} = $name->[1]->($obj);
 329       }
 330       else {
 331         warn "bad msg_template substitution: '$name'\n";
 332         #skip it?
 333       }
 334     }
 335   }
 336
 337   if ( $opt{substitutions} ) {
 338     $hash{$_} = $opt{substitutions}->{$_} foreach keys %{$opt{substitutions}};
 339   }
 340
 341   $_ = encode_entities($_ || '') foreach values(%hash);
 342
 343   ###
 344   # clean up template
 345   ###
 346   my $subject_tmpl = new Text::Template (
 347     TYPE   => 'STRING',
 348     SOURCE => $content->subject,
 349   );
 350   my $subject = $subject_tmpl->fill_in( HASH => \%hash );
 351
 352   my $body = $content->body;
 353   my ($skin, $guts) = eviscerate($body);
 354   @$guts = map {
 355     $_ = decode_entities($_); # turn all punctuation back into itself
 356     s/\r//gs;           # remove \r's
 357     s/<br[^>]*>/\n/gsi; # and <br /> tags
 358     s/<p>/\n/gsi;       # and <p>
 359     s/<\/p>//gsi;       # and </p>
 360     s/\240/ /gs;        # and &nbsp;
 361     $_
 362   } @$guts;
 363
 364   $body = '{ use Date::Format qw(time2str); "" }';
 365   while(@$skin || @$guts) {
 366     $body .= shift(@$skin) || '';
 367     $body .= shift(@$guts) || '';
 368   }
 369
 370   ###
 371   # fill-in
 372   ###
 373
 374   my $body_tmpl = new Text::Template (
 375     TYPE          => 'STRING',
 376     SOURCE        => $body,
 377   );
 378
 379   $body = $body_tmpl->fill_in( HASH => \%hash );
 380
 381   ###
 382   # and email
 383   ###
 384
 385   my @to;
 386   if ( exists($opt{'to'}) ) {
 387     @to = split(/\s*,\s*/, $opt{'to'});
 388   }
 389   else {
 390     @to = $cust_main->invoicing_list_emailonly;
 391   }
 392   # no warning when preparing with no destination
 393
 394   my $from_addr = $self->from_addr;
 395
 396   if ( !$from_addr ) {
 397     if ( $opt{'from_config'} ) {
 398       $from_addr = scalar( $conf->config($opt{'from_config'},
 399                                          $cust_main->agentnum) );
 400     }
 401     $from_addr ||= scalar( $conf->config('invoice_from',
 402                                          $cust_main->agentnum) );
 403   }
 404 #  my @cust_msg = ();
 405 #  if ( $conf->exists('log_sent_mail') and !$opt{'preview'} ) {
 406 #    my $cust_msg = FS::cust_msg->new({
 407 #        'custnum' => $cust_main->custnum,
 408 #        'msgnum'  => $self->msgnum,
 409 #        'status'  => 'prepared',
 410 #      });
 411 #    $cust_msg->insert;
 412 #    @cust_msg = ('cust_msg' => $cust_msg);
 413 #  }
 414
 415   my $text_body = encode('UTF-8',
 416                   HTML::FormatText->new(leftmargin => 0, rightmargin => 70)
 417                       ->format( HTML::TreeBuilder->new_from_content($body) )
 418                   );
 419   (
 420     'custnum' => $cust_main->custnum,
 421     'msgnum'  => $self->msgnum,
 422     'from' => $from_addr,
 423     'to'   => \@to,
 424     'bcc'  => $self->bcc_addr || undef,
 425     'subject'   => $subject,
 426     'html_body' => $body,
 427     'text_body' => $text_body
 428   );
 429
 430 }
 431
 432 =item send OPTION => VALUE
 433
 434 Fills in the template and sends it to the customer.  Options are as for
 435 'prepare'.
 436
 437 =cut
 438
 439 # broken out from prepare() in case we want to queue the sending,
 440 # preview it, etc.
 441 sub send {
 442   my $self = shift;
 443   send_email(generate_email($self->prepare(@_)));
 444 }
 445
 446 =item render OPTION => VALUE ...
 447
 448 Fills in the template and renders it to a PDF document.  Returns the
 449 name of the PDF file.
 450
 451 Options are as for 'prepare', but 'from' and 'to' are meaningless.
 452
 453 =cut
 454
 455 # will also have options to set paper size, margins, etc.
 456
 457 sub render {
 458   my $self = shift;
 459   eval "use PDF::WebKit";
 460   die $@ if $@;
 461   my %opt = @_;
 462   my %hash = $self->prepare(%opt);
 463   my $html = $hash{'html_body'};
 464
 465   # Graphics/stylesheets should probably go in /var/www on the Freeside
 466   # machine.
 467   my $kit = PDF::WebKit->new(\$html); #%options
 468   # hack to use our wrapper script
 469   $kit->configure(sub { shift->wkhtmltopdf('freeside-wkhtmltopdf') });
 470
 471   $kit->to_pdf;
 472 }
 473
 474 =item print OPTIONS
 475
 476 Render a PDF and send it to the printer.  OPTIONS are as for 'render'.
 477
 478 =cut
 479
 480 sub print {
 481   my( $self, %opt ) = @_;
 482   do_print( [ $self->render(%opt) ], agentnum=>$opt{cust_main}->agentnum );
 483 }
 484
 485 # helper sub for package dates
 486 my $ymd = sub { $_[0] ? time2str('%Y-%m-%d', $_[0]) : '' };
 487
 488 # helper sub for money amounts
 489 my $money = sub { ($conf->money_char || '$') . sprintf('%.2f', $_[0] || 0) };
 490
 491 # helper sub for usage-related messages
 492 my $usage_warning = sub {
 493   my $svc = shift;
 494   foreach my $col (qw(seconds upbytes downbytes totalbytes)) {
 495     my $amount = $svc->$col; next if $amount eq '';
 496     my $method = $col.'_threshold';
 497     my $threshold = $svc->$method; next if $threshold eq '';
 498     return [$col, $amount, $threshold] if $amount <= $threshold;
 499     # this only returns the first one that's below threshold, if there are
 500     # several.
 501   }
 502   return ['', '', ''];
 503 };
 504
 505 #my $conf = new FS::Conf;
 506
 507 #return contexts and fill-in values
 508 # If you add anything, be sure to add a description in
 509 # httemplate/edit/msg_template.html.
 510 sub substitutions {
 511   { 'cust_main' => [qw(
 512       display_custnum agentnum agent_name
 513
 514       last first company
 515       name name_short contact contact_firstlast
 516       address1 address2 city county state zip
 517       country
 518       daytime night mobile fax
 519
 520       has_ship_address
 521       ship_name ship_name_short ship_contact ship_contact_firstlast
 522       ship_address1 ship_address2 ship_city ship_county ship_state ship_zip
 523       ship_country
 524
 525       paymask payname paytype payip
 526       num_cancelled_pkgs num_ncancelled_pkgs num_pkgs
 527       classname categoryname
 528       balance
 529       credit_limit
 530       invoicing_list_emailonly
 531       cust_status ucfirst_cust_status cust_statuscolor cust_status_label
 532
 533       signupdate dundate
 534       packages recurdates
 535       ),
 536       [ invoicing_email => sub { shift->invoicing_list_emailonly_scalar } ],
 537       #compatibility: obsolete ship_ fields - use the non-ship versions
 538       map (
 539         { my $field = $_;
 540           [ "ship_$field"   => sub { shift->$field } ]
 541         }
 542         qw( last first company daytime night fax )
 543       ),
 544       # ship_name, ship_name_short, ship_contact, ship_contact_firstlast
 545       # still work, though
 546       [ expdate           => sub { shift->paydate_epoch } ], #compatibility
 547       [ signupdate_ymd    => sub { $ymd->(shift->signupdate) } ],
 548       [ dundate_ymd       => sub { $ymd->(shift->dundate) } ],
 549       [ paydate_my        => sub { sprintf('%02d/%04d', shift->paydate_monthyear) } ],
 550       [ otaker_first      => sub { shift->access_user->first } ],
 551       [ otaker_last       => sub { shift->access_user->last } ],
 552       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 553       [ company_name      => sub {
 554           $conf->config('company_name', shift->agentnum)
 555         } ],
 556       [ company_address   => sub {
 557           $conf->config('company_address', shift->agentnum)
 558         } ],
 559       [ company_phonenum  => sub {
 560           $conf->config('company_phonenum', shift->agentnum)
 561         } ],
 562       [ selfservice_server_base_url => sub {
 563           $conf->config('selfservice_server-base_url') #, shift->agentnum)
 564         } ],
 565     ],
 566     # next_bill_date
 567     'cust_pkg'  => [qw(
 568       pkgnum pkg_label pkg_label_long
 569       location_label
 570       status statuscolor
 571
 572       start_date setup bill last_bill
 573       adjourn susp expire
 574       labels_short
 575       ),
 576       [ pkg               => sub { shift->part_pkg->pkg } ],
 577       [ pkg_category      => sub { shift->part_pkg->categoryname } ],
 578       [ pkg_class         => sub { shift->part_pkg->classname } ],
 579       [ cancel            => sub { shift->getfield('cancel') } ], # grrr...
 580       [ start_ymd         => sub { $ymd->(shift->getfield('start_date')) } ],
 581       [ setup_ymd         => sub { $ymd->(shift->getfield('setup')) } ],
 582       [ next_bill_ymd     => sub { $ymd->(shift->getfield('bill')) } ],
 583       [ last_bill_ymd     => sub { $ymd->(shift->getfield('last_bill')) } ],
 584       [ adjourn_ymd       => sub { $ymd->(shift->getfield('adjourn')) } ],
 585       [ susp_ymd          => sub { $ymd->(shift->getfield('susp')) } ],
 586       [ expire_ymd        => sub { $ymd->(shift->getfield('expire')) } ],
 587       [ cancel_ymd        => sub { $ymd->(shift->getfield('cancel')) } ],
 588
 589       # not necessarily correct for non-flat packages
 590       [ setup_fee         => sub { shift->part_pkg->option('setup_fee') } ],
 591       [ recur_fee         => sub { shift->part_pkg->option('recur_fee') } ],
 592
 593       [ freq_pretty       => sub { shift->part_pkg->freq_pretty } ],
 594
 595     ],
 596     'cust_bill' => [qw(
 597       invnum
 598       _date
 599       due_date
 600     )],
 601     #XXX not really thinking about cust_bill substitutions quite yet
 602
 603     # for welcome and limit warning messages
 604     'svc_acct' => [qw(
 605       svcnum
 606       username
 607       domain
 608       ),
 609       [ password          => sub { shift->getfield('_password') } ],
 610       [ column            => sub { &$usage_warning(shift)->[0] } ],
 611       [ amount            => sub { &$usage_warning(shift)->[1] } ],
 612       [ threshold         => sub { &$usage_warning(shift)->[2] } ],
 613     ],
 614     'svc_domain' => [qw(
 615       svcnum
 616       domain
 617       ),
 618       [ registrar         => sub {
 619           my $registrar = qsearchs('registrar',
 620             { registrarnum => shift->registrarnum} );
 621           $registrar ? $registrar->registrarname : ''
 622         }
 623       ],
 624       [ catchall          => sub {
 625           my $svc_acct = qsearchs('svc_acct', { svcnum => shift->catchall });
 626           $svc_acct ? $svc_acct->email : ''
 627         }
 628       ],
 629     ],
 630     'svc_phone' => [qw(
 631       svcnum
 632       phonenum
 633       countrycode
 634       domain
 635       )
 636     ],
 637     'svc_broadband' => [qw(
 638       svcnum
 639       speed_up
 640       speed_down
 641       ip_addr
 642       mac_addr
 643       )
 644     ],
 645     # for payment receipts
 646     'cust_pay' => [qw(
 647       paynum
 648       _date
 649       ),
 650       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 651       # overrides the one in cust_main in cases where a cust_pay is passed
 652       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 653       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 654       [ payinfo           => sub {
 655           my $cust_pay = shift;
 656           ($cust_pay->payby eq 'CARD' || $cust_pay->payby eq 'CHEK') ?
 657             $cust_pay->paymask : $cust_pay->decrypt($cust_pay->payinfo)
 658         } ],
 659     ],
 660     # for payment decline messages
 661     # try to support all cust_pay fields
 662     # 'error' is a special case, it contains the raw error from the gateway
 663     'cust_pay_pending' => [qw(
 664       _date
 665       error
 666       ),
 667       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 668       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 669       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 670       [ payinfo           => sub {
 671           my $pending = shift;
 672           ($pending->payby eq 'CARD' || $pending->payby eq 'CHEK') ?
 673             $pending->paymask : $pending->decrypt($pending->payinfo)
 674         } ],
 675     ],
 676   };
 677 }
 678
 679 =item content LOCALE
 680
 681 Returns the L<FS::template_content> object appropriate to LOCALE, if there
 682 is one.  If not, returns the one with a NULL locale.
 683
 684 =cut
 685
 686 sub content {
 687   my $self = shift;
 688   my $locale = shift;
 689   qsearchs('template_content',
 690             { 'msgnum' => $self->msgnum, 'locale' => $locale }) ||
 691   qsearchs('template_content',
 692             { 'msgnum' => $self->msgnum, 'locale' => '' });
 693 }
 694
 695 =item agent
 696
 697 Returns the L<FS::agent> object for this template.
 698
 699 =cut
 700
 701 sub _upgrade_data {
 702   my ($self, %opts) = @_;
 703
 704   ###
 705   # First move any historical templates in config to real message templates
 706   ###
 707
 708   my @fixes = (
 709     [ 'alerter_msgnum',  'alerter_template',   '',               '', '' ],
 710     [ 'cancel_msgnum',   'cancelmessage',      'cancelsubject',  '', '' ],
 711     [ 'decline_msgnum',  'declinetemplate',    '',               '', '' ],
 712     [ 'impending_recur_msgnum', 'impending_recur_template', '',  '', 'impending_recur_bcc' ],
 713     [ 'payment_receipt_msgnum', 'payment_receipt_email', '',     '', '' ],
 714     [ 'welcome_msgnum',  'welcome_email',      'welcome_email-subject', 'welcome_email-from', '' ],
 715     [ 'warning_msgnum',  'warning_email',      'warning_email-subject', 'warning_email-from', '' ],
 716   );
 717
 718   my @agentnums = ('', map {$_->agentnum} qsearch('agent', {}));
 719   foreach my $agentnum (@agentnums) {
 720     foreach (@fixes) {
 721       my ($newname, $oldname, $subject, $from, $bcc) = @$_;
 722       if ($conf->exists($oldname, $agentnum)) {
 723         my $new = new FS::msg_template({
 724           'msgname'   => $oldname,
 725           'agentnum'  => $agentnum,
 726           'from_addr' => ($from && $conf->config($from, $agentnum)) || '',
 727           'bcc_addr'  => ($bcc && $conf->config($from, $agentnum)) || '',
 728           'subject'   => ($subject && $conf->config($subject, $agentnum)) || '',
 729           'mime_type' => 'text/html',
 730           'body'      => join('<BR>',$conf->config($oldname, $agentnum)),
 731         });
 732         my $error = $new->insert;
 733         die $error if $error;
 734         $conf->set($newname, $new->msgnum, $agentnum);
 735         $conf->delete($oldname, $agentnum);
 736         $conf->delete($from, $agentnum) if $from;
 737         $conf->delete($subject, $agentnum) if $subject;
 738       }
 739     }
 740
 741     if ( $conf->exists('alert_expiration', $agentnum) ) {
 742       my $msgnum = $conf->exists('alerter_msgnum', $agentnum);
 743       my $template = FS::msg_template->by_key($msgnum) if $msgnum;
 744       if (!$template) {
 745         warn "template for alerter_msgnum $msgnum not found\n";
 746         next;
 747       }
 748       # this is now a set of billing events
 749       foreach my $days (30, 15, 5) {
 750         my $event = FS::part_event->new({
 751             'agentnum'    => $agentnum,
 752             'event'       => "Card expiration warning - $days days",
 753             'eventtable'  => 'cust_main',
 754             'check_freq'  => '1d',
 755             'action'      => 'notice',
 756             'disabled'    => 'Y', #initialize first
 757         });
 758         my $error = $event->insert( 'msgnum' => $msgnum );
 759         if ($error) {
 760           warn "error creating expiration alert event:\n$error\n\n";
 761           next;
 762         }
 763         # make it work like before:
 764         # only send each warning once before the card expires,
 765         # only warn active customers,
 766         # only warn customers with CARD/DCRD,
 767         # only warn customers who get email invoices
 768         my %conds = (
 769           'once_every'          => { 'run_delay' => '30d' },
 770           'cust_paydate_within' => { 'within' => $days.'d' },
 771           'cust_status'         => { 'status' => { 'active' => 1 } },
 772           'payby'               => { 'payby'  => { 'CARD' => 1,
 773                                                    'DCRD' => 1, }
 774                                    },
 775           'message_email'       => {},
 776         );
 777         foreach (keys %conds) {
 778           my $condition = FS::part_event_condition->new({
 779               'conditionname' => $_,
 780               'eventpart'     => $event->eventpart,
 781           });
 782           $error = $condition->insert( %{ $conds{$_} });
 783           if ( $error ) {
 784             warn "error creating expiration alert event:\n$error\n\n";
 785             next;
 786           }
 787         }
 788         $error = $event->initialize;
 789         if ( $error ) {
 790           warn "expiration alert event was created, but not initialized:\n$error\n\n";
 791         }
 792       } # foreach $days
 793       $conf->delete('alerter_msgnum', $agentnum);
 794       $conf->delete('alert_expiration', $agentnum);
 795
 796     } # if alerter_msgnum
 797
 798   }
 799
 800   ###
 801   # Move subject and body from msg_template to template_content
 802   ###
 803
 804   foreach my $msg_template ( qsearch('msg_template', {}) ) {
 805     if ( $msg_template->subject || $msg_template->body ) {
 806       # create new default content
 807       my %content;
 808       $content{subject} = $msg_template->subject;
 809       $msg_template->set('subject', '');
 810
 811       # work around obscure Pg/DBD bug
 812       # https://rt.cpan.org/Public/Bug/Display.html?id=60200
 813       # (though the right fix is to upgrade DBD)
 814       my $body = $msg_template->body;
 815       if ( $body =~ /^x([0-9a-f]+)$/ ) {
 816         # there should be no real message templates that look like that
 817         warn "converting template body to TEXT\n";
 818         $body = pack('H*', $1);
 819       }
 820       $content{body} = $body;
 821       $msg_template->set('body', '');
 822
 823       my $error = $msg_template->replace(%content);
 824       die $error if $error;
 825     }
 826   }
 827
 828   ###
 829   # Add new-style default templates if missing
 830   ###
 831   $self->_populate_initial_data;
 832
 833 }
 834
 835 sub _populate_initial_data { #class method
 836   #my($class, %opts) = @_;
 837   #my $class = shift;
 838
 839   eval "use FS::msg_template::InitialData;";
 840   die $@ if $@;
 841
 842   my $initial_data = FS::msg_template::InitialData->_initial_data;
 843
 844   foreach my $hash ( @$initial_data ) {
 845
 846     next if $hash->{_conf} && $conf->config( $hash->{_conf} );
 847
 848     my $msg_template = new FS::msg_template($hash);
 849     my $error = $msg_template->insert( @{ $hash->{_insert_args} || [] } );
 850     die $error if $error;
 851
 852     $conf->set( $hash->{_conf}, $msg_template->msgnum ) if $hash->{_conf};
 853
 854   }
 855
 856 }
 857
 858 sub eviscerate {
 859   # Every bit as pleasant as it sounds.
 860   #
 861   # We do this because Text::Template::Preprocess doesn't
 862   # actually work.  It runs the entire template through
 863   # the preprocessor, instead of the code segments.  Which
 864   # is a shame, because Text::Template already contains
 865   # the code to do this operation.
 866   my $body = shift;
 867   my (@outside, @inside);
 868   my $depth = 0;
 869   my $chunk = '';
 870   while($body || $chunk) {
 871     my ($first, $delim, $rest);
 872     # put all leading non-delimiters into $first
 873     ($first, $rest) =
 874         ($body =~ /^((?:\\[{}]|[^{}])*)(.*)$/s);
 875     $chunk .= $first;
 876     # put a leading delimiter into $delim if there is one
 877     ($delim, $rest) =
 878       ($rest =~ /^([{}]?)(.*)$/s);
 879
 880     if( $delim eq '{' ) {
 881       $chunk .= '{';
 882       if( $depth == 0 ) {
 883         push @outside, $chunk;
 884         $chunk = '';
 885       }
 886       $depth++;
 887     }
 888     elsif( $delim eq '}' ) {
 889       $depth--;
 890       if( $depth == 0 ) {
 891         push @inside, $chunk;
 892         $chunk = '';
 893       }
 894       $chunk .= '}';
 895     }
 896     else {
 897       # no more delimiters
 898       if( $depth == 0 ) {
 899         push @outside, $chunk . $rest;
 900       } # else ? something wrong
 901       last;
 902     }
 903     $body = $rest;
 904   }
 905   (\@outside, \@inside);
 906 }
 907
 908 =back
 909
 910 =head1 BUGS
 911
 912 =head1 SEE ALSO
 913
 914 L<FS::Record>, schema.html from the base documentation.
 915
 916 =cut
 917
 918 1;
 919