FS/FS/cust_pay.pm

   1 package FS::cust_pay;
   2
   3 use strict;
   4 use base qw( FS::otaker_Mixin FS::payinfo_transaction_Mixin FS::cust_main_Mixin
   5              FS::Record );
   6 use vars qw( $DEBUG $me $conf @encrypted_fields
   7              $unsuspendauto $ignore_noapply
   8            );
   9 use Date::Format;
  10 use Business::CreditCard;
  11 use Text::Template;
  12 use FS::Misc::DateTime qw( parse_datetime ); #for batch_import
  13 use FS::Record qw( dbh qsearch qsearchs );
  14 use FS::UID qw( driver_name );
  15 use FS::CurrentUser;
  16 use FS::payby;
  17 use FS::cust_main_Mixin;
  18 use FS::payinfo_transaction_Mixin;
  19 use FS::cust_bill;
  20 use FS::cust_bill_pay;
  21 use FS::cust_pay_refund;
  22 use FS::cust_main;
  23 use FS::cust_pkg;
  24 use FS::cust_pay_void;
  25 use FS::upgrade_journal;
  26 use FS::Cursor;
  27
  28 $DEBUG = 0;
  29
  30 $me = '[FS::cust_pay]';
  31
  32 $ignore_noapply = 0;
  33
  34 #ask FS::UID to run this stuff for us later
  35 FS::UID->install_callback( sub {
  36   $conf = new FS::Conf;
  37   $unsuspendauto = $conf->exists('unsuspendauto');
  38 } );
  39
  40 @encrypted_fields = ('payinfo');
  41 sub nohistory_fields { ('payinfo'); }
  42
  43 =head1 NAME
  44
  45 FS::cust_pay - Object methods for cust_pay objects
  46
  47 =head1 SYNOPSIS
  48
  49   use FS::cust_pay;
  50
  51   $record = new FS::cust_pay \%hash;
  52   $record = new FS::cust_pay { 'column' => 'value' };
  53
  54   $error = $record->insert;
  55
  56   $error = $new_record->replace($old_record);
  57
  58   $error = $record->delete;
  59
  60   $error = $record->check;
  61
  62 =head1 DESCRIPTION
  63
  64 An FS::cust_pay object represents a payment; the transfer of money from a
  65 customer.  FS::cust_pay inherits from FS::Record.  The following fields are
  66 currently supported:
  67
  68 =over 4
  69
  70 =item paynum
  71
  72 primary key (assigned automatically for new payments)
  73
  74 =item custnum
  75
  76 customer (see L<FS::cust_main>)
  77
  78 =item _date
  79
  80 specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  81 L<Time::Local> and L<Date::Parse> for conversion functions.
  82
  83 =item paid
  84
  85 Amount of this payment
  86
  87 =item usernum
  88
  89 order taker (see L<FS::access_user>)
  90
  91 =item payby
  92
  93 Payment Type (See L<FS::payinfo_Mixin> for valid values)
  94
  95 =item payinfo
  96
  97 Payment Information (See L<FS::payinfo_Mixin> for data format)
  98
  99 =item paymask
 100
 101 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 102
 103 =item paybatch
 104
 105 obsolete text field for tracking card processing or other batch grouping
 106
 107 =item payunique
 108
 109 Optional unique identifer to prevent duplicate transactions.
 110
 111 =item closed
 112
 113 books closed flag, empty or `Y'
 114
 115 =item pkgnum
 116
 117 Desired pkgnum when using experimental package balances.
 118
 119 =item bank
 120
 121 The bank where the payment was deposited.
 122
 123 =item depositor
 124
 125 The name of the depositor.
 126
 127 =item account
 128
 129 The deposit account number.
 130
 131 =item teller
 132
 133 The teller number.
 134
 135 =item batchnum
 136
 137 The number of the batch this payment came from (see L<FS::pay_batch>),
 138 or null if it was processed through a realtime gateway or entered manually.
 139
 140 =item gatewaynum
 141
 142 The number of the realtime or batch gateway L<FS::payment_gateway>) this
 143 payment was processed through.  Null if it was entered manually or processed
 144 by the "system default" gateway, which doesn't have a number.
 145
 146 =item processor
 147
 148 The name of the processor module (Business::OnlinePayment, ::BatchPayment,
 149 or ::OnlineThirdPartyPayment subclass) used for this payment.  Slightly
 150 redundant with C<gatewaynum>.
 151
 152 =item auth
 153
 154 The authorization number returned by the credit card network.
 155
 156 =item order_number
 157
 158 The transaction ID returned by the gateway, if any.  This is usually what
 159 you would use to initiate a void or refund of the payment.
 160
 161 =back
 162
 163 =head1 METHODS
 164
 165 =over 4
 166
 167 =item new HASHREF
 168
 169 Creates a new payment.  To add the payment to the databse, see L<"insert">.
 170
 171 =cut
 172
 173 sub table { 'cust_pay'; }
 174 sub cust_linked { $_[0]->cust_main_custnum || $_[0]->custnum; }
 175 sub cust_unlinked_msg {
 176   my $self = shift;
 177   "WARNING: can't find cust_main.custnum ". $self->custnum.
 178   ' (cust_pay.paynum '. $self->paynum. ')';
 179 }
 180
 181 =item insert [ OPTION => VALUE ... ]
 182
 183 Adds this payment to the database.
 184
 185 For backwards-compatibility and convenience, if the additional field invnum
 186 is defined, an FS::cust_bill_pay record for the full amount of the payment
 187 will be created.  In this case, custnum is optional.
 188
 189 If the additional field discount_term is defined then a prepayment discount
 190 is taken for that length of time.  It is an error for the customer to owe
 191 after this payment is made.
 192
 193 A hash of optional arguments may be passed.  The following arguments are
 194 supported:
 195
 196 =over 4
 197
 198 =item manual
 199
 200 If true, a payment receipt is sent instead of a statement when
 201 'payment_receipt_email' configuration option is set.
 202
 203 About the "manual" flag: Normally, if the 'payment_receipt' config option
 204 is set, and the customer has an invoice email address, inserting a payment
 205 causes a I<statement> to be emailed to the customer.  If the payment is
 206 considered "manual" (or if the customer has no invoices), then it will
 207 instead send a I<payment receipt>.  "manual" should be true whenever a
 208 payment is created directly from the web interface, from a user-initiated
 209 realtime payment, or from a third-party payment via self-service.  It should
 210 be I<false> when creating a payment from a billing event or from a batch.
 211
 212 =item noemail
 213
 214 Don't send an email receipt.  (Note: does not currently work when
 215 payment_receipt-trigger is set to something other than default / cust_bill)
 216
 217 =back
 218
 219 =cut
 220
 221 sub insert {
 222   my($self, %options) = @_;
 223
 224   local $SIG{HUP} = 'IGNORE';
 225   local $SIG{INT} = 'IGNORE';
 226   local $SIG{QUIT} = 'IGNORE';
 227   local $SIG{TERM} = 'IGNORE';
 228   local $SIG{TSTP} = 'IGNORE';
 229   local $SIG{PIPE} = 'IGNORE';
 230
 231   my $oldAutoCommit = $FS::UID::AutoCommit;
 232   local $FS::UID::AutoCommit = 0;
 233   my $dbh = dbh;
 234
 235   my $cust_bill;
 236   if ( $self->invnum ) {
 237     $cust_bill = qsearchs('cust_bill', { 'invnum' => $self->invnum } )
 238       or do {
 239         $dbh->rollback if $oldAutoCommit;
 240         return "Unknown cust_bill.invnum: ". $self->invnum;
 241       };
 242     $self->custnum($cust_bill->custnum );
 243   }
 244
 245   my $error = $self->check;
 246   return $error if $error;
 247
 248   my $cust_main = $self->cust_main;
 249   my $old_balance = $cust_main->balance;
 250
 251   $error = $self->SUPER::insert;
 252   if ( $error ) {
 253     $dbh->rollback if $oldAutoCommit;
 254     return "error inserting cust_pay: $error";
 255   }
 256
 257   if ( my $credit_type = $conf->config('prepayment_discounts-credit_type') ) {
 258     if ( my $months = $self->discount_term ) {
 259       # XXX this should be moved out somewhere, but discount_term_values
 260       # doesn't fit right
 261       my ($cust_bill) = ($cust_main->cust_bill)[-1]; # most recent invoice
 262       return "can't accept prepayment for an unbilled customer" if !$cust_bill;
 263
 264       # %billing_pkgs contains this customer's active monthly packages.
 265       # Recurring fees for those packages will be credited and then rebilled
 266       # for the full discount term.  Other packages on the last invoice
 267       # (canceled, non-monthly recurring, or one-time charges) will be
 268       # left as they are.
 269       my %billing_pkgs = map { $_->pkgnum => $_ }
 270                          grep { $_->part_pkg->freq eq '1' }
 271                          $cust_main->billing_pkgs;
 272       my $credit = 0; # sum of recurring charges from that invoice
 273       my $last_bill_date = 0; # the real bill date
 274       foreach my $item ( $cust_bill->cust_bill_pkg ) {
 275         next if !exists($billing_pkgs{$item->pkgnum}); # skip inactive packages
 276         $credit += $item->recur;
 277         $last_bill_date = $item->cust_pkg->last_bill
 278           if defined($item->cust_pkg)
 279             and $item->cust_pkg->last_bill > $last_bill_date
 280       }
 281
 282       my $cust_credit = new FS::cust_credit {
 283         'custnum' => $self->custnum,
 284         'amount'  => sprintf('%.2f', $credit),
 285         'reason'  => 'customer chose to prepay for discount',
 286       };
 287       $error = $cust_credit->insert('reason_type' => $credit_type);
 288       if ( $error ) {
 289         $dbh->rollback if $oldAutoCommit;
 290         return "error inserting prepayment credit: $error";
 291       }
 292       # don't apply it yet
 293
 294       # bill for the entire term
 295       $_->bill($_->last_bill) foreach (values %billing_pkgs);
 296       $error = $cust_main->bill(
 297         # no recurring_only, we want unbilled packages with start dates to
 298         # get billed
 299         'no_usage_reset' => 1,
 300         'time'           => $last_bill_date, # not $cust_bill->_date
 301         'pkg_list'       => [ values %billing_pkgs ],
 302         'freq_override'  => $months,
 303       );
 304       if ( $error ) {
 305         $dbh->rollback if $oldAutoCommit;
 306         return "error inserting cust_pay: $error";
 307       }
 308       $error = $cust_main->apply_payments_and_credits;
 309       if ( $error ) {
 310         $dbh->rollback if $oldAutoCommit;
 311         return "error inserting cust_pay: $error";
 312       }
 313       my $new_balance = $cust_main->balance;
 314       if ($new_balance > 0) {
 315         $dbh->rollback if $oldAutoCommit;
 316         return "balance after prepay discount attempt: $new_balance";
 317       }
 318       # user friendly: override the "apply only to this invoice" mode
 319       $self->invnum('');
 320
 321     }
 322
 323   }
 324
 325   if ( $self->invnum ) {
 326     my $cust_bill_pay = new FS::cust_bill_pay {
 327       'invnum' => $self->invnum,
 328       'paynum' => $self->paynum,
 329       'amount' => $self->paid,
 330       '_date'  => $self->_date,
 331     };
 332     $error = $cust_bill_pay->insert(%options);
 333     if ( $error ) {
 334       if ( $ignore_noapply ) {
 335         warn "warning: error inserting cust_bill_pay: $error ".
 336              "(ignore_noapply flag set; inserting cust_pay record anyway)\n";
 337       } else {
 338         $dbh->rollback if $oldAutoCommit;
 339         return "error inserting cust_bill_pay: $error";
 340       }
 341     }
 342   }
 343
 344   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 345
 346   #false laziness w/ cust_credit::insert
 347   if ( $unsuspendauto && $old_balance && $cust_main->balance <= 0 ) {
 348     my @errors = $cust_main->unsuspend;
 349     #return
 350     # side-fx with nested transactions?  upstack rolls back?
 351     warn "WARNING:Errors unsuspending customer ". $cust_main->custnum. ": ".
 352          join(' / ', @errors)
 353       if @errors;
 354   }
 355   #eslaf
 356
 357   #bill setup fees for voip_cdr bill_every_call packages
 358   #some false laziness w/search in freeside-cdrd
 359   my $addl_from =
 360     'LEFT JOIN part_pkg USING ( pkgpart ) '.
 361     "LEFT JOIN part_pkg_option
 362        ON ( cust_pkg.pkgpart = part_pkg_option.pkgpart
 363             AND part_pkg_option.optionname = 'bill_every_call' )";
 364
 365   my $extra_sql = " AND plan = 'voip_cdr' AND optionvalue = '1' ".
 366                   " AND ( cust_pkg.setup IS NULL OR cust_pkg.setup = 0 ) ";
 367
 368   my @cust_pkg = qsearch({
 369     'table'     => 'cust_pkg',
 370     'addl_from' => $addl_from,
 371     'hashref'   => { 'custnum' => $self->custnum,
 372                      'susp'    => '',
 373                      'cancel'  => '',
 374                    },
 375     'extra_sql' => $extra_sql,
 376   });
 377
 378   if ( @cust_pkg ) {
 379     warn "voip_cdr bill_every_call packages found; billing customer\n";
 380     my $bill_error = $self->cust_main->bill_and_collect( 'fatal' => 'return' );
 381     if ( $bill_error ) {
 382       warn "WARNING: Error billing customer: $bill_error\n";
 383     }
 384   }
 385   #end of billing setup fees for voip_cdr bill_every_call packages
 386
 387   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 388
 389   #payment receipt
 390   my $trigger = $conf->config('payment_receipt-trigger',
 391                               $self->cust_main->agentnum) || 'cust_pay';
 392   if ( $trigger eq 'cust_pay' ) {
 393     my $error = $self->send_receipt(
 394       'manual'    => $options{'manual'},
 395       'noemail'   => $options{'noemail'},
 396       'cust_bill' => $cust_bill,
 397       'cust_main' => $cust_main,
 398     );
 399     warn "can't send payment receipt/statement: $error" if $error;
 400   }
 401
 402   '';
 403
 404 }
 405
 406 =item void [ REASON ]
 407
 408 Voids this payment: deletes the payment and all associated applications and
 409 adds a record of the voided payment to the FS::cust_pay_void table.
 410
 411 =cut
 412
 413 sub void {
 414   my $self = shift;
 415
 416   local $SIG{HUP} = 'IGNORE';
 417   local $SIG{INT} = 'IGNORE';
 418   local $SIG{QUIT} = 'IGNORE';
 419   local $SIG{TERM} = 'IGNORE';
 420   local $SIG{TSTP} = 'IGNORE';
 421   local $SIG{PIPE} = 'IGNORE';
 422
 423   my $oldAutoCommit = $FS::UID::AutoCommit;
 424   local $FS::UID::AutoCommit = 0;
 425   my $dbh = dbh;
 426
 427   my $cust_pay_void = new FS::cust_pay_void ( {
 428     map { $_ => $self->get($_) } $self->fields
 429   } );
 430   $cust_pay_void->reason(shift) if scalar(@_);
 431   my $error = $cust_pay_void->insert;
 432
 433   my $cust_pay_pending =
 434     qsearchs('cust_pay_pending', { paynum => $self->paynum });
 435   if ( $cust_pay_pending ) {
 436     $cust_pay_pending->set('void_paynum', $self->paynum);
 437     $cust_pay_pending->set('paynum', '');
 438     $error ||= $cust_pay_pending->replace;
 439   }
 440
 441   $error ||= $self->delete;
 442
 443   if ( $error ) {
 444     $dbh->rollback if $oldAutoCommit;
 445     return $error;
 446   }
 447
 448   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 449
 450   '';
 451
 452 }
 453
 454 =item delete
 455
 456 Unless the closed flag is set, deletes this payment and all associated
 457 applications (see L<FS::cust_bill_pay> and L<FS::cust_pay_refund>).  In most
 458 cases, you want to use the void method instead to leave a record of the
 459 deleted payment.
 460
 461 =cut
 462
 463 # very similar to FS::cust_credit::delete
 464 sub delete {
 465   my $self = shift;
 466   return "Can't delete closed payment" if $self->closed =~ /^Y/i;
 467
 468   local $SIG{HUP} = 'IGNORE';
 469   local $SIG{INT} = 'IGNORE';
 470   local $SIG{QUIT} = 'IGNORE';
 471   local $SIG{TERM} = 'IGNORE';
 472   local $SIG{TSTP} = 'IGNORE';
 473   local $SIG{PIPE} = 'IGNORE';
 474
 475   my $oldAutoCommit = $FS::UID::AutoCommit;
 476   local $FS::UID::AutoCommit = 0;
 477   my $dbh = dbh;
 478
 479   foreach my $app ( $self->cust_bill_pay, $self->cust_pay_refund ) {
 480     my $error = $app->delete;
 481     if ( $error ) {
 482       $dbh->rollback if $oldAutoCommit;
 483       return $error;
 484     }
 485   }
 486
 487   my $error = $self->SUPER::delete(@_);
 488   if ( $error ) {
 489     $dbh->rollback if $oldAutoCommit;
 490     return $error;
 491   }
 492
 493   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 494
 495   '';
 496
 497 }
 498
 499 =item replace [ OLD_RECORD ]
 500
 501 You can, but probably shouldn't modify payments...
 502
 503 Replaces the OLD_RECORD with this one in the database, or, if OLD_RECORD is not
 504 supplied, replaces this record.  If there is an error, returns the error,
 505 otherwise returns false.
 506
 507 =cut
 508
 509 sub replace {
 510   my $self = shift;
 511   return "Can't modify closed payment" if $self->closed =~ /^Y/i;
 512   $self->SUPER::replace(@_);
 513 }
 514
 515 =item check
 516
 517 Checks all fields to make sure this is a valid payment.  If there is an error,
 518 returns the error, otherwise returns false.  Called by the insert method.
 519
 520 =cut
 521
 522 sub check {
 523   my $self = shift;
 524
 525   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 526
 527   my $error =
 528     $self->ut_numbern('paynum')
 529     || $self->ut_numbern('custnum')
 530     || $self->ut_numbern('_date')
 531     || $self->ut_money('paid')
 532     || $self->ut_alphan('otaker')
 533     || $self->ut_textn('paybatch')
 534     || $self->ut_textn('payunique')
 535     || $self->ut_enum('closed', [ '', 'Y' ])
 536     || $self->ut_foreign_keyn('pkgnum', 'cust_pkg', 'pkgnum')
 537     || $self->ut_textn('bank')
 538     || $self->ut_alphan('depositor')
 539     || $self->ut_numbern('account')
 540     || $self->ut_numbern('teller')
 541     || $self->ut_foreign_keyn('batchnum', 'pay_batch', 'batchnum')
 542     || $self->payinfo_check()
 543   ;
 544   return $error if $error;
 545
 546   return "paid must be > 0 " if $self->paid <= 0;
 547
 548   return "unknown cust_main.custnum: ". $self->custnum
 549     unless $self->invnum
 550            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 551
 552   $self->_date(time) unless $self->_date;
 553
 554   return "invalid discount_term"
 555    if ($self->discount_term && $self->discount_term < 2);
 556
 557   if ( $self->payby eq 'CASH' and $conf->exists('require_cash_deposit_info') ) {
 558     foreach (qw(bank depositor account teller)) {
 559       return "$_ required" if $self->get($_) eq '';
 560     }
 561   }
 562
 563 #i guess not now, with cust_pay_pending, if we actually make it here, we _do_ want to record it
 564 #  # UNIQUE index should catch this too, without race conditions, but this
 565 #  # should give a better error message the other 99.9% of the time...
 566 #  if ( length($self->payunique)
 567 #       && qsearchs('cust_pay', { 'payunique' => $self->payunique } ) ) {
 568 #    #well, it *could* be a better error message
 569 #    return "duplicate transaction".
 570 #           " - a payment with unique identifer ". $self->payunique.
 571 #           " already exists";
 572 #  }
 573
 574   $self->SUPER::check;
 575 }
 576
 577 =item send_receipt HASHREF | OPTION => VALUE ...
 578
 579 Sends a payment receipt for this payment..
 580
 581 Available options:
 582
 583 =over 4
 584
 585 =item manual
 586
 587 Flag indicating the payment is being made manually.
 588
 589 =item cust_bill
 590
 591 Invoice (FS::cust_bill) object.  If not specified, the most recent invoice
 592 will be assumed.
 593
 594 =item cust_main
 595
 596 Customer (FS::cust_main) object (for efficiency).
 597
 598 =item noemail
 599
 600 Don't send an email receipt.
 601
 602 =cut
 603
 604 =back
 605
 606 =cut
 607
 608 sub send_receipt {
 609   my $self = shift;
 610   my $opt = ref($_[0]) ? shift : { @_ };
 611
 612   my $cust_bill = $opt->{'cust_bill'};
 613   my $cust_main = $opt->{'cust_main'} || $self->cust_main;
 614
 615   my $conf = new FS::Conf;
 616
 617   return '' unless $conf->config_bool('payment_receipt', $cust_main->agentnum);
 618
 619   my @invoicing_list = $cust_main->invoicing_list_emailonly;
 620   return '' unless @invoicing_list;
 621
 622   $cust_bill ||= ($cust_main->cust_bill)[-1]; #rather inefficient though?
 623
 624   my $error = '';
 625
 626   if (    ( exists($opt->{'manual'}) && $opt->{'manual'} )
 627        #|| ! $conf->exists('invoice_html_statement')
 628        || ! $cust_bill
 629      )
 630   {
 631     my $msgnum = $conf->config('payment_receipt_msgnum', $cust_main->agentnum);
 632     if ( $msgnum ) {
 633
 634       my %substitutions = ();
 635       $substitutions{invnum} = $opt->{cust_bill}->invnum if $opt->{cust_bill};
 636
 637       my $queue = new FS::queue {
 638         'job'     => 'FS::Misc::process_send_email',
 639         'paynum'  => $self->paynum,
 640         'custnum' => $cust_main->custnum,
 641       };
 642       $error = $queue->insert(
 643         FS::msg_template->by_key($msgnum)->prepare(
 644           'cust_main'     => $cust_main,
 645           'object'        => $self,
 646           'from_config'   => 'payment_receipt_from',
 647           'substitutions' => \%substitutions,
 648         ),
 649         'msgtype' => 'receipt', # override msg_template's default
 650       );
 651
 652     } elsif ( $conf->exists('payment_receipt_email') ) {
 653
 654       my $receipt_template = new Text::Template (
 655         TYPE   => 'ARRAY',
 656         SOURCE => [ map "$_\n", $conf->config('payment_receipt_email') ],
 657       ) or do {
 658         warn "can't create payment receipt template: $Text::Template::ERROR";
 659         return '';
 660       };
 661
 662       my $payby = $self->payby;
 663       my $payinfo = $self->payinfo;
 664       $payby =~ s/^BILL$/Check/ if $payinfo;
 665       if ( $payby eq 'CARD' || $payby eq 'CHEK' ) {
 666         $payinfo = $self->paymask
 667       } else {
 668         $payinfo = $self->decrypt($payinfo);
 669       }
 670       $payby =~ s/^CHEK$/Electronic check/;
 671
 672       my %fill_in = (
 673         'date'         => time2str("%a %B %o, %Y", $self->_date),
 674         'name'         => $cust_main->name,
 675         'paynum'       => $self->paynum,
 676         'paid'         => sprintf("%.2f", $self->paid),
 677         'payby'        => ucfirst(lc($payby)),
 678         'payinfo'      => $payinfo,
 679         'balance'      => $cust_main->balance,
 680         'company_name' => $conf->config('company_name', $cust_main->agentnum),
 681       );
 682
 683       $fill_in{'invnum'} = $opt->{cust_bill}->invnum if $opt->{cust_bill};
 684
 685       if ( $opt->{'cust_pkg'} ) {
 686         $fill_in{'pkg'} = $opt->{'cust_pkg'}->part_pkg->pkg;
 687         #setup date, other things?
 688       }
 689
 690       my $queue = new FS::queue {
 691         'job'     => 'FS::Misc::process_send_generated_email',
 692         'paynum'  => $self->paynum,
 693         'custnum' => $cust_main->custnum,
 694         'msgtype' => 'receipt',
 695       };
 696       $error = $queue->insert(
 697         'from'    => $conf->invoice_from_full( $cust_main->agentnum ),
 698                                    #invoice_from??? well as good as any
 699         'to'      => \@invoicing_list,
 700         'subject' => 'Payment receipt',
 701         'body'    => [ $receipt_template->fill_in( HASH => \%fill_in ) ],
 702       );
 703
 704     } else {
 705
 706       warn "payment_receipt is on, but no payment_receipt_msgnum\n";
 707
 708     }
 709
 710   #not manual and no noemail flag (here or on the customer)
 711   } elsif ( ! $opt->{'noemail'} && ! $cust_main->invoice_noemail ) {
 712
 713     my $queue = new FS::queue {
 714        'job'     => 'FS::cust_bill::queueable_email',
 715        'paynum'  => $self->paynum,
 716        'custnum' => $cust_main->custnum,
 717     };
 718
 719     $error = $queue->insert(
 720       'invnum'      => $cust_bill->invnum,
 721       'template'    => 'statement',
 722       'notice_name' => 'Statement',
 723       'no_coupon'   => 1,
 724     );
 725
 726   }
 727
 728   warn "send_receipt: $error\n" if $error;
 729 }
 730
 731 =item cust_bill_pay
 732
 733 Returns all applications to invoices (see L<FS::cust_bill_pay>) for this
 734 payment.
 735
 736 =cut
 737
 738 sub cust_bill_pay {
 739   my $self = shift;
 740   map { $_ } #return $self->num_cust_bill_pay unless wantarray;
 741   sort {    $a->_date  <=> $b->_date
 742          || $a->invnum <=> $b->invnum }
 743     qsearch( 'cust_bill_pay', { 'paynum' => $self->paynum } )
 744   ;
 745 }
 746
 747 =item cust_pay_refund
 748
 749 Returns all applications of refunds (see L<FS::cust_pay_refund>) to this
 750 payment.
 751
 752 =cut
 753
 754 sub cust_pay_refund {
 755   my $self = shift;
 756   map { $_ } #return $self->num_cust_pay_refund unless wantarray;
 757   sort { $a->_date <=> $b->_date }
 758     qsearch( 'cust_pay_refund', { 'paynum' => $self->paynum } )
 759   ;
 760 }
 761
 762
 763 =item unapplied
 764
 765 Returns the amount of this payment that is still unapplied; which is
 766 paid minus all payment applications (see L<FS::cust_bill_pay>) and refund
 767 applications (see L<FS::cust_pay_refund>).
 768
 769 =cut
 770
 771 sub unapplied {
 772   my $self = shift;
 773   my $amount = $self->paid;
 774   $amount -= $_->amount foreach ( $self->cust_bill_pay );
 775   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 776   sprintf("%.2f", $amount );
 777 }
 778
 779 =item unrefunded
 780
 781 Returns the amount of this payment that has not been refuned; which is
 782 paid minus all  refund applications (see L<FS::cust_pay_refund>).
 783
 784 =cut
 785
 786 sub unrefunded {
 787   my $self = shift;
 788   my $amount = $self->paid;
 789   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 790   sprintf("%.2f", $amount );
 791 }
 792
 793 =item amount
 794
 795 Returns the "paid" field.
 796
 797 =cut
 798
 799 sub amount {
 800   my $self = shift;
 801   $self->paid();
 802 }
 803
 804 =back
 805
 806 =head1 CLASS METHODS
 807
 808 =over 4
 809
 810 =item batch_insert CUST_PAY_OBJECT, ...
 811
 812 Class method which inserts multiple payments.  Takes a list of FS::cust_pay
 813 objects.  Returns a list, each element representing the status of inserting the
 814 corresponding payment - empty.  If there is an error inserting any payment, the
 815 entire transaction is rolled back, i.e. all payments are inserted or none are.
 816
 817 FS::cust_pay objects may have the pseudo-field 'apply_to', containing a
 818 reference to an array of (uninserted) FS::cust_bill_pay objects.  If so,
 819 those objects will be inserted with the paynum of the payment, and for
 820 each one, an error message or an empty string will be inserted into the
 821 list of errors.
 822
 823 For example:
 824
 825   my @errors = FS::cust_pay->batch_insert(@cust_pay);
 826   my $num_errors = scalar(grep $_, @errors);
 827   if ( $num_errors == 0 ) {
 828     #success; all payments were inserted
 829   } else {
 830     #failure; no payments were inserted.
 831   }
 832
 833 =cut
 834
 835 sub batch_insert {
 836   my $self = shift; #class method
 837
 838   local $SIG{HUP} = 'IGNORE';
 839   local $SIG{INT} = 'IGNORE';
 840   local $SIG{QUIT} = 'IGNORE';
 841   local $SIG{TERM} = 'IGNORE';
 842   local $SIG{TSTP} = 'IGNORE';
 843   local $SIG{PIPE} = 'IGNORE';
 844
 845   my $oldAutoCommit = $FS::UID::AutoCommit;
 846   local $FS::UID::AutoCommit = 0;
 847   my $dbh = dbh;
 848
 849   my $num_errors = 0;
 850
 851   my @errors;
 852   foreach my $cust_pay (@_) {
 853     my $error = $cust_pay->insert( 'manual' => 1 );
 854     push @errors, $error;
 855     $num_errors++ if $error;
 856
 857     if ( ref($cust_pay->get('apply_to')) eq 'ARRAY' ) {
 858
 859       foreach my $cust_bill_pay ( @{ $cust_pay->apply_to } ) {
 860         if ( $error ) { # insert placeholders if cust_pay wasn't inserted
 861           push @errors, '';
 862         }
 863         else {
 864           $cust_bill_pay->set('paynum', $cust_pay->paynum);
 865           my $apply_error = $cust_bill_pay->insert;
 866           push @errors, $apply_error || '';
 867           $num_errors++ if $apply_error;
 868         }
 869       }
 870
 871     } elsif ( !$error ) { #normal case: apply payments as usual
 872       $cust_pay->cust_main->apply_payments;
 873     }
 874
 875   }
 876
 877   if ( $num_errors ) {
 878     $dbh->rollback if $oldAutoCommit;
 879   } else {
 880     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 881   }
 882
 883   @errors;
 884
 885 }
 886
 887 =item unapplied_sql
 888
 889 Returns an SQL fragment to retreive the unapplied amount.
 890
 891 =cut
 892
 893 sub unapplied_sql {
 894   my ($class, $start, $end) = @_;
 895   my $bill_start   = $start ? "AND cust_bill_pay._date <= $start"   : '';
 896   my $bill_end     = $end   ? "AND cust_bill_pay._date > $end"     : '';
 897   my $refund_start = $start ? "AND cust_pay_refund._date <= $start" : '';
 898   my $refund_end   = $end   ? "AND cust_pay_refund._date > $end"   : '';
 899
 900   "paid
 901         - COALESCE(
 902                     ( SELECT SUM(amount) FROM cust_bill_pay
 903                         WHERE cust_pay.paynum = cust_bill_pay.paynum
 904                         $bill_start $bill_end )
 905                     ,0
 906                   )
 907         - COALESCE(
 908                     ( SELECT SUM(amount) FROM cust_pay_refund
 909                         WHERE cust_pay.paynum = cust_pay_refund.paynum
 910                         $refund_start $refund_end )
 911                     ,0
 912                   )
 913   ";
 914
 915 }
 916
 917 sub API_getinfo {
 918  my $self = shift;
 919  my @fields = grep { $_ ne 'payinfo' } $self->fields;
 920  +{ ( map { $_=>$self->$_ } @fields ),
 921   };
 922 }
 923
 924 # _upgrade_data
 925 #
 926 # Used by FS::Upgrade to migrate to a new database.
 927
 928 use FS::h_cust_pay;
 929
 930 sub _upgrade_data {  #class method
 931   my ($class, %opt) = @_;
 932
 933   warn "$me upgrading $class\n" if $DEBUG;
 934
 935   local $FS::payinfo_Mixin::ignore_masked_payinfo = 1;
 936
 937   ##
 938   # otaker/ivan upgrade
 939   ##
 940
 941   unless ( FS::upgrade_journal->is_done('cust_pay__otaker_ivan') ) {
 942
 943     #not the most efficient, but hey, it only has to run once
 944
 945     my $where = " WHERE ( otaker IS NULL OR otaker = '' OR otaker = 'ivan' )
 946                     AND usernum IS NULL
 947                     AND EXISTS ( SELECT 1 FROM cust_main
 948                                    WHERE cust_main.custnum = cust_pay.custnum )
 949                 ";
 950
 951     my $count_sql = "SELECT COUNT(*) FROM cust_pay $where";
 952
 953     my $sth = dbh->prepare($count_sql) or die dbh->errstr;
 954     $sth->execute or die $sth->errstr;
 955     my $total = $sth->fetchrow_arrayref->[0];
 956     #warn "$total cust_pay records to update\n"
 957     #  if $DEBUG;
 958     local($DEBUG) = 2 if $total > 1000; #could be a while, force progress info
 959
 960     my $count = 0;
 961     my $lastprog = 0;
 962
 963     my @cust_pay = qsearch( {
 964         'table'     => 'cust_pay',
 965         'hashref'   => {},
 966         'extra_sql' => $where,
 967         'order_by'  => 'ORDER BY paynum',
 968     } );
 969
 970     foreach my $cust_pay (@cust_pay) {
 971
 972       my $h_cust_pay = $cust_pay->h_search('insert');
 973       if ( $h_cust_pay ) {
 974         next if $cust_pay->otaker eq $h_cust_pay->history_user;
 975         #$cust_pay->otaker($h_cust_pay->history_user);
 976         $cust_pay->set('otaker', $h_cust_pay->history_user);
 977       } else {
 978         $cust_pay->set('otaker', 'legacy');
 979       }
 980
 981       delete $FS::payby::hash{'COMP'}->{cust_pay}; #quelle kludge
 982       my $error = $cust_pay->replace;
 983
 984       if ( $error ) {
 985         warn " *** WARNING: Error updating order taker for payment paynum ".
 986              $cust_pay->paynun. ": $error\n";
 987         next;
 988       }
 989
 990       $FS::payby::hash{'COMP'}->{cust_pay} = ''; #restore it
 991
 992       $count++;
 993       if ( $DEBUG > 1 && $lastprog + 30 < time ) {
 994         warn "$me $count/$total (".sprintf('%.2f',100*$count/$total). '%)'."\n";
 995         $lastprog = time;
 996       }
 997
 998     }
 999
1000     FS::upgrade_journal->set_done('cust_pay__otaker_ivan');
1001   }
1002
1003   ###
1004   # payinfo N/A upgrade
1005   ###
1006
1007   unless ( FS::upgrade_journal->is_done('cust_pay__payinfo_na') ) {
1008
1009     #XXX remove the 'N/A (tokenized)' part (or just this entire thing)
1010
1011     my @na_cust_pay = qsearch( {
1012       'table'     => 'cust_pay',
1013       'hashref'   => {}, #could be encrypted# { 'payinfo' => 'N/A' },
1014       'extra_sql' => "WHERE ( payinfo = 'N/A' OR paymask = 'N/AA' OR paymask = 'N/A (tokenized)' ) AND payby IN ( 'CARD', 'CHEK' )",
1015     } );
1016
1017     foreach my $na ( @na_cust_pay ) {
1018
1019       next unless $na->payinfo eq 'N/A';
1020
1021       my $cust_pay_pending =
1022         qsearchs('cust_pay_pending', { 'paynum' => $na->paynum } );
1023       unless ( $cust_pay_pending ) {
1024         warn " *** WARNING: not-yet recoverable N/A card for payment ".
1025              $na->paynum. " (no cust_pay_pending)\n";
1026         next;
1027       }
1028       $na->$_($cust_pay_pending->$_) for qw( payinfo paymask );
1029       my $error = $na->replace;
1030       if ( $error ) {
1031         warn " *** WARNING: Error updating payinfo for payment paynum ".
1032              $na->paynun. ": $error\n";
1033         next;
1034       }
1035
1036     }
1037
1038     FS::upgrade_journal->set_done('cust_pay__payinfo_na');
1039   }
1040
1041   ###
1042   # otaker->usernum upgrade
1043   ###
1044
1045   delete $FS::payby::hash{'COMP'}->{cust_pay}; #quelle kludge
1046   $class->_upgrade_otaker(%opt);
1047   $FS::payby::hash{'COMP'}->{cust_pay} = ''; #restore it
1048
1049   # if we do this anywhere else, it should become an FS::Upgrade method
1050   my $num_to_upgrade = $class->count('paybatch is not null');
1051   my $num_jobs = FS::queue->count('job = \'FS::cust_pay::process_upgrade_paybatch\' and status != \'failed\'');
1052   if ( $num_to_upgrade > 0 ) {
1053     warn "Need to migrate paybatch field in $num_to_upgrade payments.\n";
1054     if ( $opt{queue} ) {
1055       if ( $num_jobs > 0 ) {
1056         warn "Upgrade already queued.\n";
1057       } else {
1058         warn "Scheduling upgrade.\n";
1059         my $job = FS::queue->new({ job => 'FS::cust_pay::process_upgrade_paybatch' });
1060         $job->insert;
1061       }
1062     } else {
1063       process_upgrade_paybatch();
1064     }
1065   }
1066 }
1067
1068 sub process_upgrade_paybatch {
1069   my $dbh = dbh;
1070   local $FS::payinfo_Mixin::ignore_masked_payinfo = 1;
1071   local $FS::UID::AutoCommit = 1;
1072
1073   ###
1074   # migrate batchnums from the misused 'paybatch' field to 'batchnum'
1075   ###
1076   my $text = (driver_name =~ /^mysql/i) ? 'char' : 'text';
1077   my $search = FS::Cursor->new( {
1078     'table'     => 'cust_pay',
1079     'addl_from' => " JOIN pay_batch ON cust_pay.paybatch = CAST(pay_batch.batchnum AS $text) ",
1080   } );
1081   while (my $cust_pay = $search->fetch) {
1082     $cust_pay->set('batchnum' => $cust_pay->paybatch);
1083     $cust_pay->set('paybatch' => '');
1084     my $error = $cust_pay->replace;
1085     warn "error setting batchnum on cust_pay #".$cust_pay->paynum.":\n  $error"
1086     if $error;
1087   }
1088
1089   ###
1090   # migrate gateway info from the misused 'paybatch' field
1091   ###
1092
1093   # not only cust_pay, but also voided and refunded payments
1094   if (!FS::upgrade_journal->is_done('cust_pay__parse_paybatch_1')) {
1095     local $FS::Record::nowarn_classload=1;
1096     # really inefficient, but again, only has to run once
1097     foreach my $table (qw(cust_pay cust_pay_void cust_refund)) {
1098       my $and_batchnum_is_null =
1099         ( $table =~ /^cust_pay/ ? ' AND batchnum IS NULL' : '' );
1100       my $pkey = ($table =~ /^cust_pay/ ? 'paynum' : 'refundnum');
1101       my $search = FS::Cursor->new({
1102         table     => $table,
1103         extra_sql => "WHERE payby IN('CARD','CHEK') ".
1104                      "AND (paybatch IS NOT NULL ".
1105                      "OR (paybatch IS NULL AND auth IS NULL
1106                      $and_batchnum_is_null ) )
1107                      ORDER BY $pkey DESC"
1108       });
1109       while ( my $object = $search->fetch ) {
1110         if ( $object->paybatch eq '' ) {
1111           # repair for a previous upgrade that didn't save 'auth'
1112           my $pkey = $object->primary_key;
1113           # find the last history record that had a paybatch value
1114           my $h = qsearchs({
1115               table   => "h_$table",
1116               hashref => {
1117                 $pkey     => $object->$pkey,
1118                 paybatch  => { op=>'!=', value=>''},
1119                 history_action => 'replace_old',
1120               },
1121               order_by => 'ORDER BY history_date DESC LIMIT 1',
1122           });
1123           if (!$h) {
1124             warn "couldn't find paybatch history record for $table ".$object->$pkey."\n";
1125             next;
1126           }
1127           # if the paybatch didn't have an auth string, then it's fine
1128           $h->paybatch =~ /:(\w+):/ or next;
1129           # set paybatch to what it was in that record
1130           $object->set('paybatch', $h->paybatch)
1131           # and then upgrade it like the old records
1132         }
1133
1134         my $parsed = $object->_parse_paybatch;
1135         if (keys %$parsed) {
1136           $object->set($_ => $parsed->{$_}) foreach keys %$parsed;
1137           $object->set('auth' => $parsed->{authorization});
1138           $object->set('paybatch', '');
1139           my $error = $object->replace;
1140           warn "error parsing CARD/CHEK paybatch fields on $object #".
1141             $object->get($object->primary_key).":\n  $error\n"
1142             if $error;
1143         }
1144       } #$object
1145     } #$table
1146     FS::upgrade_journal->set_done('cust_pay__parse_paybatch_1');
1147   }
1148 }
1149
1150 =back
1151
1152 =head1 SUBROUTINES
1153
1154 =over 4
1155
1156 =item batch_import HASHREF
1157
1158 Inserts new payments.
1159
1160 =cut
1161
1162 sub batch_import {
1163   my $param = shift;
1164
1165   my $fh       = $param->{filehandle};
1166   my $format   = $param->{'format'};
1167
1168   my $agentnum = $param->{agentnum};
1169   my $_date    = $param->{_date};
1170   $_date = parse_datetime($_date) if $_date && $_date =~ /\D/;
1171   my $paybatch = $param->{'paybatch'};
1172
1173   my $custnum_prefix = $conf->config('cust_main-custnum-display_prefix');
1174   my $custnum_length = $conf->config('cust_main-custnum-display_length') || 8;
1175
1176   # here is the agent virtualization
1177   my $extra_sql = ' AND '. $FS::CurrentUser::CurrentUser->agentnums_sql;
1178
1179   my @fields;
1180   my $payby;
1181   if ( $format eq 'simple' ) {
1182     @fields = qw( custnum agent_custid paid payinfo invnum );
1183     $payby = 'BILL';
1184   } elsif ( $format eq 'extended' ) {
1185     die "unimplemented\n";
1186     @fields = qw( );
1187     $payby = 'BILL';
1188   } else {
1189     die "unknown format $format";
1190   }
1191
1192   eval "use Text::CSV_XS;";
1193   die $@ if $@;
1194
1195   my $csv = new Text::CSV_XS;
1196
1197   my $imported = 0;
1198
1199   local $SIG{HUP} = 'IGNORE';
1200   local $SIG{INT} = 'IGNORE';
1201   local $SIG{QUIT} = 'IGNORE';
1202   local $SIG{TERM} = 'IGNORE';
1203   local $SIG{TSTP} = 'IGNORE';
1204   local $SIG{PIPE} = 'IGNORE';
1205
1206   my $oldAutoCommit = $FS::UID::AutoCommit;
1207   local $FS::UID::AutoCommit = 0;
1208   my $dbh = dbh;
1209
1210   my $line;
1211   while ( defined($line=<$fh>) ) {
1212
1213     $csv->parse($line) or do {
1214       $dbh->rollback if $oldAutoCommit;
1215       return "can't parse: ". $csv->error_input();
1216     };
1217
1218     my @columns = $csv->fields();
1219
1220     my %cust_pay = (
1221       payby    => $payby,
1222       paybatch => $paybatch,
1223     );
1224     $cust_pay{_date} = $_date if $_date;
1225
1226     my $cust_main;
1227     foreach my $field ( @fields ) {
1228
1229       if ( $field eq 'agent_custid'
1230         && $agentnum
1231         && $columns[0] =~ /\S+/ )
1232       {
1233
1234         my $agent_custid = $columns[0];
1235         my %hash = ( 'agent_custid' => $agent_custid,
1236                      'agentnum'     => $agentnum,
1237                    );
1238
1239         if ( $cust_pay{'custnum'} !~ /^\s*$/ ) {
1240           $dbh->rollback if $oldAutoCommit;
1241           return "can't specify custnum with agent_custid $agent_custid";
1242         }
1243
1244         $cust_main = qsearchs({
1245                                 'table'     => 'cust_main',
1246                                 'hashref'   => \%hash,
1247                                 'extra_sql' => $extra_sql,
1248                              });
1249
1250         unless ( $cust_main ) {
1251           $dbh->rollback if $oldAutoCommit;
1252           return "can't find customer with agent_custid $agent_custid";
1253         }
1254
1255         $field = 'custnum';
1256         $columns[0] = $cust_main->custnum;
1257       }
1258
1259       $cust_pay{$field} = shift @columns;
1260     }
1261
1262     if ( $custnum_prefix && $cust_pay{custnum} =~ /^$custnum_prefix(0*([1-9]\d*))$/
1263                          && length($1) == $custnum_length ) {
1264       $cust_pay{custnum} = $2;
1265     }
1266
1267     my $custnum = $cust_pay{custnum};
1268
1269     my $cust_pay = new FS::cust_pay( \%cust_pay );
1270     my $error = $cust_pay->insert;
1271
1272     if ( ! $error && $cust_pay->custnum != $custnum ) {
1273       #invnum was defined, and ->insert set custnum to the customer for that
1274       #invoice, but it wasn't the one the import specified.
1275       $dbh->rollback if $oldAutoCommit;
1276       $error = "specified invoice #". $cust_pay{invnum}.
1277                " is for custnum ". $cust_pay->custnum.
1278                ", not specified custnum $custnum";
1279     }
1280
1281     if ( $error ) {
1282       $dbh->rollback if $oldAutoCommit;
1283       return "can't insert payment for $line: $error";
1284     }
1285
1286     if ( $format eq 'simple' ) {
1287       # include agentnum for less surprise?
1288       $cust_main = qsearchs({
1289                              'table'     => 'cust_main',
1290                              'hashref'   => { 'custnum' => $cust_pay->custnum },
1291                              'extra_sql' => $extra_sql,
1292                            })
1293         unless $cust_main;
1294
1295       unless ( $cust_main ) {
1296         $dbh->rollback if $oldAutoCommit;
1297         return "can't find customer to which payments apply at line: $line";
1298       }
1299
1300       $error = $cust_main->apply_payments_and_credits;
1301       if ( $error ) {
1302         $dbh->rollback if $oldAutoCommit;
1303         return "can't apply payments to customer for $line: $error";
1304       }
1305
1306     }
1307
1308     $imported++;
1309   }
1310
1311   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1312
1313   return "Empty file!" unless $imported;
1314
1315   ''; #no error
1316
1317 }
1318
1319 =back
1320
1321 =head1 BUGS
1322
1323 Delete and replace methods.
1324
1325 =head1 SEE ALSO
1326
1327 L<FS::cust_pay_pending>, L<FS::cust_bill_pay>, L<FS::cust_bill>, L<FS::Record>,
1328 schema.html from the base documentation.
1329
1330 =cut
1331
1332 1;
1333