FS/FS/cust_pkg/Import.pm

   1 package FS::cust_pkg::Import;
   2
   3 use strict;
   4 use vars qw( $DEBUG ); #$conf );
   5 use Data::Dumper;
   6 use FS::Misc::DateTime qw( parse_datetime );
   7 use FS::Record qw( qsearchs );
   8 use FS::cust_pkg;
   9 use FS::cust_main;
  10 use FS::svc_acct;
  11 use FS::svc_external;
  12 use FS::svc_phone;
  13 use FS::svc_domain;
  14
  15 $DEBUG = 0;
  16
  17 #install_callback FS::UID sub {
  18 #  $conf = new FS::Conf;
  19 #};
  20
  21 =head1 NAME
  22
  23 FS::cust_pkg::Import - Batch customer importing
  24
  25 =head1 SYNOPSIS
  26
  27   use FS::cust_pkg::Import;
  28
  29   #import
  30   FS::cust_pkg::Import::batch_import( {
  31     file      => $file,      #filename
  32     type      => $type,      #csv or xls
  33     format    => $format,    #extended, extended-plus_company, svc_external,
  34                              # or svc_external_svc_phone
  35     agentnum  => $agentnum,
  36     job       => $job,       #optional job queue job, for progressbar updates
  37     pkgbatch  => $pkgbatch, #optional batch unique identifier
  38   } );
  39   die $error if $error;
  40
  41   #ajax helper
  42   use FS::UI::Web::JSRPC;
  43   my $server =
  44     new FS::UI::Web::JSRPC 'FS::cust_pkg::Import::process_batch_import', $cgi;
  45   print $server->process;
  46
  47 =head1 DESCRIPTION
  48
  49 Batch package importing.
  50
  51 =head1 SUBROUTINES
  52
  53 =item process_batch_import
  54
  55 Load a batch import as a queued JSRPC job
  56
  57 =cut
  58
  59 sub process_batch_import {
  60   my $job = shift;
  61   my $param = shift;
  62   warn Dumper($param) if $DEBUG;
  63
  64   my $files = $param->{'uploaded_files'}
  65     or die "No files provided.\n";
  66
  67   my (%files) = map { /^(\w+):([\.\w]+)$/ ? ($1,$2):() } split /,/, $files;
  68
  69   my $dir = '%%%FREESIDE_CACHE%%%/cache.'. $FS::UID::datasrc. '/';
  70   my $file = $dir. $files{'file'};
  71
  72   my $type;
  73   if ( $file =~ /\.(\w+)$/i ) {
  74     $type = lc($1);
  75   } else {
  76     #or error out???
  77     warn "can't parse file type from filename $file; defaulting to CSV";
  78     $type = 'csv';
  79   }
  80
  81   my $error =
  82     FS::cust_pkg::Import::batch_import( {
  83       job      => $job,
  84       file     => $file,
  85       type     => $type,
  86       'params' => { pkgbatch => $param->{pkgbatch} },
  87       agentnum => $param->{'agentnum'},
  88       'format' => $param->{'format'},
  89     } );
  90
  91   unlink $file;
  92
  93   die "$error\n" if $error;
  94
  95 }
  96
  97 =item batch_import
  98
  99 =cut
 100
 101 my %formatfields = (
 102   'default'      => [],
 103   'all_dates'    => [],
 104   'svc_acct'     => [qw( username _password domsvc )],
 105   'svc_phone'    => [qw( countrycode phonenum sip_password pin )],
 106   'svc_external' => [qw( id title )],
 107   'location'     => [qw( address1 address2 city state zip country )],
 108 );
 109
 110 sub _formatfields {
 111   \%formatfields;
 112 }
 113
 114 my %import_options = (
 115   'table'         => 'cust_pkg',
 116
 117   'preinsert_callback'  => sub {
 118     my($record, $param) = @_;
 119     my @location_params = grep /^location\./, keys %$param;
 120     if (@location_params) {
 121       my $cust_location = FS::cust_location->new({
 122           'custnum' => $record->custnum,
 123       });
 124       foreach my $p (@location_params) {
 125         $p =~ /^location.(\w+)$/;
 126         $cust_location->set($1, $param->{$p});
 127       }
 128
 129       my $error = $cust_location->find_or_insert; # this avoids duplicates
 130       return "error creating location: $error" if $error;
 131       $record->set('locationnum', $cust_location->locationnum);
 132     }
 133     '';
 134   },
 135
 136   'postinsert_callback' => sub {
 137     my( $record, $param ) = @_;
 138
 139     my $formatfields = _formatfields;
 140     foreach my $svc_x ( grep /^svc/, keys %$formatfields ) {
 141
 142       my $ff = $formatfields->{$svc_x};
 143
 144       if ( grep $param->{"$svc_x.$_"}, @$ff ) {
 145         my $svc = "FS::$svc_x"->new( {
 146           'pkgnum'  => $record->pkgnum,
 147           'svcpart' => $record->part_pkg->svcpart($svc_x),
 148           map { $_ => $param->{"$svc_x.$_"} } @$ff
 149         } );
 150
 151         #this whole thing should be turned into a callback or config to turn on
 152         if ( $svc_x eq 'svc_acct' && $svc->username =~ /\@/ ) {
 153           my($username, $domain) = split(/\@/, $svc->username);
 154           my $svc_domain = qsearchs('svc_domain', { 'domain' => $domain } )
 155                          || new FS::svc_domain { 'svcpart' => 1,
 156                                                  'domain'  => $domain, };
 157           unless ( $svc_domain->svcnum ) {
 158             my $error = $svc_domain->insert;
 159             return "error auto-inserting domain: $error" if $error;
 160           }
 161           $svc->username($username);
 162           $svc->domsvc($svc_domain->svcnum);
 163         }
 164
 165         my $error = $svc->insert;
 166         return "error inserting service: $error" if $error;
 167       }
 168
 169     }
 170
 171     return ''; #no error
 172
 173   },
 174 );
 175
 176 sub _import_options {
 177   \%import_options;
 178 }
 179
 180 sub batch_import {
 181   my $opt = shift;
 182
 183   my $iopt = _import_options;
 184   $opt->{$_} = $iopt->{$_} foreach keys %$iopt;
 185
 186   my $agentnum  = delete $opt->{agentnum}; # i like closures (delete though?)
 187
 188   my $format = delete $opt->{'format'};
 189   my @fields = ();
 190
 191   if ( $format =~ /^(.*)-agent_custid(-agent_pkgid)?$/ ) {
 192     $format = $1;
 193     my $agent_pkgid = $2;
 194     @fields = (
 195       sub {
 196         my( $self, $value ) = @_; # $conf, $param
 197         my $cust_main = qsearchs('cust_main', {
 198           'agentnum'     => $agentnum,
 199           'agent_custid' => $value,
 200         });
 201         $self->custnum($cust_main->custnum) if $cust_main;
 202       },
 203     );
 204     push @fields, 'agent_pkgid' if $agent_pkgid;
 205   } else {
 206     @fields = ( 'custnum' );
 207   }
 208
 209   if ( $format =~ /^(.*)-locationnum$/ ) {
 210     $format = $1;
 211     push @fields, 'locationnum';
 212   }
 213
 214   if ( $format =~ /^bulk_(.*)$/ ) {
 215
 216     $format = $1;
 217
 218     $opt->{'postinsert_callback'} = sub {
 219       my( $record, $param ) = @_;
 220
 221       my $formatfields = _formatfields;
 222       foreach my $svc_x ( grep /^svc/, keys %$formatfields ) {
 223
 224         my $ff = $formatfields->{$svc_x};
 225
 226         if ( grep $param->{"$svc_x.$_"}, @$ff ) {
 227
 228           $param->{'svc_phone.phonenum'} =~ /^\s*(\d+)\s*\-\s*(\d+)\s*$/
 229             or return 'Enter a phone number range, with dash as the separator';
 230           my($start, $end) = ($1, $2);
 231           if ( length($end) < length($start) ) {
 232             $end = substr($start, 0, length($start) - length($end) ). $end;
 233           }
 234
 235           foreach my $phonenum ( "$start" .. "$end" ) {
 236
 237             my $svc = "FS::$svc_x"->new( {
 238               'pkgnum'  => $record->pkgnum,
 239               'svcpart' => $record->part_pkg->svcpart($svc_x),
 240               map { $_ => $param->{"$svc_x.$_"} } @$ff
 241             } );
 242
 243             $svc->phonenum($phonenum);
 244             #$svc->set_default_and_fixed;
 245             my $error = $svc->insert;
 246             return "error inserting service: $error" if $error;
 247
 248           }
 249
 250         }
 251
 252       }
 253
 254       return ''; #no error
 255
 256     };
 257
 258   }
 259
 260   push @fields, ( 'pkgpart', 'discountnum' );
 261
 262   my @date_fields = ();
 263   if ( $format =~ /all_dates/ ) {
 264     @date_fields = qw(
 265       order_date
 266       start_date setup bill last_bill susp adjourn
 267       resume
 268       cancel expire
 269       contract_end dundate
 270     );
 271   } else {
 272     @date_fields = qw(
 273       start_date setup bill last_bill susp adjourn
 274       cancel expire
 275     );
 276   }
 277
 278   foreach my $field (@date_fields) {
 279     push @fields, sub {
 280       my( $self, $value ) = @_; # $conf, $param
 281       #->$field has undesirable effects
 282       $self->set($field, parse_datetime($value) ); #$field closure
 283     };
 284   }
 285
 286   my @formats = split /-/, $format;
 287   foreach my $f (@formats){
 288
 289     my $formatfields = _formatfields();
 290     die "unknown format $format" unless $formatfields->{$f};
 291
 292     foreach my $field ( @{ $formatfields->{$f} } ) {
 293
 294       push @fields, sub {
 295         my( $self, $value, $conf, $param ) = @_;
 296         $param->{"$f.$field"} = $value;
 297       };
 298
 299     }
 300   }
 301
 302   $opt->{'fields'} = \@fields;
 303
 304   FS::Record::batch_import( $opt );
 305
 306 }
 307
 308 =head1 BUGS
 309
 310 Not enough documentation.
 311
 312 =head1 SEE ALSO
 313
 314 L<FS::cust_main>, L<FS::cust_pkg>,
 315 L<FS::svc_acct>, L<FS::svc_external>, L<FS::svc_phone>
 316
 317 =cut
 318
 319 1;