FS/FS/cust_main/Billing_Realtime.pm

   1 package FS::cust_main::Billing_Realtime;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use vars qw( $realtime_bop_decline_quiet ); #ugh
   6 use Carp;
   7 use Data::Dumper;
   8 use Business::CreditCard 0.35;
   9 use FS::UID qw( dbh myconnect );
  10 use FS::Record qw( qsearch qsearchs );
  11 use FS::payby;
  12 use FS::cust_pay;
  13 use FS::cust_pay_pending;
  14 use FS::cust_bill_pay;
  15 use FS::cust_refund;
  16 use FS::banned_pay;
  17 use FS::payment_gateway;
  18
  19 $realtime_bop_decline_quiet = 0;
  20
  21 # 1 is mostly method/subroutine entry and options
  22 # 2 traces progress of some operations
  23 # 3 is even more information including possibly sensitive data
  24 $DEBUG = 0;
  25 $me = '[FS::cust_main::Billing_Realtime]';
  26
  27 our $BOP_TESTING = 0;
  28 our $BOP_TESTING_SUCCESS = 1;
  29
  30 install_callback FS::UID sub {
  31   $conf = new FS::Conf;
  32   #yes, need it for stuff below (prolly should be cached)
  33 };
  34
  35 =head1 NAME
  36
  37 FS::cust_main::Billing_Realtime - Realtime billing mixin for cust_main
  38
  39 =head1 SYNOPSIS
  40
  41 =head1 DESCRIPTION
  42
  43 These methods are available on FS::cust_main objects.
  44
  45 =head1 METHODS
  46
  47 =over 4
  48
  49 =item realtime_cust_payby
  50
  51 =cut
  52
  53 sub realtime_cust_payby {
  54   my( $self, %options ) = @_;
  55
  56   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
  57
  58   $options{amount} = $self->balance unless exists( $options{amount} );
  59
  60   my @cust_payby = $self->cust_payby('CARD','CHEK');
  61
  62   my $error;
  63   foreach my $cust_payby (@cust_payby) {
  64     $error = $cust_payby->realtime_bop( %options, );
  65     last unless $error;
  66   }
  67
  68   #XXX what about the earlier errors?
  69
  70   $error;
  71
  72 }
  73
  74 =item realtime_collect [ OPTION => VALUE ... ]
  75
  76 Attempt to collect the customer's current balance with a realtime credit
  77 card or electronic check transaction (see realtime_bop() below).
  78
  79 Returns the result of realtime_bop(): nothing, an error message, or a
  80 hashref of state information for a third-party transaction.
  81
  82 Available options are: I<method>, I<amount>, I<description>, I<invnum>, I<quiet>, I<paynum_ref>, I<payunique>, I<session_id>, I<pkgnum>
  83
  84 I<method> is one of: I<CC> or I<ECHECK>.  If none is specified
  85 then it is deduced from the customer record.
  86
  87 If no I<amount> is specified, then the customer balance is used.
  88
  89 The additional options I<payname>, I<address1>, I<address2>, I<city>, I<state>,
  90 I<zip>, I<payinfo> and I<paydate> are also available.  Any of these options,
  91 if set, will override the value from the customer record.
  92
  93 I<description> is a free-text field passed to the gateway.  It defaults to
  94 the value defined by the business-onlinepayment-description configuration
  95 option, or "Internet services" if that is unset.
  96
  97 If an I<invnum> is specified, this payment (if successful) is applied to the
  98 specified invoice.
  99
 100 I<apply> will automatically apply a resulting payment.
 101
 102 I<quiet> can be set true to suppress email decline notices.
 103
 104 I<paynum_ref> can be set to a scalar reference.  It will be filled in with the
 105 resulting paynum, if any.
 106
 107 I<payunique> is a unique identifier for this payment.
 108
 109 I<session_id> is a session identifier associated with this payment.
 110
 111 I<depend_jobnum> allows payment capture to unlock export jobs
 112
 113 =cut
 114
 115 # Currently only used by ClientAPI
 116 sub realtime_collect {
 117   my( $self, %options ) = @_;
 118
 119   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 120
 121   if ( $DEBUG ) {
 122     warn "$me realtime_collect:\n";
 123     warn "  $_ => $options{$_}\n" foreach keys %options;
 124   }
 125
 126   $options{amount} = $self->balance unless exists( $options{amount} );
 127   return '' unless $options{amount} > 0;
 128
 129   return $self->realtime_bop({%options});
 130
 131 }
 132
 133 =item realtime_bop { [ ARG => VALUE ... ] }
 134
 135 Runs a realtime credit card or ACH (electronic check) transaction
 136 via a Business::OnlinePayment realtime gateway.  See
 137 L<http://420.am/business-onlinepayment> for supported gateways.
 138
 139 Required arguments in the hashref are I<amount> and either
 140 I<cust_payby> or I<method>, I<payinfo> and (as applicable for method)
 141 I<payname>, I<address1>, I<address2>, I<city>, I<state>, I<zip> and I<paydate>.
 142
 143 Available methods are: I<CC>, I<ECHECK>, or I<PAYPAL>
 144
 145 Available optional arguments are: I<description>, I<invnum>, I<apply>, I<quiet>, I<paynum_ref>, I<payunique>, I<session_id>
 146
 147 I<description> is a free-text field passed to the gateway.  It defaults to
 148 the value defined by the business-onlinepayment-description configuration
 149 option, or "Internet services" if that is unset.
 150
 151 If an I<invnum> is specified, this payment (if successful) is applied to the
 152 specified invoice.  If the customer has exactly one open invoice, that
 153 invoice number will be assumed.  If you don't specify an I<invnum> you might
 154 want to call the B<apply_payments> method or set the I<apply> option.
 155
 156 I<no_invnum> can be set to true to prevent that default invnum from being set.
 157
 158 I<apply> can be set to true to run B<apply_payments_and_credits> on success.
 159
 160 I<no_auto_apply> can be set to true to set that flag on the resulting payment
 161 (prevents payment from being applied by B<apply_payments> or B<apply_payments_and_credits>,
 162 but will still be applied if I<invnum> exists...use with I<no_invnum> for intended effect.)
 163
 164 I<quiet> can be set true to surpress email decline notices.
 165
 166 I<paynum_ref> can be set to a scalar reference.  It will be filled in with the
 167 resulting paynum, if any.
 168
 169 I<payunique> is a unique identifier for this payment.
 170
 171 I<session_id> is a session identifier associated with this payment.
 172
 173 I<depend_jobnum> allows payment capture to unlock export jobs
 174
 175 I<discount_term> attempts to take a discount by prepaying for discount_term.
 176 The payment will fail if I<amount> is incorrect for this discount term.
 177
 178 A direct (Business::OnlinePayment) transaction will return nothing on success,
 179 or an error message on failure.
 180
 181 A third-party transaction will return a hashref containing:
 182
 183 - popup_url: the URL to which a browser should be redirected to complete
 184   the transaction.
 185 - collectitems: an arrayref of name-value pairs to be posted to popup_url.
 186 - reference: a reference ID for the transaction, to show the customer.
 187
 188 (moved from cust_bill) (probably should get realtime_{card,ach,lec} here too)
 189
 190 =cut
 191
 192 # some helper routines
 193 #
 194 # _bop_recurring_billing: Checks whether this payment should have the
 195 # recurring_billing flag used by some B:OP interfaces (IPPay, PlugnPay,
 196 # vSecure, etc.). This works in two different modes:
 197 # - actual_oncard (default): treat the payment as recurring if the customer
 198 #   has made a payment using this card before.
 199 # - transaction_is_recur: treat the payment as recurring if the invoice
 200 #   being paid has any recurring package charges.
 201
 202 sub _bop_recurring_billing {
 203   my( $self, %opt ) = @_;
 204
 205   my $method = scalar($conf->config('credit_card-recurring_billing_flag'));
 206
 207   if ( defined($method) && $method eq 'transaction_is_recur' ) {
 208
 209     return 1 if $opt{'trans_is_recur'};
 210
 211   } else {
 212
 213     # return 1 if the payinfo has been used for another payment
 214     return $self->payinfo_used($opt{'payinfo'}); # in payinfo_Mixin
 215
 216   }
 217
 218   return 0;
 219
 220 }
 221
 222 #can run safely as class method if opt payment_gateway already exists
 223 sub _payment_gateway {
 224   my ($self, $options) = @_;
 225
 226   if ( $options->{'fake_gatewaynum'} ) {
 227         $options->{payment_gateway} =
 228             qsearchs('payment_gateway',
 229                       { 'gatewaynum' => $options->{'fake_gatewaynum'}, }
 230                     );
 231   }
 232
 233   $options->{payment_gateway} = $self->agent->payment_gateway( %$options )
 234     unless exists($options->{payment_gateway});
 235
 236   $options->{payment_gateway};
 237 }
 238
 239 # not a method!!!
 240 sub _bop_auth {
 241   my ($options) = @_;
 242
 243   (
 244     'login'    => $options->{payment_gateway}->gateway_username,
 245     'password' => $options->{payment_gateway}->gateway_password,
 246   );
 247 }
 248
 249 ### not a method!
 250 sub _bop_options {
 251   my ($options) = @_;
 252
 253   $options->{payment_gateway}->gatewaynum
 254     ? $options->{payment_gateway}->options
 255     : @{ $options->{payment_gateway}->get('options') };
 256
 257 }
 258
 259 sub _bop_defaults {
 260   my ($self, $options) = @_;
 261
 262   unless ( $options->{'description'} ) {
 263     if ( $conf->exists('business-onlinepayment-description') ) {
 264       my $dtempl = $conf->config('business-onlinepayment-description');
 265
 266       my $agent = $self->agent->agent;
 267       #$pkgs... not here
 268       $options->{'description'} = eval qq("$dtempl");
 269     } else {
 270       $options->{'description'} = 'Internet services';
 271     }
 272   }
 273
 274   # Default invoice number if the customer has exactly one open invoice.
 275   unless ( $options->{'invnum'} || $options->{'no_invnum'} ) {
 276     $options->{'invnum'} = '';
 277     my @open = $self->open_cust_bill;
 278     $options->{'invnum'} = $open[0]->invnum if scalar(@open) == 1;
 279   }
 280
 281 }
 282
 283 # not a method!
 284 sub _bop_cust_payby_options {
 285   my ($options) = @_;
 286   my $cust_payby = $options->{'cust_payby'};
 287   if ($cust_payby) {
 288
 289     $options->{'method'} = FS::payby->payby2bop( $cust_payby->payby );
 290
 291     if ($cust_payby->payby =~ /^(CARD|DCRD)$/) {
 292       # false laziness with cust_payby->check
 293       #   which might not have been run yet
 294       my( $m, $y );
 295       if ( $cust_payby->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
 296         ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
 297       } elsif ( $cust_payby->paydate =~ /^19(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
 298         ( $m, $y ) = ( $2, "19$1" );
 299       } elsif ( $cust_payby->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
 300         ( $m, $y ) = ( $3, "20$2" );
 301       } else {
 302         return "Illegal expiration date: ". $cust_payby->paydate;
 303       }
 304       $m = sprintf('%02d',$m);
 305       $options->{paydate} = "$y-$m-01";
 306     } else {
 307       $options->{paydate} = '';
 308     }
 309
 310     $options->{$_} = $cust_payby->$_()
 311       for qw( payinfo paycvv paymask paystart_month paystart_year
 312               payissue payname paystate paytype payip );
 313
 314     if ( $cust_payby->locationnum ) {
 315       my $cust_location = $cust_payby->cust_location;
 316       $options->{$_} = $cust_location->$_() for qw( address1 address2 city state zip );
 317     }
 318   }
 319 }
 320
 321 # can be called as class method,
 322 # but can't load default name/phone fields as class method
 323 sub _bop_content {
 324   my ($self, $options) = @_;
 325   my %content = ();
 326
 327   my $payip = $options->{'payip'};
 328   $content{customer_ip} = $payip if length($payip);
 329
 330   $content{invoice_number} = $options->{'invnum'}
 331     if exists($options->{'invnum'}) && length($options->{'invnum'});
 332
 333   $content{email_customer} =
 334     (    $conf->exists('business-onlinepayment-email_customer')
 335       || $conf->exists('business-onlinepayment-email-override') );
 336
 337   my ($payname, $payfirst, $paylast);
 338   if ( $options->{payname} && $options->{method} ne 'ECHECK' ) {
 339     ($payname = $options->{payname}) =~
 340       /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)\s*$/
 341       or return "Illegal payname $payname";
 342     ($payfirst, $paylast) = ($1, $2);
 343   } elsif (ref($self)) { # can't set payname if called as class method
 344     $payfirst = $self->getfield('first');
 345     $paylast = $self->getfield('last');
 346     $payname = "$payfirst $paylast";
 347   }
 348
 349   $content{last_name} = $paylast if $paylast;
 350   $content{first_name} = $payfirst if $payfirst;
 351
 352   $content{name} = $payname if $payname;
 353
 354   $content{address} = $options->{'address1'};
 355   my $address2 = $options->{'address2'};
 356   $content{address} .= ", ". $address2 if length($address2);
 357
 358   $content{city} = $options->{'city'};
 359   $content{state} = $options->{'state'};
 360   $content{zip} = $options->{'zip'};
 361   $content{country} = $options->{'country'};
 362
 363   # can't set phone if called as class method
 364   $content{phone} = $self->daytime || $self->night
 365     if ref($self);
 366
 367   my $currency =    $conf->exists('business-onlinepayment-currency')
 368                  && $conf->config('business-onlinepayment-currency');
 369   $content{currency} = $currency if $currency;
 370
 371   \%content;
 372 }
 373
 374 # updates payinfo and cust_payby options with token from transaction
 375 # can be called as a class method
 376 sub _tokenize_card {
 377   my ($self,$transaction,$options) = @_;
 378   if ( $transaction->can('card_token')
 379        and $transaction->card_token
 380        and !$self->tokenized($options->{'payinfo'})
 381   ) {
 382     $options->{'payinfo'} = $transaction->card_token;
 383     $options->{'cust_payby'}->payinfo($transaction->card_token) if $options->{'cust_payby'};
 384     return $transaction->card_token;
 385   }
 386   return '';
 387 }
 388
 389 my %bop_method2payby = (
 390   'CC'     => 'CARD',
 391   'ECHECK' => 'CHEK',
 392   'PAYPAL' => 'PPAL',
 393 );
 394
 395 sub realtime_bop {
 396   my $self = shift;
 397
 398   confess "Can't call realtime_bop within another transaction ".
 399           '($FS::UID::AutoCommit is false)'
 400     unless $FS::UID::AutoCommit;
 401
 402   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 403
 404   my $log = FS::Log->new('FS::cust_main::Billing_Realtime::realtime_bop');
 405
 406   my %options = ();
 407   if (ref($_[0]) eq 'HASH') {
 408     %options = %{$_[0]};
 409   } else {
 410     my ( $method, $amount ) = ( shift, shift );
 411     %options = @_;
 412     $options{method} = $method;
 413     $options{amount} = $amount;
 414   }
 415
 416   # set fields from passed cust_payby
 417   _bop_cust_payby_options(\%options);
 418
 419   # possibly run a separate transaction to tokenize card number,
 420   #   so that we never store tokenized card info in cust_pay_pending
 421   if (($options{method} eq 'CC') && !$self->tokenized($options{'payinfo'})) {
 422     my $token_error = $self->realtime_tokenize(\%options);
 423     return $token_error if $token_error;
 424     # in theory, all cust_payby will be tokenized during original save,
 425     # so we shouldn't get here with opt cust_payby...but just in case...
 426     if ($options{'cust_payby'} && $self->tokenized($options{'payinfo'})) {
 427       $token_error = $options{'cust_payby'}->replace;
 428       return $token_error if $token_error;
 429     }
 430   }
 431
 432   ###
 433   # optional credit card surcharge
 434   ###
 435
 436   my $cc_surcharge = 0;
 437   my $cc_surcharge_pct = 0;
 438   $cc_surcharge_pct = $conf->config('credit-card-surcharge-percentage', $self->agentnum)
 439     if $conf->config('credit-card-surcharge-percentage', $self->agentnum)
 440     && $options{method} eq 'CC';
 441
 442   # always add cc surcharge if called from event
 443   if($options{'cc_surcharge_from_event'} && $cc_surcharge_pct > 0) {
 444       $cc_surcharge = $options{'amount'} * $cc_surcharge_pct / 100;
 445       $options{'amount'} += $cc_surcharge;
 446       $options{'amount'} = sprintf("%.2f", $options{'amount'}); # round (again)?
 447   }
 448   elsif($cc_surcharge_pct > 0) { # we're called not from event (i.e. from a
 449                                  # payment screen), so consider the given
 450                                  # amount as post-surcharge
 451     $cc_surcharge = $options{'amount'} - ($options{'amount'} / ( 1 + $cc_surcharge_pct/100 ));
 452   }
 453
 454   $cc_surcharge = sprintf("%.2f",$cc_surcharge) if $cc_surcharge > 0;
 455   $options{'cc_surcharge'} = $cc_surcharge;
 456
 457
 458   if ( $DEBUG ) {
 459     warn "$me realtime_bop (new): $options{method} $options{amount}\n";
 460     warn " cc_surcharge = $cc_surcharge\n";
 461   }
 462   if ( $DEBUG > 2 ) {
 463     warn "  $_ => $options{$_}\n" foreach keys %options;
 464   }
 465
 466   return $self->fake_bop(\%options) if $options{'fake'};
 467
 468   $self->_bop_defaults(\%options);
 469
 470   return "Missing payinfo"
 471     unless $options{'payinfo'};
 472
 473   ###
 474   # set trans_is_recur based on invnum if there is one
 475   ###
 476
 477   my $trans_is_recur = 0;
 478   if ( $options{'invnum'} ) {
 479
 480     my $cust_bill = qsearchs('cust_bill', { 'invnum' => $options{'invnum'} } );
 481     die "invnum ". $options{'invnum'}. " not found" unless $cust_bill;
 482
 483     my @part_pkg =
 484       map  { $_->part_pkg }
 485       grep { $_ }
 486       map  { $_->cust_pkg }
 487       $cust_bill->cust_bill_pkg;
 488
 489     $trans_is_recur = 1
 490       if grep { $_->freq ne '0' } @part_pkg;
 491
 492   }
 493
 494   ###
 495   # select a gateway
 496   ###
 497
 498   my $payment_gateway =  $self->_payment_gateway( \%options );
 499   my $namespace = $payment_gateway->gateway_namespace;
 500
 501   eval "use $namespace";
 502   die $@ if $@;
 503
 504   ###
 505   # check for banned credit card/ACH
 506   ###
 507
 508   my $ban = FS::banned_pay->ban_search(
 509     'payby'   => $bop_method2payby{$options{method}},
 510     'payinfo' => $options{payinfo},
 511   );
 512   return "Banned credit card" if $ban && $ban->bantype ne 'warn';
 513
 514   ###
 515   # check for term discount validity
 516   ###
 517
 518   my $discount_term = $options{discount_term};
 519   if ( $discount_term ) {
 520     my $bill = ($self->cust_bill)[-1]
 521       or return "Can't apply a term discount to an unbilled customer";
 522     my $plan = FS::discount_plan->new(
 523       cust_bill => $bill,
 524       months    => $discount_term
 525     ) or return "No discount available for term '$discount_term'";
 526
 527     if ( $plan->discounted_total != $options{amount} ) {
 528       return "Incorrect term prepayment amount (term $discount_term, amount $options{amount}, requires ".$plan->discounted_total.")";
 529     }
 530   }
 531
 532   ###
 533   # massage data
 534   ###
 535
 536   my $bop_content = $self->_bop_content(\%options);
 537   return $bop_content unless ref($bop_content);
 538
 539   my @invoicing_list = $self->invoicing_list_emailonly;
 540   if ( $conf->exists('emailinvoiceautoalways')
 541        || $conf->exists('emailinvoiceauto') && ! @invoicing_list
 542        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
 543     push @invoicing_list, $self->all_emails;
 544   }
 545
 546   my $email = ($conf->exists('business-onlinepayment-email-override'))
 547               ? $conf->config('business-onlinepayment-email-override')
 548               : $invoicing_list[0];
 549
 550   my $paydate = '';
 551   my %content = ();
 552
 553   if ( $namespace eq 'Business::OnlinePayment' ) {
 554
 555     if ( $options{method} eq 'CC' ) {
 556
 557       $content{card_number} = $options{payinfo};
 558       $paydate = $options{'paydate'};
 559       $paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
 560       $content{expiration} = "$2/$1";
 561
 562       $content{cvv2} = $options{'paycvv'}
 563         if length($options{'paycvv'});
 564
 565       my $paystart_month = $options{'paystart_month'};
 566       my $paystart_year  = $options{'paystart_year'};
 567       $content{card_start} = "$paystart_month/$paystart_year"
 568         if $paystart_month && $paystart_year;
 569
 570       my $payissue       = $options{'payissue'};
 571       $content{issue_number} = $payissue if $payissue;
 572
 573       if ( $self->_bop_recurring_billing(
 574              'payinfo'        => $options{'payinfo'},
 575              'trans_is_recur' => $trans_is_recur,
 576            )
 577          )
 578       {
 579         $content{recurring_billing} = 'YES';
 580         $content{acct_code} = 'rebill'
 581           if $conf->exists('credit_card-recurring_billing_acct_code');
 582       }
 583
 584     } elsif ( $options{method} eq 'ECHECK' ){
 585
 586       ( $content{account_number}, $content{routing_code} ) =
 587         split('@', $options{payinfo});
 588       $content{bank_name} = $options{payname};
 589       $content{bank_state} = $options{'paystate'};
 590       $content{account_type}= uc($options{'paytype'}) || 'PERSONAL CHECKING';
 591
 592       $content{company} = $self->company if $self->company;
 593
 594       if ( $content{account_type} =~ /BUSINESS/i && $self->company ) {
 595         $content{account_name} = $self->company;
 596       } else {
 597         $content{account_name} = $self->getfield('first'). ' '.
 598                                  $self->getfield('last');
 599       }
 600
 601       $content{customer_org} = $self->company ? 'B' : 'I';
 602       $content{state_id}       = exists($options{'stateid'})
 603                                    ? $options{'stateid'}
 604                                    : $self->getfield('stateid');
 605       $content{state_id_state} = exists($options{'stateid_state'})
 606                                    ? $options{'stateid_state'}
 607                                    : $self->getfield('stateid_state');
 608       $content{customer_ssn} = exists($options{'ss'})
 609                                  ? $options{'ss'}
 610                                  : $self->ss;
 611
 612     } else {
 613       die "unknown method ". $options{method};
 614     }
 615
 616   } elsif ( $namespace eq 'Business::OnlineThirdPartyPayment' ) {
 617     #move along
 618   } else {
 619     die "unknown namespace $namespace";
 620   }
 621
 622   ###
 623   # run transaction(s)
 624   ###
 625
 626   my $balance = exists( $options{'balance'} )
 627                   ? $options{'balance'}
 628                   : $self->balance;
 629
 630   warn "claiming mutex on customer ". $self->custnum. "\n" if $DEBUG > 1;
 631   $self->select_for_update; #mutex ... just until we get our pending record in
 632   warn "obtained mutex on customer ". $self->custnum. "\n" if $DEBUG > 1;
 633
 634   #the checks here are intended to catch concurrent payments
 635   #double-form-submission prevention is taken care of in cust_pay_pending::check
 636
 637   #check the balance
 638   return "The customer's balance has changed; $options{method} transaction aborted."
 639     if $self->balance < $balance;
 640
 641   #also check and make sure there aren't *other* pending payments for this cust
 642
 643   my @pending = qsearch('cust_pay_pending', {
 644     'custnum' => $self->custnum,
 645     'status'  => { op=>'!=', value=>'done' }
 646   });
 647
 648   #for third-party payments only, remove pending payments if they're in the
 649   #'thirdparty' (waiting for customer action) state.
 650   if ( $namespace eq 'Business::OnlineThirdPartyPayment' ) {
 651     foreach ( grep { $_->status eq 'thirdparty' } @pending ) {
 652       my $error = $_->delete;
 653       warn "error deleting unfinished third-party payment ".
 654           $_->paypendingnum . ": $error\n"
 655         if $error;
 656     }
 657     @pending = grep { $_->status ne 'thirdparty' } @pending;
 658   }
 659
 660   return "A payment is already being processed for this customer (".
 661          join(', ', map 'paypendingnum '. $_->paypendingnum, @pending ).
 662          "); $options{method} transaction aborted."
 663     if scalar(@pending);
 664
 665   #okay, good to go, if we're a duplicate, cust_pay_pending will kick us out
 666
 667   my $cust_pay_pending = new FS::cust_pay_pending {
 668     'custnum'           => $self->custnum,
 669     'paid'              => $options{amount},
 670     '_date'             => '',
 671     'payby'             => $bop_method2payby{$options{method}},
 672     'payinfo'           => $options{payinfo},
 673     'paymask'           => $options{paymask},
 674     'paydate'           => $paydate,
 675     'recurring_billing' => $content{recurring_billing},
 676     'pkgnum'            => $options{'pkgnum'},
 677     'status'            => 'new',
 678     'gatewaynum'        => $payment_gateway->gatewaynum || '',
 679     'session_id'        => $options{session_id} || '',
 680     'jobnum'            => $options{depend_jobnum} || '',
 681   };
 682   $cust_pay_pending->payunique( $options{payunique} )
 683     if defined($options{payunique}) && length($options{payunique});
 684
 685   warn "inserting cust_pay_pending record for customer ". $self->custnum. "\n"
 686     if $DEBUG > 1;
 687   my $cpp_new_err = $cust_pay_pending->insert; #mutex lost when this is inserted
 688   return $cpp_new_err if $cpp_new_err;
 689
 690   warn "inserted cust_pay_pending record for customer ". $self->custnum. "\n"
 691     if $DEBUG > 1;
 692   warn Dumper($cust_pay_pending) if $DEBUG > 2;
 693
 694   my( $action1, $action2 ) =
 695     split( /\s*\,\s*/, $payment_gateway->gateway_action );
 696
 697   my $transaction = new $namespace( $payment_gateway->gateway_module,
 698                                     _bop_options(\%options),
 699                                   );
 700
 701   $transaction->content(
 702     'type'           => $options{method},
 703     _bop_auth(\%options),
 704     'action'         => $action1,
 705     'description'    => $options{'description'},
 706     'amount'         => $options{amount},
 707     #'invoice_number' => $options{'invnum'},
 708     'customer_id'    => $self->custnum,
 709     %$bop_content,
 710     'reference'      => $cust_pay_pending->paypendingnum, #for now
 711     'callback_url'   => $payment_gateway->gateway_callback_url,
 712     'cancel_url'     => $payment_gateway->gateway_cancel_url,
 713     'email'          => $email,
 714     %content, #after
 715   );
 716
 717   $cust_pay_pending->status('pending');
 718   my $cpp_pending_err = $cust_pay_pending->replace;
 719   return $cpp_pending_err if $cpp_pending_err;
 720
 721   warn Dumper($transaction) if $DEBUG > 2;
 722
 723   unless ( $BOP_TESTING ) {
 724     $transaction->test_transaction(1)
 725       if $conf->exists('business-onlinepayment-test_transaction');
 726     $transaction->submit();
 727   } else {
 728     if ( $BOP_TESTING_SUCCESS ) {
 729       $transaction->is_success(1);
 730       $transaction->authorization('fake auth');
 731     } else {
 732       $transaction->is_success(0);
 733       $transaction->error_message('fake failure');
 734     }
 735   }
 736
 737   if ( $transaction->is_success() && $namespace eq 'Business::OnlineThirdPartyPayment' ) {
 738
 739     $cust_pay_pending->status('thirdparty');
 740     my $cpp_err = $cust_pay_pending->replace;
 741     return { error => $cpp_err } if $cpp_err;
 742     return { reference => $cust_pay_pending->paypendingnum,
 743              map { $_ => $transaction->$_ } qw ( popup_url collectitems ) };
 744
 745   } elsif ( $transaction->is_success() && $action2 ) {
 746
 747     $cust_pay_pending->status('authorized');
 748     my $cpp_authorized_err = $cust_pay_pending->replace;
 749     return $cpp_authorized_err if $cpp_authorized_err;
 750
 751     my $auth = $transaction->authorization;
 752     my $ordernum = $transaction->can('order_number')
 753                    ? $transaction->order_number
 754                    : '';
 755
 756     my $capture =
 757       new Business::OnlinePayment( $payment_gateway->gateway_module,
 758                                    _bop_options(\%options),
 759                                  );
 760
 761     my %capture = (
 762       %content,
 763       type           => $options{method},
 764       action         => $action2,
 765       _bop_auth(\%options),
 766       order_number   => $ordernum,
 767       amount         => $options{amount},
 768       authorization  => $auth,
 769       description    => $options{'description'},
 770     );
 771
 772     foreach my $field (qw( authorization_source_code returned_ACI
 773                            transaction_identifier validation_code
 774                            transaction_sequence_num local_transaction_date
 775                            local_transaction_time AVS_result_code          )) {
 776       $capture{$field} = $transaction->$field() if $transaction->can($field);
 777     }
 778
 779     $capture->content( %capture );
 780
 781     $capture->test_transaction(1)
 782       if $conf->exists('business-onlinepayment-test_transaction');
 783     $capture->submit();
 784
 785     unless ( $capture->is_success ) {
 786       my $e = "Authorization successful but capture failed, custnum #".
 787               $self->custnum. ': '.  $capture->result_code.
 788               ": ". $capture->error_message;
 789       warn $e;
 790       return $e;
 791     }
 792
 793   }
 794
 795   ###
 796   # remove paycvv after initial transaction
 797   ###
 798
 799   # compare to FS::cust_main::save_cust_payby - check both to make sure working correctly
 800   if ( length($options{'paycvv'})
 801        && ! grep { $_ eq cardtype($options{payinfo}) } $conf->config('cvv-save')
 802   ) {
 803     my $error = $self->remove_cvv_from_cust_payby($options{payinfo});
 804     if ( $error ) {
 805       $log->critical('Error removing cvv for cust '.$self->custnum.': '.$error);
 806       #not returning error, should at least attempt to handle results of an otherwise valid transaction
 807       warn "WARNING: error removing cvv: $error\n";
 808     }
 809   }
 810
 811   ###
 812   # Tokenize
 813   ###
 814
 815   # This block will only run if the B::OP module supports card_token but not the Tokenize transaction;
 816   #   if that never happens, we should get rid of it (as it has the potential to store real card numbers on error)
 817   if (my $card_token = $self->_tokenize_card($transaction,\%options)) {
 818     # cpp will be replaced in _realtime_bop_result
 819     $cust_pay_pending->payinfo($card_token);
 820     if ($options{'cust_payby'} and my $error = $options{'cust_payby'}->replace) {
 821       $log->critical('Error storing token for cust '.$self->custnum.', cust_payby '.$options{'cust_payby'}->custpaybynum.': '.$error);
 822       #not returning error, should at least attempt to handle results of an otherwise valid transaction
 823       #this leaves real card number in cust_payby, but can't do much else if cust_payby won't replace
 824     }
 825   }
 826
 827   ###
 828   # result handling
 829   ###
 830
 831   $self->_realtime_bop_result( $cust_pay_pending, $transaction, %options );
 832
 833 }
 834
 835 =item fake_bop
 836
 837 =cut
 838
 839 sub fake_bop {
 840   my $self = shift;
 841
 842   my %options = ();
 843   if (ref($_[0]) eq 'HASH') {
 844     %options = %{$_[0]};
 845   } else {
 846     my ( $method, $amount ) = ( shift, shift );
 847     %options = @_;
 848     $options{method} = $method;
 849     $options{amount} = $amount;
 850   }
 851
 852   if ( $options{'fake_failure'} ) {
 853      return "Error: No error; test failure requested with fake_failure";
 854   }
 855
 856   my $cust_pay = new FS::cust_pay ( {
 857      'custnum'  => $self->custnum,
 858      'invnum'   => $options{'invnum'},
 859      'paid'     => $options{amount},
 860      '_date'    => '',
 861      'payby'    => $bop_method2payby{$options{method}},
 862      'payinfo'  => '4111111111111111',
 863      'paydate'  => '2012-05-01',
 864      'processor'      => 'FakeProcessor',
 865      'auth'           => '54',
 866      'order_number'   => '32',
 867   } );
 868   $cust_pay->payunique( $options{payunique} ) if length($options{payunique});
 869
 870   if ( $DEBUG ) {
 871       warn "fake_bop\n cust_pay: ". Dumper($cust_pay) . "\n options: ";
 872       warn "  $_ => $options{$_}\n" foreach keys %options;
 873   }
 874
 875   my $error = $cust_pay->insert($options{'manual'} ? ( 'manual' => 1 ) : () );
 876
 877   if ( $error ) {
 878     $cust_pay->invnum(''); #try again with no specific invnum
 879     my $error2 = $cust_pay->insert( $options{'manual'} ?
 880                                     ( 'manual' => 1 ) : ()
 881                                   );
 882     if ( $error2 ) {
 883       # gah, even with transactions.
 884       my $e = 'WARNING: Card/ACH debited but database not updated - '.
 885               "error inserting (fake!) payment: $error2".
 886               " (previously tried insert with invnum #$options{'invnum'}" .
 887               ": $error )";
 888       warn $e;
 889       return $e;
 890     }
 891   }
 892
 893   if ( $options{'paynum_ref'} ) {
 894     ${ $options{'paynum_ref'} } = $cust_pay->paynum;
 895   }
 896
 897   return ''; #no error
 898
 899 }
 900
 901
 902 # item _realtime_bop_result CUST_PAY_PENDING, BOP_OBJECT [ OPTION => VALUE ... ]
 903 #
 904 # Wraps up processing of a realtime credit card or ACH (electronic check)
 905 # transaction.
 906
 907 sub _realtime_bop_result {
 908   my( $self, $cust_pay_pending, $transaction, %options ) = @_;
 909
 910   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 911
 912   if ( $DEBUG ) {
 913     warn "$me _realtime_bop_result: pending transaction ".
 914       $cust_pay_pending->paypendingnum. "\n";
 915     warn "  $_ => $options{$_}\n" foreach keys %options;
 916   }
 917
 918   my $payment_gateway = $options{payment_gateway}
 919     or return "no payment gateway in arguments to _realtime_bop_result";
 920
 921   $cust_pay_pending->status($transaction->is_success() ? 'captured' : 'declined');
 922   my $cpp_captured_err = $cust_pay_pending->replace; #also saves post-transaction tokenization, if that happens
 923   return $cpp_captured_err if $cpp_captured_err;
 924
 925   if ( $transaction->is_success() ) {
 926
 927     my $order_number = $transaction->order_number
 928       if $transaction->can('order_number');
 929
 930     my $cust_pay = new FS::cust_pay ( {
 931        'custnum'  => $self->custnum,
 932        'invnum'   => $options{'invnum'},
 933        'paid'     => $cust_pay_pending->paid,
 934        '_date'    => '',
 935        'payby'    => $cust_pay_pending->payby,
 936        'payinfo'  => $options{'payinfo'},
 937        'paymask'  => $options{'paymask'} || $cust_pay_pending->paymask,
 938        'paydate'  => $cust_pay_pending->paydate,
 939        'pkgnum'   => $cust_pay_pending->pkgnum,
 940        'discount_term'  => $options{'discount_term'},
 941        'gatewaynum'     => ($payment_gateway->gatewaynum || ''),
 942        'processor'      => $payment_gateway->gateway_module,
 943        'auth'           => $transaction->authorization,
 944        'order_number'   => $order_number || '',
 945        'no_auto_apply'  => $options{'no_auto_apply'} ? 'Y' : '',
 946     } );
 947     #doesn't hurt to know, even though the dup check is in cust_pay_pending now
 948     $cust_pay->payunique( $options{payunique} )
 949       if defined($options{payunique}) && length($options{payunique});
 950
 951     my $oldAutoCommit = $FS::UID::AutoCommit;
 952     local $FS::UID::AutoCommit = 0;
 953     my $dbh = dbh;
 954
 955     #start a transaction, insert the cust_pay and set cust_pay_pending.status to done in a single transction
 956
 957     my $error = $cust_pay->insert($options{'manual'} ? ( 'manual' => 1 ) : () );
 958
 959     if ( $error ) {
 960       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 961       $cust_pay->invnum(''); #try again with no specific invnum
 962       $cust_pay->paynum('');
 963       my $error2 = $cust_pay->insert( $options{'manual'} ?
 964                                       ( 'manual' => 1 ) : ()
 965                                     );
 966       if ( $error2 ) {
 967         # gah.  but at least we have a record of the state we had to abort in
 968         # from cust_pay_pending now.
 969         $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 970         my $e = "WARNING: $options{method} captured but payment not recorded -".
 971                 " error inserting payment (". $payment_gateway->gateway_module.
 972                 "): $error2".
 973                 " (previously tried insert with invnum #$options{'invnum'}" .
 974                 ": $error ) - pending payment saved as paypendingnum ".
 975                 $cust_pay_pending->paypendingnum. "\n";
 976         warn $e;
 977         return $e;
 978       }
 979     }
 980
 981     my $jobnum = $cust_pay_pending->jobnum;
 982     if ( $jobnum ) {
 983        my $placeholder = qsearchs( 'queue', { 'jobnum' => $jobnum } );
 984
 985        unless ( $placeholder ) {
 986          $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 987          my $e = "WARNING: $options{method} captured but job $jobnum not ".
 988              "found for paypendingnum ". $cust_pay_pending->paypendingnum. "\n";
 989          warn $e;
 990          return $e;
 991        }
 992
 993        $error = $placeholder->delete;
 994
 995        if ( $error ) {
 996          $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
 997          my $e = "WARNING: $options{method} captured but could not delete ".
 998               "job $jobnum for paypendingnum ".
 999               $cust_pay_pending->paypendingnum. ": $error\n";
1000          warn $e;
1001          return $e;
1002        }
1003
1004        $cust_pay_pending->set('jobnum','');
1005
1006     }
1007
1008     if ( $options{'paynum_ref'} ) {
1009       ${ $options{'paynum_ref'} } = $cust_pay->paynum;
1010     }
1011
1012     $cust_pay_pending->status('done');
1013     $cust_pay_pending->statustext('captured');
1014     $cust_pay_pending->paynum($cust_pay->paynum);
1015     my $cpp_done_err = $cust_pay_pending->replace;
1016
1017     if ( $cpp_done_err ) {
1018
1019       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
1020       my $e = "WARNING: $options{method} captured but payment not recorded - ".
1021               "error updating status for paypendingnum ".
1022               $cust_pay_pending->paypendingnum. ": $cpp_done_err \n";
1023       warn $e;
1024       return $e;
1025
1026     } else {
1027
1028       $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1029
1030       if ( $options{'apply'} ) {
1031         my $apply_error = $self->apply_payments_and_credits;
1032         if ( $apply_error ) {
1033           warn "WARNING: error applying payment: $apply_error\n";
1034           #but we still should return no error cause the payment otherwise went
1035           #through...
1036         }
1037       }
1038
1039       # have a CC surcharge portion --> one-time charge
1040       if ( $options{'cc_surcharge'} > 0 ) {
1041             # XXX: this whole block needs to be in a transaction?
1042
1043           my $invnum;
1044           $invnum = $options{'invnum'} if $options{'invnum'};
1045           unless ( $invnum ) { # probably from a payment screen
1046              # do we have any open invoices? pick earliest
1047              # uses the fact that cust_main->cust_bill sorts by date ascending
1048              my @open = $self->open_cust_bill;
1049              $invnum = $open[0]->invnum if scalar(@open);
1050           }
1051
1052           unless ( $invnum ) {  # still nothing? pick last closed invoice
1053              # again uses fact that cust_main->cust_bill sorts by date ascending
1054              my @closed = $self->cust_bill;
1055              $invnum = $closed[$#closed]->invnum if scalar(@closed);
1056           }
1057
1058           unless ( $invnum ) {
1059             # XXX: unlikely case - pre-paying before any invoices generated
1060             # what it should do is create a new invoice and pick it
1061                 warn 'CC SURCHARGE AND NO INVOICES PICKED TO APPLY IT!';
1062                 return '';
1063           }
1064
1065           my $cust_pkg;
1066           my $charge_error = $self->charge({
1067                                     'amount'    => $options{'cc_surcharge'},
1068                                     'pkg'       => 'Credit Card Surcharge',
1069                                     'setuptax'  => 'Y',
1070                                     'cust_pkg_ref' => \$cust_pkg,
1071                                 });
1072           if($charge_error) {
1073                 warn 'Unable to add CC surcharge cust_pkg';
1074                 return '';
1075           }
1076
1077           $cust_pkg->setup(time);
1078           my $cp_error = $cust_pkg->replace;
1079           if($cp_error) {
1080               warn 'Unable to set setup time on cust_pkg for cc surcharge';
1081             # but keep going...
1082           }
1083
1084           my $cust_bill = qsearchs('cust_bill', { 'invnum' => $invnum });
1085           unless ( $cust_bill ) {
1086               warn "race condition + invoice deletion just happened";
1087               return '';
1088           }
1089
1090           my $grand_error =
1091             $cust_bill->add_cc_surcharge($cust_pkg->pkgnum,$options{'cc_surcharge'});
1092
1093           warn "cannot add CC surcharge to invoice #$invnum: $grand_error"
1094             if $grand_error;
1095       }
1096
1097       return ''; #no error
1098
1099     }
1100
1101   } else {
1102
1103     my $perror = $transaction->error_message;
1104     #$payment_gateway->gateway_module. " error: ".
1105     # removed for conciseness
1106
1107     my $jobnum = $cust_pay_pending->jobnum;
1108     if ( $jobnum ) {
1109        my $placeholder = qsearchs( 'queue', { 'jobnum' => $jobnum } );
1110
1111        if ( $placeholder ) {
1112          my $error = $placeholder->depended_delete;
1113          $error ||= $placeholder->delete;
1114          $cust_pay_pending->set('jobnum','');
1115          warn "error removing provisioning jobs after declined paypendingnum ".
1116            $cust_pay_pending->paypendingnum. ": $error\n" if $error;
1117        } else {
1118          my $e = "error finding job $jobnum for declined paypendingnum ".
1119               $cust_pay_pending->paypendingnum. "\n";
1120          warn $e;
1121        }
1122
1123     }
1124
1125     unless ( $transaction->error_message ) {
1126
1127       my $t_response;
1128       if ( $transaction->can('response_page') ) {
1129         $t_response = {
1130                         'page'    => ( $transaction->can('response_page')
1131                                          ? $transaction->response_page
1132                                          : ''
1133                                      ),
1134                         'code'    => ( $transaction->can('response_code')
1135                                          ? $transaction->response_code
1136                                          : ''
1137                                      ),
1138                         'headers' => ( $transaction->can('response_headers')
1139                                          ? $transaction->response_headers
1140                                          : ''
1141                                      ),
1142                       };
1143       } else {
1144         $t_response .=
1145           "No additional debugging information available for ".
1146             $payment_gateway->gateway_module;
1147       }
1148
1149       $perror .= "No error_message returned from ".
1150                    $payment_gateway->gateway_module. " -- ".
1151                  ( ref($t_response) ? Dumper($t_response) : $t_response );
1152
1153     }
1154
1155     if ( !$options{'quiet'} && !$realtime_bop_decline_quiet
1156          && $conf->exists('emaildecline', $self->agentnum)
1157          && grep { $_ ne 'POST' } $self->invoicing_list
1158          && ! grep { $transaction->error_message =~ /$_/ }
1159                    $conf->config('emaildecline-exclude', $self->agentnum)
1160     ) {
1161
1162       # Send a decline alert to the customer.
1163       my $msgnum = $conf->config('decline_msgnum', $self->agentnum);
1164       my $error = '';
1165       if ( $msgnum ) {
1166         # include the raw error message in the transaction state
1167         $cust_pay_pending->setfield('error', $transaction->error_message);
1168         my $msg_template = qsearchs('msg_template', { msgnum => $msgnum });
1169         $error = $msg_template->send( 'cust_main' => $self,
1170                                       'object'    => $cust_pay_pending );
1171       }
1172
1173
1174       $perror .= " (also received error sending decline notification: $error)"
1175         if $error;
1176
1177     }
1178
1179     $cust_pay_pending->status('done');
1180     $cust_pay_pending->statustext($perror);
1181     #'declined:': no, that's failure_status
1182     if ( $transaction->can('failure_status') ) {
1183       $cust_pay_pending->failure_status( $transaction->failure_status );
1184     }
1185     my $cpp_done_err = $cust_pay_pending->replace;
1186     if ( $cpp_done_err ) {
1187       my $e = "WARNING: $options{method} declined but pending payment not ".
1188               "resolved - error updating status for paypendingnum ".
1189               $cust_pay_pending->paypendingnum. ": $cpp_done_err \n";
1190       warn $e;
1191       $perror = "$e ($perror)";
1192     }
1193
1194     return $perror;
1195   }
1196
1197 }
1198
1199 =item realtime_botpp_capture CUST_PAY_PENDING [ OPTION => VALUE ... ]
1200
1201 Verifies successful third party processing of a realtime credit card or
1202 ACH (electronic check) transaction via a
1203 Business::OnlineThirdPartyPayment realtime gateway.  See
1204 L<http://420.am/business-onlinethirdpartypayment> for supported gateways.
1205
1206 Available options are: I<description>, I<invnum>, I<quiet>, I<paynum_ref>, I<payunique>
1207
1208 The additional options I<payname>, I<city>, I<state>,
1209 I<zip>, I<payinfo> and I<paydate> are also available.  Any of these options,
1210 if set, will override the value from the customer record.
1211
1212 I<description> is a free-text field passed to the gateway.  It defaults to
1213 "Internet services".
1214
1215 If an I<invnum> is specified, this payment (if successful) is applied to the
1216 specified invoice.  If you don't specify an I<invnum> you might want to
1217 call the B<apply_payments> method.
1218
1219 I<quiet> can be set true to surpress email decline notices.
1220
1221 I<paynum_ref> can be set to a scalar reference.  It will be filled in with the
1222 resulting paynum, if any.
1223
1224 I<payunique> is a unique identifier for this payment.
1225
1226 Returns a hashref containing elements bill_error (which will be undefined
1227 upon success) and session_id of any associated session.
1228
1229 =cut
1230
1231 sub realtime_botpp_capture {
1232   my( $self, $cust_pay_pending, %options ) = @_;
1233
1234   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1235
1236   if ( $DEBUG ) {
1237     warn "$me realtime_botpp_capture: pending transaction $cust_pay_pending\n";
1238     warn "  $_ => $options{$_}\n" foreach keys %options;
1239   }
1240
1241   eval "use Business::OnlineThirdPartyPayment";
1242   die $@ if $@;
1243
1244   ###
1245   # select the gateway
1246   ###
1247
1248   my $method = FS::payby->payby2bop($cust_pay_pending->payby);
1249
1250   my $payment_gateway;
1251   my $gatewaynum = $cust_pay_pending->getfield('gatewaynum');
1252   $payment_gateway = $gatewaynum ? qsearchs( 'payment_gateway',
1253                 { gatewaynum => $gatewaynum }
1254               )
1255     : $self->agent->payment_gateway( 'method' => $method,
1256                                      # 'invnum'  => $cust_pay_pending->invnum,
1257                                      # 'payinfo' => $cust_pay_pending->payinfo,
1258                                    );
1259
1260   $options{payment_gateway} = $payment_gateway; # for the helper subs
1261
1262   ###
1263   # massage data
1264   ###
1265
1266   my @invoicing_list = $self->invoicing_list_emailonly;
1267   if ( $conf->exists('emailinvoiceautoalways')
1268        || $conf->exists('emailinvoiceauto') && ! @invoicing_list
1269        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
1270     push @invoicing_list, $self->all_emails;
1271   }
1272
1273   my $email = ($conf->exists('business-onlinepayment-email-override'))
1274               ? $conf->config('business-onlinepayment-email-override')
1275               : $invoicing_list[0];
1276
1277   my %content = ();
1278
1279   $content{email_customer} =
1280     (    $conf->exists('business-onlinepayment-email_customer')
1281       || $conf->exists('business-onlinepayment-email-override') );
1282
1283   ###
1284   # run transaction(s)
1285   ###
1286
1287   my $transaction =
1288     new Business::OnlineThirdPartyPayment( $payment_gateway->gateway_module,
1289                                            _bop_options(\%options),
1290                                          );
1291
1292   $transaction->reference({ %options });
1293
1294   $transaction->content(
1295     'type'           => $method,
1296     _bop_auth(\%options),
1297     'action'         => 'Post Authorization',
1298     'description'    => $options{'description'},
1299     'amount'         => $cust_pay_pending->paid,
1300     #'invoice_number' => $options{'invnum'},
1301     'customer_id'    => $self->custnum,
1302     'reference'      => $cust_pay_pending->paypendingnum,
1303     'email'          => $email,
1304     'phone'          => $self->daytime || $self->night,
1305     %content, #after
1306     # plus whatever is required for bogus capture avoidance
1307   );
1308
1309   $transaction->submit();
1310
1311   my $error =
1312     $self->_realtime_bop_result( $cust_pay_pending, $transaction, %options );
1313
1314   if ( $options{'apply'} ) {
1315     my $apply_error = $self->apply_payments_and_credits;
1316     if ( $apply_error ) {
1317       warn "WARNING: error applying payment: $apply_error\n";
1318     }
1319   }
1320
1321   return {
1322     bill_error => $error,
1323     session_id => $cust_pay_pending->session_id,
1324   }
1325
1326 }
1327
1328 =item default_payment_gateway
1329
1330 DEPRECATED -- use agent->payment_gateway
1331
1332 =cut
1333
1334 sub default_payment_gateway {
1335   my( $self, $method ) = @_;
1336
1337   die "Real-time processing not enabled\n"
1338     unless $conf->exists('business-onlinepayment');
1339
1340   #warn "default_payment_gateway deprecated -- use agent->payment_gateway\n";
1341
1342   #load up config
1343   my $bop_config = 'business-onlinepayment';
1344   $bop_config .= '-ach'
1345     if $method =~ /^(ECHECK|CHEK)$/ && $conf->exists($bop_config. '-ach');
1346   my ( $processor, $login, $password, $action, @bop_options ) =
1347     $conf->config($bop_config);
1348   $action ||= 'normal authorization';
1349   pop @bop_options if scalar(@bop_options) % 2 && $bop_options[-1] =~ /^\s*$/;
1350   die "No real-time processor is enabled - ".
1351       "did you set the business-onlinepayment configuration value?\n"
1352     unless $processor;
1353
1354   ( $processor, $login, $password, $action, @bop_options )
1355 }
1356
1357 =item realtime_refund_bop METHOD [ OPTION => VALUE ... ]
1358
1359 Refunds a realtime credit card or ACH (electronic check) transaction
1360 via a Business::OnlinePayment realtime gateway.  See
1361 L<http://420.am/business-onlinepayment> for supported gateways.
1362
1363 Available methods are: I<CC> or I<ECHECK>
1364
1365 Available options are: I<amount>, I<reasonnum>, I<paynum>, I<paydate>
1366
1367 Most gateways require a reference to an original payment transaction to refund,
1368 so you probably need to specify a I<paynum>.
1369
1370 I<amount> defaults to the original amount of the payment if not specified.
1371
1372 I<reasonnum> specified an existing refund reason for the refund
1373
1374 I<paydate> specifies the expiration date for a credit card overriding the
1375 value from the customer record or the payment record. Specified as yyyy-mm-dd
1376
1377 Implementation note: If I<amount> is unspecified or equal to the amount of the
1378 orignal payment, first an attempt is made to "void" the transaction via
1379 the gateway (to cancel a not-yet settled transaction) and then if that fails,
1380 the normal attempt is made to "refund" ("credit") the transaction via the
1381 gateway is attempted. No attempt to "void" the transaction is made if the
1382 gateway has introspection data and doesn't support void.
1383
1384 #The additional options I<payname>, I<address1>, I<address2>, I<city>, I<state>,
1385 #I<zip>, I<payinfo> and I<paydate> are also available.  Any of these options,
1386 #if set, will override the value from the customer record.
1387
1388 #If an I<invnum> is specified, this payment (if successful) is applied to the
1389 #specified invoice.  If you don't specify an I<invnum> you might want to
1390 #call the B<apply_payments> method.
1391
1392 =cut
1393
1394 #some false laziness w/realtime_bop, not enough to make it worth merging
1395 #but some useful small subs should be pulled out
1396 sub realtime_refund_bop {
1397   my $self = shift;
1398
1399   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1400
1401   my %options = ();
1402   if (ref($_[0]) eq 'HASH') {
1403     %options = %{$_[0]};
1404   } else {
1405     my $method = shift;
1406     %options = @_;
1407     $options{method} = $method;
1408   }
1409
1410   if ( $DEBUG ) {
1411     warn "$me realtime_refund_bop (new): $options{method} refund\n";
1412     warn "  $_ => $options{$_}\n" foreach keys %options;
1413   }
1414
1415   return "No reason specified" unless $options{'reasonnum'} =~ /^\d+$/;
1416
1417   my %content = ();
1418
1419   ###
1420   # look up the original payment and optionally a gateway for that payment
1421   ###
1422
1423   my $cust_pay = '';
1424   my $amount = $options{'amount'};
1425
1426   my( $processor, $login, $password, @bop_options, $namespace ) ;
1427   my( $auth, $order_number ) = ( '', '', '' );
1428   my $gatewaynum = '';
1429
1430   if ( $options{'paynum'} ) {
1431
1432     warn "  paynum: $options{paynum}\n" if $DEBUG > 1;
1433     $cust_pay = qsearchs('cust_pay', { paynum=>$options{'paynum'} } )
1434       or return "Unknown paynum $options{'paynum'}";
1435     $amount ||= $cust_pay->paid;
1436
1437     my @cust_bill_pay = qsearch('cust_bill_pay', { paynum=>$cust_pay->paynum });
1438     $content{'invoice_number'} = $cust_bill_pay[0]->invnum if @cust_bill_pay;
1439
1440     if ( $cust_pay->get('processor') ) {
1441       ($gatewaynum, $processor, $auth, $order_number) =
1442       (
1443         $cust_pay->gatewaynum,
1444         $cust_pay->processor,
1445         $cust_pay->auth,
1446         $cust_pay->order_number,
1447       );
1448     } else {
1449       # this payment wasn't upgraded, which probably means this won't work,
1450       # but try it anyway
1451       $cust_pay->paybatch =~ /^((\d+)\-)?(\w+):\s*([\w\-\/ ]*)(:([\w\-]+))?$/
1452         or return "Can't parse paybatch for paynum $options{'paynum'}: ".
1453                   $cust_pay->paybatch;
1454       ( $gatewaynum, $processor, $auth, $order_number ) = ( $2, $3, $4, $6 );
1455     }
1456
1457     if ( $gatewaynum ) { #gateway for the payment to be refunded
1458
1459       my $payment_gateway =
1460         qsearchs('payment_gateway', { 'gatewaynum' => $gatewaynum } );
1461       die "payment gateway $gatewaynum not found"
1462         unless $payment_gateway;
1463
1464       $processor   = $payment_gateway->gateway_module;
1465       $login       = $payment_gateway->gateway_username;
1466       $password    = $payment_gateway->gateway_password;
1467       $namespace   = $payment_gateway->gateway_namespace;
1468       @bop_options = $payment_gateway->options;
1469
1470     } else { #try the default gateway
1471
1472       my $conf_processor;
1473       my $payment_gateway =
1474         $self->agent->payment_gateway('method' => $options{method});
1475
1476       ( $conf_processor, $login, $password, $namespace ) =
1477         map { my $method = "gateway_$_"; $payment_gateway->$method }
1478           qw( module username password namespace );
1479
1480       @bop_options = $payment_gateway->gatewaynum
1481                        ? $payment_gateway->options
1482                        : @{ $payment_gateway->get('options') };
1483
1484       return "processor of payment $options{'paynum'} $processor does not".
1485              " match default processor $conf_processor"
1486         unless $processor eq $conf_processor;
1487
1488     }
1489
1490
1491   } else { # didn't specify a paynum, so look for agent gateway overrides
1492            # like a normal transaction
1493
1494     my $payment_gateway =
1495       $self->agent->payment_gateway( 'method'  => $options{method},
1496                                      #'payinfo' => $payinfo,
1497                                    );
1498     my( $processor, $login, $password, $namespace ) =
1499       map { my $method = "gateway_$_"; $payment_gateway->$method }
1500         qw( module username password namespace );
1501
1502     my @bop_options = $payment_gateway->gatewaynum
1503                         ? $payment_gateway->options
1504                         : @{ $payment_gateway->get('options') };
1505
1506   }
1507   return "neither amount nor paynum specified" unless $amount;
1508
1509   eval "use $namespace";
1510   die $@ if $@;
1511
1512   %content = (
1513     %content,
1514     'type'           => $options{method},
1515     'login'          => $login,
1516     'password'       => $password,
1517     'order_number'   => $order_number,
1518     'amount'         => $amount,
1519   );
1520   $content{authorization} = $auth
1521     if length($auth); #echeck/ACH transactions have an order # but no auth
1522                       #(at least with authorize.net)
1523
1524   my $currency =    $conf->exists('business-onlinepayment-currency')
1525                  && $conf->config('business-onlinepayment-currency');
1526   $content{currency} = $currency if $currency;
1527
1528   my $disable_void_after;
1529   if ($conf->exists('disable_void_after')
1530       && $conf->config('disable_void_after') =~ /^(\d+)$/) {
1531     $disable_void_after = $1;
1532   }
1533
1534   #first try void if applicable
1535   my $void = new Business::OnlinePayment( $processor, @bop_options );
1536
1537   my $tryvoid = 1;
1538   if ($void->can('info')) {
1539       my $paytype = '';
1540       $paytype = 'ECHECK' if $cust_pay && $cust_pay->payby eq 'CHEK';
1541       $paytype = 'CC' if $cust_pay && $cust_pay->payby eq 'CARD';
1542       my %supported_actions = $void->info('supported_actions');
1543       $tryvoid = 0
1544         if ( %supported_actions && $paytype
1545                 && defined($supported_actions{$paytype})
1546                 && !grep{ $_ eq 'Void' } @{$supported_actions{$paytype}} );
1547   }
1548
1549   if ( $cust_pay && $cust_pay->paid == $amount
1550     && (
1551       ( not defined($disable_void_after) )
1552       || ( time < ($cust_pay->_date + $disable_void_after ) )
1553     )
1554     && $tryvoid
1555   ) {
1556     warn "  attempting void\n" if $DEBUG > 1;
1557     if ( $void->can('info') ) {
1558       if ( $cust_pay->payby eq 'CARD'
1559            && $void->info('CC_void_requires_card') )
1560       {
1561         $content{'card_number'} = $cust_pay->payinfo;
1562       } elsif ( $cust_pay->payby eq 'CHEK'
1563                 && $void->info('ECHECK_void_requires_account') )
1564       {
1565         ( $content{'account_number'}, $content{'routing_code'} ) =
1566           split('@', $cust_pay->payinfo);
1567         $content{'name'} = $self->get('first'). ' '. $self->get('last');
1568       }
1569     }
1570     $void->content( 'action' => 'void', %content );
1571     $void->test_transaction(1)
1572       if $conf->exists('business-onlinepayment-test_transaction');
1573     $void->submit();
1574     if ( $void->is_success ) {
1575       # specified as a refund reason, but now we want a payment void reason
1576       # extract just the reason text, let cust_pay::void handle new_or_existing
1577       my $reason = qsearchs('reason',{ 'reasonnum' => $options{'reasonnum'} });
1578       my $error;
1579       $error = 'Reason could not be loaded' unless $reason;
1580       $error = $cust_pay->void($reason->reason) unless $error;
1581       if ( $error ) {
1582         # gah, even with transactions.
1583         my $e = 'WARNING: Card/ACH voided but database not updated - '.
1584                 "error voiding payment: $error";
1585         warn $e;
1586         return $e;
1587       }
1588       warn "  void successful\n" if $DEBUG > 1;
1589       return '';
1590     }
1591   }
1592
1593   warn "  void unsuccessful, trying refund\n"
1594     if $DEBUG > 1;
1595
1596   #massage data
1597   my $address = $self->address1;
1598   $address .= ", ". $self->address2 if $self->address2;
1599
1600   my($payname, $payfirst, $paylast);
1601   if ( $self->payname && $options{method} ne 'ECHECK' ) {
1602     $payname = $self->payname;
1603     $payname =~ /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)\s*$/
1604       or return "Illegal payname $payname";
1605     ($payfirst, $paylast) = ($1, $2);
1606   } else {
1607     $payfirst = $self->getfield('first');
1608     $paylast = $self->getfield('last');
1609     $payname =  "$payfirst $paylast";
1610   }
1611
1612   my @invoicing_list = $self->invoicing_list_emailonly;
1613   if ( $conf->exists('emailinvoiceautoalways')
1614        || $conf->exists('emailinvoiceauto') && ! @invoicing_list
1615        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
1616     push @invoicing_list, $self->all_emails;
1617   }
1618
1619   my $email = ($conf->exists('business-onlinepayment-email-override'))
1620               ? $conf->config('business-onlinepayment-email-override')
1621               : $invoicing_list[0];
1622
1623   my $payip = exists($options{'payip'})
1624                 ? $options{'payip'}
1625                 : $self->payip;
1626   $content{customer_ip} = $payip
1627     if length($payip);
1628
1629   my $payinfo = '';
1630   if ( $options{method} eq 'CC' ) {
1631
1632     if ( $cust_pay ) {
1633       $content{card_number} = $payinfo = $cust_pay->payinfo;
1634       (exists($options{'paydate'}) ? $options{'paydate'} : $cust_pay->paydate)
1635         =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/ &&
1636         ($content{expiration} = "$2/$1");  # where available
1637     } else {
1638       $content{card_number} = $payinfo = $self->payinfo;
1639       (exists($options{'paydate'}) ? $options{'paydate'} : $self->paydate)
1640         =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
1641       $content{expiration} = "$2/$1";
1642     }
1643
1644   } elsif ( $options{method} eq 'ECHECK' ) {
1645
1646     if ( $cust_pay ) {
1647       $payinfo = $cust_pay->payinfo;
1648     } else {
1649       $payinfo = $self->payinfo;
1650     }
1651     ( $content{account_number}, $content{routing_code} )= split('@', $payinfo );
1652     $content{bank_name} = $self->payname;
1653     $content{account_type} = 'CHECKING';
1654     $content{account_name} = $payname;
1655     $content{customer_org} = $self->company ? 'B' : 'I';
1656     $content{customer_ssn} = $self->ss;
1657
1658   }
1659
1660   #then try refund
1661   my $refund = new Business::OnlinePayment( $processor, @bop_options );
1662   my %sub_content = $refund->content(
1663     'action'         => 'credit',
1664     'customer_id'    => $self->custnum,
1665     'last_name'      => $paylast,
1666     'first_name'     => $payfirst,
1667     'name'           => $payname,
1668     'address'        => $address,
1669     'city'           => $self->city,
1670     'state'          => $self->state,
1671     'zip'            => $self->zip,
1672     'country'        => $self->country,
1673     'email'          => $email,
1674     'phone'          => $self->daytime || $self->night,
1675     %content, #after
1676   );
1677   warn join('', map { "  $_ => $sub_content{$_}\n" } keys %sub_content )
1678     if $DEBUG > 1;
1679   $refund->test_transaction(1)
1680     if $conf->exists('business-onlinepayment-test_transaction');
1681   $refund->submit();
1682
1683   return "$processor error: ". $refund->error_message
1684     unless $refund->is_success();
1685
1686   $order_number = $refund->order_number if $refund->can('order_number');
1687
1688   # change this to just use $cust_pay->delete_cust_bill_pay?
1689   while ( $cust_pay && $cust_pay->unapplied < $amount ) {
1690     my @cust_bill_pay = $cust_pay->cust_bill_pay;
1691     last unless @cust_bill_pay;
1692     my $cust_bill_pay = pop @cust_bill_pay;
1693     my $error = $cust_bill_pay->delete;
1694     last if $error;
1695   }
1696
1697   my $cust_refund = new FS::cust_refund ( {
1698     'custnum'  => $self->custnum,
1699     'paynum'   => $options{'paynum'},
1700     'source_paynum' => $options{'paynum'},
1701     'refund'   => $amount,
1702     '_date'    => '',
1703     'payby'    => $bop_method2payby{$options{method}},
1704     'payinfo'  => $payinfo,
1705     'reasonnum'     => $options{'reasonnum'},
1706     'gatewaynum'    => $gatewaynum, # may be null
1707     'processor'     => $processor,
1708     'auth'          => $refund->authorization,
1709     'order_number'  => $order_number,
1710   } );
1711   my $error = $cust_refund->insert;
1712   if ( $error ) {
1713     $cust_refund->paynum(''); #try again with no specific paynum
1714     $cust_refund->source_paynum('');
1715     my $error2 = $cust_refund->insert;
1716     if ( $error2 ) {
1717       # gah, even with transactions.
1718       my $e = 'WARNING: Card/ACH refunded but database not updated - '.
1719               "error inserting refund ($processor): $error2".
1720               " (previously tried insert with paynum #$options{'paynum'}" .
1721               ": $error )";
1722       warn $e;
1723       return $e;
1724     }
1725   }
1726
1727   ''; #no error
1728
1729 }
1730
1731 =item realtime_verify_bop [ OPTION => VALUE ... ]
1732
1733 Runs an authorization-only transaction for $1 against this credit card (if
1734 successful, immediatly reverses the authorization).
1735
1736 Returns the empty string if the authorization was sucessful, or an error
1737 message otherwise.
1738
1739 Option I<cust_payby> should be passed, even if it's not yet been inserted.
1740 Object will be tokenized if possible, but that change will not be
1741 updated in database (must be inserted/replaced afterwards.)
1742
1743 Currently only succeeds for Business::OnlinePayment CC transactions.
1744
1745 =cut
1746
1747 #some false laziness w/realtime_bop and realtime_refund_bop, not enough to make
1748 #it worth merging but some useful small subs should be pulled out
1749 sub realtime_verify_bop {
1750   my $self = shift;
1751
1752   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1753   my $log = FS::Log->new('FS::cust_main::Billing_Realtime::realtime_verify_bop');
1754
1755   my %options = ();
1756   if (ref($_[0]) eq 'HASH') {
1757     %options = %{$_[0]};
1758   } else {
1759     %options = @_;
1760   }
1761
1762   if ( $DEBUG ) {
1763     warn "$me realtime_verify_bop\n";
1764     warn "  $_ => $options{$_}\n" foreach keys %options;
1765   }
1766
1767   # set fields from passed cust_payby
1768   return "No cust_payby" unless $options{'cust_payby'};
1769   _bop_cust_payby_options(\%options);
1770
1771   # possibly run a separate transaction to tokenize card number,
1772   #   so that we never store tokenized card info in cust_pay_pending
1773   if (($options{method} eq 'CC') && !$self->tokenized($options{'payinfo'})) {
1774     my $token_error = $self->realtime_tokenize(\%options);
1775     return $token_error if $token_error;
1776     #important that we not replace cust_payby here,
1777     #because cust_payby->replace uses realtime_verify_bop!
1778   }
1779
1780   ###
1781   # select a gateway
1782   ###
1783
1784   my $payment_gateway =  $self->_payment_gateway( \%options );
1785   my $namespace = $payment_gateway->gateway_namespace;
1786
1787   eval "use $namespace";
1788   die $@ if $@;
1789
1790   ###
1791   # check for banned credit card/ACH
1792   ###
1793
1794   my $ban = FS::banned_pay->ban_search(
1795     'payby'   => $bop_method2payby{'CC'},
1796     'payinfo' => $options{payinfo},
1797   );
1798   return "Banned credit card" if $ban && $ban->bantype ne 'warn';
1799
1800   ###
1801   # massage data
1802   ###
1803
1804   my $bop_content = $self->_bop_content(\%options);
1805   return $bop_content unless ref($bop_content);
1806
1807   my @invoicing_list = $self->invoicing_list_emailonly;
1808   if ( $conf->exists('emailinvoiceautoalways')
1809        || $conf->exists('emailinvoiceauto') && ! @invoicing_list
1810        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
1811     push @invoicing_list, $self->all_emails;
1812   }
1813
1814   my $email = ($conf->exists('business-onlinepayment-email-override'))
1815               ? $conf->config('business-onlinepayment-email-override')
1816               : $invoicing_list[0];
1817
1818   my $paydate = '';
1819   my %content = ();
1820
1821   if ( $namespace eq 'Business::OnlinePayment' ) {
1822
1823     if ( $options{method} eq 'CC' ) {
1824
1825       $content{card_number} = $options{payinfo};
1826       $paydate = $options{'paydate'};
1827       $paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
1828       $content{expiration} = "$2/$1";
1829
1830       $content{cvv2} = $options{'paycvv'}
1831         if length($options{'paycvv'});
1832
1833       my $paystart_month = $options{'paystart_month'};
1834       my $paystart_year  = $options{'paystart_year'};
1835
1836       $content{card_start} = "$paystart_month/$paystart_year"
1837         if $paystart_month && $paystart_year;
1838
1839       my $payissue       = $options{'payissue'};
1840       $content{issue_number} = $payissue if $payissue;
1841
1842     } elsif ( $options{method} eq 'ECHECK' ){
1843       #cannot verify, move along (though it shouldn't be called...)
1844       return '';
1845     } else {
1846       return "unknown method ". $options{method};
1847     }
1848   } elsif ( $namespace eq 'Business::OnlineThirdPartyPayment' ) {
1849     #cannot verify, move along
1850     return '';
1851   } else {
1852     return "unknown namespace $namespace";
1853   }
1854
1855   ###
1856   # run transaction(s)
1857   ###
1858
1859   my $error;
1860   my $transaction; #need this back so we can do _tokenize_card
1861
1862   # don't mutex the customer here, because they might be uncommitted. and
1863   # this is only verification. it doesn't matter if they have other
1864   # unfinished verifications.
1865
1866   my $cust_pay_pending = new FS::cust_pay_pending {
1867     'custnum_pending'   => 1,
1868     'paid'              => '1.00',
1869     '_date'             => '',
1870     'payby'             => $bop_method2payby{'CC'},
1871     'payinfo'           => $options{payinfo},
1872     'paymask'           => $options{paymask},
1873     'paydate'           => $paydate,
1874     'pkgnum'            => $options{'pkgnum'},
1875     'status'            => 'new',
1876     'gatewaynum'        => $payment_gateway->gatewaynum || '',
1877     'session_id'        => $options{session_id} || '',
1878   };
1879   $cust_pay_pending->payunique( $options{payunique} )
1880     if defined($options{payunique}) && length($options{payunique});
1881
1882   IMMEDIATE: {
1883     # open a separate handle for creating/updating the cust_pay_pending
1884     # record
1885     local $FS::UID::dbh = myconnect();
1886     local $FS::UID::AutoCommit = 1;
1887
1888     # if this is an existing customer (and we can tell now because
1889     # this is a fresh transaction), it's safe to assign their custnum
1890     # to the cust_pay_pending record, and then the verification attempt
1891     # will remain linked to them even if it fails.
1892     if ( FS::cust_main->by_key($self->custnum) ) {
1893       $cust_pay_pending->set('custnum', $self->custnum);
1894     }
1895
1896     warn "inserting cust_pay_pending record for customer ". $self->custnum. "\n"
1897       if $DEBUG > 1;
1898
1899     # if this fails, just return; everything else will still allow the
1900     # cust_pay_pending to have its custnum set later
1901     my $cpp_new_err = $cust_pay_pending->insert;
1902     return $cpp_new_err if $cpp_new_err;
1903
1904     warn "inserted cust_pay_pending record for customer ". $self->custnum. "\n"
1905       if $DEBUG > 1;
1906     warn Dumper($cust_pay_pending) if $DEBUG > 2;
1907
1908     $transaction = new $namespace( $payment_gateway->gateway_module,
1909                                    _bop_options(\%options),
1910                                     );
1911
1912     $transaction->content(
1913       'type'           => 'CC',
1914       _bop_auth(\%options),
1915       'action'         => 'Authorization Only',
1916       'description'    => $options{'description'},
1917       'amount'         => '1.00',
1918       'customer_id'    => $self->custnum,
1919       %$bop_content,
1920       'reference'      => $cust_pay_pending->paypendingnum, #for now
1921       'email'          => $email,
1922       %content, #after
1923     );
1924
1925     $cust_pay_pending->status('pending');
1926     my $cpp_pending_err = $cust_pay_pending->replace;
1927     return $cpp_pending_err if $cpp_pending_err;
1928
1929     warn Dumper($transaction) if $DEBUG > 2;
1930
1931     unless ( $BOP_TESTING ) {
1932       $transaction->test_transaction(1)
1933         if $conf->exists('business-onlinepayment-test_transaction');
1934       $transaction->submit();
1935     } else {
1936       if ( $BOP_TESTING_SUCCESS ) {
1937         $transaction->is_success(1);
1938         $transaction->authorization('fake auth');
1939       } else {
1940         $transaction->is_success(0);
1941         $transaction->error_message('fake failure');
1942       }
1943     }
1944
1945     if ( $transaction->is_success() ) {
1946
1947       $cust_pay_pending->status('authorized');
1948       my $cpp_authorized_err = $cust_pay_pending->replace;
1949       return $cpp_authorized_err if $cpp_authorized_err;
1950
1951       my $auth = $transaction->authorization;
1952       my $ordernum = $transaction->can('order_number')
1953                      ? $transaction->order_number
1954                      : '';
1955
1956       my $reverse = new $namespace( $payment_gateway->gateway_module,
1957                                     _bop_options(\%options),
1958                                   );
1959
1960       $reverse->content( 'action'        => 'Reverse Authorization',
1961                          _bop_auth(\%options),
1962
1963                          # B:OP
1964                          'amount'        => '1.00',
1965                          'authorization' => $transaction->authorization,
1966                          'order_number'  => $ordernum,
1967
1968                          # vsecure
1969                          'result_code'   => $transaction->result_code,
1970                          'txn_date'      => $transaction->txn_date,
1971
1972                          %content,
1973                        );
1974       $reverse->test_transaction(1)
1975         if $conf->exists('business-onlinepayment-test_transaction');
1976       $reverse->submit();
1977
1978       if ( $reverse->is_success ) {
1979
1980         $cust_pay_pending->status('done');
1981         $cust_pay_pending->statustext('reversed');
1982         my $cpp_reversed_err = $cust_pay_pending->replace;
1983         return $cpp_reversed_err if $cpp_reversed_err;
1984
1985       } else {
1986
1987         my $e = "Authorization successful but reversal failed, custnum #".
1988                 $self->custnum. ': '.  $reverse->result_code.
1989                 ": ". $reverse->error_message;
1990         $log->warning($e);
1991         warn $e;
1992         return $e;
1993
1994       }
1995
1996       ### Address Verification ###
1997       #
1998       # Single-letter codes vary by cardtype.
1999       #
2000       # Erring on the side of accepting cards if avs is not available,
2001       # only rejecting if avs occurred and there's been an explicit mismatch
2002       #
2003       # Charts below taken from vSecure documentation,
2004       #    shows codes for Amex/Dscv/MC/Visa
2005       #
2006       # ACCEPTABLE AVS RESPONSES:
2007       # Both Address and 5-digit postal code match Y A Y Y
2008       # Both address and 9-digit postal code match Y A X Y
2009       # United Kingdom – Address and postal code match _ _ _ F
2010       # International transaction – Address and postal code match _ _ _ D/M
2011       #
2012       # ACCEPTABLE, BUT ISSUE A WARNING:
2013       # Ineligible transaction; or message contains a content error _ _ _ E
2014       # System unavailable; retry R U R R
2015       # Information unavailable U W U U
2016       # Issuer does not support AVS S U S S
2017       # AVS is not applicable _ _ _ S
2018       # Incompatible formats – Not verified _ _ _ C
2019       # Incompatible formats – Address not verified; postal code matches _ _ _ P
2020       # International transaction – address not verified _ G _ G/I
2021       #
2022       # UNACCEPTABLE AVS RESPONSES:
2023       # Only Address matches A Y A A
2024       # Only 5-digit postal code matches Z Z Z Z
2025       # Only 9-digit postal code matches Z Z W W
2026       # Neither address nor postal code matches N N N N
2027
2028       if (my $avscode = uc($transaction->avs_code)) {
2029
2030         # map codes to accept/warn/reject
2031         my $avs = {
2032           'American Express card' => {
2033             'A' => 'r',
2034             'N' => 'r',
2035             'R' => 'w',
2036             'S' => 'w',
2037             'U' => 'w',
2038             'Y' => 'a',
2039             'Z' => 'r',
2040           },
2041           'Discover card' => {
2042             'A' => 'a',
2043             'G' => 'w',
2044             'N' => 'r',
2045             'U' => 'w',
2046             'W' => 'w',
2047             'Y' => 'r',
2048             'Z' => 'r',
2049           },
2050           'MasterCard' => {
2051             'A' => 'r',
2052             'N' => 'r',
2053             'R' => 'w',
2054             'S' => 'w',
2055             'U' => 'w',
2056             'W' => 'r',
2057             'X' => 'a',
2058             'Y' => 'a',
2059             'Z' => 'r',
2060           },
2061           'VISA card' => {
2062             'A' => 'r',
2063             'C' => 'w',
2064             'D' => 'a',
2065             'E' => 'w',
2066             'F' => 'a',
2067             'G' => 'w',
2068             'I' => 'w',
2069             'M' => 'a',
2070             'N' => 'r',
2071             'P' => 'w',
2072             'R' => 'w',
2073             'S' => 'w',
2074             'U' => 'w',
2075             'W' => 'r',
2076             'Y' => 'a',
2077             'Z' => 'r',
2078           },
2079         };
2080         my $cardtype = cardtype($content{card_number});
2081         if ($avs->{$cardtype}) {
2082           my $avsact = $avs->{$cardtype}->{$avscode};
2083           my $warning = '';
2084           if ($avsact eq 'r') {
2085             return "AVS code verification failed, cardtype $cardtype, code $avscode";
2086           } elsif ($avsact eq 'w') {
2087             $warning = "AVS did not occur, cardtype $cardtype, code $avscode";
2088           } elsif (!$avsact) {
2089             $warning = "AVS code unknown, cardtype $cardtype, code $avscode";
2090           } # else $avsact eq 'a'
2091           if ($warning) {
2092             $log->warning($warning);
2093             warn $warning;
2094           }
2095         } # else $cardtype avs handling not implemented
2096       } # else !$transaction->avs_code
2097
2098     } else { # is not success
2099
2100       # status is 'done' not 'declined', as in _realtime_bop_result
2101       $cust_pay_pending->status('done');
2102       $error = $transaction->error_message || 'Unknown error';
2103       $cust_pay_pending->statustext($error);
2104       # could also record failure_status here,
2105       #   but it's not supported by B::OP::vSecureProcessing...
2106       #   need a B::OP module with (reverse) auth only to test it with
2107       my $cpp_declined_err = $cust_pay_pending->replace;
2108       return $cpp_declined_err if $cpp_declined_err;
2109
2110     }
2111
2112   } # end of IMMEDIATE; we now have our $error and $transaction
2113
2114   ###
2115   # Save the custnum (as part of the main transaction, so it can reference
2116   # the cust_main)
2117   ###
2118
2119   if (!$cust_pay_pending->custnum) {
2120     $cust_pay_pending->set('custnum', $self->custnum);
2121     my $set_custnum_err = $cust_pay_pending->replace;
2122     if ($set_custnum_err) {
2123       $log->error($set_custnum_err);
2124       $error ||= $set_custnum_err;
2125       # but if there was a real verification error also, return that one
2126     }
2127   }
2128
2129   ###
2130   # remove paycvv here?  need to find out if a reversed auth
2131   #   counts as an initial transaction for paycvv retention requirements
2132   ###
2133
2134   ###
2135   # Tokenize
2136   ###
2137
2138   # This block will only run if the B::OP module supports card_token but not the Tokenize transaction;
2139   #   if that never happens, we should get rid of it (as it has the potential to store real card numbers on error)
2140   if (my $card_token = $self->_tokenize_card($transaction,\%options)) {
2141     $cust_pay_pending->payinfo($card_token);
2142     my $cpp_token_err = $cust_pay_pending->replace;
2143     #this leaves real card number in cust_pay_pending, but can't do much else if cpp won't replace
2144     return $cpp_token_err if $cpp_token_err;
2145     #important that we not replace cust_payby here,
2146     #because cust_payby->replace uses realtime_verify_bop!
2147   }
2148
2149   ###
2150   # result handling
2151   ###
2152
2153   # $error contains the transaction error_message, if is_success was false.
2154
2155   return $error;
2156
2157 }
2158
2159 =item realtime_tokenize [ OPTION => VALUE ... ]
2160
2161 If possible and necessary, runs a tokenize transaction.
2162 In order to be possible, a credit card cust_payby record
2163 must be passed and a Business::OnlinePayment gateway capable
2164 of Tokenize transactions must be configured for this user.
2165 Is only necessary if payinfo is not yet tokenized.
2166
2167 Returns the empty string if the authorization was sucessful
2168 or was not possible/necessary (thus allowing this to be safely called with
2169 non-tokenizable records/gateways, without having to perform separate tests),
2170 or an error message otherwise.
2171
2172 Option I<cust_payby> may be passed, even if it's not yet been inserted.
2173 Object will be tokenized if possible, but that change will not be
2174 updated in database (must be inserted/replaced afterwards.)
2175
2176 Otherwise, options I<method>, I<payinfo> and other cust_payby fields
2177 may be passed.  If options are passed as a hashref, I<payinfo>
2178 will be updated as appropriate in the passed hashref.
2179
2180 Can be run as a class method if option I<payment_gateway> is passed,
2181 but default customer id/name/phone can't be set in that case.  This
2182 is really only intended for tokenizing old records on upgrade.
2183
2184 =cut
2185
2186 # careful--might be run as a class method
2187 sub realtime_tokenize {
2188   my $self = shift;
2189
2190   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2191   my $log = FS::Log->new('FS::cust_main::Billing_Realtime::realtime_tokenize');
2192
2193   my %options = ();
2194   my $outoptions; #for returning cust_payby/payinfo
2195   if (ref($_[0]) eq 'HASH') {
2196     %options = %{$_[0]};
2197     $outoptions = $_[0];
2198   } else {
2199     %options = @_;
2200     $outoptions = \%options;
2201   }
2202
2203   # set fields from passed cust_payby
2204   _bop_cust_payby_options(\%options);
2205   return '' unless $options{method} eq 'CC';
2206   return '' if $self->tokenized($options{payinfo}); #already tokenized
2207
2208   ###
2209   # select a gateway
2210   ###
2211
2212   $options{'nofatal'} = 1;
2213   my $payment_gateway =  $self->_payment_gateway( \%options );
2214   return '' unless $payment_gateway;
2215   my $namespace = $payment_gateway->gateway_namespace;
2216   return '' unless $namespace eq 'Business::OnlinePayment';
2217
2218   eval "use $namespace";
2219   return $@ if $@;
2220
2221   ###
2222   # check for tokenize ability
2223   ###
2224
2225   my $transaction = new $namespace( $payment_gateway->gateway_module,
2226                                     _bop_options(\%options),
2227                                   );
2228
2229   return '' unless $transaction->can('info');
2230
2231   my %supported_actions = $transaction->info('supported_actions');
2232   return '' unless $supported_actions{'CC'}
2233                 && grep /^Tokenize$/, @{$supported_actions{'CC'}};
2234
2235   ###
2236   # check for banned credit card/ACH
2237   ###
2238
2239   my $ban = FS::banned_pay->ban_search(
2240     'payby'   => $bop_method2payby{'CC'},
2241     'payinfo' => $options{payinfo},
2242   );
2243   return "Banned credit card" if $ban && $ban->bantype ne 'warn';
2244
2245   ###
2246   # massage data
2247   ###
2248
2249   ### Currently, cardfortress only keys in on card number and exp date.
2250   ### We pass everything we'd pass to a normal transaction,
2251   ### for ease of current and future development,
2252   ### but note, when tokenizing old records, we may only have access to payinfo/paydate
2253
2254   my $bop_content = $self->_bop_content(\%options);
2255   return $bop_content unless ref($bop_content);
2256
2257   my $paydate = '';
2258   my %content = ();
2259
2260   $content{card_number} = $options{payinfo};
2261   $paydate = $options{'paydate'};
2262   $paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
2263   $content{expiration} = "$2/$1";
2264
2265   $content{cvv2} = $options{'paycvv'}
2266     if length($options{'paycvv'});
2267
2268   my $paystart_month = $options{'paystart_month'};
2269   my $paystart_year  = $options{'paystart_year'};
2270
2271   $content{card_start} = "$paystart_month/$paystart_year"
2272     if $paystart_month && $paystart_year;
2273
2274   my $payissue       = $options{'payissue'};
2275   $content{issue_number} = $payissue if $payissue;
2276
2277   $content{customer_id} = $self->custnum
2278     if ref($self);
2279
2280   ###
2281   # run transaction
2282   ###
2283
2284   my $error;
2285
2286   # no cust_pay_pending---this is not a financial transaction
2287
2288   $transaction->content(
2289     'type'           => 'CC',
2290     _bop_auth(\%options),
2291     'action'         => 'Tokenize',
2292     'description'    => $options{'description'},
2293     %$bop_content,
2294     %content, #after
2295   );
2296
2297   # no $BOP_TESTING handling for this
2298   $transaction->test_transaction(1)
2299     if $conf->exists('business-onlinepayment-test_transaction');
2300   $transaction->submit();
2301
2302   if ( $transaction->card_token() ) { # no is_success flag
2303
2304     # realtime_tokenize should not clear paycvv at this time.  it might be
2305     # needed for the first transaction, and a tokenize isn't actually a
2306     # transaction that hits the gateway.  at some point in the future, card
2307     # fortress should take on the "store paycvv until first transaction"
2308     # functionality and we should fix this in freeside, but i that's a bigger
2309     # project for another time.
2310
2311     #important that we not replace cust_payby here,
2312     #because cust_payby->replace uses realtime_tokenize!
2313     $self->_tokenize_card($transaction,$outoptions);
2314
2315   } else {
2316
2317     $error = $transaction->error_message || 'Unknown error when tokenizing card';
2318
2319   }
2320
2321   return $error;
2322
2323 }
2324
2325
2326 =item tokenized PAYINFO
2327
2328 Convenience wrapper for L<FS::payinfo_Mixin/tokenized>
2329
2330 PAYINFO is required.
2331
2332 Can be run as class or object method, never loads from object.
2333
2334 =cut
2335
2336 sub tokenized {
2337   my $this = shift;
2338   my $payinfo = shift;
2339   FS::cust_pay->tokenized($payinfo);
2340 }
2341
2342 =item token_check [ quiet => 1, queue => 1, daily => 1 ]
2343
2344 NOT A METHOD.  Acts on all customers.  Placed here because it makes
2345 use of module-internal methods, and to keep everything that uses
2346 Billing::OnlinePayment all in one place.
2347
2348 Tokenizes all tokenizable card numbers from payinfo in cust_payby and
2349 CARD transactions in cust_pay_pending, cust_pay, cust_pay_void and cust_refund.
2350
2351 If the I<queue> flag is set, newly tokenized records will be immediately
2352 committed, regardless of AutoCommit, so as to release the mutex on the record.
2353
2354 If all configured gateways have the ability to tokenize, detection of an
2355 untokenizable record will cause a fatal error.  However, if the I<queue> flag
2356 is set, this will instead cause a critical error to be recorded in the log,
2357 and any other tokenizable records will still be committed.
2358
2359 If the I<daily> flag is also set, detection of existing untokenized records will
2360 record a critical error in the system log (because they should have never appeared
2361 in the first place.)  Tokenization will still be attempted.
2362
2363 If any configured gateways do NOT have the ability to tokenize, or if a
2364 default gateway is not configured, then untokenized records are not considered
2365 a threat, and no critical errors will be generated in the log.
2366
2367 =cut
2368
2369 sub token_check {
2370   #acts on all customers
2371   my %opt = @_;
2372   my $debug = !$opt{'quiet'} || $DEBUG;
2373
2374   warn "token_check called with opts\n".Dumper(\%opt) if $debug;
2375
2376   # force some explicitness when invoking this method
2377   die "token_check must run with queue flag if run with daily flag"
2378     if $opt{'daily'} && !$opt{'queue'};
2379
2380   my $conf = FS::Conf->new;
2381
2382   my $log = FS::Log->new('FS::cust_main::Billing_Realtime::token_check');
2383
2384   my $cache = {}; #cache for module info
2385
2386   # look for a gateway that can't tokenize
2387   my $require_tokenized = 1;
2388   foreach my $gateway (
2389     FS::payment_gateway->all_gateways(
2390       'method'  => 'CC',
2391       'conf'    => $conf,
2392       'nofatal' => 1,
2393     )
2394   ) {
2395     if (!$gateway) {
2396       # no default gateway, no promise to tokenize
2397       # can just load other gateways as-needeed below
2398       $require_tokenized = 0;
2399       last;
2400     }
2401     my $info = _token_check_gateway_info($cache,$gateway);
2402     die $info unless ref($info); # means it's an error message
2403     unless ($info->{'can_tokenize'}) {
2404       # a configured gateway can't tokenize, that's all we need to know right now
2405       # can just load other gateways as-needeed below
2406       $require_tokenized = 0;
2407       last;
2408     }
2409   }
2410
2411   warn "REQUIRE TOKENIZED" if $require_tokenized && $debug;
2412
2413   # upgrade does not call this with autocommit turned on,
2414   # and autocommit will be ignored if opt queue is set,
2415   # but might as well be thorough...
2416   my $oldAutoCommit = $FS::UID::AutoCommit;
2417   local $FS::UID::AutoCommit = 0;
2418   my $dbh = dbh;
2419
2420   # for retrieving data in chunks
2421   my $step = 500;
2422   my $offset = 0;
2423
2424   ### Tokenize cust_payby
2425
2426   my @recnums;
2427
2428 CUSTLOOP:
2429   while (my $custnum = _token_check_next_recnum($dbh,'cust_main',$step,\$offset,\@recnums)) {
2430     my $cust_main = FS::cust_main->by_key($custnum);
2431     my $payment_gateway;
2432     foreach my $cust_payby ($cust_main->cust_payby('CARD','DCRD')) {
2433
2434       # see if it's already tokenized
2435       if ($cust_payby->tokenized) {
2436         warn "cust_payby ".$cust_payby->get($cust_payby->primary_key)." already tokenized" if $debug;
2437         next;
2438       }
2439
2440       if ($require_tokenized && $opt{'daily'}) {
2441         $log->critical("Untokenized card number detected in cust_payby ".$cust_payby->custpaybynum);
2442         $dbh->commit or die $dbh->errstr; # commit log message
2443       }
2444
2445       # only load gateway if we need to, and only need to load it once
2446       my $payment_gateway ||= $cust_main->_payment_gateway({
2447         'method'  => 'CC',
2448         'conf'    => $conf,
2449         'nofatal' => 1, # handle lack of gateway smoothly below
2450       });
2451       unless ($payment_gateway) {
2452         # no reason to have untokenized card numbers saved if no gateway,
2453         #   but only a problem if we expected everyone to tokenize card numbers
2454         unless ($require_tokenized) {
2455           warn "Skipping cust_payby for cust_main ".$cust_main->custnum.", no payment gateway" if $debug;
2456           next CUSTLOOP; # can skip rest of customer
2457         }
2458         my $error = "No gateway found for custnum ".$cust_main->custnum;
2459         if ($opt{'queue'}) {
2460           $log->critical($error);
2461           $dbh->commit or die $dbh->errstr; # commit error message
2462           next; # not next CUSTLOOP, want to record error for every cust_payby
2463         }
2464         $dbh->rollback if $oldAutoCommit;
2465         die $error;
2466       }
2467
2468       my $info = _token_check_gateway_info($cache,$payment_gateway);
2469       unless (ref($info)) {
2470         # only throws error if Business::OnlinePayment won't load,
2471         #   which is just cause to abort this whole process, even if queue
2472         $dbh->rollback if $oldAutoCommit;
2473         die $info; # error message
2474       }
2475       # no fail here--a configured gateway can't tokenize, so be it
2476       unless ($info->{'can_tokenize'}) {
2477         warn "Skipping ".$cust_main->custnum." cannot tokenize" if $debug;
2478         next;
2479       }
2480
2481       # time to tokenize
2482       $cust_payby = $cust_payby->select_for_update;
2483       my %tokenopts = (
2484         'payment_gateway' => $payment_gateway,
2485         'cust_payby'      => $cust_payby,
2486       );
2487       my $error = $cust_main->realtime_tokenize(\%tokenopts);
2488       if ($cust_payby->tokenized) { # implies no error
2489         $error = $cust_payby->replace;
2490       } else {
2491         $error ||= 'Unknown error';
2492       }
2493       if ($error) {
2494         $error = "Error tokenizing cust_payby ".$cust_payby->custpaybynum.": ".$error;
2495         if ($opt{'queue'}) {
2496           $log->critical($error);
2497           $dbh->commit or die $dbh->errstr; # commit log message, release mutex
2498           next; # not next CUSTLOOP, want to record error for every cust_payby
2499         }
2500         $dbh->rollback if $oldAutoCommit;
2501         die $error;
2502       }
2503       $dbh->commit or die $dbh->errstr if $opt{'queue'}; # release mutex
2504       warn "TOKENIZED cust_payby ".$cust_payby->get($cust_payby->primary_key) if $debug;
2505     }
2506     warn "cust_payby upgraded for custnum ".$cust_main->custnum if $debug;
2507
2508   }
2509
2510   ### Tokenize/mask transaction tables
2511
2512   # allow tokenization of closed cust_pay/cust_refund records
2513   local $FS::payinfo_Mixin::allow_closed_replace = 1;
2514
2515   # grep assistance:
2516   #   $cust_pay_pending->replace, $cust_pay->replace, $cust_pay_void->replace, $cust_refund->replace all run here
2517   foreach my $table ( qw(cust_pay_pending cust_pay cust_pay_void cust_refund) ) {
2518     warn "Checking $table" if $debug;
2519
2520     # FS::Cursor does not seem to work over multiple commits (gives cursor not found errors)
2521     # loading only record ids, then loading individual records one at a time
2522     my $tclass = 'FS::'.$table;
2523     $offset = 0;
2524     @recnums = ();
2525
2526     while (my $recnum = _token_check_next_recnum($dbh,$table,$step,\$offset,\@recnums)) {
2527       my $record = $tclass->by_key($recnum);
2528       if (FS::cust_main::Billing_Realtime->tokenized($record->payinfo)) {
2529         warn "Skipping tokenized record for $table ".$record->get($record->primary_key) if $debug;
2530         next;
2531       }
2532       if (!$record->payinfo) { #shouldn't happen, but at least it's not a card number
2533         warn "Skipping blank payinfo for $table ".$record->get($record->primary_key) if $debug;
2534         next;
2535       }
2536       if ($record->payinfo =~ /N\/A/) { # ??? Not sure why we do this, but it's not a card number
2537         warn "Skipping NA payinfo for $table ".$record->get($record->primary_key) if $debug;
2538         next;
2539       }
2540
2541       if ($require_tokenized && $opt{'daily'}) {
2542         $log->critical("Untokenized card number detected in $table ".$record->get($record->primary_key));
2543         $dbh->commit or die $dbh->errstr; # commit log message
2544       }
2545
2546       # don't use customer agent gateway here, use the gatewaynum specified by the record
2547       my $gateway = FS::payment_gateway->by_key_or_default(
2548         'method'     => 'CC',
2549         'conf'       => $conf,
2550         'nofatal'    => 1,
2551         'gatewaynum' => $record->gatewaynum || '',
2552       );
2553       unless ($gateway) {
2554         # means no default gateway, no promise to tokenize, can skip
2555         warn "Skipping missing gateway for $table ".$record->get($record->primary_key) if $debug;
2556         next;
2557       }
2558
2559       my $info = _token_check_gateway_info($cache,$gateway);
2560       unless (ref($info)) {
2561         # only throws error if Business::OnlinePayment won't load,
2562         #   which is just cause to abort this whole process, even if queue
2563         $dbh->rollback if $oldAutoCommit;
2564         die $info; # error message
2565       }
2566
2567       # a configured gateway can't tokenize, move along
2568       unless ($info->{'can_tokenize'}) {
2569         warn "Skipping, cannot tokenize $table ".$record->get($record->primary_key) if $debug;
2570         next;
2571       }
2572
2573       my $cust_main = $record->cust_main;
2574       if (!$cust_main) {
2575         # might happen for cust_pay_pending from failed verify records,
2576         #   in which case we attempt tokenization without cust_main
2577         # everything else should absolutely have a cust_main
2578         if ($table eq 'cust_pay_pending' && $record->{'custnum_pending'}) {
2579           warn "ATTEMPTING GATEWAY-ONLY TOKENIZE" if $debug;
2580         } else {
2581           my $error = "Could not load cust_main for $table ".$record->get($record->primary_key);
2582           if ($opt{'queue'}) {
2583             $log->critical($error);
2584             $dbh->commit or die $dbh->errstr; # commit log message
2585             next;
2586           }
2587           $dbh->rollback if $oldAutoCommit;
2588           die $error;
2589         }
2590       }
2591
2592       # if we got this far, time to mutex
2593       $record = $record->select_for_update;
2594
2595       # no clear record of name/address/etc used for transaction,
2596       # but will load name/phone/id from customer if run as an object method,
2597       # so we try that if we can
2598       my %tokenopts = (
2599         'payment_gateway' => $gateway,
2600         'method'          => 'CC',
2601         'payinfo'         => $record->payinfo,
2602         'paydate'         => $record->paydate,
2603       );
2604       my $error = $cust_main
2605                 ? $cust_main->realtime_tokenize(\%tokenopts)
2606                 : FS::cust_main::Billing_Realtime->realtime_tokenize(\%tokenopts);
2607       if (FS::cust_main::Billing_Realtime->tokenized($tokenopts{'payinfo'})) { # implies no error
2608         $record->payinfo($tokenopts{'payinfo'});
2609         $error = $record->replace;
2610       } else {
2611         $error ||= 'Unknown error';
2612       }
2613       if ($error) {
2614         $error = "Error tokenizing $table ".$record->get($record->primary_key).": ".$error;
2615         if ($opt{'queue'}) {
2616           $log->critical($error);
2617           $dbh->commit or die $dbh->errstr; # commit log message, release mutex
2618           next;
2619         }
2620         $dbh->rollback if $oldAutoCommit;
2621         die $error;
2622       }
2623       $dbh->commit or die $dbh->errstr if $opt{'queue'}; # release mutex
2624       warn "TOKENIZED $table ".$record->get($record->primary_key) if $debug;
2625
2626     } # end record loop
2627   } # end table loop
2628
2629   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2630
2631   return '';
2632 }
2633
2634 # not a method!
2635 sub _token_check_next_recnum {
2636   my ($dbh,$table,$step,$offset,$recnums) = @_;
2637   my $recnum = shift @$recnums;
2638   return $recnum if $recnum;
2639   my $tclass = 'FS::'.$table;
2640   my $sth = $dbh->prepare('SELECT '.$tclass->primary_key.' FROM '.$table.' ORDER BY '.$tclass->primary_key.' LIMIT '.$step.' OFFSET '.$$offset) or die $dbh->errstr;
2641   $sth->execute() or die $sth->errstr;
2642   my @recnums;
2643   while (my $rec = $sth->fetchrow_hashref) {
2644     push @$recnums, $rec->{$tclass->primary_key};
2645   }
2646   $sth->finish();
2647   $$offset += $step;
2648   return shift @$recnums;
2649 }
2650
2651 # not a method!
2652 sub _token_check_gateway_info {
2653   my ($cache,$payment_gateway) = @_;
2654
2655   return $cache->{$payment_gateway->gateway_module}
2656     if $cache->{$payment_gateway->gateway_module};
2657
2658   my $info = {};
2659   $cache->{$payment_gateway->gateway_module} = $info;
2660
2661   my $namespace = $payment_gateway->gateway_namespace;
2662   return $info unless $namespace eq 'Business::OnlinePayment';
2663   $info->{'is_bop'} = 1;
2664
2665   # only need to load this once,
2666   # don't want to load if nothing is_bop
2667   unless ($cache->{'Business::OnlinePayment'}) {
2668     eval "use $namespace";
2669     return "Error initializing Business:OnlinePayment: ".$@ if $@;
2670     $cache->{'Business::OnlinePayment'} = 1;
2671   }
2672
2673   my $transaction = new $namespace( $payment_gateway->gateway_module,
2674                                     _bop_options({ 'payment_gateway' => $payment_gateway }),
2675                                   );
2676
2677   return $info unless $transaction->can('info');
2678   $info->{'can_info'} = 1;
2679
2680   my %supported_actions = $transaction->info('supported_actions');
2681   $info->{'can_tokenize'} = 1
2682     if $supported_actions{'CC'}
2683       && grep /^Tokenize$/, @{$supported_actions{'CC'}};
2684
2685   # not using this any more, but for future reference...
2686   $info->{'void_requires_card'} = 1
2687     if $transaction->info('CC_void_requires_card');
2688
2689   return $info;
2690 }
2691
2692 =back
2693
2694 =head1 BUGS
2695
2696 =head1 SEE ALSO
2697
2698 L<FS::cust_main>, L<FS::cust_main::Billing>
2699
2700 =cut
2701
2702 1;