FS/FS/cust_main/Billing_Batch.pm

   1 package FS::cust_main::Billing_Batch;
   2
   3 use strict;
   4 use vars qw( $conf );
   5 use FS::Record qw( qsearch qsearchs dbh );
   6 use FS::pay_batch;
   7 use FS::cust_pay_batch;
   8 use FS::cust_bill_pay_batch;
   9
  10 install_callback FS::UID sub {
  11   $conf = new FS::Conf;
  12   #yes, need it for stuff below (prolly should be cached)
  13 };
  14
  15 =item batch_card OPTION => VALUE...
  16
  17 Adds a payment for this invoice to the pending credit card batch (see
  18 L<FS::cust_pay_batch>), or, if the B<realtime> option is set to a true value,
  19 runs the payment using a realtime gateway.
  20
  21 Options may include:
  22
  23 B<amount>: the amount to be paid; defaults to the customer's balance minus
  24 any payments in transit.
  25
  26 B<realtime>: runs this as a realtime payment instead of adding it to a
  27 batch.  Deprecated.
  28
  29 B<invnum>: sets cust_pay_batch.invnum.
  30
  31 B<address1>, B<address2>, B<city>, B<state>, B<zip>, B<country>: sets
  32 the billing address for the payment; defaults to the customer's billing
  33 location.
  34
  35 B<payby>, B<payinfo>, B<paydate>, B<payname>: sets the payment method,
  36 payment account, expiration date, and name; defaults to those fields
  37 in cust_main.
  38
  39 =cut
  40
  41 sub batch_card {
  42   my ($self, %options) = @_;
  43
  44   my $amount;
  45   if (exists($options{amount})) {
  46     $amount = $options{amount};
  47   }else{
  48     $amount = sprintf("%.2f", $self->balance - $self->in_transit_payments);
  49   }
  50   if ($amount <= 0) {
  51     warn(sprintf("Customer balance %.2f - in transit amount %.2f is <= 0.\n",
  52         $self->balance,
  53         $self->in_transit_payments
  54     ));
  55     return;
  56   }
  57
  58   my $invnum = delete $options{invnum};
  59
  60   #pay fields should all come from either cust_payby or options, not both
  61   #  in theory, could just pass payby, and use it to select cust_payby,
  62   #  but nothing currently needs that, so not implementing it now
  63   die "Incomplete payment details"
  64     if  ($options{payby} || $options{payinfo} || $options{paydate} || $options{payname})
  65     && !($options{payby} && $options{payinfo} && $options{paydate} && $options{payname});
  66
  67   #false laziness with Billing_Realtime
  68   my @cust_payby = $self->cust_payby('CARD','CHEK');
  69
  70   # batch can't try out every one like realtime, just use first one
  71   my $cust_payby = $cust_payby[0];
  72
  73   die "No customer payment info found"
  74     unless $options{payinfo} || $cust_payby;
  75
  76   my $payby = $options{payby} || $cust_payby->payby;
  77
  78   if ($options{'realtime'}) {
  79     return $self->realtime_bop( FS::payby->payby2bop($payby),
  80                                 $amount,
  81                                 %options,
  82                               );
  83   }
  84
  85   my $oldAutoCommit = $FS::UID::AutoCommit;
  86   local $FS::UID::AutoCommit = 0;
  87   my $dbh = dbh;
  88
  89   #this needs to handle mysql as well as Pg, like svc_acct.pm
  90   #(make it into a common function if folks need to do batching with mysql)
  91   $dbh->do("LOCK TABLE pay_batch IN SHARE ROW EXCLUSIVE MODE")
  92     or die "Cannot lock pay_batch: " . $dbh->errstr;
  93
  94   my %pay_batch = (
  95     'status' => 'O',
  96     'payby'  => FS::payby->payby2payment($payby),
  97   );
  98   $pay_batch{agentnum} = $self->agentnum if $conf->exists('batch-spoolagent');
  99
 100   my $pay_batch = qsearchs( 'pay_batch', \%pay_batch );
 101
 102   unless ( $pay_batch ) {
 103     $pay_batch = new FS::pay_batch \%pay_batch;
 104     my $error = $pay_batch->insert;
 105     if ( $error ) {
 106       $dbh->rollback if $oldAutoCommit;
 107       die "error creating new batch: $error\n";
 108     }
 109   }
 110
 111   my $old_cust_pay_batch = qsearchs('cust_pay_batch', {
 112       'batchnum' => $pay_batch->batchnum,
 113       'custnum'  => $self->custnum,
 114   } );
 115
 116   foreach (qw( address1 address2 city state zip country latitude longitude
 117                payby payinfo paydate payname paycode ))
 118   {
 119     $options{$_} = '' unless exists($options{$_});
 120   }
 121
 122   my $loc = $self->bill_location;
 123
 124   my $cust_pay_batch = new FS::cust_pay_batch ( {
 125     'batchnum' => $pay_batch->batchnum,
 126     'invnum'   => $invnum || 0,                    # is there a better value?
 127                                                    # this field should be
 128                                                    # removed...
 129                                                    # cust_bill_pay_batch now
 130     'custnum'  => $self->custnum,
 131     'last'     => $self->getfield('last'),
 132     'first'    => $self->getfield('first'),
 133     'address1' => $options{address1} || $loc->address1,
 134     'address2' => $options{address2} || $loc->address2,
 135     'city'     => $options{city}     || $loc->city,
 136     'state'    => $options{state}    || $loc->state,
 137     'zip'      => $options{zip}      || $loc->zip,
 138     'country'  => $options{country}  || $loc->country,
 139     'payby'    => $options{payby}    || $cust_payby->payby,
 140     'payinfo'  => $options{payinfo}  || $cust_payby->payinfo,
 141     'exp'      => $options{paydate}  || $cust_payby->paydate,
 142     'payname'  => $options{payname}  || $cust_payby->payname,
 143     'paytype'  => $options{paytype}  || $cust_payby->paytype,
 144     'amount'   => $amount,                         # consolidating
 145     'paycode'  => $options{paycode}  || $cust_payby->paycode,
 146   } );
 147
 148   $cust_pay_batch->paybatchnum($old_cust_pay_batch->paybatchnum)
 149     if $old_cust_pay_batch;
 150
 151   my $error;
 152   if ($old_cust_pay_batch) {
 153     $error = $cust_pay_batch->replace($old_cust_pay_batch)
 154   } else {
 155     $error = $cust_pay_batch->insert;
 156   }
 157
 158   if ( $error ) {
 159     $dbh->rollback if $oldAutoCommit;
 160     #die $error;
 161     return $error; # e.g. "Illegal zip" ala RT#75998
 162   }
 163
 164   my $unapplied =   $self->total_unapplied_credits
 165                   + $self->total_unapplied_payments
 166                   + $self->in_transit_payments;
 167   foreach my $cust_bill ($self->open_cust_bill) {
 168     #$dbh->commit or die $dbh->errstr if $oldAutoCommit;
 169     my $cust_bill_pay_batch = new FS::cust_bill_pay_batch {
 170       'invnum' => $cust_bill->invnum,
 171       'paybatchnum' => $cust_pay_batch->paybatchnum,
 172       'amount' => $cust_bill->owed,
 173       '_date' => time,
 174     };
 175     if ($unapplied >= $cust_bill_pay_batch->amount){
 176       $unapplied -= $cust_bill_pay_batch->amount;
 177       next;
 178     }else{
 179       $cust_bill_pay_batch->amount(sprintf ( "%.2f",
 180                                    $cust_bill_pay_batch->amount - $unapplied ));      $unapplied = 0;
 181     }
 182     $error = $cust_bill_pay_batch->insert;
 183     if ( $error ) {
 184       $dbh->rollback if $oldAutoCommit;
 185       die $error;
 186     }
 187   }
 188
 189   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 190   '';
 191 }
 192
 193 =item cust_pay_batch [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
 194
 195 Returns all batched payments (see L<FS::cust_pay_batch>) for this customer.
 196
 197 Optionally, a list or hashref of additional arguments to the qsearch call can
 198 be passed.
 199
 200 =cut
 201
 202 sub cust_pay_batch {
 203   my $self = shift;
 204   my $opt = ref($_[0]) ? shift : { @_ };
 205
 206   #return $self->num_cust_statement unless wantarray || keys %$opt;
 207
 208   $opt->{'table'} = 'cust_pay_batch';
 209   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
 210   $opt->{'hashref'}{'custnum'} = $self->custnum;
 211   $opt->{'order_by'} ||= 'ORDER BY paybatchnum ASC';
 212
 213   map { $_ } #behavior of sort undefined in scalar context
 214     sort { $a->paybatchnum <=> $b->paybatchnum }
 215       qsearch($opt);
 216 }
 217
 218 =item in_transit_payments
 219
 220 Returns the total of requests for payments for this customer pending in
 221 batches in transit to the bank.  See L<FS::pay_batch> and L<FS::cust_pay_batch>
 222
 223 =cut
 224
 225 sub in_transit_payments {
 226   my $self = shift;
 227   my $in_transit_payments = 0;
 228   foreach my $pay_batch ( qsearch('pay_batch', {
 229     'status' => 'I',
 230   } ) ) {
 231     foreach my $cust_pay_batch ( qsearch('cust_pay_batch', {
 232       'batchnum' => $pay_batch->batchnum,
 233       'custnum' => $self->custnum,
 234       'status'  => '',
 235     } ) ) {
 236       $in_transit_payments += $cust_pay_batch->amount;
 237     }
 238   }
 239   sprintf( "%.2f", $in_transit_payments );
 240 }
 241
 242 1;