FS/FS/cust_payby.pm

   1 package FS::cust_payby;
   2 use base qw( FS::payinfo_Mixin FS::cust_main_Mixin FS::Record );
   3
   4 use strict;
   5 use Scalar::Util qw( blessed );
   6 use Digest::SHA qw( sha512_base64 );
   7 use Business::CreditCard qw( validate cardtype );
   8 use FS::UID qw( dbh );
   9 use FS::Msgcat qw( gettext );
  10 use FS::Misc qw( card_types );
  11 use FS::Record; #qw( qsearch qsearchs );
  12 use FS::payby;
  13 use FS::cust_main;
  14 use FS::banned_pay;
  15
  16 our @encrypted_fields = ('payinfo', 'paycvv');
  17 sub nohistory_fields { ('payinfo', 'paycvv'); }
  18
  19 our $ignore_expired_card = 0;
  20 our $ignore_banned_card = 0;
  21 our $ignore_invalid_card = 0;
  22 our $ignore_cardtype = 0;
  23
  24 our $conf;
  25 install_callback FS::UID sub {
  26   $conf = new FS::Conf;
  27   #yes, need it for stuff below (prolly should be cached)
  28   $ignore_invalid_card = $conf->exists('allow_invalid_cards');
  29 };
  30
  31 =head1 NAME
  32
  33 FS::cust_payby - Object methods for cust_payby records
  34
  35 =head1 SYNOPSIS
  36
  37   use FS::cust_payby;
  38
  39   $record = new FS::cust_payby \%hash;
  40   $record = new FS::cust_payby { 'column' => 'value' };
  41
  42   $error = $record->insert;
  43
  44   $error = $new_record->replace($old_record);
  45
  46   $error = $record->delete;
  47
  48   $error = $record->check;
  49
  50 =head1 DESCRIPTION
  51
  52 An FS::cust_payby object represents customer stored payment information.
  53 FS::cust_payby inherits from FS::Record.  The following fields are currently
  54 supported:
  55
  56 =over 4
  57
  58 =item custpaybynum
  59
  60 primary key
  61
  62 =item custnum
  63
  64 custnum
  65
  66 =item weight
  67
  68 weight
  69
  70 =item payby
  71
  72 payby
  73
  74 =item payinfo
  75
  76 payinfo
  77
  78 =item paycvv
  79
  80 paycvv
  81
  82 =item paymask
  83
  84 paymask
  85
  86 =item paydate
  87
  88 paydate
  89
  90 =item paystart_month
  91
  92 paystart_month
  93
  94 =item paystart_year
  95
  96 paystart_year
  97
  98 =item payissue
  99
 100 payissue
 101
 102 =item payname
 103
 104 payname
 105
 106 =item paystate
 107
 108 paystate
 109
 110 =item paytype
 111
 112 paytype
 113
 114 =item payip
 115
 116 payip
 117
 118 =item paycardtype
 119
 120 The credit card type (deduced from the card number).
 121
 122 =back
 123
 124 =head1 METHODS
 125
 126 =over 4
 127
 128 =item new HASHREF
 129
 130 Creates a new record.  To add the record to the database, see L<"insert">.
 131
 132 Note that this stores the hash reference, not a distinct copy of the hash it
 133 points to.  You can ask the object for a copy with the I<hash> method.
 134
 135 =cut
 136
 137 # the new method can be inherited from FS::Record, if a table method is defined
 138
 139 sub table { 'cust_payby'; }
 140
 141 =item insert
 142
 143 Adds this record to the database.  If there is an error, returns the error,
 144 otherwise returns false.
 145
 146 =cut
 147
 148 sub insert {
 149   my $self = shift;
 150
 151   local $SIG{HUP} = 'IGNORE';
 152   local $SIG{INT} = 'IGNORE';
 153   local $SIG{QUIT} = 'IGNORE';
 154   local $SIG{TERM} = 'IGNORE';
 155   local $SIG{TSTP} = 'IGNORE';
 156   local $SIG{PIPE} = 'IGNORE';
 157
 158   my $oldAutoCommit = $FS::UID::AutoCommit;
 159   local $FS::UID::AutoCommit = 0;
 160   my $dbh = dbh;
 161
 162   my $error =  $self->check_payinfo_cardtype
 163             || $self->SUPER::insert;
 164   if ( $error ) {
 165     $dbh->rollback if $oldAutoCommit;
 166     return $error;
 167   }
 168
 169   if ( $self->payby =~ /^(CARD|CHEK)$/ ) {
 170     # new auto card/check info, want to retry realtime_ invoice events
 171     #  (new customer?  that's okay, they won't have any)
 172     my $error = $self->cust_main->retry_realtime;
 173     if ( $error ) {
 174       $dbh->rollback if $oldAutoCommit;
 175       return $error;
 176     }
 177   }
 178
 179   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 180   '';
 181
 182 }
 183
 184 =item delete
 185
 186 Delete this record from the database.
 187
 188 =item replace OLD_RECORD
 189
 190 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 191 returns the error, otherwise returns false.
 192
 193 =cut
 194
 195 sub replace {
 196   my $self = shift;
 197
 198   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 199               ? shift
 200               : $self->replace_old;
 201
 202   if ( $self->payby =~ /^(CARD|DCRD)$/
 203        && (    $self->payinfo =~ /xx/
 204             || $self->payinfo =~ /^\s*N\/A\s+\(tokenized\)\s*$/
 205           )
 206      )
 207   {
 208
 209     $self->payinfo($old->payinfo);
 210
 211   } elsif ( $self->payby =~ /^(CHEK|DCHK)$/ && $self->payinfo =~ /xx/ ) {
 212     #fix for #3085 "edit of customer's routing code only surprisingly causes
 213     #nothing to happen...
 214     # this probably won't do the right thing when we don't have the
 215     # public key (can't actually get the real $old->payinfo)
 216     my($new_account, $new_aba) = split('@', $self->payinfo);
 217     my($old_account, $old_aba) = split('@', $old->payinfo);
 218     $new_account = $old_account if $new_account =~ /xx/;
 219     $new_aba     = $old_aba     if $new_aba     =~ /xx/;
 220     $self->payinfo($new_account.'@'.$new_aba);
 221   }
 222
 223   # only unmask paycvv if payinfo stayed the same
 224   if ( $self->payby =~ /^(CARD|DCRD)$/ and $self->paycvv =~ /^\s*[\*x]+\s*$/ ) {
 225     if ( $old->payinfo eq $self->payinfo
 226          && $old->paymask eq $self->paymask
 227     ) {
 228       $self->paycvv($old->paycvv);
 229     } else {
 230       $self->paycvv('');
 231     }
 232   }
 233
 234   local($ignore_expired_card) = 1
 235     if $old->payby  =~ /^(CARD|DCRD)$/
 236     && $self->payby =~ /^(CARD|DCRD)$/
 237     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
 238
 239   local($ignore_banned_card) = 1
 240     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
 241          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
 242     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
 243
 244   if (    $self->payby =~ /^(CARD|DCRD)$/
 245        && $old->payinfo ne $self->payinfo
 246        && $old->paymask ne $self->paymask )
 247   {
 248     my $error = $self->check_payinfo_cardtype;
 249     return $error if $error;
 250
 251     if ( $conf->exists('business-onlinepayment-verification') ) {
 252       $error = $self->verify;
 253     } else {
 254       $error = $self->tokenize;
 255     }
 256     return $error if $error;
 257
 258   }
 259
 260   local $SIG{HUP} = 'IGNORE';
 261   local $SIG{INT} = 'IGNORE';
 262   local $SIG{QUIT} = 'IGNORE';
 263   local $SIG{TERM} = 'IGNORE';
 264   local $SIG{TSTP} = 'IGNORE';
 265   local $SIG{PIPE} = 'IGNORE';
 266
 267   my $oldAutoCommit = $FS::UID::AutoCommit;
 268   local $FS::UID::AutoCommit = 0;
 269   my $dbh = dbh;
 270
 271   my $error = $self->SUPER::replace($old);
 272   if ( $error ) {
 273     $dbh->rollback if $oldAutoCommit;
 274     return $error;
 275   }
 276
 277   if ( $self->payby =~ /^(CARD|CHEK)$/
 278        && ( ( $self->get('payinfo') ne $old->get('payinfo')
 279               && !$self->tokenized
 280             )
 281             || grep { $self->get($_) ne $old->get($_) } qw(paydate payname)
 282           )
 283      )
 284   {
 285
 286     # card/check/lec info has changed, want to retry realtime_ invoice events
 287     my $error = $self->cust_main->retry_realtime;
 288     if ( $error ) {
 289       $dbh->rollback if $oldAutoCommit;
 290       return $error;
 291     }
 292   }
 293
 294   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 295   '';
 296
 297 }
 298
 299 =item check
 300
 301 Checks all fields to make sure this is a valid record.  If there is
 302 an error, returns the error, otherwise returns false.  Called by the insert
 303 and replace methods.
 304
 305 =cut
 306
 307 sub check {
 308   my $self = shift;
 309
 310   my $error =
 311     $self->ut_numbern('custpaybynum')
 312     || $self->ut_foreign_key('custnum', 'cust_main', 'custnum')
 313     || $self->ut_numbern('weight')
 314     #encrypted #|| $self->ut_textn('payinfo')
 315     #encrypted #|| $self->ut_textn('paycvv')
 316 #    || $self->ut_textn('paymask') #XXX something
 317     #later #|| $self->ut_textn('paydate')
 318     || $self->ut_numbern('paystart_month')
 319     || $self->ut_numbern('paystart_year')
 320     || $self->ut_numbern('payissue')
 321 #    || $self->ut_textn('payname') #XXX something
 322     || $self->ut_alphan('paystate')
 323     || $self->ut_textn('paytype')
 324     || $self->ut_ipn('payip')
 325   ;
 326   return $error if $error;
 327
 328   ### from cust_main
 329
 330   FS::payby->can_payby($self->table, $self->payby)
 331     or return "Illegal payby: ". $self->payby;
 332
 333   # If it is encrypted and the private key is not availaible then we can't
 334   # check the credit card.
 335   my $check_payinfo = ! $self->is_encrypted($self->payinfo);
 336
 337   # Need some kind of global flag to accept invalid cards, for testing
 338   # on scrubbed data.
 339   #XXX if ( !$import && $check_payinfo && $self->payby =~ /^(CARD|DCRD)$/ ) {
 340
 341   # In this block: detect card type; reject credit card / account numbers that
 342   # are impossible or banned; reject other payment features (date, CVV length)
 343   # that are inappropriate for the card type.
 344   # However, if the payinfo is encrypted then just detect card type and assume
 345   # the other checks were already done.
 346
 347   if ( !$ignore_invalid_card &&
 348     $check_payinfo && $self->payby =~ /^(CARD|DCRD)$/ ) {
 349
 350     my $payinfo = $self->payinfo;
 351     $payinfo =~ s/\D//g;
 352     $payinfo =~ /^(\d{13,16}|\d{8,9})$/
 353       or return gettext('invalid_card'); #. ": ". $self->payinfo;
 354     $payinfo = $1;
 355     $self->payinfo($payinfo);
 356     validate($payinfo)
 357       or return gettext('invalid_card'); # . ": ". $self->payinfo;
 358
 359     # see parallel checks in check_payinfo_cardtype & payinfo_Mixin::payinfo_check
 360     my $cardtype = $self->paycardtype;
 361     if ( $self->tokenized ) {
 362       $self->('is_tokenized', 'Y'); #so we don't try to do it again
 363       if ( $self->paymask =~ /^\d+x/ ) {
 364         $cardtype = cardtype($self->paymask);
 365       } else {
 366         #return "paycardtype required ".
 367         #       "(can't derive from a token and no paymask w/prefix provided)"
 368         #  unless $cardtype;
 369       }
 370     } else {
 371       $cardtype = cardtype($self->payinfo);
 372     }
 373
 374     return gettext('unknown_card_type') if $cardtype eq "Unknown";
 375
 376     $self->set('paycardtype', $cardtype);
 377
 378     unless ( $ignore_banned_card ) {
 379       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
 380       if ( $ban ) {
 381         if ( $ban->bantype eq 'warn' ) {
 382           #or others depending on value of $ban->reason ?
 383           return '_duplicate_card'.
 384                  ': disabled from'. time2str('%a %h %o at %r', $ban->_date).
 385                  ' until '.         time2str('%a %h %o at %r', $ban->_end_date).
 386                  ' (ban# '. $ban->bannum. ')'
 387             unless $self->override_ban_warn;
 388         } else {
 389           return 'Banned credit card: banned on '.
 390                  time2str('%a %h %o at %r', $ban->_date).
 391                  ' by '. $ban->otaker.
 392                  ' (ban# '. $ban->bannum. ')';
 393         }
 394       }
 395     }
 396
 397     if (length($self->paycvv) && !$self->is_encrypted($self->paycvv)) {
 398       if ( $cardtype eq 'American Express card' ) {
 399         $self->paycvv =~ /^(\d{4})$/
 400           or return "CVV2 (CID) for American Express cards is four digits.";
 401         $self->paycvv($1);
 402       } else {
 403         $self->paycvv =~ /^(\d{3})$/
 404           or return "CVV2 (CVC2/CID) is three digits.";
 405         $self->paycvv($1);
 406       }
 407     } else {
 408       $self->paycvv('');
 409     }
 410
 411     if ( $cardtype =~ /^(Switch|Solo)$/i ) {
 412
 413       return "Start date or issue number is required for $cardtype cards"
 414         unless $self->paystart_month && $self->paystart_year or $self->payissue;
 415
 416       return "Start month must be between 1 and 12"
 417         if $self->paystart_month
 418            and $self->paystart_month < 1 || $self->paystart_month > 12;
 419
 420       return "Start year must be 1990 or later"
 421         if $self->paystart_year
 422            and $self->paystart_year < 1990;
 423
 424       return "Issue number must be beween 1 and 99"
 425         if $self->payissue
 426           and $self->payissue < 1 || $self->payissue > 99;
 427
 428     } else {
 429       $self->paystart_month('');
 430       $self->paystart_year('');
 431       $self->payissue('');
 432     }
 433
 434   } elsif ( !$ignore_invalid_card &&
 435     $check_payinfo && $self->payby =~ /^(CHEK|DCHK)$/ ) {
 436
 437     my $payinfo = $self->payinfo;
 438     $payinfo =~ s/[^\d\@\.]//g;
 439     if ( $conf->config('echeck-country') eq 'CA' ) {
 440       $payinfo =~ /^(\d+)\@(\d{5})\.(\d{3})$/
 441         or return 'invalid echeck account@branch.bank';
 442       $payinfo = "$1\@$2.$3";
 443     } elsif ( $conf->config('echeck-country') eq 'US' ) {
 444       $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
 445       $payinfo = "$1\@$2";
 446     } else {
 447       $payinfo =~ /^(\d+)\@(\d+)$/ or return 'invalid echeck account@routing';
 448       $payinfo = "$1\@$2";
 449     }
 450     $self->payinfo($payinfo);
 451     $self->paycvv('');
 452
 453     unless ( $ignore_banned_card ) {
 454       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
 455       if ( $ban ) {
 456         if ( $ban->bantype eq 'warn' ) {
 457           #or others depending on value of $ban->reason ?
 458           return '_duplicate_ach' unless $self->override_ban_warn;
 459         } else {
 460           return 'Banned ACH account: banned on '.
 461                  time2str('%a %h %o at %r', $ban->_date).
 462                  ' by '. $ban->otaker.
 463                  ' (ban# '. $ban->bannum. ')';
 464         }
 465       }
 466     }
 467
 468   } elsif ( $self->payby =~ /^CARD|DCRD$/ and $self->paymask ) {
 469     # either ignoring invalid cards, or we can't decrypt the payinfo, but
 470     # try to detect the card type anyway. this never returns failure, so
 471     # the contract of $ignore_invalid_cards is maintained.
 472     $self->set('paycardtype', cardtype($self->paymask));
 473   } else {
 474     $self->set('paycardtype', '');
 475   }
 476
 477 #  } elsif ( $self->payby eq 'PREPAY' ) {
 478 #
 479 #    my $payinfo = $self->payinfo;
 480 #    $payinfo =~ s/\W//g; #anything else would just confuse things
 481 #    $self->payinfo($payinfo);
 482 #    $error = $self->ut_alpha('payinfo');
 483 #    return "Illegal prepayment identifier: ". $self->payinfo if $error;
 484 #    return "Unknown prepayment identifier"
 485 #      unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
 486 #    $self->paycvv('');
 487
 488   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
 489
 490     $self->paydate('');
 491
 492   } elsif ( $self->payby =~ /^(CARD|DCRD)$/ ) {
 493
 494     # shouldn't payinfo_check do this?
 495     # (except we don't ever call payinfo_check from here)
 496     return "Expiration date required"
 497       if $self->paydate eq '' || $self->paydate eq '-';
 498
 499     my( $m, $y );
 500     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
 501       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
 502     } elsif ( $self->paydate =~ /^19(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
 503       ( $m, $y ) = ( $2, "19$1" );
 504     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
 505       ( $m, $y ) = ( $3, "20$2" );
 506     } else {
 507       return "Illegal expiration date: ". $self->paydate;
 508     }
 509     $m = sprintf('%02d',$m);
 510     $self->paydate("$y-$m-01");
 511     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
 512     return gettext('expired_card')
 513       if #XXX !$import
 514       #&&
 515          !$ignore_expired_card
 516       && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
 517
 518   }
 519
 520   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
 521        ( ! $conf->exists('require_cardname')
 522          || $self->payby !~ /^(CARD|DCRD)$/  )
 523   ) {
 524     $self->payname( $self->first. " ". $self->getfield('last') );
 525   } else {
 526
 527     if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
 528       $self->payname =~ /^([\w \,\.\-\']*)$/
 529         or return gettext('illegal_name'). " payname: ". $self->payname;
 530       $self->payname($1);
 531     } else {
 532       $self->payname =~ /^([\w \,\.\-\'\&]*)$/
 533         or return gettext('illegal_name'). " payname: ". $self->payname;
 534       $self->payname($1);
 535     }
 536
 537   }
 538
 539   if ( ! $self->custpaybynum ) {
 540     if ($conf->exists('business-onlinepayment-verification')) {
 541       $error = $self->verify;
 542     } else {
 543       $error = $self->tokenize;
 544     }
 545     return $error if $error;
 546   }
 547
 548   $self->SUPER::check;
 549 }
 550
 551 sub check_payinfo_cardtype {
 552   my $self = shift;
 553
 554   return '' if $ignore_cardtype;
 555
 556   return '' unless $self->payby =~ /^(CARD|CHEK)$/;
 557
 558   my $payinfo = $self->payinfo;
 559   $payinfo =~ s/\D//g;
 560
 561   # see parallel checks in cust_payby::check & payinfo_Mixin::payinfo_check
 562   if ( $self->tokenized($payinfo) ) {
 563     $self->set('is_tokenized', 'Y'); #so we don't try to do it again
 564     if ( $self->paymask =~ /^\d+x/ ) {
 565       $self->set('paycardtype', cardtype($self->paymask));
 566     } else {
 567       $self->set('paycardtype', '');
 568       #return "paycardtype required ".
 569       #       "(can't derive from a token and no paymask w/prefix provided)";
 570     }
 571     return '';
 572   }
 573
 574   my %bop_card_types = map { $_=>1 } values %{ card_types() };
 575   my $cardtype = cardtype($payinfo);
 576   $self->set('paycardtype', $cardtype);
 577
 578   return "$cardtype not accepted" unless $bop_card_types{$cardtype};
 579
 580   '';
 581
 582 }
 583
 584 sub _banned_pay_hashref {
 585   my $self = shift;
 586
 587   my %payby2ban = (
 588     'CARD' => 'CARD',
 589     'DCRD' => 'CARD',
 590     'CHEK' => 'CHEK',
 591     'DCHK' => 'CHEK'
 592   );
 593
 594   {
 595     'payby'   => $payby2ban{$self->payby},
 596     'payinfo' => $self->payinfo,
 597     #don't ever *search* on reason! #'reason'  =>
 598   };
 599 }
 600
 601 sub _new_banned_pay_hashref {
 602   my $self = shift;
 603   my $hr = $self->_banned_pay_hashref;
 604   $hr->{payinfo_hash} = 'SHA512';
 605   $hr->{payinfo} = sha512_base64($hr->{payinfo});
 606   $hr;
 607 }
 608
 609 =item paydate_mon_year
 610
 611 Returns a two element list consisting of the paydate month and year.
 612
 613 =cut
 614
 615 sub paydate_mon_year {
 616   my $self = shift;
 617
 618   my $date = $self->paydate; # || '12-2037';
 619
 620   #false laziness w/elements/select-month_year.html
 621   if ( $date  =~ /^(\d{4})-(\d{1,2})-\d{1,2}$/ ) { #PostgreSQL date format
 622     ( $2, $1 );
 623   } elsif ( $date =~ /^(\d{1,2})-(\d{1,2}-)?(\d{4}$)/ ) {
 624     ( $1, $3 );
 625   } else {
 626     warn "unrecognized expiration date format: $date";
 627     ( '', '' );
 628   }
 629
 630 }
 631
 632 =item label
 633
 634 Returns a one line text label for this payment type.
 635
 636 =cut
 637
 638 my %weight = (
 639   1 => 'Primary',
 640   2 => 'Secondary',
 641   3 => 'Tertiary',
 642   4 => 'Fourth',
 643   5 => 'Fifth',
 644   6 => 'Sixth',
 645   7 => 'Seventh',
 646 );
 647
 648 sub label {
 649   my $self = shift;
 650
 651   my $name = $self->payby =~ /^(CARD|DCRD)$/
 652               && $self->paycardtype || FS::payby->shortname($self->payby);
 653
 654   ( $self->payby =~ /^(CARD|CHEK)$/  ? $weight{$self->weight}. ' automatic '
 655                                      : 'Manual '
 656   ).
 657   "$name: ". $self->paymask.
 658   ( $self->payby =~ /^(CARD|DCRD)$/
 659       ? ' Exp '. join('/', $self->paydate_mon_year)
 660       : ''
 661   );
 662
 663 }
 664
 665 =item realtime_bop
 666
 667 Runs a L<realtime_bop|FS::cust_main::Billing_Realtime::realtime_bop> transaction on this card
 668
 669 =cut
 670
 671 sub realtime_bop {
 672   my( $self, %opt ) = @_;
 673
 674   $self->cust_main->realtime_bop({
 675     %opt,
 676     'cust_payby' => $self,
 677   });
 678
 679 }
 680
 681 =item tokenize
 682
 683 Runs a L<realtime_tokenize|FS::cust_main::Billing_Realtime::realtime_tokenize> transaction on this card
 684
 685 =cut
 686
 687 sub tokenize {
 688   my $self = shift;
 689   return '' unless $self->payby =~ /^(CARD|DCRD)$/;
 690
 691   $self->cust_main->realtime_tokenize({
 692     'cust_payby' => $self,
 693   });
 694
 695 }
 696
 697 =item verify
 698
 699 Runs a L<realtime_verify_bop|FS::cust_main::Billing_Realtime/realtime_verify_bop> transaction on this card
 700
 701 =cut
 702
 703 sub verify {
 704   my $self = shift;
 705   return '' unless $self->payby =~ /^(CARD|DCRD)$/;
 706
 707   $self->cust_main->realtime_verify_bop({
 708     'cust_payby' => $self,
 709   });
 710
 711 }
 712
 713 =item paytypes
 714
 715 Returns a list of valid values for the paytype field (bank account type for
 716 electronic check payment).
 717
 718 =cut
 719
 720 sub paytypes {
 721   #my $class = shift;
 722
 723   ('', 'Personal checking', 'Personal savings', 'Business checking', 'Business savings');
 724 }
 725
 726 =item cgi_cust_payby_fields
 727
 728 Returns the field names used in the web interface (including some pseudo-fields).
 729
 730 =cut
 731
 732 sub cgi_cust_payby_fields {
 733   #my $class = shift;
 734   [qw( payby payinfo paydate_month paydate_year paycvv payname weight
 735        payinfo1 payinfo2 payinfo3 paytype paystate payname_CHEK )];
 736 }
 737
 738 =item cgi_hash_callback HASHREF OLD
 739
 740 Subroutine (not a class or object method).  Processes a hash reference
 741 of web interface contet (transfers the data from pseudo-fields to real fields).
 742
 743 If OLD object is passed, also preserves locationnum, paystart_month, paystart_year,
 744 payissue and payip.  If the new field is blank but the old is not, the old field
 745 will be preserved.
 746
 747 =cut
 748
 749 sub cgi_hash_callback {
 750   my $hashref = shift;
 751   my $old = shift;
 752
 753   my %noauto = (
 754     'CARD' => 'DCRD',
 755     'CHEK' => 'DCHK',
 756   );
 757   # the payby selector gives the choice of CARD or CHEK (or others, but
 758   # those are the ones with auto and on-demand versions). if the user didn't
 759   # choose a weight, then they mean DCRD/DCHK.
 760   $hashref->{payby} = $noauto{$hashref->{payby}}
 761     if ! $hashref->{weight} && exists $noauto{$hashref->{payby}};
 762
 763   if ( $hashref->{payby} =~ /^(CHEK|DCHK)$/ ) {
 764
 765     unless ( grep $hashref->{$_}, qw(payinfo1 payinfo2 payinfo3 payname_CHEK)) {
 766       %$hashref = ();
 767       return;
 768     }
 769
 770     $hashref->{payinfo} = $hashref->{payinfo1}. '@';
 771     $hashref->{payinfo} .= $hashref->{payinfo3}.'.'
 772       if $conf->config('echeck-country') eq 'CA';
 773     $hashref->{payinfo} .= $hashref->{'payinfo2'};
 774
 775     $hashref->{payname} = $hashref->{'payname_CHEK'};
 776
 777   } elsif ( $hashref->{payby} =~ /^(CARD|DCRD)$/ ) {
 778
 779     unless ( grep $hashref->{$_}, qw( payinfo paycvv payname ) ) {
 780       %$hashref = ();
 781       return;
 782     }
 783
 784   }
 785
 786   $hashref->{paydate}= $hashref->{paydate_month}. '-'. $hashref->{paydate_year};
 787
 788   if ($old) {
 789     foreach my $field ( qw(locationnum paystart_month paystart_year payissue payip) ) {
 790       next if $hashref->{$field};
 791       next unless $old->get($field);
 792       $hashref->{$field} = $old->get($field);
 793     }
 794   }
 795
 796 }
 797
 798 =item search_sql
 799
 800 Class method.
 801
 802 Returns a qsearch hash expression to search for parameters specified in HASHREF.
 803 Valid paramters are:
 804
 805 =over 4
 806
 807 =item payby
 808
 809 listref
 810
 811 =item paydate_year
 812
 813 =item paydate_month
 814
 815
 816 =back
 817
 818 =cut
 819
 820 sub search_sql {
 821   my ($class, $params) = @_;
 822
 823   my @where = ();
 824   my $orderby;
 825
 826   # initialize these to prevent warnings
 827   $params = {
 828     'paydate_year'  => '',
 829     %$params
 830   };
 831
 832   ###
 833   # payby
 834   ###
 835
 836   if ( $params->{'payby'} ) {
 837
 838     my @payby = ref( $params->{'payby'} )
 839                   ? @{ $params->{'payby'} }
 840                   :  ( $params->{'payby'} );
 841
 842     @payby = grep /^([A-Z]{4})$/, @payby;
 843     my $in_payby = 'IN(' . join(',', map {"'$_'"} @payby) . ')';
 844     push @where, "cust_payby.payby $in_payby"
 845       if @payby;
 846   }
 847
 848   ###
 849   # paydate_year / paydate_month
 850   ###
 851
 852   if ( $params->{'paydate_year'} =~ /^(\d{4})$/ ) {
 853     my $year = $1;
 854     $params->{'paydate_month'} =~ /^(\d\d?)$/
 855       or die "paydate_year without paydate_month?";
 856     my $month = $1;
 857
 858     push @where,
 859       'cust_payby.paydate IS NOT NULL',
 860       "cust_payby.paydate != ''",
 861       "CAST(cust_payby.paydate AS timestamp) < CAST('$year-$month-01' AS timestamp )"
 862 ;
 863   }
 864   ##
 865   # setup queries, subs, etc. for the search
 866   ##
 867
 868   $orderby ||= 'ORDER BY custnum';
 869
 870   # here is the agent virtualization
 871   push @where,
 872     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
 873
 874   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
 875
 876   my $addl_from = ' LEFT JOIN cust_main USING ( custnum ) ';
 877   # always make address fields available in results
 878   for my $pre ('bill_', 'ship_') {
 879     $addl_from .=
 880       ' LEFT JOIN cust_location AS '.$pre.'location '.
 881       'ON (cust_main.'.$pre.'locationnum = '.$pre.'location.locationnum) ';
 882   }
 883   # always make referral available in results
 884   #   (maybe we should be using FS::UI::Web::join_cust_main instead?)
 885   $addl_from .= ' LEFT JOIN (select refnum, referral from part_referral) AS part_referral_x ON (cust_main.refnum = part_referral_x.refnum) ';
 886
 887   my $count_query = "SELECT COUNT(*) FROM cust_payby $addl_from $extra_sql";
 888
 889   my @select = ( 'cust_payby.*',
 890                  #'cust_main.custnum',
 891                  # there's a good chance that we'll need these
 892                  'cust_main.bill_locationnum',
 893                  'cust_main.ship_locationnum',
 894                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
 895                );
 896
 897   my $select = join(', ', @select);
 898
 899   my $sql_query = {
 900     'table'         => 'cust_payby',
 901     'select'        => $select,
 902     'addl_from'     => $addl_from,
 903     'hashref'       => {},
 904     'extra_sql'     => $extra_sql,
 905     'order_by'      => $orderby,
 906     'count_query'   => $count_query,
 907   };
 908   $sql_query;
 909
 910 }
 911
 912 =back
 913
 914 =cut
 915
 916 sub _upgrade_data {
 917
 918   my $class = shift;
 919   local $ignore_banned_card = 1;
 920   local $ignore_expired_card = 1;
 921   local $ignore_invalid_card = 1;
 922   $class->upgrade_set_cardtype;
 923
 924 }
 925
 926 =head1 BUGS
 927
 928 =head1 SEE ALSO
 929
 930 L<FS::Record>, schema.html from the base documentation.
 931
 932 =cut
 933
 934 1;
 935