FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use Tie::RefHash;
  12 use FS::cust_bill;
  13 use FS::cust_bill_pkg;
  14 use FS::cust_bill_pkg_display;
  15 use FS::cust_bill_pay;
  16 use FS::cust_credit_bill;
  17 use FS::cust_tax_adjustment;
  18 use FS::tax_rate;
  19 use FS::tax_rate_location;
  20 use FS::cust_bill_pkg_tax_location;
  21 use FS::cust_bill_pkg_tax_rate_location;
  22 use FS::part_event;
  23 use FS::part_event_condition;
  24 use FS::pkg_category;
  25 use FS::FeeOrigin_Mixin;
  26 use FS::Log;
  27 use FS::TaxEngine;
  28
  29 # 1 is mostly method/subroutine entry and options
  30 # 2 traces progress of some operations
  31 # 3 is even more information including possibly sensitive data
  32 $DEBUG = 0;
  33 $me = '[FS::cust_main::Billing]';
  34
  35 install_callback FS::UID sub {
  36   $conf = new FS::Conf;
  37   #yes, need it for stuff below (prolly should be cached)
  38 };
  39
  40 =head1 NAME
  41
  42 FS::cust_main::Billing - Billing mixin for cust_main
  43
  44 =head1 SYNOPSIS
  45
  46 =head1 DESCRIPTION
  47
  48 These methods are available on FS::cust_main objects.
  49
  50 =head1 METHODS
  51
  52 =over 4
  53
  54 =item bill_and_collect
  55
  56 Cancels and suspends any packages due, generates bills, applies payments and
  57 credits, and applies collection events to run cards, send bills and notices,
  58 etc.
  59
  60 By default, warns on errors and continues with the next operation (but see the
  61 "fatal" flag below).
  62
  63 Options are passed as name-value pairs.  Currently available options are:
  64
  65 =over 4
  66
  67 =item time
  68
  69 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  70
  71  use Date::Parse;
  72  ...
  73  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  74
  75 =item invoice_time
  76
  77 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  78
  79 =item check_freq
  80
  81 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  82
  83 =item resetup
  84
  85 If set true, re-charges setup fees.
  86
  87 =item fatal
  88
  89 If set any errors prevent subsequent operations from continusing.  If set
  90 specifically to "return", returns the error (or false, if there is no error).
  91 Any other true value causes errors to die.
  92
  93 =item debug
  94
  95 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  96
  97 =item job
  98
  99 Optional FS::queue entry to receive status updates.
 100
 101 =back
 102
 103 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 104 options of those methods are also available.
 105
 106 =cut
 107
 108 sub bill_and_collect {
 109   my( $self, %options ) = @_;
 110
 111   my $log = FS::Log->new('FS::cust_main::Billing::bill_and_collect');
 112   my %logopt = (object => $self);
 113   $log->debug('start', %logopt);
 114
 115   my $error;
 116
 117   #$options{actual_time} not $options{time} because freeside-daily -d is for
 118   #pre-printing invoices
 119
 120   $options{'actual_time'} ||= time;
 121   my $job = $options{'job'};
 122
 123   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 124                         ? day_end( $options{actual_time} )
 125                         : $options{actual_time}
 126                     );
 127
 128   $job->update_statustext('0,cleaning expired packages') if $job;
 129   $log->debug('canceling expired packages', %logopt);
 130   $error = $self->cancel_expired_pkgs( $actual_time );
 131   if ( $error ) {
 132     $error = "Error expiring custnum ". $self->custnum. ": $error";
 133     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 134     elsif ( $options{fatal}                                ) { die    $error; }
 135     else                                                     { warn   $error; }
 136   }
 137
 138   $log->debug('suspending adjourned packages', %logopt);
 139   $error = $self->suspend_adjourned_pkgs( $actual_time );
 140   if ( $error ) {
 141     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 142     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 143     elsif ( $options{fatal}                                ) { die    $error; }
 144     else                                                     { warn   $error; }
 145   }
 146
 147   $log->debug('unsuspending resumed packages', %logopt);
 148   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 149   if ( $error ) {
 150     $error = "Error resuming custnum ".$self->custnum. ": $error";
 151     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 152     elsif ( $options{fatal}                                ) { die    $error; }
 153     else                                                     { warn   $error; }
 154   }
 155
 156   $job->update_statustext('20,billing packages') if $job;
 157   $log->debug('billing packages', %logopt);
 158   $error = $self->bill( %options );
 159   if ( $error ) {
 160     $error = "Error billing custnum ". $self->custnum. ": $error";
 161     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 162     elsif ( $options{fatal}                                ) { die    $error; }
 163     else                                                     { warn   $error; }
 164   }
 165
 166   $job->update_statustext('50,applying payments and credits') if $job;
 167   $log->debug('applying payments and credits', %logopt);
 168   $error = $self->apply_payments_and_credits;
 169   if ( $error ) {
 170     $error = "Error applying custnum ". $self->custnum. ": $error";
 171     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 172     elsif ( $options{fatal}                                ) { die    $error; }
 173     else                                                     { warn   $error; }
 174   }
 175
 176   # In a batch tax environment, do not run collection if any pending
 177   # invoices were created.  Collection will run after the next tax batch.
 178   my $tax = FS::TaxEngine->new;
 179   if ( $tax->info->{batch} and
 180        qsearch('cust_bill', { custnum => $self->custnum, pending => 'Y' })
 181      )
 182   {
 183     warn "skipped collection for custnum ".$self->custnum.
 184          " due to pending invoices\n" if $DEBUG;
 185   } elsif ( $conf->exists('cancelled_cust-noevents')
 186              && ! $self->num_ncancelled_pkgs )
 187   {
 188     warn "skipped collection for custnum ".$self->custnum.
 189          " because they have no active packages\n" if $DEBUG;
 190   } else {
 191     # run collection normally
 192     $job->update_statustext('70,running collection events') if $job;
 193     $log->debug('running collection events', %logopt);
 194     $error = $self->collect( %options );
 195     if ( $error ) {
 196       $error = "Error collecting custnum ". $self->custnum. ": $error";
 197       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 198       elsif ($options{fatal}                               ) { die    $error; }
 199       else                                                   { warn   $error; }
 200     }
 201   }
 202
 203   $job->update_statustext('100,finished') if $job;
 204   $log->debug('finish', %logopt);
 205
 206   '';
 207
 208 }
 209
 210 sub cancel_expired_pkgs {
 211   my ( $self, $time, %options ) = @_;
 212
 213   my @cancel_pkgs = $self->ncancelled_pkgs( {
 214     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 215   } );
 216
 217   my @errors = ();
 218
 219   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 220     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 221     my $error;
 222
 223     if ( $cust_pkg->change_to_pkgnum ) {
 224
 225       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 226       if ( !$new_pkg ) {
 227         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 228                       $cust_pkg->change_to_pkgnum.'; not expiring';
 229         next CUST_PKG;
 230       }
 231       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 232                                   'unprotect_svcs'  => 1 );
 233       $error = '' if ref $error eq 'FS::cust_pkg';
 234
 235     } else { # just cancel it
 236        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 237                                            'reason_otaker' => $cpr->otaker,
 238                                            'time'          => $time,
 239                                          )
 240                                        : ()
 241                                  );
 242     }
 243     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 244   }
 245
 246   join(' / ', @errors);
 247
 248 }
 249
 250 sub suspend_adjourned_pkgs {
 251   my ( $self, $time, %options ) = @_;
 252
 253   my @susp_pkgs = $self->ncancelled_pkgs( {
 254     'extra_sql' =>
 255       " AND ( susp IS NULL OR susp = 0 )
 256         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 257               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 258             )
 259       ",
 260   } );
 261
 262   #only because there's no SQL test for is_prepaid :/
 263   @susp_pkgs =
 264     grep {     (    $_->part_pkg->is_prepaid
 265                  && $_->bill
 266                  && $_->bill < $time
 267                )
 268             || (    $_->adjourn
 269                  && $_->adjourn <= $time
 270                )
 271
 272          }
 273          @susp_pkgs;
 274
 275   my @errors = ();
 276
 277   foreach my $cust_pkg ( @susp_pkgs ) {
 278     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 279       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 280     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 281                                             'reason_otaker' => $cpr->otaker
 282                                           )
 283                                         : ()
 284                                   );
 285     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 286   }
 287
 288   join(' / ', @errors);
 289
 290 }
 291
 292 sub unsuspend_resumed_pkgs {
 293   my ( $self, $time, %options ) = @_;
 294
 295   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 296     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 297   } );
 298
 299   my @errors = ();
 300
 301   foreach my $cust_pkg ( @unsusp_pkgs ) {
 302     my $error = $cust_pkg->unsuspend( 'time' => $time );
 303     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 304   }
 305
 306   join(' / ', @errors);
 307
 308 }
 309
 310 =item bill OPTIONS
 311
 312 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 313 conjunction with the collect method by calling B<bill_and_collect>.
 314
 315 If there is an error, returns the error, otherwise returns false.
 316
 317 Options are passed as name-value pairs.  Currently available options are:
 318
 319 =over 4
 320
 321 =item resetup
 322
 323 If set true, re-charges setup fees.
 324
 325 =item recurring_only
 326
 327 If set true then only bill recurring charges, not setup, usage, one time
 328 charges, etc.
 329
 330 =item freq_override
 331
 332 If set, then override the normal frequency and look for a part_pkg_discount
 333 to take at that frequency.  This is appropriate only when the normal
 334 frequency for all packages is monthly, and is an error otherwise.  Use
 335 C<pkg_list> to limit the set of packages included in billing.
 336
 337 =item time
 338
 339 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 340
 341  use Date::Parse;
 342  ...
 343  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 344
 345 =item pkg_list
 346
 347 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 348
 349  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 350
 351 =item not_pkgpart
 352
 353 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 354
 355 =item no_prepaid
 356
 357 Do not bill prepaid packages.  Used by freeside-daily.
 358
 359 =item invoice_time
 360
 361 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 362
 363 =item cancel
 364
 365 This boolean value informs the us that the package is being cancelled.  This
 366 typically might mean not charging the normal recurring fee but only usage
 367 fees since the last billing. Setup charges may be charged.  Not all package
 368 plans support this feature (they tend to charge 0).
 369
 370 =item no_usage_reset
 371
 372 Prevent the resetting of usage limits during this call.
 373
 374 =item no_commit
 375
 376 Do not save the generated bill in the database.  Useful with return_bill
 377
 378 =item return_bill
 379
 380 A list reference on which the generated bill(s) will be returned.
 381
 382 =item estimate
 383
 384 Boolean value; indicates that this is an estimate rather than a "tax invoice".
 385 This will be passed through to the tax engine, as online tax services
 386 sometimes need to know it for reporting purposes. Otherwise it has no effect.
 387
 388 =item invoice_terms
 389
 390 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 391 terms or the default terms are used.
 392
 393 =back
 394
 395 =cut
 396
 397 sub bill {
 398   my( $self, %options ) = @_;
 399
 400   return '' if $self->complimentary eq 'Y';
 401
 402   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 403   my $log = FS::Log->new('FS::cust_main::Billing::bill');
 404   my %logopt = (object => $self);
 405
 406   $log->debug('start', %logopt);
 407   warn "$me bill customer ". $self->custnum. "\n"
 408     if $DEBUG;
 409
 410   my $time = $options{'time'} || time;
 411   my $invoice_time = $options{'invoice_time'} || $time;
 412
 413   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 414                      ? day_end( $time )
 415                      : $time
 416                  );
 417
 418   $options{'not_pkgpart'} ||= {};
 419   $options{'not_pkgpart'} = { map { $_ => 1 }
 420                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 421                             }
 422     unless ref($options{'not_pkgpart'});
 423
 424   local $SIG{HUP} = 'IGNORE';
 425   local $SIG{INT} = 'IGNORE';
 426   local $SIG{QUIT} = 'IGNORE';
 427   local $SIG{TERM} = 'IGNORE';
 428   local $SIG{TSTP} = 'IGNORE';
 429   local $SIG{PIPE} = 'IGNORE';
 430
 431   my $oldAutoCommit = $FS::UID::AutoCommit;
 432   local $FS::UID::AutoCommit = 0;
 433   my $dbh = dbh;
 434
 435   $log->debug('acquiring lock', %logopt);
 436   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 437     if $DEBUG;
 438
 439   $self->select_for_update; #mutex
 440
 441   $log->debug('running pre-bill events', %logopt);
 442   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 443     if $DEBUG;
 444
 445   my $error = $self->do_cust_event(
 446     'debug'      => ( $options{'debug'} || 0 ),
 447     'time'       => $invoice_time,
 448     'check_freq' => $options{'check_freq'},
 449     'stage'      => 'pre-bill',
 450   )
 451     unless $options{no_commit};
 452   if ( $error ) {
 453     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 454     return $error;
 455   }
 456
 457   $log->debug('done running pre-bill events', %logopt);
 458   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 459     if $DEBUG;
 460
 461   #keep auto-charge and non-auto-charge line items separate
 462   my @passes = ( '', 'no_auto' );
 463
 464   my %cust_bill_pkg = map { $_ => [] } @passes;
 465
 466   ###
 467   # find the packages which are due for billing, find out how much they are
 468   # & generate invoice database.
 469   ###
 470
 471   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 472   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 473
 474   my @precommit_hooks = ();
 475
 476   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 477
 478   my %tax_engines;
 479   my $tax_is_batch = '';
 480   foreach (@passes) {
 481     $tax_engines{$_} = FS::TaxEngine->new(cust_main    => $self,
 482                                           invoice_time => $invoice_time,
 483                                           cancel       => $options{cancel},
 484                                           estimate     => $options{estimate},
 485                                          );
 486     $tax_is_batch ||= $tax_engines{$_}->info->{batch};
 487   }
 488
 489   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 490
 491     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 492
 493     my $part_pkg = $cust_pkg->part_pkg;
 494
 495     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 496
 497     $log->debug('bill package '. $cust_pkg->pkgnum, %logopt);
 498     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 499
 500     #? to avoid use of uninitialized value errors... ?
 501     $cust_pkg->setfield('bill', '')
 502       unless defined($cust_pkg->bill);
 503
 504     my $real_pkgpart = $cust_pkg->pkgpart;
 505     my %hash = $cust_pkg->hash;
 506
 507     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 508     # suffer from performance issues
 509     $options{has_hidden} = 0;
 510     my @part_pkg = $part_pkg->self_and_bill_linked;
 511     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 512
 513     # if this package was changed from another package,
 514     # and it hasn't been billed since then,
 515     # and package balances are enabled,
 516     if ( $cust_pkg->change_pkgnum
 517         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 518         and $cust_pkg->change_date <  $invoice_time
 519       and $conf->exists('pkg-balances') )
 520     {
 521       # _transfer_balance will also create the appropriate credit
 522       my @transfer_items = $self->_transfer_balance($cust_pkg);
 523       # $part_pkg[0] is the "real" part_pkg
 524       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 525                   'no_auto' : '';
 526       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 527       # treating this as recur, just because most charges are recur...
 528       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 529
 530       # currently not considering separate_bill here, as it's for
 531       # one-time charges only
 532     }
 533
 534     foreach my $part_pkg ( @part_pkg ) {
 535
 536       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 537
 538       my $pass = '';
 539       if ( $cust_pkg->separate_bill ) {
 540         # if no_auto is also set, that's fine. we just need to not have
 541         # invoices that are both auto and no_auto, and since the package
 542         # gets an invoice all to itself, it will only be one or the other.
 543         $pass = $cust_pkg->pkgnum;
 544         if (!exists $cust_bill_pkg{$pass}) { # it may not exist yet
 545           push @passes, $pass;
 546           $total_setup{$pass} = do { my $z = 0; \$z };
 547           $total_recur{$pass} = do { my $z = 0; \$z };
 548           # it also needs its own tax context
 549           $tax_engines{$pass} = FS::TaxEngine->new(
 550                                   cust_main    => $self,
 551                                   invoice_time => $invoice_time,
 552                                   cancel       => $options{cancel},
 553                                   estimate     => $options{estimate},
 554                                 );
 555           $cust_bill_pkg{$pass} = [];
 556         }
 557       } elsif ( ($cust_pkg->no_auto || $part_pkg->no_auto) ) {
 558         $pass = 'no_auto';
 559       }
 560
 561       my $next_bill = $cust_pkg->getfield('bill') || 0;
 562       my $error;
 563       # let this run once if this is the last bill upon cancellation
 564       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 565         $error =
 566           $self->_make_lines( 'part_pkg'            => $part_pkg,
 567                               'cust_pkg'            => $cust_pkg,
 568                               'precommit_hooks'     => \@precommit_hooks,
 569                               'line_items'          => $cust_bill_pkg{$pass},
 570                               'setup'               => $total_setup{$pass},
 571                               'recur'               => $total_recur{$pass},
 572                               'tax_engine'          => $tax_engines{$pass},
 573                               'time'                => $time,
 574                               'real_pkgpart'        => $real_pkgpart,
 575                               'options'             => \%options,
 576                             );
 577
 578         # Stop if anything goes wrong
 579         last if $error;
 580
 581         # or if we're not incrementing the bill date.
 582         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 583
 584         # or if we're letting it run only once
 585         last if $options{cancel};
 586
 587         $next_bill = $cust_pkg->getfield('bill') || 0;
 588
 589         #stop if -o was passed to freeside-daily
 590         last if $options{'one_recur'};
 591       }
 592       if ($error) {
 593         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 594         return $error;
 595       }
 596
 597     } #foreach my $part_pkg
 598
 599   } #foreach my $cust_pkg
 600
 601   foreach my $pass (@passes) { # keys %cust_bill_pkg )
 602
 603     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 604
 605     warn "$me billing pass $pass\n"
 606            #.Dumper(\@cust_bill_pkg)."\n"
 607       if $DEBUG > 2;
 608
 609     ###
 610     # process fees
 611     ###
 612
 613     my @pending_fees = FS::FeeOrigin_Mixin->by_cust($self->custnum,
 614       hashref => { 'billpkgnum' => '' }
 615     );
 616     warn "$me found pending fees:\n".Dumper(\@pending_fees)."\n"
 617       if @pending_fees and $DEBUG > 1;
 618
 619     # determine whether to generate an invoice
 620     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 621
 622     foreach my $fee (@pending_fees) {
 623       $generate_bill = 1 unless $fee->nextbill;
 624     }
 625
 626     # don't create an invoice with no line items, or where the only line
 627     # items are fees that are supposed to be held until the next invoice
 628     next if !$generate_bill;
 629
 630     # calculate fees...
 631     my @fee_items;
 632     foreach my $fee_origin (@pending_fees) {
 633       my $part_fee = $fee_origin->part_fee;
 634
 635       # check whether the fee is applicable before doing anything expensive:
 636       #
 637       # if the fee def belongs to a different agent, don't charge the fee.
 638       # event conditions should prevent this, but just in case they don't,
 639       # skip the fee.
 640       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 641         warn "tried to charge fee#".$part_fee->feepart .
 642              " on customer#".$self->custnum." from a different agent.\n";
 643         next;
 644       }
 645       # also skip if it's disabled
 646       next if $part_fee->disabled eq 'Y';
 647
 648       # Decide which invoice to base the fee on.
 649       my $cust_bill = $fee_origin->cust_bill;
 650       if (!$cust_bill) {
 651         # Then link it to the current invoice. This isn't the real cust_bill
 652         # object that will be inserted--in particular there are no taxes yet.
 653         # If you want to charge a fee on the total invoice amount including
 654         # taxes, you have to put the fee on the next invoice.
 655         $cust_bill = FS::cust_bill->new({
 656             'custnum'       => $self->custnum,
 657             'cust_bill_pkg' => \@cust_bill_pkg,
 658             'charged'       => ${ $total_setup{$pass} } +
 659                                ${ $total_recur{$pass} },
 660         });
 661
 662         # If the origin is for a specific package, then only apply the fee to
 663         # line items from that package.
 664         if ( my $cust_pkg = $fee_origin->cust_pkg ) {
 665           my @charge_fee_on_item;
 666           my $charge_fee_on_amount = 0;
 667           foreach (@cust_bill_pkg) {
 668             if ($_->pkgnum == $cust_pkg->pkgnum) {
 669               push @charge_fee_on_item, $_;
 670               $charge_fee_on_amount += $_->setup + $_->recur;
 671             }
 672           }
 673           $cust_bill->set('cust_bill_pkg', \@charge_fee_on_item);
 674           $cust_bill->set('charged', $charge_fee_on_amount);
 675         }
 676
 677       } # $cust_bill is now set
 678       # calculate the fee
 679       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 680       # link this so that we can clear the marker on inserting the line item
 681       $fee_item->set('fee_origin', $fee_origin);
 682       push @fee_items, $fee_item;
 683
 684     }
 685
 686     # add fees to the invoice
 687     foreach my $fee_item (@fee_items) {
 688
 689       push @cust_bill_pkg, $fee_item;
 690       ${ $total_setup{$pass} } += $fee_item->setup;
 691       ${ $total_recur{$pass} } += $fee_item->recur;
 692
 693       my $part_fee = $fee_item->part_fee;
 694       my $fee_location = $self->ship_location; # I think?
 695
 696       my $error = $tax_engines{''}->add_sale($fee_item);
 697
 698       return $error if $error;
 699
 700     }
 701
 702     # XXX implementation of fees is supposed to make this go away...
 703     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 704            !$conf->exists('postal_invoice-recurring_only')
 705        )
 706     {
 707
 708       my $postal_pkg = $self->charge_postal_fee();
 709       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 710
 711         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 712         return "can't charge postal invoice fee for customer ".
 713           $self->custnum. ": $postal_pkg";
 714
 715       } elsif ( $postal_pkg ) {
 716
 717         my $real_pkgpart = $postal_pkg->pkgpart;
 718         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 719         # suffer from performance issues
 720         $options{has_hidden} = 0;
 721         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 722         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 723
 724         foreach my $part_pkg ( @part_pkg ) {
 725           my %postal_options = %options;
 726           delete $postal_options{cancel};
 727           my $error =
 728             $self->_make_lines( 'part_pkg'            => $part_pkg,
 729                                 'cust_pkg'            => $postal_pkg,
 730                                 'precommit_hooks'     => \@precommit_hooks,
 731                                 'line_items'          => \@cust_bill_pkg,
 732                                 'setup'               => $total_setup{$pass},
 733                                 'recur'               => $total_recur{$pass},
 734                                 'tax_engine'          => $tax_engines{$pass},
 735                                 'time'                => $time,
 736                                 'real_pkgpart'        => $real_pkgpart,
 737                                 'options'             => \%postal_options,
 738                               );
 739           if ($error) {
 740             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 741             return $error;
 742           }
 743         }
 744
 745         # it's silly to have a zero value postal_pkg, but....
 746         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 747
 748       }
 749
 750     }
 751
 752     #add tax adjustments
 753     #XXX does this work with batch tax engines?
 754     warn "adding tax adjustments...\n" if $DEBUG > 2;
 755     foreach my $cust_tax_adjustment (
 756       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 757                                        'billpkgnum' => '',
 758                                      }
 759              )
 760     ) {
 761
 762       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 763
 764       my $itemdesc = $cust_tax_adjustment->taxname;
 765       $itemdesc = '' if $itemdesc eq 'Tax';
 766
 767       push @cust_bill_pkg, new FS::cust_bill_pkg {
 768         'pkgnum'      => 0,
 769         'setup'       => $tax,
 770         'recur'       => 0,
 771         'sdate'       => '',
 772         'edate'       => '',
 773         'itemdesc'    => $itemdesc,
 774         'itemcomment' => $cust_tax_adjustment->comment,
 775         'cust_tax_adjustment' => $cust_tax_adjustment,
 776         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 777       };
 778
 779     }
 780
 781     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 782
 783     my $balance = $self->balance;
 784
 785     my $previous_bill = qsearchs({ 'table'     => 'cust_bill',
 786                                    'hashref'   => { custnum=>$self->custnum },
 787                                    'extra_sql' => 'ORDER BY _date DESC LIMIT 1',
 788                                 });
 789     my $previous_balance =
 790       $previous_bill
 791         ? ( $previous_bill->billing_balance + $previous_bill->charged )
 792         : 0;
 793
 794     $log->debug('creating the new invoice', %logopt);
 795     warn "creating the new invoice\n" if $DEBUG;
 796     #create the new invoice
 797     my $cust_bill = new FS::cust_bill ( {
 798       'custnum'             => $self->custnum,
 799       '_date'               => $invoice_time,
 800       'charged'             => $charged,
 801       'billing_balance'     => $balance,
 802       'previous_balance'    => $previous_balance,
 803       'invoice_terms'       => $options{'invoice_terms'},
 804       'cust_bill_pkg'       => \@cust_bill_pkg,
 805       'pending'             => 'Y', # clear this after doing taxes
 806     } );
 807
 808     if (!$options{no_commit}) {
 809       # probably we ought to insert it as pending, and then rollback
 810       # without ever un-pending it
 811       $error = $cust_bill->insert;
 812       if ( $error ) {
 813         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 814         return "can't create invoice for customer #". $self->custnum. ": $error";
 815       }
 816
 817     }
 818
 819     # calculate and append taxes
 820     if ( ! $tax_is_batch) {
 821       local $@;
 822       my $arrayref = eval { $tax_engines{$pass}->calculate_taxes($cust_bill) };
 823
 824       if ( $@ ) {
 825         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 826         return $@;
 827       }
 828
 829       # or should this be in TaxEngine?
 830       my $total_tax = 0;
 831       foreach my $taxline ( @$arrayref ) {
 832         $total_tax += $taxline->setup;
 833         $taxline->set('invnum' => $cust_bill->invnum); # just to be sure
 834         push @cust_bill_pkg, $taxline; # for return_bill
 835
 836         if (!$options{no_commit}) {
 837           my $error = $taxline->insert;
 838           if ( $error ) {
 839             $dbh->rollback if $oldAutoCommit;
 840             return $error;
 841           }
 842         }
 843
 844       }
 845
 846       # add tax to the invoice amount and finalize it
 847       ${ $total_setup{$pass} } = sprintf('%.2f', ${ $total_setup{$pass} } + $total_tax);
 848       $charged = sprintf('%.2f', $charged + $total_tax);
 849       $cust_bill->set('charged', $charged);
 850       $cust_bill->set('pending', '');
 851
 852       if (!$options{no_commit}) {
 853         my $error = $cust_bill->replace;
 854         if ( $error ) {
 855           $dbh->rollback if $oldAutoCommit;
 856           return $error;
 857         }
 858       }
 859
 860     } # if !$tax_is_batch
 861       # if it IS batch, then we'll do all this in process_tax_batch
 862
 863     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 864
 865   } #foreach my $pass ( keys %cust_bill_pkg )
 866
 867   foreach my $hook ( @precommit_hooks ) {
 868     eval {
 869       &{$hook}; #($self) ?
 870     } unless $options{no_commit};
 871     if ( $@ ) {
 872       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 873       return "$@ running precommit hook $hook\n";
 874     }
 875   }
 876
 877   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 878
 879   ''; #no error
 880 }
 881
 882 #discard bundled packages of 0 value
 883 # XXX we should reconsider whether we even need this
 884 sub _omit_zero_value_bundles {
 885   my @in = @_;
 886
 887   my @out = ();
 888   my @bundle = ();
 889   my $discount_show_always = $conf->exists('discount-show-always');
 890   my $show_this = 0;
 891
 892   # Sort @in the same way we do during invoice rendering, so we can identify
 893   # bundles.  See FS::Template_Mixin::_items_nontax.
 894   @in = sort { $a->pkgnum <=> $b->pkgnum        or
 895                $a->sdate  <=> $b->sdate         or
 896                ($a->pkgpart_override ? 0 : -1)  or
 897                ($b->pkgpart_override ? 0 : 1)   or
 898                $b->hidden cmp $a->hidden        or
 899                $a->pkgpart_override <=> $b->pkgpart_override
 900              } @in;
 901
 902   # this is a pack-and-deliver pattern. every time there's a cust_bill_pkg
 903   # _without_ pkgpart_override, that's the start of the new bundle. if there's
 904   # an existing bundle, and it contains a nonzero amount (or a zero amount
 905   # that's displayable anyway), push all line items in the bundle.
 906   foreach my $cust_bill_pkg ( @in ) {
 907
 908     if (scalar(@bundle) and !$cust_bill_pkg->pkgpart_override) {
 909       # ship out this bundle and reset it
 910       if ( $show_this ) {
 911         push @out, @bundle;
 912       }
 913       @bundle = ();
 914       $show_this = 0;
 915     }
 916
 917     # add this item to the current bundle
 918     push @bundle, $cust_bill_pkg;
 919
 920     # determine if it makes the bundle displayable
 921     if (   $cust_bill_pkg->setup > 0
 922         or $cust_bill_pkg->recur > 0
 923         or $cust_bill_pkg->setup_show_zero
 924         or $cust_bill_pkg->recur_show_zero
 925         or ($discount_show_always
 926           and scalar(@{ $cust_bill_pkg->get('discounts')})
 927           )
 928     ) {
 929       $show_this++;
 930     }
 931   }
 932
 933   # last bundle
 934   if ( $show_this) {
 935     push @out, @bundle;
 936   }
 937
 938   warn "  _omit_zero_value_bundles: ". scalar(@in).
 939        '->'. scalar(@out). "\n" #. Dumper(@out). "\n"
 940     if $DEBUG > 2;
 941
 942   @out;
 943 }
 944
 945 sub _make_lines {
 946   my ($self, %params) = @_;
 947
 948   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 949
 950   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
 951   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
 952   my $cust_location = $cust_pkg->tax_location;
 953   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
 954   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
 955   my $total_setup = $params{setup} or die "no setup accumulator specified";
 956   my $total_recur = $params{recur} or die "no recur accumulator specified";
 957   my $time = $params{'time'} or die "no time specified";
 958   my (%options) = %{$params{options}};
 959
 960   my $tax_engine = $params{tax_engine};
 961
 962   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
 963     # this should never happen
 964     die 'freq_override billing attempted on non-monthly package '.
 965       $cust_pkg->pkgnum;
 966   }
 967
 968   my $dbh = dbh;
 969   my $real_pkgpart = $params{real_pkgpart};
 970   my %hash = $cust_pkg->hash;
 971   my $old_cust_pkg = new FS::cust_pkg \%hash;
 972
 973   my @details = ();
 974   my $lineitems = 0;
 975
 976   $cust_pkg->pkgpart($part_pkg->pkgpart);
 977
 978   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 979                      ? day_end( $time )
 980                      : $time
 981                  );
 982
 983   ###
 984   # bill setup
 985   ###
 986
 987   my $setup = 0;
 988   my $unitsetup = 0;
 989   my @setup_discounts = ();
 990   my %setup_param = ( 'discounts'     => \@setup_discounts,
 991                       'real_pkgpart'  => $params{real_pkgpart}
 992                     );
 993   my $setup_billed_currency = '';
 994   my $setup_billed_amount = 0;
 995   # Conditions for setting setup date and charging the setup fee:
 996   # - this is not a recurring-only billing run
 997   # - and the package is not currently being canceled
 998   # - and, unless we're specifically told otherwise via 'resetup':
 999   #   - it doesn't already HAVE a setup date
1000   #   - or a start date in the future
1001   #   - and it's not suspended
1002   #
1003   # The last condition used to check the "disable_setup_suspended" option but
1004   # that's obsolete. We now never set the setup date on a suspended package.
1005   if (     ! $options{recurring_only}
1006        and ! $options{cancel}
1007        and ( $options{'resetup'}
1008              || ( ! $cust_pkg->setup
1009                   && ( ! $cust_pkg->start_date
1010                        || $cust_pkg->start_date <= $cmp_time
1011                      )
1012                   && ( ! $cust_pkg->getfield('susp') )
1013                 )
1014            )
1015      )
1016   {
1017
1018     warn "    bill setup\n" if $DEBUG > 1;
1019
1020     unless ( $cust_pkg->waive_setup ) {
1021         $lineitems++;
1022
1023         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1024         return "$@ running calc_setup for $cust_pkg\n"
1025           if $@;
1026
1027         $unitsetup = $cust_pkg->base_setup()
1028                        || $setup; #XXX uuh
1029
1030         if ( $setup_param{'billed_currency'} ) {
1031           $setup_billed_currency = delete $setup_param{'billed_currency'};
1032           $setup_billed_amount   = delete $setup_param{'billed_amount'};
1033         }
1034     }
1035
1036     $cust_pkg->setfield('setup', $time)
1037       unless $cust_pkg->setup;
1038           #do need it, but it won't get written to the db
1039           #|| $cust_pkg->pkgpart != $real_pkgpart;
1040
1041     $cust_pkg->setfield('start_date', '')
1042       if $cust_pkg->start_date;
1043
1044   }
1045
1046   ###
1047   # bill recurring fee
1048   ###
1049
1050   my $recur = 0;
1051   my $unitrecur = 0;
1052   my @recur_discounts = ();
1053   my $recur_billed_currency = '';
1054   my $recur_billed_amount = 0;
1055   my $sdate;
1056   if (     ! $cust_pkg->start_date
1057        and
1058            ( ! $cust_pkg->susp
1059                || ( $cust_pkg->susp != $cust_pkg->order_date
1060                       && (    $cust_pkg->option('suspend_bill',1)
1061                            || ( $part_pkg->option('suspend_bill', 1)
1062                                  && ! $cust_pkg->option('no_suspend_bill',1)
1063                               )
1064                          )
1065                   )
1066                || $cust_pkg->is_status_delay_cancel
1067            )
1068        and
1069             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1070          || ( $part_pkg->plan eq 'voip_cdr'
1071                && $part_pkg->option('bill_every_call')
1072             )
1073          || $options{cancel}
1074   ) {
1075
1076     # XXX should this be a package event?  probably.  events are called
1077     # at collection time at the moment, though...
1078     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1079       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1080       #don't want to reset usage just cause we want a line item??
1081       #&& $part_pkg->pkgpart == $real_pkgpart;
1082
1083     warn "    bill recur\n" if $DEBUG > 1;
1084     $lineitems++;
1085
1086     # XXX shared with $recur_prog
1087     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1088              || $cust_pkg->setup
1089              || $time;
1090
1091     #over two params!  lets at least switch to a hashref for the rest...
1092     my $increment_next_bill = ( $part_pkg->freq ne '0'
1093                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1094                                 && !$options{cancel}
1095                               );
1096     my %param = ( %setup_param,
1097                   'precommit_hooks'     => $precommit_hooks,
1098                   'increment_next_bill' => $increment_next_bill,
1099                   'discounts'           => \@recur_discounts,
1100                   'real_pkgpart'        => $real_pkgpart,
1101                   'freq_override'       => $options{freq_override} || '',
1102                   'setup_fee'           => 0,
1103                 );
1104
1105     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1106
1107     # There may be some part_pkg for which this is wrong.  Only those
1108     # which can_discount are supported.
1109     # (the UI should prevent adding discounts to these at the moment)
1110
1111     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1112          " for pkgpart ". $cust_pkg->pkgpart.
1113          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1114       if $DEBUG > 2;
1115
1116     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1117     return "$@ running $method for $cust_pkg\n"
1118       if ( $@ );
1119
1120     if ($recur eq 'NOTHING') {
1121       # then calc_cancel (or calc_recur but that's not used) has declined to
1122       # generate a recurring lineitem at all. treat this as zero, but also
1123       # try not to generate a lineitem.
1124       $recur = 0;
1125       $lineitems--;
1126     }
1127
1128     #base_cancel???
1129     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1130
1131     if ( $param{'billed_currency'} ) {
1132       $recur_billed_currency = delete $param{'billed_currency'};
1133       $recur_billed_amount   = delete $param{'billed_amount'};
1134     }
1135
1136     if ( $increment_next_bill ) {
1137
1138       my $next_bill;
1139
1140       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1141         # supplemental package
1142         # to keep in sync with the main package, simulate billing at
1143         # its frequency
1144         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1145         my $supp_pkg_freq = $part_pkg->freq;
1146         if ( $supp_pkg_freq == 0 or $main_pkg_freq == 0 ) {
1147           # the UI should prevent setting up packages like this, but just
1148           # in case
1149           return "unable to calculate supplemental package period ratio";
1150         }
1151         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1152         if ( $ratio == int($ratio) ) {
1153           # simple case: main package is X months, supp package is X*A months,
1154           # advance supp package to where the main package will be in A cycles.
1155           $next_bill = $sdate;
1156           for (1..$ratio) {
1157             $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1158           }
1159         } else {
1160           # harder case: main package is X months, supp package is Y months.
1161           # advance supp package by Y months. then if they're within half a
1162           # month of each other, resync them. this may result in the period
1163           # not being exactly Y months.
1164           $next_bill = $part_pkg->add_freq( $sdate, $supp_pkg_freq );
1165           my $main_next_bill = $main_pkg->bill;
1166           if ( $main_pkg->bill <= $time ) {
1167             # then the main package has not yet been billed on this cycle;
1168             # predict what its bill date will be.
1169             $main_next_bill =
1170               $part_pkg->add_freq( $main_next_bill, $main_pkg_freq );
1171           }
1172           if ( abs($main_next_bill - $next_bill) < 86400*15 ) {
1173             $next_bill = $main_next_bill;
1174           }
1175         }
1176
1177       } else {
1178       # the normal case, not a supplemental package
1179       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1180       return "unparsable frequency: ". $part_pkg->freq
1181         if $next_bill == -1;
1182       }
1183
1184       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1185       # only for figuring next bill date, nothing else, so, reset $sdate again
1186       # here
1187       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1188       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1189       $cust_pkg->last_bill($sdate);
1190
1191       $cust_pkg->setfield('bill', $next_bill );
1192
1193     }
1194
1195     if ( $param{'setup_fee'} ) {
1196       # Add an additional setup fee at the billing stage.
1197       # Used for prorate_defer_bill.
1198       $setup += $param{'setup_fee'};
1199       $unitsetup += $param{'setup_fee'};
1200       $lineitems++;
1201     }
1202
1203     if ( defined $param{'discount_left_setup'} ) {
1204         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1205             $setup -= $discount_setup;
1206         }
1207     }
1208
1209   }
1210
1211   warn "\$setup is undefined" unless defined($setup);
1212   warn "\$recur is undefined" unless defined($recur);
1213   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1214
1215   ###
1216   # If there's line items, create em cust_bill_pkg records
1217   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1218   ###
1219
1220   if ( $lineitems ) {
1221
1222     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1223       # hmm.. and if just the options are modified in some weird price plan?
1224
1225       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1226         if $DEBUG >1;
1227
1228       my $error = $cust_pkg->replace( $old_cust_pkg,
1229                                       'depend_jobnum'=>$options{depend_jobnum},
1230                                       'options' => { $cust_pkg->options },
1231                                     )
1232         unless $options{no_commit};
1233       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1234         if $error; #just in case
1235     }
1236
1237     $setup = sprintf( "%.2f", $setup );
1238     $recur = sprintf( "%.2f", $recur );
1239     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1240       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1241     }
1242     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1243       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1244     }
1245
1246     my $discount_show_always = $conf->exists('discount-show-always')
1247                                && (    ($setup == 0 && scalar(@setup_discounts))
1248                                     || ($recur == 0 && scalar(@recur_discounts))
1249                                   );
1250
1251     if (    $setup != 0
1252          || $recur != 0
1253          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1254          || $discount_show_always
1255          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1256          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1257        )
1258     {
1259
1260       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1261         if $DEBUG > 1;
1262
1263       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1264       if ( $DEBUG > 1 ) {
1265         warn "      adding customer package invoice detail: $_\n"
1266           foreach @cust_pkg_detail;
1267       }
1268       push @details, @cust_pkg_detail;
1269
1270       my $cust_bill_pkg = new FS::cust_bill_pkg {
1271         'pkgnum'                => $cust_pkg->pkgnum,
1272         'setup'                 => $setup,
1273         'unitsetup'             => $unitsetup,
1274         'setup_billed_currency' => $setup_billed_currency,
1275         'setup_billed_amount'   => $setup_billed_amount,
1276         'recur'                 => $recur,
1277         'unitrecur'             => $unitrecur,
1278         'recur_billed_currency' => $recur_billed_currency,
1279         'recur_billed_amount'   => $recur_billed_amount,
1280         'quantity'              => $cust_pkg->quantity,
1281         'details'               => \@details,
1282         'discounts'             => [ @setup_discounts, @recur_discounts ],
1283         'hidden'                => $part_pkg->hidden,
1284         'freq'                  => $part_pkg->freq,
1285       };
1286
1287       if ( $part_pkg->option('prorate_defer_bill',1)
1288            and !$hash{last_bill} ) {
1289         # both preceding and upcoming, technically
1290         $cust_bill_pkg->sdate( $cust_pkg->setup );
1291         $cust_bill_pkg->edate( $cust_pkg->bill );
1292       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1293         $cust_bill_pkg->sdate( $hash{last_bill} );
1294         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1295         $cust_bill_pkg->edate( $time ) if $options{cancel};
1296       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' )
1297         $cust_bill_pkg->sdate( $sdate );
1298         $cust_bill_pkg->edate( $cust_pkg->bill );
1299         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1300       }
1301
1302       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1303         unless $part_pkg->pkgpart == $real_pkgpart;
1304
1305       $$total_setup += $setup;
1306       $$total_recur += $recur;
1307
1308       ###
1309       # handle taxes
1310       ###
1311
1312       my $error = $tax_engine->add_sale($cust_bill_pkg);
1313       return $error if $error;
1314
1315       $cust_bill_pkg->set_display(
1316         part_pkg     => $part_pkg,
1317         real_pkgpart => $real_pkgpart,
1318       );
1319
1320       push @$cust_bill_pkgs, $cust_bill_pkg;
1321
1322     } #if $setup != 0 || $recur != 0
1323
1324   } #if $line_items
1325
1326   '';
1327
1328 }
1329
1330 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1331
1332 Takes one argument, a cust_pkg object that is being billed.  This will
1333 be called only if the package was created by a package change, and has
1334 not been billed since the package change, and package balance tracking
1335 is enabled.  The second argument can be an alternate package number to
1336 transfer the balance from; this should not be used externally.
1337
1338 Transfers the balance from the previous package (now canceled) to
1339 this package, by crediting one package and creating an invoice item for
1340 the other.  Inserts the credit and returns the invoice item (so that it
1341 can be added to an invoice that's being built).
1342
1343 If the previous package was never billed, and was also created by a package
1344 change, then this will also transfer the balance from I<its> previous
1345 package, and so on, until reaching a package that either has been billed
1346 or was not created by a package change.
1347
1348 =cut
1349
1350 my $balance_transfer_reason;
1351
1352 sub _transfer_balance {
1353   my $self = shift;
1354   my $cust_pkg = shift;
1355   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1356   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1357
1358   my @transfers;
1359
1360   # if $from_pkg is not the first package in the chain, and it was never
1361   # billed, walk back
1362   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1363     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1364   }
1365
1366   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1367   if ( $prev_balance != 0 ) {
1368     $balance_transfer_reason ||= FS::reason->new_or_existing(
1369       'reason' => 'Package balance transfer',
1370       'type'   => 'Internal adjustment',
1371       'class'  => 'R'
1372     );
1373
1374     my $credit = FS::cust_credit->new({
1375         'custnum'   => $self->custnum,
1376         'amount'    => abs($prev_balance),
1377         'reasonnum' => $balance_transfer_reason->reasonnum,
1378         '_date'     => $cust_pkg->change_date,
1379     });
1380
1381     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1382         'setup'     => 0,
1383         'recur'     => abs($prev_balance),
1384         #'sdate'     => $from_pkg->last_bill, # not sure about this
1385         #'edate'     => $cust_pkg->change_date,
1386         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1387                                  $from_pkg->part_pkg->pkg),
1388     });
1389
1390     if ( $prev_balance > 0 ) {
1391       # credit the old package, charge the new one
1392       $credit->set('pkgnum', $from_pkgnum);
1393       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1394     } else {
1395       # the reverse
1396       $credit->set('pkgnum', $cust_pkg->pkgnum);
1397       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1398     }
1399     my $error = $credit->insert;
1400     die "error transferring package balance from #".$from_pkgnum.
1401         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1402
1403     push @transfers, $cust_bill_pkg;
1404   } # $prev_balance != 0
1405
1406   return @transfers;
1407 }
1408
1409 #### vestigial code ####
1410
1411 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1412
1413 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1414 from _make_lines.
1415
1416 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1417 this:
1418 {
1419   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1420   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1421 }
1422
1423 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1424 is always the cust_main_county or tax_rate identified by the key.
1425
1426 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1427 the 'taxline' method to calculate the amount of the tax.  This doesn't
1428 happen until calculate_taxes, though.
1429
1430 OPTIONS may include:
1431 - part_item: a part_pkg or part_fee object to be used as the package/fee
1432   definition.
1433 - location: a cust_location to be used as the billing location.
1434 - cancel: true if this package is being billed on cancellation.  This
1435   allows tax to be calculated on usage charges only.
1436
1437 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1438 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1439 the customer's default service location).
1440
1441 This method will also calculate exemptions for any taxes that apply to the
1442 line item (using the C<set_exemptions> method of L<FS::cust_bill_pkg>) and
1443 attach them.  This is the only place C<set_exemptions> is called in normal
1444 invoice processing.
1445
1446 =cut
1447
1448 sub _handle_taxes {
1449   my $self = shift;
1450   my $taxlisthash = shift;
1451   my $cust_bill_pkg = shift;
1452   my %options = @_;
1453
1454   # at this point I realize that we have enough information to infer all this
1455   # stuff, instead of passing around giant honking argument lists
1456   my $location = $options{location} || $cust_bill_pkg->tax_location;
1457   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1458
1459   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1460
1461   return if ( $self->payby eq 'COMP' ); #dubious
1462
1463   if ( $conf->config('enable_taxproducts')
1464        && ( scalar($part_item->part_pkg_taxoverride)
1465             || $part_item->has_taxproduct
1466           )
1467      )
1468     {
1469
1470     # EXTERNAL TAX RATES (via tax_rate)
1471     my %cust_bill_pkg = ();
1472     my %taxes = ();
1473
1474     my @classes;
1475     my $usage = $cust_bill_pkg->usage || 0;
1476     push @classes, $cust_bill_pkg->usage_classes if $usage;
1477     push @classes, 'setup' if $cust_bill_pkg->setup and !$options{cancel};
1478     push @classes, 'recur' if ($cust_bill_pkg->recur - $usage)
1479         and !$options{cancel};
1480     # that's better--probably don't even need $options{cancel} now
1481     # but leave it for now, just to be safe
1482     #
1483     # About $options{cancel}: This protects against charging per-line or
1484     # per-customer or other flat-rate surcharges on a package that's being
1485     # billed on cancellation (which is an out-of-cycle bill and should only
1486     # have usage charges).  See RT#29443.
1487
1488     # customer exemption is now handled in the 'taxline' method
1489     #my $exempt = $conf->exists('cust_class-tax_exempt')
1490     #               ? ( $self->cust_class ? $self->cust_class->tax : '' )
1491     #               : $self->tax;
1492     # standardize this just to be sure
1493     #$exempt = ($exempt eq 'Y') ? 'Y' : '';
1494     #
1495     #if ( !$exempt ) {
1496
1497     unless (exists $taxes{''}) {
1498       # unsure what purpose this serves, but last time I deleted something
1499       # from here just because I didn't see the point, it actually did
1500       # something important.
1501       my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1502       return $err_or_ref unless ref($err_or_ref);
1503       $taxes{''} = $err_or_ref;
1504     }
1505
1506     # NO DISINTEGRATIONS.
1507     # my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1508     #
1509     # do not call taxline() with any argument except the entire set of
1510     # cust_bill_pkgs on an invoice that are eligible for the tax.
1511
1512     # only calculate exemptions once for each tax rate, even if it's used
1513     # for multiple classes
1514     my %tax_seen = ();
1515
1516     foreach my $class (@classes) {
1517       my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1518       return $err_or_ref unless ref($err_or_ref);
1519       my @taxes = @$err_or_ref;
1520
1521       next if !@taxes;
1522
1523       foreach my $tax ( @taxes ) {
1524
1525         my $tax_id = ref( $tax ). ' '. $tax->taxnum;
1526         # $taxlisthash: keys are tax identifiers ('FS::tax_rate 123456').
1527         # Values are arrayrefs, first the tax object (cust_main_county
1528         # or tax_rate), then the cust_bill_pkg object that the
1529         # tax applies to, then the tax class (setup, recur, usage classnum).
1530         $taxlisthash->{ $tax_id } ||= [ $tax ];
1531         push @{ $taxlisthash->{ $tax_id  } }, $cust_bill_pkg, $class;
1532
1533         # determine any exemptions that apply
1534         if (!$tax_seen{$tax_id}) {
1535           $cust_bill_pkg->set_exemptions( $tax, custnum => $self->custnum );
1536           $tax_seen{$tax_id} = 1;
1537         }
1538
1539         # tax on tax will be done later, when we actually create the tax
1540         # line items
1541
1542       }
1543     }
1544
1545   } else {
1546
1547     # INTERNAL TAX RATES (cust_main_county)
1548
1549     # We fetch taxes even if the customer is completely exempt,
1550     # because we need to record that fact.
1551
1552     my @loc_keys = qw( district city county state country );
1553     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1554
1555     $taxhash{'taxclass'} = $part_item->taxclass;
1556
1557     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1558
1559     my @taxes = (); # entries are cust_main_county objects
1560     my %taxhash_elim = %taxhash;
1561     my @elim = qw( district city county state );
1562     do {
1563
1564       #first try a match with taxclass
1565       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1566
1567       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1568         #then try a match without taxclass
1569         my %no_taxclass = %taxhash_elim;
1570         $no_taxclass{ 'taxclass' } = '';
1571         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1572       }
1573
1574       $taxhash_elim{ shift(@elim) } = '';
1575
1576     } while ( !scalar(@taxes) && scalar(@elim) );
1577
1578     foreach (@taxes) {
1579       my $tax_id = 'cust_main_county '.$_->taxnum;
1580       $taxlisthash->{$tax_id} ||= [ $_ ];
1581       $cust_bill_pkg->set_exemptions($_, custnum => $self->custnum);
1582       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1583     }
1584
1585   }
1586   '';
1587 }
1588
1589 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1590
1591 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1592 or part_fee (which will define the tax eligibility of the product), CLASS is
1593 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1594 location where the service was provided (or billed, depending on
1595 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1596 can apply to this line item.
1597
1598 =cut
1599
1600 sub _gather_taxes {
1601   my $self = shift;
1602   my $part_item = shift;
1603   my $class = shift;
1604   my $location = shift;
1605
1606   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1607
1608   my $geocode = $location->geocode('cch');
1609
1610   [ $part_item->tax_rates('cch', $geocode, $class) ]
1611
1612 }
1613
1614 #### end vestigial code ####
1615
1616 =item collect [ HASHREF | OPTION => VALUE ... ]
1617
1618 (Attempt to) collect money for this customer's outstanding invoices (see
1619 L<FS::cust_bill>).  Usually used after the bill method.
1620
1621 Actions are now triggered by billing events; see L<FS::part_event> and the
1622 billing events web interface.  Old-style invoice events (see
1623 L<FS::part_bill_event>) have been deprecated.
1624
1625 If there is an error, returns the error, otherwise returns false.
1626
1627 Options are passed as name-value pairs.
1628
1629 Currently available options are:
1630
1631 =over 4
1632
1633 =item invoice_time
1634
1635 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1636
1637 =item retry
1638
1639 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1640
1641 =item check_freq
1642
1643 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1644
1645 =item quiet
1646
1647 set true to surpress email card/ACH decline notices.
1648
1649 =item debug
1650
1651 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1652
1653 =back
1654
1655 # =item payby
1656 #
1657 # allows for one time override of normal customer billing method
1658
1659 =cut
1660
1661 sub collect {
1662   my( $self, %options ) = @_;
1663
1664   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1665
1666   my $invoice_time = $options{'invoice_time'} || time;
1667
1668   #put below somehow?
1669   local $SIG{HUP} = 'IGNORE';
1670   local $SIG{INT} = 'IGNORE';
1671   local $SIG{QUIT} = 'IGNORE';
1672   local $SIG{TERM} = 'IGNORE';
1673   local $SIG{TSTP} = 'IGNORE';
1674   local $SIG{PIPE} = 'IGNORE';
1675
1676   my $oldAutoCommit = $FS::UID::AutoCommit;
1677   local $FS::UID::AutoCommit = 0;
1678   my $dbh = dbh;
1679
1680   $self->select_for_update; #mutex
1681
1682   if ( $DEBUG ) {
1683     my $balance = $self->balance;
1684     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1685   }
1686
1687   if ( exists($options{'retry_card'}) ) {
1688     carp 'retry_card option passed to collect is deprecated; use retry';
1689     $options{'retry'} ||= $options{'retry_card'};
1690   }
1691   if ( exists($options{'retry'}) && $options{'retry'} ) {
1692     my $error = $self->retry_realtime;
1693     if ( $error ) {
1694       $dbh->rollback if $oldAutoCommit;
1695       return $error;
1696     }
1697   }
1698
1699   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1700
1701   #never want to roll back an event just because it returned an error
1702   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1703
1704   $self->do_cust_event(
1705     'debug'      => ( $options{'debug'} || 0 ),
1706     'time'       => $invoice_time,
1707     'check_freq' => $options{'check_freq'},
1708     'stage'      => 'collect',
1709   );
1710
1711 }
1712
1713 =item retry_realtime
1714
1715 Schedules realtime / batch  credit card / electronic check / LEC billing
1716 events for for retry.  Useful if card information has changed or manual
1717 retry is desired.  The 'collect' method must be called to actually retry
1718 the transaction.
1719
1720 Implementation details: For either this customer, or for each of this
1721 customer's open invoices, changes the status of the first "done" (with
1722 statustext error) realtime processing event to "failed".
1723
1724 =cut
1725
1726 sub retry_realtime {
1727   my $self = shift;
1728
1729   local $SIG{HUP} = 'IGNORE';
1730   local $SIG{INT} = 'IGNORE';
1731   local $SIG{QUIT} = 'IGNORE';
1732   local $SIG{TERM} = 'IGNORE';
1733   local $SIG{TSTP} = 'IGNORE';
1734   local $SIG{PIPE} = 'IGNORE';
1735
1736   my $oldAutoCommit = $FS::UID::AutoCommit;
1737   local $FS::UID::AutoCommit = 0;
1738   my $dbh = dbh;
1739
1740   #a little false laziness w/due_cust_event (not too bad, really)
1741
1742   # I guess this is always as of now?
1743   my $join = FS::part_event_condition->join_conditions_sql('', 'time' => time);
1744   my $order = FS::part_event_condition->order_conditions_sql;
1745   my $mine =
1746   '( '
1747    . join ( ' OR ' , map {
1748     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1749     my $custnum = FS::part_event->eventtables_custnum->{$_};
1750     "( part_event.eventtable = " . dbh->quote($_)
1751     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1752     . " from $_ $cust_join"
1753     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1754    } FS::part_event->eventtables)
1755    . ') ';
1756
1757   #here is the agent virtualization
1758   my $agent_virt = " (    part_event.agentnum IS NULL
1759                        OR part_event.agentnum = ". $self->agentnum. ' )';
1760
1761   #XXX this shouldn't be hardcoded, actions should declare it...
1762   my @realtime_events = qw(
1763     cust_bill_realtime_card
1764     cust_bill_realtime_check
1765     cust_bill_realtime_lec
1766     cust_bill_batch
1767   );
1768
1769   my $is_realtime_event =
1770     ' part_event.action IN ( '.
1771         join(',', map "'$_'", @realtime_events ).
1772     ' ) ';
1773
1774   my $batch_or_statustext =
1775     "( part_event.action = 'cust_bill_batch'
1776        OR ( statustext IS NOT NULL AND statustext != '' )
1777      )";
1778
1779
1780   my @cust_event = qsearch({
1781     'table'     => 'cust_event',
1782     'select'    => 'cust_event.*',
1783     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1784     'hashref'   => { 'status' => 'done' },
1785     'extra_sql' => " AND $batch_or_statustext ".
1786                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1787   });
1788
1789   my %seen_invnum = ();
1790   foreach my $cust_event (@cust_event) {
1791
1792     #max one for the customer, one for each open invoice
1793     my $cust_X = $cust_event->cust_X;
1794     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1795                           ? $cust_X->invnum
1796                           : 0
1797                         }++
1798          or $cust_event->part_event->eventtable eq 'cust_bill'
1799             && ! $cust_X->owed;
1800
1801     my $error = $cust_event->retry;
1802     if ( $error ) {
1803       $dbh->rollback if $oldAutoCommit;
1804       return "error scheduling event for retry: $error";
1805     }
1806
1807   }
1808
1809   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1810   '';
1811
1812 }
1813
1814 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1815
1816 Runs billing events; see L<FS::part_event> and the billing events web
1817 interface.
1818
1819 If there is an error, returns the error, otherwise returns false.
1820
1821 Options are passed as name-value pairs.
1822
1823 Currently available options are:
1824
1825 =over 4
1826
1827 =item time
1828
1829 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1830
1831 =item check_freq
1832
1833 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1834
1835 =item stage
1836
1837 "collect" (the default) or "pre-bill"
1838
1839 =item quiet
1840
1841 set true to surpress email card/ACH decline notices.
1842
1843 =item debug
1844
1845 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1846
1847 =back
1848 =cut
1849
1850 # =item payby
1851 #
1852 # allows for one time override of normal customer billing method
1853
1854 # =item retry
1855 #
1856 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1857
1858 sub do_cust_event {
1859   my( $self, %options ) = @_;
1860
1861   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1862
1863   my $time = $options{'time'} || time;
1864
1865   #put below somehow?
1866   local $SIG{HUP} = 'IGNORE';
1867   local $SIG{INT} = 'IGNORE';
1868   local $SIG{QUIT} = 'IGNORE';
1869   local $SIG{TERM} = 'IGNORE';
1870   local $SIG{TSTP} = 'IGNORE';
1871   local $SIG{PIPE} = 'IGNORE';
1872
1873   my $oldAutoCommit = $FS::UID::AutoCommit;
1874   local $FS::UID::AutoCommit = 0;
1875   my $dbh = dbh;
1876
1877   $self->select_for_update; #mutex
1878
1879   if ( $DEBUG ) {
1880     my $balance = $self->balance;
1881     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1882   }
1883
1884 #  if ( exists($options{'retry_card'}) ) {
1885 #    carp 'retry_card option passed to collect is deprecated; use retry';
1886 #    $options{'retry'} ||= $options{'retry_card'};
1887 #  }
1888 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1889 #    my $error = $self->retry_realtime;
1890 #    if ( $error ) {
1891 #      $dbh->rollback if $oldAutoCommit;
1892 #      return $error;
1893 #    }
1894 #  }
1895
1896   # false laziness w/pay_batch::import_results
1897
1898   my $due_cust_event = $self->due_cust_event(
1899     'debug'      => ( $options{'debug'} || 0 ),
1900     'time'       => $time,
1901     'check_freq' => $options{'check_freq'},
1902     'stage'      => ( $options{'stage'} || 'collect' ),
1903   );
1904   unless( ref($due_cust_event) ) {
1905     $dbh->rollback if $oldAutoCommit;
1906     return $due_cust_event;
1907   }
1908
1909   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1910   #never want to roll back an event just because it or a different one
1911   # returned an error
1912   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1913
1914   foreach my $cust_event ( @$due_cust_event ) {
1915
1916     #XXX lock event
1917
1918     #re-eval event conditions (a previous event could have changed things)
1919     unless ( $cust_event->test_conditions ) {
1920       #don't leave stray "new/locked" records around
1921       my $error = $cust_event->delete;
1922       return $error if $error;
1923       next;
1924     }
1925
1926     {
1927       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1928         if $options{'quiet'};
1929       warn "  running cust_event ". $cust_event->eventnum. "\n"
1930         if $DEBUG > 1;
1931
1932       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1933       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
1934         #XXX wtf is this?  figure out a proper dealio with return value
1935         #from do_event
1936         return $error;
1937       }
1938     }
1939
1940   }
1941
1942   '';
1943
1944 }
1945
1946 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1947
1948 Inserts database records for and returns an ordered listref of new events due
1949 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1950 events are due, an empty listref is returned.  If there is an error, returns a
1951 scalar error message.
1952
1953 To actually run the events, call each event's test_condition method, and if
1954 still true, call the event's do_event method.
1955
1956 Options are passed as a hashref or as a list of name-value pairs.  Available
1957 options are:
1958
1959 =over 4
1960
1961 =item check_freq
1962
1963 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1964
1965 =item stage
1966
1967 "collect" (the default) or "pre-bill"
1968
1969 =item time
1970
1971 "Current time" for the events.
1972
1973 =item debug
1974
1975 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1976
1977 =item eventtable
1978
1979 Only return events for the specified eventtable (by default, events of all eventtables are returned)
1980
1981 =item objects
1982
1983 Explicitly pass the objects to be tested (typically used with eventtable).
1984
1985 =item testonly
1986
1987 Set to true to return the objects, but not actually insert them into the
1988 database.
1989
1990 =back
1991
1992 =cut
1993
1994 sub due_cust_event {
1995   my $self = shift;
1996   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
1997
1998   #???
1999   #my $DEBUG = $opt{'debug'}
2000   $opt{'debug'} ||= 0; # silence some warnings
2001   local($DEBUG) = $opt{'debug'}
2002     if $opt{'debug'} > $DEBUG;
2003   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2004
2005   warn "$me due_cust_event called with options ".
2006        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2007     if $DEBUG;
2008
2009   $opt{'time'} ||= time;
2010
2011   local $SIG{HUP} = 'IGNORE';
2012   local $SIG{INT} = 'IGNORE';
2013   local $SIG{QUIT} = 'IGNORE';
2014   local $SIG{TERM} = 'IGNORE';
2015   local $SIG{TSTP} = 'IGNORE';
2016   local $SIG{PIPE} = 'IGNORE';
2017
2018   my $oldAutoCommit = $FS::UID::AutoCommit;
2019   local $FS::UID::AutoCommit = 0;
2020   my $dbh = dbh;
2021
2022   $self->select_for_update #mutex
2023     unless $opt{testonly};
2024
2025   ###
2026   # find possible events (initial search)
2027   ###
2028
2029   my @cust_event = ();
2030
2031   my @eventtable = $opt{'eventtable'}
2032                      ? ( $opt{'eventtable'} )
2033                      : FS::part_event->eventtables_runorder;
2034
2035   my $check_freq = $opt{'check_freq'} || '1d';
2036
2037   foreach my $eventtable ( @eventtable ) {
2038
2039     my @objects;
2040     if ( $opt{'objects'} ) {
2041
2042       @objects = @{ $opt{'objects'} };
2043
2044     } elsif ( $eventtable eq 'cust_main' ) {
2045
2046       @objects = ( $self );
2047
2048     } else {
2049
2050       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2051       # linkage not needed here because FS::cust_main->$eventtable will
2052       # already supply it
2053
2054       #some false laziness w/Cron::bill bill_where
2055
2056       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable,
2057         'time' => $opt{'time'});
2058       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2059         'time'=>$opt{'time'},
2060       );
2061       $where = $where ? "AND $where" : '';
2062
2063       my $are_part_event =
2064       "EXISTS ( SELECT 1 FROM part_event $join
2065         WHERE check_freq = '$check_freq'
2066         AND eventtable = '$eventtable'
2067         AND ( disabled = '' OR disabled IS NULL )
2068         $where
2069         )
2070       ";
2071       #eofalse
2072
2073       @objects = $self->$eventtable(
2074         'addl_from' => $cm_join,
2075         'extra_sql' => " AND $are_part_event",
2076       );
2077     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2078
2079     my @e_cust_event = ();
2080
2081     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2082
2083     my $cross = "CROSS JOIN $eventtable $linkage";
2084     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2085       unless $eventtable eq 'cust_main';
2086
2087     foreach my $object ( @objects ) {
2088
2089       #this first search uses the condition_sql magic for optimization.
2090       #the more possible events we can eliminate in this step the better
2091
2092       my $cross_where = '';
2093       my $pkey = $object->primary_key;
2094       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2095
2096       my $join = FS::part_event_condition->join_conditions_sql( $eventtable,
2097         'time' => $opt{'time'});
2098       my $extra_sql =
2099         FS::part_event_condition->where_conditions_sql( $eventtable,
2100                                                         'time'=>$opt{'time'}
2101                                                       );
2102       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2103
2104       $extra_sql = "AND $extra_sql" if $extra_sql;
2105
2106       #here is the agent virtualization
2107       $extra_sql .= " AND (    part_event.agentnum IS NULL
2108                             OR part_event.agentnum = ". $self->agentnum. ' )';
2109
2110       $extra_sql .= " $order";
2111
2112       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2113         if $opt{'debug'} > 2;
2114       my @part_event = qsearch( {
2115         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2116         'select'    => 'part_event.*',
2117         'table'     => 'part_event',
2118         'addl_from' => "$cross $join",
2119         'hashref'   => { 'check_freq' => $check_freq,
2120                          'eventtable' => $eventtable,
2121                          'disabled'   => '',
2122                        },
2123         'extra_sql' => "AND $cross_where $extra_sql",
2124       } );
2125
2126       if ( $DEBUG > 2 ) {
2127         my $pkey = $object->primary_key;
2128         warn "      ". scalar(@part_event).
2129              " possible events found for $eventtable ". $object->$pkey(). "\n";
2130       }
2131
2132       push @e_cust_event, map {
2133         $_->new_cust_event($object, 'time' => $opt{'time'})
2134       } @part_event;
2135
2136     }
2137
2138     warn "    ". scalar(@e_cust_event).
2139          " subtotal possible cust events found for $eventtable\n"
2140       if $DEBUG > 1;
2141
2142     push @cust_event, @e_cust_event;
2143
2144   }
2145
2146   warn "  ". scalar(@cust_event).
2147        " total possible cust events found in initial search\n"
2148     if $DEBUG; # > 1;
2149
2150
2151   ##
2152   # test stage
2153   ##
2154
2155   $opt{stage} ||= 'collect';
2156   @cust_event =
2157     grep { my $stage = $_->part_event->event_stage;
2158            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2159          }
2160          @cust_event;
2161
2162   ##
2163   # test conditions
2164   ##
2165
2166   my %unsat = ();
2167
2168   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2169                      @cust_event;
2170
2171   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2172     if $DEBUG; # > 1;
2173
2174   warn "    invalid conditions not eliminated with condition_sql:\n".
2175        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2176     if keys %unsat && $DEBUG; # > 1;
2177
2178   ##
2179   # insert
2180   ##
2181
2182   unless( $opt{testonly} ) {
2183     foreach my $cust_event ( @cust_event ) {
2184
2185       my $error = $cust_event->insert();
2186       if ( $error ) {
2187         $dbh->rollback if $oldAutoCommit;
2188         return $error;
2189       }
2190
2191     }
2192   }
2193
2194   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2195
2196   ##
2197   # return
2198   ##
2199
2200   warn "  returning events: ". Dumper(@cust_event). "\n"
2201     if $DEBUG > 2;
2202
2203   \@cust_event;
2204
2205 }
2206
2207 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2208
2209 Applies unapplied payments and credits.
2210 Payments with the no_auto_apply flag set will not be applied.
2211
2212 In most cases, this new method should be used in place of sequential
2213 apply_payments and apply_credits methods.
2214
2215 A hash of optional arguments may be passed.  Currently "manual" is supported.
2216 If true, a payment receipt is sent instead of a statement when
2217 'payment_receipt_email' configuration option is set.
2218
2219 If there is an error, returns the error, otherwise returns false.
2220
2221 =cut
2222
2223 sub apply_payments_and_credits {
2224   my( $self, %options ) = @_;
2225
2226   local $SIG{HUP} = 'IGNORE';
2227   local $SIG{INT} = 'IGNORE';
2228   local $SIG{QUIT} = 'IGNORE';
2229   local $SIG{TERM} = 'IGNORE';
2230   local $SIG{TSTP} = 'IGNORE';
2231   local $SIG{PIPE} = 'IGNORE';
2232
2233   my $oldAutoCommit = $FS::UID::AutoCommit;
2234   local $FS::UID::AutoCommit = 0;
2235   my $dbh = dbh;
2236
2237   $self->select_for_update; #mutex
2238
2239   foreach my $cust_bill ( $self->open_cust_bill ) {
2240     my $error = $cust_bill->apply_payments_and_credits(%options);
2241     if ( $error ) {
2242       $dbh->rollback if $oldAutoCommit;
2243       return "Error applying: $error";
2244     }
2245   }
2246
2247   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2248   ''; #no error
2249
2250 }
2251
2252 =item apply_credits OPTION => VALUE ...
2253
2254 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2255 to outstanding invoice balances in chronological order (or reverse
2256 chronological order if the I<order> option is set to B<newest>) and returns the
2257 value of any remaining unapplied credits available for refund (see
2258 L<FS::cust_refund>).
2259
2260 Dies if there is an error.
2261
2262 =cut
2263
2264 sub apply_credits {
2265   my $self = shift;
2266   my %opt = @_;
2267
2268   local $SIG{HUP} = 'IGNORE';
2269   local $SIG{INT} = 'IGNORE';
2270   local $SIG{QUIT} = 'IGNORE';
2271   local $SIG{TERM} = 'IGNORE';
2272   local $SIG{TSTP} = 'IGNORE';
2273   local $SIG{PIPE} = 'IGNORE';
2274
2275   my $oldAutoCommit = $FS::UID::AutoCommit;
2276   local $FS::UID::AutoCommit = 0;
2277   my $dbh = dbh;
2278
2279   $self->select_for_update; #mutex
2280
2281   unless ( $self->total_unapplied_credits ) {
2282     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2283     return 0;
2284   }
2285
2286   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2287       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2288
2289   my @invoices = $self->open_cust_bill;
2290   @invoices = sort { $b->_date <=> $a->_date } @invoices
2291     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2292
2293   if ( $conf->exists('pkg-balances') ) {
2294     # limit @credits to those w/ a pkgnum grepped from $self
2295     my %pkgnums = ();
2296     foreach my $i (@invoices) {
2297       foreach my $li ( $i->cust_bill_pkg ) {
2298         $pkgnums{$li->pkgnum} = 1;
2299       }
2300     }
2301     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2302   }
2303
2304   my $credit;
2305
2306   foreach my $cust_bill ( @invoices ) {
2307
2308     if ( !defined($credit) || $credit->credited == 0) {
2309       $credit = pop @credits or last;
2310     }
2311
2312     my $owed;
2313     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2314       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2315     } else {
2316       $owed = $cust_bill->owed;
2317     }
2318     unless ( $owed > 0 ) {
2319       push @credits, $credit;
2320       next;
2321     }
2322
2323     my $amount = min( $credit->credited, $owed );
2324
2325     my $cust_credit_bill = new FS::cust_credit_bill ( {
2326       'crednum' => $credit->crednum,
2327       'invnum'  => $cust_bill->invnum,
2328       'amount'  => $amount,
2329     } );
2330     $cust_credit_bill->pkgnum( $credit->pkgnum )
2331       if $conf->exists('pkg-balances') && $credit->pkgnum;
2332     my $error = $cust_credit_bill->insert;
2333     if ( $error ) {
2334       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2335       die $error;
2336     }
2337
2338     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2339
2340   }
2341
2342   my $total_unapplied_credits = $self->total_unapplied_credits;
2343
2344   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2345
2346   return $total_unapplied_credits;
2347 }
2348
2349 =item apply_payments  [ OPTION => VALUE ... ]
2350
2351 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2352 to outstanding invoice balances in chronological order.
2353 Payments with the no_auto_apply flag set will not be applied.
2354
2355  #and returns the value of any remaining unapplied payments.
2356
2357 A hash of optional arguments may be passed.  Currently "manual" is supported.
2358 If true, a payment receipt is sent instead of a statement when
2359 'payment_receipt_email' configuration option is set.
2360
2361 Dies if there is an error.
2362
2363 =cut
2364
2365 sub apply_payments {
2366   my( $self, %options ) = @_;
2367
2368   local $SIG{HUP} = 'IGNORE';
2369   local $SIG{INT} = 'IGNORE';
2370   local $SIG{QUIT} = 'IGNORE';
2371   local $SIG{TERM} = 'IGNORE';
2372   local $SIG{TSTP} = 'IGNORE';
2373   local $SIG{PIPE} = 'IGNORE';
2374
2375   my $oldAutoCommit = $FS::UID::AutoCommit;
2376   local $FS::UID::AutoCommit = 0;
2377   my $dbh = dbh;
2378
2379   $self->select_for_update; #mutex
2380
2381   #return 0 unless
2382
2383   my @payments = grep { !$_->no_auto_apply } $self->unapplied_cust_pay;
2384
2385   my @invoices = $self->open_cust_bill;
2386
2387   if ( $conf->exists('pkg-balances') ) {
2388     # limit @payments to those w/ a pkgnum grepped from $self
2389     my %pkgnums = ();
2390     foreach my $i (@invoices) {
2391       foreach my $li ( $i->cust_bill_pkg ) {
2392         $pkgnums{$li->pkgnum} = 1;
2393       }
2394     }
2395     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2396   }
2397
2398   my $payment;
2399
2400   foreach my $cust_bill ( @invoices ) {
2401
2402     if ( !defined($payment) || $payment->unapplied == 0 ) {
2403       $payment = pop @payments or last;
2404     }
2405
2406     my $owed;
2407     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2408       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2409     } else {
2410       $owed = $cust_bill->owed;
2411     }
2412     unless ( $owed > 0 ) {
2413       push @payments, $payment;
2414       next;
2415     }
2416
2417     my $amount = min( $payment->unapplied, $owed );
2418
2419     my $cbp = {
2420       'paynum' => $payment->paynum,
2421       'invnum' => $cust_bill->invnum,
2422       'amount' => $amount,
2423     };
2424     $cbp->{_date} = $payment->_date
2425         if $options{'manual'} && $options{'backdate_application'};
2426     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2427     $cust_bill_pay->pkgnum( $payment->pkgnum )
2428       if $conf->exists('pkg-balances') && $payment->pkgnum;
2429     my $error = $cust_bill_pay->insert(%options);
2430     if ( $error ) {
2431       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2432       die $error;
2433     }
2434
2435     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2436
2437   }
2438
2439   my $total_unapplied_payments = $self->total_unapplied_payments;
2440
2441   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2442
2443   return $total_unapplied_payments;
2444 }
2445
2446 =back
2447
2448 =head1 FLOW
2449
2450   bill_and_collect
2451
2452     cancel_expired_pkgs
2453     suspend_adjourned_pkgs
2454     unsuspend_resumed_pkgs
2455
2456     bill
2457       (do_cust_event pre-bill)
2458       _make_lines
2459       _omit_zero_value_bundles
2460       calculate_taxes
2461
2462     apply_payments_and_credits
2463     collect
2464       do_cust_event
2465         due_cust_event
2466
2467 =head1 BUGS
2468
2469 =head1 SEE ALSO
2470
2471 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2472
2473 =cut
2474
2475 1;