FS/FS/cust_svc.pm

   1 package FS::cust_svc;
   2
   3 use strict;
   4 use vars qw( @ISA $ignore_quantity );
   5 use Carp qw( cluck );
   6 use FS::Record qw( qsearch qsearchs dbh );
   7 use FS::cust_pkg;
   8 use FS::part_pkg;
   9 use FS::part_svc;
  10 use FS::pkg_svc;
  11 use FS::svc_acct;
  12 use FS::svc_domain;
  13 use FS::svc_forward;
  14 use FS::svc_broadband;
  15 use FS::domain_record;
  16 use FS::part_export;
  17
  18 @ISA = qw( FS::Record );
  19
  20 $ignore_quantity = 0;
  21
  22 sub _cache {
  23   my $self = shift;
  24   my ( $hashref, $cache ) = @_;
  25   if ( $hashref->{'username'} ) {
  26     $self->{'_svc_acct'} = FS::svc_acct->new($hashref, '');
  27   }
  28   if ( $hashref->{'svc'} ) {
  29     $self->{'_svcpart'} = FS::part_svc->new($hashref);
  30   }
  31 }
  32
  33 =head1 NAME
  34
  35 FS::cust_svc - Object method for cust_svc objects
  36
  37 =head1 SYNOPSIS
  38
  39   use FS::cust_svc;
  40
  41   $record = new FS::cust_svc \%hash
  42   $record = new FS::cust_svc { 'column' => 'value' };
  43
  44   $error = $record->insert;
  45
  46   $error = $new_record->replace($old_record);
  47
  48   $error = $record->delete;
  49
  50   $error = $record->check;
  51
  52   ($label, $value) = $record->label;
  53
  54 =head1 DESCRIPTION
  55
  56 An FS::cust_svc represents a service.  FS::cust_svc inherits from FS::Record.
  57 The following fields are currently supported:
  58
  59 =over 4
  60
  61 =item svcnum - primary key (assigned automatically for new services)
  62
  63 =item pkgnum - Package (see L<FS::cust_pkg>)
  64
  65 =item svcpart - Service definition (see L<FS::part_svc>)
  66
  67 =back
  68
  69 =head1 METHODS
  70
  71 =over 4
  72
  73 =item new HASHREF
  74
  75 Creates a new service.  To add the refund to the database, see L<"insert">.
  76 Services are normally created by creating FS::svc_ objects (see
  77 L<FS::svc_acct>, L<FS::svc_domain>, and L<FS::svc_forward>, among others).
  78
  79 =cut
  80
  81 sub table { 'cust_svc'; }
  82
  83 =item insert
  84
  85 Adds this service to the database.  If there is an error, returns the error,
  86 otherwise returns false.
  87
  88 =item delete
  89
  90 Deletes this service from the database.  If there is an error, returns the
  91 error, otherwise returns false.  Note that this only removes the cust_svc
  92 record - you should probably use the B<cancel> method instead.
  93
  94 =item cancel
  95
  96 Cancels the relevant service by calling the B<cancel> method of the associated
  97 FS::svc_XXX object (i.e. an FS::svc_acct object or FS::svc_domain object),
  98 deleting the FS::svc_XXX record and then deleting this record.
  99
 100 If there is an error, returns the error, otherwise returns false.
 101
 102 =cut
 103
 104 sub cancel {
 105   my $self = shift;
 106
 107   local $SIG{HUP} = 'IGNORE';
 108   local $SIG{INT} = 'IGNORE';
 109   local $SIG{QUIT} = 'IGNORE';
 110   local $SIG{TERM} = 'IGNORE';
 111   local $SIG{TSTP} = 'IGNORE';
 112   local $SIG{PIPE} = 'IGNORE';
 113
 114   my $oldAutoCommit = $FS::UID::AutoCommit;
 115   local $FS::UID::AutoCommit = 0;
 116   my $dbh = dbh;
 117
 118   my $part_svc = $self->part_svc;
 119
 120   $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
 121     $dbh->rollback if $oldAutoCommit;
 122     return "Illegal svcdb value in part_svc!";
 123   };
 124   my $svcdb = $1;
 125   require "FS/$svcdb.pm";
 126
 127   my $svc = $self->svc_x;
 128   if ($svc) {
 129     my $error = $svc->cancel;
 130     if ( $error ) {
 131       $dbh->rollback if $oldAutoCommit;
 132       return "Error canceling service: $error";
 133     }
 134     $error = $svc->delete;
 135     if ( $error ) {
 136       $dbh->rollback if $oldAutoCommit;
 137       return "Error deleting service: $error";
 138     }
 139   }
 140
 141   my $error = $self->delete;
 142   if ( $error ) {
 143     $dbh->rollback if $oldAutoCommit;
 144     return "Error deleting cust_svc: $error";
 145   }
 146
 147   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 148
 149   ''; #no errors
 150
 151 }
 152
 153 =item replace OLD_RECORD
 154
 155 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 156 returns the error, otherwise returns false.
 157
 158 =cut
 159
 160 sub replace {
 161   my ( $new, $old ) = ( shift, shift );
 162
 163   local $SIG{HUP} = 'IGNORE';
 164   local $SIG{INT} = 'IGNORE';
 165   local $SIG{QUIT} = 'IGNORE';
 166   local $SIG{TERM} = 'IGNORE';
 167   local $SIG{TSTP} = 'IGNORE';
 168   local $SIG{PIPE} = 'IGNORE';
 169
 170   my $oldAutoCommit = $FS::UID::AutoCommit;
 171   local $FS::UID::AutoCommit = 0;
 172   my $dbh = dbh;
 173
 174   my $error = $new->SUPER::replace($old);
 175   if ( $error ) {
 176     $dbh->rollback if $oldAutoCommit;
 177     return $error if $error;
 178   }
 179
 180   if ( $new->svcpart != $old->svcpart ) {
 181     my $svc_x = $new->svc_x;
 182     my $new_svc_x = ref($svc_x)->new({$svc_x->hash});
 183     my $error = $new_svc_x->replace($svc_x);
 184     if ( $error ) {
 185       $dbh->rollback if $oldAutoCommit;
 186       return $error if $error;
 187     }
 188   }
 189
 190   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 191   ''; #no error
 192
 193 }
 194
 195 =item check
 196
 197 Checks all fields to make sure this is a valid service.  If there is an error,
 198 returns the error, otehrwise returns false.  Called by the insert and
 199 replace methods.
 200
 201 =cut
 202
 203 sub check {
 204   my $self = shift;
 205
 206   my $error =
 207     $self->ut_numbern('svcnum')
 208     || $self->ut_numbern('pkgnum')
 209     || $self->ut_number('svcpart')
 210   ;
 211   return $error if $error;
 212
 213   my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
 214   return "Unknown svcpart" unless $part_svc;
 215
 216   if ( $self->pkgnum ) {
 217     my $cust_pkg = qsearchs( 'cust_pkg', { 'pkgnum' => $self->pkgnum } );
 218     return "Unknown pkgnum" unless $cust_pkg;
 219     my $pkg_svc = qsearchs( 'pkg_svc', {
 220       'pkgpart' => $cust_pkg->pkgpart,
 221       'svcpart' => $self->svcpart,
 222     });
 223     # or new FS::pkg_svc ( { 'pkgpart'  => $cust_pkg->pkgpart,
 224     #                        'svcpart'  => $self->svcpart,
 225     #                        'quantity' => 0                   } );
 226     my $quantity = $pkg_svc ? $pkg_svc->quantity : 0;
 227
 228     my @cust_svc = qsearch('cust_svc', {
 229       'pkgnum'  => $self->pkgnum,
 230       'svcpart' => $self->svcpart,
 231     });
 232     return "Already ". scalar(@cust_svc). " ". $part_svc->svc.
 233            " services for pkgnum ". $self->pkgnum
 234       if scalar(@cust_svc) >= $quantity && !$ignore_quantity;
 235   }
 236
 237   $self->SUPER::check;
 238 }
 239
 240 =item part_svc
 241
 242 Returns the definition for this service, as a FS::part_svc object (see
 243 L<FS::part_svc>).
 244
 245 =cut
 246
 247 sub part_svc {
 248   my $self = shift;
 249   $self->{'_svcpart'}
 250     ? $self->{'_svcpart'}
 251     : qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
 252 }
 253
 254 =item cust_pkg
 255
 256 Returns the definition for this service, as a FS::part_svc object (see
 257 L<FS::part_svc>).
 258
 259 =cut
 260
 261 sub cust_pkg {
 262   my $self = shift;
 263   qsearchs( 'cust_pkg', { 'pkgnum' => $self->pkgnum } );
 264 }
 265
 266 =item label
 267
 268 Returns a list consisting of:
 269 - The name of this service (from part_svc)
 270 - A meaningful identifier (username, domain, or mail alias)
 271 - The table name (i.e. svc_domain) for this service
 272
 273 =cut
 274
 275 sub label {
 276   my $self = shift;
 277   my $svcdb = $self->part_svc->svcdb;
 278   my $svc_x = $self->svc_x
 279     or die "can't find $svcdb.svcnum ". $self->svcnum;
 280   my $tag;
 281   if ( $svcdb eq 'svc_acct' ) {
 282     $tag = $svc_x->email;
 283   } elsif ( $svcdb eq 'svc_forward' ) {
 284     my $svc_acct = qsearchs( 'svc_acct', { 'svcnum' => $svc_x->srcsvc } );
 285     $tag = $svc_acct->email. '->';
 286     if ( $svc_x->dstsvc ) {
 287       $svc_acct = qsearchs( 'svc_acct', { 'svcnum' => $svc_x->dstsvc } );
 288       $tag .= $svc_acct->email;
 289     } else {
 290       $tag .= $svc_x->dst;
 291     }
 292   } elsif ( $svcdb eq 'svc_domain' ) {
 293     $tag = $svc_x->getfield('domain');
 294   } elsif ( $svcdb eq 'svc_www' ) {
 295     my $domain = qsearchs( 'domain_record', { 'recnum' => $svc_x->recnum } );
 296     $tag = $domain->zone;
 297   } elsif ( $svcdb eq 'svc_broadband' ) {
 298     $tag = $svc_x->ip_addr;
 299   } elsif ( $svcdb eq 'svc_external' ) {
 300     $tag = $svc_x->id. ': '. $svc_x->title;
 301   } else {
 302     cluck "warning: asked for label of unsupported svcdb; using svcnum";
 303     $tag = $svc_x->getfield('svcnum');
 304   }
 305   $self->part_svc->svc, $tag, $svcdb;
 306 }
 307
 308 =item svc_x
 309
 310 Returns the FS::svc_XXX object for this service (i.e. an FS::svc_acct object or
 311 FS::svc_domain object, etc.)
 312
 313 =cut
 314
 315 sub svc_x {
 316   my $self = shift;
 317   my $svcdb = $self->part_svc->svcdb;
 318   if ( $svcdb eq 'svc_acct' && $self->{'_svc_acct'} ) {
 319     $self->{'_svc_acct'};
 320   } else {
 321     qsearchs( $svcdb, { 'svcnum' => $self->svcnum } );
 322   }
 323 }
 324
 325 =item seconds_since TIMESTAMP
 326
 327 See L<FS::svc_acct/seconds_since>.  Equivalent to
 328 $cust_svc->svc_x->seconds_since, but more efficient.  Meaningless for records
 329 where B<svcdb> is not "svc_acct".
 330
 331 =cut
 332
 333 #note: implementation here, POD in FS::svc_acct
 334 sub seconds_since {
 335   my($self, $since) = @_;
 336   my $dbh = dbh;
 337   my $sth = $dbh->prepare(' SELECT SUM(logout-login) FROM session
 338                               WHERE svcnum = ?
 339                                 AND login >= ?
 340                                 AND logout IS NOT NULL'
 341   ) or die $dbh->errstr;
 342   $sth->execute($self->svcnum, $since) or die $sth->errstr;
 343   $sth->fetchrow_arrayref->[0];
 344 }
 345
 346 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
 347
 348 See L<FS::svc_acct/seconds_since_sqlradacct>.  Equivalent to
 349 $cust_svc->svc_x->seconds_since_sqlradacct, but more efficient.  Meaningless
 350 for records where B<svcdb> is not "svc_acct".
 351
 352 =cut
 353
 354 #note: implementation here, POD in FS::svc_acct
 355 sub seconds_since_sqlradacct {
 356   my($self, $start, $end) = @_;
 357
 358   my $svc_x = $self->svc_x;
 359
 360   my @part_export = $self->part_svc->part_export('sqlradius');
 361   push @part_export, $self->part_svc->part_export('sqlradius_withdomain');
 362   die "no sqlradius or sqlradius_withdomain export configured for this".
 363       "service type"
 364     unless @part_export;
 365     #or return undef;
 366
 367   my $seconds = 0;
 368   foreach my $part_export ( @part_export ) {
 369
 370     my $dbh = DBI->connect( map { $part_export->option($_) }
 371                             qw(datasrc username password)    )
 372       or die "can't connect to sqlradius database: ". $DBI::errstr;
 373
 374     #select a unix time conversion function based on database type
 375     my $str2time;
 376     if ( $dbh->{Driver}->{Name} eq 'mysql' ) {
 377       $str2time = 'UNIX_TIMESTAMP(';
 378     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 379       $str2time = 'EXTRACT( EPOCH FROM ';
 380     } else {
 381       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 382            "; guessing how to convert to UNIX timestamps";
 383       $str2time = 'extract(epoch from ';
 384     }
 385
 386     my $username;
 387     if ( $part_export->exporttype eq 'sqlradius' ) {
 388       $username = $svc_x->username;
 389     } elsif ( $part_export->exporttype eq 'sqlradius_withdomain' ) {
 390       $username = $svc_x->email;
 391     } else {
 392       die 'unknown exporttype '. $part_export->exporttype;
 393     }
 394
 395     my $query;
 396
 397     #find closed sessions completely within the given range
 398     my $sth = $dbh->prepare("SELECT SUM(acctsessiontime)
 399                                FROM radacct
 400                                WHERE UserName = ?
 401                                  AND $str2time AcctStartTime) >= ?
 402                                  AND $str2time AcctStopTime ) <  ?
 403                                  AND $str2time AcctStopTime ) > 0
 404                                  AND AcctStopTime IS NOT NULL"
 405     ) or die $dbh->errstr;
 406     $sth->execute($username, $start, $end) or die $sth->errstr;
 407     my $regular = $sth->fetchrow_arrayref->[0];
 408
 409     #find open sessions which start in the range, count session start->range end
 410     $query = "SELECT SUM( ? - $str2time AcctStartTime ) )
 411                 FROM radacct
 412                 WHERE UserName = ?
 413                   AND $str2time AcctStartTime ) >= ?
 414                   AND $str2time AcctStartTime ) <  ?
 415                   AND ( ? - $str2time AcctStartTime ) ) < 86400
 416                   AND (    $str2time AcctStopTime ) = 0
 417                                     OR AcctStopTime IS NULL )";
 418     $sth = $dbh->prepare($query) or die $dbh->errstr;
 419     $sth->execute($end, $username, $start, $end, $end)
 420       or die $sth->errstr. " executing query $query";
 421     my $start_during = $sth->fetchrow_arrayref->[0];
 422
 423     #find closed sessions which start before the range but stop during,
 424     #count range start->session end
 425     $sth = $dbh->prepare("SELECT SUM( $str2time AcctStopTime ) - ? )
 426                             FROM radacct
 427                             WHERE UserName = ?
 428                               AND $str2time AcctStartTime ) < ?
 429                               AND $str2time AcctStopTime  ) >= ?
 430                               AND $str2time AcctStopTime  ) <  ?
 431                               AND $str2time AcctStopTime ) > 0
 432                               AND AcctStopTime IS NOT NULL"
 433     ) or die $dbh->errstr;
 434     $sth->execute($start, $username, $start, $start, $end ) or die $sth->errstr;
 435     my $end_during = $sth->fetchrow_arrayref->[0];
 436
 437     #find closed (not anymore - or open) sessions which start before the range
 438     # but stop after, or are still open, count range start->range end
 439     # don't count open sessions (probably missing stop record)
 440     $sth = $dbh->prepare("SELECT COUNT(*)
 441                             FROM radacct
 442                             WHERE UserName = ?
 443                               AND $str2time AcctStartTime ) < ?
 444                               AND ( $str2time AcctStopTime ) >= ?
 445                                                                   )"
 446                               #      OR AcctStopTime =  0
 447                               #      OR AcctStopTime IS NULL       )"
 448     ) or die $dbh->errstr;
 449     $sth->execute($username, $start, $end ) or die $sth->errstr;
 450     my $entire_range = ($end-$start) * $sth->fetchrow_arrayref->[0];
 451
 452     $seconds += $regular + $end_during + $start_during + $entire_range;
 453
 454   }
 455
 456   $seconds;
 457
 458 }
 459
 460 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
 461
 462 See L<FS::svc_acct/attribute_since_sqlradacct>.  Equivalent to
 463 $cust_svc->svc_x->attribute_since_sqlradacct, but more efficient.  Meaningless
 464 for records where B<svcdb> is not "svc_acct".
 465
 466 =cut
 467
 468 #note: implementation here, POD in FS::svc_acct
 469 #(false laziness w/seconds_since_sqlradacct above)
 470 sub attribute_since_sqlradacct {
 471   my($self, $start, $end, $attrib) = @_;
 472
 473   my $svc_x = $self->svc_x;
 474
 475   my @part_export = $self->part_svc->part_export('sqlradius');
 476   push @part_export, $self->part_svc->part_export('sqlradius_withdomain');
 477   die "no sqlradius or sqlradius_withdomain export configured for this".
 478       "service type"
 479     unless @part_export;
 480     #or return undef;
 481
 482   my $sum = 0;
 483
 484   foreach my $part_export ( @part_export ) {
 485
 486     my $dbh = DBI->connect( map { $part_export->option($_) }
 487                             qw(datasrc username password)    )
 488       or die "can't connect to sqlradius database: ". $DBI::errstr;
 489
 490     #select a unix time conversion function based on database type
 491     my $str2time;
 492     if ( $dbh->{Driver}->{Name} eq 'mysql' ) {
 493       $str2time = 'UNIX_TIMESTAMP(';
 494     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 495       $str2time = 'EXTRACT( EPOCH FROM ';
 496     } else {
 497       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 498            "; guessing how to convert to UNIX timestamps";
 499       $str2time = 'extract(epoch from ';
 500     }
 501
 502     my $username;
 503     if ( $part_export->exporttype eq 'sqlradius' ) {
 504       $username = $svc_x->username;
 505     } elsif ( $part_export->exporttype eq 'sqlradius_withdomain' ) {
 506       $username = $svc_x->email;
 507     } else {
 508       die 'unknown exporttype '. $part_export->exporttype;
 509     }
 510
 511     my $sth = $dbh->prepare("SELECT SUM($attrib)
 512                                FROM radacct
 513                                WHERE UserName = ?
 514                                  AND $str2time AcctStopTime ) >= ?
 515                                  AND $str2time AcctStopTime ) <  ?
 516                                  AND AcctStopTime IS NOT NULL"
 517     ) or die $dbh->errstr;
 518     $sth->execute($username, $start, $end) or die $sth->errstr;
 519
 520     $sum += $sth->fetchrow_arrayref->[0];
 521
 522   }
 523
 524   $sum;
 525
 526 }
 527
 528 =item get_session_history_sqlradacct TIMESTAMP_START TIMESTAMP_END
 529
 530 See L<FS::svc_acct/get_session_history_sqlradacct>.  Equivalent to
 531 $cust_svc->svc_x->get_session_history_sqlradacct, but more efficient.
 532 Meaningless for records where B<svcdb> is not "svc_acct".
 533
 534 =cut
 535
 536 sub get_session_history {
 537   my($self, $start, $end, $attrib) = @_;
 538
 539   my $username = $self->svc_x->username;
 540
 541   my @part_export = $self->part_svc->part_export('sqlradius')
 542     or die "no sqlradius export configured for this service type";
 543     #or return undef;
 544
 545   my @sessions = ();
 546
 547   foreach my $part_export ( @part_export ) {
 548
 549     my $dbh = DBI->connect( map { $part_export->option($_) }
 550                             qw(datasrc username password)    )
 551       or die "can't connect to sqlradius database: ". $DBI::errstr;
 552
 553     #select a unix time conversion function based on database type
 554     my $str2time;
 555     if ( $dbh->{Driver}->{Name} eq 'mysql' ) {
 556       $str2time = 'UNIX_TIMESTAMP(';
 557     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 558       $str2time = 'EXTRACT( EPOCH FROM ';
 559     } else {
 560       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 561            "; guessing how to convert to UNIX timestamps";
 562       $str2time = 'extract(epoch from ';
 563     }
 564
 565     my @fields = qw( acctstarttime acctstoptime acctsessiontime
 566                      acctinputoctets acctoutputoctets framedipaddress );
 567
 568     my $sth = $dbh->prepare('SELECT '. join(', ', @fields).
 569                             "  FROM radacct
 570                                WHERE UserName = ?
 571                                  AND $str2time AcctStopTime ) >= ?
 572                                  AND $str2time AcctStopTime ) <=  ?
 573                                  ORDER BY AcctStartTime DESC
 574     ") or die $dbh->errstr;
 575     $sth->execute($username, $start, $end) or die $sth->errstr;
 576
 577     push @sessions, map { { %$_ } } @{ $sth->fetchall_arrayref({}) };
 578
 579   }
 580   \@sessions
 581
 582 }
 583
 584 =back
 585
 586 =head1 BUGS
 587
 588 Behaviour of changing the svcpart of cust_svc records is undefined and should
 589 possibly be prohibited, and pkg_svc records are not checked.
 590
 591 pkg_svc records are not checked in general (here).
 592
 593 Deleting this record doesn't check or delete the svc_* record associated
 594 with this record.
 595
 596 In seconds_since_sqlradacct, specifying a DATASRC/USERNAME/PASSWORD instead of
 597 a DBI database handle is not yet implemented.
 598
 599 =head1 SEE ALSO
 600
 601 L<FS::Record>, L<FS::cust_pkg>, L<FS::part_svc>, L<FS::pkg_svc>,
 602 schema.html from the base documentation
 603
 604 =cut
 605
 606 1;
 607