FS/FS/cust_main/Search.pm

   1 package FS::cust_main::Search;
   2
   3 use strict;
   4 use Carp qw( croak );
   5 use base qw( Exporter );
   6 use vars qw( @EXPORT_OK $DEBUG $me $conf @fuzzyfields );
   7 use String::Approx qw(amatch);
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch );
  10 use FS::cust_main;
  11 use FS::cust_main_invoice;
  12 use FS::svc_acct;
  13 use FS::payinfo_Mixin;
  14
  15 @EXPORT_OK = qw( smart_search );
  16
  17 # 1 is mostly method/subroutine entry and options
  18 # 2 traces progress of some operations
  19 # 3 is even more information including possibly sensitive data
  20 $DEBUG = 0;
  21 $me = '[FS::cust_main::Search]';
  22
  23 @fuzzyfields = (
  24   'cust_main.first', 'cust_main.last', 'cust_main.company',
  25   'cust_main.ship_company', # if you're using it
  26   'cust_location.address1',
  27   'contact.first',   'contact.last',
  28 );
  29
  30 install_callback FS::UID sub {
  31   $conf = new FS::Conf;
  32   #yes, need it for stuff below (prolly should be cached)
  33 };
  34
  35 =head1 NAME
  36
  37 FS::cust_main::Search - Customer searching
  38
  39 =head1 SYNOPSIS
  40
  41   use FS::cust_main::Search;
  42
  43   FS::cust_main::Search::smart_search(%options);
  44
  45   FS::cust_main::Search::email_search(%options);
  46
  47   FS::cust_main::Search->search( \%options );
  48
  49   FS::cust_main::Search->fuzzy_search( \%fuzzy_hashref );
  50
  51 =head1 SUBROUTINES
  52
  53 =over 4
  54
  55 =item smart_search OPTION => VALUE ...
  56
  57 Accepts the following options: I<search>, the string to search for.  The string
  58 will be searched for as a customer number, phone number, name or company name,
  59 address (if address1-search is on), invoicing email address, or credit card
  60 number.
  61
  62 Searches match as an exact, or, in some cases, a substring or fuzzy match (see
  63 the source code for the exact heuristics used); I<no_fuzzy_on_exact>, causes
  64 smart_search to
  65 skip fuzzy matching when an exact match is found.
  66
  67 Any additional options are treated as an additional qualifier on the search
  68 (i.e. I<agentnum>).
  69
  70 Returns a (possibly empty) array of FS::cust_main objects.
  71
  72 =cut
  73
  74 sub smart_search {
  75   my %options = @_;
  76
  77   #here is the agent virtualization
  78   my $agentnums_sql =
  79     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
  80   my $agentnums_href = $FS::CurrentUser::CurrentUser->agentnums_href;
  81
  82   my @cust_main = ();
  83
  84   my $skip_fuzzy = delete $options{'no_fuzzy_on_exact'};
  85   my $search = delete $options{'search'};
  86   ( my $alphanum_search = $search ) =~ s/\W//g;
  87
  88   if ( $alphanum_search =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { #phone# search
  89
  90     #false laziness w/Record::ut_phone
  91     my $phonen = "$1-$2-$3";
  92     $phonen .= " x$4" if $4;
  93
  94     my $phonenum = "$1$2$3";
  95     #my $extension = $4;
  96
  97     #cust_main phone numbers and contact phone number
  98     push @cust_main, qsearch( {
  99       'select'    => 'cust_main.*',
 100       'table'     => 'cust_main',
 101       'addl_from' => ' left join cust_contact  using (custnum) '.
 102                      ' left join contact_phone using (contactnum) ',
 103       'hashref'   => { %options },
 104       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 105                      ' ( '.
 106                          join(' OR ', map "$_ = '$phonen'",
 107                                           qw( daytime night mobile fax )
 108                              ).
 109                           " OR phonenum = '$phonenum' ".
 110                      ' ) '.
 111                      " AND $agentnums_sql", #agent virtualization
 112     } );
 113
 114     unless ( @cust_main || $phonen =~ /x\d+$/ ) { #no exact match
 115       #try looking for matches with extensions unless one was specified
 116
 117       push @cust_main, qsearch( {
 118         'table'     => 'cust_main',
 119         'hashref'   => { %options },
 120         'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 121                        ' ( '.
 122                            join(' OR ', map "$_ LIKE '$phonen\%'",
 123                                             qw( daytime night )
 124                                ).
 125                        ' ) '.
 126                        " AND $agentnums_sql", #agent virtualization
 127       } );
 128
 129     }
 130
 131   }
 132
 133
 134   if ( $search =~ /@/ ) { #email address from cust_main_invoice and contact_email
 135
 136     push @cust_main, qsearch( {
 137       'select'    => 'cust_main.*',
 138       'table'     => 'cust_main',
 139       'addl_from' => ' left join cust_main_invoice using (custnum) '.
 140                      ' left join cust_contact      using (custnum) '.
 141                      ' left join contact_email     using (contactnum) ',
 142       'hashref'   => { %options },
 143       'extra_sql' => ( scalar(keys %options) ? ' AND ' : ' WHERE ' ).
 144                      ' ( '.
 145                          join(' OR ', map "$_ = '$search'",
 146                                           qw( dest emailaddress )
 147                              ).
 148                      ' ) '.
 149                      " AND $agentnums_sql", #agent virtualization
 150     } );
 151
 152   # custnum search (also try agent_custid), with some tweaking options if your
 153   # legacy cust "numbers" have letters
 154   } elsif (    $search =~ /^\s*(\d+)\s*$/
 155             or ( $conf->config('cust_main-agent_custid-format') eq 'ww?d+'
 156                  && $search =~ /^\s*(\w\w?\d+)\s*$/
 157                )
 158             or ( $conf->config('cust_main-agent_custid-format') eq 'd+-w'
 159                  && $search =~ /^\s*(\d+-\w)\s*$/
 160                )
 161             or ( $conf->config('cust_main-custnum-display_special')
 162                  # it's not currently possible for special prefixes to contain
 163                  # digits, so just strip off any alphabetic prefix and match
 164                  # the rest to custnum
 165                  && $search =~ /^\s*[[:alpha:]]*(\d+)\s*$/
 166                )
 167             or ( $conf->exists('address1-search' )
 168                  && $search =~ /^\s*(\d+\-?\w*)\s*$/ #i.e. 1234A or 9432-D
 169                )
 170           )
 171   {
 172
 173     my $num = $1;
 174
 175     if ( $num =~ /^(\d+)$/ && $num <= 2147483647 ) { #need a bigint custnum? wow
 176       my $agent_custid_null = $conf->exists('cust_main-default_agent_custid')
 177                                 ? ' AND agent_custid IS NULL ' : '';
 178       push @cust_main, qsearch( {
 179         'table'     => 'cust_main',
 180         'hashref'   => { 'custnum' => $num, %options },
 181         'extra_sql' => " AND $agentnums_sql $agent_custid_null",
 182       } );
 183     }
 184
 185     # for all agents this user can see, if any of them have custnum prefixes
 186     # that match the search string, include customers that match the rest
 187     # of the custnum and belong to that agent
 188     foreach my $agentnum ( keys %$agentnums_href ) {
 189       my $p = $conf->config('cust_main-custnum-display_prefix', $agentnum);
 190       next if !$p;
 191       if ( $p eq substr($num, 0, length($p)) ) {
 192         push @cust_main, qsearch( {
 193           'table'   => 'cust_main',
 194           'hashref' => { 'custnum' => 0 + substr($num, length($p)),
 195                          'agentnum' => $agentnum,
 196                           %options,
 197                        },
 198         } );
 199       }
 200     }
 201
 202     push @cust_main, qsearch( {
 203         'table'     => 'cust_main',
 204         'hashref'   => { 'agent_custid' => $num, %options },
 205         'extra_sql' => " AND $agentnums_sql", #agent virtualization
 206     } );
 207
 208     if ( $conf->exists('address1-search') ) {
 209       my $len = length($num);
 210       $num = lc($num);
 211       # probably the Right Thing: return customers that have any associated
 212       # locations matching the string, not just bill/ship location
 213       push @cust_main, qsearch( {
 214         'select'    => 'cust_main.*',
 215         'table'     => 'cust_main',
 216         'addl_from' => ' JOIN cust_location USING (custnum) ',
 217         'hashref'   => { %options, },
 218         'extra_sql' =>
 219           ( keys(%options) ? ' AND ' : ' WHERE ' ).
 220           " LOWER(SUBSTRING(cust_location.address1 FROM 1 FOR $len)) = '$num' ".
 221           " AND $agentnums_sql",
 222       } );
 223     }
 224
 225   } elsif ( $search =~ /^\s*(\S.*\S)\s+\((.+), ([^,]+)\)\s*$/ ) {
 226
 227     my($company, $last, $first) = ( $1, $2, $3 );
 228
 229     # "Company (Last, First)"
 230     #this is probably something a browser remembered,
 231     #so just do an exact search (but case-insensitive, so USPS standardization
 232     #doesn't throw a wrench in the works)
 233
 234     push @cust_main, qsearch( {
 235       'table'     => 'cust_main',
 236       'hashref'   => { %options },
 237       'extra_sql' =>
 238         ( keys(%options) ? ' AND ' : ' WHERE ' ).
 239         join(' AND ',
 240           " LOWER(first)   = ". dbh->quote(lc($first)),
 241           " LOWER(last)    = ". dbh->quote(lc($last)),
 242           " LOWER(company) = ". dbh->quote(lc($company)),
 243           $agentnums_sql,
 244         ),
 245     } );
 246
 247     #contacts?
 248     # probably not necessary for the "something a browser remembered" case
 249
 250   } elsif ( $search =~ /^\s*(\S.*\S)\s*$/ ) { # value search
 251                                               # try {first,last,company}
 252
 253     my $value = lc($1);
 254
 255     # # remove "(Last, First)" in "Company (Last, First)", otherwise the
 256     # # full strings the browser remembers won't work
 257     # $value =~ s/\([\w \,\.\-\']*\)$//; #false laziness w/Record::ut_name
 258
 259     use Lingua::EN::NameParse;
 260     my $NameParse = new Lingua::EN::NameParse(
 261              auto_clean     => 1,
 262              allow_reversed => 1,
 263     );
 264
 265     my($last, $first) = ( '', '' );
 266     #maybe disable this too and just rely on NameParse?
 267     if ( $value =~ /^(.+),\s*([^,]+)$/ ) { # Last, First
 268
 269       ($last, $first) = ( $1, $2 );
 270
 271     #} elsif  ( $value =~ /^(.+)\s+(.+)$/ ) {
 272     } elsif ( ! $NameParse->parse($value) ) {
 273
 274       my %name = $NameParse->components;
 275       $first = lc($name{'given_name_1'}) || $name{'initials_1'}; #wtf NameParse, Ed?
 276       $last  = lc($name{'surname_1'});
 277
 278     }
 279
 280     if ( $first && $last ) {
 281
 282       my($q_last, $q_first) = ( dbh->quote($last), dbh->quote($first) );
 283
 284       #exact
 285       my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 286       $sql .= "( (LOWER(cust_main.last) = $q_last AND LOWER(cust_main.first) = $q_first)
 287                  OR (LOWER(contact.last) = $q_last AND LOWER(contact.first) = $q_first) )";
 288
 289       #cust_main and contacts
 290       push @cust_main, qsearch( {
 291         'select'    => 'cust_main.*',
 292         'table'     => 'cust_main',
 293         'addl_from' => ' left join cust_contact using (custnum) '.
 294                        ' left join contact using (contactnum) ',
 295         'hashref'   => { %options },
 296         'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 297       } );
 298
 299       # or it just be something that was typed in... (try that in a sec)
 300
 301     }
 302
 303     my $q_value = dbh->quote($value);
 304
 305     #exact
 306     my $sql = scalar(keys %options) ? ' AND ' : ' WHERE ';
 307     $sql .= " (    LOWER(cust_main.first)         = $q_value
 308                 OR LOWER(cust_main.last)          = $q_value
 309                 OR LOWER(cust_main.company)       = $q_value
 310                 OR LOWER(cust_main.ship_company)  = $q_value
 311                 OR LOWER(contact.first)           = $q_value
 312                 OR LOWER(contact.last)            = $q_value
 313             )";
 314
 315     #address1 (yes, it's a kludge)
 316     $sql .= "   OR EXISTS (
 317                             SELECT 1 FROM cust_location
 318                               WHERE LOWER(cust_location.address1) = $q_value
 319                                 AND cust_location.custnum = cust_main.custnum
 320                           )"
 321       if $conf->exists('address1-search');
 322
 323     push @cust_main, qsearch( {
 324       'select'    => 'cust_main.*',
 325       'table'     => 'cust_main',
 326       'addl_from' => ' left join cust_contact using (custnum) '.
 327                      ' left join contact using (contactnum) ',
 328       'hashref'   => { %options },
 329       'extra_sql' => "$sql AND $agentnums_sql", #agent virtualization
 330     } );
 331
 332     #no exact match, trying substring/fuzzy
 333     #always do substring & fuzzy (unless they're explicity config'ed off)
 334     #getting complaints searches are not returning enough
 335     unless ( @cust_main  && $skip_fuzzy || $conf->exists('disable-fuzzy') ) {
 336
 337       #still some false laziness w/search (was search/cust_main.cgi)
 338
 339       my $min_len =
 340         $FS::CurrentUser::CurrentUser->access_right('List all customers')
 341         ? 3 : 4;
 342
 343       #substring
 344
 345       my @company_hashrefs = ();
 346       if ( length($value) >= $min_len ) {
 347         @company_hashrefs = (
 348           { 'company'      => { op=>'ILIKE', value=>"%$value%" }, },
 349           { 'ship_company' => { op=>'ILIKE', value=>"%$value%" }, },
 350         );
 351       }
 352
 353       my @hashrefs = ();
 354       if ( $first && $last ) {
 355
 356         @hashrefs = (
 357           { 'first'        => { op=>'ILIKE', value=>"%$first%" },
 358             'last'         => { op=>'ILIKE', value=>"%$last%" },
 359           },
 360         );
 361
 362       } elsif ( length($value) >= $min_len ) {
 363
 364         @hashrefs = (
 365           { 'first'        => { op=>'ILIKE', value=>"%$value%" }, },
 366           { 'last'         => { op=>'ILIKE', value=>"%$value%" }, },
 367         );
 368
 369       }
 370
 371       foreach my $hashref ( @company_hashrefs, @hashrefs ) {
 372
 373         push @cust_main, qsearch( {
 374           'table'     => 'cust_main',
 375           'hashref'   => { %$hashref,
 376                            %options,
 377                          },
 378           'extra_sql' => " AND $agentnums_sql", #agent virtualizaiton
 379         } );
 380
 381       }
 382
 383       if ( $conf->exists('address1-search') && length($value) >= $min_len ) {
 384
 385         push @cust_main, qsearch( {
 386           select    => 'cust_main.*',
 387           table     => 'cust_main',
 388           addl_from => 'JOIN cust_location USING (custnum)',
 389           extra_sql => 'WHERE '.
 390                         ' cust_location.address1 ILIKE '.dbh->quote("%$value%").
 391                         " AND $agentnums_sql", #agent virtualizaiton
 392         } );
 393
 394       }
 395
 396       #contact substring
 397
 398       foreach my $hashref ( @hashrefs ) {
 399
 400         push @cust_main,
 401           grep $agentnums_href->{$_->agentnum}, #agent virt
 402             grep $_, #skip contacts that don't have cust_main records
 403               map $_->cust_main,
 404                 qsearch({
 405                           'table'     => 'contact',
 406                           'hashref'   => { %$hashref,
 407                                            #%options,
 408                                          },
 409                           #'extra_sql' => " AND $agentnums_sql", #agent virt
 410                        });
 411
 412       }
 413
 414       #fuzzy
 415       my %fuzopts = (
 416         'hashref'   => \%options,
 417         'select'    => '',
 418         'extra_sql' => "WHERE $agentnums_sql",    #agent virtualization
 419       );
 420
 421       if ( $first && $last ) {
 422         push @cust_main, FS::cust_main::Search->fuzzy_search(
 423           { 'last'   => $last,    #fuzzy hashref
 424             'first'  => $first }, #
 425           %fuzopts
 426         );
 427         push @cust_main, FS::cust_main::Search->fuzzy_search(
 428           { 'contact.last'   => $last,    #fuzzy hashref
 429             'contact.first'  => $first }, #
 430           %fuzopts
 431         );
 432       }
 433
 434       foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
 435         push @cust_main, FS::cust_main::Search->fuzzy_search(
 436           { $field => $value },
 437           %fuzopts
 438         );
 439       }
 440       foreach my $field ( 'first', 'last' ) {
 441         push @cust_main, FS::cust_main::Search->fuzzy_search(
 442           { "contact.$field" => $value },
 443           %fuzopts
 444         );
 445       }
 446       if ( $conf->exists('address1-search') ) {
 447         push @cust_main,
 448           FS::cust_main::Search->fuzzy_search(
 449             { 'cust_location.address1' => $value },
 450             %fuzopts
 451         );
 452       }
 453
 454     }
 455
 456   }
 457
 458   ( my $nospace_search = $search ) =~ s/\s//g;
 459   ( my $card_search = $nospace_search ) =~ s/\-//g;
 460   $card_search =~ s/[x\*\.\_]/x/gi;
 461
 462   if ( $card_search =~ /^[\dx]{15,16}$/i ) { #credit card search
 463
 464     ( my $like_search = $card_search ) =~ s/x/_/g;
 465     my $mask_search = FS::payinfo_Mixin->mask_payinfo('CARD', $card_search);
 466
 467     push @cust_main, qsearch({
 468       'table'     => 'cust_main',
 469       'addl_from' => ' JOIN cust_payby USING (custnum)',
 470       'hashref'   => {},
 471       'extra_sql' => " WHERE (    cust_payby.payinfo LIKE '$like_search'
 472                                OR cust_payby.paymask =    '$mask_search'
 473                              ) ".
 474                      " AND cust_payby.payby IN ('CARD','DCRD') ".
 475                      " AND $agentnums_sql", #agent virtulization
 476     });
 477
 478   }
 479
 480
 481   #eliminate duplicates
 482   my %saw = ();
 483   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 484
 485   @cust_main;
 486
 487 }
 488
 489 =item email_search
 490
 491 Accepts the following options: I<email>, the email address to search for.  The
 492 email address will be searched for as an email invoice destination and as an
 493 svc_acct account.
 494
 495 #Any additional options are treated as an additional qualifier on the search
 496 #(i.e. I<agentnum>).
 497
 498 Returns a (possibly empty) array of FS::cust_main objects (but usually just
 499 none or one).
 500
 501 =cut
 502
 503 sub email_search {
 504   my %options = @_;
 505
 506   my $email = delete $options{'email'};
 507
 508   #no agent virtualization yet
 509   #my $agentnums_sql = $FS::CurrentUser::CurrentUser->agentnums_sql;
 510
 511   my @cust_main = ();
 512
 513   if ( $email =~ /([^@]+)\@([^@]+)/ ) {
 514
 515     my ( $user, $domain ) = ( $1, $2 );
 516
 517     warn "$me smart_search: searching for $user in domain $domain"
 518       if $DEBUG;
 519
 520     push @cust_main,
 521       map { $_->cust_main }
 522       map { $_->cust_contact }
 523       map { $_->contact }
 524           qsearch( {
 525                      'table'     => 'contact_email',
 526                      'hashref'   => { 'emailaddress' => $email },
 527                    }
 528                  );
 529
 530     push @cust_main,
 531       map  $_->cust_main,
 532       grep $_,
 533       map  $_->cust_svc->cust_pkg,
 534           qsearch( {
 535                      'table'     => 'svc_acct',
 536                      'hashref'   => { 'username' => $user, },
 537                      'extra_sql' =>
 538                        'AND ( SELECT domain FROM svc_domain
 539                                 WHERE svc_acct.domsvc = svc_domain.svcnum
 540                             ) = '. dbh->quote($domain),
 541                    }
 542                  );
 543   }
 544
 545   my %saw = ();
 546   @cust_main = grep { !$saw{$_->custnum}++ } @cust_main;
 547
 548   warn "$me smart_search: found ". scalar(@cust_main). " unique customers"
 549     if $DEBUG;
 550
 551   @cust_main;
 552
 553 }
 554
 555 =back
 556
 557 =head1 CLASS METHODS
 558
 559 =over 4
 560
 561 =item search HASHREF
 562
 563 (Class method)
 564
 565 Returns a qsearch hash expression to search for parameters specified in
 566 HASHREF.  Valid parameters are
 567
 568 =over 4
 569
 570 =item agentnum
 571
 572 =item status
 573
 574 =item address
 575
 576 =item zip
 577
 578 =item refnum
 579
 580 =item cancelled_pkgs
 581
 582 bool
 583
 584 =item signupdate
 585
 586 listref of start date, end date
 587
 588 =item birthdate
 589
 590 listref of start date, end date
 591
 592 =item spouse_birthdate
 593
 594 listref of start date, end date
 595
 596 =item anniversary_date
 597
 598 listref of start date, end date
 599
 600 =item current_balance
 601
 602 listref (list returned by FS::UI::Web::parse_lt_gt($cgi, 'current_balance'))
 603
 604 =item cust_fields
 605
 606 =item flattened_pkgs
 607
 608 bool
 609
 610 =back
 611
 612 =cut
 613
 614 sub search {
 615   my ($class, $params) = @_;
 616
 617   my $dbh = dbh;
 618
 619   my @where = ();
 620   my $orderby;
 621
 622   # initialize these to prevent warnings
 623   $params = {
 624     'custnum'       => '',
 625     'agentnum'      => '',
 626     'usernum'       => '',
 627     'status'        => '',
 628     'address'       => '',
 629     'zip'           => '',
 630     'invoice_terms' => '',
 631     'custbatch'     => '',
 632     %$params
 633   };
 634
 635   ##
 636   # explicit custnum(s)
 637   ##
 638
 639   if ( $params->{'custnum'} ) {
 640     my @custnums = ref($params->{'custnum'}) ?
 641                       @{ $params->{'custnum'} } :
 642                       $params->{'custnum'};
 643     push @where,
 644       'cust_main.custnum IN (' .
 645       join(',', map { $_ =~ /^(\d+)$/ ? $1 : () } @custnums ) .
 646       ')' if scalar(@custnums) > 0;
 647   }
 648
 649   ##
 650   # parse agent
 651   ##
 652
 653   if ( $params->{'agentnum'} =~ /^(\d+)$/ and $1 ) {
 654     push @where,
 655       "cust_main.agentnum = $1";
 656   }
 657
 658   ##
 659   # parse sales person
 660   ##
 661
 662   if ( $params->{'salesnum'} =~ /^(\d+)$/ ) {
 663     push @where, ($1 > 0 ) ? "cust_main.salesnum = $1"
 664                            : 'cust_main.salesnum IS NULL';
 665   }
 666
 667   ##
 668   # parse usernum
 669   ##
 670
 671   if ( $params->{'usernum'} =~ /^(\d+)$/ and $1 ) {
 672     push @where,
 673       "cust_main.usernum = $1";
 674   }
 675
 676   ##
 677   # parse status
 678   ##
 679
 680   #prospect ordered active inactive suspended cancelled
 681   if ( grep { $params->{'status'} eq $_ } FS::cust_main->statuses() ) {
 682     my $method = $params->{'status'}. '_sql';
 683     #push @where, $class->$method();
 684     push @where, FS::cust_main->$method();
 685   }
 686
 687   my $current = '';
 688   unless ( $params->{location_history} ) {
 689     $current = '
 690       AND (    cust_location.locationnum IN ( cust_main.bill_locationnum,
 691                                               cust_main.ship_locationnum
 692                                             )
 693             OR cust_location.locationnum IN (
 694                  SELECT locationnum FROM cust_pkg
 695                   WHERE cust_pkg.custnum = cust_main.custnum
 696                     AND locationnum IS NOT NULL
 697                     AND '. FS::cust_pkg->ncancelled_recurring_sql.'
 698                )
 699           )';
 700   }
 701
 702   ##
 703   # address
 704   ##
 705   if ( $params->{'address'} ) {
 706     # allow this to be an arrayref
 707     my @values = ($params->{'address'});
 708     @values = @{$values[0]} if ref($values[0]);
 709     my @orwhere;
 710     foreach (grep /\S/, @values) {
 711       my $address = dbh->quote('%'. lc($_). '%');
 712       push @orwhere,
 713         "LOWER(cust_location.address1) LIKE $address",
 714         "LOWER(cust_location.address2) LIKE $address";
 715     }
 716     if (@orwhere) {
 717       push @where, "EXISTS(
 718         SELECT 1 FROM cust_location
 719         WHERE cust_location.custnum = cust_main.custnum
 720           AND (".join(' OR ',@orwhere).")
 721           $current
 722         )";
 723     }
 724   }
 725
 726   ##
 727   # city
 728   ##
 729   if ( $params->{'city'} =~ /\S/ ) {
 730     my $city = dbh->quote($params->{'city'});
 731     push @where, "EXISTS(
 732       SELECT 1 FROM cust_location
 733       WHERE cust_location.custnum = cust_main.custnum
 734         AND cust_location.city = $city
 735         $current
 736     )";
 737   }
 738
 739   ##
 740   # county
 741   ##
 742   if ( $params->{'county'} =~ /\S/ ) {
 743     my $county = dbh->quote($params->{'county'});
 744     push @where, "EXISTS(
 745       SELECT 1 FROM cust_location
 746       WHERE cust_location.custnum = cust_main.custnum
 747         AND cust_location.county = $county
 748         $current
 749     )";
 750   }
 751
 752   ##
 753   # state
 754   ##
 755   if ( $params->{'state'} =~ /\S/ ) {
 756     my $state = dbh->quote($params->{'state'});
 757     push @where, "EXISTS(
 758       SELECT 1 FROM cust_location
 759       WHERE cust_location.custnum = cust_main.custnum
 760         AND cust_location.state = $state
 761         $current
 762     )";
 763   }
 764
 765   ##
 766   # zipcode
 767   ##
 768   if ( $params->{'zip'} =~ /\S/ ) {
 769     my $zip = dbh->quote($params->{'zip'} . '%');
 770     push @where, "EXISTS(
 771       SELECT 1 FROM cust_location
 772       WHERE cust_location.custnum = cust_main.custnum
 773         AND cust_location.zip LIKE $zip
 774         $current
 775     )";
 776   }
 777
 778   ##
 779   # country
 780   ##
 781   if ( $params->{'country'} =~ /^(\w\w)$/ ) {
 782     my $country = uc($1);
 783     push @where, "EXISTS(
 784       SELECT 1 FROM cust_location
 785       WHERE cust_location.custnum = cust_main.custnum
 786         AND cust_location.country = '$country'
 787         $current
 788     )";
 789   }
 790
 791   ###
 792   # refnum
 793   ###
 794   if ( $params->{'refnum'}  ) {
 795
 796     my @refnum = ref( $params->{'refnum'} )
 797                    ? @{ $params->{'refnum'} }
 798                    :  ( $params->{'refnum'} );
 799
 800     @refnum = grep /^(\d*)$/, @refnum;
 801
 802     push @where, '( '. join(' OR ', map "cust_main.refnum = $_", @refnum ). ' )'
 803       if @refnum;
 804
 805   }
 806
 807   ##
 808   # parse cancelled package checkbox
 809   ##
 810
 811   my $pkgwhere = "";
 812
 813   $pkgwhere .= "AND (cancel = 0 or cancel is null)"
 814     unless $params->{'cancelled_pkgs'};
 815
 816   ##
 817   # "with email address(es)" checkbox,
 818   #    also optionally: with_email_dest and with_contact_type
 819   ##
 820
 821   if ($params->{with_email}) {
 822     my @email_dest;
 823     my $email_dest_sql;
 824     my $contact_type_sql;
 825
 826     if ($params->{with_email_dest}) {
 827       croak unless ref $params->{with_email_dest} eq 'ARRAY';
 828
 829       @email_dest = @{$params->{with_email_dest}};
 830       $email_dest_sql =
 831         " AND ( ".
 832         join(' OR ',map(" cust_contact.${_}_dest IS NOT NULL ", @email_dest)).
 833         " ) ";
 834         # Can't use message_dist = 'Y' because single quotes are escaped later
 835     }
 836     if ($params->{with_contact_type}) {
 837       croak unless ref $params->{with_contact_type} eq 'ARRAY';
 838
 839       my @contact_type = grep {/^\d+$/ && $_ > 0} @{$params->{with_contact_type}};
 840       my $has_null_type = 0;
 841       $has_null_type = 1 if grep { $_ eq 0 } @{$params->{with_contact_type}};
 842       my $hnt_sql;
 843       if ($has_null_type) {
 844         $hnt_sql  = ' OR ' if @contact_type;
 845         $hnt_sql .= ' cust_contact.classnum IS NULL ';
 846       }
 847
 848       $contact_type_sql =
 849         " AND ( ".
 850         join(' OR ', map(" cust_contact.classnum = $_ ", @contact_type)).
 851         $hnt_sql.
 852         " ) ";
 853     }
 854     push @where,
 855       "EXISTS ( SELECT 1 FROM contact_email
 856                 JOIN cust_contact USING (contactnum)
 857                 WHERE cust_contact.custnum = cust_main.custnum
 858                 $email_dest_sql
 859                 $contact_type_sql
 860               ) ";
 861   }
 862
 863   ##
 864   # "with postal mail invoices" checkbox
 865   ##
 866
 867   push @where, "cust_main.postal_invoice = 'Y'"
 868     if $params->{'POST'};
 869
 870   ##
 871   # "without postal mail invoices" checkbox
 872   ##
 873
 874   push @where, "cust_main.postal_invoice IS NULL"
 875     if $params->{'no_POST'};
 876
 877   ##
 878   # "tax exempt" checkbox
 879   ##
 880   push @where, "cust_main.tax = 'Y'"
 881     if $params->{'tax'};
 882
 883   ##
 884   # "not tax exempt" checkbox
 885   ##
 886   push @where, "(cust_main.tax = '' OR cust_main.tax IS NULL )"
 887     if $params->{'no_tax'};
 888
 889   ##
 890   # with referrals
 891   ##
 892   if ( $params->{with_referrals} =~ /^\s*(\d+)\s*$/ ) {
 893
 894     my $n = $1;
 895
 896     # referral status
 897     my $and_status = '';
 898     if ( grep { $params->{referral_status} eq $_ } FS::cust_main->statuses() ) {
 899       my $method = $params->{referral_status}. '_sql';
 900       $and_status = ' AND '. FS::cust_main->$method();
 901       $and_status =~ s/ cust_main\./ referred_cust_main./g;
 902     }
 903
 904     push @where,
 905       " $n <= ( SELECT COUNT(*) FROM cust_main AS referred_cust_main
 906                   WHERE cust_main.custnum = referred_cust_main.referral_custnum
 907                     $and_status
 908               )";
 909
 910   }
 911
 912   ##
 913   # dates
 914   ##
 915
 916   foreach my $field (qw( signupdate birthdate spouse_birthdate anniversary_date )) {
 917
 918     next unless exists($params->{$field});
 919
 920     my($beginning, $ending, $hour) = @{$params->{$field}};
 921
 922     push @where,
 923       "cust_main.$field IS NOT NULL",
 924       "cust_main.$field >= $beginning",
 925       "cust_main.$field <= $ending";
 926
 927     if($field eq 'signupdate' && defined $hour) {
 928       if ($dbh->{Driver}->{Name} =~ /Pg/i) {
 929         push @where, "extract(hour from to_timestamp(cust_main.$field)) = $hour";
 930       }
 931       elsif( $dbh->{Driver}->{Name} =~ /mysql/i) {
 932         push @where, "hour(from_unixtime(cust_main.$field)) = $hour"
 933       }
 934       else {
 935         warn "search by time of day not supported on ".$dbh->{Driver}->{Name}." databases";
 936       }
 937     }
 938
 939     $orderby ||= "ORDER BY cust_main.$field";
 940
 941   }
 942
 943   ###
 944   # classnum
 945   ###
 946
 947   if ( $params->{'classnum'} ) {
 948
 949     my @classnum = ref( $params->{'classnum'} )
 950                      ? @{ $params->{'classnum'} }
 951                      :  ( $params->{'classnum'} );
 952
 953     @classnum = grep /^(\d*)$/, @classnum;
 954
 955     if ( @classnum ) {
 956       push @where, '( '. join(' OR ', map {
 957                                             $_ ? "cust_main.classnum = $_"
 958                                                : "cust_main.classnum IS NULL"
 959                                           }
 960                                           @classnum
 961                              ).
 962                    ' )';
 963     }
 964
 965   }
 966
 967   ###
 968   # invoice terms
 969   ###
 970
 971   if ( $params->{'invoice_terms'} =~ /^([\w ]+)$/ ) {
 972     my $terms = $1;
 973     if ( $1 eq 'NULL' ) {
 974       push @where,
 975         "( cust_main.invoice_terms IS NULL OR cust_main.invoice_terms = '' )";
 976     } else {
 977       push @where,
 978         "cust_main.invoice_terms IS NOT NULL",
 979         "cust_main.invoice_terms = '$1'";
 980     }
 981   }
 982
 983   ##
 984   # amounts
 985   ##
 986
 987   if ( $params->{'current_balance'} ) {
 988
 989     #my $balance_sql = $class->balance_sql();
 990     my $balance_sql = FS::cust_main->balance_sql();
 991
 992     my @current_balance =
 993       ref( $params->{'current_balance'} )
 994       ? @{ $params->{'current_balance'} }
 995       :  ( $params->{'current_balance'} );
 996
 997     push @where, map { s/current_balance/$balance_sql/; $_ }
 998                      @current_balance;
 999
1000   }
1001
1002   ##
1003   # custbatch
1004   ##
1005
1006   if ( $params->{'custbatch'} =~ /^([\w\/\-\:\.]+)$/ and $1 ) {
1007     push @where,
1008       "cust_main.custbatch = '$1'";
1009   }
1010
1011   if ( $params->{'tagnum'} ) {
1012     my @tagnums = ref( $params->{'tagnum'} ) ? @{ $params->{'tagnum'} } : ( $params->{'tagnum'} );
1013
1014     @tagnums = grep /^(\d+)$/, @tagnums;
1015
1016     if ( @tagnums ) {
1017       if ( $params->{'all_tags'} ) {
1018         foreach ( @tagnums ) {
1019           push @where, 'exists(select 1 from cust_tag where '.
1020                        'cust_tag.custnum = cust_main.custnum and tagnum = '.
1021                        $_ . ')';
1022         }
1023       } else { # matching any tag, not all
1024         my $tags_where = "0 < (select count(1) from cust_tag where "
1025                 . " cust_tag.custnum = cust_main.custnum and tagnum in ("
1026                 . join(',', @tagnums) . "))";
1027
1028         push @where, $tags_where;
1029       }
1030     }
1031   }
1032
1033   # pkg_classnum
1034   #   all_pkg_classnums
1035   #   any_pkg_status
1036   if ( $params->{'pkg_classnum'} ) {
1037     my @pkg_classnums = ref( $params->{'pkg_classnum'} ) ?
1038                           @{ $params->{'pkg_classnum'} } :
1039                              $params->{'pkg_classnum'};
1040     @pkg_classnums = grep /^(\d+)$/, @pkg_classnums;
1041
1042     if ( @pkg_classnums ) {
1043
1044       my @pkg_where;
1045       if ( $params->{'all_pkg_classnums'} ) {
1046         push @pkg_where, "part_pkg.classnum = $_" foreach @pkg_classnums;
1047       } else {
1048         push @pkg_where,
1049           'part_pkg.classnum IN('. join(',', @pkg_classnums).')';
1050       }
1051       foreach (@pkg_where) {
1052         my $select_pkg =
1053           "SELECT 1 FROM cust_pkg JOIN part_pkg USING (pkgpart) WHERE ".
1054           "cust_pkg.custnum = cust_main.custnum AND $_ ";
1055         if ( not $params->{'any_pkg_status'} ) {
1056           $select_pkg .= 'AND '.FS::cust_pkg->active_sql;
1057         }
1058         push @where, "EXISTS($select_pkg)";
1059       }
1060     }
1061   }
1062
1063   ##
1064   # setup queries, subs, etc. for the search
1065   ##
1066
1067   $orderby ||= 'ORDER BY custnum';
1068
1069   # here is the agent virtualization
1070   push @where,
1071     $FS::CurrentUser::CurrentUser->agentnums_sql(table => 'cust_main');
1072
1073   my $extra_sql = scalar(@where) ? ' WHERE '. join(' AND ', @where) : '';
1074
1075   my $addl_from = '';
1076   # always make address fields available in results
1077   for my $pre ('bill_', 'ship_') {
1078     $addl_from .=
1079       'LEFT JOIN cust_location AS '.$pre.'location '.
1080       'ON (cust_main.'.$pre.'locationnum = '.$pre.'location.locationnum) ';
1081   }
1082
1083   # always make referral available in results
1084   #   (maybe we should be using FS::UI::Web::join_cust_main instead?)
1085   $addl_from .= ' LEFT JOIN (select refnum, referral from part_referral) AS part_referral_x ON (cust_main.refnum = part_referral_x.refnum) ';
1086
1087   my $count_query = "SELECT COUNT(*) FROM cust_main $addl_from $extra_sql";
1088
1089   my @select = (
1090                  'cust_main.custnum',
1091                  'cust_main.salesnum',
1092                  # there's a good chance that we'll need these
1093                  'cust_main.bill_locationnum',
1094                  'cust_main.ship_locationnum',
1095                  FS::UI::Web::cust_sql_fields($params->{'cust_fields'}),
1096                );
1097
1098   my @extra_headers     = ();
1099   my @extra_fields      = ();
1100   my @extra_sort_fields = ();
1101
1102   ## search contacts
1103   if ($params->{'contacts'}) {
1104     my $contact_params = $params->{'contacts'};
1105
1106     $addl_from .=
1107       ' LEFT JOIN cust_contact ON ( cust_main.custnum = cust_contact.custnum ) ';
1108
1109     if ($contact_params->{'contacts_firstname'} || $contact_params->{'contacts_lastname'}) {
1110       $addl_from .= ' LEFT JOIN contact ON ( cust_contact.contactnum = contact.contactnum ) ';
1111       my $first_query = " AND contact.first = '" . $contact_params->{'contacts_firstname'} . "'"
1112         unless !$contact_params->{'contacts_firstname'};
1113       my $last_query = " AND contact.last = '" . $contact_params->{'contacts_lastname'} . "'"
1114         unless !$contact_params->{'contacts_lastname'};
1115       $extra_sql .= " AND ( '1' $first_query $last_query )";
1116     }
1117
1118     if ($contact_params->{'contacts_email'}) {
1119       $addl_from .= ' LEFT JOIN contact_email ON ( cust_contact.contactnum = contact_email.contactnum ) ';
1120       $extra_sql .= " AND ( contact_email.emailaddress = '" . $contact_params->{'contacts_email'} . "' )";
1121     }
1122
1123     if ($contact_params->{'contacts_homephone'} || $contact_params->{'contacts_workphone'} || $contact_params->{'contacts_mobilephone'}) {
1124       $addl_from .= ' LEFT JOIN contact_phone ON ( cust_contact.contactnum = contact_phone.contactnum ) ';
1125       my $contacts_mobilephone;
1126       foreach my $phone (qw( contacts_homephone contacts_workphone contacts_mobilephone )) {
1127         (my $num = $contact_params->{$phone}) =~ s/\W//g;
1128         if ( $num =~ /^1?(\d{3})(\d{3})(\d{4})(\d*)$/ ) { $contact_params->{$phone} = "$1$2$3"; }
1129       }
1130       my $home_query = " AND ( contact_phone.phonetypenum = '2' AND contact_phone.phonenum = '" . $contact_params->{'contacts_homephone'} . "' )"
1131         unless !$contact_params->{'contacts_homephone'};
1132       my $work_query = " AND ( contact_phone.phonetypenum = '1' AND contact_phone.phonenum = '" . $contact_params->{'contacts_workphone'} . "' )"
1133         unless !$contact_params->{'contacts_workphone'};
1134       my $mobile_query = " AND ( contact_phone.phonetypenum = '3' AND contact_phone.phonenum = '" . $contact_params->{'contacts_mobilephone'} . "' )"
1135         unless !$contact_params->{'contacts_mobilephone'};
1136       $extra_sql .= " AND ( '1' $home_query $work_query $mobile_query )";
1137     }
1138
1139   }
1140
1141   if ($params->{'flattened_pkgs'}) {
1142
1143     #my $pkg_join = '';
1144     $addl_from .=
1145       ' LEFT JOIN cust_pkg ON ( cust_main.custnum = cust_pkg.custnum ) ';
1146
1147     if ($dbh->{Driver}->{Name} eq 'Pg') {
1148
1149       push @select, "
1150         ARRAY_TO_STRING(
1151           ARRAY(
1152             SELECT pkg FROM cust_pkg LEFT JOIN part_pkg USING ( pkgpart )
1153               WHERE cust_main.custnum = cust_pkg.custnum $pkgwhere
1154           ), '|'
1155         ) AS magic
1156       ";
1157
1158     } elsif ($dbh->{Driver}->{Name} =~ /^mysql/i) {
1159       push @select, "GROUP_CONCAT(part_pkg.pkg SEPARATOR '|') as magic";
1160       $addl_from .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1161       #$pkg_join  .= ' LEFT JOIN part_pkg USING ( pkgpart ) ';
1162     } else {
1163       warn "warning: unknown database type ". $dbh->{Driver}->{Name}.
1164            "omitting package information from report.";
1165     }
1166
1167     my $header_query = "
1168       SELECT COUNT(cust_pkg.custnum = cust_main.custnum) AS count
1169         FROM cust_main $addl_from $extra_sql $pkgwhere
1170           GROUP BY cust_main.custnum ORDER BY count DESC LIMIT 1
1171     ";
1172
1173     my $sth = dbh->prepare($header_query) or die dbh->errstr;
1174     $sth->execute() or die $sth->errstr;
1175     my $headerrow = $sth->fetchrow_arrayref;
1176     my $headercount = $headerrow ? $headerrow->[0] : 0;
1177     while($headercount) {
1178       unshift @extra_headers, "Package ". $headercount;
1179       unshift @extra_fields, eval q!sub {my $c = shift;
1180                                          my @a = split '\|', $c->magic;
1181                                          my $p = $a[!.--$headercount. q!];
1182                                          $p;
1183                                         };!;
1184       unshift @extra_sort_fields, '';
1185     }
1186
1187   }
1188
1189   if ( $params->{'with_referrals'} ) {
1190
1191     #XXX next: num for each customer status
1192
1193     push @select,
1194       '( SELECT COUNT(*) FROM cust_main AS referred_cust_main
1195            WHERE cust_main.custnum = referred_cust_main.referral_custnum
1196        ) AS num_referrals';
1197
1198     unshift @extra_headers, 'Referrals';
1199     unshift @extra_fields, 'num_referrals';
1200     unshift @extra_sort_fields, 'num_referrals';
1201
1202   }
1203
1204   my $select = join(', ', @select);
1205
1206   my $sql_query = {
1207     'table'             => 'cust_main',
1208     'select'            => $select,
1209     'addl_from'         => $addl_from,
1210     'hashref'           => {},
1211     'extra_sql'         => $extra_sql,
1212     'order_by'          => $orderby,
1213     'count_query'       => $count_query,
1214     'extra_headers'     => \@extra_headers,
1215     'extra_fields'      => \@extra_fields,
1216     'extra_sort_fields' => \@extra_sort_fields,
1217   };
1218   $sql_query;
1219
1220 }
1221
1222 =item fuzzy_search FUZZY_HASHREF [ OPTS ]
1223
1224 Performs a fuzzy (approximate) search and returns the matching FS::cust_main
1225 records.  Currently, I<first>, I<last>, I<company> and/or I<address1> may be
1226 specified.
1227
1228 Additional options are the same as FS::Record::qsearch
1229
1230 =cut
1231
1232 sub fuzzy_search {
1233   my $self = shift;
1234   my $fuzzy = shift;
1235   # sensible defaults, then merge in any passed options
1236   my %fuzopts = (
1237     'table'     => 'cust_main',
1238     'addl_from' => '',
1239     'extra_sql' => '',
1240     'hashref'   => {},
1241     @_
1242   );
1243
1244   my @cust_main = ();
1245
1246   my @fuzzy_mod = 'i';
1247   my $conf = new FS::Conf;
1248   my $fuzziness = $conf->config('fuzzy-fuzziness');
1249   push @fuzzy_mod, $fuzziness if $fuzziness;
1250
1251   check_and_rebuild_fuzzyfiles();
1252   foreach my $field ( keys %$fuzzy ) {
1253
1254     my $all = $self->all_X($field);
1255     next unless scalar(@$all);
1256
1257     my %match = ();
1258     $match{$_}=1 foreach ( amatch( $fuzzy->{$field}, \@fuzzy_mod, @$all ) );
1259     next if !keys(%match);
1260
1261     my $in_matches = 'IN (' .
1262                      join(',', map { dbh->quote($_) } keys %match) .
1263                      ')';
1264
1265     my $extra_sql = $fuzopts{extra_sql};
1266     if ($extra_sql =~ /^\s*where /i or keys %{ $fuzopts{hashref} }) {
1267       $extra_sql .= ' AND ';
1268     } else {
1269       $extra_sql .= 'WHERE ';
1270     }
1271     $extra_sql .= "$field $in_matches";
1272
1273     my $addl_from = $fuzopts{addl_from};
1274     if ( $field =~ /^cust_location\./ ) {
1275       $addl_from .= ' JOIN cust_location USING (custnum)';
1276     } elsif ( $field =~ /^contact\./ ) {
1277       $addl_from .= ' JOIN contact USING (custnum)';
1278     }
1279
1280     push @cust_main, qsearch({
1281       %fuzopts,
1282       'addl_from' => $addl_from,
1283       'extra_sql' => $extra_sql,
1284     });
1285   }
1286
1287   # we want the components of $fuzzy ANDed, not ORed, but still don't want dupes
1288   my %saw = ();
1289   @cust_main = grep { ++$saw{$_->custnum} == scalar(keys %$fuzzy) } @cust_main;
1290
1291   @cust_main;
1292
1293 }
1294
1295 =back
1296
1297 =head1 UTILITY SUBROUTINES
1298
1299 =over 4
1300
1301 =item check_and_rebuild_fuzzyfiles
1302
1303 =cut
1304
1305 sub check_and_rebuild_fuzzyfiles {
1306   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1307   rebuild_fuzzyfiles()
1308     if grep { ! -e "$dir/$_" }
1309          map {
1310                my ($field, $table) = reverse split('\.', $_);
1311                $table ||= 'cust_main';
1312                "$table.$field"
1313              }
1314            @fuzzyfields;
1315 }
1316
1317 =item rebuild_fuzzyfiles
1318
1319 =cut
1320
1321 sub rebuild_fuzzyfiles {
1322
1323   use Fcntl qw(:flock);
1324
1325   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1326   mkdir $dir, 0700 unless -d $dir;
1327
1328   foreach my $fuzzy ( @fuzzyfields ) {
1329
1330     my ($field, $table) = reverse split('\.', $fuzzy);
1331     $table ||= 'cust_main';
1332
1333     open(LOCK,">>$dir/$table.$field")
1334       or die "can't open $dir/$table.$field: $!";
1335     flock(LOCK,LOCK_EX)
1336       or die "can't lock $dir/$table.$field: $!";
1337
1338     open (CACHE, '>:encoding(UTF-8)', "$dir/$table.$field.tmp")
1339       or die "can't open $dir/$table.$field.tmp: $!";
1340
1341     my $sth = dbh->prepare(
1342       "SELECT $field FROM $table WHERE $field IS NOT NULL AND $field != ''"
1343     );
1344     $sth->execute or die $sth->errstr;
1345
1346     while ( my $row = $sth->fetchrow_arrayref ) {
1347       print CACHE $row->[0]. "\n";
1348     }
1349
1350     close CACHE or die "can't close $dir/$table.$field.tmp: $!";
1351
1352     rename "$dir/$table.$field.tmp", "$dir/$table.$field";
1353     close LOCK;
1354   }
1355
1356 }
1357
1358 =item append_fuzzyfiles FIRSTNAME LASTNAME COMPANY ADDRESS1
1359
1360 =cut
1361
1362 sub append_fuzzyfiles {
1363   #my( $first, $last, $company ) = @_;
1364
1365   check_and_rebuild_fuzzyfiles();
1366
1367   #foreach my $fuzzy (@fuzzyfields) {
1368   foreach my $fuzzy ( 'cust_main.first', 'cust_main.last', 'cust_main.company',
1369                       'cust_location.address1',
1370                       'cust_main.ship_company',
1371                     ) {
1372
1373     append_fuzzyfiles_fuzzyfield($fuzzy, shift);
1374
1375   }
1376
1377   1;
1378 }
1379
1380 =item append_fuzzyfiles_fuzzyfield COLUMN VALUE
1381
1382 =item append_fuzzyfiles_fuzzyfield TABLE.COLUMN VALUE
1383
1384 =cut
1385
1386 use Fcntl qw(:flock);
1387 sub append_fuzzyfiles_fuzzyfield {
1388   my( $fuzzyfield, $value ) = @_;
1389
1390   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1391
1392
1393   my ($field, $table) = reverse split('\.', $fuzzyfield);
1394   $table ||= 'cust_main';
1395
1396   return unless defined($value) && length($value);
1397
1398   open(CACHE, '>>:encoding(UTF-8)', "$dir/$table.$field" )
1399     or die "can't open $dir/$table.$field: $!";
1400   flock(CACHE,LOCK_EX)
1401     or die "can't lock $dir/$table.$field: $!";
1402
1403   print CACHE "$value\n";
1404
1405   flock(CACHE,LOCK_UN)
1406     or die "can't unlock $dir/$table.$field: $!";
1407   close CACHE;
1408
1409 }
1410
1411 =item all_X
1412
1413 =cut
1414
1415 sub all_X {
1416   my( $self, $fuzzy ) = @_;
1417   my ($field, $table) = reverse split('\.', $fuzzy);
1418   $table ||= 'cust_main';
1419
1420   my $dir = $FS::UID::conf_dir. "/cache.". $FS::UID::datasrc;
1421   open(CACHE, '<:encoding(UTF-8)', "$dir/$table.$field")
1422     or die "can't open $dir/$table.$field: $!";
1423   my @array = map { chomp; $_; } <CACHE>;
1424   close CACHE;
1425   \@array;
1426 }
1427
1428 =head1 BUGS
1429
1430 Bed bugs
1431
1432 =head1 SEE ALSO
1433
1434 L<FS::cust_main>, L<FS::Record>
1435
1436 =cut
1437
1438 1;