FS/FS/msg_template.pm

   1 package FS::msg_template;
   2
   3 use strict;
   4 use base qw( FS::Record );
   5 use Text::Template;
   6 use FS::Misc qw( generate_email send_email do_print );
   7 use FS::Conf;
   8 use FS::Record qw( qsearch qsearchs );
   9 use FS::UID qw( dbh );
  10
  11 use FS::cust_main;
  12 use FS::cust_msg;
  13 use FS::template_content;
  14
  15 use Date::Format qw( time2str );
  16 use HTML::Entities qw( decode_entities encode_entities ) ;
  17 use HTML::FormatText;
  18 use HTML::TreeBuilder;
  19 use Encode;
  20
  21 use File::Temp;
  22 use IPC::Run qw(run);
  23 use vars qw( $DEBUG $conf );
  24
  25 FS::UID->install_callback( sub { $conf = new FS::Conf; } );
  26
  27 $DEBUG=0;
  28
  29 =head1 NAME
  30
  31 FS::msg_template - Object methods for msg_template records
  32
  33 =head1 SYNOPSIS
  34
  35   use FS::msg_template;
  36
  37   $record = new FS::msg_template \%hash;
  38   $record = new FS::msg_template { 'column' => 'value' };
  39
  40   $error = $record->insert;
  41
  42   $error = $new_record->replace($old_record);
  43
  44   $error = $record->delete;
  45
  46   $error = $record->check;
  47
  48 =head1 DESCRIPTION
  49
  50 An FS::msg_template object represents a customer message template.
  51 FS::msg_template inherits from FS::Record.  The following fields are currently
  52 supported:
  53
  54 =over 4
  55
  56 =item msgnum - primary key
  57
  58 =item msgname - Name of the template.  This will appear in the user interface;
  59 if it needs to be localized for some users, add it to the message catalog.
  60
  61 =item agentnum - Agent associated with this template.  Can be NULL for a
  62 global template.
  63
  64 =item mime_type - MIME type.  Defaults to text/html.
  65
  66 =item from_addr - Source email address.
  67
  68 =item disabled - disabled ('Y' or NULL).
  69
  70 =back
  71
  72 =head1 METHODS
  73
  74 =over 4
  75
  76 =item new HASHREF
  77
  78 Creates a new template.  To add the template to the database, see L<"insert">.
  79
  80 Note that this stores the hash reference, not a distinct copy of the hash it
  81 points to.  You can ask the object for a copy with the I<hash> method.
  82
  83 =cut
  84
  85 # the new method can be inherited from FS::Record, if a table method is defined
  86
  87 sub table { 'msg_template'; }
  88
  89 =item insert [ CONTENT ]
  90
  91 Adds this record to the database.  If there is an error, returns the error,
  92 otherwise returns false.
  93
  94 A default (no locale) L<FS::template_content> object will be created.  CONTENT
  95 is an optional hash containing 'subject' and 'body' for this object.
  96
  97 =cut
  98
  99 sub insert {
 100   my $self = shift;
 101   my %content = @_;
 102
 103   my $oldAutoCommit = $FS::UID::AutoCommit;
 104   local $FS::UID::AutoCommit = 0;
 105   my $dbh = dbh;
 106
 107   my $error = $self->SUPER::insert;
 108   if ( !$error ) {
 109     $content{'msgnum'} = $self->msgnum;
 110     $content{'subject'} ||= '';
 111     $content{'body'} ||= '';
 112     my $template_content = new FS::template_content (\%content);
 113     $error = $template_content->insert;
 114   }
 115
 116   if ( $error ) {
 117     $dbh->rollback if $oldAutoCommit;
 118     return $error;
 119   }
 120
 121   $dbh->commit if $oldAutoCommit;
 122   return;
 123 }
 124
 125 =item delete
 126
 127 Delete this record from the database.
 128
 129 =cut
 130
 131 # the delete method can be inherited from FS::Record
 132
 133 =item replace [ OLD_RECORD ] [ CONTENT ]
 134
 135 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 136 returns the error, otherwise returns false.
 137
 138 CONTENT is an optional hash containing 'subject', 'body', and 'locale'.  If
 139 supplied, an L<FS::template_content> object will be created (or modified, if
 140 one already exists for this locale).
 141
 142 =cut
 143
 144 sub replace {
 145   my $self = shift;
 146   my $old = ( ref($_[0]) and $_[0]->isa('FS::Record') )
 147               ? shift
 148               : $self->replace_old;
 149   my %content = @_;
 150
 151   my $oldAutoCommit = $FS::UID::AutoCommit;
 152   local $FS::UID::AutoCommit = 0;
 153   my $dbh = dbh;
 154
 155   my $error = $self->SUPER::replace($old);
 156
 157   if ( !$error and %content ) {
 158     $content{'locale'} ||= '';
 159     my $new_content = qsearchs('template_content', {
 160                         'msgnum' => $self->msgnum,
 161                         'locale' => $content{'locale'},
 162                       } );
 163     if ( $new_content ) {
 164       $new_content->subject($content{'subject'});
 165       $new_content->body($content{'body'});
 166       $error = $new_content->replace;
 167     }
 168     else {
 169       $content{'msgnum'} = $self->msgnum;
 170       $new_content = new FS::template_content \%content;
 171       $error = $new_content->insert;
 172     }
 173   }
 174
 175   if ( $error ) {
 176     $dbh->rollback if $oldAutoCommit;
 177     return $error;
 178   }
 179
 180   warn "committing FS::msg_template->replace\n" if $DEBUG and $oldAutoCommit;
 181   $dbh->commit if $oldAutoCommit;
 182   return;
 183 }
 184
 185
 186
 187 =item check
 188
 189 Checks all fields to make sure this is a valid template.  If there is
 190 an error, returns the error, otherwise returns false.  Called by the insert
 191 and replace methods.
 192
 193 =cut
 194
 195 # the check method should currently be supplied - FS::Record contains some
 196 # data checking routines
 197
 198 sub check {
 199   my $self = shift;
 200
 201   my $error =
 202     $self->ut_numbern('msgnum')
 203     || $self->ut_text('msgname')
 204     || $self->ut_foreign_keyn('agentnum', 'agent', 'agentnum')
 205     || $self->ut_textn('mime_type')
 206     || $self->ut_enum('disabled', [ '', 'Y' ] )
 207     || $self->ut_textn('from_addr')
 208   ;
 209   return $error if $error;
 210
 211   $self->mime_type('text/html') unless $self->mime_type;
 212
 213   $self->SUPER::check;
 214 }
 215
 216 =item content_locales
 217
 218 Returns a hashref of the L<FS::template_content> objects attached to
 219 this template, with the locale as key.
 220
 221 =cut
 222
 223 sub content_locales {
 224   my $self = shift;
 225   return $self->{'_content_locales'} ||= +{
 226     map { $_->locale , $_ }
 227     qsearch('template_content', { 'msgnum' => $self->msgnum })
 228   };
 229 }
 230
 231 =item prepare OPTION => VALUE
 232
 233 Fills in the template and returns a hash of the 'from' address, 'to'
 234 addresses, subject line, and body.
 235
 236 Options are passed as a list of name/value pairs:
 237
 238 =over 4
 239
 240 =item cust_main
 241
 242 Customer object (required).
 243
 244 =item object
 245
 246 Additional context object (currently, can be a cust_main, cust_pkg,
 247 cust_bill, cust_pay, cust_pay_pending, or svc_(acct, phone, broadband,
 248 domain) ).  If the object is a svc_*, its cust_pkg will be fetched and
 249 used for substitution.
 250
 251 As a special case, this may be an arrayref of two objects.  Both
 252 objects will be available for substitution, with their field names
 253 prefixed with 'new_' and 'old_' respectively.  This is used in the
 254 rt_ticket export when exporting "replace" events.
 255
 256 =item from_config
 257
 258 Configuration option to use as the source address, based on the customer's
 259 agentnum.  If unspecified (or the named option is empty), 'invoice_from'
 260 will be used.
 261
 262 The I<from_addr> field in the template takes precedence over this.
 263
 264 =item to
 265
 266 Destination address.  The default is to use the customer's
 267 invoicing_list addresses.  Multiple addresses may be comma-separated.
 268
 269 =item substitutions
 270
 271 A hash reference of additional substitutions
 272
 273 =back
 274
 275 =cut
 276
 277 sub prepare {
 278   my( $self, %opt ) = @_;
 279
 280   my $cust_main = $opt{'cust_main'} or die 'cust_main required';
 281   my $object = $opt{'object'} or die 'object required';
 282
 283   # localization
 284   my $locale = $cust_main->locale || '';
 285   warn "no locale for cust#".$cust_main->custnum."; using default content\n"
 286     if $DEBUG and !$locale;
 287   my $content = $self->content($cust_main->locale);
 288   warn "preparing template '".$self->msgname."' to cust#".$cust_main->custnum."\n"
 289     if($DEBUG);
 290
 291   my $subs = $self->substitutions;
 292
 293   ###
 294   # create substitution table
 295   ###
 296   my %hash;
 297   my @objects = ($cust_main);
 298   my @prefixes = ('');
 299   my $svc;
 300   if( ref $object ) {
 301     if( ref($object) eq 'ARRAY' ) {
 302       # [new, old], for provisioning tickets
 303       push @objects, $object->[0], $object->[1];
 304       push @prefixes, 'new_', 'old_';
 305       $svc = $object->[0] if $object->[0]->isa('FS::svc_Common');
 306     }
 307     else {
 308       push @objects, $object;
 309       push @prefixes, '';
 310       $svc = $object if $object->isa('FS::svc_Common');
 311     }
 312   }
 313   if( $svc ) {
 314     push @objects, $svc->cust_svc->cust_pkg;
 315     push @prefixes, '';
 316   }
 317
 318   foreach my $obj (@objects) {
 319     my $prefix = shift @prefixes;
 320     foreach my $name (@{ $subs->{$obj->table} }) {
 321       if(!ref($name)) {
 322         # simple case
 323         $hash{$prefix.$name} = $obj->$name();
 324       }
 325       elsif( ref($name) eq 'ARRAY' ) {
 326         # [ foo => sub { ... } ]
 327         $hash{$prefix.($name->[0])} = $name->[1]->($obj);
 328       }
 329       else {
 330         warn "bad msg_template substitution: '$name'\n";
 331         #skip it?
 332       }
 333     }
 334   }
 335
 336   if ( $opt{substitutions} ) {
 337     $hash{$_} = $opt{substitutions}->{$_} foreach keys %{$opt{substitutions}};
 338   }
 339
 340   $_ = encode_entities($_ || '') foreach values(%hash);
 341
 342   ###
 343   # clean up template
 344   ###
 345   my $subject_tmpl = new Text::Template (
 346     TYPE   => 'STRING',
 347     SOURCE => $content->subject,
 348   );
 349   my $subject = $subject_tmpl->fill_in( HASH => \%hash );
 350
 351   my $body = $content->body;
 352   my ($skin, $guts) = eviscerate($body);
 353   @$guts = map {
 354     $_ = decode_entities($_); # turn all punctuation back into itself
 355     s/\r//gs;           # remove \r's
 356     s/<br[^>]*>/\n/gsi; # and <br /> tags
 357     s/<p>/\n/gsi;       # and <p>
 358     s/<\/p>//gsi;       # and </p>
 359     s/\240/ /gs;        # and &nbsp;
 360     $_
 361   } @$guts;
 362
 363   $body = '{ use Date::Format qw(time2str); "" }';
 364   while(@$skin || @$guts) {
 365     $body .= shift(@$skin) || '';
 366     $body .= shift(@$guts) || '';
 367   }
 368
 369   ###
 370   # fill-in
 371   ###
 372
 373   my $body_tmpl = new Text::Template (
 374     TYPE          => 'STRING',
 375     SOURCE        => $body,
 376   );
 377
 378   $body = $body_tmpl->fill_in( HASH => \%hash );
 379
 380   ###
 381   # and email
 382   ###
 383
 384   my @to;
 385   if ( exists($opt{'to'}) ) {
 386     @to = split(/\s*,\s*/, $opt{'to'});
 387   }
 388   else {
 389     @to = $cust_main->invoicing_list_emailonly;
 390   }
 391   # no warning when preparing with no destination
 392
 393   my $from_addr = $self->from_addr;
 394
 395   if ( !$from_addr ) {
 396     if ( $opt{'from_config'} ) {
 397       $from_addr = scalar( $conf->config($opt{'from_config'},
 398                                          $cust_main->agentnum) );
 399     }
 400     $from_addr ||= scalar( $conf->config('invoice_from',
 401                                          $cust_main->agentnum) );
 402   }
 403 #  my @cust_msg = ();
 404 #  if ( $conf->exists('log_sent_mail') and !$opt{'preview'} ) {
 405 #    my $cust_msg = FS::cust_msg->new({
 406 #        'custnum' => $cust_main->custnum,
 407 #        'msgnum'  => $self->msgnum,
 408 #        'status'  => 'prepared',
 409 #      });
 410 #    $cust_msg->insert;
 411 #    @cust_msg = ('cust_msg' => $cust_msg);
 412 #  }
 413
 414   my $text_body = encode('UTF-8',
 415                   HTML::FormatText->new(leftmargin => 0, rightmargin => 70)
 416                       ->format( HTML::TreeBuilder->new_from_content($body) )
 417                   );
 418   (
 419     'custnum' => $cust_main->custnum,
 420     'msgnum'  => $self->msgnum,
 421     'from' => $from_addr,
 422     'to'   => \@to,
 423     'bcc'  => $self->bcc_addr || undef,
 424     'subject'   => $subject,
 425     'html_body' => $body,
 426     'text_body' => $text_body
 427   );
 428
 429 }
 430
 431 =item send OPTION => VALUE
 432
 433 Fills in the template and sends it to the customer.  Options are as for
 434 'prepare'.
 435
 436 =cut
 437
 438 # broken out from prepare() in case we want to queue the sending,
 439 # preview it, etc.
 440 sub send {
 441   my $self = shift;
 442   send_email(generate_email($self->prepare(@_)));
 443 }
 444
 445 =item render OPTION => VALUE ...
 446
 447 Fills in the template and renders it to a PDF document.  Returns the
 448 name of the PDF file.
 449
 450 Options are as for 'prepare', but 'from' and 'to' are meaningless.
 451
 452 =cut
 453
 454 # will also have options to set paper size, margins, etc.
 455
 456 sub render {
 457   my $self = shift;
 458   eval "use PDF::WebKit";
 459   die $@ if $@;
 460   my %opt = @_;
 461   my %hash = $self->prepare(%opt);
 462   my $html = $hash{'html_body'};
 463
 464   # Graphics/stylesheets should probably go in /var/www on the Freeside
 465   # machine.
 466   my $kit = PDF::WebKit->new(\$html); #%options
 467   # hack to use our wrapper script
 468   $kit->configure(sub { shift->wkhtmltopdf('freeside-wkhtmltopdf') });
 469
 470   $kit->to_pdf;
 471 }
 472
 473 =item print OPTIONS
 474
 475 Render a PDF and send it to the printer.  OPTIONS are as for 'render'.
 476
 477 =cut
 478
 479 sub print {
 480   my( $self, %opt ) = @_;
 481   do_print( [ $self->render(%opt) ], agentnum=>$opt{cust_main}->agentnum );
 482 }
 483
 484 # helper sub for package dates
 485 my $ymd = sub { $_[0] ? time2str('%Y-%m-%d', $_[0]) : '' };
 486
 487 # helper sub for money amounts
 488 my $money = sub { ($conf->money_char || '$') . sprintf('%.2f', $_[0] || 0) };
 489
 490 # helper sub for usage-related messages
 491 my $usage_warning = sub {
 492   my $svc = shift;
 493   foreach my $col (qw(seconds upbytes downbytes totalbytes)) {
 494     my $amount = $svc->$col; next if $amount eq '';
 495     my $method = $col.'_threshold';
 496     my $threshold = $svc->$method; next if $threshold eq '';
 497     return [$col, $amount, $threshold] if $amount <= $threshold;
 498     # this only returns the first one that's below threshold, if there are
 499     # several.
 500   }
 501   return ['', '', ''];
 502 };
 503
 504 #my $conf = new FS::Conf;
 505
 506 #return contexts and fill-in values
 507 # If you add anything, be sure to add a description in
 508 # httemplate/edit/msg_template.html.
 509 sub substitutions {
 510   { 'cust_main' => [qw(
 511       display_custnum agentnum agent_name
 512
 513       last first company
 514       name name_short contact contact_firstlast
 515       address1 address2 city county state zip
 516       country
 517       daytime night mobile fax
 518
 519       has_ship_address
 520       ship_name ship_name_short ship_contact ship_contact_firstlast
 521       ship_address1 ship_address2 ship_city ship_county ship_state ship_zip
 522       ship_country
 523
 524       paymask payname paytype payip
 525       num_cancelled_pkgs num_ncancelled_pkgs num_pkgs
 526       classname categoryname
 527       balance
 528       credit_limit
 529       invoicing_list_emailonly
 530       cust_status ucfirst_cust_status cust_statuscolor
 531
 532       signupdate dundate
 533       packages recurdates
 534       ),
 535       [ invoicing_email => sub { shift->invoicing_list_emailonly_scalar } ],
 536       #compatibility: obsolete ship_ fields - use the non-ship versions
 537       map (
 538         { my $field = $_;
 539           [ "ship_$field"   => sub { shift->$field } ]
 540         }
 541         qw( last first company daytime night fax )
 542       ),
 543       # ship_name, ship_name_short, ship_contact, ship_contact_firstlast
 544       # still work, though
 545       [ expdate           => sub { shift->paydate_epoch } ], #compatibility
 546       [ signupdate_ymd    => sub { $ymd->(shift->signupdate) } ],
 547       [ dundate_ymd       => sub { $ymd->(shift->dundate) } ],
 548       [ paydate_my        => sub { sprintf('%02d/%04d', shift->paydate_monthyear) } ],
 549       [ otaker_first      => sub { shift->access_user->first } ],
 550       [ otaker_last       => sub { shift->access_user->last } ],
 551       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 552       [ company_name      => sub {
 553           $conf->config('company_name', shift->agentnum)
 554         } ],
 555       [ company_address   => sub {
 556           $conf->config('company_address', shift->agentnum)
 557         } ],
 558       [ company_phonenum  => sub {
 559           $conf->config('company_phonenum', shift->agentnum)
 560         } ],
 561     ],
 562     # next_bill_date
 563     'cust_pkg'  => [qw(
 564       pkgnum pkg_label pkg_label_long
 565       location_label
 566       status statuscolor
 567
 568       start_date setup bill last_bill
 569       adjourn susp expire
 570       labels_short
 571       ),
 572       [ pkg               => sub { shift->part_pkg->pkg } ],
 573       [ pkg_category      => sub { shift->part_pkg->categoryname } ],
 574       [ pkg_class         => sub { shift->part_pkg->classname } ],
 575       [ cancel            => sub { shift->getfield('cancel') } ], # grrr...
 576       [ start_ymd         => sub { $ymd->(shift->getfield('start_date')) } ],
 577       [ setup_ymd         => sub { $ymd->(shift->getfield('setup')) } ],
 578       [ next_bill_ymd     => sub { $ymd->(shift->getfield('bill')) } ],
 579       [ last_bill_ymd     => sub { $ymd->(shift->getfield('last_bill')) } ],
 580       [ adjourn_ymd       => sub { $ymd->(shift->getfield('adjourn')) } ],
 581       [ susp_ymd          => sub { $ymd->(shift->getfield('susp')) } ],
 582       [ expire_ymd        => sub { $ymd->(shift->getfield('expire')) } ],
 583       [ cancel_ymd        => sub { $ymd->(shift->getfield('cancel')) } ],
 584
 585       # not necessarily correct for non-flat packages
 586       [ setup_fee         => sub { shift->part_pkg->option('setup_fee') } ],
 587       [ recur_fee         => sub { shift->part_pkg->option('recur_fee') } ],
 588
 589       [ freq_pretty       => sub { shift->part_pkg->freq_pretty } ],
 590
 591     ],
 592     'cust_bill' => [qw(
 593       invnum
 594       _date
 595     )],
 596     #XXX not really thinking about cust_bill substitutions quite yet
 597
 598     # for welcome and limit warning messages
 599     'svc_acct' => [qw(
 600       svcnum
 601       username
 602       domain
 603       ),
 604       [ password          => sub { shift->getfield('_password') } ],
 605       [ column            => sub { &$usage_warning(shift)->[0] } ],
 606       [ amount            => sub { &$usage_warning(shift)->[1] } ],
 607       [ threshold         => sub { &$usage_warning(shift)->[2] } ],
 608     ],
 609     'svc_domain' => [qw(
 610       svcnum
 611       domain
 612       ),
 613       [ registrar         => sub {
 614           my $registrar = qsearchs('registrar',
 615             { registrarnum => shift->registrarnum} );
 616           $registrar ? $registrar->registrarname : ''
 617         }
 618       ],
 619       [ catchall          => sub {
 620           my $svc_acct = qsearchs('svc_acct', { svcnum => shift->catchall });
 621           $svc_acct ? $svc_acct->email : ''
 622         }
 623       ],
 624     ],
 625     'svc_phone' => [qw(
 626       svcnum
 627       phonenum
 628       countrycode
 629       domain
 630       )
 631     ],
 632     'svc_broadband' => [qw(
 633       svcnum
 634       speed_up
 635       speed_down
 636       ip_addr
 637       mac_addr
 638       )
 639     ],
 640     # for payment receipts
 641     'cust_pay' => [qw(
 642       paynum
 643       _date
 644       ),
 645       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 646       # overrides the one in cust_main in cases where a cust_pay is passed
 647       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 648       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 649       [ payinfo           => sub {
 650           my $cust_pay = shift;
 651           ($cust_pay->payby eq 'CARD' || $cust_pay->payby eq 'CHEK') ?
 652             $cust_pay->paymask : $cust_pay->decrypt($cust_pay->payinfo)
 653         } ],
 654     ],
 655     # for payment decline messages
 656     # try to support all cust_pay fields
 657     # 'error' is a special case, it contains the raw error from the gateway
 658     'cust_pay_pending' => [qw(
 659       _date
 660       error
 661       ),
 662       [ paid              => sub { sprintf("%.2f", shift->paid) } ],
 663       [ payby             => sub { FS::payby->shortname(shift->payby) } ],
 664       [ date              => sub { time2str("%a %B %o, %Y", shift->_date) } ],
 665       [ payinfo           => sub {
 666           my $pending = shift;
 667           ($pending->payby eq 'CARD' || $pending->payby eq 'CHEK') ?
 668             $pending->paymask : $pending->decrypt($pending->payinfo)
 669         } ],
 670     ],
 671   };
 672 }
 673
 674 =item content LOCALE
 675
 676 Returns the L<FS::template_content> object appropriate to LOCALE, if there
 677 is one.  If not, returns the one with a NULL locale.
 678
 679 =cut
 680
 681 sub content {
 682   my $self = shift;
 683   my $locale = shift;
 684   qsearchs('template_content',
 685             { 'msgnum' => $self->msgnum, 'locale' => $locale }) ||
 686   qsearchs('template_content',
 687             { 'msgnum' => $self->msgnum, 'locale' => '' });
 688 }
 689
 690 =item agent
 691
 692 Returns the L<FS::agent> object for this template.
 693
 694 =cut
 695
 696 sub agent {
 697   qsearchs('agent', { 'agentnum' => $_[0]->agentnum });
 698 }
 699
 700 sub _upgrade_data {
 701   my ($self, %opts) = @_;
 702
 703   my @fixes = (
 704     [ 'alerter_msgnum',  'alerter_template',   '',               '', '' ],
 705     [ 'cancel_msgnum',   'cancelmessage',      'cancelsubject',  '', '' ],
 706     [ 'decline_msgnum',  'declinetemplate',    '',               '', '' ],
 707     [ 'impending_recur_msgnum', 'impending_recur_template', '',  '', 'impending_recur_bcc' ],
 708     [ 'payment_receipt_msgnum', 'payment_receipt_email', '',     '', '' ],
 709     [ 'welcome_msgnum',  'welcome_email',      'welcome_email-subject', 'welcome_email-from', '' ],
 710     [ 'warning_msgnum',  'warning_email',      'warning_email-subject', 'warning_email-from', '' ],
 711   );
 712
 713   my @agentnums = ('', map {$_->agentnum} qsearch('agent', {}));
 714   foreach my $agentnum (@agentnums) {
 715     foreach (@fixes) {
 716       my ($newname, $oldname, $subject, $from, $bcc) = @$_;
 717       if ($conf->exists($oldname, $agentnum)) {
 718         my $new = new FS::msg_template({
 719           'msgname'   => $oldname,
 720           'agentnum'  => $agentnum,
 721           'from_addr' => ($from && $conf->config($from, $agentnum)) || '',
 722           'bcc_addr'  => ($bcc && $conf->config($from, $agentnum)) || '',
 723           'subject'   => ($subject && $conf->config($subject, $agentnum)) || '',
 724           'mime_type' => 'text/html',
 725           'body'      => join('<BR>',$conf->config($oldname, $agentnum)),
 726         });
 727         my $error = $new->insert;
 728         die $error if $error;
 729         $conf->set($newname, $new->msgnum, $agentnum);
 730         $conf->delete($oldname, $agentnum);
 731         $conf->delete($from, $agentnum) if $from;
 732         $conf->delete($subject, $agentnum) if $subject;
 733       }
 734     }
 735   }
 736   foreach my $msg_template ( qsearch('msg_template', {}) ) {
 737     if ( $msg_template->subject || $msg_template->body ) {
 738       # create new default content
 739       my %content;
 740       $content{subject} = $msg_template->subject;
 741       $msg_template->set('subject', '');
 742
 743       # work around obscure Pg/DBD bug
 744       # https://rt.cpan.org/Public/Bug/Display.html?id=60200
 745       # (though the right fix is to upgrade DBD)
 746       my $body = $msg_template->body;
 747       if ( $body =~ /^x([0-9a-f]+)$/ ) {
 748         # there should be no real message templates that look like that
 749         warn "converting template body to TEXT\n";
 750         $body = pack('H*', $1);
 751       }
 752       $content{body} = $body;
 753       $msg_template->set('body', '');
 754
 755       my $error = $msg_template->replace(%content);
 756       die $error if $error;
 757     }
 758   }
 759 }
 760
 761 sub eviscerate {
 762   # Every bit as pleasant as it sounds.
 763   #
 764   # We do this because Text::Template::Preprocess doesn't
 765   # actually work.  It runs the entire template through
 766   # the preprocessor, instead of the code segments.  Which
 767   # is a shame, because Text::Template already contains
 768   # the code to do this operation.
 769   my $body = shift;
 770   my (@outside, @inside);
 771   my $depth = 0;
 772   my $chunk = '';
 773   while($body || $chunk) {
 774     my ($first, $delim, $rest);
 775     # put all leading non-delimiters into $first
 776     ($first, $rest) =
 777         ($body =~ /^((?:\\[{}]|[^{}])*)(.*)$/s);
 778     $chunk .= $first;
 779     # put a leading delimiter into $delim if there is one
 780     ($delim, $rest) =
 781       ($rest =~ /^([{}]?)(.*)$/s);
 782
 783     if( $delim eq '{' ) {
 784       $chunk .= '{';
 785       if( $depth == 0 ) {
 786         push @outside, $chunk;
 787         $chunk = '';
 788       }
 789       $depth++;
 790     }
 791     elsif( $delim eq '}' ) {
 792       $depth--;
 793       if( $depth == 0 ) {
 794         push @inside, $chunk;
 795         $chunk = '';
 796       }
 797       $chunk .= '}';
 798     }
 799     else {
 800       # no more delimiters
 801       if( $depth == 0 ) {
 802         push @outside, $chunk . $rest;
 803       } # else ? something wrong
 804       last;
 805     }
 806     $body = $rest;
 807   }
 808   (\@outside, \@inside);
 809 }
 810
 811 =back
 812
 813 =head1 BUGS
 814
 815 =head1 SEE ALSO
 816
 817 L<FS::Record>, schema.html from the base documentation.
 818
 819 =cut
 820
 821 1;
 822