FS/FS/cust_payby.pm

   1 package FS::cust_payby;
   2 use base qw( FS::payinfo_Mixin FS::cust_main_Mixin FS::Record );
   3
   4 use strict;
   5 use Scalar::Util qw( blessed );
   6 use Digest::SHA qw( sha512_base64 );
   7 use Business::CreditCard qw( validate cardtype );
   8 use FS::UID qw( dbh );
   9 use FS::Msgcat qw( gettext );
  10 use FS::Misc qw( card_types );
  11 use FS::Record; #qw( qsearch qsearchs );
  12 use FS::payby;
  13 use FS::cust_main;
  14 use FS::banned_pay;
  15
  16 our @encrypted_fields = ('payinfo', 'paycvv');
  17 sub nohistory_fields { ('payinfo', 'paycvv'); }
  18
  19 our $ignore_expired_card = 0;
  20 our $ignore_banned_card = 0;
  21 our $ignore_invalid_card = 0;
  22 our $ignore_cardtype = 0;
  23
  24 our $conf;
  25 install_callback FS::UID sub {
  26   $conf = new FS::Conf;
  27   #yes, need it for stuff below (prolly should be cached)
  28   $ignore_invalid_card = $conf->exists('allow_invalid_cards');
  29 };
  30
  31 =head1 NAME
  32
  33 FS::cust_payby - Object methods for cust_payby records
  34
  35 =head1 SYNOPSIS
  36
  37   use FS::cust_payby;
  38
  39   $record = new FS::cust_payby \%hash;
  40   $record = new FS::cust_payby { 'column' => 'value' };
  41
  42   $error = $record->insert;
  43
  44   $error = $new_record->replace($old_record);
  45
  46   $error = $record->delete;
  47
  48   $error = $record->check;
  49
  50 =head1 DESCRIPTION
  51
  52 An FS::cust_payby object represents customer stored payment information.
  53 FS::cust_payby inherits from FS::Record.  The following fields are currently
  54 supported:
  55
  56 =over 4
  57
  58 =item custpaybynum
  59
  60 primary key
  61
  62 =item custnum
  63
  64 custnum
  65
  66 =item weight
  67
  68 weight
  69
  70 =item payby
  71
  72 payby
  73
  74 =item payinfo
  75
  76 payinfo
  77
  78 =item paycvv
  79
  80 paycvv
  81
  82 =item paymask
  83
  84 paymask
  85
  86 =item paydate
  87
  88 paydate
  89
  90 =item paystart_month
  91
  92 paystart_month
  93
  94 =item paystart_year
  95
  96 paystart_year
  97
  98 =item payissue
  99
 100 payissue
 101
 102 =item payname
 103
 104 payname
 105
 106 =item paystate
 107
 108 paystate
 109
 110 =item paytype
 111
 112 paytype
 113
 114 =item payip
 115
 116 payip
 117
 118 =item paycardtype
 119
 120 The credit card type (deduced from the card number).
 121
 122 =back
 123
 124 =head1 METHODS
 125
 126 =over 4
 127
 128 =item new HASHREF
 129
 130 Creates a new record.  To add the record to the database, see L<"insert">.
 131
 132 Note that this stores the hash reference, not a distinct copy of the hash it
 133 points to.  You can ask the object for a copy with the I<hash> method.
 134
 135 =cut
 136
 137 # the new method can be inherited from FS::Record, if a table method is defined
 138
 139 sub table { 'cust_payby'; }
 140
 141 =item insert
 142
 143 Adds this record to the database.  If there is an error, returns the error,
 144 otherwise returns false.
 145
 146 =cut
 147
 148 sub insert {
 149   my $self = shift;
 150
 151   local $SIG{HUP} = 'IGNORE';
 152   local $SIG{INT} = 'IGNORE';
 153   local $SIG{QUIT} = 'IGNORE';
 154   local $SIG{TERM} = 'IGNORE';
 155   local $SIG{TSTP} = 'IGNORE';
 156   local $SIG{PIPE} = 'IGNORE';
 157
 158   my $oldAutoCommit = $FS::UID::AutoCommit;
 159   local $FS::UID::AutoCommit = 0;
 160   my $dbh = dbh;
 161
 162   my $error =  $self->check_payinfo_cardtype
 163             || $self->SUPER::insert;
 164   if ( $error ) {
 165     $dbh->rollback if $oldAutoCommit;
 166     return $error;
 167   }
 168
 169   if ( $self->payby =~ /^(CARD|CHEK)$/ ) {
 170     # new auto card/check info, want to retry realtime_ invoice events
 171     #  (new customer?  that's okay, they won't have any)
 172     my $error = $self->cust_main->retry_realtime;
 173     if ( $error ) {
 174       $dbh->rollback if $oldAutoCommit;
 175       return $error;
 176     }
 177   }
 178
 179   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 180   '';
 181
 182 }
 183
 184 =item delete
 185
 186 Delete this record from the database.
 187
 188 =item replace OLD_RECORD
 189
 190 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 191 returns the error, otherwise returns false.
 192
 193 =cut
 194
 195 sub replace {
 196   my $self = shift;
 197
 198   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 199               ? shift
 200               : $self->replace_old;
 201
 202   if ( $self->payby =~ /^(CARD|DCRD)$/
 203        && (    $self->payinfo =~ /xx/
 204             || $self->payinfo =~ /^\s*N\/A\s+\(tokenized\)\s*$/
 205           )
 206      )
 207   {
 208
 209     $self->payinfo($old->payinfo);
 210
 211   } elsif ( $self->payby =~ /^(CHEK|DCHK)$/ && $self->payinfo =~ /xx/ ) {
 212     #fix for #3085 "edit of customer's routing code only surprisingly causes
 213     #nothing to happen...
 214     # this probably won't do the right thing when we don't have the
 215     # public key (can't actually get the real $old->payinfo)
 216     my($new_account, $new_aba) = split('@', $self->payinfo);
 217     my($old_account, $old_aba) = split('@', $old->payinfo);
 218     $new_account = $old_account if $new_account =~ /xx/;
 219     $new_aba     = $old_aba     if $new_aba     =~ /xx/;
 220     $self->payinfo($new_account.'@'.$new_aba);
 221   }
 222
 223   # only unmask paycvv if payinfo stayed the same
 224   if ( $self->payby =~ /^(CARD|DCRD)$/ and $self->paycvv =~ /^\s*[\*x]+\s*$/ ) {
 225     if ( $old->payinfo eq $self->payinfo
 226          && $old->paymask eq $self->paymask
 227     ) {
 228       $self->paycvv($old->paycvv);
 229     } else {
 230       $self->paycvv('');
 231     }
 232   }
 233
 234   local($ignore_expired_card) = 1
 235     if $old->payby  =~ /^(CARD|DCRD)$/
 236     && $self->payby =~ /^(CARD|DCRD)$/
 237     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
 238
 239   local($ignore_banned_card) = 1
 240     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
 241          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
 242     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
 243
 244   if (    $self->payby =~ /^(CARD|DCRD)$/
 245        && $old->payinfo ne $self->payinfo
 246        && $old->paymask ne $self->paymask )
 247   {
 248     my $error = $self->check_payinfo_cardtype;
 249     return $error if $error;
 250
 251     if ( $conf->exists('business-onlinepayment-verification') ) {
 252       $error = $self->verify;
 253     } else {
 254       $error = $self->tokenize;
 255     }
 256     return $error if $error;
 257
 258   }
 259
 260   local $SIG{HUP} = 'IGNORE';
 261   local $SIG{INT} = 'IGNORE';
 262   local $SIG{QUIT} = 'IGNORE';
 263   local $SIG{TERM} = 'IGNORE';
 264   local $SIG{TSTP} = 'IGNORE';
 265   local $SIG{PIPE} = 'IGNORE';
 266
 267   my $oldAutoCommit = $FS::UID::AutoCommit;
 268   local $FS::UID::AutoCommit = 0;
 269   my $dbh = dbh;
 270
 271   my $error = $self->SUPER::replace($old);
 272   if ( $error ) {
 273     $dbh->rollback if $oldAutoCommit;
 274     return $error;
 275   }
 276
 277   if ( $self->payby =~ /^(CARD|CHEK)$/
 278        && ( ( $self->get('payinfo') ne $old->get('payinfo')
 279               && !$self->tokenized
 280             )
 281             || grep { $self->get($_) ne $old->get($_) } qw(paydate payname)
 282           )
 283      )
 284   {
 285
 286     # card/check/lec info has changed, want to retry realtime_ invoice events
 287     my $error = $self->cust_main->retry_realtime;
 288     if ( $error ) {
 289       $dbh->rollback if $oldAutoCommit;
 290       return $error;
 291     }
 292   }
 293
 294   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 295   '';
 296
 297 }
 298
 299 =item check
 300
 301 Checks all fields to make sure this is a valid record.  If there is
 302 an error, returns the error, otherwise returns false.  Called by the insert
 303 and replace methods.
 304
 305 =cut
 306
 307 sub check {
 308   my $self = shift;
 309
 310   my $error =
 311     $self->ut_numbern('custpaybynum')
 312     || $self->ut_foreign_key('custnum', 'cust_main', 'custnum')
 313     || $self->ut_numbern('weight')
 314     #encrypted #|| $self->ut_textn('payinfo')
 315     #encrypted #|| $self->ut_textn('paycvv')
 316 #    || $self->ut_textn('paymask') #XXX something
 317     #later #|| $self->ut_textn('paydate')
 318     || $self->ut_numbern('paystart_month')
 319     || $self->ut_numbern('paystart_year')
 320     || $self->ut_numbern('payissue')
 321 #    || $self->ut_textn('payname') #XXX something
 322     || $self->ut_alphan('paystate')
 323     || $self->ut_textn('paytype')
 324     || $self->ut_ipn('payip')
 325   ;
 326   return $error if $error;
 327
 328   ### from cust_main
 329
 330   FS::payby->can_payby($self->table, $self->payby)
 331     or return "Illegal payby: ". $self->payby;
 332
 333   # If it is encrypted and the private key is not availaible then we can't
 334   # check the credit card.
 335   my $check_payinfo = ! $self->is_encrypted($self->payinfo);
 336
 337   # Need some kind of global flag to accept invalid cards, for testing
 338   # on scrubbed data.
 339   #XXX if ( !$import && $check_payinfo && $self->payby =~ /^(CARD|DCRD)$/ ) {
 340
 341   # In this block: detect card type; reject credit card / account numbers that
 342   # are impossible or banned; reject other payment features (date, CVV length)
 343   # that are inappropriate for the card type.
 344   # However, if the payinfo is encrypted then just detect card type and assume
 345   # the other checks were already done.
 346
 347   if ( !$ignore_invalid_card &&
 348     $check_payinfo && $self->payby =~ /^(CARD|DCRD)$/ ) {
 349
 350     my $payinfo = $self->payinfo;
 351     $payinfo =~ s/\D//g;
 352     $payinfo =~ /^(\d{13,16}|\d{8,9})$/
 353       or return gettext('invalid_card'); #. ": ". $self->payinfo;
 354     $payinfo = $1;
 355     $self->payinfo($payinfo);
 356     validate($payinfo)
 357       or return gettext('invalid_card'); # . ": ". $self->payinfo;
 358
 359     my $cardtype = $self->paycardtype || cardtype($payinfo);
 360
 361     return gettext('unknown_card_type') if $cardtype eq "Unknown";
 362
 363     $self->set('paycardtype', $cardtype);
 364
 365     unless ( $ignore_banned_card ) {
 366       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
 367       if ( $ban ) {
 368         if ( $ban->bantype eq 'warn' ) {
 369           #or others depending on value of $ban->reason ?
 370           return '_duplicate_card'.
 371                  ': disabled from'. time2str('%a %h %o at %r', $ban->_date).
 372                  ' until '.         time2str('%a %h %o at %r', $ban->_end_date).
 373                  ' (ban# '. $ban->bannum. ')'
 374             unless $self->override_ban_warn;
 375         } else {
 376           return 'Banned credit card: banned on '.
 377                  time2str('%a %h %o at %r', $ban->_date).
 378                  ' by '. $ban->otaker.
 379                  ' (ban# '. $ban->bannum. ')';
 380         }
 381       }
 382     }
 383
 384     if (length($self->paycvv) && !$self->is_encrypted($self->paycvv)) {
 385       if ( $cardtype eq 'American Express card' ) {
 386         $self->paycvv =~ /^(\d{4})$/
 387           or return "CVV2 (CID) for American Express cards is four digits.";
 388         $self->paycvv($1);
 389       } else {
 390         $self->paycvv =~ /^(\d{3})$/
 391           or return "CVV2 (CVC2/CID) is three digits.";
 392         $self->paycvv($1);
 393       }
 394     } else {
 395       $self->paycvv('');
 396     }
 397
 398     if ( $cardtype =~ /^(Switch|Solo)$/i ) {
 399
 400       return "Start date or issue number is required for $cardtype cards"
 401         unless $self->paystart_month && $self->paystart_year or $self->payissue;
 402
 403       return "Start month must be between 1 and 12"
 404         if $self->paystart_month
 405            and $self->paystart_month < 1 || $self->paystart_month > 12;
 406
 407       return "Start year must be 1990 or later"
 408         if $self->paystart_year
 409            and $self->paystart_year < 1990;
 410
 411       return "Issue number must be beween 1 and 99"
 412         if $self->payissue
 413           and $self->payissue < 1 || $self->payissue > 99;
 414
 415     } else {
 416       $self->paystart_month('');
 417       $self->paystart_year('');
 418       $self->payissue('');
 419     }
 420
 421   } elsif ( !$ignore_invalid_card &&
 422     $check_payinfo && $self->payby =~ /^(CHEK|DCHK)$/ ) {
 423
 424     my $payinfo = $self->payinfo;
 425     $payinfo =~ s/[^\d\@\.]//g;
 426     if ( $conf->config('echeck-country') eq 'CA' ) {
 427       $payinfo =~ /^(\d+)\@(\d{5})\.(\d{3})$/
 428         or return 'invalid echeck account@branch.bank';
 429       $payinfo = "$1\@$2.$3";
 430     } elsif ( $conf->config('echeck-country') eq 'US' ) {
 431       $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
 432       $payinfo = "$1\@$2";
 433     } else {
 434       $payinfo =~ /^(\d+)\@(\d+)$/ or return 'invalid echeck account@routing';
 435       $payinfo = "$1\@$2";
 436     }
 437     $self->payinfo($payinfo);
 438     $self->paycvv('');
 439
 440     unless ( $ignore_banned_card ) {
 441       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
 442       if ( $ban ) {
 443         if ( $ban->bantype eq 'warn' ) {
 444           #or others depending on value of $ban->reason ?
 445           return '_duplicate_ach' unless $self->override_ban_warn;
 446         } else {
 447           return 'Banned ACH account: banned on '.
 448                  time2str('%a %h %o at %r', $ban->_date).
 449                  ' by '. $ban->otaker.
 450                  ' (ban# '. $ban->bannum. ')';
 451         }
 452       }
 453     }
 454
 455   } elsif ( $self->payby =~ /^CARD|DCRD$/ and $self->paymask ) {
 456     # either ignoring invalid cards, or we can't decrypt the payinfo, but
 457     # try to detect the card type anyway. this never returns failure, so
 458     # the contract of $ignore_invalid_cards is maintained.
 459     $self->set('paycardtype', cardtype($self->paymask));
 460   } else {
 461     $self->set('paycardtype', '');
 462   }
 463
 464 #  } elsif ( $self->payby eq 'PREPAY' ) {
 465 #
 466 #    my $payinfo = $self->payinfo;
 467 #    $payinfo =~ s/\W//g; #anything else would just confuse things
 468 #    $self->payinfo($payinfo);
 469 #    $error = $self->ut_alpha('payinfo');
 470 #    return "Illegal prepayment identifier: ". $self->payinfo if $error;
 471 #    return "Unknown prepayment identifier"
 472 #      unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
 473 #    $self->paycvv('');
 474
 475   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
 476
 477     $self->paydate('');
 478
 479   } elsif ( $self->payby =~ /^(CARD|DCRD)$/ ) {
 480
 481     # shouldn't payinfo_check do this?
 482     # (except we don't ever call payinfo_check from here)
 483     return "Expiration date required"
 484       if $self->paydate eq '' || $self->paydate eq '-';
 485
 486     my( $m, $y );
 487     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
 488       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
 489     } elsif ( $self->paydate =~ /^19(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
 490       ( $m, $y ) = ( $2, "19$1" );
 491     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
 492       ( $m, $y ) = ( $3, "20$2" );
 493     } else {
 494       return "Illegal expiration date: ". $self->paydate;
 495     }
 496     $m = sprintf('%02d',$m);
 497     $self->paydate("$y-$m-01");
 498     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
 499     return gettext('expired_card')
 500       if #XXX !$import
 501       #&&
 502          !$ignore_expired_card
 503       && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
 504
 505   }
 506
 507   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
 508        ( ! $conf->exists('require_cardname')
 509          || $self->payby !~ /^(CARD|DCRD)$/  )
 510   ) {
 511     $self->payname( $self->first. " ". $self->getfield('last') );
 512   } else {
 513
 514     if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
 515       $self->payname =~ /^([\w \,\.\-\']*)$/
 516         or return gettext('illegal_name'). " payname: ". $self->payname;
 517       $self->payname($1);
 518     } else {
 519       $self->payname =~ /^([\w \,\.\-\'\&]*)$/
 520         or return gettext('illegal_name'). " payname: ". $self->payname;
 521       $self->payname($1);
 522     }
 523
 524   }
 525
 526   if ( ! $self->custpaybynum ) {
 527     if ($conf->exists('business-onlinepayment-verification')) {
 528       $error = $self->verify;
 529     } else {
 530       $error = $self->tokenize;
 531     }
 532     return $error if $error;
 533   }
 534
 535   $self->SUPER::check;
 536 }
 537
 538 sub check_payinfo_cardtype {
 539   my $self = shift;
 540
 541   return '' if $ignore_cardtype;
 542
 543   return '' unless $self->payby =~ /^(CARD|CHEK)$/;
 544
 545   my $payinfo = $self->payinfo;
 546   $payinfo =~ s/\D//g;
 547
 548   if ( $self->tokenized($payinfo) ) {
 549     return '';
 550   }
 551
 552   my %bop_card_types = map { $_=>1 } values %{ card_types() };
 553   my $cardtype = cardtype($payinfo);
 554   $self->set('paycardtype', $cardtype);
 555
 556   return "$cardtype not accepted" unless $bop_card_types{$cardtype};
 557
 558   '';
 559
 560 }
 561
 562 sub _banned_pay_hashref {
 563   my $self = shift;
 564
 565   my %payby2ban = (
 566     'CARD' => 'CARD',
 567     'DCRD' => 'CARD',
 568     'CHEK' => 'CHEK',
 569     'DCHK' => 'CHEK'
 570   );
 571
 572   {
 573     'payby'   => $payby2ban{$self->payby},
 574     'payinfo' => $self->payinfo,
 575     #don't ever *search* on reason! #'reason'  =>
 576   };
 577 }
 578
 579 sub _new_banned_pay_hashref {
 580   my $self = shift;
 581   my $hr = $self->_banned_pay_hashref;
 582   $hr->{payinfo_hash} = 'SHA512';
 583   $hr->{payinfo} = sha512_base64($hr->{payinfo});
 584   $hr;
 585 }
 586
 587 =item paydate_mon_year
 588
 589 Returns a two element list consisting of the paydate month and year.
 590
 591 =cut
 592
 593 sub paydate_mon_year {
 594   my $self = shift;
 595
 596   my $date = $self->paydate; # || '12-2037';
 597
 598   #false laziness w/elements/select-month_year.html
 599   if ( $date  =~ /^(\d{4})-(\d{1,2})-\d{1,2}$/ ) { #PostgreSQL date format
 600     ( $2, $1 );
 601   } elsif ( $date =~ /^(\d{1,2})-(\d{1,2}-)?(\d{4}$)/ ) {
 602     ( $1, $3 );
 603   } else {
 604     warn "unrecognized expiration date format: $date";
 605     ( '', '' );
 606   }
 607
 608 }
 609
 610 =item label
 611
 612 Returns a one line text label for this payment type.
 613
 614 =cut
 615
 616 my %weight = (
 617   1 => 'Primary',
 618   2 => 'Secondary',
 619   3 => 'Tertiary',
 620   4 => 'Fourth',
 621   5 => 'Fifth',
 622   6 => 'Sixth',
 623   7 => 'Seventh',
 624 );
 625
 626 sub label {
 627   my $self = shift;
 628
 629   my $name = $self->payby =~ /^(CARD|DCRD)$/
 630               && $self->paycardtype || FS::payby->shortname($self->payby);
 631
 632   ( $self->payby =~ /^(CARD|CHEK)$/  ? $weight{$self->weight}. ' automatic '
 633                                      : 'Manual '
 634   ).
 635   "$name: ". $self->paymask.
 636   ( $self->payby =~ /^(CARD|DCRD)$/
 637       ? ' Exp '. join('/', $self->paydate_mon_year)
 638       : ''
 639   );
 640
 641 }
 642
 643 =item realtime_bop
 644
 645 Runs a L<realtime_bop|FS::cust_main::Billing_Realtime::realtime_bop> transaction on this card
 646
 647 =cut
 648
 649 sub realtime_bop {
 650   my( $self, %opt ) = @_;
 651
 652   $self->cust_main->realtime_bop({
 653     %opt,
 654     'cust_payby' => $self,
 655   });
 656
 657 }
 658
 659 =item tokenize
 660
 661 Runs a L<realtime_tokenize|FS::cust_main::Billing_Realtime::realtime_tokenize> transaction on this card
 662
 663 =cut
 664
 665 sub tokenize {
 666   my $self = shift;
 667   return '' unless $self->payby =~ /^(CARD|DCRD)$/;
 668
 669   $self->cust_main->realtime_tokenize({
 670     'cust_payby' => $self,
 671   });
 672
 673 }
 674
 675 =item verify
 676
 677 Runs a L<realtime_verify_bop|FS::cust_main::Billing_Realtime/realtime_verify_bop> transaction on this card
 678
 679 =cut
 680
 681 sub verify {
 682   my $self = shift;
 683   return '' unless $self->payby =~ /^(CARD|DCRD)$/;
 684
 685   $self->cust_main->realtime_verify_bop({
 686     'cust_payby' => $self,
 687   });
 688
 689 }
 690
 691 =item paytypes
 692
 693 Returns a list of valid values for the paytype field (bank account type for
 694 electronic check payment).
 695
 696 =cut
 697
 698 sub paytypes {
 699   #my $class = shift;
 700
 701   ('', 'Personal checking', 'Personal savings', 'Business checking', 'Business savings');
 702 }
 703
 704 =item cgi_cust_payby_fields
 705
 706 Returns the field names used in the web interface (including some pseudo-fields).
 707
 708 =cut
 709
 710 sub cgi_cust_payby_fields {
 711   #my $class = shift;
 712   [qw( payby payinfo paydate_month paydate_year paycvv payname weight
 713        payinfo1 payinfo2 payinfo3 paytype paystate payname_CHEK )];
 714 }
 715
 716 =item cgi_hash_callback HASHREF OLD
 717
 718 Subroutine (not a class or object method).  Processes a hash reference
 719 of web interface contet (transfers the data from pseudo-fields to real fields).
 720
 721 If OLD object is passed, also preserves locationnum, paystart_month, paystart_year,
 722 payissue and payip.  If the new field is blank but the old is not, the old field
 723 will be preserved.
 724
 725 =cut
 726
 727 sub cgi_hash_callback {
 728   my $hashref = shift;
 729   my $old = shift;
 730
 731   my %noauto = (
 732     'CARD' => 'DCRD',
 733     'CHEK' => 'DCHK',
 734   );
 735   # the payby selector gives the choice of CARD or CHEK (or others, but
 736   # those are the ones with auto and on-demand versions). if the user didn't
 737   # choose a weight, then they mean DCRD/DCHK.
 738   $hashref->{payby} = $noauto{$hashref->{payby}}
 739     if ! $hashref->{weight} && exists $noauto{$hashref->{payby}};
 740
 741   if ( $hashref->{payby} =~ /^(CHEK|DCHK)$/ ) {
 742
 743     unless ( grep $hashref->{$_}, qw(payinfo1 payinfo2 payinfo3 payname_CHEK)) {
 744       %$hashref = ();
 745       return;
 746     }
 747
 748     $hashref->{payinfo} = $hashref->{payinfo1}. '@';
 749     $hashref->{payinfo} .= $hashref->{payinfo3}.'.'
 750       if $conf->config('echeck-country') eq 'CA';
 751     $hashref->{payinfo} .= $hashref->{'payinfo2'};
 752
 753     $hashref->{payname} = $hashref->{'payname_CHEK'};
 754
 755   } elsif ( $hashref->{payby} =~ /^(CARD|DCRD)$/ ) {
 756
 757     unless ( grep $hashref->{$_}, qw( payinfo paycvv payname ) ) {
 758       %$hashref = ();
 759       return;
 760     }
 761
 762   }
 763
 764   $hashref->{paydate}= $hashref->{paydate_month}. '-'. $hashref->{paydate_year};
 765
 766   if ($old) {
 767     foreach my $field ( qw(locationnum paystart_month paystart_year payissue payip) ) {
 768       next if $hashref->{$field};
 769       next unless $old->get($field);
 770       $hashref->{$field} = $old->get($field);
 771     }
 772   }
 773
 774 }
 775
 776 =item search_sql
 777
 778 Class method.
 779
 780 Returns a qsearch hash expression to search for parameters specified in HASHREF.
 781 Valid paramters are:
 782
 783 =over 4
 784
 785 =item payby
 786
 787 listref
 788
 789 =item paydate_year
 790
 791 =item paydate_month
 792
 793
 794 =back
 795
 796 =cut
 797
 798 sub search_sql {
 799   my ($class, $params) = @_;
 800
 801   my @where = ();
 802   my $orderby;
 803
 804   # initialize these to prevent warnings
 805   $params = {
 806     'paydate_year'  => '',
 807     %$params
 808   };
 809
 810   ###
 811   # payby
 812   ###
 813
 814   if ( $params->{'payby'} ) {
 815
 816     my @payby = ref( $params->{'payby'} )
 817                   ? @{ $params->{'payby'} }
 818                   :  ( $params->{'payby'} );
 819
 820     @payby = grep /^([A-Z]{4})$/, @payby;
 821     my $in_payby = 'IN(' . join(',', map {"'$_'"} @payby) . ')';
 822     push @where, "cust_payby.payby $in_payby"
 823       if @payby;
 824   }
 825
 826   ###
 827   # paydate_year / paydate_month
 828   ###
 829
 830   if ( $params->{'paydate_year'} =~ /^(\d{4})$/ ) {
 831     my $year = $1;
 832     $params->{'paydate_month'} =~ /^(\d\d?)$/
 833       or die "paydate_year without paydate_month?";
 834     my $month = $1;
 835
 836     push @where,
 837       'cust_payby.paydate IS NOT NULL',
 838       "cust_payby.paydate != ''",
 839       "CAST(cust_payby.paydate AS timestamp) < CAST('$year-$month-01' AS timestamp )"
 840 ;
 841   }
 842   ##
 843   # setup queries, subs, etc. for the search
 844   ##
 845
 846   $orderby ||= 'ORDER BY custnum';
 847
 848   # here is the agent virtualization
 849   push @where,
 850     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
 851
 852   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
 853
 854   my $addl_from = ' LEFT JOIN cust_main USING ( custnum ) ';
 855   # always make address fields available in results
 856   for my $pre ('bill_', 'ship_') {
 857     $addl_from .=
 858       ' LEFT JOIN cust_location AS '.$pre.'location '.
 859       'ON (cust_main.'.$pre.'locationnum = '.$pre.'location.locationnum) ';
 860   }
 861   # always make referral available in results
 862   #   (maybe we should be using FS::UI::Web::join_cust_main instead?)
 863   $addl_from .= ' LEFT JOIN (select refnum, referral from part_referral) AS part_referral_x ON (cust_main.refnum = part_referral_x.refnum) ';
 864
 865   my $count_query = "SELECT COUNT(*) FROM cust_payby $addl_from $extra_sql";
 866
 867   my @select = ( 'cust_payby.*',
 868                  #'cust_main.custnum',
 869                  # there's a good chance that we'll need these
 870                  'cust_main.bill_locationnum',
 871                  'cust_main.ship_locationnum',
 872                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
 873                );
 874
 875   my $select = join(', ', @select);
 876
 877   my $sql_query = {
 878     'table'         => 'cust_payby',
 879     'select'        => $select,
 880     'addl_from'     => $addl_from,
 881     'hashref'       => {},
 882     'extra_sql'     => $extra_sql,
 883     'order_by'      => $orderby,
 884     'count_query'   => $count_query,
 885   };
 886   $sql_query;
 887
 888 }
 889
 890 =back
 891
 892 =cut
 893
 894 sub _upgrade_data {
 895
 896   my $class = shift;
 897   local $ignore_banned_card = 1;
 898   local $ignore_expired_card = 1;
 899   local $ignore_invalid_card = 1;
 900   $class->upgrade_set_cardtype;
 901
 902 }
 903
 904 =head1 BUGS
 905
 906 =head1 SEE ALSO
 907
 908 L<FS::Record>, schema.html from the base documentation.
 909
 910 =cut
 911
 912 1;
 913