FS/FS/cust_main.pm

   1 package FS::cust_main;
   2 use base qw( FS::cust_main::Packages
   3              FS::cust_main::Status
   4              FS::cust_main::NationalID
   5              FS::cust_main::Billing
   6              FS::cust_main::Billing_Realtime
   7              FS::cust_main::Billing_Batch
   8              FS::cust_main::Billing_Discount
   9              FS::cust_main::Billing_ThirdParty
  10              FS::cust_main::Location
  11              FS::cust_main::Credit_Limit
  12              FS::cust_main::Merge
  13              FS::cust_main::API
  14              FS::otaker_Mixin FS::cust_main_Mixin
  15              FS::geocode_Mixin FS::Quotable_Mixin FS::Sales_Mixin
  16              FS::o2m_Common
  17              FS::Record
  18            );
  19
  20 require 5.006;
  21 use strict;
  22 use Carp;
  23 use Scalar::Util qw( blessed );
  24 use Time::Local qw(timelocal);
  25 use Data::Dumper;
  26 use Tie::IxHash;
  27 use Date::Format;
  28 #use Date::Manip;
  29 use File::Temp; #qw( tempfile );
  30 use Business::CreditCard 0.28;
  31 use List::Util qw(min);
  32 use FS::UID qw( dbh driver_name );
  33 use FS::Record qw( qsearchs qsearch dbdef regexp_sql );
  34 use FS::Cursor;
  35 use FS::Misc qw( generate_ps do_print money_pretty card_types );
  36 use FS::Msgcat qw(gettext);
  37 use FS::CurrentUser;
  38 use FS::TicketSystem;
  39 use FS::payby;
  40 use FS::cust_pkg;
  41 use FS::cust_svc;
  42 use FS::cust_bill;
  43 use FS::cust_bill_void;
  44 use FS::legacy_cust_bill;
  45 use FS::cust_pay;
  46 use FS::cust_pay_pending;
  47 use FS::cust_pay_void;
  48 use FS::cust_pay_batch;
  49 use FS::cust_credit;
  50 use FS::cust_refund;
  51 use FS::part_referral;
  52 use FS::cust_main_county;
  53 use FS::cust_location;
  54 use FS::cust_class;
  55 use FS::tax_status;
  56 use FS::cust_main_exemption;
  57 use FS::cust_tax_adjustment;
  58 use FS::cust_tax_location;
  59 use FS::agent_currency;
  60 use FS::cust_main_invoice;
  61 use FS::cust_tag;
  62 use FS::prepay_credit;
  63 use FS::queue;
  64 use FS::part_pkg;
  65 use FS::part_export;
  66 #use FS::cust_event;
  67 use FS::type_pkgs;
  68 use FS::payment_gateway;
  69 use FS::agent_payment_gateway;
  70 use FS::banned_pay;
  71 use FS::cust_main_note;
  72 use FS::cust_attachment;
  73 use FS::cust_contact;
  74 use FS::Locales;
  75 use FS::upgrade_journal;
  76 use FS::sales;
  77 use FS::cust_payby;
  78 use FS::contact;
  79
  80 # 1 is mostly method/subroutine entry and options
  81 # 2 traces progress of some operations
  82 # 3 is even more information including possibly sensitive data
  83 our $DEBUG = 0;
  84 our $me = '[FS::cust_main]';
  85
  86 our $import = 0;
  87 our $ignore_expired_card = 0;
  88 our $ignore_banned_card = 0;
  89 our $ignore_invalid_card = 0;
  90
  91 our $skip_fuzzyfiles = 0;
  92
  93 our $ucfirst_nowarn = 0;
  94
  95 #this info is in cust_payby as of 4.x
  96 #this and the fields themselves can be removed in 5.x
  97 our @encrypted_fields = ('payinfo', 'paycvv');
  98 sub nohistory_fields { ('payinfo', 'paycvv'); }
  99
 100 our $conf;
 101 our $default_agent_custid;
 102 our $custnum_display_length;
 103 #ask FS::UID to run this stuff for us later
 104 #$FS::UID::callback{'FS::cust_main'} = sub {
 105 install_callback FS::UID sub {
 106   $conf = new FS::Conf;
 107   $ignore_invalid_card    = $conf->exists('allow_invalid_cards');
 108   $default_agent_custid   = $conf->exists('cust_main-default_agent_custid');
 109   $custnum_display_length = $conf->config('cust_main-custnum-display_length');
 110 };
 111
 112 sub _cache {
 113   my $self = shift;
 114   my ( $hashref, $cache ) = @_;
 115   if ( exists $hashref->{'pkgnum'} ) {
 116     #@{ $self->{'_pkgnum'} } = ();
 117     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
 118     $self->{'_pkgnum'} = $subcache;
 119     #push @{ $self->{'_pkgnum'} },
 120     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
 121   }
 122 }
 123
 124 =head1 NAME
 125
 126 FS::cust_main - Object methods for cust_main records
 127
 128 =head1 SYNOPSIS
 129
 130   use FS::cust_main;
 131
 132   $record = new FS::cust_main \%hash;
 133   $record = new FS::cust_main { 'column' => 'value' };
 134
 135   $error = $record->insert;
 136
 137   $error = $new_record->replace($old_record);
 138
 139   $error = $record->delete;
 140
 141   $error = $record->check;
 142
 143   @cust_pkg = $record->all_pkgs;
 144
 145   @cust_pkg = $record->ncancelled_pkgs;
 146
 147   @cust_pkg = $record->suspended_pkgs;
 148
 149   $error = $record->bill;
 150   $error = $record->bill %options;
 151   $error = $record->bill 'time' => $time;
 152
 153   $error = $record->collect;
 154   $error = $record->collect %options;
 155   $error = $record->collect 'invoice_time'   => $time,
 156                           ;
 157
 158 =head1 DESCRIPTION
 159
 160 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 161 FS::Record.  The following fields are currently supported:
 162
 163 =over 4
 164
 165 =item custnum
 166
 167 Primary key (assigned automatically for new customers)
 168
 169 =item agentnum
 170
 171 Agent (see L<FS::agent>)
 172
 173 =item refnum
 174
 175 Advertising source (see L<FS::part_referral>)
 176
 177 =item first
 178
 179 First name
 180
 181 =item last
 182
 183 Last name
 184
 185 =item ss
 186
 187 Cocial security number (optional)
 188
 189 =item company
 190
 191 (optional)
 192
 193 =item daytime
 194
 195 phone (optional)
 196
 197 =item night
 198
 199 phone (optional)
 200
 201 =item fax
 202
 203 phone (optional)
 204
 205 =item mobile
 206
 207 phone (optional)
 208
 209 =item payby
 210
 211 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 212
 213 =item payinfo
 214
 215 Payment Information (See L<FS::payinfo_Mixin> for data format)
 216
 217 =item paymask
 218
 219 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 220
 221 =item paycvv
 222
 223 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 224
 225 =item paydate
 226
 227 Expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 228
 229 =item paystart_month
 230
 231 Start date month (maestro/solo cards only)
 232
 233 =item paystart_year
 234
 235 Start date year (maestro/solo cards only)
 236
 237 =item payissue
 238
 239 Issue number (maestro/solo cards only)
 240
 241 =item payname
 242
 243 Name on card or billing name
 244
 245 =item payip
 246
 247 IP address from which payment information was received
 248
 249 =item tax
 250
 251 Tax exempt, empty or `Y'
 252
 253 =item usernum
 254
 255 Order taker (see L<FS::access_user>)
 256
 257 =item comments
 258
 259 Comments (optional)
 260
 261 =item referral_custnum
 262
 263 Referring customer number
 264
 265 =item spool_cdr
 266
 267 Enable individual CDR spooling, empty or `Y'
 268
 269 =item dundate
 270
 271 A suggestion to events (see L<FS::part_bill_event">) to delay until this unix timestamp
 272
 273 =item squelch_cdr
 274
 275 Discourage individual CDR printing, empty or `Y'
 276
 277 =item edit_subject
 278
 279 Allow self-service editing of ticket subjects, empty or 'Y'
 280
 281 =item calling_list_exempt
 282
 283 Do not call, empty or 'Y'
 284
 285 =item invoice_ship_address
 286
 287 Display ship_address ("Service address") on invoices for this customer, empty or 'Y'
 288
 289 =back
 290
 291 =head1 METHODS
 292
 293 =over 4
 294
 295 =item new HASHREF
 296
 297 Creates a new customer.  To add the customer to the database, see L<"insert">.
 298
 299 Note that this stores the hash reference, not a distinct copy of the hash it
 300 points to.  You can ask the object for a copy with the I<hash> method.
 301
 302 =cut
 303
 304 sub table { 'cust_main'; }
 305
 306 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 307
 308 Adds this customer to the database.  If there is an error, returns the error,
 309 otherwise returns false.
 310
 311 Usually the customer's location will not yet exist in the database, and
 312 the C<bill_location> and C<ship_location> pseudo-fields must be set to
 313 uninserted L<FS::cust_location> objects.  These will be inserted and linked
 314 (in both directions) to the new customer record.  If they're references
 315 to the same object, they will become the same location.
 316
 317 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 318 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 319 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 320 hash reference is equivalent to not supplying this parameter.  There should be
 321 a better explanation of this, but until then, here's an example:
 322
 323   use Tie::RefHash;
 324   tie %hash, 'Tie::RefHash'; #this part is important
 325   %hash = (
 326     $cust_pkg => [ $svc_acct ],
 327     ...
 328   );
 329   $cust_main->insert( \%hash );
 330
 331 INVOICING_LIST_ARYREF: No longer supported.
 332
 333 Currently available options are: I<depend_jobnum>, I<noexport>,
 334 I<tax_exemption>, I<prospectnum>, I<contact> and I<contact_params>.
 335
 336 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 337 on the supplied jobnum (they will not run until the specific job completes).
 338 This can be used to defer provisioning until some action completes (such
 339 as running the customer's credit card successfully).
 340
 341 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 342 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 343 the B<reexport> method.)
 344
 345 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
 346 of tax names and exemption numbers.  FS::cust_main_exemption records will be
 347 created and inserted.
 348
 349 If I<prospectnum> is set, moves contacts and locations from that prospect.
 350
 351 If I<contact> is set to an arrayref of FS::contact objects, those will be
 352 inserted.
 353
 354 If I<contact_params> is set to a hashref of CGI parameters (and I<contact> is
 355 unset), inserts those new contacts with this new customer.  Handles CGI
 356 paramaters for an "m2" multiple entry field as passed by edit/cust_main.cgi
 357
 358 If I<cust_payby_params> is set to a hashref o fCGI parameters, inserts those
 359 new stored payment records with this new customer.  Handles CGI parameters
 360 for an "m2" multiple entry field as passed by edit/cust_main.cgi
 361
 362 =cut
 363
 364 sub insert {
 365   my $self = shift;
 366   my $cust_pkgs = @_ ? shift : {};
 367   my $invoicing_list;
 368   if ( $_[0] and ref($_[0]) eq 'ARRAY' ) {
 369     warn "cust_main::insert using deprecated invoicing list argument";
 370     $invoicing_list = shift;
 371   }
 372   my %options = @_;
 373   warn "$me insert called with options ".
 374        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 375     if $DEBUG;
 376
 377   local $SIG{HUP} = 'IGNORE';
 378   local $SIG{INT} = 'IGNORE';
 379   local $SIG{QUIT} = 'IGNORE';
 380   local $SIG{TERM} = 'IGNORE';
 381   local $SIG{TSTP} = 'IGNORE';
 382   local $SIG{PIPE} = 'IGNORE';
 383
 384   my $oldAutoCommit = $FS::UID::AutoCommit;
 385   local $FS::UID::AutoCommit = 0;
 386   my $dbh = dbh;
 387
 388   my $prepay_identifier = '';
 389   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = (0, 0, 0, 0, 0);
 390   my $payby = '';
 391   if ( $self->payby eq 'PREPAY' ) {
 392
 393     $self->payby(''); #'BILL');
 394     $prepay_identifier = $self->payinfo;
 395     $self->payinfo('');
 396
 397     warn "  looking up prepaid card $prepay_identifier\n"
 398       if $DEBUG > 1;
 399
 400     my $error = $self->get_prepay( $prepay_identifier,
 401                                    'amount_ref'     => \$amount,
 402                                    'seconds_ref'    => \$seconds,
 403                                    'upbytes_ref'    => \$upbytes,
 404                                    'downbytes_ref'  => \$downbytes,
 405                                    'totalbytes_ref' => \$totalbytes,
 406                                  );
 407     if ( $error ) {
 408       $dbh->rollback if $oldAutoCommit;
 409       #return "error applying prepaid card (transaction rolled back): $error";
 410       return $error;
 411     }
 412
 413     $payby = 'PREP' if $amount;
 414
 415   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD|MCHK|PPAL)$/ ) {
 416
 417     $payby = $1;
 418     $self->payby(''); #'BILL');
 419     $amount = $self->paid;
 420
 421   }
 422
 423   # insert locations
 424   foreach my $l (qw(bill_location ship_location)) {
 425
 426     my $loc = delete $self->hashref->{$l} or next;
 427
 428     if ( !$loc->locationnum ) {
 429       # warn the location that we're going to insert it with no custnum
 430       $loc->set(custnum_pending => 1);
 431       warn "  inserting $l\n"
 432         if $DEBUG > 1;
 433       my $error = $loc->insert;
 434       if ( $error ) {
 435         $dbh->rollback if $oldAutoCommit;
 436         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 437         return "$error (in $label location)";
 438       }
 439
 440     } elsif ( $loc->prospectnum ) {
 441
 442       $loc->prospectnum('');
 443       $loc->set(custnum_pending => 1);
 444       my $error = $loc->replace;
 445       if ( $error ) {
 446         $dbh->rollback if $oldAutoCommit;
 447         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 448         return "$error (moving $label location)";
 449       }
 450
 451     } elsif ( ($loc->custnum || 0) > 0 ) {
 452       # then it somehow belongs to another customer--shouldn't happen
 453       $dbh->rollback if $oldAutoCommit;
 454       return "$l belongs to customer ".$loc->custnum;
 455     }
 456     # else it already belongs to this customer
 457     # (happens when ship_location is identical to bill_location)
 458
 459     $self->set($l.'num', $loc->locationnum);
 460
 461     if ( $self->get($l.'num') eq '' ) {
 462       $dbh->rollback if $oldAutoCommit;
 463       return "$l not set";
 464     }
 465   }
 466
 467   warn "  inserting $self\n"
 468     if $DEBUG > 1;
 469
 470   $self->signupdate(time) unless $self->signupdate;
 471
 472   $self->auto_agent_custid()
 473     if $conf->config('cust_main-auto_agent_custid') && ! $self->agent_custid;
 474
 475   my $error =  $self->check_payinfo_cardtype
 476             || $self->SUPER::insert;
 477   if ( $error ) {
 478     $dbh->rollback if $oldAutoCommit;
 479     #return "inserting cust_main record (transaction rolled back): $error";
 480     return $error;
 481   }
 482
 483   # now set cust_location.custnum
 484   foreach my $l (qw(bill_location ship_location)) {
 485     warn "  setting $l.custnum\n"
 486       if $DEBUG > 1;
 487     my $loc = $self->$l or next;
 488     unless ( $loc->custnum ) {
 489       $loc->set(custnum => $self->custnum);
 490       $error ||= $loc->replace;
 491     }
 492
 493     if ( $error ) {
 494       $dbh->rollback if $oldAutoCommit;
 495       return "error setting $l custnum: $error";
 496     }
 497   }
 498
 499   warn "  setting customer tags\n"
 500     if $DEBUG > 1;
 501
 502   foreach my $tagnum ( @{ $self->tagnum || [] } ) {
 503     my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
 504                                       'custnum' => $self->custnum };
 505     my $error = $cust_tag->insert;
 506     if ( $error ) {
 507       $dbh->rollback if $oldAutoCommit;
 508       return $error;
 509     }
 510   }
 511
 512   my $prospectnum = delete $options{'prospectnum'};
 513   if ( $prospectnum ) {
 514
 515     warn "  moving contacts and locations from prospect $prospectnum\n"
 516       if $DEBUG > 1;
 517
 518     my $prospect_main =
 519       qsearchs('prospect_main', { 'prospectnum' => $prospectnum } );
 520     unless ( $prospect_main ) {
 521       $dbh->rollback if $oldAutoCommit;
 522       return "Unknown prospectnum $prospectnum";
 523     }
 524     $prospect_main->custnum($self->custnum);
 525     $prospect_main->disabled('Y');
 526     my $error = $prospect_main->replace;
 527     if ( $error ) {
 528       $dbh->rollback if $oldAutoCommit;
 529       return $error;
 530     }
 531
 532     foreach my $prospect_contact ( $prospect_main->prospect_contact ) {
 533       my $cust_contact = new FS::cust_contact {
 534         'custnum' => $self->custnum,
 535         map { $_ => $prospect_contact->$_() } qw( contactnum classnum comment )
 536       };
 537       my $error =  $cust_contact->insert
 538                 || $prospect_contact->delete;
 539       if ( $error ) {
 540         $dbh->rollback if $oldAutoCommit;
 541         return $error;
 542       }
 543     }
 544
 545     my @cust_location = $prospect_main->cust_location;
 546     my @qual = $prospect_main->qual;
 547
 548     foreach my $r ( @cust_location, @qual ) {
 549       $r->prospectnum('');
 550       $r->custnum($self->custnum);
 551       my $error = $r->replace;
 552       if ( $error ) {
 553         $dbh->rollback if $oldAutoCommit;
 554         return $error;
 555       }
 556     }
 557
 558   }
 559
 560   warn "  setting contacts\n"
 561     if $DEBUG > 1;
 562
 563   $invoicing_list ||= $options{'invoicing_list'};
 564   if ( $invoicing_list ) {
 565
 566     $invoicing_list = [ $invoicing_list ] if !ref($invoicing_list);
 567
 568     my $email = '';
 569     foreach my $dest (@$invoicing_list ) {
 570       if ($dest eq 'POST') {
 571         $self->set('postal_invoice', 'Y');
 572       } else {
 573
 574         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
 575         if ( $contact_email ) {
 576           my $cust_contact = FS::cust_contact->new({
 577               contactnum    => $contact_email->contactnum,
 578               custnum       => $self->custnum,
 579           });
 580           $cust_contact->set('invoice_dest', 'Y');
 581           my $error = $cust_contact->contactnum ?
 582                         $cust_contact->replace : $cust_contact->insert;
 583           if ( $error ) {
 584             $dbh->rollback if $oldAutoCommit;
 585             return "$error (linking to email address $dest)";
 586           }
 587
 588         } else {
 589           # this email address is not yet linked to any contact
 590           $email .= ',' if length($email);
 591           $email .= $dest;
 592         }
 593       }
 594     }
 595
 596     my $contact = FS::contact->new({
 597       'custnum'       => $self->get('custnum'),
 598       'last'          => $self->get('last'),
 599       'first'         => $self->get('first'),
 600       'emailaddress'  => $email,
 601       'invoice_dest'  => 'Y', # yes, you can set this via the contact
 602     });
 603     my $error = $contact->insert;
 604     if ( $error ) {
 605       $dbh->rollback if $oldAutoCommit;
 606       return $error;
 607     }
 608
 609   }
 610
 611   if ( my $contact = delete $options{'contact'} ) {
 612
 613     foreach my $c ( @$contact ) {
 614       $c->custnum($self->custnum);
 615       my $error = $c->insert;
 616       if ( $error ) {
 617         $dbh->rollback if $oldAutoCommit;
 618         return $error;
 619       }
 620
 621     }
 622
 623   } elsif ( my $contact_params = delete $options{'contact_params'} ) {
 624
 625     my $error = $self->process_o2m( 'table'  => 'contact',
 626                                     'fields' => FS::contact->cgi_contact_fields,
 627                                     'params' => $contact_params,
 628                                   );
 629     if ( $error ) {
 630       $dbh->rollback if $oldAutoCommit;
 631       return $error;
 632     }
 633   }
 634
 635   warn "  setting cust_payby\n"
 636     if $DEBUG > 1;
 637
 638   if ( $options{cust_payby} ) {
 639
 640     foreach my $cust_payby ( @{ $options{cust_payby} } ) {
 641       $cust_payby->custnum($self->custnum);
 642       my $error = $cust_payby->insert;
 643       if ( $error ) {
 644         $dbh->rollback if $oldAutoCommit;
 645         return $error;
 646       }
 647     }
 648
 649   } elsif ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
 650
 651     my $error = $self->process_o2m(
 652       'table'         => 'cust_payby',
 653       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
 654       'params'        => $cust_payby_params,
 655       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
 656     );
 657     if ( $error ) {
 658       $dbh->rollback if $oldAutoCommit;
 659       return $error;
 660     }
 661
 662   }
 663
 664   warn "  setting cust_main_exemption\n"
 665     if $DEBUG > 1;
 666
 667   my $tax_exemption = delete $options{'tax_exemption'};
 668   if ( $tax_exemption ) {
 669
 670     $tax_exemption = { map { $_ => '' } @$tax_exemption }
 671       if ref($tax_exemption) eq 'ARRAY';
 672
 673     foreach my $taxname ( keys %$tax_exemption ) {
 674       my $cust_main_exemption = new FS::cust_main_exemption {
 675         'custnum'       => $self->custnum,
 676         'taxname'       => $taxname,
 677         'exempt_number' => $tax_exemption->{$taxname},
 678       };
 679       my $error = $cust_main_exemption->insert;
 680       if ( $error ) {
 681         $dbh->rollback if $oldAutoCommit;
 682         return "inserting cust_main_exemption (transaction rolled back): $error";
 683       }
 684     }
 685   }
 686
 687   warn "  ordering packages\n"
 688     if $DEBUG > 1;
 689
 690   $error = $self->order_pkgs( $cust_pkgs,
 691                               %options,
 692                               'seconds_ref'    => \$seconds,
 693                               'upbytes_ref'    => \$upbytes,
 694                               'downbytes_ref'  => \$downbytes,
 695                               'totalbytes_ref' => \$totalbytes,
 696                             );
 697   if ( $error ) {
 698     $dbh->rollback if $oldAutoCommit;
 699     return $error;
 700   }
 701
 702   if ( $seconds ) {
 703     $dbh->rollback if $oldAutoCommit;
 704     return "No svc_acct record to apply pre-paid time";
 705   }
 706   if ( $upbytes || $downbytes || $totalbytes ) {
 707     $dbh->rollback if $oldAutoCommit;
 708     return "No svc_acct record to apply pre-paid data";
 709   }
 710
 711   if ( $amount ) {
 712     warn "  inserting initial $payby payment of $amount\n"
 713       if $DEBUG > 1;
 714     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 715     if ( $error ) {
 716       $dbh->rollback if $oldAutoCommit;
 717       return "inserting payment (transaction rolled back): $error";
 718     }
 719   }
 720
 721   unless ( $import || $skip_fuzzyfiles ) {
 722     warn "  queueing fuzzyfiles update\n"
 723       if $DEBUG > 1;
 724     $error = $self->queue_fuzzyfiles_update;
 725     if ( $error ) {
 726       $dbh->rollback if $oldAutoCommit;
 727       return "updating fuzzy search cache: $error";
 728     }
 729   }
 730
 731   # FS::geocode_Mixin::after_insert or something?
 732   if ( $conf->config('tax_district_method') and !$import ) {
 733     # if anything non-empty, try to look it up
 734     my $queue = new FS::queue {
 735       'job'     => 'FS::geocode_Mixin::process_district_update',
 736       'custnum' => $self->custnum,
 737     };
 738     my $error = $queue->insert( ref($self), $self->custnum );
 739     if ( $error ) {
 740       $dbh->rollback if $oldAutoCommit;
 741       return "queueing tax district update: $error";
 742     }
 743   }
 744
 745   # cust_main exports!
 746   warn "  exporting\n" if $DEBUG > 1;
 747
 748   my $export_args = $options{'export_args'} || [];
 749
 750   my @part_export =
 751     map qsearch( 'part_export', {exportnum=>$_} ),
 752       $conf->config('cust_main-exports'); #, $agentnum
 753
 754   foreach my $part_export ( @part_export ) {
 755     my $error = $part_export->export_insert($self, @$export_args);
 756     if ( $error ) {
 757       $dbh->rollback if $oldAutoCommit;
 758       return "exporting to ". $part_export->exporttype.
 759              " (transaction rolled back): $error";
 760     }
 761   }
 762
 763   #foreach my $depend_jobnum ( @$depend_jobnums ) {
 764   #    warn "[$me] inserting dependancies on supplied job $depend_jobnum\n"
 765   #      if $DEBUG;
 766   #    foreach my $jobnum ( @jobnums ) {
 767   #      my $queue = qsearchs('queue', { 'jobnum' => $jobnum } );
 768   #      warn "[$me] inserting dependancy for job $jobnum on $depend_jobnum\n"
 769   #        if $DEBUG;
 770   #      my $error = $queue->depend_insert($depend_jobnum);
 771   #      if ( $error ) {
 772   #        $dbh->rollback if $oldAutoCommit;
 773   #        return "error queuing job dependancy: $error";
 774   #      }
 775   #    }
 776   #  }
 777   #
 778   #}
 779   #
 780   #if ( exists $options{'jobnums'} ) {
 781   #  push @{ $options{'jobnums'} }, @jobnums;
 782   #}
 783
 784   warn "  insert complete; committing transaction\n"
 785     if $DEBUG > 1;
 786
 787   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 788   '';
 789
 790 }
 791
 792 use File::CounterFile;
 793 sub auto_agent_custid {
 794   my $self = shift;
 795
 796   my $format = $conf->config('cust_main-auto_agent_custid');
 797   my $agent_custid;
 798   if ( $format eq '1YMMXXXXXXXX' ) {
 799
 800     my $counter = new File::CounterFile 'cust_main.agent_custid';
 801     $counter->lock;
 802
 803     my $ym = 100000000000 + time2str('%y%m00000000', time);
 804     if ( $ym > $counter->value ) {
 805       $counter->{'value'} = $agent_custid = $ym;
 806       $counter->{'updated'} = 1;
 807     } else {
 808       $agent_custid = $counter->inc;
 809     }
 810
 811     $counter->unlock;
 812
 813   } else {
 814     die "Unknown cust_main-auto_agent_custid format: $format";
 815   }
 816
 817   $self->agent_custid($agent_custid);
 818
 819 }
 820
 821 =item PACKAGE METHODS
 822
 823 Documentation on customer package methods has been moved to
 824 L<FS::cust_main::Packages>.
 825
 826 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 827
 828 Recharges this (existing) customer with the specified prepaid card (see
 829 L<FS::prepay_credit>), specified either by I<identifier> or as an
 830 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 831 returns false.
 832
 833 Optionally, five scalar references can be passed as well.  They will have their
 834 values filled in with the amount, number of seconds, and number of upload,
 835 download, and total bytes applied by this prepaid card.
 836
 837 =cut
 838
 839 #the ref bullshit here should be refactored like get_prepay.  MyAccount.pm is
 840 #the only place that uses these args
 841 sub recharge_prepay {
 842   my( $self, $prepay_credit, $amountref, $secondsref,
 843       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 844
 845   local $SIG{HUP} = 'IGNORE';
 846   local $SIG{INT} = 'IGNORE';
 847   local $SIG{QUIT} = 'IGNORE';
 848   local $SIG{TERM} = 'IGNORE';
 849   local $SIG{TSTP} = 'IGNORE';
 850   local $SIG{PIPE} = 'IGNORE';
 851
 852   my $oldAutoCommit = $FS::UID::AutoCommit;
 853   local $FS::UID::AutoCommit = 0;
 854   my $dbh = dbh;
 855
 856   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 857
 858   my $error = $self->get_prepay( $prepay_credit,
 859                                  'amount_ref'     => \$amount,
 860                                  'seconds_ref'    => \$seconds,
 861                                  'upbytes_ref'    => \$upbytes,
 862                                  'downbytes_ref'  => \$downbytes,
 863                                  'totalbytes_ref' => \$totalbytes,
 864                                )
 865            || $self->increment_seconds($seconds)
 866            || $self->increment_upbytes($upbytes)
 867            || $self->increment_downbytes($downbytes)
 868            || $self->increment_totalbytes($totalbytes)
 869            || $self->insert_cust_pay_prepay( $amount,
 870                                              ref($prepay_credit)
 871                                                ? $prepay_credit->identifier
 872                                                : $prepay_credit
 873                                            );
 874
 875   if ( $error ) {
 876     $dbh->rollback if $oldAutoCommit;
 877     return $error;
 878   }
 879
 880   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 881   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 882   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 883   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 884   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 885
 886   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 887   '';
 888
 889 }
 890
 891 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , OPTION => VALUE ... ]
 892
 893 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 894 specified either by I<identifier> or as an FS::prepay_credit object.
 895
 896 Available options are: I<amount_ref>, I<seconds_ref>, I<upbytes_ref>, I<downbytes_ref>, and I<totalbytes_ref>.  The scalars (provided by references) will be
 897 incremented by the values of the prepaid card.
 898
 899 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 900 check or set this customer's I<agentnum>.
 901
 902 If there is an error, returns the error, otherwise returns false.
 903
 904 =cut
 905
 906
 907 sub get_prepay {
 908   my( $self, $prepay_credit, %opt ) = @_;
 909
 910   local $SIG{HUP} = 'IGNORE';
 911   local $SIG{INT} = 'IGNORE';
 912   local $SIG{QUIT} = 'IGNORE';
 913   local $SIG{TERM} = 'IGNORE';
 914   local $SIG{TSTP} = 'IGNORE';
 915   local $SIG{PIPE} = 'IGNORE';
 916
 917   my $oldAutoCommit = $FS::UID::AutoCommit;
 918   local $FS::UID::AutoCommit = 0;
 919   my $dbh = dbh;
 920
 921   unless ( ref($prepay_credit) ) {
 922
 923     my $identifier = $prepay_credit;
 924
 925     $prepay_credit = qsearchs(
 926       'prepay_credit',
 927       { 'identifier' => $identifier },
 928       '',
 929       'FOR UPDATE'
 930     );
 931
 932     unless ( $prepay_credit ) {
 933       $dbh->rollback if $oldAutoCommit;
 934       return "Invalid prepaid card: ". $identifier;
 935     }
 936
 937   }
 938
 939   if ( $prepay_credit->agentnum ) {
 940     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 941       $dbh->rollback if $oldAutoCommit;
 942       return "prepaid card not valid for agent ". $self->agentnum;
 943     }
 944     $self->agentnum($prepay_credit->agentnum);
 945   }
 946
 947   my $error = $prepay_credit->delete;
 948   if ( $error ) {
 949     $dbh->rollback if $oldAutoCommit;
 950     return "removing prepay_credit (transaction rolled back): $error";
 951   }
 952
 953   ${ $opt{$_.'_ref'} } += $prepay_credit->$_()
 954     for grep $opt{$_.'_ref'}, qw( amount seconds upbytes downbytes totalbytes );
 955
 956   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 957   '';
 958
 959 }
 960
 961 =item increment_upbytes SECONDS
 962
 963 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 964 the specified number of upbytes.  If there is an error, returns the error,
 965 otherwise returns false.
 966
 967 =cut
 968
 969 sub increment_upbytes {
 970   _increment_column( shift, 'upbytes', @_);
 971 }
 972
 973 =item increment_downbytes SECONDS
 974
 975 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 976 the specified number of downbytes.  If there is an error, returns the error,
 977 otherwise returns false.
 978
 979 =cut
 980
 981 sub increment_downbytes {
 982   _increment_column( shift, 'downbytes', @_);
 983 }
 984
 985 =item increment_totalbytes SECONDS
 986
 987 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 988 the specified number of totalbytes.  If there is an error, returns the error,
 989 otherwise returns false.
 990
 991 =cut
 992
 993 sub increment_totalbytes {
 994   _increment_column( shift, 'totalbytes', @_);
 995 }
 996
 997 =item increment_seconds SECONDS
 998
 999 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1000 the specified number of seconds.  If there is an error, returns the error,
1001 otherwise returns false.
1002
1003 =cut
1004
1005 sub increment_seconds {
1006   _increment_column( shift, 'seconds', @_);
1007 }
1008
1009 =item _increment_column AMOUNT
1010
1011 Updates this customer's single or primary account (see L<FS::svc_acct>) by
1012 the specified number of seconds or bytes.  If there is an error, returns
1013 the error, otherwise returns false.
1014
1015 =cut
1016
1017 sub _increment_column {
1018   my( $self, $column, $amount ) = @_;
1019   warn "$me increment_column called: $column, $amount\n"
1020     if $DEBUG;
1021
1022   return '' unless $amount;
1023
1024   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
1025                       $self->ncancelled_pkgs;
1026
1027   if ( ! @cust_pkg ) {
1028     return 'No packages with primary or single services found'.
1029            ' to apply pre-paid time';
1030   } elsif ( scalar(@cust_pkg) > 1 ) {
1031     #maybe have a way to specify the package/account?
1032     return 'Multiple packages found to apply pre-paid time';
1033   }
1034
1035   my $cust_pkg = $cust_pkg[0];
1036   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
1037     if $DEBUG > 1;
1038
1039   my @cust_svc =
1040     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
1041
1042   if ( ! @cust_svc ) {
1043     return 'No account found to apply pre-paid time';
1044   } elsif ( scalar(@cust_svc) > 1 ) {
1045     return 'Multiple accounts found to apply pre-paid time';
1046   }
1047
1048   my $svc_acct = $cust_svc[0]->svc_x;
1049   warn "  found service svcnum ". $svc_acct->pkgnum.
1050        ' ('. $svc_acct->email. ")\n"
1051     if $DEBUG > 1;
1052
1053   $column = "increment_$column";
1054   $svc_acct->$column($amount);
1055
1056 }
1057
1058 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
1059
1060 Inserts a prepayment in the specified amount for this customer.  An optional
1061 second argument can specify the prepayment identifier for tracking purposes.
1062 If there is an error, returns the error, otherwise returns false.
1063
1064 =cut
1065
1066 sub insert_cust_pay_prepay {
1067   shift->insert_cust_pay('PREP', @_);
1068 }
1069
1070 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
1071
1072 Inserts a cash payment in the specified amount for this customer.  An optional
1073 second argument can specify the payment identifier for tracking purposes.
1074 If there is an error, returns the error, otherwise returns false.
1075
1076 =cut
1077
1078 sub insert_cust_pay_cash {
1079   shift->insert_cust_pay('CASH', @_);
1080 }
1081
1082 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
1083
1084 Inserts a Western Union payment in the specified amount for this customer.  An
1085 optional second argument can specify the prepayment identifier for tracking
1086 purposes.  If there is an error, returns the error, otherwise returns false.
1087
1088 =cut
1089
1090 sub insert_cust_pay_west {
1091   shift->insert_cust_pay('WEST', @_);
1092 }
1093
1094 sub insert_cust_pay {
1095   my( $self, $payby, $amount ) = splice(@_, 0, 3);
1096   my $payinfo = scalar(@_) ? shift : '';
1097
1098   my $cust_pay = new FS::cust_pay {
1099     'custnum' => $self->custnum,
1100     'paid'    => sprintf('%.2f', $amount),
1101     #'_date'   => #date the prepaid card was purchased???
1102     'payby'   => $payby,
1103     'payinfo' => $payinfo,
1104   };
1105   $cust_pay->insert;
1106
1107 }
1108
1109 =item delete [ OPTION => VALUE ... ]
1110
1111 This deletes the customer.  If there is an error, returns the error, otherwise
1112 returns false.
1113
1114 This will completely remove all traces of the customer record.  This is not
1115 what you want when a customer cancels service; for that, cancel all of the
1116 customer's packages (see L</cancel>).
1117
1118 If the customer has any uncancelled packages, you need to pass a new (valid)
1119 customer number for those packages to be transferred to, as the "new_customer"
1120 option.  Cancelled packages will be deleted.  Did I mention that this is NOT
1121 what you want when a customer cancels service and that you really should be
1122 looking at L<FS::cust_pkg/cancel>?
1123
1124 You can't delete a customer with invoices (see L<FS::cust_bill>),
1125 statements (see L<FS::cust_statement>), credits (see L<FS::cust_credit>),
1126 payments (see L<FS::cust_pay>) or refunds (see L<FS::cust_refund>), unless you
1127 set the "delete_financials" option to a true value.
1128
1129 =cut
1130
1131 sub delete {
1132   my( $self, %opt ) = @_;
1133
1134   local $SIG{HUP} = 'IGNORE';
1135   local $SIG{INT} = 'IGNORE';
1136   local $SIG{QUIT} = 'IGNORE';
1137   local $SIG{TERM} = 'IGNORE';
1138   local $SIG{TSTP} = 'IGNORE';
1139   local $SIG{PIPE} = 'IGNORE';
1140
1141   my $oldAutoCommit = $FS::UID::AutoCommit;
1142   local $FS::UID::AutoCommit = 0;
1143   my $dbh = dbh;
1144
1145   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1146      $dbh->rollback if $oldAutoCommit;
1147      return "Can't delete a master agent customer";
1148   }
1149
1150   #use FS::access_user
1151   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1152      $dbh->rollback if $oldAutoCommit;
1153      return "Can't delete a master employee customer";
1154   }
1155
1156   tie my %financial_tables, 'Tie::IxHash',
1157     'cust_bill'      => 'invoices',
1158     'cust_statement' => 'statements',
1159     'cust_credit'    => 'credits',
1160     'cust_pay'       => 'payments',
1161     'cust_refund'    => 'refunds',
1162   ;
1163
1164   foreach my $table ( keys %financial_tables ) {
1165
1166     my @records = $self->$table();
1167
1168     if ( @records && ! $opt{'delete_financials'} ) {
1169       $dbh->rollback if $oldAutoCommit;
1170       return "Can't delete a customer with ". $financial_tables{$table};
1171     }
1172
1173     foreach my $record ( @records ) {
1174       my $error = $record->delete;
1175       if ( $error ) {
1176         $dbh->rollback if $oldAutoCommit;
1177         return "Error deleting ". $financial_tables{$table}. ": $error\n";
1178       }
1179     }
1180
1181   }
1182
1183   my @cust_pkg = $self->ncancelled_pkgs;
1184   if ( @cust_pkg ) {
1185     my $new_custnum = $opt{'new_custnum'};
1186     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1187       $dbh->rollback if $oldAutoCommit;
1188       return "Invalid new customer number: $new_custnum";
1189     }
1190     foreach my $cust_pkg ( @cust_pkg ) {
1191       my %hash = $cust_pkg->hash;
1192       $hash{'custnum'} = $new_custnum;
1193       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1194       my $error = $new_cust_pkg->replace($cust_pkg,
1195                                          options => { $cust_pkg->options },
1196                                         );
1197       if ( $error ) {
1198         $dbh->rollback if $oldAutoCommit;
1199         return $error;
1200       }
1201     }
1202   }
1203   my @cancelled_cust_pkg = $self->all_pkgs;
1204   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1205     my $error = $cust_pkg->delete;
1206     if ( $error ) {
1207       $dbh->rollback if $oldAutoCommit;
1208       return $error;
1209     }
1210   }
1211
1212   #cust_tax_adjustment in financials?
1213   #cust_pay_pending?  ouch
1214   foreach my $table (qw(
1215     cust_main_invoice cust_main_exemption cust_tag cust_attachment contact
1216     cust_payby cust_location cust_main_note cust_tax_adjustment
1217     cust_pay_void cust_pay_batch queue cust_tax_exempt
1218   )) {
1219     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1220       my $error = $record->delete;
1221       if ( $error ) {
1222         $dbh->rollback if $oldAutoCommit;
1223         return $error;
1224       }
1225     }
1226   }
1227
1228   my $sth = $dbh->prepare(
1229     'UPDATE cust_main SET referral_custnum = NULL WHERE referral_custnum = ?'
1230   ) or do {
1231     my $errstr = $dbh->errstr;
1232     $dbh->rollback if $oldAutoCommit;
1233     return $errstr;
1234   };
1235   $sth->execute($self->custnum) or do {
1236     my $errstr = $sth->errstr;
1237     $dbh->rollback if $oldAutoCommit;
1238     return $errstr;
1239   };
1240
1241   #tickets
1242
1243   my $ticket_dbh = '';
1244   if ($conf->config('ticket_system') eq 'RT_Internal') {
1245     $ticket_dbh = $dbh;
1246   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1247     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1248     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1249       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1250   }
1251
1252   if ( $ticket_dbh ) {
1253
1254     my $ticket_sth = $ticket_dbh->prepare(
1255       'DELETE FROM Links WHERE Target = ?'
1256     ) or do {
1257       my $errstr = $ticket_dbh->errstr;
1258       $dbh->rollback if $oldAutoCommit;
1259       return $errstr;
1260     };
1261     $ticket_sth->execute('freeside://freeside/cust_main/'.$self->custnum)
1262       or do {
1263         my $errstr = $ticket_sth->errstr;
1264         $dbh->rollback if $oldAutoCommit;
1265         return $errstr;
1266       };
1267
1268     #check and see if the customer is the only link on the ticket, and
1269     #if so, set the ticket to deleted status in RT?
1270     #maybe someday, for now this will at least fix tickets not displaying
1271
1272   }
1273
1274   #delete the customer record
1275
1276   my $error = $self->SUPER::delete;
1277   if ( $error ) {
1278     $dbh->rollback if $oldAutoCommit;
1279     return $error;
1280   }
1281
1282   # cust_main exports!
1283
1284   #my $export_args = $options{'export_args'} || [];
1285
1286   my @part_export =
1287     map qsearch( 'part_export', {exportnum=>$_} ),
1288       $conf->config('cust_main-exports'); #, $agentnum
1289
1290   foreach my $part_export ( @part_export ) {
1291     my $error = $part_export->export_delete( $self ); #, @$export_args);
1292     if ( $error ) {
1293       $dbh->rollback if $oldAutoCommit;
1294       return "exporting to ". $part_export->exporttype.
1295              " (transaction rolled back): $error";
1296     }
1297   }
1298
1299   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1300   '';
1301
1302 }
1303
1304 =item replace [ OLD_RECORD ] [ INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
1305
1306 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1307 returns the error, otherwise returns false.
1308
1309 To change the customer's address, set the pseudo-fields C<bill_location> and
1310 C<ship_location>.  The address will still only change if at least one of the
1311 address fields differs from the existing values.
1312
1313 INVOICING_LIST_ARYREF: If you pass an arrayref to this method, it will be
1314 set as the contact email address for a default contact with the same name as
1315 the customer.
1316
1317 Currently available options are: I<tax_exemption>, I<cust_payby_params>,
1318 I<contact_params>, I<invoicing_list>.
1319
1320 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
1321 of tax names and exemption numbers.  FS::cust_main_exemption records will be
1322 deleted and inserted as appropriate.
1323
1324 I<cust_payby_params> and I<contact_params> can be hashrefs of named parameter
1325 groups (describing the customer's payment methods and contacts, respectively)
1326 in the style supported by L<FS::o2m_Common/process_o2m>. See L<FS::cust_payby>
1327 and L<FS::contact> for the fields these can contain.
1328
1329 I<invoicing_list> is a synonym for the INVOICING_LIST_ARYREF parameter, and
1330 should be used instead if possible.
1331
1332 =cut
1333
1334 sub replace {
1335   my $self = shift;
1336
1337   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
1338               ? shift
1339               : $self->replace_old;
1340
1341   my @param = @_;
1342
1343   warn "$me replace called\n"
1344     if $DEBUG;
1345
1346   my $curuser = $FS::CurrentUser::CurrentUser;
1347   return "You are not permitted to create complimentary accounts."
1348     if $self->complimentary eq 'Y'
1349     && $self->complimentary ne $old->complimentary
1350     && ! $curuser->access_right('Complimentary customer');
1351
1352   local($ignore_expired_card) = 1
1353     if $old->payby  =~ /^(CARD|DCRD)$/
1354     && $self->payby =~ /^(CARD|DCRD)$/
1355     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1356
1357   local($ignore_banned_card) = 1
1358     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
1359          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
1360     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1361
1362   if (    $self->payby =~ /^(CARD|DCRD)$/
1363        && $old->payinfo ne $self->payinfo
1364        && $old->paymask ne $self->paymask )
1365   {
1366     my $error = $self->check_payinfo_cardtype;
1367     return $error if $error;
1368   }
1369
1370   return "Invoicing locale is required"
1371     if $old->locale
1372     && ! $self->locale
1373     && $conf->exists('cust_main-require_locale');
1374
1375   local $SIG{HUP} = 'IGNORE';
1376   local $SIG{INT} = 'IGNORE';
1377   local $SIG{QUIT} = 'IGNORE';
1378   local $SIG{TERM} = 'IGNORE';
1379   local $SIG{TSTP} = 'IGNORE';
1380   local $SIG{PIPE} = 'IGNORE';
1381
1382   my $oldAutoCommit = $FS::UID::AutoCommit;
1383   local $FS::UID::AutoCommit = 0;
1384   my $dbh = dbh;
1385
1386   for my $l (qw(bill_location ship_location)) {
1387     #my $old_loc = $old->$l;
1388     my $new_loc = $self->$l or next;
1389
1390     # find the existing location if there is one
1391     $new_loc->set('custnum' => $self->custnum);
1392     my $error = $new_loc->find_or_insert;
1393     if ( $error ) {
1394       $dbh->rollback if $oldAutoCommit;
1395       return $error;
1396     }
1397     $self->set($l.'num', $new_loc->locationnum);
1398   } #for $l
1399
1400   my $invoicing_list;
1401   if ( @param && ref($param[0]) eq 'ARRAY' ) { # INVOICING_LIST_ARYREF
1402     warn "cust_main::replace: using deprecated invoicing list argument";
1403     $invoicing_list = shift @param;
1404   }
1405
1406   my %options = @param;
1407
1408   $invoicing_list ||= $options{invoicing_list};
1409
1410   my @contacts = map { $_->contact } $self->cust_contact;
1411   # find a contact that matches the customer's name
1412   my ($implicit_contact) = grep { $_->first eq $old->get('first')
1413                               and $_->last  eq $old->get('last') }
1414                             @contacts;
1415   $implicit_contact ||= FS::contact->new({
1416       'custnum'       => $self->custnum,
1417       'locationnum'   => $self->get('bill_locationnum'),
1418   });
1419
1420   # for any of these that are already contact emails, link to the existing
1421   # contact
1422   if ( $invoicing_list ) {
1423     my $email = '';
1424
1425     # kind of like process_m2m on these, except:
1426     # - the other side is two tables in a join
1427     # - and we might have to create new contact_emails
1428     # - and possibly a new contact
1429     #
1430     # Find existing invoice emails that aren't on the implicit contact.
1431     # Any of these that are not on the new invoicing list will be removed.
1432     my %old_email_cust_contact;
1433     foreach my $cust_contact ($self->cust_contact) {
1434       next if !$cust_contact->invoice_dest;
1435       next if $cust_contact->contactnum == ($implicit_contact->contactnum || 0);
1436
1437       foreach my $contact_email ($cust_contact->contact->contact_email) {
1438         $old_email_cust_contact{ $contact_email->emailaddress } = $cust_contact;
1439       }
1440     }
1441
1442     foreach my $dest (@$invoicing_list) {
1443
1444       if ($dest eq 'POST') {
1445
1446         $self->set('postal_invoice', 'Y');
1447
1448       } elsif ( exists($old_email_cust_contact{$dest}) ) {
1449
1450         delete $old_email_cust_contact{$dest}; # don't need to remove it, then
1451
1452       } else {
1453
1454         # See if it belongs to some other contact; if so, link it.
1455         my $contact_email = qsearchs('contact_email', { emailaddress => $dest });
1456         if ( $contact_email
1457              and $contact_email->contactnum != ($implicit_contact->contactnum || 0) ) {
1458           my $cust_contact = qsearchs('cust_contact', {
1459               contactnum  => $contact_email->contactnum,
1460               custnum     => $self->custnum,
1461           }) || FS::cust_contact->new({
1462               contactnum    => $contact_email->contactnum,
1463               custnum       => $self->custnum,
1464           });
1465           $cust_contact->set('invoice_dest', 'Y');
1466           my $error = $cust_contact->custcontactnum ?
1467                         $cust_contact->replace : $cust_contact->insert;
1468           if ( $error ) {
1469             $dbh->rollback if $oldAutoCommit;
1470             return "$error (linking to email address $dest)";
1471           }
1472
1473         } else {
1474           # This email address is not yet linked to any contact, so it will
1475           # be added to the implicit contact.
1476           $email .= ',' if length($email);
1477           $email .= $dest;
1478         }
1479       }
1480     }
1481
1482     foreach my $remove_dest (keys %old_email_cust_contact) {
1483       my $cust_contact = $old_email_cust_contact{$remove_dest};
1484       # These were not in the list of requested destinations, so take them off.
1485       $cust_contact->set('invoice_dest', '');
1486       my $error = $cust_contact->replace;
1487       if ( $error ) {
1488         $dbh->rollback if $oldAutoCommit;
1489         return "$error (unlinking email address $remove_dest)";
1490       }
1491     }
1492
1493     # make sure it keeps up with the changed customer name, if any
1494     $implicit_contact->set('last', $self->get('last'));
1495     $implicit_contact->set('first', $self->get('first'));
1496     $implicit_contact->set('emailaddress', $email);
1497     $implicit_contact->set('invoice_dest', 'Y');
1498     $implicit_contact->set('custnum', $self->custnum);
1499
1500     my $error;
1501     if ( $implicit_contact->contactnum ) {
1502       $error = $implicit_contact->replace;
1503     } elsif ( length($email) ) { # don't create a new contact if not needed
1504       $error = $implicit_contact->insert;
1505     }
1506
1507     if ( $error ) {
1508       $dbh->rollback if $oldAutoCommit;
1509       return "$error (adding email address $email)";
1510     }
1511
1512   }
1513
1514   # replace the customer record
1515   my $error = $self->SUPER::replace($old);
1516
1517   if ( $error ) {
1518     $dbh->rollback if $oldAutoCommit;
1519     return $error;
1520   }
1521
1522   # now move packages to the new service location
1523   $self->set('ship_location', ''); #flush cache
1524   if ( $old->ship_locationnum and # should only be null during upgrade...
1525        $old->ship_locationnum != $self->ship_locationnum ) {
1526     $error = $old->ship_location->move_to($self->ship_location);
1527     if ( $error ) {
1528       $dbh->rollback if $oldAutoCommit;
1529       return $error;
1530     }
1531   }
1532   # don't move packages based on the billing location, but
1533   # disable it if it's no longer in use
1534   if ( $old->bill_locationnum and
1535        $old->bill_locationnum != $self->bill_locationnum ) {
1536     $error = $old->bill_location->disable_if_unused;
1537     if ( $error ) {
1538       $dbh->rollback if $oldAutoCommit;
1539       return $error;
1540     }
1541   }
1542
1543   if ( $self->exists('tagnum') ) { #so we don't delete these on edit by accident
1544
1545     #this could be more efficient than deleting and re-inserting, if it matters
1546     foreach my $cust_tag (qsearch('cust_tag', {'custnum'=>$self->custnum} )) {
1547       my $error = $cust_tag->delete;
1548       if ( $error ) {
1549         $dbh->rollback if $oldAutoCommit;
1550         return $error;
1551       }
1552     }
1553     foreach my $tagnum ( @{ $self->tagnum || [] } ) {
1554       my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
1555                                         'custnum' => $self->custnum };
1556       my $error = $cust_tag->insert;
1557       if ( $error ) {
1558         $dbh->rollback if $oldAutoCommit;
1559         return $error;
1560       }
1561     }
1562
1563   }
1564
1565   my $tax_exemption = delete $options{'tax_exemption'};
1566   if ( $tax_exemption ) {
1567
1568     $tax_exemption = { map { $_ => '' } @$tax_exemption }
1569       if ref($tax_exemption) eq 'ARRAY';
1570
1571     my %cust_main_exemption =
1572       map { $_->taxname => $_ }
1573           qsearch('cust_main_exemption', { 'custnum' => $old->custnum } );
1574
1575     foreach my $taxname ( keys %$tax_exemption ) {
1576
1577       if ( $cust_main_exemption{$taxname} &&
1578            $cust_main_exemption{$taxname}->exempt_number eq $tax_exemption->{$taxname}
1579          )
1580       {
1581         delete $cust_main_exemption{$taxname};
1582         next;
1583       }
1584
1585       my $cust_main_exemption = new FS::cust_main_exemption {
1586         'custnum'       => $self->custnum,
1587         'taxname'       => $taxname,
1588         'exempt_number' => $tax_exemption->{$taxname},
1589       };
1590       my $error = $cust_main_exemption->insert;
1591       if ( $error ) {
1592         $dbh->rollback if $oldAutoCommit;
1593         return "inserting cust_main_exemption (transaction rolled back): $error";
1594       }
1595     }
1596
1597     foreach my $cust_main_exemption ( values %cust_main_exemption ) {
1598       my $error = $cust_main_exemption->delete;
1599       if ( $error ) {
1600         $dbh->rollback if $oldAutoCommit;
1601         return "deleting cust_main_exemption (transaction rolled back): $error";
1602       }
1603     }
1604
1605   }
1606
1607   if ( my $cust_payby_params = delete $options{'cust_payby_params'} ) {
1608
1609     my $error = $self->process_o2m(
1610       'table'         => 'cust_payby',
1611       'fields'        => FS::cust_payby->cgi_cust_payby_fields,
1612       'params'        => $cust_payby_params,
1613       'hash_callback' => \&FS::cust_payby::cgi_hash_callback,
1614     );
1615     if ( $error ) {
1616       $dbh->rollback if $oldAutoCommit;
1617       return $error;
1618     }
1619
1620   }
1621
1622   if ( my $contact_params = delete $options{'contact_params'} ) {
1623
1624     # this can potentially replace contacts that were created by the
1625     # invoicing list argument, but the UI shouldn't allow both of them
1626     # to be specified
1627
1628     my $error = $self->process_o2m(
1629       'table'         => 'contact',
1630       'fields'        => FS::contact->cgi_contact_fields,
1631       'params'        => $contact_params,
1632     );
1633     if ( $error ) {
1634       $dbh->rollback if $oldAutoCommit;
1635       return $error;
1636     }
1637
1638   }
1639
1640   unless ( $import || $skip_fuzzyfiles ) {
1641     $error = $self->queue_fuzzyfiles_update;
1642     if ( $error ) {
1643       $dbh->rollback if $oldAutoCommit;
1644       return "updating fuzzy search cache: $error";
1645     }
1646   }
1647
1648   # tax district update in cust_location
1649
1650   # cust_main exports!
1651
1652   my $export_args = $options{'export_args'} || [];
1653
1654   my @part_export =
1655     map qsearch( 'part_export', {exportnum=>$_} ),
1656       $conf->config('cust_main-exports'); #, $agentnum
1657
1658   foreach my $part_export ( @part_export ) {
1659     my $error = $part_export->export_replace( $self, $old, @$export_args);
1660     if ( $error ) {
1661       $dbh->rollback if $oldAutoCommit;
1662       return "exporting to ". $part_export->exporttype.
1663              " (transaction rolled back): $error";
1664     }
1665   }
1666
1667   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1668   '';
1669
1670 }
1671
1672 =item queue_fuzzyfiles_update
1673
1674 Used by insert & replace to update the fuzzy search cache
1675
1676 =cut
1677
1678 use FS::cust_main::Search;
1679 sub queue_fuzzyfiles_update {
1680   my $self = shift;
1681
1682   local $SIG{HUP} = 'IGNORE';
1683   local $SIG{INT} = 'IGNORE';
1684   local $SIG{QUIT} = 'IGNORE';
1685   local $SIG{TERM} = 'IGNORE';
1686   local $SIG{TSTP} = 'IGNORE';
1687   local $SIG{PIPE} = 'IGNORE';
1688
1689   my $oldAutoCommit = $FS::UID::AutoCommit;
1690   local $FS::UID::AutoCommit = 0;
1691   my $dbh = dbh;
1692
1693   foreach my $field ( 'first', 'last', 'company', 'ship_company' ) {
1694     my $queue = new FS::queue {
1695       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1696     };
1697     my @args = "cust_main.$field", $self->get($field);
1698     my $error = $queue->insert( @args );
1699     if ( $error ) {
1700       $dbh->rollback if $oldAutoCommit;
1701       return "queueing job (transaction rolled back): $error";
1702     }
1703   }
1704
1705   my @locations = ();
1706   push @locations, $self->bill_location if $self->bill_locationnum;
1707   push @locations, $self->ship_location if @locations && $self->has_ship_address;
1708   foreach my $location (@locations) {
1709     my $queue = new FS::queue {
1710       'job' => 'FS::cust_main::Search::append_fuzzyfiles_fuzzyfield'
1711     };
1712     my @args = 'cust_location.address1', $location->address1;
1713     my $error = $queue->insert( @args );
1714     if ( $error ) {
1715       $dbh->rollback if $oldAutoCommit;
1716       return "queueing job (transaction rolled back): $error";
1717     }
1718   }
1719
1720   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1721   '';
1722
1723 }
1724
1725 =item check
1726
1727 Checks all fields to make sure this is a valid customer record.  If there is
1728 an error, returns the error, otherwise returns false.  Called by the insert
1729 and replace methods.
1730
1731 =cut
1732
1733 sub check {
1734   my $self = shift;
1735
1736   warn "$me check BEFORE: \n". $self->_dump
1737     if $DEBUG > 2;
1738
1739   my $error =
1740     $self->ut_numbern('custnum')
1741     || $self->ut_number('agentnum')
1742     || $self->ut_textn('agent_custid')
1743     || $self->ut_number('refnum')
1744     || $self->ut_foreign_keyn('bill_locationnum', 'cust_location','locationnum')
1745     || $self->ut_foreign_keyn('ship_locationnum', 'cust_location','locationnum')
1746     || $self->ut_foreign_keyn('classnum', 'cust_class', 'classnum')
1747     || $self->ut_foreign_keyn('salesnum', 'sales', 'salesnum')
1748     || $self->ut_foreign_keyn('taxstatusnum', 'tax_status', 'taxstatusnum')
1749     || $self->ut_textn('custbatch')
1750     || $self->ut_name('last')
1751     || $self->ut_name('first')
1752     || $self->ut_snumbern('signupdate')
1753     || $self->ut_snumbern('birthdate')
1754     || $self->ut_namen('spouse_last')
1755     || $self->ut_namen('spouse_first')
1756     || $self->ut_snumbern('spouse_birthdate')
1757     || $self->ut_snumbern('anniversary_date')
1758     || $self->ut_textn('company')
1759     || $self->ut_textn('ship_company')
1760     || $self->ut_anything('comments')
1761     || $self->ut_numbern('referral_custnum')
1762     || $self->ut_textn('stateid')
1763     || $self->ut_textn('stateid_state')
1764     || $self->ut_textn('invoice_terms')
1765     || $self->ut_floatn('cdr_termination_percentage')
1766     || $self->ut_floatn('credit_limit')
1767     || $self->ut_numbern('billday')
1768     || $self->ut_numbern('prorate_day')
1769     || $self->ut_flag('edit_subject')
1770     || $self->ut_flag('calling_list_exempt')
1771     || $self->ut_flag('invoice_noemail')
1772     || $self->ut_flag('message_noemail')
1773     || $self->ut_enum('locale', [ '', FS::Locales->locales ])
1774     || $self->ut_currencyn('currency')
1775     || $self->ut_alphan('po_number')
1776     || $self->ut_enum('complimentary', [ '', 'Y' ])
1777     || $self->ut_flag('invoice_ship_address')
1778     || $self->ut_flag('invoice_dest')
1779   ;
1780
1781   foreach (qw(company ship_company)) {
1782     my $company = $self->get($_);
1783     $company =~ s/^\s+//;
1784     $company =~ s/\s+$//;
1785     $company =~ s/\s+/ /g;
1786     $self->set($_, $company);
1787   }
1788
1789   #barf.  need message catalogs.  i18n.  etc.
1790   $error .= "Please select an advertising source."
1791     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1792   return $error if $error;
1793
1794   my $agent = qsearchs( 'agent', { 'agentnum' => $self->agentnum } )
1795     or return "Unknown agent";
1796
1797   if ( $self->currency ) {
1798     my $agent_currency = qsearchs( 'agent_currency', {
1799       'agentnum' => $agent->agentnum,
1800       'currency' => $self->currency,
1801     })
1802       or return "Agent ". $agent->agent.
1803                 " not permitted to offer ".  $self->currency. " invoicing";
1804   }
1805
1806   return "Unknown refnum"
1807     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1808
1809   return "Unknown referring custnum: ". $self->referral_custnum
1810     unless ! $self->referral_custnum
1811            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1812
1813   if ( $self->ss eq '' ) {
1814     $self->ss('');
1815   } else {
1816     my $ss = $self->ss;
1817     $ss =~ s/\D//g;
1818     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1819       or return "Illegal social security number: ". $self->ss;
1820     $self->ss("$1-$2-$3");
1821   }
1822
1823   #turn off invoice_ship_address if ship & bill are the same
1824   if ($self->bill_locationnum eq $self->ship_locationnum) {
1825     $self->invoice_ship_address('');
1826   }
1827
1828   # cust_main_county verification now handled by cust_location check
1829
1830   $error =
1831        $self->ut_phonen('daytime', $self->country)
1832     || $self->ut_phonen('night',   $self->country)
1833     || $self->ut_phonen('fax',     $self->country)
1834     || $self->ut_phonen('mobile',  $self->country)
1835   ;
1836   return $error if $error;
1837
1838   if ( $conf->exists('cust_main-require_phone', $self->agentnum)
1839        && ! $import
1840        && ! length($self->daytime) && ! length($self->night) && ! length($self->mobile)
1841      ) {
1842
1843     my $daytime_label = FS::Msgcat::_gettext('daytime') =~ /^(daytime)?$/
1844                           ? 'Day Phone'
1845                           : FS::Msgcat::_gettext('daytime');
1846     my $night_label = FS::Msgcat::_gettext('night') =~ /^(night)?$/
1847                         ? 'Night Phone'
1848                         : FS::Msgcat::_gettext('night');
1849
1850     my $mobile_label = FS::Msgcat::_gettext('mobile') =~ /^(mobile)?$/
1851                         ? 'Mobile Phone'
1852                         : FS::Msgcat::_gettext('mobile');
1853
1854     return "$daytime_label, $night_label or $mobile_label is required"
1855
1856   }
1857
1858   return "Please select an invoicing locale"
1859     if ! $self->locale
1860     && ! $self->custnum
1861     && $conf->exists('cust_main-require_locale');
1862
1863   foreach my $flag (qw( tax spool_cdr squelch_cdr archived email_csv_cdr )) {
1864     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
1865     $self->$flag($1);
1866   }
1867
1868   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
1869
1870   warn "$me check AFTER: \n". $self->_dump
1871     if $DEBUG > 2;
1872
1873   $self->SUPER::check;
1874 }
1875
1876 sub check_payinfo_cardtype {
1877   my $self = shift;
1878
1879   return '' unless $self->payby =~ /^(CARD|DCRD)$/;
1880
1881   my $payinfo = $self->payinfo;
1882   $payinfo =~ s/\D//g;
1883
1884   return '' if $payinfo =~ /^99\d{14}$/; #token
1885
1886   my %bop_card_types = map { $_=>1 } values %{ card_types() };
1887   my $cardtype = cardtype($payinfo);
1888
1889   return "$cardtype not accepted" unless $bop_card_types{$cardtype};
1890
1891   '';
1892
1893 }
1894
1895 =item replace_check
1896
1897 Additional checks for replace only.
1898
1899 =cut
1900
1901 sub replace_check {
1902   my ($new,$old) = @_;
1903   #preserve old value if global config is set
1904   if ($old && $conf->exists('invoice-ship_address')) {
1905     $new->invoice_ship_address($old->invoice_ship_address);
1906   }
1907   return '';
1908 }
1909
1910 =item addr_fields
1911
1912 Returns a list of fields which have ship_ duplicates.
1913
1914 =cut
1915
1916 sub addr_fields {
1917   qw( last first company
1918       locationname
1919       address1 address2 city county state zip country
1920       latitude longitude
1921       daytime night fax mobile
1922     );
1923 }
1924
1925 =item has_ship_address
1926
1927 Returns true if this customer record has a separate shipping address.
1928
1929 =cut
1930
1931 sub has_ship_address {
1932   my $self = shift;
1933   $self->bill_locationnum != $self->ship_locationnum;
1934 }
1935
1936 =item location_hash
1937
1938 Returns a list of key/value pairs, with the following keys: address1,
1939 adddress2, city, county, state, zip, country, district, and geocode.  The
1940 shipping address is used if present.
1941
1942 =cut
1943
1944 sub location_hash {
1945   my $self = shift;
1946   $self->ship_location->location_hash;
1947 }
1948
1949 =item cust_location
1950
1951 Returns all locations (see L<FS::cust_location>) for this customer.
1952
1953 =cut
1954
1955 sub cust_location {
1956   my $self = shift;
1957   qsearch({
1958     'table'   => 'cust_location',
1959     'hashref' => { 'custnum'     => $self->custnum,
1960                    'prospectnum' => '',
1961                  },
1962     'order_by' => 'ORDER BY country, LOWER(state), LOWER(city), LOWER(county), LOWER(address1), LOWER(address2)',
1963   });
1964 }
1965
1966 =item cust_contact
1967
1968 Returns all contact associations (see L<FS::cust_contact>) for this customer.
1969
1970 =cut
1971
1972 sub cust_contact {
1973   my $self = shift;
1974   qsearch('cust_contact', { 'custnum' => $self->custnum } );
1975 }
1976
1977 =item cust_payby PAYBY
1978
1979 Returns all payment methods (see L<FS::cust_payby>) for this customer.
1980
1981 If one or more PAYBY are specified, returns only payment methods for specified PAYBY.
1982 Does not validate PAYBY.
1983
1984 =cut
1985
1986 sub cust_payby {
1987   my $self = shift;
1988   my @payby = @_;
1989   my $search = {
1990     'table'    => 'cust_payby',
1991     'hashref'  => { 'custnum' => $self->custnum },
1992     'order_by' => "ORDER BY payby IN ('CARD','CHEK') DESC, weight ASC",
1993   };
1994   $search->{'extra_sql'} = ' AND payby IN ( ' . join(',', map { dbh->quote($_) } @payby) . ' ) '
1995     if @payby;
1996
1997   qsearch($search);
1998 }
1999
2000 =item has_cust_payby_auto
2001
2002 Returns true if customer has an automatic payment method ('CARD' or 'CHEK')
2003
2004 =cut
2005
2006 sub has_cust_payby_auto {
2007   my $self = shift;
2008   scalar( qsearch({
2009     'table'     => 'cust_payby',
2010     'hashref'   => { 'custnum' => $self->custnum, },
2011     'extra_sql' => " AND payby IN ( 'CARD', 'CHEK' ) ",
2012     'order_by'  => 'LIMIT 1',
2013   }) );
2014
2015 }
2016
2017 =item unsuspend
2018
2019 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
2020 and L<FS::cust_pkg>) for this customer, except those on hold.
2021
2022 Returns a list: an empty list on success or a list of errors.
2023
2024 =cut
2025
2026 sub unsuspend {
2027   my $self = shift;
2028   grep { ($_->get('setup')) && $_->unsuspend } $self->suspended_pkgs;
2029 }
2030
2031 =item release_hold
2032
2033 Unsuspends all suspended packages in the on-hold state (those without setup
2034 dates) for this customer.
2035
2036 =cut
2037
2038 sub release_hold {
2039   my $self = shift;
2040   grep { (!$_->setup) && $_->unsuspend } $self->suspended_pkgs;
2041 }
2042
2043 =item suspend
2044
2045 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
2046
2047 Returns a list: an empty list on success or a list of errors.
2048
2049 =cut
2050
2051 sub suspend {
2052   my $self = shift;
2053   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
2054 }
2055
2056 =item suspend_if_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2057
2058 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
2059 PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref instead
2060 of a list of pkgparts; the hashref has the following keys:
2061
2062 =over 4
2063
2064 =item pkgparts - listref of pkgparts
2065
2066 =item (other options are passed to the suspend method)
2067
2068 =back
2069
2070
2071 Returns a list: an empty list on success or a list of errors.
2072
2073 =cut
2074
2075 sub suspend_if_pkgpart {
2076   my $self = shift;
2077   my (@pkgparts, %opt);
2078   if (ref($_[0]) eq 'HASH'){
2079     @pkgparts = @{$_[0]{pkgparts}};
2080     %opt      = %{$_[0]};
2081   }else{
2082     @pkgparts = @_;
2083   }
2084   grep { $_->suspend(%opt) }
2085     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
2086       $self->unsuspended_pkgs;
2087 }
2088
2089 =item suspend_unless_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2090
2091 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
2092 given PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref
2093 instead of a list of pkgparts; the hashref has the following keys:
2094
2095 =over 4
2096
2097 =item pkgparts - listref of pkgparts
2098
2099 =item (other options are passed to the suspend method)
2100
2101 =back
2102
2103 Returns a list: an empty list on success or a list of errors.
2104
2105 =cut
2106
2107 sub suspend_unless_pkgpart {
2108   my $self = shift;
2109   my (@pkgparts, %opt);
2110   if (ref($_[0]) eq 'HASH'){
2111     @pkgparts = @{$_[0]{pkgparts}};
2112     %opt      = %{$_[0]};
2113   }else{
2114     @pkgparts = @_;
2115   }
2116   grep { $_->suspend(%opt) }
2117     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
2118       $self->unsuspended_pkgs;
2119 }
2120
2121 =item cancel [ OPTION => VALUE ... ]
2122
2123 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
2124
2125 Available options are:
2126
2127 =over 4
2128
2129 =item quiet - can be set true to supress email cancellation notices.
2130
2131 =item reason - can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
2132
2133 =item ban - can be set true to ban this customer's credit card or ACH information, if present.
2134
2135 =item nobill - can be set true to skip billing if it might otherwise be done.
2136
2137 =back
2138
2139 Always returns a list: an empty list on success or a list of errors.
2140
2141 =cut
2142
2143 # nb that dates are not specified as valid options to this method
2144
2145 sub cancel {
2146   my( $self, %opt ) = @_;
2147
2148   warn "$me cancel called on customer ". $self->custnum. " with options ".
2149        join(', ', map { "$_: $opt{$_}" } keys %opt ). "\n"
2150     if $DEBUG;
2151
2152   return ( 'access denied' )
2153     unless $FS::CurrentUser::CurrentUser->access_right('Cancel customer');
2154
2155   if ( $opt{'ban'} ) {
2156
2157     foreach my $cust_payby ( $self->cust_payby ) {
2158
2159       #well, if they didn't get decrypted on search, then we don't have to
2160       # try again... queue a job for the server that does have decryption
2161       # capability if we're in a paranoid multi-server implementation?
2162       return ( "Can't (yet) ban encrypted credit cards" )
2163         if $cust_payby->is_encrypted($cust_payby->payinfo);
2164
2165       my $ban = new FS::banned_pay $cust_payby->_new_banned_pay_hashref;
2166       my $error = $ban->insert;
2167       return ( $error ) if $error;
2168
2169     }
2170
2171   }
2172
2173   my @pkgs = $self->ncancelled_pkgs;
2174
2175   if ( !$opt{nobill} && $conf->exists('bill_usage_on_cancel') ) {
2176     $opt{nobill} = 1;
2177     my $error = $self->bill( pkg_list => [ @pkgs ], cancel => 1 );
2178     warn "Error billing during cancel, custnum ". $self->custnum. ": $error"
2179       if $error;
2180   }
2181
2182   warn "$me cancelling ". scalar($self->ncancelled_pkgs). "/".
2183        scalar(@pkgs). " packages for customer ". $self->custnum. "\n"
2184     if $DEBUG;
2185
2186   grep { $_ } map { $_->cancel(%opt) } $self->ncancelled_pkgs;
2187 }
2188
2189 sub _banned_pay_hashref {
2190   die 'cust_main->_banned_pay_hashref deprecated';
2191
2192   my $self = shift;
2193
2194   my %payby2ban = (
2195     'CARD' => 'CARD',
2196     'DCRD' => 'CARD',
2197     'CHEK' => 'CHEK',
2198     'DCHK' => 'CHEK'
2199   );
2200
2201   {
2202     'payby'   => $payby2ban{$self->payby},
2203     'payinfo' => $self->payinfo,
2204     #don't ever *search* on reason! #'reason'  =>
2205   };
2206 }
2207
2208 =item notes
2209
2210 Returns all notes (see L<FS::cust_main_note>) for this customer.
2211
2212 =cut
2213
2214 sub notes {
2215   my($self,$orderby_classnum) = (shift,shift);
2216   my $orderby = "sticky DESC, _date DESC";
2217   $orderby = "classnum ASC, $orderby" if $orderby_classnum;
2218   qsearch( 'cust_main_note',
2219            { 'custnum' => $self->custnum },
2220            '',
2221            "ORDER BY $orderby",
2222          );
2223 }
2224
2225 =item agent
2226
2227 Returns the agent (see L<FS::agent>) for this customer.
2228
2229 =item agent_name
2230
2231 Returns the agent name (see L<FS::agent>) for this customer.
2232
2233 =cut
2234
2235 sub agent_name {
2236   my $self = shift;
2237   $self->agent->agent;
2238 }
2239
2240 =item cust_tag
2241
2242 Returns any tags associated with this customer, as FS::cust_tag objects,
2243 or an empty list if there are no tags.
2244
2245 =item part_tag
2246
2247 Returns any tags associated with this customer, as FS::part_tag objects,
2248 or an empty list if there are no tags.
2249
2250 =cut
2251
2252 sub part_tag {
2253   my $self = shift;
2254   map $_->part_tag, $self->cust_tag;
2255 }
2256
2257
2258 =item cust_class
2259
2260 Returns the customer class, as an FS::cust_class object, or the empty string
2261 if there is no customer class.
2262
2263 =item categoryname
2264
2265 Returns the customer category name, or the empty string if there is no customer
2266 category.
2267
2268 =cut
2269
2270 sub categoryname {
2271   my $self = shift;
2272   my $cust_class = $self->cust_class;
2273   $cust_class
2274     ? $cust_class->categoryname
2275     : '';
2276 }
2277
2278 =item classname
2279
2280 Returns the customer class name, or the empty string if there is no customer
2281 class.
2282
2283 =cut
2284
2285 sub classname {
2286   my $self = shift;
2287   my $cust_class = $self->cust_class;
2288   $cust_class
2289     ? $cust_class->classname
2290     : '';
2291 }
2292
2293 =item tax_status
2294
2295 Returns the external tax status, as an FS::tax_status object, or the empty
2296 string if there is no tax status.
2297
2298 =cut
2299
2300 sub tax_status {
2301   my $self = shift;
2302   if ( $self->taxstatusnum ) {
2303     qsearchs('tax_status', { 'taxstatusnum' => $self->taxstatusnum } );
2304   } else {
2305     return '';
2306   }
2307 }
2308
2309 =item taxstatus
2310
2311 Returns the tax status code if there is one.
2312
2313 =cut
2314
2315 sub taxstatus {
2316   my $self = shift;
2317   my $tax_status = $self->tax_status;
2318   $tax_status
2319     ? $tax_status->taxstatus
2320     : '';
2321 }
2322
2323 =item BILLING METHODS
2324
2325 Documentation on billing methods has been moved to
2326 L<FS::cust_main::Billing>.
2327
2328 =item REALTIME BILLING METHODS
2329
2330 Documentation on realtime billing methods has been moved to
2331 L<FS::cust_main::Billing_Realtime>.
2332
2333 =item remove_cvv
2334
2335 Removes the I<paycvv> field from the database directly.
2336
2337 If there is an error, returns the error, otherwise returns false.
2338
2339 =cut
2340
2341 sub remove_cvv {
2342   die 'cust_main->remove_cvv deprecated';
2343   my $self = shift;
2344   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2345     or return dbh->errstr;
2346   $sth->execute($self->custnum)
2347     or return $sth->errstr;
2348   $self->paycvv('');
2349   '';
2350 }
2351
2352 =item total_owed
2353
2354 Returns the total owed for this customer on all invoices
2355 (see L<FS::cust_bill/owed>).
2356
2357 =cut
2358
2359 sub total_owed {
2360   my $self = shift;
2361   $self->total_owed_date(2145859200); #12/31/2037
2362 }
2363
2364 =item total_owed_date TIME
2365
2366 Returns the total owed for this customer on all invoices with date earlier than
2367 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2368 see L<Time::Local> and L<Date::Parse> for conversion functions.
2369
2370 =cut
2371
2372 sub total_owed_date {
2373   my $self = shift;
2374   my $time = shift;
2375
2376   my $custnum = $self->custnum;
2377
2378   my $owed_sql = FS::cust_bill->owed_sql;
2379
2380   my $sql = "
2381     SELECT SUM($owed_sql) FROM cust_bill
2382       WHERE custnum = $custnum
2383         AND _date <= $time
2384   ";
2385
2386   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2387
2388 }
2389
2390 =item total_owed_pkgnum PKGNUM
2391
2392 Returns the total owed on all invoices for this customer's specific package
2393 when using experimental package balances (see L<FS::cust_bill/owed_pkgnum>).
2394
2395 =cut
2396
2397 sub total_owed_pkgnum {
2398   my( $self, $pkgnum ) = @_;
2399   $self->total_owed_date_pkgnum(2145859200, $pkgnum); #12/31/2037
2400 }
2401
2402 =item total_owed_date_pkgnum TIME PKGNUM
2403
2404 Returns the total owed for this customer's specific package when using
2405 experimental package balances on all invoices with date earlier than
2406 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2407 see L<Time::Local> and L<Date::Parse> for conversion functions.
2408
2409 =cut
2410
2411 sub total_owed_date_pkgnum {
2412   my( $self, $time, $pkgnum ) = @_;
2413
2414   my $total_bill = 0;
2415   foreach my $cust_bill (
2416     grep { $_->_date <= $time }
2417       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2418   ) {
2419     $total_bill += $cust_bill->owed_pkgnum($pkgnum);
2420   }
2421   sprintf( "%.2f", $total_bill );
2422
2423 }
2424
2425 =item total_paid
2426
2427 Returns the total amount of all payments.
2428
2429 =cut
2430
2431 sub total_paid {
2432   my $self = shift;
2433   my $total = 0;
2434   $total += $_->paid foreach $self->cust_pay;
2435   sprintf( "%.2f", $total );
2436 }
2437
2438 =item total_unapplied_credits
2439
2440 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2441 customer.  See L<FS::cust_credit/credited>.
2442
2443 =item total_credited
2444
2445 Old name for total_unapplied_credits.  Don't use.
2446
2447 =cut
2448
2449 sub total_credited {
2450   #carp "total_credited deprecated, use total_unapplied_credits";
2451   shift->total_unapplied_credits(@_);
2452 }
2453
2454 sub total_unapplied_credits {
2455   my $self = shift;
2456
2457   my $custnum = $self->custnum;
2458
2459   my $unapplied_sql = FS::cust_credit->unapplied_sql;
2460
2461   my $sql = "
2462     SELECT SUM($unapplied_sql) FROM cust_credit
2463       WHERE custnum = $custnum
2464   ";
2465
2466   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2467
2468 }
2469
2470 =item total_unapplied_credits_pkgnum PKGNUM
2471
2472 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2473 customer.  See L<FS::cust_credit/credited>.
2474
2475 =cut
2476
2477 sub total_unapplied_credits_pkgnum {
2478   my( $self, $pkgnum ) = @_;
2479   my $total_credit = 0;
2480   $total_credit += $_->credited foreach $self->cust_credit_pkgnum($pkgnum);
2481   sprintf( "%.2f", $total_credit );
2482 }
2483
2484
2485 =item total_unapplied_payments
2486
2487 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2488 See L<FS::cust_pay/unapplied>.
2489
2490 =cut
2491
2492 sub total_unapplied_payments {
2493   my $self = shift;
2494
2495   my $custnum = $self->custnum;
2496
2497   my $unapplied_sql = FS::cust_pay->unapplied_sql;
2498
2499   my $sql = "
2500     SELECT SUM($unapplied_sql) FROM cust_pay
2501       WHERE custnum = $custnum
2502   ";
2503
2504   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2505
2506 }
2507
2508 =item total_unapplied_payments_pkgnum PKGNUM
2509
2510 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer's
2511 specific package when using experimental package balances.  See
2512 L<FS::cust_pay/unapplied>.
2513
2514 =cut
2515
2516 sub total_unapplied_payments_pkgnum {
2517   my( $self, $pkgnum ) = @_;
2518   my $total_unapplied = 0;
2519   $total_unapplied += $_->unapplied foreach $self->cust_pay_pkgnum($pkgnum);
2520   sprintf( "%.2f", $total_unapplied );
2521 }
2522
2523
2524 =item total_unapplied_refunds
2525
2526 Returns the total unrefunded refunds (see L<FS::cust_refund>) for this
2527 customer.  See L<FS::cust_refund/unapplied>.
2528
2529 =cut
2530
2531 sub total_unapplied_refunds {
2532   my $self = shift;
2533   my $custnum = $self->custnum;
2534
2535   my $unapplied_sql = FS::cust_refund->unapplied_sql;
2536
2537   my $sql = "
2538     SELECT SUM($unapplied_sql) FROM cust_refund
2539       WHERE custnum = $custnum
2540   ";
2541
2542   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2543
2544 }
2545
2546 =item balance
2547
2548 Returns the balance for this customer (total_owed plus total_unrefunded, minus
2549 total_unapplied_credits minus total_unapplied_payments).
2550
2551 =cut
2552
2553 sub balance {
2554   my $self = shift;
2555   $self->balance_date_range;
2556 }
2557
2558 =item balance_date TIME
2559
2560 Returns the balance for this customer, only considering invoices with date
2561 earlier than TIME (total_owed_date minus total_credited minus
2562 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2563 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2564 functions.
2565
2566 =cut
2567
2568 sub balance_date {
2569   my $self = shift;
2570   $self->balance_date_range(shift);
2571 }
2572
2573 =item balance_date_range [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
2574
2575 Returns the balance for this customer, optionally considering invoices with
2576 date earlier than START_TIME, and not later than END_TIME
2577 (total_owed_date minus total_unapplied_credits minus total_unapplied_payments).
2578
2579 Times are specified as SQL fragments or numeric
2580 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
2581 L<Date::Parse> for conversion functions.  The empty string can be passed
2582 to disable that time constraint completely.
2583
2584 Accepts the same options as L<balance_date_sql>:
2585
2586 =over 4
2587
2588 =item unapplied_date
2589
2590 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
2591
2592 =item cutoff
2593
2594 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
2595 time will be ignored.  Note that START_TIME and END_TIME only limit the date
2596 range for invoices and I<unapplied> payments, credits, and refunds.
2597
2598 =back
2599
2600 =cut
2601
2602 sub balance_date_range {
2603   my $self = shift;
2604   my $sql = 'SELECT SUM('. $self->balance_date_sql(@_).
2605             ') FROM cust_main WHERE custnum='. $self->custnum;
2606   sprintf( '%.2f', $self->scalar_sql($sql) || 0 );
2607 }
2608
2609 =item balance_pkgnum PKGNUM
2610
2611 Returns the balance for this customer's specific package when using
2612 experimental package balances (total_owed plus total_unrefunded, minus
2613 total_unapplied_credits minus total_unapplied_payments)
2614
2615 =cut
2616
2617 sub balance_pkgnum {
2618   my( $self, $pkgnum ) = @_;
2619
2620   sprintf( "%.2f",
2621       $self->total_owed_pkgnum($pkgnum)
2622 # n/a - refunds aren't part of pkg-balances since they don't apply to invoices
2623 #    + $self->total_unapplied_refunds_pkgnum($pkgnum)
2624     - $self->total_unapplied_credits_pkgnum($pkgnum)
2625     - $self->total_unapplied_payments_pkgnum($pkgnum)
2626   );
2627 }
2628
2629 =item payment_info
2630
2631 Returns a hash of useful information for making a payment.
2632
2633 =over 4
2634
2635 =item balance
2636
2637 Current balance.
2638
2639 =item payby
2640
2641 'CARD' (credit card - automatic), 'DCRD' (credit card - on-demand),
2642 'CHEK' (electronic check - automatic), 'DCHK' (electronic check - on-demand),
2643 'LECB' (Phone bill billing), 'BILL' (billing), or 'COMP' (free).
2644
2645 =back
2646
2647 For credit card transactions:
2648
2649 =over 4
2650
2651 =item card_type 1
2652
2653 =item payname
2654
2655 Exact name on card
2656
2657 =back
2658
2659 For electronic check transactions:
2660
2661 =over 4
2662
2663 =item stateid_state
2664
2665 =back
2666
2667 =cut
2668
2669 #XXX i need to be updated for 4.x+
2670 sub payment_info {
2671   my $self = shift;
2672
2673   my %return = ();
2674
2675   $return{balance} = $self->balance;
2676
2677   $return{payname} = $self->payname
2678                      || ( $self->first. ' '. $self->get('last') );
2679
2680   $return{$_} = $self->bill_location->$_
2681     for qw(address1 address2 city state zip);
2682
2683   $return{payby} = $self->payby;
2684   $return{stateid_state} = $self->stateid_state;
2685
2686   if ( $self->payby =~ /^(CARD|DCRD)$/ ) {
2687     $return{card_type} = cardtype($self->payinfo);
2688     $return{payinfo} = $self->paymask;
2689
2690     @return{'month', 'year'} = $self->paydate_monthyear;
2691
2692   }
2693
2694   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2695     my ($payinfo1, $payinfo2) = split '@', $self->paymask;
2696     $return{payinfo1} = $payinfo1;
2697     $return{payinfo2} = $payinfo2;
2698     $return{paytype}  = $self->paytype;
2699     $return{paystate} = $self->paystate;
2700
2701   }
2702
2703   #doubleclick protection
2704   my $_date = time;
2705   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
2706
2707   %return;
2708
2709 }
2710
2711 =item paydate_epoch
2712
2713 Returns the next payment expiration date for this customer. If they have no
2714 payment methods that will expire, returns 0.
2715
2716 =cut
2717
2718 sub paydate_epoch {
2719   my $self = shift;
2720   # filter out the ones that individually return 0, but then return 0 if
2721   # there are no results
2722   my @epochs = grep { $_ > 0 } map { $_->paydate_epoch } $self->cust_payby;
2723   min( @epochs ) || 0;
2724 }
2725
2726 =item paydate_epoch_sql
2727
2728 Returns an SQL expression to get the next payment expiration date for a
2729 customer. Returns 2143260000 (2037-12-01) if there are no payment expiration
2730 dates, so that it's safe to test for "will it expire before date X" for any
2731 date up to then.
2732
2733 =cut
2734
2735 sub paydate_epoch_sql {
2736   my $class = shift;
2737   my $paydate = FS::cust_payby->paydate_epoch_sql;
2738   "(SELECT COALESCE(MIN($paydate), 2143260000) FROM cust_payby WHERE cust_payby.custnum = cust_main.custnum)";
2739 }
2740
2741 sub tax_exemption {
2742   my( $self, $taxname ) = @_;
2743
2744   qsearchs( 'cust_main_exemption', { 'custnum' => $self->custnum,
2745                                      'taxname' => $taxname,
2746                                    },
2747           );
2748 }
2749
2750 =item cust_main_exemption
2751
2752 =item invoicing_list
2753
2754 Returns a list of email addresses (with svcnum entries expanded), and the word
2755 'POST' if the customer receives postal invoices.
2756
2757 =cut
2758
2759 sub invoicing_list {
2760   my( $self, $arrayref ) = @_;
2761
2762   if ( $arrayref ) {
2763     warn "FS::cust_main::invoicing_list(ARRAY) is no longer supported.";
2764   }
2765
2766   my @emails = $self->invoicing_list_emailonly;
2767   push @emails, 'POST' if $self->get('postal_invoice');
2768
2769   @emails;
2770 }
2771
2772 =item check_invoicing_list ARRAYREF
2773
2774 Checks these arguements as valid input for the invoicing_list method.  If there
2775 is an error, returns the error, otherwise returns false.
2776
2777 =cut
2778
2779 sub check_invoicing_list {
2780   my( $self, $arrayref ) = @_;
2781
2782   foreach my $address ( @$arrayref ) {
2783
2784     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
2785       return 'Can\'t add FAX invoice destination with a blank FAX number.';
2786     }
2787
2788     my $cust_main_invoice = new FS::cust_main_invoice ( {
2789       'custnum' => $self->custnum,
2790       'dest'    => $address,
2791     } );
2792     my $error = $self->custnum
2793                 ? $cust_main_invoice->check
2794                 : $cust_main_invoice->checkdest
2795     ;
2796     return $error if $error;
2797
2798   }
2799
2800   return "Email address required"
2801     if $conf->exists('cust_main-require_invoicing_list_email', $self->agentnum)
2802     && ! grep { $_ !~ /^([A-Z]+)$/ } @$arrayref;
2803
2804   '';
2805 }
2806
2807 =item all_emails
2808
2809 Returns the email addresses of all accounts provisioned for this customer.
2810
2811 =cut
2812
2813 sub all_emails {
2814   my $self = shift;
2815   my %list;
2816   foreach my $cust_pkg ( $self->all_pkgs ) {
2817     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
2818     my @svc_acct =
2819       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
2820         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
2821           @cust_svc;
2822     $list{$_}=1 foreach map { $_->email } @svc_acct;
2823   }
2824   keys %list;
2825 }
2826
2827 =item invoicing_list_addpost
2828
2829 Adds postal invoicing to this customer.  If this customer is already configured
2830 to receive postal invoices, does nothing.
2831
2832 =cut
2833
2834 sub invoicing_list_addpost {
2835   my $self = shift;
2836   if ( $self->get('postal_invoice') eq '' ) {
2837     $self->set('postal_invoice', 'Y');
2838     my $error = $self->replace;
2839     warn $error if $error; # should fail harder, but this is traditional
2840   }
2841 }
2842
2843 =item invoicing_list_emailonly
2844
2845 Returns the list of email invoice recipients (invoicing_list without non-email
2846 destinations such as POST and FAX).
2847
2848 =cut
2849
2850 sub invoicing_list_emailonly {
2851   my $self = shift;
2852   warn "$me invoicing_list_emailonly called"
2853     if $DEBUG;
2854   return () if !$self->custnum; # not yet inserted
2855   return map { $_->emailaddress }
2856     qsearch({
2857         table     => 'cust_contact',
2858         select    => 'emailaddress',
2859         addl_from => ' JOIN contact USING (contactnum) '.
2860                      ' JOIN contact_email USING (contactnum)',
2861         hashref   => { 'custnum' => $self->custnum, },
2862         extra_sql => q( AND cust_contact.invoice_dest = 'Y'),
2863     });
2864 }
2865
2866 =item invoicing_list_emailonly_scalar
2867
2868 Returns the list of email invoice recipients (invoicing_list without non-email
2869 destinations such as POST and FAX) as a comma-separated scalar.
2870
2871 =cut
2872
2873 sub invoicing_list_emailonly_scalar {
2874   my $self = shift;
2875   warn "$me invoicing_list_emailonly_scalar called"
2876     if $DEBUG;
2877   join(', ', $self->invoicing_list_emailonly);
2878 }
2879
2880 =item contact_list [ CLASSNUM, ... ]
2881
2882 Returns a list of contacts (L<FS::contact> objects) for the customer. If
2883 a list of contact classnums is given, returns only contacts in those
2884 classes. If the pseudo-classnum 'invoice' is given, returns contacts that
2885 are marked as invoice destinations. If '0' is given, also returns contacts
2886 with no class.
2887
2888 If no arguments are given, returns all contacts for the customer.
2889
2890 =cut
2891
2892 sub contact_list {
2893   my $self = shift;
2894   my $search = {
2895     table       => 'contact',
2896     select      => 'contact.*, cust_contact.invoice_dest',
2897     addl_from   => ' JOIN cust_contact USING (contactnum)',
2898     extra_sql   => ' WHERE cust_contact.custnum = '.$self->custnum,
2899   };
2900
2901   my @orwhere;
2902   my @classnums;
2903   foreach (@_) {
2904     if ( $_ eq 'invoice' ) {
2905       push @orwhere, 'cust_contact.invoice_dest = \'Y\'';
2906     } elsif ( $_ eq '0' ) {
2907       push @orwhere, 'cust_contact.classnum is null';
2908     } elsif ( /^\d+$/ ) {
2909       push @classnums, $_;
2910     } else {
2911       die "bad classnum argument '$_'";
2912     }
2913   }
2914
2915   if (@classnums) {
2916     push @orwhere, 'cust_contact.classnum IN ('.join(',', @classnums).')';
2917   }
2918   if (@orwhere) {
2919     $search->{extra_sql} .= ' AND (' .
2920                             join(' OR ', map "( $_ )", @orwhere) .
2921                             ')';
2922   }
2923
2924   qsearch($search);
2925 }
2926
2927 =item contact_list_email [ CLASSNUM, ... ]
2928
2929 Same as L</contact_list>, but returns email destinations instead of contact
2930 objects.
2931
2932 =cut
2933
2934 sub contact_list_email {
2935   my $self = shift;
2936   my @contacts = $self->contact_list(@_);
2937   my @emails;
2938   foreach my $contact (@contacts) {
2939     foreach my $contact_email ($contact->contact_email) {
2940       push @emails,
2941         $contact->firstlast . ' <' . $contact_email->emailaddress . '>';
2942     }
2943   }
2944   @emails;
2945 }
2946
2947 =item referral_custnum_cust_main
2948
2949 Returns the customer who referred this customer (or the empty string, if
2950 this customer was not referred).
2951
2952 Note the difference with referral_cust_main method: This method,
2953 referral_custnum_cust_main returns the single customer (if any) who referred
2954 this customer, while referral_cust_main returns an array of customers referred
2955 BY this customer.
2956
2957 =cut
2958
2959 sub referral_custnum_cust_main {
2960   my $self = shift;
2961   return '' unless $self->referral_custnum;
2962   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
2963 }
2964
2965 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
2966
2967 Returns an array of customers referred by this customer (referral_custnum set
2968 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
2969 customers referred by customers referred by this customer and so on, inclusive.
2970 The default behavior is DEPTH 1 (no recursion).
2971
2972 Note the difference with referral_custnum_cust_main method: This method,
2973 referral_cust_main, returns an array of customers referred BY this customer,
2974 while referral_custnum_cust_main returns the single customer (if any) who
2975 referred this customer.
2976
2977 =cut
2978
2979 sub referral_cust_main {
2980   my $self = shift;
2981   my $depth = @_ ? shift : 1;
2982   my $exclude = @_ ? shift : {};
2983
2984   my @cust_main =
2985     map { $exclude->{$_->custnum}++; $_; }
2986       grep { ! $exclude->{ $_->custnum } }
2987         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
2988
2989   if ( $depth > 1 ) {
2990     push @cust_main,
2991       map { $_->referral_cust_main($depth-1, $exclude) }
2992         @cust_main;
2993   }
2994
2995   @cust_main;
2996 }
2997
2998 =item referral_cust_main_ncancelled
2999
3000 Same as referral_cust_main, except only returns customers with uncancelled
3001 packages.
3002
3003 =cut
3004
3005 sub referral_cust_main_ncancelled {
3006   my $self = shift;
3007   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
3008 }
3009
3010 =item referral_cust_pkg [ DEPTH ]
3011
3012 Like referral_cust_main, except returns a flat list of all unsuspended (and
3013 uncancelled) packages for each customer.  The number of items in this list may
3014 be useful for commission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
3015
3016 =cut
3017
3018 sub referral_cust_pkg {
3019   my $self = shift;
3020   my $depth = @_ ? shift : 1;
3021
3022   map { $_->unsuspended_pkgs }
3023     grep { $_->unsuspended_pkgs }
3024       $self->referral_cust_main($depth);
3025 }
3026
3027 =item referring_cust_main
3028
3029 Returns the single cust_main record for the customer who referred this customer
3030 (referral_custnum), or false.
3031
3032 =cut
3033
3034 sub referring_cust_main {
3035   my $self = shift;
3036   return '' unless $self->referral_custnum;
3037   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3038 }
3039
3040 =item credit AMOUNT, REASON [ , OPTION => VALUE ... ]
3041
3042 Applies a credit to this customer.  If there is an error, returns the error,
3043 otherwise returns false.
3044
3045 REASON can be a text string, an FS::reason object, or a scalar reference to
3046 a reasonnum.  If a text string, it will be automatically inserted as a new
3047 reason, and a 'reason_type' option must be passed to indicate the
3048 FS::reason_type for the new reason.
3049
3050 An I<addlinfo> option may be passed to set the credit's I<addlinfo> field.
3051 Likewise for I<eventnum>, I<commission_agentnum>, I<commission_salesnum> and
3052 I<commission_pkgnum>.
3053
3054 Any other options are passed to FS::cust_credit::insert.
3055
3056 =cut
3057
3058 sub credit {
3059   my( $self, $amount, $reason, %options ) = @_;
3060
3061   my $cust_credit = new FS::cust_credit {
3062     'custnum' => $self->custnum,
3063     'amount'  => $amount,
3064   };
3065
3066   if ( ref($reason) ) {
3067
3068     if ( ref($reason) eq 'SCALAR' ) {
3069       $cust_credit->reasonnum( $$reason );
3070     } else {
3071       $cust_credit->reasonnum( $reason->reasonnum );
3072     }
3073
3074   } else {
3075     $cust_credit->set('reason', $reason)
3076   }
3077
3078   $cust_credit->$_( delete $options{$_} )
3079     foreach grep exists($options{$_}),
3080               qw( addlinfo eventnum ),
3081               map "commission_$_", qw( agentnum salesnum pkgnum );
3082
3083   $cust_credit->insert(%options);
3084
3085 }
3086
3087 =item charge HASHREF || AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3088
3089 Creates a one-time charge for this customer.  If there is an error, returns
3090 the error, otherwise returns false.
3091
3092 New-style, with a hashref of options:
3093
3094   my $error = $cust_main->charge(
3095                                   {
3096                                     'amount'     => 54.32,
3097                                     'quantity'   => 1,
3098                                     'start_date' => str2time('7/4/2009'),
3099                                     'pkg'        => 'Description',
3100                                     'comment'    => 'Comment',
3101                                     'additional' => [], #extra invoice detail
3102                                     'classnum'   => 1,  #pkg_class
3103
3104                                     'setuptax'   => '', # or 'Y' for tax exempt
3105
3106                                     'locationnum'=> 1234, # optional
3107
3108                                     #internal taxation
3109                                     'taxclass'   => 'Tax class',
3110
3111                                     #vendor taxation
3112                                     'taxproduct' => 2,  #part_pkg_taxproduct
3113                                     'override'   => {}, #XXX describe
3114
3115                                     #will be filled in with the new object
3116                                     'cust_pkg_ref' => \$cust_pkg,
3117
3118                                     #generate an invoice immediately
3119                                     'bill_now' => 0,
3120                                     'invoice_terms' => '', #with these terms
3121                                   }
3122                                 );
3123
3124 Old-style:
3125
3126   my $error = $cust_main->charge( 54.32, 'Description', 'Comment', 'Tax class' );
3127
3128 =cut
3129
3130 #super false laziness w/quotation::charge
3131 sub charge {
3132   my $self = shift;
3133   my ( $amount, $setup_cost, $quantity, $start_date, $classnum );
3134   my ( $pkg, $comment, $additional );
3135   my ( $setuptax, $taxclass );   #internal taxes
3136   my ( $taxproduct, $override ); #vendor (CCH) taxes
3137   my $no_auto = '';
3138   my $separate_bill = '';
3139   my $cust_pkg_ref = '';
3140   my ( $bill_now, $invoice_terms ) = ( 0, '' );
3141   my $locationnum;
3142   if ( ref( $_[0] ) ) {
3143     $amount     = $_[0]->{amount};
3144     $setup_cost = $_[0]->{setup_cost};
3145     $quantity   = exists($_[0]->{quantity}) ? $_[0]->{quantity} : 1;
3146     $start_date = exists($_[0]->{start_date}) ? $_[0]->{start_date} : '';
3147     $no_auto    = exists($_[0]->{no_auto}) ? $_[0]->{no_auto} : '';
3148     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3149     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3150                                            : '$'. sprintf("%.2f",$amount);
3151     $setuptax   = exists($_[0]->{setuptax}) ? $_[0]->{setuptax} : '';
3152     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3153     $classnum   = exists($_[0]->{classnum}) ? $_[0]->{classnum} : '';
3154     $additional = $_[0]->{additional} || [];
3155     $taxproduct = $_[0]->{taxproductnum};
3156     $override   = { '' => $_[0]->{tax_override} };
3157     $cust_pkg_ref = exists($_[0]->{cust_pkg_ref}) ? $_[0]->{cust_pkg_ref} : '';
3158     $bill_now = exists($_[0]->{bill_now}) ? $_[0]->{bill_now} : '';
3159     $invoice_terms = exists($_[0]->{invoice_terms}) ? $_[0]->{invoice_terms} : '';
3160     $locationnum = $_[0]->{locationnum} || $self->ship_locationnum;
3161     $separate_bill = $_[0]->{separate_bill} || '';
3162   } else { # yuck
3163     $amount     = shift;
3164     $setup_cost = '';
3165     $quantity   = 1;
3166     $start_date = '';
3167     $pkg        = @_ ? shift : 'One-time charge';
3168     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3169     $setuptax   = '';
3170     $taxclass   = @_ ? shift : '';
3171     $additional = [];
3172   }
3173
3174   local $SIG{HUP} = 'IGNORE';
3175   local $SIG{INT} = 'IGNORE';
3176   local $SIG{QUIT} = 'IGNORE';
3177   local $SIG{TERM} = 'IGNORE';
3178   local $SIG{TSTP} = 'IGNORE';
3179   local $SIG{PIPE} = 'IGNORE';
3180
3181   my $oldAutoCommit = $FS::UID::AutoCommit;
3182   local $FS::UID::AutoCommit = 0;
3183   my $dbh = dbh;
3184
3185   my $part_pkg = new FS::part_pkg ( {
3186     'pkg'           => $pkg,
3187     'comment'       => $comment,
3188     'plan'          => 'flat',
3189     'freq'          => 0,
3190     'disabled'      => 'Y',
3191     'classnum'      => ( $classnum ? $classnum : '' ),
3192     'setuptax'      => $setuptax,
3193     'taxclass'      => $taxclass,
3194     'taxproductnum' => $taxproduct,
3195     'setup_cost'    => $setup_cost,
3196   } );
3197
3198   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3199                         ( 0 .. @$additional - 1 )
3200                   ),
3201                   'additional_count' => scalar(@$additional),
3202                   'setup_fee' => $amount,
3203                 );
3204
3205   my $error = $part_pkg->insert( options       => \%options,
3206                                  tax_overrides => $override,
3207                                );
3208   if ( $error ) {
3209     $dbh->rollback if $oldAutoCommit;
3210     return $error;
3211   }
3212
3213   my $pkgpart = $part_pkg->pkgpart;
3214   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3215   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3216     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3217     $error = $type_pkgs->insert;
3218     if ( $error ) {
3219       $dbh->rollback if $oldAutoCommit;
3220       return $error;
3221     }
3222   }
3223
3224   my $cust_pkg = new FS::cust_pkg ( {
3225     'custnum'    => $self->custnum,
3226     'pkgpart'    => $pkgpart,
3227     'quantity'   => $quantity,
3228     'start_date' => $start_date,
3229     'no_auto'    => $no_auto,
3230     'separate_bill' => $separate_bill,
3231     'locationnum'=> $locationnum,
3232   } );
3233
3234   $error = $cust_pkg->insert;
3235   if ( $error ) {
3236     $dbh->rollback if $oldAutoCommit;
3237     return $error;
3238   } elsif ( $cust_pkg_ref ) {
3239     ${$cust_pkg_ref} = $cust_pkg;
3240   }
3241
3242   if ( $bill_now ) {
3243     my $error = $self->bill( 'invoice_terms' => $invoice_terms,
3244                              'pkg_list'      => [ $cust_pkg ],
3245                            );
3246     if ( $error ) {
3247       $dbh->rollback if $oldAutoCommit;
3248       return $error;
3249     }
3250   }
3251
3252   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3253   return '';
3254
3255 }
3256
3257 #=item charge_postal_fee
3258 #
3259 #Applies a one time charge this customer.  If there is an error,
3260 #returns the error, returns the cust_pkg charge object or false
3261 #if there was no charge.
3262 #
3263 #=cut
3264 #
3265 # This should be a customer event.  For that to work requires that bill
3266 # also be a customer event.
3267
3268 sub charge_postal_fee {
3269   my $self = shift;
3270
3271   my $pkgpart = $conf->config('postal_invoice-fee_pkgpart', $self->agentnum);
3272   return '' unless ($pkgpart && grep { $_ eq 'POST' } $self->invoicing_list);
3273
3274   my $cust_pkg = new FS::cust_pkg ( {
3275     'custnum'  => $self->custnum,
3276     'pkgpart'  => $pkgpart,
3277     'quantity' => 1,
3278   } );
3279
3280   my $error = $cust_pkg->insert;
3281   $error ? $error : $cust_pkg;
3282 }
3283
3284 =item cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3285
3286 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3287
3288 Optionally, a list or hashref of additional arguments to the qsearch call can
3289 be passed.
3290
3291 =cut
3292
3293 sub cust_bill {
3294   my $self = shift;
3295   my $opt = ref($_[0]) ? shift : { @_ };
3296
3297   #return $self->num_cust_bill unless wantarray || keys %$opt;
3298
3299   $opt->{'table'} = 'cust_bill';
3300   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3301   $opt->{'hashref'}{'custnum'} = $self->custnum;
3302   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3303
3304   map { $_ } #behavior of sort undefined in scalar context
3305     sort { $a->_date <=> $b->_date }
3306       qsearch($opt);
3307 }
3308
3309 =item open_cust_bill
3310
3311 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3312 customer.
3313
3314 =cut
3315
3316 sub open_cust_bill {
3317   my $self = shift;
3318
3319   $self->cust_bill(
3320     'extra_sql' => ' AND '. FS::cust_bill->owed_sql. ' > 0',
3321     #@_
3322   );
3323
3324 }
3325
3326 =item legacy_cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3327
3328 Returns all the legacy invoices (see L<FS::legacy_cust_bill>) for this customer.
3329
3330 =cut
3331
3332 sub legacy_cust_bill {
3333   my $self = shift;
3334
3335   #return $self->num_legacy_cust_bill unless wantarray;
3336
3337   map { $_ } #behavior of sort undefined in scalar context
3338     sort { $a->_date <=> $b->_date }
3339       qsearch({ 'table'    => 'legacy_cust_bill',
3340                 'hashref'  => { 'custnum' => $self->custnum, },
3341                 'order_by' => 'ORDER BY _date ASC',
3342              });
3343 }
3344
3345 =item cust_statement [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3346
3347 Returns all the statements (see L<FS::cust_statement>) for this customer.
3348
3349 Optionally, a list or hashref of additional arguments to the qsearch call can
3350 be passed.
3351
3352 =cut
3353
3354 =item cust_bill_void
3355
3356 Returns all the voided invoices (see L<FS::cust_bill_void>) for this customer.
3357
3358 =cut
3359
3360 sub cust_bill_void {
3361   my $self = shift;
3362
3363   map { $_ } #return $self->num_cust_bill_void unless wantarray;
3364   sort { $a->_date <=> $b->_date }
3365     qsearch( 'cust_bill_void', { 'custnum' => $self->custnum } )
3366 }
3367
3368 sub cust_statement {
3369   my $self = shift;
3370   my $opt = ref($_[0]) ? shift : { @_ };
3371
3372   #return $self->num_cust_statement unless wantarray || keys %$opt;
3373
3374   $opt->{'table'} = 'cust_statement';
3375   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3376   $opt->{'hashref'}{'custnum'} = $self->custnum;
3377   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3378
3379   map { $_ } #behavior of sort undefined in scalar context
3380     sort { $a->_date <=> $b->_date }
3381       qsearch($opt);
3382 }
3383
3384 =item svc_x SVCDB [ OPTION => VALUE | EXTRA_QSEARCH_PARAMS_HASHREF ]
3385
3386 Returns all services of type SVCDB (such as 'svc_acct') for this customer.
3387
3388 Optionally, a list or hashref of additional arguments to the qsearch call can
3389 be passed following the SVCDB.
3390
3391 =cut
3392
3393 sub svc_x {
3394   my $self = shift;
3395   my $svcdb = shift;
3396   if ( ! $svcdb =~ /^svc_\w+$/ ) {
3397     warn "$me svc_x requires a svcdb";
3398     return;
3399   }
3400   my $opt = ref($_[0]) ? shift : { @_ };
3401
3402   $opt->{'table'} = $svcdb;
3403   $opt->{'addl_from'} =
3404     'LEFT JOIN cust_svc USING (svcnum) LEFT JOIN cust_pkg USING (pkgnum) '.
3405     ($opt->{'addl_from'} || '');
3406
3407   my $custnum = $self->custnum;
3408   $custnum =~ /^\d+$/ or die "bad custnum '$custnum'";
3409   my $where = "cust_pkg.custnum = $custnum";
3410
3411   my $extra_sql = $opt->{'extra_sql'} || '';
3412   if ( keys %{ $opt->{'hashref'} } ) {
3413     $extra_sql = " AND $where $extra_sql";
3414   }
3415   else {
3416     if ( $opt->{'extra_sql'} =~ /^\s*where\s(.*)/si ) {
3417       $extra_sql = "WHERE $where AND $1";
3418     }
3419     else {
3420       $extra_sql = "WHERE $where $extra_sql";
3421     }
3422   }
3423   $opt->{'extra_sql'} = $extra_sql;
3424
3425   qsearch($opt);
3426 }
3427
3428 # required for use as an eventtable;
3429 sub svc_acct {
3430   my $self = shift;
3431   $self->svc_x('svc_acct', @_);
3432 }
3433
3434 =item cust_credit
3435
3436 Returns all the credits (see L<FS::cust_credit>) for this customer.
3437
3438 =cut
3439
3440 sub cust_credit {
3441   my $self = shift;
3442
3443   #return $self->num_cust_credit unless wantarray;
3444
3445   map { $_ } #behavior of sort undefined in scalar context
3446     sort { $a->_date <=> $b->_date }
3447       qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3448 }
3449
3450 =item cust_credit_pkgnum
3451
3452 Returns all the credits (see L<FS::cust_credit>) for this customer's specific
3453 package when using experimental package balances.
3454
3455 =cut
3456
3457 sub cust_credit_pkgnum {
3458   my( $self, $pkgnum ) = @_;
3459   map { $_ } #return $self->num_cust_credit_pkgnum($pkgnum) unless wantarray;
3460   sort { $a->_date <=> $b->_date }
3461     qsearch( 'cust_credit', { 'custnum' => $self->custnum,
3462                               'pkgnum'  => $pkgnum,
3463                             }
3464     );
3465 }
3466
3467 =item cust_credit_void
3468
3469 Returns all voided credits (see L<FS::cust_credit_void>) for this customer.
3470
3471 =cut
3472
3473 sub cust_credit_void {
3474   my $self = shift;
3475   map { $_ }
3476   sort { $a->_date <=> $b->_date }
3477     qsearch( 'cust_credit_void', { 'custnum' => $self->custnum } )
3478 }
3479
3480 =item cust_pay
3481
3482 Returns all the payments (see L<FS::cust_pay>) for this customer.
3483
3484 =cut
3485
3486 sub cust_pay {
3487   my $self = shift;
3488   my $opt = ref($_[0]) ? shift : { @_ };
3489
3490   return $self->num_cust_pay unless wantarray || keys %$opt;
3491
3492   $opt->{'table'} = 'cust_pay';
3493   $opt->{'hashref'}{'custnum'} = $self->custnum;
3494
3495   map { $_ } #behavior of sort undefined in scalar context
3496     sort { $a->_date <=> $b->_date }
3497       qsearch($opt);
3498
3499 }
3500
3501 =item num_cust_pay
3502
3503 Returns the number of payments (see L<FS::cust_pay>) for this customer.  Also
3504 called automatically when the cust_pay method is used in a scalar context.
3505
3506 =cut
3507
3508 sub num_cust_pay {
3509   my $self = shift;
3510   my $sql = "SELECT COUNT(*) FROM cust_pay WHERE custnum = ?";
3511   my $sth = dbh->prepare($sql) or die dbh->errstr;
3512   $sth->execute($self->custnum) or die $sth->errstr;
3513   $sth->fetchrow_arrayref->[0];
3514 }
3515
3516 =item unapplied_cust_pay
3517
3518 Returns all the unapplied payments (see L<FS::cust_pay>) for this customer.
3519
3520 =cut
3521
3522 sub unapplied_cust_pay {
3523   my $self = shift;
3524
3525   $self->cust_pay(
3526     'extra_sql' => ' AND '. FS::cust_pay->unapplied_sql. ' > 0',
3527     #@_
3528   );
3529
3530 }
3531
3532 =item cust_pay_pkgnum
3533
3534 Returns all the payments (see L<FS::cust_pay>) for this customer's specific
3535 package when using experimental package balances.
3536
3537 =cut
3538
3539 sub cust_pay_pkgnum {
3540   my( $self, $pkgnum ) = @_;
3541   map { $_ } #return $self->num_cust_pay_pkgnum($pkgnum) unless wantarray;
3542   sort { $a->_date <=> $b->_date }
3543     qsearch( 'cust_pay', { 'custnum' => $self->custnum,
3544                            'pkgnum'  => $pkgnum,
3545                          }
3546     );
3547 }
3548
3549 =item cust_pay_void
3550
3551 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3552
3553 =cut
3554
3555 sub cust_pay_void {
3556   my $self = shift;
3557   map { $_ } #return $self->num_cust_pay_void unless wantarray;
3558   sort { $a->_date <=> $b->_date }
3559     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3560 }
3561
3562 =item cust_pay_pending
3563
3564 Returns all pending payments (see L<FS::cust_pay_pending>) for this customer
3565 (without status "done").
3566
3567 =cut
3568
3569 sub cust_pay_pending {
3570   my $self = shift;
3571   return $self->num_cust_pay_pending unless wantarray;
3572   sort { $a->_date <=> $b->_date }
3573     qsearch( 'cust_pay_pending', {
3574                                    'custnum' => $self->custnum,
3575                                    'status'  => { op=>'!=', value=>'done' },
3576                                  },
3577            );
3578 }
3579
3580 =item cust_pay_pending_attempt
3581
3582 Returns all payment attempts / declined payments for this customer, as pending
3583 payments objects (see L<FS::cust_pay_pending>), with status "done" but without
3584 a corresponding payment (see L<FS::cust_pay>).
3585
3586 =cut
3587
3588 sub cust_pay_pending_attempt {
3589   my $self = shift;
3590   return $self->num_cust_pay_pending_attempt unless wantarray;
3591   sort { $a->_date <=> $b->_date }
3592     qsearch( 'cust_pay_pending', {
3593                                    'custnum' => $self->custnum,
3594                                    'status'  => 'done',
3595                                    'paynum'  => '',
3596                                  },
3597            );
3598 }
3599
3600 =item num_cust_pay_pending
3601
3602 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3603 customer (without status "done").  Also called automatically when the
3604 cust_pay_pending method is used in a scalar context.
3605
3606 =cut
3607
3608 sub num_cust_pay_pending {
3609   my $self = shift;
3610   $self->scalar_sql(
3611     " SELECT COUNT(*) FROM cust_pay_pending ".
3612       " WHERE custnum = ? AND status != 'done' ",
3613     $self->custnum
3614   );
3615 }
3616
3617 =item num_cust_pay_pending_attempt
3618
3619 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3620 customer, with status "done" but without a corresp.  Also called automatically when the
3621 cust_pay_pending method is used in a scalar context.
3622
3623 =cut
3624
3625 sub num_cust_pay_pending_attempt {
3626   my $self = shift;
3627   $self->scalar_sql(
3628     " SELECT COUNT(*) FROM cust_pay_pending ".
3629       " WHERE custnum = ? AND status = 'done' AND paynum IS NULL",
3630     $self->custnum
3631   );
3632 }
3633
3634 =item cust_refund
3635
3636 Returns all the refunds (see L<FS::cust_refund>) for this customer.
3637
3638 =cut
3639
3640 sub cust_refund {
3641   my $self = shift;
3642   map { $_ } #return $self->num_cust_refund unless wantarray;
3643   sort { $a->_date <=> $b->_date }
3644     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
3645 }
3646
3647 =item display_custnum
3648
3649 Returns the displayed customer number for this customer: agent_custid if
3650 cust_main-default_agent_custid is set and it has a value, custnum otherwise.
3651
3652 =cut
3653
3654 sub display_custnum {
3655   my $self = shift;
3656
3657   return $self->agent_custid
3658     if $default_agent_custid && $self->agent_custid;
3659
3660   my $prefix = $conf->config('cust_main-custnum-display_prefix', $self->agentnum) || '';
3661
3662   if ( $prefix ) {
3663     return $prefix .
3664            sprintf('%0'.($custnum_display_length||8).'d', $self->custnum)
3665   } elsif ( $custnum_display_length ) {
3666     return sprintf('%0'.$custnum_display_length.'d', $self->custnum);
3667   } else {
3668     return $self->custnum;
3669   }
3670 }
3671
3672 =item name
3673
3674 Returns a name string for this customer, either "Company (Last, First)" or
3675 "Last, First".
3676
3677 =cut
3678
3679 sub name {
3680   my $self = shift;
3681   my $name = $self->contact;
3682   $name = $self->company. " ($name)" if $self->company;
3683   $name;
3684 }
3685
3686 =item service_contact
3687
3688 Returns the L<FS::contact> object for this customer that has the 'Service'
3689 contact class, or undef if there is no such contact.  Deprecated; don't use
3690 this in new code.
3691
3692 =cut
3693
3694 sub service_contact {
3695   my $self = shift;
3696   if ( !exists($self->{service_contact}) ) {
3697     my $classnum = $self->scalar_sql(
3698       'SELECT classnum FROM contact_class WHERE classname = \'Service\''
3699     ) || 0; #if it's zero, qsearchs will return nothing
3700     my $cust_contact = qsearchs('cust_contact', {
3701         'classnum' => $classnum,
3702         'custnum'  => $self->custnum,
3703     });
3704     $self->{service_contact} = $cust_contact->contact if $cust_contact;
3705   }
3706   $self->{service_contact};
3707 }
3708
3709 =item ship_name
3710
3711 Returns a name string for this (service/shipping) contact, either
3712 "Company (Last, First)" or "Last, First".
3713
3714 =cut
3715
3716 sub ship_name {
3717   my $self = shift;
3718
3719   my $name = $self->ship_contact;
3720   $name = $self->company. " ($name)" if $self->company;
3721   $name;
3722 }
3723
3724 =item name_short
3725
3726 Returns a name string for this customer, either "Company" or "First Last".
3727
3728 =cut
3729
3730 sub name_short {
3731   my $self = shift;
3732   $self->company !~ /^\s*$/ ? $self->company : $self->contact_firstlast;
3733 }
3734
3735 =item ship_name_short
3736
3737 Returns a name string for this (service/shipping) contact, either "Company"
3738 or "First Last".
3739
3740 =cut
3741
3742 sub ship_name_short {
3743   my $self = shift;
3744   $self->service_contact
3745     ? $self->ship_contact_firstlast
3746     : $self->name_short
3747 }
3748
3749 =item contact
3750
3751 Returns this customer's full (billing) contact name only, "Last, First"
3752
3753 =cut
3754
3755 sub contact {
3756   my $self = shift;
3757   $self->get('last'). ', '. $self->first;
3758 }
3759
3760 =item ship_contact
3761
3762 Returns this customer's full (shipping) contact name only, "Last, First"
3763
3764 =cut
3765
3766 sub ship_contact {
3767   my $self = shift;
3768   my $contact = $self->service_contact || $self;
3769   $contact->get('last') . ', ' . $contact->get('first');
3770 }
3771
3772 =item contact_firstlast
3773
3774 Returns this customers full (billing) contact name only, "First Last".
3775
3776 =cut
3777
3778 sub contact_firstlast {
3779   my $self = shift;
3780   $self->first. ' '. $self->get('last');
3781 }
3782
3783 =item ship_contact_firstlast
3784
3785 Returns this customer's full (shipping) contact name only, "First Last".
3786
3787 =cut
3788
3789 sub ship_contact_firstlast {
3790   my $self = shift;
3791   my $contact = $self->service_contact || $self;
3792   $contact->get('first') . ' '. $contact->get('last');
3793 }
3794
3795 sub bill_country_full {
3796   my $self = shift;
3797   $self->bill_location->country_full;
3798 }
3799
3800 sub ship_country_full {
3801   my $self = shift;
3802   $self->ship_location->country_full;
3803 }
3804
3805 =item county_state_county [ PREFIX ]
3806
3807 Returns a string consisting of just the county, state and country.
3808
3809 =cut
3810
3811 sub county_state_country {
3812   my $self = shift;
3813   my $locationnum;
3814   if ( @_ && $_[0] && $self->has_ship_address ) {
3815     $locationnum = $self->ship_locationnum;
3816   } else {
3817     $locationnum = $self->bill_locationnum;
3818   }
3819   my $cust_location = qsearchs('cust_location', { locationnum=>$locationnum });
3820   $cust_location->county_state_country;
3821 }
3822
3823 =item geocode DATA_VENDOR
3824
3825 Returns a value for the customer location as encoded by DATA_VENDOR.
3826 Currently this only makes sense for "CCH" as DATA_VENDOR.
3827
3828 =cut
3829
3830 =item cust_status
3831
3832 =item status
3833
3834 Returns a status string for this customer, currently:
3835
3836 =over 4
3837
3838 =item prospect
3839
3840 No packages have ever been ordered.  Displayed as "No packages".
3841
3842 =item ordered
3843
3844 Recurring packages all are new (not yet billed).
3845
3846 =item active
3847
3848 One or more recurring packages is active.
3849
3850 =item inactive
3851
3852 No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled).
3853
3854 =item suspended
3855
3856 All non-cancelled recurring packages are suspended.
3857
3858 =item cancelled
3859
3860 All recurring packages are cancelled.
3861
3862 =back
3863
3864 Behavior of inactive vs. cancelled edge cases can be adjusted with the
3865 cust_main-status_module configuration option.
3866
3867 =cut
3868
3869 sub status { shift->cust_status(@_); }
3870
3871 sub cust_status {
3872   my $self = shift;
3873   return $self->hashref->{cust_status} if $self->hashref->{cust_status};
3874   for my $status ( FS::cust_main->statuses() ) {
3875     my $method = $status.'_sql';
3876     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
3877     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
3878     $sth->execute( ($self->custnum) x $numnum )
3879       or die "Error executing 'SELECT $sql': ". $sth->errstr;
3880     if ( $sth->fetchrow_arrayref->[0] ) {
3881       $self->hashref->{cust_status} = $status;
3882       return $status;
3883     }
3884   }
3885 }
3886
3887 =item is_status_delay_cancel
3888
3889 Returns true if customer status is 'suspended'
3890 and all suspended cust_pkg return true for
3891 cust_pkg->is_status_delay_cancel.
3892
3893 This is not a real status, this only meant for hacking display
3894 values, because otherwise treating the customer as suspended is
3895 really the whole point of the delay_cancel option.
3896
3897 =cut
3898
3899 sub is_status_delay_cancel {
3900   my ($self) = @_;
3901   return 0 unless $self->status eq 'suspended';
3902   foreach my $cust_pkg ($self->ncancelled_pkgs) {
3903     return 0 unless $cust_pkg->is_status_delay_cancel;
3904   }
3905   return 1;
3906 }
3907
3908 =item ucfirst_cust_status
3909
3910 =item ucfirst_status
3911
3912 Deprecated, use the cust_status_label method instead.
3913
3914 Returns the status with the first character capitalized.
3915
3916 =cut
3917
3918 sub ucfirst_status {
3919   carp "ucfirst_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
3920   local($ucfirst_nowarn) = 1;
3921   shift->ucfirst_cust_status(@_);
3922 }
3923
3924 sub ucfirst_cust_status {
3925   carp "ucfirst_cust_status deprecated, use cust_status_label" unless $ucfirst_nowarn;
3926   my $self = shift;
3927   ucfirst($self->cust_status);
3928 }
3929
3930 =item cust_status_label
3931
3932 =item status_label
3933
3934 Returns the display label for this status.
3935
3936 =cut
3937
3938 sub status_label { shift->cust_status_label(@_); }
3939
3940 sub cust_status_label {
3941   my $self = shift;
3942   __PACKAGE__->statuslabels->{$self->cust_status};
3943 }
3944
3945 =item statuscolor
3946
3947 Returns a hex triplet color string for this customer's status.
3948
3949 =cut
3950
3951 sub statuscolor { shift->cust_statuscolor(@_); }
3952
3953 sub cust_statuscolor {
3954   my $self = shift;
3955   __PACKAGE__->statuscolors->{$self->cust_status};
3956 }
3957
3958 =item tickets [ STATUS ]
3959
3960 Returns an array of hashes representing the customer's RT tickets.
3961
3962 An optional status (or arrayref or hashref of statuses) may be specified.
3963
3964 =cut
3965
3966 sub tickets {
3967   my $self = shift;
3968   my $status = ( @_ && $_[0] ) ? shift : '';
3969
3970   my $num = $conf->config('cust_main-max_tickets') || 10;
3971   my @tickets = ();
3972
3973   if ( $conf->config('ticket_system') ) {
3974     unless ( $conf->config('ticket_system-custom_priority_field') ) {
3975
3976       @tickets = @{ FS::TicketSystem->customer_tickets( $self->custnum,
3977                                                         $num,
3978                                                         undef,
3979                                                         $status,
3980                                                       )
3981                   };
3982
3983     } else {
3984
3985       foreach my $priority (
3986         $conf->config('ticket_system-custom_priority_field-values'), ''
3987       ) {
3988         last if scalar(@tickets) >= $num;
3989         push @tickets,
3990           @{ FS::TicketSystem->customer_tickets( $self->custnum,
3991                                                  $num - scalar(@tickets),
3992                                                  $priority,
3993                                                  $status,
3994                                                )
3995            };
3996       }
3997     }
3998   }
3999   (@tickets);
4000 }
4001
4002 =item appointments [ STATUS ]
4003
4004 Returns an array of hashes representing the customer's RT tickets which
4005 are appointments.
4006
4007 =cut
4008
4009 sub appointments {
4010   my $self = shift;
4011   my $status = ( @_ && $_[0] ) ? shift : '';
4012
4013   return () unless $conf->config('ticket_system');
4014
4015   my $queueid = $conf->config('ticket_system-appointment-queueid');
4016
4017   @{ FS::TicketSystem->customer_tickets( $self->custnum,
4018                                          99,
4019                                          undef,
4020                                          $status,
4021                                          $queueid,
4022                                        )
4023   };
4024 }
4025
4026 # Return services representing svc_accts in customer support packages
4027 sub support_services {
4028   my $self = shift;
4029   my %packages = map { $_ => 1 } $conf->config('support_packages');
4030
4031   grep { $_->pkg_svc && $_->pkg_svc->primary_svc eq 'Y' }
4032     grep { $_->part_svc->svcdb eq 'svc_acct' }
4033     map { $_->cust_svc }
4034     grep { exists $packages{ $_->pkgpart } }
4035     $self->ncancelled_pkgs;
4036
4037 }
4038
4039 # Return a list of latitude/longitude for one of the services (if any)
4040 sub service_coordinates {
4041   my $self = shift;
4042
4043   my @svc_X =
4044     grep { $_->latitude && $_->longitude }
4045     map { $_->svc_x }
4046     map { $_->cust_svc }
4047     $self->ncancelled_pkgs;
4048
4049   scalar(@svc_X) ? ( $svc_X[0]->latitude, $svc_X[0]->longitude ) : ()
4050 }
4051
4052 =item masked FIELD
4053
4054 Returns a masked version of the named field
4055
4056 =cut
4057
4058 sub masked {
4059 my ($self,$field) = @_;
4060
4061 # Show last four
4062
4063 'x'x(length($self->getfield($field))-4).
4064   substr($self->getfield($field), (length($self->getfield($field))-4));
4065
4066 }
4067
4068 =item payment_history
4069
4070 Returns an array of hashrefs standardizing information from cust_bill, cust_pay,
4071 cust_credit and cust_refund objects.  Each hashref has the following fields:
4072
4073 I<type> - one of 'Line item', 'Invoice', 'Payment', 'Credit', 'Refund' or 'Previous'
4074
4075 I<date> - value of _date field, unix timestamp
4076
4077 I<date_pretty> - user-friendly date
4078
4079 I<description> - user-friendly description of item
4080
4081 I<amount> - impact of item on user's balance
4082 (positive for Invoice/Refund/Line item, negative for Payment/Credit.)
4083 Not to be confused with the native 'amount' field in cust_credit, see below.
4084
4085 I<amount_pretty> - includes money char
4086
4087 I<balance> - customer balance, chronologically as of this item
4088
4089 I<balance_pretty> - includes money char
4090
4091 I<charged> - amount charged for cust_bill (Invoice or Line item) records, undef for other types
4092
4093 I<paid> - amount paid for cust_pay records, undef for other types
4094
4095 I<credit> - amount credited for cust_credit records, undef for other types.
4096 Literally the 'amount' field from cust_credit, renamed here to avoid confusion.
4097
4098 I<refund> - amount refunded for cust_refund records, undef for other types
4099
4100 The four table-specific keys always have positive values, whether they reflect charges or payments.
4101
4102 The following options may be passed to this method:
4103
4104 I<line_items> - if true, returns charges ('Line item') rather than invoices
4105
4106 I<start_date> - unix timestamp, only include records on or after.
4107 If specified, an item of type 'Previous' will also be included.
4108 It does not have table-specific fields.
4109
4110 I<end_date> - unix timestamp, only include records before
4111
4112 I<reverse_sort> - order from newest to oldest (default is oldest to newest)
4113
4114 I<conf> - optional already-loaded FS::Conf object.
4115
4116 =cut
4117
4118 # Caution: this gets used by FS::ClientAPI::MyAccount::billing_history,
4119 # and also for sending customer statements, which should both be kept customer-friendly.
4120 # If you add anything that shouldn't be passed on through the API or exposed
4121 # to customers, add a new option to include it, don't include it by default
4122 sub payment_history {
4123   my $self = shift;
4124   my $opt = ref($_[0]) ? $_[0] : { @_ };
4125
4126   my $conf = $$opt{'conf'} || new FS::Conf;
4127   my $money_char = $conf->config("money_char") || '$',
4128
4129   #first load entire history,
4130   #need previous to calculate previous balance
4131   #loading after end_date shouldn't hurt too much?
4132   my @history = ();
4133   if ( $$opt{'line_items'} ) {
4134
4135     foreach my $cust_bill ( $self->cust_bill ) {
4136
4137       push @history, {
4138         'type'        => 'Line item',
4139         'description' => $_->desc( $self->locale ).
4140                            ( $_->sdate && $_->edate
4141                                ? ' '. time2str('%d-%b-%Y', $_->sdate).
4142                                  ' To '. time2str('%d-%b-%Y', $_->edate)
4143                                : ''
4144                            ),
4145         'amount'      => sprintf('%.2f', $_->setup + $_->recur ),
4146         'charged'     => sprintf('%.2f', $_->setup + $_->recur ),
4147         'date'        => $cust_bill->_date,
4148         'date_pretty' => $self->time2str_local('short', $cust_bill->_date ),
4149       }
4150         foreach $cust_bill->cust_bill_pkg;
4151
4152     }
4153
4154   } else {
4155
4156     push @history, {
4157                      'type'        => 'Invoice',
4158                      'description' => 'Invoice #'. $_->display_invnum,
4159                      'amount'      => sprintf('%.2f', $_->charged ),
4160                      'charged'     => sprintf('%.2f', $_->charged ),
4161                      'date'        => $_->_date,
4162                      'date_pretty' => $self->time2str_local('short', $_->_date ),
4163                    }
4164       foreach $self->cust_bill;
4165
4166   }
4167
4168   push @history, {
4169                    'type'        => 'Payment',
4170                    'description' => 'Payment', #XXX type
4171                    'amount'      => sprintf('%.2f', 0 - $_->paid ),
4172                    'paid'        => sprintf('%.2f', $_->paid ),
4173                    'date'        => $_->_date,
4174                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4175                  }
4176     foreach $self->cust_pay;
4177
4178   push @history, {
4179                    'type'        => 'Credit',
4180                    'description' => 'Credit', #more info?
4181                    'amount'      => sprintf('%.2f', 0 -$_->amount ),
4182                    'credit'      => sprintf('%.2f', $_->amount ),
4183                    'date'        => $_->_date,
4184                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4185                  }
4186     foreach $self->cust_credit;
4187
4188   push @history, {
4189                    'type'        => 'Refund',
4190                    'description' => 'Refund', #more info?  type, like payment?
4191                    'amount'      => $_->refund,
4192                    'refund'      => $_->refund,
4193                    'date'        => $_->_date,
4194                    'date_pretty' => $self->time2str_local('short', $_->_date ),
4195                  }
4196     foreach $self->cust_refund;
4197
4198   #put it all in chronological order
4199   @history = sort { $a->{'date'} <=> $b->{'date'} } @history;
4200
4201   #calculate balance, filter items outside date range
4202   my $previous = 0;
4203   my $balance = 0;
4204   my @out = ();
4205   foreach my $item (@history) {
4206     last if $$opt{'end_date'} && ($$item{'date'} >= $$opt{'end_date'});
4207     $balance += $$item{'amount'};
4208     if ($$opt{'start_date'} && ($$item{'date'} < $$opt{'start_date'})) {
4209       $previous += $$item{'amount'};
4210       next;
4211     }
4212     $$item{'balance'} = sprintf("%.2f",$balance);
4213     foreach my $key ( qw(amount balance) ) {
4214       $$item{$key.'_pretty'} = money_pretty($$item{$key});
4215     }
4216     push(@out,$item);
4217   }
4218
4219   # start with previous balance, if there was one
4220   if ($previous) {
4221     my $item = {
4222       'type'        => 'Previous',
4223       'description' => 'Previous balance',
4224       'amount'      => sprintf("%.2f",$previous),
4225       'balance'     => sprintf("%.2f",$previous),
4226       'date'        => $$opt{'start_date'},
4227       'date_pretty' => $self->time2str_local('short', $$opt{'start_date'} ),
4228     };
4229     #false laziness with above
4230     foreach my $key ( qw(amount balance) ) {
4231       $$item{$key.'_pretty'} = $$item{$key};
4232       $$item{$key.'_pretty'} =~ s/^(-?)/$1$money_char/;
4233     }
4234     unshift(@out,$item);
4235   }
4236
4237   @out = reverse @history if $$opt{'reverse_sort'};
4238
4239   return @out;
4240 }
4241
4242 =item save_cust_payby
4243
4244 Saves a new cust_payby for this customer, replacing an existing entry only
4245 in select circumstances.  Does not validate input.
4246
4247 If auto is specified, marks this as the customer's primary method, or the
4248 specified weight.  Existing payment methods have their weight incremented as
4249 appropriate.
4250
4251 If bill_location is specified with auto, also sets location in cust_main.
4252
4253 Will not insert complete duplicates of existing records, or records in which the
4254 only difference from an existing record is to turn off automatic payment (will
4255 return without error.)  Will replace existing records in which the only difference
4256 is to add a value to a previously empty preserved field and/or turn on automatic payment.
4257 Fields marked as preserved are optional, and existing values will not be overwritten with
4258 blanks when replacing.
4259
4260 Accepts the following named parameters:
4261
4262 =over 4
4263
4264 =item payment_payby
4265
4266 either CARD or CHEK
4267
4268 =item auto
4269
4270 save as an automatic payment type (CARD/CHEK if true, DCRD/DCHK if false)
4271
4272 =item weight
4273
4274 optional, set higher than 1 for secondary, etc.
4275
4276 =item payinfo
4277
4278 required
4279
4280 =item paymask
4281
4282 optional, but should be specified for anything that might be tokenized, will be preserved when replacing
4283
4284 =item payname
4285
4286 required
4287
4288 =item payip
4289
4290 optional, will be preserved when replacing
4291
4292 =item paydate
4293
4294 CARD only, required
4295
4296 =item bill_location
4297
4298 CARD only, required, FS::cust_location object
4299
4300 =item paystart_month
4301
4302 CARD only, optional, will be preserved when replacing
4303
4304 =item paystart_year
4305
4306 CARD only, optional, will be preserved when replacing
4307
4308 =item payissue
4309
4310 CARD only, optional, will be preserved when replacing
4311
4312 =item paycvv
4313
4314 CARD only, only used if conf cvv-save is set appropriately
4315
4316 =item paytype
4317
4318 CHEK only
4319
4320 =item paystate
4321
4322 CHEK only
4323
4324 =back
4325
4326 =cut
4327
4328 #The code for this option is in place, but it's not currently used
4329 #
4330 # =item replace
4331 #
4332 # existing cust_payby object to be replaced (must match custnum)
4333
4334 # stateid/stateid_state/ss are not currently supported in cust_payby,
4335 # might not even work properly in 4.x, but will need to work here if ever added
4336
4337 sub save_cust_payby {
4338   my $self = shift;
4339   my %opt = @_;
4340
4341   my $old = $opt{'replace'};
4342   my $new = new FS::cust_payby { $old ? $old->hash : () };
4343   return "Customer number does not match" if $new->custnum and $new->custnum != $self->custnum;
4344   $new->set( 'custnum' => $self->custnum );
4345
4346   my $payby = $opt{'payment_payby'};
4347   return "Bad payby" unless grep(/^$payby$/,('CARD','CHEK'));
4348
4349   # don't allow turning off auto when replacing
4350   $opt{'auto'} ||= 1 if $old and $old->payby !~ /^D/;
4351
4352   my @check_existing; # payby relevant to this payment_payby
4353
4354   # set payby based on auto
4355   if ( $payby eq 'CARD' ) {
4356     $new->set( 'payby' => ( $opt{'auto'} ? 'CARD' : 'DCRD' ) );
4357     @check_existing = qw( CARD DCRD );
4358   } elsif ( $payby eq 'CHEK' ) {
4359     $new->set( 'payby' => ( $opt{'auto'} ? 'CHEK' : 'DCHK' ) );
4360     @check_existing = qw( CHEK DCHK );
4361   }
4362
4363   $new->set( 'weight' => $opt{'auto'} ? $opt{'weight'} : '' );
4364
4365   # basic fields
4366   $new->payinfo($opt{'payinfo'}); # sets default paymask, but not if it's already tokenized
4367   $new->paymask($opt{'paymask'}) if $opt{'paymask'}; # in case it's been tokenized, override with loaded paymask
4368   $new->set( 'payname' => $opt{'payname'} );
4369   $new->set( 'payip' => $opt{'payip'} ); # will be preserved below
4370
4371   my $conf = new FS::Conf;
4372
4373   # compare to FS::cust_main::realtime_bop - check both to make sure working correctly
4374   if ( $payby eq 'CARD' &&
4375        grep { $_ eq cardtype($opt{'payinfo'}) } $conf->config('cvv-save') ) {
4376     $new->set( 'paycvv' => $opt{'paycvv'} );
4377   } else {
4378     $new->set( 'paycvv' => '');
4379   }
4380
4381   local $SIG{HUP} = 'IGNORE';
4382   local $SIG{INT} = 'IGNORE';
4383   local $SIG{QUIT} = 'IGNORE';
4384   local $SIG{TERM} = 'IGNORE';
4385   local $SIG{TSTP} = 'IGNORE';
4386   local $SIG{PIPE} = 'IGNORE';
4387
4388   my $oldAutoCommit = $FS::UID::AutoCommit;
4389   local $FS::UID::AutoCommit = 0;
4390   my $dbh = dbh;
4391
4392   # set fields specific to payment_payby
4393   if ( $payby eq 'CARD' ) {
4394     if ($opt{'bill_location'}) {
4395       $opt{'bill_location'}->set('custnum' => $self->custnum);
4396       my $error = $opt{'bill_location'}->find_or_insert;
4397       if ( $error ) {
4398         $dbh->rollback if $oldAutoCommit;
4399         return $error;
4400       }
4401       $new->set( 'locationnum' => $opt{'bill_location'}->locationnum );
4402     }
4403     foreach my $field ( qw( paydate paystart_month paystart_year payissue ) ) {
4404       $new->set( $field => $opt{$field} );
4405     }
4406   } else {
4407     foreach my $field ( qw(paytype paystate) ) {
4408       $new->set( $field => $opt{$field} );
4409     }
4410   }
4411
4412   # other cust_payby to compare this to
4413   my @existing = $self->cust_payby(@check_existing);
4414
4415   # fields that can overwrite blanks with values, but not values with blanks
4416   my @preserve = qw( paymask locationnum paystart_month paystart_year payissue payip );
4417
4418   my $skip_cust_payby = 0; # true if we don't need to save or reweight cust_payby
4419   unless ($old) {
4420     # generally, we don't want to overwrite existing cust_payby with this,
4421     # but we can replace if we're only marking it auto or adding a preserved field
4422     # and we can avoid saving a total duplicate or merely turning off auto
4423 PAYBYLOOP:
4424     foreach my $cust_payby (@existing) {
4425       # check fields that absolutely should not change
4426       foreach my $field ($new->fields) {
4427         next if grep(/^$field$/, qw( custpaybynum payby weight ) );
4428         next if grep(/^$field$/, @preserve );
4429         next PAYBYLOOP unless $new->get($field) eq $cust_payby->get($field);
4430       }
4431       # now check fields that can replace if one value is blank
4432       my $replace = 0;
4433       foreach my $field (@preserve) {
4434         if (
4435           ( $new->get($field) and !$cust_payby->get($field) ) or
4436           ( $cust_payby->get($field) and !$new->get($field) )
4437         ) {
4438           # prevention of overwriting values with blanks happens farther below
4439           $replace = 1;
4440         } elsif ( $new->get($field) ne $cust_payby->get($field) ) {
4441           next PAYBYLOOP;
4442         }
4443       }
4444       unless ( $replace ) {
4445         # nearly identical, now check weight
4446         if ($new->get('weight') eq $cust_payby->get('weight') or !$new->get('weight')) {
4447           # ignore identical cust_payby, and ignore attempts to turn off auto
4448           # no need to save or re-weight cust_payby (but still need to update/commit $self)
4449           $skip_cust_payby = 1;
4450           last PAYBYLOOP;
4451         }
4452         # otherwise, only change is to mark this as primary
4453       }
4454       # if we got this far, we're definitely replacing
4455       $old = $cust_payby;
4456       last PAYBYLOOP;
4457     } #PAYBYLOOP
4458   }
4459
4460   if ($old) {
4461     $new->set( 'custpaybynum' => $old->custpaybynum );
4462     # don't turn off automatic payment (but allow it to be turned on)
4463     if ($new->payby =~ /^D/ and $new->payby ne $old->payby) {
4464       $opt{'auto'} = 1;
4465       $new->set( 'payby' => $old->payby );
4466       $new->set( 'weight' => 1 );
4467     }
4468     # make sure we're not overwriting values with blanks
4469     foreach my $field (@preserve) {
4470       if ( $old->get($field) and !$new->get($field) ) {
4471         $new->set( $field => $old->get($field) );
4472       }
4473     }
4474   }
4475
4476   # only overwrite cust_main bill_location if auto
4477   if ($opt{'auto'} && $opt{'bill_location'}) {
4478     $self->set('bill_location' => $opt{'bill_location'});
4479     my $error = $self->replace;
4480     if ( $error ) {
4481       $dbh->rollback if $oldAutoCommit;
4482       return $error;
4483     }
4484   }
4485
4486   # done with everything except reweighting and saving cust_payby
4487   # still need to commit changes to cust_main and cust_location
4488   if ($skip_cust_payby) {
4489     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4490     return '';
4491   }
4492
4493   # re-weight existing primary cust_pay for this payby
4494   if ($opt{'auto'}) {
4495     foreach my $cust_payby (@existing) {
4496       # relies on cust_payby return order
4497       last unless $cust_payby->payby !~ /^D/;
4498       last if $cust_payby->weight > 1;
4499       next if $new->custpaybynum eq $cust_payby->custpaybynum;
4500       next if $cust_payby->weight < ($opt{'weight'} || 1);
4501       $cust_payby->weight( $cust_payby->weight + 1 );
4502       my $error = $cust_payby->replace;
4503       if ( $error ) {
4504         $dbh->rollback if $oldAutoCommit;
4505         return "Error reweighting cust_payby: $error";
4506       }
4507     }
4508   }
4509
4510   # finally, save cust_payby
4511   my $error = $old ? $new->replace($old) : $new->insert;
4512   if ( $error ) {
4513     $dbh->rollback if $oldAutoCommit;
4514     return $error;
4515   }
4516
4517   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4518   '';
4519
4520 }
4521
4522 =back
4523
4524 =head1 CLASS METHODS
4525
4526 =over 4
4527
4528 =item statuses
4529
4530 Class method that returns the list of possible status strings for customers
4531 (see L<the status method|/status>).  For example:
4532
4533   @statuses = FS::cust_main->statuses();
4534
4535 =cut
4536
4537 sub statuses {
4538   my $self = shift;
4539   keys %{ $self->statuscolors };
4540 }
4541
4542 =item cust_status_sql
4543
4544 Returns an SQL fragment to determine the status of a cust_main record, as a
4545 string.
4546
4547 =cut
4548
4549 sub cust_status_sql {
4550   my $sql = 'CASE';
4551   for my $status ( FS::cust_main->statuses() ) {
4552     my $method = $status.'_sql';
4553     $sql .= ' WHEN ('.FS::cust_main->$method.") THEN '$status'";
4554   }
4555   $sql .= ' END';
4556   return $sql;
4557 }
4558
4559
4560 =item prospect_sql
4561
4562 Returns an SQL expression identifying prospective cust_main records (customers
4563 with no packages ever ordered)
4564
4565 =cut
4566
4567 use vars qw($select_count_pkgs);
4568 $select_count_pkgs =
4569   "SELECT COUNT(*) FROM cust_pkg
4570     WHERE cust_pkg.custnum = cust_main.custnum";
4571
4572 sub select_count_pkgs_sql {
4573   $select_count_pkgs;
4574 }
4575
4576 sub prospect_sql {
4577   " 0 = ( $select_count_pkgs ) ";
4578 }
4579
4580 =item ordered_sql
4581
4582 Returns an SQL expression identifying ordered cust_main records (customers with
4583 no active packages, but recurring packages not yet setup or one time charges
4584 not yet billed).
4585
4586 =cut
4587
4588 sub ordered_sql {
4589   FS::cust_main->none_active_sql.
4590   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->not_yet_billed_sql. " ) ";
4591 }
4592
4593 =item active_sql
4594
4595 Returns an SQL expression identifying active cust_main records (customers with
4596 active recurring packages).
4597
4598 =cut
4599
4600 sub active_sql {
4601   " 0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4602 }
4603
4604 =item none_active_sql
4605
4606 Returns an SQL expression identifying cust_main records with no active
4607 recurring packages.  This includes customers of status prospect, ordered,
4608 inactive, and suspended.
4609
4610 =cut
4611
4612 sub none_active_sql {
4613   " 0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4614 }
4615
4616 =item inactive_sql
4617
4618 Returns an SQL expression identifying inactive cust_main records (customers with
4619 no active recurring packages, but otherwise unsuspended/uncancelled).
4620
4621 =cut
4622
4623 sub inactive_sql {
4624   FS::cust_main->none_active_sql.
4625   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " ) ";
4626 }
4627
4628 =item susp_sql
4629 =item suspended_sql
4630
4631 Returns an SQL expression identifying suspended cust_main records.
4632
4633 =cut
4634
4635
4636 sub suspended_sql { susp_sql(@_); }
4637 sub susp_sql {
4638   FS::cust_main->none_active_sql.
4639   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " ) ";
4640 }
4641
4642 =item cancel_sql
4643 =item cancelled_sql
4644
4645 Returns an SQL expression identifying cancelled cust_main records.
4646
4647 =cut
4648
4649 sub cancel_sql { shift->cancelled_sql(@_); }
4650
4651 =item uncancel_sql
4652 =item uncancelled_sql
4653
4654 Returns an SQL expression identifying un-cancelled cust_main records.
4655
4656 =cut
4657
4658 sub uncancelled_sql { uncancel_sql(@_); }
4659 sub uncancel_sql { "
4660   ( 0 < ( $select_count_pkgs
4661                    AND ( cust_pkg.cancel IS NULL
4662                          OR cust_pkg.cancel = 0
4663                        )
4664         )
4665     OR 0 = ( $select_count_pkgs )
4666   )
4667 "; }
4668
4669 =item balance_sql
4670
4671 Returns an SQL fragment to retreive the balance.
4672
4673 =cut
4674
4675 sub balance_sql { "
4676     ( SELECT COALESCE( SUM(charged), 0 ) FROM cust_bill
4677         WHERE cust_bill.custnum   = cust_main.custnum     )
4678   - ( SELECT COALESCE( SUM(paid),    0 ) FROM cust_pay
4679         WHERE cust_pay.custnum    = cust_main.custnum     )
4680   - ( SELECT COALESCE( SUM(amount),  0 ) FROM cust_credit
4681         WHERE cust_credit.custnum = cust_main.custnum     )
4682   + ( SELECT COALESCE( SUM(refund),  0 ) FROM cust_refund
4683         WHERE cust_refund.custnum = cust_main.custnum     )
4684 "; }
4685
4686 =item balance_date_sql [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
4687
4688 Returns an SQL fragment to retreive the balance for this customer, optionally
4689 considering invoices with date earlier than START_TIME, and not
4690 later than END_TIME (total_owed_date minus total_unapplied_credits minus
4691 total_unapplied_payments).
4692
4693 Times are specified as SQL fragments or numeric
4694 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4695 L<Date::Parse> for conversion functions.  The empty string can be passed
4696 to disable that time constraint completely.
4697
4698 Available options are:
4699
4700 =over 4
4701
4702 =item unapplied_date
4703
4704 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
4705
4706 =item total
4707
4708 (unused.  obsolete?)
4709 set to true to remove all customer comparison clauses, for totals
4710
4711 =item where
4712
4713 (unused.  obsolete?)
4714 WHERE clause hashref (elements "AND"ed together) (typically used with the total option)
4715
4716 =item join
4717
4718 (unused.  obsolete?)
4719 JOIN clause (typically used with the total option)
4720
4721 =item cutoff
4722
4723 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
4724 time will be ignored.  Note that START_TIME and END_TIME only limit the date
4725 range for invoices and I<unapplied> payments, credits, and refunds.
4726
4727 =back
4728
4729 =cut
4730
4731 sub balance_date_sql {
4732   my( $class, $start, $end, %opt ) = @_;
4733
4734   my $cutoff = $opt{'cutoff'};
4735
4736   my $owed         = FS::cust_bill->owed_sql($cutoff);
4737   my $unapp_refund = FS::cust_refund->unapplied_sql($cutoff);
4738   my $unapp_credit = FS::cust_credit->unapplied_sql($cutoff);
4739   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4740
4741   my $j = $opt{'join'} || '';
4742
4743   my $owed_wh   = $class->_money_table_where( 'cust_bill',   $start,$end,%opt );
4744   my $refund_wh = $class->_money_table_where( 'cust_refund', $start,$end,%opt );
4745   my $credit_wh = $class->_money_table_where( 'cust_credit', $start,$end,%opt );
4746   my $pay_wh    = $class->_money_table_where( 'cust_pay',    $start,$end,%opt );
4747
4748   "   ( SELECT COALESCE(SUM($owed),         0) FROM cust_bill   $j $owed_wh   )
4749     + ( SELECT COALESCE(SUM($unapp_refund), 0) FROM cust_refund $j $refund_wh )
4750     - ( SELECT COALESCE(SUM($unapp_credit), 0) FROM cust_credit $j $credit_wh )
4751     - ( SELECT COALESCE(SUM($unapp_pay),    0) FROM cust_pay    $j $pay_wh    )
4752   ";
4753
4754 }
4755
4756 =item unapplied_payments_date_sql START_TIME [ END_TIME ]
4757
4758 Returns an SQL fragment to retreive the total unapplied payments for this
4759 customer, only considering payments with date earlier than START_TIME, and
4760 optionally not later than END_TIME.
4761
4762 Times are specified as SQL fragments or numeric
4763 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4764 L<Date::Parse> for conversion functions.  The empty string can be passed
4765 to disable that time constraint completely.
4766
4767 Available options are:
4768
4769 =cut
4770
4771 sub unapplied_payments_date_sql {
4772   my( $class, $start, $end, %opt ) = @_;
4773
4774   my $cutoff = $opt{'cutoff'};
4775
4776   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4777
4778   my $pay_where = $class->_money_table_where( 'cust_pay', $start, $end,
4779                                                           'unapplied_date'=>1 );
4780
4781   " ( SELECT COALESCE(SUM($unapp_pay), 0) FROM cust_pay $pay_where ) ";
4782 }
4783
4784 =item _money_table_where TABLE START_TIME [ END_TIME [ OPTION => VALUE ... ] ]
4785
4786 Helper method for balance_date_sql; name (and usage) subject to change
4787 (suggestions welcome).
4788
4789 Returns a WHERE clause for the specified monetary TABLE (cust_bill,
4790 cust_refund, cust_credit or cust_pay).
4791
4792 If TABLE is "cust_bill" or the unapplied_date option is true, only
4793 considers records with date earlier than START_TIME, and optionally not
4794 later than END_TIME .
4795
4796 =cut
4797
4798 sub _money_table_where {
4799   my( $class, $table, $start, $end, %opt ) = @_;
4800
4801   my @where = ();
4802   push @where, "cust_main.custnum = $table.custnum" unless $opt{'total'};
4803   if ( $table eq 'cust_bill' || $opt{'unapplied_date'} ) {
4804     push @where, "$table._date <= $start" if defined($start) && length($start);
4805     push @where, "$table._date >  $end"   if defined($end)   && length($end);
4806   }
4807   push @where, @{$opt{'where'}} if $opt{'where'};
4808   my $where = scalar(@where) ? 'WHERE '. join(' AND ', @where ) : '';
4809
4810   $where;
4811
4812 }
4813
4814 #for dyanmic FS::$table->search in httemplate/misc/email_customers.html
4815 use FS::cust_main::Search;
4816 sub search {
4817   my $class = shift;
4818   FS::cust_main::Search->search(@_);
4819 }
4820
4821 =back
4822
4823 =head1 SUBROUTINES
4824
4825 =over 4
4826
4827 =item generate_letter CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4828
4829 Generates a templated notification to the customer (see L<Text::Template>).
4830
4831 OPTIONS is a hash and may include
4832
4833 I<extra_fields> - a hashref of name/value pairs which will be substituted
4834    into the template.  These values may override values mentioned below
4835    and those from the customer record.
4836
4837 I<template_text> - if present, ignores TEMPLATE_NAME and uses the provided text
4838
4839 The following variables are available in the template instead of or in addition
4840 to the fields of the customer record.
4841
4842 I<$returnaddress> - the return address defaults to invoice_latexreturnaddress or company_address
4843
4844 =cut
4845
4846 # a lot like cust_bill::print_latex
4847 sub generate_letter {
4848   my ($self, $template, %options) = @_;
4849
4850   warn "Template $template does not exist" && return
4851     unless $conf->exists($template) || $options{'template_text'};
4852
4853   my $template_source = $options{'template_text'}
4854                         ? [ $options{'template_text'} ]
4855                         : [ map "$_\n", $conf->config($template) ];
4856
4857   my $letter_template = new Text::Template
4858                         ( TYPE       => 'ARRAY',
4859                           SOURCE     => $template_source,
4860                           DELIMITERS => [ '[@--', '--@]' ],
4861                         )
4862     or die "can't create new Text::Template object: Text::Template::ERROR";
4863
4864   $letter_template->compile()
4865     or die "can't compile template: Text::Template::ERROR";
4866
4867   my %letter_data = map { $_ => $self->$_ } $self->fields;
4868
4869   for (keys %{$options{extra_fields}}){
4870     $letter_data{$_} = $options{extra_fields}->{$_};
4871   }
4872
4873   unless(exists($letter_data{returnaddress})){
4874     my $retadd = join("\n", $conf->config_orbase( 'invoice_latexreturnaddress',
4875                                                   $self->agent_template)
4876                      );
4877     if ( length($retadd) ) {
4878       $letter_data{returnaddress} = $retadd;
4879     } elsif ( grep /\S/, $conf->config('company_address', $self->agentnum) ) {
4880       $letter_data{returnaddress} =
4881         join( "\n", map { s/( {2,})/'~' x length($1)/eg;
4882                           s/$/\\\\\*/;
4883                           $_;
4884                         }
4885                     ( $conf->config('company_name', $self->agentnum),
4886                       $conf->config('company_address', $self->agentnum),
4887                     )
4888         );
4889     } else {
4890       $letter_data{returnaddress} = '~';
4891     }
4892   }
4893
4894   $letter_data{conf_dir} = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
4895
4896   $letter_data{company_name} = $conf->config('company_name', $self->agentnum);
4897
4898   my $dir = $FS::UID::conf_dir."/cache.". $FS::UID::datasrc;
4899
4900   my $lh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4901                            DIR      => $dir,
4902                            SUFFIX   => '.eps',
4903                            UNLINK   => 0,
4904                          ) or die "can't open temp file: $!\n";
4905   print $lh $conf->config_binary('logo.eps', $self->agentnum)
4906     or die "can't write temp file: $!\n";
4907   close $lh;
4908   $letter_data{'logo_file'} = $lh->filename;
4909
4910   my $fh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4911                            DIR      => $dir,
4912                            SUFFIX   => '.tex',
4913                            UNLINK   => 0,
4914                          ) or die "can't open temp file: $!\n";
4915
4916   $letter_template->fill_in( OUTPUT => $fh, HASH => \%letter_data );
4917   close $fh;
4918   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
4919   return ($1, $letter_data{'logo_file'});
4920
4921 }
4922
4923 =item print_ps TEMPLATE
4924
4925 Returns an postscript letter filled in from TEMPLATE, as a scalar.
4926
4927 =cut
4928
4929 sub print_ps {
4930   my $self = shift;
4931   my($file, $lfile) = $self->generate_letter(@_);
4932   my $ps = FS::Misc::generate_ps($file);
4933   unlink($file.'.tex');
4934   unlink($lfile);
4935
4936   $ps;
4937 }
4938
4939 =item print TEMPLATE
4940
4941 Prints the filled in template.
4942
4943 TEMPLATE is the name of a L<Text::Template> to fill in and print.
4944
4945 =cut
4946
4947 sub queueable_print {
4948   my %opt = @_;
4949
4950   my $self = qsearchs('cust_main', { 'custnum' => $opt{custnum} } )
4951     or die "invalid customer number: " . $opt{custnum};
4952
4953 #do not backport this change to 3.x
4954 #  my $error = $self->print( { 'template' => $opt{template} } );
4955   my $error = $self->print( $opt{'template'} );
4956   die $error if $error;
4957 }
4958
4959 sub print {
4960   my ($self, $template) = (shift, shift);
4961   do_print(
4962     [ $self->print_ps($template) ],
4963     'agentnum' => $self->agentnum,
4964   );
4965 }
4966
4967 #these three subs should just go away once agent stuff is all config overrides
4968
4969 sub agent_template {
4970   my $self = shift;
4971   $self->_agent_plandata('agent_templatename');
4972 }
4973
4974 sub agent_invoice_from {
4975   my $self = shift;
4976   $self->_agent_plandata('agent_invoice_from');
4977 }
4978
4979 sub _agent_plandata {
4980   my( $self, $option ) = @_;
4981
4982   #yuck.  this whole thing needs to be reconciled better with 1.9's idea of
4983   #agent-specific Conf
4984
4985   use FS::part_event::Condition;
4986
4987   my $agentnum = $self->agentnum;
4988
4989   my $regexp = regexp_sql();
4990
4991   my $part_event_option =
4992     qsearchs({
4993       'select'    => 'part_event_option.*',
4994       'table'     => 'part_event_option',
4995       'addl_from' => q{
4996         LEFT JOIN part_event USING ( eventpart )
4997         LEFT JOIN part_event_option AS peo_agentnum
4998           ON ( part_event.eventpart = peo_agentnum.eventpart
4999                AND peo_agentnum.optionname = 'agentnum'
5000                AND peo_agentnum.optionvalue }. $regexp. q{ '(^|,)}. $agentnum. q{(,|$)'
5001              )
5002         LEFT JOIN part_event_condition
5003           ON ( part_event.eventpart = part_event_condition.eventpart
5004                AND part_event_condition.conditionname = 'cust_bill_age'
5005              )
5006         LEFT JOIN part_event_condition_option
5007           ON ( part_event_condition.eventconditionnum = part_event_condition_option.eventconditionnum
5008                AND part_event_condition_option.optionname = 'age'
5009              )
5010       },
5011       #'hashref'   => { 'optionname' => $option },
5012       #'hashref'   => { 'part_event_option.optionname' => $option },
5013       'extra_sql' =>
5014         " WHERE part_event_option.optionname = ". dbh->quote($option).
5015         " AND action = 'cust_bill_send_agent' ".
5016         " AND ( disabled IS NULL OR disabled != 'Y' ) ".
5017         " AND peo_agentnum.optionname = 'agentnum' ".
5018         " AND ( agentnum IS NULL OR agentnum = $agentnum ) ".
5019         " ORDER BY
5020            CASE WHEN part_event_condition_option.optionname IS NULL
5021            THEN -1
5022            ELSE ". FS::part_event::Condition->age2seconds_sql('part_event_condition_option.optionvalue').
5023         " END
5024           , part_event.weight".
5025         " LIMIT 1"
5026     });
5027
5028   unless ( $part_event_option ) {
5029     return $self->agent->invoice_template || ''
5030       if $option eq 'agent_templatename';
5031     return '';
5032   }
5033
5034   $part_event_option->optionvalue;
5035
5036 }
5037
5038 sub process_o2m_qsearch {
5039   my $self = shift;
5040   my $table = shift;
5041   return qsearch($table, @_) unless $table eq 'contact';
5042
5043   my $hashref = shift;
5044   my %hash = %$hashref;
5045   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
5046     or die 'guru meditation #4343';
5047
5048   qsearch({ 'table'     => 'contact',
5049             'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
5050             'hashref'   => \%hash,
5051             'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
5052                            " cust_contact.custnum = $custnum "
5053          });
5054 }
5055
5056 sub process_o2m_qsearchs {
5057   my $self = shift;
5058   my $table = shift;
5059   return qsearchs($table, @_) unless $table eq 'contact';
5060
5061   my $hashref = shift;
5062   my %hash = %$hashref;
5063   ( my $custnum = delete $hash{'custnum'} ) =~ /^(\d+)$/
5064     or die 'guru meditation #2121';
5065
5066   qsearchs({ 'table'     => 'contact',
5067              'addl_from' => 'LEFT JOIN cust_contact USING ( contactnum )',
5068              'hashref'   => \%hash,
5069              'extra_sql' => ( keys %hash ? ' AND ' : ' WHERE ' ).
5070                             " cust_contact.custnum = $custnum "
5071           });
5072 }
5073
5074 =item queued_bill 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5075
5076 Subroutine (not a method), designed to be called from the queue.
5077
5078 Takes a list of options and values.
5079
5080 Pulls up the customer record via the custnum option and calls bill_and_collect.
5081
5082 =cut
5083
5084 sub queued_bill {
5085   my (%args) = @_; #, ($time, $invoice_time, $check_freq, $resetup) = @_;
5086
5087   my $cust_main = qsearchs( 'cust_main', { custnum => $args{'custnum'} } );
5088   warn 'bill_and_collect custnum#'. $cust_main->custnum. "\n";#log custnum w/pid
5089
5090   #without this errors don't get rolled back
5091   $args{'fatal'} = 1; # runs from job queue, will be caught
5092
5093   $cust_main->bill_and_collect( %args );
5094 }
5095
5096 =item queued_collect 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5097
5098 Like queued_bill, but instead of C<bill_and_collect>, just runs the
5099 C<collect> part.  This is used in batch tax calculation, where invoice
5100 generation and collection events have to be completely separated.
5101
5102 =cut
5103
5104 sub queued_collect {
5105   my (%args) = @_;
5106   my $cust_main = FS::cust_main->by_key($args{'custnum'});
5107
5108   $cust_main->collect(%args);
5109 }
5110
5111 sub process_bill_and_collect {
5112   my $job = shift;
5113   my $param = shift;
5114   my $cust_main = qsearchs( 'cust_main', { custnum => $param->{'custnum'} } )
5115       or die "custnum '$param->{custnum}' not found!\n";
5116   $param->{'job'}   = $job;
5117   $param->{'fatal'} = 1; # runs from job queue, will be caught
5118   $param->{'retry'} = 1;
5119
5120   $cust_main->bill_and_collect( %$param );
5121 }
5122
5123 #starting to take quite a while for big dbs
5124 #   (JRNL: journaled so it only happens once per database)
5125 # - seq scan of h_cust_main (yuck), but not going to index paycvv, so
5126 # JRNL seq scan of cust_main on signupdate... index signupdate?  will that help?
5127 # JRNL seq scan of cust_main on paydate... index on substrings?  maybe set an
5128 # JRNL seq scan of cust_main on payinfo.. certainly not going toi ndex that...
5129 # JRNL leading/trailing spaces in first, last, company
5130 # JRNL migrate to cust_payby
5131 # - otaker upgrade?  journal and call it good?  (double check to make sure
5132 #    we're not still setting otaker here)
5133 #
5134 #only going to get worse with new location stuff...
5135
5136 sub _upgrade_data { #class method
5137   my ($class, %opts) = @_;
5138
5139   my @statements = ();
5140
5141   #this seems to be the only expensive one.. why does it take so long?
5142   unless ( FS::upgrade_journal->is_done('cust_main__signupdate') ) {
5143     push @statements,
5144       'UPDATE cust_main SET signupdate = (SELECT signupdate FROM h_cust_main WHERE signupdate IS NOT NULL AND h_cust_main.custnum = cust_main.custnum ORDER BY historynum DESC LIMIT 1) WHERE signupdate IS NULL';
5145     FS::upgrade_journal->set_done('cust_main__signupdate');
5146   }
5147
5148   my $t = time;
5149   foreach my $sql ( @statements ) {
5150     my $sth = dbh->prepare($sql) or die dbh->errstr;
5151     $sth->execute or die $sth->errstr;
5152     #warn ( (time - $t). " seconds\n" );
5153     #$t = time;
5154   }
5155
5156   local($ignore_expired_card) = 1;
5157   local($ignore_banned_card) = 1;
5158   local($skip_fuzzyfiles) = 1;
5159   local($import) = 1; #prevent automatic geocoding (need its own variable?)
5160
5161   FS::cust_main::Location->_upgrade_data(%opts);
5162
5163   unless ( FS::upgrade_journal->is_done('cust_main__trimspaces') ) {
5164
5165     foreach my $cust_main ( qsearch({
5166       'table'     => 'cust_main',
5167       'hashref'   => {},
5168       'extra_sql' => 'WHERE '.
5169                        join(' OR ',
5170                          map "$_ LIKE ' %' OR $_ LIKE '% ' OR $_ LIKE '%  %'",
5171                            qw( first last company )
5172                        ),
5173     }) ) {
5174       my $error = $cust_main->replace;
5175       die $error if $error;
5176     }
5177
5178     FS::upgrade_journal->set_done('cust_main__trimspaces');
5179
5180   }
5181
5182   $class->_upgrade_otaker(%opts);
5183
5184 }
5185
5186 =back
5187
5188 =head1 BUGS
5189
5190 The delete method.
5191
5192 The delete method should possibly take an FS::cust_main object reference
5193 instead of a scalar customer number.
5194
5195 Bill and collect options should probably be passed as references instead of a
5196 list.
5197
5198 There should probably be a configuration file with a list of allowed credit
5199 card types.
5200
5201 No multiple currency support (probably a larger project than just this module).
5202
5203 Birthdates rely on negative epoch values.
5204
5205 B<collect> I<invoice_time> should be renamed I<time>, like B<bill>.
5206
5207 =head1 SEE ALSO
5208
5209 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
5210 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
5211 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
5212
5213 =cut
5214
5215 1;
5216