FS/FS/cust_pay.pm

   1 package FS::cust_pay;
   2
   3 use strict;
   4 use vars qw( @ISA $conf $unsuspendauto );
   5 use Date::Format;
   6 use Business::CreditCard;
   7 use Text::Template;
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( dbh qsearch qsearchs dbh );
  10 use FS::Misc qw(send_email);
  11 use FS::cust_bill;
  12 use FS::cust_bill_pay;
  13 use FS::cust_pay_refund;
  14 use FS::cust_main;
  15
  16 @ISA = qw( FS::Record );
  17
  18 #ask FS::UID to run this stuff for us later
  19 FS::UID->install_callback( sub {
  20   $conf = new FS::Conf;
  21   $unsuspendauto = $conf->exists('unsuspendauto');
  22 } );
  23
  24 =head1 NAME
  25
  26 FS::cust_pay - Object methods for cust_pay objects
  27
  28 =head1 SYNOPSIS
  29
  30   use FS::cust_pay;
  31
  32   $record = new FS::cust_pay \%hash;
  33   $record = new FS::cust_pay { 'column' => 'value' };
  34
  35   $error = $record->insert;
  36
  37   $error = $new_record->replace($old_record);
  38
  39   $error = $record->delete;
  40
  41   $error = $record->check;
  42
  43 =head1 DESCRIPTION
  44
  45 An FS::cust_pay object represents a payment; the transfer of money from a
  46 customer.  FS::cust_pay inherits from FS::Record.  The following fields are
  47 currently supported:
  48
  49 =over 4
  50
  51 =item paynum - primary key (assigned automatically for new payments)
  52
  53 =item custnum - customer (see L<FS::cust_main>)
  54
  55 =item paid - Amount of this payment
  56
  57 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  58 L<Time::Local> and L<Date::Parse> for conversion functions.
  59
  60 =item payby - `CARD' (credit cards), `CHEK' (electronic check/ACH),
  61 `LECB' (phone bill billing), `BILL' (billing), or `COMP' (free)
  62
  63 =item payinfo - card number, check #, or comp issuer (4-8 lowercase alphanumerics; think username), respectively
  64
  65 =item paybatch - text field for tracking card processing
  66
  67 =item closed - books closed flag, empty or `Y'
  68
  69 =back
  70
  71 =head1 METHODS
  72
  73 =over 4
  74
  75 =item new HASHREF
  76
  77 Creates a new payment.  To add the payment to the databse, see L<"insert">.
  78
  79 =cut
  80
  81 sub table { 'cust_pay'; }
  82
  83 =item insert
  84
  85 Adds this payment to the database.
  86
  87 For backwards-compatibility and convenience, if the additional field invnum
  88 is defined, an FS::cust_bill_pay record for the full amount of the payment
  89 will be created.  In this case, custnum is optional.
  90
  91 =cut
  92
  93 sub insert {
  94   my $self = shift;
  95
  96   local $SIG{HUP} = 'IGNORE';
  97   local $SIG{INT} = 'IGNORE';
  98   local $SIG{QUIT} = 'IGNORE';
  99   local $SIG{TERM} = 'IGNORE';
 100   local $SIG{TSTP} = 'IGNORE';
 101   local $SIG{PIPE} = 'IGNORE';
 102
 103   my $oldAutoCommit = $FS::UID::AutoCommit;
 104   local $FS::UID::AutoCommit = 0;
 105   my $dbh = dbh;
 106
 107   if ( $self->invnum ) {
 108     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $self->invnum } )
 109       or do {
 110         $dbh->rollback if $oldAutoCommit;
 111         return "Unknown cust_bill.invnum: ". $self->invnum;
 112       };
 113     $self->custnum($cust_bill->custnum );
 114   }
 115
 116   my $cust_main = $self->cust_main;
 117   my $old_balance = $cust_main->balance;
 118
 119   my $error = $self->check;
 120   return $error if $error;
 121
 122   $error = $self->SUPER::insert;
 123   if ( $error ) {
 124     $dbh->rollback if $oldAutoCommit;
 125     return "error inserting $self: $error";
 126   }
 127
 128   if ( $self->invnum ) {
 129     my $cust_bill_pay = new FS::cust_bill_pay {
 130       'invnum' => $self->invnum,
 131       'paynum' => $self->paynum,
 132       'amount' => $self->paid,
 133       '_date'  => $self->_date,
 134     };
 135     $error = $cust_bill_pay->insert;
 136     if ( $error ) {
 137       $dbh->rollback if $oldAutoCommit;
 138       return "error inserting $cust_bill_pay: $error";
 139     }
 140   }
 141
 142   if ( $self->paybatch =~ /^webui-/ ) {
 143     my @cust_pay = qsearch('cust_pay', {
 144       'custnum' => $self->custnum,
 145       'paybatch' => $self->paybatch,
 146     } );
 147     if ( scalar(@cust_pay) > 1 ) {
 148       $dbh->rollback if $oldAutoCommit;
 149       return "a payment with webui token ". $self->paybatch. " already exists";
 150     }
 151   }
 152
 153   #false laziness w/ cust_credit::insert
 154   if ( $unsuspendauto && $old_balance && $cust_main->balance <= 0 ) {
 155     my @errors = $cust_main->unsuspend;
 156     #return
 157     # side-fx with nested transactions?  upstack rolls back?
 158     warn "WARNING:Errors unsuspending customer ". $cust_main->custnum. ": ".
 159          join(' / ', @errors)
 160       if @errors;
 161   }
 162   #eslaf
 163
 164   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 165
 166   #my $cust_main = $self->cust_main;
 167   if ( $conf->exists('payment_receipt_email')
 168        && grep { $_ ne 'POST' } $cust_main->invoicing_list
 169   ) {
 170
 171     my $receipt_template = new Text::Template (
 172       TYPE   => 'ARRAY',
 173       SOURCE => [ map "$_\n", $conf->config('payment_receipt_email') ],
 174     ) or do {
 175       warn "can't create payment receipt template: $Text::Template::ERROR";
 176       return '';
 177     };
 178
 179     my @invoicing_list = grep { $_ ne 'POST' } $cust_main->invoicing_list;
 180
 181     my $error = send_email(
 182       'from'    => $conf->config('invoice_from'), #??? well as good as any
 183       'to'      => \@invoicing_list,
 184       'subject' => 'Payment receipt',
 185       'body'    => $receipt_template->fill_in( HASH => {
 186                      'date'    => time2str("%a %B %o, %Y", $self->_date),
 187                      'paynum'  => $self->paynum,
 188                      'paid'    => $self->paid,
 189                      'payby'   => ucfirst(lc($self->payby)),
 190                      'payinfo' => ( $self->payby eq 'CARD'
 191                                       ? $self->payinfo_masked
 192                                       : $self->payinfo        ),
 193                      'balance' => $cust_main->balance,
 194                    } ),
 195     );
 196     if ( $error ) {
 197       warn "can't send payment receipt: $error";
 198     }
 199
 200   }
 201
 202   '';
 203
 204 }
 205
 206 =item delete
 207
 208 Deletes this payment and all associated applications (see L<FS::cust_bill_pay>),
 209 unless the closed flag is set.
 210
 211 =cut
 212
 213 sub delete {
 214   my $self = shift;
 215   return "Can't delete closed payment" if $self->closed =~ /^Y/i;
 216
 217   local $SIG{HUP} = 'IGNORE';
 218   local $SIG{INT} = 'IGNORE';
 219   local $SIG{QUIT} = 'IGNORE';
 220   local $SIG{TERM} = 'IGNORE';
 221   local $SIG{TSTP} = 'IGNORE';
 222   local $SIG{PIPE} = 'IGNORE';
 223
 224   my $oldAutoCommit = $FS::UID::AutoCommit;
 225   local $FS::UID::AutoCommit = 0;
 226   my $dbh = dbh;
 227
 228   foreach my $cust_bill_pay ( $self->cust_bill_pay ) {
 229     my $error = $cust_bill_pay->delete;
 230     if ( $error ) {
 231       $dbh->rollback if $oldAutoCommit;
 232       return $error;
 233     }
 234   }
 235
 236   my $error = $self->SUPER::delete(@_);
 237   if ( $error ) {
 238     $dbh->rollback if $oldAutoCommit;
 239     return $error;
 240   }
 241
 242   if ( $conf->config('deletepayments') ne '' ) {
 243
 244     my $cust_main = $self->cust_main;
 245
 246     my $error = send_email(
 247       'from'    => $conf->config('invoice_from'), #??? well as good as any
 248       'to'      => $conf->config('deletepayments'),
 249       'subject' => 'FREESIDE NOTIFICATION: Payment deleted',
 250       'body'    => [
 251         "This is an automatic message from your Freeside installation\n",
 252         "informing you that the following payment has been deleted:\n",
 253         "\n",
 254         'paynum: '. $self->paynum. "\n",
 255         'custnum: '. $self->custnum.
 256           " (". $cust_main->last. ", ". $cust_main->first. ")\n",
 257         'paid: $'. sprintf("%.2f", $self->paid). "\n",
 258         'date: '. time2str("%a %b %e %T %Y", $self->_date). "\n",
 259         'payby: '. $self->payby. "\n",
 260         'payinfo: '. $self->payinfo. "\n",
 261         'paybatch: '. $self->paybatch. "\n",
 262       ],
 263     );
 264
 265     if ( $error ) {
 266       $dbh->rollback if $oldAutoCommit;
 267       return "can't send payment deletion notification: $error";
 268     }
 269
 270   }
 271
 272   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 273
 274   '';
 275
 276 }
 277
 278 =item replace OLD_RECORD
 279
 280 Currently unimplemented (accounting reasons).
 281
 282 =cut
 283
 284 sub replace {
 285    return "Can't (yet?) modify cust_pay records!";
 286 }
 287
 288 =item check
 289
 290 Checks all fields to make sure this is a valid payment.  If there is an error,
 291 returns the error, otherwise returns false.  Called by the insert method.
 292
 293 =cut
 294
 295 sub check {
 296   my $self = shift;
 297
 298   my $error =
 299     $self->ut_numbern('paynum')
 300     || $self->ut_numbern('custnum')
 301     || $self->ut_money('paid')
 302     || $self->ut_numbern('_date')
 303     || $self->ut_textn('paybatch')
 304     || $self->ut_enum('closed', [ '', 'Y' ])
 305   ;
 306   return $error if $error;
 307
 308   return "paid must be > 0 " if $self->paid <= 0;
 309
 310   return "unknown cust_main.custnum: ". $self->custnum
 311     unless $self->invnum
 312            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 313
 314   $self->_date(time) unless $self->_date;
 315
 316   $self->payby =~ /^(CARD|CHEK|LECB|BILL|COMP)$/ or return "Illegal payby";
 317   $self->payby($1);
 318
 319   #false laziness with cust_refund::check
 320   if ( $self->payby eq 'CARD' ) {
 321     my $payinfo = $self->payinfo;
 322     $payinfo =~ s/\D//g;
 323     $self->payinfo($payinfo);
 324     if ( $self->payinfo ) {
 325       $self->payinfo =~ /^(\d{13,16})$/
 326         or return "Illegal (mistyped?) credit card number (payinfo)";
 327       $self->payinfo($1);
 328       validate($self->payinfo) or return "Illegal credit card number";
 329       return "Unknown card type" if cardtype($self->payinfo) eq "Unknown";
 330     } else {
 331       $self->payinfo('N/A');
 332     }
 333
 334   } else {
 335     $error = $self->ut_textn('payinfo');
 336     return $error if $error;
 337   }
 338
 339   $self->SUPER::check;
 340 }
 341
 342 =item cust_bill_pay
 343
 344 Returns all applications to invoices (see L<FS::cust_bill_pay>) for this
 345 payment.
 346
 347 =cut
 348
 349 sub cust_bill_pay {
 350   my $self = shift;
 351   sort { $a->_date <=> $b->_date }
 352     qsearch( 'cust_bill_pay', { 'paynum' => $self->paynum } )
 353   ;
 354 }
 355
 356 =item cust_pay_refund
 357
 358 Returns all applications of refunds (see L<FS::cust_pay_refund>) to this
 359 payment.
 360
 361 =cut
 362
 363 sub cust_pay_refund {
 364   my $self = shift;
 365   sort { $a->_date <=> $b->_date }
 366     qsearch( 'cust_pay_refund', { 'paynum' => $self->paynum } )
 367   ;
 368 }
 369
 370
 371 =item unapplied
 372
 373 Returns the amount of this payment that is still unapplied; which is
 374 paid minus all payment applications (see L<FS::cust_bill_pay>) and refund
 375 applications (see L<FS::cust_pay_refund>).
 376
 377 =cut
 378
 379 sub unapplied {
 380   my $self = shift;
 381   my $amount = $self->paid;
 382   $amount -= $_->amount foreach ( $self->cust_bill_pay );
 383   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 384   sprintf("%.2f", $amount );
 385 }
 386
 387 =item cust_main
 388
 389 Returns the parent customer object (see L<FS::cust_main>).
 390
 391 =cut
 392
 393 sub cust_main {
 394   my $self = shift;
 395   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 396 }
 397
 398 =item payinfo_masked
 399
 400 Returns a "masked" payinfo field with all but the last four characters replaced
 401 by 'x'es.  Useful for displaying credit cards.
 402
 403 =cut
 404
 405 sub payinfo_masked {
 406   my $self = shift;
 407   my $payinfo = $self->payinfo;
 408   'x'x(length($payinfo)-4). substr($payinfo,(length($payinfo)-4));
 409 }
 410
 411 =back
 412
 413 =head1 BUGS
 414
 415 Delete and replace methods.  payinfo_masked false laziness with cust_main.pm
 416 and cust_refund.pm
 417
 418 =head1 SEE ALSO
 419
 420 L<FS::cust_bill_pay>, L<FS::cust_bill>, L<FS::Record>, schema.html from the
 421 base documentation.
 422
 423 =cut
 424
 425 1;
 426