FS/FS/cust_pay_batch.pm

   1 package FS::cust_pay_batch;
   2 use base qw( FS::payinfo_Mixin FS::cust_main_Mixin FS::Record );
   3
   4 use strict;
   5 use vars qw( $DEBUG );
   6 use Carp qw( carp confess );
   7 use Business::CreditCard 0.28;
   8 use FS::Record qw(dbh qsearch qsearchs);
   9
  10 # 1 is mostly method/subroutine entry and options
  11 # 2 traces progress of some operations
  12 # 3 is even more information including possibly sensitive data
  13 $DEBUG = 0;
  14
  15 #@encrypted_fields = ('payinfo');
  16 sub nohistory_fields { ('payinfo'); }
  17
  18 =head1 NAME
  19
  20 FS::cust_pay_batch - Object methods for batch cards
  21
  22 =head1 SYNOPSIS
  23
  24   use FS::cust_pay_batch;
  25
  26   $record = new FS::cust_pay_batch \%hash;
  27   $record = new FS::cust_pay_batch { 'column' => 'value' };
  28
  29   $error = $record->insert;
  30
  31   $error = $new_record->replace($old_record);
  32
  33   $error = $record->delete;
  34
  35   $error = $record->check;
  36
  37   #deprecated# $error = $record->retriable;
  38
  39 =head1 DESCRIPTION
  40
  41 An FS::cust_pay_batch object represents a credit card transaction ready to be
  42 batched (sent to a processor).  FS::cust_pay_batch inherits from FS::Record.
  43 Typically called by the collect method of an FS::cust_main object.  The
  44 following fields are currently supported:
  45
  46 =over 4
  47
  48 =item paybatchnum - primary key (automatically assigned)
  49
  50 =item batchnum - indentifies group in batch
  51
  52 =item payby - CARD/CHEK
  53
  54 =item payinfo
  55
  56 =item exp - card expiration
  57
  58 =item amount
  59
  60 =item invnum - invoice
  61
  62 =item custnum - customer
  63
  64 =item payname - name on card
  65
  66 =item paytype - account type ((personal|business) (checking|savings))
  67
  68 =item first - name
  69
  70 =item last - name
  71
  72 =item address1
  73
  74 =item address2
  75
  76 =item city
  77
  78 =item state
  79
  80 =item zip
  81
  82 =item country
  83
  84 =item status - 'Approved' or 'Declined'
  85
  86 =item error_message - the error returned by the gateway if any
  87
  88 =item failure_status - the normalized L<Business::BatchPayment> failure
  89 status, if any
  90
  91 =back
  92
  93 =head1 METHODS
  94
  95 =over 4
  96
  97 =item new HASHREF
  98
  99 Creates a new record.  To add the record to the database, see L<"insert">.
 100
 101 Note that this stores the hash reference, not a distinct copy of the hash it
 102 points to.  You can ask the object for a copy with the I<hash> method.
 103
 104 =cut
 105
 106 sub table { 'cust_pay_batch'; }
 107
 108 =item insert
 109
 110 Adds this record to the database.  If there is an error, returns the error,
 111 otherwise returns false.
 112
 113 =item delete
 114
 115 Delete this record from the database.  If there is an error, returns the error,
 116 otherwise returns false.
 117
 118 =item replace OLD_RECORD
 119
 120 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 121 returns the error, otherwise returns false.
 122
 123 =item check
 124
 125 Checks all fields to make sure this is a valid transaction.  If there is
 126 an error, returns the error, otherwise returns false.  Called by the insert
 127 and replace methods.
 128
 129 =cut
 130
 131 sub check {
 132   my $self = shift;
 133
 134   my $conf = new FS::Conf;
 135
 136   my $error =
 137       $self->ut_numbern('paybatchnum')
 138     || $self->ut_numbern('trancode') #deprecated
 139     || $self->ut_money('amount')
 140     || $self->ut_number('invnum')
 141     || $self->ut_number('custnum')
 142     || $self->ut_text('address1')
 143     || $self->ut_textn('address2')
 144     || ($conf->exists('cust_main-no_city_in_address')
 145         ? $self->ut_textn('city')
 146         : $self->ut_text('city'))
 147     || $self->ut_textn('state')
 148   ;
 149
 150   return $error if $error;
 151
 152   $self->getfield('last') =~ /^([\w \,\.\-\']+)$/ or return "Illegal last name";
 153   $self->setfield('last',$1);
 154
 155   $self->first =~ /^([\w \,\.\-\']+)$/ or return "Illegal first name";
 156   $self->first($1);
 157
 158   $error = $self->payinfo_check();
 159   return $error if $error;
 160
 161   if ( $self->payby eq 'CHEK' ) {
 162     # because '' is on the list of paytypes:
 163     my $paytype = $self->paytype or return "Bank account type required";
 164     if (grep { $_ eq $paytype} FS::cust_payby->paytypes) {
 165       #ok
 166     } else {
 167       return "Bank account type '$paytype' is not allowed"
 168     }
 169   } else {
 170     $self->set('paytype', '');
 171   }
 172
 173   if ( $self->exp eq '' ) {
 174     return "Expiration date required"
 175       unless $self->payby =~ /^(CHEK|DCHK|WEST)$/;
 176     $self->exp('');
 177   } else {
 178     if ( $self->exp =~ /^(\d{4})[\/\-](\d{1,2})[\/\-](\d{1,2})$/ ) {
 179       $self->exp("$1-$2-$3");
 180     } elsif ( $self->exp =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
 181       if ( length($2) == 4 ) {
 182         $self->exp("$2-$1-01");
 183       } elsif ( $2 > 98 ) { #should pry change to check for "this year"
 184         $self->exp("19$2-$1-01");
 185       } else {
 186         $self->exp("20$2-$1-01");
 187       }
 188     } else {
 189       return "Illegal expiration date";
 190     }
 191   }
 192
 193   if ( $self->payname eq '' ) {
 194     $self->payname( $self->first. " ". $self->getfield('last') );
 195   } else {
 196     $self->payname =~ /^([\w \,\.\-\']+)$/
 197       or return "Illegal billing name";
 198     $self->payname($1);
 199   }
 200
 201   #we have lots of old zips in there... don't hork up batch results cause of em
 202   $self->zip =~ /^\s*(\w[\w\-\s]{2,8}\w)\s*$/
 203     or return "Illegal zip: ". $self->zip;
 204   $self->zip($1);
 205
 206   $self->country =~ /^(\w\w)$/ or return "Illegal country: ". $self->country;
 207   $self->country($1);
 208
 209   #$error = $self->ut_zip('zip', $self->country);
 210   #return $error if $error;
 211
 212   #check invnum, custnum, ?
 213
 214   $self->SUPER::check;
 215 }
 216
 217 =item cust_main
 218
 219 Returns the customer (see L<FS::cust_main>) for this batched credit card
 220 payment.
 221
 222 =item expmmyy
 223
 224 Returns the credit card expiration date in MMYY format.  If this is a
 225 CHEK payment, returns an empty string.
 226
 227 =cut
 228
 229 sub expmmyy {
 230   my $self = shift;
 231   if ( $self->payby eq 'CARD' ) {
 232     $self->get('exp') =~ /^(\d{4})-(\d{2})-(\d{2})$/;
 233     return sprintf('%02u%02u', $2, ($1 % 100));
 234   }
 235   else {
 236     return '';
 237   }
 238 }
 239
 240 =item pay_batch
 241
 242 Returns the payment batch this payment belongs to (L<FS::pay_batch).
 243
 244 =cut
 245
 246 #you know what, screw this in the new world of events.  we should be able to
 247 #get the event defs to retry (remove once.pm condition, add every.pm) without
 248 #mucking about with statuses of previous cust_event records.  right?
 249 #
 250 #=item retriable
 251 #
 252 #Marks the corresponding event (see L<FS::cust_bill_event>) for this batched
 253 #credit card payment as retriable.  Useful if the corresponding financial
 254 #institution account was declined for temporary reasons and/or a manual
 255 #retry is desired.
 256 #
 257 #Implementation details: For the named customer's invoice, changes the
 258 #statustext of the 'done' (without statustext) event to 'retriable.'
 259 #
 260 #=cut
 261
 262 sub retriable {
 263
 264   confess "deprecated method cust_pay_batch->retriable called; try removing ".
 265           "the once condition and adding an every condition?";
 266
 267 }
 268
 269 =item approve OPTIONS
 270
 271 Approve this payment.  This will replace the existing record with the
 272 same paybatchnum, set its status to 'Approved', and generate a payment
 273 record (L<FS::cust_pay>).  This should only be called from the batch
 274 import process.
 275
 276 OPTIONS may contain "gatewaynum", "processor", "auth", and "order_number".
 277
 278 =cut
 279
 280 sub approve {
 281   # to break up the Big Wall of Code that is import_results
 282   my $new = shift;
 283   my %opt = @_;
 284   my $paybatchnum = $new->paybatchnum;
 285   my $old = qsearchs('cust_pay_batch', { paybatchnum => $paybatchnum })
 286     or return "cannot approve, paybatchnum $paybatchnum not found";
 287   # leave these restrictions in place until TD EFT is converted over
 288   # to B::BP
 289   return "cannot approve paybatchnum $paybatchnum, already resolved ('".$old->status."')"
 290     if $old->status;
 291   $new->status('Approved');
 292   my $error = $new->replace($old);
 293   if ( $error ) {
 294     return "error approving paybatchnum $paybatchnum: $error\n";
 295   }
 296   my $cust_pay = new FS::cust_pay ( {
 297       'custnum'   => $new->custnum,
 298       'payby'     => $new->payby,
 299       'payinfo'   => $new->payinfo || $old->payinfo,
 300       'paid'      => $new->paid,
 301       '_date'     => $new->_date,
 302       'usernum'   => $new->usernum,
 303       'batchnum'  => $new->batchnum,
 304       'gatewaynum'    => $opt{'gatewaynum'},
 305       'processor'     => $opt{'processor'},
 306       'auth'          => $opt{'auth'},
 307       'order_number'  => $opt{'order_number'}
 308     } );
 309
 310   $error = $cust_pay->insert;
 311   if ( $error ) {
 312     return "error inserting payment for paybatchnum $paybatchnum: $error\n";
 313   }
 314   $cust_pay->cust_main->apply_payments;
 315   return;
 316 }
 317
 318 =item decline [ REASON [ STATUS ] ]
 319
 320 Decline this payment.  This will replace the existing record with the
 321 same paybatchnum, set its status to 'Declined', and run collection events
 322 as appropriate.  This should only be called from the batch import process.
 323
 324 REASON is a string description of the decline reason, defaulting to
 325 'Returned payment', and will go into the "error_message" field.
 326
 327 STATUS is a normalized failure status defined by L<Business::BatchPayment>,
 328 and will go into the "failure_status" field.
 329
 330 =cut
 331
 332 sub decline {
 333   my $new = shift;
 334   my $reason = shift || 'Returned payment';
 335   my $failure_status = shift || '';
 336   #my $conf = new FS::Conf;
 337
 338   my $paybatchnum = $new->paybatchnum;
 339   my $old = qsearchs('cust_pay_batch', { paybatchnum => $paybatchnum })
 340     or return "cannot decline, paybatchnum $paybatchnum not found";
 341   if ( $old->status ) {
 342     # Handle the case where payments are rejected after the batch has been
 343     # approved.  FS::pay_batch::import_results won't allow results to be
 344     # imported to a closed batch unless batch-manual_approval is enabled,
 345     # so we don't check it here.
 346 #    if ( $conf->exists('batch-manual_approval') and
 347     if ( lc($old->status) eq 'approved' ) {
 348       # Void the payment
 349       my $cust_pay = qsearchs('cust_pay', {
 350           custnum  => $new->custnum,
 351           batchnum => $new->batchnum
 352         });
 353       # these should all be migrated over, but if it's not found, look for
 354       # batchnum in the 'paybatch' field also
 355       $cust_pay ||= qsearchs('cust_pay', {
 356           custnum  => $new->custnum,
 357           paybatch => $new->batchnum
 358         });
 359       if ( !$cust_pay ) {
 360         # should never happen...
 361         return "failed to revoke paybatchnum $paybatchnum, payment not found";
 362       }
 363       $cust_pay->void($reason);
 364     }
 365     else {
 366       # normal case: refuse to do anything
 367       return "cannot decline paybatchnum $paybatchnum, already resolved ('".$old->status."')";
 368     }
 369   } # !$old->status
 370   $new->status('Declined');
 371   $new->error_message($reason);
 372   $new->failure_status($failure_status);
 373   my $error = $new->replace($old);
 374   if ( $error ) {
 375     return "error declining paybatchnum $paybatchnum: $error\n";
 376   }
 377   my $due_cust_event = $new->cust_main->due_cust_event(
 378     'eventtable'  => 'cust_pay_batch',
 379     'objects'     => [ $new ],
 380   );
 381   if ( !ref($due_cust_event) ) {
 382     return $due_cust_event;
 383   }
 384   # XXX breaks transaction integrity
 385   foreach my $cust_event (@$due_cust_event) {
 386     next unless $cust_event->test_conditions;
 387     if ( my $error = $cust_event->do_event() ) {
 388       return $error;
 389     }
 390   }
 391   return;
 392 }
 393
 394 =item request_item [ OPTIONS ]
 395
 396 Returns a L<Business::BatchPayment::Item> object for this batch payment
 397 entry.  This can be submitted to a processor.
 398
 399 OPTIONS can be a list of key/values to append to the attributes.  The most
 400 useful case of this is "process_date" to set a processing date based on the
 401 date the batch is being submitted.
 402
 403 =cut
 404
 405 sub request_item {
 406   local $@;
 407   my $self = shift;
 408
 409   eval "use Business::BatchPayment;";
 410   die "couldn't load Business::BatchPayment: $@" if $@;
 411
 412   my $cust_main = $self->cust_main;
 413   my $location = $cust_main->bill_location;
 414   my $pay_batch = $self->pay_batch;
 415
 416   my %payment;
 417   $payment{payment_type} = FS::payby->payby2bop( $pay_batch->payby );
 418   if ( $payment{payment_type} eq 'CC' ) {
 419     $payment{card_number} = $self->payinfo,
 420     $payment{expiration}  = $self->expmmyy,
 421   } elsif ( $payment{payment_type} eq 'ECHECK' ) {
 422     $self->payinfo =~ /(\d+)@(\d+)/; # or else what?
 423     $payment{account_number} = $1;
 424     $payment{routing_code} = $2;
 425     $payment{account_type} = $self->paytype;
 426     # XXX what if this isn't their regular payment method?
 427   } else {
 428     die "unsupported BatchPayment method: ".$pay_batch->payby;
 429   }
 430
 431   my $recurring;
 432   if ( $cust_main->status =~ /^active|suspended|ordered$/ ) {
 433     if ( $self->payinfo_used ) {
 434       $recurring = 'S'; # subsequent
 435     } else {
 436       $recurring = 'F'; # first use
 437     }
 438   } else {
 439     $recurring = 'N'; # non-recurring
 440   }
 441
 442   Business::BatchPayment->create(Item =>
 443     # required
 444     action      => 'payment',
 445     tid         => $self->paybatchnum,
 446     amount      => $self->amount,
 447
 448     # customer info
 449     customer_id => $self->custnum,
 450     first_name  => $cust_main->first,
 451     last_name   => $cust_main->last,
 452     company     => $cust_main->company,
 453     address     => $location->address1,
 454     ( map { $_ => $location->$_ } qw(address2 city state country zip) ),
 455
 456     invoice_number  => $self->invnum,
 457     recurring_billing => $recurring,
 458     %payment,
 459   );
 460 }
 461
 462 =item process_unbatch_and_delete
 463
 464 L</unbatch_and_delete> run as a queued job, accepts I<$job> and I<$param>.
 465
 466 =cut
 467
 468 sub process_unbatch_and_delete {
 469   my ($job, $param) = @_;
 470   my $self = qsearchs('cust_pay_batch',{ 'paybatchnum' => scalar($param->{'paybatchnum'}) })
 471     or die 'Could not find paybatchnum ' . $param->{'paybatchnum'};
 472   my $error = $self->unbatch_and_delete;
 473   die $error if $error;
 474   return '';
 475 }
 476
 477 =item unbatch_and_delete
 478
 479 May only be called on a record with an empty status and an associated
 480 L<pay_batch> with a status of 'O' (not yet in transit.)  Deletes all associated
 481 records from L<cust_bill_pay_batch> and then deletes this record.
 482 If there is an error, returns the error, otherwise returns false.
 483
 484 =cut
 485
 486 sub unbatch_and_delete {
 487   my $self = shift;
 488
 489   return 'Cannot unbatch a cust_pay_batch with status ' . $self->status
 490     if $self->status;
 491
 492   my $pay_batch = qsearchs('pay_batch',{ 'batchnum' => $self->batchnum })
 493     or return 'Cannot find associated pay_batch record';
 494
 495   return 'Cannot unbatch from a pay_batch with status ' . $pay_batch->status
 496     if $pay_batch->status ne 'O';
 497
 498   local $SIG{HUP} = 'IGNORE';
 499   local $SIG{INT} = 'IGNORE';
 500   local $SIG{QUIT} = 'IGNORE';
 501   local $SIG{TERM} = 'IGNORE';
 502   local $SIG{TSTP} = 'IGNORE';
 503   local $SIG{PIPE} = 'IGNORE';
 504
 505   my $oldAutoCommit = $FS::UID::AutoCommit;
 506   local $FS::UID::AutoCommit = 0;
 507   my $dbh = dbh;
 508
 509   # have not generated actual payments yet, so should be safe to delete
 510   foreach my $cust_bill_pay_batch (
 511     qsearch('cust_bill_pay_batch',{ 'paybatchnum' => $self->paybatchnum })
 512   ) {
 513     my $error = $cust_bill_pay_batch->delete;
 514     if ( $error ) {
 515       $dbh->rollback if $oldAutoCommit;
 516       return $error;
 517     }
 518   }
 519
 520   my $error = $self->delete;
 521   if ( $error ) {
 522     $dbh->rollback if $oldAutoCommit;
 523     return $error;
 524   }
 525
 526   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 527   '';
 528
 529 }
 530
 531 =item cust_bill
 532
 533 Returns the invoice linked to this batched payment. Deprecated, will be
 534 removed.
 535
 536 =cut
 537
 538 sub cust_bill {
 539   carp "FS::cust_pay_batch->cust_bill is deprecated";
 540   my $self = shift;
 541   $self->invnum ? qsearchs('cust_bill', { invnum => $self->invnum }) : '';
 542 }
 543
 544 =back
 545
 546 =head1 BUGS
 547
 548 There should probably be a configuration file with a list of allowed credit
 549 card types.
 550
 551 =head1 SEE ALSO
 552
 553 L<FS::cust_main>, L<FS::Record>
 554
 555 =cut
 556
 557 1;
 558