FS/FS/cust_pay.pm

   1 package FS::cust_pay;
   2
   3 use strict;
   4 use vars qw( @ISA );
   5 use Business::CreditCard;
   6 use FS::Record qw( dbh );
   7 use FS::cust_bill;
   8 use FS::cust_bill_pay;
   9 use FS::cust_main;
  10
  11 @ISA = qw( FS::Record );
  12
  13 =head1 NAME
  14
  15 FS::cust_pay - Object methods for cust_pay objects
  16
  17 =head1 SYNOPSIS
  18
  19   use FS::cust_pay;
  20
  21   $record = new FS::cust_pay \%hash;
  22   $record = new FS::cust_pay { 'column' => 'value' };
  23
  24   $error = $record->insert;
  25
  26   $error = $new_record->replace($old_record);
  27
  28   $error = $record->delete;
  29
  30   $error = $record->check;
  31
  32 =head1 DESCRIPTION
  33
  34 An FS::cust_pay object represents a payment; the transfer of money from a
  35 customer.  FS::cust_pay inherits from FS::Record.  The following fields are
  36 currently supported:
  37
  38 =over 4
  39
  40 =item paynum - primary key (assigned automatically for new payments)
  41
  42 =item custnum - customer (see L<FS::cust_main>)
  43
  44 =item paid - Amount of this payment
  45
  46 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  47 L<Time::Local> and L<Date::Parse> for conversion functions.
  48
  49 =item payby - `CARD' (credit cards), `BILL' (billing), or `COMP' (free)
  50
  51 =item payinfo - card number, P.O.#, or comp issuer (4-8 lowercase alphanumerics; think username)
  52
  53 =item paybatch - text field for tracking card processing
  54
  55 =back
  56
  57 =head1 METHODS
  58
  59 =over 4
  60
  61 =item new HASHREF
  62
  63 Creates a new payment.  To add the payment to the databse, see L<"insert">.
  64
  65 =cut
  66
  67 sub table { 'cust_pay'; }
  68
  69 =item insert
  70
  71 Adds this payment to the database.
  72
  73 For backwards-compatibility and convenience, if the additional field invnum
  74 is defined, an FS::cust_bill_pay record for the full amount of the payment
  75 will be created.  In this case, custnum is optional.
  76
  77 =cut
  78
  79 sub insert {
  80   my $self = shift;
  81
  82   local $SIG{HUP} = 'IGNORE';
  83   local $SIG{INT} = 'IGNORE';
  84   local $SIG{QUIT} = 'IGNORE';
  85   local $SIG{TERM} = 'IGNORE';
  86   local $SIG{TSTP} = 'IGNORE';
  87   local $SIG{PIPE} = 'IGNORE';
  88
  89   my $oldAutoCommit = $FS::UID::AutoCommit;
  90   local $FS::UID::AutoCommit = 0;
  91   my $dbh = dbh;
  92
  93   my $error = $self->check;
  94   return $error if $error;
  95
  96   if ( $self->invnum ) {
  97     my $cust_bill_pay = new FS::cust_bill_pay {
  98       'invnum' => $self->invnum,
  99       'paynum' => $self->paynum,
 100       'amount' => $self->paid,
 101       '_date'  => $self->_date,
 102     };
 103     $error = $cust_bill_pay->insert;
 104     if ( $error ) {
 105       $dbh->rollback if $oldAutoCommit;
 106       return $error;
 107     }
 108     $self->custnum($cust_bill_pay->cust_bill->custnum);
 109   }
 110
 111   $error = $self->SUPER::insert;
 112   if ( $error ) {
 113     $dbh->rollback if $oldAutoCommit;
 114     return $error;
 115   }
 116
 117   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 118
 119   '';
 120
 121 }
 122
 123 =item delete
 124
 125 Currently unimplemented (accounting reasons).
 126
 127 =cut
 128
 129 sub delete {
 130   return "Can't (yet?) delete cust_pay records!";
 131 }
 132
 133 =item replace OLD_RECORD
 134
 135 Currently unimplemented (accounting reasons).
 136
 137 =cut
 138
 139 sub replace {
 140    return "Can't (yet?) modify cust_pay records!";
 141 }
 142
 143 =item check
 144
 145 Checks all fields to make sure this is a valid payment.  If there is an error,
 146 returns the error, otherwise returns false.  Called by the insert method.
 147
 148 =cut
 149
 150 sub check {
 151   my $self = shift;
 152
 153   my $error =
 154     $self->ut_numbern('paynum')
 155     || $self->ut_number('custnum')
 156     || $self->ut_money('paid')
 157     || $self->ut_numbern('_date')
 158     || $self->ut_textn('paybatch')
 159   ;
 160   return $error if $error;
 161
 162   return "unknown cust_main.custnum: ". $self->custnum
 163     unless $self->invnum
 164            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 165
 166   $self->_date(time) unless $self->_date;
 167
 168   $self->payby =~ /^(CARD|BILL|COMP)$/ or return "Illegal payby";
 169   $self->payby($1);
 170
 171   if ( $self->payby eq 'CARD' ) {
 172     my $payinfo = $self->payinfo;
 173     $payinfo =~ s/\D//g;
 174     $self->payinfo($payinfo);
 175     if ( $self->payinfo ) {
 176       $self->payinfo =~ /^(\d{13,16})$/
 177         or return "Illegal (mistyped?) credit card number (payinfo)";
 178       $self->payinfo($1);
 179       validate($self->payinfo) or return "Illegal credit card number";
 180       return "Unknown card type" if cardtype($self->payinfo) eq "Unknown";
 181     } else {
 182       $self->payinfo('N/A');
 183     }
 184
 185   } else {
 186     $error = $self->ut_textn('payinfo');
 187     return $error if $error;
 188   }
 189
 190   ''; #no error
 191
 192 }
 193
 194 =item cust_bill_pay
 195
 196 Returns all applications to invoices (see L<FS::cust_bill_pay>) for this
 197 payment.
 198
 199 =cut
 200
 201 sub cust_bill_pay {
 202   my $self = shift;
 203   sort { $a->_date <=> $b->_date }
 204     qsearch( 'cust_bill_pay', { 'paynum' => $self->paynum } )
 205   ;
 206 }
 207
 208 =item unapplied
 209
 210 Returns the amount of this payment that is still unapplied; which is
 211 paid minus all payment applications (see L<FS::cust_bill_pay>).
 212
 213 =cut
 214
 215 sub unapplied {
 216   my $self = shift;
 217   my $amount = $self->paid;
 218   $amount -= $_->amount foreach ( $self->cust_bill_pay );
 219   sprintf("%.2f", $amount );
 220 }
 221
 222 =back
 223
 224 =head1 VERSION
 225
 226 $Id: cust_pay.pm,v 1.5 2001-09-02 02:46:55 ivan Exp $
 227
 228 =head1 BUGS
 229
 230 Delete and replace methods.
 231
 232 =head1 SEE ALSO
 233
 234 L<FS::cust_bill_pay>, L<FS::cust_bill>, L<FS::Record>, schema.html from the
 235 base documentation.
 236
 237 =cut
 238
 239 1;
 240