FS/FS/cust_pay_batch.pm

   1 package FS::cust_pay_batch;
   2
   3 use strict;
   4 use vars qw( @ISA );
   5 use FS::Record qw(dbh qsearchs);
   6 use Business::CreditCard;
   7
   8 @ISA = qw( FS::Record );
   9
  10 =head1 NAME
  11
  12 FS::cust_pay_batch - Object methods for batch cards
  13
  14 =head1 SYNOPSIS
  15
  16   use FS::cust_pay_batch;
  17
  18   $record = new FS::cust_pay_batch \%hash;
  19   $record = new FS::cust_pay_batch { 'column' => 'value' };
  20
  21   $error = $record->insert;
  22
  23   $error = $new_record->replace($old_record);
  24
  25   $error = $record->delete;
  26
  27   $error = $record->check;
  28
  29 =head1 DESCRIPTION
  30
  31 An FS::cust_pay_batch object represents a credit card transaction ready to be
  32 batched (sent to a processor).  FS::cust_pay_batch inherits from FS::Record.
  33 Typically called by the collect method of an FS::cust_main object.  The
  34 following fields are currently supported:
  35
  36 =over 4
  37
  38 =item paybatchnum - primary key (automatically assigned)
  39
  40 =item cardnum
  41
  42 =item exp - card expiration
  43
  44 =item amount
  45
  46 =item invnum - invoice
  47
  48 =item custnum - customer
  49
  50 =item payname - name on card
  51
  52 =item first - name
  53
  54 =item last - name
  55
  56 =item address1
  57
  58 =item address2
  59
  60 =item city
  61
  62 =item state
  63
  64 =item zip
  65
  66 =item country
  67
  68 =back
  69
  70 =head1 METHODS
  71
  72 =over 4
  73
  74 =item new HASHREF
  75
  76 Creates a new record.  To add the record to the database, see L<"insert">.
  77
  78 Note that this stores the hash reference, not a distinct copy of the hash it
  79 points to.  You can ask the object for a copy with the I<hash> method.
  80
  81 =cut
  82
  83 sub table { 'cust_pay_batch'; }
  84
  85 =item insert
  86
  87 Adds this record to the database.  If there is an error, returns the error,
  88 otherwise returns false.
  89
  90 =item delete
  91
  92 Delete this record from the database.  If there is an error, returns the error,
  93 otherwise returns false.
  94
  95 =item replace OLD_RECORD
  96
  97 #inactive
  98 #
  99 #Replaces the OLD_RECORD with this one in the database.  If there is an error,
 100 #returns the error, otherwise returns false.
 101
 102 =cut
 103
 104 sub replace {
 105   return "Can't (yet?) replace batched transactions!";
 106 }
 107
 108 =item check
 109
 110 Checks all fields to make sure this is a valid transaction.  If there is
 111 an error, returns the error, otherwise returns false.  Called by the insert
 112 and repalce methods.
 113
 114 =cut
 115
 116 sub check {
 117   my $self = shift;
 118
 119   my $error =
 120       $self->ut_numbern('paybatchnum')
 121     || $self->ut_numbern('trancode') #depriciated
 122     || $self->ut_number('cardnum')
 123     || $self->ut_money('amount')
 124     || $self->ut_number('invnum')
 125     || $self->ut_number('custnum')
 126     || $self->ut_text('address1')
 127     || $self->ut_textn('address2')
 128     || $self->ut_text('city')
 129     || $self->ut_textn('state')
 130   ;
 131
 132   return $error if $error;
 133
 134   $self->getfield('last') =~ /^([\w \,\.\-\']+)$/ or return "Illegal last name";
 135   $self->setfield('last',$1);
 136
 137   $self->first =~ /^([\w \,\.\-\']+)$/ or return "Illegal first name";
 138   $self->first($1);
 139
 140   my $cardnum = $self->cardnum;
 141   $cardnum =~ s/\D//g;
 142   $cardnum =~ /^(\d{13,16})$/
 143     or return "Illegal credit card number";
 144   $cardnum = $1;
 145   $self->cardnum($cardnum);
 146   validate($cardnum) or return "Illegal credit card number";
 147   return "Unknown card type" if cardtype($cardnum) eq "Unknown";
 148
 149   if ( $self->exp eq '' ) {
 150     return "Expiration date required"; #unless
 151     $self->exp('');
 152   } else {
 153     if ( $self->exp =~ /^(\d{4})[\/\-](\d{1,2})[\/\-](\d{1,2})$/ ) {
 154       $self->exp("$1-$2-$3");
 155     } elsif ( $self->exp =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
 156       if ( length($2) == 4 ) {
 157         $self->exp("$2-$1-01");
 158       } elsif ( $2 > 98 ) { #should pry change to check for "this year"
 159         $self->exp("19$2-$1-01");
 160       } else {
 161         $self->exp("20$2-$1-01");
 162       }
 163     } else {
 164       return "Illegal expiration date";
 165     }
 166   }
 167
 168   if ( $self->payname eq '' ) {
 169     $self->payname( $self->first. " ". $self->getfield('last') );
 170   } else {
 171     $self->payname =~ /^([\w \,\.\-\']+)$/
 172       or return "Illegal billing name";
 173     $self->payname($1);
 174   }
 175
 176   #$self->zip =~ /^\s*(\w[\w\-\s]{3,8}\w)\s*$/
 177   #  or return "Illegal zip: ". $self->zip;
 178   #$self->zip($1);
 179
 180   $self->country =~ /^(\w\w)$/ or return "Illegal country: ". $self->country;
 181   $self->country($1);
 182
 183   $error = $self->ut_zip('zip', $self->country);
 184   return $error if $error;
 185
 186   #check invnum, custnum, ?
 187
 188   $self->SUPER::check;
 189 }
 190
 191 =item cust_main
 192
 193 Returns the customer (see L<FS::cust_main>) for this batched credit card
 194 payment.
 195
 196 =cut
 197
 198 sub cust_main {
 199   my $self = shift;
 200   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 201 }
 202
 203 =back
 204
 205 =head1 SUBROUTINES
 206
 207 =over 4
 208
 209 =item import_results
 210
 211 =cut
 212
 213 sub import_results {
 214   use Time::Local;
 215   use FS::cust_pay;
 216   eval "use Text::CSV_XS;";
 217   die $@ if $@;
 218 #
 219   my $param = shift;
 220   my $fh = $param->{'filehandle'};
 221   my $format = $param->{'format'};
 222   my $paybatch = $param->{'paybatch'};
 223
 224   my @fields;
 225   my $end_condition;
 226   my $end_hook;
 227   my $hook;
 228   my $approved_condition;
 229   my $declined_condition;
 230
 231   if ( $format eq 'csv-td_canada_trust-merchant_pc_batch' ) {
 232
 233     @fields = (
 234       'paybatchnum', # Reference#:  Invoice number of the transaction
 235       'paid',        # Amount:  Amount of the transaction.  Dollars and cents
 236                      #          with no decimal entered.
 237       '',            # Card Type:  0 - MCrd, 1 - Visa, 2 - AMEX, 3 - Discover,
 238                      #             4 - Insignia, 5 - Diners/EnRoute, 6 - JCB
 239       '_date',       # Transaction Date:  Date the Transaction was processed
 240       'time',        # Transaction Time:  Time the transaction was processed
 241       'payinfo',     # Card Number:  Card number for the transaction
 242       '',            # Expiry Date:  Expiry date of the card
 243       '',            # Auth#:  Authorization number entered for force post
 244                      #         transaction
 245       'type',        # Transaction Type:  0 - purchase, 40 - refund,
 246                      #                    20 - force post
 247       'result',      # Processing Result: 3 - Approval,
 248                      #                    4 - Declined/Amount over limit,
 249                      #                    5 - Invalid/Expired/stolen card,
 250                      #                    6 - Comm Error
 251       '',            # Terminal ID: Terminal ID used to process the transaction
 252     );
 253
 254     $end_condition = sub {
 255       my $hash = shift;
 256       $hash->{'type'} eq '0BC';
 257     };
 258
 259     $end_hook = sub {
 260       my( $hash, $total) = @_;
 261       $total = sprintf("%.2f", $total);
 262       my $batch_total = sprintf("%.2f", $hash->{'paybatchnum'} / 100 );
 263       return "Our total $total does not match bank total $batch_total!"
 264         if $total != $batch_total;
 265       '';
 266     };
 267
 268     $hook = sub {
 269       my $hash = shift;
 270       $hash->{'paid'} = sprintf("%.2f", $hash->{'paid'} / 100 );
 271       $hash->{'_date'} = timelocal( substr($hash->{'time'},  4, 2),
 272                                     substr($hash->{'time'},  2, 2),
 273                                     substr($hash->{'time'},  0, 2),
 274                                     substr($hash->{'_date'}, 6, 2),
 275                                     substr($hash->{'_date'}, 4, 2)-1,
 276                                     substr($hash->{'_date'}, 0, 4)-1900, );
 277     };
 278
 279     $approved_condition = sub {
 280       my $hash = shift;
 281       $hash->{'type'} eq '0' && $hash->{'result'} == 3;
 282     };
 283
 284     $declined_condition = sub {
 285       my $hash = shift;
 286       $hash->{'type'} eq '0' && (    $hash->{'result'} == 4
 287                                   || $hash->{'result'} == 5 );
 288     };
 289
 290
 291   } else {
 292     return "Unknown format $format";
 293   }
 294
 295   my $csv = new Text::CSV_XS;
 296
 297   local $SIG{HUP} = 'IGNORE';
 298   local $SIG{INT} = 'IGNORE';
 299   local $SIG{QUIT} = 'IGNORE';
 300   local $SIG{TERM} = 'IGNORE';
 301   local $SIG{TSTP} = 'IGNORE';
 302   local $SIG{PIPE} = 'IGNORE';
 303
 304   my $oldAutoCommit = $FS::UID::AutoCommit;
 305   local $FS::UID::AutoCommit = 0;
 306   my $dbh = dbh;
 307
 308   my $total = 0;
 309   my $line;
 310   while ( defined($line=<$fh>) ) {
 311
 312     next if $line =~ /^\s*$/; #skip blank lines
 313
 314     $csv->parse($line) or do {
 315       $dbh->rollback if $oldAutoCommit;
 316       return "can't parse: ". $csv->error_input();
 317     };
 318
 319     my @values = $csv->fields();
 320     my %hash;
 321     foreach my $field ( @fields ) {
 322       my $value = shift @values;
 323       next unless $field;
 324       $hash{$field} = $value;
 325     }
 326
 327     if ( &{$end_condition}(\%hash) ) {
 328       my $error = &{$end_hook}(\%hash, $total);
 329       if ( $error ) {
 330         $dbh->rollback if $oldAutoCommit;
 331         return $error;
 332       }
 333       last;
 334     }
 335
 336     my $cust_pay_batch =
 337       qsearchs('cust_pay_batch', { 'paybatchnum' => $hash{'paybatchnum'} } );
 338     unless ( $cust_pay_batch ) {
 339       $dbh->rollback if $oldAutoCommit;
 340       return "unknown paybatchnum $hash{'paybatchnum'}\n";
 341     }
 342     my $custnum = $cust_pay_batch->custnum,
 343
 344     my $error = $cust_pay_batch->delete;
 345     if ( $error ) {
 346       $dbh->rollback if $oldAutoCommit;
 347       return "error removing paybatchnum $hash{'paybatchnum'}: $error\n";
 348     }
 349
 350     &{$hook}(\%hash);
 351
 352     if ( &{$approved_condition}(\%hash) ) {
 353
 354       my $cust_pay = new FS::cust_pay ( {
 355         'custnum'  => $custnum,
 356         'payby'    => 'CARD',
 357         'paybatch' => $paybatch,
 358         map { $_ => $hash{$_} } (qw( paid _date payinfo )),
 359       } );
 360       $error = $cust_pay->insert;
 361       if ( $error ) {
 362         $dbh->rollback if $oldAutoCommit;
 363         return "error adding payment paybatchnum $hash{'paybatchnum'}: $error\n";
 364       }
 365       $total += $hash{'paid'};
 366
 367       $cust_pay->cust_main->apply_payments;
 368
 369     } elsif ( &{$declined_condition}(\%hash) ) {
 370
 371       #this should be configurable... if anybody else ever uses batches
 372       $cust_pay_batch->cust_main->suspend;
 373
 374     }
 375
 376   }
 377
 378   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 379   '';
 380
 381 }
 382
 383 =back
 384
 385 =head1 BUGS
 386
 387 There should probably be a configuration file with a list of allowed credit
 388 card types.
 389
 390 =head1 SEE ALSO
 391
 392 L<FS::cust_main>, L<FS::Record>
 393
 394 =cut
 395
 396 1;
 397