FS/FS/cust_svc.pm

   1 package FS::cust_svc;
   2
   3 use strict;
   4 use vars qw( @ISA $ignore_quantity );
   5 use Carp qw( cluck );
   6 use FS::Record qw( qsearch qsearchs dbh );
   7 use FS::cust_pkg;
   8 use FS::part_pkg;
   9 use FS::part_svc;
  10 use FS::pkg_svc;
  11 use FS::svc_acct;
  12 use FS::svc_domain;
  13 use FS::svc_forward;
  14 use FS::svc_broadband;
  15 use FS::domain_record;
  16 use FS::part_export;
  17
  18 @ISA = qw( FS::Record );
  19
  20 $ignore_quantity = 0;
  21
  22 sub _cache {
  23   my $self = shift;
  24   my ( $hashref, $cache ) = @_;
  25   if ( $hashref->{'username'} ) {
  26     $self->{'_svc_acct'} = FS::svc_acct->new($hashref, '');
  27   }
  28   if ( $hashref->{'svc'} ) {
  29     $self->{'_svcpart'} = FS::part_svc->new($hashref);
  30   }
  31 }
  32
  33 =head1 NAME
  34
  35 FS::cust_svc - Object method for cust_svc objects
  36
  37 =head1 SYNOPSIS
  38
  39   use FS::cust_svc;
  40
  41   $record = new FS::cust_svc \%hash
  42   $record = new FS::cust_svc { 'column' => 'value' };
  43
  44   $error = $record->insert;
  45
  46   $error = $new_record->replace($old_record);
  47
  48   $error = $record->delete;
  49
  50   $error = $record->check;
  51
  52   ($label, $value) = $record->label;
  53
  54 =head1 DESCRIPTION
  55
  56 An FS::cust_svc represents a service.  FS::cust_svc inherits from FS::Record.
  57 The following fields are currently supported:
  58
  59 =over 4
  60
  61 =item svcnum - primary key (assigned automatically for new services)
  62
  63 =item pkgnum - Package (see L<FS::cust_pkg>)
  64
  65 =item svcpart - Service definition (see L<FS::part_svc>)
  66
  67 =back
  68
  69 =head1 METHODS
  70
  71 =over 4
  72
  73 =item new HASHREF
  74
  75 Creates a new service.  To add the refund to the database, see L<"insert">.
  76 Services are normally created by creating FS::svc_ objects (see
  77 L<FS::svc_acct>, L<FS::svc_domain>, and L<FS::svc_forward>, among others).
  78
  79 =cut
  80
  81 sub table { 'cust_svc'; }
  82
  83 =item insert
  84
  85 Adds this service to the database.  If there is an error, returns the error,
  86 otherwise returns false.
  87
  88 =item delete
  89
  90 Deletes this service from the database.  If there is an error, returns the
  91 error, otherwise returns false.  Note that this only removes the cust_svc
  92 record - you should probably use the B<cancel> method instead.
  93
  94 =item cancel
  95
  96 Cancels the relevant service by calling the B<cancel> method of the associated
  97 FS::svc_XXX object (i.e. an FS::svc_acct object or FS::svc_domain object),
  98 deleting the FS::svc_XXX record and then deleting this record.
  99
 100 If there is an error, returns the error, otherwise returns false.
 101
 102 =cut
 103
 104 sub cancel {
 105   my $self = shift;
 106
 107   local $SIG{HUP} = 'IGNORE';
 108   local $SIG{INT} = 'IGNORE';
 109   local $SIG{QUIT} = 'IGNORE';
 110   local $SIG{TERM} = 'IGNORE';
 111   local $SIG{TSTP} = 'IGNORE';
 112   local $SIG{PIPE} = 'IGNORE';
 113
 114   my $oldAutoCommit = $FS::UID::AutoCommit;
 115   local $FS::UID::AutoCommit = 0;
 116   my $dbh = dbh;
 117
 118   my $part_svc = $self->part_svc;
 119
 120   $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
 121     $dbh->rollback if $oldAutoCommit;
 122     return "Illegal svcdb value in part_svc!";
 123   };
 124   my $svcdb = $1;
 125   require "FS/$svcdb.pm";
 126
 127   my $svc = $self->svc_x;
 128   if ($svc) {
 129     my $error = $svc->cancel;
 130     if ( $error ) {
 131       $dbh->rollback if $oldAutoCommit;
 132       return "Error canceling service: $error";
 133     }
 134     $error = $svc->delete;
 135     if ( $error ) {
 136       $dbh->rollback if $oldAutoCommit;
 137       return "Error deleting service: $error";
 138     }
 139   }
 140
 141   my $error = $self->delete;
 142   if ( $error ) {
 143     $dbh->rollback if $oldAutoCommit;
 144     return "Error deleting cust_svc: $error";
 145   }
 146
 147   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 148
 149   ''; #no errors
 150
 151 }
 152
 153 =item replace OLD_RECORD
 154
 155 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 156 returns the error, otherwise returns false.
 157
 158 =cut
 159
 160 sub replace {
 161   my ( $new, $old ) = ( shift, shift );
 162
 163   local $SIG{HUP} = 'IGNORE';
 164   local $SIG{INT} = 'IGNORE';
 165   local $SIG{QUIT} = 'IGNORE';
 166   local $SIG{TERM} = 'IGNORE';
 167   local $SIG{TSTP} = 'IGNORE';
 168   local $SIG{PIPE} = 'IGNORE';
 169
 170   my $oldAutoCommit = $FS::UID::AutoCommit;
 171   local $FS::UID::AutoCommit = 0;
 172   my $dbh = dbh;
 173
 174   my $error = $new->SUPER::replace($old);
 175   if ( $error ) {
 176     $dbh->rollback if $oldAutoCommit;
 177     return $error if $error;
 178   }
 179
 180   if ( $new->svcpart != $old->svcpart ) {
 181     my $svc_x = $new->svc_x;
 182     my $new_svc_x = ref($svc_x)->new({$svc_x->hash});
 183     my $error = $new_svc_x->replace($svc_x);
 184     if ( $error ) {
 185       $dbh->rollback if $oldAutoCommit;
 186       return $error if $error;
 187     }
 188   }
 189
 190   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 191   ''; #no error
 192
 193 }
 194
 195 =item check
 196
 197 Checks all fields to make sure this is a valid service.  If there is an error,
 198 returns the error, otehrwise returns false.  Called by the insert and
 199 replace methods.
 200
 201 =cut
 202
 203 sub check {
 204   my $self = shift;
 205
 206   my $error =
 207     $self->ut_numbern('svcnum')
 208     || $self->ut_numbern('pkgnum')
 209     || $self->ut_number('svcpart')
 210   ;
 211   return $error if $error;
 212
 213   my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
 214   return "Unknown svcpart" unless $part_svc;
 215
 216   if ( $self->pkgnum ) {
 217     my $cust_pkg = qsearchs( 'cust_pkg', { 'pkgnum' => $self->pkgnum } );
 218     return "Unknown pkgnum" unless $cust_pkg;
 219     my $pkg_svc = qsearchs( 'pkg_svc', {
 220       'pkgpart' => $cust_pkg->pkgpart,
 221       'svcpart' => $self->svcpart,
 222     });
 223     # or new FS::pkg_svc ( { 'pkgpart'  => $cust_pkg->pkgpart,
 224     #                        'svcpart'  => $self->svcpart,
 225     #                        'quantity' => 0                   } );
 226     my $quantity = $pkg_svc ? $pkg_svc->quantity : 0;
 227
 228     my @cust_svc = qsearch('cust_svc', {
 229       'pkgnum'  => $self->pkgnum,
 230       'svcpart' => $self->svcpart,
 231     });
 232     return "Already ". scalar(@cust_svc). " ". $part_svc->svc.
 233            " services for pkgnum ". $self->pkgnum
 234       if scalar(@cust_svc) >= $quantity && !$ignore_quantity;
 235   }
 236
 237   $self->SUPER::check;
 238 }
 239
 240 =item part_svc
 241
 242 Returns the definition for this service, as a FS::part_svc object (see
 243 L<FS::part_svc>).
 244
 245 =cut
 246
 247 sub part_svc {
 248   my $self = shift;
 249   $self->{'_svcpart'}
 250     ? $self->{'_svcpart'}
 251     : qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
 252 }
 253
 254 =item cust_pkg
 255
 256 Returns the definition for this service, as a FS::part_svc object (see
 257 L<FS::part_svc>).
 258
 259 =cut
 260
 261 sub cust_pkg {
 262   my $self = shift;
 263   qsearchs( 'cust_pkg', { 'pkgnum' => $self->pkgnum } );
 264 }
 265
 266 =item label
 267
 268 Returns a list consisting of:
 269 - The name of this service (from part_svc)
 270 - A meaningful identifier (username, domain, or mail alias)
 271 - The table name (i.e. svc_domain) for this service
 272
 273 =cut
 274
 275 sub label {
 276   my $self = shift;
 277   my $svcdb = $self->part_svc->svcdb;
 278   my $svc_x = $self->svc_x
 279     or die "can't find $svcdb.svcnum ". $self->svcnum;
 280   my $tag;
 281   if ( $svcdb eq 'svc_acct' ) {
 282     $tag = $svc_x->email;
 283   } elsif ( $svcdb eq 'svc_forward' ) {
 284     if ( $svc_x->srcsvc ) {
 285       my $svc_acct = $svc_x->srcsvc_acct;
 286       $tag = $svc_acct->email;
 287     } else {
 288       $tag = $svc_x->src;
 289     }
 290     $tag .= '->';
 291     if ( $svc_x->dstsvc ) {
 292       my $svc_acct = $svc_x->dstsvc_acct;
 293       $tag .= $svc_acct->email;
 294     } else {
 295       $tag .= $svc_x->dst;
 296     }
 297   } elsif ( $svcdb eq 'svc_domain' ) {
 298     $tag = $svc_x->getfield('domain');
 299   } elsif ( $svcdb eq 'svc_www' ) {
 300     my $domain = qsearchs( 'domain_record', { 'recnum' => $svc_x->recnum } );
 301     $tag = $domain->zone;
 302   } elsif ( $svcdb eq 'svc_broadband' ) {
 303     $tag = $svc_x->ip_addr;
 304   } elsif ( $svcdb eq 'svc_external' ) {
 305     $tag = $svc_x->id. ': '. $svc_x->title;
 306   } else {
 307     cluck "warning: asked for label of unsupported svcdb; using svcnum";
 308     $tag = $svc_x->getfield('svcnum');
 309   }
 310   $self->part_svc->svc, $tag, $svcdb;
 311 }
 312
 313 =item svc_x
 314
 315 Returns the FS::svc_XXX object for this service (i.e. an FS::svc_acct object or
 316 FS::svc_domain object, etc.)
 317
 318 =cut
 319
 320 sub svc_x {
 321   my $self = shift;
 322   my $svcdb = $self->part_svc->svcdb;
 323   if ( $svcdb eq 'svc_acct' && $self->{'_svc_acct'} ) {
 324     $self->{'_svc_acct'};
 325   } else {
 326     qsearchs( $svcdb, { 'svcnum' => $self->svcnum } );
 327   }
 328 }
 329
 330 =item seconds_since TIMESTAMP
 331
 332 See L<FS::svc_acct/seconds_since>.  Equivalent to
 333 $cust_svc->svc_x->seconds_since, but more efficient.  Meaningless for records
 334 where B<svcdb> is not "svc_acct".
 335
 336 =cut
 337
 338 #note: implementation here, POD in FS::svc_acct
 339 sub seconds_since {
 340   my($self, $since) = @_;
 341   my $dbh = dbh;
 342   my $sth = $dbh->prepare(' SELECT SUM(logout-login) FROM session
 343                               WHERE svcnum = ?
 344                                 AND login >= ?
 345                                 AND logout IS NOT NULL'
 346   ) or die $dbh->errstr;
 347   $sth->execute($self->svcnum, $since) or die $sth->errstr;
 348   $sth->fetchrow_arrayref->[0];
 349 }
 350
 351 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
 352
 353 See L<FS::svc_acct/seconds_since_sqlradacct>.  Equivalent to
 354 $cust_svc->svc_x->seconds_since_sqlradacct, but more efficient.  Meaningless
 355 for records where B<svcdb> is not "svc_acct".
 356
 357 =cut
 358
 359 #note: implementation here, POD in FS::svc_acct
 360 sub seconds_since_sqlradacct {
 361   my($self, $start, $end) = @_;
 362
 363   my $svc_x = $self->svc_x;
 364
 365   my @part_export = $self->part_svc->part_export('sqlradius');
 366   push @part_export, $self->part_svc->part_export('sqlradius_withdomain');
 367   die "no sqlradius or sqlradius_withdomain export configured for this".
 368       "service type"
 369     unless @part_export;
 370     #or return undef;
 371
 372   my $seconds = 0;
 373   foreach my $part_export ( @part_export ) {
 374
 375     next if $part_export->option('ignore_accounting');
 376
 377     my $dbh = DBI->connect( map { $part_export->option($_) }
 378                             qw(datasrc username password)    )
 379       or die "can't connect to sqlradius database: ". $DBI::errstr;
 380
 381     #select a unix time conversion function based on database type
 382     my $str2time;
 383     if ( $dbh->{Driver}->{Name} =~ /^mysql(PP)?$/ ) {
 384       $str2time = 'UNIX_TIMESTAMP(';
 385     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 386       $str2time = 'EXTRACT( EPOCH FROM ';
 387     } else {
 388       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 389            "; guessing how to convert to UNIX timestamps";
 390       $str2time = 'extract(epoch from ';
 391     }
 392
 393     my $username;
 394     if ( $part_export->exporttype eq 'sqlradius' ) {
 395       $username = $svc_x->username;
 396     } elsif ( $part_export->exporttype eq 'sqlradius_withdomain' ) {
 397       $username = $svc_x->email;
 398     } else {
 399       die 'unknown exporttype '. $part_export->exporttype;
 400     }
 401
 402     my $query;
 403
 404     #find closed sessions completely within the given range
 405     my $sth = $dbh->prepare("SELECT SUM(acctsessiontime)
 406                                FROM radacct
 407                                WHERE UserName = ?
 408                                  AND $str2time AcctStartTime) >= ?
 409                                  AND $str2time AcctStopTime ) <  ?
 410                                  AND $str2time AcctStopTime ) > 0
 411                                  AND AcctStopTime IS NOT NULL"
 412     ) or die $dbh->errstr;
 413     $sth->execute($username, $start, $end) or die $sth->errstr;
 414     my $regular = $sth->fetchrow_arrayref->[0];
 415
 416     #find open sessions which start in the range, count session start->range end
 417     $query = "SELECT SUM( ? - $str2time AcctStartTime ) )
 418                 FROM radacct
 419                 WHERE UserName = ?
 420                   AND $str2time AcctStartTime ) >= ?
 421                   AND $str2time AcctStartTime ) <  ?
 422                   AND ( ? - $str2time AcctStartTime ) ) < 86400
 423                   AND (    $str2time AcctStopTime ) = 0
 424                                     OR AcctStopTime IS NULL )";
 425     $sth = $dbh->prepare($query) or die $dbh->errstr;
 426     $sth->execute($end, $username, $start, $end, $end)
 427       or die $sth->errstr. " executing query $query";
 428     my $start_during = $sth->fetchrow_arrayref->[0];
 429
 430     #find closed sessions which start before the range but stop during,
 431     #count range start->session end
 432     $sth = $dbh->prepare("SELECT SUM( $str2time AcctStopTime ) - ? )
 433                             FROM radacct
 434                             WHERE UserName = ?
 435                               AND $str2time AcctStartTime ) < ?
 436                               AND $str2time AcctStopTime  ) >= ?
 437                               AND $str2time AcctStopTime  ) <  ?
 438                               AND $str2time AcctStopTime ) > 0
 439                               AND AcctStopTime IS NOT NULL"
 440     ) or die $dbh->errstr;
 441     $sth->execute($start, $username, $start, $start, $end ) or die $sth->errstr;
 442     my $end_during = $sth->fetchrow_arrayref->[0];
 443
 444     #find closed (not anymore - or open) sessions which start before the range
 445     # but stop after, or are still open, count range start->range end
 446     # don't count open sessions (probably missing stop record)
 447     $sth = $dbh->prepare("SELECT COUNT(*)
 448                             FROM radacct
 449                             WHERE UserName = ?
 450                               AND $str2time AcctStartTime ) < ?
 451                               AND ( $str2time AcctStopTime ) >= ?
 452                                                                   )"
 453                               #      OR AcctStopTime =  0
 454                               #      OR AcctStopTime IS NULL       )"
 455     ) or die $dbh->errstr;
 456     $sth->execute($username, $start, $end ) or die $sth->errstr;
 457     my $entire_range = ($end-$start) * $sth->fetchrow_arrayref->[0];
 458
 459     $seconds += $regular + $end_during + $start_during + $entire_range;
 460
 461   }
 462
 463   $seconds;
 464
 465 }
 466
 467 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
 468
 469 See L<FS::svc_acct/attribute_since_sqlradacct>.  Equivalent to
 470 $cust_svc->svc_x->attribute_since_sqlradacct, but more efficient.  Meaningless
 471 for records where B<svcdb> is not "svc_acct".
 472
 473 =cut
 474
 475 #note: implementation here, POD in FS::svc_acct
 476 #(false laziness w/seconds_since_sqlradacct above)
 477 sub attribute_since_sqlradacct {
 478   my($self, $start, $end, $attrib) = @_;
 479
 480   my $svc_x = $self->svc_x;
 481
 482   my @part_export = $self->part_svc->part_export('sqlradius');
 483   push @part_export, $self->part_svc->part_export('sqlradius_withdomain');
 484   die "no sqlradius or sqlradius_withdomain export configured for this".
 485       "service type"
 486     unless @part_export;
 487     #or return undef;
 488
 489   my $sum = 0;
 490
 491   foreach my $part_export ( @part_export ) {
 492
 493     next if $part_export->option('ignore_accounting');
 494
 495     my $dbh = DBI->connect( map { $part_export->option($_) }
 496                             qw(datasrc username password)    )
 497       or die "can't connect to sqlradius database: ". $DBI::errstr;
 498
 499     #select a unix time conversion function based on database type
 500     my $str2time;
 501     if ( $dbh->{Driver}->{Name} =~ /^mysql(PP)?$/ ) {
 502       $str2time = 'UNIX_TIMESTAMP(';
 503     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 504       $str2time = 'EXTRACT( EPOCH FROM ';
 505     } else {
 506       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 507            "; guessing how to convert to UNIX timestamps";
 508       $str2time = 'extract(epoch from ';
 509     }
 510
 511     my $username;
 512     if ( $part_export->exporttype eq 'sqlradius' ) {
 513       $username = $svc_x->username;
 514     } elsif ( $part_export->exporttype eq 'sqlradius_withdomain' ) {
 515       $username = $svc_x->email;
 516     } else {
 517       die 'unknown exporttype '. $part_export->exporttype;
 518     }
 519
 520     my $sth = $dbh->prepare("SELECT SUM($attrib)
 521                                FROM radacct
 522                                WHERE UserName = ?
 523                                  AND $str2time AcctStopTime ) >= ?
 524                                  AND $str2time AcctStopTime ) <  ?
 525                                  AND AcctStopTime IS NOT NULL"
 526     ) or die $dbh->errstr;
 527     $sth->execute($username, $start, $end) or die $sth->errstr;
 528
 529     $sum += $sth->fetchrow_arrayref->[0];
 530
 531   }
 532
 533   $sum;
 534
 535 }
 536
 537 =item get_session_history_sqlradacct TIMESTAMP_START TIMESTAMP_END
 538
 539 See L<FS::svc_acct/get_session_history_sqlradacct>.  Equivalent to
 540 $cust_svc->svc_x->get_session_history_sqlradacct, but more efficient.
 541 Meaningless for records where B<svcdb> is not "svc_acct".
 542
 543 =cut
 544
 545 sub get_session_history {
 546   my($self, $start, $end, $attrib) = @_;
 547
 548   my $username = $self->svc_x->username;
 549
 550   my @part_export = $self->part_svc->part_export('sqlradius')
 551     or die "no sqlradius export configured for this service type";
 552     #or return undef;
 553
 554   my @sessions = ();
 555
 556   foreach my $part_export ( @part_export ) {
 557
 558     my $dbh = DBI->connect( map { $part_export->option($_) }
 559                             qw(datasrc username password)    )
 560       or die "can't connect to sqlradius database: ". $DBI::errstr;
 561
 562     #select a unix time conversion function based on database type
 563     my $str2time;
 564     if ( $dbh->{Driver}->{Name} =~ /^mysql(PP)?$/ ) {
 565       $str2time = 'UNIX_TIMESTAMP(';
 566     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 567       $str2time = 'EXTRACT( EPOCH FROM ';
 568     } else {
 569       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 570            "; guessing how to convert to UNIX timestamps";
 571       $str2time = 'extract(epoch from ';
 572     }
 573
 574     my @fields = qw( acctstarttime acctstoptime acctsessiontime
 575                      acctinputoctets acctoutputoctets framedipaddress );
 576
 577     my $sth = $dbh->prepare('SELECT '. join(', ', @fields).
 578                             "  FROM radacct
 579                                WHERE UserName = ?
 580                                  AND $str2time AcctStopTime ) >= ?
 581                                  AND $str2time AcctStopTime ) <=  ?
 582                                  ORDER BY AcctStartTime DESC
 583     ") or die $dbh->errstr;
 584     $sth->execute($username, $start, $end) or die $sth->errstr;
 585
 586     push @sessions, map { { %$_ } } @{ $sth->fetchall_arrayref({}) };
 587
 588   }
 589   \@sessions
 590
 591 }
 592
 593 =back
 594
 595 =head1 BUGS
 596
 597 Behaviour of changing the svcpart of cust_svc records is undefined and should
 598 possibly be prohibited, and pkg_svc records are not checked.
 599
 600 pkg_svc records are not checked in general (here).
 601
 602 Deleting this record doesn't check or delete the svc_* record associated
 603 with this record.
 604
 605 In seconds_since_sqlradacct, specifying a DATASRC/USERNAME/PASSWORD instead of
 606 a DBI database handle is not yet implemented.
 607
 608 =head1 SEE ALSO
 609
 610 L<FS::Record>, L<FS::cust_pkg>, L<FS::part_svc>, L<FS::pkg_svc>,
 611 schema.html from the base documentation
 612
 613 =cut
 614
 615 1;
 616