FS/FS/cust_pay.pm

   1 package FS::cust_pay;
   2
   3 use strict;
   4 use vars qw( @ISA $conf $unsuspendauto );
   5 use Date::Format;
   6 use Business::CreditCard;
   7 use Text::Template;
   8 use FS::Record qw( dbh qsearch qsearchs );
   9 use FS::Misc qw(send_email);
  10 use FS::cust_bill;
  11 use FS::cust_bill_pay;
  12 use FS::cust_pay_refund;
  13 use FS::cust_main;
  14 use FS::cust_pay_void;
  15
  16 @ISA = qw( FS::Record );
  17
  18 #ask FS::UID to run this stuff for us later
  19 FS::UID->install_callback( sub {
  20   $conf = new FS::Conf;
  21   $unsuspendauto = $conf->exists('unsuspendauto');
  22 } );
  23
  24 =head1 NAME
  25
  26 FS::cust_pay - Object methods for cust_pay objects
  27
  28 =head1 SYNOPSIS
  29
  30   use FS::cust_pay;
  31
  32   $record = new FS::cust_pay \%hash;
  33   $record = new FS::cust_pay { 'column' => 'value' };
  34
  35   $error = $record->insert;
  36
  37   $error = $new_record->replace($old_record);
  38
  39   $error = $record->delete;
  40
  41   $error = $record->check;
  42
  43 =head1 DESCRIPTION
  44
  45 An FS::cust_pay object represents a payment; the transfer of money from a
  46 customer.  FS::cust_pay inherits from FS::Record.  The following fields are
  47 currently supported:
  48
  49 =over 4
  50
  51 =item paynum - primary key (assigned automatically for new payments)
  52
  53 =item custnum - customer (see L<FS::cust_main>)
  54
  55 =item paid - Amount of this payment
  56
  57 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  58 L<Time::Local> and L<Date::Parse> for conversion functions.
  59
  60 =item payby - `CARD' (credit cards), `CHEK' (electronic check/ACH),
  61 `LECB' (phone bill billing), `BILL' (billing), or `COMP' (free)
  62
  63 =item payinfo - card number, check #, or comp issuer (4-8 lowercase alphanumerics; think username), respectively
  64
  65 =item paybatch - text field for tracking card processing
  66
  67 =item closed - books closed flag, empty or `Y'
  68
  69 =back
  70
  71 =head1 METHODS
  72
  73 =over 4
  74
  75 =item new HASHREF
  76
  77 Creates a new payment.  To add the payment to the databse, see L<"insert">.
  78
  79 =cut
  80
  81 sub table { 'cust_pay'; }
  82
  83 =item insert
  84
  85 Adds this payment to the database.
  86
  87 For backwards-compatibility and convenience, if the additional field invnum
  88 is defined, an FS::cust_bill_pay record for the full amount of the payment
  89 will be created.  In this case, custnum is optional.
  90
  91 =cut
  92
  93 sub insert {
  94   my $self = shift;
  95
  96   local $SIG{HUP} = 'IGNORE';
  97   local $SIG{INT} = 'IGNORE';
  98   local $SIG{QUIT} = 'IGNORE';
  99   local $SIG{TERM} = 'IGNORE';
 100   local $SIG{TSTP} = 'IGNORE';
 101   local $SIG{PIPE} = 'IGNORE';
 102
 103   my $oldAutoCommit = $FS::UID::AutoCommit;
 104   local $FS::UID::AutoCommit = 0;
 105   my $dbh = dbh;
 106
 107   if ( $self->invnum ) {
 108     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $self->invnum } )
 109       or do {
 110         $dbh->rollback if $oldAutoCommit;
 111         return "Unknown cust_bill.invnum: ". $self->invnum;
 112       };
 113     $self->custnum($cust_bill->custnum );
 114   }
 115
 116   my $cust_main = $self->cust_main;
 117   my $old_balance = $cust_main->balance;
 118
 119   my $error = $self->check;
 120   return $error if $error;
 121
 122   $error = $self->SUPER::insert;
 123   if ( $error ) {
 124     $dbh->rollback if $oldAutoCommit;
 125     return "error inserting $self: $error";
 126   }
 127
 128   if ( $self->invnum ) {
 129     my $cust_bill_pay = new FS::cust_bill_pay {
 130       'invnum' => $self->invnum,
 131       'paynum' => $self->paynum,
 132       'amount' => $self->paid,
 133       '_date'  => $self->_date,
 134     };
 135     $error = $cust_bill_pay->insert;
 136     if ( $error ) {
 137       $dbh->rollback if $oldAutoCommit;
 138       return "error inserting $cust_bill_pay: $error";
 139     }
 140   }
 141
 142   if ( $self->paybatch =~ /^webui-/ ) {
 143     my @cust_pay = qsearch('cust_pay', {
 144       'custnum' => $self->custnum,
 145       'paybatch' => $self->paybatch,
 146     } );
 147     if ( scalar(@cust_pay) > 1 ) {
 148       $dbh->rollback if $oldAutoCommit;
 149       return "a payment with webui token ". $self->paybatch. " already exists";
 150     }
 151   }
 152
 153   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 154
 155   #false laziness w/ cust_credit::insert
 156   if ( $unsuspendauto && $old_balance && $cust_main->balance <= 0 ) {
 157     my @errors = $cust_main->unsuspend;
 158     #return
 159     # side-fx with nested transactions?  upstack rolls back?
 160     warn "WARNING:Errors unsuspending customer ". $cust_main->custnum. ": ".
 161          join(' / ', @errors)
 162       if @errors;
 163   }
 164   #eslaf
 165
 166   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 167
 168   #my $cust_main = $self->cust_main;
 169   if ( $conf->exists('payment_receipt_email')
 170        && grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list
 171   ) {
 172
 173     my $receipt_template = new Text::Template (
 174       TYPE   => 'ARRAY',
 175       SOURCE => [ map "$_\n", $conf->config('payment_receipt_email') ],
 176     ) or do {
 177       warn "can't create payment receipt template: $Text::Template::ERROR";
 178       return '';
 179     };
 180
 181     my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list;
 182
 183     my $payby = $self->payby;
 184     my $payinfo = $self->payinfo;
 185     $payby =~ s/^BILL$/Check/ if $payinfo;
 186     $payinfo = $self->payinfo_masked if $payby eq 'CARD' || $payby eq 'CHEK';
 187     $payby =~ s/^CHEK$/Electronic check/;
 188
 189     my $error = send_email(
 190       'from'    => $conf->config('invoice_from'), #??? well as good as any
 191       'to'      => \@invoicing_list,
 192       'subject' => 'Payment receipt',
 193       'body'    => [ $receipt_template->fill_in( HASH => {
 194                        'date'    => time2str("%a %B %o, %Y", $self->_date),
 195                        'name'    => $cust_main->name,
 196                        'paynum'  => $self->paynum,
 197                        'paid'    => sprintf("%.2f", $self->paid),
 198                        'payby'   => ucfirst(lc($payby)),
 199                        'payinfo' => $payinfo,
 200                        'balance' => $cust_main->balance,
 201                    } ) ],
 202     );
 203     if ( $error ) {
 204       warn "can't send payment receipt: $error";
 205     }
 206
 207   }
 208
 209   '';
 210
 211 }
 212
 213 =item void [ REASON ]
 214
 215 Voids this payment: deletes the payment and all associated applications and
 216 adds a record of the voided payment to the FS::cust_pay_void table.
 217
 218 =cut
 219
 220 sub void {
 221   my $self = shift;
 222
 223   local $SIG{HUP} = 'IGNORE';
 224   local $SIG{INT} = 'IGNORE';
 225   local $SIG{QUIT} = 'IGNORE';
 226   local $SIG{TERM} = 'IGNORE';
 227   local $SIG{TSTP} = 'IGNORE';
 228   local $SIG{PIPE} = 'IGNORE';
 229
 230   my $oldAutoCommit = $FS::UID::AutoCommit;
 231   local $FS::UID::AutoCommit = 0;
 232   my $dbh = dbh;
 233
 234   my $cust_pay_void = new FS::cust_pay_void ( {
 235     map { $_ => $self->get($_) } $self->fields
 236   } );
 237   $cust_pay_void->reason(shift) if scalar(@_);
 238   my $error = $cust_pay_void->insert;
 239   if ( $error ) {
 240     $dbh->rollback if $oldAutoCommit;
 241     return $error;
 242   }
 243
 244   $error = $self->delete;
 245   if ( $error ) {
 246     $dbh->rollback if $oldAutoCommit;
 247     return $error;
 248   }
 249
 250   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 251
 252   '';
 253
 254 }
 255
 256 =item delete
 257
 258 Deletes this payment and all associated applications (see L<FS::cust_bill_pay>),
 259 unless the closed flag is set.  In most cases, you want to use the void
 260 method instead to leave a record of the deleted payment.
 261
 262 =cut
 263
 264 sub delete {
 265   my $self = shift;
 266   return "Can't delete closed payment" if $self->closed =~ /^Y/i;
 267
 268   local $SIG{HUP} = 'IGNORE';
 269   local $SIG{INT} = 'IGNORE';
 270   local $SIG{QUIT} = 'IGNORE';
 271   local $SIG{TERM} = 'IGNORE';
 272   local $SIG{TSTP} = 'IGNORE';
 273   local $SIG{PIPE} = 'IGNORE';
 274
 275   my $oldAutoCommit = $FS::UID::AutoCommit;
 276   local $FS::UID::AutoCommit = 0;
 277   my $dbh = dbh;
 278
 279   foreach my $app ( $self->cust_bill_pay, $self->cust_pay_refund ) {
 280     my $error = $app->delete;
 281     if ( $error ) {
 282       $dbh->rollback if $oldAutoCommit;
 283       return $error;
 284     }
 285   }
 286
 287   my $error = $self->SUPER::delete(@_);
 288   if ( $error ) {
 289     $dbh->rollback if $oldAutoCommit;
 290     return $error;
 291   }
 292
 293   if ( $conf->config('deletepayments') ne '' ) {
 294
 295     my $cust_main = $self->cust_main;
 296
 297     my $error = send_email(
 298       'from'    => $conf->config('invoice_from'), #??? well as good as any
 299       'to'      => $conf->config('deletepayments'),
 300       'subject' => 'FREESIDE NOTIFICATION: Payment deleted',
 301       'body'    => [
 302         "This is an automatic message from your Freeside installation\n",
 303         "informing you that the following payment has been deleted:\n",
 304         "\n",
 305         'paynum: '. $self->paynum. "\n",
 306         'custnum: '. $self->custnum.
 307           " (". $cust_main->last. ", ". $cust_main->first. ")\n",
 308         'paid: $'. sprintf("%.2f", $self->paid). "\n",
 309         'date: '. time2str("%a %b %e %T %Y", $self->_date). "\n",
 310         'payby: '. $self->payby. "\n",
 311         'payinfo: '. $self->payinfo. "\n",
 312         'paybatch: '. $self->paybatch. "\n",
 313       ],
 314     );
 315
 316     if ( $error ) {
 317       $dbh->rollback if $oldAutoCommit;
 318       return "can't send payment deletion notification: $error";
 319     }
 320
 321   }
 322
 323   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 324
 325   '';
 326
 327 }
 328
 329 =item replace OLD_RECORD
 330
 331 You probably shouldn't modify payments...
 332
 333 =item check
 334
 335 Checks all fields to make sure this is a valid payment.  If there is an error,
 336 returns the error, otherwise returns false.  Called by the insert method.
 337
 338 =cut
 339
 340 sub check {
 341   my $self = shift;
 342
 343   my $error =
 344     $self->ut_numbern('paynum')
 345     || $self->ut_numbern('custnum')
 346     || $self->ut_money('paid')
 347     || $self->ut_numbern('_date')
 348     || $self->ut_textn('paybatch')
 349     || $self->ut_enum('closed', [ '', 'Y' ])
 350   ;
 351   return $error if $error;
 352
 353   return "paid must be > 0 " if $self->paid <= 0;
 354
 355   return "unknown cust_main.custnum: ". $self->custnum
 356     unless $self->invnum
 357            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 358
 359   $self->_date(time) unless $self->_date;
 360
 361   $self->payby =~ /^(CARD|CHEK|LECB|BILL|COMP|PREP)$/ or return "Illegal payby";
 362   $self->payby($1);
 363
 364   #false laziness with cust_refund::check
 365   if ( $self->payby eq 'CARD' ) {
 366     my $payinfo = $self->payinfo;
 367     $payinfo =~ s/\D//g;
 368     $self->payinfo($payinfo);
 369     if ( $self->payinfo ) {
 370       $self->payinfo =~ /^(\d{13,16})$/
 371         or return "Illegal (mistyped?) credit card number (payinfo)";
 372       $self->payinfo($1);
 373       validate($self->payinfo) or return "Illegal credit card number";
 374       return "Unknown card type" if cardtype($self->payinfo) eq "Unknown";
 375     } else {
 376       $self->payinfo('N/A');
 377     }
 378
 379   } else {
 380     $error = $self->ut_textn('payinfo');
 381     return $error if $error;
 382   }
 383
 384   $self->SUPER::check;
 385 }
 386
 387 =item cust_bill_pay
 388
 389 Returns all applications to invoices (see L<FS::cust_bill_pay>) for this
 390 payment.
 391
 392 =cut
 393
 394 sub cust_bill_pay {
 395   my $self = shift;
 396   sort {    $a->_date  <=> $b->_date
 397          || $a->invnum <=> $b->invnum }
 398     qsearch( 'cust_bill_pay', { 'paynum' => $self->paynum } )
 399   ;
 400 }
 401
 402 =item cust_pay_refund
 403
 404 Returns all applications of refunds (see L<FS::cust_pay_refund>) to this
 405 payment.
 406
 407 =cut
 408
 409 sub cust_pay_refund {
 410   my $self = shift;
 411   sort { $a->_date <=> $b->_date }
 412     qsearch( 'cust_pay_refund', { 'paynum' => $self->paynum } )
 413   ;
 414 }
 415
 416
 417 =item unapplied
 418
 419 Returns the amount of this payment that is still unapplied; which is
 420 paid minus all payment applications (see L<FS::cust_bill_pay>) and refund
 421 applications (see L<FS::cust_pay_refund>).
 422
 423 =cut
 424
 425 sub unapplied {
 426   my $self = shift;
 427   my $amount = $self->paid;
 428   $amount -= $_->amount foreach ( $self->cust_bill_pay );
 429   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 430   sprintf("%.2f", $amount );
 431 }
 432
 433 =item unrefunded
 434
 435 Returns the amount of this payment that has not been refuned; which is
 436 paid minus all  refund applications (see L<FS::cust_pay_refund>).
 437
 438 =cut
 439
 440 sub unrefunded {
 441   my $self = shift;
 442   my $amount = $self->paid;
 443   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 444   sprintf("%.2f", $amount );
 445 }
 446
 447
 448 =item cust_main
 449
 450 Returns the parent customer object (see L<FS::cust_main>).
 451
 452 =cut
 453
 454 sub cust_main {
 455   my $self = shift;
 456   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 457 }
 458
 459 =item payinfo_masked
 460
 461 Returns a "masked" payinfo field with all but the last four characters replaced
 462 by 'x'es.  Useful for displaying credit cards.
 463
 464 =cut
 465
 466 sub payinfo_masked {
 467   my $self = shift;
 468   #some false laziness w/cust_main::paymask
 469   if ( $self->payby eq 'CARD' ) {
 470     my $payinfo = $self->payinfo;
 471     'x'x(length($payinfo)-4). substr($payinfo,(length($payinfo)-4));
 472   } elsif ( $self->payby eq 'CHEK' ) {
 473     my( $account, $aba ) = split('@', $self->payinfo );
 474     'x'x(length($account)-2). substr($account,(length($account)-2)). "@". $aba;
 475   } else {
 476     $self->payinfo;
 477   }
 478 }
 479
 480 =back
 481
 482 =head1 BUGS
 483
 484 Delete and replace methods.  payinfo_masked false laziness with cust_main.pm
 485 and cust_refund.pm
 486
 487 =head1 SEE ALSO
 488
 489 L<FS::cust_bill_pay>, L<FS::cust_bill>, L<FS::Record>, schema.html from the
 490 base documentation.
 491
 492 =cut
 493
 494 1;
 495