FS/FS/cust_main/Search.pm

   1 package FS::cust_main::Search;
   2
   3 use strict;
   4 use base qw( Exporter );
   5 use vars qw( @EXPORT_OK $DEBUG $me $conf @fuzzyfields );
   6 use String::Approx qw(amatch);
   7 use FS::UID qw( dbh );
   8 use FS::Record qw( qsearch );
   9 use FS::cust_main;
  10 use FS::cust_main_invoice;
  11 use FS::svc_acct;
  12 use FS::payinfo_Mixin;
  13
  14 @EXPORT_OK = qw( smart_search );
  15
  16 # 1 is mostly method/subroutine entry and options
  17 # 2 traces progress of some operations
  18 # 3 is even more information including possibly sensitive data
  19 $DEBUG = 0;
  20 $me = '[FS::cust_main::Search]';
  21
  22 @fuzzyfields = (
  23   'cust_main.first', 'cust_main.last', 'cust_main.company',
  24   'cust_main.ship_company', # if you're using it
  25   'cust_location.address1',
  26   'contact.first',   'contact.last',
  27 );
  28
  29 install_callback FS::UID sub {
  30   $conf = new FS::Conf;
  31   #yes, need it for stuff below (prolly should be cached)
  32 };
  33
  34 =head1 NAME
  35
  36 FS::cust_main::Search - Customer searching
  37
  38 =head1 SYNOPSIS
  39
  40   use FS::cust_main::Search;
  41
  42   FS::cust_main::Search::smart_search(%options);
  43
  44   FS::cust_main::Search::email_search(%options);
  45
  46   FS::cust_main::Search->search( \%options );
  47
  48   FS::cust_main::Search->fuzzy_search( \%fuzzy_hashref );
  49
  50 =head1 SUBROUTINES
  51
  52 =over 4
  53
  54 =item smart_search OPTION => VALUE ...
  55
  56 Accepts the following options: I<search>, the string to search for.  The string
  57 will be searched for as a customer number, phone number, name or company name,
  58 address (if address1-search is on), invoicing email address, or credit card
  59 number.
  60
  61 Searches match as an exact, or, in some cases, a substring or fuzzy match (see
  62 the source code for the exact heuristics used); I<no_fuzzy_on_exact>, causes
  63 smart_search to
  64 skip fuzzy matching when an exact match is found.
  65
  66 Any additional options are treated as an additional qualifier on the search
  67 (i.e. I<agentnum>).
  68
  69 Returns a (possibly empty) array of FS::cust_main objects.
  70
  71 =cut
  72
  73 sub smart_search {
  74   my %options = @_;
  75
  76   #here is the agent virtualization
  77   my $agentnums_sql =
  78     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
  79   my $agentnums_href = $FS::CurrentUser::CurrentUser->agentnums_href;
  80
  81   my @cust_main = ();
  82
  83   my $skip_fuzzy = delete $options{'no_fuzzy_on_exact'};
  84   my $search = delete $options{'search'};
  85   ( my $alphanum_search = $search ) =~ s/\W//g;
  86
  87   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
  88
  89     #false laziness w/Record::ut_phone
  90     my $phonen = "$1-$2-$3";
  91     $phonen .= " x$4" if $4;
  92
  93     my $phonenum = "$1$2$3";
  94     #my $extension = $4;
  95
  96     #cust_main phone numbers
  97     push @cust_main, qsearch( {
  98       'table'   => 'cust_main',
  99       'hashref' => { %options },
 100       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 101                      ' ( '.
 102                          join(' OR ', map "$_ = '$phonen'",
 103                                           qw( daytime night mobile fax )
 104                              ).
 105                      ' ) '.
 106                      " AND $agentnums_sql", #agent virtualization
 107     } );
 108
 109     #contact phone numbers
 110     push @cust_main,
 111       grep $agentnums_href->{$_->agentnum}, #agent virt
 112         grep $_, #skip contacts that don't have cust_main records
 113           map $_->contact->cust_main,
 114             qsearch({
 115                       'table'   => 'contact_phone',
 116                       'hashref' => { 'phonenum' => $phonenum },
 117                    });
 118
 119     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
 120       #try looking for matches with extensions unless one was specified
 121
 122       push @cust_main, qsearch( {
 123         'table'   => 'cust_main',
 124         'hashref' => { %options },
 125         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 126                        ' ( '.
 127                            join(' OR ', map "$_ LIKE '$phonen\%'",
 128                                             qw( daytime night )
 129                                ).
 130                        ' ) '.
 131                        " AND $agentnums_sql", #agent virtualization
 132       } );
 133
 134     }
 135
 136   }
 137
 138
 139   if ( $search =~ /@/ ) { #email address
 140
 141       # invoicing email address
 142       push @cust_main,
 143         grep $agentnums_href->{$_->agentnum}, #agent virt
 144           map $_->cust_main,
 145               qsearch( {
 146                          'table'     => 'cust_main_invoice',
 147                          'hashref'   => { 'dest' => $search },
 148                        }
 149                      );
 150
 151       # contact email address
 152       push @cust_main,
 153         grep $agentnums_href->{$_->agentnum}, #agent virt
 154           grep $_, #skip contacts that don't have cust_main records
 155             map $_->contact->cust_main,
 156               qsearch( {
 157                          'table'     => 'contact_email',
 158                          'hashref'   => { 'emailaddress' => $search },
 159                        }
 160                      );
 161
 162   # custnum search (also try agent_custid), with some tweaking options if your
 163   # legacy cust "numbers" have letters
 164   } elsif ( $search =~ /^\s*(\d+)\s*$/
 165          || ( $conf->config('cust_main-agent_custid-format') eq 'ww?d+'
 166               && $search =~ /^\s*(\w\w?\d+)\s*$/
 167             )
 168          || ( $conf->config('cust_main-custnum-display_special')
 169            # it's not currently possible for special prefixes to contain
 170            # digits, so just strip off any alphabetic prefix and match
 171            # the rest to custnum
 172               && $search =~ /^\s*[[:alpha:]]*(\d+)\s*$/
 173             )
 174          || ( $conf->exists('address1-search' )
 175               && $search =~ /^\s*(\d+\-?\w*)\s*$/ #i.e. 1234A or 9432-D
 176             )
 177      )
 178   {
 179
 180     my $num = $1;
 181
 182     if ( $num =~ /^(\d+)$/ && $num <= 2147483647 ) { #need a bigint custnum? wow
 183       my $agent_custid_null = $conf->exists('cust_main-default_agent_custid')
 184                                 ? ' AND agent_custid IS NULL ' : '';
 185       push @cust_main, qsearch( {
 186         'table'     => 'cust_main',
 187         'hashref'   => { 'custnum' => $num, %options },
 188         'extra_sql' => " AND $agentnums_sql $agent_custid_null",
 189       } );
 190     }
 191
 192     # for all agents this user can see, if any of them have custnum prefixes
 193     # that match the search string, include customers that match the rest
 194     # of the custnum and belong to that agent
 195     foreach my $agentnum ( keys %$agentnums_href ) {
 196       my $p = $conf->config('cust_main-custnum-display_prefix', $agentnum);
 197       next if !$p;
 198       if ( $p eq substr($num, 0, length($p)) ) {
 199         push @cust_main, qsearch( {
 200           'table'   => 'cust_main',
 201           'hashref' => { 'custnum' => 0 + substr($num, length($p)),
 202                          'agentnum' => $agentnum,
 203                           %options,
 204                        },
 205         } );
 206       }
 207     }
 208
 209     push @cust_main, qsearch( {
 210         'table'     => 'cust_main',
 211         'hashref'   => { 'agent_custid' => $num, %options },
 212         'extra_sql' => " AND $agentnums_sql", #agent virtualization
 213     } );
 214
 215     if ( $conf->exists('address1-search') ) {
 216       my $len = length($num);
 217       $num = lc($num);
 218       # probably the Right Thing: return customers that have any associated
 219       # locations matching the string, not just bill/ship location
 220       push @cust_main, qsearch( {
 221         'table'     => 'cust_main',
 222         'addl_from' => ' JOIN cust_location USING (custnum) ',
 223         'hashref'   => { %options, },
 224         'extra_sql' =>
 225           ( keys(%options) ? ' AND ' : ' WHERE ' ).
 226           " LOWER(SUBSTRING(cust_location.address1 FROM 1 FOR $len)) = '$num' ".
 227           " AND $agentnums_sql",
 228       } );
 229     }
 230
 231   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
 232
 233     my($company, $last, $first) = ( $1, $2, $3 );
 234
 235     # "Company (Last, First)"
 236     #this is probably something a browser remembered,
 237     #so just do an exact search (but case-insensitive, so USPS standardization
 238     #doesn't throw a wrench in the works)
 239
 240     push @cust_main, qsearch( {
 241         'table'     => 'cust_main',
 242         'hashref'   => { %options },
 243         'extra_sql' =>
 244         ( keys(%options) ? ' AND ' : ' WHERE ' ).
 245         join(' AND ',
 246           " LOWER(first)   = ". dbh->quote(lc($first)),
 247           " LOWER(last)    = ". dbh->quote(lc($last)),
 248           " LOWER(company) = ". dbh->quote(lc($company)),
 249           $agentnums_sql,
 250         ),
 251       } ),
 252
 253     #contacts?
 254     # probably not necessary for the "something a browser remembered" case
 255
 256   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
 257                                               # try {first,last,company}
 258
 259     my $value = lc($1);
 260
 261     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
 262     # # full strings the browser remembers won't work
 263     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
 264
 265     use Lingua::EN::NameParse;
 266     my $NameParse = new Lingua::EN::NameParse(
 267              auto_clean     => 1,
 268              allow_reversed => 1,
 269     );
 270
 271     my($last, $first) = ( '', '' );
 272     #maybe disable this too and just rely on NameParse?
 273     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
 274
 275       ($last, $first) = ( $1, $2 );
 276
 277     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
 278     } elsif ( ! $NameParse->parse($value) ) {
 279
 280       my %name = $NameParse->components;
 281       $first = $name{'given_name_1'} || $name{'initials_1'}; #wtf NameParse, Ed?
 282       $last  = $name{'surname_1'};
 283
 284     }
 285
 286     if ( $first && $last ) {
 287
 288       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
 289
 290       #exact
 291       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 292       $sql .= "( LOWER(cust_main.last) = $q_last AND LOWER(cust_main.first) = $q_first )";
 293
 294       #cust_main
 295       push @cust_main, qsearch( {
 296         'table'     => 'cust_main',
 297         'hashref'   => \%options,
 298         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 299       } );
 300
 301       #contacts
 302       push @cust_main,
 303         grep $agentnums_href->{$_->agentnum}, #agent virt
 304           grep $_, #skip contacts that don't have cust_main records
 305             map $_->cust_main,
 306               qsearch( {
 307                          'table'     => 'contact',
 308                          'hashref'   => { 'first' => $first,
 309                                           'last'  => $last,
 310                                         },
 311                        }
 312                      );
 313
 314       # or it just be something that was typed in... (try that in a sec)
 315
 316     }
 317
 318     my $q_value = dbh->quote($value);
 319
 320     #exact
 321     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 322     $sql .= " (    LOWER(cust_main.first)         = $q_value
 323                 OR LOWER(cust_main.last)          = $q_value
 324                 OR LOWER(cust_main.company)       = $q_value
 325                 OR LOWER(cust_main.ship_company)  = $q_value
 326             ";
 327
 328     #address1 (yes, it's a kludge)
 329     $sql .= "   OR EXISTS (
 330                             SELECT 1 FROM cust_location
 331                               WHERE LOWER(cust_location.address1) = $q_value
 332                                 AND cust_location.custnum = cust_main.custnum
 333                           )"
 334       if $conf->exists('address1-search');
 335
 336     #contacts (look, another kludge)
 337     $sql .= "   OR EXISTS ( SELECT 1 FROM contact
 338                               WHERE (    LOWER(contact.first) = $q_value
 339                                       OR LOWER(contact.last)  = $q_value
 340                                     )
 341                                 AND contact.custnum IS NOT NULL
 342                                 AND contact.custnum = cust_main.custnum
 343                           )
 344               ) ";
 345
 346     push @cust_main, qsearch( {
 347       'table'     => 'cust_main',
 348       'hashref'   => \%options,
 349       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 350     } );
 351
 352     #no exact match, trying substring/fuzzy
 353     #always do substring & fuzzy (unless they're explicity config'ed off)
 354     #getting complaints searches are not returning enough
 355     unless ( @cust_main  && $skip_fuzzy || $conf->exists('disable-fuzzy') ) {
 356
 357       #still some false laziness w/search (was search/cust_main.cgi)
 358
 359       #substring
 360
 361       my @company_hashrefs = (
 362         { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
 363         { 'ship_company' => { op=>'ILIKE', value=>"%$value%" }, },
 364       );
 365
 366       my @hashrefs = ();
 367
 368       if ( $first && $last ) {
 369
 370         @hashrefs = (
 371           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
 372             'last'         => { op=>'ILIKE', value=>"%$last%" },
 373           },
 374         );
 375
 376       } else {
 377
 378         @hashrefs = (
 379           { 'first'        => { op=>'ILIKE', value=>"%$value%" }, },
 380           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
 381         );
 382       }
 383
 384       foreach my $hashref ( @company_hashrefs, @hashrefs ) {
 385
 386         push @cust_main, qsearch( {
 387           'table'     => 'cust_main',
 388           'hashref'   => { %$hashref,
 389                            %options,
 390                          },
 391           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
 392         } );
 393
 394       }
 395
 396       if ( $conf->exists('address1-search') ) {
 397
 398         push @cust_main, qsearch( {
 399           table     => 'cust_main',
 400           addl_from => 'JOIN cust_location USING (custnum)',
 401           extra_sql => 'WHERE '.
 402                         ' cust_location.address1 ILIKE '.dbh->quote("%$value%").
 403                         " AND $agentnums_sql", #agent virtualizaiton
 404         } );
 405
 406       }
 407
 408       #contact substring
 409
 410       foreach my $hashref ( @hashrefs ) {
 411
 412         push @cust_main,
 413           grep $agentnums_href->{$_->agentnum}, #agent virt
 414             grep $_, #skip contacts that don't have cust_main records
 415               map $_->cust_main,
 416                 qsearch({
 417                           'table'     => 'contact',
 418                           'hashref'   => { %$hashref,
 419                                            #%options,
 420                                          },
 421                           #'extra_sql' => " AND $agentnums_sql", #agent virt
 422                        });
 423
 424       }
 425
 426       #fuzzy
 427       my %fuzopts = (
 428         'hashref'   => \%options,
 429         'select'    => '',
 430         'extra_sql' => "WHERE $agentnums_sql",    #agent virtualization
 431       );
 432
 433       if ( $first && $last ) {
 434         push @cust_main, FS::cust_main::Search->fuzzy_search(
 435           { 'last'   => $last,    #fuzzy hashref
 436             'first'  => $first }, #
 437           %fuzopts
 438         );
 439         push @cust_main, FS::cust_main::Search->fuzzy_search(
 440           { 'contact.last'   => $last,    #fuzzy hashref
 441             'contact.first'  => $first }, #
 442           %fuzopts
 443         );
 444      }
 445       foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
 446         push @cust_main, FS::cust_main::Search->fuzzy_search(
 447           { $field => $value },
 448           %fuzopts
 449         );
 450       }
 451       foreach my $field ( 'first', 'last' ) {
 452         push @cust_main, FS::cust_main::Search->fuzzy_search(
 453           { "contact.$field" => $value },
 454           %fuzopts
 455         );
 456       }
 457       if ( $conf->exists('address1-search') ) {
 458         push @cust_main,
 459           FS::cust_main::Search->fuzzy_search(
 460             { 'cust_location.address1' => $value },
 461             %fuzopts
 462         );
 463       }
 464
 465     }
 466
 467   }
 468
 469   ( my $nospace_search = $search ) =~ s/\s//g;
 470   ( my $card_search = $nospace_search ) =~ s/\-//g;
 471   $card_search =~ s/[x\*\.\_]/x/gi;
 472
 473   if ( $card_search =~ /^[\dx]{15,16}$/i ) { #credit card search
 474
 475     ( my $like_search = $card_search ) =~ s/x/_/g;
 476     my $mask_search = FS::payinfo_Mixin->mask_payinfo('CARD', $card_search);
 477
 478     push @cust_main, qsearch({
 479       'table'     => 'cust_main',
 480       'addl_from' => ' JOIN cust_payby USING (custnum)',
 481       'hashref'   => {},
 482       'extra_sql' => " WHERE (    cust_payby.payinfo LIKE '$like_search'
 483                                OR cust_payby.paymask =    '$mask_search'
 484                              ) ".
 485                      " AND cust_payby.payby IN ('CARD','DCRD') ".
 486                      " AND $agentnums_sql", #agent virtulization
 487     });
 488
 489   }
 490
 491
 492   #eliminate duplicates
 493   my %saw = ();
 494   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 495
 496   @cust_main;
 497
 498 }
 499
 500 =item email_search
 501
 502 Accepts the following options: I<email>, the email address to search for.  The
 503 email address will be searched for as an email invoice destination and as an
 504 svc_acct account.
 505
 506 #Any additional options are treated as an additional qualifier on the search
 507 #(i.e. I<agentnum>).
 508
 509 Returns a (possibly empty) array of FS::cust_main objects (but usually just
 510 none or one).
 511
 512 =cut
 513
 514 sub email_search {
 515   my %options = @_;
 516
 517   local($DEBUG) = 1;
 518
 519   my $email = delete $options{'email'};
 520
 521   #we're only being used by RT at the moment... no agent virtualization yet
 522   #my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
 523
 524   my @cust_main = ();
 525
 526   if ( $email =~ /([^@]+)\@([^@]+)/ ) {
 527
 528     my ( $user, $domain ) = ( $1, $2 );
 529
 530     warn "$me smart_search: searching for $user in domain $domain"
 531       if $DEBUG;
 532
 533     push @cust_main,
 534       map { $_->cust_main }
 535       map { $_->cust_contact }
 536       map { $_->contact }
 537           qsearch( {
 538                      'table'     => 'contact_email',
 539                      'hashref'   => { 'emailaddress' => $email },
 540                    }
 541                  );
 542
 543     push @cust_main,
 544       map  $_->cust_main,
 545       grep $_,
 546       map  $_->cust_svc->cust_pkg,
 547           qsearch( {
 548                      'table'     => 'svc_acct',
 549                      'hashref'   => { 'username' => $user, },
 550                      'extra_sql' =>
 551                        'AND ( SELECT domain FROM svc_domain
 552                                 WHERE svc_acct.domsvc = svc_domain.svcnum
 553                             ) = '. dbh->quote($domain),
 554                    }
 555                  );
 556   }
 557
 558   my %saw = ();
 559   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 560
 561   warn "$me smart_search: found ". scalar(@cust_main). " unique customers"
 562     if $DEBUG;
 563
 564   @cust_main;
 565
 566 }
 567
 568 =back
 569
 570 =head1 CLASS METHODS
 571
 572 =over 4
 573
 574 =item search HASHREF
 575
 576 (Class method)
 577
 578 Returns a qsearch hash expression to search for parameters specified in
 579 HASHREF.  Valid parameters are
 580
 581 =over 4
 582
 583 =item agentnum
 584
 585 =item status
 586
 587 =item address
 588
 589 =item zip
 590
 591 =item refnum
 592
 593 =item cancelled_pkgs
 594
 595 bool
 596
 597 =item signupdate
 598
 599 listref of start date, end date
 600
 601 =item birthdate
 602
 603 listref of start date, end date
 604
 605 =item spouse_birthdate
 606
 607 listref of start date, end date
 608
 609 =item anniversary_date
 610
 611 listref of start date, end date
 612
 613 =item current_balance
 614
 615 listref (list returned by FS::UI::Web::parse_lt_gt($cgi, 'current_balance'))
 616
 617 =item cust_fields
 618
 619 =item flattened_pkgs
 620
 621 bool
 622
 623 =back
 624
 625 =cut
 626
 627 sub search {
 628   my ($class, $params) = @_;
 629
 630   my $dbh = dbh;
 631
 632   my @where = ();
 633   my $orderby;
 634
 635   # initialize these to prevent warnings
 636   $params = {
 637     'custnum'       => '',
 638     'agentnum'      => '',
 639     'usernum'       => '',
 640     'status'        => '',
 641     'address'       => '',
 642     'zip'           => '',
 643     'invoice_terms' => '',
 644     'custbatch'     => '',
 645     %$params
 646   };
 647
 648   ##
 649   # explicit custnum(s)
 650   ##
 651
 652   if ( $params->{'custnum'} ) {
 653     my @custnums = ref($params->{'custnum'}) ?
 654                       @{ $params->{'custnum'} } :
 655                       $params->{'custnum'};
 656     push @where,
 657       'cust_main.custnum IN (' .
 658       join(',', map { $_ =~ /^(\d+)$/ ? $1 : () } @custnums ) .
 659       ')' if scalar(@custnums) > 0;
 660   }
 661
 662   ##
 663   # parse agent
 664   ##
 665
 666   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
 667     push @where,
 668       "cust_main.agentnum = $1";
 669   }
 670
 671   ##
 672   # parse sales person
 673   ##
 674
 675   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
 676     push @where, ($1 > 0 ) ? "cust_main.salesnum = $1"
 677                            : 'cust_main.salesnum IS NULL';
 678   }
 679
 680   ##
 681   # parse usernum
 682   ##
 683
 684   if ( $params->{'usernum'} =~ /^(\d+)$/ and $1 ) {
 685     push @where,
 686       "cust_main.usernum = $1";
 687   }
 688
 689   ##
 690   # parse status
 691   ##
 692
 693   #prospect ordered active inactive suspended cancelled
 694   if ( grep { $params->{'status'} eq $_ } FS::cust_main->statuses() ) {
 695     my $method = $params->{'status'}. '_sql';
 696     #push @where, $class->$method();
 697     push @where, FS::cust_main->$method();
 698   }
 699
 700   ##
 701   # address
 702   ##
 703   if ( $params->{'address'} ) {
 704     # allow this to be an arrayref
 705     my @values = ($params->{'address'});
 706     @values = @{$values[0]} if ref($values[0]);
 707     my @orwhere;
 708     foreach (grep /\S/, @values) {
 709       my $address = dbh->quote('%'. lc($_). '%');
 710       push @orwhere,
 711         "LOWER(cust_location.address1) LIKE $address",
 712         "LOWER(cust_location.address2) LIKE $address";
 713     }
 714     if (@orwhere) {
 715       push @where, "EXISTS(
 716         SELECT 1 FROM cust_location
 717         WHERE cust_location.custnum = cust_main.custnum
 718           AND (".join(' OR ',@orwhere).")
 719         )";
 720     }
 721   }
 722
 723   ##
 724   # city
 725   ##
 726   if ( $params->{'city'} =~ /\S/ ) {
 727     my $city = dbh->quote($params->{'city'});
 728     push @where, "EXISTS(
 729       SELECT 1 FROM cust_location
 730       WHERE cust_location.custnum = cust_main.custnum
 731         AND cust_location.city = $city
 732     )";
 733   }
 734
 735   ##
 736   # county
 737   ##
 738   if ( $params->{'county'} =~ /\S/ ) {
 739     my $county = dbh->quote($params->{'county'});
 740     push @where, "EXISTS(
 741       SELECT 1 FROM cust_location
 742       WHERE cust_location.custnum = cust_main.custnum
 743         AND cust_location.county = $county
 744     )";
 745   }
 746
 747   ##
 748   # state
 749   ##
 750   if ( $params->{'state'} =~ /\S/ ) {
 751     my $state = dbh->quote($params->{'state'});
 752     push @where, "EXISTS(
 753       SELECT 1 FROM cust_location
 754       WHERE cust_location.custnum = cust_main.custnum
 755         AND cust_location.state = $state
 756     )";
 757   }
 758
 759   ##
 760   # zipcode
 761   ##
 762   if ( $params->{'zip'} =~ /\S/ ) {
 763     my $zip = dbh->quote($params->{'zip'} . '%');
 764     push @where, "EXISTS(
 765       SELECT 1 FROM cust_location
 766       WHERE cust_location.custnum = cust_main.custnum
 767         AND cust_location.zip LIKE $zip
 768     )";
 769   }
 770
 771   ##
 772   # country
 773   ##
 774   if ( $params->{'country'} =~ /^(\w\w)$/ ) {
 775     my $country = uc($1);
 776     push @where, "EXISTS(
 777       SELECT 1 FROM cust_location
 778       WHERE cust_location.custnum = cust_main.custnum
 779         AND cust_location.country = '$country'
 780     )";
 781   }
 782
 783   ###
 784   # refnum
 785   ###
 786   if ( $params->{'refnum'}  ) {
 787
 788     my @refnum = ref( $params->{'refnum'} )
 789                    ? @{ $params->{'refnum'} }
 790                    :  ( $params->{'refnum'} );
 791
 792     @refnum = grep /^(\d*)$/, @refnum;
 793
 794     push @where, '( '. join(' OR ', map "cust_main.refnum = $_", @refnum ). ' )'
 795       if @refnum;
 796
 797   }
 798
 799   ##
 800   # parse cancelled package checkbox
 801   ##
 802
 803   my $pkgwhere = "";
 804
 805   $pkgwhere .= "AND (cancel = 0 or cancel is null)"
 806     unless $params->{'cancelled_pkgs'};
 807
 808   ##
 809   # "with email address(es)" checkbox
 810   ##
 811
 812   push @where,
 813     'EXISTS ( SELECT 1 FROM contact_email
 814                 JOIN cust_contact USING (contactnum)
 815                 WHERE cust_contact.custnum = cust_main.custnum
 816             )'
 817     if $params->{'with_email'};
 818
 819   ##
 820   # "with postal mail invoices" checkbox
 821   ##
 822
 823   push @where, "cust_main.postal_invoice = 'Y'"
 824     if $params->{'POST'};
 825
 826   ##
 827   # "without postal mail invoices" checkbox
 828   ##
 829
 830   push @where, "cust_main.postal_invoice IS NULL"
 831     if $params->{'no_POST'};
 832
 833   ##
 834   # "tax exempt" checkbox
 835   ##
 836   push @where, "cust_main.tax = 'Y'"
 837     if $params->{'tax'};
 838
 839   ##
 840   # "not tax exempt" checkbox
 841   ##
 842   push @where, "(cust_main.tax = '' OR cust_main.tax IS NULL )"
 843     if $params->{'no_tax'};
 844
 845   ##
 846   # dates
 847   ##
 848
 849   foreach my $field (qw( signupdate birthdate spouse_birthdate anniversary_date )) {
 850
 851     next unless exists($params->{$field});
 852
 853     my($beginning, $ending, $hour) = @{$params->{$field}};
 854
 855     push @where,
 856       "cust_main.$field IS NOT NULL",
 857       "cust_main.$field >= $beginning",
 858       "cust_main.$field <= $ending";
 859
 860     if($field eq 'signupdate' && defined $hour) {
 861       if ($dbh->{Driver}->{Name} =~ /Pg/i) {
 862         push @where, "extract(hour from to_timestamp(cust_main.$field)) = $hour";
 863       }
 864       elsif( $dbh->{Driver}->{Name} =~ /mysql/i) {
 865         push @where, "hour(from_unixtime(cust_main.$field)) = $hour"
 866       }
 867       else {
 868         warn "search by time of day not supported on ".$dbh->{Driver}->{Name}." databases";
 869       }
 870     }
 871
 872     $orderby ||= "ORDER BY cust_main.$field";
 873
 874   }
 875
 876   ###
 877   # classnum
 878   ###
 879
 880   if ( $params->{'classnum'} ) {
 881
 882     my @classnum = ref( $params->{'classnum'} )
 883                      ? @{ $params->{'classnum'} }
 884                      :  ( $params->{'classnum'} );
 885
 886     @classnum = grep /^(\d*)$/, @classnum;
 887
 888     if ( @classnum ) {
 889       push @where, '( '. join(' OR ', map {
 890                                             $_ ? "cust_main.classnum = $_"
 891                                                : "cust_main.classnum IS NULL"
 892                                           }
 893                                           @classnum
 894                              ).
 895                    ' )';
 896     }
 897
 898   }
 899
 900   ###
 901   # invoice terms
 902   ###
 903
 904   if ( $params->{'invoice_terms'} =~ /^([\w ]+)$/ ) {
 905     my $terms = $1;
 906     if ( $1 eq 'NULL' ) {
 907       push @where,
 908         "( cust_main.invoice_terms IS NULL OR cust_main.invoice_terms = '' )";
 909     } else {
 910       push @where,
 911         "cust_main.invoice_terms IS NOT NULL",
 912         "cust_main.invoice_terms = '$1'";
 913     }
 914   }
 915
 916   ##
 917   # amounts
 918   ##
 919
 920   if ( $params->{'current_balance'} ) {
 921
 922     #my $balance_sql = $class->balance_sql();
 923     my $balance_sql = FS::cust_main->balance_sql();
 924
 925     my @current_balance =
 926       ref( $params->{'current_balance'} )
 927       ? @{ $params->{'current_balance'} }
 928       :  ( $params->{'current_balance'} );
 929
 930     push @where, map { s/current_balance/$balance_sql/; $_ }
 931                      @current_balance;
 932
 933   }
 934
 935   ##
 936   # custbatch
 937   ##
 938
 939   if ( $params->{'custbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
 940     push @where,
 941       "cust_main.custbatch = '$1'";
 942   }
 943
 944   if ( $params->{'tagnum'} ) {
 945     my @tagnums = ref( $params->{'tagnum'} ) ? @{ $params->{'tagnum'} } : ( $params->{'tagnum'} );
 946
 947     @tagnums = grep /^(\d+)$/, @tagnums;
 948
 949     if ( @tagnums ) {
 950       if ( $params->{'all_tags'} ) {
 951         foreach ( @tagnums ) {
 952           push @where, 'exists(select 1 from cust_tag where '.
 953                        'cust_tag.custnum = cust_main.custnum and tagnum = '.
 954                        $_ . ')';
 955         }
 956       } else { # matching any tag, not all
 957         my $tags_where = "0 < (select count(1) from cust_tag where "
 958                 . " cust_tag.custnum = cust_main.custnum and tagnum in ("
 959                 . join(',', @tagnums) . "))";
 960
 961         push @where, $tags_where;
 962       }
 963     }
 964   }
 965
 966   # pkg_classnum
 967   #   all_pkg_classnums
 968   #   any_pkg_status
 969   if ( $params->{'pkg_classnum'} ) {
 970     my @pkg_classnums = ref( $params->{'pkg_classnum'} ) ?
 971                           @{ $params->{'pkg_classnum'} } :
 972                              $params->{'pkg_classnum'};
 973     @pkg_classnums = grep /^(\d+)$/, @pkg_classnums;
 974
 975     if ( @pkg_classnums ) {
 976
 977       my @pkg_where;
 978       if ( $params->{'all_pkg_classnums'} ) {
 979         push @pkg_where, "part_pkg.classnum = $_" foreach @pkg_classnums;
 980       } else {
 981         push @pkg_where,
 982           'part_pkg.classnum IN('. join(',', @pkg_classnums).')';
 983       }
 984       foreach (@pkg_where) {
 985         my $select_pkg =
 986           "SELECT 1 FROM cust_pkg JOIN part_pkg USING (pkgpart) WHERE ".
 987           "cust_pkg.custnum = cust_main.custnum AND $_ ";
 988         if ( not $params->{'any_pkg_status'} ) {
 989           $select_pkg .= 'AND '.FS::cust_pkg->active_sql;
 990         }
 991         push @where, "EXISTS($select_pkg)";
 992       }
 993     }
 994   }
 995
 996   ##
 997   # setup queries, subs, etc. for the search
 998   ##
 999
1000   $orderby ||= 'ORDER BY custnum';
1001
1002   # here is the agent virtualization
1003   push @where,
1004     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
1005
1006   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
1007
1008   my $addl_from = '';
1009   # always make address fields available in results
1010   for my $pre ('bill_', 'ship_') {
1011     $addl_from .=
1012       'LEFT JOIN cust_location AS '.$pre.'location '.
1013       'ON (cust_main.'.$pre.'locationnum = '.$pre.'location.locationnum) ';
1014   }
1015
1016   my $count_query = "SELECT COUNT(*) FROM cust_main $addl_from $extra_sql";
1017
1018   my @select = (
1019                  'cust_main.custnum',
1020                  'cust_main.salesnum',
1021                  # there's a good chance that we'll need these
1022                  'cust_main.bill_locationnum',
1023                  'cust_main.ship_locationnum',
1024                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
1025                );
1026
1027   my(@extra_headers) = ();
1028   my(@extra_fields)  = ();
1029
1030   if ($params->{'flattened_pkgs'}) {
1031
1032     #my $pkg_join = '';
1033     $addl_from .=
1034       ' LEFT JOIN cust_pkg ON ( cust_main.custnum = cust_pkg.custnum ) ';
1035
1036     if ($dbh->{Driver}->{Name} eq 'Pg') {
1037
1038       push @select, "
1039         ARRAY_TO_STRING(
1040           ARRAY(
1041             SELECT pkg FROM cust_pkg LEFT JOIN part_pkg USING ( pkgpart )
1042               WHERE cust_main.custnum = cust_pkg.custnum $pkgwhere
1043           ), '|'
1044         ) AS magic
1045       ";
1046
1047     } elsif ($dbh->{Driver}->{Name} =~ /^mysql/i) {
1048       push @select, "GROUP_CONCAT(part_pkg.pkg SEPARATOR '|') as magic";
1049       $addl_from .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1050       #$pkg_join  .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1051     } else {
1052       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
1053            "omitting package information from report.";
1054     }
1055
1056     my $header_query = "
1057       SELECT COUNT(cust_pkg.custnum = cust_main.custnum) AS count
1058         FROM cust_main $addl_from $extra_sql $pkgwhere
1059           GROUP BY cust_main.custnum ORDER BY count DESC LIMIT 1
1060     ";
1061
1062     my $sth = dbh->prepare($header_query) or die dbh->errstr;
1063     $sth->execute() or die $sth->errstr;
1064     my $headerrow = $sth->fetchrow_arrayref;
1065     my $headercount = $headerrow ? $headerrow->[0] : 0;
1066     while($headercount) {
1067       unshift @extra_headers, "Package ". $headercount;
1068       unshift @extra_fields, eval q!sub {my $c = shift;
1069                                          my @a = split '\|', $c->magic;
1070                                          my $p = $a[!.--$headercount. q!];
1071                                          $p;
1072                                         };!;
1073     }
1074
1075   }
1076
1077   my $select = join(', ', @select);
1078
1079   my $sql_query = {
1080     'table'         => 'cust_main',
1081     'select'        => $select,
1082     'addl_from'     => $addl_from,
1083     'hashref'       => {},
1084     'extra_sql'     => $extra_sql,
1085     'order_by'      => $orderby,
1086     'count_query'   => $count_query,
1087     'extra_headers' => \@extra_headers,
1088     'extra_fields'  => \@extra_fields,
1089   };
1090   $sql_query;
1091
1092 }
1093
1094 =item fuzzy_search FUZZY_HASHREF [ OPTS ]
1095
1096 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
1097 records.  Currently, I<first>, I<last>, I<company> and/or I<address1> may be
1098 specified.
1099
1100 Additional options are the same as FS::Record::qsearch
1101
1102 =cut
1103
1104 sub fuzzy_search {
1105   my $self = shift;
1106   my $fuzzy = shift;
1107   # sensible defaults, then merge in any passed options
1108   my %fuzopts = (
1109     'table'     => 'cust_main',
1110     'addl_from' => '',
1111     'extra_sql' => '',
1112     'hashref'   => {},
1113     @_
1114   );
1115
1116   my @cust_main = ();
1117
1118   my @fuzzy_mod = 'i';
1119   my $conf = new FS::Conf;
1120   my $fuzziness = $conf->config('fuzzy-fuzziness');
1121   push @fuzzy_mod, $fuzziness if $fuzziness;
1122
1123   check_and_rebuild_fuzzyfiles();
1124   foreach my $field ( keys %$fuzzy ) {
1125
1126     my $all = $self->all_X($field);
1127     next unless scalar(@$all);
1128
1129     my %match = ();
1130     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, \@fuzzy_mod, @$all ) );
1131     next if !keys(%match);
1132
1133     my $in_matches = 'IN (' .
1134                      join(',', map { dbh->quote($_) } keys %match) .
1135                      ')';
1136
1137     my $extra_sql = $fuzopts{extra_sql};
1138     if ($extra_sql =~ /^\s*where /i or keys %{ $fuzopts{hashref} }) {
1139       $extra_sql .= ' AND ';
1140     } else {
1141       $extra_sql .= 'WHERE ';
1142     }
1143     $extra_sql .= "$field $in_matches";
1144
1145     my $addl_from = $fuzopts{addl_from};
1146     if ( $field =~ /^cust_location\./ ) {
1147       $addl_from .= ' JOIN cust_location USING (custnum)';
1148     } elsif ( $field =~ /^contact\./ ) {
1149       $addl_from .= ' JOIN contact USING (custnum)';
1150     }
1151
1152     push @cust_main, qsearch({
1153       %fuzopts,
1154       'addl_from' => $addl_from,
1155       'extra_sql' => $extra_sql,
1156     });
1157   }
1158
1159   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
1160   my %saw = ();
1161   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
1162
1163   @cust_main;
1164
1165 }
1166
1167 =back
1168
1169 =head1 UTILITY SUBROUTINES
1170
1171 =over 4
1172
1173 =item check_and_rebuild_fuzzyfiles
1174
1175 =cut
1176
1177 sub check_and_rebuild_fuzzyfiles {
1178   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1179   rebuild_fuzzyfiles()
1180     if grep { ! -e "$dir/$_" }
1181          map {
1182                my ($field, $table) = reverse split('\.', $_);
1183                $table ||= 'cust_main';
1184                "$table.$field"
1185              }
1186            @fuzzyfields;
1187 }
1188
1189 =item rebuild_fuzzyfiles
1190
1191 =cut
1192
1193 sub rebuild_fuzzyfiles {
1194
1195   use Fcntl qw(:flock);
1196
1197   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1198   mkdir $dir, 0700 unless -d $dir;
1199
1200   foreach my $fuzzy ( @fuzzyfields ) {
1201
1202     my ($field, $table) = reverse split('\.', $fuzzy);
1203     $table ||= 'cust_main';
1204
1205     open(LOCK,">>$dir/$table.$field")
1206       or die "can't open $dir/$table.$field: $!";
1207     flock(LOCK,LOCK_EX)
1208       or die "can't lock $dir/$table.$field: $!";
1209
1210     open (CACHE, '>:encoding(UTF-8)', "$dir/$table.$field.tmp")
1211       or die "can't open $dir/$table.$field.tmp: $!";
1212
1213     my $sth = dbh->prepare(
1214       "SELECT $field FROM $table WHERE $field IS NOT NULL AND $field != ''"
1215     );
1216     $sth->execute or die $sth->errstr;
1217
1218     while ( my $row = $sth->fetchrow_arrayref ) {
1219       print CACHE $row->[0]. "\n";
1220     }
1221
1222     close CACHE or die "can't close $dir/$table.$field.tmp: $!";
1223
1224     rename "$dir/$table.$field.tmp", "$dir/$table.$field";
1225     close LOCK;
1226   }
1227
1228 }
1229
1230 =item append_fuzzyfiles FIRSTNAME LASTNAME COMPANY ADDRESS1
1231
1232 =cut
1233
1234 sub append_fuzzyfiles {
1235   #my( $first, $last, $company ) = @_;
1236
1237   check_and_rebuild_fuzzyfiles();
1238
1239   #foreach my $fuzzy (@fuzzyfields) {
1240   foreach my $fuzzy ( 'cust_main.first', 'cust_main.last', 'cust_main.company',
1241                       'cust_location.address1',
1242                       'cust_main.ship_company',
1243                     ) {
1244
1245     append_fuzzyfiles_fuzzyfield($fuzzy, shift);
1246
1247   }
1248
1249   1;
1250 }
1251
1252 =item append_fuzzyfiles_fuzzyfield COLUMN VALUE
1253
1254 =item append_fuzzyfiles_fuzzyfield TABLE.COLUMN VALUE
1255
1256 =cut
1257
1258 use Fcntl qw(:flock);
1259 sub append_fuzzyfiles_fuzzyfield {
1260   my( $fuzzyfield, $value ) = @_;
1261
1262   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1263
1264
1265   my ($field, $table) = reverse split('\.', $fuzzyfield);
1266   $table ||= 'cust_main';
1267
1268   return unless defined($value) && length($value);
1269
1270   open(CACHE, '>>:encoding(UTF-8)', "$dir/$table.$field" )
1271     or die "can't open $dir/$table.$field: $!";
1272   flock(CACHE,LOCK_EX)
1273     or die "can't lock $dir/$table.$field: $!";
1274
1275   print CACHE "$value\n";
1276
1277   flock(CACHE,LOCK_UN)
1278     or die "can't unlock $dir/$table.$field: $!";
1279   close CACHE;
1280
1281 }
1282
1283 =item all_X
1284
1285 =cut
1286
1287 sub all_X {
1288   my( $self, $fuzzy ) = @_;
1289   my ($field, $table) = reverse split('\.', $fuzzy);
1290   $table ||= 'cust_main';
1291
1292   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1293   open(CACHE, '<:encoding(UTF-8)', "$dir/$table.$field")
1294     or die "can't open $dir/$table.$field: $!";
1295   my @array = map { chomp; $_; } <CACHE>;
1296   close CACHE;
1297   \@array;
1298 }
1299
1300 =head1 BUGS
1301
1302 Bed bugs
1303
1304 =head1 SEE ALSO
1305
1306 L<FS::cust_main>, L<FS::Record>
1307
1308 =cut
1309
1310 1;
1311