FS/FS/cust_pkg.pm

   1 package FS::cust_pkg;
   2 use base qw( FS::cust_pkg::Search FS::cust_pkg::API
   3              FS::otaker_Mixin FS::cust_main_Mixin FS::Sales_Mixin
   4              FS::contact_Mixin FS::location_Mixin
   5              FS::m2m_Common FS::option_Common
   6            );
   7
   8 use strict;
   9 use Carp qw(cluck);
  10 use Scalar::Util qw( blessed );
  11 use List::Util qw(min max);
  12 use Tie::IxHash;
  13 use Time::Local qw( timelocal timelocal_nocheck );
  14 use MIME::Entity;
  15 use FS::UID qw( dbh driver_name );
  16 use FS::Record qw( qsearch qsearchs fields );
  17 use FS::CurrentUser;
  18 use FS::cust_svc;
  19 use FS::part_pkg;
  20 use FS::cust_main;
  21 use FS::contact;
  22 use FS::cust_location;
  23 use FS::pkg_svc;
  24 use FS::cust_bill_pkg;
  25 use FS::cust_pkg_detail;
  26 use FS::cust_pkg_usage;
  27 use FS::cdr_cust_pkg_usage;
  28 use FS::cust_event;
  29 use FS::h_cust_svc;
  30 use FS::reg_code;
  31 use FS::part_svc;
  32 use FS::cust_pkg_reason;
  33 use FS::reason;
  34 use FS::cust_pkg_usageprice;
  35 use FS::cust_pkg_discount;
  36 use FS::discount;
  37 use FS::sales;
  38 # for modify_charge
  39 use FS::cust_credit;
  40
  41 # temporary fix; remove this once (un)suspend admin notices are cleaned up
  42 use FS::Misc qw(send_email);
  43
  44 # need to 'use' these instead of 'require' in sub { cancel, suspend, unsuspend,
  45 # setup }
  46 # because they load configuration by setting FS::UID::callback (see TODO)
  47 use FS::svc_acct;
  48 use FS::svc_domain;
  49 use FS::svc_www;
  50 use FS::svc_forward;
  51
  52 # for sending cancel emails in sub cancel
  53 use FS::Conf;
  54
  55 our ($disable_agentcheck, $DEBUG, $me, $import) = (0, 0, '[FS::cust_pkg]', 0);
  56
  57 our $upgrade = 0; #go away after setup+start dates cleaned up for old customers
  58
  59 our $cache_enabled = 0;
  60
  61 sub _simplecache {
  62   my( $self, $hashref ) = @_;
  63   if ( $cache_enabled && $hashref->{'pkg'} && $hashref->{'plan'} ) {
  64     $self->{'_pkgpart'} = FS::part_pkg->new($hashref);
  65   }
  66 }
  67
  68 sub _cache {
  69   my $self = shift;
  70   my ( $hashref, $cache ) = @_;
  71 #  #if ( $hashref->{'pkgpart'} ) {
  72 #  if ( $hashref->{'pkg'} ) {
  73 #    # #@{ $self->{'_pkgnum'} } = ();
  74 #    # my $subcache = $cache->subcache('pkgpart', 'part_pkg');
  75 #    # $self->{'_pkgpart'} = $subcache;
  76 #    # #push @{ $self->{'_pkgnum'} },
  77 #    #   FS::part_pkg->new_or_cached($hashref, $subcache);
  78 #    $self->{'_pkgpart'} = FS::part_pkg->new($hashref);
  79 #  }
  80   if ( exists $hashref->{'svcnum'} ) {
  81     #@{ $self->{'_pkgnum'} } = ();
  82     my $subcache = $cache->subcache('svcnum', 'cust_svc', $hashref->{pkgnum});
  83     $self->{'_svcnum'} = $subcache;
  84     #push @{ $self->{'_pkgnum'} },
  85     FS::cust_svc->new_or_cached($hashref, $subcache) if $hashref->{svcnum};
  86   }
  87 }
  88
  89 =head1 NAME
  90
  91 FS::cust_pkg - Object methods for cust_pkg objects
  92
  93 =head1 SYNOPSIS
  94
  95   use FS::cust_pkg;
  96
  97   $record = new FS::cust_pkg \%hash;
  98   $record = new FS::cust_pkg { 'column' => 'value' };
  99
 100   $error = $record->insert;
 101
 102   $error = $new_record->replace($old_record);
 103
 104   $error = $record->delete;
 105
 106   $error = $record->check;
 107
 108   $error = $record->cancel;
 109
 110   $error = $record->suspend;
 111
 112   $error = $record->unsuspend;
 113
 114   $part_pkg = $record->part_pkg;
 115
 116   @labels = $record->labels;
 117
 118   $seconds = $record->seconds_since($timestamp);
 119
 120   #bulk cancel+order... perhaps slightly deprecated, only used by the bulk
 121   # cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
 122   $error = FS::cust_pkg::order( $custnum, \@pkgparts );
 123   $error = FS::cust_pkg::order( $custnum, \@pkgparts, \@remove_pkgnums ] );
 124
 125 =head1 DESCRIPTION
 126
 127 An FS::cust_pkg object represents a customer billing item.  FS::cust_pkg
 128 inherits from FS::Record.  The following fields are currently supported:
 129
 130 =over 4
 131
 132 =item pkgnum
 133
 134 Primary key (assigned automatically for new billing items)
 135
 136 =item custnum
 137
 138 Customer (see L<FS::cust_main>)
 139
 140 =item pkgpart
 141
 142 Billing item definition (see L<FS::part_pkg>)
 143
 144 =item locationnum
 145
 146 Optional link to package location (see L<FS::location>)
 147
 148 =item order_date
 149
 150 date package was ordered (also remains same on changes)
 151
 152 =item start_date
 153
 154 date
 155
 156 =item setup
 157
 158 date
 159
 160 =item bill
 161
 162 date (next bill date)
 163
 164 =item last_bill
 165
 166 last bill date
 167
 168 =item adjourn
 169
 170 date
 171
 172 =item susp
 173
 174 date
 175
 176 =item expire
 177
 178 date
 179
 180 =item contract_end
 181
 182 date
 183
 184 =item cancel
 185
 186 date
 187
 188 =item usernum
 189
 190 order taker (see L<FS::access_user>)
 191
 192 =item quantity
 193
 194 If not set, defaults to 1
 195
 196 =item change_date
 197
 198 Date of change from previous package
 199
 200 =item change_pkgnum
 201
 202 Previous pkgnum
 203
 204 =item change_pkgpart
 205
 206 Previous pkgpart
 207
 208 =item change_locationnum
 209
 210 Previous locationnum
 211
 212 =item waive_setup
 213
 214 =item main_pkgnum
 215
 216 The pkgnum of the package that this package is supplemental to, if any.
 217
 218 =item pkglinknum
 219
 220 The package link (L<FS::part_pkg_link>) that defines this supplemental
 221 package, if it is one.
 222
 223 =item change_to_pkgnum
 224
 225 The pkgnum of the package this one will be "changed to" in the future
 226 (on its expiration date).
 227
 228 =back
 229
 230 Note: setup, last_bill, bill, adjourn, susp, expire, cancel and change_date
 231 are specified as UNIX timestamps; see L<perlfunc/"time">.  Also see
 232 L<Time::Local> and L<Date::Parse> for conversion functions.
 233
 234 =head1 METHODS
 235
 236 =over 4
 237
 238 =item new HASHREF
 239
 240 Create a new billing item.  To add the item to the database, see L<"insert">.
 241
 242 =cut
 243
 244 sub table { 'cust_pkg'; }
 245 sub cust_linked { $_[0]->cust_main_custnum || $_[0]->custnum }
 246 sub cust_unlinked_msg {
 247   my $self = shift;
 248   "WARNING: can't find cust_main.custnum ". $self->custnum.
 249   ' (cust_pkg.pkgnum '. $self->pkgnum. ')';
 250 }
 251
 252 =item set_initial_timers
 253
 254 If required by the package definition, sets any automatic expire, adjourn,
 255 or contract_end timers to some number of months after the start date
 256 (or setup date, if the package has already been setup). If the package has
 257 a delayed setup fee after a period of "free days", will also set the
 258 start date to the end of that period.
 259
 260 If the package has an automatic transfer rule (C<change_to_pkgnum>), then
 261 this will also order the package and set its start date.
 262
 263 =cut
 264
 265 sub set_initial_timers {
 266   my $self = shift;
 267   my $part_pkg = $self->part_pkg;
 268   my $start = $self->start_date || $self->setup || time;
 269
 270   foreach my $action ( qw(expire adjourn contract_end) ) {
 271     my $months = $part_pkg->get("${action}_months");
 272     if($months and !$self->get($action)) {
 273       $self->set($action, $part_pkg->add_freq($start, $months) );
 274     }
 275   }
 276
 277   # if this package has an expire date and a change_to_pkgpart, set automatic
 278   # package transfer
 279   # (but don't call change_later, as that would call $self->replace, and we're
 280   # probably in the middle of $self->insert right now)
 281   if ( $part_pkg->expire_months and $part_pkg->change_to_pkgpart ) {
 282     if ( $self->change_to_pkgnum ) {
 283       # this can happen if a package is ordered on hold, scheduled for a
 284       # future change _while on hold_, and then released from hold, causing
 285       # the automatic transfer to schedule.
 286       #
 287       # what's correct behavior in that case? I think it's to disallow
 288       # future-changing an on-hold package that has an automatic transfer.
 289       # but if we DO get into this situation, let the manual package change
 290       # win.
 291       warn "pkgnum ".$self->pkgnum.": manual future package change blocks ".
 292            "automatic transfer.\n";
 293     } else {
 294       my $change_to = FS::cust_pkg->new( {
 295           start_date  => $self->get('expire'),
 296           pkgpart     => $part_pkg->change_to_pkgpart,
 297           map { $_ => $self->get($_) }
 298             qw( custnum locationnum quantity refnum salesnum contract_end )
 299       } );
 300       my $error = $change_to->insert;
 301
 302       return $error if $error;
 303       $self->set('change_to_pkgnum', $change_to->pkgnum);
 304     }
 305   }
 306
 307   # if this package has "free days" and delayed setup fee, then
 308   # set start date that many days in the future.
 309   # (this should have been set in the UI, but enforce it here)
 310   if ( $part_pkg->option('free_days',1)
 311        && $part_pkg->option('delay_setup',1)
 312      )
 313   {
 314     $self->start_date( $part_pkg->default_start_date );
 315   }
 316
 317   '';
 318 }
 319
 320 =item insert [ OPTION => VALUE ... ]
 321
 322 Adds this billing item to the database ("Orders" the item).  If there is an
 323 error, returns the error, otherwise returns false.
 324
 325 If the additional field I<promo_code> is defined instead of I<pkgpart>, it
 326 will be used to look up the package definition and agent restrictions will be
 327 ignored.
 328
 329 If the additional field I<refnum> is defined, an FS::pkg_referral record will
 330 be created and inserted.  Multiple FS::pkg_referral records can be created by
 331 setting I<refnum> to an array reference of refnums or a hash reference with
 332 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
 333 record will be created corresponding to cust_main.refnum.
 334
 335 If the additional field I<cust_pkg_usageprice> is defined, it will be treated
 336 as an arrayref of FS::cust_pkg_usageprice objects, which will be inserted.
 337 (Note that this field cannot be set with a usual ->cust_pkg_usageprice method.
 338 It can be set as part of the hash when creating the object, or with the B<set>
 339 method.)
 340
 341 The following options are available:
 342
 343 =over 4
 344
 345 =item change
 346
 347 If set true, supresses actions that should only be taken for new package
 348 orders.  (Currently this includes: intro periods when delay_setup is on,
 349 auto-adding a 1st start date, auto-adding expiration/adjourn/contract_end dates)
 350
 351 =item options
 352
 353 cust_pkg_option records will be created
 354
 355 =item ticket_subject
 356
 357 a ticket will be added to this customer with this subject
 358
 359 =item ticket_queue
 360
 361 an optional queue name for ticket additions
 362
 363 =item allow_pkgpart
 364
 365 Don't check the legality of the package definition.  This should be used
 366 when performing a package change that doesn't change the pkgpart (i.e.
 367 a location change).
 368
 369 =back
 370
 371 =cut
 372
 373 sub insert {
 374   my( $self, %options ) = @_;
 375
 376   my $oldAutoCommit = $FS::UID::AutoCommit;
 377   local $FS::UID::AutoCommit = 0;
 378   my $dbh = dbh;
 379
 380   my $error;
 381   $error = $self->check_pkgpart unless $options{'allow_pkgpart'};
 382
 383   my $part_pkg = $self->part_pkg;
 384
 385   if ( ! $import && ! $options{'change'} ) {
 386
 387     # set order date to now
 388     $self->order_date(time) unless ($import && $self->order_date);
 389
 390     # if the package def says to start only on the first of the month:
 391     if ( $part_pkg->option('start_1st', 1) && !$self->start_date ) {
 392       my ($sec,$min,$hour,$mday,$mon,$year) = (localtime(time) )[0,1,2,3,4,5];
 393       $mon += 1 unless $mday == 1;
 394       until ( $mon < 12 ) { $mon -= 12; $year++; }
 395       $self->start_date( timelocal_nocheck(0,0,0,1,$mon,$year) );
 396     }
 397
 398     if ($self->susp eq 'now' or $part_pkg->start_on_hold) {
 399       # if the package was ordered on hold:
 400       # - suspend it
 401       # - don't set the start date (it will be started manually)
 402       $self->set('susp', $self->order_date);
 403       $self->set('start_date', '');
 404     } else {
 405       # set expire/adjourn/contract_end timers, and free days, if appropriate
 406       # and automatic package transfer, which can fail, so capture the result
 407       $error = $self->set_initial_timers;
 408     }
 409   } # else this is a package change, and shouldn't have "new package" behavior
 410
 411   $error ||= $self->SUPER::insert($options{options} ? %{$options{options}} : ());
 412   if ( $error ) {
 413     $dbh->rollback if $oldAutoCommit;
 414     return $error;
 415   }
 416
 417   $self->refnum($self->cust_main->refnum) unless $self->refnum;
 418   $self->refnum( [ $self->refnum ] ) unless ref($self->refnum);
 419   $self->process_m2m( 'link_table'   => 'pkg_referral',
 420                       'target_table' => 'part_referral',
 421                       'params'       => $self->refnum,
 422                     );
 423
 424   if ( $self->hashref->{cust_pkg_usageprice} ) {
 425     for my $cust_pkg_usageprice ( @{ $self->hashref->{cust_pkg_usageprice} } ) {
 426       $cust_pkg_usageprice->pkgnum( $self->pkgnum );
 427       my $error = $cust_pkg_usageprice->insert;
 428       if ( $error ) {
 429         $dbh->rollback if $oldAutoCommit;
 430         return $error;
 431       }
 432     }
 433   }
 434
 435   if ( $self->setup_discountnum || $self->recur_discountnum ) {
 436     my $error = $self->insert_discount();
 437     if ( $error ) {
 438       $dbh->rollback if $oldAutoCommit;
 439       return $error;
 440     }
 441   }
 442
 443   my $conf = new FS::Conf;
 444
 445   if ($self->locationnum) {
 446     my @part_export =
 447       map qsearch( 'part_export', {exportnum=>$_} ),
 448         $conf->config('cust_location-exports'); #, $agentnum
 449
 450     foreach my $part_export ( @part_export ) {
 451       my $error = $part_export->export_pkg_location($self); #, @$export_args);
 452       if ( $error ) {
 453         $dbh->rollback if $oldAutoCommit;
 454         return "exporting to ". $part_export->exporttype.
 455                " (transaction rolled back): $error";
 456       }
 457     }
 458   }
 459
 460   if ( ! $import && $conf->config('ticket_system') && $options{ticket_subject} ) {
 461
 462     #this init stuff is still inefficient, but at least its limited to
 463     # the small number (any?) folks using ticket emailing on pkg order
 464
 465     #eval '
 466     #  use lib ( "/opt/rt3/local/lib", "/opt/rt3/lib" );
 467     #  use RT;
 468     #';
 469     #die $@ if $@;
 470     #
 471     #RT::LoadConfig();
 472     #RT::Init();
 473     use FS::TicketSystem;
 474     FS::TicketSystem->init();
 475
 476     my $q = new RT::Queue($RT::SystemUser);
 477     $q->Load($options{ticket_queue}) if $options{ticket_queue};
 478     my $t = new RT::Ticket($RT::SystemUser);
 479     my $mime = new MIME::Entity;
 480     $mime->build( Type => 'text/plain', Data => $options{ticket_subject} );
 481     $t->Create( $options{ticket_queue} ? (Queue => $q) : (),
 482                 Subject => $options{ticket_subject},
 483                 MIMEObj => $mime,
 484               );
 485     $t->AddLink( Type   => 'MemberOf',
 486                  Target => 'freeside://freeside/cust_main/'. $self->custnum,
 487                );
 488   }
 489
 490   if (! $import && $conf->config('welcome_letter') && $self->cust_main->num_pkgs == 1) {
 491     my $queue = new FS::queue {
 492       'job'     => 'FS::cust_main::queueable_print',
 493     };
 494     $error = $queue->insert(
 495       'custnum'  => $self->custnum,
 496       'template' => 'welcome_letter',
 497     );
 498
 499     if ($error) {
 500       warn "can't send welcome letter: $error";
 501     }
 502
 503   }
 504
 505   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 506   '';
 507
 508 }
 509
 510 =item delete
 511
 512 This method now works but you probably shouldn't use it.
 513
 514 You don't want to delete packages, because there would then be no record
 515 the customer ever purchased the package.  Instead, see the cancel method and
 516 hide cancelled packages.
 517
 518 =cut
 519
 520 # this is still used internally to abort future package changes, so it
 521 # does need to work
 522
 523 sub delete {
 524   my $self = shift;
 525
 526   # The following foreign keys to cust_pkg are not cleaned up here, and will
 527   # cause package deletion to fail:
 528   #
 529   # cust_credit.pkgnum and commission_pkgnum (and cust_credit_void)
 530   # cust_credit_bill.pkgnum
 531   # cust_pay_pending.pkgnum
 532   # cust_pay.pkgnum (and cust_pay_void)
 533   # cust_bill_pay.pkgnum (wtf, shouldn't reference pkgnum)
 534   # cust_pkg_usage.pkgnum
 535   # cust_pkg.uncancel_pkgnum, change_pkgnum, main_pkgnum, and change_to_pkgnum
 536
 537   # cust_svc is handled by canceling the package before deleting it
 538   # cust_pkg_option is handled via option_Common
 539
 540   my $oldAutoCommit = $FS::UID::AutoCommit;
 541   local $FS::UID::AutoCommit = 0;
 542   my $dbh = dbh;
 543
 544   foreach my $cust_pkg_discount ($self->cust_pkg_discount) {
 545     my $error = $cust_pkg_discount->delete;
 546     if ( $error ) {
 547       $dbh->rollback if $oldAutoCommit;
 548       return $error;
 549     }
 550   }
 551   #cust_bill_pkg_discount?
 552
 553   foreach my $cust_pkg_detail ($self->cust_pkg_detail) {
 554     my $error = $cust_pkg_detail->delete;
 555     if ( $error ) {
 556       $dbh->rollback if $oldAutoCommit;
 557       return $error;
 558     }
 559   }
 560
 561   foreach my $cust_pkg_reason (
 562     qsearchs( {
 563                 'table' => 'cust_pkg_reason',
 564                 'hashref' => { 'pkgnum' => $self->pkgnum },
 565               }
 566             )
 567   ) {
 568     my $error = $cust_pkg_reason->delete;
 569     if ( $error ) {
 570       $dbh->rollback if $oldAutoCommit;
 571       return $error;
 572     }
 573   }
 574
 575   foreach my $pkg_referral ( $self->pkg_referral ) {
 576     my $error = $pkg_referral->delete;
 577     if ( $error ) {
 578       $dbh->rollback if $oldAutoCommit;
 579       return $error;
 580     }
 581   }
 582
 583   my $error = $self->SUPER::delete(@_);
 584   if ( $error ) {
 585     $dbh->rollback if $oldAutoCommit;
 586     return $error;
 587   }
 588
 589   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 590
 591   '';
 592
 593 }
 594
 595 =item replace [ OLD_RECORD ] [ HASHREF | OPTION => VALUE ... ]
 596
 597 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 598 returns the error, otherwise returns false.
 599
 600 Currently, custnum, setup, bill, adjourn, susp, expire, and cancel may be changed.
 601
 602 Changing pkgpart may have disasterous effects.  See the order subroutine.
 603
 604 setup and bill are normally updated by calling the bill method of a customer
 605 object (see L<FS::cust_main>).
 606
 607 suspend is normally updated by the suspend and unsuspend methods.
 608
 609 cancel is normally updated by the cancel method (and also the order subroutine
 610 in some cases).
 611
 612 Available options are:
 613
 614 =over 4
 615
 616 =item reason
 617
 618 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
 619
 620 =item reason_otaker
 621
 622 the access_user (see L<FS::access_user>) providing the reason
 623
 624 =item options
 625
 626 hashref of keys and values - cust_pkg_option records will be created, updated or removed as appopriate
 627
 628 =back
 629
 630 =cut
 631
 632 sub replace {
 633   my $new = shift;
 634
 635   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 636               ? shift
 637               : $new->replace_old;
 638
 639   my $options =
 640     ( ref($_[0]) eq 'HASH' )
 641       ? shift
 642       : { @_ };
 643
 644   #return "Can't (yet?) change pkgpart!" if $old->pkgpart != $new->pkgpart;
 645   #return "Can't change otaker!" if $old->otaker ne $new->otaker;
 646
 647   #allow this *sigh*
 648   #return "Can't change setup once it exists!"
 649   #  if $old->getfield('setup') &&
 650   #     $old->getfield('setup') != $new->getfield('setup');
 651
 652   #some logic for bill, susp, cancel?
 653
 654   local($disable_agentcheck) = 1 if $old->pkgpart == $new->pkgpart;
 655
 656   my $oldAutoCommit = $FS::UID::AutoCommit;
 657   local $FS::UID::AutoCommit = 0;
 658   my $dbh = dbh;
 659
 660   foreach my $method ( qw(adjourn expire) ) {  # How many reasons?
 661     if ($options->{'reason'} && $new->$method && $old->$method ne $new->$method) {
 662       my $error = $new->insert_reason(
 663         'reason'        => $options->{'reason'},
 664         'date'          => $new->$method,
 665         'action'        => $method,
 666         'reason_otaker' => $options->{'reason_otaker'},
 667       );
 668       if ( $error ) {
 669         dbh->rollback if $oldAutoCommit;
 670         return "Error inserting cust_pkg_reason: $error";
 671       }
 672     }
 673   }
 674
 675   #save off and freeze RADIUS attributes for any associated svc_acct records
 676   my @svc_acct = ();
 677   if ( $old->part_pkg->is_prepaid || $new->part_pkg->is_prepaid ) {
 678
 679                 #also check for specific exports?
 680                 # to avoid spurious modify export events
 681     @svc_acct = map  { $_->svc_x }
 682                 grep { $_->part_svc->svcdb eq 'svc_acct' }
 683                      $old->cust_svc;
 684
 685     $_->snapshot foreach @svc_acct;
 686
 687   }
 688
 689   my $error =  $new->export_pkg_change($old)
 690             || $new->SUPER::replace( $old,
 691                                      $options->{options}
 692                                        ? $options->{options}
 693                                        : ()
 694                                    );
 695   if ( $error ) {
 696     $dbh->rollback if $oldAutoCommit;
 697     return $error;
 698   }
 699
 700   #for prepaid packages,
 701   #trigger export of new RADIUS Expiration attribute when cust_pkg.bill changes
 702   foreach my $old_svc_acct ( @svc_acct ) {
 703     my $new_svc_acct = new FS::svc_acct { $old_svc_acct->hash };
 704     my $s_error =
 705       $new_svc_acct->replace( $old_svc_acct,
 706                               'depend_jobnum' => $options->{depend_jobnum},
 707                             );
 708     if ( $s_error ) {
 709       $dbh->rollback if $oldAutoCommit;
 710       return $s_error;
 711     }
 712   }
 713
 714   # also run exports if removing locationnum?
 715   #   doesn't seem to happen, and we don't export blank locationnum on insert...
 716   if ($new->locationnum and ($new->locationnum != $old->locationnum)) {
 717     my $conf = new FS::Conf;
 718     my @part_export =
 719       map qsearch( 'part_export', {exportnum=>$_} ),
 720         $conf->config('cust_location-exports'); #, $agentnum
 721
 722     foreach my $part_export ( @part_export ) {
 723       my $error = $part_export->export_pkg_location($new); #, @$export_args);
 724       if ( $error ) {
 725         $dbh->rollback if $oldAutoCommit;
 726         return "exporting to ". $part_export->exporttype.
 727                " (transaction rolled back): $error";
 728       }
 729     }
 730   }
 731
 732   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 733   '';
 734
 735 }
 736
 737 =item check
 738
 739 Checks all fields to make sure this is a valid billing item.  If there is an
 740 error, returns the error, otherwise returns false.  Called by the insert and
 741 replace methods.
 742
 743 =cut
 744
 745 sub check {
 746   my $self = shift;
 747
 748   if ( !$self->locationnum or $self->locationnum == -1 ) {
 749     $self->set('locationnum', $self->cust_main->ship_locationnum);
 750   }
 751
 752   my $error =
 753     $self->ut_numbern('pkgnum')
 754     || $self->ut_foreign_key('custnum', 'cust_main', 'custnum')
 755     || $self->ut_numbern('pkgpart')
 756     || $self->ut_foreign_keyn('contactnum',  'contact',       'contactnum' )
 757     || $self->ut_foreign_keyn('locationnum', 'cust_location', 'locationnum')
 758     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
 759     || $self->ut_numbern('quantity')
 760     || $self->ut_numbern('start_date')
 761     || $self->ut_numbern('setup')
 762     || $self->ut_numbern('bill')
 763     || $self->ut_numbern('susp')
 764     || $self->ut_numbern('cancel')
 765     || $self->ut_numbern('adjourn')
 766     || $self->ut_numbern('resume')
 767     || $self->ut_numbern('expire')
 768     || $self->ut_numbern('dundate')
 769     || $self->ut_flag('no_auto', [ '', 'Y' ])
 770     || $self->ut_flag('waive_setup', [ '', 'Y' ])
 771     || $self->ut_flag('separate_bill')
 772     || $self->ut_textn('agent_pkgid')
 773     || $self->ut_enum('recur_show_zero', [ '', 'Y', 'N', ])
 774     || $self->ut_enum('setup_show_zero', [ '', 'Y', 'N', ])
 775     || $self->ut_foreign_keyn('main_pkgnum', 'cust_pkg', 'pkgnum')
 776     || $self->ut_foreign_keyn('pkglinknum', 'part_pkg_link', 'pkglinknum')
 777     || $self->ut_foreign_keyn('change_to_pkgnum', 'cust_pkg', 'pkgnum')
 778   ;
 779   return $error if $error;
 780
 781   return "A package with both start date (future start) and setup date (already started) will never bill"
 782     if $self->start_date && $self->setup && ! $upgrade;
 783
 784   return "A future unsuspend date can only be set for a package with a suspend date"
 785     if $self->resume and !$self->susp and !$self->adjourn;
 786
 787   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 788
 789   $self->SUPER::check;
 790 }
 791
 792 =item check_pkgpart
 793
 794 Check the pkgpart to make sure it's allowed with the reg_code and/or
 795 promo_code of the package (if present) and with the customer's agent.
 796 Called from C<insert>, unless we are doing a package change that doesn't
 797 affect pkgpart.
 798
 799 =cut
 800
 801 sub check_pkgpart {
 802   my $self = shift;
 803
 804   # my $error = $self->ut_numbern('pkgpart'); # already done
 805
 806   my $error;
 807   if ( $self->reg_code ) {
 808
 809     unless ( grep { $self->pkgpart == $_->pkgpart }
 810              map  { $_->reg_code_pkg }
 811              qsearchs( 'reg_code', { 'code'     => $self->reg_code,
 812                                      'agentnum' => $self->cust_main->agentnum })
 813            ) {
 814       return "Unknown registration code";
 815     }
 816
 817   } elsif ( $self->promo_code ) {
 818
 819     my $promo_part_pkg =
 820       qsearchs('part_pkg', {
 821         'pkgpart'    => $self->pkgpart,
 822         'promo_code' => { op=>'ILIKE', value=>$self->promo_code },
 823       } );
 824     return 'Unknown promotional code' unless $promo_part_pkg;
 825
 826   } else {
 827
 828     unless ( $disable_agentcheck ) {
 829       my $agent =
 830         qsearchs( 'agent', { 'agentnum' => $self->cust_main->agentnum } );
 831       return "agent ". $agent->agentnum. ':'. $agent->agent.
 832              " can't purchase pkgpart ". $self->pkgpart
 833         unless $agent->pkgpart_hashref->{ $self->pkgpart }
 834             || $agent->agentnum == $self->part_pkg->agentnum;
 835     }
 836
 837     $error = $self->ut_foreign_key('pkgpart', 'part_pkg', 'pkgpart' );
 838     return $error if $error;
 839
 840   }
 841
 842   '';
 843
 844 }
 845
 846 =item cancel [ OPTION => VALUE ... ]
 847
 848 Cancels and removes all services (see L<FS::cust_svc> and L<FS::part_svc>)
 849 in this package, then cancels the package itself (sets the cancel field to
 850 now).
 851
 852 Available options are:
 853
 854 =over 4
 855
 856 =item quiet - can be set true to supress email cancellation notices.
 857
 858 =item time -  can be set to cancel the package based on a specific future or
 859 historical date.  Using time ensures that the remaining amount is calculated
 860 correctly.  Note however that this is an immediate cancel and just changes
 861 the date.  You are PROBABLY looking to expire the account instead of using
 862 this.
 863
 864 =item reason - can be set to a cancellation reason (see L<FS:reason>),
 865 either a reasonnum of an existing reason, or passing a hashref will create
 866 a new reason.  The hashref should have the following keys: typenum - Reason
 867 type (see L<FS::reason_type>, reason - Text of the new reason.
 868
 869 =item date - can be set to a unix style timestamp to specify when to
 870 cancel (expire)
 871
 872 =item nobill - can be set true to skip billing if it might otherwise be done.
 873
 874 =item unused_credit - can be set to 1 to credit the remaining time, or 0 to
 875 not credit it.  This must be set (by change()) when changing the package
 876 to a different pkgpart or location, and probably shouldn't be in any other
 877 case.  If it's not set, the 'unused_credit_cancel' part_pkg option will
 878 be used.
 879
 880 =item no_delay_cancel - prevents delay_cancel behavior
 881 no matter what other options say, for use when changing packages (or any
 882 other time you're really sure you want an immediate cancel)
 883
 884 =back
 885
 886 If there is an error, returns the error, otherwise returns false.
 887
 888 =cut
 889
 890 #NOT DOCUMENTING - this should only be used when calling recursively
 891 #=item delay_cancel - for internal use, to allow proper handling of
 892 #supplemental packages when the main package is flagged to suspend
 893 #before cancelling, probably shouldn't be used otherwise (set the
 894 #corresponding package option instead)
 895
 896 sub cancel {
 897   my( $self, %options ) = @_;
 898   my $error;
 899
 900   # supplemental packages can now be separately canceled, though the UI
 901   # shouldn't permit it
 902   #
 903   ## pass all suspend/cancel actions to the main package
 904   ## (unless the pkglinknum has been removed, then the link is defunct and
 905   ## this package can be canceled on its own)
 906   #if ( $self->main_pkgnum and $self->pkglinknum and !$options{'from_main'} ) {
 907   #  return $self->main_pkg->cancel(%options);
 908   #}
 909
 910   my $conf = new FS::Conf;
 911
 912   warn "cust_pkg::cancel called with options".
 913        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 914     if $DEBUG;
 915
 916   my $oldAutoCommit = $FS::UID::AutoCommit;
 917   local $FS::UID::AutoCommit = 0;
 918   my $dbh = dbh;
 919
 920   my $old = $self->select_for_update;
 921
 922   if ( $old->get('cancel') || $self->get('cancel') ) {
 923     dbh->rollback if $oldAutoCommit;
 924     return "";  # no error
 925   }
 926
 927   # XXX possibly set cancel_time to the expire date?
 928   my $cancel_time = $options{'time'} || time;
 929   my $date = $options{'date'} if $options{'date'}; # expire/cancel later
 930   $date = '' if ($date && $date <= $cancel_time);      # complain instead?
 931
 932   my $delay_cancel = $options{'no_delay_cancel'} ? 0 : $options{'delay_cancel'};
 933   if ( !$date && $self->part_pkg->option('delay_cancel',1)
 934        && (($self->status eq 'active') || ($self->status eq 'suspended'))
 935        && !$options{'no_delay_cancel'}
 936   ) {
 937     my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
 938     my $expsecs = 60*60*24*$expdays;
 939     my $suspfor = $self->susp ? $cancel_time - $self->susp : 0;
 940     $expsecs = $expsecs - $suspfor if $suspfor;
 941     unless ($expsecs <= 0) { #if it's already been suspended long enough, don't re-suspend
 942       $delay_cancel = 1;
 943       $date = $cancel_time + $expsecs;
 944     }
 945   }
 946
 947   #race condition: usage could be ongoing until unprovisioned
 948   #resolved by performing a change package instead (which unprovisions) and
 949   #later cancelling
 950   if ( !$options{nobill} && !$date ) {
 951     # && $conf->exists('bill_usage_on_cancel') ) { #calc_cancel checks this
 952       my $copy = $self->new({$self->hash});
 953       my $error =
 954         $copy->cust_main->bill( 'pkg_list' => [ $copy ],
 955                                 'cancel'   => 1,
 956                                 'time'     => $cancel_time );
 957       warn "Error billing during cancel, custnum ".
 958         #$self->cust_main->custnum. ": $error"
 959         ": $error"
 960         if $error;
 961   }
 962
 963   if ( $options{'reason'} ) {
 964     $error = $self->insert_reason( 'reason' => $options{'reason'},
 965                                    'action' => $date ? 'expire' : 'cancel',
 966                                    'date'   => $date ? $date : $cancel_time,
 967                                    'reason_otaker' => $options{'reason_otaker'},
 968                                  );
 969     if ( $error ) {
 970       dbh->rollback if $oldAutoCommit;
 971       return "Error inserting cust_pkg_reason: $error";
 972     }
 973   }
 974
 975   my %svc_cancel_opt = ();
 976   $svc_cancel_opt{'date'} = $date if $date;
 977   foreach my $cust_svc (
 978     #schwartz
 979     map  { $_->[0] }
 980     sort { $a->[1] <=> $b->[1] }
 981     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; }
 982     qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
 983   ) {
 984     my $part_svc = $cust_svc->part_svc;
 985     next if ( defined($part_svc) and $part_svc->preserve );
 986     my $error = $cust_svc->cancel( %svc_cancel_opt );
 987
 988     if ( $error ) {
 989       $dbh->rollback if $oldAutoCommit;
 990       return 'Error '. ($svc_cancel_opt{'date'} ? 'expiring' : 'canceling' ).
 991              " cust_svc: $error";
 992     }
 993   }
 994
 995   # if a reasonnum was passed, get the actual reason object so we can check
 996   # unused_credit
 997
 998   my $reason;
 999   if ($options{'reason'} =~ /^\d+$/) {
1000     $reason = FS::reason->by_key($options{'reason'});
1001   }
1002
1003   unless ($date) {
1004     # credit remaining time if any of these are true:
1005     # - unused_credit => 1 was passed (this happens when canceling a package
1006     #   for a package change when unused_credit_change is set)
1007     # - no unused_credit option, and there is a cancel reason, and the cancel
1008     #   reason says to credit the package
1009     # - no unused_credit option, and the package definition says to credit the
1010     #   package on cancellation
1011     my $do_credit;
1012     if ( exists($options{'unused_credit'}) ) {
1013       $do_credit = $options{'unused_credit'};
1014     } elsif ( defined($reason) && $reason->unused_credit ) {
1015       $do_credit = 1;
1016     } else {
1017       $do_credit = $self->part_pkg->option('unused_credit_cancel', 1);
1018     }
1019     if ( $do_credit ) {
1020       my $error = $self->credit_remaining('cancel', $cancel_time);
1021       if ($error) {
1022         $dbh->rollback if $oldAutoCommit;
1023         return $error;
1024       }
1025     }
1026   } #unless $date
1027
1028   my %hash = $self->hash;
1029   if ( $date ) {
1030     $hash{'expire'} = $date;
1031     if ($delay_cancel) {
1032       # just to be sure these are clear
1033       $hash{'adjourn'} = undef;
1034       $hash{'resume'} = undef;
1035     }
1036   } else {
1037     $hash{'cancel'} = $cancel_time;
1038   }
1039   $hash{'change_custnum'} = $options{'change_custnum'};
1040
1041   # if this is a supplemental package that's lost its part_pkg_link, and it's
1042   # being canceled for real, unlink it completely
1043   if ( !$date and ! $self->pkglinknum ) {
1044     $hash{main_pkgnum} = '';
1045   }
1046
1047   # if there is a future package change scheduled, unlink from it (like
1048   # abort_change) first, then delete it.
1049   $hash{'change_to_pkgnum'} = '';
1050
1051   # save the package state
1052   my $new = new FS::cust_pkg ( \%hash );
1053   $error = $new->replace( $self, options => { $self->options } );
1054
1055   if ( $self->change_to_pkgnum ) {
1056     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
1057     $error ||= $change_to->cancel('no_delay_cancel' => 1) || $change_to->delete;
1058   }
1059   if ( $error ) {
1060     $dbh->rollback if $oldAutoCommit;
1061     return $error;
1062   }
1063
1064   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1065     $error = $supp_pkg->cancel(%options,
1066       'from_main' => 1,
1067       'date' => $date, #in case it got changed by delay_cancel
1068       'delay_cancel' => $delay_cancel,
1069     );
1070     if ( $error ) {
1071       $dbh->rollback if $oldAutoCommit;
1072       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
1073     }
1074   }
1075
1076   if ($delay_cancel && !$options{'from_main'}) {
1077     $error = $new->suspend(
1078       'from_cancel' => 1,
1079       'time'        => $cancel_time
1080     );
1081   }
1082
1083   unless ($date) {
1084     foreach my $usage ( $self->cust_pkg_usage ) {
1085       $error = $usage->delete;
1086       if ( $error ) {
1087         $dbh->rollback if $oldAutoCommit;
1088         return "deleting usage pools: $error";
1089       }
1090     }
1091   }
1092
1093   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1094   return '' if $date; #no errors
1095
1096   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ } $self->cust_main->invoicing_list;
1097   if ( !$options{'quiet'} &&
1098         $conf->exists('emailcancel', $self->cust_main->agentnum) &&
1099         @invoicing_list ) {
1100     my $msgnum = $conf->config('cancel_msgnum', $self->cust_main->agentnum);
1101     my $error = '';
1102     if ( $msgnum ) {
1103       my $msg_template = qsearchs('msg_template', { msgnum => $msgnum });
1104       $error = $msg_template->send( 'cust_main' => $self->cust_main,
1105                                     'object'    => $self );
1106     }
1107     #should this do something on errors?
1108   }
1109
1110   ''; #no errors
1111
1112 }
1113
1114 =item cancel_if_expired [ NOW_TIMESTAMP ]
1115
1116 Cancels this package if its expire date has been reached.
1117
1118 =cut
1119
1120 sub cancel_if_expired {
1121   my $self = shift;
1122   my $time = shift || time;
1123   return '' unless $self->expire && $self->expire <= $time;
1124   my $error = $self->cancel;
1125   if ( $error ) {
1126     return "Error cancelling expired pkg ". $self->pkgnum. " for custnum ".
1127            $self->custnum. ": $error";
1128   }
1129   '';
1130 }
1131
1132 =item uncancel_svc_x
1133
1134 For cancelled cust_pkg, returns a list of new, uninserted FS::svc_X records
1135 for services that would be inserted by L</uncancel>.  Returned objects also
1136 include the field _h_svc_x, which contains the service history object.
1137
1138 Set pkgnum before inserting.
1139
1140 Accepts the following options:
1141
1142 only_svcnum - arrayref of svcnum, only returns objects for these svcnum
1143 (and only if they would otherwise be returned by this)
1144
1145 =cut
1146
1147 sub uncancel_svc_x {
1148   my ($self, %opt) = @_;
1149
1150   die 'uncancel_svc_x called on a non-cancelled cust_pkg' unless $self->get('cancel');
1151
1152   #find historical services within this timeframe before the package cancel
1153   # (incompatible with "time" option to cust_pkg->cancel?)
1154   my $fuzz = 2 * 60; #2 minutes?  too much?   (might catch separate unprovision)
1155                      #            too little? (unprovisioing export delay?)
1156   my($end, $start) = ( $self->get('cancel'), $self->get('cancel') - $fuzz );
1157   my @h_cust_svc = $self->h_cust_svc( $end, $start );
1158
1159   my @svc_x;
1160   foreach my $h_cust_svc (@h_cust_svc) {
1161     next if $opt{'only_svcnum'} && !(grep { $_ == $h_cust_svc->svcnum } @{$opt{'only_svcnum'}});
1162     # filter out services that still exist on this package (ie preserved svcs)
1163     # but keep services that have since been provisioned on another package (for informational purposes)
1164     next if qsearchs('cust_svc',{ 'svcnum' => $h_cust_svc->svcnum, 'pkgnum' => $self->pkgnum });
1165     my $h_svc_x = $h_cust_svc->h_svc_x( $end, $start );
1166     next unless $h_svc_x; # this probably doesn't happen, but just in case
1167     (my $table = $h_svc_x->table) =~ s/^h_//;
1168     require "FS/$table.pm";
1169     my $class = "FS::$table";
1170     my $svc_x = $class->new( {
1171       'svcpart' => $h_cust_svc->svcpart,
1172       '_h_svc_x' => $h_svc_x,
1173       map { $_ => $h_svc_x->get($_) } fields($table)
1174     } );
1175
1176     # radius_usergroup
1177     if ( $h_svc_x->isa('FS::h_svc_Radius_Mixin') ) {
1178       $svc_x->usergroup( [ $h_svc_x->h_usergroup($end, $start) ] );
1179     }
1180
1181     #these are pretty rare, but should handle them
1182     # - dsl_device (mac addresses)
1183     # - phone_device (mac addresses)
1184     # - dsl_note (ikano notes)
1185     # - domain_record (i.e. restore DNS information w/domains)
1186     # - inventory_item(?) (inventory w/un-cancelling service?)
1187     # - nas (svc_broaband nas stuff)
1188     #this stuff is unused in the wild afaik
1189     # - mailinglistmember
1190     # - router.svcnum?
1191     # - svc_domain.parent_svcnum?
1192     # - acct_snarf (ancient mail fetching config)
1193     # - cgp_rule (communigate)
1194     # - cust_svc_option (used by our Tron stuff)
1195     # - acct_rt_transaction (used by our time worked stuff)
1196
1197     push @svc_x, $svc_x;
1198   }
1199   return @svc_x;
1200 }
1201
1202 =item uncancel_svc_summary
1203
1204 Returns an array of hashrefs, one for each service that could
1205 potentially be reprovisioned by L</uncancel>, with the following keys:
1206
1207 svcpart
1208
1209 svc
1210
1211 uncancel_svcnum
1212
1213 label - from history table if not currently calculable, undefined if it can't be loaded
1214
1215 reprovisionable - 1 if test reprovision succeeded, otherwise 0
1216
1217 num_cust_svc - number of svcs for this svcpart, only if summarizing (see below)
1218
1219 Cannot be run from within a transaction.  Performs inserts
1220 to test the results, and then rolls back the transaction.
1221 Does not perform exports, so does not catch if export would fail.
1222
1223 Also accepts the following options:
1224
1225 no_test_reprovision - skip the test inserts (reprovisionable field will not exist)
1226
1227 summarize_size - if true, returns a single summary record for svcparts with at
1228 least this many svcs, will have key num_cust_svc but not uncancel_svcnum, label or reprovisionable
1229
1230 =cut
1231
1232 sub uncancel_svc_summary {
1233   my ($self, %opt) = @_;
1234
1235   die 'uncancel_svc_summary called on a non-cancelled cust_pkg' unless $self->get('cancel');
1236   die 'uncancel_svc_summary called from within a transaction' unless $FS::UID::AutoCommit;
1237
1238   local $FS::svc_Common::noexport_hack = 1; # very important not to run exports!!!
1239   local $FS::UID::AutoCommit = 0;
1240
1241   # sort by svcpart, to check summarize_size
1242   my $uncancel_svc_x = {};
1243   foreach my $svc_x (sort { $a->{'svcpart'} <=> $b->{'svcpart'} } $self->uncancel_svc_x) {
1244     $uncancel_svc_x->{$svc_x->svcpart} = [] unless $uncancel_svc_x->{$svc_x->svcpart};
1245     push @{$uncancel_svc_x->{$svc_x->svcpart}}, $svc_x;
1246   }
1247
1248   my @out;
1249   foreach my $svcpart (keys %$uncancel_svc_x) {
1250     my @svcpart_svc_x = @{$uncancel_svc_x->{$svcpart}};
1251     if ($opt{'summarize_size'} && (@svcpart_svc_x >= $opt{'summarize_size'})) {
1252       my $svc_x = $svcpart_svc_x[0]; #grab first one for access to $part_svc
1253       my $part_svc = $svc_x->part_svc;
1254       push @out, {
1255         'svcpart'      => $part_svc->svcpart,
1256         'svc'          => $part_svc->svc,
1257         'num_cust_svc' => scalar(@svcpart_svc_x),
1258       };
1259     } else {
1260       foreach my $svc_x (@svcpart_svc_x) {
1261         my $part_svc = $svc_x->part_svc;
1262         my $out = {
1263           'svcpart' => $part_svc->svcpart,
1264           'svc'     => $part_svc->svc,
1265           'uncancel_svcnum' => $svc_x->get('_h_svc_x')->svcnum,
1266         };
1267         $svc_x->pkgnum($self->pkgnum); # provisioning services on a canceled package, will be rolled back
1268         if ($opt{'no_test_reprovision'} or $svc_x->insert) {
1269           # avoid possibly fatal errors from missing linked records
1270           eval { $out->{'label'} = $svc_x->label };
1271           eval { $out->{'label'} = $svc_x->get('_h_svc_x')->label } unless defined($out->{'label'});
1272           $out->{'reprovisionable'} = 0 unless $opt{'no_test_reprovision'};
1273         } else {
1274           $out->{'label'} = $svc_x->label;
1275           $out->{'reprovisionable'} = 1;
1276         }
1277         push @out, $out;
1278       }
1279     }
1280   }
1281
1282   dbh->rollback;
1283   return @out;
1284 }
1285
1286 =item uncancel
1287
1288 "Un-cancels" this package: Orders a new package with the same custnum, pkgpart,
1289 locationnum, (other fields?).  Attempts to re-provision cancelled services
1290 using history information (errors at this stage are not fatal).
1291
1292 cust_pkg: pass a scalar reference, will be filled in with the new cust_pkg object
1293
1294 svc_fatal: service provisioning errors are fatal
1295
1296 svc_errors: pass an array reference, will be filled in with any provisioning errors
1297
1298 only_svcnum: arrayref, only attempt to re-provision these cancelled services
1299
1300 main_pkgnum: link the package as a supplemental package of this one.  For
1301 internal use only.
1302
1303 =cut
1304
1305 sub uncancel {
1306   my( $self, %options ) = @_;
1307
1308   #in case you try do do $uncancel-date = $cust_pkg->uncacel
1309   return '' unless $self->get('cancel');
1310
1311   if ( $self->main_pkgnum and !$options{'main_pkgnum'} ) {
1312     return $self->main_pkg->uncancel(%options);
1313   }
1314
1315   ##
1316   # Transaction-alize
1317   ##
1318
1319   my $oldAutoCommit = $FS::UID::AutoCommit;
1320   local $FS::UID::AutoCommit = 0;
1321   my $dbh = dbh;
1322
1323   ##
1324   # insert the new package
1325   ##
1326
1327   my $cust_pkg = new FS::cust_pkg {
1328     last_bill       => ( $options{'last_bill'} || $self->get('last_bill') ),
1329     bill            => ( $options{'bill'}      || $self->get('bill')      ),
1330     uncancel        => time,
1331     uncancel_pkgnum => $self->pkgnum,
1332     main_pkgnum     => ($options{'main_pkgnum'} || ''),
1333     map { $_ => $self->get($_) } qw(
1334       custnum pkgpart locationnum
1335       setup
1336       susp adjourn resume expire start_date contract_end dundate
1337       change_date change_pkgpart change_locationnum
1338       no_auto separate_bill quantity agent_pkgid
1339       recur_show_zero setup_show_zero
1340     ),
1341   };
1342
1343   my $error = $cust_pkg->insert(
1344     'change' => 1, #supresses any referral credit to a referring customer
1345     'allow_pkgpart' => 1, # allow this even if the package def is disabled
1346   );
1347   if ($error) {
1348     $dbh->rollback if $oldAutoCommit;
1349     return $error;
1350   }
1351
1352   ##
1353   # insert services
1354   ##
1355
1356   my @svc_errors;
1357   foreach my $svc_x ($self->uncancel_svc_x('only_svcnum' => $options{'only_svcnum'})) {
1358
1359     $svc_x->pkgnum($cust_pkg->pkgnum);
1360     my $svc_error = $svc_x->insert;
1361
1362     if ( $svc_error ) {
1363       if ( $options{svc_fatal} ) {
1364         $dbh->rollback if $oldAutoCommit;
1365         return $svc_error;
1366       } else {
1367         # if we've failed to insert the svc_x object, svc_Common->insert
1368         # will have removed the cust_svc already.  if not, then both records
1369         # were inserted but we failed for some other reason (export, most
1370         # likely).  in that case, report the error and delete the records.
1371         push @svc_errors, $svc_error;
1372         my $cust_svc = qsearchs('cust_svc', { 'svcnum' => $svc_x->svcnum });
1373         if ( $cust_svc ) {
1374           # except if export_insert failed, export_delete probably won't be
1375           # much better
1376           local $FS::svc_Common::noexport_hack = 1;
1377           my $cleanup_error = $svc_x->delete; # also deletes cust_svc
1378           if ( $cleanup_error ) { # and if THAT fails, then run away
1379             $dbh->rollback if $oldAutoCommit;
1380             return $cleanup_error;
1381           }
1382         }
1383       } # svc_fatal
1384     } # svc_error
1385   } #foreach uncancel_svc_x
1386
1387   ##
1388   # also move over any services that didn't unprovision at cancellation
1389   ##
1390
1391   foreach my $cust_svc ( qsearch('cust_svc', { pkgnum => $self->pkgnum } ) ) {
1392     $cust_svc->pkgnum( $cust_pkg->pkgnum );
1393     my $error = $cust_svc->replace;
1394     if ( $error ) {
1395       $dbh->rollback if $oldAutoCommit;
1396       return $error;
1397     }
1398   }
1399
1400   ##
1401   # Uncancel any supplemental packages, and make them supplemental to the
1402   # new one.
1403   ##
1404
1405   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1406     my $new_pkg;
1407     $error = $supp_pkg->uncancel(%options, 'main_pkgnum' => $cust_pkg->pkgnum);
1408     if ( $error ) {
1409       $dbh->rollback if $oldAutoCommit;
1410       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
1411     }
1412   }
1413
1414   ##
1415   # Finish
1416   ##
1417
1418   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1419
1420   ${ $options{cust_pkg} }   = $cust_pkg   if ref($options{cust_pkg});
1421   @{ $options{svc_errors} } = @svc_errors if ref($options{svc_errors});
1422
1423   '';
1424 }
1425
1426 =item unexpire
1427
1428 Cancels any pending expiration (sets the expire field to null)
1429 for this package and any supplemental packages.
1430
1431 If there is an error, returns the error, otherwise returns false.
1432
1433 =cut
1434
1435 sub unexpire {
1436   my( $self ) = @_;
1437   my $error;
1438
1439   my $oldAutoCommit = $FS::UID::AutoCommit;
1440   local $FS::UID::AutoCommit = 0;
1441   my $dbh = dbh;
1442
1443   my $old = $self->select_for_update;
1444
1445   my $pkgnum = $old->pkgnum;
1446   if ( $old->get('cancel') || $self->get('cancel') ) {
1447     dbh->rollback if $oldAutoCommit;
1448     return "Can't unexpire cancelled package $pkgnum";
1449     # or at least it's pointless
1450   }
1451
1452   unless ( $old->get('expire') && $self->get('expire') ) {
1453     dbh->rollback if $oldAutoCommit;
1454     return "";  # no error
1455   }
1456
1457   my %hash = $self->hash;
1458   $hash{'expire'} = '';
1459   my $new = new FS::cust_pkg ( \%hash );
1460   $error = $new->replace( $self, options => { $self->options } );
1461   if ( $error ) {
1462     $dbh->rollback if $oldAutoCommit;
1463     return $error;
1464   }
1465
1466   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1467     $error = $supp_pkg->unexpire;
1468     if ( $error ) {
1469       $dbh->rollback if $oldAutoCommit;
1470       return "unexpiring supplemental pkg#".$supp_pkg->pkgnum.": $error";
1471     }
1472   }
1473
1474   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1475
1476   ''; #no errors
1477
1478 }
1479
1480 =item suspend [ OPTION => VALUE ... ]
1481
1482 Suspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1483 package, then suspends the package itself (sets the susp field to now).
1484
1485 Available options are:
1486
1487 =over 4
1488
1489 =item reason - can be set to a cancellation reason (see L<FS:reason>),
1490 either a reasonnum of an existing reason, or passing a hashref will create
1491 a new reason.  The hashref should have the following keys:
1492 - typenum - Reason type (see L<FS::reason_type>
1493 - reason - Text of the new reason.
1494
1495 =item date - can be set to a unix style timestamp to specify when to
1496 suspend (adjourn)
1497
1498 =item time - can be set to override the current time, for calculation
1499 of final invoices or unused-time credits
1500
1501 =item resume_date - can be set to a time when the package should be
1502 unsuspended.  This may be more convenient than calling C<unsuspend()>
1503 separately.
1504
1505 =item from_main - allows a supplemental package to be suspended, rather
1506 than redirecting the method call to its main package.  For internal use.
1507
1508 =item from_cancel - used when suspending from the cancel method, forces
1509 this to skip everything besides basic suspension.  For internal use.
1510
1511 =back
1512
1513 If there is an error, returns the error, otherwise returns false.
1514
1515 =cut
1516
1517 sub suspend {
1518   my( $self, %options ) = @_;
1519   my $error;
1520
1521   # supplemental packages still can't be separately suspended, but silently
1522   # exit instead of failing or passing the action to the main package (so
1523   # that the "Suspend customer" action doesn't trip over the supplemental
1524   # packages and die)
1525
1526   if ( $self->main_pkgnum and !$options{'from_main'} ) {
1527     return;
1528   }
1529
1530   my $oldAutoCommit = $FS::UID::AutoCommit;
1531   local $FS::UID::AutoCommit = 0;
1532   my $dbh = dbh;
1533
1534   my $old = $self->select_for_update;
1535
1536   my $pkgnum = $old->pkgnum;
1537   if ( $old->get('cancel') || $self->get('cancel') ) {
1538     dbh->rollback if $oldAutoCommit;
1539     return "Can't suspend cancelled package $pkgnum";
1540   }
1541
1542   if ( $old->get('susp') || $self->get('susp') ) {
1543     dbh->rollback if $oldAutoCommit;
1544     return "";  # no error                     # complain on adjourn?
1545   }
1546
1547   my $suspend_time = $options{'time'} || time;
1548   my $date = $options{date} if $options{date}; # adjourn/suspend later
1549   $date = '' if ($date && $date <= $suspend_time); # complain instead?
1550
1551   if ( $date && $old->get('expire') && $old->get('expire') < $date ) {
1552     dbh->rollback if $oldAutoCommit;
1553     return "Package $pkgnum expires before it would be suspended.";
1554   }
1555
1556   # some false laziness with sub cancel
1557   if ( !$options{nobill} && !$date && !$options{'from_cancel'} &&
1558        $self->part_pkg->option('bill_suspend_as_cancel',1) ) {
1559     # kind of a kludge--'bill_suspend_as_cancel' to avoid having to
1560     # make the entire cust_main->bill path recognize 'suspend' and
1561     # 'cancel' separately.
1562     warn "Billing $pkgnum on suspension (at $suspend_time)\n" if $DEBUG;
1563     my $copy = $self->new({$self->hash});
1564     my $error =
1565       $copy->cust_main->bill( 'pkg_list' => [ $copy ],
1566                               'cancel'   => 1,
1567                               'time'     => $suspend_time );
1568     warn "Error billing during suspend, custnum ".
1569       #$self->cust_main->custnum. ": $error"
1570       ": $error"
1571       if $error;
1572   }
1573
1574   my $cust_pkg_reason;
1575   if ( $options{'reason'} ) {
1576     $error = $self->insert_reason( 'reason' => $options{'reason'},
1577                                    'action' => $date ? 'adjourn' : 'suspend',
1578                                    'date'   => $date ? $date : $suspend_time,
1579                                    'reason_otaker' => $options{'reason_otaker'},
1580                                  );
1581     if ( $error ) {
1582       dbh->rollback if $oldAutoCommit;
1583       return "Error inserting cust_pkg_reason: $error";
1584     }
1585     $cust_pkg_reason = qsearchs('cust_pkg_reason', {
1586         'date'    => $date ? $date : $suspend_time,
1587         'action'  => $date ? 'A' : 'S',
1588         'pkgnum'  => $self->pkgnum,
1589     });
1590   }
1591
1592   # if a reasonnum was passed, get the actual reason object so we can check
1593   # unused_credit
1594   # (passing a reason hashref is still allowed, but it can't be used with
1595   # the fancy behavioral options.)
1596
1597   my $reason;
1598   if ($options{'reason'} =~ /^\d+$/) {
1599     $reason = FS::reason->by_key($options{'reason'});
1600   }
1601
1602   my %hash = $self->hash;
1603   if ( $date ) {
1604     $hash{'adjourn'} = $date;
1605   } else {
1606     $hash{'susp'} = $suspend_time;
1607   }
1608
1609   my $resume_date = $options{'resume_date'} || 0;
1610   if ( $resume_date > ($date || $suspend_time) ) {
1611     $hash{'resume'} = $resume_date;
1612   }
1613
1614   $options{options} ||= {};
1615
1616   my $new = new FS::cust_pkg ( \%hash );
1617   $error = $new->replace( $self, options => { $self->options,
1618                                               %{ $options{options} },
1619                                             }
1620                         );
1621   if ( $error ) {
1622     $dbh->rollback if $oldAutoCommit;
1623     return $error;
1624   }
1625
1626   unless ( $date ) { # then we are suspending now
1627
1628     unless ($options{'from_cancel'}) {
1629       # credit remaining time if appropriate
1630       # (if required by the package def, or the suspend reason)
1631       my $unused_credit = $self->part_pkg->option('unused_credit_suspend',1)
1632                           || ( defined($reason) && $reason->unused_credit );
1633
1634       if ( $unused_credit ) {
1635         warn "crediting unused time on pkg#".$self->pkgnum."\n" if $DEBUG;
1636         my $error = $self->credit_remaining('suspend', $suspend_time);
1637         if ($error) {
1638           $dbh->rollback if $oldAutoCommit;
1639           return $error;
1640         }
1641       }
1642     }
1643
1644     my @cust_svc = qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } );
1645
1646     #attempt ordering ala cust_svc_suspend_cascade (without infinite-looping
1647     # on the circular dep case)
1648     #  (this is too simple for multi-level deps, we need to use something
1649     #   to resolve the DAG properly when possible)
1650     my %svcpart = ();
1651     $svcpart{$_->svcpart} = 0 foreach @cust_svc;
1652     foreach my $svcpart ( keys %svcpart ) {
1653       foreach my $part_svc_link (
1654         FS::part_svc_link->by_agentnum($self->cust_main->agentnum,
1655                                          src_svcpart => $svcpart,
1656                                          link_type => 'cust_svc_suspend_cascade'
1657                                       )
1658       ) {
1659         $svcpart{$part_svc_link->dst_svcpart} = max(
1660           $svcpart{$part_svc_link->dst_svcpart},
1661           $svcpart{$part_svc_link->src_svcpart} + 1
1662         );
1663       }
1664     }
1665     @cust_svc = sort { $svcpart{ $a->svcpart } <=> $svcpart{ $b->svcpart } }
1666                   @cust_svc;
1667
1668     my @labels = ();
1669     foreach my $cust_svc ( @cust_svc ) {
1670       $cust_svc->suspend( 'labels_arrayref' => \@labels );
1671     }
1672
1673     # suspension fees: if there is a feepart, and it's not an unsuspend fee,
1674     # and this is not a suspend-before-cancel
1675     if ( $cust_pkg_reason ) {
1676       my $reason_obj = $cust_pkg_reason->reason;
1677       if ( $reason_obj->feepart and
1678            ! $reason_obj->fee_on_unsuspend and
1679            ! $options{'from_cancel'} ) {
1680
1681         # register the need to charge a fee, cust_main->bill will do the rest
1682         warn "registering suspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1683           if $DEBUG;
1684         my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1685             'pkgreasonnum'  => $cust_pkg_reason->num,
1686             'pkgnum'        => $self->pkgnum,
1687             'feepart'       => $reason->feepart,
1688             'nextbill'      => $reason->fee_hold,
1689         });
1690         $error ||= $cust_pkg_reason_fee->insert;
1691       }
1692     }
1693
1694     my $conf = new FS::Conf;
1695     if ( $conf->config('suspend_email_admin') && !$options{'from_cancel'} ) {
1696
1697       my $error = send_email(
1698         'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1699                                    #invoice_from ??? well as good as any
1700         'to'      => $conf->config('suspend_email_admin'),
1701         'subject' => 'FREESIDE NOTIFICATION: Customer package suspended',
1702         'body'    => [
1703           "This is an automatic message from your Freeside installation\n",
1704           "informing you that the following customer package has been suspended:\n",
1705           "\n",
1706           'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1707           'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1708           ( map { "Service : $_\n" } @labels ),
1709         ],
1710         'custnum' => $self->custnum,
1711         'msgtype' => 'admin'
1712       );
1713
1714       if ( $error ) {
1715         warn "WARNING: can't send suspension admin email (suspending anyway): ".
1716              "$error\n";
1717       }
1718
1719     }
1720
1721   }
1722
1723   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1724     $error = $supp_pkg->suspend(%options, 'from_main' => 1);
1725     if ( $error ) {
1726       $dbh->rollback if $oldAutoCommit;
1727       return "suspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1728     }
1729   }
1730
1731   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1732
1733   ''; #no errors
1734 }
1735
1736 =item credit_remaining MODE TIME
1737
1738 Generate a credit for this package for the time remaining in the current
1739 billing period.  MODE is either "suspend" or "cancel" (determines the
1740 credit type).  TIME is the time of suspension/cancellation.  Both arguments
1741 are mandatory.
1742
1743 =cut
1744
1745 # Implementation note:
1746 #
1747 # If you pkgpart-change a package that has been billed, and it's set to give
1748 # credit on package change, then this method gets called and then the new
1749 # package will have no last_bill date. Therefore the customer will be credited
1750 # only once (per billing period) even if there are multiple package changes.
1751 #
1752 # If you location-change a package that has been billed, this method will NOT
1753 # be called and the new package WILL have the last bill date of the old
1754 # package.
1755 #
1756 # If the new package is then canceled within the same billing cycle,
1757 # credit_remaining needs to run calc_remain on the OLD package to determine
1758 # the amount of unused time to credit.
1759
1760 sub credit_remaining {
1761   # Add a credit for remaining service
1762   my ($self, $mode, $time) = @_;
1763   die 'credit_remaining requires suspend or cancel'
1764     unless $mode eq 'suspend' or $mode eq 'cancel';
1765   die 'no suspend/cancel time' unless $time > 0;
1766
1767   my $conf = FS::Conf->new;
1768   my $reason_type = $conf->config($mode.'_credit_type');
1769
1770   my $last_bill = $self->getfield('last_bill') || 0;
1771   my $next_bill = $self->getfield('bill') || 0;
1772   if ( $last_bill > 0         # the package has been billed
1773       and $next_bill > 0      # the package has a next bill date
1774       and $next_bill >= $time # which is in the future
1775   ) {
1776     my @cust_credit_source_bill_pkg = ();
1777     my $remaining_value = 0;
1778
1779     my $remain_pkg = $self;
1780     $remaining_value = $remain_pkg->calc_remain(
1781       'time' => $time,
1782       'cust_credit_source_bill_pkg' => \@cust_credit_source_bill_pkg,
1783     );
1784
1785     # we may have to walk back past some package changes to get to the
1786     # one that actually has unused time
1787     while ( $remaining_value == 0 ) {
1788       if ( $remain_pkg->change_pkgnum ) {
1789         $remain_pkg = FS::cust_pkg->by_key($remain_pkg->change_pkgnum);
1790       } else {
1791         # the package has really never been billed
1792         return;
1793       }
1794       $remaining_value = $remain_pkg->calc_remain(
1795         'time' => $time,
1796         'cust_credit_source_bill_pkg' => \@cust_credit_source_bill_pkg,
1797       );
1798     }
1799
1800     if ( $remaining_value > 0 ) {
1801       warn "Crediting for $remaining_value on package ".$self->pkgnum."\n"
1802         if $DEBUG;
1803       my $error = $self->cust_main->credit(
1804         $remaining_value,
1805         'Credit for unused time on '. $self->part_pkg->pkg,
1806         'reason_type' => $reason_type,
1807         'cust_credit_source_bill_pkg' => \@cust_credit_source_bill_pkg,
1808       );
1809       return "Error crediting customer \$$remaining_value for unused time".
1810         " on ". $self->part_pkg->pkg. ": $error"
1811         if $error;
1812     } #if $remaining_value
1813   } #if $last_bill, etc.
1814   '';
1815 }
1816
1817 =item unsuspend [ OPTION => VALUE ... ]
1818
1819 Unsuspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1820 package, then unsuspends the package itself (clears the susp field and the
1821 adjourn field if it is in the past).  If the suspend reason includes an
1822 unsuspension package, that package will be ordered.
1823
1824 Available options are:
1825
1826 =over 4
1827
1828 =item date
1829
1830 Can be set to a date to unsuspend the package in the future (the 'resume'
1831 field).
1832
1833 =item adjust_next_bill
1834
1835 Can be set true to adjust the next bill date forward by
1836 the amount of time the account was inactive.  This was set true by default
1837 in the past (from 1.4.2 and 1.5.0pre6 through 1.7.0), but now needs to be
1838 explicitly requested with this option or in the price plan.
1839
1840 =back
1841
1842 If there is an error, returns the error, otherwise returns false.
1843
1844 =cut
1845
1846 sub unsuspend {
1847   my( $self, %opt ) = @_;
1848   my $error;
1849
1850   # pass all suspend/cancel actions to the main package
1851   if ( $self->main_pkgnum and !$opt{'from_main'} ) {
1852     return $self->main_pkg->unsuspend(%opt);
1853   }
1854
1855   my $oldAutoCommit = $FS::UID::AutoCommit;
1856   local $FS::UID::AutoCommit = 0;
1857   my $dbh = dbh;
1858
1859   my $old = $self->select_for_update;
1860
1861   my $pkgnum = $old->pkgnum;
1862   if ( $old->get('cancel') || $self->get('cancel') ) {
1863     $dbh->rollback if $oldAutoCommit;
1864     return "Can't unsuspend cancelled package $pkgnum";
1865   }
1866
1867   unless ( $old->get('susp') && $self->get('susp') ) {
1868     $dbh->rollback if $oldAutoCommit;
1869     return "";  # no error                     # complain instead?
1870   }
1871
1872   # handle the case of setting a future unsuspend (resume) date
1873   # and do not continue to actually unsuspend the package
1874   my $date = $opt{'date'};
1875   if ( $date and $date > time ) { # return an error if $date <= time?
1876
1877     if ( $old->get('expire') && $old->get('expire') < $date ) {
1878       $dbh->rollback if $oldAutoCommit;
1879       return "Package $pkgnum expires before it would be unsuspended.";
1880     }
1881
1882     my $new = new FS::cust_pkg { $self->hash };
1883     $new->set('resume', $date);
1884     $error = $new->replace($self, options => $self->options);
1885
1886     if ( $error ) {
1887       $dbh->rollback if $oldAutoCommit;
1888       return $error;
1889     }
1890     else {
1891       $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1892       return '';
1893     }
1894
1895   } #if $date
1896
1897   if (!$self->setup) {
1898     # then this package is being released from on-hold status
1899     $error = $self->set_initial_timers;
1900     if ( $error ) {
1901       $dbh->rollback if $oldAutoCommit;
1902       return $error;
1903     }
1904   }
1905
1906   my @labels = ();
1907
1908   foreach my $cust_svc (
1909     qsearch('cust_svc',{'pkgnum'=> $self->pkgnum } )
1910   ) {
1911     my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1912
1913     $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1914       $dbh->rollback if $oldAutoCommit;
1915       return "Illegal svcdb value in part_svc!";
1916     };
1917     my $svcdb = $1;
1918     require "FS/$svcdb.pm";
1919
1920     my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1921     if ($svc) {
1922       $error = $svc->unsuspend;
1923       if ( $error ) {
1924         $dbh->rollback if $oldAutoCommit;
1925         return $error;
1926       }
1927       my( $label, $value ) = $cust_svc->label;
1928       push @labels, "$label: $value";
1929     }
1930
1931   }
1932
1933   my $cust_pkg_reason = $self->last_cust_pkg_reason('susp');
1934   my $reason = $cust_pkg_reason ? $cust_pkg_reason->reason : '';
1935
1936   my %hash = $self->hash;
1937   my $inactive = time - $hash{'susp'};
1938
1939   my $conf = new FS::Conf;
1940
1941   #adjust the next bill date forward
1942   # increment next bill date if certain conditions are met:
1943   # - it was due to be billed at some point
1944   # - either the global or local config says to do this
1945   my $adjust_bill = 0;
1946   if (
1947        $inactive > 0
1948     && ( $hash{'bill'} || $hash{'setup'} )
1949     && (    $opt{'adjust_next_bill'}
1950          || $conf->exists('unsuspend-always_adjust_next_bill_date')
1951          || $self->part_pkg->option('unsuspend_adjust_bill', 1)
1952        )
1953   ) {
1954     $adjust_bill = 1;
1955   }
1956
1957   # but not if:
1958   # - the package billed during suspension
1959   # - or it was ordered on hold
1960   # - or the customer was credited for the unused time
1961
1962   if ( $self->option('suspend_bill',1)
1963       or ( $self->part_pkg->option('suspend_bill',1)
1964            and ! $self->option('no_suspend_bill',1)
1965          )
1966       or $hash{'order_date'} == $hash{'susp'}
1967   ) {
1968     $adjust_bill = 0;
1969   }
1970
1971   if ( $adjust_bill ) {
1972     if (    $self->part_pkg->option('unused_credit_suspend')
1973          or ( ref($reason) and $reason->unused_credit ) ) {
1974       # then the customer was credited for the unused time before suspending,
1975       # so their next bill should be immediate
1976       $hash{'bill'} = time;
1977     } else {
1978       # add the length of time suspended to the bill date
1979       $hash{'bill'} = ( $hash{'bill'} || $hash{'setup'} ) + $inactive;
1980     }
1981   }
1982
1983   $hash{'susp'} = '';
1984   $hash{'adjourn'} = '' if $hash{'adjourn'} and $hash{'adjourn'} < time;
1985   $hash{'resume'} = '' if !$hash{'adjourn'};
1986   my $new = new FS::cust_pkg ( \%hash );
1987   $error = $new->replace( $self, options => { $self->options } );
1988   if ( $error ) {
1989     $dbh->rollback if $oldAutoCommit;
1990     return $error;
1991   }
1992
1993   my $unsusp_pkg;
1994
1995   if ( $reason ) {
1996     if ( $reason->unsuspend_pkgpart ) {
1997       warn "Suspend reason '".$reason->reason."' uses deprecated unsuspend_pkgpart feature.\n";
1998       my $part_pkg = FS::part_pkg->by_key($reason->unsuspend_pkgpart)
1999         or $error = "Unsuspend package definition ".$reason->unsuspend_pkgpart.
2000                     " not found.";
2001       my $start_date = $self->cust_main->next_bill_date
2002         if $reason->unsuspend_hold;
2003
2004       if ( $part_pkg ) {
2005         $unsusp_pkg = FS::cust_pkg->new({
2006             'custnum'     => $self->custnum,
2007             'pkgpart'     => $reason->unsuspend_pkgpart,
2008             'start_date'  => $start_date,
2009             'locationnum' => $self->locationnum,
2010             # discount? probably not...
2011         });
2012
2013         $error ||= $self->cust_main->order_pkg( 'cust_pkg' => $unsusp_pkg );
2014       }
2015     }
2016     # new way, using fees
2017     if ( $reason->feepart and $reason->fee_on_unsuspend ) {
2018       # register the need to charge a fee, cust_main->bill will do the rest
2019       warn "registering unsuspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
2020         if $DEBUG;
2021       my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
2022           'pkgreasonnum'  => $cust_pkg_reason->num,
2023           'pkgnum'        => $self->pkgnum,
2024           'feepart'       => $reason->feepart,
2025           'nextbill'      => $reason->fee_hold,
2026       });
2027       $error ||= $cust_pkg_reason_fee->insert;
2028     }
2029
2030     if ( $error ) {
2031       $dbh->rollback if $oldAutoCommit;
2032       return $error;
2033     }
2034   }
2035
2036   if ( $conf->config('unsuspend_email_admin') ) {
2037
2038     my $error = send_email(
2039       'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
2040                                  #invoice_from ??? well as good as any
2041       'to'      => $conf->config('unsuspend_email_admin'),
2042       'subject' => 'FREESIDE NOTIFICATION: Customer package unsuspended',       'body'    => [
2043         "This is an automatic message from your Freeside installation\n",
2044         "informing you that the following customer package has been unsuspended:\n",
2045         "\n",
2046         'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
2047         'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
2048         ( map { "Service : $_\n" } @labels ),
2049         ($unsusp_pkg ?
2050           "An unsuspension fee was charged: ".
2051             $unsusp_pkg->part_pkg->pkg_comment."\n"
2052           : ''
2053         ),
2054       ],
2055       'custnum' => $self->custnum,
2056       'msgtype' => 'admin',
2057     );
2058
2059     if ( $error ) {
2060       warn "WARNING: can't send unsuspension admin email (unsuspending anyway): ".
2061            "$error\n";
2062     }
2063
2064   }
2065
2066   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
2067     $error = $supp_pkg->unsuspend(%opt, 'from_main' => 1);
2068     if ( $error ) {
2069       $dbh->rollback if $oldAutoCommit;
2070       return "unsuspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
2071     }
2072   }
2073
2074   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2075
2076   ''; #no errors
2077 }
2078
2079 =item unadjourn
2080
2081 Cancels any pending suspension (sets the adjourn field to null)
2082 for this package and any supplemental packages.
2083
2084 If there is an error, returns the error, otherwise returns false.
2085
2086 =cut
2087
2088 sub unadjourn {
2089   my( $self ) = @_;
2090   my $error;
2091
2092   my $oldAutoCommit = $FS::UID::AutoCommit;
2093   local $FS::UID::AutoCommit = 0;
2094   my $dbh = dbh;
2095
2096   my $old = $self->select_for_update;
2097
2098   my $pkgnum = $old->pkgnum;
2099   if ( $old->get('cancel') || $self->get('cancel') ) {
2100     dbh->rollback if $oldAutoCommit;
2101     return "Can't unadjourn cancelled package $pkgnum";
2102     # or at least it's pointless
2103   }
2104
2105   if ( $old->get('susp') || $self->get('susp') ) {
2106     dbh->rollback if $oldAutoCommit;
2107     return "Can't unadjourn suspended package $pkgnum";
2108     # perhaps this is arbitrary
2109   }
2110
2111   unless ( $old->get('adjourn') && $self->get('adjourn') ) {
2112     dbh->rollback if $oldAutoCommit;
2113     return "";  # no error
2114   }
2115
2116   my %hash = $self->hash;
2117   $hash{'adjourn'} = '';
2118   $hash{'resume'}  = '';
2119   my $new = new FS::cust_pkg ( \%hash );
2120   $error = $new->replace( $self, options => { $self->options } );
2121   if ( $error ) {
2122     $dbh->rollback if $oldAutoCommit;
2123     return $error;
2124   }
2125
2126   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
2127     $error = $supp_pkg->unadjourn;
2128     if ( $error ) {
2129       $dbh->rollback if $oldAutoCommit;
2130       return "unadjourning supplemental pkg#".$supp_pkg->pkgnum.": $error";
2131     }
2132   }
2133
2134   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2135
2136   ''; #no errors
2137
2138 }
2139
2140
2141 =item change HASHREF | OPTION => VALUE ...
2142
2143 Changes this package: cancels it and creates a new one, with a different
2144 pkgpart or locationnum or both.  All services are transferred to the new
2145 package (no change will be made if this is not possible).
2146
2147 Options may be passed as a list of key/value pairs or as a hash reference.
2148 Options are:
2149
2150 =over 4
2151
2152 =item locationnum
2153
2154 New locationnum, to change the location for this package.
2155
2156 =item cust_location
2157
2158 New FS::cust_location object, to create a new location and assign it
2159 to this package.
2160
2161 =item cust_main
2162
2163 New FS::cust_main object, to create a new customer and assign the new package
2164 to it.
2165
2166 =item pkgpart
2167
2168 New pkgpart (see L<FS::part_pkg>).
2169
2170 =item refnum
2171
2172 New refnum (see L<FS::part_referral>).
2173
2174 =item quantity
2175
2176 New quantity; if unspecified, the new package will have the same quantity
2177 as the old.
2178
2179 =item cust_pkg
2180
2181 "New" (existing) FS::cust_pkg object.  The package's services and other
2182 attributes will be transferred to this package.
2183
2184 =item keep_dates
2185
2186 Set to true to transfer billing dates (start_date, setup, last_bill, bill,
2187 susp, adjourn, cancel, expire, and contract_end) to the new package.
2188
2189 =item unprotect_svcs
2190
2191 Normally, change() will rollback and return an error if some services
2192 can't be transferred (also see the I<cust_pkg-change_svcpart> config option).
2193 If unprotect_svcs is true, this method will transfer as many services as
2194 it can and then unconditionally cancel the old package.
2195
2196 =item contract_end
2197
2198 If specified, sets this value for the contract_end date on the new package
2199 (without regard for keep_dates or the usual date-preservation behavior.)
2200 Will throw an error if defined but false;  the UI doesn't allow editing
2201 this unless it already exists, making removal impossible to undo.
2202
2203 =back
2204
2205 At least one of locationnum, cust_location, pkgpart, refnum, cust_main, or
2206 cust_pkg must be specified (otherwise, what's the point?)
2207
2208 Returns either the new FS::cust_pkg object or a scalar error.
2209
2210 For example:
2211
2212   my $err_or_new_cust_pkg = $old_cust_pkg->change
2213
2214 =cut
2215
2216 #used by change and change_later
2217 #didn't put with documented check methods because it depends on change-specific opts
2218 #and it also possibly edits the value of opts
2219 sub _check_change {
2220   my $self = shift;
2221   my $opt = shift;
2222   if ( defined($opt->{'contract_end'}) ) {
2223     my $current_contract_end = $self->get('contract_end');
2224     unless ($opt->{'contract_end'}) {
2225       if ($current_contract_end) {
2226         return "Cannot remove contract end date when changing packages";
2227       } else {
2228         #shouldn't even pass this option if there's not a current value
2229         #but can be handled gracefully if the option is empty
2230         warn "Contract end date passed unexpectedly";
2231         delete $opt->{'contract_end'};
2232         return '';
2233       }
2234     }
2235     unless ($current_contract_end) {
2236       #option shouldn't be passed, throw error if it's non-empty
2237       return "Cannot add contract end date when changing packages " . $self->pkgnum;
2238     }
2239   }
2240   return '';
2241 }
2242
2243 #some false laziness w/order
2244 sub change {
2245   my $self = shift;
2246   my $opt = ref($_[0]) ? shift : { @_ };
2247
2248   my $conf = new FS::Conf;
2249
2250   # handle contract_end on cust_pkg same as passed option
2251   if ( $opt->{'cust_pkg'} ) {
2252     $opt->{'contract_end'} = $opt->{'cust_pkg'}->contract_end;
2253     delete $opt->{'contract_end'} unless $opt->{'contract_end'};
2254   }
2255
2256   # check contract_end, prevent adding/removing
2257   my $error = $self->_check_change($opt);
2258   return $error if $error;
2259
2260   # Transactionize this whole mess
2261   my $oldAutoCommit = $FS::UID::AutoCommit;
2262   local $FS::UID::AutoCommit = 0;
2263   my $dbh = dbh;
2264
2265   if ( $opt->{'cust_location'} ) {
2266     $error = $opt->{'cust_location'}->find_or_insert;
2267     if ( $error ) {
2268       $dbh->rollback if $oldAutoCommit;
2269       return "creating location record: $error";
2270     }
2271     $opt->{'locationnum'} = $opt->{'cust_location'}->locationnum;
2272   }
2273
2274   # Before going any further here: if the package is still in the pre-setup
2275   # state, it's safe to modify it in place. No need to charge/credit for
2276   # partial period, transfer services, transfer usage pools, copy invoice
2277   # details, or change any dates.
2278   if ( ! $self->setup and ! $opt->{cust_pkg} and ! $opt->{cust_main} ) {
2279     foreach ( qw( locationnum pkgpart quantity refnum salesnum ) ) {
2280       if ( length($opt->{$_}) ) {
2281         $self->set($_, $opt->{$_});
2282       }
2283     }
2284     # almost. if the new pkgpart specifies start/adjourn/expire timers,
2285     # apply those.
2286     if ( $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart ) {
2287       $error ||= $self->set_initial_timers;
2288     }
2289     # but if contract_end was explicitly specified, that overrides all else
2290     $self->set('contract_end', $opt->{'contract_end'})
2291       if $opt->{'contract_end'};
2292     $error ||= $self->replace;
2293     if ( $error ) {
2294       $dbh->rollback if $oldAutoCommit;
2295       return "modifying package: $error";
2296     } else {
2297       $dbh->commit if $oldAutoCommit;
2298       return $self;
2299     }
2300   }
2301
2302   my %hash = ();
2303
2304   my $time = time;
2305
2306   $hash{'setup'} = $time if $self->get('setup');
2307
2308   $hash{'change_date'} = $time;
2309   $hash{"change_$_"}  = $self->$_()
2310     foreach qw( pkgnum pkgpart locationnum );
2311
2312   if ( $opt->{'cust_pkg'} ) {
2313     # treat changing to a package with a different pkgpart as a
2314     # pkgpart change (because it is)
2315     $opt->{'pkgpart'} = $opt->{'cust_pkg'}->pkgpart;
2316   }
2317
2318   # whether to override pkgpart checking on the new package
2319   my $same_pkgpart = 1;
2320   if ( $opt->{'pkgpart'} and ( $opt->{'pkgpart'} != $self->pkgpart ) ) {
2321     $same_pkgpart = 0;
2322   }
2323
2324   my $unused_credit = 0;
2325   my $keep_dates = $opt->{'keep_dates'};
2326
2327   # Special case.  If the pkgpart is changing, and the customer is going to be
2328   # credited for remaining time, don't keep setup, bill, or last_bill dates,
2329   # and DO pass the flag to cancel() to credit the customer.  If the old
2330   # package had a setup date, set the new package's setup to the package
2331   # change date so that it has the same status as before.
2332   if ( $opt->{'pkgpart'}
2333        and $opt->{'pkgpart'} != $self->pkgpart
2334        and $self->part_pkg->option('unused_credit_change', 1) ) {
2335     $unused_credit = 1;
2336     $keep_dates = 0;
2337     $hash{'last_bill'} = '';
2338     $hash{'bill'} = '';
2339   }
2340
2341   if ( $keep_dates ) {
2342     foreach my $date ( qw(setup bill last_bill) ) {
2343       $hash{$date} = $self->getfield($date);
2344     }
2345   }
2346   # always keep the following dates
2347   foreach my $date (qw(order_date susp adjourn cancel expire resume
2348                     start_date contract_end)) {
2349     $hash{$date} = $self->getfield($date);
2350   }
2351   # but if contract_end was explicitly specified, that overrides all else
2352   $hash{'contract_end'} = $opt->{'contract_end'}
2353     if $opt->{'contract_end'};
2354
2355   # allow $opt->{'locationnum'} = '' to specifically set it to null
2356   # (i.e. customer default location)
2357   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2358
2359   # usually this doesn't matter.  the two cases where it does are:
2360   # 1. unused_credit_change + pkgpart change + setup fee on the new package
2361   # and
2362   # 2. (more importantly) changing a package before it's billed
2363   $hash{'waive_setup'} = $self->waive_setup;
2364
2365   # if this package is scheduled for a future package change, preserve that
2366   $hash{'change_to_pkgnum'} = $self->change_to_pkgnum;
2367
2368   my $custnum = $self->custnum;
2369   if ( $opt->{cust_main} ) {
2370     my $cust_main = $opt->{cust_main};
2371     unless ( $cust_main->custnum ) {
2372       my $error = $cust_main->insert( @{ $opt->{cust_main_insert_args}||[] } );
2373       if ( $error ) {
2374         $dbh->rollback if $oldAutoCommit;
2375         return "inserting customer record: $error";
2376       }
2377     }
2378     $custnum = $cust_main->custnum;
2379   }
2380
2381   $hash{'contactnum'} = $opt->{'contactnum'} if $opt->{'contactnum'};
2382
2383   my $cust_pkg;
2384   if ( $opt->{'cust_pkg'} ) {
2385     # The target package already exists; update it to show that it was
2386     # changed from this package.
2387     $cust_pkg = $opt->{'cust_pkg'};
2388
2389     # follow all the above rules for date changes, etc.
2390     foreach (keys %hash) {
2391       $cust_pkg->set($_, $hash{$_});
2392     }
2393     # except those that implement the future package change behavior
2394     foreach (qw(change_to_pkgnum start_date expire)) {
2395       $cust_pkg->set($_, '');
2396     }
2397
2398     $error = $cust_pkg->replace;
2399
2400   } else {
2401     # Create the new package.
2402     $cust_pkg = new FS::cust_pkg {
2403       custnum     => $custnum,
2404       locationnum => $opt->{'locationnum'},
2405       ( map {  $_ => ( $opt->{$_} || $self->$_() )  }
2406           qw( pkgpart quantity refnum salesnum )
2407       ),
2408       %hash,
2409     };
2410     $error = $cust_pkg->insert( 'change' => 1,
2411                                 'allow_pkgpart' => $same_pkgpart );
2412   }
2413   if ($error) {
2414     $dbh->rollback if $oldAutoCommit;
2415     return "inserting new package: $error";
2416   }
2417
2418   # Transfer services and cancel old package.
2419   # Enforce service limits only if this is a pkgpart change.
2420   local $FS::cust_svc::ignore_quantity;
2421   $FS::cust_svc::ignore_quantity = 1 if $same_pkgpart;
2422   $error = $self->transfer($cust_pkg);
2423   if ($error and $error == 0) {
2424     # $old_pkg->transfer failed.
2425     $dbh->rollback if $oldAutoCommit;
2426     return "transferring $error";
2427   }
2428
2429   if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
2430     warn "trying transfer again with change_svcpart option\n" if $DEBUG;
2431     $error = $self->transfer($cust_pkg, 'change_svcpart'=>1 );
2432     if ($error and $error == 0) {
2433       # $old_pkg->transfer failed.
2434       $dbh->rollback if $oldAutoCommit;
2435       return "converting $error";
2436     }
2437   }
2438
2439   # We set unprotect_svcs when executing a "future package change".  It's
2440   # not a user-interactive operation, so returning an error means the
2441   # package change will just fail.  Rather than have that happen, we'll
2442   # let leftover services be deleted.
2443   if ($error > 0 and !$opt->{'unprotect_svcs'}) {
2444     # Transfers were successful, but we still had services left on the old
2445     # package.  We can't change the package under this circumstances, so abort.
2446     $dbh->rollback if $oldAutoCommit;
2447     return "unable to transfer all services";
2448   }
2449
2450   #reset usage if changing pkgpart
2451   # AND usage rollover is off (otherwise adds twice, now and at package bill)
2452   if ($self->pkgpart != $cust_pkg->pkgpart) {
2453     my $part_pkg = $cust_pkg->part_pkg;
2454     $error = $part_pkg->reset_usage($cust_pkg, $part_pkg->is_prepaid
2455                                                  ? ()
2456                                                  : ( 'null' => 1 )
2457                                    )
2458       if $part_pkg->can('reset_usage') && ! $part_pkg->option('usage_rollover',1);
2459
2460     if ($error) {
2461       $dbh->rollback if $oldAutoCommit;
2462       return "setting usage values: $error";
2463     }
2464   } else {
2465     # if NOT changing pkgpart, transfer any usage pools over
2466     foreach my $usage ($self->cust_pkg_usage) {
2467       $usage->set('pkgnum', $cust_pkg->pkgnum);
2468       $error = $usage->replace;
2469       if ( $error ) {
2470         $dbh->rollback if $oldAutoCommit;
2471         return "transferring usage pools: $error";
2472       }
2473     }
2474   }
2475
2476   # transfer usage pricing add-ons, if we're not changing pkgpart or if they were specified
2477   if ( $same_pkgpart || $opt->{'cust_pkg_usageprice'}) {
2478     my @old_cust_pkg_usageprice;
2479     if ($opt->{'cust_pkg_usageprice'}) {
2480       @old_cust_pkg_usageprice = @{ $opt->{'cust_pkg_usageprice'} };
2481     } else {
2482       @old_cust_pkg_usageprice = $self->cust_pkg_usageprice;
2483     }
2484     foreach my $old_cust_pkg_usageprice (@old_cust_pkg_usageprice) {
2485       my $new_cust_pkg_usageprice = new FS::cust_pkg_usageprice {
2486         'pkgnum'         => $cust_pkg->pkgnum,
2487         'usagepricepart' => $old_cust_pkg_usageprice->usagepricepart,
2488         'quantity'       => $old_cust_pkg_usageprice->quantity,
2489       };
2490       $error = $new_cust_pkg_usageprice->insert;
2491       if ( $error ) {
2492         $dbh->rollback if $oldAutoCommit;
2493         return "Error transferring usage pricing add-on: $error";
2494       }
2495     }
2496   }
2497
2498   # transfer discounts, if we're not changing pkgpart
2499   if ( $same_pkgpart ) {
2500     foreach my $old_discount ($self->cust_pkg_discount_active) {
2501       # don't remove the old discount, we may still need to bill that package.
2502       my $new_discount = new FS::cust_pkg_discount {
2503         'pkgnum'      => $cust_pkg->pkgnum,
2504         'discountnum' => $old_discount->discountnum,
2505         'months_used' => $old_discount->months_used,
2506       };
2507       $error = $new_discount->insert;
2508       if ( $error ) {
2509         $dbh->rollback if $oldAutoCommit;
2510         return "transferring discounts: $error";
2511       }
2512     }
2513   }
2514
2515   # transfer (copy) invoice details
2516   foreach my $detail ($self->cust_pkg_detail) {
2517     my $new_detail = FS::cust_pkg_detail->new({ $detail->hash });
2518     $new_detail->set('pkgdetailnum', '');
2519     $new_detail->set('pkgnum', $cust_pkg->pkgnum);
2520     $error = $new_detail->insert;
2521     if ( $error ) {
2522       $dbh->rollback if $oldAutoCommit;
2523       return "transferring package notes: $error";
2524     }
2525   }
2526
2527   my @new_supp_pkgs;
2528
2529   if ( !$opt->{'cust_pkg'} ) {
2530     # Order any supplemental packages.
2531     my $part_pkg = $cust_pkg->part_pkg;
2532     my @old_supp_pkgs = $self->supplemental_pkgs;
2533     foreach my $link ($part_pkg->supp_part_pkg_link) {
2534       my $old;
2535       foreach (@old_supp_pkgs) {
2536         if ($_->pkgpart == $link->dst_pkgpart) {
2537           $old = $_;
2538           $_->pkgpart(0); # so that it can't match more than once
2539         }
2540         last if $old;
2541       }
2542       # false laziness with FS::cust_main::Packages::order_pkg
2543       my $new = FS::cust_pkg->new({
2544           pkgpart       => $link->dst_pkgpart,
2545           pkglinknum    => $link->pkglinknum,
2546           custnum       => $custnum,
2547           main_pkgnum   => $cust_pkg->pkgnum,
2548           locationnum   => $cust_pkg->locationnum,
2549           start_date    => $cust_pkg->start_date,
2550           order_date    => $cust_pkg->order_date,
2551           expire        => $cust_pkg->expire,
2552           adjourn       => $cust_pkg->adjourn,
2553           contract_end  => $cust_pkg->contract_end,
2554           refnum        => $cust_pkg->refnum,
2555           discountnum   => $cust_pkg->discountnum,
2556           waive_setup   => $cust_pkg->waive_setup,
2557       });
2558       if ( $old and $opt->{'keep_dates'} ) {
2559         foreach (qw(setup bill last_bill)) {
2560           $new->set($_, $old->get($_));
2561         }
2562       }
2563       $error = $new->insert( allow_pkgpart => $same_pkgpart );
2564       # transfer services
2565       if ( $old ) {
2566         $error ||= $old->transfer($new);
2567       }
2568       if ( $error and $error > 0 ) {
2569         # no reason why this should ever fail, but still...
2570         $error = "Unable to transfer all services from supplemental package ".
2571           $old->pkgnum;
2572       }
2573       if ( $error ) {
2574         $dbh->rollback if $oldAutoCommit;
2575         return $error;
2576       }
2577       push @new_supp_pkgs, $new;
2578     }
2579   } # if !$opt->{'cust_pkg'}
2580     # because if there is one, then supplemental packages would already
2581     # have been created for it.
2582
2583   #Good to go, cancel old package.  Notify 'cancel' of whether to credit
2584   #remaining time.
2585   #Don't allow billing the package (preceding period packages and/or
2586   #outstanding usage) if we are keeping dates (i.e. location changing),
2587   #because the new package will be billed for the same date range.
2588   #Supplemental packages are also canceled here.
2589
2590   # during scheduled changes, avoid canceling the package we just
2591   # changed to (duh)
2592   $self->set('change_to_pkgnum' => '');
2593
2594   $error = $self->cancel(
2595     quiet          => 1,
2596     unused_credit  => $unused_credit,
2597     nobill         => $keep_dates,
2598     change_custnum => ( $self->custnum != $custnum ? $custnum : '' ),
2599     no_delay_cancel => 1,
2600   );
2601   if ($error) {
2602     $dbh->rollback if $oldAutoCommit;
2603     return "canceling old package: $error";
2604   }
2605
2606   if ( $conf->exists('cust_pkg-change_pkgpart-bill_now') ) {
2607     #$self->cust_main
2608     my $error = $cust_pkg->cust_main->bill(
2609       'pkg_list' => [ $cust_pkg, @new_supp_pkgs ]
2610     );
2611     if ( $error ) {
2612       $dbh->rollback if $oldAutoCommit;
2613       return "billing new package: $error";
2614     }
2615   }
2616
2617   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2618
2619   $cust_pkg;
2620
2621 }
2622
2623 =item change_later OPTION => VALUE...
2624
2625 Schedule a package change for a later date.  This actually orders the new
2626 package immediately, but sets its start date for a future date, and sets
2627 the current package to expire on the same date.
2628
2629 If the package is already scheduled for a change, this can be called with
2630 'start_date' to change the scheduled date, or with pkgpart and/or
2631 locationnum to modify the package change.  To cancel the scheduled change
2632 entirely, see C<abort_change>.
2633
2634 Options include:
2635
2636 =over 4
2637
2638 =item start_date
2639
2640 The date for the package change.  Required, and must be in the future.
2641
2642 =item pkgpart
2643
2644 =item locationnum
2645
2646 =item quantity
2647
2648 =item contract_end
2649
2650 The pkgpart, locationnum, quantity and optional contract_end of the new
2651 package, with the same meaning as in C<change>.
2652
2653 =back
2654
2655 =cut
2656
2657 sub change_later {
2658   my $self = shift;
2659   my $opt = ref($_[0]) ? shift : { @_ };
2660
2661   # check contract_end, prevent adding/removing
2662   my $error = $self->_check_change($opt);
2663   return $error if $error;
2664
2665   my $oldAutoCommit = $FS::UID::AutoCommit;
2666   local $FS::UID::AutoCommit = 0;
2667   my $dbh = dbh;
2668
2669   my $cust_main = $self->cust_main;
2670
2671   my $date = delete $opt->{'start_date'} or return 'start_date required';
2672
2673   if ( $date <= time ) {
2674     $dbh->rollback if $oldAutoCommit;
2675     return "start_date $date is in the past";
2676   }
2677
2678   # If the user entered a new location, set it up now.
2679   if ( $opt->{'cust_location'} ) {
2680     $error = $opt->{'cust_location'}->find_or_insert;
2681     if ( $error ) {
2682       $dbh->rollback if $oldAutoCommit;
2683       return "creating location record: $error";
2684     }
2685     $opt->{'locationnum'} = $opt->{'cust_location'}->locationnum;
2686   }
2687
2688   if ( $self->change_to_pkgnum ) {
2689     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
2690     my $new_pkgpart = $opt->{'pkgpart'}
2691         if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $change_to->pkgpart;
2692     my $new_locationnum = $opt->{'locationnum'}
2693         if $opt->{'locationnum'} and $opt->{'locationnum'} != $change_to->locationnum;
2694     my $new_quantity = $opt->{'quantity'}
2695         if $opt->{'quantity'} and $opt->{'quantity'} != $change_to->quantity;
2696     my $new_contract_end = $opt->{'contract_end'}
2697         if $opt->{'contract_end'} and $opt->{'contract_end'} != $change_to->contract_end;
2698     if ( $new_pkgpart or $new_locationnum or $new_quantity or $new_contract_end ) {
2699       # it hasn't been billed yet, so in principle we could just edit
2700       # it in place (w/o a package change), but that's bad form.
2701       # So change the package according to the new options...
2702       my $err_or_pkg = $change_to->change(%$opt);
2703       if ( ref $err_or_pkg ) {
2704         # Then set that package up for a future start.
2705         $self->set('change_to_pkgnum', $err_or_pkg->pkgnum);
2706         $self->set('expire', $date); # in case it's different
2707         $err_or_pkg->set('start_date', $date);
2708         $err_or_pkg->set('change_date', '');
2709         $err_or_pkg->set('change_pkgnum', '');
2710
2711         $error = $self->replace       ||
2712                  $err_or_pkg->replace ||
2713                  #because change() might've edited existing scheduled change in place
2714                  (($err_or_pkg->pkgnum == $change_to->pkgnum) ? '' :
2715                   $change_to->cancel('no_delay_cancel' => 1) ||
2716                   $change_to->delete);
2717       } else {
2718         $error = $err_or_pkg;
2719       }
2720     } else { # change the start date only.
2721       $self->set('expire', $date);
2722       $change_to->set('start_date', $date);
2723       $error = $self->replace || $change_to->replace;
2724     }
2725     if ( $error ) {
2726       $dbh->rollback if $oldAutoCommit;
2727       return $error;
2728     } else {
2729       $dbh->commit if $oldAutoCommit;
2730       return '';
2731     }
2732   } # if $self->change_to_pkgnum
2733
2734   my $new_pkgpart = $opt->{'pkgpart'}
2735       if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart;
2736   my $new_locationnum = $opt->{'locationnum'}
2737       if $opt->{'locationnum'} and $opt->{'locationnum'} != $self->locationnum;
2738   my $new_quantity = $opt->{'quantity'}
2739       if $opt->{'quantity'} and $opt->{'quantity'} != $self->quantity;
2740   my $new_contract_end = $opt->{'contract_end'}
2741       if $opt->{'contract_end'} and $opt->{'contract_end'} != $self->contract_end;
2742
2743   return '' unless $new_pkgpart or $new_locationnum or $new_quantity or $new_contract_end; # wouldn't do anything
2744
2745   # allow $opt->{'locationnum'} = '' to specifically set it to null
2746   # (i.e. customer default location)
2747   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2748
2749   my $new = FS::cust_pkg->new( {
2750     custnum     => $self->custnum,
2751     locationnum => $opt->{'locationnum'},
2752     start_date  => $date,
2753     map   {  $_ => ( $opt->{$_} || $self->$_() )  }
2754       qw( pkgpart quantity refnum salesnum contract_end )
2755   } );
2756   $error = $new->insert('change' => 1,
2757                         'allow_pkgpart' => ($new_pkgpart ? 0 : 1));
2758   if ( !$error ) {
2759     $self->set('change_to_pkgnum', $new->pkgnum);
2760     $self->set('expire', $date);
2761     $error = $self->replace;
2762   }
2763   if ( $error ) {
2764     $dbh->rollback if $oldAutoCommit;
2765   } else {
2766     $dbh->commit if $oldAutoCommit;
2767   }
2768
2769   $error;
2770 }
2771
2772 =item abort_change
2773
2774 Cancels a future package change scheduled by C<change_later>.
2775
2776 =cut
2777
2778 sub abort_change {
2779   my $self = shift;
2780   my $oldAutoCommit = $FS::UID::AutoCommit;
2781   local $FS::UID::AutoCommit = 0;
2782
2783   my $pkgnum = $self->change_to_pkgnum;
2784   my $change_to = FS::cust_pkg->by_key($pkgnum) if $pkgnum;
2785   my $error;
2786   $self->set('change_to_pkgnum', '');
2787   $self->set('expire', '');
2788   $error = $self->replace;
2789   if ( $change_to ) {
2790     $error ||= $change_to->cancel || $change_to->delete;
2791   }
2792
2793   if ( $oldAutoCommit ) {
2794     if ( $error ) {
2795       dbh->rollback;
2796     } else {
2797       dbh->commit;
2798     }
2799   }
2800
2801   return $error;
2802 }
2803
2804 =item set_quantity QUANTITY
2805
2806 Change the package's quantity field.  This is one of the few package properties
2807 that can safely be changed without canceling and reordering the package
2808 (because it doesn't affect tax eligibility).  Returns an error or an
2809 empty string.
2810
2811 =cut
2812
2813 sub set_quantity {
2814   my $self = shift;
2815   $self = $self->replace_old; # just to make sure
2816   $self->quantity(shift);
2817   $self->replace;
2818 }
2819
2820 =item set_salesnum SALESNUM
2821
2822 Change the package's salesnum (sales person) field.  This is one of the few
2823 package properties that can safely be changed without canceling and reordering
2824 the package (because it doesn't affect tax eligibility).  Returns an error or
2825 an empty string.
2826
2827 =cut
2828
2829 sub set_salesnum {
2830   my $self = shift;
2831   $self = $self->replace_old; # just to make sure
2832   $self->salesnum(shift);
2833   $self->replace;
2834   # XXX this should probably reassign any credit that's already been given
2835 }
2836
2837 =item modify_charge OPTIONS
2838
2839 Change the properties of a one-time charge.  The following properties can
2840 be changed this way:
2841 - pkg: the package description
2842 - classnum: the package class
2843 - additional: arrayref of additional invoice details to add to this package
2844
2845 and, I<if the charge has not yet been billed>:
2846 - start_date: the date when it will be billed
2847 - amount: the setup fee to be charged
2848 - quantity: the multiplier for the setup fee
2849 - separate_bill: whether to put the charge on a separate invoice
2850
2851 If you pass 'adjust_commission' => 1, and the classnum changes, and there are
2852 commission credits linked to this charge, they will be recalculated.
2853
2854 =cut
2855
2856 sub modify_charge {
2857   my $self = shift;
2858   my %opt = @_;
2859   my $part_pkg = $self->part_pkg;
2860   my $pkgnum = $self->pkgnum;
2861
2862   my $dbh = dbh;
2863   my $oldAutoCommit = $FS::UID::AutoCommit;
2864   local $FS::UID::AutoCommit = 0;
2865
2866   return "Can't use modify_charge except on one-time charges"
2867     unless $part_pkg->freq eq '0';
2868
2869   if ( length($opt{'pkg'}) and $part_pkg->pkg ne $opt{'pkg'} ) {
2870     $part_pkg->set('pkg', $opt{'pkg'});
2871   }
2872
2873   my %pkg_opt = $part_pkg->options;
2874   my $pkg_opt_modified = 0;
2875
2876   $opt{'additional'} ||= [];
2877   my $i;
2878   my @old_additional;
2879   foreach (grep /^additional/, keys %pkg_opt) {
2880     ($i) = ($_ =~ /^additional_info(\d+)$/);
2881     $old_additional[$i] = $pkg_opt{$_} if $i;
2882     delete $pkg_opt{$_};
2883   }
2884
2885   for ( $i = 0; exists($opt{'additional'}->[$i]); $i++ ) {
2886     $pkg_opt{ "additional_info$i" } = $opt{'additional'}->[$i];
2887     if (!exists($old_additional[$i])
2888         or $old_additional[$i] ne $opt{'additional'}->[$i])
2889     {
2890       $pkg_opt_modified = 1;
2891     }
2892   }
2893   $pkg_opt_modified = 1 if (scalar(@old_additional) - 1) != $i;
2894   $pkg_opt{'additional_count'} = $i if $i > 0;
2895
2896   my $old_classnum;
2897   if ( exists($opt{'classnum'}) and $part_pkg->classnum ne $opt{'classnum'} )
2898   {
2899     # remember it
2900     $old_classnum = $part_pkg->classnum;
2901     $part_pkg->set('classnum', $opt{'classnum'});
2902   }
2903
2904   if ( !$self->get('setup') ) {
2905     # not yet billed, so allow amount, setup_cost, quantity, start_date,
2906     # and separate_bill
2907
2908     if ( exists($opt{'amount'})
2909           and $part_pkg->option('setup_fee') != $opt{'amount'}
2910           and $opt{'amount'} > 0 ) {
2911
2912       $pkg_opt{'setup_fee'} = $opt{'amount'};
2913       $pkg_opt_modified = 1;
2914     }
2915
2916     if ( exists($opt{'setup_cost'})
2917           and $part_pkg->setup_cost != $opt{'setup_cost'}
2918           and $opt{'setup_cost'} > 0 ) {
2919
2920       $part_pkg->set('setup_cost', $opt{'setup_cost'});
2921     }
2922
2923     if ( exists($opt{'quantity'})
2924           and $opt{'quantity'} != $self->quantity
2925           and $opt{'quantity'} > 0 ) {
2926
2927       $self->set('quantity', $opt{'quantity'});
2928     }
2929
2930     if ( exists($opt{'start_date'})
2931           and $opt{'start_date'} != $self->start_date ) {
2932
2933       $self->set('start_date', $opt{'start_date'});
2934     }
2935
2936     if ( exists($opt{'separate_bill'})
2937           and $opt{'separate_bill'} ne $self->separate_bill ) {
2938
2939       $self->set('separate_bill', $opt{'separate_bill'});
2940     }
2941
2942
2943   } # else simply ignore them; the UI shouldn't allow editing the fields
2944
2945
2946   if ( exists($opt{'taxclass'})
2947           and $part_pkg->taxclass ne $opt{'taxclass'}) {
2948
2949       $part_pkg->set('taxclass', $opt{'taxclass'});
2950   }
2951
2952   my $error;
2953   if ( $part_pkg->modified or $pkg_opt_modified ) {
2954     # can we safely modify the package def?
2955     # Yes, if it's not available for purchase, and this is the only instance
2956     # of it.
2957     if ( $part_pkg->disabled
2958          and FS::cust_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 1
2959          and FS::quotation_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 0
2960        ) {
2961       $error = $part_pkg->replace( options => \%pkg_opt );
2962     } else {
2963       # clone it
2964       $part_pkg = $part_pkg->clone;
2965       $part_pkg->set('disabled' => 'Y');
2966       $error = $part_pkg->insert( options => \%pkg_opt );
2967       # and associate this as yet-unbilled package to the new package def
2968       $self->set('pkgpart' => $part_pkg->pkgpart);
2969     }
2970     if ( $error ) {
2971       $dbh->rollback if $oldAutoCommit;
2972       return $error;
2973     }
2974   }
2975
2976   if ($self->modified) { # for quantity or start_date change, or if we had
2977                          # to clone the existing package def
2978     my $error = $self->replace;
2979     return $error if $error;
2980   }
2981   if (defined $old_classnum) {
2982     # fix invoice grouping records
2983     my $old_catname = $old_classnum
2984                       ? FS::pkg_class->by_key($old_classnum)->categoryname
2985                       : '';
2986     my $new_catname = $opt{'classnum'}
2987                       ? $part_pkg->pkg_class->categoryname
2988                       : '';
2989     if ( $old_catname ne $new_catname ) {
2990       foreach my $cust_bill_pkg ($self->cust_bill_pkg) {
2991         # (there should only be one...)
2992         my @display = qsearch( 'cust_bill_pkg_display', {
2993             'billpkgnum'  => $cust_bill_pkg->billpkgnum,
2994             'section'     => $old_catname,
2995         });
2996         foreach (@display) {
2997           $_->set('section', $new_catname);
2998           $error = $_->replace;
2999           if ( $error ) {
3000             $dbh->rollback if $oldAutoCommit;
3001             return $error;
3002           }
3003         }
3004       } # foreach $cust_bill_pkg
3005     }
3006
3007     if ( $opt{'adjust_commission'} ) {
3008       # fix commission credits...tricky.
3009       foreach my $cust_event ($self->cust_event) {
3010         my $part_event = $cust_event->part_event;
3011         foreach my $table (qw(sales agent)) {
3012           my $class =
3013             "FS::part_event::Action::Mixin::credit_${table}_pkg_class";
3014           my $credit = qsearchs('cust_credit', {
3015               'eventnum' => $cust_event->eventnum,
3016           });
3017           if ( $part_event->isa($class) ) {
3018             # Yes, this results in current commission rates being applied
3019             # retroactively to a one-time charge.  For accounting purposes
3020             # there ought to be some kind of time limit on doing this.
3021             my $amount = $part_event->_calc_credit($self);
3022             if ( $credit and $credit->amount ne $amount ) {
3023               # Void the old credit.
3024               $error = $credit->void('Package class changed');
3025               if ( $error ) {
3026                 $dbh->rollback if $oldAutoCommit;
3027                 return "$error (adjusting commission credit)";
3028               }
3029             }
3030             # redo the event action to recreate the credit.
3031             local $@ = '';
3032             eval { $part_event->do_action( $self, $cust_event ) };
3033             if ( $@ ) {
3034               $dbh->rollback if $oldAutoCommit;
3035               return $@;
3036             }
3037           } # if $part_event->isa($class)
3038         } # foreach $table
3039       } # foreach $cust_event
3040     } # if $opt{'adjust_commission'}
3041   } # if defined $old_classnum
3042
3043   $dbh->commit if $oldAutoCommit;
3044   '';
3045 }
3046
3047
3048
3049 use Data::Dumper;
3050 sub process_bulk_cust_pkg {
3051   my $job = shift;
3052   my $param = shift;
3053   warn Dumper($param) if $DEBUG;
3054
3055   my $old_part_pkg = qsearchs('part_pkg',
3056                               { pkgpart => $param->{'old_pkgpart'} });
3057   my $new_part_pkg = qsearchs('part_pkg',
3058                               { pkgpart => $param->{'new_pkgpart'} });
3059   die "Must select a new package type\n" unless $new_part_pkg;
3060   #my $keep_dates = $param->{'keep_dates'} || 0;
3061   my $keep_dates = 1; # there is no good reason to turn this off
3062
3063   my $oldAutoCommit = $FS::UID::AutoCommit;
3064   local $FS::UID::AutoCommit = 0;
3065   my $dbh = dbh;
3066
3067   my @cust_pkgs = qsearch('cust_pkg', { 'pkgpart' => $param->{'old_pkgpart'} } );
3068
3069   my $i = 0;
3070   foreach my $old_cust_pkg ( @cust_pkgs ) {
3071     $i++;
3072     $job->update_statustext(int(100*$i/(scalar @cust_pkgs)));
3073     if ( $old_cust_pkg->getfield('cancel') ) {
3074       warn '[process_bulk_cust_pkg ] skipping canceled pkgnum '.
3075         $old_cust_pkg->pkgnum."\n"
3076         if $DEBUG;
3077       next;
3078     }
3079     warn '[process_bulk_cust_pkg] changing pkgnum '.$old_cust_pkg->pkgnum."\n"
3080       if $DEBUG;
3081     my $error = $old_cust_pkg->change(
3082       'pkgpart'     => $param->{'new_pkgpart'},
3083       'keep_dates'  => $keep_dates
3084     );
3085     if ( !ref($error) ) { # change returns the cust_pkg on success
3086       $dbh->rollback;
3087       die "Error changing pkgnum ".$old_cust_pkg->pkgnum.": '$error'\n";
3088     }
3089   }
3090   $dbh->commit if $oldAutoCommit;
3091   return;
3092 }
3093
3094 =item last_bill
3095
3096 Returns the last bill date, or if there is no last bill date, the setup date.
3097 Useful for billing metered services.
3098
3099 =cut
3100
3101 sub last_bill {
3102   my $self = shift;
3103   return $self->setfield('last_bill', $_[0]) if @_;
3104   return $self->getfield('last_bill') if $self->getfield('last_bill');
3105   my $cust_bill_pkg = qsearchs('cust_bill_pkg', { 'pkgnum' => $self->pkgnum,
3106                                                   'edate'  => $self->bill,  } );
3107   $cust_bill_pkg ? $cust_bill_pkg->sdate : $self->setup || 0;
3108 }
3109
3110 =item last_cust_pkg_reason ACTION
3111
3112 Returns the most recent ACTION FS::cust_pkg_reason associated with the package.
3113 Returns false if there is no reason or the package is not currenly ACTION'd
3114 ACTION is one of adjourn, susp, cancel, or expire.
3115
3116 =cut
3117
3118 sub last_cust_pkg_reason {
3119   my ( $self, $action ) = ( shift, shift );
3120   my $date = $self->get($action);
3121   qsearchs( {
3122               'table' => 'cust_pkg_reason',
3123               'hashref' => { 'pkgnum' => $self->pkgnum,
3124                              'action' => substr(uc($action), 0, 1),
3125                              'date'   => $date,
3126                            },
3127               'order_by' => 'ORDER BY num DESC LIMIT 1',
3128            } );
3129 }
3130
3131 =item last_reason ACTION
3132
3133 Returns the most recent ACTION FS::reason associated with the package.
3134 Returns false if there is no reason or the package is not currenly ACTION'd
3135 ACTION is one of adjourn, susp, cancel, or expire.
3136
3137 =cut
3138
3139 sub last_reason {
3140   my $cust_pkg_reason = shift->last_cust_pkg_reason(@_);
3141   $cust_pkg_reason->reason
3142     if $cust_pkg_reason;
3143 }
3144
3145 =item part_pkg
3146
3147 Returns the definition for this billing item, as an FS::part_pkg object (see
3148 L<FS::part_pkg>).
3149
3150 =cut
3151
3152 sub part_pkg {
3153   my $self = shift;
3154   return $self->{'_pkgpart'} if $self->{'_pkgpart'};
3155   cluck "cust_pkg->part_pkg called" if $DEBUG > 1;
3156   qsearchs( 'part_pkg', { 'pkgpart' => $self->pkgpart } );
3157 }
3158
3159 =item old_cust_pkg
3160
3161 Returns the cancelled package this package was changed from, if any.
3162
3163 =cut
3164
3165 sub old_cust_pkg {
3166   my $self = shift;
3167   return '' unless $self->change_pkgnum;
3168   qsearchs('cust_pkg', { 'pkgnum' => $self->change_pkgnum } );
3169 }
3170
3171 =item change_cust_main
3172
3173 Returns the customter this package was detached to, if any.
3174
3175 =cut
3176
3177 sub change_cust_main {
3178   my $self = shift;
3179   return '' unless $self->change_custnum;
3180   qsearchs('cust_main', { 'custnum' => $self->change_custnum } );
3181 }
3182
3183 =item calc_setup
3184
3185 Calls the I<calc_setup> of the FS::part_pkg object associated with this billing
3186 item.
3187
3188 =cut
3189
3190 sub calc_setup {
3191   my $self = shift;
3192   $self->part_pkg->calc_setup($self, @_);
3193 }
3194
3195 =item calc_recur
3196
3197 Calls the I<calc_recur> of the FS::part_pkg object associated with this billing
3198 item.
3199
3200 =cut
3201
3202 sub calc_recur {
3203   my $self = shift;
3204   $self->part_pkg->calc_recur($self, @_);
3205 }
3206
3207 =item base_setup
3208
3209 Calls the I<base_setup> of the FS::part_pkg object associated with this billing
3210 item.
3211
3212 =cut
3213
3214 sub base_setup {
3215   my $self = shift;
3216   $self->part_pkg->base_setup($self, @_);
3217 }
3218
3219 =item base_recur
3220
3221 Calls the I<base_recur> of the FS::part_pkg object associated with this billing
3222 item.
3223
3224 =cut
3225
3226 sub base_recur {
3227   my $self = shift;
3228   $self->part_pkg->base_recur($self, @_);
3229 }
3230
3231 =item calc_remain
3232
3233 Calls the I<calc_remain> of the FS::part_pkg object associated with this
3234 billing item.
3235
3236 =cut
3237
3238 sub calc_remain {
3239   my $self = shift;
3240   $self->part_pkg->calc_remain($self, @_);
3241 }
3242
3243 =item calc_cancel
3244
3245 Calls the I<calc_cancel> of the FS::part_pkg object associated with this
3246 billing item.
3247
3248 =cut
3249
3250 sub calc_cancel {
3251   my $self = shift;
3252   $self->part_pkg->calc_cancel($self, @_);
3253 }
3254
3255 =item cust_bill_pkg
3256
3257 Returns any invoice line items for this package (see L<FS::cust_bill_pkg>).
3258
3259 =cut
3260
3261 sub cust_bill_pkg {
3262   my $self = shift;
3263   qsearch( 'cust_bill_pkg', { 'pkgnum' => $self->pkgnum } );
3264 }
3265
3266 =item cust_pkg_detail [ DETAILTYPE ]
3267
3268 Returns any customer package details for this package (see
3269 L<FS::cust_pkg_detail>).
3270
3271 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
3272
3273 =cut
3274
3275 sub cust_pkg_detail {
3276   my $self = shift;
3277   my %hash = ( 'pkgnum' => $self->pkgnum );
3278   $hash{detailtype} = shift if @_;
3279   qsearch({
3280     'table'    => 'cust_pkg_detail',
3281     'hashref'  => \%hash,
3282     'order_by' => 'ORDER BY weight, pkgdetailnum',
3283   });
3284 }
3285
3286 =item set_cust_pkg_detail DETAILTYPE [ DETAIL, DETAIL, ... ]
3287
3288 Sets customer package details for this package (see L<FS::cust_pkg_detail>).
3289
3290 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
3291
3292 If there is an error, returns the error, otherwise returns false.
3293
3294 =cut
3295
3296 sub set_cust_pkg_detail {
3297   my( $self, $detailtype, @details ) = @_;
3298
3299   my $oldAutoCommit = $FS::UID::AutoCommit;
3300   local $FS::UID::AutoCommit = 0;
3301   my $dbh = dbh;
3302
3303   foreach my $current ( $self->cust_pkg_detail($detailtype) ) {
3304     my $error = $current->delete;
3305     if ( $error ) {
3306       $dbh->rollback if $oldAutoCommit;
3307       return "error removing old detail: $error";
3308     }
3309   }
3310
3311   foreach my $detail ( @details ) {
3312     my $cust_pkg_detail = new FS::cust_pkg_detail {
3313       'pkgnum'     => $self->pkgnum,
3314       'detailtype' => $detailtype,
3315       'detail'     => $detail,
3316     };
3317     my $error = $cust_pkg_detail->insert;
3318     if ( $error ) {
3319       $dbh->rollback if $oldAutoCommit;
3320       return "error adding new detail: $error";
3321     }
3322
3323   }
3324
3325   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3326   '';
3327
3328 }
3329
3330 =item cust_event
3331
3332 Returns the customer billing events (see L<FS::cust_event>) for this invoice.
3333
3334 =cut
3335
3336 #false laziness w/cust_bill.pm
3337 sub cust_event {
3338   my $self = shift;
3339   qsearch({
3340     'table'     => 'cust_event',
3341     'addl_from' => 'JOIN part_event USING ( eventpart )',
3342     'hashref'   => { 'tablenum' => $self->pkgnum },
3343     'extra_sql' => " AND eventtable = 'cust_pkg' ",
3344   });
3345 }
3346
3347 =item num_cust_event
3348
3349 Returns the number of customer billing events (see L<FS::cust_event>) for this package.
3350
3351 =cut
3352
3353 #false laziness w/cust_bill.pm
3354 sub num_cust_event {
3355   my $self = shift;
3356   my $sql = "SELECT COUNT(*) ". $self->_from_cust_event_where;
3357   $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref->[0];
3358 }
3359
3360 =item exists_cust_event
3361
3362 Returns true if there are customer billing events (see L<FS::cust_event>) for this package.  More efficient than using num_cust_event.
3363
3364 =cut
3365
3366 sub exists_cust_event {
3367   my $self = shift;
3368   my $sql = "SELECT 1 ". $self->_from_cust_event_where. " LIMIT 1";
3369   my $row = $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref;
3370   $row ? $row->[0] : '';
3371 }
3372
3373 sub _from_cust_event_where {
3374   #my $self = shift;
3375   " FROM cust_event JOIN part_event USING ( eventpart ) ".
3376   "  WHERE tablenum = ? AND eventtable = 'cust_pkg' ";
3377 }
3378
3379 sub _prep_ex {
3380   my( $self, $sql, @args ) = @_;
3381   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
3382   $sth->execute(@args)         or die $sth->errstr. " executing $sql";
3383   $sth;
3384 }
3385
3386 =item part_pkg_currency_option OPTIONNAME
3387
3388 Returns a two item list consisting of the currency of this customer, if any,
3389 and a value for the provided option.  If the customer has a currency, the value
3390 is the option value the given name and the currency (see
3391 L<FS::part_pkg_currency>).  Otherwise, if the customer has no currency, is the
3392 regular option value for the given name (see L<FS::part_pkg_option>).
3393
3394 =cut
3395
3396 sub part_pkg_currency_option {
3397   my( $self, $optionname ) = @_;
3398   my $part_pkg = $self->part_pkg;
3399   if ( my $currency = $self->cust_main->currency ) {
3400     ($currency, $part_pkg->part_pkg_currency_option($currency, $optionname) );
3401   } else {
3402     ('', $part_pkg->option($optionname) );
3403   }
3404 }
3405
3406 =item cust_svc [ SVCPART ] (old, deprecated usage)
3407
3408 =item cust_svc [ OPTION => VALUE ... ] (current usage)
3409
3410 =item cust_svc_unsorted [ OPTION => VALUE ... ]
3411
3412 Returns the services for this package, as FS::cust_svc objects (see
3413 L<FS::cust_svc>).  Available options are svcpart and svcdb.  If either is
3414 spcififed, returns only the matching services.
3415
3416 As an optimization, use the cust_svc_unsorted version if you are not displaying
3417 the results.
3418
3419 =cut
3420
3421 sub cust_svc {
3422   my $self = shift;
3423   cluck "cust_pkg->cust_svc called" if $DEBUG > 2;
3424   $self->_sort_cust_svc( $self->cust_svc_unsorted_arrayref(@_) );
3425 }
3426
3427 sub cust_svc_unsorted {
3428   my $self = shift;
3429   @{ $self->cust_svc_unsorted_arrayref(@_) };
3430 }
3431
3432 sub cust_svc_unsorted_arrayref {
3433   my $self = shift;
3434
3435   return [] unless $self->num_cust_svc(@_);
3436
3437   my %opt = ();
3438   if ( @_ && $_[0] =~ /^\d+/ ) {
3439     $opt{svcpart} = shift;
3440   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3441     %opt = %{ $_[0] };
3442   } elsif ( @_ ) {
3443     %opt = @_;
3444   }
3445
3446   my %search = (
3447     'select'    => 'cust_svc.*, part_svc.*',
3448     'table'     => 'cust_svc',
3449     'hashref'   => { 'pkgnum' => $self->pkgnum },
3450     'addl_from' => 'LEFT JOIN part_svc USING ( svcpart )',
3451   );
3452   $search{hashref}->{svcpart} = $opt{svcpart}
3453     if $opt{svcpart};
3454   $search{extra_sql} = ' AND svcdb = '. dbh->quote( $opt{svcdb} )
3455     if $opt{svcdb};
3456
3457   [ qsearch(\%search) ];
3458
3459 }
3460
3461 =item overlimit [ SVCPART ]
3462
3463 Returns the services for this package which have exceeded their
3464 usage limit as FS::cust_svc objects (see L<FS::cust_svc>).  If a svcpart
3465 is specified, return only the matching services.
3466
3467 =cut
3468
3469 sub overlimit {
3470   my $self = shift;
3471   return () unless $self->num_cust_svc(@_);
3472   grep { $_->overlimit } $self->cust_svc(@_);
3473 }
3474
3475 =item h_cust_svc END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3476
3477 Returns historical services for this package created before END TIMESTAMP and
3478 (optionally) not cancelled before START_TIMESTAMP, as FS::h_cust_svc objects
3479 (see L<FS::h_cust_svc>).  If MODE is 'I' (for 'invoice'), services with the
3480 I<pkg_svc.hidden> flag will be omitted.
3481
3482 =cut
3483
3484 sub h_cust_svc {
3485   my $self = shift;
3486   warn "$me _h_cust_svc called on $self\n"
3487     if $DEBUG;
3488
3489   my ($end, $start, $mode) = @_;
3490
3491   local($FS::Record::qsearch_qualify_columns) = 0;
3492
3493   my @cust_svc = $self->_sort_cust_svc(
3494     [ qsearch( 'h_cust_svc',
3495       { 'pkgnum' => $self->pkgnum, },
3496       FS::h_cust_svc->sql_h_search(@_),
3497     ) ]
3498   );
3499
3500   if ( defined($mode) && $mode eq 'I' ) {
3501     my %hidden_svcpart = map { $_->svcpart => $_->hidden } $self->part_svc;
3502     return grep { !$hidden_svcpart{$_->svcpart} } @cust_svc;
3503   } else {
3504     return @cust_svc;
3505   }
3506 }
3507
3508 sub _sort_cust_svc {
3509   my( $self, $arrayref ) = @_;
3510
3511   my $sort =
3512     sub ($$) { my ($a, $b) = @_; $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] };
3513
3514   my %pkg_svc = map { $_->svcpart => $_ }
3515                 qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
3516
3517   map  { $_->[0] }
3518   sort $sort
3519   map {
3520         my $pkg_svc = $pkg_svc{ $_->svcpart } || '';
3521         [ $_,
3522           $pkg_svc ? $pkg_svc->primary_svc : '',
3523           $pkg_svc ? $pkg_svc->quantity : 0,
3524         ];
3525       }
3526   @$arrayref;
3527
3528 }
3529
3530 =item num_cust_svc [ SVCPART ] (old, deprecated usage)
3531
3532 =item num_cust_svc [ OPTION => VALUE ... ] (current usage)
3533
3534 Returns the number of services for this package.  Available options are svcpart
3535 and svcdb.  If either is spcififed, returns only the matching services.
3536
3537 =cut
3538
3539 sub num_cust_svc {
3540   my $self = shift;
3541
3542   return $self->{'_num_cust_svc'}
3543     if !scalar(@_)
3544        && exists($self->{'_num_cust_svc'})
3545        && $self->{'_num_cust_svc'} =~ /\d/;
3546
3547   cluck "cust_pkg->num_cust_svc called, _num_cust_svc:".$self->{'_num_cust_svc'}
3548     if $DEBUG > 2;
3549
3550   my %opt = ();
3551   if ( @_ && $_[0] =~ /^\d+/ ) {
3552     $opt{svcpart} = shift;
3553   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3554     %opt = %{ $_[0] };
3555   } elsif ( @_ ) {
3556     %opt = @_;
3557   }
3558
3559   my $select = 'SELECT COUNT(*) FROM cust_svc ';
3560   my $where = ' WHERE pkgnum = ? ';
3561   my @param = ($self->pkgnum);
3562
3563   if ( $opt{'svcpart'} ) {
3564     $where .= ' AND svcpart = ? ';
3565     push @param, $opt{'svcpart'};
3566   }
3567   if ( $opt{'svcdb'} ) {
3568     $select .= ' LEFT JOIN part_svc USING ( svcpart ) ';
3569     $where .= ' AND svcdb = ? ';
3570     push @param, $opt{'svcdb'};
3571   }
3572
3573   my $sth = dbh->prepare("$select $where") or die  dbh->errstr;
3574   $sth->execute(@param) or die $sth->errstr;
3575   $sth->fetchrow_arrayref->[0];
3576 }
3577
3578 =item available_part_svc
3579
3580 Returns a list of FS::part_svc objects representing services included in this
3581 package but not yet provisioned.  Each FS::part_svc object also has an extra
3582 field, I<num_avail>, which specifies the number of available services.
3583
3584 Accepts option I<provision_hold>;  if true, only returns part_svc for which the
3585 associated pkg_svc has the provision_hold flag set.
3586
3587 =cut
3588
3589 sub available_part_svc {
3590   my $self = shift;
3591   my %opt  = @_;
3592
3593   my $pkg_quantity = $self->quantity || 1;
3594
3595   grep { $_->num_avail > 0 }
3596   map {
3597     my $part_svc = $_->part_svc;
3598     $part_svc->{'Hash'}{'num_avail'} = #evil encapsulation-breaking
3599     $pkg_quantity * $_->quantity - $self->num_cust_svc($_->svcpart);
3600
3601     # more evil encapsulation breakage
3602     if ($part_svc->{'Hash'}{'num_avail'} > 0) {
3603       my @exports = $part_svc->part_export_did;
3604       $part_svc->{'Hash'}{'can_get_dids'} = scalar(@exports);
3605         }
3606
3607     $part_svc;
3608   }
3609   grep { $opt{'provision_hold'} ? $_->provision_hold : 1 }
3610   $self->part_pkg->pkg_svc;
3611 }
3612
3613 =item part_svc [ OPTION => VALUE ... ]
3614
3615 Returns a list of FS::part_svc objects representing provisioned and available
3616 services included in this package.  Each FS::part_svc object also has the
3617 following extra fields:
3618
3619 =over 4
3620
3621 =item num_cust_svc
3622
3623 (count)
3624
3625 =item num_avail
3626
3627 (quantity - count)
3628
3629 =item cust_pkg_svc
3630
3631 (services) - array reference containing the provisioned services, as cust_svc objects
3632
3633 =back
3634
3635 Accepts two options:
3636
3637 =over 4
3638
3639 =item summarize_size
3640
3641 If true, will omit the extra cust_pkg_svc option for objects where num_cust_svc
3642 is this size or greater.
3643
3644 =item hide_discontinued
3645
3646 If true, will omit looking for services that are no longer avaialble in the
3647 package definition.
3648
3649 =back
3650
3651 =cut
3652
3653 #svcnum
3654 #label -> ($cust_svc->label)[1]
3655
3656 sub part_svc {
3657   my $self = shift;
3658   my %opt = @_;
3659
3660   my $pkg_quantity = $self->quantity || 1;
3661
3662   #XXX some sort of sort order besides numeric by svcpart...
3663   my @part_svc = sort { $a->svcpart <=> $b->svcpart } map {
3664     my $pkg_svc = $_;
3665     my $part_svc = $pkg_svc->part_svc;
3666     my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3667     $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #more evil
3668     $part_svc->{'Hash'}{'num_avail'}    =
3669       max( 0, $pkg_quantity * $pkg_svc->quantity - $num_cust_svc );
3670     $part_svc->{'Hash'}{'cust_pkg_svc'} =
3671         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : []
3672       unless exists($opt{summarize_size}) && $opt{summarize_size} > 0
3673           && $num_cust_svc >= $opt{summarize_size};
3674     $part_svc->{'Hash'}{'hidden'} = $pkg_svc->hidden;
3675     $part_svc;
3676   } $self->part_pkg->pkg_svc;
3677
3678   unless ( $opt{hide_discontinued} ) {
3679     #extras
3680     push @part_svc, map {
3681       my $part_svc = $_;
3682       my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3683       $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #speak no evail
3684       $part_svc->{'Hash'}{'num_avail'}    = 0; #0-$num_cust_svc ?
3685       $part_svc->{'Hash'}{'cust_pkg_svc'} =
3686         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : [];
3687       $part_svc;
3688     } $self->extra_part_svc;
3689   }
3690
3691   @part_svc;
3692
3693 }
3694
3695 =item extra_part_svc
3696
3697 Returns a list of FS::part_svc objects corresponding to services in this
3698 package which are still provisioned but not (any longer) available in the
3699 package definition.
3700
3701 =cut
3702
3703 sub extra_part_svc {
3704   my $self = shift;
3705
3706   my $pkgnum  = $self->pkgnum;
3707   #my $pkgpart = $self->pkgpart;
3708
3709 #  qsearch( {
3710 #    'table'     => 'part_svc',
3711 #    'hashref'   => {},
3712 #    'extra_sql' =>
3713 #      "WHERE 0 = ( SELECT COUNT(*) FROM pkg_svc
3714 #                     WHERE pkg_svc.svcpart = part_svc.svcpart
3715 #                       AND pkg_svc.pkgpart = ?
3716 #                       AND quantity > 0
3717 #                 )
3718 #        AND 0 < ( SELECT COUNT(*) FROM cust_svc
3719 #                       LEFT JOIN cust_pkg USING ( pkgnum )
3720 #                     WHERE cust_svc.svcpart = part_svc.svcpart
3721 #                       AND pkgnum = ?
3722 #                 )",
3723 #    'extra_param' => [ [$self->pkgpart=>'int'], [$self->pkgnum=>'int'] ],
3724 #  } );
3725
3726 #seems to benchmark slightly faster... (or did?)
3727
3728   my @pkgparts = map $_->pkgpart, $self->part_pkg->self_and_svc_linked;
3729   my $pkgparts = join(',', @pkgparts);
3730
3731   qsearch( {
3732     #'select'      => 'DISTINCT ON (svcpart) part_svc.*',
3733     #MySQL doesn't grok DISINCT ON
3734     'select'      => 'DISTINCT part_svc.*',
3735     'table'       => 'part_svc',
3736     'addl_from'   =>
3737       "LEFT JOIN pkg_svc  ON (     pkg_svc.svcpart   = part_svc.svcpart
3738                                AND pkg_svc.pkgpart IN ($pkgparts)
3739                                AND quantity > 0
3740                              )
3741        LEFT JOIN cust_svc ON (     cust_svc.svcpart = part_svc.svcpart )
3742        LEFT JOIN cust_pkg USING ( pkgnum )
3743       ",
3744     'hashref'     => {},
3745     'extra_sql'   => "WHERE pkgsvcnum IS NULL AND cust_pkg.pkgnum = ? ",
3746     'extra_param' => [ [$self->pkgnum=>'int'] ],
3747   } );
3748 }
3749
3750 =item status
3751
3752 Returns a short status string for this package, currently:
3753
3754 =over 4
3755
3756 =item on hold
3757
3758 =item not yet billed
3759
3760 =item one-time charge
3761
3762 =item active
3763
3764 =item suspended
3765
3766 =item cancelled
3767
3768 =back
3769
3770 =cut
3771
3772 sub status {
3773   my $self = shift;
3774
3775   my $freq = length($self->freq) ? $self->freq : $self->part_pkg->freq;
3776
3777   return 'cancelled' if $self->get('cancel');
3778   return 'on hold' if $self->susp && ! $self->setup;
3779   return 'suspended' if $self->susp;
3780   return 'not yet billed' unless $self->setup;
3781   return 'one-time charge' if $freq =~ /^(0|$)/;
3782   return 'active';
3783 }
3784
3785 =item ucfirst_status
3786
3787 Returns the status with the first character capitalized.
3788
3789 =cut
3790
3791 sub ucfirst_status {
3792   ucfirst(shift->status);
3793 }
3794
3795 =item statuses
3796
3797 Class method that returns the list of possible status strings for packages
3798 (see L<the status method|/status>).  For example:
3799
3800   @statuses = FS::cust_pkg->statuses();
3801
3802 =cut
3803
3804 tie my %statuscolor, 'Tie::IxHash',
3805   'on hold'         => 'FF00F5', #brighter purple!
3806   'not yet billed'  => '009999', #teal? cyan?
3807   'one-time charge' => '0000CC', #blue  #'000000',
3808   'active'          => '00CC00',
3809   'suspended'       => 'FF9900',
3810   'cancelled'       => 'FF0000',
3811 ;
3812
3813 sub statuses {
3814   my $self = shift; #could be class...
3815   #grep { $_ !~ /^(not yet billed)$/ } #this is a dumb status anyway
3816   #                                    # mayble split btw one-time vs. recur
3817     keys %statuscolor;
3818 }
3819
3820 sub statuscolors {
3821   #my $self = shift;
3822   \%statuscolor;
3823 }
3824
3825 =item statuscolor
3826
3827 Returns a hex triplet color string for this package's status.
3828
3829 =cut
3830
3831 sub statuscolor {
3832   my $self = shift;
3833   $statuscolor{$self->status};
3834 }
3835
3836 =item is_status_delay_cancel
3837
3838 Returns true if part_pkg has option delay_cancel,
3839 cust_pkg status is 'suspended' and expire is set
3840 to cancel package within the next day (or however
3841 many days are set in global config part_pkg-delay_cancel-days.
3842
3843 Accepts option I<part_pkg-delay_cancel-days> which should be
3844 the value of the config setting, to avoid looking it up again.
3845
3846 This is not a real status, this only meant for hacking display
3847 values, because otherwise treating the package as suspended is
3848 really the whole point of the delay_cancel option.
3849
3850 =cut
3851
3852 sub is_status_delay_cancel {
3853   my ($self,%opt) = @_;
3854   if ( $self->main_pkgnum and $self->pkglinknum ) {
3855     return $self->main_pkg->is_status_delay_cancel;
3856   }
3857   return 0 unless $self->part_pkg->option('delay_cancel',1);
3858   return 0 unless $self->status eq 'suspended';
3859   return 0 unless $self->expire;
3860   my $expdays = $opt{'part_pkg-delay_cancel-days'};
3861   unless ($expdays) {
3862     my $conf = new FS::Conf;
3863     $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
3864   }
3865   my $expsecs = 60*60*24*$expdays;
3866   return 0 unless $self->expire < time + $expsecs;
3867   return 1;
3868 }
3869
3870 =item pkg_label
3871
3872 Returns a label for this package.  (Currently "pkgnum: pkg - comment" or
3873 "pkg - comment" depending on user preference).
3874
3875 =cut
3876
3877 sub pkg_label {
3878   my $self = shift;
3879   my $label = $self->part_pkg->pkg_comment( cust_pkg=>$self, nopkgpart=>1 );
3880   $label = $self->pkgnum. ": $label"
3881     if $FS::CurrentUser::CurrentUser->option('show_pkgnum');
3882   $label;
3883 }
3884
3885 =item pkg_label_long
3886
3887 Returns a long label for this package, adding the primary service's label to
3888 pkg_label.
3889
3890 =cut
3891
3892 sub pkg_label_long {
3893   my $self = shift;
3894   my $label = $self->pkg_label;
3895   my $cust_svc = $self->primary_cust_svc;
3896   $label .= ' ('. ($cust_svc->label)[1]. ')' if $cust_svc;
3897   $label;
3898 }
3899
3900 =item pkg_locale
3901
3902 Returns a customer-localized label for this package.
3903
3904 =cut
3905
3906 sub pkg_locale {
3907   my $self = shift;
3908   $self->part_pkg->pkg_locale( $self->cust_main->locale );
3909 }
3910
3911 =item primary_cust_svc
3912
3913 Returns a primary service (as FS::cust_svc object) if one can be identified.
3914
3915 =cut
3916
3917 #for labeling purposes - might not 100% match up with part_pkg->svcpart's idea
3918
3919 sub primary_cust_svc {
3920   my $self = shift;
3921
3922   my @cust_svc = $self->cust_svc;
3923
3924   return '' unless @cust_svc; #no serivces - irrelevant then
3925
3926   return $cust_svc[0] if scalar(@cust_svc) == 1; #always return a single service
3927
3928   # primary service as specified in the package definition
3929   # or exactly one service definition with quantity one
3930   my $svcpart = $self->part_pkg->svcpart;
3931   @cust_svc = grep { $_->svcpart == $svcpart } @cust_svc;
3932   return $cust_svc[0] if scalar(@cust_svc) == 1;
3933
3934   #couldn't identify one thing..
3935   return '';
3936 }
3937
3938 =item labels
3939
3940 Returns a list of lists, calling the label method for all services
3941 (see L<FS::cust_svc>) of this billing item.
3942
3943 =cut
3944
3945 sub labels {
3946   my $self = shift;
3947   map { [ $_->label ] } $self->cust_svc;
3948 }
3949
3950 =item h_labels END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3951
3952 Like the labels method, but returns historical information on services that
3953 were active as of END_TIMESTAMP and (optionally) not cancelled before
3954 START_TIMESTAMP.  If MODE is 'I' (for 'invoice'), services with the
3955 I<pkg_svc.hidden> flag will be omitted.
3956
3957 Returns a list of lists, calling the label method for all (historical) services
3958 (see L<FS::h_cust_svc>) of this billing item.
3959
3960 =cut
3961
3962 sub h_labels {
3963   my $self = shift;
3964   warn "$me _h_labels called on $self\n"
3965     if $DEBUG;
3966   map { [ $_->label(@_) ] } $self->h_cust_svc(@_);
3967 }
3968
3969 =item labels_short
3970
3971 Like labels, except returns a simple flat list, and shortens long
3972 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3973 identical services to one line that lists the service label and the number of
3974 individual services rather than individual items.
3975
3976 =cut
3977
3978 sub labels_short {
3979   shift->_labels_short( 'labels', @_ );
3980 }
3981
3982 =item h_labels_short END_TIMESTAMP [ START_TIMESTAMP ]
3983
3984 Like h_labels, except returns a simple flat list, and shortens long
3985 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3986 identical services to one line that lists the service label and the number of
3987 individual services rather than individual items.
3988
3989 =cut
3990
3991 sub h_labels_short {
3992   shift->_labels_short( 'h_labels', @_ );
3993 }
3994
3995 sub _labels_short {
3996   my( $self, $method ) = ( shift, shift );
3997
3998   warn "$me _labels_short called on $self with $method method\n"
3999     if $DEBUG;
4000
4001   my $conf = new FS::Conf;
4002   my $max_same_services = $conf->config('cust_bill-max_same_services') || 5;
4003
4004   warn "$me _labels_short populating \%labels\n"
4005     if $DEBUG;
4006
4007   my %labels;
4008   #tie %labels, 'Tie::IxHash';
4009   push @{ $labels{$_->[0]} }, $_->[1]
4010     foreach $self->$method(@_);
4011
4012   warn "$me _labels_short populating \@labels\n"
4013     if $DEBUG;
4014
4015   my @labels;
4016   foreach my $label ( keys %labels ) {
4017     my %seen = ();
4018     my @values = grep { ! $seen{$_}++ } @{ $labels{$label} };
4019     my $num = scalar(@values);
4020     warn "$me _labels_short $num items for $label\n"
4021       if $DEBUG;
4022
4023     if ( $num > $max_same_services ) {
4024       warn "$me _labels_short   more than $max_same_services, so summarizing\n"
4025         if $DEBUG;
4026       push @labels, "$label ($num)";
4027     } else {
4028       if ( $conf->exists('cust_bill-consolidate_services') ) {
4029         warn "$me _labels_short   consolidating services\n"
4030           if $DEBUG;
4031         # push @labels, "$label: ". join(', ', @values);
4032         while ( @values ) {
4033           my $detail = "$label: ";
4034           $detail .= shift(@values). ', '
4035             while @values
4036                && ( length($detail.$values[0]) < 78 || $detail eq "$label: " );
4037           $detail =~ s/, $//;
4038           push @labels, $detail;
4039         }
4040         warn "$me _labels_short   done consolidating services\n"
4041           if $DEBUG;
4042       } else {
4043         warn "$me _labels_short   adding service data\n"
4044           if $DEBUG;
4045         push @labels, map { "$label: $_" } @values;
4046       }
4047     }
4048   }
4049
4050  @labels;
4051
4052 }
4053
4054 =item cust_main
4055
4056 Returns the parent customer object (see L<FS::cust_main>).
4057
4058 =item balance
4059
4060 Returns the balance for this specific package, when using
4061 experimental package balance.
4062
4063 =cut
4064
4065 sub balance {
4066   my $self = shift;
4067   $self->cust_main->balance_pkgnum( $self->pkgnum );
4068 }
4069
4070 #these subs are in location_Mixin.pm now... unfortunately the POD doesn't mixin
4071
4072 =item cust_location
4073
4074 Returns the location object, if any (see L<FS::cust_location>).
4075
4076 =item cust_location_or_main
4077
4078 If this package is associated with a location, returns the locaiton (see
4079 L<FS::cust_location>), otherwise returns the customer (see L<FS::cust_main>).
4080
4081 =item location_label [ OPTION => VALUE ... ]
4082
4083 Returns the label of the location object (see L<FS::cust_location>).
4084
4085 =cut
4086
4087 #end of subs in location_Mixin.pm now... unfortunately the POD doesn't mixin
4088
4089 =item tax_locationnum
4090
4091 Returns the foreign key to a L<FS::cust_location> object for calculating
4092 tax on this package, as determined by the C<tax-pkg_address> and
4093 C<tax-ship_address> configuration flags.
4094
4095 =cut
4096
4097 sub tax_locationnum {
4098   my $self = shift;
4099   my $conf = FS::Conf->new;
4100   if ( $conf->exists('tax-pkg_address') ) {
4101     return $self->locationnum;
4102   }
4103   elsif ( $conf->exists('tax-ship_address') ) {
4104     return $self->cust_main->ship_locationnum;
4105   }
4106   else {
4107     return $self->cust_main->bill_locationnum;
4108   }
4109 }
4110
4111 =item tax_location
4112
4113 Returns the L<FS::cust_location> object for tax_locationnum.
4114
4115 =cut
4116
4117 sub tax_location {
4118   my $self = shift;
4119   my $conf = FS::Conf->new;
4120   if ( $conf->exists('tax-pkg_address') and $self->locationnum ) {
4121     return FS::cust_location->by_key($self->locationnum);
4122   }
4123   elsif ( $conf->exists('tax-ship_address') ) {
4124     return $self->cust_main->ship_location;
4125   }
4126   else {
4127     return $self->cust_main->bill_location;
4128   }
4129 }
4130
4131 =item seconds_since TIMESTAMP
4132
4133 Returns the number of seconds all accounts (see L<FS::svc_acct>) in this
4134 package have been online since TIMESTAMP, according to the session monitor.
4135
4136 TIMESTAMP is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
4137 L<Time::Local> and L<Date::Parse> for conversion functions.
4138
4139 =cut
4140
4141 sub seconds_since {
4142   my($self, $since) = @_;
4143   my $seconds = 0;
4144
4145   foreach my $cust_svc (
4146     grep { $_->part_svc->svcdb eq 'svc_acct' } $self->cust_svc
4147   ) {
4148     $seconds += $cust_svc->seconds_since($since);
4149   }
4150
4151   $seconds;
4152
4153 }
4154
4155 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
4156
4157 Returns the numbers of seconds all accounts (see L<FS::svc_acct>) in this
4158 package have been online between TIMESTAMP_START (inclusive) and TIMESTAMP_END
4159 (exclusive).
4160
4161 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
4162 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
4163 functions.
4164
4165
4166 =cut
4167
4168 sub seconds_since_sqlradacct {
4169   my($self, $start, $end) = @_;
4170
4171   my $seconds = 0;
4172
4173   foreach my $cust_svc (
4174     grep {
4175       my $part_svc = $_->part_svc;
4176       $part_svc->svcdb eq 'svc_acct'
4177         && scalar($part_svc->part_export_usage);
4178     } $self->cust_svc
4179   ) {
4180     $seconds += $cust_svc->seconds_since_sqlradacct($start, $end);
4181   }
4182
4183   $seconds;
4184
4185 }
4186
4187 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
4188
4189 Returns the sum of the given attribute for all accounts (see L<FS::svc_acct>)
4190 in this package for sessions ending between TIMESTAMP_START (inclusive) and
4191 TIMESTAMP_END
4192 (exclusive).
4193
4194 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
4195 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
4196 functions.
4197
4198 =cut
4199
4200 sub attribute_since_sqlradacct {
4201   my($self, $start, $end, $attrib) = @_;
4202
4203   my $sum = 0;
4204
4205   foreach my $cust_svc (
4206     grep {
4207       my $part_svc = $_->part_svc;
4208       scalar($part_svc->part_export_usage);
4209     } $self->cust_svc
4210   ) {
4211     $sum += $cust_svc->attribute_since_sqlradacct($start, $end, $attrib);
4212   }
4213
4214   $sum;
4215
4216 }
4217
4218 =item quantity
4219
4220 =cut
4221
4222 sub quantity {
4223   my( $self, $value ) = @_;
4224   if ( defined($value) ) {
4225     $self->setfield('quantity', $value);
4226   }
4227   $self->getfield('quantity') || 1;
4228 }
4229
4230 =item transfer DEST_PKGNUM | DEST_CUST_PKG, [ OPTION => VALUE ... ]
4231
4232 Transfers as many services as possible from this package to another package.
4233
4234 The destination package can be specified by pkgnum by passing an FS::cust_pkg
4235 object.  The destination package must already exist.
4236
4237 Services are moved only if the destination allows services with the correct
4238 I<svcpart> (not svcdb), unless the B<change_svcpart> option is set true.  Use
4239 this option with caution!  No provision is made for export differences
4240 between the old and new service definitions.  Probably only should be used
4241 when your exports for all service definitions of a given svcdb are identical.
4242 (attempt a transfer without it first, to move all possible svcpart-matching
4243 services)
4244
4245 Any services that can't be moved remain in the original package.
4246
4247 Returns an error, if there is one; otherwise, returns the number of services
4248 that couldn't be moved.
4249
4250 =cut
4251
4252 sub transfer {
4253   my ($self, $dest_pkgnum, %opt) = @_;
4254
4255   my $remaining = 0;
4256   my $dest;
4257   my %target;
4258
4259   if (ref ($dest_pkgnum) eq 'FS::cust_pkg') {
4260     $dest = $dest_pkgnum;
4261     $dest_pkgnum = $dest->pkgnum;
4262   } else {
4263     $dest = qsearchs('cust_pkg', { pkgnum => $dest_pkgnum });
4264   }
4265
4266   return ('Package does not exist: '.$dest_pkgnum) unless $dest;
4267
4268   foreach my $pkg_svc ( $dest->part_pkg->pkg_svc ) {
4269     $target{$pkg_svc->svcpart} = $pkg_svc->quantity * ( $dest->quantity || 1 );
4270   }
4271
4272   foreach my $cust_svc ($dest->cust_svc) {
4273     $target{$cust_svc->svcpart}--;
4274   }
4275
4276   my %svcpart2svcparts = ();
4277   if ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
4278     warn "change_svcpart option received, creating alternates list\n" if $DEBUG;
4279     foreach my $svcpart ( map { $_->svcpart } $self->cust_svc ) {
4280       next if exists $svcpart2svcparts{$svcpart};
4281       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
4282       $svcpart2svcparts{$svcpart} = [
4283         map  { $_->[0] }
4284         sort { $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] }
4285         map {
4286               my $pkg_svc = qsearchs( 'pkg_svc', { 'pkgpart' => $dest->pkgpart,
4287                                                    'svcpart' => $_          } );
4288               [ $_,
4289                 $pkg_svc ? $pkg_svc->primary_svc : '',
4290                 $pkg_svc ? $pkg_svc->quantity : 0,
4291               ];
4292             }
4293
4294         grep { $_ != $svcpart }
4295         map  { $_->svcpart }
4296         qsearch('part_svc', { 'svcdb' => $part_svc->svcdb } )
4297       ];
4298       warn "alternates for svcpart $svcpart: ".
4299            join(', ', @{$svcpart2svcparts{$svcpart}}). "\n"
4300         if $DEBUG;
4301     }
4302   }
4303
4304   my $error;
4305   foreach my $cust_svc ($self->cust_svc) {
4306     my $svcnum = $cust_svc->svcnum;
4307     if($target{$cust_svc->svcpart} > 0
4308        or $FS::cust_svc::ignore_quantity) { # maybe should be a 'force' option
4309       $target{$cust_svc->svcpart}--;
4310       my $new = new FS::cust_svc { $cust_svc->hash };
4311       $new->pkgnum($dest_pkgnum);
4312       $error = $new->replace($cust_svc);
4313     } elsif ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
4314       if ( $DEBUG ) {
4315         warn "looking for alternates for svcpart ". $cust_svc->svcpart. "\n";
4316         warn "alternates to consider: ".
4317              join(', ', @{$svcpart2svcparts{$cust_svc->svcpart}}). "\n";
4318       }
4319       my @alternate = grep {
4320                              warn "considering alternate svcpart $_: ".
4321                                   "$target{$_} available in new package\n"
4322                                if $DEBUG;
4323                              $target{$_} > 0;
4324                            } @{$svcpart2svcparts{$cust_svc->svcpart}};
4325       if ( @alternate ) {
4326         warn "alternate(s) found\n" if $DEBUG;
4327         my $change_svcpart = $alternate[0];
4328         $target{$change_svcpart}--;
4329         my $new = new FS::cust_svc { $cust_svc->hash };
4330         $new->svcpart($change_svcpart);
4331         $new->pkgnum($dest_pkgnum);
4332         $error = $new->replace($cust_svc);
4333       } else {
4334         $remaining++;
4335       }
4336     } else {
4337       $remaining++
4338     }
4339     if ( $error ) {
4340       my @label = $cust_svc->label;
4341       return "$label[0] $label[1]: $error";
4342     }
4343   }
4344   return $remaining;
4345 }
4346
4347 =item grab_svcnums SVCNUM, SVCNUM ...
4348
4349 Change the pkgnum for the provided services to this packages.  If there is an
4350 error, returns the error, otherwise returns false.
4351
4352 =cut
4353
4354 sub grab_svcnums {
4355   my $self = shift;
4356   my @svcnum = @_;
4357
4358   my $oldAutoCommit = $FS::UID::AutoCommit;
4359   local $FS::UID::AutoCommit = 0;
4360   my $dbh = dbh;
4361
4362   foreach my $svcnum (@svcnum) {
4363     my $cust_svc = qsearchs('cust_svc', { svcnum=>$svcnum } ) or do {
4364       $dbh->rollback if $oldAutoCommit;
4365       return "unknown svcnum $svcnum";
4366     };
4367     $cust_svc->pkgnum( $self->pkgnum );
4368     my $error = $cust_svc->replace;
4369     if ( $error ) {
4370       $dbh->rollback if $oldAutoCommit;
4371       return $error;
4372     }
4373   }
4374
4375   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4376   '';
4377
4378 }
4379
4380 =item reexport
4381
4382 This method is deprecated.  See the I<depend_jobnum> option to the insert and
4383 order_pkgs methods in FS::cust_main for a better way to defer provisioning.
4384
4385 =cut
4386
4387 #looks like this is still used by the order_pkg and change_pkg methods in
4388 # ClientAPI/MyAccount, need to look into those before removing
4389 sub reexport {
4390   my $self = shift;
4391
4392   my $oldAutoCommit = $FS::UID::AutoCommit;
4393   local $FS::UID::AutoCommit = 0;
4394   my $dbh = dbh;
4395
4396   foreach my $cust_svc ( $self->cust_svc ) {
4397     #false laziness w/svc_Common::insert
4398     my $svc_x = $cust_svc->svc_x;
4399     foreach my $part_export ( $cust_svc->part_svc->part_export ) {
4400       my $error = $part_export->export_insert($svc_x);
4401       if ( $error ) {
4402         $dbh->rollback if $oldAutoCommit;
4403         return $error;
4404       }
4405     }
4406   }
4407
4408   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4409   '';
4410
4411 }
4412
4413 =item export_pkg_change OLD_CUST_PKG
4414
4415 Calls the "pkg_change" export action for all services attached to this package.
4416
4417 =cut
4418
4419 sub export_pkg_change {
4420   my( $self, $old )  = ( shift, shift );
4421
4422   my $oldAutoCommit = $FS::UID::AutoCommit;
4423   local $FS::UID::AutoCommit = 0;
4424   my $dbh = dbh;
4425
4426   foreach my $svc_x ( map $_->svc_x, $self->cust_svc ) {
4427     my $error = $svc_x->export('pkg_change', $self, $old);
4428     if ( $error ) {
4429       $dbh->rollback if $oldAutoCommit;
4430       return $error;
4431     }
4432   }
4433
4434   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4435   '';
4436
4437 }
4438
4439 =item insert_reason
4440
4441 Associates this package with a (suspension or cancellation) reason (see
4442 L<FS::cust_pkg_reason>, possibly inserting a new reason on the fly (see
4443 L<FS::reason>).
4444
4445 Available options are:
4446
4447 =over 4
4448
4449 =item reason
4450
4451 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
4452
4453 =item reason_otaker
4454
4455 the access_user (see L<FS::access_user>) providing the reason
4456
4457 =item date
4458
4459 a unix timestamp
4460
4461 =item action
4462
4463 the action (cancel, susp, adjourn, expire) associated with the reason
4464
4465 =back
4466
4467 If there is an error, returns the error, otherwise returns false.
4468
4469 =cut
4470
4471 sub insert_reason {
4472   my ($self, %options) = @_;
4473
4474   my $otaker = $options{reason_otaker} ||
4475                $FS::CurrentUser::CurrentUser->username;
4476
4477   my $reasonnum;
4478   if ( $options{'reason'} =~ /^(\d+)$/ ) {
4479
4480     $reasonnum = $1;
4481
4482   } elsif ( ref($options{'reason'}) ) {
4483
4484     return 'Enter a new reason (or select an existing one)'
4485       unless $options{'reason'}->{'reason'} !~ /^\s*$/;
4486
4487     my $reason = new FS::reason({
4488       'reason_type' => $options{'reason'}->{'typenum'},
4489       'reason'      => $options{'reason'}->{'reason'},
4490     });
4491     my $error = $reason->insert;
4492     return $error if $error;
4493
4494     $reasonnum = $reason->reasonnum;
4495
4496   } else {
4497     return "Unparseable reason: ". $options{'reason'};
4498   }
4499
4500   my $cust_pkg_reason =
4501     new FS::cust_pkg_reason({ 'pkgnum'    => $self->pkgnum,
4502                               'reasonnum' => $reasonnum,
4503                               'otaker'    => $otaker,
4504                               'action'    => substr(uc($options{'action'}),0,1),
4505                               'date'      => $options{'date'}
4506                                                ? $options{'date'}
4507                                                : time,
4508                             });
4509
4510   $cust_pkg_reason->insert;
4511 }
4512
4513 =item insert_discount
4514
4515 Associates this package with a discount (see L<FS::cust_pkg_discount>, possibly
4516 inserting a new discount on the fly (see L<FS::discount>).
4517
4518 This will look at the cust_pkg for a pseudo-field named "setup_discountnum",
4519 and if present, will create a setup discount. If the discountnum is -1,
4520 a new discount definition will be inserted using the value in
4521 "setup_discountnum_amount" or "setup_discountnum_percent". Likewise for recur.
4522
4523 If there is an error, returns the error, otherwise returns false.
4524
4525 =cut
4526
4527 sub insert_discount {
4528   #my ($self, %options) = @_;
4529   my $self = shift;
4530
4531   foreach my $x (qw(setup recur)) {
4532     if ( my $discountnum = $self->get("${x}_discountnum") ) {
4533       my $cust_pkg_discount = FS::cust_pkg_discount->new( {
4534         'pkgnum'      => $self->pkgnum,
4535         'discountnum' => $discountnum,
4536         'setuprecur'  => $x,
4537         'months_used' => 0,
4538         'end_date'    => '', #XXX
4539         #for the create a new discount case
4540         'amount'      => $self->get("${x}_discountnum_amount"),
4541         'percent'     => $self->get("${x}_discountnum_percent"),
4542         'months'      => $self->get("${x}_discountnum_months"),
4543       } );
4544       if ( $x eq 'setup' ) {
4545         $cust_pkg_discount->setup('Y');
4546         $cust_pkg_discount->months('');
4547       }
4548       my $error = $cust_pkg_discount->insert;
4549       return $error if $error;
4550     }
4551   }
4552
4553   '';
4554 }
4555
4556 =item set_usage USAGE_VALUE_HASHREF
4557
4558 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4559 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4560 upbytes, downbytes, and totalbytes are appropriate keys.
4561
4562 All svc_accts which are part of this package have their values reset.
4563
4564 =cut
4565
4566 sub set_usage {
4567   my ($self, $valueref, %opt) = @_;
4568
4569   #only svc_acct can set_usage for now
4570   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4571     my $svc_x = $cust_svc->svc_x;
4572     $svc_x->set_usage($valueref, %opt)
4573       if $svc_x->can("set_usage");
4574   }
4575 }
4576
4577 =item recharge USAGE_VALUE_HASHREF
4578
4579 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4580 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4581 upbytes, downbytes, and totalbytes are appropriate keys.
4582
4583 All svc_accts which are part of this package have their values incremented.
4584
4585 =cut
4586
4587 sub recharge {
4588   my ($self, $valueref) = @_;
4589
4590   #only svc_acct can set_usage for now
4591   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4592     my $svc_x = $cust_svc->svc_x;
4593     $svc_x->recharge($valueref)
4594       if $svc_x->can("recharge");
4595   }
4596 }
4597
4598 =item apply_usageprice
4599
4600 =cut
4601
4602 sub apply_usageprice {
4603   my $self = shift;
4604
4605   my $oldAutoCommit = $FS::UID::AutoCommit;
4606   local $FS::UID::AutoCommit = 0;
4607   my $dbh = dbh;
4608
4609   my $error = '';
4610
4611   foreach my $cust_pkg_usageprice ( $self->cust_pkg_usageprice ) {
4612     $error ||= $cust_pkg_usageprice->apply;
4613   }
4614
4615   if ( $error ) {
4616     $dbh->rollback if $oldAutoCommit;
4617     die "error applying part_pkg_usageprice add-ons, pkgnum ". $self->pkgnum.
4618         ": $error\n";
4619   } else {
4620     $dbh->commit if $oldAutoCommit;
4621   }
4622
4623
4624 }
4625
4626 =item cust_pkg_discount
4627
4628 =item cust_pkg_discount_active
4629
4630 =cut
4631
4632 sub cust_pkg_discount_active {
4633   my $self = shift;
4634   grep { $_->status eq 'active' } $self->cust_pkg_discount;
4635 }
4636
4637 =item cust_pkg_usage
4638
4639 Returns a list of all voice usage counters attached to this package.
4640
4641 =item apply_usage OPTIONS
4642
4643 Takes the following options:
4644 - cdr: a call detail record (L<FS::cdr>)
4645 - rate_detail: the rate determined for this call (L<FS::rate_detail>)
4646 - minutes: the maximum number of minutes to be charged
4647
4648 Finds available usage minutes for a call of this class, and subtracts
4649 up to that many minutes from the usage pool.  If the usage pool is empty,
4650 and the C<cdr-minutes_priority> global config option is set, minutes may
4651 be taken from other calls as well.  Either way, an allocation record will
4652 be created (L<FS::cdr_cust_pkg_usage>) and this method will return the
4653 number of minutes of usage applied to the call.
4654
4655 =cut
4656
4657 sub apply_usage {
4658   my ($self, %opt) = @_;
4659   my $cdr = $opt{cdr};
4660   my $rate_detail = $opt{rate_detail};
4661   my $minutes = $opt{minutes};
4662   my $classnum = $rate_detail->classnum;
4663   my $pkgnum = $self->pkgnum;
4664   my $custnum = $self->custnum;
4665
4666   my $oldAutoCommit = $FS::UID::AutoCommit;
4667   local $FS::UID::AutoCommit = 0;
4668   my $dbh = dbh;
4669
4670   my $order = FS::Conf->new->config('cdr-minutes_priority');
4671
4672   my $is_classnum;
4673   if ( $classnum ) {
4674     $is_classnum = ' part_pkg_usage_class.classnum = '.$classnum;
4675   } else {
4676     $is_classnum = ' part_pkg_usage_class.classnum IS NULL';
4677   }
4678   my @usage_recs = qsearch({
4679       'table'     => 'cust_pkg_usage',
4680       'addl_from' => ' JOIN part_pkg_usage       USING (pkgusagepart)'.
4681                      ' JOIN cust_pkg             USING (pkgnum)'.
4682                      ' JOIN part_pkg_usage_class USING (pkgusagepart)',
4683       'select'    => 'cust_pkg_usage.*',
4684       'extra_sql' => " WHERE ( cust_pkg.pkgnum = $pkgnum OR ".
4685                      " ( cust_pkg.custnum = $custnum AND ".
4686                      " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4687                      $is_classnum . ' AND '.
4688                      " cust_pkg_usage.minutes > 0",
4689       'order_by'  => " ORDER BY priority ASC",
4690   });
4691
4692   my $orig_minutes = $minutes;
4693   my $error;
4694   while (!$error and $minutes > 0 and @usage_recs) {
4695     my $cust_pkg_usage = shift @usage_recs;
4696     $cust_pkg_usage->select_for_update;
4697     my $cdr_cust_pkg_usage = FS::cdr_cust_pkg_usage->new({
4698         pkgusagenum => $cust_pkg_usage->pkgusagenum,
4699         acctid      => $cdr->acctid,
4700         minutes     => min($cust_pkg_usage->minutes, $minutes),
4701     });
4702     $cust_pkg_usage->set('minutes',
4703       $cust_pkg_usage->minutes - $cdr_cust_pkg_usage->minutes
4704     );
4705     $error = $cust_pkg_usage->replace || $cdr_cust_pkg_usage->insert;
4706     $minutes -= $cdr_cust_pkg_usage->minutes;
4707   }
4708   if ( $order and $minutes > 0 and !$error ) {
4709     # then try to steal minutes from another call
4710     my %search = (
4711         'table'     => 'cdr_cust_pkg_usage',
4712         'addl_from' => ' JOIN cust_pkg_usage        USING (pkgusagenum)'.
4713                        ' JOIN part_pkg_usage        USING (pkgusagepart)'.
4714                        ' JOIN cust_pkg              USING (pkgnum)'.
4715                        ' JOIN part_pkg_usage_class  USING (pkgusagepart)'.
4716                        ' JOIN cdr                   USING (acctid)',
4717         'select'    => 'cdr_cust_pkg_usage.*',
4718         'extra_sql' => " WHERE cdr.freesidestatus = 'rated' AND ".
4719                        " ( cust_pkg.pkgnum = $pkgnum OR ".
4720                        " ( cust_pkg.custnum = $custnum AND ".
4721                        " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4722                        " part_pkg_usage_class.classnum = $classnum",
4723         'order_by'  => ' ORDER BY part_pkg_usage.priority ASC',
4724     );
4725     if ( $order eq 'time' ) {
4726       # find CDRs that are using minutes, but have a later startdate
4727       # than this call
4728       my $startdate = $cdr->startdate;
4729       if ($startdate !~ /^\d+$/) {
4730         die "bad cdr startdate '$startdate'";
4731       }
4732       $search{'extra_sql'} .= " AND cdr.startdate > $startdate";
4733       # minimize needless reshuffling
4734       $search{'order_by'} .= ', cdr.startdate DESC';
4735     } else {
4736       # XXX may not work correctly with rate_time schedules.  Could
4737       # fix this by storing ratedetailnum in cdr_cust_pkg_usage, I
4738       # think...
4739       $search{'addl_from'} .=
4740         ' JOIN rate_detail'.
4741         ' ON (cdr.rated_ratedetailnum = rate_detail.ratedetailnum)';
4742       if ( $order eq 'rate_high' ) {
4743         $search{'extra_sql'} .= ' AND rate_detail.min_charge < '.
4744                                 $rate_detail->min_charge;
4745         $search{'order_by'} .= ', rate_detail.min_charge ASC';
4746       } elsif ( $order eq 'rate_low' ) {
4747         $search{'extra_sql'} .= ' AND rate_detail.min_charge > '.
4748                                 $rate_detail->min_charge;
4749         $search{'order_by'} .= ', rate_detail.min_charge DESC';
4750       } else {
4751         #  this should really never happen
4752         die "invalid cdr-minutes_priority value '$order'\n";
4753       }
4754     }
4755     my @cdr_usage_recs = qsearch(\%search);
4756     my %reproc_cdrs;
4757     while (!$error and @cdr_usage_recs and $minutes > 0) {
4758       my $cdr_cust_pkg_usage = shift @cdr_usage_recs;
4759       my $cust_pkg_usage = $cdr_cust_pkg_usage->cust_pkg_usage;
4760       my $old_cdr = $cdr_cust_pkg_usage->cdr;
4761       $reproc_cdrs{$old_cdr->acctid} = $old_cdr;
4762       $cdr_cust_pkg_usage->select_for_update;
4763       $old_cdr->select_for_update;
4764       $cust_pkg_usage->select_for_update;
4765       # in case someone else stole the usage from this CDR
4766       # while waiting for the lock...
4767       next if $old_cdr->acctid != $cdr_cust_pkg_usage->acctid;
4768       # steal the usage allocation and flag the old CDR for reprocessing
4769       $cdr_cust_pkg_usage->set('acctid', $cdr->acctid);
4770       # if the allocation is more minutes than we need, adjust it...
4771       my $delta = $cdr_cust_pkg_usage->minutes - $minutes;
4772       if ( $delta > 0 ) {
4773         $cdr_cust_pkg_usage->set('minutes', $minutes);
4774         $cust_pkg_usage->set('minutes', $cust_pkg_usage->minutes + $delta);
4775         $error = $cust_pkg_usage->replace;
4776       }
4777       #warn 'CDR '.$cdr->acctid . ' stealing allocation '.$cdr_cust_pkg_usage->cdrusagenum.' from CDR '.$old_cdr->acctid."\n";
4778       $error ||= $cdr_cust_pkg_usage->replace;
4779       # deduct the stolen minutes
4780       $minutes -= $cdr_cust_pkg_usage->minutes;
4781     }
4782     # after all minute-stealing is done, reset the affected CDRs
4783     foreach (values %reproc_cdrs) {
4784       $error ||= $_->set_status('');
4785       # XXX or should we just call $cdr->rate right here?
4786       # it's not like we can create a loop this way, since the min_charge
4787       # or call time has to go monotonically in one direction.
4788       # we COULD get some very deep recursions going, though...
4789     }
4790   } # if $order and $minutes
4791   if ( $error ) {
4792     $dbh->rollback;
4793     die "error applying included minutes\npkgnum ".$self->pkgnum.", class $classnum, acctid ".$cdr->acctid."\n$error\n"
4794   } else {
4795     $dbh->commit if $oldAutoCommit;
4796     return $orig_minutes - $minutes;
4797   }
4798 }
4799
4800 =item supplemental_pkgs
4801
4802 Returns a list of all packages supplemental to this one.
4803
4804 =cut
4805
4806 sub supplemental_pkgs {
4807   my $self = shift;
4808   qsearch('cust_pkg', { 'main_pkgnum' => $self->pkgnum });
4809 }
4810
4811 =item main_pkg
4812
4813 Returns the package that this one is supplemental to, if any.
4814
4815 =cut
4816
4817 sub main_pkg {
4818   my $self = shift;
4819   if ( $self->main_pkgnum ) {
4820     return FS::cust_pkg->by_key($self->main_pkgnum);
4821   }
4822   return;
4823 }
4824
4825 =back
4826
4827 =head1 CLASS METHODS
4828
4829 =over 4
4830
4831 =item recurring_sql
4832
4833 Returns an SQL expression identifying recurring packages.
4834
4835 =cut
4836
4837 sub recurring_sql { "
4838   '0' != ( select freq from part_pkg
4839              where cust_pkg.pkgpart = part_pkg.pkgpart )
4840 "; }
4841
4842 =item onetime_sql
4843
4844 Returns an SQL expression identifying one-time packages.
4845
4846 =cut
4847
4848 sub onetime_sql { "
4849   '0' = ( select freq from part_pkg
4850             where cust_pkg.pkgpart = part_pkg.pkgpart )
4851 "; }
4852
4853 =item ordered_sql
4854
4855 Returns an SQL expression identifying ordered packages (recurring packages not
4856 yet billed).
4857
4858 =cut
4859
4860 sub ordered_sql {
4861    $_[0]->recurring_sql. " AND ". $_[0]->not_yet_billed_sql;
4862 }
4863
4864 =item active_sql
4865
4866 Returns an SQL expression identifying active packages.
4867
4868 =cut
4869
4870 sub active_sql {
4871   $_[0]->recurring_sql. "
4872   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4873   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4874   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4875 "; }
4876
4877 =item not_yet_billed_sql
4878
4879 Returns an SQL expression identifying packages which have not yet been billed.
4880
4881 =cut
4882
4883 sub not_yet_billed_sql { "
4884       ( cust_pkg.setup  IS NULL OR cust_pkg.setup  = 0 )
4885   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4886   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4887 "; }
4888
4889 =item inactive_sql
4890
4891 Returns an SQL expression identifying inactive packages (one-time packages
4892 that are otherwise unsuspended/uncancelled).
4893
4894 =cut
4895
4896 sub inactive_sql { "
4897   ". $_[0]->onetime_sql(). "
4898   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4899   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4900   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4901 "; }
4902
4903 =item on_hold_sql
4904
4905 Returns an SQL expression identifying on-hold packages.
4906
4907 =cut
4908
4909 sub on_hold_sql {
4910   #$_[0]->recurring_sql(). ' AND '.
4911   "
4912         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel  = 0 )
4913     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp   != 0
4914     AND ( cust_pkg.setup  IS     NULL  OR cust_pkg.setup   = 0 )
4915   ";
4916 }
4917
4918 =item susp_sql
4919 =item suspended_sql
4920
4921 Returns an SQL expression identifying suspended packages.
4922
4923 =cut
4924
4925 sub suspended_sql { susp_sql(@_); }
4926 sub susp_sql {
4927   #$_[0]->recurring_sql(). ' AND '.
4928   "
4929         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel = 0 )
4930     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp  != 0
4931     AND   cust_pkg.setup  IS NOT NULL AND cust_pkg.setup != 0
4932   ";
4933 }
4934
4935 =item cancel_sql
4936 =item cancelled_sql
4937
4938 Returns an SQL exprression identifying cancelled packages.
4939
4940 =cut
4941
4942 sub cancelled_sql { cancel_sql(@_); }
4943 sub cancel_sql {
4944   #$_[0]->recurring_sql(). ' AND '.
4945   "cust_pkg.cancel IS NOT NULL AND cust_pkg.cancel != 0";
4946 }
4947
4948 =item status_sql
4949
4950 Returns an SQL expression to give the package status as a string.
4951
4952 =cut
4953
4954 sub status_sql {
4955 "CASE
4956   WHEN cust_pkg.cancel IS NOT NULL THEN 'cancelled'
4957   WHEN ( cust_pkg.susp IS NOT NULL AND cust_pkg.setup IS NULL ) THEN 'on hold'
4958   WHEN cust_pkg.susp IS NOT NULL THEN 'suspended'
4959   WHEN cust_pkg.setup IS NULL THEN 'not yet billed'
4960   WHEN ".onetime_sql()." THEN 'one-time charge'
4961   ELSE 'active'
4962 END"
4963 }
4964
4965 =item fcc_477_count
4966
4967 Returns a list of two package counts.  The first is a count of packages
4968 based on the supplied criteria and the second is the count of residential
4969 packages with those same criteria.  Criteria are specified as in the search
4970 method.
4971
4972 =cut
4973
4974 sub fcc_477_count {
4975   my ($class, $params) = @_;
4976
4977   my $sql_query = $class->search( $params );
4978
4979   my $count_sql = delete($sql_query->{'count_query'});
4980   $count_sql =~ s/ FROM/,count(CASE WHEN cust_main.company IS NULL OR cust_main.company = '' THEN 1 END) FROM/
4981     or die "couldn't parse count_sql";
4982
4983   my $count_sth = dbh->prepare($count_sql)
4984     or die "Error preparing $count_sql: ". dbh->errstr;
4985   $count_sth->execute
4986     or die "Error executing $count_sql: ". $count_sth->errstr;
4987   my $count_arrayref = $count_sth->fetchrow_arrayref;
4988
4989   return ( @$count_arrayref );
4990
4991 }
4992
4993 =item tax_locationnum_sql
4994
4995 Returns an SQL expression for the tax location for a package, based
4996 on the settings of 'tax-pkg_address' and 'tax-ship_address'.
4997
4998 =cut
4999
5000 sub tax_locationnum_sql {
5001   my $conf = FS::Conf->new;
5002   if ( $conf->exists('tax-pkg_address') ) {
5003     'cust_pkg.locationnum';
5004   }
5005   elsif ( $conf->exists('tax-ship_address') ) {
5006     'cust_main.ship_locationnum';
5007   }
5008   else {
5009     'cust_main.bill_locationnum';
5010   }
5011 }
5012
5013 =item location_sql
5014
5015 Returns a list: the first item is an SQL fragment identifying matching
5016 packages/customers via location (taking into account shipping and package
5017 address taxation, if enabled), and subsequent items are the parameters to
5018 substitute for the placeholders in that fragment.
5019
5020 =cut
5021
5022 sub location_sql {
5023   my($class, %opt) = @_;
5024   my $ornull = $opt{'ornull'};
5025
5026   my $conf = new FS::Conf;
5027
5028   # '?' placeholders in _location_sql_where
5029   my $x = $ornull ? 3 : 2;
5030   my @bill_param = (
5031     ('district')x3,
5032     ('city')x3,
5033     ('county')x$x,
5034     ('state')x$x,
5035     'country'
5036   );
5037
5038   my $main_where;
5039   my @main_param;
5040   if ( $conf->exists('tax-ship_address') ) {
5041
5042     $main_where = "(
5043          (     ( ship_last IS NULL     OR  ship_last  = '' )
5044            AND ". _location_sql_where('cust_main', '', $ornull ). "
5045          )
5046       OR (       ship_last IS NOT NULL AND ship_last != ''
5047            AND ". _location_sql_where('cust_main', 'ship_', $ornull ). "
5048          )
5049     )";
5050     #    AND payby != 'COMP'
5051
5052     @main_param = ( @bill_param, @bill_param );
5053
5054   } else {
5055
5056     $main_where = _location_sql_where('cust_main'); # AND payby != 'COMP'
5057     @main_param = @bill_param;
5058
5059   }
5060
5061   my $where;
5062   my @param;
5063   if ( $conf->exists('tax-pkg_address') ) {
5064
5065     my $loc_where = _location_sql_where( 'cust_location', '', $ornull );
5066
5067     $where = " (
5068                     ( cust_pkg.locationnum IS     NULL AND $main_where )
5069                  OR ( cust_pkg.locationnum IS NOT NULL AND $loc_where  )
5070                )
5071              ";
5072     @param = ( @main_param, @bill_param );
5073
5074   } else {
5075
5076     $where = $main_where;
5077     @param = @main_param;
5078
5079   }
5080
5081   ( $where, @param );
5082
5083 }
5084
5085 #subroutine, helper for location_sql
5086 sub _location_sql_where {
5087   my $table  = shift;
5088   my $prefix = @_ ? shift : '';
5089   my $ornull = @_ ? shift : '';
5090
5091 #  $ornull             = $ornull          ? " OR ( ? IS NULL AND $table.${prefix}county IS NULL ) " : '';
5092
5093   $ornull = $ornull ? ' OR ? IS NULL ' : '';
5094
5095   my $or_empty_city     = " OR ( ? = '' AND $table.${prefix}city     IS NULL )";
5096   my $or_empty_county   = " OR ( ? = '' AND $table.${prefix}county   IS NULL )";
5097   my $or_empty_state    = " OR ( ? = '' AND $table.${prefix}state    IS NULL )";
5098
5099   my $text = (driver_name =~ /^mysql/i) ? 'char' : 'text';
5100
5101 #        ( $table.${prefix}city    = ? $or_empty_city   $ornull )
5102   "
5103         ( $table.district = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5104     AND ( $table.${prefix}city     = ? OR ? = '' OR CAST(? AS $text) IS NULL )
5105     AND ( $table.${prefix}county   = ? $or_empty_county $ornull )
5106     AND ( $table.${prefix}state    = ? $or_empty_state  $ornull )
5107     AND   $table.${prefix}country  = ?
5108   ";
5109 }
5110
5111 sub _X_show_zero {
5112   my( $self, $what ) = @_;
5113
5114   my $what_show_zero = $what. '_show_zero';
5115   length($self->$what_show_zero())
5116     ? ($self->$what_show_zero() eq 'Y')
5117     : $self->part_pkg->$what_show_zero();
5118 }
5119
5120 =head1 SUBROUTINES
5121
5122 =over 4
5123
5124 =item order CUSTNUM, PKGPARTS_ARYREF, [ REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF [ REFNUM ] ] ]
5125
5126 Bulk cancel + order subroutine.  Perhaps slightly deprecated, only used by the
5127 bulk cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
5128
5129 CUSTNUM is a customer (see L<FS::cust_main>)
5130
5131 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5132 L<FS::part_pkg>) to order for this customer.  Duplicates are of course
5133 permitted.
5134
5135 REMOVE_PKGNUMS is an optional list of pkgnums specifying the billing items to
5136 remove for this customer.  The services (see L<FS::cust_svc>) are moved to the
5137 new billing items.  An error is returned if this is not possible (see
5138 L<FS::pkg_svc>).  An empty arrayref is equivalent to not specifying this
5139 parameter.
5140
5141 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5142 newly-created cust_pkg objects.
5143
5144 REFNUM, if specified, will specify the FS::pkg_referral record to be created
5145 and inserted.  Multiple FS::pkg_referral records can be created by
5146 setting I<refnum> to an array reference of refnums or a hash reference with
5147 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
5148 record will be created corresponding to cust_main.refnum.
5149
5150 =cut
5151
5152 sub order {
5153   my ($custnum, $pkgparts, $remove_pkgnum, $return_cust_pkg, $refnum) = @_;
5154
5155   my $conf = new FS::Conf;
5156
5157   # Transactionize this whole mess
5158   my $oldAutoCommit = $FS::UID::AutoCommit;
5159   local $FS::UID::AutoCommit = 0;
5160   my $dbh = dbh;
5161
5162   my $error;
5163 #  my $cust_main = qsearchs('cust_main', { custnum => $custnum });
5164 #  return "Customer not found: $custnum" unless $cust_main;
5165
5166   warn "$me order: pkgnums to remove: ". join(',', @$remove_pkgnum). "\n"
5167     if $DEBUG;
5168
5169   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5170                          @$remove_pkgnum;
5171
5172   my $change = scalar(@old_cust_pkg) != 0;
5173
5174   my %hash = ();
5175   if ( scalar(@old_cust_pkg) == 1 && scalar(@$pkgparts) == 1 ) {
5176
5177     warn "$me order: changing pkgnum ". $old_cust_pkg[0]->pkgnum.
5178          " to pkgpart ". $pkgparts->[0]. "\n"
5179       if $DEBUG;
5180
5181     my $err_or_cust_pkg =
5182       $old_cust_pkg[0]->change( 'pkgpart' => $pkgparts->[0],
5183                                 'refnum'  => $refnum,
5184                               );
5185
5186     unless (ref($err_or_cust_pkg)) {
5187       $dbh->rollback if $oldAutoCommit;
5188       return $err_or_cust_pkg;
5189     }
5190
5191     push @$return_cust_pkg, $err_or_cust_pkg;
5192     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5193     return '';
5194
5195   }
5196
5197   # Create the new packages.
5198   foreach my $pkgpart (@$pkgparts) {
5199
5200     warn "$me order: inserting pkgpart $pkgpart\n" if $DEBUG;
5201
5202     my $cust_pkg = new FS::cust_pkg { custnum => $custnum,
5203                                       pkgpart => $pkgpart,
5204                                       refnum  => $refnum,
5205                                       %hash,
5206                                     };
5207     $error = $cust_pkg->insert( 'change' => $change );
5208     push @$return_cust_pkg, $cust_pkg;
5209
5210     foreach my $link ($cust_pkg->part_pkg->supp_part_pkg_link) {
5211       my $supp_pkg = FS::cust_pkg->new({
5212           custnum => $custnum,
5213           pkgpart => $link->dst_pkgpart,
5214           refnum  => $refnum,
5215           main_pkgnum => $cust_pkg->pkgnum,
5216           %hash,
5217       });
5218       $error ||= $supp_pkg->insert( 'change' => $change );
5219       push @$return_cust_pkg, $supp_pkg;
5220     }
5221
5222     if ($error) {
5223       $dbh->rollback if $oldAutoCommit;
5224       return $error;
5225     }
5226
5227   }
5228   # $return_cust_pkg now contains refs to all of the newly
5229   # created packages.
5230
5231   # Transfer services and cancel old packages.
5232   foreach my $old_pkg (@old_cust_pkg) {
5233
5234     warn "$me order: transferring services from pkgnum ". $old_pkg->pkgnum. "\n"
5235       if $DEBUG;
5236
5237     foreach my $new_pkg (@$return_cust_pkg) {
5238       $error = $old_pkg->transfer($new_pkg);
5239       if ($error and $error == 0) {
5240         # $old_pkg->transfer failed.
5241         $dbh->rollback if $oldAutoCommit;
5242         return $error;
5243       }
5244     }
5245
5246     if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
5247       warn "trying transfer again with change_svcpart option\n" if $DEBUG;
5248       foreach my $new_pkg (@$return_cust_pkg) {
5249         $error = $old_pkg->transfer($new_pkg, 'change_svcpart'=>1 );
5250         if ($error and $error == 0) {
5251           # $old_pkg->transfer failed.
5252         $dbh->rollback if $oldAutoCommit;
5253         return $error;
5254         }
5255       }
5256     }
5257
5258     if ($error > 0) {
5259       # Transfers were successful, but we went through all of the
5260       # new packages and still had services left on the old package.
5261       # We can't cancel the package under the circumstances, so abort.
5262       $dbh->rollback if $oldAutoCommit;
5263       return "Unable to transfer all services from package ".$old_pkg->pkgnum;
5264     }
5265     $error = $old_pkg->cancel( quiet=>1, 'no_delay_cancel'=>1 );
5266     if ($error) {
5267       $dbh->rollback;
5268       return $error;
5269     }
5270   }
5271   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5272   '';
5273 }
5274
5275 =item bulk_change PKGPARTS_ARYREF, REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF ]
5276
5277 A bulk change method to change packages for multiple customers.
5278
5279 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5280 L<FS::part_pkg>) to order for each customer.  Duplicates are of course
5281 permitted.
5282
5283 REMOVE_PKGNUMS is an list of pkgnums specifying the billing items to
5284 replace.  The services (see L<FS::cust_svc>) are moved to the
5285 new billing items.  An error is returned if this is not possible (see
5286 L<FS::pkg_svc>).
5287
5288 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5289 newly-created cust_pkg objects.
5290
5291 =cut
5292
5293 sub bulk_change {
5294   my ($pkgparts, $remove_pkgnum, $return_cust_pkg) = @_;
5295
5296   # Transactionize this whole mess
5297   my $oldAutoCommit = $FS::UID::AutoCommit;
5298   local $FS::UID::AutoCommit = 0;
5299   my $dbh = dbh;
5300
5301   my @errors;
5302   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5303                          @$remove_pkgnum;
5304
5305   while(scalar(@old_cust_pkg)) {
5306     my @return = ();
5307     my $custnum = $old_cust_pkg[0]->custnum;
5308     my (@remove) = map { $_->pkgnum }
5309                    grep { $_->custnum == $custnum } @old_cust_pkg;
5310     @old_cust_pkg = grep { $_->custnum != $custnum } @old_cust_pkg;
5311
5312     my $error = order $custnum, $pkgparts, \@remove, \@return;
5313
5314     push @errors, $error
5315       if $error;
5316     push @$return_cust_pkg, @return;
5317   }
5318
5319   if (scalar(@errors)) {
5320     $dbh->rollback if $oldAutoCommit;
5321     return join(' / ', @errors);
5322   }
5323
5324   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5325   '';
5326 }
5327
5328 =item forward_emails
5329
5330 Returns a hash of svcnums and corresponding email addresses
5331 for svc_acct services that can be used as source or dest
5332 for svc_forward services provisioned in this package.
5333
5334 Accepts options I<svc_forward> OR I<svcnum> for a svc_forward
5335 service;  if included, will ensure the current values of the
5336 specified service are included in the list, even if for some
5337 other reason they wouldn't be.  If called as a class method
5338 with a specified service, returns only these current values.
5339
5340 Caution: does not actually check if svc_forward services are
5341 available to be provisioned on this package.
5342
5343 =cut
5344
5345 sub forward_emails {
5346   my $self = shift;
5347   my %opt = @_;
5348
5349   #load optional service, thoroughly validated
5350   die "Use svcnum or svc_forward, not both"
5351     if $opt{'svcnum'} && $opt{'svc_forward'};
5352   my $svc_forward = $opt{'svc_forward'};
5353   $svc_forward ||= qsearchs('svc_forward',{ 'svcnum' => $opt{'svcnum'} })
5354     if $opt{'svcnum'};
5355   die "Specified service is not a forward service"
5356     if $svc_forward && (ref($svc_forward) ne 'FS::svc_forward');
5357   die "Specified service not found"
5358     if ($opt{'svcnum'} || $opt{'svc_forward'}) && !$svc_forward;
5359
5360   my %email;
5361
5362   ## everything below was basically copied from httemplate/edit/svc_forward.cgi
5363   ## with minimal refactoring, not sure why we can't just load all svc_accts for this custnum
5364
5365   #add current values from specified service, if there was one
5366   if ($svc_forward) {
5367     foreach my $method (qw( srcsvc_acct dstsvc_acct )) {
5368       my $svc_acct = $svc_forward->$method();
5369       $email{$svc_acct->svcnum} = $svc_acct->email if $svc_acct;
5370     }
5371   }
5372
5373   if (ref($self) eq 'FS::cust_pkg') {
5374
5375     #and including the rest for this customer
5376     my($u_part_svc,@u_acct_svcparts);
5377     foreach $u_part_svc ( qsearch('part_svc',{'svcdb'=>'svc_acct'}) ) {
5378       push @u_acct_svcparts,$u_part_svc->getfield('svcpart');
5379     }
5380
5381     my $custnum = $self->getfield('custnum');
5382     foreach my $i_cust_pkg ( qsearch('cust_pkg',{'custnum'=>$custnum}) ) {
5383       my $cust_pkgnum = $i_cust_pkg->getfield('pkgnum');
5384       #now find the corresponding record(s) in cust_svc (for this pkgnum!)
5385       foreach my $acct_svcpart (@u_acct_svcparts) {
5386         foreach my $i_cust_svc (
5387           qsearch( 'cust_svc', { 'pkgnum'  => $cust_pkgnum,
5388                                  'svcpart' => $acct_svcpart } )
5389         ) {
5390           my $svc_acct = qsearchs( 'svc_acct', { 'svcnum' => $i_cust_svc->svcnum } );
5391           $email{$svc_acct->svcnum} = $svc_acct->email;
5392         }
5393       }
5394     }
5395   }
5396
5397   return %email;
5398 }
5399
5400 # Used by FS::Upgrade to migrate to a new database.
5401 sub _upgrade_data {  # class method
5402   my ($class, %opts) = @_;
5403   $class->_upgrade_otaker(%opts);
5404   my @statements = (
5405     # RT#10139, bug resulting in contract_end being set when it shouldn't
5406   'UPDATE cust_pkg SET contract_end = NULL WHERE contract_end = -1',
5407     # RT#10830, bad calculation of prorate date near end of year
5408     # the date range for bill is December 2009, and we move it forward
5409     # one year if it's before the previous bill date (which it should
5410     # never be)
5411   'UPDATE cust_pkg SET bill = bill + (365*24*60*60) WHERE bill < last_bill
5412   AND bill > 1259654400 AND bill < 1262332800 AND (SELECT plan FROM part_pkg
5413   WHERE part_pkg.pkgpart = cust_pkg.pkgpart) = \'prorate\'',
5414     # RT6628, add order_date to cust_pkg
5415     'update cust_pkg set order_date = (select history_date from h_cust_pkg
5416         where h_cust_pkg.pkgnum = cust_pkg.pkgnum and
5417         history_action = \'insert\') where order_date is null',
5418   );
5419   foreach my $sql (@statements) {
5420     my $sth = dbh->prepare($sql);
5421     $sth->execute or die $sth->errstr;
5422   }
5423
5424   # RT31194: supplemental package links that are deleted don't clean up
5425   # linked records
5426   my @pkglinknums = qsearch({
5427       'select'    => 'DISTINCT cust_pkg.pkglinknum',
5428       'table'     => 'cust_pkg',
5429       'addl_from' => ' LEFT JOIN part_pkg_link USING (pkglinknum) ',
5430       'extra_sql' => ' WHERE cust_pkg.pkglinknum IS NOT NULL
5431                         AND part_pkg_link.pkglinknum IS NULL',
5432   });
5433   foreach (@pkglinknums) {
5434     my $pkglinknum = $_->pkglinknum;
5435     warn "cleaning part_pkg_link #$pkglinknum\n";
5436     my $part_pkg_link = FS::part_pkg_link->new({pkglinknum => $pkglinknum});
5437     my $error = $part_pkg_link->remove_linked;
5438     die $error if $error;
5439   }
5440 }
5441
5442 =back
5443
5444 =head1 BUGS
5445
5446 sub order is not OO.  Perhaps it should be moved to FS::cust_main and made so?
5447
5448 In sub order, the @pkgparts array (passed by reference) is clobbered.
5449
5450 Also in sub order, no money is adjusted.  Once FS::part_pkg defines a standard
5451 method to pass dates to the recur_prog expression, it should do so.
5452
5453 FS::svc_acct, FS::svc_domain, FS::svc_www, FS::svc_ip and FS::svc_forward are
5454 loaded via 'use' at compile time, rather than via 'require' in sub { setup,
5455 suspend, unsuspend, cancel } because they use %FS::UID::callback to load
5456 configuration values.  Probably need a subroutine which decides what to do
5457 based on whether or not we've fetched the user yet, rather than a hash.  See
5458 FS::UID and the TODO.
5459
5460 Now that things are transactional should the check in the insert method be
5461 moved to check ?
5462
5463 =head1 SEE ALSO
5464
5465 L<FS::Record>, L<FS::cust_main>, L<FS::part_pkg>, L<FS::cust_svc>,
5466 L<FS::pkg_svc>, schema.html from the base documentation
5467
5468 =cut
5469
5470 1;
5471