FS/FS/cust_main.pm

   1 package FS::cust_main;
   2
   3 require 5.006;
   4 use strict;
   5 use base qw( FS::cust_main::Packages FS::cust_main::Status
   6              FS::cust_main::NationalID
   7              FS::cust_main::Billing FS::cust_main::Billing_Realtime
   8              FS::cust_main::Billing_Discount
   9              FS::cust_main::Location
  10              FS::otaker_Mixin FS::payinfo_Mixin FS::cust_main_Mixin
  11              FS::geocode_Mixin FS::Quotable_Mixin
  12              FS::o2m_Common
  13              FS::Record
  14            );
  15 use vars qw( $DEBUG $me $conf
  16              @encrypted_fields
  17              $import
  18              $ignore_expired_card $ignore_banned_card $ignore_illegal_zip
  19              $skip_fuzzyfiles
  20              @paytypes
  21            );
  22 use Carp;
  23 use Scalar::Util qw( blessed );
  24 use Time::Local qw(timelocal);
  25 use Storable qw(thaw);
  26 use MIME::Base64;
  27 use Data::Dumper;
  28 use Tie::IxHash;
  29 use Digest::MD5 qw(md5_base64);
  30 use Date::Format;
  31 #use Date::Manip;
  32 use File::Temp; #qw( tempfile );
  33 use Business::CreditCard 0.28;
  34 use Locale::Country;
  35 use FS::UID qw( getotaker dbh driver_name );
  36 use FS::Record qw( qsearchs qsearch dbdef regexp_sql );
  37 use FS::Misc qw( generate_email send_email generate_ps do_print );
  38 use FS::Msgcat qw(gettext);
  39 use FS::CurrentUser;
  40 use FS::TicketSystem;
  41 use FS::payby;
  42 use FS::cust_pkg;
  43 use FS::cust_svc;
  44 use FS::cust_bill;
  45 use FS::cust_bill_void;
  46 use FS::legacy_cust_bill;
  47 use FS::cust_pay;
  48 use FS::cust_pay_pending;
  49 use FS::cust_pay_void;
  50 use FS::cust_pay_batch;
  51 use FS::cust_credit;
  52 use FS::cust_refund;
  53 use FS::part_referral;
  54 use FS::cust_main_county;
  55 use FS::cust_location;
  56 use FS::cust_class;
  57 use FS::cust_main_exemption;
  58 use FS::cust_tax_adjustment;
  59 use FS::cust_tax_location;
  60 use FS::agent;
  61 use FS::cust_main_invoice;
  62 use FS::cust_tag;
  63 use FS::prepay_credit;
  64 use FS::queue;
  65 use FS::part_pkg;
  66 use FS::part_export;
  67 #use FS::cust_event;
  68 use FS::type_pkgs;
  69 use FS::payment_gateway;
  70 use FS::agent_payment_gateway;
  71 use FS::banned_pay;
  72 use FS::cust_main_note;
  73 use FS::cust_attachment;
  74 use FS::contact;
  75 use FS::Locales;
  76 use FS::upgrade_journal;
  77
  78 # 1 is mostly method/subroutine entry and options
  79 # 2 traces progress of some operations
  80 # 3 is even more information including possibly sensitive data
  81 $DEBUG = 0;
  82 $me = '[FS::cust_main]';
  83
  84 $import = 0;
  85 $ignore_expired_card = 0;
  86 $ignore_banned_card = 0;
  87
  88 $skip_fuzzyfiles = 0;
  89
  90 @encrypted_fields = ('payinfo', 'paycvv');
  91 sub nohistory_fields { ('payinfo', 'paycvv'); }
  92
  93 @paytypes = ('', 'Personal checking', 'Personal savings', 'Business checking', 'Business savings');
  94
  95 #ask FS::UID to run this stuff for us later
  96 #$FS::UID::callback{'FS::cust_main'} = sub {
  97 install_callback FS::UID sub {
  98   $conf = new FS::Conf;
  99   #yes, need it for stuff below (prolly should be cached)
 100 };
 101
 102 sub _cache {
 103   my $self = shift;
 104   my ( $hashref, $cache ) = @_;
 105   if ( exists $hashref->{'pkgnum'} ) {
 106     #@{ $self->{'_pkgnum'} } = ();
 107     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
 108     $self->{'_pkgnum'} = $subcache;
 109     #push @{ $self->{'_pkgnum'} },
 110     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
 111   }
 112 }
 113
 114 =head1 NAME
 115
 116 FS::cust_main - Object methods for cust_main records
 117
 118 =head1 SYNOPSIS
 119
 120   use FS::cust_main;
 121
 122   $record = new FS::cust_main \%hash;
 123   $record = new FS::cust_main { 'column' => 'value' };
 124
 125   $error = $record->insert;
 126
 127   $error = $new_record->replace($old_record);
 128
 129   $error = $record->delete;
 130
 131   $error = $record->check;
 132
 133   @cust_pkg = $record->all_pkgs;
 134
 135   @cust_pkg = $record->ncancelled_pkgs;
 136
 137   @cust_pkg = $record->suspended_pkgs;
 138
 139   $error = $record->bill;
 140   $error = $record->bill %options;
 141   $error = $record->bill 'time' => $time;
 142
 143   $error = $record->collect;
 144   $error = $record->collect %options;
 145   $error = $record->collect 'invoice_time'   => $time,
 146                           ;
 147
 148 =head1 DESCRIPTION
 149
 150 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 151 FS::Record.  The following fields are currently supported:
 152
 153 =over 4
 154
 155 =item custnum
 156
 157 Primary key (assigned automatically for new customers)
 158
 159 =item agentnum
 160
 161 Agent (see L<FS::agent>)
 162
 163 =item refnum
 164
 165 Advertising source (see L<FS::part_referral>)
 166
 167 =item first
 168
 169 First name
 170
 171 =item last
 172
 173 Last name
 174
 175 =item ss
 176
 177 Cocial security number (optional)
 178
 179 =item company
 180
 181 (optional)
 182
 183 =item daytime
 184
 185 phone (optional)
 186
 187 =item night
 188
 189 phone (optional)
 190
 191 =item fax
 192
 193 phone (optional)
 194
 195 =item mobile
 196
 197 phone (optional)
 198
 199 =item payby
 200
 201 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 202
 203 =item payinfo
 204
 205 Payment Information (See L<FS::payinfo_Mixin> for data format)
 206
 207 =item paymask
 208
 209 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 210
 211 =item paycvv
 212
 213 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 214
 215 =item paydate
 216
 217 Expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 218
 219 =item paystart_month
 220
 221 Start date month (maestro/solo cards only)
 222
 223 =item paystart_year
 224
 225 Start date year (maestro/solo cards only)
 226
 227 =item payissue
 228
 229 Issue number (maestro/solo cards only)
 230
 231 =item payname
 232
 233 Name on card or billing name
 234
 235 =item payip
 236
 237 IP address from which payment information was received
 238
 239 =item tax
 240
 241 Tax exempt, empty or `Y'
 242
 243 =item usernum
 244
 245 Order taker (see L<FS::access_user>)
 246
 247 =item comments
 248
 249 Comments (optional)
 250
 251 =item referral_custnum
 252
 253 Referring customer number
 254
 255 =item spool_cdr
 256
 257 Enable individual CDR spooling, empty or `Y'
 258
 259 =item dundate
 260
 261 A suggestion to events (see L<FS::part_bill_event">) to delay until this unix timestamp
 262
 263 =item squelch_cdr
 264
 265 Discourage individual CDR printing, empty or `Y'
 266
 267 =item edit_subject
 268
 269 Allow self-service editing of ticket subjects, empty or 'Y'
 270
 271 =item calling_list_exempt
 272
 273 Do not call, empty or 'Y'
 274
 275 =back
 276
 277 =head1 METHODS
 278
 279 =over 4
 280
 281 =item new HASHREF
 282
 283 Creates a new customer.  To add the customer to the database, see L<"insert">.
 284
 285 Note that this stores the hash reference, not a distinct copy of the hash it
 286 points to.  You can ask the object for a copy with the I<hash> method.
 287
 288 =cut
 289
 290 sub table { 'cust_main'; }
 291
 292 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 293
 294 Adds this customer to the database.  If there is an error, returns the error,
 295 otherwise returns false.
 296
 297 Usually the customer's location will not yet exist in the database, and
 298 the C<bill_location> and C<ship_location> pseudo-fields must be set to
 299 uninserted L<FS::cust_location> objects.  These will be inserted and linked
 300 (in both directions) to the new customer record.  If they're references
 301 to the same object, they will become the same location.
 302
 303 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 304 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 305 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 306 hash reference is equivalent to not supplying this parameter.  There should be
 307 a better explanation of this, but until then, here's an example:
 308
 309   use Tie::RefHash;
 310   tie %hash, 'Tie::RefHash'; #this part is important
 311   %hash = (
 312     $cust_pkg => [ $svc_acct ],
 313     ...
 314   );
 315   $cust_main->insert( \%hash );
 316
 317 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
 318 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
 319 expected and rollback the entire transaction; it is not necessary to call
 320 check_invoicing_list first.  The invoicing_list is set after the records in the
 321 CUST_PKG_HASHREF above are inserted, so it is now possible to set an
 322 invoicing_list destination to the newly-created svc_acct.  Here's an example:
 323
 324   $cust_main->insert( {}, [ $email, 'POST' ] );
 325
 326 Currently available options are: I<depend_jobnum>, I<noexport>,
 327 I<tax_exemption> and I<prospectnum>.
 328
 329 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 330 on the supplied jobnum (they will not run until the specific job completes).
 331 This can be used to defer provisioning until some action completes (such
 332 as running the customer's credit card successfully).
 333
 334 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 335 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 336 the B<reexport> method.)
 337
 338 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
 339 of tax names and exemption numbers.  FS::cust_main_exemption records will be
 340 created and inserted.
 341
 342 If I<prospectnum> is set, moves contacts and locations from that prospect.
 343
 344 =cut
 345
 346 sub insert {
 347   my $self = shift;
 348   my $cust_pkgs = @_ ? shift : {};
 349   my $invoicing_list = @_ ? shift : '';
 350   my %options = @_;
 351   warn "$me insert called with options ".
 352        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 353     if $DEBUG;
 354
 355   local $SIG{HUP} = 'IGNORE';
 356   local $SIG{INT} = 'IGNORE';
 357   local $SIG{QUIT} = 'IGNORE';
 358   local $SIG{TERM} = 'IGNORE';
 359   local $SIG{TSTP} = 'IGNORE';
 360   local $SIG{PIPE} = 'IGNORE';
 361
 362   my $oldAutoCommit = $FS::UID::AutoCommit;
 363   local $FS::UID::AutoCommit = 0;
 364   my $dbh = dbh;
 365
 366   my $prepay_identifier = '';
 367   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = (0, 0, 0, 0, 0);
 368   my $payby = '';
 369   if ( $self->payby eq 'PREPAY' ) {
 370
 371     $self->payby('BILL');
 372     $prepay_identifier = $self->payinfo;
 373     $self->payinfo('');
 374
 375     warn "  looking up prepaid card $prepay_identifier\n"
 376       if $DEBUG > 1;
 377
 378     my $error = $self->get_prepay( $prepay_identifier,
 379                                    'amount_ref'     => \$amount,
 380                                    'seconds_ref'    => \$seconds,
 381                                    'upbytes_ref'    => \$upbytes,
 382                                    'downbytes_ref'  => \$downbytes,
 383                                    'totalbytes_ref' => \$totalbytes,
 384                                  );
 385     if ( $error ) {
 386       $dbh->rollback if $oldAutoCommit;
 387       #return "error applying prepaid card (transaction rolled back): $error";
 388       return $error;
 389     }
 390
 391     $payby = 'PREP' if $amount;
 392
 393   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD)$/ ) {
 394
 395     $payby = $1;
 396     $self->payby('BILL');
 397     $amount = $self->paid;
 398
 399   }
 400
 401   # insert locations
 402   foreach my $l (qw(bill_location ship_location)) {
 403     my $loc = delete $self->hashref->{$l};
 404     # XXX if we're moving a prospect's locations, do that here
 405     if ( !$loc ) {
 406       return "$l not set";
 407     }
 408
 409     if ( !$loc->locationnum ) {
 410       # warn the location that we're going to insert it with no custnum
 411       $loc->set(custnum_pending => 1);
 412       warn "  inserting $l\n"
 413         if $DEBUG > 1;
 414       my $error = $loc->insert;
 415       if ( $error ) {
 416         $dbh->rollback if $oldAutoCommit;
 417         my $label = $l eq 'ship_location' ? 'service' : 'billing';
 418         return "$error (in $label location)";
 419       }
 420     }
 421     elsif ( ($loc->custnum || 0) > 0 or $loc->prospectnum ) {
 422       # then it somehow belongs to another customer--shouldn't happen
 423       $dbh->rollback if $oldAutoCommit;
 424       return "$l belongs to customer ".$loc->custnum;
 425     }
 426     # else it already belongs to this customer
 427     # (happens when ship_location is identical to bill_location)
 428
 429     $self->set($l.'num', $loc->locationnum);
 430
 431     if ( $self->get($l.'num') eq '' ) {
 432       $dbh->rollback if $oldAutoCommit;
 433       return "$l not set";
 434     }
 435   }
 436
 437   warn "  inserting $self\n"
 438     if $DEBUG > 1;
 439
 440   $self->signupdate(time) unless $self->signupdate;
 441
 442   $self->auto_agent_custid()
 443     if $conf->config('cust_main-auto_agent_custid') && ! $self->agent_custid;
 444
 445   my $error = $self->SUPER::insert;
 446   if ( $error ) {
 447     $dbh->rollback if $oldAutoCommit;
 448     #return "inserting cust_main record (transaction rolled back): $error";
 449     return $error;
 450   }
 451
 452   # now set cust_location.custnum
 453   foreach my $l (qw(bill_location ship_location)) {
 454     warn "  setting $l.custnum\n"
 455       if $DEBUG > 1;
 456     my $loc = $self->$l;
 457     unless ( $loc->custnum ) {
 458       $loc->set(custnum => $self->custnum);
 459       $error ||= $loc->replace;
 460     }
 461
 462     if ( $error ) {
 463       $dbh->rollback if $oldAutoCommit;
 464       return "error setting $l custnum: $error";
 465     }
 466   }
 467
 468   warn "  setting invoicing list\n"
 469     if $DEBUG > 1;
 470
 471   if ( $invoicing_list ) {
 472     $error = $self->check_invoicing_list( $invoicing_list );
 473     if ( $error ) {
 474       $dbh->rollback if $oldAutoCommit;
 475       #return "checking invoicing_list (transaction rolled back): $error";
 476       return $error;
 477     }
 478     $self->invoicing_list( $invoicing_list );
 479   }
 480
 481   warn "  setting customer tags\n"
 482     if $DEBUG > 1;
 483
 484   foreach my $tagnum ( @{ $self->tagnum || [] } ) {
 485     my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
 486                                       'custnum' => $self->custnum };
 487     my $error = $cust_tag->insert;
 488     if ( $error ) {
 489       $dbh->rollback if $oldAutoCommit;
 490       return $error;
 491     }
 492   }
 493
 494   my $prospectnum = delete $options{'prospectnum'};
 495   if ( $prospectnum ) {
 496
 497     warn "  moving contacts and locations from prospect $prospectnum\n"
 498       if $DEBUG > 1;
 499
 500     my $prospect_main =
 501       qsearchs('prospect_main', { 'prospectnum' => $prospectnum } );
 502     unless ( $prospect_main ) {
 503       $dbh->rollback if $oldAutoCommit;
 504       return "Unknown prospectnum $prospectnum";
 505     }
 506     $prospect_main->custnum($self->custnum);
 507     $prospect_main->disabled('Y');
 508     my $error = $prospect_main->replace;
 509     if ( $error ) {
 510       $dbh->rollback if $oldAutoCommit;
 511       return $error;
 512     }
 513
 514     my @contact = $prospect_main->contact;
 515     my @cust_location = $prospect_main->cust_location;
 516     my @qual = $prospect_main->qual;
 517
 518     foreach my $r ( @contact, @cust_location, @qual ) {
 519       $r->prospectnum('');
 520       $r->custnum($self->custnum);
 521       my $error = $r->replace;
 522       if ( $error ) {
 523         $dbh->rollback if $oldAutoCommit;
 524         return $error;
 525       }
 526     }
 527
 528   }
 529
 530   warn "  setting cust_main_exemption\n"
 531     if $DEBUG > 1;
 532
 533   my $tax_exemption = delete $options{'tax_exemption'};
 534   if ( $tax_exemption ) {
 535
 536     $tax_exemption = { map { $_ => '' } @$tax_exemption }
 537       if ref($tax_exemption) eq 'ARRAY';
 538
 539     foreach my $taxname ( keys %$tax_exemption ) {
 540       my $cust_main_exemption = new FS::cust_main_exemption {
 541         'custnum'       => $self->custnum,
 542         'taxname'       => $taxname,
 543         'exempt_number' => $tax_exemption->{$taxname},
 544       };
 545       my $error = $cust_main_exemption->insert;
 546       if ( $error ) {
 547         $dbh->rollback if $oldAutoCommit;
 548         return "inserting cust_main_exemption (transaction rolled back): $error";
 549       }
 550     }
 551   }
 552
 553   if ( $self->can('start_copy_skel') ) {
 554     my $error = $self->start_copy_skel;
 555     if ( $error ) {
 556       $dbh->rollback if $oldAutoCommit;
 557       return $error;
 558     }
 559   }
 560
 561   warn "  ordering packages\n"
 562     if $DEBUG > 1;
 563
 564   $error = $self->order_pkgs( $cust_pkgs,
 565                               %options,
 566                               'seconds_ref'    => \$seconds,
 567                               'upbytes_ref'    => \$upbytes,
 568                               'downbytes_ref'  => \$downbytes,
 569                               'totalbytes_ref' => \$totalbytes,
 570                             );
 571   if ( $error ) {
 572     $dbh->rollback if $oldAutoCommit;
 573     return $error;
 574   }
 575
 576   if ( $seconds ) {
 577     $dbh->rollback if $oldAutoCommit;
 578     return "No svc_acct record to apply pre-paid time";
 579   }
 580   if ( $upbytes || $downbytes || $totalbytes ) {
 581     $dbh->rollback if $oldAutoCommit;
 582     return "No svc_acct record to apply pre-paid data";
 583   }
 584
 585   if ( $amount ) {
 586     warn "  inserting initial $payby payment of $amount\n"
 587       if $DEBUG > 1;
 588     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 589     if ( $error ) {
 590       $dbh->rollback if $oldAutoCommit;
 591       return "inserting payment (transaction rolled back): $error";
 592     }
 593   }
 594
 595   unless ( $import || $skip_fuzzyfiles ) {
 596     warn "  queueing fuzzyfiles update\n"
 597       if $DEBUG > 1;
 598     $error = $self->queue_fuzzyfiles_update;
 599     if ( $error ) {
 600       $dbh->rollback if $oldAutoCommit;
 601       return "updating fuzzy search cache: $error";
 602     }
 603   }
 604
 605   # FS::geocode_Mixin::after_insert or something?
 606   if ( $conf->config('tax_district_method') and !$import ) {
 607     # if anything non-empty, try to look it up
 608     my $queue = new FS::queue {
 609       'job'     => 'FS::geocode_Mixin::process_district_update',
 610       'custnum' => $self->custnum,
 611     };
 612     my $error = $queue->insert( ref($self), $self->custnum );
 613     if ( $error ) {
 614       $dbh->rollback if $oldAutoCommit;
 615       return "queueing tax district update: $error";
 616     }
 617   }
 618
 619   # cust_main exports!
 620   warn "  exporting\n" if $DEBUG > 1;
 621
 622   my $export_args = $options{'export_args'} || [];
 623
 624   my @part_export =
 625     map qsearch( 'part_export', {exportnum=>$_} ),
 626       $conf->config('cust_main-exports'); #, $agentnum
 627
 628   foreach my $part_export ( @part_export ) {
 629     my $error = $part_export->export_insert($self, @$export_args);
 630     if ( $error ) {
 631       $dbh->rollback if $oldAutoCommit;
 632       return "exporting to ". $part_export->exporttype.
 633              " (transaction rolled back): $error";
 634     }
 635   }
 636
 637   #foreach my $depend_jobnum ( @$depend_jobnums ) {
 638   #    warn "[$me] inserting dependancies on supplied job $depend_jobnum\n"
 639   #      if $DEBUG;
 640   #    foreach my $jobnum ( @jobnums ) {
 641   #      my $queue = qsearchs('queue', { 'jobnum' => $jobnum } );
 642   #      warn "[$me] inserting dependancy for job $jobnum on $depend_jobnum\n"
 643   #        if $DEBUG;
 644   #      my $error = $queue->depend_insert($depend_jobnum);
 645   #      if ( $error ) {
 646   #        $dbh->rollback if $oldAutoCommit;
 647   #        return "error queuing job dependancy: $error";
 648   #      }
 649   #    }
 650   #  }
 651   #
 652   #}
 653   #
 654   #if ( exists $options{'jobnums'} ) {
 655   #  push @{ $options{'jobnums'} }, @jobnums;
 656   #}
 657
 658   warn "  insert complete; committing transaction\n"
 659     if $DEBUG > 1;
 660
 661   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 662   '';
 663
 664 }
 665
 666 use File::CounterFile;
 667 sub auto_agent_custid {
 668   my $self = shift;
 669
 670   my $format = $conf->config('cust_main-auto_agent_custid');
 671   my $agent_custid;
 672   if ( $format eq '1YMMXXXXXXXX' ) {
 673
 674     my $counter = new File::CounterFile 'cust_main.agent_custid';
 675     $counter->lock;
 676
 677     my $ym = 100000000000 + time2str('%y%m00000000', time);
 678     if ( $ym > $counter->value ) {
 679       $counter->{'value'} = $agent_custid = $ym;
 680       $counter->{'updated'} = 1;
 681     } else {
 682       $agent_custid = $counter->inc;
 683     }
 684
 685     $counter->unlock;
 686
 687   } else {
 688     die "Unknown cust_main-auto_agent_custid format: $format";
 689   }
 690
 691   $self->agent_custid($agent_custid);
 692
 693 }
 694
 695 =item PACKAGE METHODS
 696
 697 Documentation on customer package methods has been moved to
 698 L<FS::cust_main::Packages>.
 699
 700 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 701
 702 Recharges this (existing) customer with the specified prepaid card (see
 703 L<FS::prepay_credit>), specified either by I<identifier> or as an
 704 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 705 returns false.
 706
 707 Optionally, five scalar references can be passed as well.  They will have their
 708 values filled in with the amount, number of seconds, and number of upload,
 709 download, and total bytes applied by this prepaid card.
 710
 711 =cut
 712
 713 #the ref bullshit here should be refactored like get_prepay.  MyAccount.pm is
 714 #the only place that uses these args
 715 sub recharge_prepay {
 716   my( $self, $prepay_credit, $amountref, $secondsref,
 717       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 718
 719   local $SIG{HUP} = 'IGNORE';
 720   local $SIG{INT} = 'IGNORE';
 721   local $SIG{QUIT} = 'IGNORE';
 722   local $SIG{TERM} = 'IGNORE';
 723   local $SIG{TSTP} = 'IGNORE';
 724   local $SIG{PIPE} = 'IGNORE';
 725
 726   my $oldAutoCommit = $FS::UID::AutoCommit;
 727   local $FS::UID::AutoCommit = 0;
 728   my $dbh = dbh;
 729
 730   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 731
 732   my $error = $self->get_prepay( $prepay_credit,
 733                                  'amount_ref'     => \$amount,
 734                                  'seconds_ref'    => \$seconds,
 735                                  'upbytes_ref'    => \$upbytes,
 736                                  'downbytes_ref'  => \$downbytes,
 737                                  'totalbytes_ref' => \$totalbytes,
 738                                )
 739            || $self->increment_seconds($seconds)
 740            || $self->increment_upbytes($upbytes)
 741            || $self->increment_downbytes($downbytes)
 742            || $self->increment_totalbytes($totalbytes)
 743            || $self->insert_cust_pay_prepay( $amount,
 744                                              ref($prepay_credit)
 745                                                ? $prepay_credit->identifier
 746                                                : $prepay_credit
 747                                            );
 748
 749   if ( $error ) {
 750     $dbh->rollback if $oldAutoCommit;
 751     return $error;
 752   }
 753
 754   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 755   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 756   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 757   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 758   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 759
 760   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 761   '';
 762
 763 }
 764
 765 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , OPTION => VALUE ... ]
 766
 767 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 768 specified either by I<identifier> or as an FS::prepay_credit object.
 769
 770 Available options are: I<amount_ref>, I<seconds_ref>, I<upbytes_ref>, I<downbytes_ref>, and I<totalbytes_ref>.  The scalars (provided by references) will be
 771 incremented by the values of the prepaid card.
 772
 773 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 774 check or set this customer's I<agentnum>.
 775
 776 If there is an error, returns the error, otherwise returns false.
 777
 778 =cut
 779
 780
 781 sub get_prepay {
 782   my( $self, $prepay_credit, %opt ) = @_;
 783
 784   local $SIG{HUP} = 'IGNORE';
 785   local $SIG{INT} = 'IGNORE';
 786   local $SIG{QUIT} = 'IGNORE';
 787   local $SIG{TERM} = 'IGNORE';
 788   local $SIG{TSTP} = 'IGNORE';
 789   local $SIG{PIPE} = 'IGNORE';
 790
 791   my $oldAutoCommit = $FS::UID::AutoCommit;
 792   local $FS::UID::AutoCommit = 0;
 793   my $dbh = dbh;
 794
 795   unless ( ref($prepay_credit) ) {
 796
 797     my $identifier = $prepay_credit;
 798
 799     $prepay_credit = qsearchs(
 800       'prepay_credit',
 801       { 'identifier' => $identifier },
 802       '',
 803       'FOR UPDATE'
 804     );
 805
 806     unless ( $prepay_credit ) {
 807       $dbh->rollback if $oldAutoCommit;
 808       return "Invalid prepaid card: ". $identifier;
 809     }
 810
 811   }
 812
 813   if ( $prepay_credit->agentnum ) {
 814     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 815       $dbh->rollback if $oldAutoCommit;
 816       return "prepaid card not valid for agent ". $self->agentnum;
 817     }
 818     $self->agentnum($prepay_credit->agentnum);
 819   }
 820
 821   my $error = $prepay_credit->delete;
 822   if ( $error ) {
 823     $dbh->rollback if $oldAutoCommit;
 824     return "removing prepay_credit (transaction rolled back): $error";
 825   }
 826
 827   ${ $opt{$_.'_ref'} } += $prepay_credit->$_()
 828     for grep $opt{$_.'_ref'}, qw( amount seconds upbytes downbytes totalbytes );
 829
 830   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 831   '';
 832
 833 }
 834
 835 =item increment_upbytes SECONDS
 836
 837 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 838 the specified number of upbytes.  If there is an error, returns the error,
 839 otherwise returns false.
 840
 841 =cut
 842
 843 sub increment_upbytes {
 844   _increment_column( shift, 'upbytes', @_);
 845 }
 846
 847 =item increment_downbytes SECONDS
 848
 849 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 850 the specified number of downbytes.  If there is an error, returns the error,
 851 otherwise returns false.
 852
 853 =cut
 854
 855 sub increment_downbytes {
 856   _increment_column( shift, 'downbytes', @_);
 857 }
 858
 859 =item increment_totalbytes SECONDS
 860
 861 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 862 the specified number of totalbytes.  If there is an error, returns the error,
 863 otherwise returns false.
 864
 865 =cut
 866
 867 sub increment_totalbytes {
 868   _increment_column( shift, 'totalbytes', @_);
 869 }
 870
 871 =item increment_seconds SECONDS
 872
 873 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 874 the specified number of seconds.  If there is an error, returns the error,
 875 otherwise returns false.
 876
 877 =cut
 878
 879 sub increment_seconds {
 880   _increment_column( shift, 'seconds', @_);
 881 }
 882
 883 =item _increment_column AMOUNT
 884
 885 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 886 the specified number of seconds or bytes.  If there is an error, returns
 887 the error, otherwise returns false.
 888
 889 =cut
 890
 891 sub _increment_column {
 892   my( $self, $column, $amount ) = @_;
 893   warn "$me increment_column called: $column, $amount\n"
 894     if $DEBUG;
 895
 896   return '' unless $amount;
 897
 898   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
 899                       $self->ncancelled_pkgs;
 900
 901   if ( ! @cust_pkg ) {
 902     return 'No packages with primary or single services found'.
 903            ' to apply pre-paid time';
 904   } elsif ( scalar(@cust_pkg) > 1 ) {
 905     #maybe have a way to specify the package/account?
 906     return 'Multiple packages found to apply pre-paid time';
 907   }
 908
 909   my $cust_pkg = $cust_pkg[0];
 910   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
 911     if $DEBUG > 1;
 912
 913   my @cust_svc =
 914     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
 915
 916   if ( ! @cust_svc ) {
 917     return 'No account found to apply pre-paid time';
 918   } elsif ( scalar(@cust_svc) > 1 ) {
 919     return 'Multiple accounts found to apply pre-paid time';
 920   }
 921
 922   my $svc_acct = $cust_svc[0]->svc_x;
 923   warn "  found service svcnum ". $svc_acct->pkgnum.
 924        ' ('. $svc_acct->email. ")\n"
 925     if $DEBUG > 1;
 926
 927   $column = "increment_$column";
 928   $svc_acct->$column($amount);
 929
 930 }
 931
 932 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
 933
 934 Inserts a prepayment in the specified amount for this customer.  An optional
 935 second argument can specify the prepayment identifier for tracking purposes.
 936 If there is an error, returns the error, otherwise returns false.
 937
 938 =cut
 939
 940 sub insert_cust_pay_prepay {
 941   shift->insert_cust_pay('PREP', @_);
 942 }
 943
 944 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
 945
 946 Inserts a cash payment in the specified amount for this customer.  An optional
 947 second argument can specify the payment identifier for tracking purposes.
 948 If there is an error, returns the error, otherwise returns false.
 949
 950 =cut
 951
 952 sub insert_cust_pay_cash {
 953   shift->insert_cust_pay('CASH', @_);
 954 }
 955
 956 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
 957
 958 Inserts a Western Union payment in the specified amount for this customer.  An
 959 optional second argument can specify the prepayment identifier for tracking
 960 purposes.  If there is an error, returns the error, otherwise returns false.
 961
 962 =cut
 963
 964 sub insert_cust_pay_west {
 965   shift->insert_cust_pay('WEST', @_);
 966 }
 967
 968 sub insert_cust_pay {
 969   my( $self, $payby, $amount ) = splice(@_, 0, 3);
 970   my $payinfo = scalar(@_) ? shift : '';
 971
 972   my $cust_pay = new FS::cust_pay {
 973     'custnum' => $self->custnum,
 974     'paid'    => sprintf('%.2f', $amount),
 975     #'_date'   => #date the prepaid card was purchased???
 976     'payby'   => $payby,
 977     'payinfo' => $payinfo,
 978   };
 979   $cust_pay->insert;
 980
 981 }
 982
 983 =item reexport
 984
 985 This method is deprecated.  See the I<depend_jobnum> option to the insert and
 986 order_pkgs methods for a better way to defer provisioning.
 987
 988 Re-schedules all exports by calling the B<reexport> method of all associated
 989 packages (see L<FS::cust_pkg>).  If there is an error, returns the error;
 990 otherwise returns false.
 991
 992 =cut
 993
 994 sub reexport {
 995   my $self = shift;
 996
 997   carp "WARNING: FS::cust_main::reexport is deprectated; ".
 998        "use the depend_jobnum option to insert or order_pkgs to delay export";
 999
1000   local $SIG{HUP} = 'IGNORE';
1001   local $SIG{INT} = 'IGNORE';
1002   local $SIG{QUIT} = 'IGNORE';
1003   local $SIG{TERM} = 'IGNORE';
1004   local $SIG{TSTP} = 'IGNORE';
1005   local $SIG{PIPE} = 'IGNORE';
1006
1007   my $oldAutoCommit = $FS::UID::AutoCommit;
1008   local $FS::UID::AutoCommit = 0;
1009   my $dbh = dbh;
1010
1011   foreach my $cust_pkg ( $self->ncancelled_pkgs ) {
1012     my $error = $cust_pkg->reexport;
1013     if ( $error ) {
1014       $dbh->rollback if $oldAutoCommit;
1015       return $error;
1016     }
1017   }
1018
1019   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1020   '';
1021
1022 }
1023
1024 =item delete [ OPTION => VALUE ... ]
1025
1026 This deletes the customer.  If there is an error, returns the error, otherwise
1027 returns false.
1028
1029 This will completely remove all traces of the customer record.  This is not
1030 what you want when a customer cancels service; for that, cancel all of the
1031 customer's packages (see L</cancel>).
1032
1033 If the customer has any uncancelled packages, you need to pass a new (valid)
1034 customer number for those packages to be transferred to, as the "new_customer"
1035 option.  Cancelled packages will be deleted.  Did I mention that this is NOT
1036 what you want when a customer cancels service and that you really should be
1037 looking at L<FS::cust_pkg/cancel>?
1038
1039 You can't delete a customer with invoices (see L<FS::cust_bill>),
1040 statements (see L<FS::cust_statement>), credits (see L<FS::cust_credit>),
1041 payments (see L<FS::cust_pay>) or refunds (see L<FS::cust_refund>), unless you
1042 set the "delete_financials" option to a true value.
1043
1044 =cut
1045
1046 sub delete {
1047   my( $self, %opt ) = @_;
1048
1049   local $SIG{HUP} = 'IGNORE';
1050   local $SIG{INT} = 'IGNORE';
1051   local $SIG{QUIT} = 'IGNORE';
1052   local $SIG{TERM} = 'IGNORE';
1053   local $SIG{TSTP} = 'IGNORE';
1054   local $SIG{PIPE} = 'IGNORE';
1055
1056   my $oldAutoCommit = $FS::UID::AutoCommit;
1057   local $FS::UID::AutoCommit = 0;
1058   my $dbh = dbh;
1059
1060   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1061      $dbh->rollback if $oldAutoCommit;
1062      return "Can't delete a master agent customer";
1063   }
1064
1065   #use FS::access_user
1066   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1067      $dbh->rollback if $oldAutoCommit;
1068      return "Can't delete a master employee customer";
1069   }
1070
1071   tie my %financial_tables, 'Tie::IxHash',
1072     'cust_bill'      => 'invoices',
1073     'cust_statement' => 'statements',
1074     'cust_credit'    => 'credits',
1075     'cust_pay'       => 'payments',
1076     'cust_refund'    => 'refunds',
1077   ;
1078
1079   foreach my $table ( keys %financial_tables ) {
1080
1081     my @records = $self->$table();
1082
1083     if ( @records && ! $opt{'delete_financials'} ) {
1084       $dbh->rollback if $oldAutoCommit;
1085       return "Can't delete a customer with ". $financial_tables{$table};
1086     }
1087
1088     foreach my $record ( @records ) {
1089       my $error = $record->delete;
1090       if ( $error ) {
1091         $dbh->rollback if $oldAutoCommit;
1092         return "Error deleting ". $financial_tables{$table}. ": $error\n";
1093       }
1094     }
1095
1096   }
1097
1098   my @cust_pkg = $self->ncancelled_pkgs;
1099   if ( @cust_pkg ) {
1100     my $new_custnum = $opt{'new_custnum'};
1101     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1102       $dbh->rollback if $oldAutoCommit;
1103       return "Invalid new customer number: $new_custnum";
1104     }
1105     foreach my $cust_pkg ( @cust_pkg ) {
1106       my %hash = $cust_pkg->hash;
1107       $hash{'custnum'} = $new_custnum;
1108       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1109       my $error = $new_cust_pkg->replace($cust_pkg,
1110                                          options => { $cust_pkg->options },
1111                                         );
1112       if ( $error ) {
1113         $dbh->rollback if $oldAutoCommit;
1114         return $error;
1115       }
1116     }
1117   }
1118   my @cancelled_cust_pkg = $self->all_pkgs;
1119   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1120     my $error = $cust_pkg->delete;
1121     if ( $error ) {
1122       $dbh->rollback if $oldAutoCommit;
1123       return $error;
1124     }
1125   }
1126
1127   #cust_tax_adjustment in financials?
1128   #cust_pay_pending?  ouch
1129   #cust_recon?
1130   foreach my $table (qw(
1131     cust_main_invoice cust_main_exemption cust_tag cust_attachment contact
1132     cust_location cust_main_note cust_tax_adjustment
1133     cust_pay_void cust_pay_batch queue cust_tax_exempt
1134   )) {
1135     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1136       my $error = $record->delete;
1137       if ( $error ) {
1138         $dbh->rollback if $oldAutoCommit;
1139         return $error;
1140       }
1141     }
1142   }
1143
1144   my $sth = $dbh->prepare(
1145     'UPDATE cust_main SET referral_custnum = NULL WHERE referral_custnum = ?'
1146   ) or do {
1147     my $errstr = $dbh->errstr;
1148     $dbh->rollback if $oldAutoCommit;
1149     return $errstr;
1150   };
1151   $sth->execute($self->custnum) or do {
1152     my $errstr = $sth->errstr;
1153     $dbh->rollback if $oldAutoCommit;
1154     return $errstr;
1155   };
1156
1157   #tickets
1158
1159   my $ticket_dbh = '';
1160   if ($conf->config('ticket_system') eq 'RT_Internal') {
1161     $ticket_dbh = $dbh;
1162   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1163     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1164     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1165       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1166   }
1167
1168   if ( $ticket_dbh ) {
1169
1170     my $ticket_sth = $ticket_dbh->prepare(
1171       'DELETE FROM Links WHERE Target = ?'
1172     ) or do {
1173       my $errstr = $ticket_dbh->errstr;
1174       $dbh->rollback if $oldAutoCommit;
1175       return $errstr;
1176     };
1177     $ticket_sth->execute('freeside://freeside/cust_main/'.$self->custnum)
1178       or do {
1179         my $errstr = $ticket_sth->errstr;
1180         $dbh->rollback if $oldAutoCommit;
1181         return $errstr;
1182       };
1183
1184     #check and see if the customer is the only link on the ticket, and
1185     #if so, set the ticket to deleted status in RT?
1186     #maybe someday, for now this will at least fix tickets not displaying
1187
1188   }
1189
1190   #delete the customer record
1191
1192   my $error = $self->SUPER::delete;
1193   if ( $error ) {
1194     $dbh->rollback if $oldAutoCommit;
1195     return $error;
1196   }
1197
1198   # cust_main exports!
1199
1200   #my $export_args = $options{'export_args'} || [];
1201
1202   my @part_export =
1203     map qsearch( 'part_export', {exportnum=>$_} ),
1204       $conf->config('cust_main-exports'); #, $agentnum
1205
1206   foreach my $part_export ( @part_export ) {
1207     my $error = $part_export->export_delete( $self ); #, @$export_args);
1208     if ( $error ) {
1209       $dbh->rollback if $oldAutoCommit;
1210       return "exporting to ". $part_export->exporttype.
1211              " (transaction rolled back): $error";
1212     }
1213   }
1214
1215   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1216   '';
1217
1218 }
1219
1220 =item merge NEW_CUSTNUM [ , OPTION => VALUE ... ]
1221
1222 This merges this customer into the provided new custnum, and then deletes the
1223 customer.  If there is an error, returns the error, otherwise returns false.
1224
1225 The source customer's name, company name, phone numbers, agent,
1226 referring customer, customer class, advertising source, order taker, and
1227 billing information (except balance) are discarded.
1228
1229 All packages are moved to the target customer.  Packages with package locations
1230 are preserved.  Packages without package locations are moved to a new package
1231 location with the source customer's service/shipping address.
1232
1233 All invoices, statements, payments, credits and refunds are moved to the target
1234 customer.  The source customer's balance is added to the target customer.
1235
1236 All notes, attachments, tickets and customer tags are moved to the target
1237 customer.
1238
1239 Change history is not currently moved.
1240
1241 =cut
1242
1243 sub merge {
1244   my( $self, $new_custnum, %opt ) = @_;
1245
1246   return "Can't merge a customer into self" if $self->custnum == $new_custnum;
1247
1248   my $new_cust_main = qsearchs( 'cust_main', { 'custnum' => $new_custnum } )
1249     or return "Invalid new customer number: $new_custnum";
1250
1251   return 'Access denied: "Merge customer across agents" access right required to merge into a customer of a different agent'
1252     if $self->agentnum != $new_cust_main->agentnum
1253     && ! $FS::CurrentUser::CurrentUser->access_right('Merge customer across agents');
1254
1255   local $SIG{HUP} = 'IGNORE';
1256   local $SIG{INT} = 'IGNORE';
1257   local $SIG{QUIT} = 'IGNORE';
1258   local $SIG{TERM} = 'IGNORE';
1259   local $SIG{TSTP} = 'IGNORE';
1260   local $SIG{PIPE} = 'IGNORE';
1261
1262   my $oldAutoCommit = $FS::UID::AutoCommit;
1263   local $FS::UID::AutoCommit = 0;
1264   my $dbh = dbh;
1265
1266   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1267      $dbh->rollback if $oldAutoCommit;
1268      return "Can't merge a master agent customer";
1269   }
1270
1271   #use FS::access_user
1272   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1273      $dbh->rollback if $oldAutoCommit;
1274      return "Can't merge a master employee customer";
1275   }
1276
1277   if ( qsearch('cust_pay_pending', { 'custnum' => $self->custnum,
1278                                      'status'  => { op=>'!=', value=>'done' },
1279                                    }
1280               )
1281   ) {
1282      $dbh->rollback if $oldAutoCommit;
1283      return "Can't merge a customer with pending payments";
1284   }
1285
1286   tie my %financial_tables, 'Tie::IxHash',
1287     'cust_bill'      => 'invoices',
1288     'cust_bill_void' => 'voided invoices',
1289     'cust_statement' => 'statements',
1290     'cust_credit'    => 'credits',
1291     'cust_pay'       => 'payments',
1292     'cust_pay_void'  => 'voided payments',
1293     'cust_refund'    => 'refunds',
1294   ;
1295
1296   foreach my $table ( keys %financial_tables ) {
1297
1298     my @records = $self->$table();
1299
1300     foreach my $record ( @records ) {
1301       $record->custnum($new_custnum);
1302       my $error = $record->replace;
1303       if ( $error ) {
1304         $dbh->rollback if $oldAutoCommit;
1305         return "Error merging ". $financial_tables{$table}. ": $error\n";
1306       }
1307     }
1308
1309   }
1310
1311   my $name = $self->ship_name; #?
1312
1313   my $locationnum = '';
1314   foreach my $cust_pkg ( $self->all_pkgs ) {
1315     $cust_pkg->custnum($new_custnum);
1316
1317     unless ( $cust_pkg->locationnum ) {
1318       unless ( $locationnum ) {
1319         my $cust_location = new FS::cust_location {
1320           $self->location_hash,
1321           'custnum' => $new_custnum,
1322         };
1323         my $error = $cust_location->insert;
1324         if ( $error ) {
1325           $dbh->rollback if $oldAutoCommit;
1326           return $error;
1327         }
1328         $locationnum = $cust_location->locationnum;
1329       }
1330       $cust_pkg->locationnum($locationnum);
1331     }
1332
1333     my $error = $cust_pkg->replace;
1334     if ( $error ) {
1335       $dbh->rollback if $oldAutoCommit;
1336       return $error;
1337     }
1338
1339     # add customer (ship) name to svc_phone.phone_name if blank
1340     my @cust_svc = $cust_pkg->cust_svc;
1341     foreach my $cust_svc (@cust_svc) {
1342       my($label, $value, $svcdb) = $cust_svc->label;
1343       next unless $svcdb eq 'svc_phone';
1344       my $svc_phone = $cust_svc->svc_x;
1345       next if $svc_phone->phone_name;
1346       $svc_phone->phone_name($name);
1347       my $error = $svc_phone->replace;
1348       if ( $error ) {
1349         $dbh->rollback if $oldAutoCommit;
1350         return $error;
1351       }
1352     }
1353
1354   }
1355
1356   #not considered:
1357   # cust_tax_exempt (texas tax exemptions)
1358   # cust_recon (some sort of not-well understood thing for OnPac)
1359
1360   #these are moved over
1361   foreach my $table (qw(
1362     cust_tag cust_location contact cust_attachment cust_main_note
1363     cust_tax_adjustment cust_pay_batch queue
1364   )) {
1365     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1366       $record->custnum($new_custnum);
1367       my $error = $record->replace;
1368       if ( $error ) {
1369         $dbh->rollback if $oldAutoCommit;
1370         return $error;
1371       }
1372     }
1373   }
1374
1375   #these aren't preserved
1376   foreach my $table (qw(
1377     cust_main_exemption cust_main_invoice
1378   )) {
1379     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1380       my $error = $record->delete;
1381       if ( $error ) {
1382         $dbh->rollback if $oldAutoCommit;
1383         return $error;
1384       }
1385     }
1386   }
1387
1388
1389   my $sth = $dbh->prepare(
1390     'UPDATE cust_main SET referral_custnum = ? WHERE referral_custnum = ?'
1391   ) or do {
1392     my $errstr = $dbh->errstr;
1393     $dbh->rollback if $oldAutoCommit;
1394     return $errstr;
1395   };
1396   $sth->execute($new_custnum, $self->custnum) or do {
1397     my $errstr = $sth->errstr;
1398     $dbh->rollback if $oldAutoCommit;
1399     return $errstr;
1400   };
1401
1402   #tickets
1403
1404   my $ticket_dbh = '';
1405   if ($conf->config('ticket_system') eq 'RT_Internal') {
1406     $ticket_dbh = $dbh;
1407   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1408     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1409     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1410       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1411   }
1412
1413   if ( $ticket_dbh ) {
1414
1415     my $ticket_sth = $ticket_dbh->prepare(
1416       'UPDATE Links SET Target = ? WHERE Target = ?'
1417     ) or do {
1418       my $errstr = $ticket_dbh->errstr;
1419       $dbh->rollback if $oldAutoCommit;
1420       return $errstr;
1421     };
1422     $ticket_sth->execute('freeside://freeside/cust_main/'.$new_custnum,
1423                          'freeside://freeside/cust_main/'.$self->custnum)
1424       or do {
1425         my $errstr = $ticket_sth->errstr;
1426         $dbh->rollback if $oldAutoCommit;
1427         return $errstr;
1428       };
1429
1430   }
1431
1432   #delete the customer record
1433
1434   my $error = $self->delete;
1435   if ( $error ) {
1436     $dbh->rollback if $oldAutoCommit;
1437     return $error;
1438   }
1439
1440   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1441   '';
1442
1443 }
1444
1445 =item replace [ OLD_RECORD ] [ INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
1446
1447 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1448 returns the error, otherwise returns false.
1449
1450 To change the customer's address, set the pseudo-fields C<bill_location> and
1451 C<ship_location>.  The address will still only change if at least one of the
1452 address fields differs from the existing values.
1453
1454 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
1455 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
1456 expected and rollback the entire transaction; it is not necessary to call
1457 check_invoicing_list first.  Here's an example:
1458
1459   $new_cust_main->replace( $old_cust_main, [ $email, 'POST' ] );
1460
1461 Currently available options are: I<tax_exemption>.
1462
1463 The I<tax_exemption> option can be set to an arrayref of tax names or a hashref
1464 of tax names and exemption numbers.  FS::cust_main_exemption records will be
1465 deleted and inserted as appropriate.
1466
1467 =cut
1468
1469 sub replace {
1470   my $self = shift;
1471
1472   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
1473               ? shift
1474               : $self->replace_old;
1475
1476   my @param = @_;
1477
1478   warn "$me replace called\n"
1479     if $DEBUG;
1480
1481   my $curuser = $FS::CurrentUser::CurrentUser;
1482   if (    $self->payby eq 'COMP'
1483        && $self->payby ne $old->payby
1484        && ! $curuser->access_right('Complimentary customer')
1485      )
1486   {
1487     return "You are not permitted to create complimentary accounts.";
1488   }
1489
1490   local($ignore_expired_card) = 1
1491     if $old->payby  =~ /^(CARD|DCRD)$/
1492     && $self->payby =~ /^(CARD|DCRD)$/
1493     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1494
1495   local($ignore_banned_card) = 1
1496     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
1497          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
1498     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1499
1500   return "Invoicing locale is required"
1501     if $old->locale
1502     && ! $self->locale
1503     && $conf->exists('cust_main-require_locale');
1504
1505   local $SIG{HUP} = 'IGNORE';
1506   local $SIG{INT} = 'IGNORE';
1507   local $SIG{QUIT} = 'IGNORE';
1508   local $SIG{TERM} = 'IGNORE';
1509   local $SIG{TSTP} = 'IGNORE';
1510   local $SIG{PIPE} = 'IGNORE';
1511
1512   my $oldAutoCommit = $FS::UID::AutoCommit;
1513   local $FS::UID::AutoCommit = 0;
1514   my $dbh = dbh;
1515
1516   for my $l (qw(bill_location ship_location)) {
1517     my $old_loc = $old->$l;
1518     my $new_loc = $self->$l;
1519
1520     if ( !$new_loc->locationnum ) {
1521       # changing location
1522       # If the new location is all empty fields, or if it's identical to
1523       # the old location in all fields, don't replace.
1524       my @nonempty = grep { $new_loc->$_ } $self->location_fields;
1525       next if !@nonempty;
1526       my @unlike = grep { $new_loc->$_ ne $old_loc->$_ } $self->location_fields;
1527
1528       if ( @unlike or $old_loc->disabled ) {
1529         warn "  changed $l fields: ".join(',',@unlike)."\n"
1530           if $DEBUG;
1531         $new_loc->set(custnum => $self->custnum);
1532
1533         # insert it--the old location will be disabled later
1534         my $error = $new_loc->insert;
1535         if ( $error ) {
1536           $dbh->rollback if $oldAutoCommit;
1537           return $error;
1538         }
1539
1540       } else {
1541       # no fields have changed and $old_loc isn't disabled, so don't change it
1542         next;
1543       }
1544
1545     }
1546     elsif ( $new_loc->custnum ne $self->custnum or $new_loc->prospectnum ) {
1547       $dbh->rollback if $oldAutoCommit;
1548       return "$l belongs to customer ".$new_loc->custnum;
1549     }
1550     # else the new location belongs to this customer so we're good
1551
1552     # set the foo_locationnum now that we have one.
1553     $self->set($l.'num', $new_loc->locationnum);
1554
1555   } #for $l
1556
1557   my $error = $self->SUPER::replace($old);
1558
1559   if ( $error ) {
1560     $dbh->rollback if $oldAutoCommit;
1561     return $error;
1562   }
1563
1564   # now move packages to the new service location
1565   $self->set('ship_location', ''); #flush cache
1566   if ( $old->ship_locationnum and # should only be null during upgrade...
1567        $old->ship_locationnum != $self->ship_locationnum ) {
1568     $error = $old->ship_location->move_to($self->ship_location);
1569     if ( $error ) {
1570       $dbh->rollback if $oldAutoCommit;
1571       return $error;
1572     }
1573   }
1574   # don't move packages based on the billing location, but
1575   # disable it if it's no longer in use
1576   if ( $old->bill_locationnum and
1577        $old->bill_locationnum != $self->bill_locationnum ) {
1578     $error = $old->bill_location->disable_if_unused;
1579     if ( $error ) {
1580       $dbh->rollback if $oldAutoCommit;
1581       return $error;
1582     }
1583   }
1584
1585   if ( @param && ref($param[0]) eq 'ARRAY' ) { # INVOICING_LIST_ARYREF
1586     my $invoicing_list = shift @param;
1587     $error = $self->check_invoicing_list( $invoicing_list );
1588     if ( $error ) {
1589       $dbh->rollback if $oldAutoCommit;
1590       return $error;
1591     }
1592     $self->invoicing_list( $invoicing_list );
1593   }
1594
1595   if ( $self->exists('tagnum') ) { #so we don't delete these on edit by accident
1596
1597     #this could be more efficient than deleting and re-inserting, if it matters
1598     foreach my $cust_tag (qsearch('cust_tag', {'custnum'=>$self->custnum} )) {
1599       my $error = $cust_tag->delete;
1600       if ( $error ) {
1601         $dbh->rollback if $oldAutoCommit;
1602         return $error;
1603       }
1604     }
1605     foreach my $tagnum ( @{ $self->tagnum || [] } ) {
1606       my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
1607                                         'custnum' => $self->custnum };
1608       my $error = $cust_tag->insert;
1609       if ( $error ) {
1610         $dbh->rollback if $oldAutoCommit;
1611         return $error;
1612       }
1613     }
1614
1615   }
1616
1617   my %options = @param;
1618
1619   my $tax_exemption = delete $options{'tax_exemption'};
1620   if ( $tax_exemption ) {
1621
1622     $tax_exemption = { map { $_ => '' } @$tax_exemption }
1623       if ref($tax_exemption) eq 'ARRAY';
1624
1625     my %cust_main_exemption =
1626       map { $_->taxname => $_ }
1627           qsearch('cust_main_exemption', { 'custnum' => $old->custnum } );
1628
1629     foreach my $taxname ( keys %$tax_exemption ) {
1630
1631       if ( $cust_main_exemption{$taxname} &&
1632            $cust_main_exemption{$taxname}->exempt_number eq $tax_exemption->{$taxname}
1633          )
1634       {
1635         delete $cust_main_exemption{$taxname};
1636         next;
1637       }
1638
1639       my $cust_main_exemption = new FS::cust_main_exemption {
1640         'custnum'       => $self->custnum,
1641         'taxname'       => $taxname,
1642         'exempt_number' => $tax_exemption->{$taxname},
1643       };
1644       my $error = $cust_main_exemption->insert;
1645       if ( $error ) {
1646         $dbh->rollback if $oldAutoCommit;
1647         return "inserting cust_main_exemption (transaction rolled back): $error";
1648       }
1649     }
1650
1651     foreach my $cust_main_exemption ( values %cust_main_exemption ) {
1652       my $error = $cust_main_exemption->delete;
1653       if ( $error ) {
1654         $dbh->rollback if $oldAutoCommit;
1655         return "deleting cust_main_exemption (transaction rolled back): $error";
1656       }
1657     }
1658
1659   }
1660
1661   if ( $self->payby =~ /^(CARD|CHEK|LECB)$/
1662        && ( ( $self->get('payinfo') ne $old->get('payinfo')
1663               && $self->get('payinfo') !~ /^99\d{14}$/
1664             )
1665             || grep { $self->get($_) ne $old->get($_) } qw(paydate payname)
1666           )
1667      )
1668   {
1669
1670     # card/check/lec info has changed, want to retry realtime_ invoice events
1671     my $error = $self->retry_realtime;
1672     if ( $error ) {
1673       $dbh->rollback if $oldAutoCommit;
1674       return $error;
1675     }
1676   }
1677
1678   unless ( $import || $skip_fuzzyfiles ) {
1679     $error = $self->queue_fuzzyfiles_update;
1680     if ( $error ) {
1681       $dbh->rollback if $oldAutoCommit;
1682       return "updating fuzzy search cache: $error";
1683     }
1684   }
1685
1686   # tax district update in cust_location
1687
1688   # cust_main exports!
1689
1690   my $export_args = $options{'export_args'} || [];
1691
1692   my @part_export =
1693     map qsearch( 'part_export', {exportnum=>$_} ),
1694       $conf->config('cust_main-exports'); #, $agentnum
1695
1696   foreach my $part_export ( @part_export ) {
1697     my $error = $part_export->export_replace( $self, $old, @$export_args);
1698     if ( $error ) {
1699       $dbh->rollback if $oldAutoCommit;
1700       return "exporting to ". $part_export->exporttype.
1701              " (transaction rolled back): $error";
1702     }
1703   }
1704
1705   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1706   '';
1707
1708 }
1709
1710 =item queue_fuzzyfiles_update
1711
1712 Used by insert & replace to update the fuzzy search cache
1713
1714 =cut
1715
1716 use FS::cust_main::Search;
1717 sub queue_fuzzyfiles_update {
1718   my $self = shift;
1719
1720   local $SIG{HUP} = 'IGNORE';
1721   local $SIG{INT} = 'IGNORE';
1722   local $SIG{QUIT} = 'IGNORE';
1723   local $SIG{TERM} = 'IGNORE';
1724   local $SIG{TSTP} = 'IGNORE';
1725   local $SIG{PIPE} = 'IGNORE';
1726
1727   my $oldAutoCommit = $FS::UID::AutoCommit;
1728   local $FS::UID::AutoCommit = 0;
1729   my $dbh = dbh;
1730
1731   my @locations = $self->bill_location;
1732   push @locations, $self->ship_location if $self->has_ship_address;
1733   foreach my $location (@locations) {
1734     my $queue = new FS::queue {
1735       'job' => 'FS::cust_main::Search::append_fuzzyfiles'
1736     };
1737     my @args = map $location->get($_), @FS::cust_main::Search::fuzzyfields;
1738     my $error = $queue->insert( @args );
1739     if ( $error ) {
1740       $dbh->rollback if $oldAutoCommit;
1741       return "queueing job (transaction rolled back): $error";
1742     }
1743   }
1744
1745   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1746   '';
1747
1748 }
1749
1750 =item check
1751
1752 Checks all fields to make sure this is a valid customer record.  If there is
1753 an error, returns the error, otherwise returns false.  Called by the insert
1754 and replace methods.
1755
1756 =cut
1757
1758 sub check {
1759   my $self = shift;
1760
1761   warn "$me check BEFORE: \n". $self->_dump
1762     if $DEBUG > 2;
1763
1764   my $error =
1765     $self->ut_numbern('custnum')
1766     || $self->ut_number('agentnum')
1767     || $self->ut_textn('agent_custid')
1768     || $self->ut_number('refnum')
1769     || $self->ut_foreign_key('bill_locationnum', 'cust_location','locationnum')
1770     || $self->ut_foreign_key('ship_locationnum', 'cust_location','locationnum')
1771     || $self->ut_foreign_keyn('classnum', 'cust_class', 'classnum')
1772     || $self->ut_textn('custbatch')
1773     || $self->ut_name('last')
1774     || $self->ut_name('first')
1775     || $self->ut_snumbern('signupdate')
1776     || $self->ut_snumbern('birthdate')
1777     || $self->ut_snumbern('spouse_birthdate')
1778     || $self->ut_snumbern('anniversary_date')
1779     || $self->ut_textn('company')
1780     || $self->ut_anything('comments')
1781     || $self->ut_numbern('referral_custnum')
1782     || $self->ut_textn('stateid')
1783     || $self->ut_textn('stateid_state')
1784     || $self->ut_textn('invoice_terms')
1785     || $self->ut_floatn('cdr_termination_percentage')
1786     || $self->ut_floatn('credit_limit')
1787     || $self->ut_numbern('billday')
1788     || $self->ut_numbern('prorate_day')
1789     || $self->ut_enum('edit_subject', [ '', 'Y' ] )
1790     || $self->ut_enum('calling_list_exempt', [ '', 'Y' ] )
1791     || $self->ut_enum('invoice_noemail', [ '', 'Y' ] )
1792     || $self->ut_enum('locale', [ '', FS::Locales->locales ])
1793   ;
1794
1795   #barf.  need message catalogs.  i18n.  etc.
1796   $error .= "Please select an advertising source."
1797     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1798   return $error if $error;
1799
1800   return "Unknown agent"
1801     unless qsearchs( 'agent', { 'agentnum' => $self->agentnum } );
1802
1803   return "Unknown refnum"
1804     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1805
1806   return "Unknown referring custnum: ". $self->referral_custnum
1807     unless ! $self->referral_custnum
1808            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1809
1810   if ( $self->ss eq '' ) {
1811     $self->ss('');
1812   } else {
1813     my $ss = $self->ss;
1814     $ss =~ s/\D//g;
1815     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1816       or return "Illegal social security number: ". $self->ss;
1817     $self->ss("$1-$2-$3");
1818   }
1819
1820   # cust_main_county verification now handled by cust_location check
1821
1822   $error =
1823        $self->ut_phonen('daytime', $self->country)
1824     || $self->ut_phonen('night',   $self->country)
1825     || $self->ut_phonen('fax',     $self->country)
1826     || $self->ut_phonen('mobile',  $self->country)
1827   ;
1828   return $error if $error;
1829
1830   if ( $conf->exists('cust_main-require_phone', $self->agentnum)
1831        && ! $import
1832        && ! length($self->daytime) && ! length($self->night) && ! length($self->mobile)
1833      ) {
1834
1835     my $daytime_label = FS::Msgcat::_gettext('daytime') =~ /^(daytime)?$/
1836                           ? 'Day Phone'
1837                           : FS::Msgcat::_gettext('daytime');
1838     my $night_label = FS::Msgcat::_gettext('night') =~ /^(night)?$/
1839                         ? 'Night Phone'
1840                         : FS::Msgcat::_gettext('night');
1841
1842     my $mobile_label = FS::Msgcat::_gettext('mobile') =~ /^(mobile)?$/
1843                         ? 'Mobile Phone'
1844                         : FS::Msgcat::_gettext('mobile');
1845
1846     return "$daytime_label, $night_label or $mobile_label is required"
1847
1848   }
1849
1850   #$self->payby =~ /^(CARD|DCRD|CHEK|DCHK|LECB|BILL|COMP|PREPAY|CASH|WEST|MCRD)$/
1851   #  or return "Illegal payby: ". $self->payby;
1852   #$self->payby($1);
1853   FS::payby->can_payby($self->table, $self->payby)
1854     or return "Illegal payby: ". $self->payby;
1855
1856   $error =    $self->ut_numbern('paystart_month')
1857            || $self->ut_numbern('paystart_year')
1858            || $self->ut_numbern('payissue')
1859            || $self->ut_textn('paytype')
1860   ;
1861   return $error if $error;
1862
1863   if ( $self->payip eq '' ) {
1864     $self->payip('');
1865   } else {
1866     $error = $self->ut_ip('payip');
1867     return $error if $error;
1868   }
1869
1870   # If it is encrypted and the private key is not availaible then we can't
1871   # check the credit card.
1872   my $check_payinfo = ! $self->is_encrypted($self->payinfo);
1873
1874   # Need some kind of global flag to accept invalid cards, for testing
1875   # on scrubbed data.
1876   if ( !$import && $check_payinfo && $self->payby =~ /^(CARD|DCRD)$/ ) {
1877
1878     my $payinfo = $self->payinfo;
1879     $payinfo =~ s/\D//g;
1880     $payinfo =~ /^(\d{13,16}|\d{8,9})$/
1881       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1882     $payinfo = $1;
1883     $self->payinfo($payinfo);
1884     validate($payinfo)
1885       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1886
1887     return gettext('unknown_card_type')
1888       if $self->payinfo !~ /^99\d{14}$/ #token
1889       && cardtype($self->payinfo) eq "Unknown";
1890
1891     unless ( $ignore_banned_card ) {
1892       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1893       if ( $ban ) {
1894         if ( $ban->bantype eq 'warn' ) {
1895           #or others depending on value of $ban->reason ?
1896           return '_duplicate_card'.
1897                  ': disabled from'. time2str('%a %h %o at %r', $ban->_date).
1898                  ' until '.         time2str('%a %h %o at %r', $ban->_end_date).
1899                  ' (ban# '. $ban->bannum. ')'
1900             unless $self->override_ban_warn;
1901         } else {
1902           return 'Banned credit card: banned on '.
1903                  time2str('%a %h %o at %r', $ban->_date).
1904                  ' by '. $ban->otaker.
1905                  ' (ban# '. $ban->bannum. ')';
1906         }
1907       }
1908     }
1909
1910     if (length($self->paycvv) && !$self->is_encrypted($self->paycvv)) {
1911       if ( cardtype($self->payinfo) eq 'American Express card' ) {
1912         $self->paycvv =~ /^(\d{4})$/
1913           or return "CVV2 (CID) for American Express cards is four digits.";
1914         $self->paycvv($1);
1915       } else {
1916         $self->paycvv =~ /^(\d{3})$/
1917           or return "CVV2 (CVC2/CID) is three digits.";
1918         $self->paycvv($1);
1919       }
1920     } else {
1921       $self->paycvv('');
1922     }
1923
1924     my $cardtype = cardtype($payinfo);
1925     if ( $cardtype =~ /^(Switch|Solo)$/i ) {
1926
1927       return "Start date or issue number is required for $cardtype cards"
1928         unless $self->paystart_month && $self->paystart_year or $self->payissue;
1929
1930       return "Start month must be between 1 and 12"
1931         if $self->paystart_month
1932            and $self->paystart_month < 1 || $self->paystart_month > 12;
1933
1934       return "Start year must be 1990 or later"
1935         if $self->paystart_year
1936            and $self->paystart_year < 1990;
1937
1938       return "Issue number must be beween 1 and 99"
1939         if $self->payissue
1940           and $self->payissue < 1 || $self->payissue > 99;
1941
1942     } else {
1943       $self->paystart_month('');
1944       $self->paystart_year('');
1945       $self->payissue('');
1946     }
1947
1948   } elsif ( $check_payinfo && $self->payby =~ /^(CHEK|DCHK)$/ ) {
1949
1950     my $payinfo = $self->payinfo;
1951     $payinfo =~ s/[^\d\@\.]//g;
1952     if ( $conf->config('echeck-country') eq 'CA' ) {
1953       $payinfo =~ /^(\d+)\@(\d{5})\.(\d{3})$/
1954         or return 'invalid echeck account@branch.bank';
1955       $payinfo = "$1\@$2.$3";
1956     } elsif ( $conf->config('echeck-country') eq 'US' ) {
1957       $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
1958       $payinfo = "$1\@$2";
1959     } else {
1960       $payinfo =~ /^(\d+)\@(\d+)$/ or return 'invalid echeck account@routing';
1961       $payinfo = "$1\@$2";
1962     }
1963     $self->payinfo($payinfo);
1964     $self->paycvv('');
1965
1966     unless ( $ignore_banned_card ) {
1967       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1968       if ( $ban ) {
1969         if ( $ban->bantype eq 'warn' ) {
1970           #or others depending on value of $ban->reason ?
1971           return '_duplicate_ach' unless $self->override_ban_warn;
1972         } else {
1973           return 'Banned ACH account: banned on '.
1974                  time2str('%a %h %o at %r', $ban->_date).
1975                  ' by '. $ban->otaker.
1976                  ' (ban# '. $ban->bannum. ')';
1977         }
1978       }
1979     }
1980
1981   } elsif ( $self->payby eq 'LECB' ) {
1982
1983     my $payinfo = $self->payinfo;
1984     $payinfo =~ s/\D//g;
1985     $payinfo =~ /^1?(\d{10})$/ or return 'invalid btn billing telephone number';
1986     $payinfo = $1;
1987     $self->payinfo($payinfo);
1988     $self->paycvv('');
1989
1990   } elsif ( $self->payby eq 'BILL' ) {
1991
1992     $error = $self->ut_textn('payinfo');
1993     return "Illegal P.O. number: ". $self->payinfo if $error;
1994     $self->paycvv('');
1995
1996   } elsif ( $self->payby eq 'COMP' ) {
1997
1998     my $curuser = $FS::CurrentUser::CurrentUser;
1999     if (    ! $self->custnum
2000          && ! $curuser->access_right('Complimentary customer')
2001        )
2002     {
2003       return "You are not permitted to create complimentary accounts."
2004     }
2005
2006     $error = $self->ut_textn('payinfo');
2007     return "Illegal comp account issuer: ". $self->payinfo if $error;
2008     $self->paycvv('');
2009
2010   } elsif ( $self->payby eq 'PREPAY' ) {
2011
2012     my $payinfo = $self->payinfo;
2013     $payinfo =~ s/\W//g; #anything else would just confuse things
2014     $self->payinfo($payinfo);
2015     $error = $self->ut_alpha('payinfo');
2016     return "Illegal prepayment identifier: ". $self->payinfo if $error;
2017     return "Unknown prepayment identifier"
2018       unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
2019     $self->paycvv('');
2020
2021   }
2022
2023   if ( $self->paydate eq '' || $self->paydate eq '-' ) {
2024     return "Expiration date required"
2025       unless $self->payby =~ /^(BILL|PREPAY|CHEK|DCHK|LECB|CASH|WEST|MCRD)$/;
2026     $self->paydate('');
2027   } else {
2028     my( $m, $y );
2029     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
2030       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
2031     } elsif ( $self->paydate =~ /^19(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2032       ( $m, $y ) = ( $2, "19$1" );
2033     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2034       ( $m, $y ) = ( $3, "20$2" );
2035     } else {
2036       return "Illegal expiration date: ". $self->paydate;
2037     }
2038     $m = sprintf('%02d',$m);
2039     $self->paydate("$y-$m-01");
2040     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
2041     return gettext('expired_card')
2042       if !$import
2043       && !$ignore_expired_card
2044       && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
2045   }
2046
2047   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
2048        ( ! $conf->exists('require_cardname')
2049          || $self->payby !~ /^(CARD|DCRD)$/  )
2050   ) {
2051     $self->payname( $self->first. " ". $self->getfield('last') );
2052   } else {
2053     $self->payname =~ /^([\w \,\.\-\'\&]+)$/
2054       or return gettext('illegal_name'). " payname: ". $self->payname;
2055     $self->payname($1);
2056   }
2057
2058   return "Please select an invoicing locale"
2059     if ! $self->locale
2060     && ! $self->custnum
2061     && $conf->exists('cust_main-require_locale');
2062
2063   foreach my $flag (qw( tax spool_cdr squelch_cdr archived email_csv_cdr )) {
2064     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
2065     $self->$flag($1);
2066   }
2067
2068   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
2069
2070   warn "$me check AFTER: \n". $self->_dump
2071     if $DEBUG > 2;
2072
2073   $self->SUPER::check;
2074 }
2075
2076 =item addr_fields
2077
2078 Returns a list of fields which have ship_ duplicates.
2079
2080 =cut
2081
2082 sub addr_fields {
2083   qw( last first company
2084       address1 address2 city county state zip country
2085       latitude longitude
2086       daytime night fax mobile
2087     );
2088 }
2089
2090 =item has_ship_address
2091
2092 Returns true if this customer record has a separate shipping address.
2093
2094 =cut
2095
2096 sub has_ship_address {
2097   my $self = shift;
2098   $self->bill_locationnum != $self->ship_locationnum;
2099 }
2100
2101 =item location_hash
2102
2103 Returns a list of key/value pairs, with the following keys: address1,
2104 adddress2, city, county, state, zip, country, district, and geocode.  The
2105 shipping address is used if present.
2106
2107 =cut
2108
2109 sub location_hash {
2110   my $self = shift;
2111   $self->ship_location->location_hash;
2112 }
2113
2114 =item cust_location
2115
2116 Returns all locations (see L<FS::cust_location>) for this customer.
2117
2118 =cut
2119
2120 sub cust_location {
2121   my $self = shift;
2122   qsearch('cust_location', { 'custnum' => $self->custnum,
2123                              'prospectnum' => '' } );
2124 }
2125
2126 =item cust_contact
2127
2128 Returns all contacts (see L<FS::contact>) for this customer.
2129
2130 =cut
2131
2132 #already used :/ sub contact {
2133 sub cust_contact {
2134   my $self = shift;
2135   qsearch('contact', { 'custnum' => $self->custnum } );
2136 }
2137
2138 =item unsuspend
2139
2140 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
2141 and L<FS::cust_pkg>) for this customer.  Always returns a list: an empty list
2142 on success or a list of errors.
2143
2144 =cut
2145
2146 sub unsuspend {
2147   my $self = shift;
2148   grep { $_->unsuspend } $self->suspended_pkgs;
2149 }
2150
2151 =item suspend
2152
2153 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
2154
2155 Returns a list: an empty list on success or a list of errors.
2156
2157 =cut
2158
2159 sub suspend {
2160   my $self = shift;
2161   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
2162 }
2163
2164 =item suspend_if_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2165
2166 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
2167 PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref instead
2168 of a list of pkgparts; the hashref has the following keys:
2169
2170 =over 4
2171
2172 =item pkgparts - listref of pkgparts
2173
2174 =item (other options are passed to the suspend method)
2175
2176 =back
2177
2178
2179 Returns a list: an empty list on success or a list of errors.
2180
2181 =cut
2182
2183 sub suspend_if_pkgpart {
2184   my $self = shift;
2185   my (@pkgparts, %opt);
2186   if (ref($_[0]) eq 'HASH'){
2187     @pkgparts = @{$_[0]{pkgparts}};
2188     %opt      = %{$_[0]};
2189   }else{
2190     @pkgparts = @_;
2191   }
2192   grep { $_->suspend(%opt) }
2193     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
2194       $self->unsuspended_pkgs;
2195 }
2196
2197 =item suspend_unless_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2198
2199 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
2200 given PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref
2201 instead of a list of pkgparts; the hashref has the following keys:
2202
2203 =over 4
2204
2205 =item pkgparts - listref of pkgparts
2206
2207 =item (other options are passed to the suspend method)
2208
2209 =back
2210
2211 Returns a list: an empty list on success or a list of errors.
2212
2213 =cut
2214
2215 sub suspend_unless_pkgpart {
2216   my $self = shift;
2217   my (@pkgparts, %opt);
2218   if (ref($_[0]) eq 'HASH'){
2219     @pkgparts = @{$_[0]{pkgparts}};
2220     %opt      = %{$_[0]};
2221   }else{
2222     @pkgparts = @_;
2223   }
2224   grep { $_->suspend(%opt) }
2225     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
2226       $self->unsuspended_pkgs;
2227 }
2228
2229 =item cancel [ OPTION => VALUE ... ]
2230
2231 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
2232
2233 Available options are:
2234
2235 =over 4
2236
2237 =item quiet - can be set true to supress email cancellation notices.
2238
2239 =item reason - can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
2240
2241 =item ban - can be set true to ban this customer's credit card or ACH information, if present.
2242
2243 =item nobill - can be set true to skip billing if it might otherwise be done.
2244
2245 =back
2246
2247 Always returns a list: an empty list on success or a list of errors.
2248
2249 =cut
2250
2251 # nb that dates are not specified as valid options to this method
2252
2253 sub cancel {
2254   my( $self, %opt ) = @_;
2255
2256   warn "$me cancel called on customer ". $self->custnum. " with options ".
2257        join(', ', map { "$_: $opt{$_}" } keys %opt ). "\n"
2258     if $DEBUG;
2259
2260   return ( 'access denied' )
2261     unless $FS::CurrentUser::CurrentUser->access_right('Cancel customer');
2262
2263   if ( $opt{'ban'} && $self->payby =~ /^(CARD|DCRD|CHEK|DCHK)$/ ) {
2264
2265     #should try decryption (we might have the private key)
2266     # and if not maybe queue a job for the server that does?
2267     return ( "Can't (yet) ban encrypted credit cards" )
2268       if $self->is_encrypted($self->payinfo);
2269
2270     my $ban = new FS::banned_pay $self->_new_banned_pay_hashref;
2271     my $error = $ban->insert;
2272     return ( $error ) if $error;
2273
2274   }
2275
2276   my @pkgs = $self->ncancelled_pkgs;
2277
2278   if ( !$opt{nobill} && $conf->exists('bill_usage_on_cancel') ) {
2279     $opt{nobill} = 1;
2280     my $error = $self->bill( pkg_list => [ @pkgs ], cancel => 1 );
2281     warn "Error billing during cancel, custnum ". $self->custnum. ": $error"
2282       if $error;
2283   }
2284
2285   warn "$me cancelling ". scalar($self->ncancelled_pkgs). "/".
2286        scalar(@pkgs). " packages for customer ". $self->custnum. "\n"
2287     if $DEBUG;
2288
2289   grep { $_ } map { $_->cancel(%opt) } $self->ncancelled_pkgs;
2290 }
2291
2292 sub _banned_pay_hashref {
2293   my $self = shift;
2294
2295   my %payby2ban = (
2296     'CARD' => 'CARD',
2297     'DCRD' => 'CARD',
2298     'CHEK' => 'CHEK',
2299     'DCHK' => 'CHEK'
2300   );
2301
2302   {
2303     'payby'   => $payby2ban{$self->payby},
2304     'payinfo' => $self->payinfo,
2305     #don't ever *search* on reason! #'reason'  =>
2306   };
2307 }
2308
2309 sub _new_banned_pay_hashref {
2310   my $self = shift;
2311   my $hr = $self->_banned_pay_hashref;
2312   $hr->{payinfo} = md5_base64($hr->{payinfo});
2313   $hr;
2314 }
2315
2316 =item notes
2317
2318 Returns all notes (see L<FS::cust_main_note>) for this customer.
2319
2320 =cut
2321
2322 sub notes {
2323   my($self,$orderby_classnum) = (shift,shift);
2324   my $orderby = "_DATE DESC";
2325   $orderby = "CLASSNUM ASC, $orderby" if $orderby_classnum;
2326   qsearch( 'cust_main_note',
2327            { 'custnum' => $self->custnum },
2328            '',
2329            "ORDER BY $orderby",
2330          );
2331 }
2332
2333 =item agent
2334
2335 Returns the agent (see L<FS::agent>) for this customer.
2336
2337 =cut
2338
2339 sub agent {
2340   my $self = shift;
2341   qsearchs( 'agent', { 'agentnum' => $self->agentnum } );
2342 }
2343
2344 =item agent_name
2345
2346 Returns the agent name (see L<FS::agent>) for this customer.
2347
2348 =cut
2349
2350 sub agent_name {
2351   my $self = shift;
2352   $self->agent->agent;
2353 }
2354
2355 =item cust_tag
2356
2357 Returns any tags associated with this customer, as FS::cust_tag objects,
2358 or an empty list if there are no tags.
2359
2360 =cut
2361
2362 sub cust_tag {
2363   my $self = shift;
2364   qsearch('cust_tag', { 'custnum' => $self->custnum } );
2365 }
2366
2367 =item part_tag
2368
2369 Returns any tags associated with this customer, as FS::part_tag objects,
2370 or an empty list if there are no tags.
2371
2372 =cut
2373
2374 sub part_tag {
2375   my $self = shift;
2376   map $_->part_tag, $self->cust_tag;
2377 }
2378
2379
2380 =item cust_class
2381
2382 Returns the customer class, as an FS::cust_class object, or the empty string
2383 if there is no customer class.
2384
2385 =cut
2386
2387 sub cust_class {
2388   my $self = shift;
2389   if ( $self->classnum ) {
2390     qsearchs('cust_class', { 'classnum' => $self->classnum } );
2391   } else {
2392     return '';
2393   }
2394 }
2395
2396 =item categoryname
2397
2398 Returns the customer category name, or the empty string if there is no customer
2399 category.
2400
2401 =cut
2402
2403 sub categoryname {
2404   my $self = shift;
2405   my $cust_class = $self->cust_class;
2406   $cust_class
2407     ? $cust_class->categoryname
2408     : '';
2409 }
2410
2411 =item classname
2412
2413 Returns the customer class name, or the empty string if there is no customer
2414 class.
2415
2416 =cut
2417
2418 sub classname {
2419   my $self = shift;
2420   my $cust_class = $self->cust_class;
2421   $cust_class
2422     ? $cust_class->classname
2423     : '';
2424 }
2425
2426 =item BILLING METHODS
2427
2428 Documentation on billing methods has been moved to
2429 L<FS::cust_main::Billing>.
2430
2431 =item REALTIME BILLING METHODS
2432
2433 Documentation on realtime billing methods has been moved to
2434 L<FS::cust_main::Billing_Realtime>.
2435
2436 =item remove_cvv
2437
2438 Removes the I<paycvv> field from the database directly.
2439
2440 If there is an error, returns the error, otherwise returns false.
2441
2442 =cut
2443
2444 sub remove_cvv {
2445   my $self = shift;
2446   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2447     or return dbh->errstr;
2448   $sth->execute($self->custnum)
2449     or return $sth->errstr;
2450   $self->paycvv('');
2451   '';
2452 }
2453
2454 =item batch_card OPTION => VALUE...
2455
2456 Adds a payment for this invoice to the pending credit card batch (see
2457 L<FS::cust_pay_batch>), or, if the B<realtime> option is set to a true value,
2458 runs the payment using a realtime gateway.
2459
2460 Options may include:
2461
2462 B<amount>: the amount to be paid; defaults to the customer's balance minus
2463 any payments in transit.
2464
2465 B<payby>: the payment method; defaults to cust_main.payby
2466
2467 B<realtime>: runs this as a realtime payment instead of adding it to a
2468 batch.  Deprecated.
2469
2470 B<invnum>: sets cust_pay_batch.invnum.
2471
2472 B<address1>, B<address2>, B<city>, B<state>, B<zip>, B<country>: sets
2473 the billing address for the payment; defaults to the customer's billing
2474 location.
2475
2476 B<payinfo>, B<paydate>, B<payname>: sets the payment account, expiration
2477 date, and name; defaults to those fields in cust_main.
2478
2479 =cut
2480
2481 sub batch_card {
2482   my ($self, %options) = @_;
2483
2484   my $amount;
2485   if (exists($options{amount})) {
2486     $amount = $options{amount};
2487   }else{
2488     $amount = sprintf("%.2f", $self->balance - $self->in_transit_payments);
2489   }
2490   return '' unless $amount > 0;
2491
2492   my $invnum = delete $options{invnum};
2493   my $payby = $options{payby} || $self->payby;  #still dubious
2494
2495   if ($options{'realtime'}) {
2496     return $self->realtime_bop( FS::payby->payby2bop($self->payby),
2497                                 $amount,
2498                                 %options,
2499                               );
2500   }
2501
2502   my $oldAutoCommit = $FS::UID::AutoCommit;
2503   local $FS::UID::AutoCommit = 0;
2504   my $dbh = dbh;
2505
2506   #this needs to handle mysql as well as Pg, like svc_acct.pm
2507   #(make it into a common function if folks need to do batching with mysql)
2508   $dbh->do("LOCK TABLE pay_batch IN SHARE ROW EXCLUSIVE MODE")
2509     or return "Cannot lock pay_batch: " . $dbh->errstr;
2510
2511   my %pay_batch = (
2512     'status' => 'O',
2513     'payby'  => FS::payby->payby2payment($payby),
2514   );
2515   $pay_batch{agentnum} = $self->agentnum if $conf->exists('batch-spoolagent');
2516
2517   my $pay_batch = qsearchs( 'pay_batch', \%pay_batch );
2518
2519   unless ( $pay_batch ) {
2520     $pay_batch = new FS::pay_batch \%pay_batch;
2521     my $error = $pay_batch->insert;
2522     if ( $error ) {
2523       $dbh->rollback if $oldAutoCommit;
2524       die "error creating new batch: $error\n";
2525     }
2526   }
2527
2528   my $old_cust_pay_batch = qsearchs('cust_pay_batch', {
2529       'batchnum' => $pay_batch->batchnum,
2530       'custnum'  => $self->custnum,
2531   } );
2532
2533   foreach (qw( address1 address2 city state zip country latitude longitude
2534                payby payinfo paydate payname ))
2535   {
2536     $options{$_} = '' unless exists($options{$_});
2537   }
2538
2539   my $loc = $self->bill_location;
2540
2541   my $cust_pay_batch = new FS::cust_pay_batch ( {
2542     'batchnum' => $pay_batch->batchnum,
2543     'invnum'   => $invnum || 0,                    # is there a better value?
2544                                                    # this field should be
2545                                                    # removed...
2546                                                    # cust_bill_pay_batch now
2547     'custnum'  => $self->custnum,
2548     'last'     => $self->getfield('last'),
2549     'first'    => $self->getfield('first'),
2550     'address1' => $options{address1} || $loc->address1,
2551     'address2' => $options{address2} || $loc->address2,
2552     'city'     => $options{city}     || $loc->city,
2553     'state'    => $options{state}    || $loc->state,
2554     'zip'      => $options{zip}      || $loc->zip,
2555     'country'  => $options{country}  || $loc->country,
2556     'payby'    => $options{payby}    || $self->payby,
2557     'payinfo'  => $options{payinfo}  || $self->payinfo,
2558     'exp'      => $options{paydate}  || $self->paydate,
2559     'payname'  => $options{payname}  || $self->payname,
2560     'amount'   => $amount,                         # consolidating
2561   } );
2562
2563   $cust_pay_batch->paybatchnum($old_cust_pay_batch->paybatchnum)
2564     if $old_cust_pay_batch;
2565
2566   my $error;
2567   if ($old_cust_pay_batch) {
2568     $error = $cust_pay_batch->replace($old_cust_pay_batch)
2569   } else {
2570     $error = $cust_pay_batch->insert;
2571   }
2572
2573   if ( $error ) {
2574     $dbh->rollback if $oldAutoCommit;
2575     die $error;
2576   }
2577
2578   my $unapplied =   $self->total_unapplied_credits
2579                   + $self->total_unapplied_payments
2580                   + $self->in_transit_payments;
2581   foreach my $cust_bill ($self->open_cust_bill) {
2582     #$dbh->commit or die $dbh->errstr if $oldAutoCommit;
2583     my $cust_bill_pay_batch = new FS::cust_bill_pay_batch {
2584       'invnum' => $cust_bill->invnum,
2585       'paybatchnum' => $cust_pay_batch->paybatchnum,
2586       'amount' => $cust_bill->owed,
2587       '_date' => time,
2588     };
2589     if ($unapplied >= $cust_bill_pay_batch->amount){
2590       $unapplied -= $cust_bill_pay_batch->amount;
2591       next;
2592     }else{
2593       $cust_bill_pay_batch->amount(sprintf ( "%.2f",
2594                                    $cust_bill_pay_batch->amount - $unapplied ));      $unapplied = 0;
2595     }
2596     $error = $cust_bill_pay_batch->insert;
2597     if ( $error ) {
2598       $dbh->rollback if $oldAutoCommit;
2599       die $error;
2600     }
2601   }
2602
2603   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2604   '';
2605 }
2606
2607 =item total_owed
2608
2609 Returns the total owed for this customer on all invoices
2610 (see L<FS::cust_bill/owed>).
2611
2612 =cut
2613
2614 sub total_owed {
2615   my $self = shift;
2616   $self->total_owed_date(2145859200); #12/31/2037
2617 }
2618
2619 =item total_owed_date TIME
2620
2621 Returns the total owed for this customer on all invoices with date earlier than
2622 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2623 see L<Time::Local> and L<Date::Parse> for conversion functions.
2624
2625 =cut
2626
2627 sub total_owed_date {
2628   my $self = shift;
2629   my $time = shift;
2630
2631   my $custnum = $self->custnum;
2632
2633   my $owed_sql = FS::cust_bill->owed_sql;
2634
2635   my $sql = "
2636     SELECT SUM($owed_sql) FROM cust_bill
2637       WHERE custnum = $custnum
2638         AND _date <= $time
2639   ";
2640
2641   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2642
2643 }
2644
2645 =item total_owed_pkgnum PKGNUM
2646
2647 Returns the total owed on all invoices for this customer's specific package
2648 when using experimental package balances (see L<FS::cust_bill/owed_pkgnum>).
2649
2650 =cut
2651
2652 sub total_owed_pkgnum {
2653   my( $self, $pkgnum ) = @_;
2654   $self->total_owed_date_pkgnum(2145859200, $pkgnum); #12/31/2037
2655 }
2656
2657 =item total_owed_date_pkgnum TIME PKGNUM
2658
2659 Returns the total owed for this customer's specific package when using
2660 experimental package balances on all invoices with date earlier than
2661 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2662 see L<Time::Local> and L<Date::Parse> for conversion functions.
2663
2664 =cut
2665
2666 sub total_owed_date_pkgnum {
2667   my( $self, $time, $pkgnum ) = @_;
2668
2669   my $total_bill = 0;
2670   foreach my $cust_bill (
2671     grep { $_->_date <= $time }
2672       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2673   ) {
2674     $total_bill += $cust_bill->owed_pkgnum($pkgnum);
2675   }
2676   sprintf( "%.2f", $total_bill );
2677
2678 }
2679
2680 =item total_paid
2681
2682 Returns the total amount of all payments.
2683
2684 =cut
2685
2686 sub total_paid {
2687   my $self = shift;
2688   my $total = 0;
2689   $total += $_->paid foreach $self->cust_pay;
2690   sprintf( "%.2f", $total );
2691 }
2692
2693 =item total_unapplied_credits
2694
2695 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2696 customer.  See L<FS::cust_credit/credited>.
2697
2698 =item total_credited
2699
2700 Old name for total_unapplied_credits.  Don't use.
2701
2702 =cut
2703
2704 sub total_credited {
2705   #carp "total_credited deprecated, use total_unapplied_credits";
2706   shift->total_unapplied_credits(@_);
2707 }
2708
2709 sub total_unapplied_credits {
2710   my $self = shift;
2711
2712   my $custnum = $self->custnum;
2713
2714   my $unapplied_sql = FS::cust_credit->unapplied_sql;
2715
2716   my $sql = "
2717     SELECT SUM($unapplied_sql) FROM cust_credit
2718       WHERE custnum = $custnum
2719   ";
2720
2721   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2722
2723 }
2724
2725 =item total_unapplied_credits_pkgnum PKGNUM
2726
2727 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2728 customer.  See L<FS::cust_credit/credited>.
2729
2730 =cut
2731
2732 sub total_unapplied_credits_pkgnum {
2733   my( $self, $pkgnum ) = @_;
2734   my $total_credit = 0;
2735   $total_credit += $_->credited foreach $self->cust_credit_pkgnum($pkgnum);
2736   sprintf( "%.2f", $total_credit );
2737 }
2738
2739
2740 =item total_unapplied_payments
2741
2742 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2743 See L<FS::cust_pay/unapplied>.
2744
2745 =cut
2746
2747 sub total_unapplied_payments {
2748   my $self = shift;
2749
2750   my $custnum = $self->custnum;
2751
2752   my $unapplied_sql = FS::cust_pay->unapplied_sql;
2753
2754   my $sql = "
2755     SELECT SUM($unapplied_sql) FROM cust_pay
2756       WHERE custnum = $custnum
2757   ";
2758
2759   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2760
2761 }
2762
2763 =item total_unapplied_payments_pkgnum PKGNUM
2764
2765 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer's
2766 specific package when using experimental package balances.  See
2767 L<FS::cust_pay/unapplied>.
2768
2769 =cut
2770
2771 sub total_unapplied_payments_pkgnum {
2772   my( $self, $pkgnum ) = @_;
2773   my $total_unapplied = 0;
2774   $total_unapplied += $_->unapplied foreach $self->cust_pay_pkgnum($pkgnum);
2775   sprintf( "%.2f", $total_unapplied );
2776 }
2777
2778
2779 =item total_unapplied_refunds
2780
2781 Returns the total unrefunded refunds (see L<FS::cust_refund>) for this
2782 customer.  See L<FS::cust_refund/unapplied>.
2783
2784 =cut
2785
2786 sub total_unapplied_refunds {
2787   my $self = shift;
2788   my $custnum = $self->custnum;
2789
2790   my $unapplied_sql = FS::cust_refund->unapplied_sql;
2791
2792   my $sql = "
2793     SELECT SUM($unapplied_sql) FROM cust_refund
2794       WHERE custnum = $custnum
2795   ";
2796
2797   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2798
2799 }
2800
2801 =item balance
2802
2803 Returns the balance for this customer (total_owed plus total_unrefunded, minus
2804 total_unapplied_credits minus total_unapplied_payments).
2805
2806 =cut
2807
2808 sub balance {
2809   my $self = shift;
2810   $self->balance_date_range;
2811 }
2812
2813 =item balance_date TIME
2814
2815 Returns the balance for this customer, only considering invoices with date
2816 earlier than TIME (total_owed_date minus total_credited minus
2817 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2818 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2819 functions.
2820
2821 =cut
2822
2823 sub balance_date {
2824   my $self = shift;
2825   $self->balance_date_range(shift);
2826 }
2827
2828 =item balance_date_range [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
2829
2830 Returns the balance for this customer, optionally considering invoices with
2831 date earlier than START_TIME, and not later than END_TIME
2832 (total_owed_date minus total_unapplied_credits minus total_unapplied_payments).
2833
2834 Times are specified as SQL fragments or numeric
2835 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
2836 L<Date::Parse> for conversion functions.  The empty string can be passed
2837 to disable that time constraint completely.
2838
2839 Available options are:
2840
2841 =over 4
2842
2843 =item unapplied_date
2844
2845 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
2846
2847 =back
2848
2849 =cut
2850
2851 sub balance_date_range {
2852   my $self = shift;
2853   my $sql = 'SELECT SUM('. $self->balance_date_sql(@_).
2854             ') FROM cust_main WHERE custnum='. $self->custnum;
2855   sprintf( '%.2f', $self->scalar_sql($sql) || 0 );
2856 }
2857
2858 =item balance_pkgnum PKGNUM
2859
2860 Returns the balance for this customer's specific package when using
2861 experimental package balances (total_owed plus total_unrefunded, minus
2862 total_unapplied_credits minus total_unapplied_payments)
2863
2864 =cut
2865
2866 sub balance_pkgnum {
2867   my( $self, $pkgnum ) = @_;
2868
2869   sprintf( "%.2f",
2870       $self->total_owed_pkgnum($pkgnum)
2871 # n/a - refunds aren't part of pkg-balances since they don't apply to invoices
2872 #    + $self->total_unapplied_refunds_pkgnum($pkgnum)
2873     - $self->total_unapplied_credits_pkgnum($pkgnum)
2874     - $self->total_unapplied_payments_pkgnum($pkgnum)
2875   );
2876 }
2877
2878 =item in_transit_payments
2879
2880 Returns the total of requests for payments for this customer pending in
2881 batches in transit to the bank.  See L<FS::pay_batch> and L<FS::cust_pay_batch>
2882
2883 =cut
2884
2885 sub in_transit_payments {
2886   my $self = shift;
2887   my $in_transit_payments = 0;
2888   foreach my $pay_batch ( qsearch('pay_batch', {
2889     'status' => 'I',
2890   } ) ) {
2891     foreach my $cust_pay_batch ( qsearch('cust_pay_batch', {
2892       'batchnum' => $pay_batch->batchnum,
2893       'custnum' => $self->custnum,
2894     } ) ) {
2895       $in_transit_payments += $cust_pay_batch->amount;
2896     }
2897   }
2898   sprintf( "%.2f", $in_transit_payments );
2899 }
2900
2901 =item payment_info
2902
2903 Returns a hash of useful information for making a payment.
2904
2905 =over 4
2906
2907 =item balance
2908
2909 Current balance.
2910
2911 =item payby
2912
2913 'CARD' (credit card - automatic), 'DCRD' (credit card - on-demand),
2914 'CHEK' (electronic check - automatic), 'DCHK' (electronic check - on-demand),
2915 'LECB' (Phone bill billing), 'BILL' (billing), or 'COMP' (free).
2916
2917 =back
2918
2919 For credit card transactions:
2920
2921 =over 4
2922
2923 =item card_type 1
2924
2925 =item payname
2926
2927 Exact name on card
2928
2929 =back
2930
2931 For electronic check transactions:
2932
2933 =over 4
2934
2935 =item stateid_state
2936
2937 =back
2938
2939 =cut
2940
2941 sub payment_info {
2942   my $self = shift;
2943
2944   my %return = ();
2945
2946   $return{balance} = $self->balance;
2947
2948   $return{payname} = $self->payname
2949                      || ( $self->first. ' '. $self->get('last') );
2950
2951   $return{$_} = $self->bill_location->$_
2952     for qw(address1 address2 city state zip);
2953
2954   $return{payby} = $self->payby;
2955   $return{stateid_state} = $self->stateid_state;
2956
2957   if ( $self->payby =~ /^(CARD|DCRD)$/ ) {
2958     $return{card_type} = cardtype($self->payinfo);
2959     $return{payinfo} = $self->paymask;
2960
2961     @return{'month', 'year'} = $self->paydate_monthyear;
2962
2963   }
2964
2965   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2966     my ($payinfo1, $payinfo2) = split '@', $self->paymask;
2967     $return{payinfo1} = $payinfo1;
2968     $return{payinfo2} = $payinfo2;
2969     $return{paytype}  = $self->paytype;
2970     $return{paystate} = $self->paystate;
2971
2972   }
2973
2974   #doubleclick protection
2975   my $_date = time;
2976   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
2977
2978   %return;
2979
2980 }
2981
2982 =item paydate_monthyear
2983
2984 Returns a two-element list consisting of the month and year of this customer's
2985 paydate (credit card expiration date for CARD customers)
2986
2987 =cut
2988
2989 sub paydate_monthyear {
2990   my $self = shift;
2991   if ( $self->paydate  =~ /^(\d{4})-(\d{1,2})-\d{1,2}$/ ) { #Pg date format
2992     ( $2, $1 );
2993   } elsif ( $self->paydate =~ /^(\d{1,2})-(\d{1,2}-)?(\d{4}$)/ ) {
2994     ( $1, $3 );
2995   } else {
2996     ('', '');
2997   }
2998 }
2999
3000 =item paydate_epoch
3001
3002 Returns the exact time in seconds corresponding to the payment method
3003 expiration date.  For CARD/DCRD customers this is the end of the month;
3004 for others (COMP is the only other payby that uses paydate) it's the start.
3005 Returns 0 if the paydate is empty or set to the far future.
3006
3007 =cut
3008
3009 sub paydate_epoch {
3010   my $self = shift;
3011   my ($month, $year) = $self->paydate_monthyear;
3012   return 0 if !$year or $year >= 2037;
3013   if ( $self->payby eq 'CARD' or $self->payby eq 'DCRD' ) {
3014     $month++;
3015     if ( $month == 13 ) {
3016       $month = 1;
3017       $year++;
3018     }
3019     return timelocal(0,0,0,1,$month-1,$year) - 1;
3020   }
3021   else {
3022     return timelocal(0,0,0,1,$month-1,$year);
3023   }
3024 }
3025
3026 =item paydate_epoch_sql
3027
3028 Class method.  Returns an SQL expression to obtain the payment expiration date
3029 as a number of seconds.
3030
3031 =cut
3032
3033 # Special expiration date behavior for non-CARD/DCRD customers has been
3034 # carefully preserved.  Do we really use that?
3035 sub paydate_epoch_sql {
3036   my $class = shift;
3037   my $table = shift || 'cust_main';
3038   my ($case1, $case2);
3039   if ( driver_name eq 'Pg' ) {
3040     $case1 = "EXTRACT( EPOCH FROM CAST( $table.paydate AS TIMESTAMP ) + INTERVAL '1 month') - 1";
3041     $case2 = "EXTRACT( EPOCH FROM CAST( $table.paydate AS TIMESTAMP ) )";
3042   }
3043   elsif ( lc(driver_name) eq 'mysql' ) {
3044     $case1 = "UNIX_TIMESTAMP( DATE_ADD( CAST( $table.paydate AS DATETIME ), INTERVAL 1 month ) ) - 1";
3045     $case2 = "UNIX_TIMESTAMP( CAST( $table.paydate AS DATETIME ) )";
3046   }
3047   else { return '' }
3048   return "CASE WHEN $table.payby IN('CARD','DCRD')
3049   THEN ($case1)
3050   ELSE ($case2)
3051   END"
3052 }
3053
3054 =item tax_exemption TAXNAME
3055
3056 =cut
3057
3058 sub tax_exemption {
3059   my( $self, $taxname ) = @_;
3060
3061   qsearchs( 'cust_main_exemption', { 'custnum' => $self->custnum,
3062                                      'taxname' => $taxname,
3063                                    },
3064           );
3065 }
3066
3067 =item cust_main_exemption
3068
3069 =cut
3070
3071 sub cust_main_exemption {
3072   my $self = shift;
3073   qsearch( 'cust_main_exemption', { 'custnum' => $self->custnum } );
3074 }
3075
3076 =item invoicing_list [ ARRAYREF ]
3077
3078 If an arguement is given, sets these email addresses as invoice recipients
3079 (see L<FS::cust_main_invoice>).  Errors are not fatal and are not reported
3080 (except as warnings), so use check_invoicing_list first.
3081
3082 Returns a list of email addresses (with svcnum entries expanded).
3083
3084 Note: You can clear the invoicing list by passing an empty ARRAYREF.  You can
3085 check it without disturbing anything by passing nothing.
3086
3087 This interface may change in the future.
3088
3089 =cut
3090
3091 sub invoicing_list {
3092   my( $self, $arrayref ) = @_;
3093
3094   if ( $arrayref ) {
3095     my @cust_main_invoice;
3096     if ( $self->custnum ) {
3097       @cust_main_invoice =
3098         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3099     } else {
3100       @cust_main_invoice = ();
3101     }
3102     foreach my $cust_main_invoice ( @cust_main_invoice ) {
3103       #warn $cust_main_invoice->destnum;
3104       unless ( grep { $cust_main_invoice->address eq $_ } @{$arrayref} ) {
3105         #warn $cust_main_invoice->destnum;
3106         my $error = $cust_main_invoice->delete;
3107         warn $error if $error;
3108       }
3109     }
3110     if ( $self->custnum ) {
3111       @cust_main_invoice =
3112         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3113     } else {
3114       @cust_main_invoice = ();
3115     }
3116     my %seen = map { $_->address => 1 } @cust_main_invoice;
3117     foreach my $address ( @{$arrayref} ) {
3118       next if exists $seen{$address} && $seen{$address};
3119       $seen{$address} = 1;
3120       my $cust_main_invoice = new FS::cust_main_invoice ( {
3121         'custnum' => $self->custnum,
3122         'dest'    => $address,
3123       } );
3124       my $error = $cust_main_invoice->insert;
3125       warn $error if $error;
3126     }
3127   }
3128
3129   if ( $self->custnum ) {
3130     map { $_->address }
3131       qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3132   } else {
3133     ();
3134   }
3135
3136 }
3137
3138 =item check_invoicing_list ARRAYREF
3139
3140 Checks these arguements as valid input for the invoicing_list method.  If there
3141 is an error, returns the error, otherwise returns false.
3142
3143 =cut
3144
3145 sub check_invoicing_list {
3146   my( $self, $arrayref ) = @_;
3147
3148   foreach my $address ( @$arrayref ) {
3149
3150     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
3151       return 'Can\'t add FAX invoice destination with a blank FAX number.';
3152     }
3153
3154     my $cust_main_invoice = new FS::cust_main_invoice ( {
3155       'custnum' => $self->custnum,
3156       'dest'    => $address,
3157     } );
3158     my $error = $self->custnum
3159                 ? $cust_main_invoice->check
3160                 : $cust_main_invoice->checkdest
3161     ;
3162     return $error if $error;
3163
3164   }
3165
3166   return "Email address required"
3167     if $conf->exists('cust_main-require_invoicing_list_email', $self->agentnum)
3168     && ! grep { $_ !~ /^([A-Z]+)$/ } @$arrayref;
3169
3170   '';
3171 }
3172
3173 =item set_default_invoicing_list
3174
3175 Sets the invoicing list to all accounts associated with this customer,
3176 overwriting any previous invoicing list.
3177
3178 =cut
3179
3180 sub set_default_invoicing_list {
3181   my $self = shift;
3182   $self->invoicing_list($self->all_emails);
3183 }
3184
3185 =item all_emails
3186
3187 Returns the email addresses of all accounts provisioned for this customer.
3188
3189 =cut
3190
3191 sub all_emails {
3192   my $self = shift;
3193   my %list;
3194   foreach my $cust_pkg ( $self->all_pkgs ) {
3195     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
3196     my @svc_acct =
3197       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3198         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3199           @cust_svc;
3200     $list{$_}=1 foreach map { $_->email } @svc_acct;
3201   }
3202   keys %list;
3203 }
3204
3205 =item invoicing_list_addpost
3206
3207 Adds postal invoicing to this customer.  If this customer is already configured
3208 to receive postal invoices, does nothing.
3209
3210 =cut
3211
3212 sub invoicing_list_addpost {
3213   my $self = shift;
3214   return if grep { $_ eq 'POST' } $self->invoicing_list;
3215   my @invoicing_list = $self->invoicing_list;
3216   push @invoicing_list, 'POST';
3217   $self->invoicing_list(\@invoicing_list);
3218 }
3219
3220 =item invoicing_list_emailonly
3221
3222 Returns the list of email invoice recipients (invoicing_list without non-email
3223 destinations such as POST and FAX).
3224
3225 =cut
3226
3227 sub invoicing_list_emailonly {
3228   my $self = shift;
3229   warn "$me invoicing_list_emailonly called"
3230     if $DEBUG;
3231   grep { $_ !~ /^([A-Z]+)$/ } $self->invoicing_list;
3232 }
3233
3234 =item invoicing_list_emailonly_scalar
3235
3236 Returns the list of email invoice recipients (invoicing_list without non-email
3237 destinations such as POST and FAX) as a comma-separated scalar.
3238
3239 =cut
3240
3241 sub invoicing_list_emailonly_scalar {
3242   my $self = shift;
3243   warn "$me invoicing_list_emailonly_scalar called"
3244     if $DEBUG;
3245   join(', ', $self->invoicing_list_emailonly);
3246 }
3247
3248 =item referral_custnum_cust_main
3249
3250 Returns the customer who referred this customer (or the empty string, if
3251 this customer was not referred).
3252
3253 Note the difference with referral_cust_main method: This method,
3254 referral_custnum_cust_main returns the single customer (if any) who referred
3255 this customer, while referral_cust_main returns an array of customers referred
3256 BY this customer.
3257
3258 =cut
3259
3260 sub referral_custnum_cust_main {
3261   my $self = shift;
3262   return '' unless $self->referral_custnum;
3263   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3264 }
3265
3266 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
3267
3268 Returns an array of customers referred by this customer (referral_custnum set
3269 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
3270 customers referred by customers referred by this customer and so on, inclusive.
3271 The default behavior is DEPTH 1 (no recursion).
3272
3273 Note the difference with referral_custnum_cust_main method: This method,
3274 referral_cust_main, returns an array of customers referred BY this customer,
3275 while referral_custnum_cust_main returns the single customer (if any) who
3276 referred this customer.
3277
3278 =cut
3279
3280 sub referral_cust_main {
3281   my $self = shift;
3282   my $depth = @_ ? shift : 1;
3283   my $exclude = @_ ? shift : {};
3284
3285   my @cust_main =
3286     map { $exclude->{$_->custnum}++; $_; }
3287       grep { ! $exclude->{ $_->custnum } }
3288         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
3289
3290   if ( $depth > 1 ) {
3291     push @cust_main,
3292       map { $_->referral_cust_main($depth-1, $exclude) }
3293         @cust_main;
3294   }
3295
3296   @cust_main;
3297 }
3298
3299 =item referral_cust_main_ncancelled
3300
3301 Same as referral_cust_main, except only returns customers with uncancelled
3302 packages.
3303
3304 =cut
3305
3306 sub referral_cust_main_ncancelled {
3307   my $self = shift;
3308   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
3309 }
3310
3311 =item referral_cust_pkg [ DEPTH ]
3312
3313 Like referral_cust_main, except returns a flat list of all unsuspended (and
3314 uncancelled) packages for each customer.  The number of items in this list may
3315 be useful for commission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
3316
3317 =cut
3318
3319 sub referral_cust_pkg {
3320   my $self = shift;
3321   my $depth = @_ ? shift : 1;
3322
3323   map { $_->unsuspended_pkgs }
3324     grep { $_->unsuspended_pkgs }
3325       $self->referral_cust_main($depth);
3326 }
3327
3328 =item referring_cust_main
3329
3330 Returns the single cust_main record for the customer who referred this customer
3331 (referral_custnum), or false.
3332
3333 =cut
3334
3335 sub referring_cust_main {
3336   my $self = shift;
3337   return '' unless $self->referral_custnum;
3338   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3339 }
3340
3341 =item credit AMOUNT, REASON [ , OPTION => VALUE ... ]
3342
3343 Applies a credit to this customer.  If there is an error, returns the error,
3344 otherwise returns false.
3345
3346 REASON can be a text string, an FS::reason object, or a scalar reference to
3347 a reasonnum.  If a text string, it will be automatically inserted as a new
3348 reason, and a 'reason_type' option must be passed to indicate the
3349 FS::reason_type for the new reason.
3350
3351 An I<addlinfo> option may be passed to set the credit's I<addlinfo> field.
3352
3353 Any other options are passed to FS::cust_credit::insert.
3354
3355 =cut
3356
3357 sub credit {
3358   my( $self, $amount, $reason, %options ) = @_;
3359
3360   my $cust_credit = new FS::cust_credit {
3361     'custnum' => $self->custnum,
3362     'amount'  => $amount,
3363   };
3364
3365   if ( ref($reason) ) {
3366
3367     if ( ref($reason) eq 'SCALAR' ) {
3368       $cust_credit->reasonnum( $$reason );
3369     } else {
3370       $cust_credit->reasonnum( $reason->reasonnum );
3371     }
3372
3373   } else {
3374     $cust_credit->set('reason', $reason)
3375   }
3376
3377   for (qw( addlinfo eventnum )) {
3378     $cust_credit->$_( delete $options{$_} )
3379       if exists($options{$_});
3380   }
3381
3382   $cust_credit->insert(%options);
3383
3384 }
3385
3386 =item charge HASHREF || AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3387
3388 Creates a one-time charge for this customer.  If there is an error, returns
3389 the error, otherwise returns false.
3390
3391 New-style, with a hashref of options:
3392
3393   my $error = $cust_main->charge(
3394                                   {
3395                                     'amount'     => 54.32,
3396                                     'quantity'   => 1,
3397                                     'start_date' => str2time('7/4/2009'),
3398                                     'pkg'        => 'Description',
3399                                     'comment'    => 'Comment',
3400                                     'additional' => [], #extra invoice detail
3401                                     'classnum'   => 1,  #pkg_class
3402
3403                                     'setuptax'   => '', # or 'Y' for tax exempt
3404
3405                                     'locationnum'=> 1234, # optional
3406
3407                                     #internal taxation
3408                                     'taxclass'   => 'Tax class',
3409
3410                                     #vendor taxation
3411                                     'taxproduct' => 2,  #part_pkg_taxproduct
3412                                     'override'   => {}, #XXX describe
3413
3414                                     #will be filled in with the new object
3415                                     'cust_pkg_ref' => \$cust_pkg,
3416
3417                                     #generate an invoice immediately
3418                                     'bill_now' => 0,
3419                                     'invoice_terms' => '', #with these terms
3420                                   }
3421                                 );
3422
3423 Old-style:
3424
3425   my $error = $cust_main->charge( 54.32, 'Description', 'Comment', 'Tax class' );
3426
3427 =cut
3428
3429 sub charge {
3430   my $self = shift;
3431   my ( $amount, $quantity, $start_date, $classnum );
3432   my ( $pkg, $comment, $additional );
3433   my ( $setuptax, $taxclass );   #internal taxes
3434   my ( $taxproduct, $override ); #vendor (CCH) taxes
3435   my $no_auto = '';
3436   my $cust_pkg_ref = '';
3437   my ( $bill_now, $invoice_terms ) = ( 0, '' );
3438   my $locationnum;
3439   if ( ref( $_[0] ) ) {
3440     $amount     = $_[0]->{amount};
3441     $quantity   = exists($_[0]->{quantity}) ? $_[0]->{quantity} : 1;
3442     $start_date = exists($_[0]->{start_date}) ? $_[0]->{start_date} : '';
3443     $no_auto    = exists($_[0]->{no_auto}) ? $_[0]->{no_auto} : '';
3444     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3445     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3446                                            : '$'. sprintf("%.2f",$amount);
3447     $setuptax   = exists($_[0]->{setuptax}) ? $_[0]->{setuptax} : '';
3448     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3449     $classnum   = exists($_[0]->{classnum}) ? $_[0]->{classnum} : '';
3450     $additional = $_[0]->{additional} || [];
3451     $taxproduct = $_[0]->{taxproductnum};
3452     $override   = { '' => $_[0]->{tax_override} };
3453     $cust_pkg_ref = exists($_[0]->{cust_pkg_ref}) ? $_[0]->{cust_pkg_ref} : '';
3454     $bill_now = exists($_[0]->{bill_now}) ? $_[0]->{bill_now} : '';
3455     $invoice_terms = exists($_[0]->{invoice_terms}) ? $_[0]->{invoice_terms} : '';
3456     $locationnum = $_[0]->{locationnum} || $self->ship_locationnum;
3457   } else {
3458     $amount     = shift;
3459     $quantity   = 1;
3460     $start_date = '';
3461     $pkg        = @_ ? shift : 'One-time charge';
3462     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3463     $setuptax   = '';
3464     $taxclass   = @_ ? shift : '';
3465     $additional = [];
3466   }
3467
3468   local $SIG{HUP} = 'IGNORE';
3469   local $SIG{INT} = 'IGNORE';
3470   local $SIG{QUIT} = 'IGNORE';
3471   local $SIG{TERM} = 'IGNORE';
3472   local $SIG{TSTP} = 'IGNORE';
3473   local $SIG{PIPE} = 'IGNORE';
3474
3475   my $oldAutoCommit = $FS::UID::AutoCommit;
3476   local $FS::UID::AutoCommit = 0;
3477   my $dbh = dbh;
3478
3479   my $part_pkg = new FS::part_pkg ( {
3480     'pkg'           => $pkg,
3481     'comment'       => $comment,
3482     'plan'          => 'flat',
3483     'freq'          => 0,
3484     'disabled'      => 'Y',
3485     'classnum'      => ( $classnum ? $classnum : '' ),
3486     'setuptax'      => $setuptax,
3487     'taxclass'      => $taxclass,
3488     'taxproductnum' => $taxproduct,
3489   } );
3490
3491   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3492                         ( 0 .. @$additional - 1 )
3493                   ),
3494                   'additional_count' => scalar(@$additional),
3495                   'setup_fee' => $amount,
3496                 );
3497
3498   my $error = $part_pkg->insert( options       => \%options,
3499                                  tax_overrides => $override,
3500                                );
3501   if ( $error ) {
3502     $dbh->rollback if $oldAutoCommit;
3503     return $error;
3504   }
3505
3506   my $pkgpart = $part_pkg->pkgpart;
3507   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3508   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3509     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3510     $error = $type_pkgs->insert;
3511     if ( $error ) {
3512       $dbh->rollback if $oldAutoCommit;
3513       return $error;
3514     }
3515   }
3516
3517   my $cust_pkg = new FS::cust_pkg ( {
3518     'custnum'    => $self->custnum,
3519     'pkgpart'    => $pkgpart,
3520     'quantity'   => $quantity,
3521     'start_date' => $start_date,
3522     'no_auto'    => $no_auto,
3523     'locationnum'=> $locationnum,
3524   } );
3525
3526   $error = $cust_pkg->insert;
3527   if ( $error ) {
3528     $dbh->rollback if $oldAutoCommit;
3529     return $error;
3530   } elsif ( $cust_pkg_ref ) {
3531     ${$cust_pkg_ref} = $cust_pkg;
3532   }
3533
3534   if ( $bill_now ) {
3535     my $error = $self->bill( 'invoice_terms' => $invoice_terms,
3536                              'pkg_list'      => [ $cust_pkg ],
3537                            );
3538     if ( $error ) {
3539       $dbh->rollback if $oldAutoCommit;
3540       return $error;
3541     }
3542   }
3543
3544   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3545   return '';
3546
3547 }
3548
3549 #=item charge_postal_fee
3550 #
3551 #Applies a one time charge this customer.  If there is an error,
3552 #returns the error, returns the cust_pkg charge object or false
3553 #if there was no charge.
3554 #
3555 #=cut
3556 #
3557 # This should be a customer event.  For that to work requires that bill
3558 # also be a customer event.
3559
3560 sub charge_postal_fee {
3561   my $self = shift;
3562
3563   my $pkgpart = $conf->config('postal_invoice-fee_pkgpart', $self->agentnum);
3564   return '' unless ($pkgpart && grep { $_ eq 'POST' } $self->invoicing_list);
3565
3566   my $cust_pkg = new FS::cust_pkg ( {
3567     'custnum'  => $self->custnum,
3568     'pkgpart'  => $pkgpart,
3569     'quantity' => 1,
3570   } );
3571
3572   my $error = $cust_pkg->insert;
3573   $error ? $error : $cust_pkg;
3574 }
3575
3576 =item cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3577
3578 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3579
3580 Optionally, a list or hashref of additional arguments to the qsearch call can
3581 be passed.
3582
3583 =cut
3584
3585 sub cust_bill {
3586   my $self = shift;
3587   my $opt = ref($_[0]) ? shift : { @_ };
3588
3589   #return $self->num_cust_bill unless wantarray || keys %$opt;
3590
3591   $opt->{'table'} = 'cust_bill';
3592   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3593   $opt->{'hashref'}{'custnum'} = $self->custnum;
3594   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3595
3596   map { $_ } #behavior of sort undefined in scalar context
3597     sort { $a->_date <=> $b->_date }
3598       qsearch($opt);
3599 }
3600
3601 =item open_cust_bill
3602
3603 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3604 customer.
3605
3606 =cut
3607
3608 sub open_cust_bill {
3609   my $self = shift;
3610
3611   $self->cust_bill(
3612     'extra_sql' => ' AND '. FS::cust_bill->owed_sql. ' > 0',
3613     #@_
3614   );
3615
3616 }
3617
3618 =item legacy_cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3619
3620 Returns all the legacy invoices (see L<FS::legacy_cust_bill>) for this customer.
3621
3622 =cut
3623
3624 sub legacy_cust_bill {
3625   my $self = shift;
3626
3627   #return $self->num_legacy_cust_bill unless wantarray;
3628
3629   map { $_ } #behavior of sort undefined in scalar context
3630     sort { $a->_date <=> $b->_date }
3631       qsearch({ 'table'    => 'legacy_cust_bill',
3632                 'hashref'  => { 'custnum' => $self->custnum, },
3633                 'order_by' => 'ORDER BY _date ASC',
3634              });
3635 }
3636
3637 =item cust_statement [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3638
3639 Returns all the statements (see L<FS::cust_statement>) for this customer.
3640
3641 Optionally, a list or hashref of additional arguments to the qsearch call can
3642 be passed.
3643
3644 =cut
3645
3646 =item cust_bill_void
3647
3648 Returns all the voided invoices (see L<FS::cust_bill_void>) for this customer.
3649
3650 =cut
3651
3652 sub cust_bill_void {
3653   my $self = shift;
3654
3655   map { $_ } #return $self->num_cust_bill_void unless wantarray;
3656   sort { $a->_date <=> $b->_date }
3657     qsearch( 'cust_bill_void', { 'custnum' => $self->custnum } )
3658 }
3659
3660 sub cust_statement {
3661   my $self = shift;
3662   my $opt = ref($_[0]) ? shift : { @_ };
3663
3664   #return $self->num_cust_statement unless wantarray || keys %$opt;
3665
3666   $opt->{'table'} = 'cust_statement';
3667   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3668   $opt->{'hashref'}{'custnum'} = $self->custnum;
3669   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3670
3671   map { $_ } #behavior of sort undefined in scalar context
3672     sort { $a->_date <=> $b->_date }
3673       qsearch($opt);
3674 }
3675
3676 =item svc_x SVCDB [ OPTION => VALUE | EXTRA_QSEARCH_PARAMS_HASHREF ]
3677
3678 Returns all services of type SVCDB (such as 'svc_acct') for this customer.
3679
3680 Optionally, a list or hashref of additional arguments to the qsearch call can
3681 be passed following the SVCDB.
3682
3683 =cut
3684
3685 sub svc_x {
3686   my $self = shift;
3687   my $svcdb = shift;
3688   if ( ! $svcdb =~ /^svc_\w+$/ ) {
3689     warn "$me svc_x requires a svcdb";
3690     return;
3691   }
3692   my $opt = ref($_[0]) ? shift : { @_ };
3693
3694   $opt->{'table'} = $svcdb;
3695   $opt->{'addl_from'} =
3696     'LEFT JOIN cust_svc USING (svcnum) LEFT JOIN cust_pkg USING (pkgnum) '.
3697     ($opt->{'addl_from'} || '');
3698
3699   my $custnum = $self->custnum;
3700   $custnum =~ /^\d+$/ or die "bad custnum '$custnum'";
3701   my $where = "cust_pkg.custnum = $custnum";
3702
3703   my $extra_sql = $opt->{'extra_sql'} || '';
3704   if ( keys %{ $opt->{'hashref'} } ) {
3705     $extra_sql = " AND $where $extra_sql";
3706   }
3707   else {
3708     if ( $opt->{'extra_sql'} =~ /^\s*where\s(.*)/si ) {
3709       $extra_sql = "WHERE $where AND $1";
3710     }
3711     else {
3712       $extra_sql = "WHERE $where $extra_sql";
3713     }
3714   }
3715   $opt->{'extra_sql'} = $extra_sql;
3716
3717   qsearch($opt);
3718 }
3719
3720 # required for use as an eventtable;
3721 sub svc_acct {
3722   my $self = shift;
3723   $self->svc_x('svc_acct', @_);
3724 }
3725
3726 =item cust_credit
3727
3728 Returns all the credits (see L<FS::cust_credit>) for this customer.
3729
3730 =cut
3731
3732 sub cust_credit {
3733   my $self = shift;
3734   map { $_ } #return $self->num_cust_credit unless wantarray;
3735   sort { $a->_date <=> $b->_date }
3736     qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3737 }
3738
3739 =item cust_credit_pkgnum
3740
3741 Returns all the credits (see L<FS::cust_credit>) for this customer's specific
3742 package when using experimental package balances.
3743
3744 =cut
3745
3746 sub cust_credit_pkgnum {
3747   my( $self, $pkgnum ) = @_;
3748   map { $_ } #return $self->num_cust_credit_pkgnum($pkgnum) unless wantarray;
3749   sort { $a->_date <=> $b->_date }
3750     qsearch( 'cust_credit', { 'custnum' => $self->custnum,
3751                               'pkgnum'  => $pkgnum,
3752                             }
3753     );
3754 }
3755
3756 =item cust_pay
3757
3758 Returns all the payments (see L<FS::cust_pay>) for this customer.
3759
3760 =cut
3761
3762 sub cust_pay {
3763   my $self = shift;
3764   return $self->num_cust_pay unless wantarray;
3765   sort { $a->_date <=> $b->_date }
3766     qsearch( 'cust_pay', { 'custnum' => $self->custnum } )
3767 }
3768
3769 =item num_cust_pay
3770
3771 Returns the number of payments (see L<FS::cust_pay>) for this customer.  Also
3772 called automatically when the cust_pay method is used in a scalar context.
3773
3774 =cut
3775
3776 sub num_cust_pay {
3777   my $self = shift;
3778   my $sql = "SELECT COUNT(*) FROM cust_pay WHERE custnum = ?";
3779   my $sth = dbh->prepare($sql) or die dbh->errstr;
3780   $sth->execute($self->custnum) or die $sth->errstr;
3781   $sth->fetchrow_arrayref->[0];
3782 }
3783
3784 =item cust_pay_pkgnum
3785
3786 Returns all the payments (see L<FS::cust_pay>) for this customer's specific
3787 package when using experimental package balances.
3788
3789 =cut
3790
3791 sub cust_pay_pkgnum {
3792   my( $self, $pkgnum ) = @_;
3793   map { $_ } #return $self->num_cust_pay_pkgnum($pkgnum) unless wantarray;
3794   sort { $a->_date <=> $b->_date }
3795     qsearch( 'cust_pay', { 'custnum' => $self->custnum,
3796                            'pkgnum'  => $pkgnum,
3797                          }
3798     );
3799 }
3800
3801 =item cust_pay_void
3802
3803 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3804
3805 =cut
3806
3807 sub cust_pay_void {
3808   my $self = shift;
3809   map { $_ } #return $self->num_cust_pay_void unless wantarray;
3810   sort { $a->_date <=> $b->_date }
3811     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3812 }
3813
3814 =item cust_pay_batch [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3815
3816 Returns all batched payments (see L<FS::cust_pay_batch>) for this customer.
3817
3818 Optionally, a list or hashref of additional arguments to the qsearch call can
3819 be passed.
3820
3821 =cut
3822
3823 sub cust_pay_batch {
3824   my $self = shift;
3825   my $opt = ref($_[0]) ? shift : { @_ };
3826
3827   #return $self->num_cust_statement unless wantarray || keys %$opt;
3828
3829   $opt->{'table'} = 'cust_pay_batch';
3830   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3831   $opt->{'hashref'}{'custnum'} = $self->custnum;
3832   $opt->{'order_by'} ||= 'ORDER BY paybatchnum ASC';
3833
3834   map { $_ } #behavior of sort undefined in scalar context
3835     sort { $a->paybatchnum <=> $b->paybatchnum }
3836       qsearch($opt);
3837 }
3838
3839 =item cust_pay_pending
3840
3841 Returns all pending payments (see L<FS::cust_pay_pending>) for this customer
3842 (without status "done").
3843
3844 =cut
3845
3846 sub cust_pay_pending {
3847   my $self = shift;
3848   return $self->num_cust_pay_pending unless wantarray;
3849   sort { $a->_date <=> $b->_date }
3850     qsearch( 'cust_pay_pending', {
3851                                    'custnum' => $self->custnum,
3852                                    'status'  => { op=>'!=', value=>'done' },
3853                                  },
3854            );
3855 }
3856
3857 =item cust_pay_pending_attempt
3858
3859 Returns all payment attempts / declined payments for this customer, as pending
3860 payments objects (see L<FS::cust_pay_pending>), with status "done" but without
3861 a corresponding payment (see L<FS::cust_pay>).
3862
3863 =cut
3864
3865 sub cust_pay_pending_attempt {
3866   my $self = shift;
3867   return $self->num_cust_pay_pending_attempt unless wantarray;
3868   sort { $a->_date <=> $b->_date }
3869     qsearch( 'cust_pay_pending', {
3870                                    'custnum' => $self->custnum,
3871                                    'status'  => 'done',
3872                                    'paynum'  => '',
3873                                  },
3874            );
3875 }
3876
3877 =item num_cust_pay_pending
3878
3879 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3880 customer (without status "done").  Also called automatically when the
3881 cust_pay_pending method is used in a scalar context.
3882
3883 =cut
3884
3885 sub num_cust_pay_pending {
3886   my $self = shift;
3887   $self->scalar_sql(
3888     " SELECT COUNT(*) FROM cust_pay_pending ".
3889       " WHERE custnum = ? AND status != 'done' ",
3890     $self->custnum
3891   );
3892 }
3893
3894 =item num_cust_pay_pending_attempt
3895
3896 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3897 customer, with status "done" but without a corresp.  Also called automatically when the
3898 cust_pay_pending method is used in a scalar context.
3899
3900 =cut
3901
3902 sub num_cust_pay_pending_attempt {
3903   my $self = shift;
3904   $self->scalar_sql(
3905     " SELECT COUNT(*) FROM cust_pay_pending ".
3906       " WHERE custnum = ? AND status = 'done' AND paynum IS NULL",
3907     $self->custnum
3908   );
3909 }
3910
3911 =item cust_refund
3912
3913 Returns all the refunds (see L<FS::cust_refund>) for this customer.
3914
3915 =cut
3916
3917 sub cust_refund {
3918   my $self = shift;
3919   map { $_ } #return $self->num_cust_refund unless wantarray;
3920   sort { $a->_date <=> $b->_date }
3921     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
3922 }
3923
3924 =item display_custnum
3925
3926 Returns the displayed customer number for this customer: agent_custid if
3927 cust_main-default_agent_custid is set and it has a value, custnum otherwise.
3928
3929 =cut
3930
3931 sub display_custnum {
3932   my $self = shift;
3933
3934   my $prefix = $conf->config('cust_main-custnum-display_prefix', $self->agentnum) || '';
3935   if ( my $special = $conf->config('cust_main-custnum-display_special') ) {
3936     if ( $special eq 'CoStAg' ) {
3937       $prefix = uc( join('',
3938         $self->country,
3939         ($self->state =~ /^(..)/),
3940         $prefix || ($self->agent->agent =~ /^(..)/)
3941       ) );
3942     }
3943     elsif ( $special eq 'CoStCl' ) {
3944       $prefix = uc( join('',
3945         $self->country,
3946         ($self->state =~ /^(..)/),
3947         ($self->classnum ? $self->cust_class->classname =~ /^(..)/ : '__')
3948       ) );
3949     }
3950     # add any others here if needed
3951   }
3952
3953   my $length = $conf->config('cust_main-custnum-display_length');
3954   if ( $conf->exists('cust_main-default_agent_custid') && $self->agent_custid ){
3955     return $self->agent_custid;
3956   } elsif ( $prefix ) {
3957     $length = 8 if !defined($length);
3958     return $prefix .
3959            sprintf('%0'.$length.'d', $self->custnum)
3960   } elsif ( $length ) {
3961     return sprintf('%0'.$length.'d', $self->custnum);
3962   } else {
3963     return $self->custnum;
3964   }
3965 }
3966
3967 =item name
3968
3969 Returns a name string for this customer, either "Company (Last, First)" or
3970 "Last, First".
3971
3972 =cut
3973
3974 sub name {
3975   my $self = shift;
3976   my $name = $self->contact;
3977   $name = $self->company. " ($name)" if $self->company;
3978   $name;
3979 }
3980
3981 =item service_contact
3982
3983 Returns the L<FS::contact> object for this customer that has the 'Service'
3984 contact class, or undef if there is no such contact.  Deprecated; don't use
3985 this in new code.
3986
3987 =cut
3988
3989 sub service_contact {
3990   my $self = shift;
3991   if ( !exists($self->{service_contact}) ) {
3992     my $classnum = $self->scalar_sql(
3993       'SELECT classnum FROM contact_class WHERE classname = \'Service\''
3994     ) || 0; #if it's zero, qsearchs will return nothing
3995     $self->{service_contact} = qsearchs('contact', {
3996         'classnum' => $classnum, 'custnum' => $self->custnum
3997       }) || undef;
3998   }
3999   $self->{service_contact};
4000 }
4001
4002 =item ship_name
4003
4004 Returns a name string for this (service/shipping) contact, either
4005 "Company (Last, First)" or "Last, First".
4006
4007 =cut
4008
4009 sub ship_name {
4010   my $self = shift;
4011
4012   my $name = $self->ship_contact;
4013   $name = $self->company. " ($name)" if $self->company;
4014   $name;
4015 }
4016
4017 =item name_short
4018
4019 Returns a name string for this customer, either "Company" or "First Last".
4020
4021 =cut
4022
4023 sub name_short {
4024   my $self = shift;
4025   $self->company !~ /^\s*$/ ? $self->company : $self->contact_firstlast;
4026 }
4027
4028 =item ship_name_short
4029
4030 Returns a name string for this (service/shipping) contact, either "Company"
4031 or "First Last".
4032
4033 =cut
4034
4035 sub ship_name_short {
4036   my $self = shift;
4037   $self->service_contact
4038     ? $self->ship_contact_firstlast
4039     : $self->name_short
4040 }
4041
4042 =item contact
4043
4044 Returns this customer's full (billing) contact name only, "Last, First"
4045
4046 =cut
4047
4048 sub contact {
4049   my $self = shift;
4050   $self->get('last'). ', '. $self->first;
4051 }
4052
4053 =item ship_contact
4054
4055 Returns this customer's full (shipping) contact name only, "Last, First"
4056
4057 =cut
4058
4059 sub ship_contact {
4060   my $self = shift;
4061   my $contact = $self->service_contact || $self;
4062   $contact->get('last') . ', ' . $contact->get('first');
4063 }
4064
4065 =item contact_firstlast
4066
4067 Returns this customers full (billing) contact name only, "First Last".
4068
4069 =cut
4070
4071 sub contact_firstlast {
4072   my $self = shift;
4073   $self->first. ' '. $self->get('last');
4074 }
4075
4076 =item ship_contact_firstlast
4077
4078 Returns this customer's full (shipping) contact name only, "First Last".
4079
4080 =cut
4081
4082 sub ship_contact_firstlast {
4083   my $self = shift;
4084   my $contact = $self->service_contact || $self;
4085   $contact->get('first') . ' '. $contact->get('last');
4086 }
4087
4088 #XXX this doesn't work in 3.x+
4089 #=item country_full
4090 #
4091 #Returns this customer's full country name
4092 #
4093 #=cut
4094 #
4095 #sub country_full {
4096 #  my $self = shift;
4097 #  code2country($self->country);
4098 #}
4099
4100 =item county_state_county [ PREFIX ]
4101
4102 Returns a string consisting of just the county, state and country.
4103
4104 =cut
4105
4106 sub county_state_country {
4107   my $self = shift;
4108   my $locationnum;
4109   if ( @_ && $_[0] && $self->has_ship_address ) {
4110     $locationnum = $self->ship_locationnum;
4111   } else {
4112     $locationnum = $self->bill_locationnum;
4113   }
4114   my $cust_location = qsearchs('cust_location', { locationnum=>$locationnum });
4115   $cust_location->county_state_country;
4116 }
4117
4118 =item geocode DATA_VENDOR
4119
4120 Returns a value for the customer location as encoded by DATA_VENDOR.
4121 Currently this only makes sense for "CCH" as DATA_VENDOR.
4122
4123 =cut
4124
4125 =item cust_status
4126
4127 =item status
4128
4129 Returns a status string for this customer, currently:
4130
4131 =over 4
4132
4133 =item prospect - No packages have ever been ordered
4134
4135 =item ordered - Recurring packages all are new (not yet billed).
4136
4137 =item active - One or more recurring packages is active
4138
4139 =item inactive - No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled)
4140
4141 =item suspended - All non-cancelled recurring packages are suspended
4142
4143 =item cancelled - All recurring packages are cancelled
4144
4145 =back
4146
4147 Behavior of inactive vs. cancelled edge cases can be adjusted with the
4148 cust_main-status_module configuration option.
4149
4150 =cut
4151
4152 sub status { shift->cust_status(@_); }
4153
4154 sub cust_status {
4155   my $self = shift;
4156   for my $status ( FS::cust_main->statuses() ) {
4157     my $method = $status.'_sql';
4158     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
4159     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
4160     $sth->execute( ($self->custnum) x $numnum )
4161       or die "Error executing 'SELECT $sql': ". $sth->errstr;
4162     return $status if $sth->fetchrow_arrayref->[0];
4163   }
4164 }
4165
4166 =item ucfirst_cust_status
4167
4168 =item ucfirst_status
4169
4170 Returns the status with the first character capitalized.
4171
4172 =cut
4173
4174 sub ucfirst_status { shift->ucfirst_cust_status(@_); }
4175
4176 sub ucfirst_cust_status {
4177   my $self = shift;
4178   ucfirst($self->cust_status);
4179 }
4180
4181 =item statuscolor
4182
4183 Returns a hex triplet color string for this customer's status.
4184
4185 =cut
4186
4187 sub statuscolor { shift->cust_statuscolor(@_); }
4188
4189 sub cust_statuscolor {
4190   my $self = shift;
4191   __PACKAGE__->statuscolors->{$self->cust_status};
4192 }
4193
4194 =item tickets
4195
4196 Returns an array of hashes representing the customer's RT tickets.
4197
4198 =cut
4199
4200 sub tickets {
4201   my $self = shift;
4202
4203   my $num = $conf->config('cust_main-max_tickets') || 10;
4204   my @tickets = ();
4205
4206   if ( $conf->config('ticket_system') ) {
4207     unless ( $conf->config('ticket_system-custom_priority_field') ) {
4208
4209       @tickets = @{ FS::TicketSystem->customer_tickets($self->custnum, $num) };
4210
4211     } else {
4212
4213       foreach my $priority (
4214         $conf->config('ticket_system-custom_priority_field-values'), ''
4215       ) {
4216         last if scalar(@tickets) >= $num;
4217         push @tickets,
4218           @{ FS::TicketSystem->customer_tickets( $self->custnum,
4219                                                  $num - scalar(@tickets),
4220                                                  $priority,
4221                                                )
4222            };
4223       }
4224     }
4225   }
4226   (@tickets);
4227 }
4228
4229 # Return services representing svc_accts in customer support packages
4230 sub support_services {
4231   my $self = shift;
4232   my %packages = map { $_ => 1 } $conf->config('support_packages');
4233
4234   grep { $_->pkg_svc && $_->pkg_svc->primary_svc eq 'Y' }
4235     grep { $_->part_svc->svcdb eq 'svc_acct' }
4236     map { $_->cust_svc }
4237     grep { exists $packages{ $_->pkgpart } }
4238     $self->ncancelled_pkgs;
4239
4240 }
4241
4242 # Return a list of latitude/longitude for one of the services (if any)
4243 sub service_coordinates {
4244   my $self = shift;
4245
4246   my @svc_X =
4247     grep { $_->latitude && $_->longitude }
4248     map { $_->svc_x }
4249     map { $_->cust_svc }
4250     $self->ncancelled_pkgs;
4251
4252   scalar(@svc_X) ? ( $svc_X[0]->latitude, $svc_X[0]->longitude ) : ()
4253 }
4254
4255 =item masked FIELD
4256
4257 Returns a masked version of the named field
4258
4259 =cut
4260
4261 sub masked {
4262 my ($self,$field) = @_;
4263
4264 # Show last four
4265
4266 'x'x(length($self->getfield($field))-4).
4267   substr($self->getfield($field), (length($self->getfield($field))-4));
4268
4269 }
4270
4271 =back
4272
4273 =head1 CLASS METHODS
4274
4275 =over 4
4276
4277 =item statuses
4278
4279 Class method that returns the list of possible status strings for customers
4280 (see L<the status method|/status>).  For example:
4281
4282   @statuses = FS::cust_main->statuses();
4283
4284 =cut
4285
4286 sub statuses {
4287   my $self = shift;
4288   keys %{ $self->statuscolors };
4289 }
4290
4291 =item cust_status_sql
4292
4293 Returns an SQL fragment to determine the status of a cust_main record, as a
4294 string.
4295
4296 =cut
4297
4298 sub cust_status_sql {
4299   my $sql = 'CASE';
4300   for my $status ( FS::cust_main->statuses() ) {
4301     my $method = $status.'_sql';
4302     $sql .= ' WHEN ('.FS::cust_main->$method.") THEN '$status'";
4303   }
4304   $sql .= ' END';
4305   return $sql;
4306 }
4307
4308
4309 =item prospect_sql
4310
4311 Returns an SQL expression identifying prospective cust_main records (customers
4312 with no packages ever ordered)
4313
4314 =cut
4315
4316 use vars qw($select_count_pkgs);
4317 $select_count_pkgs =
4318   "SELECT COUNT(*) FROM cust_pkg
4319     WHERE cust_pkg.custnum = cust_main.custnum";
4320
4321 sub select_count_pkgs_sql {
4322   $select_count_pkgs;
4323 }
4324
4325 sub prospect_sql {
4326   " 0 = ( $select_count_pkgs ) ";
4327 }
4328
4329 =item ordered_sql
4330
4331 Returns an SQL expression identifying ordered cust_main records (customers with
4332 no active packages, but recurring packages not yet setup or one time charges
4333 not yet billed).
4334
4335 =cut
4336
4337 sub ordered_sql {
4338   FS::cust_main->none_active_sql.
4339   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->not_yet_billed_sql. " ) ";
4340 }
4341
4342 =item active_sql
4343
4344 Returns an SQL expression identifying active cust_main records (customers with
4345 active recurring packages).
4346
4347 =cut
4348
4349 sub active_sql {
4350   " 0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4351 }
4352
4353 =item none_active_sql
4354
4355 Returns an SQL expression identifying cust_main records with no active
4356 recurring packages.  This includes customers of status prospect, ordered,
4357 inactive, and suspended.
4358
4359 =cut
4360
4361 sub none_active_sql {
4362   " 0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4363 }
4364
4365 =item inactive_sql
4366
4367 Returns an SQL expression identifying inactive cust_main records (customers with
4368 no active recurring packages, but otherwise unsuspended/uncancelled).
4369
4370 =cut
4371
4372 sub inactive_sql {
4373   FS::cust_main->none_active_sql.
4374   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " ) ";
4375 }
4376
4377 =item susp_sql
4378 =item suspended_sql
4379
4380 Returns an SQL expression identifying suspended cust_main records.
4381
4382 =cut
4383
4384
4385 sub suspended_sql { susp_sql(@_); }
4386 sub susp_sql {
4387   FS::cust_main->none_active_sql.
4388   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " ) ";
4389 }
4390
4391 =item cancel_sql
4392 =item cancelled_sql
4393
4394 Returns an SQL expression identifying cancelled cust_main records.
4395
4396 =cut
4397
4398 sub cancel_sql { shift->cancelled_sql(@_); }
4399
4400 =item uncancel_sql
4401 =item uncancelled_sql
4402
4403 Returns an SQL expression identifying un-cancelled cust_main records.
4404
4405 =cut
4406
4407 sub uncancelled_sql { uncancel_sql(@_); }
4408 sub uncancel_sql { "
4409   ( 0 < ( $select_count_pkgs
4410                    AND ( cust_pkg.cancel IS NULL
4411                          OR cust_pkg.cancel = 0
4412                        )
4413         )
4414     OR 0 = ( $select_count_pkgs )
4415   )
4416 "; }
4417
4418 =item balance_sql
4419
4420 Returns an SQL fragment to retreive the balance.
4421
4422 =cut
4423
4424 sub balance_sql { "
4425     ( SELECT COALESCE( SUM(charged), 0 ) FROM cust_bill
4426         WHERE cust_bill.custnum   = cust_main.custnum     )
4427   - ( SELECT COALESCE( SUM(paid),    0 ) FROM cust_pay
4428         WHERE cust_pay.custnum    = cust_main.custnum     )
4429   - ( SELECT COALESCE( SUM(amount),  0 ) FROM cust_credit
4430         WHERE cust_credit.custnum = cust_main.custnum     )
4431   + ( SELECT COALESCE( SUM(refund),  0 ) FROM cust_refund
4432         WHERE cust_refund.custnum = cust_main.custnum     )
4433 "; }
4434
4435 =item balance_date_sql [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
4436
4437 Returns an SQL fragment to retreive the balance for this customer, optionally
4438 considering invoices with date earlier than START_TIME, and not
4439 later than END_TIME (total_owed_date minus total_unapplied_credits minus
4440 total_unapplied_payments).
4441
4442 Times are specified as SQL fragments or numeric
4443 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4444 L<Date::Parse> for conversion functions.  The empty string can be passed
4445 to disable that time constraint completely.
4446
4447 Available options are:
4448
4449 =over 4
4450
4451 =item unapplied_date
4452
4453 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
4454
4455 =item total
4456
4457 (unused.  obsolete?)
4458 set to true to remove all customer comparison clauses, for totals
4459
4460 =item where
4461
4462 (unused.  obsolete?)
4463 WHERE clause hashref (elements "AND"ed together) (typically used with the total option)
4464
4465 =item join
4466
4467 (unused.  obsolete?)
4468 JOIN clause (typically used with the total option)
4469
4470 =item cutoff
4471
4472 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
4473 time will be ignored.  Note that START_TIME and END_TIME only limit the date
4474 range for invoices and I<unapplied> payments, credits, and refunds.
4475
4476 =back
4477
4478 =cut
4479
4480 sub balance_date_sql {
4481   my( $class, $start, $end, %opt ) = @_;
4482
4483   my $cutoff = $opt{'cutoff'};
4484
4485   my $owed         = FS::cust_bill->owed_sql($cutoff);
4486   my $unapp_refund = FS::cust_refund->unapplied_sql($cutoff);
4487   my $unapp_credit = FS::cust_credit->unapplied_sql($cutoff);
4488   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4489
4490   my $j = $opt{'join'} || '';
4491
4492   my $owed_wh   = $class->_money_table_where( 'cust_bill',   $start,$end,%opt );
4493   my $refund_wh = $class->_money_table_where( 'cust_refund', $start,$end,%opt );
4494   my $credit_wh = $class->_money_table_where( 'cust_credit', $start,$end,%opt );
4495   my $pay_wh    = $class->_money_table_where( 'cust_pay',    $start,$end,%opt );
4496
4497   "   ( SELECT COALESCE(SUM($owed),         0) FROM cust_bill   $j $owed_wh   )
4498     + ( SELECT COALESCE(SUM($unapp_refund), 0) FROM cust_refund $j $refund_wh )
4499     - ( SELECT COALESCE(SUM($unapp_credit), 0) FROM cust_credit $j $credit_wh )
4500     - ( SELECT COALESCE(SUM($unapp_pay),    0) FROM cust_pay    $j $pay_wh    )
4501   ";
4502
4503 }
4504
4505 =item unapplied_payments_date_sql START_TIME [ END_TIME ]
4506
4507 Returns an SQL fragment to retreive the total unapplied payments for this
4508 customer, only considering payments with date earlier than START_TIME, and
4509 optionally not later than END_TIME.
4510
4511 Times are specified as SQL fragments or numeric
4512 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4513 L<Date::Parse> for conversion functions.  The empty string can be passed
4514 to disable that time constraint completely.
4515
4516 Available options are:
4517
4518 =cut
4519
4520 sub unapplied_payments_date_sql {
4521   my( $class, $start, $end, %opt ) = @_;
4522
4523   my $cutoff = $opt{'cutoff'};
4524
4525   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4526
4527   my $pay_where = $class->_money_table_where( 'cust_pay', $start, $end,
4528                                                           'unapplied_date'=>1 );
4529
4530   " ( SELECT COALESCE(SUM($unapp_pay), 0) FROM cust_pay $pay_where ) ";
4531 }
4532
4533 =item _money_table_where TABLE START_TIME [ END_TIME [ OPTION => VALUE ... ] ]
4534
4535 Helper method for balance_date_sql; name (and usage) subject to change
4536 (suggestions welcome).
4537
4538 Returns a WHERE clause for the specified monetary TABLE (cust_bill,
4539 cust_refund, cust_credit or cust_pay).
4540
4541 If TABLE is "cust_bill" or the unapplied_date option is true, only
4542 considers records with date earlier than START_TIME, and optionally not
4543 later than END_TIME .
4544
4545 =cut
4546
4547 sub _money_table_where {
4548   my( $class, $table, $start, $end, %opt ) = @_;
4549
4550   my @where = ();
4551   push @where, "cust_main.custnum = $table.custnum" unless $opt{'total'};
4552   if ( $table eq 'cust_bill' || $opt{'unapplied_date'} ) {
4553     push @where, "$table._date <= $start" if defined($start) && length($start);
4554     push @where, "$table._date >  $end"   if defined($end)   && length($end);
4555   }
4556   push @where, @{$opt{'where'}} if $opt{'where'};
4557   my $where = scalar(@where) ? 'WHERE '. join(' AND ', @where ) : '';
4558
4559   $where;
4560
4561 }
4562
4563 #for dyanmic FS::$table->search in httemplate/misc/email_customers.html
4564 use FS::cust_main::Search;
4565 sub search {
4566   my $class = shift;
4567   FS::cust_main::Search->search(@_);
4568 }
4569
4570 =back
4571
4572 =head1 SUBROUTINES
4573
4574 =over 4
4575
4576 =item batch_charge
4577
4578 =cut
4579
4580 sub batch_charge {
4581   my $param = shift;
4582   #warn join('-',keys %$param);
4583   my $fh = $param->{filehandle};
4584   my $agentnum = $param->{agentnum};
4585   my $format = $param->{format};
4586
4587   my $extra_sql = ' AND '. $FS::CurrentUser::CurrentUser->agentnums_sql;
4588
4589   my @fields;
4590   if ( $format eq 'simple' ) {
4591     @fields = qw( custnum agent_custid amount pkg );
4592   } else {
4593     die "unknown format $format";
4594   }
4595
4596   eval "use Text::CSV_XS;";
4597   die $@ if $@;
4598
4599   my $csv = new Text::CSV_XS;
4600   #warn $csv;
4601   #warn $fh;
4602
4603   my $imported = 0;
4604   #my $columns;
4605
4606   local $SIG{HUP} = 'IGNORE';
4607   local $SIG{INT} = 'IGNORE';
4608   local $SIG{QUIT} = 'IGNORE';
4609   local $SIG{TERM} = 'IGNORE';
4610   local $SIG{TSTP} = 'IGNORE';
4611   local $SIG{PIPE} = 'IGNORE';
4612
4613   my $oldAutoCommit = $FS::UID::AutoCommit;
4614   local $FS::UID::AutoCommit = 0;
4615   my $dbh = dbh;
4616
4617   #while ( $columns = $csv->getline($fh) ) {
4618   my $line;
4619   while ( defined($line=<$fh>) ) {
4620
4621     $csv->parse($line) or do {
4622       $dbh->rollback if $oldAutoCommit;
4623       return "can't parse: ". $csv->error_input();
4624     };
4625
4626     my @columns = $csv->fields();
4627     #warn join('-',@columns);
4628
4629     my %row = ();
4630     foreach my $field ( @fields ) {
4631       $row{$field} = shift @columns;
4632     }
4633
4634     if ( $row{custnum} && $row{agent_custid} ) {
4635       dbh->rollback if $oldAutoCommit;
4636       return "can't specify custnum with agent_custid $row{agent_custid}";
4637     }
4638
4639     my %hash = ();
4640     if ( $row{agent_custid} && $agentnum ) {
4641       %hash = ( 'agent_custid' => $row{agent_custid},
4642                 'agentnum'     => $agentnum,
4643               );
4644     }
4645
4646     if ( $row{custnum} ) {
4647       %hash = ( 'custnum' => $row{custnum} );
4648     }
4649
4650     unless ( scalar(keys %hash) ) {
4651       $dbh->rollback if $oldAutoCommit;
4652       return "can't find customer without custnum or agent_custid and agentnum";
4653     }
4654
4655     my $cust_main = qsearchs('cust_main', { %hash } );
4656     unless ( $cust_main ) {
4657       $dbh->rollback if $oldAutoCommit;
4658       my $custnum = $row{custnum} || $row{agent_custid};
4659       return "unknown custnum $custnum";
4660     }
4661
4662     if ( $row{'amount'} > 0 ) {
4663       my $error = $cust_main->charge($row{'amount'}, $row{'pkg'});
4664       if ( $error ) {
4665         $dbh->rollback if $oldAutoCommit;
4666         return $error;
4667       }
4668       $imported++;
4669     } elsif ( $row{'amount'} < 0 ) {
4670       my $error = $cust_main->credit( sprintf( "%.2f", 0-$row{'amount'} ),
4671                                       $row{'pkg'}                         );
4672       if ( $error ) {
4673         $dbh->rollback if $oldAutoCommit;
4674         return $error;
4675       }
4676       $imported++;
4677     } else {
4678       #hmm?
4679     }
4680
4681   }
4682
4683   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4684
4685   return "Empty file!" unless $imported;
4686
4687   ''; #no error
4688
4689 }
4690
4691 =item notify CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4692
4693 Deprecated.  Use event notification and message templates
4694 (L<FS::msg_template>) instead.
4695
4696 Sends a templated email notification to the customer (see L<Text::Template>).
4697
4698 OPTIONS is a hash and may include
4699
4700 I<from> - the email sender (default is invoice_from)
4701
4702 I<to> - comma-separated scalar or arrayref of recipients
4703    (default is invoicing_list)
4704
4705 I<subject> - The subject line of the sent email notification
4706    (default is "Notice from company_name")
4707
4708 I<extra_fields> - a hashref of name/value pairs which will be substituted
4709    into the template
4710
4711 The following variables are vavailable in the template.
4712
4713 I<$first> - the customer first name
4714 I<$last> - the customer last name
4715 I<$company> - the customer company
4716 I<$payby> - a description of the method of payment for the customer
4717             # would be nice to use FS::payby::shortname
4718 I<$payinfo> - the account information used to collect for this customer
4719 I<$expdate> - the expiration of the customer payment in seconds from epoch
4720
4721 =cut
4722
4723 sub notify {
4724   my ($self, $template, %options) = @_;
4725
4726   return unless $conf->exists($template);
4727
4728   my $from = $conf->config('invoice_from', $self->agentnum)
4729     if $conf->exists('invoice_from', $self->agentnum);
4730   $from = $options{from} if exists($options{from});
4731
4732   my $to = join(',', $self->invoicing_list_emailonly);
4733   $to = $options{to} if exists($options{to});
4734
4735   my $subject = "Notice from " . $conf->config('company_name', $self->agentnum)
4736     if $conf->exists('company_name', $self->agentnum);
4737   $subject = $options{subject} if exists($options{subject});
4738
4739   my $notify_template = new Text::Template (TYPE => 'ARRAY',
4740                                             SOURCE => [ map "$_\n",
4741                                               $conf->config($template)]
4742                                            )
4743     or die "can't create new Text::Template object: Text::Template::ERROR";
4744   $notify_template->compile()
4745     or die "can't compile template: Text::Template::ERROR";
4746
4747   $FS::notify_template::_template::company_name =
4748     $conf->config('company_name', $self->agentnum);
4749   $FS::notify_template::_template::company_address =
4750     join("\n", $conf->config('company_address', $self->agentnum) ). "\n";
4751
4752   my $paydate = $self->paydate || '2037-12-31';
4753   $FS::notify_template::_template::first = $self->first;
4754   $FS::notify_template::_template::last = $self->last;
4755   $FS::notify_template::_template::company = $self->company;
4756   $FS::notify_template::_template::payinfo = $self->mask_payinfo;
4757   my $payby = $self->payby;
4758   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
4759   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
4760
4761   #credit cards expire at the end of the month/year of their exp date
4762   if ($payby eq 'CARD' || $payby eq 'DCRD') {
4763     $FS::notify_template::_template::payby = 'credit card';
4764     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
4765     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
4766     $expire_time--;
4767   }elsif ($payby eq 'COMP') {
4768     $FS::notify_template::_template::payby = 'complimentary account';
4769   }else{
4770     $FS::notify_template::_template::payby = 'current method';
4771   }
4772   $FS::notify_template::_template::expdate = $expire_time;
4773
4774   for (keys %{$options{extra_fields}}){
4775     no strict "refs";
4776     ${"FS::notify_template::_template::$_"} = $options{extra_fields}->{$_};
4777   }
4778
4779   send_email(from => $from,
4780              to => $to,
4781              subject => $subject,
4782              body => $notify_template->fill_in( PACKAGE =>
4783                                                 'FS::notify_template::_template'                                              ),
4784             );
4785
4786 }
4787
4788 =item generate_letter CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4789
4790 Generates a templated notification to the customer (see L<Text::Template>).
4791
4792 OPTIONS is a hash and may include
4793
4794 I<extra_fields> - a hashref of name/value pairs which will be substituted
4795    into the template.  These values may override values mentioned below
4796    and those from the customer record.
4797
4798 The following variables are available in the template instead of or in addition
4799 to the fields of the customer record.
4800
4801 I<$payby> - a description of the method of payment for the customer
4802             # would be nice to use FS::payby::shortname
4803 I<$payinfo> - the masked account information used to collect for this customer
4804 I<$expdate> - the expiration of the customer payment method in seconds from epoch
4805 I<$returnaddress> - the return address defaults to invoice_latexreturnaddress or company_address
4806
4807 =cut
4808
4809 # a lot like cust_bill::print_latex
4810 sub generate_letter {
4811   my ($self, $template, %options) = @_;
4812
4813   return unless $conf->exists($template);
4814
4815   my $letter_template = new Text::Template
4816                         ( TYPE       => 'ARRAY',
4817                           SOURCE     => [ map "$_\n", $conf->config($template)],
4818                           DELIMITERS => [ '[@--', '--@]' ],
4819                         )
4820     or die "can't create new Text::Template object: Text::Template::ERROR";
4821
4822   $letter_template->compile()
4823     or die "can't compile template: Text::Template::ERROR";
4824
4825   my %letter_data = map { $_ => $self->$_ } $self->fields;
4826   $letter_data{payinfo} = $self->mask_payinfo;
4827
4828   #my $paydate = $self->paydate || '2037-12-31';
4829   my $paydate = $self->paydate =~ /^\S+$/ ? $self->paydate : '2037-12-31';
4830
4831   my $payby = $self->payby;
4832   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
4833   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
4834
4835   #credit cards expire at the end of the month/year of their exp date
4836   if ($payby eq 'CARD' || $payby eq 'DCRD') {
4837     $letter_data{payby} = 'credit card';
4838     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
4839     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
4840     $expire_time--;
4841   }elsif ($payby eq 'COMP') {
4842     $letter_data{payby} = 'complimentary account';
4843   }else{
4844     $letter_data{payby} = 'current method';
4845   }
4846   $letter_data{expdate} = $expire_time;
4847
4848   for (keys %{$options{extra_fields}}){
4849     $letter_data{$_} = $options{extra_fields}->{$_};
4850   }
4851
4852   unless(exists($letter_data{returnaddress})){
4853     my $retadd = join("\n", $conf->config_orbase( 'invoice_latexreturnaddress',
4854                                                   $self->agent_template)
4855                      );
4856     if ( length($retadd) ) {
4857       $letter_data{returnaddress} = $retadd;
4858     } elsif ( grep /\S/, $conf->config('company_address', $self->agentnum) ) {
4859       $letter_data{returnaddress} =
4860         join( "\n", map { s/( {2,})/'~' x length($1)/eg;
4861                           s/$/\\\\\*/;
4862                           $_;
4863                         }
4864                     ( $conf->config('company_name', $self->agentnum),
4865                       $conf->config('company_address', $self->agentnum),
4866                     )
4867         );
4868     } else {
4869       $letter_data{returnaddress} = '~';
4870     }
4871   }
4872
4873   $letter_data{conf_dir} = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
4874
4875   $letter_data{company_name} = $conf->config('company_name', $self->agentnum);
4876
4877   my $dir = $FS::UID::conf_dir."/cache.". $FS::UID::datasrc;
4878
4879   my $lh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4880                            DIR      => $dir,
4881                            SUFFIX   => '.eps',
4882                            UNLINK   => 0,
4883                          ) or die "can't open temp file: $!\n";
4884   print $lh $conf->config_binary('logo.eps', $self->agentnum)
4885     or die "can't write temp file: $!\n";
4886   close $lh;
4887   $letter_data{'logo_file'} = $lh->filename;
4888
4889   my $fh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4890                            DIR      => $dir,
4891                            SUFFIX   => '.tex',
4892                            UNLINK   => 0,
4893                          ) or die "can't open temp file: $!\n";
4894
4895   $letter_template->fill_in( OUTPUT => $fh, HASH => \%letter_data );
4896   close $fh;
4897   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
4898   return ($1, $letter_data{'logo_file'});
4899
4900 }
4901
4902 =item print_ps TEMPLATE
4903
4904 Returns an postscript letter filled in from TEMPLATE, as a scalar.
4905
4906 =cut
4907
4908 sub print_ps {
4909   my $self = shift;
4910   my($file, $lfile) = $self->generate_letter(@_);
4911   my $ps = FS::Misc::generate_ps($file);
4912   unlink($file.'.tex');
4913   unlink($lfile);
4914
4915   $ps;
4916 }
4917
4918 =item print TEMPLATE
4919
4920 Prints the filled in template.
4921
4922 TEMPLATE is the name of a L<Text::Template> to fill in and print.
4923
4924 =cut
4925
4926 sub queueable_print {
4927   my %opt = @_;
4928
4929   my $self = qsearchs('cust_main', { 'custnum' => $opt{custnum} } )
4930     or die "invalid customer number: " . $opt{custvnum};
4931
4932   my $error = $self->print( $opt{template} );
4933   die $error if $error;
4934 }
4935
4936 sub print {
4937   my ($self, $template) = (shift, shift);
4938   do_print(
4939     [ $self->print_ps($template) ],
4940     'agentnum' => $self->agentnum,
4941   );
4942 }
4943
4944 #these three subs should just go away once agent stuff is all config overrides
4945
4946 sub agent_template {
4947   my $self = shift;
4948   $self->_agent_plandata('agent_templatename');
4949 }
4950
4951 sub agent_invoice_from {
4952   my $self = shift;
4953   $self->_agent_plandata('agent_invoice_from');
4954 }
4955
4956 sub _agent_plandata {
4957   my( $self, $option ) = @_;
4958
4959   #yuck.  this whole thing needs to be reconciled better with 1.9's idea of
4960   #agent-specific Conf
4961
4962   use FS::part_event::Condition;
4963
4964   my $agentnum = $self->agentnum;
4965
4966   my $regexp = regexp_sql();
4967
4968   my $part_event_option =
4969     qsearchs({
4970       'select'    => 'part_event_option.*',
4971       'table'     => 'part_event_option',
4972       'addl_from' => q{
4973         LEFT JOIN part_event USING ( eventpart )
4974         LEFT JOIN part_event_option AS peo_agentnum
4975           ON ( part_event.eventpart = peo_agentnum.eventpart
4976                AND peo_agentnum.optionname = 'agentnum'
4977                AND peo_agentnum.optionvalue }. $regexp. q{ '(^|,)}. $agentnum. q{(,|$)'
4978              )
4979         LEFT JOIN part_event_condition
4980           ON ( part_event.eventpart = part_event_condition.eventpart
4981                AND part_event_condition.conditionname = 'cust_bill_age'
4982              )
4983         LEFT JOIN part_event_condition_option
4984           ON ( part_event_condition.eventconditionnum = part_event_condition_option.eventconditionnum
4985                AND part_event_condition_option.optionname = 'age'
4986              )
4987       },
4988       #'hashref'   => { 'optionname' => $option },
4989       #'hashref'   => { 'part_event_option.optionname' => $option },
4990       'extra_sql' =>
4991         " WHERE part_event_option.optionname = ". dbh->quote($option).
4992         " AND action = 'cust_bill_send_agent' ".
4993         " AND ( disabled IS NULL OR disabled != 'Y' ) ".
4994         " AND peo_agentnum.optionname = 'agentnum' ".
4995         " AND ( agentnum IS NULL OR agentnum = $agentnum ) ".
4996         " ORDER BY
4997            CASE WHEN part_event_condition_option.optionname IS NULL
4998            THEN -1
4999            ELSE ". FS::part_event::Condition->age2seconds_sql('part_event_condition_option.optionvalue').
5000         " END
5001           , part_event.weight".
5002         " LIMIT 1"
5003     });
5004
5005   unless ( $part_event_option ) {
5006     return $self->agent->invoice_template || ''
5007       if $option eq 'agent_templatename';
5008     return '';
5009   }
5010
5011   $part_event_option->optionvalue;
5012
5013 }
5014
5015 =item queued_bill 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
5016
5017 Subroutine (not a method), designed to be called from the queue.
5018
5019 Takes a list of options and values.
5020
5021 Pulls up the customer record via the custnum option and calls bill_and_collect.
5022
5023 =cut
5024
5025 sub queued_bill {
5026   my (%args) = @_; #, ($time, $invoice_time, $check_freq, $resetup) = @_;
5027
5028   my $cust_main = qsearchs( 'cust_main', { custnum => $args{'custnum'} } );
5029   warn 'bill_and_collect custnum#'. $cust_main->custnum. "\n";#log custnum w/pid
5030
5031   $cust_main->bill_and_collect( %args );
5032 }
5033
5034 sub process_bill_and_collect {
5035   my $job = shift;
5036   my $param = thaw(decode_base64(shift));
5037   my $cust_main = qsearchs( 'cust_main', { custnum => $param->{'custnum'} } )
5038       or die "custnum '$param->{custnum}' not found!\n";
5039   $param->{'job'}   = $job;
5040   $param->{'fatal'} = 1; # runs from job queue, will be caught
5041   $param->{'retry'} = 1;
5042
5043   $cust_main->bill_and_collect( %$param );
5044 }
5045
5046 =item process_censustract_update CUSTNUM
5047
5048 Queueable function to update the census tract to the current year (as set in
5049 the 'census_year' configuration variable) and retrieve the new tract code.
5050
5051 =cut
5052
5053 sub process_censustract_update {
5054   eval "use FS::Misc::Geo qw(get_censustract)";
5055   die $@ if $@;
5056   my $custnum = shift;
5057   my $cust_main = qsearchs( 'cust_main', { custnum => $custnum })
5058       or die "custnum '$custnum' not found!\n";
5059
5060   my $new_year = $conf->config('census_year') or return;
5061   my $new_tract = get_censustract({ $cust_main->location_hash }, $new_year);
5062   if ( $new_tract =~ /^\d/ ) {
5063     # then it's a tract code
5064         $cust_main->set('censustract', $new_tract);
5065     $cust_main->set('censusyear',  $new_year);
5066
5067     local($ignore_expired_card) = 1;
5068     local($ignore_illegal_zip) = 1;
5069     local($ignore_banned_card) = 1;
5070     local($skip_fuzzyfiles) = 1;
5071     local($import) = 1; #prevent automatic geocoding (need its own variable?)
5072     my $error = $cust_main->replace;
5073     die $error if $error;
5074   }
5075   else {
5076     # it's an error message
5077     die $new_tract;
5078   }
5079   return;
5080 }
5081
5082 #starting to take quite a while for big dbs
5083 # - seq scan of h_cust_main (yuck), but not going to index paycvv, so
5084 # - seq scan of cust_main on signupdate... index signupdate?  will that help?
5085 # - seq scan of cust_main on paydate... index on substrings?  maybe set an
5086 #    upgrade journal flag now that we have that, yyyy-m-dd paydates are ancient
5087 # - seq scan of cust_main on payinfo.. certainly not going toi ndex that...
5088 #    upgrade journal again?  this is also an ancient problem
5089 # - otaker upgrade?  journal and call it good?  (double check to make sure
5090 #    we're not still setting otaker here)
5091 #
5092 #only going to get worse with new location stuff...
5093
5094 sub _upgrade_data { #class method
5095   my ($class, %opts) = @_;
5096
5097   my @statements = (
5098     'UPDATE h_cust_main SET paycvv = NULL WHERE paycvv IS NOT NULL',
5099   );
5100
5101   #this seems to be the only expensive one.. why does it take so long?
5102   unless ( FS::upgrade_journal->is_done('cust_main__signupdate') ) {
5103     push @statements,
5104       'UPDATE cust_main SET signupdate = (SELECT signupdate FROM h_cust_main WHERE signupdate IS NOT NULL AND h_cust_main.custnum = cust_main.custnum ORDER BY historynum DESC LIMIT 1) WHERE signupdate IS NULL';
5105     FS::upgrade_journal->set_done('cust_main__signupdate');
5106   }
5107
5108   unless ( FS::upgrade_journal->is_done('cust_main__paydate') ) {
5109
5110     # fix yyyy-m-dd formatted paydates
5111     if ( driver_name =~ /^mysql/i ) {
5112       push @statements,
5113       "UPDATE cust_main SET paydate = CONCAT( SUBSTRING(paydate FROM 1 FOR 5), '0', SUBSTRING(paydate FROM 6) ) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5114     } else { # the SQL standard
5115       push @statements,
5116       "UPDATE cust_main SET paydate = SUBSTRING(paydate FROM 1 FOR 5) || '0' || SUBSTRING(paydate FROM 6) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
5117     }
5118     FS::upgrade_journal->set_done('cust_main__paydate');
5119   }
5120
5121   unless ( FS::upgrade_journal->is_done('cust_main__payinfo') ) {
5122
5123     push @statements, #fix the weird BILL with a cc# in payinfo problem
5124       #DCRD to be safe
5125       "UPDATE cust_main SET payby = 'DCRD' WHERE payby = 'BILL' and length(payinfo) = 16 and payinfo ". regexp_sql. q( '^[0-9]*$' );
5126
5127     FS::upgrade_journal->set_done('cust_main__payinfo');
5128
5129   }
5130
5131   my $t = time;
5132   foreach my $sql ( @statements ) {
5133     my $sth = dbh->prepare($sql) or die dbh->errstr;
5134     $sth->execute or die $sth->errstr;
5135     #warn ( (time - $t). " seconds\n" );
5136     #$t = time;
5137   }
5138
5139   local($ignore_expired_card) = 1;
5140   local($ignore_banned_card) = 1;
5141   local($skip_fuzzyfiles) = 1;
5142   local($import) = 1; #prevent automatic geocoding (need its own variable?)
5143   $class->_upgrade_otaker(%opts);
5144
5145   FS::cust_main::Location->_upgrade_data(%opts);
5146
5147 }
5148
5149 =back
5150
5151 =head1 BUGS
5152
5153 The delete method.
5154
5155 The delete method should possibly take an FS::cust_main object reference
5156 instead of a scalar customer number.
5157
5158 Bill and collect options should probably be passed as references instead of a
5159 list.
5160
5161 There should probably be a configuration file with a list of allowed credit
5162 card types.
5163
5164 No multiple currency support (probably a larger project than just this module).
5165
5166 payinfo_masked false laziness with cust_pay.pm and cust_refund.pm
5167
5168 Birthdates rely on negative epoch values.
5169
5170 The payby for card/check batches is broken.  With mixed batching, bad
5171 things will happen.
5172
5173 B<collect> I<invoice_time> should be renamed I<time>, like B<bill>.
5174
5175 =head1 SEE ALSO
5176
5177 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
5178 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
5179 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
5180
5181 =cut
5182
5183 1;
5184