FS/FS/geocode_Mixin.pm

   1 package FS::geocode_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me );
   5 use Carp;
   6 use Locale::Country;
   7 use Geo::Coder::Googlev3; #compile time for now, until others are supported
   8 use FS::Record qw( qsearchs qsearch );
   9 use FS::Conf;
  10 use FS::cust_pkg;
  11 use FS::cust_location;
  12 use FS::cust_tax_location;
  13 use FS::part_pkg;
  14
  15 $DEBUG = 0;
  16 $me = '[FS::geocode_Mixin]';
  17
  18 =head1 NAME
  19
  20 FS::geocode_Mixin - Mixin class for records that contain address and other
  21 location fields.
  22
  23 =head1 SYNOPSIS
  24
  25   package FS::some_table;
  26   use base ( FS::geocode_Mixin FS::Record );
  27
  28 =head1 DESCRIPTION
  29
  30 FS::geocode_Mixin - This is a mixin class for records that contain address
  31 and other location fields.
  32
  33 =head1 METHODS
  34
  35 =over 4
  36
  37 =cut
  38
  39 =item location_hash
  40
  41 Returns a list of key/value pairs, with the following keys: address1, address2,
  42 city, county, state, zip, country, geocode, location_type, location_number,
  43 location_kind.  The shipping address is used if present.
  44
  45 =cut
  46
  47 #geocode dependent on tax-ship_address config
  48
  49 sub location_hash {
  50   my $self = shift;
  51   my $prefix = $self->has_ship_address ? 'ship_' : '';
  52
  53   map { my $method = ($_ eq 'geocode') ? $_ : $prefix.$_;
  54         $_ => $self->get($method);
  55       }
  56       qw( address1 address2 city county state zip country geocode
  57         location_type location_number location_kind );
  58 }
  59
  60 =item location_label [ OPTION => VALUE ... ]
  61
  62 Returns the label of the service location (see analog in L<FS::cust_location>) for this customer.
  63
  64 Options are
  65
  66 =over 4
  67
  68 =item join_string
  69
  70 used to separate the address elements (defaults to ', ')
  71
  72 =item escape_function
  73
  74 a callback used for escaping the text of the address elements
  75
  76 =back
  77
  78 =cut
  79
  80 sub location_label {
  81   my $self = shift;
  82   my %opt = @_;
  83
  84   my $separator = $opt{join_string} || ', ';
  85   my $escape = $opt{escape_function} || sub{ shift };
  86   my $ds = $opt{double_space} || '  ';
  87   my $line = '';
  88   my $cydefault =
  89     $opt{'countrydefault'} || FS::Conf->new->config('countrydefault') || 'US';
  90   my $prefix = $self->has_ship_address ? 'ship_' : '';
  91
  92   my $notfirst = 0;
  93   foreach (qw ( address1 address2 ) ) {
  94     my $method = "$prefix$_";
  95     $line .= ($notfirst ? $separator : ''). &$escape($self->$method)
  96       if $self->$method;
  97     $notfirst++;
  98   }
  99
 100   my $lt = $self->get($prefix.'location_type');
 101   if ( $lt ) {
 102     my %location_type;
 103     if ( 1 ) { #ikano, switch on via config
 104       { no warnings 'void';
 105         eval { 'use FS::part_export::ikano;' };
 106         die $@ if $@;
 107       }
 108       %location_type = FS::part_export::ikano->location_types;
 109     } else {
 110       %location_type = (); #?
 111     }
 112
 113     $line .= ' '.&$escape( $location_type{$lt} || $lt );
 114   }
 115
 116   $line .= ' '. &$escape($self->get($prefix.'location_number'))
 117     if $self->get($prefix.'location_number');
 118
 119   $notfirst = 0;
 120   foreach (qw ( city county state zip ) ) {
 121     my $method = "$prefix$_";
 122     if ( $self->$method ) {
 123       $line .= ' (' if $method eq 'county';
 124       $line .= ($notfirst ? ' ' : $separator). &$escape($self->$method);
 125       $line .= ' )' if $method eq 'county';
 126       $notfirst++;
 127     }
 128   }
 129   $line .= $separator. &$escape(code2country($self->country))
 130     if $self->country ne $cydefault;
 131
 132   $line;
 133 }
 134
 135 =item set_coord
 136
 137 =cut
 138
 139 sub set_coord {
 140   my $self = shift;
 141   my $pre = scalar(@_) ? shift : '';
 142
 143   #my $module = FS::Conf->new->config('geocode_module') || 'Geo::Coder::Googlev3';
 144
 145   my $geocoder = Geo::Coder::Googlev3->new;
 146   my $location = $geocoder->geocode( location =>
 147     $self->get($pre.'address1'). ','.
 148     ( $self->get($pre.'address2') ? $self->get($pre.'address2').',' : '' ).
 149     $self->get($pre.'city'). ','.
 150     $self->get($pre.'state'). ','.
 151     code2country($self->get($pre.'country'))
 152   );
 153
 154   #errors?
 155
 156   my $geo_loc = $location->{'geometry'}{'location'} or return;
 157   if ( $geo_loc->{'lat'} && $geo_loc->{'lng'} ) {
 158     $self->set($pre.'latitude',  $geo_loc->{'lat'} );
 159     $self->set($pre.'longitude', $geo_loc->{'lng'} );
 160     $self->set($pre.'coord_auto', 'Y');
 161   }
 162
 163 }
 164
 165 =item geocode DATA_VENDOR
 166
 167 Returns a value for the customer location as encoded by DATA_VENDOR.
 168 Currently this only makes sense for "CCH" as DATA_VENDOR.
 169
 170 =cut
 171
 172 sub geocode {
 173   my ($self, $data_vendor) = (shift, shift);  #always cch for now
 174
 175   my $geocode = $self->get('geocode');  #XXX only one data_vendor for geocode
 176   return $geocode if $geocode;
 177
 178   my $prefix =
 179    ( FS::Conf->new->exists('tax-ship_address') && $self->has_ship_address )
 180    ? 'ship_'
 181    : '';
 182
 183   my($zip,$plus4) = split /-/, $self->get("${prefix}zip")
 184     if $self->country eq 'US';
 185
 186   $zip ||= '';
 187   $plus4 ||= '';
 188   #CCH specific location stuff
 189   my $extra_sql = $plus4 ? "AND plus4lo <= '$plus4' AND plus4hi >= '$plus4'"
 190                          : '';
 191
 192   my @cust_tax_location =
 193     qsearch( {
 194                'table'     => 'cust_tax_location',
 195                'hashref'   => { 'zip' => $zip, 'data_vendor' => $data_vendor },
 196                'extra_sql' => $extra_sql,
 197                'order_by'  => 'ORDER BY plus4hi',#overlapping with distinct ends
 198              }
 199            );
 200   $geocode = $cust_tax_location[0]->geocode
 201     if scalar(@cust_tax_location);
 202
 203   warn "WARNING: customer ". $self->custnum.
 204        ": multiple locations for zip ". $self->get("${prefix}zip").
 205        "; using arbitrary geocode $geocode\n"
 206     if scalar(@cust_tax_location) > 1;
 207
 208   $geocode;
 209 }
 210
 211 =back
 212
 213 =head1 BUGS
 214
 215 =head1 SEE ALSO
 216
 217 L<FS::Record>, schema.html from the base documentation.
 218
 219 =cut
 220
 221 1;
 222