FS/FS/msg_template.pm

   1 package FS::msg_template;
   2
   3 use strict;
   4 use base qw( FS::Record );
   5 use Text::Template;
   6 use FS::Misc qw( generate_email send_email );
   7 use FS::Conf;
   8 use FS::Record qw( qsearch qsearchs );
   9
  10 use Date::Format qw( time2str );
  11 use HTML::Entities qw( decode_entities encode_entities ) ;
  12 use HTML::FormatText;
  13 use HTML::TreeBuilder;
  14 use vars '$DEBUG';
  15
  16 $DEBUG=0;
  17
  18 =head1 NAME
  19
  20 FS::msg_template - Object methods for msg_template records
  21
  22 =head1 SYNOPSIS
  23
  24   use FS::msg_template;
  25
  26   $record = new FS::msg_template \%hash;
  27   $record = new FS::msg_template { 'column' => 'value' };
  28
  29   $error = $record->insert;
  30
  31   $error = $new_record->replace($old_record);
  32
  33   $error = $record->delete;
  34
  35   $error = $record->check;
  36
  37 =head1 DESCRIPTION
  38
  39 An FS::msg_template object represents a customer message template.
  40 FS::msg_template inherits from FS::Record.  The following fields are currently
  41 supported:
  42
  43 =over 4
  44
  45 =item msgnum
  46
  47 primary key
  48
  49 =item msgname
  50
  51 Template name.
  52
  53 =item agentnum
  54
  55 Agent associated with this template.  Can be NULL for a global template.
  56
  57 =item mime_type
  58
  59 MIME type.  Defaults to text/html.
  60
  61 =item from_addr
  62
  63 Source email address.
  64
  65 =item subject
  66
  67 The message subject line, in L<Text::Template> format.
  68
  69 =item body
  70
  71 The message body, as plain text or HTML, in L<Text::Template> format.
  72
  73 =item disabled
  74
  75 disabled
  76
  77 =back
  78
  79 =head1 METHODS
  80
  81 =over 4
  82
  83 =item new HASHREF
  84
  85 Creates a new template.  To add the template to the database, see L<"insert">.
  86
  87 Note that this stores the hash reference, not a distinct copy of the hash it
  88 points to.  You can ask the object for a copy with the I<hash> method.
  89
  90 =cut
  91
  92 # the new method can be inherited from FS::Record, if a table method is defined
  93
  94 sub table { 'msg_template'; }
  95
  96 =item insert
  97
  98 Adds this record to the database.  If there is an error, returns the error,
  99 otherwise returns false.
 100
 101 =cut
 102
 103 # the insert method can be inherited from FS::Record
 104
 105 =item delete
 106
 107 Delete this record from the database.
 108
 109 =cut
 110
 111 # the delete method can be inherited from FS::Record
 112
 113 =item replace OLD_RECORD
 114
 115 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 116 returns the error, otherwise returns false.
 117
 118 =cut
 119
 120 # the replace method can be inherited from FS::Record
 121
 122 =item check
 123
 124 Checks all fields to make sure this is a valid template.  If there is
 125 an error, returns the error, otherwise returns false.  Called by the insert
 126 and replace methods.
 127
 128 =cut
 129
 130 # the check method should currently be supplied - FS::Record contains some
 131 # data checking routines
 132
 133 sub check {
 134   my $self = shift;
 135
 136   my $error =
 137     $self->ut_numbern('msgnum')
 138     || $self->ut_text('msgname')
 139     || $self->ut_foreign_keyn('agentnum', 'agent', 'agentnum')
 140     || $self->ut_textn('mime_type')
 141     || $self->ut_anything('subject')
 142     || $self->ut_anything('body')
 143     || $self->ut_enum('disabled', [ '', 'Y' ] )
 144     || $self->ut_textn('from_addr')
 145   ;
 146   return $error if $error;
 147
 148   $self->mime_type('text/html') unless $self->mime_type;
 149
 150   $self->SUPER::check;
 151 }
 152
 153 =item prepare OPTION => VALUE
 154
 155 Fills in the template and returns a hash of the 'from' address, 'to'
 156 addresses, subject line, and body.
 157
 158 Options are passed as a list of name/value pairs:
 159
 160 =over 4
 161
 162 =item cust_main
 163
 164 Customer object (required).
 165
 166 =item object
 167
 168 Additional context object (currently, can be a cust_main, cust_pkg,
 169 cust_bill, cust_pay, cust_pay_pending, or svc_(acct, phone, broadband,
 170 domain) ).  If the object is a svc_*, its cust_pkg will be fetched and
 171 used for substitution.
 172
 173 As a special case, this may be an arrayref of two objects.  Both
 174 objects will be available for substitution, with their field names
 175 prefixed with 'new_' and 'old_' respectively.  This is used in the
 176 rt_ticket export when exporting "replace" events.
 177
 178 =item to
 179
 180 Destination address.  The default is to use the customer's
 181 invoicing_list addresses.
 182
 183 =back
 184
 185 =cut
 186
 187 sub prepare {
 188   my( $self, %opt ) = @_;
 189
 190   my $cust_main = $opt{'cust_main'};
 191   my $object = $opt{'object'};
 192   warn "preparing template '".$self->msgname."' to cust#".$cust_main->custnum."\n"
 193     if($DEBUG);
 194
 195   my $subs = $self->substitutions;
 196
 197   ###
 198   # create substitution table
 199   ###
 200   my %hash;
 201   my @objects = ($cust_main);
 202   my @prefixes = ('');
 203   my $svc;
 204   if( ref $object ) {
 205     if( ref($object) eq 'ARRAY' ) {
 206       # [new, old], for provisioning tickets
 207       push @objects, $object->[0], $object->[1];
 208       push @prefixes, 'new_', 'old_';
 209       $svc = $object->[0] if $object->[0]->isa('FS::svc_Common');
 210     }
 211     else {
 212       push @objects, $object;
 213       push @prefixes, '';
 214       $svc = $object if $object->isa('FS::svc_Common');
 215     }
 216   }
 217   if( $svc ) {
 218     push @objects, $svc->cust_svc->cust_pkg;
 219     push @prefixes, '';
 220   }
 221
 222   foreach my $obj (@objects) {
 223     my $prefix = shift @prefixes;
 224     foreach my $name (@{ $subs->{$obj->table} }) {
 225       if(!ref($name)) {
 226         # simple case
 227         $hash{$prefix.$name} = $obj->$name();
 228       }
 229       elsif( ref($name) eq 'ARRAY' ) {
 230         # [ foo => sub { ... } ]
 231         $hash{$prefix.($name->[0])} = $name->[1]->($obj);
 232       }
 233       else {
 234         warn "bad msg_template substitution: '$name'\n";
 235         #skip it?
 236       }
 237     }
 238   }
 239   $_ = encode_entities($_) foreach values(%hash);
 240
 241
 242   ###
 243   # clean up template
 244   ###
 245   my $subject_tmpl = new Text::Template (
 246     TYPE   => 'STRING',
 247     SOURCE => $self->subject,
 248   );
 249   my $subject = $subject_tmpl->fill_in( HASH => \%hash );
 250
 251   my $body = $self->body;
 252   my ($skin, $guts) = eviscerate($body);
 253   @$guts = map {
 254     $_ = decode_entities($_); # turn all punctuation back into itself
 255     s/\r//gs;           # remove \r's
 256     s/<br[^>]*>/\n/gsi; # and <br /> tags
 257     s/<p>/\n/gsi;       # and <p>
 258     s/<\/p>//gsi;       # and </p>
 259     s/\240/ /gs;        # and &nbsp;
 260     $_
 261   } @$guts;
 262
 263   $body = '{ use Date::Format qw(time2str); "" }';
 264   while(@$skin || @$guts) {
 265     $body .= shift(@$skin) || '';
 266     $body .= shift(@$guts) || '';
 267   }
 268
 269   ###
 270   # fill-in
 271   ###
 272
 273   my $body_tmpl = new Text::Template (
 274     TYPE          => 'STRING',
 275     SOURCE        => $body,
 276   );
 277
 278   $body = $body_tmpl->fill_in( HASH => \%hash );
 279
 280   ###
 281   # and email
 282   ###
 283
 284   my @to = ($opt{'to'}) || $cust_main->invoicing_list_emailonly;
 285   #warn "prepared msg_template with no email destination (custnum ".
 286   #  $cust_main->custnum.")\n"
 287   #  if !@to;
 288   #  warning is not appropriate now that we use these for tickets
 289
 290   my $conf = new FS::Conf;
 291
 292   (
 293     'from' => $self->from_addr ||
 294               scalar( $conf->config('invoice_from', $cust_main->agentnum) ),
 295     'to'   => \@to,
 296     'bcc'  => $self->bcc_addr || undef,
 297     'subject'   => $subject,
 298     'html_body' => $body,
 299     'text_body' => HTML::FormatText->new(leftmargin => 0, rightmargin => 70
 300                     )->format( HTML::TreeBuilder->new_from_content($body) ),
 301   );
 302
 303 }
 304
 305 =item send OPTION => VALUE
 306
 307 Fills in the template and sends it to the customer.  Options are as for
 308 'prepare'.
 309
 310 =cut
 311
 312 # broken out from prepare() in case we want to queue the sending,
 313 # preview it, etc.
 314 sub send {
 315   my $self = shift;
 316   send_email(generate_email($self->prepare(@_)));
 317 }
 318
 319 # helper sub for package dates
 320 my $ymd = sub { $_[0] ? time2str('%Y-%m-%d', $_[0]) : '' };
 321
 322 # needed for some things
 323 my $conf = new FS::Conf;
 324
 325 #return contexts and fill-in values
 326 # If you add anything, be sure to add a description in
 327 # httemplate/edit/msg_template.html.
 328 sub substitutions {
 329   { 'cust_main' => [qw(
 330       display_custnum agentnum agent_name
 331
 332       last first company
 333       name name_short contact contact_firstlast
 334       address1 address2 city county state zip
 335       country
 336       daytime night fax
 337
 338       has_ship_address
 339       ship_last ship_first ship_company
 340       ship_name ship_name_short ship_contact ship_contact_firstlast
 341       ship_address1 ship_address2 ship_city ship_county ship_state ship_zip
 342       ship_country
 343       ship_daytime ship_night ship_fax
 344
 345       paymask payname paytype payip
 346       num_cancelled_pkgs num_ncancelled_pkgs num_pkgs
 347       classname categoryname
 348       balance
 349       credit_limit
 350       invoicing_list_emailonly
 351       cust_status ucfirst_cust_status cust_statuscolor
 352
 353       signupdate dundate
 354       expdate
 355       packages recurdates
 356       ),
 357       # expdate is a special case
 358       [ signupdate_ymd    => sub { time2str('%Y-%m-%d', shift->signupdate) } ],
 359       [ dundate_ymd       => sub { time2str('%Y-%m-%d', shift->dundate) } ],
 360       [ paydate_my        => sub { sprintf('%02d/%04d', shift->paydate_monthyear) } ],
 361       [ otaker_first      => sub { shift->access_user->first } ],
 362       [ otaker_last       => sub { shift->access_user->last } ],
 363       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 364       [ company_name      => sub {
 365           $conf->config('company_name', shift->agentnum)
 366         } ],
 367       [ company_address   => sub {
 368           $conf->config('company_address', shift->agentnum)
 369         } ],
 370     ],
 371     # next_bill_date
 372     'cust_pkg'  => [qw(
 373       pkgnum pkg_label pkg_label_long
 374       location_label
 375       status statuscolor
 376
 377       start_date setup bill last_bill
 378       adjourn susp expire
 379       labels_short
 380       ),
 381       [ pkg               => sub { shift->part_pkg->pkg } ],
 382       [ cancel            => sub { shift->getfield('cancel') } ], # grrr...
 383       [ start_ymd         => sub { $ymd->(shift->getfield('start_date')) } ],
 384       [ setup_ymd         => sub { $ymd->(shift->getfield('setup')) } ],
 385       [ next_bill_ymd     => sub { $ymd->(shift->getfield('bill')) } ],
 386       [ last_bill_ymd     => sub { $ymd->(shift->getfield('last_bill')) } ],
 387       [ adjourn_ymd       => sub { $ymd->(shift->getfield('adjourn')) } ],
 388       [ susp_ymd          => sub { $ymd->(shift->getfield('susp')) } ],
 389       [ expire_ymd        => sub { $ymd->(shift->getfield('expire')) } ],
 390       [ cancel_ymd        => sub { $ymd->(shift->getfield('cancel')) } ],
 391     ],
 392     'cust_bill' => [qw(
 393       invnum
 394       _date
 395     )],
 396     #XXX not really thinking about cust_bill substitutions quite yet
 397
 398     # for welcome and limit warning messages
 399     'svc_acct' => [qw(
 400       svcnum
 401       username
 402       domain
 403       ),
 404       [ password          => sub { shift->getfield('_password') } ],
 405     ],
 406     'svc_domain' => [qw(
 407       svcnum
 408       domain
 409       ),
 410       [ registrar         => sub {
 411           my $registrar = qsearchs('registrar',
 412             { registrarnum => shift->registrarnum} );
 413           $registrar ? $registrar->registrarname : ''
 414         }
 415       ],
 416       [ catchall          => sub {
 417           my $svc_acct = qsearchs('svc_acct', { svcnum => shift->catchall });
 418           $svc_acct ? $svc_acct->email : ''
 419         }
 420       ],
 421     ],
 422     'svc_phone' => [qw(
 423       svcnum
 424       phonenum
 425       countrycode
 426       domain
 427       )
 428     ],
 429     'svc_broadband' => [qw(
 430       svcnum
 431       speed_up
 432       speed_down
 433       ip_addr
 434       mac_addr
 435       )
 436     ],
 437     # for payment receipts
 438     'cust_pay' => [qw(
 439       paynum
 440       _date
 441       ),
 442       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 443       # overrides the one in cust_main in cases where a cust_pay is passed
 444       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 445       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 446       [ payinfo           => sub {
 447           my $cust_pay = shift;
 448           ($cust_pay->payby eq 'CARD' || $cust_pay->payby eq 'CHEK') ?
 449             $cust_pay->paymask : $cust_pay->decrypt($cust_pay->payinfo)
 450         } ],
 451     ],
 452     # for payment decline messages
 453     # try to support all cust_pay fields
 454     # 'error' is a special case, it contains the raw error from the gateway
 455     'cust_pay_pending' => [qw(
 456       _date
 457       error
 458       ),
 459       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 460       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 461       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 462       [ payinfo           => sub {
 463           my $pending = shift;
 464           ($pending->payby eq 'CARD' || $pending->payby eq 'CHEK') ?
 465             $pending->paymask : $pending->decrypt($pending->payinfo)
 466         } ],
 467     ],
 468   };
 469 }
 470
 471 sub _upgrade_data {
 472   my ($self, %opts) = @_;
 473
 474   my @fixes = (
 475     [ 'alerter_msgnum',  'alerter_template',   '',               '', '' ],
 476     [ 'cancel_msgnum',   'cancelmessage',      'cancelsubject',  '', '' ],
 477     [ 'decline_msgnum',  'declinetemplate',    '',               '', '' ],
 478     [ 'impending_recur_msgnum', 'impending_recur_template', '',  '', 'impending_recur_bcc' ],
 479     [ 'payment_receipt_msgnum', 'payment_receipt_email', '',     '', '' ],
 480     [ 'welcome_msgnum',  'welcome_email',      'welcome_email-subject', 'welcome_email-from', '' ],
 481     [ 'warning_msgnum',  'warning_email',      'warning_email-subject', 'warning_email-from', '' ],
 482   );
 483
 484   my $conf = new FS::Conf;
 485   my @agentnums = ('', map {$_->agentnum} qsearch('agent', {}));
 486   foreach my $agentnum (@agentnums) {
 487     foreach (@fixes) {
 488       my ($newname, $oldname, $subject, $from, $bcc) = @$_;
 489       if ($conf->exists($oldname, $agentnum)) {
 490         my $new = new FS::msg_template({
 491            'msgname'   => $oldname,
 492            'agentnum'  => $agentnum,
 493            'from_addr' => ($from && $conf->config($from, $agentnum)) ||
 494                           $conf->config('invoice_from', $agentnum),
 495            'bcc_addr'  => ($bcc && $conf->config($from, $agentnum)) || '',
 496            'subject'   => ($subject && $conf->config($subject, $agentnum)) || '',
 497            'mime_type' => 'text/html',
 498            'body'      => join('<BR>',$conf->config($oldname, $agentnum)),
 499         });
 500         my $error = $new->insert;
 501         die $error if $error;
 502         $conf->set($newname, $new->msgnum, $agentnum);
 503         $conf->delete($oldname, $agentnum);
 504         $conf->delete($from, $agentnum) if $from;
 505         $conf->delete($subject, $agentnum) if $subject;
 506       }
 507     }
 508   }
 509 }
 510
 511 sub eviscerate {
 512   # Every bit as pleasant as it sounds.
 513   #
 514   # We do this because Text::Template::Preprocess doesn't
 515   # actually work.  It runs the entire template through
 516   # the preprocessor, instead of the code segments.  Which
 517   # is a shame, because Text::Template already contains
 518   # the code to do this operation.
 519   my $body = shift;
 520   my (@outside, @inside);
 521   my $depth = 0;
 522   my $chunk = '';
 523   while($body || $chunk) {
 524     my ($first, $delim, $rest);
 525     # put all leading non-delimiters into $first
 526     ($first, $rest) =
 527         ($body =~ /^((?:\\[{}]|[^{}])*)(.*)$/s);
 528     $chunk .= $first;
 529     # put a leading delimiter into $delim if there is one
 530     ($delim, $rest) =
 531       ($rest =~ /^([{}]?)(.*)$/s);
 532
 533     if( $delim eq '{' ) {
 534       $chunk .= '{';
 535       if( $depth == 0 ) {
 536         push @outside, $chunk;
 537         $chunk = '';
 538       }
 539       $depth++;
 540     }
 541     elsif( $delim eq '}' ) {
 542       $depth--;
 543       if( $depth == 0 ) {
 544         push @inside, $chunk;
 545         $chunk = '';
 546       }
 547       $chunk .= '}';
 548     }
 549     else {
 550       # no more delimiters
 551       if( $depth == 0 ) {
 552         push @outside, $chunk . $rest;
 553       } # else ? something wrong
 554       last;
 555     }
 556     $body = $rest;
 557   }
 558   (\@outside, \@inside);
 559 }
 560
 561 =back
 562
 563 =head1 BUGS
 564
 565 =head1 SEE ALSO
 566
 567 L<FS::Record>, schema.html from the base documentation.
 568
 569 =cut
 570
 571 1;
 572