FS/FS/cust_main/Search.pm

   1 package FS::cust_main::Search;
   2
   3 use strict;
   4 use base qw( Exporter );
   5 use vars qw( @EXPORT_OK $DEBUG $me $conf @fuzzyfields );
   6 use String::Approx qw(amatch);
   7 use FS::UID qw( dbh );
   8 use FS::Record qw( qsearch );
   9 use FS::cust_main;
  10 use FS::cust_main_invoice;
  11 use FS::svc_acct;
  12
  13 @EXPORT_OK = qw( smart_search );
  14
  15 # 1 is mostly method/subroutine entry and options
  16 # 2 traces progress of some operations
  17 # 3 is even more information including possibly sensitive data
  18 $DEBUG = 0;
  19 $me = '[FS::cust_main::Search]';
  20
  21 @fuzzyfields = ( 'first', 'last', 'company', 'address1' );
  22
  23 install_callback FS::UID sub {
  24   $conf = new FS::Conf;
  25   #yes, need it for stuff below (prolly should be cached)
  26 };
  27
  28 =head1 NAME
  29
  30 FS::cust_main::Search - Customer searching
  31
  32 =head1 SYNOPSIS
  33
  34   use FS::cust_main::Search;
  35
  36   FS::cust_main::Search::smart_search(%options);
  37
  38   FS::cust_main::Search::email_search(%options);
  39
  40   FS::cust_main::Search->search( \%options );
  41
  42   FS::cust_main::Search->fuzzy_search( \%fuzzy_hashref );
  43
  44 =head1 SUBROUTINES
  45
  46 =over 4
  47
  48 =item smart_search OPTION => VALUE ...
  49
  50 Accepts the following options: I<search>, the string to search for.  The string
  51 will be searched for as a customer number, phone number, name or company name,
  52 as an exact, or, in some cases, a substring or fuzzy match (see the source code
  53 for the exact heuristics used); I<no_fuzzy_on_exact>, causes smart_search to
  54 skip fuzzy matching when an exact match is found.
  55
  56 Any additional options are treated as an additional qualifier on the search
  57 (i.e. I<agentnum>).
  58
  59 Returns a (possibly empty) array of FS::cust_main objects.
  60
  61 =cut
  62
  63 sub smart_search {
  64   my %options = @_;
  65
  66   #here is the agent virtualization
  67   my $agentnums_sql =
  68     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
  69
  70   my @cust_main = ();
  71
  72   my $skip_fuzzy = delete $options{'no_fuzzy_on_exact'};
  73   my $search = delete $options{'search'};
  74   ( my $alphanum_search = $search ) =~ s/\W//g;
  75
  76   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
  77
  78     #false laziness w/Record::ut_phone
  79     my $phonen = "$1-$2-$3";
  80     $phonen .= " x$4" if $4;
  81
  82     push @cust_main, qsearch( {
  83       'table'   => 'cust_main',
  84       'hashref' => { %options },
  85       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
  86                      ' ( '.
  87                          join(' OR ', map "$_ = '$phonen'",
  88                                           qw( daytime night fax )
  89                              ).
  90                      ' ) '.
  91                      " AND $agentnums_sql", #agent virtualization
  92     } );
  93
  94     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
  95       #try looking for matches with extensions unless one was specified
  96
  97       push @cust_main, qsearch( {
  98         'table'   => 'cust_main',
  99         'hashref' => { %options },
 100         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 101                        ' ( '.
 102                            join(' OR ', map "$_ LIKE '$phonen\%'",
 103                                             qw( daytime night )
 104                                ).
 105                        ' ) '.
 106                        " AND $agentnums_sql", #agent virtualization
 107       } );
 108
 109     }
 110
 111   # custnum search (also try agent_custid), with some tweaking options if your
 112   # legacy cust "numbers" have letters
 113   }
 114
 115
 116   if ( $search =~ /@/ ) {
 117       push @cust_main,
 118           map $_->cust_main,
 119               qsearch( {
 120                          'table'     => 'cust_main_invoice',
 121                          'hashref'   => { 'dest' => $search },
 122                        }
 123                      );
 124   } elsif ( $search =~ /^\s*(\d+)\s*$/
 125          || ( $conf->config('cust_main-agent_custid-format') eq 'ww?d+'
 126               && $search =~ /^\s*(\w\w?\d+)\s*$/
 127             )
 128          || ( $conf->config('cust_main-custnum-display_special')
 129            # it's not currently possible for special prefixes to contain
 130            # digits, so just strip off any alphabetic prefix and match
 131            # the rest to custnum
 132               && $search =~ /^\s*[[:alpha:]]*(\d+)\s*$/
 133             )
 134          || ( $conf->exists('address1-search' )
 135               && $search =~ /^\s*(\d+\-?\w*)\s*$/ #i.e. 1234A or 9432-D
 136             )
 137      )
 138   {
 139
 140     my $num = $1;
 141
 142     if ( $num =~ /^(\d+)$/ && $num <= 2147483647 ) { #need a bigint custnum? wow
 143       my $agent_custid_null = $conf->exists('cust_main-default_agent_custid')
 144                                 ? ' AND agent_custid IS NULL ' : '';
 145       push @cust_main, qsearch( {
 146         'table'     => 'cust_main',
 147         'hashref'   => { 'custnum' => $num, %options },
 148         'extra_sql' => " AND $agentnums_sql $agent_custid_null",
 149       } );
 150     }
 151
 152     # for all agents this user can see, if any of them have custnum prefixes
 153     # that match the search string, include customers that match the rest
 154     # of the custnum and belong to that agent
 155     foreach my $agentnum ( $FS::CurrentUser::CurrentUser->agentnums ) {
 156       my $p = $conf->config('cust_main-custnum-display_prefix', $agentnum);
 157       next if !$p;
 158       if ( $p eq substr($num, 0, length($p)) ) {
 159         push @cust_main, qsearch( {
 160           'table'   => 'cust_main',
 161           'hashref' => { 'custnum' => 0 + substr($num, length($p)),
 162                          'agentnum' => $agentnum,
 163                           %options,
 164                        },
 165         } );
 166       }
 167     }
 168
 169     push @cust_main, qsearch( {
 170         'table'     => 'cust_main',
 171         'hashref'   => { 'agent_custid' => $num, %options },
 172         'extra_sql' => " AND $agentnums_sql", #agent virtualization
 173     } );
 174
 175     if ( $conf->exists('address1-search') ) {
 176       my $len = length($num);
 177       $num = lc($num);
 178       # probably the Right Thing: return customers that have any associated
 179       # locations matching the string, not just bill/ship location
 180       push @cust_main, qsearch( {
 181         'table'     => 'cust_main',
 182         'addl_from' => ' JOIN cust_location USING (custnum) ',
 183         'hashref'   => { %options, },
 184         'extra_sql' =>
 185           ( keys(%options) ? ' AND ' : ' WHERE ' ).
 186           " LOWER(SUBSTRING(cust_location.address1 FROM 1 FOR $len)) = '$num' ".
 187           " AND $agentnums_sql",
 188       } );
 189     }
 190
 191   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
 192
 193     my($company, $last, $first) = ( $1, $2, $3 );
 194
 195     # "Company (Last, First)"
 196     #this is probably something a browser remembered,
 197     #so just do an exact search (but case-insensitive, so USPS standardization
 198     #doesn't throw a wrench in the works)
 199
 200     push @cust_main, qsearch( {
 201         'table'     => 'cust_main',
 202         'hashref'   => { %options },
 203         'extra_sql' =>
 204         ( keys(%options) ? ' AND ' : ' WHERE ' ).
 205         join(' AND ',
 206           " LOWER(first)   = ". dbh->quote(lc($first)),
 207           " LOWER(last)    = ". dbh->quote(lc($last)),
 208           " LOWER(company) = ". dbh->quote(lc($company)),
 209           $agentnums_sql,
 210         ),
 211       } ),
 212     #contacts?
 213
 214   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
 215                                               # try (ship_){last,company}
 216
 217     my $value = lc($1);
 218
 219     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
 220     # # full strings the browser remembers won't work
 221     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
 222
 223     use Lingua::EN::NameParse;
 224     my $NameParse = new Lingua::EN::NameParse(
 225              auto_clean     => 1,
 226              allow_reversed => 1,
 227     );
 228
 229     my($last, $first) = ( '', '' );
 230     #maybe disable this too and just rely on NameParse?
 231     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
 232
 233       ($last, $first) = ( $1, $2 );
 234
 235     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
 236     } elsif ( ! $NameParse->parse($value) ) {
 237
 238       my %name = $NameParse->components;
 239       $first = $name{'given_name_1'} || $name{'initials_1'}; #wtf NameParse, Ed?
 240       $last  = $name{'surname_1'};
 241
 242     }
 243
 244     if ( $first && $last ) {
 245
 246       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
 247
 248       #exact
 249       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 250       $sql .= "( LOWER(cust_main.last) = $q_last AND LOWER(cust_main.first) = $q_first )";
 251
 252       push @cust_main, qsearch( {
 253         'table'     => 'cust_main',
 254         'hashref'   => \%options,
 255         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 256       } );
 257       #contacts?
 258
 259       # or it just be something that was typed in... (try that in a sec)
 260
 261     }
 262
 263     my $q_value = dbh->quote($value);
 264
 265     #exact
 266     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 267     $sql .= " (    LOWER(last)          = $q_value
 268                 OR LOWER(company)       = $q_value
 269             ";
 270     #yes, it's a kludge
 271     $sql .= "   OR EXISTS(
 272                 SELECT 1 FROM cust_location
 273                 WHERE LOWER(cust_location.address1) = $q_value
 274                   AND cust_location.custnum = cust_main.custnum
 275             )
 276             "
 277       if $conf->exists('address1-search');
 278     $sql .= " )";
 279
 280     push @cust_main, qsearch( {
 281       'table'     => 'cust_main',
 282       'hashref'   => \%options,
 283       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 284     } );
 285
 286     #no exact match, trying substring/fuzzy
 287     #always do substring & fuzzy (unless they're explicity config'ed off)
 288     #getting complaints searches are not returning enough
 289     unless ( @cust_main  && $skip_fuzzy || $conf->exists('disable-fuzzy') ) {
 290
 291       #still some false laziness w/search (was search/cust_main.cgi)
 292
 293       #substring
 294
 295       my @hashrefs = (
 296         { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
 297       );
 298
 299       if ( $first && $last ) {
 300         #contacts? ship_first/ship_last are gone
 301
 302         push @hashrefs,
 303           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
 304             'last'         => { op=>'ILIKE', value=>"%$last%" },
 305           },
 306         ;
 307
 308       } else {
 309
 310         push @hashrefs,
 311           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
 312         ;
 313       }
 314
 315       foreach my $hashref ( @hashrefs ) {
 316
 317         push @cust_main, qsearch( {
 318           'table'     => 'cust_main',
 319           'hashref'   => { %$hashref,
 320                            %options,
 321                          },
 322           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
 323         } );
 324
 325       }
 326
 327       if ( $conf->exists('address1-search') ) {
 328
 329         push @cust_main, qsearch( {
 330           'table'     => 'cust_main',
 331           'addl_from' => 'JOIN cust_location USING (custnum)',
 332           'extra_sql' => 'WHERE cust_location.address1 ILIKE '.
 333                           dbh->quote("%$value%"),
 334         } );
 335
 336       }
 337
 338       #fuzzy
 339       my %fuzopts = (
 340         'hashref'   => \%options,
 341         'select'    => '',
 342         'extra_sql' => " AND $agentnums_sql",    #agent virtualization
 343       );
 344
 345       if ( $first && $last ) {
 346         push @cust_main, FS::cust_main::Search->fuzzy_search(
 347           { 'last'   => $last,    #fuzzy hashref
 348             'first'  => $first }, #
 349           %fuzopts
 350         );
 351       }
 352       foreach my $field ( 'last', 'company' ) {
 353         push @cust_main,
 354           FS::cust_main::Search->fuzzy_search( { $field => $value }, %fuzopts );
 355       }
 356       if ( $conf->exists('address1-search') ) {
 357         push @cust_main,
 358           FS::cust_main::Search->fuzzy_search( { 'address1' => $value }, %fuzopts );
 359       }
 360
 361     }
 362
 363   }
 364
 365   #eliminate duplicates
 366   my %saw = ();
 367   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 368
 369   @cust_main;
 370
 371 }
 372
 373 =item email_search
 374
 375 Accepts the following options: I<email>, the email address to search for.  The
 376 email address will be searched for as an email invoice destination and as an
 377 svc_acct account.
 378
 379 #Any additional options are treated as an additional qualifier on the search
 380 #(i.e. I<agentnum>).
 381
 382 Returns a (possibly empty) array of FS::cust_main objects (but usually just
 383 none or one).
 384
 385 =cut
 386
 387 sub email_search {
 388   my %options = @_;
 389
 390   local($DEBUG) = 1;
 391
 392   my $email = delete $options{'email'};
 393
 394   #we're only being used by RT at the moment... no agent virtualization yet
 395   #my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
 396
 397   my @cust_main = ();
 398
 399   if ( $email =~ /([^@]+)\@([^@]+)/ ) {
 400
 401     my ( $user, $domain ) = ( $1, $2 );
 402
 403     warn "$me smart_search: searching for $user in domain $domain"
 404       if $DEBUG;
 405
 406     push @cust_main,
 407       map $_->cust_main,
 408           qsearch( {
 409                      'table'     => 'cust_main_invoice',
 410                      'hashref'   => { 'dest' => $email },
 411                    }
 412                  );
 413
 414     push @cust_main,
 415       map  $_->cust_main,
 416       grep $_,
 417       map  $_->cust_svc->cust_pkg,
 418           qsearch( {
 419                      'table'     => 'svc_acct',
 420                      'hashref'   => { 'username' => $user, },
 421                      'extra_sql' =>
 422                        'AND ( SELECT domain FROM svc_domain
 423                                 WHERE svc_acct.domsvc = svc_domain.svcnum
 424                             ) = '. dbh->quote($domain),
 425                    }
 426                  );
 427   }
 428
 429   my %saw = ();
 430   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 431
 432   warn "$me smart_search: found ". scalar(@cust_main). " unique customers"
 433     if $DEBUG;
 434
 435   @cust_main;
 436
 437 }
 438
 439 =back
 440
 441 =head1 CLASS METHODS
 442
 443 =over 4
 444
 445 =item search HASHREF
 446
 447 (Class method)
 448
 449 Returns a qsearch hash expression to search for parameters specified in
 450 HASHREF.  Valid parameters are
 451
 452 =over 4
 453
 454 =item agentnum
 455
 456 =item status
 457
 458 =item address
 459
 460 =item refnum
 461
 462 =item cancelled_pkgs
 463
 464 bool
 465
 466 =item signupdate
 467
 468 listref of start date, end date
 469
 470 =item birthdate
 471
 472 listref of start date, end date
 473
 474 =item spouse_birthdate
 475
 476 listref of start date, end date
 477
 478 =item anniversary_date
 479
 480 listref of start date, end date
 481
 482 =item payby
 483
 484 listref
 485
 486 =item paydate_year
 487
 488 =item paydate_month
 489
 490 =item current_balance
 491
 492 listref (list returned by FS::UI::Web::parse_lt_gt($cgi, 'current_balance'))
 493
 494 =item cust_fields
 495
 496 =item flattened_pkgs
 497
 498 bool
 499
 500 =back
 501
 502 =cut
 503
 504 sub search {
 505   my ($class, $params) = @_;
 506
 507   my $dbh = dbh;
 508
 509   my @where = ();
 510   my $orderby;
 511
 512   # initialize these to prevent warnings
 513   $params = {
 514     'custnum'       => '',
 515     'agentnum'      => '',
 516     'usernum'       => '',
 517     'status'        => '',
 518     'address'       => '',
 519     'paydate_year'  => '',
 520     'invoice_terms' => '',
 521     'custbatch'     => '',
 522     %$params
 523   };
 524
 525   ##
 526   # explicit custnum(s)
 527   ##
 528
 529   if ( $params->{'custnum'} ) {
 530     my @custnums = ref($params->{'custnum'}) ?
 531                       @{ $params->{'custnum'} } :
 532                       $params->{'custnum'};
 533     push @where,
 534       'cust_main.custnum IN (' .
 535       join(',', map { $_ =~ /^(\d+)$/ ? $1 : () } @custnums ) .
 536       ')' if scalar(@custnums) > 0;
 537   }
 538
 539   ##
 540   # parse agent
 541   ##
 542
 543   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
 544     push @where,
 545       "cust_main.agentnum = $1";
 546   }
 547
 548   ##
 549   # do the same for user
 550   ##
 551
 552   if ( $params->{'usernum'} =~ /^(\d+)$/ and $1 ) {
 553     push @where,
 554       "cust_main.usernum = $1";
 555   }
 556
 557   ##
 558   # parse status
 559   ##
 560
 561   #prospect ordered active inactive suspended cancelled
 562   if ( grep { $params->{'status'} eq $_ } FS::cust_main->statuses() ) {
 563     my $method = $params->{'status'}. '_sql';
 564     #push @where, $class->$method();
 565     push @where, FS::cust_main->$method();
 566   }
 567
 568   ##
 569   # address
 570   ##
 571   if ( $params->{'address'} =~ /\S/ ) {
 572     my $address = dbh->quote('%'. lc($params->{'address'}). '%');
 573     push @where, "EXISTS(
 574       SELECT 1 FROM cust_location
 575       WHERE cust_location.custnum = cust_main.custnum
 576         AND (LOWER(cust_location.address1) LIKE $address OR
 577              LOWER(cust_location.address2) LIKE $address)
 578     )";
 579   }
 580
 581   ###
 582   # refnum
 583   ###
 584   if ( $params->{'refnum'}  ) {
 585
 586     my @refnum = ref( $params->{'refnum'} )
 587                    ? @{ $params->{'refnum'} }
 588                    :  ( $params->{'refnum'} );
 589
 590     @refnum = grep /^(\d*)$/, @refnum;
 591
 592     push @where, '( '. join(' OR ', map "cust_main.refnum = $_", @refnum ). ' )'
 593       if @refnum;
 594
 595   }
 596
 597   ##
 598   # parse cancelled package checkbox
 599   ##
 600
 601   my $pkgwhere = "";
 602
 603   $pkgwhere .= "AND (cancel = 0 or cancel is null)"
 604     unless $params->{'cancelled_pkgs'};
 605
 606   ##
 607   # parse without census tract checkbox
 608   ##
 609
 610   push @where, "(censustract = '' or censustract is null)"
 611     if $params->{'no_censustract'};
 612
 613   ##
 614   # parse with hardcoded tax location checkbox
 615   ##
 616
 617   push @where, "geocode is not null"
 618     if $params->{'with_geocode'};
 619
 620   ##
 621   # dates
 622   ##
 623
 624   foreach my $field (qw( signupdate birthdate spouse_birthdate anniversary_date )) {
 625
 626     next unless exists($params->{$field});
 627
 628     my($beginning, $ending, $hour) = @{$params->{$field}};
 629
 630     push @where,
 631       "cust_main.$field IS NOT NULL",
 632       "cust_main.$field >= $beginning",
 633       "cust_main.$field <= $ending";
 634
 635     if($field eq 'signupdate' && defined $hour) {
 636       if ($dbh->{Driver}->{Name} =~ /Pg/i) {
 637         push @where, "extract(hour from to_timestamp(cust_main.$field)) = $hour";
 638       }
 639       elsif( $dbh->{Driver}->{Name} =~ /mysql/i) {
 640         push @where, "hour(from_unixtime(cust_main.$field)) = $hour"
 641       }
 642       else {
 643         warn "search by time of day not supported on ".$dbh->{Driver}->{Name}." databases";
 644       }
 645     }
 646
 647     $orderby ||= "ORDER BY cust_main.$field";
 648
 649   }
 650
 651   ###
 652   # classnum
 653   ###
 654
 655   if ( $params->{'classnum'} ) {
 656
 657     my @classnum = ref( $params->{'classnum'} )
 658                      ? @{ $params->{'classnum'} }
 659                      :  ( $params->{'classnum'} );
 660
 661     @classnum = grep /^(\d*)$/, @classnum;
 662
 663     if ( @classnum ) {
 664       push @where, '( '. join(' OR ', map {
 665                                             $_ ? "cust_main.classnum = $_"
 666                                                : "cust_main.classnum IS NULL"
 667                                           }
 668                                           @classnum
 669                              ).
 670                    ' )';
 671     }
 672
 673   }
 674
 675   ###
 676   # payby
 677   ###
 678
 679   if ( $params->{'payby'} ) {
 680
 681     my @payby = ref( $params->{'payby'} )
 682                   ? @{ $params->{'payby'} }
 683                   :  ( $params->{'payby'} );
 684
 685     @payby = grep /^([A-Z]{4})$/, @payby;
 686
 687     push @where, '( '. join(' OR ', map "cust_main.payby = '$_'", @payby). ' )'
 688       if @payby;
 689
 690   }
 691
 692   ###
 693   # paydate_year / paydate_month
 694   ###
 695
 696   if ( $params->{'paydate_year'} =~ /^(\d{4})$/ ) {
 697     my $year = $1;
 698     $params->{'paydate_month'} =~ /^(\d\d?)$/
 699       or die "paydate_year without paydate_month?";
 700     my $month = $1;
 701
 702     push @where,
 703       'paydate IS NOT NULL',
 704       "paydate != ''",
 705       "CAST(paydate AS timestamp) < CAST('$year-$month-01' AS timestamp )"
 706 ;
 707   }
 708
 709   ###
 710   # invoice terms
 711   ###
 712
 713   if ( $params->{'invoice_terms'} =~ /^([\w ]+)$/ ) {
 714     my $terms = $1;
 715     if ( $1 eq 'NULL' ) {
 716       push @where,
 717         "( cust_main.invoice_terms IS NULL OR cust_main.invoice_terms = '' )";
 718     } else {
 719       push @where,
 720         "cust_main.invoice_terms IS NOT NULL",
 721         "cust_main.invoice_terms = '$1'";
 722     }
 723   }
 724
 725   ##
 726   # amounts
 727   ##
 728
 729   if ( $params->{'current_balance'} ) {
 730
 731     #my $balance_sql = $class->balance_sql();
 732     my $balance_sql = FS::cust_main->balance_sql();
 733
 734     my @current_balance =
 735       ref( $params->{'current_balance'} )
 736       ? @{ $params->{'current_balance'} }
 737       :  ( $params->{'current_balance'} );
 738
 739     push @where, map { s/current_balance/$balance_sql/; $_ }
 740                      @current_balance;
 741
 742   }
 743
 744   ##
 745   # custbatch
 746   ##
 747
 748   if ( $params->{'custbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
 749     push @where,
 750       "cust_main.custbatch = '$1'";
 751   }
 752
 753   if ( $params->{'tagnum'} ) {
 754     my @tagnums = ref( $params->{'tagnum'} ) ? @{ $params->{'tagnum'} } : ( $params->{'tagnum'} );
 755
 756     @tagnums = grep /^(\d+)$/, @tagnums;
 757
 758     if ( @tagnums ) {
 759         my $tags_where = "0 < (select count(1) from cust_tag where "
 760                 . " cust_tag.custnum = cust_main.custnum and tagnum in ("
 761                 . join(',', @tagnums) . "))";
 762
 763         push @where, $tags_where;
 764     }
 765   }
 766
 767
 768   ##
 769   # setup queries, subs, etc. for the search
 770   ##
 771
 772   $orderby ||= 'ORDER BY custnum';
 773
 774   # here is the agent virtualization
 775   push @where,
 776     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
 777
 778   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
 779
 780   my $addl_from = '';
 781
 782   my $count_query = "SELECT COUNT(*) FROM cust_main $extra_sql";
 783
 784   my @select = (
 785                  'cust_main.custnum',
 786                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
 787                );
 788
 789   my(@extra_headers) = ();
 790   my(@extra_fields)  = ();
 791
 792   if ($params->{'flattened_pkgs'}) {
 793
 794     #my $pkg_join = '';
 795     $addl_from .= ' LEFT JOIN cust_pkg USING ( custnum ) ';
 796
 797     if ($dbh->{Driver}->{Name} eq 'Pg') {
 798
 799       push @select, "
 800         ARRAY_TO_STRING(
 801           ARRAY(
 802             SELECT pkg FROM cust_pkg LEFT JOIN part_pkg USING ( pkgpart )
 803               WHERE cust_main.custnum = cust_pkg.custnum $pkgwhere
 804           ), '|'
 805         ) AS magic
 806       ";
 807
 808     } elsif ($dbh->{Driver}->{Name} =~ /^mysql/i) {
 809       push @select, "GROUP_CONCAT(part_pkg.pkg SEPARATOR '|') as magic";
 810       $addl_from .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
 811       #$pkg_join  .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
 812     } else {
 813       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
 814            "omitting package information from report.";
 815     }
 816
 817     my $header_query = "
 818       SELECT COUNT(cust_pkg.custnum = cust_main.custnum) AS count
 819         FROM cust_main $addl_from $extra_sql $pkgwhere
 820           GROUP BY cust_main.custnum ORDER BY count DESC LIMIT 1
 821     ";
 822
 823     my $sth = dbh->prepare($header_query) or die dbh->errstr;
 824     $sth->execute() or die $sth->errstr;
 825     my $headerrow = $sth->fetchrow_arrayref;
 826     my $headercount = $headerrow ? $headerrow->[0] : 0;
 827     while($headercount) {
 828       unshift @extra_headers, "Package ". $headercount;
 829       unshift @extra_fields, eval q!sub {my $c = shift;
 830                                          my @a = split '\|', $c->magic;
 831                                          my $p = $a[!.--$headercount. q!];
 832                                          $p;
 833                                         };!;
 834     }
 835
 836   }
 837
 838   if ( $params->{'with_geocode'} ) {
 839
 840     unshift @extra_headers, 'Tax location override', 'Calculated tax location';
 841     unshift @extra_fields, sub { my $c = shift; $c->get('geocode'); },
 842                            sub { my $c = shift;
 843                                  $c->set('geocode', '');
 844                                  $c->geocode('cch'); #XXX only cch right now
 845                                };
 846     push @select, 'geocode';
 847     push @select, 'zip' unless grep { $_ eq 'zip' } @select;
 848     push @select, 'ship_zip' unless grep { $_ eq 'ship_zip' } @select;
 849   }
 850
 851   my $select = join(', ', @select);
 852
 853   my $sql_query = {
 854     'table'         => 'cust_main',
 855     'select'        => $select,
 856     'addl_from'     => $addl_from,
 857     'hashref'       => {},
 858     'extra_sql'     => $extra_sql,
 859     'order_by'      => $orderby,
 860     'count_query'   => $count_query,
 861     'extra_headers' => \@extra_headers,
 862     'extra_fields'  => \@extra_fields,
 863   };
 864
 865 }
 866
 867 =item fuzzy_search FUZZY_HASHREF [ OPTS ]
 868
 869 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
 870 records.  Currently, I<first>, I<last>, I<company> and/or I<address1> may be
 871 specified.
 872
 873 Additional options are the same as FS::Record::qsearch
 874
 875 =cut
 876
 877 sub fuzzy_search {
 878   my( $self, $fuzzy ) = @_;
 879   # sensible defaults, then merge in any passed options
 880   my %fuzopts = (
 881     'table'     => 'cust_main',
 882     'addl_from' => '',
 883     'extra_sql' => '',
 884     'hashref'   => {},
 885     @_
 886   );
 887
 888   my @cust_main = ();
 889
 890   check_and_rebuild_fuzzyfiles();
 891   foreach my $field ( keys %$fuzzy ) {
 892
 893     my $all = $self->all_X($field);
 894     next unless scalar(@$all);
 895
 896     my %match = ();
 897     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, ['i'], @$all ) );
 898
 899     my @fcust = ();
 900     foreach ( keys %match ) {
 901       if ( $field eq 'address1' ) {
 902         #because it lives outside the table
 903         my $addl_from = $fuzopts{addl_from} .
 904                         'JOIN cust_location USING (custnum)';
 905         my $extra_sql = $fuzopts{extra_sql} .
 906                         " AND cust_location.address1 = ".dbh->quote($_);
 907         push @fcust, qsearch({
 908             %fuzopts,
 909             'addl_from' => $addl_from,
 910             'extra_sql' => $extra_sql,
 911         });
 912       } else {
 913         my $hash = $fuzopts{hashref};
 914         $hash->{$field} = $_;
 915         push @fcust, qsearch({
 916             %fuzopts,
 917             'hashref' => $hash
 918         });
 919       }
 920     }
 921     my %fsaw = ();
 922     push @cust_main, grep { ! $fsaw{$_->custnum}++ } @fcust;
 923   }
 924
 925   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
 926   my %saw = ();
 927   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
 928
 929   @cust_main;
 930
 931 }
 932
 933 =back
 934
 935 =head1 UTILITY SUBROUTINES
 936
 937 =over 4
 938
 939 =item check_and_rebuild_fuzzyfiles
 940
 941 =cut
 942
 943 sub check_and_rebuild_fuzzyfiles {
 944   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 945   rebuild_fuzzyfiles() if grep { ! -e "$dir/cust_main.$_" } @fuzzyfields;
 946 }
 947
 948 =item rebuild_fuzzyfiles
 949
 950 =cut
 951
 952 sub rebuild_fuzzyfiles {
 953
 954   use Fcntl qw(:flock);
 955
 956   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
 957   mkdir $dir, 0700 unless -d $dir;
 958
 959   foreach my $fuzzy ( @fuzzyfields ) {
 960
 961     open(LOCK,">>$dir/cust_main.$fuzzy")
 962       or die "can't open $dir/cust_main.$fuzzy: $!";
 963     flock(LOCK,LOCK_EX)
 964       or die "can't lock $dir/cust_main.$fuzzy: $!";
 965
 966     open (CACHE, '>:encoding(UTF-8)', "$dir/cust_main.$fuzzy.tmp")
 967       or die "can't open $dir/cust_main.$fuzzy.tmp: $!";
 968
 969     foreach my $field ( $fuzzy, "ship_$fuzzy" ) {
 970       my $sth = dbh->prepare("SELECT $field FROM cust_main".
 971                              " WHERE $field != '' AND $field IS NOT NULL");
 972       $sth->execute or die $sth->errstr;
 973
 974       while ( my $row = $sth->fetchrow_arrayref ) {
 975         print CACHE $row->[0]. "\n";
 976       }
 977
 978     }
 979
 980     close CACHE or die "can't close $dir/cust_main.$fuzzy.tmp: $!";
 981
 982     rename "$dir/cust_main.$fuzzy.tmp", "$dir/cust_main.$fuzzy";
 983     close LOCK;
 984   }
 985
 986 }
 987
 988 =item append_fuzzyfiles FIRSTNAME LASTNAME COMPANY ADDRESS1
 989
 990 =cut
 991
 992 sub append_fuzzyfiles {
 993   #my( $first, $last, $company ) = @_;
 994
 995   check_and_rebuild_fuzzyfiles();
 996
 997   use Fcntl qw(:flock);
 998
 999   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1000
1001   foreach my $field (@fuzzyfields) {
1002     my $value = shift;
1003
1004     if ( $value ) {
1005
1006       open(CACHE, '>>:encoding(UTF-8)', "$dir/cust_main.$field" )
1007         or die "can't open $dir/cust_main.$field: $!";
1008       flock(CACHE,LOCK_EX)
1009         or die "can't lock $dir/cust_main.$field: $!";
1010
1011       print CACHE "$value\n";
1012
1013       flock(CACHE,LOCK_UN)
1014         or die "can't unlock $dir/cust_main.$field: $!";
1015       close CACHE;
1016     }
1017
1018   }
1019
1020   1;
1021 }
1022
1023 =item all_X
1024
1025 =cut
1026
1027 sub all_X {
1028   my( $self, $field ) = @_;
1029   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1030   open(CACHE, '<:encoding(UTF-8)', "$dir/cust_main.$field")
1031     or die "can't open $dir/cust_main.$field: $!";
1032   my @array = map { chomp; $_; } <CACHE>;
1033   close CACHE;
1034   \@array;
1035 }
1036
1037 =head1 BUGS
1038
1039 Bed bugs
1040
1041 =head1 SEE ALSO
1042
1043 L<FS::cust_main>, L<FS::Record>
1044
1045 =cut
1046
1047 1;
1048