FS/FS/cust_pay.pm

   1 package FS::cust_pay;
   2
   3 use strict;
   4 use vars qw( @ISA $conf $unsuspendauto );
   5 use Date::Format;
   6 use Business::CreditCard;
   7 use Text::Template;
   8 use FS::Record qw( dbh qsearch qsearchs );
   9 use FS::Misc qw(send_email);
  10 use FS::cust_bill;
  11 use FS::cust_bill_pay;
  12 use FS::cust_pay_refund;
  13 use FS::cust_main;
  14 use FS::cust_pay_void;
  15
  16 @ISA = qw( FS::Record );
  17
  18 #ask FS::UID to run this stuff for us later
  19 FS::UID->install_callback( sub {
  20   $conf = new FS::Conf;
  21   $unsuspendauto = $conf->exists('unsuspendauto');
  22 } );
  23
  24 =head1 NAME
  25
  26 FS::cust_pay - Object methods for cust_pay objects
  27
  28 =head1 SYNOPSIS
  29
  30   use FS::cust_pay;
  31
  32   $record = new FS::cust_pay \%hash;
  33   $record = new FS::cust_pay { 'column' => 'value' };
  34
  35   $error = $record->insert;
  36
  37   $error = $new_record->replace($old_record);
  38
  39   $error = $record->delete;
  40
  41   $error = $record->check;
  42
  43 =head1 DESCRIPTION
  44
  45 An FS::cust_pay object represents a payment; the transfer of money from a
  46 customer.  FS::cust_pay inherits from FS::Record.  The following fields are
  47 currently supported:
  48
  49 =over 4
  50
  51 =item paynum - primary key (assigned automatically for new payments)
  52
  53 =item custnum - customer (see L<FS::cust_main>)
  54
  55 =item paid - Amount of this payment
  56
  57 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  58 L<Time::Local> and L<Date::Parse> for conversion functions.
  59
  60 =item payby - `CARD' (credit cards), `CHEK' (electronic check/ACH),
  61 `LECB' (phone bill billing), `BILL' (billing), or `COMP' (free)
  62
  63 =item payinfo - card number, check #, or comp issuer (4-8 lowercase alphanumerics; think username), respectively
  64
  65 =item paybatch - text field for tracking card processing
  66
  67 =item closed - books closed flag, empty or `Y'
  68
  69 =back
  70
  71 =head1 METHODS
  72
  73 =over 4
  74
  75 =item new HASHREF
  76
  77 Creates a new payment.  To add the payment to the databse, see L<"insert">.
  78
  79 =cut
  80
  81 sub table { 'cust_pay'; }
  82
  83 =item insert
  84
  85 Adds this payment to the database.
  86
  87 For backwards-compatibility and convenience, if the additional field invnum
  88 is defined, an FS::cust_bill_pay record for the full amount of the payment
  89 will be created.  In this case, custnum is optional.
  90
  91 =cut
  92
  93 sub insert {
  94   my $self = shift;
  95
  96   local $SIG{HUP} = 'IGNORE';
  97   local $SIG{INT} = 'IGNORE';
  98   local $SIG{QUIT} = 'IGNORE';
  99   local $SIG{TERM} = 'IGNORE';
 100   local $SIG{TSTP} = 'IGNORE';
 101   local $SIG{PIPE} = 'IGNORE';
 102
 103   my $oldAutoCommit = $FS::UID::AutoCommit;
 104   local $FS::UID::AutoCommit = 0;
 105   my $dbh = dbh;
 106
 107   if ( $self->invnum ) {
 108     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $self->invnum } )
 109       or do {
 110         $dbh->rollback if $oldAutoCommit;
 111         return "Unknown cust_bill.invnum: ". $self->invnum;
 112       };
 113     $self->custnum($cust_bill->custnum );
 114   }
 115
 116   my $cust_main = $self->cust_main;
 117   my $old_balance = $cust_main->balance;
 118
 119   my $error = $self->check;
 120   return $error if $error;
 121
 122   $error = $self->SUPER::insert;
 123   if ( $error ) {
 124     $dbh->rollback if $oldAutoCommit;
 125     return "error inserting $self: $error";
 126   }
 127
 128   if ( $self->invnum ) {
 129     my $cust_bill_pay = new FS::cust_bill_pay {
 130       'invnum' => $self->invnum,
 131       'paynum' => $self->paynum,
 132       'amount' => $self->paid,
 133       '_date'  => $self->_date,
 134     };
 135     $error = $cust_bill_pay->insert;
 136     if ( $error ) {
 137       $dbh->rollback if $oldAutoCommit;
 138       return "error inserting $cust_bill_pay: $error";
 139     }
 140   }
 141
 142   if ( $self->paybatch =~ /^webui-/ ) {
 143     my @cust_pay = qsearch('cust_pay', {
 144       'custnum' => $self->custnum,
 145       'paybatch' => $self->paybatch,
 146     } );
 147     if ( scalar(@cust_pay) > 1 ) {
 148       $dbh->rollback if $oldAutoCommit;
 149       return "a payment with webui token ". $self->paybatch. " already exists";
 150     }
 151   }
 152
 153   #false laziness w/ cust_credit::insert
 154   if ( $unsuspendauto && $old_balance && $cust_main->balance <= 0 ) {
 155     my @errors = $cust_main->unsuspend;
 156     #return
 157     # side-fx with nested transactions?  upstack rolls back?
 158     warn "WARNING:Errors unsuspending customer ". $cust_main->custnum. ": ".
 159          join(' / ', @errors)
 160       if @errors;
 161   }
 162   #eslaf
 163
 164   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 165
 166   #my $cust_main = $self->cust_main;
 167   if ( $conf->exists('payment_receipt_email')
 168        && grep { $_ ne 'POST' } $cust_main->invoicing_list
 169   ) {
 170
 171     my $receipt_template = new Text::Template (
 172       TYPE   => 'ARRAY',
 173       SOURCE => [ map "$_\n", $conf->config('payment_receipt_email') ],
 174     ) or do {
 175       warn "can't create payment receipt template: $Text::Template::ERROR";
 176       return '';
 177     };
 178
 179     my @invoicing_list = grep { $_ ne 'POST' } $cust_main->invoicing_list;
 180
 181     my $payby = $self->payby;
 182     my $payinfo = $self->payinfo;
 183     $payby =~ s/^BILL$/Check/ if $payinfo;
 184     $payinfo = $self->payinfo_masked if $payby eq 'CARD';
 185
 186     my $error = send_email(
 187       'from'    => $conf->config('invoice_from'), #??? well as good as any
 188       'to'      => \@invoicing_list,
 189       'subject' => 'Payment receipt',
 190       'body'    => [ $receipt_template->fill_in( HASH => {
 191                        'date'    => time2str("%a %B %o, %Y", $self->_date),
 192                        'name'    => $cust_main->name,
 193                        'paynum'  => $self->paynum,
 194                        'paid'    => sprintf("%.2f", $self->paid),
 195                        'payby'   => ucfirst(lc($payby)),
 196                        'payinfo' => $payinfo,
 197                        'balance' => $cust_main->balance,
 198                    } ) ],
 199     );
 200     if ( $error ) {
 201       warn "can't send payment receipt: $error";
 202     }
 203
 204   }
 205
 206   '';
 207
 208 }
 209
 210 =item void [ REASON ]
 211
 212 Voids this payment: deletes the payment and all associated applications and
 213 adds a record of the voided payment to the FS::cust_pay_void table.
 214
 215 =cut
 216
 217 sub void {
 218   my $self = shift;
 219
 220   local $SIG{HUP} = 'IGNORE';
 221   local $SIG{INT} = 'IGNORE';
 222   local $SIG{QUIT} = 'IGNORE';
 223   local $SIG{TERM} = 'IGNORE';
 224   local $SIG{TSTP} = 'IGNORE';
 225   local $SIG{PIPE} = 'IGNORE';
 226
 227   my $oldAutoCommit = $FS::UID::AutoCommit;
 228   local $FS::UID::AutoCommit = 0;
 229   my $dbh = dbh;
 230
 231   my $cust_pay_void = new FS::cust_pay_void ( {
 232     map { $_ => $self->get($_) } $self->fields
 233   } );
 234   $cust_pay_void->reason(shift) if scalar(@_);
 235   my $error = $cust_pay_void->insert;
 236   if ( $error ) {
 237     $dbh->rollback if $oldAutoCommit;
 238     return $error;
 239   }
 240
 241   $error = $self->delete;
 242   if ( $error ) {
 243     $dbh->rollback if $oldAutoCommit;
 244     return $error;
 245   }
 246
 247   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 248
 249   '';
 250
 251 }
 252
 253 =item delete
 254
 255 Deletes this payment and all associated applications (see L<FS::cust_bill_pay>),
 256 unless the closed flag is set.  In most cases, you want to use the void
 257 method instead to leave a record of the deleted payment.
 258
 259 =cut
 260
 261 sub delete {
 262   my $self = shift;
 263   return "Can't delete closed payment" if $self->closed =~ /^Y/i;
 264
 265   local $SIG{HUP} = 'IGNORE';
 266   local $SIG{INT} = 'IGNORE';
 267   local $SIG{QUIT} = 'IGNORE';
 268   local $SIG{TERM} = 'IGNORE';
 269   local $SIG{TSTP} = 'IGNORE';
 270   local $SIG{PIPE} = 'IGNORE';
 271
 272   my $oldAutoCommit = $FS::UID::AutoCommit;
 273   local $FS::UID::AutoCommit = 0;
 274   my $dbh = dbh;
 275
 276   foreach my $app ( $self->cust_bill_pay, $self->cust_pay_refund ) {
 277     my $error = $app->delete;
 278     if ( $error ) {
 279       $dbh->rollback if $oldAutoCommit;
 280       return $error;
 281     }
 282   }
 283
 284   my $error = $self->SUPER::delete(@_);
 285   if ( $error ) {
 286     $dbh->rollback if $oldAutoCommit;
 287     return $error;
 288   }
 289
 290   if ( $conf->config('deletepayments') ne '' ) {
 291
 292     my $cust_main = $self->cust_main;
 293
 294     my $error = send_email(
 295       'from'    => $conf->config('invoice_from'), #??? well as good as any
 296       'to'      => $conf->config('deletepayments'),
 297       'subject' => 'FREESIDE NOTIFICATION: Payment deleted',
 298       'body'    => [
 299         "This is an automatic message from your Freeside installation\n",
 300         "informing you that the following payment has been deleted:\n",
 301         "\n",
 302         'paynum: '. $self->paynum. "\n",
 303         'custnum: '. $self->custnum.
 304           " (". $cust_main->last. ", ". $cust_main->first. ")\n",
 305         'paid: $'. sprintf("%.2f", $self->paid). "\n",
 306         'date: '. time2str("%a %b %e %T %Y", $self->_date). "\n",
 307         'payby: '. $self->payby. "\n",
 308         'payinfo: '. $self->payinfo. "\n",
 309         'paybatch: '. $self->paybatch. "\n",
 310       ],
 311     );
 312
 313     if ( $error ) {
 314       $dbh->rollback if $oldAutoCommit;
 315       return "can't send payment deletion notification: $error";
 316     }
 317
 318   }
 319
 320   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 321
 322   '';
 323
 324 }
 325
 326 =item replace OLD_RECORD
 327
 328 You probably shouldn't modify payments...
 329
 330 =item check
 331
 332 Checks all fields to make sure this is a valid payment.  If there is an error,
 333 returns the error, otherwise returns false.  Called by the insert method.
 334
 335 =cut
 336
 337 sub check {
 338   my $self = shift;
 339
 340   my $error =
 341     $self->ut_numbern('paynum')
 342     || $self->ut_numbern('custnum')
 343     || $self->ut_money('paid')
 344     || $self->ut_numbern('_date')
 345     || $self->ut_textn('paybatch')
 346     || $self->ut_enum('closed', [ '', 'Y' ])
 347   ;
 348   return $error if $error;
 349
 350   return "paid must be > 0 " if $self->paid <= 0;
 351
 352   return "unknown cust_main.custnum: ". $self->custnum
 353     unless $self->invnum
 354            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 355
 356   $self->_date(time) unless $self->_date;
 357
 358   $self->payby =~ /^(CARD|CHEK|LECB|BILL|COMP)$/ or return "Illegal payby";
 359   $self->payby($1);
 360
 361   #false laziness with cust_refund::check
 362   if ( $self->payby eq 'CARD' ) {
 363     my $payinfo = $self->payinfo;
 364     $payinfo =~ s/\D//g;
 365     $self->payinfo($payinfo);
 366     if ( $self->payinfo ) {
 367       $self->payinfo =~ /^(\d{13,16})$/
 368         or return "Illegal (mistyped?) credit card number (payinfo)";
 369       $self->payinfo($1);
 370       validate($self->payinfo) or return "Illegal credit card number";
 371       return "Unknown card type" if cardtype($self->payinfo) eq "Unknown";
 372     } else {
 373       $self->payinfo('N/A');
 374     }
 375
 376   } else {
 377     $error = $self->ut_textn('payinfo');
 378     return $error if $error;
 379   }
 380
 381   $self->SUPER::check;
 382 }
 383
 384 =item cust_bill_pay
 385
 386 Returns all applications to invoices (see L<FS::cust_bill_pay>) for this
 387 payment.
 388
 389 =cut
 390
 391 sub cust_bill_pay {
 392   my $self = shift;
 393   sort {    $a->_date  <=> $b->_date
 394          || $a->invnum <=> $b->invnum }
 395     qsearch( 'cust_bill_pay', { 'paynum' => $self->paynum } )
 396   ;
 397 }
 398
 399 =item cust_pay_refund
 400
 401 Returns all applications of refunds (see L<FS::cust_pay_refund>) to this
 402 payment.
 403
 404 =cut
 405
 406 sub cust_pay_refund {
 407   my $self = shift;
 408   sort { $a->_date <=> $b->_date }
 409     qsearch( 'cust_pay_refund', { 'paynum' => $self->paynum } )
 410   ;
 411 }
 412
 413
 414 =item unapplied
 415
 416 Returns the amount of this payment that is still unapplied; which is
 417 paid minus all payment applications (see L<FS::cust_bill_pay>) and refund
 418 applications (see L<FS::cust_pay_refund>).
 419
 420 =cut
 421
 422 sub unapplied {
 423   my $self = shift;
 424   my $amount = $self->paid;
 425   $amount -= $_->amount foreach ( $self->cust_bill_pay );
 426   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 427   sprintf("%.2f", $amount );
 428 }
 429
 430 =item unrefunded
 431
 432 Returns the amount of this payment that has not been refuned; which is
 433 paid minus all  refund applications (see L<FS::cust_pay_refund>).
 434
 435 =cut
 436
 437 sub unrefunded {
 438   my $self = shift;
 439   my $amount = $self->paid;
 440   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 441   sprintf("%.2f", $amount );
 442 }
 443
 444
 445 =item cust_main
 446
 447 Returns the parent customer object (see L<FS::cust_main>).
 448
 449 =cut
 450
 451 sub cust_main {
 452   my $self = shift;
 453   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 454 }
 455
 456 =item payinfo_masked
 457
 458 Returns a "masked" payinfo field with all but the last four characters replaced
 459 by 'x'es.  Useful for displaying credit cards.
 460
 461 =cut
 462
 463 sub payinfo_masked {
 464   my $self = shift;
 465   my $payinfo = $self->payinfo;
 466   'x'x(length($payinfo)-4). substr($payinfo,(length($payinfo)-4));
 467 }
 468
 469 =back
 470
 471 =head1 BUGS
 472
 473 Delete and replace methods.  payinfo_masked false laziness with cust_main.pm
 474 and cust_refund.pm
 475
 476 =head1 SEE ALSO
 477
 478 L<FS::cust_bill_pay>, L<FS::cust_bill>, L<FS::Record>, schema.html from the
 479 base documentation.
 480
 481 =cut
 482
 483 1;
 484