FS/FS/geocode_Mixin.pm

   1 package FS::geocode_Mixin;
   2
   3 use strict;
   4 use vars qw( $DEBUG $me );
   5 use Carp;
   6 use Locale::Country ();
   7 use Geo::Coder::Googlev3; #compile time for now, until others are supported
   8 use FS::Record qw( qsearchs qsearch );
   9 use FS::Conf;
  10 use FS::cust_pkg;
  11 use FS::cust_location;
  12 use FS::cust_tax_location;
  13 use FS::part_pkg;
  14
  15 $DEBUG = 0;
  16 $me = '[FS::geocode_Mixin]';
  17
  18 =head1 NAME
  19
  20 FS::geocode_Mixin - Mixin class for records that contain address and other
  21 location fields.
  22
  23 =head1 SYNOPSIS
  24
  25   package FS::some_table;
  26   use base ( FS::geocode_Mixin FS::Record );
  27
  28 =head1 DESCRIPTION
  29
  30 FS::geocode_Mixin - This is a mixin class for records that contain address
  31 and other location fields.
  32
  33 =head1 METHODS
  34
  35 =over 4
  36
  37 =cut
  38
  39 =item location_hash
  40
  41 Returns a list of key/value pairs, with the following keys: address1, address2,
  42 city, county, state, zip, country, geocode, location_type, location_number,
  43 location_kind.  The shipping address is used if present.
  44
  45 =cut
  46
  47 #geocode dependent on tax-ship_address config
  48
  49 sub location_hash {
  50   my $self = shift;
  51   my $prefix = $self->has_ship_address ? 'ship_' : '';
  52
  53   map { my $method = ($_ eq 'geocode') ? $_ : $prefix.$_;
  54         $_ => $self->get($method);
  55       }
  56       qw( address1 address2 city county state zip country geocode
  57         location_type location_number location_kind );
  58 }
  59
  60 =item location_label [ OPTION => VALUE ... ]
  61
  62 Returns the label of the service location (see analog in L<FS::cust_location>) for this customer.
  63
  64 Options are
  65
  66 =over 4
  67
  68 =item join_string
  69
  70 used to separate the address elements (defaults to ', ')
  71
  72 =item escape_function
  73
  74 a callback used for escaping the text of the address elements
  75
  76 =back
  77
  78 =cut
  79
  80 sub location_label {
  81   my $self = shift;
  82   my %opt = @_;
  83
  84   my $separator = $opt{join_string} || ', ';
  85   my $escape = $opt{escape_function} || sub{ shift };
  86   my $ds = $opt{double_space} || '  ';
  87   my $line = '';
  88   my $cydefault =
  89     $opt{'countrydefault'} || FS::Conf->new->config('countrydefault') || 'US';
  90   my $prefix = $self->has_ship_address ? 'ship_' : '';
  91
  92   my $notfirst = 0;
  93   foreach (qw ( address1 address2 ) ) {
  94     my $method = "$prefix$_";
  95     $line .= ($notfirst ? $separator : ''). &$escape($self->$method)
  96       if $self->$method;
  97     $notfirst++;
  98   }
  99
 100   my $lt = $self->get($prefix.'location_type');
 101   if ( $lt ) {
 102     my %location_type;
 103     if ( 1 ) { #ikano, switch on via config
 104       { no warnings 'void';
 105         eval { 'use FS::part_export::ikano;' };
 106         die $@ if $@;
 107       }
 108       %location_type = FS::part_export::ikano->location_types;
 109     } else {
 110       %location_type = (); #?
 111     }
 112
 113     $line .= ' '.&$escape( $location_type{$lt} || $lt );
 114   }
 115
 116   $line .= ' '. &$escape($self->get($prefix.'location_number'))
 117     if $self->get($prefix.'location_number');
 118
 119   $notfirst = 0;
 120   foreach (qw ( city county state zip ) ) {
 121     my $method = "$prefix$_";
 122     if ( $self->$method ) {
 123       $line .= ' (' if $method eq 'county';
 124       $line .= ($notfirst ? ' ' : $separator). &$escape($self->$method);
 125       $line .= ' )' if $method eq 'county';
 126       $notfirst++;
 127     }
 128   }
 129   $line .= $separator. &$escape($self->country_full)
 130     if $self->country ne $cydefault;
 131
 132   $line;
 133 }
 134
 135 =item country_full
 136
 137 Returns the full country name.
 138
 139 =cut
 140
 141 sub country_full {
 142   my $self = shift;
 143   $self->code2country($self->get('country'));
 144 }
 145
 146 sub code2country {
 147   my( $self, $country ) = @_;
 148
 149   #a hash?  not expecting an explosion of business from unrecognized countries..
 150   return 'KKTC' if $country eq 'XC';
 151
 152   Locale::Country::code2country($country);
 153 }
 154
 155 =item set_coord
 156
 157 Look up the coordinates of the location using (currently) the Google Maps
 158 API and set the 'latitude' and 'longitude' fields accordingly.
 159
 160 =cut
 161
 162 sub set_coord {
 163   my $self = shift;
 164
 165   #my $module = FS::Conf->new->config('geocode_module') || 'Geo::Coder::Googlev3';
 166
 167   my $geocoder = Geo::Coder::Googlev3->new;
 168
 169   my $location = eval {
 170     $geocoder->geocode( location =>
 171       $self->get('address1'). ','.
 172       ( $self->get('address2') ? $self->get('address2').',' : '' ).
 173       $self->get('city'). ','.
 174       $self->get('state'). ','.
 175       $self->country_full
 176     );
 177   };
 178   if ( $@ ) {
 179     warn "geocoding error: $@\n";
 180     return;
 181   }
 182
 183   my $geo_loc = $location->{'geometry'}{'location'} or return;
 184   if ( $geo_loc->{'lat'} && $geo_loc->{'lng'} ) {
 185     $self->set('latitude',  $geo_loc->{'lat'} );
 186     $self->set('longitude', $geo_loc->{'lng'} );
 187     $self->set('coord_auto', 'Y');
 188   }
 189
 190 }
 191
 192 =item geocode DATA_VENDOR
 193
 194 Returns a value for the customer location as encoded by DATA_VENDOR.
 195 Currently this only makes sense for "CCH" as DATA_VENDOR.
 196
 197 =cut
 198
 199 sub geocode {
 200   my ($self, $data_vendor) = (shift, shift);  #always cch for now
 201
 202   my $geocode = $self->get('geocode');  #XXX only one data_vendor for geocode
 203   return $geocode if $geocode;
 204
 205   if ( $self->isa('FS::cust_main') ) {
 206     warn "WARNING: FS::cust_main->geocode deprecated";
 207
 208     # do the best we can
 209     my $m = FS::Conf->new->exists('tax-ship_address') ? 'ship_location'
 210                                                       : 'bill_location';
 211     my $location = $self->$m or return '';
 212     return $location->geocode($data_vendor);
 213   }
 214
 215   my($zip,$plus4) = split /-/, $self->get('zip')
 216     if $self->country eq 'US';
 217
 218   $zip ||= '';
 219   $plus4 ||= '';
 220   #CCH specific location stuff
 221   my $extra_sql = $plus4 ? "AND plus4lo <= '$plus4' AND plus4hi >= '$plus4'"
 222                          : '';
 223
 224   my @cust_tax_location =
 225     qsearch( {
 226                'table'     => 'cust_tax_location',
 227                'hashref'   => { 'zip' => $zip, 'data_vendor' => $data_vendor },
 228                'extra_sql' => $extra_sql,
 229                'order_by'  => 'ORDER BY plus4hi',#overlapping with distinct ends
 230              }
 231            );
 232   $geocode = $cust_tax_location[0]->geocode
 233     if scalar(@cust_tax_location);
 234
 235   warn "WARNING: customer ". $self->custnum.
 236        ": multiple locations for zip ". $self->get("zip").
 237        "; using arbitrary geocode $geocode\n"
 238     if scalar(@cust_tax_location) > 1;
 239
 240   $geocode;
 241 }
 242
 243 =item process_district_update CLASS ID
 244
 245 Queueable function to update the tax district code using the selected method
 246 (config 'tax_district_method').  CLASS is either 'FS::cust_main' or
 247 'FS::cust_location'; ID is the key in one of those tables.
 248
 249 =cut
 250
 251 # this is run from the job queue so I'm not transactionizing it.
 252
 253 sub process_district_update {
 254   my $class = shift;
 255   my $id = shift;
 256
 257   local $DEBUG = 1;
 258
 259   eval "use FS::Misc::Geo qw(get_district); use FS::Conf; use $class;";
 260   die $@ if $@;
 261   die "$class has no location data" if !$class->can('location_hash');
 262
 263   my $conf = FS::Conf->new;
 264   my $method = $conf->config('tax_district_method')
 265     or return; #nothing to do if null
 266   my $self = $class->by_key($id) or die "object $id not found";
 267
 268   # dies on error, fine
 269   my $tax_info = get_district({ $self->location_hash }, $method);
 270
 271   if ( $tax_info ) {
 272     $self->set('district', $tax_info->{'district'} );
 273     my $error = $self->replace;
 274     die $error if $error;
 275
 276     my %hash = map { $_ => uc( $tax_info->{$_} ) }
 277       qw( district city county state country );
 278     $hash{'source'} = $method; # apply the update only to taxes we maintain
 279
 280     my @old = qsearch('cust_main_county', \%hash);
 281     if ( @old ) {
 282       # prune any duplicates rather than updating them
 283       my %keep; # key => cust_main_county record
 284       foreach my $cust_main_county (@old) {
 285         my $key = join('.', $cust_main_county->city ,
 286                             $cust_main_county->district ,
 287                             $cust_main_county->taxclass
 288                       );
 289         if ( exists $keep{$key} ) {
 290           my $disable_this = $cust_main_county;
 291           # prefer records that have a tax name
 292           if ( $cust_main_county->taxname and not $keep{$key}->taxname ) {
 293             $disable_this = $keep{$key};
 294             $keep{$key} = $cust_main_county;
 295           }
 296           # disable by setting the rate to zero, and setting source to null
 297           # so it doesn't get auto-updated in the future. don't actually
 298           # delete it, that produces orphan records
 299           warn "disabling tax rate #" .
 300             $disable_this->taxnum .
 301             " because it's a duplicate for $key\n"
 302             if $DEBUG;
 303           # by setting its rate to zero, and never updating
 304           # it again
 305           $disable_this->set('tax' => 0);
 306           $disable_this->set('source' => '');
 307           $error = $disable_this->replace;
 308           die $error if $error;
 309         }
 310
 311         $keep{$key} ||= $cust_main_county;
 312
 313       }
 314       foreach my $key (keys %keep) {
 315         my $cust_main_county = $keep{$key};
 316         warn "updating tax rate #".$cust_main_county->taxnum.
 317           " for $key" if $DEBUG;
 318         # update the tax rate only
 319         $cust_main_county->set('tax', $tax_info->{'tax'});
 320         $error ||= $cust_main_county->replace;
 321       }
 322     } else {
 323       # make a new tax record, and mark it so we can find it later
 324       $tax_info->{'source'} = $method;
 325       my $new = new FS::cust_main_county $tax_info;
 326       warn "creating tax rate for district ".$tax_info->{'district'} if $DEBUG;
 327       $error = $new->insert;
 328     }
 329     die $error if $error;
 330
 331   }
 332   return;
 333 }
 334
 335 =back
 336
 337 =head1 BUGS
 338
 339 =head1 SEE ALSO
 340
 341 L<FS::Record>, schema.html from the base documentation.
 342
 343 =cut
 344
 345 1;
 346