FS/FS/cust_pay.pm

   1 package FS::cust_pay;
   2
   3 use strict;
   4 use base qw( FS::otaker_Mixin FS::payinfo_transaction_Mixin FS::cust_main_Mixin
   5              FS::Record );
   6 use vars qw( $DEBUG $me $conf @encrypted_fields
   7              $unsuspendauto $ignore_noapply
   8            );
   9 use Date::Format;
  10 use Business::CreditCard;
  11 use Text::Template;
  12 use FS::UID qw( getotaker );
  13 use FS::Misc qw( send_email );
  14 use FS::Record qw( dbh qsearch qsearchs );
  15 use FS::CurrentUser;
  16 use FS::payby;
  17 use FS::cust_main_Mixin;
  18 use FS::payinfo_transaction_Mixin;
  19 use FS::cust_bill;
  20 use FS::cust_bill_pay;
  21 use FS::cust_pay_refund;
  22 use FS::cust_main;
  23 use FS::cust_pkg;
  24 use FS::cust_pay_void;
  25
  26 $DEBUG = 0;
  27
  28 $me = '[FS::cust_pay]';
  29
  30 $ignore_noapply = 0;
  31
  32 #ask FS::UID to run this stuff for us later
  33 FS::UID->install_callback( sub {
  34   $conf = new FS::Conf;
  35   $unsuspendauto = $conf->exists('unsuspendauto');
  36 } );
  37
  38 @encrypted_fields = ('payinfo');
  39
  40 =head1 NAME
  41
  42 FS::cust_pay - Object methods for cust_pay objects
  43
  44 =head1 SYNOPSIS
  45
  46   use FS::cust_pay;
  47
  48   $record = new FS::cust_pay \%hash;
  49   $record = new FS::cust_pay { 'column' => 'value' };
  50
  51   $error = $record->insert;
  52
  53   $error = $new_record->replace($old_record);
  54
  55   $error = $record->delete;
  56
  57   $error = $record->check;
  58
  59 =head1 DESCRIPTION
  60
  61 An FS::cust_pay object represents a payment; the transfer of money from a
  62 customer.  FS::cust_pay inherits from FS::Record.  The following fields are
  63 currently supported:
  64
  65 =over 4
  66
  67 =item paynum
  68
  69 primary key (assigned automatically for new payments)
  70
  71 =item custnum
  72
  73 customer (see L<FS::cust_main>)
  74
  75 =item _date
  76
  77 specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  78 L<Time::Local> and L<Date::Parse> for conversion functions.
  79
  80 =item paid
  81
  82 Amount of this payment
  83
  84 =item usernum
  85
  86 order taker (see L<FS::access_user>)
  87
  88 =item payby
  89
  90 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
  91
  92 =item payinfo
  93
  94 Payment Information (See L<FS::payinfo_Mixin> for data format)
  95
  96 =item paymask
  97
  98 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
  99
 100 =item paybatch
 101
 102 text field for tracking card processing or other batch grouping
 103
 104 =item payunique
 105
 106 Optional unique identifer to prevent duplicate transactions.
 107
 108 =item closed
 109
 110 books closed flag, empty or `Y'
 111
 112 =item pkgnum
 113
 114 Desired pkgnum when using experimental package balances.
 115
 116 =back
 117
 118 =head1 METHODS
 119
 120 =over 4
 121
 122 =item new HASHREF
 123
 124 Creates a new payment.  To add the payment to the databse, see L<"insert">.
 125
 126 =cut
 127
 128 sub table { 'cust_pay'; }
 129 sub cust_linked { $_[0]->cust_main_custnum; }
 130 sub cust_unlinked_msg {
 131   my $self = shift;
 132   "WARNING: can't find cust_main.custnum ". $self->custnum.
 133   ' (cust_pay.paynum '. $self->paynum. ')';
 134 }
 135
 136 =item insert [ OPTION => VALUE ... ]
 137
 138 Adds this payment to the database.
 139
 140 For backwards-compatibility and convenience, if the additional field invnum
 141 is defined, an FS::cust_bill_pay record for the full amount of the payment
 142 will be created.  In this case, custnum is optional.
 143
 144 If the additional field discount_term is defined then a prepayment discount
 145 is taken for that length of time.  It is an error for the customer to owe
 146 after this payment is made.
 147
 148 A hash of optional arguments may be passed.  Currently "manual" is supported.
 149 If true, a payment receipt is sent instead of a statement when
 150 'payment_receipt_email' configuration option is set.
 151
 152 =cut
 153
 154 sub insert {
 155   my($self, %options) = @_;
 156
 157   local $SIG{HUP} = 'IGNORE';
 158   local $SIG{INT} = 'IGNORE';
 159   local $SIG{QUIT} = 'IGNORE';
 160   local $SIG{TERM} = 'IGNORE';
 161   local $SIG{TSTP} = 'IGNORE';
 162   local $SIG{PIPE} = 'IGNORE';
 163
 164   my $oldAutoCommit = $FS::UID::AutoCommit;
 165   local $FS::UID::AutoCommit = 0;
 166   my $dbh = dbh;
 167
 168   my $cust_bill;
 169   if ( $self->invnum ) {
 170     $cust_bill = qsearchs('cust_bill', { 'invnum' => $self->invnum } )
 171       or do {
 172         $dbh->rollback if $oldAutoCommit;
 173         return "Unknown cust_bill.invnum: ". $self->invnum;
 174       };
 175     $self->custnum($cust_bill->custnum );
 176   }
 177
 178   my $error = $self->check;
 179   return $error if $error;
 180
 181   my $cust_main = $self->cust_main;
 182   my $old_balance = $cust_main->balance;
 183
 184   $error = $self->SUPER::insert;
 185   if ( $error ) {
 186     $dbh->rollback if $oldAutoCommit;
 187     return "error inserting cust_pay: $error";
 188   }
 189
 190   if ( my $credit_type = $conf->config('prepayment_discounts-credit_type') ) {
 191     if ( my $months = $self->discount_term ) {
 192       #hmmm... error handling
 193       my ($credit, $savings, $total) =
 194         $cust_main->discount_term_values($months);
 195       my $cust_credit = new FS::cust_credit {
 196         'custnum' => $self->custnum,
 197         'amount'  => $credit,
 198         'reason'  => 'customer chose to prepay for discount',
 199       };
 200       $error = $cust_credit->insert('reason_type' => $credit_type);
 201       if ( $error ) {
 202         $dbh->rollback if $oldAutoCommit;
 203         return "error inserting cust_pay: $error";
 204       }
 205       my @pkgs = $cust_main->_discount_pkgs_and_bill;
 206       my $cust_bill = shift(@pkgs);
 207       @pkgs = &FS::cust_main::Billing::_discountable_pkgs_at_term($months, @pkgs);
 208       $_->bill($_->last_bill) foreach @pkgs;
 209       $error = $cust_main->bill(
 210         'recurring_only' => 1,
 211         'time'           => $cust_bill->invoice_date,
 212         'no_usage_reset' => 1,
 213         'pkg_list'       => \@pkgs,
 214         'freq_override'   => $months,
 215       );
 216       if ( $error ) {
 217         $dbh->rollback if $oldAutoCommit;
 218         return "error inserting cust_pay: $error";
 219       }
 220       $error = $cust_main->apply_payments_and_credits;
 221       if ( $error ) {
 222         $dbh->rollback if $oldAutoCommit;
 223         return "error inserting cust_pay: $error";
 224       }
 225       my $new_balance = $cust_main->balance;
 226       if ($new_balance > 0) {
 227         $dbh->rollback if $oldAutoCommit;
 228         return "balance after prepay discount attempt: $new_balance";
 229       }
 230
 231     }
 232
 233   }
 234
 235   if ( $self->invnum ) {
 236     my $cust_bill_pay = new FS::cust_bill_pay {
 237       'invnum' => $self->invnum,
 238       'paynum' => $self->paynum,
 239       'amount' => $self->paid,
 240       '_date'  => $self->_date,
 241     };
 242     $error = $cust_bill_pay->insert(%options);
 243     if ( $error ) {
 244       if ( $ignore_noapply ) {
 245         warn "warning: error inserting cust_bill_pay: $error ".
 246              "(ignore_noapply flag set; inserting cust_pay record anyway)\n";
 247       } else {
 248         $dbh->rollback if $oldAutoCommit;
 249         return "error inserting cust_bill_pay: $error";
 250       }
 251     }
 252   }
 253
 254   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 255
 256   #false laziness w/ cust_credit::insert
 257   if ( $unsuspendauto && $old_balance && $cust_main->balance <= 0 ) {
 258     my @errors = $cust_main->unsuspend;
 259     #return
 260     # side-fx with nested transactions?  upstack rolls back?
 261     warn "WARNING:Errors unsuspending customer ". $cust_main->custnum. ": ".
 262          join(' / ', @errors)
 263       if @errors;
 264   }
 265   #eslaf
 266
 267   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 268
 269   #payment receipt
 270   my $trigger = $conf->config('payment_receipt-trigger') || 'cust_pay';
 271   if ( $trigger eq 'cust_pay' ) {
 272     my $error = $self->send_receipt(
 273       'manual'    => $options{'manual'},
 274       'cust_bill' => $cust_bill,
 275       'cust_main' => $cust_main,
 276     );
 277     warn "can't send payment receipt/statement: $error" if $error;
 278   }
 279
 280   '';
 281
 282 }
 283
 284 =item void [ REASON ]
 285
 286 Voids this payment: deletes the payment and all associated applications and
 287 adds a record of the voided payment to the FS::cust_pay_void table.
 288
 289 =cut
 290
 291 sub void {
 292   my $self = shift;
 293
 294   local $SIG{HUP} = 'IGNORE';
 295   local $SIG{INT} = 'IGNORE';
 296   local $SIG{QUIT} = 'IGNORE';
 297   local $SIG{TERM} = 'IGNORE';
 298   local $SIG{TSTP} = 'IGNORE';
 299   local $SIG{PIPE} = 'IGNORE';
 300
 301   my $oldAutoCommit = $FS::UID::AutoCommit;
 302   local $FS::UID::AutoCommit = 0;
 303   my $dbh = dbh;
 304
 305   my $cust_pay_void = new FS::cust_pay_void ( {
 306     map { $_ => $self->get($_) } $self->fields
 307   } );
 308   $cust_pay_void->reason(shift) if scalar(@_);
 309   my $error = $cust_pay_void->insert;
 310   if ( $error ) {
 311     $dbh->rollback if $oldAutoCommit;
 312     return $error;
 313   }
 314
 315   $error = $self->delete;
 316   if ( $error ) {
 317     $dbh->rollback if $oldAutoCommit;
 318     return $error;
 319   }
 320
 321   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 322
 323   '';
 324
 325 }
 326
 327 =item delete
 328
 329 Unless the closed flag is set, deletes this payment and all associated
 330 applications (see L<FS::cust_bill_pay> and L<FS::cust_pay_refund>).  In most
 331 cases, you want to use the void method instead to leave a record of the
 332 deleted payment.
 333
 334 =cut
 335
 336 # very similar to FS::cust_credit::delete
 337 sub delete {
 338   my $self = shift;
 339   return "Can't delete closed payment" if $self->closed =~ /^Y/i;
 340
 341   local $SIG{HUP} = 'IGNORE';
 342   local $SIG{INT} = 'IGNORE';
 343   local $SIG{QUIT} = 'IGNORE';
 344   local $SIG{TERM} = 'IGNORE';
 345   local $SIG{TSTP} = 'IGNORE';
 346   local $SIG{PIPE} = 'IGNORE';
 347
 348   my $oldAutoCommit = $FS::UID::AutoCommit;
 349   local $FS::UID::AutoCommit = 0;
 350   my $dbh = dbh;
 351
 352   foreach my $app ( $self->cust_bill_pay, $self->cust_pay_refund ) {
 353     my $error = $app->delete;
 354     if ( $error ) {
 355       $dbh->rollback if $oldAutoCommit;
 356       return $error;
 357     }
 358   }
 359
 360   my $error = $self->SUPER::delete(@_);
 361   if ( $error ) {
 362     $dbh->rollback if $oldAutoCommit;
 363     return $error;
 364   }
 365
 366   if (    $conf->exists('deletepayments')
 367        && $conf->config('deletepayments') ne '' ) {
 368
 369     my $cust_main = $self->cust_main;
 370
 371     my $error = send_email(
 372       'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
 373                                  #invoice_from??? well as good as any
 374       'to'      => $conf->config('deletepayments'),
 375       'subject' => 'FREESIDE NOTIFICATION: Payment deleted',
 376       'body'    => [
 377         "This is an automatic message from your Freeside installation\n",
 378         "informing you that the following payment has been deleted:\n",
 379         "\n",
 380         'paynum: '. $self->paynum. "\n",
 381         'custnum: '. $self->custnum.
 382           " (". $cust_main->last. ", ". $cust_main->first. ")\n",
 383         'paid: $'. sprintf("%.2f", $self->paid). "\n",
 384         'date: '. time2str("%a %b %e %T %Y", $self->_date). "\n",
 385         'payby: '. $self->payby. "\n",
 386         'payinfo: '. $self->paymask. "\n",
 387         'paybatch: '. $self->paybatch. "\n",
 388       ],
 389     );
 390
 391     if ( $error ) {
 392       $dbh->rollback if $oldAutoCommit;
 393       return "can't send payment deletion notification: $error";
 394     }
 395
 396   }
 397
 398   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 399
 400   '';
 401
 402 }
 403
 404 =item replace OLD_RECORD
 405
 406 You can, but probably shouldn't modify payments...
 407
 408 =cut
 409
 410 sub replace {
 411   #return "Can't modify payment!"
 412   my $self = shift;
 413   return "Can't modify closed payment" if $self->closed =~ /^Y/i;
 414   $self->SUPER::replace(@_);
 415 }
 416
 417 =item check
 418
 419 Checks all fields to make sure this is a valid payment.  If there is an error,
 420 returns the error, otherwise returns false.  Called by the insert method.
 421
 422 =cut
 423
 424 sub check {
 425   my $self = shift;
 426
 427   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 428
 429   my $error =
 430     $self->ut_numbern('paynum')
 431     || $self->ut_numbern('custnum')
 432     || $self->ut_numbern('_date')
 433     || $self->ut_money('paid')
 434     || $self->ut_alphan('otaker')
 435     || $self->ut_textn('paybatch')
 436     || $self->ut_textn('payunique')
 437     || $self->ut_enum('closed', [ '', 'Y' ])
 438     || $self->ut_foreign_keyn('pkgnum', 'cust_pkg', 'pkgnum')
 439     || $self->payinfo_check()
 440     || $self->ut_numbern('discount_term')
 441   ;
 442   return $error if $error;
 443
 444   return "paid must be > 0 " if $self->paid <= 0;
 445
 446   return "unknown cust_main.custnum: ". $self->custnum
 447     unless $self->invnum
 448            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 449
 450   $self->_date(time) unless $self->_date;
 451
 452   return "invalid discount_term"
 453    if ($self->discount_term && $self->discount_term < 2);
 454
 455 #i guess not now, with cust_pay_pending, if we actually make it here, we _do_ want to record it
 456 #  # UNIQUE index should catch this too, without race conditions, but this
 457 #  # should give a better error message the other 99.9% of the time...
 458 #  if ( length($self->payunique)
 459 #       && qsearchs('cust_pay', { 'payunique' => $self->payunique } ) ) {
 460 #    #well, it *could* be a better error message
 461 #    return "duplicate transaction".
 462 #           " - a payment with unique identifer ". $self->payunique.
 463 #           " already exists";
 464 #  }
 465
 466   $self->SUPER::check;
 467 }
 468
 469 =item send_receipt HASHREF | OPTION => VALUE ...
 470
 471 Sends a payment receipt for this payment..
 472
 473 Available options:
 474
 475 =over 4
 476
 477 =item manual
 478
 479 Flag indicating the payment is being made manually.
 480
 481 =item cust_bill
 482
 483 Invoice (FS::cust_bill) object.  If not specified, the most recent invoice
 484 will be assumed.
 485
 486 =item cust_main
 487
 488 Customer (FS::cust_main) object (for efficiency).
 489
 490 =back
 491
 492 =cut
 493
 494 sub send_receipt {
 495   my $self = shift;
 496   my $opt = ref($_[0]) ? shift : { @_ };
 497
 498   my $cust_bill = $opt->{'cust_bill'};
 499   my $cust_main = $opt->{'cust_main'} || $self->cust_main;
 500
 501   my $conf = new FS::Conf;
 502
 503   return '' unless $conf->exists('payment_receipt');
 504
 505   my @invoicing_list = $cust_main->invoicing_list_emailonly;
 506   return '' unless @invoicing_list;
 507
 508   $cust_bill ||= ($cust_main->cust_bill)[-1]; #rather inefficient though?
 509
 510   my $error = '';
 511
 512   if (    ( exists($opt->{'manual'}) && $opt->{'manual'} )
 513        || ! $conf->exists('invoice_html_statement')
 514        || ! $cust_bill
 515      )
 516   {
 517
 518     if ( $conf->exists('payment_receipt_msgnum')
 519          && $conf->config('payment_receipt_msgnum')
 520        )
 521     {
 522       my $msg_template =
 523           FS::msg_template->by_key($conf->config('payment_receipt_msgnum'));
 524       $error = $msg_template->send('cust_main'=> $cust_main, 'object'=> $self);
 525
 526     } elsif ( $conf->exists('payment_receipt_email') ) {
 527
 528       my $receipt_template = new Text::Template (
 529         TYPE   => 'ARRAY',
 530         SOURCE => [ map "$_\n", $conf->config('payment_receipt_email') ],
 531       ) or do {
 532         warn "can't create payment receipt template: $Text::Template::ERROR";
 533         return '';
 534       };
 535
 536       my $payby = $self->payby;
 537       my $payinfo = $self->payinfo;
 538       $payby =~ s/^BILL$/Check/ if $payinfo;
 539       if ( $payby eq 'CARD' || $payby eq 'CHEK' ) {
 540         $payinfo = $self->paymask
 541       } else {
 542         $payinfo = $self->decrypt($payinfo);
 543       }
 544       $payby =~ s/^CHEK$/Electronic check/;
 545
 546       my %fill_in = (
 547         'date'         => time2str("%a %B %o, %Y", $self->_date),
 548         'name'         => $cust_main->name,
 549         'paynum'       => $self->paynum,
 550         'paid'         => sprintf("%.2f", $self->paid),
 551         'payby'        => ucfirst(lc($payby)),
 552         'payinfo'      => $payinfo,
 553         'balance'      => $cust_main->balance,
 554         'company_name' => $conf->config('company_name', $cust_main->agentnum),
 555       );
 556
 557       if ( $opt->{'cust_pkg'} ) {
 558         $fill_in{'pkg'} = $opt->{'cust_pkg'}->part_pkg->pkg;
 559         #setup date, other things?
 560       }
 561
 562       $error = send_email(
 563         'from'    => $conf->config('invoice_from', $cust_main->agentnum),
 564                                    #invoice_from??? well as good as any
 565         'to'      => \@invoicing_list,
 566         'subject' => 'Payment receipt',
 567         'body'    => [ $receipt_template->fill_in( HASH => \%fill_in ) ],
 568       );
 569
 570     } else {
 571
 572       warn "payment_receipt is on, but no payment_receipt_msgnum or invoice_html_statement is configured\n";
 573
 574     }
 575
 576   } else { #not manual
 577
 578     my $queue = new FS::queue {
 579        'paynum' => $self->paynum,
 580        'job'    => 'FS::cust_bill::queueable_email',
 581     };
 582
 583     $error = $queue->insert(
 584       'invnum'   => $cust_bill->invnum,
 585       'template' => 'statement',
 586     );
 587
 588   }
 589
 590     warn "send_receipt: $error\n" if $error;
 591 }
 592
 593 =item cust_bill_pay
 594
 595 Returns all applications to invoices (see L<FS::cust_bill_pay>) for this
 596 payment.
 597
 598 =cut
 599
 600 sub cust_bill_pay {
 601   my $self = shift;
 602   map { $_ } #return $self->num_cust_bill_pay unless wantarray;
 603   sort {    $a->_date  <=> $b->_date
 604          || $a->invnum <=> $b->invnum }
 605     qsearch( 'cust_bill_pay', { 'paynum' => $self->paynum } )
 606   ;
 607 }
 608
 609 =item cust_pay_refund
 610
 611 Returns all applications of refunds (see L<FS::cust_pay_refund>) to this
 612 payment.
 613
 614 =cut
 615
 616 sub cust_pay_refund {
 617   my $self = shift;
 618   map { $_ } #return $self->num_cust_pay_refund unless wantarray;
 619   sort { $a->_date <=> $b->_date }
 620     qsearch( 'cust_pay_refund', { 'paynum' => $self->paynum } )
 621   ;
 622 }
 623
 624
 625 =item unapplied
 626
 627 Returns the amount of this payment that is still unapplied; which is
 628 paid minus all payment applications (see L<FS::cust_bill_pay>) and refund
 629 applications (see L<FS::cust_pay_refund>).
 630
 631 =cut
 632
 633 sub unapplied {
 634   my $self = shift;
 635   my $amount = $self->paid;
 636   $amount -= $_->amount foreach ( $self->cust_bill_pay );
 637   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 638   sprintf("%.2f", $amount );
 639 }
 640
 641 =item unrefunded
 642
 643 Returns the amount of this payment that has not been refuned; which is
 644 paid minus all  refund applications (see L<FS::cust_pay_refund>).
 645
 646 =cut
 647
 648 sub unrefunded {
 649   my $self = shift;
 650   my $amount = $self->paid;
 651   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 652   sprintf("%.2f", $amount );
 653 }
 654
 655 =item amount
 656
 657 Returns the "paid" field.
 658
 659 =cut
 660
 661 sub amount {
 662   my $self = shift;
 663   $self->paid();
 664 }
 665
 666 =back
 667
 668 =head1 CLASS METHODS
 669
 670 =over 4
 671
 672 =item batch_insert CUST_PAY_OBJECT, ...
 673
 674 Class method which inserts multiple payments.  Takes a list of FS::cust_pay
 675 objects.  Returns a list, each element representing the status of inserting the
 676 corresponding payment - empty.  If there is an error inserting any payment, the
 677 entire transaction is rolled back, i.e. all payments are inserted or none are.
 678
 679 For example:
 680
 681   my @errors = FS::cust_pay->batch_insert(@cust_pay);
 682   my $num_errors = scalar(grep $_, @errors);
 683   if ( $num_errors == 0 ) {
 684     #success; all payments were inserted
 685   } else {
 686     #failure; no payments were inserted.
 687   }
 688
 689 =cut
 690
 691 sub batch_insert {
 692   my $self = shift; #class method
 693
 694   local $SIG{HUP} = 'IGNORE';
 695   local $SIG{INT} = 'IGNORE';
 696   local $SIG{QUIT} = 'IGNORE';
 697   local $SIG{TERM} = 'IGNORE';
 698   local $SIG{TSTP} = 'IGNORE';
 699   local $SIG{PIPE} = 'IGNORE';
 700
 701   my $oldAutoCommit = $FS::UID::AutoCommit;
 702   local $FS::UID::AutoCommit = 0;
 703   my $dbh = dbh;
 704
 705   my $errors = 0;
 706
 707   my @errors = map {
 708     my $error = $_->insert( 'manual' => 1 );
 709     if ( $error ) {
 710       $errors++;
 711     } else {
 712       $_->cust_main->apply_payments;
 713     }
 714     $error;
 715   } @_;
 716
 717   if ( $errors ) {
 718     $dbh->rollback if $oldAutoCommit;
 719   } else {
 720     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 721   }
 722
 723   @errors;
 724
 725 }
 726
 727 =item unapplied_sql
 728
 729 Returns an SQL fragment to retreive the unapplied amount.
 730
 731 =cut
 732
 733 sub unapplied_sql {
 734   my ($class, $start, $end) = @_;
 735   my $bill_start   = $start ? "AND cust_bill_pay._date <= $start"   : '';
 736   my $bill_end     = $end   ? "AND cust_bill_pay._date > $end"     : '';
 737   my $refund_start = $start ? "AND cust_pay_refund._date <= $start" : '';
 738   my $refund_end   = $end   ? "AND cust_pay_refund._date > $end"   : '';
 739
 740   "paid
 741         - COALESCE(
 742                     ( SELECT SUM(amount) FROM cust_bill_pay
 743                         WHERE cust_pay.paynum = cust_bill_pay.paynum
 744                         $bill_start $bill_end )
 745                     ,0
 746                   )
 747         - COALESCE(
 748                     ( SELECT SUM(amount) FROM cust_pay_refund
 749                         WHERE cust_pay.paynum = cust_pay_refund.paynum
 750                         $refund_start $refund_end )
 751                     ,0
 752                   )
 753   ";
 754
 755 }
 756
 757 # _upgrade_data
 758 #
 759 # Used by FS::Upgrade to migrate to a new database.
 760
 761 use FS::h_cust_pay;
 762
 763 sub _upgrade_data {  #class method
 764   my ($class, %opts) = @_;
 765
 766   warn "$me upgrading $class\n" if $DEBUG;
 767
 768   ##
 769   # otaker/ivan upgrade
 770   ##
 771
 772   #not the most efficient, but hey, it only has to run once
 773
 774   my $where = "WHERE ( otaker IS NULL OR otaker = '' OR otaker = 'ivan' ) ".
 775               "  AND usernum IS NULL ".
 776               "  AND 0 < ( SELECT COUNT(*) FROM cust_main                 ".
 777               "              WHERE cust_main.custnum = cust_pay.custnum ) ";
 778
 779   my $count_sql = "SELECT COUNT(*) FROM cust_pay $where";
 780
 781   my $sth = dbh->prepare($count_sql) or die dbh->errstr;
 782   $sth->execute or die $sth->errstr;
 783   my $total = $sth->fetchrow_arrayref->[0];
 784   #warn "$total cust_pay records to update\n"
 785   #  if $DEBUG;
 786   local($DEBUG) = 2 if $total > 1000; #could be a while, force progress info
 787
 788   my $count = 0;
 789   my $lastprog = 0;
 790
 791   my @cust_pay = qsearch( {
 792       'table'     => 'cust_pay',
 793       'hashref'   => {},
 794       'extra_sql' => $where,
 795       'order_by'  => 'ORDER BY paynum',
 796   } );
 797
 798   foreach my $cust_pay (@cust_pay) {
 799
 800     my $h_cust_pay = $cust_pay->h_search('insert');
 801     if ( $h_cust_pay ) {
 802       next if $cust_pay->otaker eq $h_cust_pay->history_user;
 803       $cust_pay->otaker($h_cust_pay->history_user);
 804     } else {
 805       $cust_pay->otaker('legacy');
 806     }
 807
 808     delete $FS::payby::hash{'COMP'}->{cust_pay}; #quelle kludge
 809     my $error = $cust_pay->replace;
 810
 811     if ( $error ) {
 812       warn " *** WARNING: Error updating order taker for payment paynum ".
 813            $cust_pay->paynun. ": $error\n";
 814       next;
 815     }
 816
 817     $FS::payby::hash{'COMP'}->{cust_pay} = ''; #restore it
 818
 819     $count++;
 820     if ( $DEBUG > 1 && $lastprog + 30 < time ) {
 821       warn "$me $count/$total (". sprintf('%.2f',100*$count/$total). '%)'. "\n";
 822       $lastprog = time;
 823     }
 824
 825   }
 826
 827   ###
 828   # payinfo N/A upgrade
 829   ###
 830
 831   #XXX remove the 'N/A (tokenized)' part (or just this entire thing)
 832
 833   my @na_cust_pay = qsearch( {
 834     'table'     => 'cust_pay',
 835     'hashref'   => {}, #could be encrypted# { 'payinfo' => 'N/A' },
 836     'extra_sql' => "WHERE ( payinfo = 'N/A' OR paymask = 'N/AA' OR paymask = 'N/A (tokenized)' ) AND payby IN ( 'CARD', 'CHEK' )",
 837   } );
 838
 839   foreach my $na ( @na_cust_pay ) {
 840
 841     next unless $na->payinfo eq 'N/A';
 842
 843     my $cust_pay_pending =
 844       qsearchs('cust_pay_pending', { 'paynum' => $na->paynum } );
 845     unless ( $cust_pay_pending ) {
 846       warn " *** WARNING: not-yet recoverable N/A card for payment ".
 847            $na->paynum. " (no cust_pay_pending)\n";
 848       next;
 849     }
 850     $na->$_($cust_pay_pending->$_) for qw( payinfo paymask );
 851     my $error = $na->replace;
 852     if ( $error ) {
 853       warn " *** WARNING: Error updating payinfo for payment paynum ".
 854            $na->paynun. ": $error\n";
 855       next;
 856     }
 857
 858   }
 859
 860   ###
 861   # otaker->usernum upgrade
 862   ###
 863
 864   delete $FS::payby::hash{'COMP'}->{cust_pay}; #quelle kludge
 865   $class->_upgrade_otaker(%opts);
 866   $FS::payby::hash{'COMP'}->{cust_pay} = ''; #restore it
 867
 868 }
 869
 870 =back
 871
 872 =head1 SUBROUTINES
 873
 874 =over 4
 875
 876 =item batch_import HASHREF
 877
 878 Inserts new payments.
 879
 880 =cut
 881
 882 sub batch_import {
 883   my $param = shift;
 884
 885   my $fh = $param->{filehandle};
 886   my $agentnum = $param->{agentnum};
 887   my $format = $param->{'format'};
 888   my $paybatch = $param->{'paybatch'};
 889
 890   # here is the agent virtualization
 891   my $extra_sql = ' AND '. $FS::CurrentUser::CurrentUser->agentnums_sql;
 892
 893   my @fields;
 894   my $payby;
 895   if ( $format eq 'simple' ) {
 896     @fields = qw( custnum agent_custid paid payinfo );
 897     $payby = 'BILL';
 898   } elsif ( $format eq 'extended' ) {
 899     die "unimplemented\n";
 900     @fields = qw( );
 901     $payby = 'BILL';
 902   } else {
 903     die "unknown format $format";
 904   }
 905
 906   eval "use Text::CSV_XS;";
 907   die $@ if $@;
 908
 909   my $csv = new Text::CSV_XS;
 910
 911   my $imported = 0;
 912
 913   local $SIG{HUP} = 'IGNORE';
 914   local $SIG{INT} = 'IGNORE';
 915   local $SIG{QUIT} = 'IGNORE';
 916   local $SIG{TERM} = 'IGNORE';
 917   local $SIG{TSTP} = 'IGNORE';
 918   local $SIG{PIPE} = 'IGNORE';
 919
 920   my $oldAutoCommit = $FS::UID::AutoCommit;
 921   local $FS::UID::AutoCommit = 0;
 922   my $dbh = dbh;
 923
 924   my $line;
 925   while ( defined($line=<$fh>) ) {
 926
 927     $csv->parse($line) or do {
 928       $dbh->rollback if $oldAutoCommit;
 929       return "can't parse: ". $csv->error_input();
 930     };
 931
 932     my @columns = $csv->fields();
 933
 934     my %cust_pay = (
 935       payby    => $payby,
 936       paybatch => $paybatch,
 937     );
 938
 939     my $cust_main;
 940     foreach my $field ( @fields ) {
 941
 942       if ( $field eq 'agent_custid'
 943         && $agentnum
 944         && $columns[0] =~ /\S+/ )
 945       {
 946
 947         my $agent_custid = $columns[0];
 948         my %hash = ( 'agent_custid' => $agent_custid,
 949                      'agentnum'     => $agentnum,
 950                    );
 951
 952         if ( $cust_pay{'custnum'} !~ /^\s*$/ ) {
 953           $dbh->rollback if $oldAutoCommit;
 954           return "can't specify custnum with agent_custid $agent_custid";
 955         }
 956
 957         $cust_main = qsearchs({
 958                                 'table'     => 'cust_main',
 959                                 'hashref'   => \%hash,
 960                                 'extra_sql' => $extra_sql,
 961                              });
 962
 963         unless ( $cust_main ) {
 964           $dbh->rollback if $oldAutoCommit;
 965           return "can't find customer with agent_custid $agent_custid";
 966         }
 967
 968         $field = 'custnum';
 969         $columns[0] = $cust_main->custnum;
 970       }
 971
 972       $cust_pay{$field} = shift @columns;
 973     }
 974
 975     my $cust_pay = new FS::cust_pay( \%cust_pay );
 976     my $error = $cust_pay->insert;
 977
 978     if ( $error ) {
 979       $dbh->rollback if $oldAutoCommit;
 980       return "can't insert payment for $line: $error";
 981     }
 982
 983     if ( $format eq 'simple' ) {
 984       # include agentnum for less surprise?
 985       $cust_main = qsearchs({
 986                              'table'     => 'cust_main',
 987                              'hashref'   => { 'custnum' => $cust_pay->custnum },
 988                              'extra_sql' => $extra_sql,
 989                            })
 990         unless $cust_main;
 991
 992       unless ( $cust_main ) {
 993         $dbh->rollback if $oldAutoCommit;
 994         return "can't find customer to which payments apply at line: $line";
 995       }
 996
 997       $error = $cust_main->apply_payments_and_credits;
 998       if ( $error ) {
 999         $dbh->rollback if $oldAutoCommit;
1000         return "can't apply payments to customer for $line: $error";
1001       }
1002
1003     }
1004
1005     $imported++;
1006   }
1007
1008   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1009
1010   return "Empty file!" unless $imported;
1011
1012   ''; #no error
1013
1014 }
1015
1016 =back
1017
1018 =head1 BUGS
1019
1020 Delete and replace methods.
1021
1022 =head1 SEE ALSO
1023
1024 L<FS::cust_pay_pending>, L<FS::cust_bill_pay>, L<FS::cust_bill>, L<FS::Record>,
1025 schema.html from the base documentation.
1026
1027 =cut
1028
1029 1;
1030