FS/FS/cust_pay_batch.pm

   1 package FS::cust_pay_batch;
   2
   3 use strict;
   4 use vars qw( @ISA );
   5 use FS::Record qw(dbh qsearchs);
   6 use Business::CreditCard;
   7
   8 @ISA = qw( FS::Record );
   9
  10 =head1 NAME
  11
  12 FS::cust_pay_batch - Object methods for batch cards
  13
  14 =head1 SYNOPSIS
  15
  16   use FS::cust_pay_batch;
  17
  18   $record = new FS::cust_pay_batch \%hash;
  19   $record = new FS::cust_pay_batch { 'column' => 'value' };
  20
  21   $error = $record->insert;
  22
  23   $error = $new_record->replace($old_record);
  24
  25   $error = $record->delete;
  26
  27   $error = $record->check;
  28
  29 =head1 DESCRIPTION
  30
  31 An FS::cust_pay_batch object represents a credit card transaction ready to be
  32 batched (sent to a processor).  FS::cust_pay_batch inherits from FS::Record.
  33 Typically called by the collect method of an FS::cust_main object.  The
  34 following fields are currently supported:
  35
  36 =over 4
  37
  38 =item paybatchnum - primary key (automatically assigned)
  39
  40 =item cardnum
  41
  42 =item exp - card expiration
  43
  44 =item amount
  45
  46 =item invnum - invoice
  47
  48 =item custnum - customer
  49
  50 =item payname - name on card
  51
  52 =item first - name
  53
  54 =item last - name
  55
  56 =item address1
  57
  58 =item address2
  59
  60 =item city
  61
  62 =item state
  63
  64 =item zip
  65
  66 =item country
  67
  68 =back
  69
  70 =head1 METHODS
  71
  72 =over 4
  73
  74 =item new HASHREF
  75
  76 Creates a new record.  To add the record to the database, see L<"insert">.
  77
  78 Note that this stores the hash reference, not a distinct copy of the hash it
  79 points to.  You can ask the object for a copy with the I<hash> method.
  80
  81 =cut
  82
  83 sub table { 'cust_pay_batch'; }
  84
  85 =item insert
  86
  87 Adds this record to the database.  If there is an error, returns the error,
  88 otherwise returns false.
  89
  90 =item delete
  91
  92 Delete this record from the database.  If there is an error, returns the error,
  93 otherwise returns false.
  94
  95 =item replace OLD_RECORD
  96
  97 #inactive
  98 #
  99 #Replaces the OLD_RECORD with this one in the database.  If there is an error,
 100 #returns the error, otherwise returns false.
 101
 102 =cut
 103
 104 sub replace {
 105   return "Can't (yet?) replace batched transactions!";
 106 }
 107
 108 =item check
 109
 110 Checks all fields to make sure this is a valid transaction.  If there is
 111 an error, returns the error, otherwise returns false.  Called by the insert
 112 and repalce methods.
 113
 114 =cut
 115
 116 sub check {
 117   my $self = shift;
 118
 119   my $error =
 120       $self->ut_numbern('paybatchnum')
 121     || $self->ut_numbern('trancode') #depriciated
 122     || $self->ut_number('cardnum')
 123     || $self->ut_money('amount')
 124     || $self->ut_number('invnum')
 125     || $self->ut_number('custnum')
 126     || $self->ut_text('address1')
 127     || $self->ut_textn('address2')
 128     || $self->ut_text('city')
 129     || $self->ut_textn('state')
 130   ;
 131
 132   return $error if $error;
 133
 134   $self->getfield('last') =~ /^([\w \,\.\-\']+)$/ or return "Illegal last name";
 135   $self->setfield('last',$1);
 136
 137   $self->first =~ /^([\w \,\.\-\']+)$/ or return "Illegal first name";
 138   $self->first($1);
 139
 140   my $cardnum = $self->cardnum;
 141   $cardnum =~ s/\D//g;
 142   $cardnum =~ /^(\d{13,16})$/
 143     or return "Illegal credit card number";
 144   $cardnum = $1;
 145   $self->cardnum($cardnum);
 146   validate($cardnum) or return "Illegal credit card number";
 147   return "Unknown card type" if cardtype($cardnum) eq "Unknown";
 148
 149   if ( $self->exp eq '' ) {
 150     return "Expriation date required"; #unless
 151     $self->exp('');
 152   } else {
 153     if ( $self->exp =~ /^(\d{4})[\/\-](\d{1,2})[\/\-](\d{1,2})$/ ) {
 154       $self->exp("$1-$2-$3");
 155     } elsif ( $self->exp =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
 156       if ( length($2) == 4 ) {
 157         $self->exp("$2-$1-01");
 158       } elsif ( $2 > 98 ) { #should pry change to check for "this year"
 159         $self->exp("19$2-$1-01");
 160       } else {
 161         $self->exp("20$2-$1-01");
 162       }
 163     } else {
 164       return "Illegal expiration date";
 165     }
 166   }
 167
 168   if ( $self->payname eq '' ) {
 169     $self->payname( $self->first. " ". $self->getfield('last') );
 170   } else {
 171     $self->payname =~ /^([\w \,\.\-\']+)$/
 172       or return "Illegal billing name";
 173     $self->payname($1);
 174   }
 175
 176   #$self->zip =~ /^\s*(\w[\w\-\s]{3,8}\w)\s*$/
 177   #  or return "Illegal zip: ". $self->zip;
 178   #$self->zip($1);
 179
 180   $self->country =~ /^(\w\w)$/ or return "Illegal country: ". $self->country;
 181   $self->country($1);
 182
 183   $error = $self->ut_zip('zip', $self->country);
 184   return $error if $error;
 185
 186   #check invnum, custnum, ?
 187
 188   $self->SUPER::check;
 189 }
 190
 191 =back
 192
 193 =head1 SUBROUTINES
 194
 195 =over 4
 196
 197 =item import_results
 198
 199 =cut
 200
 201 sub import_results {
 202   use Time::Local;
 203   use FS::cust_pay;
 204   eval "use Text::CSV_XS;";
 205   die $@ if $@;
 206 #
 207   my $param = shift;
 208   my $fh = $param->{'filehandle'};
 209   my $format = $param->{'format'};
 210   my $paybatch = $param->{'paybatch'};
 211
 212   my @fields;
 213   my $condition;
 214   my $hook;
 215
 216   if ( $format eq 'csv-td_canada_trust-merchant_pc_batch' ) {
 217
 218     @fields = (
 219       'paybatchnum', # Reference#:  Invoice number of the transaction
 220       'paid',        # Amount:  Amount of the transaction.  Dollars and cents
 221                      #          with no decimal entered.
 222       '',            # Card Type:  0 - MCrd, 1 - Visa, 2 - AMEX, 3 - Discover,
 223                      #             4 - Insignia, 5 - Diners/EnRoute, 6 - JCB
 224       '_date',       # Transaction Date:  Date the Transaction was processed
 225       'time',        # Transaction Time:  Time the transaction was processed
 226       'payinfo',     # Card Number:  Card number for the transaction
 227       '',            # Expiry Date:  Expiry date of the card
 228       '',            # Auth#:  Authorization number entered for force post
 229                      #         transaction
 230       'type',        # Transaction Type:  0 - purchase, 40 - refund,
 231                      #                    20 - force post
 232       'result',      # Processing Result: 3 - Approval,
 233                      #                    4 - Declined/Amount over limit,
 234                      #                    5 - Invalid/Expired/stolen card,
 235                      #                    6 - Comm Error
 236       '',            # Terminal ID: Terminal ID used to process the transaction
 237     );
 238
 239     $condition = sub {
 240       my $hash = shift;
 241       $hash->{'result'} == 3 && $hash->{'type'} == 0;
 242     };
 243
 244     $hook = sub {
 245       my $hash = shift;
 246       $hash->{'paid'} = sprintf("%.2f", $hash->{'paid'} / 100 );
 247       $hash->{'_date'} = timelocal( substr($hash->{'time'},  4, 2),
 248                                     substr($hash->{'time'},  2, 2),
 249                                     substr($hash->{'time'},  0, 2),
 250                                     substr($hash->{'_date'}, 6, 2),
 251                                     substr($hash->{'_date'}, 4, 2)-1,
 252                                     substr($hash->{'_date'}, 0, 4)-1900, );
 253     };
 254
 255   } else {
 256     return "Unknown format $format";
 257   }
 258
 259   my $csv = new Text::CSV_XS;
 260
 261   local $SIG{HUP} = 'IGNORE';
 262   local $SIG{INT} = 'IGNORE';
 263   local $SIG{QUIT} = 'IGNORE';
 264   local $SIG{TERM} = 'IGNORE';
 265   local $SIG{TSTP} = 'IGNORE';
 266   local $SIG{PIPE} = 'IGNORE';
 267
 268   my $oldAutoCommit = $FS::UID::AutoCommit;
 269   local $FS::UID::AutoCommit = 0;
 270   my $dbh = dbh;
 271
 272   my $line;
 273   while ( defined($line=<$fh>) ) {
 274
 275     $csv->parse($line) or do {
 276       $dbh->rollback if $oldAutoCommit;
 277       return "can't parse: ". $csv->error_input();
 278     };
 279
 280     my @values = $csv->fields();
 281     my %hash;
 282     foreach my $field ( @fields ) {
 283       my $value = shift @values;
 284       next unless $field;
 285       $hash{$field} = $value;
 286     }
 287
 288     my $cust_pay_batch =
 289       qsearchs('cust_pay_batch', { 'paybatchnum' => $hash{'paybatchnum'} } );
 290     unless ( $cust_pay_batch ) {
 291       $dbh->rollback if $oldAutoCommit;
 292       return "unknown paybatchnum $hash{'paybatchnum'}\n";
 293     }
 294     my $custnum = $cust_pay_batch->custnum,
 295
 296     my $error = $cust_pay_batch->delete;
 297     if ( $error ) {
 298       $dbh->rollback if $oldAutoCommit;
 299       return "error removing paybatchnum $hash{'paybatchnum'}: $error\n";
 300     }
 301
 302     next unless &{$condition}(\%hash);
 303
 304     &{$hook}(\%hash);
 305
 306     my $cust_pay = new FS::cust_pay ( {
 307       'custnum'  => $custnum,
 308       'payby'    => 'CARD',
 309       'paybatch' => $paybatch,
 310       map { $_ => $hash{$_} } (qw( paid _date payinfo )),
 311     } );
 312     $error = $cust_pay->insert;
 313     if ( $error ) {
 314       $dbh->rollback if $oldAutoCommit;
 315       return "error adding payment paybatchnum $hash{'paybatchnum'}: $error\n";
 316     }
 317
 318     $cust_pay->cust_main->apply_payments;
 319
 320   }
 321
 322   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 323   '';
 324
 325 }
 326
 327 =back
 328
 329 =head1 BUGS
 330
 331 There should probably be a configuration file with a list of allowed credit
 332 card types.
 333
 334 =head1 SEE ALSO
 335
 336 L<FS::cust_main>, L<FS::Record>
 337
 338 =cut
 339
 340 1;
 341