FS/FS/cust_pay.pm

   1 package FS::cust_pay;
   2
   3 use strict;
   4 use base qw( FS::otaker_Mixin FS::payinfo_transaction_Mixin FS::cust_main_Mixin
   5              FS::Record );
   6 use vars qw( $DEBUG $me $conf @encrypted_fields
   7              $unsuspendauto $ignore_noapply
   8            );
   9 use Date::Format;
  10 use Business::CreditCard;
  11 use Text::Template;
  12 use FS::UID qw( getotaker );
  13 use FS::Misc qw( send_email );
  14 use FS::Record qw( dbh qsearch qsearchs );
  15 use FS::payby;
  16 use FS::cust_main_Mixin;
  17 use FS::payinfo_transaction_Mixin;
  18 use FS::cust_bill;
  19 use FS::cust_bill_pay;
  20 use FS::cust_pay_refund;
  21 use FS::cust_main;
  22 use FS::cust_pkg;
  23 use FS::cust_pay_void;
  24
  25 $DEBUG = 0;
  26
  27 $me = '[FS::cust_pay]';
  28
  29 $ignore_noapply = 0;
  30
  31 #ask FS::UID to run this stuff for us later
  32 FS::UID->install_callback( sub {
  33   $conf = new FS::Conf;
  34   $unsuspendauto = $conf->exists('unsuspendauto');
  35 } );
  36
  37 @encrypted_fields = ('payinfo');
  38
  39 =head1 NAME
  40
  41 FS::cust_pay - Object methods for cust_pay objects
  42
  43 =head1 SYNOPSIS
  44
  45   use FS::cust_pay;
  46
  47   $record = new FS::cust_pay \%hash;
  48   $record = new FS::cust_pay { 'column' => 'value' };
  49
  50   $error = $record->insert;
  51
  52   $error = $new_record->replace($old_record);
  53
  54   $error = $record->delete;
  55
  56   $error = $record->check;
  57
  58 =head1 DESCRIPTION
  59
  60 An FS::cust_pay object represents a payment; the transfer of money from a
  61 customer.  FS::cust_pay inherits from FS::Record.  The following fields are
  62 currently supported:
  63
  64 =over 4
  65
  66 =item paynum
  67
  68 primary key (assigned automatically for new payments)
  69
  70 =item custnum
  71
  72 customer (see L<FS::cust_main>)
  73
  74 =item _date
  75
  76 specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  77 L<Time::Local> and L<Date::Parse> for conversion functions.
  78
  79 =item paid
  80
  81 Amount of this payment
  82
  83 =item usernum
  84
  85 order taker (see L<FS::access_user>)
  86
  87 =item payby
  88
  89 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
  90
  91 =item payinfo
  92
  93 Payment Information (See L<FS::payinfo_Mixin> for data format)
  94
  95 =item paymask
  96
  97 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
  98
  99 =item paybatch
 100
 101 text field for tracking card processing or other batch grouping
 102
 103 =item payunique
 104
 105 Optional unique identifer to prevent duplicate transactions.
 106
 107 =item closed
 108
 109 books closed flag, empty or `Y'
 110
 111 =item pkgnum
 112
 113 Desired pkgnum when using experimental package balances.
 114
 115 =back
 116
 117 =head1 METHODS
 118
 119 =over 4
 120
 121 =item new HASHREF
 122
 123 Creates a new payment.  To add the payment to the databse, see L<"insert">.
 124
 125 =cut
 126
 127 sub table { 'cust_pay'; }
 128 sub cust_linked { $_[0]->cust_main_custnum; }
 129 sub cust_unlinked_msg {
 130   my $self = shift;
 131   "WARNING: can't find cust_main.custnum ". $self->custnum.
 132   ' (cust_pay.paynum '. $self->paynum. ')';
 133 }
 134
 135 =item insert [ OPTION => VALUE ... ]
 136
 137 Adds this payment to the database.
 138
 139 For backwards-compatibility and convenience, if the additional field invnum
 140 is defined, an FS::cust_bill_pay record for the full amount of the payment
 141 will be created.  In this case, custnum is optional.
 142
 143 A hash of optional arguments may be passed.  Currently "manual" is supported.
 144 If true, a payment receipt is sent instead of a statement when
 145 'payment_receipt_email' configuration option is set.
 146
 147 =cut
 148
 149 sub insert {
 150   my($self, %options) = @_;
 151
 152   local $SIG{HUP} = 'IGNORE';
 153   local $SIG{INT} = 'IGNORE';
 154   local $SIG{QUIT} = 'IGNORE';
 155   local $SIG{TERM} = 'IGNORE';
 156   local $SIG{TSTP} = 'IGNORE';
 157   local $SIG{PIPE} = 'IGNORE';
 158
 159   my $oldAutoCommit = $FS::UID::AutoCommit;
 160   local $FS::UID::AutoCommit = 0;
 161   my $dbh = dbh;
 162
 163   my $cust_bill;
 164   if ( $self->invnum ) {
 165     $cust_bill = qsearchs('cust_bill', { 'invnum' => $self->invnum } )
 166       or do {
 167         $dbh->rollback if $oldAutoCommit;
 168         return "Unknown cust_bill.invnum: ". $self->invnum;
 169       };
 170     $self->custnum($cust_bill->custnum );
 171   }
 172
 173   my $error = $self->check;
 174   return $error if $error;
 175
 176   my $cust_main = $self->cust_main;
 177   my $old_balance = $cust_main->balance;
 178
 179   $error = $self->SUPER::insert;
 180   if ( $error ) {
 181     $dbh->rollback if $oldAutoCommit;
 182     return "error inserting $self: $error";
 183   }
 184
 185   if ( $self->invnum ) {
 186     my $cust_bill_pay = new FS::cust_bill_pay {
 187       'invnum' => $self->invnum,
 188       'paynum' => $self->paynum,
 189       'amount' => $self->paid,
 190       '_date'  => $self->_date,
 191     };
 192     $error = $cust_bill_pay->insert(%options);
 193     if ( $error ) {
 194       if ( $ignore_noapply ) {
 195         warn "warning: error inserting $cust_bill_pay: $error ".
 196              "(ignore_noapply flag set; inserting cust_pay record anyway)\n";
 197       } else {
 198         $dbh->rollback if $oldAutoCommit;
 199         return "error inserting $cust_bill_pay: $error";
 200       }
 201     }
 202   }
 203
 204   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 205
 206   #false laziness w/ cust_credit::insert
 207   if ( $unsuspendauto && $old_balance && $cust_main->balance <= 0 ) {
 208     my @errors = $cust_main->unsuspend;
 209     #return
 210     # side-fx with nested transactions?  upstack rolls back?
 211     warn "WARNING:Errors unsuspending customer ". $cust_main->custnum. ": ".
 212          join(' / ', @errors)
 213       if @errors;
 214   }
 215   #eslaf
 216
 217   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 218
 219   #payment receipt
 220   my $trigger = $conf->config('payment_receipt-trigger') || 'cust_pay';
 221   if ( $trigger eq 'cust_pay' ) {
 222     my $error = $self->send_receipt(
 223       'manual'    => $options{'manual'},
 224       'cust_bill' => $cust_bill,
 225       'cust_main' => $cust_main,
 226     );
 227     warn "can't send payment receipt/statement: $error" if $error;
 228   }
 229
 230   '';
 231
 232 }
 233
 234 =item void [ REASON ]
 235
 236 Voids this payment: deletes the payment and all associated applications and
 237 adds a record of the voided payment to the FS::cust_pay_void table.
 238
 239 =cut
 240
 241 sub void {
 242   my $self = shift;
 243
 244   local $SIG{HUP} = 'IGNORE';
 245   local $SIG{INT} = 'IGNORE';
 246   local $SIG{QUIT} = 'IGNORE';
 247   local $SIG{TERM} = 'IGNORE';
 248   local $SIG{TSTP} = 'IGNORE';
 249   local $SIG{PIPE} = 'IGNORE';
 250
 251   my $oldAutoCommit = $FS::UID::AutoCommit;
 252   local $FS::UID::AutoCommit = 0;
 253   my $dbh = dbh;
 254
 255   my $cust_pay_void = new FS::cust_pay_void ( {
 256     map { $_ => $self->get($_) } $self->fields
 257   } );
 258   $cust_pay_void->reason(shift) if scalar(@_);
 259   my $error = $cust_pay_void->insert;
 260   if ( $error ) {
 261     $dbh->rollback if $oldAutoCommit;
 262     return $error;
 263   }
 264
 265   $error = $self->delete;
 266   if ( $error ) {
 267     $dbh->rollback if $oldAutoCommit;
 268     return $error;
 269   }
 270
 271   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 272
 273   '';
 274
 275 }
 276
 277 =item delete
 278
 279 Unless the closed flag is set, deletes this payment and all associated
 280 applications (see L<FS::cust_bill_pay> and L<FS::cust_pay_refund>).  In most
 281 cases, you want to use the void method instead to leave a record of the
 282 deleted payment.
 283
 284 =cut
 285
 286 # very similar to FS::cust_credit::delete
 287 sub delete {
 288   my $self = shift;
 289   return "Can't delete closed payment" if $self->closed =~ /^Y/i;
 290
 291   local $SIG{HUP} = 'IGNORE';
 292   local $SIG{INT} = 'IGNORE';
 293   local $SIG{QUIT} = 'IGNORE';
 294   local $SIG{TERM} = 'IGNORE';
 295   local $SIG{TSTP} = 'IGNORE';
 296   local $SIG{PIPE} = 'IGNORE';
 297
 298   my $oldAutoCommit = $FS::UID::AutoCommit;
 299   local $FS::UID::AutoCommit = 0;
 300   my $dbh = dbh;
 301
 302   foreach my $app ( $self->cust_bill_pay, $self->cust_pay_refund ) {
 303     my $error = $app->delete;
 304     if ( $error ) {
 305       $dbh->rollback if $oldAutoCommit;
 306       return $error;
 307     }
 308   }
 309
 310   my $error = $self->SUPER::delete(@_);
 311   if ( $error ) {
 312     $dbh->rollback if $oldAutoCommit;
 313     return $error;
 314   }
 315
 316   if (    $conf->exists('deletepayments')
 317        && $conf->config('deletepayments') ne '' ) {
 318
 319     my $cust_main = $self->cust_main;
 320
 321     my $error = send_email(
 322       'from'    => $conf->config('invoice_from', $self->cust_main->agentnum),
 323                                  #invoice_from??? well as good as any
 324       'to'      => $conf->config('deletepayments'),
 325       'subject' => 'FREESIDE NOTIFICATION: Payment deleted',
 326       'body'    => [
 327         "This is an automatic message from your Freeside installation\n",
 328         "informing you that the following payment has been deleted:\n",
 329         "\n",
 330         'paynum: '. $self->paynum. "\n",
 331         'custnum: '. $self->custnum.
 332           " (". $cust_main->last. ", ". $cust_main->first. ")\n",
 333         'paid: $'. sprintf("%.2f", $self->paid). "\n",
 334         'date: '. time2str("%a %b %e %T %Y", $self->_date). "\n",
 335         'payby: '. $self->payby. "\n",
 336         'payinfo: '. $self->paymask. "\n",
 337         'paybatch: '. $self->paybatch. "\n",
 338       ],
 339     );
 340
 341     if ( $error ) {
 342       $dbh->rollback if $oldAutoCommit;
 343       return "can't send payment deletion notification: $error";
 344     }
 345
 346   }
 347
 348   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 349
 350   '';
 351
 352 }
 353
 354 =item replace OLD_RECORD
 355
 356 You can, but probably shouldn't modify payments...
 357
 358 =cut
 359
 360 sub replace {
 361   #return "Can't modify payment!"
 362   my $self = shift;
 363   return "Can't modify closed payment" if $self->closed =~ /^Y/i;
 364   $self->SUPER::replace(@_);
 365 }
 366
 367 =item check
 368
 369 Checks all fields to make sure this is a valid payment.  If there is an error,
 370 returns the error, otherwise returns false.  Called by the insert method.
 371
 372 =cut
 373
 374 sub check {
 375   my $self = shift;
 376
 377   $self->otaker(getotaker) unless ($self->otaker);
 378
 379   my $error =
 380     $self->ut_numbern('paynum')
 381     || $self->ut_numbern('custnum')
 382     || $self->ut_numbern('_date')
 383     || $self->ut_money('paid')
 384     || $self->ut_alphan('otaker')
 385     || $self->ut_textn('paybatch')
 386     || $self->ut_textn('payunique')
 387     || $self->ut_enum('closed', [ '', 'Y' ])
 388     || $self->ut_foreign_keyn('pkgnum', 'cust_pkg', 'pkgnum')
 389     || $self->payinfo_check()
 390   ;
 391   return $error if $error;
 392
 393   return "paid must be > 0 " if $self->paid <= 0;
 394
 395   return "unknown cust_main.custnum: ". $self->custnum
 396     unless $self->invnum
 397            || qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 398
 399   $self->_date(time) unless $self->_date;
 400
 401 #i guess not now, with cust_pay_pending, if we actually make it here, we _do_ want to record it
 402 #  # UNIQUE index should catch this too, without race conditions, but this
 403 #  # should give a better error message the other 99.9% of the time...
 404 #  if ( length($self->payunique)
 405 #       && qsearchs('cust_pay', { 'payunique' => $self->payunique } ) ) {
 406 #    #well, it *could* be a better error message
 407 #    return "duplicate transaction".
 408 #           " - a payment with unique identifer ". $self->payunique.
 409 #           " already exists";
 410 #  }
 411
 412   $self->SUPER::check;
 413 }
 414
 415 =item send_receipt HASHREF | OPTION => VALUE ...
 416
 417 Sends a payment receipt for this payment..
 418
 419 Available options:
 420
 421 =over 4
 422
 423 =item manual
 424
 425 Flag indicating the payment is being made manually.
 426
 427 =item cust_bill
 428
 429 Invoice (FS::cust_bill) object.  If not specified, the most recent invoice
 430 will be assumed.
 431
 432 =item cust_main
 433
 434 Customer (FS::cust_main) object (for efficiency).
 435
 436 =back
 437
 438 =cut
 439
 440 sub send_receipt {
 441   my $self = shift;
 442   my $opt = ref($_[0]) ? shift : { @_ };
 443
 444   my $cust_bill = $opt->{'cust_bill'};
 445   my $cust_main = $opt->{'cust_main'} || $self->cust_main;
 446
 447   my $conf = new FS::Conf;
 448
 449   return ''
 450     unless $conf->exists('payment_receipt_email')
 451         && grep { $_ !~ /^(POST|FAX)$/ } $cust_main->invoicing_list;
 452
 453   $cust_bill ||= ($cust_main->cust_bill)[-1]; #rather inefficient though?
 454
 455   if (    ( exists($opt->{'manual'}) && $opt->{'manual'} )
 456        || ! $conf->exists('invoice_html_statement')
 457        || ! $cust_bill
 458      ) {
 459
 460     my $receipt_template = new Text::Template (
 461       TYPE   => 'ARRAY',
 462       SOURCE => [ map "$_\n", $conf->config('payment_receipt_email') ],
 463     ) or do {
 464       warn "can't create payment receipt template: $Text::Template::ERROR";
 465       return '';
 466     };
 467
 468     my @invoicing_list = grep { $_ !~ /^(POST|FAX)$/ }
 469                            $cust_main->invoicing_list;
 470
 471     my $payby = $self->payby;
 472     my $payinfo = $self->payinfo;
 473     $payby =~ s/^BILL$/Check/ if $payinfo;
 474     if ( $payby eq 'CARD' || $payby eq 'CHEK' ) {
 475       $payinfo = $self->paymask
 476     } else {
 477       $payinfo = $self->decrypt($payinfo);
 478     }
 479     $payby =~ s/^CHEK$/Electronic check/;
 480
 481     my %fill_in = (
 482       'date'         => time2str("%a %B %o, %Y", $self->_date),
 483       'name'         => $cust_main->name,
 484       'paynum'       => $self->paynum,
 485       'paid'         => sprintf("%.2f", $self->paid),
 486       'payby'        => ucfirst(lc($payby)),
 487       'payinfo'      => $payinfo,
 488       'balance'      => $cust_main->balance,
 489       'company_name' => $conf->config('company_name', $cust_main->agentnum),
 490     );
 491
 492     if ( $opt->{'cust_pkg'} ) {
 493       $fill_in{'pkg'} = $opt->{'cust_pkg'}->part_pkg->pkg;
 494       #setup date, other things?
 495     }
 496
 497     send_email(
 498       'from'    => $conf->config('invoice_from', $cust_main->agentnum),
 499                                  #invoice_from??? well as good as any
 500       'to'      => \@invoicing_list,
 501       'subject' => 'Payment receipt',
 502       'body'    => [ $receipt_template->fill_in( HASH => \%fill_in ) ],
 503     );
 504
 505   } else {
 506
 507     my $queue = new FS::queue {
 508        'paynum' => $self->paynum,
 509        'job'    => 'FS::cust_bill::queueable_email',
 510     };
 511
 512     $queue->insert(
 513       'invnum'   => $cust_bill->invnum,
 514       'template' => 'statement',
 515     );
 516
 517   }
 518
 519 }
 520
 521 =item cust_bill_pay
 522
 523 Returns all applications to invoices (see L<FS::cust_bill_pay>) for this
 524 payment.
 525
 526 =cut
 527
 528 sub cust_bill_pay {
 529   my $self = shift;
 530   map { $_ } #return $self->num_cust_bill_pay unless wantarray;
 531   sort {    $a->_date  <=> $b->_date
 532          || $a->invnum <=> $b->invnum }
 533     qsearch( 'cust_bill_pay', { 'paynum' => $self->paynum } )
 534   ;
 535 }
 536
 537 =item cust_pay_refund
 538
 539 Returns all applications of refunds (see L<FS::cust_pay_refund>) to this
 540 payment.
 541
 542 =cut
 543
 544 sub cust_pay_refund {
 545   my $self = shift;
 546   map { $_ } #return $self->num_cust_pay_refund unless wantarray;
 547   sort { $a->_date <=> $b->_date }
 548     qsearch( 'cust_pay_refund', { 'paynum' => $self->paynum } )
 549   ;
 550 }
 551
 552
 553 =item unapplied
 554
 555 Returns the amount of this payment that is still unapplied; which is
 556 paid minus all payment applications (see L<FS::cust_bill_pay>) and refund
 557 applications (see L<FS::cust_pay_refund>).
 558
 559 =cut
 560
 561 sub unapplied {
 562   my $self = shift;
 563   my $amount = $self->paid;
 564   $amount -= $_->amount foreach ( $self->cust_bill_pay );
 565   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 566   sprintf("%.2f", $amount );
 567 }
 568
 569 =item unrefunded
 570
 571 Returns the amount of this payment that has not been refuned; which is
 572 paid minus all  refund applications (see L<FS::cust_pay_refund>).
 573
 574 =cut
 575
 576 sub unrefunded {
 577   my $self = shift;
 578   my $amount = $self->paid;
 579   $amount -= $_->amount foreach ( $self->cust_pay_refund );
 580   sprintf("%.2f", $amount );
 581 }
 582
 583 =item amount
 584
 585 Returns the "paid" field.
 586
 587 =cut
 588
 589 sub amount {
 590   my $self = shift;
 591   $self->paid();
 592 }
 593
 594 =back
 595
 596 =head1 CLASS METHODS
 597
 598 =over 4
 599
 600 =item batch_insert CUST_PAY_OBJECT, ...
 601
 602 Class method which inserts multiple payments.  Takes a list of FS::cust_pay
 603 objects.  Returns a list, each element representing the status of inserting the
 604 corresponding payment - empty.  If there is an error inserting any payment, the
 605 entire transaction is rolled back, i.e. all payments are inserted or none are.
 606
 607 For example:
 608
 609   my @errors = FS::cust_pay->batch_insert(@cust_pay);
 610   my $num_errors = scalar(grep $_, @errors);
 611   if ( $num_errors == 0 ) {
 612     #success; all payments were inserted
 613   } else {
 614     #failure; no payments were inserted.
 615   }
 616
 617 =cut
 618
 619 sub batch_insert {
 620   my $self = shift; #class method
 621
 622   local $SIG{HUP} = 'IGNORE';
 623   local $SIG{INT} = 'IGNORE';
 624   local $SIG{QUIT} = 'IGNORE';
 625   local $SIG{TERM} = 'IGNORE';
 626   local $SIG{TSTP} = 'IGNORE';
 627   local $SIG{PIPE} = 'IGNORE';
 628
 629   my $oldAutoCommit = $FS::UID::AutoCommit;
 630   local $FS::UID::AutoCommit = 0;
 631   my $dbh = dbh;
 632
 633   my $errors = 0;
 634
 635   my @errors = map {
 636     my $error = $_->insert( 'manual' => 1 );
 637     if ( $error ) {
 638       $errors++;
 639     } else {
 640       $_->cust_main->apply_payments;
 641     }
 642     $error;
 643   } @_;
 644
 645   if ( $errors ) {
 646     $dbh->rollback if $oldAutoCommit;
 647   } else {
 648     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 649   }
 650
 651   @errors;
 652
 653 }
 654
 655 =item unapplied_sql
 656
 657 Returns an SQL fragment to retreive the unapplied amount.
 658
 659 =cut
 660
 661 sub unapplied_sql {
 662   #my $class = shift;
 663
 664   "paid
 665         - COALESCE(
 666                     ( SELECT SUM(amount) FROM cust_bill_pay
 667                         WHERE cust_pay.paynum = cust_bill_pay.paynum )
 668                     ,0
 669                   )
 670         - COALESCE(
 671                     ( SELECT SUM(amount) FROM cust_pay_refund
 672                         WHERE cust_pay.paynum = cust_pay_refund.paynum )
 673                     ,0
 674                   )
 675   ";
 676
 677 }
 678
 679 # _upgrade_data
 680 #
 681 # Used by FS::Upgrade to migrate to a new database.
 682
 683 use FS::h_cust_pay;
 684
 685 sub _upgrade_data {  #class method
 686   my ($class, %opts) = @_;
 687
 688   warn "$me upgrading $class\n" if $DEBUG;
 689
 690   #not the most efficient, but hey, it only has to run once
 691
 692   my $where = "WHERE ( otaker IS NULL OR otaker = '' OR otaker = 'ivan' ) ".
 693               "  AND usernum IS NULL ".
 694               "  AND 0 < ( SELECT COUNT(*) FROM cust_main                 ".
 695               "              WHERE cust_main.custnum = cust_pay.custnum ) ";
 696
 697   my $count_sql = "SELECT COUNT(*) FROM cust_pay $where";
 698
 699   my $sth = dbh->prepare($count_sql) or die dbh->errstr;
 700   $sth->execute or die $sth->errstr;
 701   my $total = $sth->fetchrow_arrayref->[0];
 702   #warn "$total cust_pay records to update\n"
 703   #  if $DEBUG;
 704   local($DEBUG) = 2 if $total > 1000; #could be a while, force progress info
 705
 706   my $count = 0;
 707   my $lastprog = 0;
 708
 709   my @cust_pay = qsearch( {
 710       'table'     => 'cust_pay',
 711       'hashref'   => {},
 712       'extra_sql' => $where,
 713       'order_by'  => 'ORDER BY paynum',
 714   } );
 715
 716   foreach my $cust_pay (@cust_pay) {
 717
 718     my $h_cust_pay = $cust_pay->h_search('insert');
 719     if ( $h_cust_pay ) {
 720       next if $cust_pay->otaker eq $h_cust_pay->history_user;
 721       $cust_pay->otaker($h_cust_pay->history_user);
 722     } else {
 723       $cust_pay->otaker('legacy');
 724     }
 725
 726     delete $FS::payby::hash{'COMP'}->{cust_pay}; #quelle kludge
 727     my $error = $cust_pay->replace;
 728
 729     if ( $error ) {
 730       warn " *** WARNING: Error updating order taker for payment paynum ".
 731            $cust_pay->paynun. ": $error\n";
 732       next;
 733     }
 734
 735     $FS::payby::hash{'COMP'}->{cust_pay} = ''; #restore it
 736
 737     $count++;
 738     if ( $DEBUG > 1 && $lastprog + 30 < time ) {
 739       warn "$me $count/$total (". sprintf('%.2f',100*$count/$total). '%)'. "\n";
 740       $lastprog = time;
 741     }
 742
 743   }
 744
 745   $class->_upgrade_otaker(%opts);
 746
 747 }
 748
 749 =back
 750
 751 =head1 SUBROUTINES
 752
 753 =over 4
 754
 755 =item batch_import HASHREF
 756
 757 Inserts new payments.
 758
 759 =cut
 760
 761 sub batch_import {
 762   my $param = shift;
 763
 764   my $fh = $param->{filehandle};
 765   my $agentnum = $param->{agentnum};
 766   my $format = $param->{'format'};
 767   my $paybatch = $param->{'paybatch'};
 768
 769   # here is the agent virtualization
 770   my $extra_sql = ' AND '. $FS::CurrentUser::CurrentUser->agentnums_sql;
 771
 772   my @fields;
 773   my $payby;
 774   if ( $format eq 'simple' ) {
 775     @fields = qw( custnum agent_custid paid payinfo );
 776     $payby = 'BILL';
 777   } elsif ( $format eq 'extended' ) {
 778     die "unimplemented\n";
 779     @fields = qw( );
 780     $payby = 'BILL';
 781   } else {
 782     die "unknown format $format";
 783   }
 784
 785   eval "use Text::CSV_XS;";
 786   die $@ if $@;
 787
 788   my $csv = new Text::CSV_XS;
 789
 790   my $imported = 0;
 791
 792   local $SIG{HUP} = 'IGNORE';
 793   local $SIG{INT} = 'IGNORE';
 794   local $SIG{QUIT} = 'IGNORE';
 795   local $SIG{TERM} = 'IGNORE';
 796   local $SIG{TSTP} = 'IGNORE';
 797   local $SIG{PIPE} = 'IGNORE';
 798
 799   my $oldAutoCommit = $FS::UID::AutoCommit;
 800   local $FS::UID::AutoCommit = 0;
 801   my $dbh = dbh;
 802
 803   my $line;
 804   while ( defined($line=<$fh>) ) {
 805
 806     $csv->parse($line) or do {
 807       $dbh->rollback if $oldAutoCommit;
 808       return "can't parse: ". $csv->error_input();
 809     };
 810
 811     my @columns = $csv->fields();
 812
 813     my %cust_pay = (
 814       payby    => $payby,
 815       paybatch => $paybatch,
 816     );
 817
 818     my $cust_main;
 819     foreach my $field ( @fields ) {
 820
 821       if ( $field eq 'agent_custid'
 822         && $agentnum
 823         && $columns[0] =~ /\S+/ )
 824       {
 825
 826         my $agent_custid = $columns[0];
 827         my %hash = ( 'agent_custid' => $agent_custid,
 828                      'agentnum'     => $agentnum,
 829                    );
 830
 831         if ( $cust_pay{'custnum'} !~ /^\s*$/ ) {
 832           $dbh->rollback if $oldAutoCommit;
 833           return "can't specify custnum with agent_custid $agent_custid";
 834         }
 835
 836         $cust_main = qsearchs({
 837                                 'table'     => 'cust_main',
 838                                 'hashref'   => \%hash,
 839                                 'extra_sql' => $extra_sql,
 840                              });
 841
 842         unless ( $cust_main ) {
 843           $dbh->rollback if $oldAutoCommit;
 844           return "can't find customer with agent_custid $agent_custid";
 845         }
 846
 847         $field = 'custnum';
 848         $columns[0] = $cust_main->custnum;
 849       }
 850
 851       $cust_pay{$field} = shift @columns;
 852     }
 853
 854     my $cust_pay = new FS::cust_pay( \%cust_pay );
 855     my $error = $cust_pay->insert;
 856
 857     if ( $error ) {
 858       $dbh->rollback if $oldAutoCommit;
 859       return "can't insert payment for $line: $error";
 860     }
 861
 862     if ( $format eq 'simple' ) {
 863       # include agentnum for less surprise?
 864       $cust_main = qsearchs({
 865                              'table'     => 'cust_main',
 866                              'hashref'   => { 'custnum' => $cust_pay->custnum },
 867                              'extra_sql' => $extra_sql,
 868                            })
 869         unless $cust_main;
 870
 871       unless ( $cust_main ) {
 872         $dbh->rollback if $oldAutoCommit;
 873         return "can't find customer to which payments apply at line: $line";
 874       }
 875
 876       $error = $cust_main->apply_payments_and_credits;
 877       if ( $error ) {
 878         $dbh->rollback if $oldAutoCommit;
 879         return "can't apply payments to customer for $line: $error";
 880       }
 881
 882     }
 883
 884     $imported++;
 885   }
 886
 887   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 888
 889   return "Empty file!" unless $imported;
 890
 891   ''; #no error
 892
 893 }
 894
 895 =back
 896
 897 =head1 BUGS
 898
 899 Delete and replace methods.
 900
 901 =head1 SEE ALSO
 902
 903 L<FS::cust_pay_pending>, L<FS::cust_bill_pay>, L<FS::cust_bill>, L<FS::Record>,
 904 schema.html from the base documentation.
 905
 906 =cut
 907
 908 1;
 909