FS/FS/cust_svc.pm

   1 package FS::cust_svc;
   2
   3 use strict;
   4 use vars qw( @ISA $DEBUG $ignore_quantity );
   5 use Carp qw( carp cluck );
   6 use FS::Conf;
   7 use FS::Record qw( qsearch qsearchs dbh );
   8 use FS::cust_pkg;
   9 use FS::part_pkg;
  10 use FS::part_svc;
  11 use FS::pkg_svc;
  12 use FS::svc_acct;
  13 use FS::svc_domain;
  14 use FS::svc_forward;
  15 use FS::svc_broadband;
  16 use FS::svc_external;
  17 use FS::domain_record;
  18 use FS::part_export;
  19
  20 @ISA = qw( FS::Record );
  21
  22 $DEBUG = 0;
  23
  24 $ignore_quantity = 0;
  25
  26 sub _cache {
  27   my $self = shift;
  28   my ( $hashref, $cache ) = @_;
  29   if ( $hashref->{'username'} ) {
  30     $self->{'_svc_acct'} = FS::svc_acct->new($hashref, '');
  31   }
  32   if ( $hashref->{'svc'} ) {
  33     $self->{'_svcpart'} = FS::part_svc->new($hashref);
  34   }
  35 }
  36
  37 =head1 NAME
  38
  39 FS::cust_svc - Object method for cust_svc objects
  40
  41 =head1 SYNOPSIS
  42
  43   use FS::cust_svc;
  44
  45   $record = new FS::cust_svc \%hash
  46   $record = new FS::cust_svc { 'column' => 'value' };
  47
  48   $error = $record->insert;
  49
  50   $error = $new_record->replace($old_record);
  51
  52   $error = $record->delete;
  53
  54   $error = $record->check;
  55
  56   ($label, $value) = $record->label;
  57
  58 =head1 DESCRIPTION
  59
  60 An FS::cust_svc represents a service.  FS::cust_svc inherits from FS::Record.
  61 The following fields are currently supported:
  62
  63 =over 4
  64
  65 =item svcnum - primary key (assigned automatically for new services)
  66
  67 =item pkgnum - Package (see L<FS::cust_pkg>)
  68
  69 =item svcpart - Service definition (see L<FS::part_svc>)
  70
  71 =back
  72
  73 =head1 METHODS
  74
  75 =over 4
  76
  77 =item new HASHREF
  78
  79 Creates a new service.  To add the refund to the database, see L<"insert">.
  80 Services are normally created by creating FS::svc_ objects (see
  81 L<FS::svc_acct>, L<FS::svc_domain>, and L<FS::svc_forward>, among others).
  82
  83 =cut
  84
  85 sub table { 'cust_svc'; }
  86
  87 =item insert
  88
  89 Adds this service to the database.  If there is an error, returns the error,
  90 otherwise returns false.
  91
  92 =item delete
  93
  94 Deletes this service from the database.  If there is an error, returns the
  95 error, otherwise returns false.  Note that this only removes the cust_svc
  96 record - you should probably use the B<cancel> method instead.
  97
  98 =item cancel
  99
 100 Cancels the relevant service by calling the B<cancel> method of the associated
 101 FS::svc_XXX object (i.e. an FS::svc_acct object or FS::svc_domain object),
 102 deleting the FS::svc_XXX record and then deleting this record.
 103
 104 If there is an error, returns the error, otherwise returns false.
 105
 106 =cut
 107
 108 sub cancel {
 109   my $self = shift;
 110
 111   local $SIG{HUP} = 'IGNORE';
 112   local $SIG{INT} = 'IGNORE';
 113   local $SIG{QUIT} = 'IGNORE';
 114   local $SIG{TERM} = 'IGNORE';
 115   local $SIG{TSTP} = 'IGNORE';
 116   local $SIG{PIPE} = 'IGNORE';
 117
 118   my $oldAutoCommit = $FS::UID::AutoCommit;
 119   local $FS::UID::AutoCommit = 0;
 120   my $dbh = dbh;
 121
 122   my $part_svc = $self->part_svc;
 123
 124   $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
 125     $dbh->rollback if $oldAutoCommit;
 126     return "Illegal svcdb value in part_svc!";
 127   };
 128   my $svcdb = $1;
 129   require "FS/$svcdb.pm";
 130
 131   my $svc = $self->svc_x;
 132   if ($svc) {
 133     my $error = $svc->cancel;
 134     if ( $error ) {
 135       $dbh->rollback if $oldAutoCommit;
 136       return "Error canceling service: $error";
 137     }
 138     $error = $svc->delete;
 139     if ( $error ) {
 140       $dbh->rollback if $oldAutoCommit;
 141       return "Error deleting service: $error";
 142     }
 143   }
 144
 145   my $error = $self->delete;
 146   if ( $error ) {
 147     $dbh->rollback if $oldAutoCommit;
 148     return "Error deleting cust_svc: $error";
 149   }
 150
 151   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 152
 153   ''; #no errors
 154
 155 }
 156
 157 =item replace OLD_RECORD
 158
 159 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 160 returns the error, otherwise returns false.
 161
 162 =cut
 163
 164 sub replace {
 165   my ( $new, $old ) = ( shift, shift );
 166
 167   local $SIG{HUP} = 'IGNORE';
 168   local $SIG{INT} = 'IGNORE';
 169   local $SIG{QUIT} = 'IGNORE';
 170   local $SIG{TERM} = 'IGNORE';
 171   local $SIG{TSTP} = 'IGNORE';
 172   local $SIG{PIPE} = 'IGNORE';
 173
 174   my $oldAutoCommit = $FS::UID::AutoCommit;
 175   local $FS::UID::AutoCommit = 0;
 176   my $dbh = dbh;
 177
 178   if ( $new->svcpart != $old->svcpart ) {
 179     my $svc_x = $new->svc_x;
 180     my $new_svc_x = ref($svc_x)->new({$svc_x->hash, svcpart=>$new->svcpart });
 181     local($FS::Record::nowarn_identical) = 1;
 182     my $error = $new_svc_x->replace($svc_x);
 183     if ( $error ) {
 184       $dbh->rollback if $oldAutoCommit;
 185       return $error if $error;
 186     }
 187   }
 188
 189   my $error = $new->SUPER::replace($old);
 190   if ( $error ) {
 191     $dbh->rollback if $oldAutoCommit;
 192     return $error if $error;
 193   }
 194
 195   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 196   ''; #no error
 197
 198 }
 199
 200 =item check
 201
 202 Checks all fields to make sure this is a valid service.  If there is an error,
 203 returns the error, otehrwise returns false.  Called by the insert and
 204 replace methods.
 205
 206 =cut
 207
 208 sub check {
 209   my $self = shift;
 210
 211   my $error =
 212     $self->ut_numbern('svcnum')
 213     || $self->ut_numbern('pkgnum')
 214     || $self->ut_number('svcpart')
 215   ;
 216   return $error if $error;
 217
 218   my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
 219   return "Unknown svcpart" unless $part_svc;
 220
 221   if ( $self->pkgnum ) {
 222     my $cust_pkg = qsearchs( 'cust_pkg', { 'pkgnum' => $self->pkgnum } );
 223     return "Unknown pkgnum" unless $cust_pkg;
 224     my $pkg_svc = qsearchs( 'pkg_svc', {
 225       'pkgpart' => $cust_pkg->pkgpart,
 226       'svcpart' => $self->svcpart,
 227     });
 228     # or new FS::pkg_svc ( { 'pkgpart'  => $cust_pkg->pkgpart,
 229     #                        'svcpart'  => $self->svcpart,
 230     #                        'quantity' => 0                   } );
 231     my $quantity = $pkg_svc ? $pkg_svc->quantity : 0;
 232
 233     my @cust_svc = qsearch('cust_svc', {
 234       'pkgnum'  => $self->pkgnum,
 235       'svcpart' => $self->svcpart,
 236     });
 237     return "Already ". scalar(@cust_svc). " ". $part_svc->svc.
 238            " services for pkgnum ". $self->pkgnum
 239       if scalar(@cust_svc) >= $quantity && !$ignore_quantity;
 240   }
 241
 242   $self->SUPER::check;
 243 }
 244
 245 =item part_svc
 246
 247 Returns the definition for this service, as a FS::part_svc object (see
 248 L<FS::part_svc>).
 249
 250 =cut
 251
 252 sub part_svc {
 253   my $self = shift;
 254   $self->{'_svcpart'}
 255     ? $self->{'_svcpart'}
 256     : qsearchs( 'part_svc', { 'svcpart' => $self->svcpart } );
 257 }
 258
 259 =item cust_pkg
 260
 261 Returns the definition for this service, as a FS::part_svc object (see
 262 L<FS::part_svc>).
 263
 264 =cut
 265
 266 sub cust_pkg {
 267   my $self = shift;
 268   qsearchs( 'cust_pkg', { 'pkgnum' => $self->pkgnum } );
 269 }
 270
 271 =item label
 272
 273 Returns a list consisting of:
 274 - The name of this service (from part_svc)
 275 - A meaningful identifier (username, domain, or mail alias)
 276 - The table name (i.e. svc_domain) for this service
 277
 278 =cut
 279
 280 sub label {
 281   my $self = shift;
 282   carp "FS::cust_svc::label called on $self" if $DEBUG;
 283   my $svc_x = $self->svc_x
 284     or die "can't find ". $self->part_svc->svcdb. '.svcnum '. $self->svcnum;
 285   $self->_svc_label($svc_x);
 286 }
 287
 288 sub _svc_label {
 289   my( $self, $svc_x ) = ( shift, shift );
 290   my $svcdb = $self->part_svc->svcdb;
 291
 292   my $tag;
 293   if ( $svcdb eq 'svc_acct' ) {
 294     $tag = $svc_x->email(@_);
 295   } elsif ( $svcdb eq 'svc_forward' ) {
 296     if ( $svc_x->srcsvc ) {
 297       my $svc_acct = $svc_x->srcsvc_acct(@_);
 298       $tag = $svc_acct->email(@_);
 299     } else {
 300       $tag = $svc_x->src;
 301     }
 302     $tag .= '->';
 303     if ( $svc_x->dstsvc ) {
 304       my $svc_acct = $svc_x->dstsvc_acct(@_);
 305       $tag .= $svc_acct->email(@_);
 306     } else {
 307       $tag .= $svc_x->dst;
 308     }
 309   } elsif ( $svcdb eq 'svc_domain' ) {
 310     $tag = $svc_x->getfield('domain');
 311   } elsif ( $svcdb eq 'svc_www' ) {
 312     my $domain_record = $svc_x->domain_record(@_);
 313     $tag = $domain_record->zone;
 314   } elsif ( $svcdb eq 'svc_broadband' ) {
 315     $tag = $svc_x->ip_addr;
 316   } elsif ( $svcdb eq 'svc_external' ) {
 317     my $conf = new FS::Conf;
 318     if ( $conf->config('svc_external-display_type') eq 'artera_turbo' ) {
 319       $tag = sprintf('%010d', $svc_x->id). '-'.
 320              substr('0000000000'.uc($svc_x->title), -10);
 321     } else {
 322       $tag = $svc_x->id. ': '. $svc_x->title;
 323     }
 324   } else {
 325     cluck "warning: asked for label of unsupported svcdb; using svcnum";
 326     $tag = $svc_x->getfield('svcnum');
 327   }
 328
 329   $self->part_svc->svc, $tag, $svcdb;
 330
 331 }
 332
 333 =item svc_x
 334
 335 Returns the FS::svc_XXX object for this service (i.e. an FS::svc_acct object or
 336 FS::svc_domain object, etc.)
 337
 338 =cut
 339
 340 sub svc_x {
 341   my $self = shift;
 342   my $svcdb = $self->part_svc->svcdb;
 343   if ( $svcdb eq 'svc_acct' && $self->{'_svc_acct'} ) {
 344     $self->{'_svc_acct'};
 345   } else {
 346     #require "FS/$svcdb.pm";
 347     qsearchs( $svcdb, { 'svcnum' => $self->svcnum } );
 348   }
 349 }
 350
 351 =item seconds_since TIMESTAMP
 352
 353 See L<FS::svc_acct/seconds_since>.  Equivalent to
 354 $cust_svc->svc_x->seconds_since, but more efficient.  Meaningless for records
 355 where B<svcdb> is not "svc_acct".
 356
 357 =cut
 358
 359 #note: implementation here, POD in FS::svc_acct
 360 sub seconds_since {
 361   my($self, $since) = @_;
 362   my $dbh = dbh;
 363   my $sth = $dbh->prepare(' SELECT SUM(logout-login) FROM session
 364                               WHERE svcnum = ?
 365                                 AND login >= ?
 366                                 AND logout IS NOT NULL'
 367   ) or die $dbh->errstr;
 368   $sth->execute($self->svcnum, $since) or die $sth->errstr;
 369   $sth->fetchrow_arrayref->[0];
 370 }
 371
 372 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
 373
 374 See L<FS::svc_acct/seconds_since_sqlradacct>.  Equivalent to
 375 $cust_svc->svc_x->seconds_since_sqlradacct, but more efficient.  Meaningless
 376 for records where B<svcdb> is not "svc_acct".
 377
 378 =cut
 379
 380 #note: implementation here, POD in FS::svc_acct
 381 sub seconds_since_sqlradacct {
 382   my($self, $start, $end) = @_;
 383
 384   my $svc_x = $self->svc_x;
 385
 386   my @part_export = $self->part_svc->part_export('sqlradius');
 387   push @part_export, $self->part_svc->part_export('sqlradius_withdomain');
 388   die "no sqlradius or sqlradius_withdomain export configured for this".
 389       "service type"
 390     unless @part_export;
 391     #or return undef;
 392
 393   my $seconds = 0;
 394   foreach my $part_export ( @part_export ) {
 395
 396     next if $part_export->option('ignore_accounting');
 397
 398     my $dbh = DBI->connect( map { $part_export->option($_) }
 399                             qw(datasrc username password)    )
 400       or die "can't connect to sqlradius database: ". $DBI::errstr;
 401
 402     #select a unix time conversion function based on database type
 403     my $str2time;
 404     if ( $dbh->{Driver}->{Name} =~ /^mysql(PP)?$/ ) {
 405       $str2time = 'UNIX_TIMESTAMP(';
 406     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 407       $str2time = 'EXTRACT( EPOCH FROM ';
 408     } else {
 409       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 410            "; guessing how to convert to UNIX timestamps";
 411       $str2time = 'extract(epoch from ';
 412     }
 413
 414     my $username;
 415     if ( $part_export->exporttype eq 'sqlradius' ) {
 416       $username = $svc_x->username;
 417     } elsif ( $part_export->exporttype eq 'sqlradius_withdomain' ) {
 418       $username = $svc_x->email;
 419     } else {
 420       die 'unknown exporttype '. $part_export->exporttype;
 421     }
 422
 423     my $query;
 424
 425     #find closed sessions completely within the given range
 426     my $sth = $dbh->prepare("SELECT SUM(acctsessiontime)
 427                                FROM radacct
 428                                WHERE UserName = ?
 429                                  AND $str2time AcctStartTime) >= ?
 430                                  AND $str2time AcctStopTime ) <  ?
 431                                  AND $str2time AcctStopTime ) > 0
 432                                  AND AcctStopTime IS NOT NULL"
 433     ) or die $dbh->errstr;
 434     $sth->execute($username, $start, $end) or die $sth->errstr;
 435     my $regular = $sth->fetchrow_arrayref->[0];
 436
 437     #find open sessions which start in the range, count session start->range end
 438     $query = "SELECT SUM( ? - $str2time AcctStartTime ) )
 439                 FROM radacct
 440                 WHERE UserName = ?
 441                   AND $str2time AcctStartTime ) >= ?
 442                   AND $str2time AcctStartTime ) <  ?
 443                   AND ( ? - $str2time AcctStartTime ) ) < 86400
 444                   AND (    $str2time AcctStopTime ) = 0
 445                                     OR AcctStopTime IS NULL )";
 446     $sth = $dbh->prepare($query) or die $dbh->errstr;
 447     $sth->execute($end, $username, $start, $end, $end)
 448       or die $sth->errstr. " executing query $query";
 449     my $start_during = $sth->fetchrow_arrayref->[0];
 450
 451     #find closed sessions which start before the range but stop during,
 452     #count range start->session end
 453     $sth = $dbh->prepare("SELECT SUM( $str2time AcctStopTime ) - ? )
 454                             FROM radacct
 455                             WHERE UserName = ?
 456                               AND $str2time AcctStartTime ) < ?
 457                               AND $str2time AcctStopTime  ) >= ?
 458                               AND $str2time AcctStopTime  ) <  ?
 459                               AND $str2time AcctStopTime ) > 0
 460                               AND AcctStopTime IS NOT NULL"
 461     ) or die $dbh->errstr;
 462     $sth->execute($start, $username, $start, $start, $end ) or die $sth->errstr;
 463     my $end_during = $sth->fetchrow_arrayref->[0];
 464
 465     #find closed (not anymore - or open) sessions which start before the range
 466     # but stop after, or are still open, count range start->range end
 467     # don't count open sessions (probably missing stop record)
 468     $sth = $dbh->prepare("SELECT COUNT(*)
 469                             FROM radacct
 470                             WHERE UserName = ?
 471                               AND $str2time AcctStartTime ) < ?
 472                               AND ( $str2time AcctStopTime ) >= ?
 473                                                                   )"
 474                               #      OR AcctStopTime =  0
 475                               #      OR AcctStopTime IS NULL       )"
 476     ) or die $dbh->errstr;
 477     $sth->execute($username, $start, $end ) or die $sth->errstr;
 478     my $entire_range = ($end-$start) * $sth->fetchrow_arrayref->[0];
 479
 480     $seconds += $regular + $end_during + $start_during + $entire_range;
 481
 482   }
 483
 484   $seconds;
 485
 486 }
 487
 488 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
 489
 490 See L<FS::svc_acct/attribute_since_sqlradacct>.  Equivalent to
 491 $cust_svc->svc_x->attribute_since_sqlradacct, but more efficient.  Meaningless
 492 for records where B<svcdb> is not "svc_acct".
 493
 494 =cut
 495
 496 #note: implementation here, POD in FS::svc_acct
 497 #(false laziness w/seconds_since_sqlradacct above)
 498 sub attribute_since_sqlradacct {
 499   my($self, $start, $end, $attrib) = @_;
 500
 501   my $svc_x = $self->svc_x;
 502
 503   my @part_export = $self->part_svc->part_export('sqlradius');
 504   push @part_export, $self->part_svc->part_export('sqlradius_withdomain');
 505   die "no sqlradius or sqlradius_withdomain export configured for this".
 506       "service type"
 507     unless @part_export;
 508     #or return undef;
 509
 510   my $sum = 0;
 511
 512   foreach my $part_export ( @part_export ) {
 513
 514     next if $part_export->option('ignore_accounting');
 515
 516     my $dbh = DBI->connect( map { $part_export->option($_) }
 517                             qw(datasrc username password)    )
 518       or die "can't connect to sqlradius database: ". $DBI::errstr;
 519
 520     #select a unix time conversion function based on database type
 521     my $str2time;
 522     if ( $dbh->{Driver}->{Name} =~ /^mysql(PP)?$/ ) {
 523       $str2time = 'UNIX_TIMESTAMP(';
 524     } elsif ( $dbh->{Driver}->{Name} eq 'Pg' ) {
 525       $str2time = 'EXTRACT( EPOCH FROM ';
 526     } else {
 527       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 528            "; guessing how to convert to UNIX timestamps";
 529       $str2time = 'extract(epoch from ';
 530     }
 531
 532     my $username;
 533     if ( $part_export->exporttype eq 'sqlradius' ) {
 534       $username = $svc_x->username;
 535     } elsif ( $part_export->exporttype eq 'sqlradius_withdomain' ) {
 536       $username = $svc_x->email;
 537     } else {
 538       die 'unknown exporttype '. $part_export->exporttype;
 539     }
 540
 541     my $sth = $dbh->prepare("SELECT SUM($attrib)
 542                                FROM radacct
 543                                WHERE UserName = ?
 544                                  AND $str2time AcctStopTime ) >= ?
 545                                  AND $str2time AcctStopTime ) <  ?
 546                                  AND AcctStopTime IS NOT NULL"
 547     ) or die $dbh->errstr;
 548     $sth->execute($username, $start, $end) or die $sth->errstr;
 549
 550     $sum += $sth->fetchrow_arrayref->[0];
 551
 552   }
 553
 554   $sum;
 555
 556 }
 557
 558 =item get_session_history TIMESTAMP_START TIMESTAMP_END
 559
 560 See L<FS::svc_acct/get_session_history>.  Equivalent to
 561 $cust_svc->svc_x->get_session_history, but more efficient.  Meaningless for
 562 records where B<svcdb> is not "svc_acct".
 563
 564 =cut
 565
 566 sub get_session_history {
 567   my($self, $start, $end, $attrib) = @_;
 568
 569   #$attrib ???
 570
 571   #my @part_export = $cust_svc->part_svc->part_export->can('usage_sessions');
 572   my @part_export = $self->part_svc->part_export('sqlradius');
 573   push @part_export, $self->part_svc->part_export('sqlradius_withdomain');
 574   die "no sqlradius or sqlradius_withdomain export configured for this".
 575       "service type"
 576     unless @part_export;
 577     #or return undef;
 578
 579   my @sessions = ();
 580
 581   foreach my $part_export ( @part_export ) {
 582     push @sessions,
 583       @{ $part_export->usage_sessions( $start, $end, $self->svc_x ) };
 584   }
 585
 586   @sessions;
 587
 588 }
 589
 590 =item pkg_svc
 591
 592 Returns the pkg_svc record for for this service, if applicable.
 593
 594 =cut
 595
 596 sub pkg_svc {
 597   my $self = shift;
 598   my $cust_pkg = $self->cust_pkg;
 599   return undef unless $cust_pkg;
 600
 601   qsearchs( 'pkg_svc', { 'svcpart' => $self->svcpart,
 602                          'pkgpart' => $cust_pkg->pkgpart,
 603                        }
 604           );
 605 }
 606
 607 =back
 608
 609 =head1 BUGS
 610
 611 Behaviour of changing the svcpart of cust_svc records is undefined and should
 612 possibly be prohibited, and pkg_svc records are not checked.
 613
 614 pkg_svc records are not checked in general (here).
 615
 616 Deleting this record doesn't check or delete the svc_* record associated
 617 with this record.
 618
 619 In seconds_since_sqlradacct, specifying a DATASRC/USERNAME/PASSWORD instead of
 620 a DBI database handle is not yet implemented.
 621
 622 =head1 SEE ALSO
 623
 624 L<FS::Record>, L<FS::cust_pkg>, L<FS::part_svc>, L<FS::pkg_svc>,
 625 schema.html from the base documentation
 626
 627 =cut
 628
 629 1;
 630