FS/FS/cust_pkg/Import.pm

   1 package FS::cust_pkg::Import;
   2
   3 use strict;
   4 use vars qw( $DEBUG ); #$conf );
   5 use Data::Dumper;
   6 use FS::Misc::DateTime qw( parse_datetime );
   7 use FS::Record qw( qsearchs );
   8 use FS::cust_pkg;
   9 use FS::cust_main;
  10 use FS::svc_acct;
  11 use FS::svc_external;
  12 use FS::svc_phone;
  13 use FS::svc_domain;
  14
  15 $DEBUG = 0;
  16
  17 #install_callback FS::UID sub {
  18 #  $conf = new FS::Conf;
  19 #};
  20
  21 =head1 NAME
  22
  23 FS::cust_pkg::Import - Batch customer importing
  24
  25 =head1 SYNOPSIS
  26
  27   use FS::cust_pkg::Import;
  28
  29   #import
  30   FS::cust_pkg::Import::batch_import( {
  31     file      => $file,      #filename
  32     type      => $type,      #csv or xls
  33     format    => $format,    #extended, extended-plus_company, svc_external,
  34                              # or svc_external_svc_phone
  35     agentnum  => $agentnum,
  36     job       => $job,       #optional job queue job, for progressbar updates
  37     pkgbatch  => $pkgbatch, #optional batch unique identifier
  38   } );
  39   die $error if $error;
  40
  41   #ajax helper
  42   use FS::UI::Web::JSRPC;
  43   my $server =
  44     new FS::UI::Web::JSRPC 'FS::cust_pkg::Import::process_batch_import', $cgi;
  45   print $server->process;
  46
  47 =head1 DESCRIPTION
  48
  49 Batch package importing.
  50
  51 =head1 SUBROUTINES
  52
  53 =item process_batch_import
  54
  55 Load a batch import as a queued JSRPC job
  56
  57 =cut
  58
  59 sub process_batch_import {
  60   my $job = shift;
  61   my $param = shift;
  62   warn Dumper($param) if $DEBUG;
  63
  64   my $files = $param->{'uploaded_files'}
  65     or die "No files provided.\n";
  66
  67   my (%files) = map { /^(\w+):([\.\w]+)$/ ? ($1,$2):() } split /,/, $files;
  68
  69   my $dir = '%%%FREESIDE_CACHE%%%/cache.'. $FS::UID::datasrc. '/';
  70   my $file = $dir. $files{'file'};
  71
  72   my $type;
  73   if ( $file =~ /\.(\w+)$/i ) {
  74     $type = lc($1);
  75   } else {
  76     #or error out???
  77     warn "can't parse file type from filename $file; defaulting to CSV";
  78     $type = 'csv';
  79   }
  80
  81   my $error =
  82     FS::cust_pkg::Import::batch_import( {
  83       job      => $job,
  84       file     => $file,
  85       type     => $type,
  86       'params' => { pkgbatch => $param->{pkgbatch} },
  87       agentnum => $param->{'agentnum'},
  88       'format' => $param->{'format'},
  89     } );
  90
  91   unlink $file;
  92
  93   die "$error\n" if $error;
  94
  95 }
  96
  97 =item batch_import
  98
  99 =cut
 100
 101 my %formatfields = (
 102   'default'      => [],
 103   'all_dates'    => [],
 104   'svc_acct'     => [qw( username _password domsvc )],
 105   'svc_phone'    => [qw( countrycode phonenum sip_password pin )],
 106   'svc_external' => [qw( id title )],
 107   'location'     => [qw( address1 address2 city state zip country )],
 108   'quan_price'   => [qw( quantity setup_fee recur_fee )],
 109 );
 110
 111 sub _formatfields {
 112   \%formatfields;
 113 }
 114
 115 my %import_options = (
 116   'table'         => 'cust_pkg',
 117
 118   'preinsert_callback'  => sub {
 119     my($record, $param) = @_;
 120
 121     my @location_params = grep { /^location\./ && length($param->{$_}) }
 122                             keys %$param;
 123     if (@location_params) {
 124 warn join('-', @location_params);
 125       my $cust_location = FS::cust_location->new({
 126           'custnum' => $record->custnum,
 127       });
 128       foreach my $p (@location_params) {
 129         $p =~ /^location.(\w+)$/;
 130         $cust_location->set($1, $param->{$p});
 131       }
 132
 133       my $error = $cust_location->find_or_insert; # this avoids duplicates
 134       return "error creating location: $error" if $error;
 135       $record->set('locationnum', $cust_location->locationnum);
 136     }
 137
 138     $record->quantity( $param->{'quan_price.quantity'} )
 139       if $param->{'quan_price.quantity'} > 0;
 140
 141     my $s = $param->{'quan_price.setup_fee'};
 142     my $r = $param->{'quan_price.recur_fee'};
 143     my $part_pkg = $record->part_pkg;
 144     if (    ( $s && $s != $part_pkg->option('setup_fee') )
 145          or ( $r && $r != $part_pkg->option('recur_fee') )
 146        )
 147     {
 148       my $custom_part_pkg = $part_pkg->clone;
 149       $custom_part_pkg->disabled('Y');
 150       my %options = $part_pkg->options;
 151       $options{'setup_fee'} = $s if $s;
 152       $options{'recur_fee'} = $r if $r;
 153       my $error = $custom_part_pkg->insert( options=>\%options );
 154       return "error customizing package: $error" if $error;
 155       $record->pkgpart( $custom_part_pkg->pkgpart );
 156     }
 157
 158
 159     '';
 160   },
 161
 162   'postinsert_callback' => sub {
 163     my( $record, $param ) = @_;
 164
 165     my $formatfields = _formatfields;
 166     foreach my $svc_x ( grep /^svc/, keys %$formatfields ) {
 167
 168       my $ff = $formatfields->{$svc_x};
 169
 170       if ( grep $param->{"$svc_x.$_"}, @$ff ) {
 171         my $svc = "FS::$svc_x"->new( {
 172           'pkgnum'  => $record->pkgnum,
 173           'svcpart' => $record->part_pkg->svcpart($svc_x),
 174           map { $_ => $param->{"$svc_x.$_"} } @$ff
 175         } );
 176
 177         #this whole thing should be turned into a callback or config to turn on
 178         if ( $svc_x eq 'svc_acct' && $svc->username =~ /\@/ ) {
 179           my($username, $domain) = split(/\@/, $svc->username);
 180           my $svc_domain = qsearchs('svc_domain', { 'domain' => $domain } )
 181                          || new FS::svc_domain { 'svcpart' => 1,
 182                                                  'domain'  => $domain, };
 183           unless ( $svc_domain->svcnum ) {
 184             my $error = $svc_domain->insert;
 185             return "error auto-inserting domain: $error" if $error;
 186           }
 187           $svc->username($username);
 188           $svc->domsvc($svc_domain->svcnum);
 189         }
 190
 191         my $error = $svc->insert;
 192         return "error inserting service: $error" if $error;
 193       }
 194
 195     }
 196
 197     return ''; #no error
 198
 199   },
 200 );
 201
 202 sub _import_options {
 203   \%import_options;
 204 }
 205
 206 sub batch_import {
 207   my $opt = shift;
 208
 209   my $iopt = _import_options;
 210   $opt->{$_} = $iopt->{$_} foreach keys %$iopt;
 211
 212   my $agentnum  = delete $opt->{agentnum}; # i like closures (delete though?)
 213
 214   my $format = delete $opt->{'format'};
 215   my @fields = ();
 216
 217   if ( $format =~ /^(.*)-agent_custid(-agent_pkgid)?$/ ) {
 218     $format = $1;
 219     my $agent_pkgid = $2;
 220     @fields = (
 221       sub {
 222         my( $self, $value ) = @_; # $conf, $param
 223         my $cust_main = qsearchs('cust_main', {
 224           'agentnum'     => $agentnum,
 225           'agent_custid' => $value,
 226         });
 227         $self->custnum($cust_main->custnum) if $cust_main;
 228       },
 229     );
 230     push @fields, 'agent_pkgid' if $agent_pkgid;
 231   } else {
 232     @fields = ( 'custnum' );
 233   }
 234
 235   if ( $format =~ /^(.*)-locationnum$/ ) {
 236     $format = $1;
 237     push @fields, 'locationnum';
 238   }
 239
 240   if ( $format =~ /^bulk_(.*)$/ ) {
 241
 242     $format = $1;
 243
 244     $opt->{'postinsert_callback'} = sub {
 245       my( $record, $param ) = @_;
 246
 247       my $formatfields = _formatfields;
 248       foreach my $svc_x ( grep /^svc/, keys %$formatfields ) {
 249
 250         my $ff = $formatfields->{$svc_x};
 251
 252         if ( grep $param->{"$svc_x.$_"}, @$ff ) {
 253
 254           $param->{'svc_phone.phonenum'} =~ /^\s*(\d+)\s*\-\s*(\d+)\s*$/
 255             or return 'Enter a phone number range, with dash as the separator';
 256           my($start, $end) = ($1, $2);
 257           if ( length($end) < length($start) ) {
 258             $end = substr($start, 0, length($start) - length($end) ). $end;
 259           }
 260
 261           foreach my $phonenum ( "$start" .. "$end" ) {
 262
 263             my $svc = "FS::$svc_x"->new( {
 264               'pkgnum'  => $record->pkgnum,
 265               'svcpart' => $record->part_pkg->svcpart($svc_x),
 266               map { $_ => $param->{"$svc_x.$_"} } @$ff
 267             } );
 268
 269             $svc->phonenum($phonenum);
 270             #$svc->set_default_and_fixed;
 271             my $error = $svc->insert;
 272             return "error inserting service: $error" if $error;
 273
 274           }
 275
 276         }
 277
 278       }
 279
 280       return ''; #no error
 281
 282     };
 283
 284   }
 285
 286   push @fields, ( 'pkgpart', 'discountnum' );
 287
 288   my @date_fields = ();
 289   if ( $format =~ /all_dates/ ) {
 290     @date_fields = qw(
 291       order_date
 292       start_date setup bill last_bill susp adjourn
 293       resume
 294       cancel expire
 295       contract_end dundate
 296     );
 297   } else {
 298     @date_fields = qw(
 299       start_date setup bill last_bill susp adjourn
 300       cancel expire
 301     );
 302   }
 303
 304   foreach my $field (@date_fields) {
 305     push @fields, sub {
 306       my( $self, $value ) = @_; # $conf, $param
 307       #->$field has undesirable effects
 308       $self->set($field, parse_datetime($value) ); #$field closure
 309     };
 310   }
 311
 312   my @formats = split /-/, $format;
 313   foreach my $f (@formats){
 314
 315     my $formatfields = _formatfields();
 316     die "unknown format $format" unless $formatfields->{$f};
 317
 318     foreach my $field ( @{ $formatfields->{$f} } ) {
 319
 320       push @fields, sub {
 321         my( $self, $value, $conf, $param ) = @_;
 322         $param->{"$f.$field"} = $value;
 323       };
 324
 325     }
 326   }
 327
 328   $opt->{'fields'} = \@fields;
 329
 330   FS::Record::batch_import( $opt );
 331
 332 }
 333
 334 =head1 BUGS
 335
 336 Not enough documentation.
 337
 338 =head1 SEE ALSO
 339
 340 L<FS::cust_main>, L<FS::cust_pkg>,
 341 L<FS::svc_acct>, L<FS::svc_external>, L<FS::svc_phone>
 342
 343 =cut
 344
 345 1;