FS/FS/cust_svc.pm

   1 package FS::cust_svc;
   2
   3 use strict;
   4 use vars qw( @ISA $ignore_quantity );
   5 use Carp qw( cluck );
   6 use FS::Record qw( qsearch qsearchs dbh );
   7 use FS::cust_pkg;
   8 use FS::part_pkg;
   9 use FS::part_svc;
  10 use FS::pkg_svc;
  11 use FS::svc_acct;
  12 use FS::svc_domain;
  13 use FS::svc_forward;
  14 use FS::svc_broadband;
  15 use FS::domain_record;
  16 use FS::part_export;
  17
  18 @ISA = qw( FS::Record );
  19
  20 $ignore_quantity = 0;
  21
  22 sub _cache {
  23   my $self = shift;
  24   my ( $hashref, $cache ) = @_;
  25   if ( $hashref->{'username'} ) {
  26     $self->{'_svc_acct'} = FS::svc_acct->new($hashref, '');
  27   }
  28   if ( $hashref->{'svc'} ) {
  29     $self->{'_svcpart'} = FS::part_svc->new($hashref);
  30   }
  31 }
  32
  33 =head1 NAME
  34
  35 FS::cust_svc - Object method for cust_svc objects
  36
  37 =head1 SYNOPSIS
  38
  39   use FS::cust_svc;
  40
  41   $record = new FS::cust_svc \%hash
  42   $record = new FS::cust_svc { 'column' => 'value' };
  43
  44   $error = $record->insert;
  45
  46   $error = $new_record->replace($old_record);
  47
  48   $error = $record->delete;
  49
  50   $error = $record->check;
  51
  52   ($label, $value) = $record->label;
  53
  54 =head1 DESCRIPTION
  55
  56 An FS::cust_svc represents a service.  FS::cust_svc inherits from FS::Record.
  57 The following fields are currently supported:
  58
  59 =over 4
  60
  61 =item svcnum - primary key (assigned automatically for new services)
  62
  63 =item pkgnum - Package (see L<FS::cust_pkg>)
  64
  65 =item svcpart - Service definition (see L<FS::part_svc>)
  66
  67 =back
  68
  69 =head1 METHODS
  70
  71 =over 4
  72
  73 =item new HASHREF
  74
  75 Creates a new service.  To add the refund to the database, see L<"insert">.
  76 Services are normally created by creating FS::svc_ objects (see
  77 L<FS::svc_acct>, L<FS::svc_domain>, and L<FS::svc_forward>, among others).
  78
  79 =cut
  80
  81 sub table { 'cust_svc'; }
  82
  83 =item insert
  84
  85 Adds this service to the database.  If there is an error, returns the error,
  86 otherwise returns false.
  87
  88 =item delete
  89
  90 Deletes this service from the database.  If there is an error, returns the
  91 error, otherwise returns false.  Note that this only removes the cust_svc
  92 record - you should probably use the B<cancel> method instead.
  93
  94 =item cancel
  95
  96 Cancels the relevant service by calling the B<cancel> method of the associated
  97 FS::svc_XXX object (i.e. an FS::svc_acct object or FS::svc_domain object),
  98 deleting the FS::svc_XXX record and then deleting this record.
  99
 100 If there is an error, returns the error, otherwise returns false.
 101
 102 =cut
 103
 104 sub cancel {
 105   my $self = shift;
 106
 107   local $SIG{HUP} = 'IGNORE';
 108   local $SIG{INT} = 'IGNORE';
 109   local $SIG{QUIT} = 'IGNORE';
 110   local $SIG{TERM} = 'IGNORE';
 111   local $SIG{TSTP} = 'IGNORE';
 112   local $SIG{PIPE} = 'IGNORE';
 113
 114   my $oldAutoCommit = $FS::UID::AutoCommit;
 115   local $FS::UID::AutoCommit = 0;
 116   my $dbh = dbh;
 117
 118   my $part_svc = $self->part_svc;
 119
 120   $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
 121     $dbh->rollback if $oldAutoCommit;
 122     return "Illegal svcdb value in part_svc!";
 123   };
 124   my $svcdb = $1;
 125   require "FS/$svcdb.pm";
 126
 127   my $svc = $self->svc_x;
 128   if ($svc) {
 129     my $error = $svc->cancel;
 130     if ( $error ) {
 131       $dbh->rollback if $oldAutoCommit;
 132       return "Error canceling service: $error";
 133     }
 134     $error = $svc->delete;
 135     if ( $error ) {
 136       $dbh->rollback if $oldAutoCommit;
 137       return "Error deleting service: $error";
 138     }
 139   }
 140
 141   my $error = $self->delete;
 142   if ( $error ) {
 143     $dbh->rollback if $oldAutoCommit;
 144     return "Error deleting cust_svc: $error";
 145   }
 146
 147   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 148
 149   ''; #no errors
 150
 151 }
 152
 153 =item replace OLD_RECORD
 154
 155 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 156 returns the error, otherwise returns false.
 157
 158 =cut
 159
 160 sub replace {
 161   my ( $new, $old ) = ( shift, shift );
 162
 163   local $SIG{HUP} = 'IGNORE';
 164   local $SIG{INT} = 'IGNORE';
 165   local $SIG{QUIT} = 'IGNORE';
 166   local $SIG{TERM} = 'IGNORE';
 167   local $SIG{TSTP} = 'IGNORE';
 168   local $SIG{PIPE} = 'IGNORE';
 169
 170   my $oldAutoCommit = $FS::UID::AutoCommit;
 171   local $FS::UID::AutoCommit = 0;
 172   my $dbh = dbh;
 173
 174   my $error = $new->SUPER::replace($old);
 175   if ( $error ) {
 176     $dbh->rollback if $oldAutoCommit;
 177     return $error if $error;
 178   }
 179
 180   if ( $new->svcpart != $old->svcpart ) {
 181     my $svc_x = $new->svc_x;
 182     my $new_svc_x = ref($svc_x)->new({$svc_x->hash});
 183     my $error = $new_svc_x->replace($svc_x);
 184     if ( $error ) {
 185       $dbh->rollback if $oldAutoCommit;
 186       return $error if $error;
 187     }
 188   }
 189
 190   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 191   ''; #no error
 192
 193 }
 194
 195 =item check
 196
 197 Checks all fields to make sure this is a valid service.  If there is an error,
 198 returns the error, otehrwise returns false.  Called by the insert and
 199 replace methods.
 200
 201 =cut
 202
 203 sub check {
 204   my $self = shift;
 205
 206   my $error =
 207     $self->ut_numbern('svcnum')
 208     || $self->ut_numbern('pkgnum')
 209     || $self->ut_number('svcpart')
 210   ;
 211   return $error if $error;
 212
 213   my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
 214   return "Unknown svcpart" unless $part_svc;
 215
 216   if ( $self->pkgnum ) {
 217     my $cust_pkg = qsearchs( 'cust_pkg', { 'pkgnum' => $self->pkgnum } );
 218     return "Unknown pkgnum" unless $cust_pkg;
 219     my $pkg_svc = qsearchs( 'pkg_svc', {
 220       'pkgpart' => $cust_pkg->pkgpart,
 221       'svcpart' => $self->svcpart,
 222     });
 223     # or new FS::pkg_svc ( { 'pkgpart'  => $cust_pkg->pkgpart,
 224     #                        'svcpart'  => $self->svcpart,
 225     #                        'quantity' => 0                   } );
 226     my $quantity = $pkg_svc ? $pkg_svc->quantity : 0;
 227
 228     my @cust_svc = qsearch('cust_svc', {
 229       'pkgnum'  => $self->pkgnum,
 230       'svcpart' => $self->svcpart,
 231     });
 232     return "Already ". scalar(@cust_svc). " ". $part_svc->svc.
 233            " services for pkgnum ". $self->pkgnum
 234       if scalar(@cust_svc) >= $quantity && !$ignore_quantity;
 235   }
 236
 237   $self->SUPER::check;
 238 }
 239
 240 =item part_svc
 241
 242 Returns the definition for this service, as a FS::part_svc object (see
 243 L<FS::part_svc>).
 244
 245 =cut
 246
 247 sub part_svc {
 248   my $self = shift;
 249   $self->{'_svcpart'}
 250     ? $self->{'_svcpart'}
 251     : qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
 252 }
 253
 254 =item cust_pkg
 255
 256 Returns the definition for this service, as a FS::part_svc object (see
 257 L<FS::part_svc>).
 258
 259 =cut
 260
 261 sub cust_pkg {
 262   my $self = shift;
 263   qsearchs( 'cust_pkg', { 'pkgnum' => $self->pkgnum } );
 264 }
 265
 266 =item label
 267
 268 Returns a list consisting of:
 269 - The name of this service (from part_svc)
 270 - A meaningful identifier (username, domain, or mail alias)
 271 - The table name (i.e. svc_domain) for this service
 272
 273 =cut
 274
 275 sub label {
 276   my $self = shift;
 277   my $svcdb = $self->part_svc->svcdb;
 278   my $svc_x = $self->svc_x
 279     or die "can't find $svcdb.svcnum ". $self->svcnum;
 280   my $tag;
 281   if ( $svcdb eq 'svc_acct' ) {
 282     $tag = $svc_x->email;
 283   } elsif ( $svcdb eq 'svc_forward' ) {
 284     my $svc_acct = qsearchs( 'svc_acct', { 'svcnum' => $svc_x->srcsvc } );
 285     $tag = $svc_acct->email. '->';
 286     if ( $svc_x->dstsvc ) {
 287       $svc_acct = qsearchs( 'svc_acct', { 'svcnum' => $svc_x->dstsvc } );
 288       $tag .= $svc_acct->email;
 289     } else {
 290       $tag .= $svc_x->dst;
 291     }
 292   } elsif ( $svcdb eq 'svc_domain' ) {
 293     $tag = $svc_x->getfield('domain');
 294   } elsif ( $svcdb eq 'svc_www' ) {
 295     my $domain = qsearchs( 'domain_record', { 'recnum' => $svc_x->recnum } );
 296     $tag = $domain->zone;
 297   } elsif ( $svcdb eq 'svc_broadband' ) {
 298     $tag = $svc_x->ip_addr;
 299   } else {
 300     cluck "warning: asked for label of unsupported svcdb; using svcnum";
 301     $tag = $svc_x->getfield('svcnum');
 302   }
 303   $self->part_svc->svc, $tag, $svcdb;
 304 }
 305
 306 =item svc_x
 307
 308 Returns the FS::svc_XXX object for this service (i.e. an FS::svc_acct object or
 309 FS::svc_domain object, etc.)
 310
 311 =cut
 312
 313 sub svc_x {
 314   my $self = shift;
 315   my $svcdb = $self->part_svc->svcdb;
 316   if ( $svcdb eq 'svc_acct' && $self->{'_svc_acct'} ) {
 317     $self->{'_svc_acct'};
 318   } else {
 319     qsearchs( $svcdb, { 'svcnum' => $self->svcnum } );
 320   }
 321 }
 322
 323 =item seconds_since TIMESTAMP
 324
 325 See L<FS::svc_acct/seconds_since>.  Equivalent to
 326 $cust_svc->svc_x->seconds_since, but more efficient.  Meaningless for records
 327 where B<svcdb> is not "svc_acct".
 328
 329 =cut
 330
 331 #note: implementation here, POD in FS::svc_acct
 332 sub seconds_since {
 333   my($self, $since) = @_;
 334   my $dbh = dbh;
 335   my $sth = $dbh->prepare(' SELECT SUM(logout-login) FROM session
 336                               WHERE svcnum = ?
 337                                 AND login >= ?
 338                                 AND logout IS NOT NULL'
 339   ) or die $dbh->errstr;
 340   $sth->execute($self->svcnum, $since) or die $sth->errstr;
 341   $sth->fetchrow_arrayref->[0];
 342 }
 343
 344 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
 345
 346 See L<FS::svc_acct/seconds_since_sqlradacct>.  Equivalent to
 347 $cust_svc->svc_x->seconds_since_sqlradacct, but more efficient.  Meaningless
 348 for records where B<svcdb> is not "svc_acct".
 349
 350 =cut
 351
 352 #note: implementation here, POD in FS::svc_acct
 353 sub seconds_since_sqlradacct {
 354   my($self, $start, $end) = @_;
 355
 356   my $username = $self->svc_x->username;
 357
 358   my @part_export = $self->part_svc->part_export('sqlradius')
 359     or die "no sqlradius export configured for this service type";
 360     #or return undef;
 361
 362   my $seconds = 0;
 363   foreach my $part_export ( @part_export ) {
 364
 365     my $dbh = DBI->connect( map { $part_export->option($_) }
 366                             qw(datasrc username password)    )
 367       or die "can't connect to sqlradius database: ". $DBI::errstr;
 368
 369     #select a unix time conversion function based on database type
 370     my $str2time;
 371     if ( $dbh->{Driver}->{Name} eq 'mysql' ) {
 372       $str2time = 'UNIX_TIMESTAMP(';
 373     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 374       $str2time = 'EXTRACT( EPOCH FROM ';
 375     } else {
 376       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 377            "; guessing how to convert to UNIX timestamps";
 378       $str2time = 'extract(epoch from ';
 379     }
 380
 381     my $query;
 382
 383     #find closed sessions completely within the given range
 384     my $sth = $dbh->prepare("SELECT SUM(acctsessiontime)
 385                                FROM radacct
 386                                WHERE UserName = ?
 387                                  AND $str2time AcctStartTime) >= ?
 388                                  AND $str2time AcctStopTime ) <  ?
 389                                  AND $str2time AcctStopTime ) > 0
 390                                  AND AcctStopTime IS NOT NULL"
 391     ) or die $dbh->errstr;
 392     $sth->execute($username, $start, $end) or die $sth->errstr;
 393     my $regular = $sth->fetchrow_arrayref->[0];
 394
 395     #find open sessions which start in the range, count session start->range end
 396     $query = "SELECT SUM( ? - $str2time AcctStartTime ) )
 397                 FROM radacct
 398                 WHERE UserName = ?
 399                   AND $str2time AcctStartTime ) >= ?
 400                   AND $str2time AcctStartTime ) <  ?
 401                   AND ( ? - $str2time AcctStartTime ) ) < 86400
 402                   AND (    $str2time AcctStopTime ) = 0
 403                                     OR AcctStopTime IS NULL )";
 404     $sth = $dbh->prepare($query) or die $dbh->errstr;
 405     $sth->execute($end, $username, $start, $end, $end)
 406       or die $sth->errstr. " executing query $query";
 407     my $start_during = $sth->fetchrow_arrayref->[0];
 408
 409     #find closed sessions which start before the range but stop during,
 410     #count range start->session end
 411     $sth = $dbh->prepare("SELECT SUM( $str2time AcctStopTime ) - ? )
 412                             FROM radacct
 413                             WHERE UserName = ?
 414                               AND $str2time AcctStartTime ) < ?
 415                               AND $str2time AcctStopTime  ) >= ?
 416                               AND $str2time AcctStopTime  ) <  ?
 417                               AND $str2time AcctStopTime ) > 0
 418                               AND AcctStopTime IS NOT NULL"
 419     ) or die $dbh->errstr;
 420     $sth->execute($start, $username, $start, $start, $end ) or die $sth->errstr;
 421     my $end_during = $sth->fetchrow_arrayref->[0];
 422
 423     #find closed (not anymore - or open) sessions which start before the range
 424     # but stop after, or are still open, count range start->range end
 425     # don't count open sessions (probably missing stop record)
 426     $sth = $dbh->prepare("SELECT COUNT(*)
 427                             FROM radacct
 428                             WHERE UserName = ?
 429                               AND $str2time AcctStartTime ) < ?
 430                               AND ( $str2time AcctStopTime ) >= ?
 431                                                                   )"
 432                               #      OR AcctStopTime =  0
 433                               #      OR AcctStopTime IS NULL       )"
 434     ) or die $dbh->errstr;
 435     $sth->execute($username, $start, $end ) or die $sth->errstr;
 436     my $entire_range = ($end-$start) * $sth->fetchrow_arrayref->[0];
 437
 438     $seconds += $regular + $end_during + $start_during + $entire_range;
 439
 440   }
 441
 442   $seconds;
 443
 444 }
 445
 446 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
 447
 448 See L<FS::svc_acct/attribute_since_sqlradacct>.  Equivalent to
 449 $cust_svc->svc_x->attribute_since_sqlradacct, but more efficient.  Meaningless
 450 for records where B<svcdb> is not "svc_acct".
 451
 452 =cut
 453
 454 #note: implementation here, POD in FS::svc_acct
 455 #(false laziness w/seconds_since_sqlradacct above)
 456 sub attribute_since_sqlradacct {
 457   my($self, $start, $end, $attrib) = @_;
 458
 459   my $username = $self->svc_x->username;
 460
 461   my @part_export = $self->part_svc->part_export('sqlradius')
 462     or die "no sqlradius export configured for this service type";
 463     #or return undef;
 464
 465   my $sum = 0;
 466
 467   foreach my $part_export ( @part_export ) {
 468
 469     my $dbh = DBI->connect( map { $part_export->option($_) }
 470                             qw(datasrc username password)    )
 471       or die "can't connect to sqlradius database: ". $DBI::errstr;
 472
 473     #select a unix time conversion function based on database type
 474     my $str2time;
 475     if ( $dbh->{Driver}->{Name} eq 'mysql' ) {
 476       $str2time = 'UNIX_TIMESTAMP(';
 477     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 478       $str2time = 'EXTRACT( EPOCH FROM ';
 479     } else {
 480       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 481            "; guessing how to convert to UNIX timestamps";
 482       $str2time = 'extract(epoch from ';
 483     }
 484
 485     my $sth = $dbh->prepare("SELECT SUM($attrib)
 486                                FROM radacct
 487                                WHERE UserName = ?
 488                                  AND $str2time AcctStopTime ) >= ?
 489                                  AND $str2time AcctStopTime ) <  ?
 490                                  AND AcctStopTime IS NOT NULL"
 491     ) or die $dbh->errstr;
 492     $sth->execute($username, $start, $end) or die $sth->errstr;
 493
 494     $sum += $sth->fetchrow_arrayref->[0];
 495
 496   }
 497
 498   $sum;
 499
 500 }
 501
 502 =item get_session_history_sqlradacct TIMESTAMP_START TIMESTAMP_END
 503
 504 See L<FS::svc_acct/get_session_history_sqlradacct>.  Equivalent to
 505 $cust_svc->svc_x->get_session_history_sqlradacct, but more efficient.
 506 Meaningless for records where B<svcdb> is not "svc_acct".
 507
 508 =cut
 509
 510 sub get_session_history {
 511   my($self, $start, $end, $attrib) = @_;
 512
 513   my $username = $self->svc_x->username;
 514
 515   my @part_export = $self->part_svc->part_export('sqlradius')
 516     or die "no sqlradius export configured for this service type";
 517     #or return undef;
 518
 519   my @sessions = ();
 520
 521   foreach my $part_export ( @part_export ) {
 522
 523     my $dbh = DBI->connect( map { $part_export->option($_) }
 524                             qw(datasrc username password)    )
 525       or die "can't connect to sqlradius database: ". $DBI::errstr;
 526
 527     #select a unix time conversion function based on database type
 528     my $str2time;
 529     if ( $dbh->{Driver}->{Name} eq 'mysql' ) {
 530       $str2time = 'UNIX_TIMESTAMP(';
 531     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 532       $str2time = 'EXTRACT( EPOCH FROM ';
 533     } else {
 534       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 535            "; guessing how to convert to UNIX timestamps";
 536       $str2time = 'extract(epoch from ';
 537     }
 538
 539     my @fields = qw( acctstarttime acctstoptime acctsessiontime
 540                      acctinputoctets acctoutputoctets framedipaddress );
 541
 542     my $sth = $dbh->prepare('SELECT '. join(', ', @fields).
 543                             "  FROM radacct
 544                                WHERE UserName = ?
 545                                  AND $str2time AcctStopTime ) >= ?
 546                                  AND $str2time AcctStopTime ) <=  ?
 547                                  ORDER BY AcctStartTime DESC
 548     ") or die $dbh->errstr;
 549     $sth->execute($username, $start, $end) or die $sth->errstr;
 550
 551     push @sessions, map { { %$_ } } @{ $sth->fetchall_arrayref({}) };
 552
 553   }
 554   \@sessions
 555
 556 }
 557
 558 =back
 559
 560 =head1 BUGS
 561
 562 Behaviour of changing the svcpart of cust_svc records is undefined and should
 563 possibly be prohibited, and pkg_svc records are not checked.
 564
 565 pkg_svc records are not checked in general (here).
 566
 567 Deleting this record doesn't check or delete the svc_* record associated
 568 with this record.
 569
 570 In seconds_since_sqlradacct, specifying a DATASRC/USERNAME/PASSWORD instead of
 571 a DBI database handle is not yet implemented.
 572
 573 =head1 SEE ALSO
 574
 575 L<FS::Record>, L<FS::cust_pkg>, L<FS::part_svc>, L<FS::pkg_svc>,
 576 schema.html from the base documentation
 577
 578 =cut
 579
 580 1;
 581