FS/FS/msg_template.pm

   1 package FS::msg_template;
   2 use base qw( FS::Record );
   3
   4 use strict;
   5 use vars qw( $DEBUG $conf );
   6
   7 use Date::Format qw( time2str );
   8 use File::Temp;
   9 use IPC::Run qw(run);
  10 use Text::Template;
  11
  12 use HTML::Entities qw( decode_entities encode_entities ) ;
  13 use HTML::FormatText;
  14 use HTML::TreeBuilder;
  15 use Encode;
  16
  17 use FS::Misc qw( generate_email send_email do_print );
  18 use FS::Conf;
  19 use FS::Record qw( qsearch qsearchs );
  20 use FS::UID qw( dbh );
  21
  22 use FS::cust_main;
  23 use FS::cust_msg;
  24 use FS::template_content;
  25
  26 FS::UID->install_callback( sub { $conf = new FS::Conf; } );
  27
  28 $DEBUG=0;
  29
  30 =head1 NAME
  31
  32 FS::msg_template - Object methods for msg_template records
  33
  34 =head1 SYNOPSIS
  35
  36   use FS::msg_template;
  37
  38   $record = new FS::msg_template \%hash;
  39   $record = new FS::msg_template { 'column' => 'value' };
  40
  41   $error = $record->insert;
  42
  43   $error = $new_record->replace($old_record);
  44
  45   $error = $record->delete;
  46
  47   $error = $record->check;
  48
  49 =head1 DESCRIPTION
  50
  51 An FS::msg_template object represents a customer message template.
  52 FS::msg_template inherits from FS::Record.  The following fields are currently
  53 supported:
  54
  55 =over 4
  56
  57 =item msgnum - primary key
  58
  59 =item msgname - Name of the template.  This will appear in the user interface;
  60 if it needs to be localized for some users, add it to the message catalog.
  61
  62 =item agentnum - Agent associated with this template.  Can be NULL for a
  63 global template.
  64
  65 =item mime_type - MIME type.  Defaults to text/html.
  66
  67 =item from_addr - Source email address.
  68
  69 =item disabled - disabled ('Y' or NULL).
  70
  71 =back
  72
  73 =head1 METHODS
  74
  75 =over 4
  76
  77 =item new HASHREF
  78
  79 Creates a new template.  To add the template to the database, see L<"insert">.
  80
  81 Note that this stores the hash reference, not a distinct copy of the hash it
  82 points to.  You can ask the object for a copy with the I<hash> method.
  83
  84 =cut
  85
  86 # the new method can be inherited from FS::Record, if a table method is defined
  87
  88 sub table { 'msg_template'; }
  89
  90 =item insert [ CONTENT ]
  91
  92 Adds this record to the database.  If there is an error, returns the error,
  93 otherwise returns false.
  94
  95 A default (no locale) L<FS::template_content> object will be created.  CONTENT
  96 is an optional hash containing 'subject' and 'body' for this object.
  97
  98 =cut
  99
 100 sub insert {
 101   my $self = shift;
 102   my %content = @_;
 103
 104   my $oldAutoCommit = $FS::UID::AutoCommit;
 105   local $FS::UID::AutoCommit = 0;
 106   my $dbh = dbh;
 107
 108   my $error = $self->SUPER::insert;
 109   if ( !$error ) {
 110     $content{'msgnum'} = $self->msgnum;
 111     $content{'subject'} ||= '';
 112     $content{'body'} ||= '';
 113     my $template_content = new FS::template_content (\%content);
 114     $error = $template_content->insert;
 115   }
 116
 117   if ( $error ) {
 118     $dbh->rollback if $oldAutoCommit;
 119     return $error;
 120   }
 121
 122   $dbh->commit if $oldAutoCommit;
 123   return;
 124 }
 125
 126 =item delete
 127
 128 Delete this record from the database.
 129
 130 =cut
 131
 132 # the delete method can be inherited from FS::Record
 133
 134 =item replace [ OLD_RECORD ] [ CONTENT ]
 135
 136 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 137 returns the error, otherwise returns false.
 138
 139 CONTENT is an optional hash containing 'subject', 'body', and 'locale'.  If
 140 supplied, an L<FS::template_content> object will be created (or modified, if
 141 one already exists for this locale).
 142
 143 =cut
 144
 145 sub replace {
 146   my $self = shift;
 147   my $old = ( ref($_[0]) and $_[0]->isa('FS::Record') )
 148               ? shift
 149               : $self->replace_old;
 150   my %content = @_;
 151
 152   my $oldAutoCommit = $FS::UID::AutoCommit;
 153   local $FS::UID::AutoCommit = 0;
 154   my $dbh = dbh;
 155
 156   my $error = $self->SUPER::replace($old);
 157
 158   if ( !$error and %content ) {
 159     $content{'locale'} ||= '';
 160     my $new_content = qsearchs('template_content', {
 161                         'msgnum' => $self->msgnum,
 162                         'locale' => $content{'locale'},
 163                       } );
 164     if ( $new_content ) {
 165       $new_content->subject($content{'subject'});
 166       $new_content->body($content{'body'});
 167       $error = $new_content->replace;
 168     }
 169     else {
 170       $content{'msgnum'} = $self->msgnum;
 171       $new_content = new FS::template_content \%content;
 172       $error = $new_content->insert;
 173     }
 174   }
 175
 176   if ( $error ) {
 177     $dbh->rollback if $oldAutoCommit;
 178     return $error;
 179   }
 180
 181   warn "committing FS::msg_template->replace\n" if $DEBUG and $oldAutoCommit;
 182   $dbh->commit if $oldAutoCommit;
 183   return;
 184 }
 185
 186
 187
 188 =item check
 189
 190 Checks all fields to make sure this is a valid template.  If there is
 191 an error, returns the error, otherwise returns false.  Called by the insert
 192 and replace methods.
 193
 194 =cut
 195
 196 # the check method should currently be supplied - FS::Record contains some
 197 # data checking routines
 198
 199 sub check {
 200   my $self = shift;
 201
 202   my $error =
 203     $self->ut_numbern('msgnum')
 204     || $self->ut_text('msgname')
 205     || $self->ut_foreign_keyn('agentnum', 'agent', 'agentnum')
 206     || $self->ut_textn('mime_type')
 207     || $self->ut_enum('disabled', [ '', 'Y' ] )
 208     || $self->ut_textn('from_addr')
 209   ;
 210   return $error if $error;
 211
 212   $self->mime_type('text/html') unless $self->mime_type;
 213
 214   $self->SUPER::check;
 215 }
 216
 217 =item content_locales
 218
 219 Returns a hashref of the L<FS::template_content> objects attached to
 220 this template, with the locale as key.
 221
 222 =cut
 223
 224 sub content_locales {
 225   my $self = shift;
 226   return $self->{'_content_locales'} ||= +{
 227     map { $_->locale , $_ }
 228     qsearch('template_content', { 'msgnum' => $self->msgnum })
 229   };
 230 }
 231
 232 =item prepare OPTION => VALUE
 233
 234 Fills in the template and returns a hash of the 'from' address, 'to'
 235 addresses, subject line, and body.
 236
 237 Options are passed as a list of name/value pairs:
 238
 239 =over 4
 240
 241 =item cust_main
 242
 243 Customer object (required).
 244
 245 =item object
 246
 247 Additional context object (currently, can be a cust_main, cust_pkg,
 248 cust_bill, cust_pay, cust_pay_pending, or svc_(acct, phone, broadband,
 249 domain) ).  If the object is a svc_*, its cust_pkg will be fetched and
 250 used for substitution.
 251
 252 As a special case, this may be an arrayref of two objects.  Both
 253 objects will be available for substitution, with their field names
 254 prefixed with 'new_' and 'old_' respectively.  This is used in the
 255 rt_ticket export when exporting "replace" events.
 256
 257 =item from_config
 258
 259 Configuration option to use as the source address, based on the customer's
 260 agentnum.  If unspecified (or the named option is empty), 'invoice_from'
 261 will be used.
 262
 263 The I<from_addr> field in the template takes precedence over this.
 264
 265 =item to
 266
 267 Destination address.  The default is to use the customer's
 268 invoicing_list addresses.  Multiple addresses may be comma-separated.
 269
 270 =item substitutions
 271
 272 A hash reference of additional substitutions
 273
 274 =back
 275
 276 =cut
 277
 278 sub prepare {
 279   my( $self, %opt ) = @_;
 280
 281   my $cust_main = $opt{'cust_main'}; # or die 'cust_main required';
 282   my $object = $opt{'object'} or die 'object required';
 283
 284   # localization
 285   my $locale = $cust_main && $cust_main->locale || '';
 286   warn "no locale for cust#".$cust_main->custnum."; using default content\n"
 287     if $DEBUG and $cust_main && !$locale;
 288   my $content = $self->content($locale);
 289
 290   warn "preparing template '".$self->msgname."\n"
 291     if $DEBUG;
 292
 293   my $subs = $self->substitutions;
 294
 295   ###
 296   # create substitution table
 297   ###
 298   my %hash;
 299   my @objects = ();
 300   push @objects, $cust_main if $cust_main;
 301   my @prefixes = ('');
 302   my $svc;
 303   if( ref $object ) {
 304     if( ref($object) eq 'ARRAY' ) {
 305       # [new, old], for provisioning tickets
 306       push @objects, $object->[0], $object->[1];
 307       push @prefixes, 'new_', 'old_';
 308       $svc = $object->[0] if $object->[0]->isa('FS::svc_Common');
 309     }
 310     else {
 311       push @objects, $object;
 312       push @prefixes, '';
 313       $svc = $object if $object->isa('FS::svc_Common');
 314     }
 315   }
 316   if( $svc ) {
 317     push @objects, $svc->cust_svc->cust_pkg;
 318     push @prefixes, '';
 319   }
 320
 321   foreach my $obj (@objects) {
 322     my $prefix = shift @prefixes;
 323     foreach my $name (@{ $subs->{$obj->table} }) {
 324       if(!ref($name)) {
 325         # simple case
 326         $hash{$prefix.$name} = $obj->$name();
 327       }
 328       elsif( ref($name) eq 'ARRAY' ) {
 329         # [ foo => sub { ... } ]
 330         $hash{$prefix.($name->[0])} = $name->[1]->($obj);
 331       }
 332       else {
 333         warn "bad msg_template substitution: '$name'\n";
 334         #skip it?
 335       }
 336     }
 337   }
 338
 339   if ( $opt{substitutions} ) {
 340     $hash{$_} = $opt{substitutions}->{$_} foreach keys %{$opt{substitutions}};
 341   }
 342
 343   $_ = encode_entities($_ || '') foreach values(%hash);
 344
 345   ###
 346   # clean up template
 347   ###
 348   my $subject_tmpl = new Text::Template (
 349     TYPE   => 'STRING',
 350     SOURCE => $content->subject,
 351   );
 352   my $subject = $subject_tmpl->fill_in( HASH => \%hash );
 353
 354   my $body = $content->body;
 355   my ($skin, $guts) = eviscerate($body);
 356   @$guts = map {
 357     $_ = decode_entities($_); # turn all punctuation back into itself
 358     s/\r//gs;           # remove \r's
 359     s/<br[^>]*>/\n/gsi; # and <br /> tags
 360     s/<p>/\n/gsi;       # and <p>
 361     s/<\/p>//gsi;       # and </p>
 362     s/\240/ /gs;        # and &nbsp;
 363     $_
 364   } @$guts;
 365
 366   $body = '{ use Date::Format qw(time2str); "" }';
 367   while(@$skin || @$guts) {
 368     $body .= shift(@$skin) || '';
 369     $body .= shift(@$guts) || '';
 370   }
 371
 372   ###
 373   # fill-in
 374   ###
 375
 376   my $body_tmpl = new Text::Template (
 377     TYPE          => 'STRING',
 378     SOURCE        => $body,
 379   );
 380
 381   $body = $body_tmpl->fill_in( HASH => \%hash );
 382
 383   ###
 384   # and email
 385   ###
 386
 387   my @to;
 388   if ( exists($opt{'to'}) ) {
 389     @to = split(/\s*,\s*/, $opt{'to'});
 390   } elsif ( $cust_main ) {
 391     @to = $cust_main->invoicing_list_emailonly;
 392   } else {
 393     die 'no To: address or cust_main object specified';
 394   }
 395
 396   my $from_addr = $self->from_addr;
 397
 398   if ( !$from_addr ) {
 399
 400     my $agentnum = $cust_main ? $cust_main->agentnum : '';
 401
 402     if ( $opt{'from_config'} ) {
 403       $from_addr = $conf->config($opt{'from_config'}, $agentnum);
 404     }
 405     $from_addr ||= $conf->invoice_from_full($agentnum);
 406   }
 407 #  my @cust_msg = ();
 408 #  if ( $conf->exists('log_sent_mail') and !$opt{'preview'} ) {
 409 #    my $cust_msg = FS::cust_msg->new({
 410 #        'custnum' => $cust_main->custnum,
 411 #        'msgnum'  => $self->msgnum,
 412 #        'status'  => 'prepared',
 413 #      });
 414 #    $cust_msg->insert;
 415 #    @cust_msg = ('cust_msg' => $cust_msg);
 416 #  }
 417
 418   my $text_body = encode('UTF-8',
 419                   HTML::FormatText->new(leftmargin => 0, rightmargin => 70)
 420                       ->format( HTML::TreeBuilder->new_from_content($body) )
 421                   );
 422   (
 423     'custnum'   => ( $cust_main ? $cust_main->custnum : ''),
 424     'msgnum'    => $self->msgnum,
 425     'from'      => $from_addr,
 426     'to'        => \@to,
 427     'bcc'       => $self->bcc_addr || undef,
 428     'subject'   => $subject,
 429     'html_body' => $body,
 430     'text_body' => $text_body
 431   );
 432
 433 }
 434
 435 =item send OPTION => VALUE
 436
 437 Fills in the template and sends it to the customer.  Options are as for
 438 'prepare'.
 439
 440 =cut
 441
 442 # broken out from prepare() in case we want to queue the sending,
 443 # preview it, etc.
 444 sub send {
 445   my $self = shift;
 446   send_email(generate_email($self->prepare(@_)));
 447 }
 448
 449 =item render OPTION => VALUE ...
 450
 451 Fills in the template and renders it to a PDF document.  Returns the
 452 name of the PDF file.
 453
 454 Options are as for 'prepare', but 'from' and 'to' are meaningless.
 455
 456 =cut
 457
 458 # will also have options to set paper size, margins, etc.
 459
 460 sub render {
 461   my $self = shift;
 462   eval "use PDF::WebKit";
 463   die $@ if $@;
 464   my %opt = @_;
 465   my %hash = $self->prepare(%opt);
 466   my $html = $hash{'html_body'};
 467
 468   # Graphics/stylesheets should probably go in /var/www on the Freeside
 469   # machine.
 470   my $kit = PDF::WebKit->new(\$html); #%options
 471   # hack to use our wrapper script
 472   $kit->configure(sub { shift->wkhtmltopdf('freeside-wkhtmltopdf') });
 473
 474   $kit->to_pdf;
 475 }
 476
 477 =item print OPTIONS
 478
 479 Render a PDF and send it to the printer.  OPTIONS are as for 'render'.
 480
 481 =cut
 482
 483 sub print {
 484   my( $self, %opt ) = @_;
 485   do_print( [ $self->render(%opt) ], agentnum=>$opt{cust_main}->agentnum );
 486 }
 487
 488 # helper sub for package dates
 489 my $ymd = sub { $_[0] ? time2str('%Y-%m-%d', $_[0]) : '' };
 490
 491 # helper sub for money amounts
 492 my $money = sub { ($conf->money_char || '$') . sprintf('%.2f', $_[0] || 0) };
 493
 494 # helper sub for usage-related messages
 495 my $usage_warning = sub {
 496   my $svc = shift;
 497   foreach my $col (qw(seconds upbytes downbytes totalbytes)) {
 498     my $amount = $svc->$col; next if $amount eq '';
 499     my $method = $col.'_threshold';
 500     my $threshold = $svc->$method; next if $threshold eq '';
 501     return [$col, $amount, $threshold] if $amount <= $threshold;
 502     # this only returns the first one that's below threshold, if there are
 503     # several.
 504   }
 505   return ['', '', ''];
 506 };
 507
 508 #my $conf = new FS::Conf;
 509
 510 #return contexts and fill-in values
 511 # If you add anything, be sure to add a description in
 512 # httemplate/edit/msg_template.html.
 513 sub substitutions {
 514   { 'cust_main' => [qw(
 515       display_custnum agentnum agent_name
 516
 517       last first company
 518       name name_short contact contact_firstlast
 519       address1 address2 city county state zip
 520       country
 521       daytime night mobile fax
 522
 523       has_ship_address
 524       ship_name ship_name_short ship_contact ship_contact_firstlast
 525       ship_address1 ship_address2 ship_city ship_county ship_state ship_zip
 526       ship_country
 527
 528       paymask payname paytype payip
 529       num_cancelled_pkgs num_ncancelled_pkgs num_pkgs
 530       classname categoryname
 531       balance
 532       credit_limit
 533       invoicing_list_emailonly
 534       cust_status ucfirst_cust_status cust_statuscolor cust_status_label
 535
 536       signupdate dundate
 537       packages recurdates
 538       ),
 539       [ invoicing_email => sub { shift->invoicing_list_emailonly_scalar } ],
 540       #compatibility: obsolete ship_ fields - use the non-ship versions
 541       map (
 542         { my $field = $_;
 543           [ "ship_$field"   => sub { shift->$field } ]
 544         }
 545         qw( last first company daytime night fax )
 546       ),
 547       # ship_name, ship_name_short, ship_contact, ship_contact_firstlast
 548       # still work, though
 549       [ expdate           => sub { shift->paydate_epoch } ], #compatibility
 550       [ signupdate_ymd    => sub { $ymd->(shift->signupdate) } ],
 551       [ dundate_ymd       => sub { $ymd->(shift->dundate) } ],
 552       [ paydate_my        => sub { sprintf('%02d/%04d', shift->paydate_monthyear) } ],
 553       [ otaker_first      => sub { shift->access_user->first } ],
 554       [ otaker_last       => sub { shift->access_user->last } ],
 555       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 556       [ company_name      => sub {
 557           $conf->config('company_name', shift->agentnum)
 558         } ],
 559       [ company_address   => sub {
 560           $conf->config('company_address', shift->agentnum)
 561         } ],
 562       [ company_phonenum  => sub {
 563           $conf->config('company_phonenum', shift->agentnum)
 564         } ],
 565       [ selfservice_server_base_url => sub {
 566           $conf->config('selfservice_server-base_url') #, shift->agentnum)
 567         } ],
 568     ],
 569     # next_bill_date
 570     'cust_pkg'  => [qw(
 571       pkgnum pkg_label pkg_label_long
 572       location_label
 573       status statuscolor
 574
 575       start_date setup bill last_bill
 576       adjourn susp expire
 577       labels_short
 578       ),
 579       [ pkg               => sub { shift->part_pkg->pkg } ],
 580       [ pkg_category      => sub { shift->part_pkg->categoryname } ],
 581       [ pkg_class         => sub { shift->part_pkg->classname } ],
 582       [ cancel            => sub { shift->getfield('cancel') } ], # grrr...
 583       [ start_ymd         => sub { $ymd->(shift->getfield('start_date')) } ],
 584       [ setup_ymd         => sub { $ymd->(shift->getfield('setup')) } ],
 585       [ next_bill_ymd     => sub { $ymd->(shift->getfield('bill')) } ],
 586       [ last_bill_ymd     => sub { $ymd->(shift->getfield('last_bill')) } ],
 587       [ adjourn_ymd       => sub { $ymd->(shift->getfield('adjourn')) } ],
 588       [ susp_ymd          => sub { $ymd->(shift->getfield('susp')) } ],
 589       [ expire_ymd        => sub { $ymd->(shift->getfield('expire')) } ],
 590       [ cancel_ymd        => sub { $ymd->(shift->getfield('cancel')) } ],
 591
 592       # not necessarily correct for non-flat packages
 593       [ setup_fee         => sub { shift->part_pkg->option('setup_fee') } ],
 594       [ recur_fee         => sub { shift->part_pkg->option('recur_fee') } ],
 595
 596       [ freq_pretty       => sub { shift->part_pkg->freq_pretty } ],
 597
 598     ],
 599     'cust_bill' => [qw(
 600       invnum
 601       _date
 602       _date_pretty
 603       due_date
 604       due_date2str
 605     )],
 606     #XXX not really thinking about cust_bill substitutions quite yet
 607
 608     # for welcome and limit warning messages
 609     'svc_acct' => [qw(
 610       svcnum
 611       username
 612       domain
 613       ),
 614       [ password          => sub { shift->getfield('_password') } ],
 615       [ column            => sub { &$usage_warning(shift)->[0] } ],
 616       [ amount            => sub { &$usage_warning(shift)->[1] } ],
 617       [ threshold         => sub { &$usage_warning(shift)->[2] } ],
 618     ],
 619     'svc_domain' => [qw(
 620       svcnum
 621       domain
 622       ),
 623       [ registrar         => sub {
 624           my $registrar = qsearchs('registrar',
 625             { registrarnum => shift->registrarnum} );
 626           $registrar ? $registrar->registrarname : ''
 627         }
 628       ],
 629       [ catchall          => sub {
 630           my $svc_acct = qsearchs('svc_acct', { svcnum => shift->catchall });
 631           $svc_acct ? $svc_acct->email : ''
 632         }
 633       ],
 634     ],
 635     'svc_phone' => [qw(
 636       svcnum
 637       phonenum
 638       countrycode
 639       domain
 640       )
 641     ],
 642     'svc_broadband' => [qw(
 643       svcnum
 644       speed_up
 645       speed_down
 646       ip_addr
 647       mac_addr
 648       )
 649     ],
 650     # for payment receipts
 651     'cust_pay' => [qw(
 652       paynum
 653       _date
 654       ),
 655       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 656       # overrides the one in cust_main in cases where a cust_pay is passed
 657       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 658       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 659       [ payinfo           => sub {
 660           my $cust_pay = shift;
 661           ($cust_pay->payby eq 'CARD' || $cust_pay->payby eq 'CHEK') ?
 662             $cust_pay->paymask : $cust_pay->decrypt($cust_pay->payinfo)
 663         } ],
 664     ],
 665     # for payment decline messages
 666     # try to support all cust_pay fields
 667     # 'error' is a special case, it contains the raw error from the gateway
 668     'cust_pay_pending' => [qw(
 669       _date
 670       error
 671       ),
 672       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 673       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 674       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 675       [ payinfo           => sub {
 676           my $pending = shift;
 677           ($pending->payby eq 'CARD' || $pending->payby eq 'CHEK') ?
 678             $pending->paymask : $pending->decrypt($pending->payinfo)
 679         } ],
 680     ],
 681   };
 682 }
 683
 684 =item content LOCALE
 685
 686 Returns the L<FS::template_content> object appropriate to LOCALE, if there
 687 is one.  If not, returns the one with a NULL locale.
 688
 689 =cut
 690
 691 sub content {
 692   my $self = shift;
 693   my $locale = shift;
 694   qsearchs('template_content',
 695             { 'msgnum' => $self->msgnum, 'locale' => $locale }) ||
 696   qsearchs('template_content',
 697             { 'msgnum' => $self->msgnum, 'locale' => '' });
 698 }
 699
 700 =item agent
 701
 702 Returns the L<FS::agent> object for this template.
 703
 704 =cut
 705
 706 sub _upgrade_data {
 707   my ($self, %opts) = @_;
 708
 709   ###
 710   # First move any historical templates in config to real message templates
 711   ###
 712
 713   my @fixes = (
 714     [ 'alerter_msgnum',  'alerter_template',   '',               '', '' ],
 715     [ 'cancel_msgnum',   'cancelmessage',      'cancelsubject',  '', '' ],
 716     [ 'decline_msgnum',  'declinetemplate',    '',               '', '' ],
 717     [ 'impending_recur_msgnum', 'impending_recur_template', '',  '', 'impending_recur_bcc' ],
 718     [ 'payment_receipt_msgnum', 'payment_receipt_email', '',     '', '' ],
 719     [ 'welcome_msgnum',  'welcome_email',      'welcome_email-subject', 'welcome_email-from', '' ],
 720     [ 'warning_msgnum',  'warning_email',      'warning_email-subject', 'warning_email-from', '' ],
 721   );
 722
 723   my @agentnums = ('', map {$_->agentnum} qsearch('agent', {}));
 724   foreach my $agentnum (@agentnums) {
 725     foreach (@fixes) {
 726       my ($newname, $oldname, $subject, $from, $bcc) = @$_;
 727       if ($conf->exists($oldname, $agentnum)) {
 728         my $new = new FS::msg_template({
 729           'msgname'   => $oldname,
 730           'agentnum'  => $agentnum,
 731           'from_addr' => ($from && $conf->config($from, $agentnum)) || '',
 732           'bcc_addr'  => ($bcc && $conf->config($from, $agentnum)) || '',
 733           'subject'   => ($subject && $conf->config($subject, $agentnum)) || '',
 734           'mime_type' => 'text/html',
 735           'body'      => join('<BR>',$conf->config($oldname, $agentnum)),
 736         });
 737         my $error = $new->insert;
 738         die $error if $error;
 739         $conf->set($newname, $new->msgnum, $agentnum);
 740         $conf->delete($oldname, $agentnum);
 741         $conf->delete($from, $agentnum) if $from;
 742         $conf->delete($subject, $agentnum) if $subject;
 743       }
 744     }
 745
 746     if ( $conf->exists('alert_expiration', $agentnum) ) {
 747       my $msgnum = $conf->exists('alerter_msgnum', $agentnum);
 748       my $template = FS::msg_template->by_key($msgnum) if $msgnum;
 749       if (!$template) {
 750         warn "template for alerter_msgnum $msgnum not found\n";
 751         next;
 752       }
 753       # this is now a set of billing events
 754       foreach my $days (30, 15, 5) {
 755         my $event = FS::part_event->new({
 756             'agentnum'    => $agentnum,
 757             'event'       => "Card expiration warning - $days days",
 758             'eventtable'  => 'cust_main',
 759             'check_freq'  => '1d',
 760             'action'      => 'notice',
 761             'disabled'    => 'Y', #initialize first
 762         });
 763         my $error = $event->insert( 'msgnum' => $msgnum );
 764         if ($error) {
 765           warn "error creating expiration alert event:\n$error\n\n";
 766           next;
 767         }
 768         # make it work like before:
 769         # only send each warning once before the card expires,
 770         # only warn active customers,
 771         # only warn customers with CARD/DCRD,
 772         # only warn customers who get email invoices
 773         my %conds = (
 774           'once_every'          => { 'run_delay' => '30d' },
 775           'cust_paydate_within' => { 'within' => $days.'d' },
 776           'cust_status'         => { 'status' => { 'active' => 1 } },
 777           'payby'               => { 'payby'  => { 'CARD' => 1,
 778                                                    'DCRD' => 1, }
 779                                    },
 780           'message_email'       => {},
 781         );
 782         foreach (keys %conds) {
 783           my $condition = FS::part_event_condition->new({
 784               'conditionname' => $_,
 785               'eventpart'     => $event->eventpart,
 786           });
 787           $error = $condition->insert( %{ $conds{$_} });
 788           if ( $error ) {
 789             warn "error creating expiration alert event:\n$error\n\n";
 790             next;
 791           }
 792         }
 793         $error = $event->initialize;
 794         if ( $error ) {
 795           warn "expiration alert event was created, but not initialized:\n$error\n\n";
 796         }
 797       } # foreach $days
 798       $conf->delete('alerter_msgnum', $agentnum);
 799       $conf->delete('alert_expiration', $agentnum);
 800
 801     } # if alerter_msgnum
 802
 803   }
 804
 805   ###
 806   # Move subject and body from msg_template to template_content
 807   ###
 808
 809   foreach my $msg_template ( qsearch('msg_template', {}) ) {
 810     if ( $msg_template->subject || $msg_template->body ) {
 811       # create new default content
 812       my %content;
 813       $content{subject} = $msg_template->subject;
 814       $msg_template->set('subject', '');
 815
 816       # work around obscure Pg/DBD bug
 817       # https://rt.cpan.org/Public/Bug/Display.html?id=60200
 818       # (though the right fix is to upgrade DBD)
 819       my $body = $msg_template->body;
 820       if ( $body =~ /^x([0-9a-f]+)$/ ) {
 821         # there should be no real message templates that look like that
 822         warn "converting template body to TEXT\n";
 823         $body = pack('H*', $1);
 824       }
 825       $content{body} = $body;
 826       $msg_template->set('body', '');
 827
 828       my $error = $msg_template->replace(%content);
 829       die $error if $error;
 830     }
 831   }
 832
 833   ###
 834   # Add new-style default templates if missing
 835   ###
 836   $self->_populate_initial_data;
 837
 838 }
 839
 840 sub _populate_initial_data { #class method
 841   #my($class, %opts) = @_;
 842   #my $class = shift;
 843
 844   eval "use FS::msg_template::InitialData;";
 845   die $@ if $@;
 846
 847   my $initial_data = FS::msg_template::InitialData->_initial_data;
 848
 849   foreach my $hash ( @$initial_data ) {
 850
 851     next if $hash->{_conf} && $conf->config( $hash->{_conf} );
 852
 853     my $msg_template = new FS::msg_template($hash);
 854     my $error = $msg_template->insert( @{ $hash->{_insert_args} || [] } );
 855     die $error if $error;
 856
 857     $conf->set( $hash->{_conf}, $msg_template->msgnum ) if $hash->{_conf};
 858
 859   }
 860
 861 }
 862
 863 sub eviscerate {
 864   # Every bit as pleasant as it sounds.
 865   #
 866   # We do this because Text::Template::Preprocess doesn't
 867   # actually work.  It runs the entire template through
 868   # the preprocessor, instead of the code segments.  Which
 869   # is a shame, because Text::Template already contains
 870   # the code to do this operation.
 871   my $body = shift;
 872   my (@outside, @inside);
 873   my $depth = 0;
 874   my $chunk = '';
 875   while($body || $chunk) {
 876     my ($first, $delim, $rest);
 877     # put all leading non-delimiters into $first
 878     ($first, $rest) =
 879         ($body =~ /^((?:\\[{}]|[^{}])*)(.*)$/s);
 880     $chunk .= $first;
 881     # put a leading delimiter into $delim if there is one
 882     ($delim, $rest) =
 883       ($rest =~ /^([{}]?)(.*)$/s);
 884
 885     if( $delim eq '{' ) {
 886       $chunk .= '{';
 887       if( $depth == 0 ) {
 888         push @outside, $chunk;
 889         $chunk = '';
 890       }
 891       $depth++;
 892     }
 893     elsif( $delim eq '}' ) {
 894       $depth--;
 895       if( $depth == 0 ) {
 896         push @inside, $chunk;
 897         $chunk = '';
 898       }
 899       $chunk .= '}';
 900     }
 901     else {
 902       # no more delimiters
 903       if( $depth == 0 ) {
 904         push @outside, $chunk . $rest;
 905       } # else ? something wrong
 906       last;
 907     }
 908     $body = $rest;
 909   }
 910   (\@outside, \@inside);
 911 }
 912
 913 =back
 914
 915 =head1 BUGS
 916
 917 =head1 SEE ALSO
 918
 919 L<FS::Record>, schema.html from the base documentation.
 920
 921 =cut
 922
 923 1;
 924