FS/FS/cust_pay.pm

   1 package FS::cust_pay;
   2
   3 use strict;
   4 use vars qw( @ISA $conf $unsuspendauto );
   5 use Date::Format;
   6 use Business::CreditCard;
   7 use Text::Template;
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( dbh qsearch qsearchs dbh );
  10 use FS::Misc qw(send_email);
  11 use FS::cust_bill;
  12 use FS::cust_bill_pay;
  13 use FS::cust_pay_refund;
  14 use FS::cust_main;
  15
  16 @ISA = qw( FS::Record );
  17
  18 #ask FS::UID to run this stuff for us later
  19 FS::UID->install_callback( sub {
  20   $conf = new FS::Conf;
  21   $unsuspendauto = $conf->exists('unsuspendauto');
  22 } );
  23
  24 =head1 NAME
  25
  26 FS::cust_pay - Object methods for cust_pay objects
  27
  28 =head1 SYNOPSIS
  29
  30   use FS::cust_pay;
  31
  32   $record = new FS::cust_pay \%hash;
  33   $record = new FS::cust_pay { 'column' => 'value' };
  34
  35   $error = $record->insert;
  36
  37   $error = $new_record->replace($old_record);
  38
  39   $error = $record->delete;
  40
  41   $error = $record->check;
  42
  43 =head1 DESCRIPTION
  44
  45 An FS::cust_pay object represents a payment; the transfer of money from a
  46 customer.  FS::cust_pay inherits from FS::Record.  The following fields are
  47 currently supported:
  48
  49 =over 4
  50
  51 =item paynum - primary key (assigned automatically for new payments)
  52
  53 =item custnum - customer (see L<FS::cust_main>)
  54
  55 =item paid - Amount of this payment
  56
  57 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  58 L<Time::Local> and L<Date::Parse> for conversion functions.
  59
  60 =item payby - `CARD' (credit cards), `CHEK' (electronic check/ACH),
  61 `LECB' (phone bill billing), `BILL' (billing), or `COMP' (free)
  62
  63 =item payinfo - card number, check #, or comp issuer (4-8 lowercase alphanumerics; think username), respectively
  64
  65 =item paybatch - text field for tracking card processing
  66
  67 =item closed - books closed flag, empty or `Y'
  68
  69 =back
  70
  71 =head1 METHODS
  72
  73 =over 4
  74
  75 =item new HASHREF
  76
  77 Creates a new payment.  To add the payment to the databse, see L<"insert">.
  78
  79 =cut
  80
  81 sub table { 'cust_pay'; }
  82
  83 =item insert
  84
  85 Adds this payment to the database.
  86
  87 For backwards-compatibility and convenience, if the additional field invnum
  88 is defined, an FS::cust_bill_pay record for the full amount of the payment
  89 will be created.  In this case, custnum is optional.
  90
  91 =cut
  92
  93 sub insert {
  94   my $self = shift;
  95
  96   local $SIG{HUP} = 'IGNORE';
  97   local $SIG{INT} = 'IGNORE';
  98   local $SIG{QUIT} = 'IGNORE';
  99   local $SIG{TERM} = 'IGNORE';
 100   local $SIG{TSTP} = 'IGNORE';
 101   local $SIG{PIPE} = 'IGNORE';
 102
 103   my $oldAutoCommit = $FS::UID::AutoCommit;
 104   local $FS::UID::AutoCommit = 0;
 105   my $dbh = dbh;
 106
 107   if ( $self->invnum ) {
 108     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $self->invnum } )
 109       or do {
 110         $dbh->rollback if $oldAutoCommit;
 111         return "Unknown cust_bill.invnum: ". $self->invnum;
 112       };
 113     $self->custnum($cust_bill->custnum );
 114   }
 115
 116   my $cust_main = $self->cust_main;
 117   my $old_balance = $cust_main->balance;
 118
 119   my $error = $self->check;
 120   return $error if $error;
 121
 122   $error = $self->SUPER::insert;
 123   if ( $error ) {
 124     $dbh->rollback if $oldAutoCommit;
 125     return "error inserting $self: $error";
 126   }
 127
 128   if ( $self->invnum ) {
 129     my $cust_bill_pay = new FS::cust_bill_pay {
 130       'invnum' => $self->invnum,
 131       'paynum' => $self->paynum,
 132       'amount' => $self->paid,
 133       '_date'  => $self->_date,
 134     };
 135     $error = $cust_bill_pay->insert;
 136     if ( $error ) {
 137       $dbh->rollback if $oldAutoCommit;
 138       return "error inserting $cust_bill_pay: $error";
 139     }
 140   }
 141
 142   if ( $self->paybatch =~ /^webui-/ ) {
 143     my @cust_pay = qsearch('cust_pay', {
 144       'custnum' => $self->custnum,
 145       'paybatch' => $self->paybatch,
 146     } );
 147     if ( scalar(@cust_pay) > 1 ) {
 148       $dbh->rollback if $oldAutoCommit;
 149       return "a payment with webui token ". $self->paybatch. " already exists";
 150     }
 151   }
 152
 153   #false laziness w/ cust_credit::insert
 154   if ( $unsuspendauto && $old_balance && $cust_main->balance <= 0 ) {
 155     my @errors = $cust_main->unsuspend;
 156     #return
 157     # side-fx with nested transactions?  upstack rolls back?
 158     warn "WARNING:Errors unsuspending customer ". $cust_main->custnum. ": ".
 159          join(' / ', @errors)
 160       if @errors;
 161   }
 162   #eslaf
 163
 164   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 165
 166   #my $cust_main = $self->cust_main;
 167   if ( $conf->exists('payment_receipt_email')
 168        && grep { $_ ne 'POST' } $cust_main->invoicing_list
 169   ) {
 170
 171     my $receipt_template = new Text::Template (
 172       TYPE   => 'ARRAY',
 173       SOURCE => [ map "$_\n", $conf->config('payment_receipt_email') ],
 174     ) or do {
 175       warn "can't create payment receipt template: $Text::Template::ERROR";
 176       return '';
 177     };
 178
 179     my @invoicing_list = grep { $_ ne 'POST' } $cust_main->invoicing_list;
 180
 181     my $payby = $self->payby;
 182     my $payinfo = $self->payinfo;
 183     $payby =~ s/^BILL$/Check/ if $payinfo;
 184     $payinfo = $self->payinfo_masked if $payby eq 'CARD';
 185
 186     my $error = send_email(
 187       'from'    => $conf->config('invoice_from'), #??? well as good as any
 188       'to'      => \@invoicing_list,
 189       'subject' => 'Payment receipt',
 190       'body'    => [ $receipt_template->fill_in( HASH => {
 191                        'date'    => time2str("%a %B %o, %Y", $self->_date),
 192                        'name'    => $cust_main->name,
 193                        'paynum'  => $self->paynum,
 194                        'paid'    => sprintf("%.2f", $self->paid),
 195                        'payby'   => ucfirst(lc($payby)),
 196                        'payinfo' => $payinfo,
 197                        'balance' => $cust_main->balance,
 198                    } ) ],
 199     );
 200     if ( $error ) {
 201       warn "can't send payment receipt: $error";
 202     }
 203
 204   }
 205
 206   '';
 207
 208 }
 209
 210 =item delete
 211
 212 Deletes this payment and all associated applications (see L<FS::cust_bill_pay>),
 213 unless the closed flag is set.
 214
 215 =cut
 216
 217 sub delete {
 218   my $self = shift;
 219   return "Can't delete closed payment" if $self->closed =~ /^Y/i;
 220
 221   local $SIG{HUP} = 'IGNORE';
 222   local $SIG{INT} = 'IGNORE';
 223   local $SIG{QUIT} = 'IGNORE';
 224   local $SIG{TERM} = 'IGNORE';
 225   local $SIG{TSTP} = 'IGNORE';
 226   local $SIG{PIPE} = 'IGNORE';
 227
 228   my $oldAutoCommit = $FS::UID::AutoCommit;
 229   local $FS::UID::AutoCommit = 0;
 230   my $dbh = dbh;
 231
 232   foreach my $cust_bill_pay ( $self->cust_bill_pay ) {
 233     my $error = $cust_bill_pay->delete;
 234     if ( $error ) {
 235       $dbh->rollback if $oldAutoCommit;
 236       return $error;
 237     }
 238   }
 239
 240   my $error = $self->SUPER::delete(@_);
 241   if ( $error ) {
 242     $dbh->rollback if $oldAutoCommit;
 243     return $error;
 244   }
 245
 246   if ( $conf->config('deletepayments') ne '' ) {
 247
 248     my $cust_main = $self->cust_main;
 249
 250     my $error = send_email(
 251       'from'    => $conf->config('invoice_from'), #??? well as good as any
 252       'to'      => $conf->config('deletepayments'),
 253       'subject' => 'FREESIDE NOTIFICATION: Payment deleted',
 254       'body'    => [
 255         "This is an automatic message from your Freeside installation\n",
 256         "informing you that the following payment has been deleted:\n",
 257         "\n",
 258         'paynum: '. $self->paynum. "\n",
 259         'custnum: '. $self->custnum.
 260           " (". $cust_main->last. ", ". $cust_main->first. ")\n",
 261         'paid: $'. sprintf("%.2f", $self->paid). "\n",
 262         'date: '. time2str("%a %b %e %T %Y", $self->_date). "\n",
 263         'payby: '. $self->payby. "\n",
 264         'payinfo: '. $self->payinfo. "\n",
 265         'paybatch: '. $self->paybatch. "\n",
 266       ],
 267     );
 268
 269     if ( $error ) {
 270       $dbh->rollback if $oldAutoCommit;
 271       return "can't send payment deletion notification: $error";
 272     }
 273
 274   }
 275
 276   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 277
 278   '';
 279
 280 }
 281
 282 =item replace OLD_RECORD
 283
 284 Currently unimplemented (accounting reasons).
 285
 286 =cut
 287
 288 sub replace {
 289    return "Can't (yet?) modify cust_pay records!";
 290 }
 291
 292 =item check
 293
 294 Checks all fields to make sure this is a valid payment.  If there is an error,
 295 returns the error, otherwise returns false.  Called by the insert method.
 296
 297 =cut
 298
 299 sub check {
 300   my $self = shift;
 301
 302   my $error =
 303     $self->ut_numbern('paynum')
 304     || $self->ut_numbern('custnum')
 305     || $self->ut_money('paid')
 306     || $self->ut_numbern('_date')
 307     || $self->ut_textn('paybatch')
 308     || $self->ut_enum('closed', [ '', 'Y' ])
 309   ;
 310   return $error if $error;
 311
 312   return "paid must be > 0 " if $self->paid <= 0;
 313
 314   return "unknown cust_main.custnum: ". $self->custnum
 315     unless $self->invnum
 316            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 317
 318   $self->_date(time) unless $self->_date;
 319
 320   $self->payby =~ /^(CARD|CHEK|LECB|BILL|COMP)$/ or return "Illegal payby";
 321   $self->payby($1);
 322
 323   #false laziness with cust_refund::check
 324   if ( $self->payby eq 'CARD' ) {
 325     my $payinfo = $self->payinfo;
 326     $payinfo =~ s/\D//g;
 327     $self->payinfo($payinfo);
 328     if ( $self->payinfo ) {
 329       $self->payinfo =~ /^(\d{13,16})$/
 330         or return "Illegal (mistyped?) credit card number (payinfo)";
 331       $self->payinfo($1);
 332       validate($self->payinfo) or return "Illegal credit card number";
 333       return "Unknown card type" if cardtype($self->payinfo) eq "Unknown";
 334     } else {
 335       $self->payinfo('N/A');
 336     }
 337
 338   } else {
 339     $error = $self->ut_textn('payinfo');
 340     return $error if $error;
 341   }
 342
 343   $self->SUPER::check;
 344 }
 345
 346 =item cust_bill_pay
 347
 348 Returns all applications to invoices (see L<FS::cust_bill_pay>) for this
 349 payment.
 350
 351 =cut
 352
 353 sub cust_bill_pay {
 354   my $self = shift;
 355   sort { $a->_date <=> $b->_date }
 356     qsearch( 'cust_bill_pay', { 'paynum' => $self->paynum } )
 357   ;
 358 }
 359
 360 =item cust_pay_refund
 361
 362 Returns all applications of refunds (see L<FS::cust_pay_refund>) to this
 363 payment.
 364
 365 =cut
 366
 367 sub cust_pay_refund {
 368   my $self = shift;
 369   sort { $a->_date <=> $b->_date }
 370     qsearch( 'cust_pay_refund', { 'paynum' => $self->paynum } )
 371   ;
 372 }
 373
 374
 375 =item unapplied
 376
 377 Returns the amount of this payment that is still unapplied; which is
 378 paid minus all payment applications (see L<FS::cust_bill_pay>) and refund
 379 applications (see L<FS::cust_pay_refund>).
 380
 381 =cut
 382
 383 sub unapplied {
 384   my $self = shift;
 385   my $amount = $self->paid;
 386   $amount -= $_->amount foreach ( $self->cust_bill_pay );
 387   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 388   sprintf("%.2f", $amount );
 389 }
 390
 391 =item cust_main
 392
 393 Returns the parent customer object (see L<FS::cust_main>).
 394
 395 =cut
 396
 397 sub cust_main {
 398   my $self = shift;
 399   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 400 }
 401
 402 =item payinfo_masked
 403
 404 Returns a "masked" payinfo field with all but the last four characters replaced
 405 by 'x'es.  Useful for displaying credit cards.
 406
 407 =cut
 408
 409 sub payinfo_masked {
 410   my $self = shift;
 411   my $payinfo = $self->payinfo;
 412   'x'x(length($payinfo)-4). substr($payinfo,(length($payinfo)-4));
 413 }
 414
 415 =back
 416
 417 =head1 BUGS
 418
 419 Delete and replace methods.  payinfo_masked false laziness with cust_main.pm
 420 and cust_refund.pm
 421
 422 =head1 SEE ALSO
 423
 424 L<FS::cust_bill_pay>, L<FS::cust_bill>, L<FS::Record>, schema.html from the
 425 base documentation.
 426
 427 =cut
 428
 429 1;
 430