FS/FS/cust_main/Billing.pm

   1 package FS::cust_main::Billing;
   2
   3 use strict;
   4 use vars qw( $conf $DEBUG $me );
   5 use Carp;
   6 use Data::Dumper;
   7 use List::Util qw( min );
   8 use FS::UID qw( dbh );
   9 use FS::Record qw( qsearch qsearchs dbdef );
  10 use FS::Misc::DateTime qw( day_end );
  11 use Tie::RefHash;
  12 use FS::cust_bill;
  13 use FS::cust_bill_pkg;
  14 use FS::cust_bill_pkg_display;
  15 use FS::cust_bill_pay;
  16 use FS::cust_credit_bill;
  17 use FS::cust_tax_adjustment;
  18 use FS::tax_rate;
  19 use FS::tax_rate_location;
  20 use FS::cust_bill_pkg_tax_location;
  21 use FS::cust_bill_pkg_tax_rate_location;
  22 use FS::part_event;
  23 use FS::part_event_condition;
  24 use FS::pkg_category;
  25 use FS::FeeOrigin_Mixin;
  26 use FS::Log;
  27 use FS::TaxEngine;
  28
  29 # 1 is mostly method/subroutine entry and options
  30 # 2 traces progress of some operations
  31 # 3 is even more information including possibly sensitive data
  32 $DEBUG = 0;
  33 $me = '[FS::cust_main::Billing]';
  34
  35 install_callback FS::UID sub {
  36   $conf = new FS::Conf;
  37   #yes, need it for stuff below (prolly should be cached)
  38 };
  39
  40 =head1 NAME
  41
  42 FS::cust_main::Billing - Billing mixin for cust_main
  43
  44 =head1 SYNOPSIS
  45
  46 =head1 DESCRIPTION
  47
  48 These methods are available on FS::cust_main objects.
  49
  50 =head1 METHODS
  51
  52 =over 4
  53
  54 =item bill_and_collect
  55
  56 Cancels and suspends any packages due, generates bills, applies payments and
  57 credits, and applies collection events to run cards, send bills and notices,
  58 etc.
  59
  60 By default, warns on errors and continues with the next operation (but see the
  61 "fatal" flag below).
  62
  63 Options are passed as name-value pairs.  Currently available options are:
  64
  65 =over 4
  66
  67 =item time
  68
  69 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
  70
  71  use Date::Parse;
  72  ...
  73  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
  74
  75 =item invoice_time
  76
  77 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
  78
  79 =item check_freq
  80
  81 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
  82
  83 =item resetup
  84
  85 If set true, re-charges setup fees.
  86
  87 =item fatal
  88
  89 If set any errors prevent subsequent operations from continusing.  If set
  90 specifically to "return", returns the error (or false, if there is no error).
  91 Any other true value causes errors to die.
  92
  93 =item debug
  94
  95 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
  96
  97 =item job
  98
  99 Optional FS::queue entry to receive status updates.
 100
 101 =back
 102
 103 Options are passed to the B<bill> and B<collect> methods verbatim, so all
 104 options of those methods are also available.
 105
 106 =cut
 107
 108 sub bill_and_collect {
 109   my( $self, %options ) = @_;
 110
 111   my $log = FS::Log->new('FS::cust_main::Billing::bill_and_collect');
 112   my %logopt = (object => $self);
 113   $log->debug('start', %logopt);
 114
 115   my $error;
 116
 117   #$options{actual_time} not $options{time} because freeside-daily -d is for
 118   #pre-printing invoices
 119
 120   $options{'actual_time'} ||= time;
 121   my $job = $options{'job'};
 122
 123   my $actual_time = ( $conf->exists('next-bill-ignore-time')
 124                         ? day_end( $options{actual_time} )
 125                         : $options{actual_time}
 126                     );
 127
 128   $job->update_statustext('0,cleaning expired packages') if $job;
 129   $log->debug('canceling expired packages', %logopt);
 130   $error = $self->cancel_expired_pkgs( $actual_time );
 131   if ( $error ) {
 132     $error = "Error expiring custnum ". $self->custnum. ": $error";
 133     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 134     elsif ( $options{fatal}                                ) { die    $error; }
 135     else                                                     { warn   $error; }
 136   }
 137
 138   $log->debug('suspending adjourned packages', %logopt);
 139   $error = $self->suspend_adjourned_pkgs( $actual_time );
 140   if ( $error ) {
 141     $error = "Error adjourning custnum ". $self->custnum. ": $error";
 142     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 143     elsif ( $options{fatal}                                ) { die    $error; }
 144     else                                                     { warn   $error; }
 145   }
 146
 147   $log->debug('unsuspending resumed packages', %logopt);
 148   $error = $self->unsuspend_resumed_pkgs( $actual_time );
 149   if ( $error ) {
 150     $error = "Error resuming custnum ".$self->custnum. ": $error";
 151     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 152     elsif ( $options{fatal}                                ) { die    $error; }
 153     else                                                     { warn   $error; }
 154   }
 155
 156   $job->update_statustext('20,billing packages') if $job;
 157   $log->debug('billing packages', %logopt);
 158   $error = $self->bill( %options );
 159   if ( $error ) {
 160     $error = "Error billing custnum ". $self->custnum. ": $error";
 161     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 162     elsif ( $options{fatal}                                ) { die    $error; }
 163     else                                                     { warn   $error; }
 164   }
 165
 166   $job->update_statustext('50,applying payments and credits') if $job;
 167   $log->debug('applying payments and credits', %logopt);
 168   $error = $self->apply_payments_and_credits;
 169   if ( $error ) {
 170     $error = "Error applying custnum ". $self->custnum. ": $error";
 171     if    ( $options{fatal} && $options{fatal} eq 'return' ) { return $error; }
 172     elsif ( $options{fatal}                                ) { die    $error; }
 173     else                                                     { warn   $error; }
 174   }
 175
 176   # In a batch tax environment, do not run collection if any pending
 177   # invoices were created.  Collection will run after the next tax batch.
 178   my $tax = FS::TaxEngine->new;
 179   if ( $tax->info->{batch} and
 180        qsearch('cust_bill', { custnum => $self->custnum, pending => 'Y' })
 181      )
 182   {
 183     warn "skipped collection for custnum ".$self->custnum.
 184          " due to pending invoices\n" if $DEBUG;
 185   } elsif ( $conf->exists('cancelled_cust-noevents')
 186              && ! $self->num_ncancelled_pkgs )
 187   {
 188     warn "skipped collection for custnum ".$self->custnum.
 189          " because they have no active packages\n" if $DEBUG;
 190   } else {
 191     # run collection normally
 192     $job->update_statustext('70,running collection events') if $job;
 193     $log->debug('running collection events', %logopt);
 194     $error = $self->collect( %options );
 195     if ( $error ) {
 196       $error = "Error collecting custnum ". $self->custnum. ": $error";
 197       if    ($options{fatal} && $options{fatal} eq 'return') { return $error; }
 198       elsif ($options{fatal}                               ) { die    $error; }
 199       else                                                   { warn   $error; }
 200     }
 201   }
 202
 203   $job->update_statustext('100,finished') if $job;
 204   $log->debug('finish', %logopt);
 205
 206   '';
 207
 208 }
 209
 210 sub cancel_expired_pkgs {
 211   my ( $self, $time, %options ) = @_;
 212
 213   my @cancel_pkgs = $self->ncancelled_pkgs( {
 214     'extra_sql' => " AND expire IS NOT NULL AND expire > 0 AND expire <= $time "
 215   } );
 216
 217   my @errors = ();
 218
 219   CUST_PKG: foreach my $cust_pkg ( @cancel_pkgs ) {
 220     my $cpr = $cust_pkg->last_cust_pkg_reason('expire');
 221     my $error;
 222
 223     if ( $cust_pkg->change_to_pkgnum ) {
 224
 225       my $new_pkg = FS::cust_pkg->by_key($cust_pkg->change_to_pkgnum);
 226       if ( !$new_pkg ) {
 227         push @errors, 'can\'t change pkgnum '.$cust_pkg->pkgnum.' to pkgnum '.
 228                       $cust_pkg->change_to_pkgnum.'; not expiring';
 229         next CUST_PKG;
 230       }
 231       $error = $cust_pkg->change( 'cust_pkg'        => $new_pkg,
 232                                   'unprotect_svcs'  => 1 );
 233       $error = '' if ref $error eq 'FS::cust_pkg';
 234
 235     } else { # just cancel it
 236        $error = $cust_pkg->cancel($cpr ? ( 'reason'        => $cpr->reasonnum,
 237                                            'reason_otaker' => $cpr->otaker,
 238                                            'time'          => $time,
 239                                          )
 240                                        : ()
 241                                  );
 242     }
 243     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 244   }
 245
 246   join(' / ', @errors);
 247
 248 }
 249
 250 sub suspend_adjourned_pkgs {
 251   my ( $self, $time, %options ) = @_;
 252
 253   my @susp_pkgs = $self->ncancelled_pkgs( {
 254     'extra_sql' =>
 255       " AND ( susp IS NULL OR susp = 0 )
 256         AND (    ( bill    IS NOT NULL AND bill    != 0 AND bill    <  $time )
 257               OR ( adjourn IS NOT NULL AND adjourn != 0 AND adjourn <= $time )
 258             )
 259       ",
 260   } );
 261
 262   #only because there's no SQL test for is_prepaid :/
 263   @susp_pkgs =
 264     grep {     (    $_->part_pkg->is_prepaid
 265                  && $_->bill
 266                  && $_->bill < $time
 267                )
 268             || (    $_->adjourn
 269                  && $_->adjourn <= $time
 270                )
 271
 272          }
 273          @susp_pkgs;
 274
 275   my @errors = ();
 276
 277   foreach my $cust_pkg ( @susp_pkgs ) {
 278     my $cpr = $cust_pkg->last_cust_pkg_reason('adjourn')
 279       if ($cust_pkg->adjourn && $cust_pkg->adjourn < $^T);
 280     my $error = $cust_pkg->suspend($cpr ? ( 'reason' => $cpr->reasonnum,
 281                                             'reason_otaker' => $cpr->otaker
 282                                           )
 283                                         : ()
 284                                   );
 285     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 286   }
 287
 288   join(' / ', @errors);
 289
 290 }
 291
 292 sub unsuspend_resumed_pkgs {
 293   my ( $self, $time, %options ) = @_;
 294
 295   my @unsusp_pkgs = $self->ncancelled_pkgs( {
 296     'extra_sql' => " AND resume IS NOT NULL AND resume > 0 AND resume <= $time "
 297   } );
 298
 299   my @errors = ();
 300
 301   foreach my $cust_pkg ( @unsusp_pkgs ) {
 302     my $error = $cust_pkg->unsuspend( 'time' => $time );
 303     push @errors, 'pkgnum '.$cust_pkg->pkgnum.": $error" if $error;
 304   }
 305
 306   join(' / ', @errors);
 307
 308 }
 309
 310 =item bill OPTIONS
 311
 312 Generates invoices (see L<FS::cust_bill>) for this customer.  Usually used in
 313 conjunction with the collect method by calling B<bill_and_collect>.
 314
 315 If there is an error, returns the error, otherwise returns false.
 316
 317 Options are passed as name-value pairs.  Currently available options are:
 318
 319 =over 4
 320
 321 =item resetup
 322
 323 If set true, re-charges setup fees.
 324
 325 =item recurring_only
 326
 327 If set true then only bill recurring charges, not setup, usage, one time
 328 charges, etc.
 329
 330 =item freq_override
 331
 332 If set, then override the normal frequency and look for a part_pkg_discount
 333 to take at that frequency.  This is appropriate only when the normal
 334 frequency for all packages is monthly, and is an error otherwise.  Use
 335 C<pkg_list> to limit the set of packages included in billing.
 336
 337 =item time
 338
 339 Bills the customer as if it were that time.  Specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.  For example:
 340
 341  use Date::Parse;
 342  ...
 343  $cust_main->bill( 'time' => str2time('April 20th, 2001') );
 344
 345 =item pkg_list
 346
 347 An array ref of specific packages (objects) to attempt billing, instead trying all of them.
 348
 349  $cust_main->bill( pkg_list => [$pkg1, $pkg2] );
 350
 351 =item not_pkgpart
 352
 353 A hashref of pkgparts to exclude from this billing run (can also be specified as a comma-separated scalar).
 354
 355 =item no_prepaid
 356
 357 Do not bill prepaid packages.  Used by freeside-daily.
 358
 359 =item invoice_time
 360
 361 Used in conjunction with the I<time> option, this option specifies the date of for the generated invoices.  Other calculations, such as whether or not to generate the invoice in the first place, are not affected.
 362
 363 =item cancel
 364
 365 This boolean value informs the us that the package is being cancelled.  This
 366 typically might mean not charging the normal recurring fee but only usage
 367 fees since the last billing. Setup charges may be charged.  Not all package
 368 plans support this feature (they tend to charge 0).
 369
 370 =item no_usage_reset
 371
 372 Prevent the resetting of usage limits during this call.
 373
 374 =item no_commit
 375
 376 Do not save the generated bill in the database.  Useful with return_bill
 377
 378 =item return_bill
 379
 380 A list reference on which the generated bill(s) will be returned.
 381
 382 =item estimate
 383
 384 Boolean value; indicates that this is an estimate rather than a "tax invoice".
 385 This will be passed through to the tax engine, as online tax services
 386 sometimes need to know it for reporting purposes. Otherwise it has no effect.
 387
 388 =item invoice_terms
 389
 390 Optional terms to be printed on this invoice.  Otherwise, customer-specific
 391 terms or the default terms are used.
 392
 393 =back
 394
 395 =cut
 396
 397 sub bill {
 398   my( $self, %options ) = @_;
 399
 400   return '' if $self->complimentary eq 'Y';
 401
 402   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 403   my $log = FS::Log->new('FS::cust_main::Billing::bill');
 404   my %logopt = (object => $self);
 405
 406   $log->debug('start', %logopt);
 407   warn "$me bill customer ". $self->custnum. "\n"
 408     if $DEBUG;
 409
 410   my $time = $options{'time'} || time;
 411   my $invoice_time = $options{'invoice_time'} || $time;
 412
 413   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 414                      ? day_end( $time )
 415                      : $time
 416                  );
 417
 418   $options{'not_pkgpart'} ||= {};
 419   $options{'not_pkgpart'} = { map { $_ => 1 }
 420                                   split(/\s*,\s*/, $options{'not_pkgpart'})
 421                             }
 422     unless ref($options{'not_pkgpart'});
 423
 424   local $SIG{HUP} = 'IGNORE';
 425   local $SIG{INT} = 'IGNORE';
 426   local $SIG{QUIT} = 'IGNORE';
 427   local $SIG{TERM} = 'IGNORE';
 428   local $SIG{TSTP} = 'IGNORE';
 429   local $SIG{PIPE} = 'IGNORE';
 430
 431   my $oldAutoCommit = $FS::UID::AutoCommit;
 432   local $FS::UID::AutoCommit = 0;
 433   my $dbh = dbh;
 434
 435   $log->debug('acquiring lock', %logopt);
 436   warn "$me acquiring lock on customer ". $self->custnum. "\n"
 437     if $DEBUG;
 438
 439   $self->select_for_update; #mutex
 440
 441   $log->debug('running pre-bill events', %logopt);
 442   warn "$me running pre-bill events for customer ". $self->custnum. "\n"
 443     if $DEBUG;
 444
 445   my $error = $self->do_cust_event(
 446     'debug'      => ( $options{'debug'} || 0 ),
 447     'time'       => $invoice_time,
 448     'check_freq' => $options{'check_freq'},
 449     'stage'      => 'pre-bill',
 450   )
 451     unless $options{no_commit};
 452   if ( $error ) {
 453     $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 454     return $error;
 455   }
 456
 457   $log->debug('done running pre-bill events', %logopt);
 458   warn "$me done running pre-bill events for customer ". $self->custnum. "\n"
 459     if $DEBUG;
 460
 461   #keep auto-charge and non-auto-charge line items separate
 462   my @passes = ( '', 'no_auto' );
 463
 464   my %cust_bill_pkg = map { $_ => [] } @passes;
 465
 466   ###
 467   # find the packages which are due for billing, find out how much they are
 468   # & generate invoice database.
 469   ###
 470
 471   my %total_setup   = map { my $z = 0; $_ => \$z; } @passes;
 472   my %total_recur   = map { my $z = 0; $_ => \$z; } @passes;
 473
 474   my @precommit_hooks = ();
 475
 476   $options{'pkg_list'} ||= [ $self->ncancelled_pkgs ];  #param checks?
 477
 478   my %tax_engines;
 479   my $tax_is_batch = '';
 480   foreach (@passes) {
 481     $tax_engines{$_} = FS::TaxEngine->new(cust_main    => $self,
 482                                           invoice_time => $invoice_time,
 483                                           cancel       => $options{cancel},
 484                                           estimate     => $options{estimate},
 485                                          );
 486     $tax_is_batch ||= $tax_engines{$_}->info->{batch};
 487   }
 488
 489   foreach my $cust_pkg ( @{ $options{'pkg_list'} } ) {
 490
 491     next if $options{'not_pkgpart'}->{$cust_pkg->pkgpart};
 492
 493     my $part_pkg = $cust_pkg->part_pkg;
 494
 495     next if $options{'no_prepaid'} && $part_pkg->is_prepaid;
 496
 497     $log->debug('bill package '. $cust_pkg->pkgnum, %logopt);
 498     warn "  bill package ". $cust_pkg->pkgnum. "\n" if $DEBUG;
 499
 500     #? to avoid use of uninitialized value errors... ?
 501     $cust_pkg->setfield('bill', '')
 502       unless defined($cust_pkg->bill);
 503
 504     my $real_pkgpart = $cust_pkg->pkgpart;
 505     my %hash = $cust_pkg->hash;
 506
 507     # we could implement this bit as FS::part_pkg::has_hidden, but we already
 508     # suffer from performance issues
 509     $options{has_hidden} = 0;
 510     my @part_pkg = $part_pkg->self_and_bill_linked;
 511     $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 512
 513     # if this package was changed from another package,
 514     # and it hasn't been billed since then,
 515     # and package balances are enabled,
 516     if ( $cust_pkg->change_pkgnum
 517         and $cust_pkg->change_date >= ($cust_pkg->last_bill || 0)
 518         and $cust_pkg->change_date <  $invoice_time
 519       and $conf->exists('pkg-balances') )
 520     {
 521       # _transfer_balance will also create the appropriate credit
 522       my @transfer_items = $self->_transfer_balance($cust_pkg);
 523       # $part_pkg[0] is the "real" part_pkg
 524       my $pass = ($cust_pkg->no_auto || $part_pkg[0]->no_auto) ?
 525                   'no_auto' : '';
 526       push @{ $cust_bill_pkg{$pass} }, @transfer_items;
 527       # treating this as recur, just because most charges are recur...
 528       ${$total_recur{$pass}} += $_->recur foreach @transfer_items;
 529
 530       # currently not considering separate_bill here, as it's for
 531       # one-time charges only
 532     }
 533
 534     foreach my $part_pkg ( @part_pkg ) {
 535
 536       $cust_pkg->set($_, $hash{$_}) foreach qw ( setup last_bill bill );
 537
 538       my $pass = '';
 539       if ( $cust_pkg->separate_bill ) {
 540         # if no_auto is also set, that's fine. we just need to not have
 541         # invoices that are both auto and no_auto, and since the package
 542         # gets an invoice all to itself, it will only be one or the other.
 543         $pass = $cust_pkg->pkgnum;
 544         if (!exists $cust_bill_pkg{$pass}) { # it may not exist yet
 545           push @passes, $pass;
 546           $total_setup{$pass} = do { my $z = 0; \$z };
 547           $total_recur{$pass} = do { my $z = 0; \$z };
 548           # it also needs its own tax context
 549           $tax_engines{$pass} = FS::TaxEngine->new(
 550                                   cust_main    => $self,
 551                                   invoice_time => $invoice_time,
 552                                   cancel       => $options{cancel},
 553                                   estimate     => $options{estimate},
 554                                 );
 555           $cust_bill_pkg{$pass} = [];
 556         }
 557       } elsif ( ($cust_pkg->no_auto || $part_pkg->no_auto) ) {
 558         $pass = 'no_auto';
 559       }
 560
 561       my $next_bill = $cust_pkg->getfield('bill') || 0;
 562       my $error;
 563       # let this run once if this is the last bill upon cancellation
 564       while ( $next_bill <= $cmp_time or $options{cancel} ) {
 565         $error =
 566           $self->_make_lines( 'part_pkg'            => $part_pkg,
 567                               'cust_pkg'            => $cust_pkg,
 568                               'precommit_hooks'     => \@precommit_hooks,
 569                               'line_items'          => $cust_bill_pkg{$pass},
 570                               'setup'               => $total_setup{$pass},
 571                               'recur'               => $total_recur{$pass},
 572                               'tax_engine'          => $tax_engines{$pass},
 573                               'time'                => $time,
 574                               'real_pkgpart'        => $real_pkgpart,
 575                               'options'             => \%options,
 576                             );
 577
 578         # Stop if anything goes wrong
 579         last if $error;
 580
 581         # or if we're not incrementing the bill date.
 582         last if ($cust_pkg->getfield('bill') || 0) == $next_bill;
 583
 584         # or if we're letting it run only once
 585         last if $options{cancel};
 586
 587         $next_bill = $cust_pkg->getfield('bill') || 0;
 588
 589         #stop if -o was passed to freeside-daily
 590         last if $options{'one_recur'};
 591       }
 592       if ($error) {
 593         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 594         return $error;
 595       }
 596
 597     } #foreach my $part_pkg
 598
 599   } #foreach my $cust_pkg
 600
 601   foreach my $pass (@passes) { # keys %cust_bill_pkg )
 602
 603     my @cust_bill_pkg = _omit_zero_value_bundles(@{ $cust_bill_pkg{$pass} });
 604
 605     warn "$me billing pass $pass\n"
 606            #.Dumper(\@cust_bill_pkg)."\n"
 607       if $DEBUG > 2;
 608
 609     ###
 610     # process fees
 611     ###
 612
 613     my @pending_fees = FS::FeeOrigin_Mixin->by_cust($self->custnum,
 614       hashref => { 'billpkgnum' => '' }
 615     );
 616     warn "$me found pending fees:\n".Dumper(\@pending_fees)."\n"
 617       if @pending_fees and $DEBUG > 1;
 618
 619     # determine whether to generate an invoice
 620     my $generate_bill = scalar(@cust_bill_pkg) > 0;
 621
 622     foreach my $fee (@pending_fees) {
 623       $generate_bill = 1 unless $fee->nextbill;
 624     }
 625
 626     # don't create an invoice with no line items, or where the only line
 627     # items are fees that are supposed to be held until the next invoice
 628     next if !$generate_bill;
 629
 630     # calculate fees...
 631     my @fee_items;
 632     foreach my $fee_origin (@pending_fees) {
 633       my $part_fee = $fee_origin->part_fee;
 634
 635       # check whether the fee is applicable before doing anything expensive:
 636       #
 637       # if the fee def belongs to a different agent, don't charge the fee.
 638       # event conditions should prevent this, but just in case they don't,
 639       # skip the fee.
 640       if ( $part_fee->agentnum and $part_fee->agentnum != $self->agentnum ) {
 641         warn "tried to charge fee#".$part_fee->feepart .
 642              " on customer#".$self->custnum." from a different agent.\n";
 643         next;
 644       }
 645       # also skip if it's disabled
 646       next if $part_fee->disabled eq 'Y';
 647
 648       # Decide which invoice to base the fee on.
 649       my $cust_bill = $fee_origin->cust_bill;
 650       if (!$cust_bill) {
 651         # Then link it to the current invoice. This isn't the real cust_bill
 652         # object that will be inserted--in particular there are no taxes yet.
 653         # If you want to charge a fee on the total invoice amount including
 654         # taxes, you have to put the fee on the next invoice.
 655         $cust_bill = FS::cust_bill->new({
 656             'custnum'       => $self->custnum,
 657             'cust_bill_pkg' => \@cust_bill_pkg,
 658             'charged'       => ${ $total_setup{$pass} } +
 659                                ${ $total_recur{$pass} },
 660         });
 661
 662         # If the origin is for a specific package, then only apply the fee to
 663         # line items from that package.
 664         if ( my $cust_pkg = $fee_origin->cust_pkg ) {
 665           my @charge_fee_on_item;
 666           my $charge_fee_on_amount = 0;
 667           foreach (@cust_bill_pkg) {
 668             if ($_->pkgnum == $cust_pkg->pkgnum) {
 669               push @charge_fee_on_item, $_;
 670               $charge_fee_on_amount += $_->setup + $_->recur;
 671             }
 672           }
 673           $cust_bill->set('cust_bill_pkg', \@charge_fee_on_item);
 674           $cust_bill->set('charged', $charge_fee_on_amount);
 675         }
 676
 677       } # $cust_bill is now set
 678       # calculate the fee
 679       my $fee_item = $part_fee->lineitem($cust_bill) or next;
 680       # link this so that we can clear the marker on inserting the line item
 681       $fee_item->set('fee_origin', $fee_origin);
 682       push @fee_items, $fee_item;
 683
 684     }
 685
 686     # add fees to the invoice
 687     foreach my $fee_item (@fee_items) {
 688
 689       push @cust_bill_pkg, $fee_item;
 690       ${ $total_setup{$pass} } += $fee_item->setup;
 691       ${ $total_recur{$pass} } += $fee_item->recur;
 692
 693       my $part_fee = $fee_item->part_fee;
 694       my $fee_location = $self->ship_location; # I think?
 695
 696       my $error = $tax_engines{''}->add_sale($fee_item);
 697
 698       return $error if $error;
 699
 700     }
 701
 702     # XXX implementation of fees is supposed to make this go away...
 703     if ( scalar( grep { $_->recur && $_->recur > 0 } @cust_bill_pkg) ||
 704            !$conf->exists('postal_invoice-recurring_only')
 705        )
 706     {
 707
 708       my $postal_pkg = $self->charge_postal_fee();
 709       if ( $postal_pkg && !ref( $postal_pkg ) ) {
 710
 711         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 712         return "can't charge postal invoice fee for customer ".
 713           $self->custnum. ": $postal_pkg";
 714
 715       } elsif ( $postal_pkg ) {
 716
 717         my $real_pkgpart = $postal_pkg->pkgpart;
 718         # we could implement this bit as FS::part_pkg::has_hidden, but we already
 719         # suffer from performance issues
 720         $options{has_hidden} = 0;
 721         my @part_pkg = $postal_pkg->part_pkg->self_and_bill_linked;
 722         $options{has_hidden} = 1 if ($part_pkg[1] && $part_pkg[1]->hidden);
 723
 724         foreach my $part_pkg ( @part_pkg ) {
 725           my %postal_options = %options;
 726           delete $postal_options{cancel};
 727           my $error =
 728             $self->_make_lines( 'part_pkg'            => $part_pkg,
 729                                 'cust_pkg'            => $postal_pkg,
 730                                 'precommit_hooks'     => \@precommit_hooks,
 731                                 'line_items'          => \@cust_bill_pkg,
 732                                 'setup'               => $total_setup{$pass},
 733                                 'recur'               => $total_recur{$pass},
 734                                 'tax_engine'          => $tax_engines{$pass},
 735                                 'time'                => $time,
 736                                 'real_pkgpart'        => $real_pkgpart,
 737                                 'options'             => \%postal_options,
 738                               );
 739           if ($error) {
 740             $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 741             return $error;
 742           }
 743         }
 744
 745         # it's silly to have a zero value postal_pkg, but....
 746         @cust_bill_pkg = _omit_zero_value_bundles(@cust_bill_pkg);
 747
 748       }
 749
 750     }
 751
 752     #add tax adjustments
 753     #XXX does this work with batch tax engines?
 754     warn "adding tax adjustments...\n" if $DEBUG > 2;
 755     foreach my $cust_tax_adjustment (
 756       qsearch('cust_tax_adjustment', { 'custnum'    => $self->custnum,
 757                                        'billpkgnum' => '',
 758                                      }
 759              )
 760     ) {
 761
 762       my $tax = sprintf('%.2f', $cust_tax_adjustment->amount );
 763
 764       my $itemdesc = $cust_tax_adjustment->taxname;
 765       $itemdesc = '' if $itemdesc eq 'Tax';
 766
 767       push @cust_bill_pkg, new FS::cust_bill_pkg {
 768         'pkgnum'      => 0,
 769         'setup'       => $tax,
 770         'recur'       => 0,
 771         'sdate'       => '',
 772         'edate'       => '',
 773         'itemdesc'    => $itemdesc,
 774         'itemcomment' => $cust_tax_adjustment->comment,
 775         'cust_tax_adjustment' => $cust_tax_adjustment,
 776         #'cust_bill_pkg_tax_location' => \@cust_bill_pkg_tax_location,
 777       };
 778
 779     }
 780
 781     my $charged = sprintf('%.2f', ${ $total_setup{$pass} } + ${ $total_recur{$pass} } );
 782
 783     my $balance = $self->balance;
 784
 785     my $previous_bill = qsearchs({ 'table'     => 'cust_bill',
 786                                    'hashref'   => { custnum=>$self->custnum },
 787                                    'extra_sql' => 'ORDER BY _date DESC LIMIT 1',
 788                                 });
 789     my $previous_balance =
 790       $previous_bill
 791         ? ( $previous_bill->billing_balance + $previous_bill->charged )
 792         : 0;
 793
 794     $log->debug('creating the new invoice', %logopt);
 795     warn "creating the new invoice\n" if $DEBUG;
 796     #create the new invoice
 797     my $cust_bill = new FS::cust_bill ( {
 798       'custnum'             => $self->custnum,
 799       '_date'               => $invoice_time,
 800       'charged'             => $charged,
 801       'billing_balance'     => $balance,
 802       'previous_balance'    => $previous_balance,
 803       'invoice_terms'       => $options{'invoice_terms'},
 804       'cust_bill_pkg'       => \@cust_bill_pkg,
 805       'pending'             => 'Y', # clear this after doing taxes
 806     } );
 807
 808     if (!$options{no_commit}) {
 809       # probably we ought to insert it as pending, and then rollback
 810       # without ever un-pending it
 811       $error = $cust_bill->insert;
 812       if ( $error ) {
 813         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 814         return "can't create invoice for customer #". $self->custnum. ": $error";
 815       }
 816
 817     }
 818
 819     # calculate and append taxes
 820     if ( ! $tax_is_batch) {
 821       local $@;
 822       my $arrayref = eval { $tax_engines{$pass}->calculate_taxes($cust_bill) };
 823
 824       if ( $@ ) {
 825         $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 826         return $@;
 827       }
 828
 829       # or should this be in TaxEngine?
 830       my $total_tax = 0;
 831       foreach my $taxline ( @$arrayref ) {
 832         $total_tax += $taxline->setup;
 833         $taxline->set('invnum' => $cust_bill->invnum); # just to be sure
 834         push @cust_bill_pkg, $taxline; # for return_bill
 835
 836         if (!$options{no_commit}) {
 837           my $error = $taxline->insert;
 838           if ( $error ) {
 839             $dbh->rollback if $oldAutoCommit;
 840             return $error;
 841           }
 842         }
 843
 844       }
 845
 846       # add tax to the invoice amount and finalize it
 847       ${ $total_setup{$pass} } = sprintf('%.2f', ${ $total_setup{$pass} } + $total_tax);
 848       $charged = sprintf('%.2f', $charged + $total_tax);
 849       $cust_bill->set('charged', $charged);
 850       $cust_bill->set('pending', '');
 851
 852       if (!$options{no_commit}) {
 853         my $error = $cust_bill->replace;
 854         if ( $error ) {
 855           $dbh->rollback if $oldAutoCommit;
 856           return $error;
 857         }
 858       }
 859
 860     } # if !$tax_is_batch
 861       # if it IS batch, then we'll do all this in process_tax_batch
 862
 863     push @{$options{return_bill}}, $cust_bill if $options{return_bill};
 864
 865   } #foreach my $pass ( keys %cust_bill_pkg )
 866
 867   foreach my $hook ( @precommit_hooks ) {
 868     eval {
 869       &{$hook}; #($self) ?
 870     } unless $options{no_commit};
 871     if ( $@ ) {
 872       $dbh->rollback if $oldAutoCommit && !$options{no_commit};
 873       return "$@ running precommit hook $hook\n";
 874     }
 875   }
 876
 877   $dbh->commit or die $dbh->errstr if $oldAutoCommit && !$options{no_commit};
 878
 879   ''; #no error
 880 }
 881
 882 #discard bundled packages of 0 value
 883 # XXX we should reconsider whether we even need this
 884 sub _omit_zero_value_bundles {
 885   my @in = @_;
 886
 887   my @out = ();
 888   my @bundle = ();
 889   my $discount_show_always = $conf->exists('discount-show-always');
 890   my $show_this = 0;
 891
 892   # Sort @in the same way we do during invoice rendering, so we can identify
 893   # bundles.  See FS::Template_Mixin::_items_nontax.
 894   @in = sort { $a->pkgnum <=> $b->pkgnum        or
 895                $a->sdate  <=> $b->sdate         or
 896                ($a->pkgpart_override ? 0 : -1)  or
 897                ($b->pkgpart_override ? 0 : 1)   or
 898                $b->hidden cmp $a->hidden        or
 899                $a->pkgpart_override <=> $b->pkgpart_override
 900              } @in;
 901
 902   # this is a pack-and-deliver pattern. every time there's a cust_bill_pkg
 903   # _without_ pkgpart_override, that's the start of the new bundle. if there's
 904   # an existing bundle, and it contains a nonzero amount (or a zero amount
 905   # that's displayable anyway), push all line items in the bundle.
 906   foreach my $cust_bill_pkg ( @in ) {
 907
 908     if (scalar(@bundle) and !$cust_bill_pkg->pkgpart_override) {
 909       # ship out this bundle and reset it
 910       if ( $show_this ) {
 911         push @out, @bundle;
 912       }
 913       @bundle = ();
 914       $show_this = 0;
 915     }
 916
 917     # add this item to the current bundle
 918     push @bundle, $cust_bill_pkg;
 919
 920     # determine if it makes the bundle displayable
 921     if (   $cust_bill_pkg->setup > 0
 922         or $cust_bill_pkg->recur > 0
 923         or $cust_bill_pkg->setup_show_zero
 924         or $cust_bill_pkg->recur_show_zero
 925         or ($discount_show_always
 926           and scalar(@{ $cust_bill_pkg->get('discounts')})
 927           )
 928     ) {
 929       $show_this++;
 930     }
 931   }
 932
 933   # last bundle
 934   if ( $show_this) {
 935     push @out, @bundle;
 936   }
 937
 938   warn "  _omit_zero_value_bundles: ". scalar(@in).
 939        '->'. scalar(@out). "\n" #. Dumper(@out). "\n"
 940     if $DEBUG > 2;
 941
 942   @out;
 943 }
 944
 945 sub _make_lines {
 946   my ($self, %params) = @_;
 947
 948   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
 949
 950   my $part_pkg = $params{part_pkg} or die "no part_pkg specified";
 951   my $cust_pkg = $params{cust_pkg} or die "no cust_pkg specified";
 952   my $cust_location = $cust_pkg->tax_location;
 953   my $precommit_hooks = $params{precommit_hooks} or die "no precommit_hooks specified";
 954   my $cust_bill_pkgs = $params{line_items} or die "no line buffer specified";
 955   my $total_setup = $params{setup} or die "no setup accumulator specified";
 956   my $total_recur = $params{recur} or die "no recur accumulator specified";
 957   my $time = $params{'time'} or die "no time specified";
 958   my (%options) = %{$params{options}};
 959
 960   my $tax_engine = $params{tax_engine};
 961
 962   if ( $part_pkg->freq ne '1' and ($options{'freq_override'} || 0) > 0 ) {
 963     # this should never happen
 964     die 'freq_override billing attempted on non-monthly package '.
 965       $cust_pkg->pkgnum;
 966   }
 967
 968   my $dbh = dbh;
 969   my $real_pkgpart = $params{real_pkgpart};
 970   my %hash = $cust_pkg->hash;
 971   my $old_cust_pkg = new FS::cust_pkg \%hash;
 972
 973   my @details = ();
 974   my $lineitems = 0;
 975
 976   $cust_pkg->pkgpart($part_pkg->pkgpart);
 977
 978   my $cmp_time = ( $conf->exists('next-bill-ignore-time')
 979                      ? day_end( $time )
 980                      : $time
 981                  );
 982
 983   ###
 984   # bill setup
 985   ###
 986
 987   my $setup = 0;
 988   my $unitsetup = 0;
 989   my @setup_discounts = ();
 990   my %setup_param = ( 'discounts'     => \@setup_discounts,
 991                       'real_pkgpart'  => $params{real_pkgpart}
 992                     );
 993   my $setup_billed_currency = '';
 994   my $setup_billed_amount = 0;
 995   # Conditions for setting setup date and charging the setup fee:
 996   # - this is not a recurring-only billing run
 997   # - and the package is not currently being canceled
 998   # - and, unless we're specifically told otherwise via 'resetup':
 999   #   - it doesn't already HAVE a setup date
1000   #   - or a start date in the future
1001   #   - and it's not suspended
1002   # - and it doesn't have an expire date in the past
1003   #
1004   # The "disable_setup_suspended" option is now obsolete; we never set the
1005   # setup date on a suspended package.
1006   if (     ! $options{recurring_only}
1007        and ! $options{cancel}
1008        and ( $options{'resetup'}
1009              || ( ! $cust_pkg->setup
1010                   && ( ! $cust_pkg->start_date
1011                        || $cust_pkg->start_date <= $cmp_time
1012                      )
1013                   && ( ! $cust_pkg->getfield('susp') )
1014                 )
1015            )
1016        and ( ! $cust_pkg->expire
1017              || $cust_pkg->expire > $cmp_time )
1018      )
1019   {
1020
1021     warn "    bill setup\n" if $DEBUG > 1;
1022
1023     unless ( $cust_pkg->waive_setup ) {
1024         $lineitems++;
1025
1026         $setup = eval { $cust_pkg->calc_setup( $time, \@details, \%setup_param ) };
1027         return "$@ running calc_setup for $cust_pkg\n"
1028           if $@;
1029
1030         # Only increment unitsetup here if there IS a setup fee.
1031         # prorate_defer_bill may cause calc_setup on a setup-stage package
1032         # to return zero, and the setup fee to be charged later. (This happens
1033         # when it's first billed on the prorate cutoff day. RT#31276.)
1034         if ( $setup ) {
1035           $unitsetup = $cust_pkg->base_setup()
1036                          || $setup; #XXX uuh
1037         }
1038
1039         if ( $setup_param{'billed_currency'} ) {
1040           $setup_billed_currency = delete $setup_param{'billed_currency'};
1041           $setup_billed_amount   = delete $setup_param{'billed_amount'};
1042         }
1043     }
1044
1045     $cust_pkg->setfield('setup', $time)
1046       unless $cust_pkg->setup;
1047           #do need it, but it won't get written to the db
1048           #|| $cust_pkg->pkgpart != $real_pkgpart;
1049
1050     $cust_pkg->setfield('start_date', '')
1051       if $cust_pkg->start_date;
1052
1053   }
1054
1055   ###
1056   # bill recurring fee
1057   ###
1058
1059   my $recur = 0;
1060   my $unitrecur = 0;
1061   my @recur_discounts = ();
1062   my $recur_billed_currency = '';
1063   my $recur_billed_amount = 0;
1064   my $sdate;
1065   # Conditions for billing the recurring fee:
1066   # - the package doesn't have a future start date
1067   # - and it's not suspended
1068   #   - unless suspend_bill is enabled on the package or package def
1069   #     - but still not, if the package is on hold
1070   #   - or it's suspended for a delayed cancellation
1071   # - and its next bill date is in the past
1072   #   - or it doesn't have a next bill date yet
1073   #   - or it's a one-time charge
1074   #   - or it's a CDR plan with the "bill_every_call" option
1075   #   - or it's being canceled
1076   # - and it doesn't have an expire date in the past (this can happen with
1077   #   advance billing)
1078   #   - again, unless it's being canceled
1079   if (     ! $cust_pkg->start_date
1080        and
1081            ( ! $cust_pkg->susp
1082                || ( $cust_pkg->susp != $cust_pkg->order_date
1083                       && (    $cust_pkg->option('suspend_bill',1)
1084                            || ( $part_pkg->option('suspend_bill', 1)
1085                                  && ! $cust_pkg->option('no_suspend_bill',1)
1086                               )
1087                          )
1088                   )
1089                || $cust_pkg->is_status_delay_cancel
1090            )
1091        and
1092             ( $part_pkg->freq ne '0' && ( $cust_pkg->bill || 0 ) <= $cmp_time )
1093          || ( $part_pkg->plan eq 'voip_cdr'
1094                && $part_pkg->option('bill_every_call')
1095             )
1096          || $options{cancel}
1097
1098        and
1099           ( ! $cust_pkg->expire
1100             || $cust_pkg->expire > $cmp_time
1101             || $options{cancel}
1102           )
1103   ) {
1104
1105     # XXX should this be a package event?  probably.  events are called
1106     # at collection time at the moment, though...
1107     $part_pkg->reset_usage($cust_pkg, 'debug'=>$DEBUG)
1108       if $part_pkg->can('reset_usage') && !$options{'no_usage_reset'};
1109       #don't want to reset usage just cause we want a line item??
1110       #&& $part_pkg->pkgpart == $real_pkgpart;
1111
1112     warn "    bill recur\n" if $DEBUG > 1;
1113     $lineitems++;
1114
1115     # XXX shared with $recur_prog
1116     $sdate = ( $options{cancel} ? $cust_pkg->last_bill : $cust_pkg->bill )
1117              || $cust_pkg->setup
1118              || $time;
1119
1120     #over two params!  lets at least switch to a hashref for the rest...
1121     my $increment_next_bill = ( $part_pkg->freq ne '0'
1122                                 && ( $cust_pkg->getfield('bill') || 0 ) <= $cmp_time
1123                                 && !$options{cancel}
1124                               );
1125     my %param = ( %setup_param,
1126                   'precommit_hooks'     => $precommit_hooks,
1127                   'increment_next_bill' => $increment_next_bill,
1128                   'discounts'           => \@recur_discounts,
1129                   'real_pkgpart'        => $real_pkgpart,
1130                   'freq_override'       => $options{freq_override} || '',
1131                   'setup_fee'           => 0,
1132                 );
1133
1134     my $method = $options{cancel} ? 'calc_cancel' : 'calc_recur';
1135
1136     # There may be some part_pkg for which this is wrong.  Only those
1137     # which can_discount are supported.
1138     # (the UI should prevent adding discounts to these at the moment)
1139
1140     warn "calling $method on cust_pkg ". $cust_pkg->pkgnum.
1141          " for pkgpart ". $cust_pkg->pkgpart.
1142          " with params ". join(' / ', map "$_=>$param{$_}", keys %param). "\n"
1143       if $DEBUG > 2;
1144
1145     $recur = eval { $cust_pkg->$method( \$sdate, \@details, \%param ) };
1146     return "$@ running $method for $cust_pkg\n"
1147       if ( $@ );
1148
1149     if ($recur eq 'NOTHING') {
1150       # then calc_cancel (or calc_recur but that's not used) has declined to
1151       # generate a recurring lineitem at all. treat this as zero, but also
1152       # try not to generate a lineitem.
1153       $recur = 0;
1154       $lineitems--;
1155     }
1156
1157     #base_cancel???
1158     $unitrecur = $cust_pkg->base_recur( \$sdate ) || $recur; #XXX uuh, better
1159
1160     if ( $param{'billed_currency'} ) {
1161       $recur_billed_currency = delete $param{'billed_currency'};
1162       $recur_billed_amount   = delete $param{'billed_amount'};
1163     }
1164
1165     if ( $increment_next_bill ) {
1166
1167       my $next_bill;
1168
1169       if ( my $main_pkg = $cust_pkg->main_pkg ) {
1170         # supplemental package
1171         # to keep in sync with the main package, simulate billing at
1172         # its frequency
1173         my $main_pkg_freq = $main_pkg->part_pkg->freq;
1174         my $supp_pkg_freq = $part_pkg->freq;
1175         if ( $supp_pkg_freq == 0 or $main_pkg_freq == 0 ) {
1176           # the UI should prevent setting up packages like this, but just
1177           # in case
1178           return "unable to calculate supplemental package period ratio";
1179         }
1180         my $ratio = $supp_pkg_freq / $main_pkg_freq;
1181         if ( $ratio == int($ratio) ) {
1182           # simple case: main package is X months, supp package is X*A months,
1183           # advance supp package to where the main package will be in A cycles.
1184           $next_bill = $sdate;
1185           for (1..$ratio) {
1186             $next_bill = $part_pkg->add_freq( $next_bill, $main_pkg_freq );
1187           }
1188         } else {
1189           # harder case: main package is X months, supp package is Y months.
1190           # advance supp package by Y months. then if they're within half a
1191           # month of each other, resync them. this may result in the period
1192           # not being exactly Y months.
1193           $next_bill = $part_pkg->add_freq( $sdate, $supp_pkg_freq );
1194           my $main_next_bill = $main_pkg->bill;
1195           if ( $main_pkg->bill <= $time ) {
1196             # then the main package has not yet been billed on this cycle;
1197             # predict what its bill date will be.
1198             $main_next_bill =
1199               $part_pkg->add_freq( $main_next_bill, $main_pkg_freq );
1200           }
1201           if ( abs($main_next_bill - $next_bill) < 86400*15 ) {
1202             $next_bill = $main_next_bill;
1203           }
1204         }
1205
1206       } else {
1207       # the normal case, not a supplemental package
1208       $next_bill = $part_pkg->add_freq($sdate, $options{freq_override} || 0);
1209       return "unparsable frequency: ".
1210         ($options{freq_override} || $part_pkg->freq)
1211         if $next_bill == -1;
1212       }
1213
1214       #pro-rating magic - if $recur_prog fiddled $sdate, want to use that
1215       # only for figuring next bill date, nothing else, so, reset $sdate again
1216       # here
1217       $sdate = $cust_pkg->bill || $cust_pkg->setup || $time;
1218       #no need, its in $hash{last_bill}# my $last_bill = $cust_pkg->last_bill;
1219       $cust_pkg->last_bill($sdate);
1220
1221       $cust_pkg->setfield('bill', $next_bill );
1222
1223     }
1224
1225     if ( $param{'setup_fee'} ) {
1226       # Add an additional setup fee at the billing stage.
1227       # Used for prorate_defer_bill.
1228       $setup += $param{'setup_fee'};
1229       $unitsetup = $cust_pkg->base_setup();
1230       $lineitems++;
1231     }
1232
1233     if ( defined $param{'discount_left_setup'} ) {
1234         foreach my $discount_setup ( values %{$param{'discount_left_setup'}} ) {
1235             $setup -= $discount_setup;
1236         }
1237     }
1238
1239   }
1240
1241   warn "\$setup is undefined" unless defined($setup);
1242   warn "\$recur is undefined" unless defined($recur);
1243   warn "\$cust_pkg->bill is undefined" unless defined($cust_pkg->bill);
1244
1245   ###
1246   # If there's line items, create em cust_bill_pkg records
1247   # If $cust_pkg has been modified, update it (if we're a real pkgpart)
1248   ###
1249
1250   if ( $lineitems ) {
1251
1252     if ( $cust_pkg->modified && $cust_pkg->pkgpart == $real_pkgpart ) {
1253       # hmm.. and if just the options are modified in some weird price plan?
1254
1255       warn "  package ". $cust_pkg->pkgnum. " modified; updating\n"
1256         if $DEBUG >1;
1257
1258       my $error = $cust_pkg->replace( $old_cust_pkg,
1259                                       'depend_jobnum'=>$options{depend_jobnum},
1260                                       'options' => { $cust_pkg->options },
1261                                     )
1262         unless $options{no_commit};
1263       return "Error modifying pkgnum ". $cust_pkg->pkgnum. ": $error"
1264         if $error; #just in case
1265     }
1266
1267     $setup = sprintf( "%.2f", $setup );
1268     $recur = sprintf( "%.2f", $recur );
1269     if ( $setup < 0 && ! $conf->exists('allow_negative_charges') ) {
1270       return "negative setup $setup for pkgnum ". $cust_pkg->pkgnum;
1271     }
1272     if ( $recur < 0 && ! $conf->exists('allow_negative_charges') ) {
1273       return "negative recur $recur for pkgnum ". $cust_pkg->pkgnum;
1274     }
1275
1276     my $discount_show_always = $conf->exists('discount-show-always')
1277                                && (    ($setup == 0 && scalar(@setup_discounts))
1278                                     || ($recur == 0 && scalar(@recur_discounts))
1279                                   );
1280
1281     if (    $setup != 0
1282          || $recur != 0
1283          || (!$part_pkg->hidden && $options{has_hidden}) #include some $0 lines
1284          || $discount_show_always
1285          || ($setup == 0 && $cust_pkg->_X_show_zero('setup'))
1286          || ($recur == 0 && $cust_pkg->_X_show_zero('recur'))
1287        )
1288     {
1289
1290       warn "    charges (setup=$setup, recur=$recur); adding line items\n"
1291         if $DEBUG > 1;
1292
1293       my @cust_pkg_detail = map { $_->detail } $cust_pkg->cust_pkg_detail('I');
1294       if ( $DEBUG > 1 ) {
1295         warn "      adding customer package invoice detail: $_\n"
1296           foreach @cust_pkg_detail;
1297       }
1298       push @details, @cust_pkg_detail;
1299
1300       my $cust_bill_pkg = new FS::cust_bill_pkg {
1301         'pkgnum'                => $cust_pkg->pkgnum,
1302         'setup'                 => $setup,
1303         'unitsetup'             => $unitsetup,
1304         'setup_billed_currency' => $setup_billed_currency,
1305         'setup_billed_amount'   => $setup_billed_amount,
1306         'recur'                 => $recur,
1307         'unitrecur'             => $unitrecur,
1308         'recur_billed_currency' => $recur_billed_currency,
1309         'recur_billed_amount'   => $recur_billed_amount,
1310         'quantity'              => $cust_pkg->quantity,
1311         'details'               => \@details,
1312         'discounts'             => [ @setup_discounts, @recur_discounts ],
1313         'hidden'                => $part_pkg->hidden,
1314         'freq'                  => $part_pkg->freq,
1315       };
1316
1317       if ( $part_pkg->option('prorate_defer_bill',1)
1318            and !$hash{last_bill} ) {
1319         # both preceding and upcoming, technically
1320         $cust_bill_pkg->sdate( $cust_pkg->setup );
1321         $cust_bill_pkg->edate( $cust_pkg->bill );
1322       } elsif ( $part_pkg->recur_temporality eq 'preceding' ) {
1323         $cust_bill_pkg->sdate( $hash{last_bill} );
1324         $cust_bill_pkg->edate( $sdate - 86399   ); #60s*60m*24h-1
1325         $cust_bill_pkg->edate( $time ) if $options{cancel};
1326       } else { #if ( $part_pkg->recur_temporality eq 'upcoming' )
1327         $cust_bill_pkg->sdate( $sdate );
1328         $cust_bill_pkg->edate( $cust_pkg->bill );
1329         #$cust_bill_pkg->edate( $time ) if $options{cancel};
1330       }
1331
1332       $cust_bill_pkg->pkgpart_override($part_pkg->pkgpart)
1333         unless $part_pkg->pkgpart == $real_pkgpart;
1334
1335       $$total_setup += $setup;
1336       $$total_recur += $recur;
1337
1338       ###
1339       # handle taxes
1340       ###
1341
1342       my $error = $tax_engine->add_sale($cust_bill_pkg);
1343       return $error if $error;
1344
1345       $cust_bill_pkg->set_display(
1346         part_pkg     => $part_pkg,
1347         real_pkgpart => $real_pkgpart,
1348       );
1349
1350       push @$cust_bill_pkgs, $cust_bill_pkg;
1351
1352     } #if $setup != 0 || $recur != 0
1353
1354   } #if $line_items
1355
1356   '';
1357
1358 }
1359
1360 =item _transfer_balance TO_PKG [ FROM_PKGNUM ]
1361
1362 Takes one argument, a cust_pkg object that is being billed.  This will
1363 be called only if the package was created by a package change, and has
1364 not been billed since the package change, and package balance tracking
1365 is enabled.  The second argument can be an alternate package number to
1366 transfer the balance from; this should not be used externally.
1367
1368 Transfers the balance from the previous package (now canceled) to
1369 this package, by crediting one package and creating an invoice item for
1370 the other.  Inserts the credit and returns the invoice item (so that it
1371 can be added to an invoice that's being built).
1372
1373 If the previous package was never billed, and was also created by a package
1374 change, then this will also transfer the balance from I<its> previous
1375 package, and so on, until reaching a package that either has been billed
1376 or was not created by a package change.
1377
1378 =cut
1379
1380 my $balance_transfer_reason;
1381
1382 sub _transfer_balance {
1383   my $self = shift;
1384   my $cust_pkg = shift;
1385   my $from_pkgnum = shift || $cust_pkg->change_pkgnum;
1386   my $from_pkg = FS::cust_pkg->by_key($from_pkgnum);
1387
1388   my @transfers;
1389
1390   # if $from_pkg is not the first package in the chain, and it was never
1391   # billed, walk back
1392   if ( $from_pkg->change_pkgnum and scalar($from_pkg->cust_bill_pkg) == 0 ) {
1393     @transfers = $self->_transfer_balance($cust_pkg, $from_pkg->change_pkgnum);
1394   }
1395
1396   my $prev_balance = $self->balance_pkgnum($from_pkgnum);
1397   if ( $prev_balance != 0 ) {
1398     $balance_transfer_reason ||= FS::reason->new_or_existing(
1399       'reason' => 'Package balance transfer',
1400       'type'   => 'Internal adjustment',
1401       'class'  => 'R'
1402     );
1403
1404     my $credit = FS::cust_credit->new({
1405         'custnum'   => $self->custnum,
1406         'amount'    => abs($prev_balance),
1407         'reasonnum' => $balance_transfer_reason->reasonnum,
1408         '_date'     => $cust_pkg->change_date,
1409     });
1410
1411     my $cust_bill_pkg = FS::cust_bill_pkg->new({
1412         'setup'     => 0,
1413         'recur'     => abs($prev_balance),
1414         #'sdate'     => $from_pkg->last_bill, # not sure about this
1415         #'edate'     => $cust_pkg->change_date,
1416         'itemdesc'  => $self->mt('Previous Balance, [_1]',
1417                                  $from_pkg->part_pkg->pkg),
1418     });
1419
1420     if ( $prev_balance > 0 ) {
1421       # credit the old package, charge the new one
1422       $credit->set('pkgnum', $from_pkgnum);
1423       $cust_bill_pkg->set('pkgnum', $cust_pkg->pkgnum);
1424     } else {
1425       # the reverse
1426       $credit->set('pkgnum', $cust_pkg->pkgnum);
1427       $cust_bill_pkg->set('pkgnum', $from_pkgnum);
1428     }
1429     my $error = $credit->insert;
1430     die "error transferring package balance from #".$from_pkgnum.
1431         " to #".$cust_pkg->pkgnum.": $error\n" if $error;
1432
1433     push @transfers, $cust_bill_pkg;
1434   } # $prev_balance != 0
1435
1436   return @transfers;
1437 }
1438
1439 #### vestigial code ####
1440
1441 =item handle_taxes TAXLISTHASH CUST_BILL_PKG [ OPTIONS ]
1442
1443 This is _handle_taxes.  It's called once for each cust_bill_pkg generated
1444 from _make_lines.
1445
1446 TAXLISTHASH is a hashref shared across the entire invoice.  It looks like
1447 this:
1448 {
1449   'cust_main_county 1001' => [ [FS::cust_main_county], ... ],
1450   'cust_main_county 1002' => [ [FS::cust_main_county], ... ],
1451 }
1452
1453 'cust_main_county' can also be 'tax_rate'.  The first object in the array
1454 is always the cust_main_county or tax_rate identified by the key.
1455
1456 That "..." is a list of FS::cust_bill_pkg objects that will be fed to
1457 the 'taxline' method to calculate the amount of the tax.  This doesn't
1458 happen until calculate_taxes, though.
1459
1460 OPTIONS may include:
1461 - part_item: a part_pkg or part_fee object to be used as the package/fee
1462   definition.
1463 - location: a cust_location to be used as the billing location.
1464 - cancel: true if this package is being billed on cancellation.  This
1465   allows tax to be calculated on usage charges only.
1466
1467 If not supplied, part_item will be inferred from the pkgnum or feepart of the
1468 cust_bill_pkg, and location from the pkgnum (or, for fees, the invnum and
1469 the customer's default service location).
1470
1471 This method will also calculate exemptions for any taxes that apply to the
1472 line item (using the C<set_exemptions> method of L<FS::cust_bill_pkg>) and
1473 attach them.  This is the only place C<set_exemptions> is called in normal
1474 invoice processing.
1475
1476 =cut
1477
1478 sub _handle_taxes {
1479   my $self = shift;
1480   my $taxlisthash = shift;
1481   my $cust_bill_pkg = shift;
1482   my %options = @_;
1483
1484   # at this point I realize that we have enough information to infer all this
1485   # stuff, instead of passing around giant honking argument lists
1486   my $location = $options{location} || $cust_bill_pkg->tax_location;
1487   my $part_item = $options{part_item} || $cust_bill_pkg->part_X;
1488
1489   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1490
1491   return if ( $self->payby eq 'COMP' ); #dubious
1492
1493   if ( $conf->config('enable_taxproducts')
1494        && ( scalar($part_item->part_pkg_taxoverride)
1495             || $part_item->has_taxproduct
1496           )
1497      )
1498     {
1499
1500     # EXTERNAL TAX RATES (via tax_rate)
1501     my %cust_bill_pkg = ();
1502     my %taxes = ();
1503
1504     my @classes;
1505     my $usage = $cust_bill_pkg->usage || 0;
1506     push @classes, $cust_bill_pkg->usage_classes if $usage;
1507     push @classes, 'setup' if $cust_bill_pkg->setup and !$options{cancel};
1508     push @classes, 'recur' if ($cust_bill_pkg->recur - $usage)
1509         and !$options{cancel};
1510     # that's better--probably don't even need $options{cancel} now
1511     # but leave it for now, just to be safe
1512     #
1513     # About $options{cancel}: This protects against charging per-line or
1514     # per-customer or other flat-rate surcharges on a package that's being
1515     # billed on cancellation (which is an out-of-cycle bill and should only
1516     # have usage charges).  See RT#29443.
1517
1518     # customer exemption is now handled in the 'taxline' method
1519     #my $exempt = $conf->exists('cust_class-tax_exempt')
1520     #               ? ( $self->cust_class ? $self->cust_class->tax : '' )
1521     #               : $self->tax;
1522     # standardize this just to be sure
1523     #$exempt = ($exempt eq 'Y') ? 'Y' : '';
1524     #
1525     #if ( !$exempt ) {
1526
1527     unless (exists $taxes{''}) {
1528       # unsure what purpose this serves, but last time I deleted something
1529       # from here just because I didn't see the point, it actually did
1530       # something important.
1531       my $err_or_ref = $self->_gather_taxes($part_item, '', $location);
1532       return $err_or_ref unless ref($err_or_ref);
1533       $taxes{''} = $err_or_ref;
1534     }
1535
1536     # NO DISINTEGRATIONS.
1537     # my %tax_cust_bill_pkg = $cust_bill_pkg->disintegrate;
1538     #
1539     # do not call taxline() with any argument except the entire set of
1540     # cust_bill_pkgs on an invoice that are eligible for the tax.
1541
1542     # only calculate exemptions once for each tax rate, even if it's used
1543     # for multiple classes
1544     my %tax_seen = ();
1545
1546     foreach my $class (@classes) {
1547       my $err_or_ref = $self->_gather_taxes($part_item, $class, $location);
1548       return $err_or_ref unless ref($err_or_ref);
1549       my @taxes = @$err_or_ref;
1550
1551       next if !@taxes;
1552
1553       foreach my $tax ( @taxes ) {
1554
1555         my $tax_id = ref( $tax ). ' '. $tax->taxnum;
1556         # $taxlisthash: keys are tax identifiers ('FS::tax_rate 123456').
1557         # Values are arrayrefs, first the tax object (cust_main_county
1558         # or tax_rate), then the cust_bill_pkg object that the
1559         # tax applies to, then the tax class (setup, recur, usage classnum).
1560         $taxlisthash->{ $tax_id } ||= [ $tax ];
1561         push @{ $taxlisthash->{ $tax_id  } }, $cust_bill_pkg, $class;
1562
1563         # determine any exemptions that apply
1564         if (!$tax_seen{$tax_id}) {
1565           $cust_bill_pkg->set_exemptions( $tax, custnum => $self->custnum );
1566           $tax_seen{$tax_id} = 1;
1567         }
1568
1569         # tax on tax will be done later, when we actually create the tax
1570         # line items
1571
1572       }
1573     }
1574
1575   } else {
1576
1577     # INTERNAL TAX RATES (cust_main_county)
1578
1579     # We fetch taxes even if the customer is completely exempt,
1580     # because we need to record that fact.
1581
1582     my @loc_keys = qw( district city county state country );
1583     my %taxhash = map { $_ => $location->$_ } @loc_keys;
1584
1585     $taxhash{'taxclass'} = $part_item->taxclass;
1586
1587     warn "taxhash:\n". Dumper(\%taxhash) if $DEBUG > 2;
1588
1589     my @taxes = (); # entries are cust_main_county objects
1590     my %taxhash_elim = %taxhash;
1591     my @elim = qw( district city county state );
1592     do {
1593
1594       #first try a match with taxclass
1595       @taxes = qsearch( 'cust_main_county', \%taxhash_elim );
1596
1597       if ( !scalar(@taxes) && $taxhash_elim{'taxclass'} ) {
1598         #then try a match without taxclass
1599         my %no_taxclass = %taxhash_elim;
1600         $no_taxclass{ 'taxclass' } = '';
1601         @taxes = qsearch( 'cust_main_county', \%no_taxclass );
1602       }
1603
1604       $taxhash_elim{ shift(@elim) } = '';
1605
1606     } while ( !scalar(@taxes) && scalar(@elim) );
1607
1608     foreach (@taxes) {
1609       my $tax_id = 'cust_main_county '.$_->taxnum;
1610       $taxlisthash->{$tax_id} ||= [ $_ ];
1611       $cust_bill_pkg->set_exemptions($_, custnum => $self->custnum);
1612       push @{ $taxlisthash->{$tax_id} }, $cust_bill_pkg;
1613     }
1614
1615   }
1616   '';
1617 }
1618
1619 =item _gather_taxes PART_ITEM CLASS CUST_LOCATION
1620
1621 Internal method used with vendor-provided tax tables.  PART_ITEM is a part_pkg
1622 or part_fee (which will define the tax eligibility of the product), CLASS is
1623 'setup', 'recur', null, or a C<usage_class> number, and CUST_LOCATION is the
1624 location where the service was provided (or billed, depending on
1625 configuration).  Returns an arrayref of L<FS::tax_rate> objects that
1626 can apply to this line item.
1627
1628 =cut
1629
1630 sub _gather_taxes {
1631   my $self = shift;
1632   my $part_item = shift;
1633   my $class = shift;
1634   my $location = shift;
1635
1636   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1637
1638   my $geocode = $location->geocode('cch');
1639
1640   [ $part_item->tax_rates('cch', $geocode, $class) ]
1641
1642 }
1643
1644 #### end vestigial code ####
1645
1646 =item collect [ HASHREF | OPTION => VALUE ... ]
1647
1648 (Attempt to) collect money for this customer's outstanding invoices (see
1649 L<FS::cust_bill>).  Usually used after the bill method.
1650
1651 Actions are now triggered by billing events; see L<FS::part_event> and the
1652 billing events web interface.  Old-style invoice events (see
1653 L<FS::part_bill_event>) have been deprecated.
1654
1655 If there is an error, returns the error, otherwise returns false.
1656
1657 Options are passed as name-value pairs.
1658
1659 Currently available options are:
1660
1661 =over 4
1662
1663 =item invoice_time
1664
1665 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1666
1667 =item retry
1668
1669 Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1670
1671 =item check_freq
1672
1673 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1674
1675 =item quiet
1676
1677 set true to surpress email card/ACH decline notices.
1678
1679 =item debug
1680
1681 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1682
1683 =back
1684
1685 # =item payby
1686 #
1687 # allows for one time override of normal customer billing method
1688
1689 =cut
1690
1691 sub collect {
1692   my( $self, %options ) = @_;
1693
1694   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1695
1696   my $invoice_time = $options{'invoice_time'} || time;
1697
1698   #put below somehow?
1699   local $SIG{HUP} = 'IGNORE';
1700   local $SIG{INT} = 'IGNORE';
1701   local $SIG{QUIT} = 'IGNORE';
1702   local $SIG{TERM} = 'IGNORE';
1703   local $SIG{TSTP} = 'IGNORE';
1704   local $SIG{PIPE} = 'IGNORE';
1705
1706   my $oldAutoCommit = $FS::UID::AutoCommit;
1707   local $FS::UID::AutoCommit = 0;
1708   my $dbh = dbh;
1709
1710   $self->select_for_update; #mutex
1711
1712   if ( $DEBUG ) {
1713     my $balance = $self->balance;
1714     warn "$me collect customer ". $self->custnum. ": balance $balance\n"
1715   }
1716
1717   if ( exists($options{'retry_card'}) ) {
1718     carp 'retry_card option passed to collect is deprecated; use retry';
1719     $options{'retry'} ||= $options{'retry_card'};
1720   }
1721   if ( exists($options{'retry'}) && $options{'retry'} ) {
1722     my $error = $self->retry_realtime;
1723     if ( $error ) {
1724       $dbh->rollback if $oldAutoCommit;
1725       return $error;
1726     }
1727   }
1728
1729   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1730
1731   #never want to roll back an event just because it returned an error
1732   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1733
1734   $self->do_cust_event(
1735     'debug'      => ( $options{'debug'} || 0 ),
1736     'time'       => $invoice_time,
1737     'check_freq' => $options{'check_freq'},
1738     'stage'      => 'collect',
1739   );
1740
1741 }
1742
1743 =item retry_realtime
1744
1745 Schedules realtime / batch  credit card / electronic check / LEC billing
1746 events for for retry.  Useful if card information has changed or manual
1747 retry is desired.  The 'collect' method must be called to actually retry
1748 the transaction.
1749
1750 Implementation details: For either this customer, or for each of this
1751 customer's open invoices, changes the status of the first "done" (with
1752 statustext error) realtime processing event to "failed".
1753
1754 =cut
1755
1756 sub retry_realtime {
1757   my $self = shift;
1758
1759   local $SIG{HUP} = 'IGNORE';
1760   local $SIG{INT} = 'IGNORE';
1761   local $SIG{QUIT} = 'IGNORE';
1762   local $SIG{TERM} = 'IGNORE';
1763   local $SIG{TSTP} = 'IGNORE';
1764   local $SIG{PIPE} = 'IGNORE';
1765
1766   my $oldAutoCommit = $FS::UID::AutoCommit;
1767   local $FS::UID::AutoCommit = 0;
1768   my $dbh = dbh;
1769
1770   #a little false laziness w/due_cust_event (not too bad, really)
1771
1772   # I guess this is always as of now?
1773   my $join = FS::part_event_condition->join_conditions_sql('', 'time' => time);
1774   my $order = FS::part_event_condition->order_conditions_sql;
1775   my $mine =
1776   '( '
1777    . join ( ' OR ' , map {
1778     my $cust_join = FS::part_event->eventtables_cust_join->{$_} || '';
1779     my $custnum = FS::part_event->eventtables_custnum->{$_};
1780     "( part_event.eventtable = " . dbh->quote($_)
1781     . " AND tablenum IN( SELECT " . dbdef->table($_)->primary_key
1782     . " from $_ $cust_join"
1783     . " where $custnum = " . dbh->quote( $self->custnum ) . "))" ;
1784    } FS::part_event->eventtables)
1785    . ') ';
1786
1787   #here is the agent virtualization
1788   my $agent_virt = " (    part_event.agentnum IS NULL
1789                        OR part_event.agentnum = ". $self->agentnum. ' )';
1790
1791   #XXX this shouldn't be hardcoded, actions should declare it...
1792   my @realtime_events = qw(
1793     cust_bill_realtime_card
1794     cust_bill_realtime_check
1795     cust_bill_realtime_lec
1796     cust_bill_batch
1797   );
1798
1799   my $is_realtime_event =
1800     ' part_event.action IN ( '.
1801         join(',', map "'$_'", @realtime_events ).
1802     ' ) ';
1803
1804   my $batch_or_statustext =
1805     "( part_event.action = 'cust_bill_batch'
1806        OR ( statustext IS NOT NULL AND statustext != '' )
1807      )";
1808
1809
1810   my @cust_event = qsearch({
1811     'table'     => 'cust_event',
1812     'select'    => 'cust_event.*',
1813     'addl_from' => "LEFT JOIN part_event USING ( eventpart ) $join",
1814     'hashref'   => { 'status' => 'done' },
1815     'extra_sql' => " AND $batch_or_statustext ".
1816                    " AND $mine AND $is_realtime_event AND $agent_virt $order" # LIMIT 1"
1817   });
1818
1819   my %seen_invnum = ();
1820   foreach my $cust_event (@cust_event) {
1821
1822     #max one for the customer, one for each open invoice
1823     my $cust_X = $cust_event->cust_X;
1824     next if $seen_invnum{ $cust_event->part_event->eventtable eq 'cust_bill'
1825                           ? $cust_X->invnum
1826                           : 0
1827                         }++
1828          or $cust_event->part_event->eventtable eq 'cust_bill'
1829             && ! $cust_X->owed;
1830
1831     my $error = $cust_event->retry;
1832     if ( $error ) {
1833       $dbh->rollback if $oldAutoCommit;
1834       return "error scheduling event for retry: $error";
1835     }
1836
1837   }
1838
1839   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1840   '';
1841
1842 }
1843
1844 =item do_cust_event [ HASHREF | OPTION => VALUE ... ]
1845
1846 Runs billing events; see L<FS::part_event> and the billing events web
1847 interface.
1848
1849 If there is an error, returns the error, otherwise returns false.
1850
1851 Options are passed as name-value pairs.
1852
1853 Currently available options are:
1854
1855 =over 4
1856
1857 =item time
1858
1859 Use this time when deciding when to print invoices and late notices on those invoices.  The default is now.  It is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion functions.
1860
1861 =item check_freq
1862
1863 "1d" for the traditional, daily events (the default), or "1m" for the new monthly events (part_event.check_freq)
1864
1865 =item stage
1866
1867 "collect" (the default) or "pre-bill"
1868
1869 =item quiet
1870
1871 set true to surpress email card/ACH decline notices.
1872
1873 =item debug
1874
1875 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
1876
1877 =back
1878 =cut
1879
1880 # =item payby
1881 #
1882 # allows for one time override of normal customer billing method
1883
1884 # =item retry
1885 #
1886 # Retry card/echeck/LEC transactions even when not scheduled by invoice events.
1887
1888 sub do_cust_event {
1889   my( $self, %options ) = @_;
1890
1891   local($DEBUG) = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
1892
1893   my $time = $options{'time'} || time;
1894
1895   #put below somehow?
1896   local $SIG{HUP} = 'IGNORE';
1897   local $SIG{INT} = 'IGNORE';
1898   local $SIG{QUIT} = 'IGNORE';
1899   local $SIG{TERM} = 'IGNORE';
1900   local $SIG{TSTP} = 'IGNORE';
1901   local $SIG{PIPE} = 'IGNORE';
1902
1903   my $oldAutoCommit = $FS::UID::AutoCommit;
1904   local $FS::UID::AutoCommit = 0;
1905   my $dbh = dbh;
1906
1907   $self->select_for_update; #mutex
1908
1909   if ( $DEBUG ) {
1910     my $balance = $self->balance;
1911     warn "$me do_cust_event customer ". $self->custnum. ": balance $balance\n"
1912   }
1913
1914 #  if ( exists($options{'retry_card'}) ) {
1915 #    carp 'retry_card option passed to collect is deprecated; use retry';
1916 #    $options{'retry'} ||= $options{'retry_card'};
1917 #  }
1918 #  if ( exists($options{'retry'}) && $options{'retry'} ) {
1919 #    my $error = $self->retry_realtime;
1920 #    if ( $error ) {
1921 #      $dbh->rollback if $oldAutoCommit;
1922 #      return $error;
1923 #    }
1924 #  }
1925
1926   # false laziness w/pay_batch::import_results
1927
1928   my $due_cust_event = $self->due_cust_event(
1929     'debug'      => ( $options{'debug'} || 0 ),
1930     'time'       => $time,
1931     'check_freq' => $options{'check_freq'},
1932     'stage'      => ( $options{'stage'} || 'collect' ),
1933   );
1934   unless( ref($due_cust_event) ) {
1935     $dbh->rollback if $oldAutoCommit;
1936     return $due_cust_event;
1937   }
1938
1939   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1940   #never want to roll back an event just because it or a different one
1941   # returned an error
1942   local $FS::UID::AutoCommit = 1; #$oldAutoCommit;
1943
1944   foreach my $cust_event ( @$due_cust_event ) {
1945
1946     #XXX lock event
1947
1948     #re-eval event conditions (a previous event could have changed things)
1949     unless ( $cust_event->test_conditions ) {
1950       #don't leave stray "new/locked" records around
1951       my $error = $cust_event->delete;
1952       return $error if $error;
1953       next;
1954     }
1955
1956     {
1957       local $FS::cust_main::Billing_Realtime::realtime_bop_decline_quiet = 1
1958         if $options{'quiet'};
1959       warn "  running cust_event ". $cust_event->eventnum. "\n"
1960         if $DEBUG > 1;
1961
1962       #if ( my $error = $cust_event->do_event(%options) ) { #XXX %options?
1963       if ( my $error = $cust_event->do_event( 'time' => $time ) ) {
1964         #XXX wtf is this?  figure out a proper dealio with return value
1965         #from do_event
1966         return $error;
1967       }
1968     }
1969
1970   }
1971
1972   '';
1973
1974 }
1975
1976 =item due_cust_event [ HASHREF | OPTION => VALUE ... ]
1977
1978 Inserts database records for and returns an ordered listref of new events due
1979 for this customer, as FS::cust_event objects (see L<FS::cust_event>).  If no
1980 events are due, an empty listref is returned.  If there is an error, returns a
1981 scalar error message.
1982
1983 To actually run the events, call each event's test_condition method, and if
1984 still true, call the event's do_event method.
1985
1986 Options are passed as a hashref or as a list of name-value pairs.  Available
1987 options are:
1988
1989 =over 4
1990
1991 =item check_freq
1992
1993 Search only for events of this check frequency (how often events of this type are checked); currently "1d" (daily, the default) and "1m" (monthly) are recognized.
1994
1995 =item stage
1996
1997 "collect" (the default) or "pre-bill"
1998
1999 =item time
2000
2001 "Current time" for the events.
2002
2003 =item debug
2004
2005 Debugging level.  Default is 0 (no debugging), or can be set to 1 (passed-in options), 2 (traces progress), 3 (more information), or 4 (include full search queries)
2006
2007 =item eventtable
2008
2009 Only return events for the specified eventtable (by default, events of all eventtables are returned)
2010
2011 =item objects
2012
2013 Explicitly pass the objects to be tested (typically used with eventtable).
2014
2015 =item testonly
2016
2017 Set to true to return the objects, but not actually insert them into the
2018 database.
2019
2020 =back
2021
2022 =cut
2023
2024 sub due_cust_event {
2025   my $self = shift;
2026   my %opt = ref($_[0]) ? %{ $_[0] } : @_;
2027
2028   #???
2029   #my $DEBUG = $opt{'debug'}
2030   $opt{'debug'} ||= 0; # silence some warnings
2031   local($DEBUG) = $opt{'debug'}
2032     if $opt{'debug'} > $DEBUG;
2033   $DEBUG = $FS::cust_main::DEBUG if $FS::cust_main::DEBUG > $DEBUG;
2034
2035   warn "$me due_cust_event called with options ".
2036        join(', ', map { "$_: $opt{$_}" } keys %opt). "\n"
2037     if $DEBUG;
2038
2039   $opt{'time'} ||= time;
2040
2041   local $SIG{HUP} = 'IGNORE';
2042   local $SIG{INT} = 'IGNORE';
2043   local $SIG{QUIT} = 'IGNORE';
2044   local $SIG{TERM} = 'IGNORE';
2045   local $SIG{TSTP} = 'IGNORE';
2046   local $SIG{PIPE} = 'IGNORE';
2047
2048   my $oldAutoCommit = $FS::UID::AutoCommit;
2049   local $FS::UID::AutoCommit = 0;
2050   my $dbh = dbh;
2051
2052   $self->select_for_update #mutex
2053     unless $opt{testonly};
2054
2055   ###
2056   # find possible events (initial search)
2057   ###
2058
2059   my @cust_event = ();
2060
2061   my @eventtable = $opt{'eventtable'}
2062                      ? ( $opt{'eventtable'} )
2063                      : FS::part_event->eventtables_runorder;
2064
2065   my $check_freq = $opt{'check_freq'} || '1d';
2066
2067   foreach my $eventtable ( @eventtable ) {
2068
2069     my @objects;
2070     if ( $opt{'objects'} ) {
2071
2072       @objects = @{ $opt{'objects'} };
2073
2074     } elsif ( $eventtable eq 'cust_main' ) {
2075
2076       @objects = ( $self );
2077
2078     } else {
2079
2080       my $cm_join = " LEFT JOIN cust_main USING ( custnum )";
2081       # linkage not needed here because FS::cust_main->$eventtable will
2082       # already supply it
2083
2084       #some false laziness w/Cron::bill bill_where
2085
2086       my $join  = FS::part_event_condition->join_conditions_sql( $eventtable,
2087         'time' => $opt{'time'});
2088       my $where = FS::part_event_condition->where_conditions_sql($eventtable,
2089         'time'=>$opt{'time'},
2090       );
2091       $where = $where ? "AND $where" : '';
2092
2093       my $are_part_event =
2094       "EXISTS ( SELECT 1 FROM part_event $join
2095         WHERE check_freq = '$check_freq'
2096         AND eventtable = '$eventtable'
2097         AND ( disabled = '' OR disabled IS NULL )
2098         $where
2099         )
2100       ";
2101       #eofalse
2102
2103       @objects = $self->$eventtable(
2104         'addl_from' => $cm_join,
2105         'extra_sql' => " AND $are_part_event",
2106       );
2107     } # if ( !$opt{objects} and $eventtable ne 'cust_main' )
2108
2109     my @e_cust_event = ();
2110
2111     my $linkage = FS::part_event->eventtables_cust_join->{$eventtable} || '';
2112
2113     my $cross = "CROSS JOIN $eventtable $linkage";
2114     $cross .= ' LEFT JOIN cust_main USING ( custnum )'
2115       unless $eventtable eq 'cust_main';
2116
2117     foreach my $object ( @objects ) {
2118
2119       #this first search uses the condition_sql magic for optimization.
2120       #the more possible events we can eliminate in this step the better
2121
2122       my $cross_where = '';
2123       my $pkey = $object->primary_key;
2124       $cross_where = "$eventtable.$pkey = ". $object->$pkey();
2125
2126       my $join = FS::part_event_condition->join_conditions_sql( $eventtable,
2127         'time' => $opt{'time'});
2128       my $extra_sql =
2129         FS::part_event_condition->where_conditions_sql( $eventtable,
2130                                                         'time'=>$opt{'time'}
2131                                                       );
2132       my $order = FS::part_event_condition->order_conditions_sql( $eventtable );
2133
2134       $extra_sql = "AND $extra_sql" if $extra_sql;
2135
2136       #here is the agent virtualization
2137       $extra_sql .= " AND (    part_event.agentnum IS NULL
2138                             OR part_event.agentnum = ". $self->agentnum. ' )';
2139
2140       $extra_sql .= " $order";
2141
2142       warn "searching for events for $eventtable ". $object->$pkey. "\n"
2143         if $opt{'debug'} > 2;
2144       my @part_event = qsearch( {
2145         'debug'     => ( $opt{'debug'} > 3 ? 1 : 0 ),
2146         'select'    => 'part_event.*',
2147         'table'     => 'part_event',
2148         'addl_from' => "$cross $join",
2149         'hashref'   => { 'check_freq' => $check_freq,
2150                          'eventtable' => $eventtable,
2151                          'disabled'   => '',
2152                        },
2153         'extra_sql' => "AND $cross_where $extra_sql",
2154       } );
2155
2156       if ( $DEBUG > 2 ) {
2157         my $pkey = $object->primary_key;
2158         warn "      ". scalar(@part_event).
2159              " possible events found for $eventtable ". $object->$pkey(). "\n";
2160       }
2161
2162       push @e_cust_event, map {
2163         $_->new_cust_event($object, 'time' => $opt{'time'})
2164       } @part_event;
2165
2166     }
2167
2168     warn "    ". scalar(@e_cust_event).
2169          " subtotal possible cust events found for $eventtable\n"
2170       if $DEBUG > 1;
2171
2172     push @cust_event, @e_cust_event;
2173
2174   }
2175
2176   warn "  ". scalar(@cust_event).
2177        " total possible cust events found in initial search\n"
2178     if $DEBUG; # > 1;
2179
2180
2181   ##
2182   # test stage
2183   ##
2184
2185   $opt{stage} ||= 'collect';
2186   @cust_event =
2187     grep { my $stage = $_->part_event->event_stage;
2188            $opt{stage} eq $stage or ( ! $stage && $opt{stage} eq 'collect' )
2189          }
2190          @cust_event;
2191
2192   ##
2193   # test conditions
2194   ##
2195
2196   my %unsat = ();
2197
2198   @cust_event = grep $_->test_conditions( 'stats_hashref' => \%unsat ),
2199                      @cust_event;
2200
2201   warn "  ". scalar(@cust_event). " cust events left satisfying conditions\n"
2202     if $DEBUG; # > 1;
2203
2204   warn "    invalid conditions not eliminated with condition_sql:\n".
2205        join('', map "      $_: ".$unsat{$_}."\n", keys %unsat )
2206     if keys %unsat && $DEBUG; # > 1;
2207
2208   ##
2209   # insert
2210   ##
2211
2212   unless( $opt{testonly} ) {
2213     foreach my $cust_event ( @cust_event ) {
2214
2215       my $error = $cust_event->insert();
2216       if ( $error ) {
2217         $dbh->rollback if $oldAutoCommit;
2218         return $error;
2219       }
2220
2221     }
2222   }
2223
2224   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2225
2226   ##
2227   # return
2228   ##
2229
2230   warn "  returning events: ". Dumper(@cust_event). "\n"
2231     if $DEBUG > 2;
2232
2233   \@cust_event;
2234
2235 }
2236
2237 =item apply_payments_and_credits [ OPTION => VALUE ... ]
2238
2239 Applies unapplied payments and credits.
2240 Payments with the no_auto_apply flag set will not be applied.
2241
2242 In most cases, this new method should be used in place of sequential
2243 apply_payments and apply_credits methods.
2244
2245 A hash of optional arguments may be passed.  Currently "manual" is supported.
2246 If true, a payment receipt is sent instead of a statement when
2247 'payment_receipt_email' configuration option is set.
2248
2249 If there is an error, returns the error, otherwise returns false.
2250
2251 =cut
2252
2253 sub apply_payments_and_credits {
2254   my( $self, %options ) = @_;
2255
2256   local $SIG{HUP} = 'IGNORE';
2257   local $SIG{INT} = 'IGNORE';
2258   local $SIG{QUIT} = 'IGNORE';
2259   local $SIG{TERM} = 'IGNORE';
2260   local $SIG{TSTP} = 'IGNORE';
2261   local $SIG{PIPE} = 'IGNORE';
2262
2263   my $oldAutoCommit = $FS::UID::AutoCommit;
2264   local $FS::UID::AutoCommit = 0;
2265   my $dbh = dbh;
2266
2267   $self->select_for_update; #mutex
2268
2269   foreach my $cust_bill ( $self->open_cust_bill ) {
2270     my $error = $cust_bill->apply_payments_and_credits(%options);
2271     if ( $error ) {
2272       $dbh->rollback if $oldAutoCommit;
2273       return "Error applying: $error";
2274     }
2275   }
2276
2277   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2278   ''; #no error
2279
2280 }
2281
2282 =item apply_credits OPTION => VALUE ...
2283
2284 Applies (see L<FS::cust_credit_bill>) unapplied credits (see L<FS::cust_credit>)
2285 to outstanding invoice balances in chronological order (or reverse
2286 chronological order if the I<order> option is set to B<newest>) and returns the
2287 value of any remaining unapplied credits available for refund (see
2288 L<FS::cust_refund>).
2289
2290 Dies if there is an error.
2291
2292 =cut
2293
2294 sub apply_credits {
2295   my $self = shift;
2296   my %opt = @_;
2297
2298   local $SIG{HUP} = 'IGNORE';
2299   local $SIG{INT} = 'IGNORE';
2300   local $SIG{QUIT} = 'IGNORE';
2301   local $SIG{TERM} = 'IGNORE';
2302   local $SIG{TSTP} = 'IGNORE';
2303   local $SIG{PIPE} = 'IGNORE';
2304
2305   my $oldAutoCommit = $FS::UID::AutoCommit;
2306   local $FS::UID::AutoCommit = 0;
2307   my $dbh = dbh;
2308
2309   $self->select_for_update; #mutex
2310
2311   unless ( $self->total_unapplied_credits ) {
2312     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2313     return 0;
2314   }
2315
2316   my @credits = sort { $b->_date <=> $a->_date} (grep { $_->credited > 0 }
2317       qsearch('cust_credit', { 'custnum' => $self->custnum } ) );
2318
2319   my @invoices = $self->open_cust_bill;
2320   @invoices = sort { $b->_date <=> $a->_date } @invoices
2321     if defined($opt{'order'}) && $opt{'order'} eq 'newest';
2322
2323   if ( $conf->exists('pkg-balances') ) {
2324     # limit @credits to those w/ a pkgnum grepped from $self
2325     my %pkgnums = ();
2326     foreach my $i (@invoices) {
2327       foreach my $li ( $i->cust_bill_pkg ) {
2328         $pkgnums{$li->pkgnum} = 1;
2329       }
2330     }
2331     @credits = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @credits;
2332   }
2333
2334   my $credit;
2335
2336   foreach my $cust_bill ( @invoices ) {
2337
2338     if ( !defined($credit) || $credit->credited == 0) {
2339       $credit = pop @credits or last;
2340     }
2341
2342     my $owed;
2343     if ( $conf->exists('pkg-balances') && $credit->pkgnum ) {
2344       $owed = $cust_bill->owed_pkgnum($credit->pkgnum);
2345     } else {
2346       $owed = $cust_bill->owed;
2347     }
2348     unless ( $owed > 0 ) {
2349       push @credits, $credit;
2350       next;
2351     }
2352
2353     my $amount = min( $credit->credited, $owed );
2354
2355     my $cust_credit_bill = new FS::cust_credit_bill ( {
2356       'crednum' => $credit->crednum,
2357       'invnum'  => $cust_bill->invnum,
2358       'amount'  => $amount,
2359     } );
2360     $cust_credit_bill->pkgnum( $credit->pkgnum )
2361       if $conf->exists('pkg-balances') && $credit->pkgnum;
2362     my $error = $cust_credit_bill->insert;
2363     if ( $error ) {
2364       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2365       die $error;
2366     }
2367
2368     redo if ($cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2369
2370   }
2371
2372   my $total_unapplied_credits = $self->total_unapplied_credits;
2373
2374   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2375
2376   return $total_unapplied_credits;
2377 }
2378
2379 =item apply_payments  [ OPTION => VALUE ... ]
2380
2381 Applies (see L<FS::cust_bill_pay>) unapplied payments (see L<FS::cust_pay>)
2382 to outstanding invoice balances in chronological order.
2383 Payments with the no_auto_apply flag set will not be applied.
2384
2385  #and returns the value of any remaining unapplied payments.
2386
2387 A hash of optional arguments may be passed.  Currently "manual" is supported.
2388 If true, a payment receipt is sent instead of a statement when
2389 'payment_receipt_email' configuration option is set.
2390
2391 Dies if there is an error.
2392
2393 =cut
2394
2395 sub apply_payments {
2396   my( $self, %options ) = @_;
2397
2398   local $SIG{HUP} = 'IGNORE';
2399   local $SIG{INT} = 'IGNORE';
2400   local $SIG{QUIT} = 'IGNORE';
2401   local $SIG{TERM} = 'IGNORE';
2402   local $SIG{TSTP} = 'IGNORE';
2403   local $SIG{PIPE} = 'IGNORE';
2404
2405   my $oldAutoCommit = $FS::UID::AutoCommit;
2406   local $FS::UID::AutoCommit = 0;
2407   my $dbh = dbh;
2408
2409   $self->select_for_update; #mutex
2410
2411   #return 0 unless
2412
2413   my @payments = grep { !$_->no_auto_apply } $self->unapplied_cust_pay;
2414
2415   my @invoices = $self->open_cust_bill;
2416
2417   if ( $conf->exists('pkg-balances') ) {
2418     # limit @payments to those w/ a pkgnum grepped from $self
2419     my %pkgnums = ();
2420     foreach my $i (@invoices) {
2421       foreach my $li ( $i->cust_bill_pkg ) {
2422         $pkgnums{$li->pkgnum} = 1;
2423       }
2424     }
2425     @payments = grep { ! $_->pkgnum || $pkgnums{$_->pkgnum} } @payments;
2426   }
2427
2428   my $payment;
2429
2430   foreach my $cust_bill ( @invoices ) {
2431
2432     if ( !defined($payment) || $payment->unapplied == 0 ) {
2433       $payment = pop @payments or last;
2434     }
2435
2436     my $owed;
2437     if ( $conf->exists('pkg-balances') && $payment->pkgnum ) {
2438       $owed = $cust_bill->owed_pkgnum($payment->pkgnum);
2439     } else {
2440       $owed = $cust_bill->owed;
2441     }
2442     unless ( $owed > 0 ) {
2443       push @payments, $payment;
2444       next;
2445     }
2446
2447     my $amount = min( $payment->unapplied, $owed );
2448
2449     my $cbp = {
2450       'paynum' => $payment->paynum,
2451       'invnum' => $cust_bill->invnum,
2452       'amount' => $amount,
2453     };
2454     $cbp->{_date} = $payment->_date
2455         if $options{'manual'} && $options{'backdate_application'};
2456     my $cust_bill_pay = new FS::cust_bill_pay($cbp);
2457     $cust_bill_pay->pkgnum( $payment->pkgnum )
2458       if $conf->exists('pkg-balances') && $payment->pkgnum;
2459     my $error = $cust_bill_pay->insert(%options);
2460     if ( $error ) {
2461       $dbh->rollback or die $dbh->errstr if $oldAutoCommit;
2462       die $error;
2463     }
2464
2465     redo if ( $cust_bill->owed > 0) && ! $conf->exists('pkg-balances');
2466
2467   }
2468
2469   my $total_unapplied_payments = $self->total_unapplied_payments;
2470
2471   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2472
2473   return $total_unapplied_payments;
2474 }
2475
2476 =back
2477
2478 =head1 FLOW
2479
2480   bill_and_collect
2481
2482     cancel_expired_pkgs
2483     suspend_adjourned_pkgs
2484     unsuspend_resumed_pkgs
2485
2486     bill
2487       (do_cust_event pre-bill)
2488       _make_lines
2489       _omit_zero_value_bundles
2490       calculate_taxes
2491
2492     apply_payments_and_credits
2493     collect
2494       do_cust_event
2495         due_cust_event
2496
2497 =head1 BUGS
2498
2499 =head1 SEE ALSO
2500
2501 L<FS::cust_main>, L<FS::cust_main::Billing_Realtime>
2502
2503 =cut
2504
2505 1;