FS/FS/cust_pkg.pm

   1 package FS::cust_pkg;
   2 use base qw( FS::cust_pkg::Search FS::cust_pkg::API
   3              FS::otaker_Mixin FS::cust_main_Mixin FS::Sales_Mixin
   4              FS::contact_Mixin FS::location_Mixin
   5              FS::m2m_Common FS::option_Common
   6            );
   7
   8 use strict;
   9 use Carp qw(cluck);
  10 use Scalar::Util qw( blessed );
  11 use List::Util qw(min max);
  12 use Tie::IxHash;
  13 use Time::Local qw( timelocal timelocal_nocheck );
  14 use MIME::Entity;
  15 use FS::UID qw( dbh driver_name );
  16 use FS::Record qw( qsearch qsearchs fields );
  17 use FS::CurrentUser;
  18 use FS::cust_svc;
  19 use FS::part_pkg;
  20 use FS::cust_main;
  21 use FS::contact;
  22 use FS::cust_location;
  23 use FS::pkg_svc;
  24 use FS::cust_bill_pkg;
  25 use FS::cust_pkg_detail;
  26 use FS::cust_pkg_usage;
  27 use FS::cdr_cust_pkg_usage;
  28 use FS::cust_event;
  29 use FS::h_cust_svc;
  30 use FS::reg_code;
  31 use FS::part_svc;
  32 use FS::cust_pkg_reason;
  33 use FS::reason;
  34 use FS::cust_pkg_usageprice;
  35 use FS::cust_pkg_discount;
  36 use FS::discount;
  37 use FS::sales;
  38 # for modify_charge
  39 use FS::cust_credit;
  40
  41 # temporary fix; remove this once (un)suspend admin notices are cleaned up
  42 use FS::Misc qw(send_email);
  43
  44 # need to 'use' these instead of 'require' in sub { cancel, suspend, unsuspend,
  45 # setup }
  46 # because they load configuration by setting FS::UID::callback (see TODO)
  47 use FS::svc_acct;
  48 use FS::svc_domain;
  49 use FS::svc_www;
  50 use FS::svc_forward;
  51
  52 # for sending cancel emails in sub cancel
  53 use FS::Conf;
  54
  55 our ($disable_agentcheck, $DEBUG, $me, $import) = (0, 0, '[FS::cust_pkg]', 0);
  56
  57 our $upgrade = 0; #go away after setup+start dates cleaned up for old customers
  58
  59 our $cache_enabled = 0;
  60
  61 sub _simplecache {
  62   my( $self, $hashref ) = @_;
  63   if ( $cache_enabled && $hashref->{'pkg'} && $hashref->{'plan'} ) {
  64     $self->{'_pkgpart'} = FS::part_pkg->new($hashref);
  65   }
  66 }
  67
  68 sub _cache {
  69   my $self = shift;
  70   my ( $hashref, $cache ) = @_;
  71 #  #if ( $hashref->{'pkgpart'} ) {
  72 #  if ( $hashref->{'pkg'} ) {
  73 #    # #@{ $self->{'_pkgnum'} } = ();
  74 #    # my $subcache = $cache->subcache('pkgpart', 'part_pkg');
  75 #    # $self->{'_pkgpart'} = $subcache;
  76 #    # #push @{ $self->{'_pkgnum'} },
  77 #    #   FS::part_pkg->new_or_cached($hashref, $subcache);
  78 #    $self->{'_pkgpart'} = FS::part_pkg->new($hashref);
  79 #  }
  80   if ( exists $hashref->{'svcnum'} ) {
  81     #@{ $self->{'_pkgnum'} } = ();
  82     my $subcache = $cache->subcache('svcnum', 'cust_svc', $hashref->{pkgnum});
  83     $self->{'_svcnum'} = $subcache;
  84     #push @{ $self->{'_pkgnum'} },
  85     FS::cust_svc->new_or_cached($hashref, $subcache) if $hashref->{svcnum};
  86   }
  87 }
  88
  89 =head1 NAME
  90
  91 FS::cust_pkg - Object methods for cust_pkg objects
  92
  93 =head1 SYNOPSIS
  94
  95   use FS::cust_pkg;
  96
  97   $record = new FS::cust_pkg \%hash;
  98   $record = new FS::cust_pkg { 'column' => 'value' };
  99
 100   $error = $record->insert;
 101
 102   $error = $new_record->replace($old_record);
 103
 104   $error = $record->delete;
 105
 106   $error = $record->check;
 107
 108   $error = $record->cancel;
 109
 110   $error = $record->suspend;
 111
 112   $error = $record->unsuspend;
 113
 114   $part_pkg = $record->part_pkg;
 115
 116   @labels = $record->labels;
 117
 118   $seconds = $record->seconds_since($timestamp);
 119
 120   #bulk cancel+order... perhaps slightly deprecated, only used by the bulk
 121   # cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
 122   $error = FS::cust_pkg::order( $custnum, \@pkgparts );
 123   $error = FS::cust_pkg::order( $custnum, \@pkgparts, \@remove_pkgnums ] );
 124
 125 =head1 DESCRIPTION
 126
 127 An FS::cust_pkg object represents a customer billing item.  FS::cust_pkg
 128 inherits from FS::Record.  The following fields are currently supported:
 129
 130 =over 4
 131
 132 =item pkgnum
 133
 134 Primary key (assigned automatically for new billing items)
 135
 136 =item custnum
 137
 138 Customer (see L<FS::cust_main>)
 139
 140 =item pkgpart
 141
 142 Billing item definition (see L<FS::part_pkg>)
 143
 144 =item locationnum
 145
 146 Optional link to package location (see L<FS::location>)
 147
 148 =item order_date
 149
 150 date package was ordered (also remains same on changes)
 151
 152 =item start_date
 153
 154 date
 155
 156 =item setup
 157
 158 date
 159
 160 =item bill
 161
 162 date (next bill date)
 163
 164 =item last_bill
 165
 166 last bill date
 167
 168 =item adjourn
 169
 170 date
 171
 172 =item susp
 173
 174 date
 175
 176 =item expire
 177
 178 date
 179
 180 =item contract_end
 181
 182 date
 183
 184 =item cancel
 185
 186 date
 187
 188 =item usernum
 189
 190 order taker (see L<FS::access_user>)
 191
 192 =item quantity
 193
 194 If not set, defaults to 1
 195
 196 =item change_date
 197
 198 Date of change from previous package
 199
 200 =item change_pkgnum
 201
 202 Previous pkgnum
 203
 204 =item change_pkgpart
 205
 206 Previous pkgpart
 207
 208 =item change_locationnum
 209
 210 Previous locationnum
 211
 212 =item waive_setup
 213
 214 =item main_pkgnum
 215
 216 The pkgnum of the package that this package is supplemental to, if any.
 217
 218 =item pkglinknum
 219
 220 The package link (L<FS::part_pkg_link>) that defines this supplemental
 221 package, if it is one.
 222
 223 =item change_to_pkgnum
 224
 225 The pkgnum of the package this one will be "changed to" in the future
 226 (on its expiration date).
 227
 228 =back
 229
 230 Note: setup, last_bill, bill, adjourn, susp, expire, cancel and change_date
 231 are specified as UNIX timestamps; see L<perlfunc/"time">.  Also see
 232 L<Time::Local> and L<Date::Parse> for conversion functions.
 233
 234 =head1 METHODS
 235
 236 =over 4
 237
 238 =item new HASHREF
 239
 240 Create a new billing item.  To add the item to the database, see L<"insert">.
 241
 242 =cut
 243
 244 sub table { 'cust_pkg'; }
 245 sub cust_linked { $_[0]->cust_main_custnum || $_[0]->custnum }
 246 sub cust_unlinked_msg {
 247   my $self = shift;
 248   "WARNING: can't find cust_main.custnum ". $self->custnum.
 249   ' (cust_pkg.pkgnum '. $self->pkgnum. ')';
 250 }
 251
 252 =item set_initial_timers
 253
 254 If required by the package definition, sets any automatic expire, adjourn,
 255 or contract_end timers to some number of months after the start date
 256 (or setup date, if the package has already been setup). If the package has
 257 a delayed setup fee after a period of "free days", will also set the
 258 start date to the end of that period.
 259
 260 If the package has an automatic transfer rule (C<change_to_pkgnum>), then
 261 this will also order the package and set its start date.
 262
 263 =cut
 264
 265 sub set_initial_timers {
 266   my $self = shift;
 267   my $part_pkg = $self->part_pkg;
 268   my $start = $self->start_date || $self->setup || time;
 269
 270   foreach my $action ( qw(expire adjourn contract_end) ) {
 271     my $months = $part_pkg->get("${action}_months");
 272     if($months and !$self->get($action)) {
 273       $self->set($action, $part_pkg->add_freq($start, $months) );
 274     }
 275   }
 276
 277   # if this package has an expire date and a change_to_pkgpart, set automatic
 278   # package transfer
 279   # (but don't call change_later, as that would call $self->replace, and we're
 280   # probably in the middle of $self->insert right now)
 281   if ( $part_pkg->expire_months and $part_pkg->change_to_pkgpart ) {
 282     if ( $self->change_to_pkgnum ) {
 283       # this can happen if a package is ordered on hold, scheduled for a
 284       # future change _while on hold_, and then released from hold, causing
 285       # the automatic transfer to schedule.
 286       #
 287       # what's correct behavior in that case? I think it's to disallow
 288       # future-changing an on-hold package that has an automatic transfer.
 289       # but if we DO get into this situation, let the manual package change
 290       # win.
 291       warn "pkgnum ".$self->pkgnum.": manual future package change blocks ".
 292            "automatic transfer.\n";
 293     } else {
 294       my $change_to = FS::cust_pkg->new( {
 295           start_date  => $self->get('expire'),
 296           pkgpart     => $part_pkg->change_to_pkgpart,
 297           map { $_ => $self->get($_) }
 298             qw( custnum locationnum quantity refnum salesnum contract_end )
 299       } );
 300       my $error = $change_to->insert;
 301
 302       return $error if $error;
 303       $self->set('change_to_pkgnum', $change_to->pkgnum);
 304     }
 305   }
 306
 307   # if this package has "free days" and delayed setup fee, then
 308   # set start date that many days in the future.
 309   # (this should have been set in the UI, but enforce it here)
 310   if ( $part_pkg->option('free_days',1)
 311        && $part_pkg->option('delay_setup',1)
 312      )
 313   {
 314     $self->start_date( $part_pkg->default_start_date );
 315   }
 316
 317   '';
 318 }
 319
 320 =item insert [ OPTION => VALUE ... ]
 321
 322 Adds this billing item to the database ("Orders" the item).  If there is an
 323 error, returns the error, otherwise returns false.
 324
 325 If the additional field I<promo_code> is defined instead of I<pkgpart>, it
 326 will be used to look up the package definition and agent restrictions will be
 327 ignored.
 328
 329 If the additional field I<refnum> is defined, an FS::pkg_referral record will
 330 be created and inserted.  Multiple FS::pkg_referral records can be created by
 331 setting I<refnum> to an array reference of refnums or a hash reference with
 332 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
 333 record will be created corresponding to cust_main.refnum.
 334
 335 If the additional field I<cust_pkg_usageprice> is defined, it will be treated
 336 as an arrayref of FS::cust_pkg_usageprice objects, which will be inserted.
 337 (Note that this field cannot be set with a usual ->cust_pkg_usageprice method.
 338 It can be set as part of the hash when creating the object, or with the B<set>
 339 method.)
 340
 341 The following options are available:
 342
 343 =over 4
 344
 345 =item change
 346
 347 If set true, supresses actions that should only be taken for new package
 348 orders.  (Currently this includes: intro periods when delay_setup is on,
 349 auto-adding a 1st start date, auto-adding expiration/adjourn/contract_end dates)
 350
 351 =item options
 352
 353 cust_pkg_option records will be created
 354
 355 =item ticket_subject
 356
 357 a ticket will be added to this customer with this subject
 358
 359 =item ticket_queue
 360
 361 an optional queue name for ticket additions
 362
 363 =item allow_pkgpart
 364
 365 Don't check the legality of the package definition.  This should be used
 366 when performing a package change that doesn't change the pkgpart (i.e.
 367 a location change).
 368
 369 =back
 370
 371 =cut
 372
 373 sub insert {
 374   my( $self, %options ) = @_;
 375
 376   my $oldAutoCommit = $FS::UID::AutoCommit;
 377   local $FS::UID::AutoCommit = 0;
 378   my $dbh = dbh;
 379
 380   my $error;
 381   $error = $self->check_pkgpart unless $options{'allow_pkgpart'};
 382
 383   my $part_pkg = $self->part_pkg;
 384
 385   if ( ! $import && ! $options{'change'} ) {
 386
 387     # set order date to now
 388     $self->order_date(time) unless ($import && $self->order_date);
 389
 390     # if the package def says to start only on the first of the month:
 391     if ( $part_pkg->option('start_1st', 1) && !$self->start_date ) {
 392       my ($sec,$min,$hour,$mday,$mon,$year) = (localtime(time) )[0,1,2,3,4,5];
 393       $mon += 1 unless $mday == 1;
 394       until ( $mon < 12 ) { $mon -= 12; $year++; }
 395       $self->start_date( timelocal_nocheck(0,0,0,1,$mon,$year) );
 396     }
 397
 398     if ($self->susp eq 'now' or $part_pkg->start_on_hold) {
 399       # if the package was ordered on hold:
 400       # - suspend it
 401       # - don't set the start date (it will be started manually)
 402       $self->set('susp', $self->order_date);
 403       $self->set('start_date', '');
 404     } else {
 405       # set expire/adjourn/contract_end timers, and free days, if appropriate
 406       # and automatic package transfer, which can fail, so capture the result
 407       $error = $self->set_initial_timers;
 408     }
 409   } # else this is a package change, and shouldn't have "new package" behavior
 410
 411   $error ||= $self->SUPER::insert($options{options} ? %{$options{options}} : ());
 412   if ( $error ) {
 413     $dbh->rollback if $oldAutoCommit;
 414     return $error;
 415   }
 416
 417   $self->refnum($self->cust_main->refnum) unless $self->refnum;
 418   $self->refnum( [ $self->refnum ] ) unless ref($self->refnum);
 419   $self->process_m2m( 'link_table'   => 'pkg_referral',
 420                       'target_table' => 'part_referral',
 421                       'params'       => $self->refnum,
 422                     );
 423
 424   if ( $self->hashref->{cust_pkg_usageprice} ) {
 425     for my $cust_pkg_usageprice ( @{ $self->hashref->{cust_pkg_usageprice} } ) {
 426       $cust_pkg_usageprice->pkgnum( $self->pkgnum );
 427       my $error = $cust_pkg_usageprice->insert;
 428       if ( $error ) {
 429         $dbh->rollback if $oldAutoCommit;
 430         return $error;
 431       }
 432     }
 433   }
 434
 435   if ( $self->setup_discountnum || $self->recur_discountnum ) {
 436     my $error = $self->insert_discount();
 437     if ( $error ) {
 438       $dbh->rollback if $oldAutoCommit;
 439       return $error;
 440     }
 441   }
 442
 443   my $conf = new FS::Conf;
 444
 445   if ($self->locationnum) {
 446     my @part_export =
 447       map qsearch( 'part_export', {exportnum=>$_} ),
 448         $conf->config('cust_location-exports'); #, $agentnum
 449
 450     foreach my $part_export ( @part_export ) {
 451       my $error = $part_export->export_pkg_location($self); #, @$export_args);
 452       if ( $error ) {
 453         $dbh->rollback if $oldAutoCommit;
 454         return "exporting to ". $part_export->exporttype.
 455                " (transaction rolled back): $error";
 456       }
 457     }
 458   }
 459
 460   if ( ! $import && $conf->config('ticket_system') && $options{ticket_subject} ) {
 461
 462     #this init stuff is still inefficient, but at least its limited to
 463     # the small number (any?) folks using ticket emailing on pkg order
 464
 465     #eval '
 466     #  use lib ( "/opt/rt3/local/lib", "/opt/rt3/lib" );
 467     #  use RT;
 468     #';
 469     #die $@ if $@;
 470     #
 471     #RT::LoadConfig();
 472     #RT::Init();
 473     use FS::TicketSystem;
 474     FS::TicketSystem->init();
 475
 476     my $q = new RT::Queue($RT::SystemUser);
 477     $q->Load($options{ticket_queue}) if $options{ticket_queue};
 478     my $t = new RT::Ticket($RT::SystemUser);
 479     my $mime = new MIME::Entity;
 480     $mime->build( Type => 'text/plain', Data => $options{ticket_subject} );
 481     $t->Create( $options{ticket_queue} ? (Queue => $q) : (),
 482                 Subject => $options{ticket_subject},
 483                 MIMEObj => $mime,
 484               );
 485     $t->AddLink( Type   => 'MemberOf',
 486                  Target => 'freeside://freeside/cust_main/'. $self->custnum,
 487                );
 488   }
 489
 490   if (! $import && $conf->config('welcome_letter') && $self->cust_main->num_pkgs == 1) {
 491     my $queue = new FS::queue {
 492       'job'     => 'FS::cust_main::queueable_print',
 493     };
 494     $error = $queue->insert(
 495       'custnum'  => $self->custnum,
 496       'template' => 'welcome_letter',
 497     );
 498
 499     if ($error) {
 500       warn "can't send welcome letter: $error";
 501     }
 502
 503   }
 504
 505   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 506   '';
 507
 508 }
 509
 510 =item delete
 511
 512 This method now works but you probably shouldn't use it.
 513
 514 You don't want to delete packages, because there would then be no record
 515 the customer ever purchased the package.  Instead, see the cancel method and
 516 hide cancelled packages.
 517
 518 =cut
 519
 520 # this is still used internally to abort future package changes, so it
 521 # does need to work
 522
 523 sub delete {
 524   my $self = shift;
 525
 526   # The following foreign keys to cust_pkg are not cleaned up here, and will
 527   # cause package deletion to fail:
 528   #
 529   # cust_credit.pkgnum and commission_pkgnum (and cust_credit_void)
 530   # cust_credit_bill.pkgnum
 531   # cust_pay_pending.pkgnum
 532   # cust_pay.pkgnum (and cust_pay_void)
 533   # cust_bill_pay.pkgnum (wtf, shouldn't reference pkgnum)
 534   # cust_pkg_usage.pkgnum
 535   # cust_pkg.uncancel_pkgnum, change_pkgnum, main_pkgnum, and change_to_pkgnum
 536
 537   # cust_svc is handled by canceling the package before deleting it
 538   # cust_pkg_option is handled via option_Common
 539
 540   my $oldAutoCommit = $FS::UID::AutoCommit;
 541   local $FS::UID::AutoCommit = 0;
 542   my $dbh = dbh;
 543
 544   foreach my $cust_pkg_discount ($self->cust_pkg_discount) {
 545     my $error = $cust_pkg_discount->delete;
 546     if ( $error ) {
 547       $dbh->rollback if $oldAutoCommit;
 548       return $error;
 549     }
 550   }
 551   #cust_bill_pkg_discount?
 552
 553   foreach my $cust_pkg_detail ($self->cust_pkg_detail) {
 554     my $error = $cust_pkg_detail->delete;
 555     if ( $error ) {
 556       $dbh->rollback if $oldAutoCommit;
 557       return $error;
 558     }
 559   }
 560
 561   foreach my $cust_pkg_reason (
 562     qsearchs( {
 563                 'table' => 'cust_pkg_reason',
 564                 'hashref' => { 'pkgnum' => $self->pkgnum },
 565               }
 566             )
 567   ) {
 568     my $error = $cust_pkg_reason->delete;
 569     if ( $error ) {
 570       $dbh->rollback if $oldAutoCommit;
 571       return $error;
 572     }
 573   }
 574
 575   foreach my $pkg_referral ( $self->pkg_referral ) {
 576     my $error = $pkg_referral->delete;
 577     if ( $error ) {
 578       $dbh->rollback if $oldAutoCommit;
 579       return $error;
 580     }
 581   }
 582
 583   my $error = $self->SUPER::delete(@_);
 584   if ( $error ) {
 585     $dbh->rollback if $oldAutoCommit;
 586     return $error;
 587   }
 588
 589   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 590
 591   '';
 592
 593 }
 594
 595 =item replace [ OLD_RECORD ] [ HASHREF | OPTION => VALUE ... ]
 596
 597 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 598 returns the error, otherwise returns false.
 599
 600 Currently, custnum, setup, bill, adjourn, susp, expire, and cancel may be changed.
 601
 602 Changing pkgpart may have disasterous effects.  See the order subroutine.
 603
 604 setup and bill are normally updated by calling the bill method of a customer
 605 object (see L<FS::cust_main>).
 606
 607 suspend is normally updated by the suspend and unsuspend methods.
 608
 609 cancel is normally updated by the cancel method (and also the order subroutine
 610 in some cases).
 611
 612 Available options are:
 613
 614 =over 4
 615
 616 =item reason
 617
 618 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
 619
 620 =item reason_otaker
 621
 622 the access_user (see L<FS::access_user>) providing the reason
 623
 624 =item options
 625
 626 hashref of keys and values - cust_pkg_option records will be created, updated or removed as appopriate
 627
 628 =back
 629
 630 =cut
 631
 632 sub replace {
 633   my $new = shift;
 634
 635   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 636               ? shift
 637               : $new->replace_old;
 638
 639   my $options =
 640     ( ref($_[0]) eq 'HASH' )
 641       ? shift
 642       : { @_ };
 643
 644   #return "Can't (yet?) change pkgpart!" if $old->pkgpart != $new->pkgpart;
 645   #return "Can't change otaker!" if $old->otaker ne $new->otaker;
 646
 647   #allow this *sigh*
 648   #return "Can't change setup once it exists!"
 649   #  if $old->getfield('setup') &&
 650   #     $old->getfield('setup') != $new->getfield('setup');
 651
 652   #some logic for bill, susp, cancel?
 653
 654   local($disable_agentcheck) = 1 if $old->pkgpart == $new->pkgpart;
 655
 656   my $oldAutoCommit = $FS::UID::AutoCommit;
 657   local $FS::UID::AutoCommit = 0;
 658   my $dbh = dbh;
 659
 660   foreach my $method ( qw(adjourn expire) ) {  # How many reasons?
 661     if ($options->{'reason'} && $new->$method && $old->$method ne $new->$method) {
 662       my $error = $new->insert_reason(
 663         'reason'        => $options->{'reason'},
 664         'date'          => $new->$method,
 665         'action'        => $method,
 666         'reason_otaker' => $options->{'reason_otaker'},
 667       );
 668       if ( $error ) {
 669         dbh->rollback if $oldAutoCommit;
 670         return "Error inserting cust_pkg_reason: $error";
 671       }
 672     }
 673   }
 674
 675   #save off and freeze RADIUS attributes for any associated svc_acct records
 676   my @svc_acct = ();
 677   if ( $old->part_pkg->is_prepaid || $new->part_pkg->is_prepaid ) {
 678
 679                 #also check for specific exports?
 680                 # to avoid spurious modify export events
 681     @svc_acct = map  { $_->svc_x }
 682                 grep { $_->part_svc->svcdb eq 'svc_acct' }
 683                      $old->cust_svc;
 684
 685     $_->snapshot foreach @svc_acct;
 686
 687   }
 688
 689   my $error =  $new->export_pkg_change($old)
 690             || $new->SUPER::replace( $old,
 691                                      $options->{options}
 692                                        ? $options->{options}
 693                                        : ()
 694                                    );
 695   if ( $error ) {
 696     $dbh->rollback if $oldAutoCommit;
 697     return $error;
 698   }
 699
 700   #for prepaid packages,
 701   #trigger export of new RADIUS Expiration attribute when cust_pkg.bill changes
 702   foreach my $old_svc_acct ( @svc_acct ) {
 703     my $new_svc_acct = new FS::svc_acct { $old_svc_acct->hash };
 704     my $s_error =
 705       $new_svc_acct->replace( $old_svc_acct,
 706                               'depend_jobnum' => $options->{depend_jobnum},
 707                             );
 708     if ( $s_error ) {
 709       $dbh->rollback if $oldAutoCommit;
 710       return $s_error;
 711     }
 712   }
 713
 714   # also run exports if removing locationnum?
 715   #   doesn't seem to happen, and we don't export blank locationnum on insert...
 716   if ($new->locationnum and ($new->locationnum != $old->locationnum)) {
 717     my $conf = new FS::Conf;
 718     my @part_export =
 719       map qsearch( 'part_export', {exportnum=>$_} ),
 720         $conf->config('cust_location-exports'); #, $agentnum
 721
 722     foreach my $part_export ( @part_export ) {
 723       my $error = $part_export->export_pkg_location($new); #, @$export_args);
 724       if ( $error ) {
 725         $dbh->rollback if $oldAutoCommit;
 726         return "exporting to ". $part_export->exporttype.
 727                " (transaction rolled back): $error";
 728       }
 729     }
 730   }
 731
 732   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 733   '';
 734
 735 }
 736
 737 =item check
 738
 739 Checks all fields to make sure this is a valid billing item.  If there is an
 740 error, returns the error, otherwise returns false.  Called by the insert and
 741 replace methods.
 742
 743 =cut
 744
 745 sub check {
 746   my $self = shift;
 747
 748   if ( !$self->locationnum or $self->locationnum == -1 ) {
 749     $self->set('locationnum', $self->cust_main->ship_locationnum);
 750   }
 751
 752   my $error =
 753     $self->ut_numbern('pkgnum')
 754     || $self->ut_foreign_key('custnum', 'cust_main', 'custnum')
 755     || $self->ut_numbern('pkgpart')
 756     || $self->ut_foreign_keyn('contactnum',  'contact',       'contactnum' )
 757     || $self->ut_foreign_keyn('locationnum', 'cust_location', 'locationnum')
 758     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
 759     || $self->ut_numbern('quantity')
 760     || $self->ut_numbern('start_date')
 761     || $self->ut_numbern('setup')
 762     || $self->ut_numbern('bill')
 763     || $self->ut_numbern('susp')
 764     || $self->ut_numbern('cancel')
 765     || $self->ut_numbern('adjourn')
 766     || $self->ut_numbern('resume')
 767     || $self->ut_numbern('expire')
 768     || $self->ut_numbern('dundate')
 769     || $self->ut_flag('no_auto', [ '', 'Y' ])
 770     || $self->ut_flag('waive_setup', [ '', 'Y' ])
 771     || $self->ut_flag('separate_bill')
 772     || $self->ut_textn('agent_pkgid')
 773     || $self->ut_enum('recur_show_zero', [ '', 'Y', 'N', ])
 774     || $self->ut_enum('setup_show_zero', [ '', 'Y', 'N', ])
 775     || $self->ut_foreign_keyn('main_pkgnum', 'cust_pkg', 'pkgnum')
 776     || $self->ut_foreign_keyn('pkglinknum', 'part_pkg_link', 'pkglinknum')
 777     || $self->ut_foreign_keyn('change_to_pkgnum', 'cust_pkg', 'pkgnum')
 778   ;
 779   return $error if $error;
 780
 781   return "A package with both start date (future start) and setup date (already started) will never bill"
 782     if $self->start_date && $self->setup && ! $upgrade;
 783
 784   return "A future unsuspend date can only be set for a package with a suspend date"
 785     if $self->resume and !$self->susp and !$self->adjourn;
 786
 787   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 788
 789   $self->SUPER::check;
 790 }
 791
 792 =item check_pkgpart
 793
 794 Check the pkgpart to make sure it's allowed with the reg_code and/or
 795 promo_code of the package (if present) and with the customer's agent.
 796 Called from C<insert>, unless we are doing a package change that doesn't
 797 affect pkgpart.
 798
 799 =cut
 800
 801 sub check_pkgpart {
 802   my $self = shift;
 803
 804   # my $error = $self->ut_numbern('pkgpart'); # already done
 805
 806   my $error;
 807   if ( $self->reg_code ) {
 808
 809     unless ( grep { $self->pkgpart == $_->pkgpart }
 810              map  { $_->reg_code_pkg }
 811              qsearchs( 'reg_code', { 'code'     => $self->reg_code,
 812                                      'agentnum' => $self->cust_main->agentnum })
 813            ) {
 814       return "Unknown registration code";
 815     }
 816
 817   } elsif ( $self->promo_code ) {
 818
 819     my $promo_part_pkg =
 820       qsearchs('part_pkg', {
 821         'pkgpart'    => $self->pkgpart,
 822         'promo_code' => { op=>'ILIKE', value=>$self->promo_code },
 823       } );
 824     return 'Unknown promotional code' unless $promo_part_pkg;
 825
 826   } else {
 827
 828     unless ( $disable_agentcheck ) {
 829       my $agent =
 830         qsearchs( 'agent', { 'agentnum' => $self->cust_main->agentnum } );
 831       return "agent ". $agent->agentnum. ':'. $agent->agent.
 832              " can't purchase pkgpart ". $self->pkgpart
 833         unless $agent->pkgpart_hashref->{ $self->pkgpart }
 834             || $agent->agentnum == $self->part_pkg->agentnum;
 835     }
 836
 837     $error = $self->ut_foreign_key('pkgpart', 'part_pkg', 'pkgpart' );
 838     return $error if $error;
 839
 840   }
 841
 842   '';
 843
 844 }
 845
 846 =item cancel [ OPTION => VALUE ... ]
 847
 848 Cancels and removes all services (see L<FS::cust_svc> and L<FS::part_svc>)
 849 in this package, then cancels the package itself (sets the cancel field to
 850 now).
 851
 852 Available options are:
 853
 854 =over 4
 855
 856 =item quiet - can be set true to supress email cancellation notices.
 857
 858 =item time -  can be set to cancel the package based on a specific future or
 859 historical date.  Using time ensures that the remaining amount is calculated
 860 correctly.  Note however that this is an immediate cancel and just changes
 861 the date.  You are PROBABLY looking to expire the account instead of using
 862 this.
 863
 864 =item reason - can be set to a cancellation reason (see L<FS:reason>),
 865 either a reasonnum of an existing reason, or passing a hashref will create
 866 a new reason.  The hashref should have the following keys: typenum - Reason
 867 type (see L<FS::reason_type>, reason - Text of the new reason.
 868
 869 =item date - can be set to a unix style timestamp to specify when to
 870 cancel (expire)
 871
 872 =item nobill - can be set true to skip billing if it might otherwise be done.
 873
 874 =item unused_credit - can be set to 1 to credit the remaining time, or 0 to
 875 not credit it.  This must be set (by change()) when changing the package
 876 to a different pkgpart or location, and probably shouldn't be in any other
 877 case.  If it's not set, the 'unused_credit_cancel' part_pkg option will
 878 be used.
 879
 880 =item no_delay_cancel - prevents delay_cancel behavior
 881 no matter what other options say, for use when changing packages (or any
 882 other time you're really sure you want an immediate cancel)
 883
 884 =back
 885
 886 If there is an error, returns the error, otherwise returns false.
 887
 888 =cut
 889
 890 #NOT DOCUMENTING - this should only be used when calling recursively
 891 #=item delay_cancel - for internal use, to allow proper handling of
 892 #supplemental packages when the main package is flagged to suspend
 893 #before cancelling, probably shouldn't be used otherwise (set the
 894 #corresponding package option instead)
 895
 896 sub cancel {
 897   my( $self, %options ) = @_;
 898   my $error;
 899
 900   # supplemental packages can now be separately canceled, though the UI
 901   # shouldn't permit it
 902   #
 903   ## pass all suspend/cancel actions to the main package
 904   ## (unless the pkglinknum has been removed, then the link is defunct and
 905   ## this package can be canceled on its own)
 906   #if ( $self->main_pkgnum and $self->pkglinknum and !$options{'from_main'} ) {
 907   #  return $self->main_pkg->cancel(%options);
 908   #}
 909
 910   my $conf = new FS::Conf;
 911
 912   warn "cust_pkg::cancel called with options".
 913        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 914     if $DEBUG;
 915
 916   my $oldAutoCommit = $FS::UID::AutoCommit;
 917   local $FS::UID::AutoCommit = 0;
 918   my $dbh = dbh;
 919
 920   my $old = $self->select_for_update;
 921
 922   if ( $old->get('cancel') || $self->get('cancel') ) {
 923     dbh->rollback if $oldAutoCommit;
 924     return "";  # no error
 925   }
 926
 927   # XXX possibly set cancel_time to the expire date?
 928   my $cancel_time = $options{'time'} || time;
 929   my $date = $options{'date'} if $options{'date'}; # expire/cancel later
 930   $date = '' if ($date && $date <= $cancel_time);      # complain instead?
 931
 932   my $delay_cancel = $options{'no_delay_cancel'} ? 0 : $options{'delay_cancel'};
 933   if ( !$date && $self->part_pkg->option('delay_cancel',1)
 934        && (($self->status eq 'active') || ($self->status eq 'suspended'))
 935        && !$options{'no_delay_cancel'}
 936   ) {
 937     my $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
 938     my $expsecs = 60*60*24*$expdays;
 939     my $suspfor = $self->susp ? $cancel_time - $self->susp : 0;
 940     $expsecs = $expsecs - $suspfor if $suspfor;
 941     unless ($expsecs <= 0) { #if it's already been suspended long enough, don't re-suspend
 942       $delay_cancel = 1;
 943       $date = $cancel_time + $expsecs;
 944     }
 945   }
 946
 947   #race condition: usage could be ongoing until unprovisioned
 948   #resolved by performing a change package instead (which unprovisions) and
 949   #later cancelling
 950   if ( !$options{nobill} && !$date ) {
 951     # && $conf->exists('bill_usage_on_cancel') ) { #calc_cancel checks this
 952       my $copy = $self->new({$self->hash});
 953       my $error =
 954         $copy->cust_main->bill( 'pkg_list' => [ $copy ],
 955                                 'cancel'   => 1,
 956                                 'time'     => $cancel_time );
 957       warn "Error billing during cancel, custnum ".
 958         #$self->cust_main->custnum. ": $error"
 959         ": $error"
 960         if $error;
 961   }
 962
 963   if ( $options{'reason'} ) {
 964     $error = $self->insert_reason( 'reason' => $options{'reason'},
 965                                    'action' => $date ? 'expire' : 'cancel',
 966                                    'date'   => $date ? $date : $cancel_time,
 967                                    'reason_otaker' => $options{'reason_otaker'},
 968                                  );
 969     if ( $error ) {
 970       dbh->rollback if $oldAutoCommit;
 971       return "Error inserting cust_pkg_reason: $error";
 972     }
 973   }
 974
 975   my %svc_cancel_opt = ();
 976   $svc_cancel_opt{'date'} = $date if $date;
 977   foreach my $cust_svc (
 978     #schwartz
 979     map  { $_->[0] }
 980     sort { $a->[1] <=> $b->[1] }
 981     map  { [ $_, $_->svc_x ? $_->svc_x->table_info->{'cancel_weight'} : -1 ]; }
 982     qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } )
 983   ) {
 984     my $part_svc = $cust_svc->part_svc;
 985     next if ( defined($part_svc) and $part_svc->preserve );
 986     my $error = $cust_svc->cancel( %svc_cancel_opt );
 987
 988     if ( $error ) {
 989       $dbh->rollback if $oldAutoCommit;
 990       return 'Error '. ($svc_cancel_opt{'date'} ? 'expiring' : 'canceling' ).
 991              " cust_svc: $error";
 992     }
 993   }
 994
 995   # if a reasonnum was passed, get the actual reason object so we can check
 996   # unused_credit
 997
 998   my $reason;
 999   if ($options{'reason'} =~ /^\d+$/) {
1000     $reason = FS::reason->by_key($options{'reason'});
1001   }
1002
1003   unless ($date) {
1004     # credit remaining time if any of these are true:
1005     # - unused_credit => 1 was passed (this happens when canceling a package
1006     #   for a package change when unused_credit_change is set)
1007     # - no unused_credit option, and there is a cancel reason, and the cancel
1008     #   reason says to credit the package
1009     # - no unused_credit option, and the package definition says to credit the
1010     #   package on cancellation
1011     my $do_credit;
1012     if ( exists($options{'unused_credit'}) ) {
1013       $do_credit = $options{'unused_credit'};
1014     } elsif ( defined($reason) && $reason->unused_credit ) {
1015       $do_credit = 1;
1016     } else {
1017       $do_credit = $self->part_pkg->option('unused_credit_cancel', 1);
1018     }
1019     if ( $do_credit ) {
1020       my $error = $self->credit_remaining('cancel', $cancel_time);
1021       if ($error) {
1022         $dbh->rollback if $oldAutoCommit;
1023         return $error;
1024       }
1025     }
1026   } #unless $date
1027
1028   my %hash = $self->hash;
1029   if ( $date ) {
1030     $hash{'expire'} = $date;
1031     if ($delay_cancel) {
1032       # just to be sure these are clear
1033       $hash{'adjourn'} = undef;
1034       $hash{'resume'} = undef;
1035     }
1036   } else {
1037     $hash{'cancel'} = $cancel_time;
1038   }
1039   $hash{'change_custnum'} = $options{'change_custnum'};
1040
1041   # if this is a supplemental package that's lost its part_pkg_link, and it's
1042   # being canceled for real, unlink it completely
1043   if ( !$date and ! $self->pkglinknum ) {
1044     $hash{main_pkgnum} = '';
1045   }
1046
1047   # if there is a future package change scheduled, unlink from it (like
1048   # abort_change) first, then delete it.
1049   $hash{'change_to_pkgnum'} = '';
1050
1051   # save the package state
1052   my $new = new FS::cust_pkg ( \%hash );
1053   $error = $new->replace( $self, options => { $self->options } );
1054
1055   if ( $self->change_to_pkgnum ) {
1056     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
1057     $error ||= $change_to->cancel('no_delay_cancel' => 1) || $change_to->delete;
1058   }
1059   if ( $error ) {
1060     $dbh->rollback if $oldAutoCommit;
1061     return $error;
1062   }
1063
1064   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1065     $error = $supp_pkg->cancel(%options,
1066       'from_main' => 1,
1067       'date' => $date, #in case it got changed by delay_cancel
1068       'delay_cancel' => $delay_cancel,
1069     );
1070     if ( $error ) {
1071       $dbh->rollback if $oldAutoCommit;
1072       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
1073     }
1074   }
1075
1076   if ($delay_cancel && !$options{'from_main'}) {
1077     $error = $new->suspend(
1078       'from_cancel' => 1,
1079       'time'        => $cancel_time
1080     );
1081   }
1082
1083   unless ($date) {
1084     foreach my $usage ( $self->cust_pkg_usage ) {
1085       $error = $usage->delete;
1086       if ( $error ) {
1087         $dbh->rollback if $oldAutoCommit;
1088         return "deleting usage pools: $error";
1089       }
1090     }
1091   }
1092
1093   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1094   return '' if $date; #no errors
1095
1096   my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ } $self->cust_main->invoicing_list;
1097   if ( !$options{'quiet'} &&
1098         $conf->exists('emailcancel', $self->cust_main->agentnum) &&
1099         @invoicing_list ) {
1100     my $msgnum = $conf->config('cancel_msgnum', $self->cust_main->agentnum);
1101     my $error = '';
1102     if ( $msgnum ) {
1103       my $msg_template = qsearchs('msg_template', { msgnum => $msgnum });
1104       $error = $msg_template->send( 'cust_main' => $self->cust_main,
1105                                     'object'    => $self );
1106     }
1107     #should this do something on errors?
1108   }
1109
1110   ''; #no errors
1111
1112 }
1113
1114 =item cancel_if_expired [ NOW_TIMESTAMP ]
1115
1116 Cancels this package if its expire date has been reached.
1117
1118 =cut
1119
1120 sub cancel_if_expired {
1121   my $self = shift;
1122   my $time = shift || time;
1123   return '' unless $self->expire && $self->expire <= $time;
1124   my $error = $self->cancel;
1125   if ( $error ) {
1126     return "Error cancelling expired pkg ". $self->pkgnum. " for custnum ".
1127            $self->custnum. ": $error";
1128   }
1129   '';
1130 }
1131
1132 =item uncancel
1133
1134 "Un-cancels" this package: Orders a new package with the same custnum, pkgpart,
1135 locationnum, (other fields?).  Attempts to re-provision cancelled services
1136 using history information (errors at this stage are not fatal).
1137
1138 cust_pkg: pass a scalar reference, will be filled in with the new cust_pkg object
1139
1140 svc_fatal: service provisioning errors are fatal
1141
1142 svc_errors: pass an array reference, will be filled in with any provisioning errors
1143
1144 main_pkgnum: link the package as a supplemental package of this one.  For
1145 internal use only.
1146
1147 =cut
1148
1149 sub uncancel {
1150   my( $self, %options ) = @_;
1151
1152   #in case you try do do $uncancel-date = $cust_pkg->uncacel
1153   return '' unless $self->get('cancel');
1154
1155   if ( $self->main_pkgnum and !$options{'main_pkgnum'} ) {
1156     return $self->main_pkg->uncancel(%options);
1157   }
1158
1159   ##
1160   # Transaction-alize
1161   ##
1162
1163   my $oldAutoCommit = $FS::UID::AutoCommit;
1164   local $FS::UID::AutoCommit = 0;
1165   my $dbh = dbh;
1166
1167   ##
1168   # insert the new package
1169   ##
1170
1171   my $cust_pkg = new FS::cust_pkg {
1172     last_bill       => ( $options{'last_bill'} || $self->get('last_bill') ),
1173     bill            => ( $options{'bill'}      || $self->get('bill')      ),
1174     uncancel        => time,
1175     uncancel_pkgnum => $self->pkgnum,
1176     main_pkgnum     => ($options{'main_pkgnum'} || ''),
1177     map { $_ => $self->get($_) } qw(
1178       custnum pkgpart locationnum
1179       setup
1180       susp adjourn resume expire start_date contract_end dundate
1181       change_date change_pkgpart change_locationnum
1182       no_auto separate_bill quantity agent_pkgid
1183       recur_show_zero setup_show_zero
1184     ),
1185   };
1186
1187   my $error = $cust_pkg->insert(
1188     'change' => 1, #supresses any referral credit to a referring customer
1189     'allow_pkgpart' => 1, # allow this even if the package def is disabled
1190   );
1191   if ($error) {
1192     $dbh->rollback if $oldAutoCommit;
1193     return $error;
1194   }
1195
1196   ##
1197   # insert services
1198   ##
1199
1200   #find historical services within this timeframe before the package cancel
1201   # (incompatible with "time" option to cust_pkg->cancel?)
1202   my $fuzz = 2 * 60; #2 minutes?  too much?   (might catch separate unprovision)
1203                      #            too little? (unprovisioing export delay?)
1204   my($end, $start) = ( $self->get('cancel'), $self->get('cancel') - $fuzz );
1205   my @h_cust_svc = $self->h_cust_svc( $end, $start );
1206
1207   my @svc_errors;
1208   foreach my $h_cust_svc (@h_cust_svc) {
1209     my $h_svc_x = $h_cust_svc->h_svc_x( $end, $start );
1210     #next unless $h_svc_x; #should this happen?
1211     (my $table = $h_svc_x->table) =~ s/^h_//;
1212     require "FS/$table.pm";
1213     my $class = "FS::$table";
1214     my $svc_x = $class->new( {
1215       'pkgnum'  => $cust_pkg->pkgnum,
1216       'svcpart' => $h_cust_svc->svcpart,
1217       map { $_ => $h_svc_x->get($_) } fields($table)
1218     } );
1219
1220     # radius_usergroup
1221     if ( $h_svc_x->isa('FS::h_svc_Radius_Mixin') ) {
1222       $svc_x->usergroup( [ $h_svc_x->h_usergroup($end, $start) ] );
1223     }
1224
1225     my $svc_error = $svc_x->insert;
1226     if ( $svc_error ) {
1227       if ( $options{svc_fatal} ) {
1228         $dbh->rollback if $oldAutoCommit;
1229         return $svc_error;
1230       } else {
1231         # if we've failed to insert the svc_x object, svc_Common->insert
1232         # will have removed the cust_svc already.  if not, then both records
1233         # were inserted but we failed for some other reason (export, most
1234         # likely).  in that case, report the error and delete the records.
1235         push @svc_errors, $svc_error;
1236         my $cust_svc = qsearchs('cust_svc', { 'svcnum' => $svc_x->svcnum });
1237         if ( $cust_svc ) {
1238           # except if export_insert failed, export_delete probably won't be
1239           # much better
1240           local $FS::svc_Common::noexport_hack = 1;
1241           my $cleanup_error = $svc_x->delete; # also deletes cust_svc
1242           if ( $cleanup_error ) { # and if THAT fails, then run away
1243             $dbh->rollback if $oldAutoCommit;
1244             return $cleanup_error;
1245           }
1246         }
1247       } # svc_fatal
1248     } # svc_error
1249   } #foreach $h_cust_svc
1250
1251   #these are pretty rare, but should handle them
1252   # - dsl_device (mac addresses)
1253   # - phone_device (mac addresses)
1254   # - dsl_note (ikano notes)
1255   # - domain_record (i.e. restore DNS information w/domains)
1256   # - inventory_item(?) (inventory w/un-cancelling service?)
1257   # - nas (svc_broaband nas stuff)
1258   #this stuff is unused in the wild afaik
1259   # - mailinglistmember
1260   # - router.svcnum?
1261   # - svc_domain.parent_svcnum?
1262   # - acct_snarf (ancient mail fetching config)
1263   # - cgp_rule (communigate)
1264   # - cust_svc_option (used by our Tron stuff)
1265   # - acct_rt_transaction (used by our time worked stuff)
1266
1267   ##
1268   # also move over any services that didn't unprovision at cancellation
1269   ##
1270
1271   foreach my $cust_svc ( qsearch('cust_svc', { pkgnum => $self->pkgnum } ) ) {
1272     $cust_svc->pkgnum( $cust_pkg->pkgnum );
1273     my $error = $cust_svc->replace;
1274     if ( $error ) {
1275       $dbh->rollback if $oldAutoCommit;
1276       return $error;
1277     }
1278   }
1279
1280   ##
1281   # Uncancel any supplemental packages, and make them supplemental to the
1282   # new one.
1283   ##
1284
1285   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1286     my $new_pkg;
1287     $error = $supp_pkg->uncancel(%options, 'main_pkgnum' => $cust_pkg->pkgnum);
1288     if ( $error ) {
1289       $dbh->rollback if $oldAutoCommit;
1290       return "canceling supplemental pkg#".$supp_pkg->pkgnum.": $error";
1291     }
1292   }
1293
1294   ##
1295   # Finish
1296   ##
1297
1298   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1299
1300   ${ $options{cust_pkg} }   = $cust_pkg   if ref($options{cust_pkg});
1301   @{ $options{svc_errors} } = @svc_errors if ref($options{svc_errors});
1302
1303   '';
1304 }
1305
1306 =item unexpire
1307
1308 Cancels any pending expiration (sets the expire field to null).
1309
1310 If there is an error, returns the error, otherwise returns false.
1311
1312 =cut
1313
1314 sub unexpire {
1315   my( $self, %options ) = @_;
1316   my $error;
1317
1318   my $oldAutoCommit = $FS::UID::AutoCommit;
1319   local $FS::UID::AutoCommit = 0;
1320   my $dbh = dbh;
1321
1322   my $old = $self->select_for_update;
1323
1324   my $pkgnum = $old->pkgnum;
1325   if ( $old->get('cancel') || $self->get('cancel') ) {
1326     dbh->rollback if $oldAutoCommit;
1327     return "Can't unexpire cancelled package $pkgnum";
1328     # or at least it's pointless
1329   }
1330
1331   unless ( $old->get('expire') && $self->get('expire') ) {
1332     dbh->rollback if $oldAutoCommit;
1333     return "";  # no error
1334   }
1335
1336   my %hash = $self->hash;
1337   $hash{'expire'} = '';
1338   my $new = new FS::cust_pkg ( \%hash );
1339   $error = $new->replace( $self, options => { $self->options } );
1340   if ( $error ) {
1341     $dbh->rollback if $oldAutoCommit;
1342     return $error;
1343   }
1344
1345   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1346
1347   ''; #no errors
1348
1349 }
1350
1351 =item suspend [ OPTION => VALUE ... ]
1352
1353 Suspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1354 package, then suspends the package itself (sets the susp field to now).
1355
1356 Available options are:
1357
1358 =over 4
1359
1360 =item reason - can be set to a cancellation reason (see L<FS:reason>),
1361 either a reasonnum of an existing reason, or passing a hashref will create
1362 a new reason.  The hashref should have the following keys:
1363 - typenum - Reason type (see L<FS::reason_type>
1364 - reason - Text of the new reason.
1365
1366 =item date - can be set to a unix style timestamp to specify when to
1367 suspend (adjourn)
1368
1369 =item time - can be set to override the current time, for calculation
1370 of final invoices or unused-time credits
1371
1372 =item resume_date - can be set to a time when the package should be
1373 unsuspended.  This may be more convenient than calling C<unsuspend()>
1374 separately.
1375
1376 =item from_main - allows a supplemental package to be suspended, rather
1377 than redirecting the method call to its main package.  For internal use.
1378
1379 =item from_cancel - used when suspending from the cancel method, forces
1380 this to skip everything besides basic suspension.  For internal use.
1381
1382 =back
1383
1384 If there is an error, returns the error, otherwise returns false.
1385
1386 =cut
1387
1388 sub suspend {
1389   my( $self, %options ) = @_;
1390   my $error;
1391
1392   # supplemental packages still can't be separately suspended, but silently
1393   # exit instead of failing or passing the action to the main package (so
1394   # that the "Suspend customer" action doesn't trip over the supplemental
1395   # packages and die)
1396
1397   if ( $self->main_pkgnum and !$options{'from_main'} ) {
1398     return;
1399   }
1400
1401   my $oldAutoCommit = $FS::UID::AutoCommit;
1402   local $FS::UID::AutoCommit = 0;
1403   my $dbh = dbh;
1404
1405   my $old = $self->select_for_update;
1406
1407   my $pkgnum = $old->pkgnum;
1408   if ( $old->get('cancel') || $self->get('cancel') ) {
1409     dbh->rollback if $oldAutoCommit;
1410     return "Can't suspend cancelled package $pkgnum";
1411   }
1412
1413   if ( $old->get('susp') || $self->get('susp') ) {
1414     dbh->rollback if $oldAutoCommit;
1415     return "";  # no error                     # complain on adjourn?
1416   }
1417
1418   my $suspend_time = $options{'time'} || time;
1419   my $date = $options{date} if $options{date}; # adjourn/suspend later
1420   $date = '' if ($date && $date <= $suspend_time); # complain instead?
1421
1422   if ( $date && $old->get('expire') && $old->get('expire') < $date ) {
1423     dbh->rollback if $oldAutoCommit;
1424     return "Package $pkgnum expires before it would be suspended.";
1425   }
1426
1427   # some false laziness with sub cancel
1428   if ( !$options{nobill} && !$date && !$options{'from_cancel'} &&
1429        $self->part_pkg->option('bill_suspend_as_cancel',1) ) {
1430     # kind of a kludge--'bill_suspend_as_cancel' to avoid having to
1431     # make the entire cust_main->bill path recognize 'suspend' and
1432     # 'cancel' separately.
1433     warn "Billing $pkgnum on suspension (at $suspend_time)\n" if $DEBUG;
1434     my $copy = $self->new({$self->hash});
1435     my $error =
1436       $copy->cust_main->bill( 'pkg_list' => [ $copy ],
1437                               'cancel'   => 1,
1438                               'time'     => $suspend_time );
1439     warn "Error billing during suspend, custnum ".
1440       #$self->cust_main->custnum. ": $error"
1441       ": $error"
1442       if $error;
1443   }
1444
1445   my $cust_pkg_reason;
1446   if ( $options{'reason'} ) {
1447     $error = $self->insert_reason( 'reason' => $options{'reason'},
1448                                    'action' => $date ? 'adjourn' : 'suspend',
1449                                    'date'   => $date ? $date : $suspend_time,
1450                                    'reason_otaker' => $options{'reason_otaker'},
1451                                  );
1452     if ( $error ) {
1453       dbh->rollback if $oldAutoCommit;
1454       return "Error inserting cust_pkg_reason: $error";
1455     }
1456     $cust_pkg_reason = qsearchs('cust_pkg_reason', {
1457         'date'    => $date ? $date : $suspend_time,
1458         'action'  => $date ? 'A' : 'S',
1459         'pkgnum'  => $self->pkgnum,
1460     });
1461   }
1462
1463   # if a reasonnum was passed, get the actual reason object so we can check
1464   # unused_credit
1465   # (passing a reason hashref is still allowed, but it can't be used with
1466   # the fancy behavioral options.)
1467
1468   my $reason;
1469   if ($options{'reason'} =~ /^\d+$/) {
1470     $reason = FS::reason->by_key($options{'reason'});
1471   }
1472
1473   my %hash = $self->hash;
1474   if ( $date ) {
1475     $hash{'adjourn'} = $date;
1476   } else {
1477     $hash{'susp'} = $suspend_time;
1478   }
1479
1480   my $resume_date = $options{'resume_date'} || 0;
1481   if ( $resume_date > ($date || $suspend_time) ) {
1482     $hash{'resume'} = $resume_date;
1483   }
1484
1485   $options{options} ||= {};
1486
1487   my $new = new FS::cust_pkg ( \%hash );
1488   $error = $new->replace( $self, options => { $self->options,
1489                                               %{ $options{options} },
1490                                             }
1491                         );
1492   if ( $error ) {
1493     $dbh->rollback if $oldAutoCommit;
1494     return $error;
1495   }
1496
1497   unless ( $date ) { # then we are suspending now
1498
1499     unless ($options{'from_cancel'}) {
1500       # credit remaining time if appropriate
1501       # (if required by the package def, or the suspend reason)
1502       my $unused_credit = $self->part_pkg->option('unused_credit_suspend',1)
1503                           || ( defined($reason) && $reason->unused_credit );
1504
1505       if ( $unused_credit ) {
1506         warn "crediting unused time on pkg#".$self->pkgnum."\n" if $DEBUG;
1507         my $error = $self->credit_remaining('suspend', $suspend_time);
1508         if ($error) {
1509           $dbh->rollback if $oldAutoCommit;
1510           return $error;
1511         }
1512       }
1513     }
1514
1515     my @cust_svc = qsearch( 'cust_svc', { 'pkgnum' => $self->pkgnum } );
1516
1517     #attempt ordering ala cust_svc_suspend_cascade (without infinite-looping
1518     # on the circular dep case)
1519     #  (this is too simple for multi-level deps, we need to use something
1520     #   to resolve the DAG properly when possible)
1521     my %svcpart = ();
1522     $svcpart{$_->svcpart} = 0 foreach @cust_svc;
1523     foreach my $svcpart ( keys %svcpart ) {
1524       foreach my $part_svc_link (
1525         FS::part_svc_link->by_agentnum($self->cust_main->agentnum,
1526                                          src_svcpart => $svcpart,
1527                                          link_type => 'cust_svc_suspend_cascade'
1528                                       )
1529       ) {
1530         $svcpart{$part_svc_link->dst_svcpart} = max(
1531           $svcpart{$part_svc_link->dst_svcpart},
1532           $svcpart{$part_svc_link->src_svcpart} + 1
1533         );
1534       }
1535     }
1536     @cust_svc = sort { $svcpart{ $a->svcpart } <=> $svcpart{ $b->svcpart } }
1537                   @cust_svc;
1538
1539     my @labels = ();
1540     foreach my $cust_svc ( @cust_svc ) {
1541       $cust_svc->suspend( 'labels_arrayref' => \@labels );
1542     }
1543
1544     # suspension fees: if there is a feepart, and it's not an unsuspend fee,
1545     # and this is not a suspend-before-cancel
1546     if ( $cust_pkg_reason ) {
1547       my $reason_obj = $cust_pkg_reason->reason;
1548       if ( $reason_obj->feepart and
1549            ! $reason_obj->fee_on_unsuspend and
1550            ! $options{'from_cancel'} ) {
1551
1552         # register the need to charge a fee, cust_main->bill will do the rest
1553         warn "registering suspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1554           if $DEBUG;
1555         my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1556             'pkgreasonnum'  => $cust_pkg_reason->num,
1557             'pkgnum'        => $self->pkgnum,
1558             'feepart'       => $reason->feepart,
1559             'nextbill'      => $reason->fee_hold,
1560         });
1561         $error ||= $cust_pkg_reason_fee->insert;
1562       }
1563     }
1564
1565     my $conf = new FS::Conf;
1566     if ( $conf->config('suspend_email_admin') && !$options{'from_cancel'} ) {
1567
1568       my $error = send_email(
1569         'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1570                                    #invoice_from ??? well as good as any
1571         'to'      => $conf->config('suspend_email_admin'),
1572         'subject' => 'FREESIDE NOTIFICATION: Customer package suspended',
1573         'body'    => [
1574           "This is an automatic message from your Freeside installation\n",
1575           "informing you that the following customer package has been suspended:\n",
1576           "\n",
1577           'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1578           'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1579           ( map { "Service : $_\n" } @labels ),
1580         ],
1581         'custnum' => $self->custnum,
1582         'msgtype' => 'admin'
1583       );
1584
1585       if ( $error ) {
1586         warn "WARNING: can't send suspension admin email (suspending anyway): ".
1587              "$error\n";
1588       }
1589
1590     }
1591
1592   }
1593
1594   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1595     $error = $supp_pkg->suspend(%options, 'from_main' => 1);
1596     if ( $error ) {
1597       $dbh->rollback if $oldAutoCommit;
1598       return "suspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1599     }
1600   }
1601
1602   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1603
1604   ''; #no errors
1605 }
1606
1607 =item credit_remaining MODE TIME
1608
1609 Generate a credit for this package for the time remaining in the current
1610 billing period.  MODE is either "suspend" or "cancel" (determines the
1611 credit type).  TIME is the time of suspension/cancellation.  Both arguments
1612 are mandatory.
1613
1614 =cut
1615
1616 # Implementation note:
1617 #
1618 # If you pkgpart-change a package that has been billed, and it's set to give
1619 # credit on package change, then this method gets called and then the new
1620 # package will have no last_bill date. Therefore the customer will be credited
1621 # only once (per billing period) even if there are multiple package changes.
1622 #
1623 # If you location-change a package that has been billed, this method will NOT
1624 # be called and the new package WILL have the last bill date of the old
1625 # package.
1626 #
1627 # If the new package is then canceled within the same billing cycle,
1628 # credit_remaining needs to run calc_remain on the OLD package to determine
1629 # the amount of unused time to credit.
1630
1631 sub credit_remaining {
1632   # Add a credit for remaining service
1633   my ($self, $mode, $time) = @_;
1634   die 'credit_remaining requires suspend or cancel'
1635     unless $mode eq 'suspend' or $mode eq 'cancel';
1636   die 'no suspend/cancel time' unless $time > 0;
1637
1638   my $conf = FS::Conf->new;
1639   my $reason_type = $conf->config($mode.'_credit_type');
1640
1641   my $last_bill = $self->getfield('last_bill') || 0;
1642   my $next_bill = $self->getfield('bill') || 0;
1643   if ( $last_bill > 0         # the package has been billed
1644       and $next_bill > 0      # the package has a next bill date
1645       and $next_bill >= $time # which is in the future
1646   ) {
1647     my @cust_credit_source_bill_pkg = ();
1648     my $remaining_value = 0;
1649
1650     my $remain_pkg = $self;
1651     $remaining_value = $remain_pkg->calc_remain(
1652       'time' => $time,
1653       'cust_credit_source_bill_pkg' => \@cust_credit_source_bill_pkg,
1654     );
1655
1656     # we may have to walk back past some package changes to get to the
1657     # one that actually has unused time
1658     while ( $remaining_value == 0 ) {
1659       if ( $remain_pkg->change_pkgnum ) {
1660         $remain_pkg = FS::cust_pkg->by_key($remain_pkg->change_pkgnum);
1661       } else {
1662         # the package has really never been billed
1663         return;
1664       }
1665       $remaining_value = $remain_pkg->calc_remain(
1666         'time' => $time,
1667         'cust_credit_source_bill_pkg' => \@cust_credit_source_bill_pkg,
1668       );
1669     }
1670
1671     if ( $remaining_value > 0 ) {
1672       warn "Crediting for $remaining_value on package ".$self->pkgnum."\n"
1673         if $DEBUG;
1674       my $error = $self->cust_main->credit(
1675         $remaining_value,
1676         'Credit for unused time on '. $self->part_pkg->pkg,
1677         'reason_type' => $reason_type,
1678         'cust_credit_source_bill_pkg' => \@cust_credit_source_bill_pkg,
1679       );
1680       return "Error crediting customer \$$remaining_value for unused time".
1681         " on ". $self->part_pkg->pkg. ": $error"
1682         if $error;
1683     } #if $remaining_value
1684   } #if $last_bill, etc.
1685   '';
1686 }
1687
1688 =item unsuspend [ OPTION => VALUE ... ]
1689
1690 Unsuspends all services (see L<FS::cust_svc> and L<FS::part_svc>) in this
1691 package, then unsuspends the package itself (clears the susp field and the
1692 adjourn field if it is in the past).  If the suspend reason includes an
1693 unsuspension package, that package will be ordered.
1694
1695 Available options are:
1696
1697 =over 4
1698
1699 =item date
1700
1701 Can be set to a date to unsuspend the package in the future (the 'resume'
1702 field).
1703
1704 =item adjust_next_bill
1705
1706 Can be set true to adjust the next bill date forward by
1707 the amount of time the account was inactive.  This was set true by default
1708 in the past (from 1.4.2 and 1.5.0pre6 through 1.7.0), but now needs to be
1709 explicitly requested with this option or in the price plan.
1710
1711 =back
1712
1713 If there is an error, returns the error, otherwise returns false.
1714
1715 =cut
1716
1717 sub unsuspend {
1718   my( $self, %opt ) = @_;
1719   my $error;
1720
1721   # pass all suspend/cancel actions to the main package
1722   if ( $self->main_pkgnum and !$opt{'from_main'} ) {
1723     return $self->main_pkg->unsuspend(%opt);
1724   }
1725
1726   my $oldAutoCommit = $FS::UID::AutoCommit;
1727   local $FS::UID::AutoCommit = 0;
1728   my $dbh = dbh;
1729
1730   my $old = $self->select_for_update;
1731
1732   my $pkgnum = $old->pkgnum;
1733   if ( $old->get('cancel') || $self->get('cancel') ) {
1734     $dbh->rollback if $oldAutoCommit;
1735     return "Can't unsuspend cancelled package $pkgnum";
1736   }
1737
1738   unless ( $old->get('susp') && $self->get('susp') ) {
1739     $dbh->rollback if $oldAutoCommit;
1740     return "";  # no error                     # complain instead?
1741   }
1742
1743   # handle the case of setting a future unsuspend (resume) date
1744   # and do not continue to actually unsuspend the package
1745   my $date = $opt{'date'};
1746   if ( $date and $date > time ) { # return an error if $date <= time?
1747
1748     if ( $old->get('expire') && $old->get('expire') < $date ) {
1749       $dbh->rollback if $oldAutoCommit;
1750       return "Package $pkgnum expires before it would be unsuspended.";
1751     }
1752
1753     my $new = new FS::cust_pkg { $self->hash };
1754     $new->set('resume', $date);
1755     $error = $new->replace($self, options => $self->options);
1756
1757     if ( $error ) {
1758       $dbh->rollback if $oldAutoCommit;
1759       return $error;
1760     }
1761     else {
1762       $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1763       return '';
1764     }
1765
1766   } #if $date
1767
1768   if (!$self->setup) {
1769     # then this package is being released from on-hold status
1770     $error = $self->set_initial_timers;
1771     if ( $error ) {
1772       $dbh->rollback if $oldAutoCommit;
1773       return $error;
1774     }
1775   }
1776
1777   my @labels = ();
1778
1779   foreach my $cust_svc (
1780     qsearch('cust_svc',{'pkgnum'=> $self->pkgnum } )
1781   ) {
1782     my $part_svc = qsearchs( 'part_svc', { 'svcpart' => $cust_svc->svcpart } );
1783
1784     $part_svc->svcdb =~ /^([\w\-]+)$/ or do {
1785       $dbh->rollback if $oldAutoCommit;
1786       return "Illegal svcdb value in part_svc!";
1787     };
1788     my $svcdb = $1;
1789     require "FS/$svcdb.pm";
1790
1791     my $svc = qsearchs( $svcdb, { 'svcnum' => $cust_svc->svcnum } );
1792     if ($svc) {
1793       $error = $svc->unsuspend;
1794       if ( $error ) {
1795         $dbh->rollback if $oldAutoCommit;
1796         return $error;
1797       }
1798       my( $label, $value ) = $cust_svc->label;
1799       push @labels, "$label: $value";
1800     }
1801
1802   }
1803
1804   my $cust_pkg_reason = $self->last_cust_pkg_reason('susp');
1805   my $reason = $cust_pkg_reason ? $cust_pkg_reason->reason : '';
1806
1807   my %hash = $self->hash;
1808   my $inactive = time - $hash{'susp'};
1809
1810   my $conf = new FS::Conf;
1811
1812   #adjust the next bill date forward
1813   # increment next bill date if certain conditions are met:
1814   # - it was due to be billed at some point
1815   # - either the global or local config says to do this
1816   my $adjust_bill = 0;
1817   if (
1818        $inactive > 0
1819     && ( $hash{'bill'} || $hash{'setup'} )
1820     && (    $opt{'adjust_next_bill'}
1821          || $conf->exists('unsuspend-always_adjust_next_bill_date')
1822          || $self->part_pkg->option('unsuspend_adjust_bill', 1)
1823        )
1824   ) {
1825     $adjust_bill = 1;
1826   }
1827
1828   # but not if:
1829   # - the package billed during suspension
1830   # - or it was ordered on hold
1831   # - or the customer was credited for the unused time
1832
1833   if ( $self->option('suspend_bill',1)
1834       or ( $self->part_pkg->option('suspend_bill',1)
1835            and ! $self->option('no_suspend_bill',1)
1836          )
1837       or $hash{'order_date'} == $hash{'susp'}
1838   ) {
1839     $adjust_bill = 0;
1840   }
1841
1842   if ( $adjust_bill ) {
1843     if (    $self->part_pkg->option('unused_credit_suspend')
1844          or ( ref($reason) and $reason->unused_credit ) ) {
1845       # then the customer was credited for the unused time before suspending,
1846       # so their next bill should be immediate
1847       $hash{'bill'} = time;
1848     } else {
1849       # add the length of time suspended to the bill date
1850       $hash{'bill'} = ( $hash{'bill'} || $hash{'setup'} ) + $inactive;
1851     }
1852   }
1853
1854   $hash{'susp'} = '';
1855   $hash{'adjourn'} = '' if $hash{'adjourn'} and $hash{'adjourn'} < time;
1856   $hash{'resume'} = '' if !$hash{'adjourn'};
1857   my $new = new FS::cust_pkg ( \%hash );
1858   $error = $new->replace( $self, options => { $self->options } );
1859   if ( $error ) {
1860     $dbh->rollback if $oldAutoCommit;
1861     return $error;
1862   }
1863
1864   my $unsusp_pkg;
1865
1866   if ( $reason ) {
1867     if ( $reason->unsuspend_pkgpart ) {
1868       warn "Suspend reason '".$reason->reason."' uses deprecated unsuspend_pkgpart feature.\n";
1869       my $part_pkg = FS::part_pkg->by_key($reason->unsuspend_pkgpart)
1870         or $error = "Unsuspend package definition ".$reason->unsuspend_pkgpart.
1871                     " not found.";
1872       my $start_date = $self->cust_main->next_bill_date
1873         if $reason->unsuspend_hold;
1874
1875       if ( $part_pkg ) {
1876         $unsusp_pkg = FS::cust_pkg->new({
1877             'custnum'     => $self->custnum,
1878             'pkgpart'     => $reason->unsuspend_pkgpart,
1879             'start_date'  => $start_date,
1880             'locationnum' => $self->locationnum,
1881             # discount? probably not...
1882         });
1883
1884         $error ||= $self->cust_main->order_pkg( 'cust_pkg' => $unsusp_pkg );
1885       }
1886     }
1887     # new way, using fees
1888     if ( $reason->feepart and $reason->fee_on_unsuspend ) {
1889       # register the need to charge a fee, cust_main->bill will do the rest
1890       warn "registering unsuspend fee: pkgnum ".$self->pkgnum.", feepart ".$reason->feepart."\n"
1891         if $DEBUG;
1892       my $cust_pkg_reason_fee = FS::cust_pkg_reason_fee->new({
1893           'pkgreasonnum'  => $cust_pkg_reason->num,
1894           'pkgnum'        => $self->pkgnum,
1895           'feepart'       => $reason->feepart,
1896           'nextbill'      => $reason->fee_hold,
1897       });
1898       $error ||= $cust_pkg_reason_fee->insert;
1899     }
1900
1901     if ( $error ) {
1902       $dbh->rollback if $oldAutoCommit;
1903       return $error;
1904     }
1905   }
1906
1907   if ( $conf->config('unsuspend_email_admin') ) {
1908
1909     my $error = send_email(
1910       'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
1911                                  #invoice_from ??? well as good as any
1912       'to'      => $conf->config('unsuspend_email_admin'),
1913       'subject' => 'FREESIDE NOTIFICATION: Customer package unsuspended',       'body'    => [
1914         "This is an automatic message from your Freeside installation\n",
1915         "informing you that the following customer package has been unsuspended:\n",
1916         "\n",
1917         'Customer: #'. $self->custnum. ' '. $self->cust_main->name. "\n",
1918         'Package : #'. $self->pkgnum. " (". $self->part_pkg->pkg_comment. ")\n",
1919         ( map { "Service : $_\n" } @labels ),
1920         ($unsusp_pkg ?
1921           "An unsuspension fee was charged: ".
1922             $unsusp_pkg->part_pkg->pkg_comment."\n"
1923           : ''
1924         ),
1925       ],
1926       'custnum' => $self->custnum,
1927       'msgtype' => 'admin',
1928     );
1929
1930     if ( $error ) {
1931       warn "WARNING: can't send unsuspension admin email (unsuspending anyway): ".
1932            "$error\n";
1933     }
1934
1935   }
1936
1937   foreach my $supp_pkg ( $self->supplemental_pkgs ) {
1938     $error = $supp_pkg->unsuspend(%opt, 'from_main' => 1);
1939     if ( $error ) {
1940       $dbh->rollback if $oldAutoCommit;
1941       return "unsuspending supplemental pkg#".$supp_pkg->pkgnum.": $error";
1942     }
1943   }
1944
1945   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1946
1947   ''; #no errors
1948 }
1949
1950 =item unadjourn
1951
1952 Cancels any pending suspension (sets the adjourn field to null).
1953
1954 If there is an error, returns the error, otherwise returns false.
1955
1956 =cut
1957
1958 sub unadjourn {
1959   my( $self, %options ) = @_;
1960   my $error;
1961
1962   my $oldAutoCommit = $FS::UID::AutoCommit;
1963   local $FS::UID::AutoCommit = 0;
1964   my $dbh = dbh;
1965
1966   my $old = $self->select_for_update;
1967
1968   my $pkgnum = $old->pkgnum;
1969   if ( $old->get('cancel') || $self->get('cancel') ) {
1970     dbh->rollback if $oldAutoCommit;
1971     return "Can't unadjourn cancelled package $pkgnum";
1972     # or at least it's pointless
1973   }
1974
1975   if ( $old->get('susp') || $self->get('susp') ) {
1976     dbh->rollback if $oldAutoCommit;
1977     return "Can't unadjourn suspended package $pkgnum";
1978     # perhaps this is arbitrary
1979   }
1980
1981   unless ( $old->get('adjourn') && $self->get('adjourn') ) {
1982     dbh->rollback if $oldAutoCommit;
1983     return "";  # no error
1984   }
1985
1986   my %hash = $self->hash;
1987   $hash{'adjourn'} = '';
1988   $hash{'resume'}  = '';
1989   my $new = new FS::cust_pkg ( \%hash );
1990   $error = $new->replace( $self, options => { $self->options } );
1991   if ( $error ) {
1992     $dbh->rollback if $oldAutoCommit;
1993     return $error;
1994   }
1995
1996   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1997
1998   ''; #no errors
1999
2000 }
2001
2002
2003 =item change HASHREF | OPTION => VALUE ...
2004
2005 Changes this package: cancels it and creates a new one, with a different
2006 pkgpart or locationnum or both.  All services are transferred to the new
2007 package (no change will be made if this is not possible).
2008
2009 Options may be passed as a list of key/value pairs or as a hash reference.
2010 Options are:
2011
2012 =over 4
2013
2014 =item locationnum
2015
2016 New locationnum, to change the location for this package.
2017
2018 =item cust_location
2019
2020 New FS::cust_location object, to create a new location and assign it
2021 to this package.
2022
2023 =item cust_main
2024
2025 New FS::cust_main object, to create a new customer and assign the new package
2026 to it.
2027
2028 =item pkgpart
2029
2030 New pkgpart (see L<FS::part_pkg>).
2031
2032 =item refnum
2033
2034 New refnum (see L<FS::part_referral>).
2035
2036 =item quantity
2037
2038 New quantity; if unspecified, the new package will have the same quantity
2039 as the old.
2040
2041 =item cust_pkg
2042
2043 "New" (existing) FS::cust_pkg object.  The package's services and other
2044 attributes will be transferred to this package.
2045
2046 =item keep_dates
2047
2048 Set to true to transfer billing dates (start_date, setup, last_bill, bill,
2049 susp, adjourn, cancel, expire, and contract_end) to the new package.
2050
2051 =item unprotect_svcs
2052
2053 Normally, change() will rollback and return an error if some services
2054 can't be transferred (also see the I<cust_pkg-change_svcpart> config option).
2055 If unprotect_svcs is true, this method will transfer as many services as
2056 it can and then unconditionally cancel the old package.
2057
2058 =item contract_end
2059
2060 If specified, sets this value for the contract_end date on the new package
2061 (without regard for keep_dates or the usual date-preservation behavior.)
2062 Will throw an error if defined but false;  the UI doesn't allow editing
2063 this unless it already exists, making removal impossible to undo.
2064
2065 =back
2066
2067 At least one of locationnum, cust_location, pkgpart, refnum, cust_main, or
2068 cust_pkg must be specified (otherwise, what's the point?)
2069
2070 Returns either the new FS::cust_pkg object or a scalar error.
2071
2072 For example:
2073
2074   my $err_or_new_cust_pkg = $old_cust_pkg->change
2075
2076 =cut
2077
2078 #used by change and change_later
2079 #didn't put with documented check methods because it depends on change-specific opts
2080 #and it also possibly edits the value of opts
2081 sub _check_change {
2082   my $self = shift;
2083   my $opt = shift;
2084   if ( defined($opt->{'contract_end'}) ) {
2085     my $current_contract_end = $self->get('contract_end');
2086     unless ($opt->{'contract_end'}) {
2087       if ($current_contract_end) {
2088         return "Cannot remove contract end date when changing packages";
2089       } else {
2090         #shouldn't even pass this option if there's not a current value
2091         #but can be handled gracefully if the option is empty
2092         warn "Contract end date passed unexpectedly";
2093         delete $opt->{'contract_end'};
2094         return '';
2095       }
2096     }
2097     unless ($current_contract_end) {
2098       #option shouldn't be passed, throw error if it's non-empty
2099       return "Cannot add contract end date when changing packages " . $self->pkgnum;
2100     }
2101   }
2102   return '';
2103 }
2104
2105 #some false laziness w/order
2106 sub change {
2107   my $self = shift;
2108   my $opt = ref($_[0]) ? shift : { @_ };
2109
2110   my $conf = new FS::Conf;
2111
2112   # handle contract_end on cust_pkg same as passed option
2113   if ( $opt->{'cust_pkg'} ) {
2114     $opt->{'contract_end'} = $opt->{'cust_pkg'}->contract_end;
2115     delete $opt->{'contract_end'} unless $opt->{'contract_end'};
2116   }
2117
2118   # check contract_end, prevent adding/removing
2119   my $error = $self->_check_change($opt);
2120   return $error if $error;
2121
2122   # Transactionize this whole mess
2123   my $oldAutoCommit = $FS::UID::AutoCommit;
2124   local $FS::UID::AutoCommit = 0;
2125   my $dbh = dbh;
2126
2127   if ( $opt->{'cust_location'} ) {
2128     $error = $opt->{'cust_location'}->find_or_insert;
2129     if ( $error ) {
2130       $dbh->rollback if $oldAutoCommit;
2131       return "creating location record: $error";
2132     }
2133     $opt->{'locationnum'} = $opt->{'cust_location'}->locationnum;
2134   }
2135
2136   # Before going any further here: if the package is still in the pre-setup
2137   # state, it's safe to modify it in place. No need to charge/credit for
2138   # partial period, transfer services, transfer usage pools, copy invoice
2139   # details, or change any dates.
2140   if ( ! $self->setup and ! $opt->{cust_pkg} and ! $opt->{cust_main} ) {
2141     foreach ( qw( locationnum pkgpart quantity refnum salesnum ) ) {
2142       if ( length($opt->{$_}) ) {
2143         $self->set($_, $opt->{$_});
2144       }
2145     }
2146     # almost. if the new pkgpart specifies start/adjourn/expire timers,
2147     # apply those.
2148     if ( $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart ) {
2149       $error ||= $self->set_initial_timers;
2150     }
2151     # but if contract_end was explicitly specified, that overrides all else
2152     $self->set('contract_end', $opt->{'contract_end'})
2153       if $opt->{'contract_end'};
2154     $error ||= $self->replace;
2155     if ( $error ) {
2156       $dbh->rollback if $oldAutoCommit;
2157       return "modifying package: $error";
2158     } else {
2159       $dbh->commit if $oldAutoCommit;
2160       return $self;
2161     }
2162   }
2163
2164   my %hash = ();
2165
2166   my $time = time;
2167
2168   $hash{'setup'} = $time if $self->get('setup');
2169
2170   $hash{'change_date'} = $time;
2171   $hash{"change_$_"}  = $self->$_()
2172     foreach qw( pkgnum pkgpart locationnum );
2173
2174   if ( $opt->{'cust_pkg'} ) {
2175     # treat changing to a package with a different pkgpart as a
2176     # pkgpart change (because it is)
2177     $opt->{'pkgpart'} = $opt->{'cust_pkg'}->pkgpart;
2178   }
2179
2180   # whether to override pkgpart checking on the new package
2181   my $same_pkgpart = 1;
2182   if ( $opt->{'pkgpart'} and ( $opt->{'pkgpart'} != $self->pkgpart ) ) {
2183     $same_pkgpart = 0;
2184   }
2185
2186   my $unused_credit = 0;
2187   my $keep_dates = $opt->{'keep_dates'};
2188
2189   # Special case.  If the pkgpart is changing, and the customer is going to be
2190   # credited for remaining time, don't keep setup, bill, or last_bill dates,
2191   # and DO pass the flag to cancel() to credit the customer.  If the old
2192   # package had a setup date, set the new package's setup to the package
2193   # change date so that it has the same status as before.
2194   if ( $opt->{'pkgpart'}
2195        and $opt->{'pkgpart'} != $self->pkgpart
2196        and $self->part_pkg->option('unused_credit_change', 1) ) {
2197     $unused_credit = 1;
2198     $keep_dates = 0;
2199     $hash{'last_bill'} = '';
2200     $hash{'bill'} = '';
2201   }
2202
2203   if ( $keep_dates ) {
2204     foreach my $date ( qw(setup bill last_bill) ) {
2205       $hash{$date} = $self->getfield($date);
2206     }
2207   }
2208   # always keep the following dates
2209   foreach my $date (qw(order_date susp adjourn cancel expire resume
2210                     start_date contract_end)) {
2211     $hash{$date} = $self->getfield($date);
2212   }
2213   # but if contract_end was explicitly specified, that overrides all else
2214   $hash{'contract_end'} = $opt->{'contract_end'}
2215     if $opt->{'contract_end'};
2216
2217   # allow $opt->{'locationnum'} = '' to specifically set it to null
2218   # (i.e. customer default location)
2219   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2220
2221   # usually this doesn't matter.  the two cases where it does are:
2222   # 1. unused_credit_change + pkgpart change + setup fee on the new package
2223   # and
2224   # 2. (more importantly) changing a package before it's billed
2225   $hash{'waive_setup'} = $self->waive_setup;
2226
2227   # if this package is scheduled for a future package change, preserve that
2228   $hash{'change_to_pkgnum'} = $self->change_to_pkgnum;
2229
2230   my $custnum = $self->custnum;
2231   if ( $opt->{cust_main} ) {
2232     my $cust_main = $opt->{cust_main};
2233     unless ( $cust_main->custnum ) {
2234       my $error = $cust_main->insert( @{ $opt->{cust_main_insert_args}||[] } );
2235       if ( $error ) {
2236         $dbh->rollback if $oldAutoCommit;
2237         return "inserting customer record: $error";
2238       }
2239     }
2240     $custnum = $cust_main->custnum;
2241   }
2242
2243   $hash{'contactnum'} = $opt->{'contactnum'} if $opt->{'contactnum'};
2244
2245   my $cust_pkg;
2246   if ( $opt->{'cust_pkg'} ) {
2247     # The target package already exists; update it to show that it was
2248     # changed from this package.
2249     $cust_pkg = $opt->{'cust_pkg'};
2250
2251     # follow all the above rules for date changes, etc.
2252     foreach (keys %hash) {
2253       $cust_pkg->set($_, $hash{$_});
2254     }
2255     # except those that implement the future package change behavior
2256     foreach (qw(change_to_pkgnum start_date expire)) {
2257       $cust_pkg->set($_, '');
2258     }
2259
2260     $error = $cust_pkg->replace;
2261
2262   } else {
2263     # Create the new package.
2264     $cust_pkg = new FS::cust_pkg {
2265       custnum     => $custnum,
2266       locationnum => $opt->{'locationnum'},
2267       ( map {  $_ => ( $opt->{$_} || $self->$_() )  }
2268           qw( pkgpart quantity refnum salesnum )
2269       ),
2270       %hash,
2271     };
2272     $error = $cust_pkg->insert( 'change' => 1,
2273                                 'allow_pkgpart' => $same_pkgpart );
2274   }
2275   if ($error) {
2276     $dbh->rollback if $oldAutoCommit;
2277     return "inserting new package: $error";
2278   }
2279
2280   # Transfer services and cancel old package.
2281   # Enforce service limits only if this is a pkgpart change.
2282   local $FS::cust_svc::ignore_quantity;
2283   $FS::cust_svc::ignore_quantity = 1 if $same_pkgpart;
2284   $error = $self->transfer($cust_pkg);
2285   if ($error and $error == 0) {
2286     # $old_pkg->transfer failed.
2287     $dbh->rollback if $oldAutoCommit;
2288     return "transferring $error";
2289   }
2290
2291   if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
2292     warn "trying transfer again with change_svcpart option\n" if $DEBUG;
2293     $error = $self->transfer($cust_pkg, 'change_svcpart'=>1 );
2294     if ($error and $error == 0) {
2295       # $old_pkg->transfer failed.
2296       $dbh->rollback if $oldAutoCommit;
2297       return "converting $error";
2298     }
2299   }
2300
2301   # We set unprotect_svcs when executing a "future package change".  It's
2302   # not a user-interactive operation, so returning an error means the
2303   # package change will just fail.  Rather than have that happen, we'll
2304   # let leftover services be deleted.
2305   if ($error > 0 and !$opt->{'unprotect_svcs'}) {
2306     # Transfers were successful, but we still had services left on the old
2307     # package.  We can't change the package under this circumstances, so abort.
2308     $dbh->rollback if $oldAutoCommit;
2309     return "unable to transfer all services";
2310   }
2311
2312   #reset usage if changing pkgpart
2313   # AND usage rollover is off (otherwise adds twice, now and at package bill)
2314   if ($self->pkgpart != $cust_pkg->pkgpart) {
2315     my $part_pkg = $cust_pkg->part_pkg;
2316     $error = $part_pkg->reset_usage($cust_pkg, $part_pkg->is_prepaid
2317                                                  ? ()
2318                                                  : ( 'null' => 1 )
2319                                    )
2320       if $part_pkg->can('reset_usage') && ! $part_pkg->option('usage_rollover',1);
2321
2322     if ($error) {
2323       $dbh->rollback if $oldAutoCommit;
2324       return "setting usage values: $error";
2325     }
2326   } else {
2327     # if NOT changing pkgpart, transfer any usage pools over
2328     foreach my $usage ($self->cust_pkg_usage) {
2329       $usage->set('pkgnum', $cust_pkg->pkgnum);
2330       $error = $usage->replace;
2331       if ( $error ) {
2332         $dbh->rollback if $oldAutoCommit;
2333         return "transferring usage pools: $error";
2334       }
2335     }
2336   }
2337
2338   # transfer usage pricing add-ons, if we're not changing pkgpart or if they were specified
2339   if ( $same_pkgpart || $opt->{'cust_pkg_usageprice'}) {
2340     my @old_cust_pkg_usageprice;
2341     if ($opt->{'cust_pkg_usageprice'}) {
2342       @old_cust_pkg_usageprice = @{ $opt->{'cust_pkg_usageprice'} };
2343     } else {
2344       @old_cust_pkg_usageprice = $self->cust_pkg_usageprice;
2345     }
2346     foreach my $old_cust_pkg_usageprice (@old_cust_pkg_usageprice) {
2347       my $new_cust_pkg_usageprice = new FS::cust_pkg_usageprice {
2348         'pkgnum'         => $cust_pkg->pkgnum,
2349         'usagepricepart' => $old_cust_pkg_usageprice->usagepricepart,
2350         'quantity'       => $old_cust_pkg_usageprice->quantity,
2351       };
2352       $error = $new_cust_pkg_usageprice->insert;
2353       if ( $error ) {
2354         $dbh->rollback if $oldAutoCommit;
2355         return "Error transferring usage pricing add-on: $error";
2356       }
2357     }
2358   }
2359
2360   # transfer discounts, if we're not changing pkgpart
2361   if ( $same_pkgpart ) {
2362     foreach my $old_discount ($self->cust_pkg_discount_active) {
2363       # don't remove the old discount, we may still need to bill that package.
2364       my $new_discount = new FS::cust_pkg_discount {
2365         'pkgnum'      => $cust_pkg->pkgnum,
2366         'discountnum' => $old_discount->discountnum,
2367         'months_used' => $old_discount->months_used,
2368       };
2369       $error = $new_discount->insert;
2370       if ( $error ) {
2371         $dbh->rollback if $oldAutoCommit;
2372         return "transferring discounts: $error";
2373       }
2374     }
2375   }
2376
2377   # transfer (copy) invoice details
2378   foreach my $detail ($self->cust_pkg_detail) {
2379     my $new_detail = FS::cust_pkg_detail->new({ $detail->hash });
2380     $new_detail->set('pkgdetailnum', '');
2381     $new_detail->set('pkgnum', $cust_pkg->pkgnum);
2382     $error = $new_detail->insert;
2383     if ( $error ) {
2384       $dbh->rollback if $oldAutoCommit;
2385       return "transferring package notes: $error";
2386     }
2387   }
2388
2389   my @new_supp_pkgs;
2390
2391   if ( !$opt->{'cust_pkg'} ) {
2392     # Order any supplemental packages.
2393     my $part_pkg = $cust_pkg->part_pkg;
2394     my @old_supp_pkgs = $self->supplemental_pkgs;
2395     foreach my $link ($part_pkg->supp_part_pkg_link) {
2396       my $old;
2397       foreach (@old_supp_pkgs) {
2398         if ($_->pkgpart == $link->dst_pkgpart) {
2399           $old = $_;
2400           $_->pkgpart(0); # so that it can't match more than once
2401         }
2402         last if $old;
2403       }
2404       # false laziness with FS::cust_main::Packages::order_pkg
2405       my $new = FS::cust_pkg->new({
2406           pkgpart       => $link->dst_pkgpart,
2407           pkglinknum    => $link->pkglinknum,
2408           custnum       => $custnum,
2409           main_pkgnum   => $cust_pkg->pkgnum,
2410           locationnum   => $cust_pkg->locationnum,
2411           start_date    => $cust_pkg->start_date,
2412           order_date    => $cust_pkg->order_date,
2413           expire        => $cust_pkg->expire,
2414           adjourn       => $cust_pkg->adjourn,
2415           contract_end  => $cust_pkg->contract_end,
2416           refnum        => $cust_pkg->refnum,
2417           discountnum   => $cust_pkg->discountnum,
2418           waive_setup   => $cust_pkg->waive_setup,
2419       });
2420       if ( $old and $opt->{'keep_dates'} ) {
2421         foreach (qw(setup bill last_bill)) {
2422           $new->set($_, $old->get($_));
2423         }
2424       }
2425       $error = $new->insert( allow_pkgpart => $same_pkgpart );
2426       # transfer services
2427       if ( $old ) {
2428         $error ||= $old->transfer($new);
2429       }
2430       if ( $error and $error > 0 ) {
2431         # no reason why this should ever fail, but still...
2432         $error = "Unable to transfer all services from supplemental package ".
2433           $old->pkgnum;
2434       }
2435       if ( $error ) {
2436         $dbh->rollback if $oldAutoCommit;
2437         return $error;
2438       }
2439       push @new_supp_pkgs, $new;
2440     }
2441   } # if !$opt->{'cust_pkg'}
2442     # because if there is one, then supplemental packages would already
2443     # have been created for it.
2444
2445   #Good to go, cancel old package.  Notify 'cancel' of whether to credit
2446   #remaining time.
2447   #Don't allow billing the package (preceding period packages and/or
2448   #outstanding usage) if we are keeping dates (i.e. location changing),
2449   #because the new package will be billed for the same date range.
2450   #Supplemental packages are also canceled here.
2451
2452   # during scheduled changes, avoid canceling the package we just
2453   # changed to (duh)
2454   $self->set('change_to_pkgnum' => '');
2455
2456   $error = $self->cancel(
2457     quiet          => 1,
2458     unused_credit  => $unused_credit,
2459     nobill         => $keep_dates,
2460     change_custnum => ( $self->custnum != $custnum ? $custnum : '' ),
2461     no_delay_cancel => 1,
2462   );
2463   if ($error) {
2464     $dbh->rollback if $oldAutoCommit;
2465     return "canceling old package: $error";
2466   }
2467
2468   if ( $conf->exists('cust_pkg-change_pkgpart-bill_now') ) {
2469     #$self->cust_main
2470     my $error = $cust_pkg->cust_main->bill(
2471       'pkg_list' => [ $cust_pkg, @new_supp_pkgs ]
2472     );
2473     if ( $error ) {
2474       $dbh->rollback if $oldAutoCommit;
2475       return "billing new package: $error";
2476     }
2477   }
2478
2479   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2480
2481   $cust_pkg;
2482
2483 }
2484
2485 =item change_later OPTION => VALUE...
2486
2487 Schedule a package change for a later date.  This actually orders the new
2488 package immediately, but sets its start date for a future date, and sets
2489 the current package to expire on the same date.
2490
2491 If the package is already scheduled for a change, this can be called with
2492 'start_date' to change the scheduled date, or with pkgpart and/or
2493 locationnum to modify the package change.  To cancel the scheduled change
2494 entirely, see C<abort_change>.
2495
2496 Options include:
2497
2498 =over 4
2499
2500 =item start_date
2501
2502 The date for the package change.  Required, and must be in the future.
2503
2504 =item pkgpart
2505
2506 =item locationnum
2507
2508 =item quantity
2509
2510 =item contract_end
2511
2512 The pkgpart, locationnum, quantity and optional contract_end of the new
2513 package, with the same meaning as in C<change>.
2514
2515 =back
2516
2517 =cut
2518
2519 sub change_later {
2520   my $self = shift;
2521   my $opt = ref($_[0]) ? shift : { @_ };
2522
2523   # check contract_end, prevent adding/removing
2524   my $error = $self->_check_change($opt);
2525   return $error if $error;
2526
2527   my $oldAutoCommit = $FS::UID::AutoCommit;
2528   local $FS::UID::AutoCommit = 0;
2529   my $dbh = dbh;
2530
2531   my $cust_main = $self->cust_main;
2532
2533   my $date = delete $opt->{'start_date'} or return 'start_date required';
2534
2535   if ( $date <= time ) {
2536     $dbh->rollback if $oldAutoCommit;
2537     return "start_date $date is in the past";
2538   }
2539
2540   if ( $self->change_to_pkgnum ) {
2541     my $change_to = FS::cust_pkg->by_key($self->change_to_pkgnum);
2542     my $new_pkgpart = $opt->{'pkgpart'}
2543         if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $change_to->pkgpart;
2544     my $new_locationnum = $opt->{'locationnum'}
2545         if $opt->{'locationnum'} and $opt->{'locationnum'} != $change_to->locationnum;
2546     my $new_quantity = $opt->{'quantity'}
2547         if $opt->{'quantity'} and $opt->{'quantity'} != $change_to->quantity;
2548     my $new_contract_end = $opt->{'contract_end'}
2549         if $opt->{'contract_end'} and $opt->{'contract_end'} != $change_to->contract_end;
2550     if ( $new_pkgpart or $new_locationnum or $new_quantity or $new_contract_end ) {
2551       # it hasn't been billed yet, so in principle we could just edit
2552       # it in place (w/o a package change), but that's bad form.
2553       # So change the package according to the new options...
2554       my $err_or_pkg = $change_to->change(%$opt);
2555       if ( ref $err_or_pkg ) {
2556         # Then set that package up for a future start.
2557         $self->set('change_to_pkgnum', $err_or_pkg->pkgnum);
2558         $self->set('expire', $date); # in case it's different
2559         $err_or_pkg->set('start_date', $date);
2560         $err_or_pkg->set('change_date', '');
2561         $err_or_pkg->set('change_pkgnum', '');
2562
2563         $error = $self->replace       ||
2564                  $err_or_pkg->replace ||
2565                  #because change() might've edited existing scheduled change in place
2566                  (($err_or_pkg->pkgnum == $change_to->pkgnum) ? '' :
2567                   $change_to->cancel('no_delay_cancel' => 1) ||
2568                   $change_to->delete);
2569       } else {
2570         $error = $err_or_pkg;
2571       }
2572     } else { # change the start date only.
2573       $self->set('expire', $date);
2574       $change_to->set('start_date', $date);
2575       $error = $self->replace || $change_to->replace;
2576     }
2577     if ( $error ) {
2578       $dbh->rollback if $oldAutoCommit;
2579       return $error;
2580     } else {
2581       $dbh->commit if $oldAutoCommit;
2582       return '';
2583     }
2584   } # if $self->change_to_pkgnum
2585
2586   my $new_pkgpart = $opt->{'pkgpart'}
2587       if $opt->{'pkgpart'} and $opt->{'pkgpart'} != $self->pkgpart;
2588   my $new_locationnum = $opt->{'locationnum'}
2589       if $opt->{'locationnum'} and $opt->{'locationnum'} != $self->locationnum;
2590   my $new_quantity = $opt->{'quantity'}
2591       if $opt->{'quantity'} and $opt->{'quantity'} != $self->quantity;
2592   my $new_contract_end = $opt->{'contract_end'}
2593       if $opt->{'contract_end'} and $opt->{'contract_end'} != $self->contract_end;
2594
2595   return '' unless $new_pkgpart or $new_locationnum or $new_quantity or $new_contract_end; # wouldn't do anything
2596
2597   # allow $opt->{'locationnum'} = '' to specifically set it to null
2598   # (i.e. customer default location)
2599   $opt->{'locationnum'} = $self->locationnum if !exists($opt->{'locationnum'});
2600
2601   my $new = FS::cust_pkg->new( {
2602     custnum     => $self->custnum,
2603     locationnum => $opt->{'locationnum'},
2604     start_date  => $date,
2605     map   {  $_ => ( $opt->{$_} || $self->$_() )  }
2606       qw( pkgpart quantity refnum salesnum contract_end )
2607   } );
2608   $error = $new->insert('change' => 1,
2609                         'allow_pkgpart' => ($new_pkgpart ? 0 : 1));
2610   if ( !$error ) {
2611     $self->set('change_to_pkgnum', $new->pkgnum);
2612     $self->set('expire', $date);
2613     $error = $self->replace;
2614   }
2615   if ( $error ) {
2616     $dbh->rollback if $oldAutoCommit;
2617   } else {
2618     $dbh->commit if $oldAutoCommit;
2619   }
2620
2621   $error;
2622 }
2623
2624 =item abort_change
2625
2626 Cancels a future package change scheduled by C<change_later>.
2627
2628 =cut
2629
2630 sub abort_change {
2631   my $self = shift;
2632   my $oldAutoCommit = $FS::UID::AutoCommit;
2633   local $FS::UID::AutoCommit = 0;
2634
2635   my $pkgnum = $self->change_to_pkgnum;
2636   my $change_to = FS::cust_pkg->by_key($pkgnum) if $pkgnum;
2637   my $error;
2638   $self->set('change_to_pkgnum', '');
2639   $self->set('expire', '');
2640   $error = $self->replace;
2641   if ( $change_to ) {
2642     $error ||= $change_to->cancel || $change_to->delete;
2643   }
2644
2645   if ( $oldAutoCommit ) {
2646     if ( $error ) {
2647       dbh->rollback;
2648     } else {
2649       dbh->commit;
2650     }
2651   }
2652
2653   return $error;
2654 }
2655
2656 =item set_quantity QUANTITY
2657
2658 Change the package's quantity field.  This is one of the few package properties
2659 that can safely be changed without canceling and reordering the package
2660 (because it doesn't affect tax eligibility).  Returns an error or an
2661 empty string.
2662
2663 =cut
2664
2665 sub set_quantity {
2666   my $self = shift;
2667   $self = $self->replace_old; # just to make sure
2668   $self->quantity(shift);
2669   $self->replace;
2670 }
2671
2672 =item set_salesnum SALESNUM
2673
2674 Change the package's salesnum (sales person) field.  This is one of the few
2675 package properties that can safely be changed without canceling and reordering
2676 the package (because it doesn't affect tax eligibility).  Returns an error or
2677 an empty string.
2678
2679 =cut
2680
2681 sub set_salesnum {
2682   my $self = shift;
2683   $self = $self->replace_old; # just to make sure
2684   $self->salesnum(shift);
2685   $self->replace;
2686   # XXX this should probably reassign any credit that's already been given
2687 }
2688
2689 =item modify_charge OPTIONS
2690
2691 Change the properties of a one-time charge.  The following properties can
2692 be changed this way:
2693 - pkg: the package description
2694 - classnum: the package class
2695 - additional: arrayref of additional invoice details to add to this package
2696
2697 and, I<if the charge has not yet been billed>:
2698 - start_date: the date when it will be billed
2699 - amount: the setup fee to be charged
2700 - quantity: the multiplier for the setup fee
2701 - separate_bill: whether to put the charge on a separate invoice
2702
2703 If you pass 'adjust_commission' => 1, and the classnum changes, and there are
2704 commission credits linked to this charge, they will be recalculated.
2705
2706 =cut
2707
2708 sub modify_charge {
2709   my $self = shift;
2710   my %opt = @_;
2711   my $part_pkg = $self->part_pkg;
2712   my $pkgnum = $self->pkgnum;
2713
2714   my $dbh = dbh;
2715   my $oldAutoCommit = $FS::UID::AutoCommit;
2716   local $FS::UID::AutoCommit = 0;
2717
2718   return "Can't use modify_charge except on one-time charges"
2719     unless $part_pkg->freq eq '0';
2720
2721   if ( length($opt{'pkg'}) and $part_pkg->pkg ne $opt{'pkg'} ) {
2722     $part_pkg->set('pkg', $opt{'pkg'});
2723   }
2724
2725   my %pkg_opt = $part_pkg->options;
2726   my $pkg_opt_modified = 0;
2727
2728   $opt{'additional'} ||= [];
2729   my $i;
2730   my @old_additional;
2731   foreach (grep /^additional/, keys %pkg_opt) {
2732     ($i) = ($_ =~ /^additional_info(\d+)$/);
2733     $old_additional[$i] = $pkg_opt{$_} if $i;
2734     delete $pkg_opt{$_};
2735   }
2736
2737   for ( $i = 0; exists($opt{'additional'}->[$i]); $i++ ) {
2738     $pkg_opt{ "additional_info$i" } = $opt{'additional'}->[$i];
2739     if (!exists($old_additional[$i])
2740         or $old_additional[$i] ne $opt{'additional'}->[$i])
2741     {
2742       $pkg_opt_modified = 1;
2743     }
2744   }
2745   $pkg_opt_modified = 1 if (scalar(@old_additional) - 1) != $i;
2746   $pkg_opt{'additional_count'} = $i if $i > 0;
2747
2748   my $old_classnum;
2749   if ( exists($opt{'classnum'}) and $part_pkg->classnum ne $opt{'classnum'} )
2750   {
2751     # remember it
2752     $old_classnum = $part_pkg->classnum;
2753     $part_pkg->set('classnum', $opt{'classnum'});
2754   }
2755
2756   if ( !$self->get('setup') ) {
2757     # not yet billed, so allow amount, setup_cost, quantity, start_date,
2758     # and separate_bill
2759
2760     if ( exists($opt{'amount'})
2761           and $part_pkg->option('setup_fee') != $opt{'amount'}
2762           and $opt{'amount'} > 0 ) {
2763
2764       $pkg_opt{'setup_fee'} = $opt{'amount'};
2765       $pkg_opt_modified = 1;
2766     }
2767
2768     if ( exists($opt{'setup_cost'})
2769           and $part_pkg->setup_cost != $opt{'setup_cost'}
2770           and $opt{'setup_cost'} > 0 ) {
2771
2772       $part_pkg->set('setup_cost', $opt{'setup_cost'});
2773     }
2774
2775     if ( exists($opt{'quantity'})
2776           and $opt{'quantity'} != $self->quantity
2777           and $opt{'quantity'} > 0 ) {
2778
2779       $self->set('quantity', $opt{'quantity'});
2780     }
2781
2782     if ( exists($opt{'start_date'})
2783           and $opt{'start_date'} != $self->start_date ) {
2784
2785       $self->set('start_date', $opt{'start_date'});
2786     }
2787
2788     if ( exists($opt{'separate_bill'})
2789           and $opt{'separate_bill'} ne $self->separate_bill ) {
2790
2791       $self->set('separate_bill', $opt{'separate_bill'});
2792     }
2793
2794
2795   } # else simply ignore them; the UI shouldn't allow editing the fields
2796
2797
2798   if ( exists($opt{'taxclass'})
2799           and $part_pkg->taxclass ne $opt{'taxclass'}) {
2800
2801       $part_pkg->set('taxclass', $opt{'taxclass'});
2802   }
2803
2804   my $error;
2805   if ( $part_pkg->modified or $pkg_opt_modified ) {
2806     # can we safely modify the package def?
2807     # Yes, if it's not available for purchase, and this is the only instance
2808     # of it.
2809     if ( $part_pkg->disabled
2810          and FS::cust_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 1
2811          and FS::quotation_pkg->count('pkgpart = '.$part_pkg->pkgpart) == 0
2812        ) {
2813       $error = $part_pkg->replace( options => \%pkg_opt );
2814     } else {
2815       # clone it
2816       $part_pkg = $part_pkg->clone;
2817       $part_pkg->set('disabled' => 'Y');
2818       $error = $part_pkg->insert( options => \%pkg_opt );
2819       # and associate this as yet-unbilled package to the new package def
2820       $self->set('pkgpart' => $part_pkg->pkgpart);
2821     }
2822     if ( $error ) {
2823       $dbh->rollback if $oldAutoCommit;
2824       return $error;
2825     }
2826   }
2827
2828   if ($self->modified) { # for quantity or start_date change, or if we had
2829                          # to clone the existing package def
2830     my $error = $self->replace;
2831     return $error if $error;
2832   }
2833   if (defined $old_classnum) {
2834     # fix invoice grouping records
2835     my $old_catname = $old_classnum
2836                       ? FS::pkg_class->by_key($old_classnum)->categoryname
2837                       : '';
2838     my $new_catname = $opt{'classnum'}
2839                       ? $part_pkg->pkg_class->categoryname
2840                       : '';
2841     if ( $old_catname ne $new_catname ) {
2842       foreach my $cust_bill_pkg ($self->cust_bill_pkg) {
2843         # (there should only be one...)
2844         my @display = qsearch( 'cust_bill_pkg_display', {
2845             'billpkgnum'  => $cust_bill_pkg->billpkgnum,
2846             'section'     => $old_catname,
2847         });
2848         foreach (@display) {
2849           $_->set('section', $new_catname);
2850           $error = $_->replace;
2851           if ( $error ) {
2852             $dbh->rollback if $oldAutoCommit;
2853             return $error;
2854           }
2855         }
2856       } # foreach $cust_bill_pkg
2857     }
2858
2859     if ( $opt{'adjust_commission'} ) {
2860       # fix commission credits...tricky.
2861       foreach my $cust_event ($self->cust_event) {
2862         my $part_event = $cust_event->part_event;
2863         foreach my $table (qw(sales agent)) {
2864           my $class =
2865             "FS::part_event::Action::Mixin::credit_${table}_pkg_class";
2866           my $credit = qsearchs('cust_credit', {
2867               'eventnum' => $cust_event->eventnum,
2868           });
2869           if ( $part_event->isa($class) ) {
2870             # Yes, this results in current commission rates being applied
2871             # retroactively to a one-time charge.  For accounting purposes
2872             # there ought to be some kind of time limit on doing this.
2873             my $amount = $part_event->_calc_credit($self);
2874             if ( $credit and $credit->amount ne $amount ) {
2875               # Void the old credit.
2876               $error = $credit->void('Package class changed');
2877               if ( $error ) {
2878                 $dbh->rollback if $oldAutoCommit;
2879                 return "$error (adjusting commission credit)";
2880               }
2881             }
2882             # redo the event action to recreate the credit.
2883             local $@ = '';
2884             eval { $part_event->do_action( $self, $cust_event ) };
2885             if ( $@ ) {
2886               $dbh->rollback if $oldAutoCommit;
2887               return $@;
2888             }
2889           } # if $part_event->isa($class)
2890         } # foreach $table
2891       } # foreach $cust_event
2892     } # if $opt{'adjust_commission'}
2893   } # if defined $old_classnum
2894
2895   $dbh->commit if $oldAutoCommit;
2896   '';
2897 }
2898
2899
2900
2901 use Data::Dumper;
2902 sub process_bulk_cust_pkg {
2903   my $job = shift;
2904   my $param = shift;
2905   warn Dumper($param) if $DEBUG;
2906
2907   my $old_part_pkg = qsearchs('part_pkg',
2908                               { pkgpart => $param->{'old_pkgpart'} });
2909   my $new_part_pkg = qsearchs('part_pkg',
2910                               { pkgpart => $param->{'new_pkgpart'} });
2911   die "Must select a new package type\n" unless $new_part_pkg;
2912   #my $keep_dates = $param->{'keep_dates'} || 0;
2913   my $keep_dates = 1; # there is no good reason to turn this off
2914
2915   my $oldAutoCommit = $FS::UID::AutoCommit;
2916   local $FS::UID::AutoCommit = 0;
2917   my $dbh = dbh;
2918
2919   my @cust_pkgs = qsearch('cust_pkg', { 'pkgpart' => $param->{'old_pkgpart'} } );
2920
2921   my $i = 0;
2922   foreach my $old_cust_pkg ( @cust_pkgs ) {
2923     $i++;
2924     $job->update_statustext(int(100*$i/(scalar @cust_pkgs)));
2925     if ( $old_cust_pkg->getfield('cancel') ) {
2926       warn '[process_bulk_cust_pkg ] skipping canceled pkgnum '.
2927         $old_cust_pkg->pkgnum."\n"
2928         if $DEBUG;
2929       next;
2930     }
2931     warn '[process_bulk_cust_pkg] changing pkgnum '.$old_cust_pkg->pkgnum."\n"
2932       if $DEBUG;
2933     my $error = $old_cust_pkg->change(
2934       'pkgpart'     => $param->{'new_pkgpart'},
2935       'keep_dates'  => $keep_dates
2936     );
2937     if ( !ref($error) ) { # change returns the cust_pkg on success
2938       $dbh->rollback;
2939       die "Error changing pkgnum ".$old_cust_pkg->pkgnum.": '$error'\n";
2940     }
2941   }
2942   $dbh->commit if $oldAutoCommit;
2943   return;
2944 }
2945
2946 =item last_bill
2947
2948 Returns the last bill date, or if there is no last bill date, the setup date.
2949 Useful for billing metered services.
2950
2951 =cut
2952
2953 sub last_bill {
2954   my $self = shift;
2955   return $self->setfield('last_bill', $_[0]) if @_;
2956   return $self->getfield('last_bill') if $self->getfield('last_bill');
2957   my $cust_bill_pkg = qsearchs('cust_bill_pkg', { 'pkgnum' => $self->pkgnum,
2958                                                   'edate'  => $self->bill,  } );
2959   $cust_bill_pkg ? $cust_bill_pkg->sdate : $self->setup || 0;
2960 }
2961
2962 =item last_cust_pkg_reason ACTION
2963
2964 Returns the most recent ACTION FS::cust_pkg_reason associated with the package.
2965 Returns false if there is no reason or the package is not currenly ACTION'd
2966 ACTION is one of adjourn, susp, cancel, or expire.
2967
2968 =cut
2969
2970 sub last_cust_pkg_reason {
2971   my ( $self, $action ) = ( shift, shift );
2972   my $date = $self->get($action);
2973   qsearchs( {
2974               'table' => 'cust_pkg_reason',
2975               'hashref' => { 'pkgnum' => $self->pkgnum,
2976                              'action' => substr(uc($action), 0, 1),
2977                              'date'   => $date,
2978                            },
2979               'order_by' => 'ORDER BY num DESC LIMIT 1',
2980            } );
2981 }
2982
2983 =item last_reason ACTION
2984
2985 Returns the most recent ACTION FS::reason associated with the package.
2986 Returns false if there is no reason or the package is not currenly ACTION'd
2987 ACTION is one of adjourn, susp, cancel, or expire.
2988
2989 =cut
2990
2991 sub last_reason {
2992   my $cust_pkg_reason = shift->last_cust_pkg_reason(@_);
2993   $cust_pkg_reason->reason
2994     if $cust_pkg_reason;
2995 }
2996
2997 =item part_pkg
2998
2999 Returns the definition for this billing item, as an FS::part_pkg object (see
3000 L<FS::part_pkg>).
3001
3002 =cut
3003
3004 sub part_pkg {
3005   my $self = shift;
3006   return $self->{'_pkgpart'} if $self->{'_pkgpart'};
3007   cluck "cust_pkg->part_pkg called" if $DEBUG > 1;
3008   qsearchs( 'part_pkg', { 'pkgpart' => $self->pkgpart } );
3009 }
3010
3011 =item old_cust_pkg
3012
3013 Returns the cancelled package this package was changed from, if any.
3014
3015 =cut
3016
3017 sub old_cust_pkg {
3018   my $self = shift;
3019   return '' unless $self->change_pkgnum;
3020   qsearchs('cust_pkg', { 'pkgnum' => $self->change_pkgnum } );
3021 }
3022
3023 =item change_cust_main
3024
3025 Returns the customter this package was detached to, if any.
3026
3027 =cut
3028
3029 sub change_cust_main {
3030   my $self = shift;
3031   return '' unless $self->change_custnum;
3032   qsearchs('cust_main', { 'custnum' => $self->change_custnum } );
3033 }
3034
3035 =item calc_setup
3036
3037 Calls the I<calc_setup> of the FS::part_pkg object associated with this billing
3038 item.
3039
3040 =cut
3041
3042 sub calc_setup {
3043   my $self = shift;
3044   $self->part_pkg->calc_setup($self, @_);
3045 }
3046
3047 =item calc_recur
3048
3049 Calls the I<calc_recur> of the FS::part_pkg object associated with this billing
3050 item.
3051
3052 =cut
3053
3054 sub calc_recur {
3055   my $self = shift;
3056   $self->part_pkg->calc_recur($self, @_);
3057 }
3058
3059 =item base_setup
3060
3061 Calls the I<base_setup> of the FS::part_pkg object associated with this billing
3062 item.
3063
3064 =cut
3065
3066 sub base_setup {
3067   my $self = shift;
3068   $self->part_pkg->base_setup($self, @_);
3069 }
3070
3071 =item base_recur
3072
3073 Calls the I<base_recur> of the FS::part_pkg object associated with this billing
3074 item.
3075
3076 =cut
3077
3078 sub base_recur {
3079   my $self = shift;
3080   $self->part_pkg->base_recur($self, @_);
3081 }
3082
3083 =item calc_remain
3084
3085 Calls the I<calc_remain> of the FS::part_pkg object associated with this
3086 billing item.
3087
3088 =cut
3089
3090 sub calc_remain {
3091   my $self = shift;
3092   $self->part_pkg->calc_remain($self, @_);
3093 }
3094
3095 =item calc_cancel
3096
3097 Calls the I<calc_cancel> of the FS::part_pkg object associated with this
3098 billing item.
3099
3100 =cut
3101
3102 sub calc_cancel {
3103   my $self = shift;
3104   $self->part_pkg->calc_cancel($self, @_);
3105 }
3106
3107 =item cust_bill_pkg
3108
3109 Returns any invoice line items for this package (see L<FS::cust_bill_pkg>).
3110
3111 =cut
3112
3113 sub cust_bill_pkg {
3114   my $self = shift;
3115   qsearch( 'cust_bill_pkg', { 'pkgnum' => $self->pkgnum } );
3116 }
3117
3118 =item cust_pkg_detail [ DETAILTYPE ]
3119
3120 Returns any customer package details for this package (see
3121 L<FS::cust_pkg_detail>).
3122
3123 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
3124
3125 =cut
3126
3127 sub cust_pkg_detail {
3128   my $self = shift;
3129   my %hash = ( 'pkgnum' => $self->pkgnum );
3130   $hash{detailtype} = shift if @_;
3131   qsearch({
3132     'table'    => 'cust_pkg_detail',
3133     'hashref'  => \%hash,
3134     'order_by' => 'ORDER BY weight, pkgdetailnum',
3135   });
3136 }
3137
3138 =item set_cust_pkg_detail DETAILTYPE [ DETAIL, DETAIL, ... ]
3139
3140 Sets customer package details for this package (see L<FS::cust_pkg_detail>).
3141
3142 DETAILTYPE can be set to "I" for invoice details or "C" for comments.
3143
3144 If there is an error, returns the error, otherwise returns false.
3145
3146 =cut
3147
3148 sub set_cust_pkg_detail {
3149   my( $self, $detailtype, @details ) = @_;
3150
3151   my $oldAutoCommit = $FS::UID::AutoCommit;
3152   local $FS::UID::AutoCommit = 0;
3153   my $dbh = dbh;
3154
3155   foreach my $current ( $self->cust_pkg_detail($detailtype) ) {
3156     my $error = $current->delete;
3157     if ( $error ) {
3158       $dbh->rollback if $oldAutoCommit;
3159       return "error removing old detail: $error";
3160     }
3161   }
3162
3163   foreach my $detail ( @details ) {
3164     my $cust_pkg_detail = new FS::cust_pkg_detail {
3165       'pkgnum'     => $self->pkgnum,
3166       'detailtype' => $detailtype,
3167       'detail'     => $detail,
3168     };
3169     my $error = $cust_pkg_detail->insert;
3170     if ( $error ) {
3171       $dbh->rollback if $oldAutoCommit;
3172       return "error adding new detail: $error";
3173     }
3174
3175   }
3176
3177   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3178   '';
3179
3180 }
3181
3182 =item cust_event
3183
3184 Returns the customer billing events (see L<FS::cust_event>) for this invoice.
3185
3186 =cut
3187
3188 #false laziness w/cust_bill.pm
3189 sub cust_event {
3190   my $self = shift;
3191   qsearch({
3192     'table'     => 'cust_event',
3193     'addl_from' => 'JOIN part_event USING ( eventpart )',
3194     'hashref'   => { 'tablenum' => $self->pkgnum },
3195     'extra_sql' => " AND eventtable = 'cust_pkg' ",
3196   });
3197 }
3198
3199 =item num_cust_event
3200
3201 Returns the number of customer billing events (see L<FS::cust_event>) for this package.
3202
3203 =cut
3204
3205 #false laziness w/cust_bill.pm
3206 sub num_cust_event {
3207   my $self = shift;
3208   my $sql = "SELECT COUNT(*) ". $self->_from_cust_event_where;
3209   $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref->[0];
3210 }
3211
3212 =item exists_cust_event
3213
3214 Returns true if there are customer billing events (see L<FS::cust_event>) for this package.  More efficient than using num_cust_event.
3215
3216 =cut
3217
3218 sub exists_cust_event {
3219   my $self = shift;
3220   my $sql = "SELECT 1 ". $self->_from_cust_event_where. " LIMIT 1";
3221   my $row = $self->_prep_ex($sql, $self->pkgnum)->fetchrow_arrayref;
3222   $row ? $row->[0] : '';
3223 }
3224
3225 sub _from_cust_event_where {
3226   #my $self = shift;
3227   " FROM cust_event JOIN part_event USING ( eventpart ) ".
3228   "  WHERE tablenum = ? AND eventtable = 'cust_pkg' ";
3229 }
3230
3231 sub _prep_ex {
3232   my( $self, $sql, @args ) = @_;
3233   my $sth = dbh->prepare($sql) or die  dbh->errstr. " preparing $sql";
3234   $sth->execute(@args)         or die $sth->errstr. " executing $sql";
3235   $sth;
3236 }
3237
3238 =item part_pkg_currency_option OPTIONNAME
3239
3240 Returns a two item list consisting of the currency of this customer, if any,
3241 and a value for the provided option.  If the customer has a currency, the value
3242 is the option value the given name and the currency (see
3243 L<FS::part_pkg_currency>).  Otherwise, if the customer has no currency, is the
3244 regular option value for the given name (see L<FS::part_pkg_option>).
3245
3246 =cut
3247
3248 sub part_pkg_currency_option {
3249   my( $self, $optionname ) = @_;
3250   my $part_pkg = $self->part_pkg;
3251   if ( my $currency = $self->cust_main->currency ) {
3252     ($currency, $part_pkg->part_pkg_currency_option($currency, $optionname) );
3253   } else {
3254     ('', $part_pkg->option($optionname) );
3255   }
3256 }
3257
3258 =item cust_svc [ SVCPART ] (old, deprecated usage)
3259
3260 =item cust_svc [ OPTION => VALUE ... ] (current usage)
3261
3262 =item cust_svc_unsorted [ OPTION => VALUE ... ]
3263
3264 Returns the services for this package, as FS::cust_svc objects (see
3265 L<FS::cust_svc>).  Available options are svcpart and svcdb.  If either is
3266 spcififed, returns only the matching services.
3267
3268 As an optimization, use the cust_svc_unsorted version if you are not displaying
3269 the results.
3270
3271 =cut
3272
3273 sub cust_svc {
3274   my $self = shift;
3275   cluck "cust_pkg->cust_svc called" if $DEBUG > 2;
3276   $self->_sort_cust_svc( $self->cust_svc_unsorted_arrayref(@_) );
3277 }
3278
3279 sub cust_svc_unsorted {
3280   my $self = shift;
3281   @{ $self->cust_svc_unsorted_arrayref(@_) };
3282 }
3283
3284 sub cust_svc_unsorted_arrayref {
3285   my $self = shift;
3286
3287   return [] unless $self->num_cust_svc(@_);
3288
3289   my %opt = ();
3290   if ( @_ && $_[0] =~ /^\d+/ ) {
3291     $opt{svcpart} = shift;
3292   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3293     %opt = %{ $_[0] };
3294   } elsif ( @_ ) {
3295     %opt = @_;
3296   }
3297
3298   my %search = (
3299     'select'    => 'cust_svc.*, part_svc.*',
3300     'table'     => 'cust_svc',
3301     'hashref'   => { 'pkgnum' => $self->pkgnum },
3302     'addl_from' => 'LEFT JOIN part_svc USING ( svcpart )',
3303   );
3304   $search{hashref}->{svcpart} = $opt{svcpart}
3305     if $opt{svcpart};
3306   $search{extra_sql} = ' AND svcdb = '. dbh->quote( $opt{svcdb} )
3307     if $opt{svcdb};
3308
3309   [ qsearch(\%search) ];
3310
3311 }
3312
3313 =item overlimit [ SVCPART ]
3314
3315 Returns the services for this package which have exceeded their
3316 usage limit as FS::cust_svc objects (see L<FS::cust_svc>).  If a svcpart
3317 is specified, return only the matching services.
3318
3319 =cut
3320
3321 sub overlimit {
3322   my $self = shift;
3323   return () unless $self->num_cust_svc(@_);
3324   grep { $_->overlimit } $self->cust_svc(@_);
3325 }
3326
3327 =item h_cust_svc END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3328
3329 Returns historical services for this package created before END TIMESTAMP and
3330 (optionally) not cancelled before START_TIMESTAMP, as FS::h_cust_svc objects
3331 (see L<FS::h_cust_svc>).  If MODE is 'I' (for 'invoice'), services with the
3332 I<pkg_svc.hidden> flag will be omitted.
3333
3334 =cut
3335
3336 sub h_cust_svc {
3337   my $self = shift;
3338   warn "$me _h_cust_svc called on $self\n"
3339     if $DEBUG;
3340
3341   my ($end, $start, $mode) = @_;
3342
3343   local($FS::Record::qsearch_qualify_columns) = 0;
3344
3345   my @cust_svc = $self->_sort_cust_svc(
3346     [ qsearch( 'h_cust_svc',
3347       { 'pkgnum' => $self->pkgnum, },
3348       FS::h_cust_svc->sql_h_search(@_),
3349     ) ]
3350   );
3351
3352   if ( defined($mode) && $mode eq 'I' ) {
3353     my %hidden_svcpart = map { $_->svcpart => $_->hidden } $self->part_svc;
3354     return grep { !$hidden_svcpart{$_->svcpart} } @cust_svc;
3355   } else {
3356     return @cust_svc;
3357   }
3358 }
3359
3360 sub _sort_cust_svc {
3361   my( $self, $arrayref ) = @_;
3362
3363   my $sort =
3364     sub ($$) { my ($a, $b) = @_; $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] };
3365
3366   my %pkg_svc = map { $_->svcpart => $_ }
3367                 qsearch( 'pkg_svc', { 'pkgpart' => $self->pkgpart } );
3368
3369   map  { $_->[0] }
3370   sort $sort
3371   map {
3372         my $pkg_svc = $pkg_svc{ $_->svcpart } || '';
3373         [ $_,
3374           $pkg_svc ? $pkg_svc->primary_svc : '',
3375           $pkg_svc ? $pkg_svc->quantity : 0,
3376         ];
3377       }
3378   @$arrayref;
3379
3380 }
3381
3382 =item num_cust_svc [ SVCPART ] (old, deprecated usage)
3383
3384 =item num_cust_svc [ OPTION => VALUE ... ] (current usage)
3385
3386 Returns the number of services for this package.  Available options are svcpart
3387 and svcdb.  If either is spcififed, returns only the matching services.
3388
3389 =cut
3390
3391 sub num_cust_svc {
3392   my $self = shift;
3393
3394   return $self->{'_num_cust_svc'}
3395     if !scalar(@_)
3396        && exists($self->{'_num_cust_svc'})
3397        && $self->{'_num_cust_svc'} =~ /\d/;
3398
3399   cluck "cust_pkg->num_cust_svc called, _num_cust_svc:".$self->{'_num_cust_svc'}
3400     if $DEBUG > 2;
3401
3402   my %opt = ();
3403   if ( @_ && $_[0] =~ /^\d+/ ) {
3404     $opt{svcpart} = shift;
3405   } elsif ( @_ && ref($_[0]) eq 'HASH' ) {
3406     %opt = %{ $_[0] };
3407   } elsif ( @_ ) {
3408     %opt = @_;
3409   }
3410
3411   my $select = 'SELECT COUNT(*) FROM cust_svc ';
3412   my $where = ' WHERE pkgnum = ? ';
3413   my @param = ($self->pkgnum);
3414
3415   if ( $opt{'svcpart'} ) {
3416     $where .= ' AND svcpart = ? ';
3417     push @param, $opt{'svcpart'};
3418   }
3419   if ( $opt{'svcdb'} ) {
3420     $select .= ' LEFT JOIN part_svc USING ( svcpart ) ';
3421     $where .= ' AND svcdb = ? ';
3422     push @param, $opt{'svcdb'};
3423   }
3424
3425   my $sth = dbh->prepare("$select $where") or die  dbh->errstr;
3426   $sth->execute(@param) or die $sth->errstr;
3427   $sth->fetchrow_arrayref->[0];
3428 }
3429
3430 =item available_part_svc
3431
3432 Returns a list of FS::part_svc objects representing services included in this
3433 package but not yet provisioned.  Each FS::part_svc object also has an extra
3434 field, I<num_avail>, which specifies the number of available services.
3435
3436 Accepts option I<provision_hold>;  if true, only returns part_svc for which the
3437 associated pkg_svc has the provision_hold flag set.
3438
3439 =cut
3440
3441 sub available_part_svc {
3442   my $self = shift;
3443   my %opt  = @_;
3444
3445   my $pkg_quantity = $self->quantity || 1;
3446
3447   grep { $_->num_avail > 0 }
3448   map {
3449     my $part_svc = $_->part_svc;
3450     $part_svc->{'Hash'}{'num_avail'} = #evil encapsulation-breaking
3451     $pkg_quantity * $_->quantity - $self->num_cust_svc($_->svcpart);
3452
3453     # more evil encapsulation breakage
3454     if ($part_svc->{'Hash'}{'num_avail'} > 0) {
3455       my @exports = $part_svc->part_export_did;
3456       $part_svc->{'Hash'}{'can_get_dids'} = scalar(@exports);
3457         }
3458
3459     $part_svc;
3460   }
3461   grep { $opt{'provision_hold'} ? $_->provision_hold : 1 }
3462   $self->part_pkg->pkg_svc;
3463 }
3464
3465 =item part_svc [ OPTION => VALUE ... ]
3466
3467 Returns a list of FS::part_svc objects representing provisioned and available
3468 services included in this package.  Each FS::part_svc object also has the
3469 following extra fields:
3470
3471 =over 4
3472
3473 =item num_cust_svc
3474
3475 (count)
3476
3477 =item num_avail
3478
3479 (quantity - count)
3480
3481 =item cust_pkg_svc
3482
3483 (services) - array reference containing the provisioned services, as cust_svc objects
3484
3485 =back
3486
3487 Accepts two options:
3488
3489 =over 4
3490
3491 =item summarize_size
3492
3493 If true, will omit the extra cust_pkg_svc option for objects where num_cust_svc
3494 is this size or greater.
3495
3496 =item hide_discontinued
3497
3498 If true, will omit looking for services that are no longer avaialble in the
3499 package definition.
3500
3501 =back
3502
3503 =cut
3504
3505 #svcnum
3506 #label -> ($cust_svc->label)[1]
3507
3508 sub part_svc {
3509   my $self = shift;
3510   my %opt = @_;
3511
3512   my $pkg_quantity = $self->quantity || 1;
3513
3514   #XXX some sort of sort order besides numeric by svcpart...
3515   my @part_svc = sort { $a->svcpart <=> $b->svcpart } map {
3516     my $pkg_svc = $_;
3517     my $part_svc = $pkg_svc->part_svc;
3518     my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3519     $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #more evil
3520     $part_svc->{'Hash'}{'num_avail'}    =
3521       max( 0, $pkg_quantity * $pkg_svc->quantity - $num_cust_svc );
3522     $part_svc->{'Hash'}{'cust_pkg_svc'} =
3523         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : []
3524       unless exists($opt{summarize_size}) && $opt{summarize_size} > 0
3525           && $num_cust_svc >= $opt{summarize_size};
3526     $part_svc->{'Hash'}{'hidden'} = $pkg_svc->hidden;
3527     $part_svc;
3528   } $self->part_pkg->pkg_svc;
3529
3530   unless ( $opt{hide_discontinued} ) {
3531     #extras
3532     push @part_svc, map {
3533       my $part_svc = $_;
3534       my $num_cust_svc = $self->num_cust_svc($part_svc->svcpart);
3535       $part_svc->{'Hash'}{'num_cust_svc'} = $num_cust_svc; #speak no evail
3536       $part_svc->{'Hash'}{'num_avail'}    = 0; #0-$num_cust_svc ?
3537       $part_svc->{'Hash'}{'cust_pkg_svc'} =
3538         $num_cust_svc ? [ $self->cust_svc($part_svc->svcpart) ] : [];
3539       $part_svc;
3540     } $self->extra_part_svc;
3541   }
3542
3543   @part_svc;
3544
3545 }
3546
3547 =item extra_part_svc
3548
3549 Returns a list of FS::part_svc objects corresponding to services in this
3550 package which are still provisioned but not (any longer) available in the
3551 package definition.
3552
3553 =cut
3554
3555 sub extra_part_svc {
3556   my $self = shift;
3557
3558   my $pkgnum  = $self->pkgnum;
3559   #my $pkgpart = $self->pkgpart;
3560
3561 #  qsearch( {
3562 #    'table'     => 'part_svc',
3563 #    'hashref'   => {},
3564 #    'extra_sql' =>
3565 #      "WHERE 0 = ( SELECT COUNT(*) FROM pkg_svc
3566 #                     WHERE pkg_svc.svcpart = part_svc.svcpart
3567 #                       AND pkg_svc.pkgpart = ?
3568 #                       AND quantity > 0
3569 #                 )
3570 #        AND 0 < ( SELECT COUNT(*) FROM cust_svc
3571 #                       LEFT JOIN cust_pkg USING ( pkgnum )
3572 #                     WHERE cust_svc.svcpart = part_svc.svcpart
3573 #                       AND pkgnum = ?
3574 #                 )",
3575 #    'extra_param' => [ [$self->pkgpart=>'int'], [$self->pkgnum=>'int'] ],
3576 #  } );
3577
3578 #seems to benchmark slightly faster... (or did?)
3579
3580   my @pkgparts = map $_->pkgpart, $self->part_pkg->self_and_svc_linked;
3581   my $pkgparts = join(',', @pkgparts);
3582
3583   qsearch( {
3584     #'select'      => 'DISTINCT ON (svcpart) part_svc.*',
3585     #MySQL doesn't grok DISINCT ON
3586     'select'      => 'DISTINCT part_svc.*',
3587     'table'       => 'part_svc',
3588     'addl_from'   =>
3589       "LEFT JOIN pkg_svc  ON (     pkg_svc.svcpart   = part_svc.svcpart
3590                                AND pkg_svc.pkgpart IN ($pkgparts)
3591                                AND quantity > 0
3592                              )
3593        LEFT JOIN cust_svc ON (     cust_svc.svcpart = part_svc.svcpart )
3594        LEFT JOIN cust_pkg USING ( pkgnum )
3595       ",
3596     'hashref'     => {},
3597     'extra_sql'   => "WHERE pkgsvcnum IS NULL AND cust_pkg.pkgnum = ? ",
3598     'extra_param' => [ [$self->pkgnum=>'int'] ],
3599   } );
3600 }
3601
3602 =item status
3603
3604 Returns a short status string for this package, currently:
3605
3606 =over 4
3607
3608 =item on hold
3609
3610 =item not yet billed
3611
3612 =item one-time charge
3613
3614 =item active
3615
3616 =item suspended
3617
3618 =item cancelled
3619
3620 =back
3621
3622 =cut
3623
3624 sub status {
3625   my $self = shift;
3626
3627   my $freq = length($self->freq) ? $self->freq : $self->part_pkg->freq;
3628
3629   return 'cancelled' if $self->get('cancel');
3630   return 'on hold' if $self->susp && ! $self->setup;
3631   return 'suspended' if $self->susp;
3632   return 'not yet billed' unless $self->setup;
3633   return 'one-time charge' if $freq =~ /^(0|$)/;
3634   return 'active';
3635 }
3636
3637 =item ucfirst_status
3638
3639 Returns the status with the first character capitalized.
3640
3641 =cut
3642
3643 sub ucfirst_status {
3644   ucfirst(shift->status);
3645 }
3646
3647 =item statuses
3648
3649 Class method that returns the list of possible status strings for packages
3650 (see L<the status method|/status>).  For example:
3651
3652   @statuses = FS::cust_pkg->statuses();
3653
3654 =cut
3655
3656 tie my %statuscolor, 'Tie::IxHash',
3657   'on hold'         => 'FF00F5', #brighter purple!
3658   'not yet billed'  => '009999', #teal? cyan?
3659   'one-time charge' => '0000CC', #blue  #'000000',
3660   'active'          => '00CC00',
3661   'suspended'       => 'FF9900',
3662   'cancelled'       => 'FF0000',
3663 ;
3664
3665 sub statuses {
3666   my $self = shift; #could be class...
3667   #grep { $_ !~ /^(not yet billed)$/ } #this is a dumb status anyway
3668   #                                    # mayble split btw one-time vs. recur
3669     keys %statuscolor;
3670 }
3671
3672 sub statuscolors {
3673   #my $self = shift;
3674   \%statuscolor;
3675 }
3676
3677 =item statuscolor
3678
3679 Returns a hex triplet color string for this package's status.
3680
3681 =cut
3682
3683 sub statuscolor {
3684   my $self = shift;
3685   $statuscolor{$self->status};
3686 }
3687
3688 =item is_status_delay_cancel
3689
3690 Returns true if part_pkg has option delay_cancel,
3691 cust_pkg status is 'suspended' and expire is set
3692 to cancel package within the next day (or however
3693 many days are set in global config part_pkg-delay_cancel-days.
3694
3695 Accepts option I<part_pkg-delay_cancel-days> which should be
3696 the value of the config setting, to avoid looking it up again.
3697
3698 This is not a real status, this only meant for hacking display
3699 values, because otherwise treating the package as suspended is
3700 really the whole point of the delay_cancel option.
3701
3702 =cut
3703
3704 sub is_status_delay_cancel {
3705   my ($self,%opt) = @_;
3706   if ( $self->main_pkgnum and $self->pkglinknum ) {
3707     return $self->main_pkg->is_status_delay_cancel;
3708   }
3709   return 0 unless $self->part_pkg->option('delay_cancel',1);
3710   return 0 unless $self->status eq 'suspended';
3711   return 0 unless $self->expire;
3712   my $expdays = $opt{'part_pkg-delay_cancel-days'};
3713   unless ($expdays) {
3714     my $conf = new FS::Conf;
3715     $expdays = $conf->config('part_pkg-delay_cancel-days') || 1;
3716   }
3717   my $expsecs = 60*60*24*$expdays;
3718   return 0 unless $self->expire < time + $expsecs;
3719   return 1;
3720 }
3721
3722 =item pkg_label
3723
3724 Returns a label for this package.  (Currently "pkgnum: pkg - comment" or
3725 "pkg - comment" depending on user preference).
3726
3727 =cut
3728
3729 sub pkg_label {
3730   my $self = shift;
3731   my $label = $self->part_pkg->pkg_comment( cust_pkg=>$self, nopkgpart=>1 );
3732   $label = $self->pkgnum. ": $label"
3733     if $FS::CurrentUser::CurrentUser->option('show_pkgnum');
3734   $label;
3735 }
3736
3737 =item pkg_label_long
3738
3739 Returns a long label for this package, adding the primary service's label to
3740 pkg_label.
3741
3742 =cut
3743
3744 sub pkg_label_long {
3745   my $self = shift;
3746   my $label = $self->pkg_label;
3747   my $cust_svc = $self->primary_cust_svc;
3748   $label .= ' ('. ($cust_svc->label)[1]. ')' if $cust_svc;
3749   $label;
3750 }
3751
3752 =item pkg_locale
3753
3754 Returns a customer-localized label for this package.
3755
3756 =cut
3757
3758 sub pkg_locale {
3759   my $self = shift;
3760   $self->part_pkg->pkg_locale( $self->cust_main->locale );
3761 }
3762
3763 =item primary_cust_svc
3764
3765 Returns a primary service (as FS::cust_svc object) if one can be identified.
3766
3767 =cut
3768
3769 #for labeling purposes - might not 100% match up with part_pkg->svcpart's idea
3770
3771 sub primary_cust_svc {
3772   my $self = shift;
3773
3774   my @cust_svc = $self->cust_svc;
3775
3776   return '' unless @cust_svc; #no serivces - irrelevant then
3777
3778   return $cust_svc[0] if scalar(@cust_svc) == 1; #always return a single service
3779
3780   # primary service as specified in the package definition
3781   # or exactly one service definition with quantity one
3782   my $svcpart = $self->part_pkg->svcpart;
3783   @cust_svc = grep { $_->svcpart == $svcpart } @cust_svc;
3784   return $cust_svc[0] if scalar(@cust_svc) == 1;
3785
3786   #couldn't identify one thing..
3787   return '';
3788 }
3789
3790 =item labels
3791
3792 Returns a list of lists, calling the label method for all services
3793 (see L<FS::cust_svc>) of this billing item.
3794
3795 =cut
3796
3797 sub labels {
3798   my $self = shift;
3799   map { [ $_->label ] } $self->cust_svc;
3800 }
3801
3802 =item h_labels END_TIMESTAMP [ START_TIMESTAMP ] [ MODE ]
3803
3804 Like the labels method, but returns historical information on services that
3805 were active as of END_TIMESTAMP and (optionally) not cancelled before
3806 START_TIMESTAMP.  If MODE is 'I' (for 'invoice'), services with the
3807 I<pkg_svc.hidden> flag will be omitted.
3808
3809 Returns a list of lists, calling the label method for all (historical) services
3810 (see L<FS::h_cust_svc>) of this billing item.
3811
3812 =cut
3813
3814 sub h_labels {
3815   my $self = shift;
3816   warn "$me _h_labels called on $self\n"
3817     if $DEBUG;
3818   map { [ $_->label(@_) ] } $self->h_cust_svc(@_);
3819 }
3820
3821 =item labels_short
3822
3823 Like labels, except returns a simple flat list, and shortens long
3824 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3825 identical services to one line that lists the service label and the number of
3826 individual services rather than individual items.
3827
3828 =cut
3829
3830 sub labels_short {
3831   shift->_labels_short( 'labels', @_ );
3832 }
3833
3834 =item h_labels_short END_TIMESTAMP [ START_TIMESTAMP ]
3835
3836 Like h_labels, except returns a simple flat list, and shortens long
3837 (currently >5 or the cust_bill-max_same_services configuration value) lists of
3838 identical services to one line that lists the service label and the number of
3839 individual services rather than individual items.
3840
3841 =cut
3842
3843 sub h_labels_short {
3844   shift->_labels_short( 'h_labels', @_ );
3845 }
3846
3847 sub _labels_short {
3848   my( $self, $method ) = ( shift, shift );
3849
3850   warn "$me _labels_short called on $self with $method method\n"
3851     if $DEBUG;
3852
3853   my $conf = new FS::Conf;
3854   my $max_same_services = $conf->config('cust_bill-max_same_services') || 5;
3855
3856   warn "$me _labels_short populating \%labels\n"
3857     if $DEBUG;
3858
3859   my %labels;
3860   #tie %labels, 'Tie::IxHash';
3861   push @{ $labels{$_->[0]} }, $_->[1]
3862     foreach $self->$method(@_);
3863
3864   warn "$me _labels_short populating \@labels\n"
3865     if $DEBUG;
3866
3867   my @labels;
3868   foreach my $label ( keys %labels ) {
3869     my %seen = ();
3870     my @values = grep { ! $seen{$_}++ } @{ $labels{$label} };
3871     my $num = scalar(@values);
3872     warn "$me _labels_short $num items for $label\n"
3873       if $DEBUG;
3874
3875     if ( $num > $max_same_services ) {
3876       warn "$me _labels_short   more than $max_same_services, so summarizing\n"
3877         if $DEBUG;
3878       push @labels, "$label ($num)";
3879     } else {
3880       if ( $conf->exists('cust_bill-consolidate_services') ) {
3881         warn "$me _labels_short   consolidating services\n"
3882           if $DEBUG;
3883         # push @labels, "$label: ". join(', ', @values);
3884         while ( @values ) {
3885           my $detail = "$label: ";
3886           $detail .= shift(@values). ', '
3887             while @values
3888                && ( length($detail.$values[0]) < 78 || $detail eq "$label: " );
3889           $detail =~ s/, $//;
3890           push @labels, $detail;
3891         }
3892         warn "$me _labels_short   done consolidating services\n"
3893           if $DEBUG;
3894       } else {
3895         warn "$me _labels_short   adding service data\n"
3896           if $DEBUG;
3897         push @labels, map { "$label: $_" } @values;
3898       }
3899     }
3900   }
3901
3902  @labels;
3903
3904 }
3905
3906 =item cust_main
3907
3908 Returns the parent customer object (see L<FS::cust_main>).
3909
3910 =item balance
3911
3912 Returns the balance for this specific package, when using
3913 experimental package balance.
3914
3915 =cut
3916
3917 sub balance {
3918   my $self = shift;
3919   $self->cust_main->balance_pkgnum( $self->pkgnum );
3920 }
3921
3922 #these subs are in location_Mixin.pm now... unfortunately the POD doesn't mixin
3923
3924 =item cust_location
3925
3926 Returns the location object, if any (see L<FS::cust_location>).
3927
3928 =item cust_location_or_main
3929
3930 If this package is associated with a location, returns the locaiton (see
3931 L<FS::cust_location>), otherwise returns the customer (see L<FS::cust_main>).
3932
3933 =item location_label [ OPTION => VALUE ... ]
3934
3935 Returns the label of the location object (see L<FS::cust_location>).
3936
3937 =cut
3938
3939 #end of subs in location_Mixin.pm now... unfortunately the POD doesn't mixin
3940
3941 =item tax_locationnum
3942
3943 Returns the foreign key to a L<FS::cust_location> object for calculating
3944 tax on this package, as determined by the C<tax-pkg_address> and
3945 C<tax-ship_address> configuration flags.
3946
3947 =cut
3948
3949 sub tax_locationnum {
3950   my $self = shift;
3951   my $conf = FS::Conf->new;
3952   if ( $conf->exists('tax-pkg_address') ) {
3953     return $self->locationnum;
3954   }
3955   elsif ( $conf->exists('tax-ship_address') ) {
3956     return $self->cust_main->ship_locationnum;
3957   }
3958   else {
3959     return $self->cust_main->bill_locationnum;
3960   }
3961 }
3962
3963 =item tax_location
3964
3965 Returns the L<FS::cust_location> object for tax_locationnum.
3966
3967 =cut
3968
3969 sub tax_location {
3970   my $self = shift;
3971   my $conf = FS::Conf->new;
3972   if ( $conf->exists('tax-pkg_address') and $self->locationnum ) {
3973     return FS::cust_location->by_key($self->locationnum);
3974   }
3975   elsif ( $conf->exists('tax-ship_address') ) {
3976     return $self->cust_main->ship_location;
3977   }
3978   else {
3979     return $self->cust_main->bill_location;
3980   }
3981 }
3982
3983 =item seconds_since TIMESTAMP
3984
3985 Returns the number of seconds all accounts (see L<FS::svc_acct>) in this
3986 package have been online since TIMESTAMP, according to the session monitor.
3987
3988 TIMESTAMP is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
3989 L<Time::Local> and L<Date::Parse> for conversion functions.
3990
3991 =cut
3992
3993 sub seconds_since {
3994   my($self, $since) = @_;
3995   my $seconds = 0;
3996
3997   foreach my $cust_svc (
3998     grep { $_->part_svc->svcdb eq 'svc_acct' } $self->cust_svc
3999   ) {
4000     $seconds += $cust_svc->seconds_since($since);
4001   }
4002
4003   $seconds;
4004
4005 }
4006
4007 =item seconds_since_sqlradacct TIMESTAMP_START TIMESTAMP_END
4008
4009 Returns the numbers of seconds all accounts (see L<FS::svc_acct>) in this
4010 package have been online between TIMESTAMP_START (inclusive) and TIMESTAMP_END
4011 (exclusive).
4012
4013 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
4014 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
4015 functions.
4016
4017
4018 =cut
4019
4020 sub seconds_since_sqlradacct {
4021   my($self, $start, $end) = @_;
4022
4023   my $seconds = 0;
4024
4025   foreach my $cust_svc (
4026     grep {
4027       my $part_svc = $_->part_svc;
4028       $part_svc->svcdb eq 'svc_acct'
4029         && scalar($part_svc->part_export_usage);
4030     } $self->cust_svc
4031   ) {
4032     $seconds += $cust_svc->seconds_since_sqlradacct($start, $end);
4033   }
4034
4035   $seconds;
4036
4037 }
4038
4039 =item attribute_since_sqlradacct TIMESTAMP_START TIMESTAMP_END ATTRIBUTE
4040
4041 Returns the sum of the given attribute for all accounts (see L<FS::svc_acct>)
4042 in this package for sessions ending between TIMESTAMP_START (inclusive) and
4043 TIMESTAMP_END
4044 (exclusive).
4045
4046 TIMESTAMP_START and TIMESTAMP_END are specified as UNIX timestamps; see
4047 L<perlfunc/"time">.  Also see L<Time::Local> and L<Date::Parse> for conversion
4048 functions.
4049
4050 =cut
4051
4052 sub attribute_since_sqlradacct {
4053   my($self, $start, $end, $attrib) = @_;
4054
4055   my $sum = 0;
4056
4057   foreach my $cust_svc (
4058     grep {
4059       my $part_svc = $_->part_svc;
4060       scalar($part_svc->part_export_usage);
4061     } $self->cust_svc
4062   ) {
4063     $sum += $cust_svc->attribute_since_sqlradacct($start, $end, $attrib);
4064   }
4065
4066   $sum;
4067
4068 }
4069
4070 =item quantity
4071
4072 =cut
4073
4074 sub quantity {
4075   my( $self, $value ) = @_;
4076   if ( defined($value) ) {
4077     $self->setfield('quantity', $value);
4078   }
4079   $self->getfield('quantity') || 1;
4080 }
4081
4082 =item transfer DEST_PKGNUM | DEST_CUST_PKG, [ OPTION => VALUE ... ]
4083
4084 Transfers as many services as possible from this package to another package.
4085
4086 The destination package can be specified by pkgnum by passing an FS::cust_pkg
4087 object.  The destination package must already exist.
4088
4089 Services are moved only if the destination allows services with the correct
4090 I<svcpart> (not svcdb), unless the B<change_svcpart> option is set true.  Use
4091 this option with caution!  No provision is made for export differences
4092 between the old and new service definitions.  Probably only should be used
4093 when your exports for all service definitions of a given svcdb are identical.
4094 (attempt a transfer without it first, to move all possible svcpart-matching
4095 services)
4096
4097 Any services that can't be moved remain in the original package.
4098
4099 Returns an error, if there is one; otherwise, returns the number of services
4100 that couldn't be moved.
4101
4102 =cut
4103
4104 sub transfer {
4105   my ($self, $dest_pkgnum, %opt) = @_;
4106
4107   my $remaining = 0;
4108   my $dest;
4109   my %target;
4110
4111   if (ref ($dest_pkgnum) eq 'FS::cust_pkg') {
4112     $dest = $dest_pkgnum;
4113     $dest_pkgnum = $dest->pkgnum;
4114   } else {
4115     $dest = qsearchs('cust_pkg', { pkgnum => $dest_pkgnum });
4116   }
4117
4118   return ('Package does not exist: '.$dest_pkgnum) unless $dest;
4119
4120   foreach my $pkg_svc ( $dest->part_pkg->pkg_svc ) {
4121     $target{$pkg_svc->svcpart} = $pkg_svc->quantity * ( $dest->quantity || 1 );
4122   }
4123
4124   foreach my $cust_svc ($dest->cust_svc) {
4125     $target{$cust_svc->svcpart}--;
4126   }
4127
4128   my %svcpart2svcparts = ();
4129   if ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
4130     warn "change_svcpart option received, creating alternates list\n" if $DEBUG;
4131     foreach my $svcpart ( map { $_->svcpart } $self->cust_svc ) {
4132       next if exists $svcpart2svcparts{$svcpart};
4133       my $part_svc = qsearchs('part_svc', { 'svcpart' => $svcpart } );
4134       $svcpart2svcparts{$svcpart} = [
4135         map  { $_->[0] }
4136         sort { $b->[1] cmp $a->[1]  or  $a->[2] <=> $b->[2] }
4137         map {
4138               my $pkg_svc = qsearchs( 'pkg_svc', { 'pkgpart' => $dest->pkgpart,
4139                                                    'svcpart' => $_          } );
4140               [ $_,
4141                 $pkg_svc ? $pkg_svc->primary_svc : '',
4142                 $pkg_svc ? $pkg_svc->quantity : 0,
4143               ];
4144             }
4145
4146         grep { $_ != $svcpart }
4147         map  { $_->svcpart }
4148         qsearch('part_svc', { 'svcdb' => $part_svc->svcdb } )
4149       ];
4150       warn "alternates for svcpart $svcpart: ".
4151            join(', ', @{$svcpart2svcparts{$svcpart}}). "\n"
4152         if $DEBUG;
4153     }
4154   }
4155
4156   my $error;
4157   foreach my $cust_svc ($self->cust_svc) {
4158     my $svcnum = $cust_svc->svcnum;
4159     if($target{$cust_svc->svcpart} > 0
4160        or $FS::cust_svc::ignore_quantity) { # maybe should be a 'force' option
4161       $target{$cust_svc->svcpart}--;
4162       my $new = new FS::cust_svc { $cust_svc->hash };
4163       $new->pkgnum($dest_pkgnum);
4164       $error = $new->replace($cust_svc);
4165     } elsif ( exists $opt{'change_svcpart'} && $opt{'change_svcpart'} ) {
4166       if ( $DEBUG ) {
4167         warn "looking for alternates for svcpart ". $cust_svc->svcpart. "\n";
4168         warn "alternates to consider: ".
4169              join(', ', @{$svcpart2svcparts{$cust_svc->svcpart}}). "\n";
4170       }
4171       my @alternate = grep {
4172                              warn "considering alternate svcpart $_: ".
4173                                   "$target{$_} available in new package\n"
4174                                if $DEBUG;
4175                              $target{$_} > 0;
4176                            } @{$svcpart2svcparts{$cust_svc->svcpart}};
4177       if ( @alternate ) {
4178         warn "alternate(s) found\n" if $DEBUG;
4179         my $change_svcpart = $alternate[0];
4180         $target{$change_svcpart}--;
4181         my $new = new FS::cust_svc { $cust_svc->hash };
4182         $new->svcpart($change_svcpart);
4183         $new->pkgnum($dest_pkgnum);
4184         $error = $new->replace($cust_svc);
4185       } else {
4186         $remaining++;
4187       }
4188     } else {
4189       $remaining++
4190     }
4191     if ( $error ) {
4192       my @label = $cust_svc->label;
4193       return "$label[0] $label[1]: $error";
4194     }
4195   }
4196   return $remaining;
4197 }
4198
4199 =item grab_svcnums SVCNUM, SVCNUM ...
4200
4201 Change the pkgnum for the provided services to this packages.  If there is an
4202 error, returns the error, otherwise returns false.
4203
4204 =cut
4205
4206 sub grab_svcnums {
4207   my $self = shift;
4208   my @svcnum = @_;
4209
4210   my $oldAutoCommit = $FS::UID::AutoCommit;
4211   local $FS::UID::AutoCommit = 0;
4212   my $dbh = dbh;
4213
4214   foreach my $svcnum (@svcnum) {
4215     my $cust_svc = qsearchs('cust_svc', { svcnum=>$svcnum } ) or do {
4216       $dbh->rollback if $oldAutoCommit;
4217       return "unknown svcnum $svcnum";
4218     };
4219     $cust_svc->pkgnum( $self->pkgnum );
4220     my $error = $cust_svc->replace;
4221     if ( $error ) {
4222       $dbh->rollback if $oldAutoCommit;
4223       return $error;
4224     }
4225   }
4226
4227   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4228   '';
4229
4230 }
4231
4232 =item reexport
4233
4234 This method is deprecated.  See the I<depend_jobnum> option to the insert and
4235 order_pkgs methods in FS::cust_main for a better way to defer provisioning.
4236
4237 =cut
4238
4239 #looks like this is still used by the order_pkg and change_pkg methods in
4240 # ClientAPI/MyAccount, need to look into those before removing
4241 sub reexport {
4242   my $self = shift;
4243
4244   my $oldAutoCommit = $FS::UID::AutoCommit;
4245   local $FS::UID::AutoCommit = 0;
4246   my $dbh = dbh;
4247
4248   foreach my $cust_svc ( $self->cust_svc ) {
4249     #false laziness w/svc_Common::insert
4250     my $svc_x = $cust_svc->svc_x;
4251     foreach my $part_export ( $cust_svc->part_svc->part_export ) {
4252       my $error = $part_export->export_insert($svc_x);
4253       if ( $error ) {
4254         $dbh->rollback if $oldAutoCommit;
4255         return $error;
4256       }
4257     }
4258   }
4259
4260   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4261   '';
4262
4263 }
4264
4265 =item export_pkg_change OLD_CUST_PKG
4266
4267 Calls the "pkg_change" export action for all services attached to this package.
4268
4269 =cut
4270
4271 sub export_pkg_change {
4272   my( $self, $old )  = ( shift, shift );
4273
4274   my $oldAutoCommit = $FS::UID::AutoCommit;
4275   local $FS::UID::AutoCommit = 0;
4276   my $dbh = dbh;
4277
4278   foreach my $svc_x ( map $_->svc_x, $self->cust_svc ) {
4279     my $error = $svc_x->export('pkg_change', $self, $old);
4280     if ( $error ) {
4281       $dbh->rollback if $oldAutoCommit;
4282       return $error;
4283     }
4284   }
4285
4286   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4287   '';
4288
4289 }
4290
4291 =item insert_reason
4292
4293 Associates this package with a (suspension or cancellation) reason (see
4294 L<FS::cust_pkg_reason>, possibly inserting a new reason on the fly (see
4295 L<FS::reason>).
4296
4297 Available options are:
4298
4299 =over 4
4300
4301 =item reason
4302
4303 can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
4304
4305 =item reason_otaker
4306
4307 the access_user (see L<FS::access_user>) providing the reason
4308
4309 =item date
4310
4311 a unix timestamp
4312
4313 =item action
4314
4315 the action (cancel, susp, adjourn, expire) associated with the reason
4316
4317 =back
4318
4319 If there is an error, returns the error, otherwise returns false.
4320
4321 =cut
4322
4323 sub insert_reason {
4324   my ($self, %options) = @_;
4325
4326   my $otaker = $options{reason_otaker} ||
4327                $FS::CurrentUser::CurrentUser->username;
4328
4329   my $reasonnum;
4330   if ( $options{'reason'} =~ /^(\d+)$/ ) {
4331
4332     $reasonnum = $1;
4333
4334   } elsif ( ref($options{'reason'}) ) {
4335
4336     return 'Enter a new reason (or select an existing one)'
4337       unless $options{'reason'}->{'reason'} !~ /^\s*$/;
4338
4339     my $reason = new FS::reason({
4340       'reason_type' => $options{'reason'}->{'typenum'},
4341       'reason'      => $options{'reason'}->{'reason'},
4342     });
4343     my $error = $reason->insert;
4344     return $error if $error;
4345
4346     $reasonnum = $reason->reasonnum;
4347
4348   } else {
4349     return "Unparseable reason: ". $options{'reason'};
4350   }
4351
4352   my $cust_pkg_reason =
4353     new FS::cust_pkg_reason({ 'pkgnum'    => $self->pkgnum,
4354                               'reasonnum' => $reasonnum,
4355                               'otaker'    => $otaker,
4356                               'action'    => substr(uc($options{'action'}),0,1),
4357                               'date'      => $options{'date'}
4358                                                ? $options{'date'}
4359                                                : time,
4360                             });
4361
4362   $cust_pkg_reason->insert;
4363 }
4364
4365 =item insert_discount
4366
4367 Associates this package with a discount (see L<FS::cust_pkg_discount>, possibly
4368 inserting a new discount on the fly (see L<FS::discount>).
4369
4370 This will look at the cust_pkg for a pseudo-field named "setup_discountnum",
4371 and if present, will create a setup discount. If the discountnum is -1,
4372 a new discount definition will be inserted using the value in
4373 "setup_discountnum_amount" or "setup_discountnum_percent". Likewise for recur.
4374
4375 If there is an error, returns the error, otherwise returns false.
4376
4377 =cut
4378
4379 sub insert_discount {
4380   #my ($self, %options) = @_;
4381   my $self = shift;
4382
4383   foreach my $x (qw(setup recur)) {
4384     if ( my $discountnum = $self->get("${x}_discountnum") ) {
4385       my $cust_pkg_discount = FS::cust_pkg_discount->new( {
4386         'pkgnum'      => $self->pkgnum,
4387         'discountnum' => $discountnum,
4388         'setuprecur'  => $x,
4389         'months_used' => 0,
4390         'end_date'    => '', #XXX
4391         #for the create a new discount case
4392         'amount'      => $self->get("${x}_discountnum_amount"),
4393         'percent'     => $self->get("${x}_discountnum_percent"),
4394         'months'      => $self->get("${x}_discountnum_months"),
4395       } );
4396       if ( $x eq 'setup' ) {
4397         $cust_pkg_discount->setup('Y');
4398         $cust_pkg_discount->months('');
4399       }
4400       my $error = $cust_pkg_discount->insert;
4401       return $error if $error;
4402     }
4403   }
4404
4405   '';
4406 }
4407
4408 =item set_usage USAGE_VALUE_HASHREF
4409
4410 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4411 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4412 upbytes, downbytes, and totalbytes are appropriate keys.
4413
4414 All svc_accts which are part of this package have their values reset.
4415
4416 =cut
4417
4418 sub set_usage {
4419   my ($self, $valueref, %opt) = @_;
4420
4421   #only svc_acct can set_usage for now
4422   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4423     my $svc_x = $cust_svc->svc_x;
4424     $svc_x->set_usage($valueref, %opt)
4425       if $svc_x->can("set_usage");
4426   }
4427 }
4428
4429 =item recharge USAGE_VALUE_HASHREF
4430
4431 USAGE_VALUE_HASHREF is a hashref of svc_acct usage columns and the amounts
4432 to which they should be set (see L<FS::svc_acct>).  Currently seconds,
4433 upbytes, downbytes, and totalbytes are appropriate keys.
4434
4435 All svc_accts which are part of this package have their values incremented.
4436
4437 =cut
4438
4439 sub recharge {
4440   my ($self, $valueref) = @_;
4441
4442   #only svc_acct can set_usage for now
4443   foreach my $cust_svc ( $self->cust_svc( 'svcdb'=>'svc_acct' ) ) {
4444     my $svc_x = $cust_svc->svc_x;
4445     $svc_x->recharge($valueref)
4446       if $svc_x->can("recharge");
4447   }
4448 }
4449
4450 =item apply_usageprice
4451
4452 =cut
4453
4454 sub apply_usageprice {
4455   my $self = shift;
4456
4457   my $oldAutoCommit = $FS::UID::AutoCommit;
4458   local $FS::UID::AutoCommit = 0;
4459   my $dbh = dbh;
4460
4461   my $error = '';
4462
4463   foreach my $cust_pkg_usageprice ( $self->cust_pkg_usageprice ) {
4464     $error ||= $cust_pkg_usageprice->apply;
4465   }
4466
4467   if ( $error ) {
4468     $dbh->rollback if $oldAutoCommit;
4469     die "error applying part_pkg_usageprice add-ons, pkgnum ". $self->pkgnum.
4470         ": $error\n";
4471   } else {
4472     $dbh->commit if $oldAutoCommit;
4473   }
4474
4475
4476 }
4477
4478 =item cust_pkg_discount
4479
4480 =item cust_pkg_discount_active
4481
4482 =cut
4483
4484 sub cust_pkg_discount_active {
4485   my $self = shift;
4486   grep { $_->status eq 'active' } $self->cust_pkg_discount;
4487 }
4488
4489 =item cust_pkg_usage
4490
4491 Returns a list of all voice usage counters attached to this package.
4492
4493 =item apply_usage OPTIONS
4494
4495 Takes the following options:
4496 - cdr: a call detail record (L<FS::cdr>)
4497 - rate_detail: the rate determined for this call (L<FS::rate_detail>)
4498 - minutes: the maximum number of minutes to be charged
4499
4500 Finds available usage minutes for a call of this class, and subtracts
4501 up to that many minutes from the usage pool.  If the usage pool is empty,
4502 and the C<cdr-minutes_priority> global config option is set, minutes may
4503 be taken from other calls as well.  Either way, an allocation record will
4504 be created (L<FS::cdr_cust_pkg_usage>) and this method will return the
4505 number of minutes of usage applied to the call.
4506
4507 =cut
4508
4509 sub apply_usage {
4510   my ($self, %opt) = @_;
4511   my $cdr = $opt{cdr};
4512   my $rate_detail = $opt{rate_detail};
4513   my $minutes = $opt{minutes};
4514   my $classnum = $rate_detail->classnum;
4515   my $pkgnum = $self->pkgnum;
4516   my $custnum = $self->custnum;
4517
4518   my $oldAutoCommit = $FS::UID::AutoCommit;
4519   local $FS::UID::AutoCommit = 0;
4520   my $dbh = dbh;
4521
4522   my $order = FS::Conf->new->config('cdr-minutes_priority');
4523
4524   my $is_classnum;
4525   if ( $classnum ) {
4526     $is_classnum = ' part_pkg_usage_class.classnum = '.$classnum;
4527   } else {
4528     $is_classnum = ' part_pkg_usage_class.classnum IS NULL';
4529   }
4530   my @usage_recs = qsearch({
4531       'table'     => 'cust_pkg_usage',
4532       'addl_from' => ' JOIN part_pkg_usage       USING (pkgusagepart)'.
4533                      ' JOIN cust_pkg             USING (pkgnum)'.
4534                      ' JOIN part_pkg_usage_class USING (pkgusagepart)',
4535       'select'    => 'cust_pkg_usage.*',
4536       'extra_sql' => " WHERE ( cust_pkg.pkgnum = $pkgnum OR ".
4537                      " ( cust_pkg.custnum = $custnum AND ".
4538                      " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4539                      $is_classnum . ' AND '.
4540                      " cust_pkg_usage.minutes > 0",
4541       'order_by'  => " ORDER BY priority ASC",
4542   });
4543
4544   my $orig_minutes = $minutes;
4545   my $error;
4546   while (!$error and $minutes > 0 and @usage_recs) {
4547     my $cust_pkg_usage = shift @usage_recs;
4548     $cust_pkg_usage->select_for_update;
4549     my $cdr_cust_pkg_usage = FS::cdr_cust_pkg_usage->new({
4550         pkgusagenum => $cust_pkg_usage->pkgusagenum,
4551         acctid      => $cdr->acctid,
4552         minutes     => min($cust_pkg_usage->minutes, $minutes),
4553     });
4554     $cust_pkg_usage->set('minutes',
4555       $cust_pkg_usage->minutes - $cdr_cust_pkg_usage->minutes
4556     );
4557     $error = $cust_pkg_usage->replace || $cdr_cust_pkg_usage->insert;
4558     $minutes -= $cdr_cust_pkg_usage->minutes;
4559   }
4560   if ( $order and $minutes > 0 and !$error ) {
4561     # then try to steal minutes from another call
4562     my %search = (
4563         'table'     => 'cdr_cust_pkg_usage',
4564         'addl_from' => ' JOIN cust_pkg_usage        USING (pkgusagenum)'.
4565                        ' JOIN part_pkg_usage        USING (pkgusagepart)'.
4566                        ' JOIN cust_pkg              USING (pkgnum)'.
4567                        ' JOIN part_pkg_usage_class  USING (pkgusagepart)'.
4568                        ' JOIN cdr                   USING (acctid)',
4569         'select'    => 'cdr_cust_pkg_usage.*',
4570         'extra_sql' => " WHERE cdr.freesidestatus = 'rated' AND ".
4571                        " ( cust_pkg.pkgnum = $pkgnum OR ".
4572                        " ( cust_pkg.custnum = $custnum AND ".
4573                        " part_pkg_usage.shared IS NOT NULL ) ) AND ".
4574                        " part_pkg_usage_class.classnum = $classnum",
4575         'order_by'  => ' ORDER BY part_pkg_usage.priority ASC',
4576     );
4577     if ( $order eq 'time' ) {
4578       # find CDRs that are using minutes, but have a later startdate
4579       # than this call
4580       my $startdate = $cdr->startdate;
4581       if ($startdate !~ /^\d+$/) {
4582         die "bad cdr startdate '$startdate'";
4583       }
4584       $search{'extra_sql'} .= " AND cdr.startdate > $startdate";
4585       # minimize needless reshuffling
4586       $search{'order_by'} .= ', cdr.startdate DESC';
4587     } else {
4588       # XXX may not work correctly with rate_time schedules.  Could
4589       # fix this by storing ratedetailnum in cdr_cust_pkg_usage, I
4590       # think...
4591       $search{'addl_from'} .=
4592         ' JOIN rate_detail'.
4593         ' ON (cdr.rated_ratedetailnum = rate_detail.ratedetailnum)';
4594       if ( $order eq 'rate_high' ) {
4595         $search{'extra_sql'} .= ' AND rate_detail.min_charge < '.
4596                                 $rate_detail->min_charge;
4597         $search{'order_by'} .= ', rate_detail.min_charge ASC';
4598       } elsif ( $order eq 'rate_low' ) {
4599         $search{'extra_sql'} .= ' AND rate_detail.min_charge > '.
4600                                 $rate_detail->min_charge;
4601         $search{'order_by'} .= ', rate_detail.min_charge DESC';
4602       } else {
4603         #  this should really never happen
4604         die "invalid cdr-minutes_priority value '$order'\n";
4605       }
4606     }
4607     my @cdr_usage_recs = qsearch(\%search);
4608     my %reproc_cdrs;
4609     while (!$error and @cdr_usage_recs and $minutes > 0) {
4610       my $cdr_cust_pkg_usage = shift @cdr_usage_recs;
4611       my $cust_pkg_usage = $cdr_cust_pkg_usage->cust_pkg_usage;
4612       my $old_cdr = $cdr_cust_pkg_usage->cdr;
4613       $reproc_cdrs{$old_cdr->acctid} = $old_cdr;
4614       $cdr_cust_pkg_usage->select_for_update;
4615       $old_cdr->select_for_update;
4616       $cust_pkg_usage->select_for_update;
4617       # in case someone else stole the usage from this CDR
4618       # while waiting for the lock...
4619       next if $old_cdr->acctid != $cdr_cust_pkg_usage->acctid;
4620       # steal the usage allocation and flag the old CDR for reprocessing
4621       $cdr_cust_pkg_usage->set('acctid', $cdr->acctid);
4622       # if the allocation is more minutes than we need, adjust it...
4623       my $delta = $cdr_cust_pkg_usage->minutes - $minutes;
4624       if ( $delta > 0 ) {
4625         $cdr_cust_pkg_usage->set('minutes', $minutes);
4626         $cust_pkg_usage->set('minutes', $cust_pkg_usage->minutes + $delta);
4627         $error = $cust_pkg_usage->replace;
4628       }
4629       #warn 'CDR '.$cdr->acctid . ' stealing allocation '.$cdr_cust_pkg_usage->cdrusagenum.' from CDR '.$old_cdr->acctid."\n";
4630       $error ||= $cdr_cust_pkg_usage->replace;
4631       # deduct the stolen minutes
4632       $minutes -= $cdr_cust_pkg_usage->minutes;
4633     }
4634     # after all minute-stealing is done, reset the affected CDRs
4635     foreach (values %reproc_cdrs) {
4636       $error ||= $_->set_status('');
4637       # XXX or should we just call $cdr->rate right here?
4638       # it's not like we can create a loop this way, since the min_charge
4639       # or call time has to go monotonically in one direction.
4640       # we COULD get some very deep recursions going, though...
4641     }
4642   } # if $order and $minutes
4643   if ( $error ) {
4644     $dbh->rollback;
4645     die "error applying included minutes\npkgnum ".$self->pkgnum.", class $classnum, acctid ".$cdr->acctid."\n$error\n"
4646   } else {
4647     $dbh->commit if $oldAutoCommit;
4648     return $orig_minutes - $minutes;
4649   }
4650 }
4651
4652 =item supplemental_pkgs
4653
4654 Returns a list of all packages supplemental to this one.
4655
4656 =cut
4657
4658 sub supplemental_pkgs {
4659   my $self = shift;
4660   qsearch('cust_pkg', { 'main_pkgnum' => $self->pkgnum });
4661 }
4662
4663 =item main_pkg
4664
4665 Returns the package that this one is supplemental to, if any.
4666
4667 =cut
4668
4669 sub main_pkg {
4670   my $self = shift;
4671   if ( $self->main_pkgnum ) {
4672     return FS::cust_pkg->by_key($self->main_pkgnum);
4673   }
4674   return;
4675 }
4676
4677 =back
4678
4679 =head1 CLASS METHODS
4680
4681 =over 4
4682
4683 =item recurring_sql
4684
4685 Returns an SQL expression identifying recurring packages.
4686
4687 =cut
4688
4689 sub recurring_sql { "
4690   '0' != ( select freq from part_pkg
4691              where cust_pkg.pkgpart = part_pkg.pkgpart )
4692 "; }
4693
4694 =item onetime_sql
4695
4696 Returns an SQL expression identifying one-time packages.
4697
4698 =cut
4699
4700 sub onetime_sql { "
4701   '0' = ( select freq from part_pkg
4702             where cust_pkg.pkgpart = part_pkg.pkgpart )
4703 "; }
4704
4705 =item ordered_sql
4706
4707 Returns an SQL expression identifying ordered packages (recurring packages not
4708 yet billed).
4709
4710 =cut
4711
4712 sub ordered_sql {
4713    $_[0]->recurring_sql. " AND ". $_[0]->not_yet_billed_sql;
4714 }
4715
4716 =item active_sql
4717
4718 Returns an SQL expression identifying active packages.
4719
4720 =cut
4721
4722 sub active_sql {
4723   $_[0]->recurring_sql. "
4724   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4725   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4726   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4727 "; }
4728
4729 =item not_yet_billed_sql
4730
4731 Returns an SQL expression identifying packages which have not yet been billed.
4732
4733 =cut
4734
4735 sub not_yet_billed_sql { "
4736       ( cust_pkg.setup  IS NULL OR cust_pkg.setup  = 0 )
4737   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4738   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4739 "; }
4740
4741 =item inactive_sql
4742
4743 Returns an SQL expression identifying inactive packages (one-time packages
4744 that are otherwise unsuspended/uncancelled).
4745
4746 =cut
4747
4748 sub inactive_sql { "
4749   ". $_[0]->onetime_sql(). "
4750   AND cust_pkg.setup IS NOT NULL AND cust_pkg.setup != 0
4751   AND ( cust_pkg.cancel IS NULL OR cust_pkg.cancel = 0 )
4752   AND ( cust_pkg.susp   IS NULL OR cust_pkg.susp   = 0 )
4753 "; }
4754
4755 =item on_hold_sql
4756
4757 Returns an SQL expression identifying on-hold packages.
4758
4759 =cut
4760
4761 sub on_hold_sql {
4762   #$_[0]->recurring_sql(). ' AND '.
4763   "
4764         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel  = 0 )
4765     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp   != 0
4766     AND ( cust_pkg.setup  IS     NULL  OR cust_pkg.setup   = 0 )
4767   ";
4768 }
4769
4770 =item susp_sql
4771 =item suspended_sql
4772
4773 Returns an SQL expression identifying suspended packages.
4774
4775 =cut
4776
4777 sub suspended_sql { susp_sql(@_); }
4778 sub susp_sql {
4779   #$_[0]->recurring_sql(). ' AND '.
4780   "
4781         ( cust_pkg.cancel IS     NULL  OR cust_pkg.cancel = 0 )
4782     AND   cust_pkg.susp   IS NOT NULL AND cust_pkg.susp  != 0
4783     AND   cust_pkg.setup  IS NOT NULL AND cust_pkg.setup != 0
4784   ";
4785 }
4786
4787 =item cancel_sql
4788 =item cancelled_sql
4789
4790 Returns an SQL exprression identifying cancelled packages.
4791
4792 =cut
4793
4794 sub cancelled_sql { cancel_sql(@_); }
4795 sub cancel_sql {
4796   #$_[0]->recurring_sql(). ' AND '.
4797   "cust_pkg.cancel IS NOT NULL AND cust_pkg.cancel != 0";
4798 }
4799
4800 =item status_sql
4801
4802 Returns an SQL expression to give the package status as a string.
4803
4804 =cut
4805
4806 sub status_sql {
4807 "CASE
4808   WHEN cust_pkg.cancel IS NOT NULL THEN 'cancelled'
4809   WHEN ( cust_pkg.susp IS NOT NULL AND cust_pkg.setup IS NULL ) THEN 'on hold'
4810   WHEN cust_pkg.susp IS NOT NULL THEN 'suspended'
4811   WHEN cust_pkg.setup IS NULL THEN 'not yet billed'
4812   WHEN ".onetime_sql()." THEN 'one-time charge'
4813   ELSE 'active'
4814 END"
4815 }
4816
4817 =item fcc_477_count
4818
4819 Returns a list of two package counts.  The first is a count of packages
4820 based on the supplied criteria and the second is the count of residential
4821 packages with those same criteria.  Criteria are specified as in the search
4822 method.
4823
4824 =cut
4825
4826 sub fcc_477_count {
4827   my ($class, $params) = @_;
4828
4829   my $sql_query = $class->search( $params );
4830
4831   my $count_sql = delete($sql_query->{'count_query'});
4832   $count_sql =~ s/ FROM/,count(CASE WHEN cust_main.company IS NULL OR cust_main.company = '' THEN 1 END) FROM/
4833     or die "couldn't parse count_sql";
4834
4835   my $count_sth = dbh->prepare($count_sql)
4836     or die "Error preparing $count_sql: ". dbh->errstr;
4837   $count_sth->execute
4838     or die "Error executing $count_sql: ". $count_sth->errstr;
4839   my $count_arrayref = $count_sth->fetchrow_arrayref;
4840
4841   return ( @$count_arrayref );
4842
4843 }
4844
4845 =item tax_locationnum_sql
4846
4847 Returns an SQL expression for the tax location for a package, based
4848 on the settings of 'tax-pkg_address' and 'tax-ship_address'.
4849
4850 =cut
4851
4852 sub tax_locationnum_sql {
4853   my $conf = FS::Conf->new;
4854   if ( $conf->exists('tax-pkg_address') ) {
4855     'cust_pkg.locationnum';
4856   }
4857   elsif ( $conf->exists('tax-ship_address') ) {
4858     'cust_main.ship_locationnum';
4859   }
4860   else {
4861     'cust_main.bill_locationnum';
4862   }
4863 }
4864
4865 =item location_sql
4866
4867 Returns a list: the first item is an SQL fragment identifying matching
4868 packages/customers via location (taking into account shipping and package
4869 address taxation, if enabled), and subsequent items are the parameters to
4870 substitute for the placeholders in that fragment.
4871
4872 =cut
4873
4874 sub location_sql {
4875   my($class, %opt) = @_;
4876   my $ornull = $opt{'ornull'};
4877
4878   my $conf = new FS::Conf;
4879
4880   # '?' placeholders in _location_sql_where
4881   my $x = $ornull ? 3 : 2;
4882   my @bill_param = (
4883     ('district')x3,
4884     ('city')x3,
4885     ('county')x$x,
4886     ('state')x$x,
4887     'country'
4888   );
4889
4890   my $main_where;
4891   my @main_param;
4892   if ( $conf->exists('tax-ship_address') ) {
4893
4894     $main_where = "(
4895          (     ( ship_last IS NULL     OR  ship_last  = '' )
4896            AND ". _location_sql_where('cust_main', '', $ornull ). "
4897          )
4898       OR (       ship_last IS NOT NULL AND ship_last != ''
4899            AND ". _location_sql_where('cust_main', 'ship_', $ornull ). "
4900          )
4901     )";
4902     #    AND payby != 'COMP'
4903
4904     @main_param = ( @bill_param, @bill_param );
4905
4906   } else {
4907
4908     $main_where = _location_sql_where('cust_main'); # AND payby != 'COMP'
4909     @main_param = @bill_param;
4910
4911   }
4912
4913   my $where;
4914   my @param;
4915   if ( $conf->exists('tax-pkg_address') ) {
4916
4917     my $loc_where = _location_sql_where( 'cust_location', '', $ornull );
4918
4919     $where = " (
4920                     ( cust_pkg.locationnum IS     NULL AND $main_where )
4921                  OR ( cust_pkg.locationnum IS NOT NULL AND $loc_where  )
4922                )
4923              ";
4924     @param = ( @main_param, @bill_param );
4925
4926   } else {
4927
4928     $where = $main_where;
4929     @param = @main_param;
4930
4931   }
4932
4933   ( $where, @param );
4934
4935 }
4936
4937 #subroutine, helper for location_sql
4938 sub _location_sql_where {
4939   my $table  = shift;
4940   my $prefix = @_ ? shift : '';
4941   my $ornull = @_ ? shift : '';
4942
4943 #  $ornull             = $ornull          ? " OR ( ? IS NULL AND $table.${prefix}county IS NULL ) " : '';
4944
4945   $ornull = $ornull ? ' OR ? IS NULL ' : '';
4946
4947   my $or_empty_city     = " OR ( ? = '' AND $table.${prefix}city     IS NULL )";
4948   my $or_empty_county   = " OR ( ? = '' AND $table.${prefix}county   IS NULL )";
4949   my $or_empty_state    = " OR ( ? = '' AND $table.${prefix}state    IS NULL )";
4950
4951   my $text = (driver_name =~ /^mysql/i) ? 'char' : 'text';
4952
4953 #        ( $table.${prefix}city    = ? $or_empty_city   $ornull )
4954   "
4955         ( $table.district = ? OR ? = '' OR CAST(? AS $text) IS NULL )
4956     AND ( $table.${prefix}city     = ? OR ? = '' OR CAST(? AS $text) IS NULL )
4957     AND ( $table.${prefix}county   = ? $or_empty_county $ornull )
4958     AND ( $table.${prefix}state    = ? $or_empty_state  $ornull )
4959     AND   $table.${prefix}country  = ?
4960   ";
4961 }
4962
4963 sub _X_show_zero {
4964   my( $self, $what ) = @_;
4965
4966   my $what_show_zero = $what. '_show_zero';
4967   length($self->$what_show_zero())
4968     ? ($self->$what_show_zero() eq 'Y')
4969     : $self->part_pkg->$what_show_zero();
4970 }
4971
4972 =head1 SUBROUTINES
4973
4974 =over 4
4975
4976 =item order CUSTNUM, PKGPARTS_ARYREF, [ REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF [ REFNUM ] ] ]
4977
4978 Bulk cancel + order subroutine.  Perhaps slightly deprecated, only used by the
4979 bulk cancel+order in the web UI and nowhere else (edit/process/cust_pkg.cgi)
4980
4981 CUSTNUM is a customer (see L<FS::cust_main>)
4982
4983 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
4984 L<FS::part_pkg>) to order for this customer.  Duplicates are of course
4985 permitted.
4986
4987 REMOVE_PKGNUMS is an optional list of pkgnums specifying the billing items to
4988 remove for this customer.  The services (see L<FS::cust_svc>) are moved to the
4989 new billing items.  An error is returned if this is not possible (see
4990 L<FS::pkg_svc>).  An empty arrayref is equivalent to not specifying this
4991 parameter.
4992
4993 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
4994 newly-created cust_pkg objects.
4995
4996 REFNUM, if specified, will specify the FS::pkg_referral record to be created
4997 and inserted.  Multiple FS::pkg_referral records can be created by
4998 setting I<refnum> to an array reference of refnums or a hash reference with
4999 refnums as keys.  If no I<refnum> is defined, a default FS::pkg_referral
5000 record will be created corresponding to cust_main.refnum.
5001
5002 =cut
5003
5004 sub order {
5005   my ($custnum, $pkgparts, $remove_pkgnum, $return_cust_pkg, $refnum) = @_;
5006
5007   my $conf = new FS::Conf;
5008
5009   # Transactionize this whole mess
5010   my $oldAutoCommit = $FS::UID::AutoCommit;
5011   local $FS::UID::AutoCommit = 0;
5012   my $dbh = dbh;
5013
5014   my $error;
5015 #  my $cust_main = qsearchs('cust_main', { custnum => $custnum });
5016 #  return "Customer not found: $custnum" unless $cust_main;
5017
5018   warn "$me order: pkgnums to remove: ". join(',', @$remove_pkgnum). "\n"
5019     if $DEBUG;
5020
5021   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5022                          @$remove_pkgnum;
5023
5024   my $change = scalar(@old_cust_pkg) != 0;
5025
5026   my %hash = ();
5027   if ( scalar(@old_cust_pkg) == 1 && scalar(@$pkgparts) == 1 ) {
5028
5029     warn "$me order: changing pkgnum ". $old_cust_pkg[0]->pkgnum.
5030          " to pkgpart ". $pkgparts->[0]. "\n"
5031       if $DEBUG;
5032
5033     my $err_or_cust_pkg =
5034       $old_cust_pkg[0]->change( 'pkgpart' => $pkgparts->[0],
5035                                 'refnum'  => $refnum,
5036                               );
5037
5038     unless (ref($err_or_cust_pkg)) {
5039       $dbh->rollback if $oldAutoCommit;
5040       return $err_or_cust_pkg;
5041     }
5042
5043     push @$return_cust_pkg, $err_or_cust_pkg;
5044     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5045     return '';
5046
5047   }
5048
5049   # Create the new packages.
5050   foreach my $pkgpart (@$pkgparts) {
5051
5052     warn "$me order: inserting pkgpart $pkgpart\n" if $DEBUG;
5053
5054     my $cust_pkg = new FS::cust_pkg { custnum => $custnum,
5055                                       pkgpart => $pkgpart,
5056                                       refnum  => $refnum,
5057                                       %hash,
5058                                     };
5059     $error = $cust_pkg->insert( 'change' => $change );
5060     push @$return_cust_pkg, $cust_pkg;
5061
5062     foreach my $link ($cust_pkg->part_pkg->supp_part_pkg_link) {
5063       my $supp_pkg = FS::cust_pkg->new({
5064           custnum => $custnum,
5065           pkgpart => $link->dst_pkgpart,
5066           refnum  => $refnum,
5067           main_pkgnum => $cust_pkg->pkgnum,
5068           %hash,
5069       });
5070       $error ||= $supp_pkg->insert( 'change' => $change );
5071       push @$return_cust_pkg, $supp_pkg;
5072     }
5073
5074     if ($error) {
5075       $dbh->rollback if $oldAutoCommit;
5076       return $error;
5077     }
5078
5079   }
5080   # $return_cust_pkg now contains refs to all of the newly
5081   # created packages.
5082
5083   # Transfer services and cancel old packages.
5084   foreach my $old_pkg (@old_cust_pkg) {
5085
5086     warn "$me order: transferring services from pkgnum ". $old_pkg->pkgnum. "\n"
5087       if $DEBUG;
5088
5089     foreach my $new_pkg (@$return_cust_pkg) {
5090       $error = $old_pkg->transfer($new_pkg);
5091       if ($error and $error == 0) {
5092         # $old_pkg->transfer failed.
5093         $dbh->rollback if $oldAutoCommit;
5094         return $error;
5095       }
5096     }
5097
5098     if ( $error > 0 && $conf->exists('cust_pkg-change_svcpart') ) {
5099       warn "trying transfer again with change_svcpart option\n" if $DEBUG;
5100       foreach my $new_pkg (@$return_cust_pkg) {
5101         $error = $old_pkg->transfer($new_pkg, 'change_svcpart'=>1 );
5102         if ($error and $error == 0) {
5103           # $old_pkg->transfer failed.
5104         $dbh->rollback if $oldAutoCommit;
5105         return $error;
5106         }
5107       }
5108     }
5109
5110     if ($error > 0) {
5111       # Transfers were successful, but we went through all of the
5112       # new packages and still had services left on the old package.
5113       # We can't cancel the package under the circumstances, so abort.
5114       $dbh->rollback if $oldAutoCommit;
5115       return "Unable to transfer all services from package ".$old_pkg->pkgnum;
5116     }
5117     $error = $old_pkg->cancel( quiet=>1, 'no_delay_cancel'=>1 );
5118     if ($error) {
5119       $dbh->rollback;
5120       return $error;
5121     }
5122   }
5123   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5124   '';
5125 }
5126
5127 =item bulk_change PKGPARTS_ARYREF, REMOVE_PKGNUMS_ARYREF [ RETURN_CUST_PKG_ARRAYREF ]
5128
5129 A bulk change method to change packages for multiple customers.
5130
5131 PKGPARTS is a list of pkgparts specifying the the billing item definitions (see
5132 L<FS::part_pkg>) to order for each customer.  Duplicates are of course
5133 permitted.
5134
5135 REMOVE_PKGNUMS is an list of pkgnums specifying the billing items to
5136 replace.  The services (see L<FS::cust_svc>) are moved to the
5137 new billing items.  An error is returned if this is not possible (see
5138 L<FS::pkg_svc>).
5139
5140 RETURN_CUST_PKG_ARRAYREF, if specified, will be filled in with the
5141 newly-created cust_pkg objects.
5142
5143 =cut
5144
5145 sub bulk_change {
5146   my ($pkgparts, $remove_pkgnum, $return_cust_pkg) = @_;
5147
5148   # Transactionize this whole mess
5149   my $oldAutoCommit = $FS::UID::AutoCommit;
5150   local $FS::UID::AutoCommit = 0;
5151   my $dbh = dbh;
5152
5153   my @errors;
5154   my @old_cust_pkg = map { qsearchs('cust_pkg', { pkgnum => $_ }) }
5155                          @$remove_pkgnum;
5156
5157   while(scalar(@old_cust_pkg)) {
5158     my @return = ();
5159     my $custnum = $old_cust_pkg[0]->custnum;
5160     my (@remove) = map { $_->pkgnum }
5161                    grep { $_->custnum == $custnum } @old_cust_pkg;
5162     @old_cust_pkg = grep { $_->custnum != $custnum } @old_cust_pkg;
5163
5164     my $error = order $custnum, $pkgparts, \@remove, \@return;
5165
5166     push @errors, $error
5167       if $error;
5168     push @$return_cust_pkg, @return;
5169   }
5170
5171   if (scalar(@errors)) {
5172     $dbh->rollback if $oldAutoCommit;
5173     return join(' / ', @errors);
5174   }
5175
5176   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
5177   '';
5178 }
5179
5180 =item forward_emails
5181
5182 Returns a hash of svcnums and corresponding email addresses
5183 for svc_acct services that can be used as source or dest
5184 for svc_forward services provisioned in this package.
5185
5186 Accepts options I<svc_forward> OR I<svcnum> for a svc_forward
5187 service;  if included, will ensure the current values of the
5188 specified service are included in the list, even if for some
5189 other reason they wouldn't be.  If called as a class method
5190 with a specified service, returns only these current values.
5191
5192 Caution: does not actually check if svc_forward services are
5193 available to be provisioned on this package.
5194
5195 =cut
5196
5197 sub forward_emails {
5198   my $self = shift;
5199   my %opt = @_;
5200
5201   #load optional service, thoroughly validated
5202   die "Use svcnum or svc_forward, not both"
5203     if $opt{'svcnum'} && $opt{'svc_forward'};
5204   my $svc_forward = $opt{'svc_forward'};
5205   $svc_forward ||= qsearchs('svc_forward',{ 'svcnum' => $opt{'svcnum'} })
5206     if $opt{'svcnum'};
5207   die "Specified service is not a forward service"
5208     if $svc_forward && (ref($svc_forward) ne 'FS::svc_forward');
5209   die "Specified service not found"
5210     if ($opt{'svcnum'} || $opt{'svc_forward'}) && !$svc_forward;
5211
5212   my %email;
5213
5214   ## everything below was basically copied from httemplate/edit/svc_forward.cgi
5215   ## with minimal refactoring, not sure why we can't just load all svc_accts for this custnum
5216
5217   #add current values from specified service, if there was one
5218   if ($svc_forward) {
5219     foreach my $method (qw( srcsvc_acct dstsvc_acct )) {
5220       my $svc_acct = $svc_forward->$method();
5221       $email{$svc_acct->svcnum} = $svc_acct->email if $svc_acct;
5222     }
5223   }
5224
5225   if (ref($self) eq 'FS::cust_pkg') {
5226
5227     #and including the rest for this customer
5228     my($u_part_svc,@u_acct_svcparts);
5229     foreach $u_part_svc ( qsearch('part_svc',{'svcdb'=>'svc_acct'}) ) {
5230       push @u_acct_svcparts,$u_part_svc->getfield('svcpart');
5231     }
5232
5233     my $custnum = $self->getfield('custnum');
5234     foreach my $i_cust_pkg ( qsearch('cust_pkg',{'custnum'=>$custnum}) ) {
5235       my $cust_pkgnum = $i_cust_pkg->getfield('pkgnum');
5236       #now find the corresponding record(s) in cust_svc (for this pkgnum!)
5237       foreach my $acct_svcpart (@u_acct_svcparts) {
5238         foreach my $i_cust_svc (
5239           qsearch( 'cust_svc', { 'pkgnum'  => $cust_pkgnum,
5240                                  'svcpart' => $acct_svcpart } )
5241         ) {
5242           my $svc_acct = qsearchs( 'svc_acct', { 'svcnum' => $i_cust_svc->svcnum } );
5243           $email{$svc_acct->svcnum} = $svc_acct->email;
5244         }
5245       }
5246     }
5247   }
5248
5249   return %email;
5250 }
5251
5252 # Used by FS::Upgrade to migrate to a new database.
5253 sub _upgrade_data {  # class method
5254   my ($class, %opts) = @_;
5255   $class->_upgrade_otaker(%opts);
5256   my @statements = (
5257     # RT#10139, bug resulting in contract_end being set when it shouldn't
5258   'UPDATE cust_pkg SET contract_end = NULL WHERE contract_end = -1',
5259     # RT#10830, bad calculation of prorate date near end of year
5260     # the date range for bill is December 2009, and we move it forward
5261     # one year if it's before the previous bill date (which it should
5262     # never be)
5263   'UPDATE cust_pkg SET bill = bill + (365*24*60*60) WHERE bill < last_bill
5264   AND bill > 1259654400 AND bill < 1262332800 AND (SELECT plan FROM part_pkg
5265   WHERE part_pkg.pkgpart = cust_pkg.pkgpart) = \'prorate\'',
5266     # RT6628, add order_date to cust_pkg
5267     'update cust_pkg set order_date = (select history_date from h_cust_pkg
5268         where h_cust_pkg.pkgnum = cust_pkg.pkgnum and
5269         history_action = \'insert\') where order_date is null',
5270   );
5271   foreach my $sql (@statements) {
5272     my $sth = dbh->prepare($sql);
5273     $sth->execute or die $sth->errstr;
5274   }
5275
5276   # RT31194: supplemental package links that are deleted don't clean up
5277   # linked records
5278   my @pkglinknums = qsearch({
5279       'select'    => 'DISTINCT cust_pkg.pkglinknum',
5280       'table'     => 'cust_pkg',
5281       'addl_from' => ' LEFT JOIN part_pkg_link USING (pkglinknum) ',
5282       'extra_sql' => ' WHERE cust_pkg.pkglinknum IS NOT NULL
5283                         AND part_pkg_link.pkglinknum IS NULL',
5284   });
5285   foreach (@pkglinknums) {
5286     my $pkglinknum = $_->pkglinknum;
5287     warn "cleaning part_pkg_link #$pkglinknum\n";
5288     my $part_pkg_link = FS::part_pkg_link->new({pkglinknum => $pkglinknum});
5289     my $error = $part_pkg_link->remove_linked;
5290     die $error if $error;
5291   }
5292 }
5293
5294 =back
5295
5296 =head1 BUGS
5297
5298 sub order is not OO.  Perhaps it should be moved to FS::cust_main and made so?
5299
5300 In sub order, the @pkgparts array (passed by reference) is clobbered.
5301
5302 Also in sub order, no money is adjusted.  Once FS::part_pkg defines a standard
5303 method to pass dates to the recur_prog expression, it should do so.
5304
5305 FS::svc_acct, FS::svc_domain, FS::svc_www, FS::svc_ip and FS::svc_forward are
5306 loaded via 'use' at compile time, rather than via 'require' in sub { setup,
5307 suspend, unsuspend, cancel } because they use %FS::UID::callback to load
5308 configuration values.  Probably need a subroutine which decides what to do
5309 based on whether or not we've fetched the user yet, rather than a hash.  See
5310 FS::UID and the TODO.
5311
5312 Now that things are transactional should the check in the insert method be
5313 moved to check ?
5314
5315 =head1 SEE ALSO
5316
5317 L<FS::Record>, L<FS::cust_main>, L<FS::part_pkg>, L<FS::cust_svc>,
5318 L<FS::pkg_svc>, schema.html from the base documentation
5319
5320 =cut
5321
5322 1;
5323