FS/FS/cust_main/Search.pm

   1 package FS::cust_main::Search;
   2
   3 use strict;
   4 use base qw( Exporter );
   5 use vars qw( @EXPORT_OK $DEBUG $me $conf @fuzzyfields );
   6 use String::Approx qw(amatch);
   7 use FS::UID qw( dbh );
   8 use FS::Record qw( qsearch );
   9 use FS::cust_main;
  10 use FS::cust_main_invoice;
  11 use FS::svc_acct;
  12 use FS::payinfo_Mixin;
  13
  14 @EXPORT_OK = qw( smart_search );
  15
  16 # 1 is mostly method/subroutine entry and options
  17 # 2 traces progress of some operations
  18 # 3 is even more information including possibly sensitive data
  19 $DEBUG = 0;
  20 $me = '[FS::cust_main::Search]';
  21
  22 @fuzzyfields = (
  23   'cust_main.first', 'cust_main.last', 'cust_main.company',
  24   'cust_main.ship_company', # if you're using it
  25   'cust_location.address1',
  26   'contact.first',   'contact.last',
  27 );
  28
  29 install_callback FS::UID sub {
  30   $conf = new FS::Conf;
  31   #yes, need it for stuff below (prolly should be cached)
  32 };
  33
  34 =head1 NAME
  35
  36 FS::cust_main::Search - Customer searching
  37
  38 =head1 SYNOPSIS
  39
  40   use FS::cust_main::Search;
  41
  42   FS::cust_main::Search::smart_search(%options);
  43
  44   FS::cust_main::Search::email_search(%options);
  45
  46   FS::cust_main::Search->search( \%options );
  47
  48   FS::cust_main::Search->fuzzy_search( \%fuzzy_hashref );
  49
  50 =head1 SUBROUTINES
  51
  52 =over 4
  53
  54 =item smart_search OPTION => VALUE ...
  55
  56 Accepts the following options: I<search>, the string to search for.  The string
  57 will be searched for as a customer number, phone number, name or company name,
  58 address (if address1-search is on), invoicing email address, or credit card
  59 number.
  60
  61 Searches match as an exact, or, in some cases, a substring or fuzzy match (see
  62 the source code for the exact heuristics used); I<no_fuzzy_on_exact>, causes
  63 smart_search to
  64 skip fuzzy matching when an exact match is found.
  65
  66 Any additional options are treated as an additional qualifier on the search
  67 (i.e. I<agentnum>).
  68
  69 Returns a (possibly empty) array of FS::cust_main objects.
  70
  71 =cut
  72
  73 sub smart_search {
  74   my %options = @_;
  75
  76   #here is the agent virtualization
  77   my $agentnums_sql =
  78     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
  79   my $agentnums_href = $FS::CurrentUser::CurrentUser->agentnums_href;
  80
  81   my @cust_main = ();
  82
  83   my $skip_fuzzy = delete $options{'no_fuzzy_on_exact'};
  84   my $search = delete $options{'search'};
  85   ( my $alphanum_search = $search ) =~ s/\W//g;
  86
  87   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
  88
  89     #false laziness w/Record::ut_phone
  90     my $phonen = "$1-$2-$3";
  91     $phonen .= " x$4" if $4;
  92
  93     my $phonenum = "$1$2$3";
  94     #my $extension = $4;
  95
  96     #cust_main phone numbers
  97     push @cust_main, qsearch( {
  98       'table'   => 'cust_main',
  99       'hashref' => { %options },
 100       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 101                      ' ( '.
 102                          join(' OR ', map "$_ = '$phonen'",
 103                                           qw( daytime night mobile fax )
 104                              ).
 105                      ' ) '.
 106                      " AND $agentnums_sql", #agent virtualization
 107     } );
 108
 109     #contact phone numbers
 110     push @cust_main,
 111       grep $agentnums_href->{$_->agentnum}, #agent virt
 112         grep $_, #skip contacts that don't have cust_main records
 113           map $_->contact->cust_main,
 114             qsearch({
 115                       'table'   => 'contact_phone',
 116                       'hashref' => { 'phonenum' => $phonenum },
 117                    });
 118
 119     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
 120       #try looking for matches with extensions unless one was specified
 121
 122       push @cust_main, qsearch( {
 123         'table'   => 'cust_main',
 124         'hashref' => { %options },
 125         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 126                        ' ( '.
 127                            join(' OR ', map "$_ LIKE '$phonen\%'",
 128                                             qw( daytime night )
 129                                ).
 130                        ' ) '.
 131                        " AND $agentnums_sql", #agent virtualization
 132       } );
 133
 134     }
 135
 136   }
 137
 138
 139   if ( $search =~ /@/ ) { #email address
 140
 141       # invoicing email address
 142       push @cust_main,
 143         grep $agentnums_href->{$_->agentnum}, #agent virt
 144           map $_->cust_main,
 145               qsearch( {
 146                          'table'     => 'cust_main_invoice',
 147                          'hashref'   => { 'dest' => $search },
 148                        }
 149                      );
 150
 151       # contact email address
 152       push @cust_main,
 153         grep $agentnums_href->{$_->agentnum}, #agent virt
 154           grep $_, #skip contacts that don't have cust_main records
 155             map $_->contact->cust_main,
 156               qsearch( {
 157                          'table'     => 'contact_email',
 158                          'hashref'   => { 'emailaddress' => $search },
 159                        }
 160                      );
 161
 162   # custnum search (also try agent_custid), with some tweaking options if your
 163   # legacy cust "numbers" have letters
 164   } elsif ( $search =~ /^\s*(\d+)\s*$/
 165          || ( $conf->config('cust_main-agent_custid-format') eq 'ww?d+'
 166               && $search =~ /^\s*(\w\w?\d+)\s*$/
 167             )
 168          || ( $conf->config('cust_main-custnum-display_special')
 169            # it's not currently possible for special prefixes to contain
 170            # digits, so just strip off any alphabetic prefix and match
 171            # the rest to custnum
 172               && $search =~ /^\s*[[:alpha:]]*(\d+)\s*$/
 173             )
 174          || ( $conf->exists('address1-search' )
 175               && $search =~ /^\s*(\d+\-?\w*)\s*$/ #i.e. 1234A or 9432-D
 176             )
 177      )
 178   {
 179
 180     my $num = $1;
 181
 182     if ( $num =~ /^(\d+)$/ && $num <= 2147483647 ) { #need a bigint custnum? wow
 183       my $agent_custid_null = $conf->exists('cust_main-default_agent_custid')
 184                                 ? ' AND agent_custid IS NULL ' : '';
 185       push @cust_main, qsearch( {
 186         'table'     => 'cust_main',
 187         'hashref'   => { 'custnum' => $num, %options },
 188         'extra_sql' => " AND $agentnums_sql $agent_custid_null",
 189       } );
 190     }
 191
 192     # for all agents this user can see, if any of them have custnum prefixes
 193     # that match the search string, include customers that match the rest
 194     # of the custnum and belong to that agent
 195     foreach my $agentnum ( keys %$agentnums_href ) {
 196       my $p = $conf->config('cust_main-custnum-display_prefix', $agentnum);
 197       next if !$p;
 198       if ( $p eq substr($num, 0, length($p)) ) {
 199         push @cust_main, qsearch( {
 200           'table'   => 'cust_main',
 201           'hashref' => { 'custnum' => 0 + substr($num, length($p)),
 202                          'agentnum' => $agentnum,
 203                           %options,
 204                        },
 205         } );
 206       }
 207     }
 208
 209     push @cust_main, qsearch( {
 210         'table'     => 'cust_main',
 211         'hashref'   => { 'agent_custid' => $num, %options },
 212         'extra_sql' => " AND $agentnums_sql", #agent virtualization
 213     } );
 214
 215     if ( $conf->exists('address1-search') ) {
 216       my $len = length($num);
 217       $num = lc($num);
 218       # probably the Right Thing: return customers that have any associated
 219       # locations matching the string, not just bill/ship location
 220       push @cust_main, qsearch( {
 221         'table'     => 'cust_main',
 222         'addl_from' => ' JOIN cust_location USING (custnum) ',
 223         'hashref'   => { %options, },
 224         'extra_sql' =>
 225           ( keys(%options) ? ' AND ' : ' WHERE ' ).
 226           " LOWER(SUBSTRING(cust_location.address1 FROM 1 FOR $len)) = '$num' ".
 227           " AND $agentnums_sql",
 228       } );
 229     }
 230
 231   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
 232
 233     my($company, $last, $first) = ( $1, $2, $3 );
 234
 235     # "Company (Last, First)"
 236     #this is probably something a browser remembered,
 237     #so just do an exact search (but case-insensitive, so USPS standardization
 238     #doesn't throw a wrench in the works)
 239
 240     push @cust_main, qsearch( {
 241         'table'     => 'cust_main',
 242         'hashref'   => { %options },
 243         'extra_sql' =>
 244         ( keys(%options) ? ' AND ' : ' WHERE ' ).
 245         join(' AND ',
 246           " LOWER(first)   = ". dbh->quote(lc($first)),
 247           " LOWER(last)    = ". dbh->quote(lc($last)),
 248           " LOWER(company) = ". dbh->quote(lc($company)),
 249           $agentnums_sql,
 250         ),
 251       } ),
 252
 253     #contacts?
 254     # probably not necessary for the "something a browser remembered" case
 255
 256   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
 257                                               # try {first,last,company}
 258
 259     my $value = lc($1);
 260
 261     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
 262     # # full strings the browser remembers won't work
 263     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
 264
 265     use Lingua::EN::NameParse;
 266     my $NameParse = new Lingua::EN::NameParse(
 267              auto_clean     => 1,
 268              allow_reversed => 1,
 269     );
 270
 271     my($last, $first) = ( '', '' );
 272     #maybe disable this too and just rely on NameParse?
 273     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
 274
 275       ($last, $first) = ( $1, $2 );
 276
 277     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
 278     } elsif ( ! $NameParse->parse($value) ) {
 279
 280       my %name = $NameParse->components;
 281       $first = $name{'given_name_1'} || $name{'initials_1'}; #wtf NameParse, Ed?
 282       $last  = $name{'surname_1'};
 283
 284     }
 285
 286     if ( $first && $last ) {
 287
 288       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
 289
 290       #exact
 291       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 292       $sql .= "( LOWER(cust_main.last) = $q_last AND LOWER(cust_main.first) = $q_first )";
 293
 294       #cust_main
 295       push @cust_main, qsearch( {
 296         'table'     => 'cust_main',
 297         'hashref'   => \%options,
 298         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 299       } );
 300
 301       #contacts
 302       push @cust_main,
 303         grep $agentnums_href->{$_->agentnum}, #agent virt
 304           grep $_, #skip contacts that don't have cust_main records
 305             map $_->cust_main,
 306               qsearch( {
 307                          'table'     => 'contact',
 308                          'hashref'   => { 'first' => $first,
 309                                           'last'  => $last,
 310                                         },
 311                        }
 312                      );
 313
 314       # or it just be something that was typed in... (try that in a sec)
 315
 316     }
 317
 318     my $q_value = dbh->quote($value);
 319
 320     #exact
 321     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 322     $sql .= " (    LOWER(cust_main.first)         = $q_value
 323                 OR LOWER(cust_main.last)          = $q_value
 324                 OR LOWER(cust_main.company)       = $q_value
 325                 OR LOWER(cust_main.ship_company)  = $q_value
 326             ";
 327
 328     #address1 (yes, it's a kludge)
 329     $sql .= "   OR EXISTS (
 330                             SELECT 1 FROM cust_location
 331                               WHERE LOWER(cust_location.address1) = $q_value
 332                                 AND cust_location.custnum = cust_main.custnum
 333                           )"
 334       if $conf->exists('address1-search');
 335
 336     #contacts (look, another kludge)
 337     $sql .= "   OR EXISTS ( SELECT 1 FROM contact
 338                               WHERE (    LOWER(contact.first) = $q_value
 339                                       OR LOWER(contact.last)  = $q_value
 340                                     )
 341                                 AND contact.custnum IS NOT NULL
 342                                 AND contact.custnum = cust_main.custnum
 343                           )
 344               ) ";
 345
 346     push @cust_main, qsearch( {
 347       'table'     => 'cust_main',
 348       'hashref'   => \%options,
 349       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 350     } );
 351
 352     #no exact match, trying substring/fuzzy
 353     #always do substring & fuzzy (unless they're explicity config'ed off)
 354     #getting complaints searches are not returning enough
 355     unless ( @cust_main  && $skip_fuzzy || $conf->exists('disable-fuzzy') ) {
 356
 357       #still some false laziness w/search (was search/cust_main.cgi)
 358
 359       #substring
 360
 361       my @company_hashrefs = (
 362         { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
 363         { 'ship_company' => { op=>'ILIKE', value=>"%$value%" }, },
 364       );
 365
 366       my @hashrefs = ();
 367
 368       if ( $first && $last ) {
 369
 370         @hashrefs = (
 371           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
 372             'last'         => { op=>'ILIKE', value=>"%$last%" },
 373           },
 374         );
 375
 376       } else {
 377
 378         @hashrefs = (
 379           { 'first'        => { op=>'ILIKE', value=>"%$value%" }, },
 380           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
 381         );
 382       }
 383
 384       foreach my $hashref ( @company_hashrefs, @hashrefs ) {
 385
 386         push @cust_main, qsearch( {
 387           'table'     => 'cust_main',
 388           'hashref'   => { %$hashref,
 389                            %options,
 390                          },
 391           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
 392         } );
 393
 394       }
 395
 396       if ( $conf->exists('address1-search') ) {
 397
 398         push @cust_main, qsearch( {
 399           table     => 'cust_main',
 400           addl_from => 'JOIN cust_location USING (custnum)',
 401           extra_sql => 'WHERE '.
 402                         ' cust_location.address1 ILIKE '.dbh->quote("%$value%").
 403                         " AND $agentnums_sql", #agent virtualizaiton
 404         } );
 405
 406       }
 407
 408       #contact substring
 409
 410       foreach my $hashref ( @hashrefs ) {
 411
 412         push @cust_main,
 413           grep $agentnums_href->{$_->agentnum}, #agent virt
 414             grep $_, #skip contacts that don't have cust_main records
 415               map $_->cust_main,
 416                 qsearch({
 417                           'table'     => 'contact',
 418                           'hashref'   => { %$hashref,
 419                                            #%options,
 420                                          },
 421                           #'extra_sql' => " AND $agentnums_sql", #agent virt
 422                        });
 423
 424       }
 425
 426       #fuzzy
 427       my %fuzopts = (
 428         'hashref'   => \%options,
 429         'select'    => '',
 430         'extra_sql' => "WHERE $agentnums_sql",    #agent virtualization
 431       );
 432
 433       if ( $first && $last ) {
 434         push @cust_main, FS::cust_main::Search->fuzzy_search(
 435           { 'last'   => $last,    #fuzzy hashref
 436             'first'  => $first }, #
 437           %fuzopts
 438         );
 439         push @cust_main, FS::cust_main::Search->fuzzy_search(
 440           { 'contact.last'   => $last,    #fuzzy hashref
 441             'contact.first'  => $first }, #
 442           %fuzopts
 443         );
 444      }
 445       foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
 446         push @cust_main, FS::cust_main::Search->fuzzy_search(
 447           { $field => $value },
 448           %fuzopts
 449         );
 450       }
 451       foreach my $field ( 'first', 'last' ) {
 452         push @cust_main, FS::cust_main::Search->fuzzy_search(
 453           { "contact.$field" => $value },
 454           %fuzopts
 455         );
 456       }
 457       if ( $conf->exists('address1-search') ) {
 458         push @cust_main,
 459           FS::cust_main::Search->fuzzy_search(
 460             { 'cust_location.address1' => $value },
 461             %fuzopts
 462         );
 463       }
 464
 465     }
 466
 467   }
 468
 469   ( my $nospace_search = $search ) =~ s/\s//g;
 470   ( my $card_search = $nospace_search ) =~ s/\-//g;
 471   $card_search =~ s/[x\*\.\_]/x/gi;
 472
 473   if ( $card_search =~ /^[\dx]{15,16}$/i ) { #credit card search
 474
 475     ( my $like_search = $card_search ) =~ s/x/_/g;
 476     my $mask_search = FS::payinfo_Mixin->mask_payinfo('CARD', $card_search);
 477
 478     push @cust_main, qsearch({
 479       'table'     => 'cust_main',
 480       'addl_from' => ' JOIN cust_payby USING (custnum)',
 481       'hashref'   => {},
 482       'extra_sql' => " WHERE (    cust_payby.payinfo LIKE '$like_search'
 483                                OR cust_payby.paymask =    '$mask_search'
 484                              ) ".
 485                      " AND cust_payby.payby IN ('CARD','DCRD') ".
 486                      " AND $agentnums_sql", #agent virtulization
 487     });
 488
 489   }
 490
 491
 492   #eliminate duplicates
 493   my %saw = ();
 494   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 495
 496   @cust_main;
 497
 498 }
 499
 500 =item email_search
 501
 502 Accepts the following options: I<email>, the email address to search for.  The
 503 email address will be searched for as an email invoice destination and as an
 504 svc_acct account.
 505
 506 #Any additional options are treated as an additional qualifier on the search
 507 #(i.e. I<agentnum>).
 508
 509 Returns a (possibly empty) array of FS::cust_main objects (but usually just
 510 none or one).
 511
 512 =cut
 513
 514 sub email_search {
 515   my %options = @_;
 516
 517   my $email = delete $options{'email'};
 518
 519   #no agent virtualization yet
 520   #my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
 521
 522   my @cust_main = ();
 523
 524   if ( $email =~ /([^@]+)\@([^@]+)/ ) {
 525
 526     my ( $user, $domain ) = ( $1, $2 );
 527
 528     warn "$me smart_search: searching for $user in domain $domain"
 529       if $DEBUG;
 530
 531     push @cust_main,
 532       map { $_->cust_main }
 533       map { $_->cust_contact }
 534       map { $_->contact }
 535           qsearch( {
 536                      'table'     => 'contact_email',
 537                      'hashref'   => { 'emailaddress' => $email },
 538                    }
 539                  );
 540
 541     push @cust_main,
 542       map  $_->cust_main,
 543       grep $_,
 544       map  $_->cust_svc->cust_pkg,
 545           qsearch( {
 546                      'table'     => 'svc_acct',
 547                      'hashref'   => { 'username' => $user, },
 548                      'extra_sql' =>
 549                        'AND ( SELECT domain FROM svc_domain
 550                                 WHERE svc_acct.domsvc = svc_domain.svcnum
 551                             ) = '. dbh->quote($domain),
 552                    }
 553                  );
 554   }
 555
 556   my %saw = ();
 557   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 558
 559   warn "$me smart_search: found ". scalar(@cust_main). " unique customers"
 560     if $DEBUG;
 561
 562   @cust_main;
 563
 564 }
 565
 566 =back
 567
 568 =head1 CLASS METHODS
 569
 570 =over 4
 571
 572 =item search HASHREF
 573
 574 (Class method)
 575
 576 Returns a qsearch hash expression to search for parameters specified in
 577 HASHREF.  Valid parameters are
 578
 579 =over 4
 580
 581 =item agentnum
 582
 583 =item status
 584
 585 =item address
 586
 587 =item zip
 588
 589 =item refnum
 590
 591 =item cancelled_pkgs
 592
 593 bool
 594
 595 =item signupdate
 596
 597 listref of start date, end date
 598
 599 =item birthdate
 600
 601 listref of start date, end date
 602
 603 =item spouse_birthdate
 604
 605 listref of start date, end date
 606
 607 =item anniversary_date
 608
 609 listref of start date, end date
 610
 611 =item current_balance
 612
 613 listref (list returned by FS::UI::Web::parse_lt_gt($cgi, 'current_balance'))
 614
 615 =item cust_fields
 616
 617 =item flattened_pkgs
 618
 619 bool
 620
 621 =back
 622
 623 =cut
 624
 625 sub search {
 626   my ($class, $params) = @_;
 627
 628   my $dbh = dbh;
 629
 630   my @where = ();
 631   my $orderby;
 632
 633   # initialize these to prevent warnings
 634   $params = {
 635     'custnum'       => '',
 636     'agentnum'      => '',
 637     'usernum'       => '',
 638     'status'        => '',
 639     'address'       => '',
 640     'zip'           => '',
 641     'invoice_terms' => '',
 642     'custbatch'     => '',
 643     %$params
 644   };
 645
 646   ##
 647   # explicit custnum(s)
 648   ##
 649
 650   if ( $params->{'custnum'} ) {
 651     my @custnums = ref($params->{'custnum'}) ?
 652                       @{ $params->{'custnum'} } :
 653                       $params->{'custnum'};
 654     push @where,
 655       'cust_main.custnum IN (' .
 656       join(',', map { $_ =~ /^(\d+)$/ ? $1 : () } @custnums ) .
 657       ')' if scalar(@custnums) > 0;
 658   }
 659
 660   ##
 661   # parse agent
 662   ##
 663
 664   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
 665     push @where,
 666       "cust_main.agentnum = $1";
 667   }
 668
 669   ##
 670   # parse sales person
 671   ##
 672
 673   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
 674     push @where, ($1 > 0 ) ? "cust_main.salesnum = $1"
 675                            : 'cust_main.salesnum IS NULL';
 676   }
 677
 678   ##
 679   # parse usernum
 680   ##
 681
 682   if ( $params->{'usernum'} =~ /^(\d+)$/ and $1 ) {
 683     push @where,
 684       "cust_main.usernum = $1";
 685   }
 686
 687   ##
 688   # parse status
 689   ##
 690
 691   #prospect ordered active inactive suspended cancelled
 692   if ( grep { $params->{'status'} eq $_ } FS::cust_main->statuses() ) {
 693     my $method = $params->{'status'}. '_sql';
 694     #push @where, $class->$method();
 695     push @where, FS::cust_main->$method();
 696   }
 697
 698   ##
 699   # address
 700   ##
 701   if ( $params->{'address'} ) {
 702     # allow this to be an arrayref
 703     my @values = ($params->{'address'});
 704     @values = @{$values[0]} if ref($values[0]);
 705     my @orwhere;
 706     foreach (grep /\S/, @values) {
 707       my $address = dbh->quote('%'. lc($_). '%');
 708       push @orwhere,
 709         "LOWER(cust_location.address1) LIKE $address",
 710         "LOWER(cust_location.address2) LIKE $address";
 711     }
 712     if (@orwhere) {
 713       push @where, "EXISTS(
 714         SELECT 1 FROM cust_location
 715         WHERE cust_location.custnum = cust_main.custnum
 716           AND (".join(' OR ',@orwhere).")
 717         )";
 718     }
 719   }
 720
 721   ##
 722   # city
 723   ##
 724   if ( $params->{'city'} =~ /\S/ ) {
 725     my $city = dbh->quote($params->{'city'});
 726     push @where, "EXISTS(
 727       SELECT 1 FROM cust_location
 728       WHERE cust_location.custnum = cust_main.custnum
 729         AND cust_location.city = $city
 730     )";
 731   }
 732
 733   ##
 734   # county
 735   ##
 736   if ( $params->{'county'} =~ /\S/ ) {
 737     my $county = dbh->quote($params->{'county'});
 738     push @where, "EXISTS(
 739       SELECT 1 FROM cust_location
 740       WHERE cust_location.custnum = cust_main.custnum
 741         AND cust_location.county = $county
 742     )";
 743   }
 744
 745   ##
 746   # state
 747   ##
 748   if ( $params->{'state'} =~ /\S/ ) {
 749     my $state = dbh->quote($params->{'state'});
 750     push @where, "EXISTS(
 751       SELECT 1 FROM cust_location
 752       WHERE cust_location.custnum = cust_main.custnum
 753         AND cust_location.state = $state
 754     )";
 755   }
 756
 757   ##
 758   # zipcode
 759   ##
 760   if ( $params->{'zip'} =~ /\S/ ) {
 761     my $zip = dbh->quote($params->{'zip'} . '%');
 762     push @where, "EXISTS(
 763       SELECT 1 FROM cust_location
 764       WHERE cust_location.custnum = cust_main.custnum
 765         AND cust_location.zip LIKE $zip
 766     )";
 767   }
 768
 769   ##
 770   # country
 771   ##
 772   if ( $params->{'country'} =~ /^(\w\w)$/ ) {
 773     my $country = uc($1);
 774     push @where, "EXISTS(
 775       SELECT 1 FROM cust_location
 776       WHERE cust_location.custnum = cust_main.custnum
 777         AND cust_location.country = '$country'
 778     )";
 779   }
 780
 781   ###
 782   # refnum
 783   ###
 784   if ( $params->{'refnum'}  ) {
 785
 786     my @refnum = ref( $params->{'refnum'} )
 787                    ? @{ $params->{'refnum'} }
 788                    :  ( $params->{'refnum'} );
 789
 790     @refnum = grep /^(\d*)$/, @refnum;
 791
 792     push @where, '( '. join(' OR ', map "cust_main.refnum = $_", @refnum ). ' )'
 793       if @refnum;
 794
 795   }
 796
 797   ##
 798   # parse cancelled package checkbox
 799   ##
 800
 801   my $pkgwhere = "";
 802
 803   $pkgwhere .= "AND (cancel = 0 or cancel is null)"
 804     unless $params->{'cancelled_pkgs'};
 805
 806   ##
 807   # "with email address(es)" checkbox
 808   ##
 809
 810   push @where,
 811     'EXISTS ( SELECT 1 FROM contact_email
 812                 JOIN cust_contact USING (contactnum)
 813                 WHERE cust_contact.custnum = cust_main.custnum
 814             )'
 815     if $params->{'with_email'};
 816
 817   ##
 818   # "with postal mail invoices" checkbox
 819   ##
 820
 821   push @where, "cust_main.postal_invoice = 'Y'"
 822     if $params->{'POST'};
 823
 824   ##
 825   # "without postal mail invoices" checkbox
 826   ##
 827
 828   push @where, "cust_main.postal_invoice IS NULL"
 829     if $params->{'no_POST'};
 830
 831   ##
 832   # "tax exempt" checkbox
 833   ##
 834   push @where, "cust_main.tax = 'Y'"
 835     if $params->{'tax'};
 836
 837   ##
 838   # "not tax exempt" checkbox
 839   ##
 840   push @where, "(cust_main.tax = '' OR cust_main.tax IS NULL )"
 841     if $params->{'no_tax'};
 842
 843   ##
 844   # dates
 845   ##
 846
 847   foreach my $field (qw( signupdate birthdate spouse_birthdate anniversary_date )) {
 848
 849     next unless exists($params->{$field});
 850
 851     my($beginning, $ending, $hour) = @{$params->{$field}};
 852
 853     push @where,
 854       "cust_main.$field IS NOT NULL",
 855       "cust_main.$field >= $beginning",
 856       "cust_main.$field <= $ending";
 857
 858     if($field eq 'signupdate' && defined $hour) {
 859       if ($dbh->{Driver}->{Name} =~ /Pg/i) {
 860         push @where, "extract(hour from to_timestamp(cust_main.$field)) = $hour";
 861       }
 862       elsif( $dbh->{Driver}->{Name} =~ /mysql/i) {
 863         push @where, "hour(from_unixtime(cust_main.$field)) = $hour"
 864       }
 865       else {
 866         warn "search by time of day not supported on ".$dbh->{Driver}->{Name}." databases";
 867       }
 868     }
 869
 870     $orderby ||= "ORDER BY cust_main.$field";
 871
 872   }
 873
 874   ###
 875   # classnum
 876   ###
 877
 878   if ( $params->{'classnum'} ) {
 879
 880     my @classnum = ref( $params->{'classnum'} )
 881                      ? @{ $params->{'classnum'} }
 882                      :  ( $params->{'classnum'} );
 883
 884     @classnum = grep /^(\d*)$/, @classnum;
 885
 886     if ( @classnum ) {
 887       push @where, '( '. join(' OR ', map {
 888                                             $_ ? "cust_main.classnum = $_"
 889                                                : "cust_main.classnum IS NULL"
 890                                           }
 891                                           @classnum
 892                              ).
 893                    ' )';
 894     }
 895
 896   }
 897
 898   ###
 899   # invoice terms
 900   ###
 901
 902   if ( $params->{'invoice_terms'} =~ /^([\w ]+)$/ ) {
 903     my $terms = $1;
 904     if ( $1 eq 'NULL' ) {
 905       push @where,
 906         "( cust_main.invoice_terms IS NULL OR cust_main.invoice_terms = '' )";
 907     } else {
 908       push @where,
 909         "cust_main.invoice_terms IS NOT NULL",
 910         "cust_main.invoice_terms = '$1'";
 911     }
 912   }
 913
 914   ##
 915   # amounts
 916   ##
 917
 918   if ( $params->{'current_balance'} ) {
 919
 920     #my $balance_sql = $class->balance_sql();
 921     my $balance_sql = FS::cust_main->balance_sql();
 922
 923     my @current_balance =
 924       ref( $params->{'current_balance'} )
 925       ? @{ $params->{'current_balance'} }
 926       :  ( $params->{'current_balance'} );
 927
 928     push @where, map { s/current_balance/$balance_sql/; $_ }
 929                      @current_balance;
 930
 931   }
 932
 933   ##
 934   # custbatch
 935   ##
 936
 937   if ( $params->{'custbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
 938     push @where,
 939       "cust_main.custbatch = '$1'";
 940   }
 941
 942   if ( $params->{'tagnum'} ) {
 943     my @tagnums = ref( $params->{'tagnum'} ) ? @{ $params->{'tagnum'} } : ( $params->{'tagnum'} );
 944
 945     @tagnums = grep /^(\d+)$/, @tagnums;
 946
 947     if ( @tagnums ) {
 948       if ( $params->{'all_tags'} ) {
 949         foreach ( @tagnums ) {
 950           push @where, 'exists(select 1 from cust_tag where '.
 951                        'cust_tag.custnum = cust_main.custnum and tagnum = '.
 952                        $_ . ')';
 953         }
 954       } else { # matching any tag, not all
 955         my $tags_where = "0 < (select count(1) from cust_tag where "
 956                 . " cust_tag.custnum = cust_main.custnum and tagnum in ("
 957                 . join(',', @tagnums) . "))";
 958
 959         push @where, $tags_where;
 960       }
 961     }
 962   }
 963
 964   # pkg_classnum
 965   #   all_pkg_classnums
 966   #   any_pkg_status
 967   if ( $params->{'pkg_classnum'} ) {
 968     my @pkg_classnums = ref( $params->{'pkg_classnum'} ) ?
 969                           @{ $params->{'pkg_classnum'} } :
 970                              $params->{'pkg_classnum'};
 971     @pkg_classnums = grep /^(\d+)$/, @pkg_classnums;
 972
 973     if ( @pkg_classnums ) {
 974
 975       my @pkg_where;
 976       if ( $params->{'all_pkg_classnums'} ) {
 977         push @pkg_where, "part_pkg.classnum = $_" foreach @pkg_classnums;
 978       } else {
 979         push @pkg_where,
 980           'part_pkg.classnum IN('. join(',', @pkg_classnums).')';
 981       }
 982       foreach (@pkg_where) {
 983         my $select_pkg =
 984           "SELECT 1 FROM cust_pkg JOIN part_pkg USING (pkgpart) WHERE ".
 985           "cust_pkg.custnum = cust_main.custnum AND $_ ";
 986         if ( not $params->{'any_pkg_status'} ) {
 987           $select_pkg .= 'AND '.FS::cust_pkg->active_sql;
 988         }
 989         push @where, "EXISTS($select_pkg)";
 990       }
 991     }
 992   }
 993
 994   ##
 995   # setup queries, subs, etc. for the search
 996   ##
 997
 998   $orderby ||= 'ORDER BY custnum';
 999
1000   # here is the agent virtualization
1001   push @where,
1002     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
1003
1004   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
1005
1006   my $addl_from = '';
1007   # always make address fields available in results
1008   for my $pre ('bill_', 'ship_') {
1009     $addl_from .=
1010       'LEFT JOIN cust_location AS '.$pre.'location '.
1011       'ON (cust_main.'.$pre.'locationnum = '.$pre.'location.locationnum) ';
1012   }
1013
1014   # always make referral available in results
1015   #   (maybe we should be using FS::UI::Web::join_cust_main instead?)
1016   $addl_from .= ' LEFT JOIN (select refnum, referral from part_referral) AS part_referral_x ON (cust_main.refnum = part_referral_x.refnum) ';
1017
1018   my $count_query = "SELECT COUNT(*) FROM cust_main $addl_from $extra_sql";
1019
1020   my @select = (
1021                  'cust_main.custnum',
1022                  'cust_main.salesnum',
1023                  # there's a good chance that we'll need these
1024                  'cust_main.bill_locationnum',
1025                  'cust_main.ship_locationnum',
1026                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
1027                );
1028
1029   my(@extra_headers) = ();
1030   my(@extra_fields)  = ();
1031
1032   if ($params->{'flattened_pkgs'}) {
1033
1034     #my $pkg_join = '';
1035     $addl_from .=
1036       ' LEFT JOIN cust_pkg ON ( cust_main.custnum = cust_pkg.custnum ) ';
1037
1038     if ($dbh->{Driver}->{Name} eq 'Pg') {
1039
1040       push @select, "
1041         ARRAY_TO_STRING(
1042           ARRAY(
1043             SELECT pkg FROM cust_pkg LEFT JOIN part_pkg USING ( pkgpart )
1044               WHERE cust_main.custnum = cust_pkg.custnum $pkgwhere
1045           ), '|'
1046         ) AS magic
1047       ";
1048
1049     } elsif ($dbh->{Driver}->{Name} =~ /^mysql/i) {
1050       push @select, "GROUP_CONCAT(part_pkg.pkg SEPARATOR '|') as magic";
1051       $addl_from .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1052       #$pkg_join  .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1053     } else {
1054       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
1055            "omitting package information from report.";
1056     }
1057
1058     my $header_query = "
1059       SELECT COUNT(cust_pkg.custnum = cust_main.custnum) AS count
1060         FROM cust_main $addl_from $extra_sql $pkgwhere
1061           GROUP BY cust_main.custnum ORDER BY count DESC LIMIT 1
1062     ";
1063
1064     my $sth = dbh->prepare($header_query) or die dbh->errstr;
1065     $sth->execute() or die $sth->errstr;
1066     my $headerrow = $sth->fetchrow_arrayref;
1067     my $headercount = $headerrow ? $headerrow->[0] : 0;
1068     while($headercount) {
1069       unshift @extra_headers, "Package ". $headercount;
1070       unshift @extra_fields, eval q!sub {my $c = shift;
1071                                          my @a = split '\|', $c->magic;
1072                                          my $p = $a[!.--$headercount. q!];
1073                                          $p;
1074                                         };!;
1075     }
1076
1077   }
1078
1079   my $select = join(', ', @select);
1080
1081   my $sql_query = {
1082     'table'         => 'cust_main',
1083     'select'        => $select,
1084     'addl_from'     => $addl_from,
1085     'hashref'       => {},
1086     'extra_sql'     => $extra_sql,
1087     'order_by'      => $orderby,
1088     'count_query'   => $count_query,
1089     'extra_headers' => \@extra_headers,
1090     'extra_fields'  => \@extra_fields,
1091   };
1092   $sql_query;
1093
1094 }
1095
1096 =item fuzzy_search FUZZY_HASHREF [ OPTS ]
1097
1098 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
1099 records.  Currently, I<first>, I<last>, I<company> and/or I<address1> may be
1100 specified.
1101
1102 Additional options are the same as FS::Record::qsearch
1103
1104 =cut
1105
1106 sub fuzzy_search {
1107   my $self = shift;
1108   my $fuzzy = shift;
1109   # sensible defaults, then merge in any passed options
1110   my %fuzopts = (
1111     'table'     => 'cust_main',
1112     'addl_from' => '',
1113     'extra_sql' => '',
1114     'hashref'   => {},
1115     @_
1116   );
1117
1118   my @cust_main = ();
1119
1120   my @fuzzy_mod = 'i';
1121   my $conf = new FS::Conf;
1122   my $fuzziness = $conf->config('fuzzy-fuzziness');
1123   push @fuzzy_mod, $fuzziness if $fuzziness;
1124
1125   check_and_rebuild_fuzzyfiles();
1126   foreach my $field ( keys %$fuzzy ) {
1127
1128     my $all = $self->all_X($field);
1129     next unless scalar(@$all);
1130
1131     my %match = ();
1132     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, \@fuzzy_mod, @$all ) );
1133     next if !keys(%match);
1134
1135     my $in_matches = 'IN (' .
1136                      join(',', map { dbh->quote($_) } keys %match) .
1137                      ')';
1138
1139     my $extra_sql = $fuzopts{extra_sql};
1140     if ($extra_sql =~ /^\s*where /i or keys %{ $fuzopts{hashref} }) {
1141       $extra_sql .= ' AND ';
1142     } else {
1143       $extra_sql .= 'WHERE ';
1144     }
1145     $extra_sql .= "$field $in_matches";
1146
1147     my $addl_from = $fuzopts{addl_from};
1148     if ( $field =~ /^cust_location\./ ) {
1149       $addl_from .= ' JOIN cust_location USING (custnum)';
1150     } elsif ( $field =~ /^contact\./ ) {
1151       $addl_from .= ' JOIN contact USING (custnum)';
1152     }
1153
1154     push @cust_main, qsearch({
1155       %fuzopts,
1156       'addl_from' => $addl_from,
1157       'extra_sql' => $extra_sql,
1158     });
1159   }
1160
1161   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
1162   my %saw = ();
1163   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
1164
1165   @cust_main;
1166
1167 }
1168
1169 =back
1170
1171 =head1 UTILITY SUBROUTINES
1172
1173 =over 4
1174
1175 =item check_and_rebuild_fuzzyfiles
1176
1177 =cut
1178
1179 sub check_and_rebuild_fuzzyfiles {
1180   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1181   rebuild_fuzzyfiles()
1182     if grep { ! -e "$dir/$_" }
1183          map {
1184                my ($field, $table) = reverse split('\.', $_);
1185                $table ||= 'cust_main';
1186                "$table.$field"
1187              }
1188            @fuzzyfields;
1189 }
1190
1191 =item rebuild_fuzzyfiles
1192
1193 =cut
1194
1195 sub rebuild_fuzzyfiles {
1196
1197   use Fcntl qw(:flock);
1198
1199   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1200   mkdir $dir, 0700 unless -d $dir;
1201
1202   foreach my $fuzzy ( @fuzzyfields ) {
1203
1204     my ($field, $table) = reverse split('\.', $fuzzy);
1205     $table ||= 'cust_main';
1206
1207     open(LOCK,">>$dir/$table.$field")
1208       or die "can't open $dir/$table.$field: $!";
1209     flock(LOCK,LOCK_EX)
1210       or die "can't lock $dir/$table.$field: $!";
1211
1212     open (CACHE, '>:encoding(UTF-8)', "$dir/$table.$field.tmp")
1213       or die "can't open $dir/$table.$field.tmp: $!";
1214
1215     my $sth = dbh->prepare(
1216       "SELECT $field FROM $table WHERE $field IS NOT NULL AND $field != ''"
1217     );
1218     $sth->execute or die $sth->errstr;
1219
1220     while ( my $row = $sth->fetchrow_arrayref ) {
1221       print CACHE $row->[0]. "\n";
1222     }
1223
1224     close CACHE or die "can't close $dir/$table.$field.tmp: $!";
1225
1226     rename "$dir/$table.$field.tmp", "$dir/$table.$field";
1227     close LOCK;
1228   }
1229
1230 }
1231
1232 =item append_fuzzyfiles FIRSTNAME LASTNAME COMPANY ADDRESS1
1233
1234 =cut
1235
1236 sub append_fuzzyfiles {
1237   #my( $first, $last, $company ) = @_;
1238
1239   check_and_rebuild_fuzzyfiles();
1240
1241   #foreach my $fuzzy (@fuzzyfields) {
1242   foreach my $fuzzy ( 'cust_main.first', 'cust_main.last', 'cust_main.company',
1243                       'cust_location.address1',
1244                       'cust_main.ship_company',
1245                     ) {
1246
1247     append_fuzzyfiles_fuzzyfield($fuzzy, shift);
1248
1249   }
1250
1251   1;
1252 }
1253
1254 =item append_fuzzyfiles_fuzzyfield COLUMN VALUE
1255
1256 =item append_fuzzyfiles_fuzzyfield TABLE.COLUMN VALUE
1257
1258 =cut
1259
1260 use Fcntl qw(:flock);
1261 sub append_fuzzyfiles_fuzzyfield {
1262   my( $fuzzyfield, $value ) = @_;
1263
1264   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1265
1266
1267   my ($field, $table) = reverse split('\.', $fuzzyfield);
1268   $table ||= 'cust_main';
1269
1270   return unless defined($value) && length($value);
1271
1272   open(CACHE, '>>:encoding(UTF-8)', "$dir/$table.$field" )
1273     or die "can't open $dir/$table.$field: $!";
1274   flock(CACHE,LOCK_EX)
1275     or die "can't lock $dir/$table.$field: $!";
1276
1277   print CACHE "$value\n";
1278
1279   flock(CACHE,LOCK_UN)
1280     or die "can't unlock $dir/$table.$field: $!";
1281   close CACHE;
1282
1283 }
1284
1285 =item all_X
1286
1287 =cut
1288
1289 sub all_X {
1290   my( $self, $fuzzy ) = @_;
1291   my ($field, $table) = reverse split('\.', $fuzzy);
1292   $table ||= 'cust_main';
1293
1294   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1295   open(CACHE, '<:encoding(UTF-8)', "$dir/$table.$field")
1296     or die "can't open $dir/$table.$field: $!";
1297   my @array = map { chomp; $_; } <CACHE>;
1298   close CACHE;
1299   \@array;
1300 }
1301
1302 =head1 BUGS
1303
1304 Bed bugs
1305
1306 =head1 SEE ALSO
1307
1308 L<FS::cust_main>, L<FS::Record>
1309
1310 =cut
1311
1312 1;
1313