FS/FS/cust_main/Billing_Realtime.pm

   1 package FS::cust_main::Billing_Realtime;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use vars qw( $realtime_bop_decline_quiet ); #ugh
   6 use Carp;
   7 use Data::Dumper;
   8 use Business::CreditCard 0.28;
   9 use FS::UID qw( dbh );
  10 use FS::Record qw( qsearch qsearchs );
  11 use FS::Misc qw( send_email );
  12 use FS::payby;
  13 use FS::cust_pay;
  14 use FS::cust_pay_pending;
  15 use FS::cust_refund;
  16 use FS::banned_pay;
  17
  18 $realtime_bop_decline_quiet = 0;
  19
  20 # 1 is mostly method/subroutine entry and options
  21 # 2 traces progress of some operations
  22 # 3 is even more information including possibly sensitive data
  23 $DEBUG = 0;
  24 $me = '[FS::cust_main::Billing_Realtime]';
  25
  26 our $BOP_TESTING = 0;
  27 our $BOP_TESTING_SUCCESS = 1;
  28
  29 install_callback FS::UID sub {
  30   $conf = new FS::Conf;
  31   #yes, need it for stuff below (prolly should be cached)
  32 };
  33
  34 =head1 NAME
  35
  36 FS::cust_main::Billing_Realtime - Realtime billing mixin for cust_main
  37
  38 =head1 SYNOPSIS
  39
  40 =head1 DESCRIPTION
  41
  42 These methods are available on FS::cust_main objects.
  43
  44 =head1 METHODS
  45
  46 =over 4
  47
  48 =item realtime_cust_payby
  49
  50 =cut
  51
  52 sub realtime_cust_payby {
  53   my( $self, %options ) = @_;
  54
  55   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
  56
  57   $options{amount} = $self->balance unless exists( $options{amount} );
  58
  59   my @cust_payby = qsearch({
  60     'table'     => 'cust_payby',
  61     'hashref'   => { 'custnum' => $self->custnum, },
  62     'extra_sql' => " AND payby IN ( 'CARD', 'CHEK' ) ",
  63     'order_by'  => 'ORDER BY weight ASC',
  64   });
  65
  66   my $error;
  67   foreach my $cust_payby (@cust_payby) {
  68     $error = $cust_payby->realtime_bop( %options, );
  69     last unless $error;
  70   }
  71
  72   #XXX what about the earlier errors?
  73
  74   $error;
  75
  76 }
  77
  78 =item realtime_collect [ OPTION => VALUE ... ]
  79
  80 Attempt to collect the customer's current balance with a realtime credit
  81 card, electronic check, or phone bill transaction (see realtime_bop() below).
  82
  83 Returns the result of realtime_bop(): nothing, an error message, or a
  84 hashref of state information for a third-party transaction.
  85
  86 Available options are: I<method>, I<amount>, I<description>, I<invnum>, I<quiet>, I<paynum_ref>, I<payunique>, I<session_id>, I<pkgnum>
  87
  88 I<method> is one of: I<CC>, I<ECHECK> and I<LEC>.  If none is specified
  89 then it is deduced from the customer record.
  90
  91 If no I<amount> is specified, then the customer balance is used.
  92
  93 The additional options I<payname>, I<address1>, I<address2>, I<city>, I<state>,
  94 I<zip>, I<payinfo> and I<paydate> are also available.  Any of these options,
  95 if set, will override the value from the customer record.
  96
  97 I<description> is a free-text field passed to the gateway.  It defaults to
  98 the value defined by the business-onlinepayment-description configuration
  99 option, or "Internet services" if that is unset.
 100
 101 If an I<invnum> is specified, this payment (if successful) is applied to the
 102 specified invoice.
 103
 104 I<apply> will automatically apply a resulting payment.
 105
 106 I<quiet> can be set true to suppress email decline notices.
 107
 108 I<paynum_ref> can be set to a scalar reference.  It will be filled in with the
 109 resulting paynum, if any.
 110
 111 I<payunique> is a unique identifier for this payment.
 112
 113 I<session_id> is a session identifier associated with this payment.
 114
 115 I<depend_jobnum> allows payment capture to unlock export jobs
 116
 117 =cut
 118
 119 sub realtime_collect {
 120   my( $self, %options ) = @_;
 121
 122   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 123
 124   if ( $DEBUG ) {
 125     warn "$me realtime_collect:\n";
 126     warn "  $_ => $options{$_}\n" foreach keys %options;
 127   }
 128
 129   $options{amount} = $self->balance unless exists( $options{amount} );
 130   $options{method} = FS::payby->payby2bop($self->payby)
 131     unless exists( $options{method} );
 132
 133   return $self->realtime_bop({%options});
 134
 135 }
 136
 137 =item realtime_bop { [ ARG => VALUE ... ] }
 138
 139 Runs a realtime credit card, ACH (electronic check) or phone bill transaction
 140 via a Business::OnlinePayment realtime gateway.  See
 141 L<http://420.am/business-onlinepayment> for supported gateways.
 142
 143 Required arguments in the hashref are I<method>, and I<amount>
 144
 145 Available methods are: I<CC>, I<ECHECK>, I<LEC>, and I<PAYPAL>
 146
 147 Available optional arguments are: I<description>, I<invnum>, I<apply>, I<quiet>, I<paynum_ref>, I<payunique>, I<session_id>
 148
 149 The additional options I<payname>, I<address1>, I<address2>, I<city>, I<state>,
 150 I<zip>, I<payinfo> and I<paydate> are also available.  Any of these options,
 151 if set, will override the value from the customer record.
 152
 153 I<description> is a free-text field passed to the gateway.  It defaults to
 154 the value defined by the business-onlinepayment-description configuration
 155 option, or "Internet services" if that is unset.
 156
 157 If an I<invnum> is specified, this payment (if successful) is applied to the
 158 specified invoice.  If the customer has exactly one open invoice, that
 159 invoice number will be assumed.  If you don't specify an I<invnum> you might
 160 want to call the B<apply_payments> method or set the I<apply> option.
 161
 162 I<apply> can be set to true to apply a resulting payment.
 163
 164 I<quiet> can be set true to surpress email decline notices.
 165
 166 I<paynum_ref> can be set to a scalar reference.  It will be filled in with the
 167 resulting paynum, if any.
 168
 169 I<payunique> is a unique identifier for this payment.
 170
 171 I<session_id> is a session identifier associated with this payment.
 172
 173 I<depend_jobnum> allows payment capture to unlock export jobs
 174
 175 I<discount_term> attempts to take a discount by prepaying for discount_term.
 176 The payment will fail if I<amount> is incorrect for this discount term.
 177
 178 A direct (Business::OnlinePayment) transaction will return nothing on success,
 179 or an error message on failure.
 180
 181 A third-party transaction will return a hashref containing:
 182
 183 - popup_url: the URL to which a browser should be redirected to complete
 184   the transaction.
 185 - collectitems: an arrayref of name-value pairs to be posted to popup_url.
 186 - reference: a reference ID for the transaction, to show the customer.
 187
 188 (moved from cust_bill) (probably should get realtime_{card,ach,lec} here too)
 189
 190 =cut
 191
 192 # some helper routines
 193 sub _bop_recurring_billing {
 194   my( $self, %opt ) = @_;
 195
 196   my $method = scalar($conf->config('credit_card-recurring_billing_flag'));
 197
 198   if ( defined($method) && $method eq 'transaction_is_recur' ) {
 199
 200     return 1 if $opt{'trans_is_recur'};
 201
 202   } else {
 203
 204     # return 1 if the payinfo has been used for another payment
 205     return $self->payinfo_used($opt{'payinfo'}); # in payinfo_Mixin
 206
 207   }
 208
 209   return 0;
 210
 211 }
 212
 213 sub _payment_gateway {
 214   my ($self, $options) = @_;
 215
 216   if ( $options->{'selfservice'} ) {
 217     my $gatewaynum = FS::Conf->new->config('selfservice-payment_gateway');
 218     if ( $gatewaynum ) {
 219       return $options->{payment_gateway} ||=
 220           qsearchs('payment_gateway', { gatewaynum => $gatewaynum });
 221     }
 222   }
 223
 224   if ( $options->{'fake_gatewaynum'} ) {
 225         $options->{payment_gateway} =
 226             qsearchs('payment_gateway',
 227                       { 'gatewaynum' => $options->{'fake_gatewaynum'}, }
 228                     );
 229   }
 230
 231   $options->{payment_gateway} = $self->agent->payment_gateway( %$options )
 232     unless exists($options->{payment_gateway});
 233
 234   $options->{payment_gateway};
 235 }
 236
 237 sub _bop_auth {
 238   my ($self, $options) = @_;
 239
 240   (
 241     'login'    => $options->{payment_gateway}->gateway_username,
 242     'password' => $options->{payment_gateway}->gateway_password,
 243   );
 244 }
 245
 246 sub _bop_options {
 247   my ($self, $options) = @_;
 248
 249   $options->{payment_gateway}->gatewaynum
 250     ? $options->{payment_gateway}->options
 251     : @{ $options->{payment_gateway}->get('options') };
 252
 253 }
 254
 255 sub _bop_defaults {
 256   my ($self, $options) = @_;
 257
 258   unless ( $options->{'description'} ) {
 259     if ( $conf->exists('business-onlinepayment-description') ) {
 260       my $dtempl = $conf->config('business-onlinepayment-description');
 261
 262       my $agent = $self->agent->agent;
 263       #$pkgs... not here
 264       $options->{'description'} = eval qq("$dtempl");
 265     } else {
 266       $options->{'description'} = 'Internet services';
 267     }
 268   }
 269
 270   $options->{payinfo} = $self->payinfo unless exists( $options->{payinfo} );
 271
 272   # Default invoice number if the customer has exactly one open invoice.
 273   if( ! $options->{'invnum'} ) {
 274     $options->{'invnum'} = '';
 275     my @open = $self->open_cust_bill;
 276     $options->{'invnum'} = $open[0]->invnum if scalar(@open) == 1;
 277   }
 278
 279   $options->{payname} = $self->payname unless exists( $options->{payname} );
 280 }
 281
 282 sub _bop_content {
 283   my ($self, $options) = @_;
 284   my %content = ();
 285
 286   my $payip = exists($options->{'payip'}) ? $options->{'payip'} : $self->payip;
 287   $content{customer_ip} = $payip if length($payip);
 288
 289   $content{invoice_number} = $options->{'invnum'}
 290     if exists($options->{'invnum'}) && length($options->{'invnum'});
 291
 292   $content{email_customer} =
 293     (    $conf->exists('business-onlinepayment-email_customer')
 294       || $conf->exists('business-onlinepayment-email-override') );
 295
 296   my ($payname, $payfirst, $paylast);
 297   if ( $options->{payname} && $options->{method} ne 'ECHECK' ) {
 298     ($payname = $options->{payname}) =~
 299       /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)\s*$/
 300       or return "Illegal payname $payname";
 301     ($payfirst, $paylast) = ($1, $2);
 302   } else {
 303     $payfirst = $self->getfield('first');
 304     $paylast = $self->getfield('last');
 305     $payname = "$payfirst $paylast";
 306   }
 307
 308   $content{last_name} = $paylast;
 309   $content{first_name} = $payfirst;
 310
 311   $content{name} = $payname;
 312
 313   $content{address} = exists($options->{'address1'})
 314                         ? $options->{'address1'}
 315                         : $self->address1;
 316   my $address2 = exists($options->{'address2'})
 317                    ? $options->{'address2'}
 318                    : $self->address2;
 319   $content{address} .= ", ". $address2 if length($address2);
 320
 321   $content{city} = exists($options->{city})
 322                      ? $options->{city}
 323                      : $self->city;
 324   $content{state} = exists($options->{state})
 325                       ? $options->{state}
 326                       : $self->state;
 327   $content{zip} = exists($options->{zip})
 328                     ? $options->{'zip'}
 329                     : $self->zip;
 330   $content{country} = exists($options->{country})
 331                         ? $options->{country}
 332                         : $self->country;
 333
 334   $content{phone} = $self->daytime || $self->night;
 335
 336   my $currency =    $conf->exists('business-onlinepayment-currency')
 337                  && $conf->config('business-onlinepayment-currency');
 338   $content{currency} = $currency if $currency;
 339
 340   \%content;
 341 }
 342
 343 my %bop_method2payby = (
 344   'CC'     => 'CARD',
 345   'ECHECK' => 'CHEK',
 346   'LEC'    => 'LECB',
 347   'PAYPAL' => 'PPAL',
 348 );
 349
 350 sub realtime_bop {
 351   my $self = shift;
 352
 353   confess "Can't call realtime_bop within another transaction ".
 354           '($FS::UID::AutoCommit is false)'
 355     unless $FS::UID::AutoCommit;
 356
 357   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 358
 359   my %options = ();
 360   if (ref($_[0]) eq 'HASH') {
 361     %options = %{$_[0]};
 362   } else {
 363     my ( $method, $amount ) = ( shift, shift );
 364     %options = @_;
 365     $options{method} = $method;
 366     $options{amount} = $amount;
 367   }
 368
 369
 370   ###
 371   # optional credit card surcharge
 372   ###
 373
 374   my $cc_surcharge = 0;
 375   my $cc_surcharge_pct = 0;
 376   $cc_surcharge_pct = $conf->config('credit-card-surcharge-percentage')
 377     if $conf->config('credit-card-surcharge-percentage')
 378     && $options{method} eq 'CC';
 379
 380   # always add cc surcharge if called from event
 381   if($options{'cc_surcharge_from_event'} && $cc_surcharge_pct > 0) {
 382       $cc_surcharge = $options{'amount'} * $cc_surcharge_pct / 100;
 383       $options{'amount'} += $cc_surcharge;
 384       $options{'amount'} = sprintf("%.2f", $options{'amount'}); # round (again)?
 385   }
 386   elsif($cc_surcharge_pct > 0) { # we're called not from event (i.e. from a
 387                                  # payment screen), so consider the given
 388                                  # amount as post-surcharge
 389     $cc_surcharge = $options{'amount'} - ($options{'amount'} / ( 1 + $cc_surcharge_pct/100 ));
 390   }
 391
 392   $cc_surcharge = sprintf("%.2f",$cc_surcharge) if $cc_surcharge > 0;
 393   $options{'cc_surcharge'} = $cc_surcharge;
 394
 395
 396   if ( $DEBUG ) {
 397     warn "$me realtime_bop (new): $options{method} $options{amount}\n";
 398     warn " cc_surcharge = $cc_surcharge\n";
 399   }
 400   if ( $DEBUG > 2 ) {
 401     warn "  $_ => $options{$_}\n" foreach keys %options;
 402   }
 403
 404   return $self->fake_bop(\%options) if $options{'fake'};
 405
 406   $self->_bop_defaults(\%options);
 407
 408   ###
 409   # set trans_is_recur based on invnum if there is one
 410   ###
 411
 412   my $trans_is_recur = 0;
 413   if ( $options{'invnum'} ) {
 414
 415     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $options{'invnum'} } );
 416     die "invnum ". $options{'invnum'}. " not found" unless $cust_bill;
 417
 418     my @part_pkg =
 419       map  { $_->part_pkg }
 420       grep { $_ }
 421       map  { $_->cust_pkg }
 422       $cust_bill->cust_bill_pkg;
 423
 424     $trans_is_recur = 1
 425       if grep { $_->freq ne '0' } @part_pkg;
 426
 427   }
 428
 429   ###
 430   # select a gateway
 431   ###
 432
 433   my $payment_gateway =  $self->_payment_gateway( \%options );
 434   my $namespace = $payment_gateway->gateway_namespace;
 435
 436   eval "use $namespace";
 437   die $@ if $@;
 438
 439   ###
 440   # check for banned credit card/ACH
 441   ###
 442
 443   my $ban = FS::banned_pay->ban_search(
 444     'payby'   => $bop_method2payby{$options{method}},
 445     'payinfo' => $options{payinfo},
 446   );
 447   return "Banned credit card" if $ban && $ban->bantype ne 'warn';
 448
 449   ###
 450   # check for term discount validity
 451   ###
 452
 453   my $discount_term = $options{discount_term};
 454   if ( $discount_term ) {
 455     my $bill = ($self->cust_bill)[-1]
 456       or return "Can't apply a term discount to an unbilled customer";
 457     my $plan = FS::discount_plan->new(
 458       cust_bill => $bill,
 459       months    => $discount_term
 460     ) or return "No discount available for term '$discount_term'";
 461
 462     if ( $plan->discounted_total != $options{amount} ) {
 463       return "Incorrect term prepayment amount (term $discount_term, amount $options{amount}, requires ".$plan->discounted_total.")";
 464     }
 465   }
 466
 467   ###
 468   # massage data
 469   ###
 470
 471   my $bop_content = $self->_bop_content(\%options);
 472   return $bop_content unless ref($bop_content);
 473
 474   my @invoicing_list = $self->invoicing_list_emailonly;
 475   if ( $conf->exists('emailinvoiceautoalways')
 476        || $conf->exists('emailinvoiceauto') && ! @invoicing_list
 477        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
 478     push @invoicing_list, $self->all_emails;
 479   }
 480
 481   my $email = ($conf->exists('business-onlinepayment-email-override'))
 482               ? $conf->config('business-onlinepayment-email-override')
 483               : $invoicing_list[0];
 484
 485   my $paydate = '';
 486   my %content = ();
 487
 488   if ( $namespace eq 'Business::OnlinePayment' ) {
 489
 490     if ( $options{method} eq 'CC' ) {
 491
 492       $content{card_number} = $options{payinfo};
 493       $paydate = exists($options{'paydate'})
 494                       ? $options{'paydate'}
 495                       : $self->paydate;
 496       $paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
 497       $content{expiration} = "$2/$1";
 498
 499       my $paycvv = exists($options{'paycvv'})
 500                      ? $options{'paycvv'}
 501                      : $self->paycvv;
 502       $content{cvv2} = $paycvv
 503         if length($paycvv);
 504
 505       my $paystart_month = exists($options{'paystart_month'})
 506                              ? $options{'paystart_month'}
 507                              : $self->paystart_month;
 508
 509       my $paystart_year  = exists($options{'paystart_year'})
 510                              ? $options{'paystart_year'}
 511                              : $self->paystart_year;
 512
 513       $content{card_start} = "$paystart_month/$paystart_year"
 514         if $paystart_month && $paystart_year;
 515
 516       my $payissue       = exists($options{'payissue'})
 517                              ? $options{'payissue'}
 518                              : $self->payissue;
 519       $content{issue_number} = $payissue if $payissue;
 520
 521       if ( $self->_bop_recurring_billing(
 522              'payinfo'        => $options{'payinfo'},
 523              'trans_is_recur' => $trans_is_recur,
 524            )
 525          )
 526       {
 527         $content{recurring_billing} = 'YES';
 528         $content{acct_code} = 'rebill'
 529           if $conf->exists('credit_card-recurring_billing_acct_code');
 530       }
 531
 532     } elsif ( $options{method} eq 'ECHECK' ){
 533
 534       ( $content{account_number}, $content{routing_code} ) =
 535         split('@', $options{payinfo});
 536       $content{bank_name} = $options{payname};
 537       $content{bank_state} = exists($options{'paystate'})
 538                                ? $options{'paystate'}
 539                                : $self->getfield('paystate');
 540       $content{account_type}=
 541         (exists($options{'paytype'}) && $options{'paytype'})
 542           ? uc($options{'paytype'})
 543           : uc($self->getfield('paytype')) || 'PERSONAL CHECKING';
 544
 545       if ( $content{account_type} =~ /BUSINESS/i && $self->company ) {
 546         $content{account_name} = $self->company;
 547       } else {
 548         $content{account_name} = $self->getfield('first'). ' '.
 549                                  $self->getfield('last');
 550       }
 551
 552       $content{customer_org} = $self->company ? 'B' : 'I';
 553       $content{state_id}       = exists($options{'stateid'})
 554                                    ? $options{'stateid'}
 555                                    : $self->getfield('stateid');
 556       $content{state_id_state} = exists($options{'stateid_state'})
 557                                    ? $options{'stateid_state'}
 558                                    : $self->getfield('stateid_state');
 559       $content{customer_ssn} = exists($options{'ss'})
 560                                  ? $options{'ss'}
 561                                  : $self->ss;
 562
 563     } elsif ( $options{method} eq 'LEC' ) {
 564       $content{phone} = $options{payinfo};
 565     } else {
 566       die "unknown method ". $options{method};
 567     }
 568
 569   } elsif ( $namespace eq 'Business::OnlineThirdPartyPayment' ) {
 570     #move along
 571   } else {
 572     die "unknown namespace $namespace";
 573   }
 574
 575   ###
 576   # run transaction(s)
 577   ###
 578
 579   my $balance = exists( $options{'balance'} )
 580                   ? $options{'balance'}
 581                   : $self->balance;
 582
 583   warn "claiming mutex on customer ". $self->custnum. "\n" if $DEBUG > 1;
 584   $self->select_for_update; #mutex ... just until we get our pending record in
 585   warn "obtained mutex on customer ". $self->custnum. "\n" if $DEBUG > 1;
 586
 587   #the checks here are intended to catch concurrent payments
 588   #double-form-submission prevention is taken care of in cust_pay_pending::check
 589
 590   #check the balance
 591   return "The customer's balance has changed; $options{method} transaction aborted."
 592     if $self->balance < $balance;
 593
 594   #also check and make sure there aren't *other* pending payments for this cust
 595
 596   my @pending = qsearch('cust_pay_pending', {
 597     'custnum' => $self->custnum,
 598     'status'  => { op=>'!=', value=>'done' }
 599   });
 600
 601   #for third-party payments only, remove pending payments if they're in the
 602   #'thirdparty' (waiting for customer action) state.
 603   if ( $namespace eq 'Business::OnlineThirdPartyPayment' ) {
 604     foreach ( grep { $_->status eq 'thirdparty' } @pending ) {
 605       my $error = $_->delete;
 606       warn "error deleting unfinished third-party payment ".
 607           $_->paypendingnum . ": $error\n"
 608         if $error;
 609     }
 610     @pending = grep { $_->status ne 'thirdparty' } @pending;
 611   }
 612
 613   return "A payment is already being processed for this customer (".
 614          join(', ', map 'paypendingnum '. $_->paypendingnum, @pending ).
 615          "); $options{method} transaction aborted."
 616     if scalar(@pending);
 617
 618   #okay, good to go, if we're a duplicate, cust_pay_pending will kick us out
 619
 620   my $cust_pay_pending = new FS::cust_pay_pending {
 621     'custnum'           => $self->custnum,
 622     'paid'              => $options{amount},
 623     '_date'             => '',
 624     'payby'             => $bop_method2payby{$options{method}},
 625     'payinfo'           => $options{payinfo},
 626     'paydate'           => $paydate,
 627     'recurring_billing' => $content{recurring_billing},
 628     'pkgnum'            => $options{'pkgnum'},
 629     'status'            => 'new',
 630     'gatewaynum'        => $payment_gateway->gatewaynum || '',
 631     'session_id'        => $options{session_id} || '',
 632     'jobnum'            => $options{depend_jobnum} || '',
 633   };
 634   $cust_pay_pending->payunique( $options{payunique} )
 635     if defined($options{payunique}) && length($options{payunique});
 636
 637   warn "inserting cust_pay_pending record for customer ". $self->custnum. "\n"
 638     if $DEBUG > 1;
 639   my $cpp_new_err = $cust_pay_pending->insert; #mutex lost when this is inserted
 640   return $cpp_new_err if $cpp_new_err;
 641
 642   warn "inserted cust_pay_pending record for customer ". $self->custnum. "\n"
 643     if $DEBUG > 1;
 644   warn Dumper($cust_pay_pending) if $DEBUG > 2;
 645
 646   my( $action1, $action2 ) =
 647     split( /\s*\,\s*/, $payment_gateway->gateway_action );
 648
 649   my $transaction = new $namespace( $payment_gateway->gateway_module,
 650                                     $self->_bop_options(\%options),
 651                                   );
 652
 653   $transaction->content(
 654     'type'           => $options{method},
 655     $self->_bop_auth(\%options),
 656     'action'         => $action1,
 657     'description'    => $options{'description'},
 658     'amount'         => $options{amount},
 659     #'invoice_number' => $options{'invnum'},
 660     'customer_id'    => $self->custnum,
 661     %$bop_content,
 662     'reference'      => $cust_pay_pending->paypendingnum, #for now
 663     'callback_url'   => $payment_gateway->gateway_callback_url,
 664     'cancel_url'     => $payment_gateway->gateway_cancel_url,
 665     'email'          => $email,
 666     %content, #after
 667   );
 668
 669   $cust_pay_pending->status('pending');
 670   my $cpp_pending_err = $cust_pay_pending->replace;
 671   return $cpp_pending_err if $cpp_pending_err;
 672
 673   warn Dumper($transaction) if $DEBUG > 2;
 674
 675   unless ( $BOP_TESTING ) {
 676     $transaction->test_transaction(1)
 677       if $conf->exists('business-onlinepayment-test_transaction');
 678     $transaction->submit();
 679   } else {
 680     if ( $BOP_TESTING_SUCCESS ) {
 681       $transaction->is_success(1);
 682       $transaction->authorization('fake auth');
 683     } else {
 684       $transaction->is_success(0);
 685       $transaction->error_message('fake failure');
 686     }
 687   }
 688
 689   if ( $transaction->is_success() && $namespace eq 'Business::OnlineThirdPartyPayment' ) {
 690
 691     $cust_pay_pending->status('thirdparty');
 692     my $cpp_err = $cust_pay_pending->replace;
 693     return { error => $cpp_err } if $cpp_err;
 694     return { reference => $cust_pay_pending->paypendingnum,
 695              map { $_ => $transaction->$_ } qw ( popup_url collectitems ) };
 696
 697   } elsif ( $transaction->is_success() && $action2 ) {
 698
 699     $cust_pay_pending->status('authorized');
 700     my $cpp_authorized_err = $cust_pay_pending->replace;
 701     return $cpp_authorized_err if $cpp_authorized_err;
 702
 703     my $auth = $transaction->authorization;
 704     my $ordernum = $transaction->can('order_number')
 705                    ? $transaction->order_number
 706                    : '';
 707
 708     my $capture =
 709       new Business::OnlinePayment( $payment_gateway->gateway_module,
 710                                    $self->_bop_options(\%options),
 711                                  );
 712
 713     my %capture = (
 714       %content,
 715       type           => $options{method},
 716       action         => $action2,
 717       $self->_bop_auth(\%options),
 718       order_number   => $ordernum,
 719       amount         => $options{amount},
 720       authorization  => $auth,
 721       description    => $options{'description'},
 722     );
 723
 724     foreach my $field (qw( authorization_source_code returned_ACI
 725                            transaction_identifier validation_code
 726                            transaction_sequence_num local_transaction_date
 727                            local_transaction_time AVS_result_code          )) {
 728       $capture{$field} = $transaction->$field() if $transaction->can($field);
 729     }
 730
 731     $capture->content( %capture );
 732
 733     $capture->test_transaction(1)
 734       if $conf->exists('business-onlinepayment-test_transaction');
 735     $capture->submit();
 736
 737     unless ( $capture->is_success ) {
 738       my $e = "Authorization successful but capture failed, custnum #".
 739               $self->custnum. ': '.  $capture->result_code.
 740               ": ". $capture->error_message;
 741       warn $e;
 742       return $e;
 743     }
 744
 745   }
 746
 747   ###
 748   # remove paycvv after initial transaction
 749   ###
 750
 751   #false laziness w/misc/process/payment.cgi - check both to make sure working
 752   # correctly
 753   if ( length($self->paycvv)
 754        && ! grep { $_ eq cardtype($options{payinfo}) } $conf->config('cvv-save')
 755   ) {
 756     my $error = $self->remove_cvv;
 757     if ( $error ) {
 758       warn "WARNING: error removing cvv: $error\n";
 759     }
 760   }
 761
 762   ###
 763   # Tokenize
 764   ###
 765
 766
 767   if ( $transaction->can('card_token') && $transaction->card_token ) {
 768
 769     $self->card_token($transaction->card_token);
 770
 771     if ( $options{'payinfo'} eq $self->payinfo ) {
 772       $self->payinfo($transaction->card_token);
 773       my $error = $self->replace;
 774       if ( $error ) {
 775         warn "WARNING: error storing token: $error, but proceeding anyway\n";
 776       }
 777     }
 778
 779   }
 780
 781   ###
 782   # result handling
 783   ###
 784
 785   $self->_realtime_bop_result( $cust_pay_pending, $transaction, %options );
 786
 787 }
 788
 789 =item fake_bop
 790
 791 =cut
 792
 793 sub fake_bop {
 794   my $self = shift;
 795
 796   my %options = ();
 797   if (ref($_[0]) eq 'HASH') {
 798     %options = %{$_[0]};
 799   } else {
 800     my ( $method, $amount ) = ( shift, shift );
 801     %options = @_;
 802     $options{method} = $method;
 803     $options{amount} = $amount;
 804   }
 805
 806   if ( $options{'fake_failure'} ) {
 807      return "Error: No error; test failure requested with fake_failure";
 808   }
 809
 810   my $cust_pay = new FS::cust_pay ( {
 811      'custnum'  => $self->custnum,
 812      'invnum'   => $options{'invnum'},
 813      'paid'     => $options{amount},
 814      '_date'    => '',
 815      'payby'    => $bop_method2payby{$options{method}},
 816      #'payinfo'  => $payinfo,
 817      'payinfo'  => '4111111111111111',
 818      #'paydate'  => $paydate,
 819      'paydate'  => '2012-05-01',
 820      'processor'      => 'FakeProcessor',
 821      'auth'           => '54',
 822      'order_number'   => '32',
 823   } );
 824   $cust_pay->payunique( $options{payunique} ) if length($options{payunique});
 825
 826   if ( $DEBUG ) {
 827       warn "fake_bop\n cust_pay: ". Dumper($cust_pay) . "\n options: ";
 828       warn "  $_ => $options{$_}\n" foreach keys %options;
 829   }
 830
 831   my $error = $cust_pay->insert($options{'manual'} ? ( 'manual' => 1 ) : () );
 832
 833   if ( $error ) {
 834     $cust_pay->invnum(''); #try again with no specific invnum
 835     my $error2 = $cust_pay->insert( $options{'manual'} ?
 836                                     ( 'manual' => 1 ) : ()
 837                                   );
 838     if ( $error2 ) {
 839       # gah, even with transactions.
 840       my $e = 'WARNING: Card/ACH debited but database not updated - '.
 841               "error inserting (fake!) payment: $error2".
 842               " (previously tried insert with invnum #$options{'invnum'}" .
 843               ": $error )";
 844       warn $e;
 845       return $e;
 846     }
 847   }
 848
 849   if ( $options{'paynum_ref'} ) {
 850     ${ $options{'paynum_ref'} } = $cust_pay->paynum;
 851   }
 852
 853   return ''; #no error
 854
 855 }
 856
 857
 858 # item _realtime_bop_result CUST_PAY_PENDING, BOP_OBJECT [ OPTION => VALUE ... ]
 859 #
 860 # Wraps up processing of a realtime credit card, ACH (electronic check) or
 861 # phone bill transaction.
 862
 863 sub _realtime_bop_result {
 864   my( $self, $cust_pay_pending, $transaction, %options ) = @_;
 865
 866   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 867
 868   if ( $DEBUG ) {
 869     warn "$me _realtime_bop_result: pending transaction ".
 870       $cust_pay_pending->paypendingnum. "\n";
 871     warn "  $_ => $options{$_}\n" foreach keys %options;
 872   }
 873
 874   my $payment_gateway = $options{payment_gateway}
 875     or return "no payment gateway in arguments to _realtime_bop_result";
 876
 877   $cust_pay_pending->status($transaction->is_success() ? 'captured' : 'declined');
 878   my $cpp_captured_err = $cust_pay_pending->replace;
 879   return $cpp_captured_err if $cpp_captured_err;
 880
 881   if ( $transaction->is_success() ) {
 882
 883     my $order_number = $transaction->order_number
 884       if $transaction->can('order_number');
 885
 886     my $cust_pay = new FS::cust_pay ( {
 887        'custnum'  => $self->custnum,
 888        'invnum'   => $options{'invnum'},
 889        'paid'     => $cust_pay_pending->paid,
 890        '_date'    => '',
 891        'payby'    => $cust_pay_pending->payby,
 892        'payinfo'  => $options{'payinfo'},
 893        'paydate'  => $cust_pay_pending->paydate,
 894        'pkgnum'   => $cust_pay_pending->pkgnum,
 895        'discount_term'  => $options{'discount_term'},
 896        'gatewaynum'     => ($payment_gateway->gatewaynum || ''),
 897        'processor'      => $payment_gateway->gateway_module,
 898        'auth'           => $transaction->authorization,
 899        'order_number'   => $order_number || '',
 900
 901     } );
 902     #doesn't hurt to know, even though the dup check is in cust_pay_pending now
 903     $cust_pay->payunique( $options{payunique} )
 904       if defined($options{payunique}) && length($options{payunique});
 905
 906     my $oldAutoCommit = $FS::UID::AutoCommit;
 907     local $FS::UID::AutoCommit = 0;
 908     my $dbh = dbh;
 909
 910     #start a transaction, insert the cust_pay and set cust_pay_pending.status to done in a single transction
 911
 912     my $error = $cust_pay->insert($options{'manual'} ? ( 'manual' => 1 ) : () );
 913
 914     if ( $error ) {
 915       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 916       $cust_pay->invnum(''); #try again with no specific invnum
 917       $cust_pay->paynum('');
 918       my $error2 = $cust_pay->insert( $options{'manual'} ?
 919                                       ( 'manual' => 1 ) : ()
 920                                     );
 921       if ( $error2 ) {
 922         # gah.  but at least we have a record of the state we had to abort in
 923         # from cust_pay_pending now.
 924         $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 925         my $e = "WARNING: $options{method} captured but payment not recorded -".
 926                 " error inserting payment (". $payment_gateway->gateway_module.
 927                 "): $error2".
 928                 " (previously tried insert with invnum #$options{'invnum'}" .
 929                 ": $error ) - pending payment saved as paypendingnum ".
 930                 $cust_pay_pending->paypendingnum. "\n";
 931         warn $e;
 932         return $e;
 933       }
 934     }
 935
 936     my $jobnum = $cust_pay_pending->jobnum;
 937     if ( $jobnum ) {
 938        my $placeholder = qsearchs( 'queue', { 'jobnum' => $jobnum } );
 939
 940        unless ( $placeholder ) {
 941          $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 942          my $e = "WARNING: $options{method} captured but job $jobnum not ".
 943              "found for paypendingnum ". $cust_pay_pending->paypendingnum. "\n";
 944          warn $e;
 945          return $e;
 946        }
 947
 948        $error = $placeholder->delete;
 949
 950        if ( $error ) {
 951          $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 952          my $e = "WARNING: $options{method} captured but could not delete ".
 953               "job $jobnum for paypendingnum ".
 954               $cust_pay_pending->paypendingnum. ": $error\n";
 955          warn $e;
 956          return $e;
 957        }
 958
 959     }
 960
 961     if ( $options{'paynum_ref'} ) {
 962       ${ $options{'paynum_ref'} } = $cust_pay->paynum;
 963     }
 964
 965     $cust_pay_pending->status('done');
 966     $cust_pay_pending->statustext('captured');
 967     $cust_pay_pending->paynum($cust_pay->paynum);
 968     my $cpp_done_err = $cust_pay_pending->replace;
 969
 970     if ( $cpp_done_err ) {
 971
 972       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 973       my $e = "WARNING: $options{method} captured but payment not recorded - ".
 974               "error updating status for paypendingnum ".
 975               $cust_pay_pending->paypendingnum. ": $cpp_done_err \n";
 976       warn $e;
 977       return $e;
 978
 979     } else {
 980
 981       $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 982
 983       if ( $options{'apply'} ) {
 984         my $apply_error = $self->apply_payments_and_credits;
 985         if ( $apply_error ) {
 986           warn "WARNING: error applying payment: $apply_error\n";
 987           #but we still should return no error cause the payment otherwise went
 988           #through...
 989         }
 990       }
 991
 992       # have a CC surcharge portion --> one-time charge
 993       if ( $options{'cc_surcharge'} > 0 ) {
 994             # XXX: this whole block needs to be in a transaction?
 995
 996           my $invnum;
 997           $invnum = $options{'invnum'} if $options{'invnum'};
 998           unless ( $invnum ) { # probably from a payment screen
 999              # do we have any open invoices? pick earliest
1000              # uses the fact that cust_main->cust_bill sorts by date ascending
1001              my @open = $self->open_cust_bill;
1002              $invnum = $open[0]->invnum if scalar(@open);
1003           }
1004
1005           unless ( $invnum ) {  # still nothing? pick last closed invoice
1006              # again uses fact that cust_main->cust_bill sorts by date ascending
1007              my @closed = $self->cust_bill;
1008              $invnum = $closed[$#closed]->invnum if scalar(@closed);
1009           }
1010
1011           unless ( $invnum ) {
1012             # XXX: unlikely case - pre-paying before any invoices generated
1013             # what it should do is create a new invoice and pick it
1014                 warn 'CC SURCHARGE AND NO INVOICES PICKED TO APPLY IT!';
1015                 return '';
1016           }
1017
1018           my $cust_pkg;
1019           my $charge_error = $self->charge({
1020                                     'amount'    => $options{'cc_surcharge'},
1021                                     'pkg'       => 'Credit Card Surcharge',
1022                                     'setuptax'  => 'Y',
1023                                     'cust_pkg_ref' => \$cust_pkg,
1024                                 });
1025           if($charge_error) {
1026                 warn 'Unable to add CC surcharge cust_pkg';
1027                 return '';
1028           }
1029
1030           $cust_pkg->setup(time);
1031           my $cp_error = $cust_pkg->replace;
1032           if($cp_error) {
1033               warn 'Unable to set setup time on cust_pkg for cc surcharge';
1034             # but keep going...
1035           }
1036
1037           my $cust_bill = qsearchs('cust_bill', { 'invnum' => $invnum });
1038           unless ( $cust_bill ) {
1039               warn "race condition + invoice deletion just happened";
1040               return '';
1041           }
1042
1043           my $grand_error =
1044             $cust_bill->add_cc_surcharge($cust_pkg->pkgnum,$options{'cc_surcharge'});
1045
1046           warn "cannot add CC surcharge to invoice #$invnum: $grand_error"
1047             if $grand_error;
1048       }
1049
1050       return ''; #no error
1051
1052     }
1053
1054   } else {
1055
1056     my $perror = $transaction->error_message;
1057     #$payment_gateway->gateway_module. " error: ".
1058     # removed for conciseness
1059
1060     my $jobnum = $cust_pay_pending->jobnum;
1061     if ( $jobnum ) {
1062        my $placeholder = qsearchs( 'queue', { 'jobnum' => $jobnum } );
1063
1064        if ( $placeholder ) {
1065          my $error = $placeholder->depended_delete;
1066          $error ||= $placeholder->delete;
1067          warn "error removing provisioning jobs after declined paypendingnum ".
1068            $cust_pay_pending->paypendingnum. ": $error\n";
1069        } else {
1070          my $e = "error finding job $jobnum for declined paypendingnum ".
1071               $cust_pay_pending->paypendingnum. "\n";
1072          warn $e;
1073        }
1074
1075     }
1076
1077     unless ( $transaction->error_message ) {
1078
1079       my $t_response;
1080       if ( $transaction->can('response_page') ) {
1081         $t_response = {
1082                         'page'    => ( $transaction->can('response_page')
1083                                          ? $transaction->response_page
1084                                          : ''
1085                                      ),
1086                         'code'    => ( $transaction->can('response_code')
1087                                          ? $transaction->response_code
1088                                          : ''
1089                                      ),
1090                         'headers' => ( $transaction->can('response_headers')
1091                                          ? $transaction->response_headers
1092                                          : ''
1093                                      ),
1094                       };
1095       } else {
1096         $t_response .=
1097           "No additional debugging information available for ".
1098             $payment_gateway->gateway_module;
1099       }
1100
1101       $perror .= "No error_message returned from ".
1102                    $payment_gateway->gateway_module. " -- ".
1103                  ( ref($t_response) ? Dumper($t_response) : $t_response );
1104
1105     }
1106
1107     if ( !$options{'quiet'} && !$realtime_bop_decline_quiet
1108          && $conf->exists('emaildecline', $self->agentnum)
1109          && grep { $_ ne 'POST' } $self->invoicing_list
1110          && ! grep { $transaction->error_message =~ /$_/ }
1111                    $conf->config('emaildecline-exclude', $self->agentnum)
1112     ) {
1113
1114       # Send a decline alert to the customer.
1115       my $msgnum = $conf->config('decline_msgnum', $self->agentnum);
1116       my $error = '';
1117       if ( $msgnum ) {
1118         # include the raw error message in the transaction state
1119         $cust_pay_pending->setfield('error', $transaction->error_message);
1120         my $msg_template = qsearchs('msg_template', { msgnum => $msgnum });
1121         $error = $msg_template->send( 'cust_main' => $self,
1122                                       'object'    => $cust_pay_pending );
1123       }
1124       else { #!$msgnum
1125
1126         my @templ = $conf->config('declinetemplate');
1127         my $template = new Text::Template (
1128           TYPE   => 'ARRAY',
1129           SOURCE => [ map "$_\n", @templ ],
1130         ) or return "($perror) can't create template: $Text::Template::ERROR";
1131         $template->compile()
1132           or return "($perror) can't compile template: $Text::Template::ERROR";
1133
1134         my $templ_hash = {
1135           'company_name'    =>
1136             scalar( $conf->config('company_name', $self->agentnum ) ),
1137           'company_address' =>
1138             join("\n", $conf->config('company_address', $self->agentnum ) ),
1139           'error'           => $transaction->error_message,
1140         };
1141
1142         my $error = send_email(
1143           'from'    => $conf->invoice_from_full( $self->agentnum ),
1144           'to'      => [ grep { $_ ne 'POST' } $self->invoicing_list ],
1145           'subject' => 'Your payment could not be processed',
1146           'body'    => [ $template->fill_in(HASH => $templ_hash) ],
1147         );
1148       }
1149
1150       $perror .= " (also received error sending decline notification: $error)"
1151         if $error;
1152
1153     }
1154
1155     $cust_pay_pending->status('done');
1156     $cust_pay_pending->statustext($perror);
1157     #'declined:': no, that's failure_status
1158     if ( $transaction->can('failure_status') ) {
1159       $cust_pay_pending->failure_status( $transaction->failure_status );
1160     }
1161     my $cpp_done_err = $cust_pay_pending->replace;
1162     if ( $cpp_done_err ) {
1163       my $e = "WARNING: $options{method} declined but pending payment not ".
1164               "resolved - error updating status for paypendingnum ".
1165               $cust_pay_pending->paypendingnum. ": $cpp_done_err \n";
1166       warn $e;
1167       $perror = "$e ($perror)";
1168     }
1169
1170     return $perror;
1171   }
1172
1173 }
1174
1175 =item realtime_botpp_capture CUST_PAY_PENDING [ OPTION => VALUE ... ]
1176
1177 Verifies successful third party processing of a realtime credit card,
1178 ACH (electronic check) or phone bill transaction via a
1179 Business::OnlineThirdPartyPayment realtime gateway.  See
1180 L<http://420.am/business-onlinethirdpartypayment> for supported gateways.
1181
1182 Available options are: I<description>, I<invnum>, I<quiet>, I<paynum_ref>, I<payunique>
1183
1184 The additional options I<payname>, I<city>, I<state>,
1185 I<zip>, I<payinfo> and I<paydate> are also available.  Any of these options,
1186 if set, will override the value from the customer record.
1187
1188 I<description> is a free-text field passed to the gateway.  It defaults to
1189 "Internet services".
1190
1191 If an I<invnum> is specified, this payment (if successful) is applied to the
1192 specified invoice.  If you don't specify an I<invnum> you might want to
1193 call the B<apply_payments> method.
1194
1195 I<quiet> can be set true to surpress email decline notices.
1196
1197 I<paynum_ref> can be set to a scalar reference.  It will be filled in with the
1198 resulting paynum, if any.
1199
1200 I<payunique> is a unique identifier for this payment.
1201
1202 Returns a hashref containing elements bill_error (which will be undefined
1203 upon success) and session_id of any associated session.
1204
1205 =cut
1206
1207 sub realtime_botpp_capture {
1208   my( $self, $cust_pay_pending, %options ) = @_;
1209
1210   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1211
1212   if ( $DEBUG ) {
1213     warn "$me realtime_botpp_capture: pending transaction $cust_pay_pending\n";
1214     warn "  $_ => $options{$_}\n" foreach keys %options;
1215   }
1216
1217   eval "use Business::OnlineThirdPartyPayment";
1218   die $@ if $@;
1219
1220   ###
1221   # select the gateway
1222   ###
1223
1224   my $method = FS::payby->payby2bop($cust_pay_pending->payby);
1225
1226   my $payment_gateway;
1227   my $gatewaynum = $cust_pay_pending->getfield('gatewaynum');
1228   $payment_gateway = $gatewaynum ? qsearchs( 'payment_gateway',
1229                 { gatewaynum => $gatewaynum }
1230               )
1231     : $self->agent->payment_gateway( 'method' => $method,
1232                                      # 'invnum'  => $cust_pay_pending->invnum,
1233                                      # 'payinfo' => $cust_pay_pending->payinfo,
1234                                    );
1235
1236   $options{payment_gateway} = $payment_gateway; # for the helper subs
1237
1238   ###
1239   # massage data
1240   ###
1241
1242   my @invoicing_list = $self->invoicing_list_emailonly;
1243   if ( $conf->exists('emailinvoiceautoalways')
1244        || $conf->exists('emailinvoiceauto') && ! @invoicing_list
1245        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
1246     push @invoicing_list, $self->all_emails;
1247   }
1248
1249   my $email = ($conf->exists('business-onlinepayment-email-override'))
1250               ? $conf->config('business-onlinepayment-email-override')
1251               : $invoicing_list[0];
1252
1253   my %content = ();
1254
1255   $content{email_customer} =
1256     (    $conf->exists('business-onlinepayment-email_customer')
1257       || $conf->exists('business-onlinepayment-email-override') );
1258
1259   ###
1260   # run transaction(s)
1261   ###
1262
1263   my $transaction =
1264     new Business::OnlineThirdPartyPayment( $payment_gateway->gateway_module,
1265                                            $self->_bop_options(\%options),
1266                                          );
1267
1268   $transaction->reference({ %options });
1269
1270   $transaction->content(
1271     'type'           => $method,
1272     $self->_bop_auth(\%options),
1273     'action'         => 'Post Authorization',
1274     'description'    => $options{'description'},
1275     'amount'         => $cust_pay_pending->paid,
1276     #'invoice_number' => $options{'invnum'},
1277     'customer_id'    => $self->custnum,
1278     'reference'      => $cust_pay_pending->paypendingnum,
1279     'email'          => $email,
1280     'phone'          => $self->daytime || $self->night,
1281     %content, #after
1282     # plus whatever is required for bogus capture avoidance
1283   );
1284
1285   $transaction->submit();
1286
1287   my $error =
1288     $self->_realtime_bop_result( $cust_pay_pending, $transaction, %options );
1289
1290   if ( $options{'apply'} ) {
1291     my $apply_error = $self->apply_payments_and_credits;
1292     if ( $apply_error ) {
1293       warn "WARNING: error applying payment: $apply_error\n";
1294     }
1295   }
1296
1297   return {
1298     bill_error => $error,
1299     session_id => $cust_pay_pending->session_id,
1300   }
1301
1302 }
1303
1304 =item default_payment_gateway
1305
1306 DEPRECATED -- use agent->payment_gateway
1307
1308 =cut
1309
1310 sub default_payment_gateway {
1311   my( $self, $method ) = @_;
1312
1313   die "Real-time processing not enabled\n"
1314     unless $conf->exists('business-onlinepayment');
1315
1316   #warn "default_payment_gateway deprecated -- use agent->payment_gateway\n";
1317
1318   #load up config
1319   my $bop_config = 'business-onlinepayment';
1320   $bop_config .= '-ach'
1321     if $method =~ /^(ECHECK|CHEK)$/ && $conf->exists($bop_config. '-ach');
1322   my ( $processor, $login, $password, $action, @bop_options ) =
1323     $conf->config($bop_config);
1324   $action ||= 'normal authorization';
1325   pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
1326   die "No real-time processor is enabled - ".
1327       "did you set the business-onlinepayment configuration value?\n"
1328     unless $processor;
1329
1330   ( $processor, $login, $password, $action, @bop_options )
1331 }
1332
1333 =item realtime_refund_bop METHOD [ OPTION => VALUE ... ]
1334
1335 Refunds a realtime credit card, ACH (electronic check) or phone bill transaction
1336 via a Business::OnlinePayment realtime gateway.  See
1337 L<http://420.am/business-onlinepayment> for supported gateways.
1338
1339 Available methods are: I<CC>, I<ECHECK> and I<LEC>
1340
1341 Available options are: I<amount>, I<reason>, I<paynum>, I<paydate>
1342
1343 Most gateways require a reference to an original payment transaction to refund,
1344 so you probably need to specify a I<paynum>.
1345
1346 I<amount> defaults to the original amount of the payment if not specified.
1347
1348 I<reason> specifies a reason for the refund.
1349
1350 I<paydate> specifies the expiration date for a credit card overriding the
1351 value from the customer record or the payment record. Specified as yyyy-mm-dd
1352
1353 Implementation note: If I<amount> is unspecified or equal to the amount of the
1354 orignal payment, first an attempt is made to "void" the transaction via
1355 the gateway (to cancel a not-yet settled transaction) and then if that fails,
1356 the normal attempt is made to "refund" ("credit") the transaction via the
1357 gateway is attempted. No attempt to "void" the transaction is made if the
1358 gateway has introspection data and doesn't support void.
1359
1360 #The additional options I<payname>, I<address1>, I<address2>, I<city>, I<state>,
1361 #I<zip>, I<payinfo> and I<paydate> are also available.  Any of these options,
1362 #if set, will override the value from the customer record.
1363
1364 #If an I<invnum> is specified, this payment (if successful) is applied to the
1365 #specified invoice.  If you don't specify an I<invnum> you might want to
1366 #call the B<apply_payments> method.
1367
1368 =cut
1369
1370 #some false laziness w/realtime_bop, not enough to make it worth merging
1371 #but some useful small subs should be pulled out
1372 sub realtime_refund_bop {
1373   my $self = shift;
1374
1375   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1376
1377   my %options = ();
1378   if (ref($_[0]) eq 'HASH') {
1379     %options = %{$_[0]};
1380   } else {
1381     my $method = shift;
1382     %options = @_;
1383     $options{method} = $method;
1384   }
1385
1386   if ( $DEBUG ) {
1387     warn "$me realtime_refund_bop (new): $options{method} refund\n";
1388     warn "  $_ => $options{$_}\n" foreach keys %options;
1389   }
1390
1391   ###
1392   # look up the original payment and optionally a gateway for that payment
1393   ###
1394
1395   my $cust_pay = '';
1396   my $amount = $options{'amount'};
1397
1398   my( $processor, $login, $password, @bop_options, $namespace ) ;
1399   my( $auth, $order_number ) = ( '', '', '' );
1400   my $gatewaynum = '';
1401
1402   if ( $options{'paynum'} ) {
1403
1404     warn "  paynum: $options{paynum}\n" if $DEBUG > 1;
1405     $cust_pay = qsearchs('cust_pay', { paynum=>$options{'paynum'} } )
1406       or return "Unknown paynum $options{'paynum'}";
1407     $amount ||= $cust_pay->paid;
1408
1409     if ( $cust_pay->get('processor') ) {
1410       ($gatewaynum, $processor, $auth, $order_number) =
1411       (
1412         $cust_pay->gatewaynum,
1413         $cust_pay->processor,
1414         $cust_pay->auth,
1415         $cust_pay->order_number,
1416       );
1417     } else {
1418       # this payment wasn't upgraded, which probably means this won't work,
1419       # but try it anyway
1420       $cust_pay->paybatch =~ /^((\d+)\-)?(\w+):\s*([\w\-\/ ]*)(:([\w\-]+))?$/
1421         or return "Can't parse paybatch for paynum $options{'paynum'}: ".
1422                   $cust_pay->paybatch;
1423       ( $gatewaynum, $processor, $auth, $order_number ) = ( $2, $3, $4, $6 );
1424     }
1425
1426     if ( $gatewaynum ) { #gateway for the payment to be refunded
1427
1428       my $payment_gateway =
1429         qsearchs('payment_gateway', { 'gatewaynum' => $gatewaynum } );
1430       die "payment gateway $gatewaynum not found"
1431         unless $payment_gateway;
1432
1433       $processor   = $payment_gateway->gateway_module;
1434       $login       = $payment_gateway->gateway_username;
1435       $password    = $payment_gateway->gateway_password;
1436       $namespace   = $payment_gateway->gateway_namespace;
1437       @bop_options = $payment_gateway->options;
1438
1439     } else { #try the default gateway
1440
1441       my $conf_processor;
1442       my $payment_gateway =
1443         $self->agent->payment_gateway('method' => $options{method});
1444
1445       ( $conf_processor, $login, $password, $namespace ) =
1446         map { my $method = "gateway_$_"; $payment_gateway->$method }
1447           qw( module username password namespace );
1448
1449       @bop_options = $payment_gateway->gatewaynum
1450                        ? $payment_gateway->options
1451                        : @{ $payment_gateway->get('options') };
1452
1453       return "processor of payment $options{'paynum'} $processor does not".
1454              " match default processor $conf_processor"
1455         unless $processor eq $conf_processor;
1456
1457     }
1458
1459
1460   } else { # didn't specify a paynum, so look for agent gateway overrides
1461            # like a normal transaction
1462
1463     my $payment_gateway =
1464       $self->agent->payment_gateway( 'method'  => $options{method},
1465                                      #'payinfo' => $payinfo,
1466                                    );
1467     my( $processor, $login, $password, $namespace ) =
1468       map { my $method = "gateway_$_"; $payment_gateway->$method }
1469         qw( module username password namespace );
1470
1471     my @bop_options = $payment_gateway->gatewaynum
1472                         ? $payment_gateway->options
1473                         : @{ $payment_gateway->get('options') };
1474
1475   }
1476   return "neither amount nor paynum specified" unless $amount;
1477
1478   eval "use $namespace";
1479   die $@ if $@;
1480
1481   my %content = (
1482     'type'           => $options{method},
1483     'login'          => $login,
1484     'password'       => $password,
1485     'order_number'   => $order_number,
1486     'amount'         => $amount,
1487   );
1488   $content{authorization} = $auth
1489     if length($auth); #echeck/ACH transactions have an order # but no auth
1490                       #(at least with authorize.net)
1491
1492   my $currency =    $conf->exists('business-onlinepayment-currency')
1493                  && $conf->config('business-onlinepayment-currency');
1494   $content{currency} = $currency if $currency;
1495
1496   my $disable_void_after;
1497   if ($conf->exists('disable_void_after')
1498       && $conf->config('disable_void_after') =~ /^(\d+)$/) {
1499     $disable_void_after = $1;
1500   }
1501
1502   #first try void if applicable
1503   my $void = new Business::OnlinePayment( $processor, @bop_options );
1504
1505   my $tryvoid = 1;
1506   if ($void->can('info')) {
1507       my $paytype = '';
1508       $paytype = 'ECHECK' if $cust_pay && $cust_pay->payby eq 'CHEK';
1509       $paytype = 'CC' if $cust_pay && $cust_pay->payby eq 'CARD';
1510       my %supported_actions = $void->info('supported_actions');
1511       $tryvoid = 0
1512         if ( %supported_actions && $paytype
1513                 && defined($supported_actions{$paytype})
1514                 && !grep{ $_ eq 'Void' } @{$supported_actions{$paytype}} );
1515   }
1516
1517   if ( $cust_pay && $cust_pay->paid == $amount
1518     && (
1519       ( not defined($disable_void_after) )
1520       || ( time < ($cust_pay->_date + $disable_void_after ) )
1521     )
1522     && $tryvoid
1523   ) {
1524     warn "  attempting void\n" if $DEBUG > 1;
1525     if ( $void->can('info') ) {
1526       if ( $cust_pay->payby eq 'CARD'
1527            && $void->info('CC_void_requires_card') )
1528       {
1529         $content{'card_number'} = $cust_pay->payinfo;
1530       } elsif ( $cust_pay->payby eq 'CHEK'
1531                 && $void->info('ECHECK_void_requires_account') )
1532       {
1533         ( $content{'account_number'}, $content{'routing_code'} ) =
1534           split('@', $cust_pay->payinfo);
1535         $content{'name'} = $self->get('first'). ' '. $self->get('last');
1536       }
1537     }
1538     $void->content( 'action' => 'void', %content );
1539     $void->test_transaction(1)
1540       if $conf->exists('business-onlinepayment-test_transaction');
1541     $void->submit();
1542     if ( $void->is_success ) {
1543       my $error = $cust_pay->void($options{'reason'});
1544       if ( $error ) {
1545         # gah, even with transactions.
1546         my $e = 'WARNING: Card/ACH voided but database not updated - '.
1547                 "error voiding payment: $error";
1548         warn $e;
1549         return $e;
1550       }
1551       warn "  void successful\n" if $DEBUG > 1;
1552       return '';
1553     }
1554   }
1555
1556   warn "  void unsuccessful, trying refund\n"
1557     if $DEBUG > 1;
1558
1559   #massage data
1560   my $address = $self->address1;
1561   $address .= ", ". $self->address2 if $self->address2;
1562
1563   my($payname, $payfirst, $paylast);
1564   if ( $self->payname && $options{method} ne 'ECHECK' ) {
1565     $payname = $self->payname;
1566     $payname =~ /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)\s*$/
1567       or return "Illegal payname $payname";
1568     ($payfirst, $paylast) = ($1, $2);
1569   } else {
1570     $payfirst = $self->getfield('first');
1571     $paylast = $self->getfield('last');
1572     $payname =  "$payfirst $paylast";
1573   }
1574
1575   my @invoicing_list = $self->invoicing_list_emailonly;
1576   if ( $conf->exists('emailinvoiceautoalways')
1577        || $conf->exists('emailinvoiceauto') && ! @invoicing_list
1578        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
1579     push @invoicing_list, $self->all_emails;
1580   }
1581
1582   my $email = ($conf->exists('business-onlinepayment-email-override'))
1583               ? $conf->config('business-onlinepayment-email-override')
1584               : $invoicing_list[0];
1585
1586   my $payip = exists($options{'payip'})
1587                 ? $options{'payip'}
1588                 : $self->payip;
1589   $content{customer_ip} = $payip
1590     if length($payip);
1591
1592   my $payinfo = '';
1593   if ( $options{method} eq 'CC' ) {
1594
1595     if ( $cust_pay ) {
1596       $content{card_number} = $payinfo = $cust_pay->payinfo;
1597       (exists($options{'paydate'}) ? $options{'paydate'} : $cust_pay->paydate)
1598         =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/ &&
1599         ($content{expiration} = "$2/$1");  # where available
1600     } else {
1601       $content{card_number} = $payinfo = $self->payinfo;
1602       (exists($options{'paydate'}) ? $options{'paydate'} : $self->paydate)
1603         =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
1604       $content{expiration} = "$2/$1";
1605     }
1606
1607   } elsif ( $options{method} eq 'ECHECK' ) {
1608
1609     if ( $cust_pay ) {
1610       $payinfo = $cust_pay->payinfo;
1611     } else {
1612       $payinfo = $self->payinfo;
1613     }
1614     ( $content{account_number}, $content{routing_code} )= split('@', $payinfo );
1615     $content{bank_name} = $self->payname;
1616     $content{account_type} = 'CHECKING';
1617     $content{account_name} = $payname;
1618     $content{customer_org} = $self->company ? 'B' : 'I';
1619     $content{customer_ssn} = $self->ss;
1620   } elsif ( $options{method} eq 'LEC' ) {
1621     $content{phone} = $payinfo = $self->payinfo;
1622   }
1623
1624   #then try refund
1625   my $refund = new Business::OnlinePayment( $processor, @bop_options );
1626   my %sub_content = $refund->content(
1627     'action'         => 'credit',
1628     'customer_id'    => $self->custnum,
1629     'last_name'      => $paylast,
1630     'first_name'     => $payfirst,
1631     'name'           => $payname,
1632     'address'        => $address,
1633     'city'           => $self->city,
1634     'state'          => $self->state,
1635     'zip'            => $self->zip,
1636     'country'        => $self->country,
1637     'email'          => $email,
1638     'phone'          => $self->daytime || $self->night,
1639     %content, #after
1640   );
1641   warn join('', map { "  $_ => $sub_content{$_}\n" } keys %sub_content )
1642     if $DEBUG > 1;
1643   $refund->test_transaction(1)
1644     if $conf->exists('business-onlinepayment-test_transaction');
1645   $refund->submit();
1646
1647   return "$processor error: ". $refund->error_message
1648     unless $refund->is_success();
1649
1650   $order_number = $refund->order_number if $refund->can('order_number');
1651
1652   while ( $cust_pay && $cust_pay->unapplied < $amount ) {
1653     my @cust_bill_pay = $cust_pay->cust_bill_pay;
1654     last unless @cust_bill_pay;
1655     my $cust_bill_pay = pop @cust_bill_pay;
1656     my $error = $cust_bill_pay->delete;
1657     last if $error;
1658   }
1659
1660   my $cust_refund = new FS::cust_refund ( {
1661     'custnum'  => $self->custnum,
1662     'paynum'   => $options{'paynum'},
1663     'refund'   => $amount,
1664     '_date'    => '',
1665     'payby'    => $bop_method2payby{$options{method}},
1666     'payinfo'  => $payinfo,
1667     'reason'   => $options{'reason'} || 'card or ACH refund',
1668     'gatewaynum'    => $gatewaynum, # may be null
1669     'processor'     => $processor,
1670     'auth'          => $refund->authorization,
1671     'order_number'  => $order_number,
1672   } );
1673   my $error = $cust_refund->insert;
1674   if ( $error ) {
1675     $cust_refund->paynum(''); #try again with no specific paynum
1676     my $error2 = $cust_refund->insert;
1677     if ( $error2 ) {
1678       # gah, even with transactions.
1679       my $e = 'WARNING: Card/ACH refunded but database not updated - '.
1680               "error inserting refund ($processor): $error2".
1681               " (previously tried insert with paynum #$options{'paynum'}" .
1682               ": $error )";
1683       warn $e;
1684       return $e;
1685     }
1686   }
1687
1688   ''; #no error
1689
1690 }
1691
1692 =back
1693
1694 =head1 BUGS
1695
1696 Not autoloaded.
1697
1698 =head1 SEE ALSO
1699
1700 L<FS::cust_main>, L<FS::cust_main::Billing>
1701
1702 =cut
1703
1704 1;