FS/FS/cust_main.pm

   1 package FS::cust_main;
   2
   3 require 5.006;
   4 use strict;
   5              #FS::cust_main:_Marketgear when they're ready to move to 2.1
   6 use base qw( FS::cust_main::Packages FS::cust_main::Status
   7              FS::cust_main::Billing FS::cust_main::Billing_Realtime
   8              FS::cust_main::Billing_Discount
   9              FS::otaker_Mixin FS::payinfo_Mixin FS::cust_main_Mixin
  10              FS::geocode_Mixin
  11              FS::Record
  12            );
  13 use vars qw( $DEBUG $me $conf
  14              @encrypted_fields
  15              $import
  16              $ignore_expired_card $ignore_illegal_zip $ignore_banned_card
  17              $skip_fuzzyfiles
  18              @paytypes
  19            );
  20 use Carp;
  21 use Scalar::Util qw( blessed );
  22 use Time::Local qw(timelocal);
  23 use Storable qw(thaw);
  24 use MIME::Base64;
  25 use Data::Dumper;
  26 use Tie::IxHash;
  27 use Digest::MD5 qw(md5_base64);
  28 use Date::Format;
  29 #use Date::Manip;
  30 use File::Temp; #qw( tempfile );
  31 use Business::CreditCard 0.28;
  32 use Locale::Country;
  33 use FS::UID qw( getotaker dbh driver_name );
  34 use FS::Record qw( qsearchs qsearch dbdef regexp_sql );
  35 use FS::Misc qw( generate_email send_email generate_ps do_print );
  36 use FS::Msgcat qw(gettext);
  37 use FS::CurrentUser;
  38 use FS::TicketSystem;
  39 use FS::payby;
  40 use FS::cust_pkg;
  41 use FS::cust_svc;
  42 use FS::cust_bill;
  43 use FS::legacy_cust_bill;
  44 use FS::cust_pay;
  45 use FS::cust_pay_pending;
  46 use FS::cust_pay_void;
  47 use FS::cust_pay_batch;
  48 use FS::cust_credit;
  49 use FS::cust_refund;
  50 use FS::part_referral;
  51 use FS::cust_main_county;
  52 use FS::cust_location;
  53 use FS::cust_class;
  54 use FS::cust_main_exemption;
  55 use FS::cust_tax_adjustment;
  56 use FS::cust_tax_location;
  57 use FS::agent;
  58 use FS::cust_main_invoice;
  59 use FS::cust_tag;
  60 use FS::prepay_credit;
  61 use FS::queue;
  62 use FS::part_pkg;
  63 use FS::part_export;
  64 #use FS::cust_event;
  65 use FS::type_pkgs;
  66 use FS::payment_gateway;
  67 use FS::agent_payment_gateway;
  68 use FS::banned_pay;
  69 use FS::cust_main_note;
  70 use FS::cust_attachment;
  71 use FS::contact;
  72 use FS::Locales;
  73
  74 # 1 is mostly method/subroutine entry and options
  75 # 2 traces progress of some operations
  76 # 3 is even more information including possibly sensitive data
  77 $DEBUG = 0;
  78 $me = '[FS::cust_main]';
  79
  80 $import = 0;
  81 $ignore_expired_card = 0;
  82 $ignore_illegal_zip = 0;
  83 $ignore_banned_card = 0;
  84
  85 $skip_fuzzyfiles = 0;
  86
  87 @encrypted_fields = ('payinfo', 'paycvv');
  88 sub nohistory_fields { ('payinfo', 'paycvv'); }
  89
  90 @paytypes = ('', 'Personal checking', 'Personal savings', 'Business checking', 'Business savings');
  91
  92 #ask FS::UID to run this stuff for us later
  93 #$FS::UID::callback{'FS::cust_main'} = sub {
  94 install_callback FS::UID sub {
  95   $conf = new FS::Conf;
  96   #yes, need it for stuff below (prolly should be cached)
  97 };
  98
  99 sub _cache {
 100   my $self = shift;
 101   my ( $hashref, $cache ) = @_;
 102   if ( exists $hashref->{'pkgnum'} ) {
 103     #@{ $self->{'_pkgnum'} } = ();
 104     my $subcache = $cache->subcache( 'pkgnum', 'cust_pkg', $hashref->{custnum});
 105     $self->{'_pkgnum'} = $subcache;
 106     #push @{ $self->{'_pkgnum'} },
 107     FS::cust_pkg->new_or_cached($hashref, $subcache) if $hashref->{pkgnum};
 108   }
 109 }
 110
 111 =head1 NAME
 112
 113 FS::cust_main - Object methods for cust_main records
 114
 115 =head1 SYNOPSIS
 116
 117   use FS::cust_main;
 118
 119   $record = new FS::cust_main \%hash;
 120   $record = new FS::cust_main { 'column' => 'value' };
 121
 122   $error = $record->insert;
 123
 124   $error = $new_record->replace($old_record);
 125
 126   $error = $record->delete;
 127
 128   $error = $record->check;
 129
 130   @cust_pkg = $record->all_pkgs;
 131
 132   @cust_pkg = $record->ncancelled_pkgs;
 133
 134   @cust_pkg = $record->suspended_pkgs;
 135
 136   $error = $record->bill;
 137   $error = $record->bill %options;
 138   $error = $record->bill 'time' => $time;
 139
 140   $error = $record->collect;
 141   $error = $record->collect %options;
 142   $error = $record->collect 'invoice_time'   => $time,
 143                           ;
 144
 145 =head1 DESCRIPTION
 146
 147 An FS::cust_main object represents a customer.  FS::cust_main inherits from
 148 FS::Record.  The following fields are currently supported:
 149
 150 =over 4
 151
 152 =item custnum
 153
 154 Primary key (assigned automatically for new customers)
 155
 156 =item agentnum
 157
 158 Agent (see L<FS::agent>)
 159
 160 =item refnum
 161
 162 Advertising source (see L<FS::part_referral>)
 163
 164 =item first
 165
 166 First name
 167
 168 =item last
 169
 170 Last name
 171
 172 =item ss
 173
 174 Cocial security number (optional)
 175
 176 =item company
 177
 178 (optional)
 179
 180 =item address1
 181
 182 =item address2
 183
 184 (optional)
 185
 186 =item city
 187
 188 =item county
 189
 190 (optional, see L<FS::cust_main_county>)
 191
 192 =item state
 193
 194 (see L<FS::cust_main_county>)
 195
 196 =item zip
 197
 198 =item country
 199
 200 (see L<FS::cust_main_county>)
 201
 202 =item daytime
 203
 204 phone (optional)
 205
 206 =item night
 207
 208 phone (optional)
 209
 210 =item fax
 211
 212 phone (optional)
 213
 214 =item mobile
 215
 216 phone (optional)
 217
 218 =item ship_first
 219
 220 Shipping first name
 221
 222 =item ship_last
 223
 224 Shipping last name
 225
 226 =item ship_company
 227
 228 (optional)
 229
 230 =item ship_address1
 231
 232 =item ship_address2
 233
 234 (optional)
 235
 236 =item ship_city
 237
 238 =item ship_county
 239
 240 (optional, see L<FS::cust_main_county>)
 241
 242 =item ship_state
 243
 244 (see L<FS::cust_main_county>)
 245
 246 =item ship_zip
 247
 248 =item ship_country
 249
 250 (see L<FS::cust_main_county>)
 251
 252 =item ship_daytime
 253
 254 phone (optional)
 255
 256 =item ship_night
 257
 258 phone (optional)
 259
 260 =item ship_fax
 261
 262 phone (optional)
 263
 264 =item ship_mobile
 265
 266 phone (optional)
 267
 268 =item payby
 269
 270 Payment Type (See L<FS::payinfo_Mixin> for valid payby values)
 271
 272 =item payinfo
 273
 274 Payment Information (See L<FS::payinfo_Mixin> for data format)
 275
 276 =item paymask
 277
 278 Masked payinfo (See L<FS::payinfo_Mixin> for how this works)
 279
 280 =item paycvv
 281
 282 Card Verification Value, "CVV2" (also known as CVC2 or CID), the 3 or 4 digit number on the back (or front, for American Express) of the credit card
 283
 284 =item paydate
 285
 286 Expiration date, mm/yyyy, m/yyyy, mm/yy or m/yy
 287
 288 =item paystart_month
 289
 290 Start date month (maestro/solo cards only)
 291
 292 =item paystart_year
 293
 294 Start date year (maestro/solo cards only)
 295
 296 =item payissue
 297
 298 Issue number (maestro/solo cards only)
 299
 300 =item payname
 301
 302 Name on card or billing name
 303
 304 =item payip
 305
 306 IP address from which payment information was received
 307
 308 =item tax
 309
 310 Tax exempt, empty or `Y'
 311
 312 =item usernum
 313
 314 Order taker (see L<FS::access_user>)
 315
 316 =item comments
 317
 318 Comments (optional)
 319
 320 =item referral_custnum
 321
 322 Referring customer number
 323
 324 =item spool_cdr
 325
 326 Enable individual CDR spooling, empty or `Y'
 327
 328 =item dundate
 329
 330 A suggestion to events (see L<FS::part_bill_event">) to delay until this unix timestamp
 331
 332 =item squelch_cdr
 333
 334 Discourage individual CDR printing, empty or `Y'
 335
 336 =item edit_subject
 337
 338 Allow self-service editing of ticket subjects, empty or 'Y'
 339
 340 =item calling_list_exempt
 341
 342 Do not call, empty or 'Y'
 343
 344 =back
 345
 346 =head1 METHODS
 347
 348 =over 4
 349
 350 =item new HASHREF
 351
 352 Creates a new customer.  To add the customer to the database, see L<"insert">.
 353
 354 Note that this stores the hash reference, not a distinct copy of the hash it
 355 points to.  You can ask the object for a copy with the I<hash> method.
 356
 357 =cut
 358
 359 sub table { 'cust_main'; }
 360
 361 =item insert [ CUST_PKG_HASHREF [ , INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
 362
 363 Adds this customer to the database.  If there is an error, returns the error,
 364 otherwise returns false.
 365
 366 CUST_PKG_HASHREF: If you pass a Tie::RefHash data structure to the insert
 367 method containing FS::cust_pkg and FS::svc_I<tablename> objects, all records
 368 are inserted atomicly, or the transaction is rolled back.  Passing an empty
 369 hash reference is equivalent to not supplying this parameter.  There should be
 370 a better explanation of this, but until then, here's an example:
 371
 372   use Tie::RefHash;
 373   tie %hash, 'Tie::RefHash'; #this part is important
 374   %hash = (
 375     $cust_pkg => [ $svc_acct ],
 376     ...
 377   );
 378   $cust_main->insert( \%hash );
 379
 380 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
 381 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
 382 expected and rollback the entire transaction; it is not necessary to call
 383 check_invoicing_list first.  The invoicing_list is set after the records in the
 384 CUST_PKG_HASHREF above are inserted, so it is now possible to set an
 385 invoicing_list destination to the newly-created svc_acct.  Here's an example:
 386
 387   $cust_main->insert( {}, [ $email, 'POST' ] );
 388
 389 Currently available options are: I<depend_jobnum>, I<noexport>,
 390 I<tax_exemption> and I<prospectnum>.
 391
 392 If I<depend_jobnum> is set, all provisioning jobs will have a dependancy
 393 on the supplied jobnum (they will not run until the specific job completes).
 394 This can be used to defer provisioning until some action completes (such
 395 as running the customer's credit card successfully).
 396
 397 The I<noexport> option is deprecated.  If I<noexport> is set true, no
 398 provisioning jobs (exports) are scheduled.  (You can schedule them later with
 399 the B<reexport> method.)
 400
 401 The I<tax_exemption> option can be set to an arrayref of tax names.
 402 FS::cust_main_exemption records will be created and inserted.
 403
 404 If I<prospectnum> is set, moves contacts and locations from that prospect.
 405
 406 =cut
 407
 408 sub insert {
 409   my $self = shift;
 410   my $cust_pkgs = @_ ? shift : {};
 411   my $invoicing_list = @_ ? shift : '';
 412   my %options = @_;
 413   warn "$me insert called with options ".
 414        join(', ', map { "$_: $options{$_}" } keys %options ). "\n"
 415     if $DEBUG;
 416
 417   local $SIG{HUP} = 'IGNORE';
 418   local $SIG{INT} = 'IGNORE';
 419   local $SIG{QUIT} = 'IGNORE';
 420   local $SIG{TERM} = 'IGNORE';
 421   local $SIG{TSTP} = 'IGNORE';
 422   local $SIG{PIPE} = 'IGNORE';
 423
 424   my $oldAutoCommit = $FS::UID::AutoCommit;
 425   local $FS::UID::AutoCommit = 0;
 426   my $dbh = dbh;
 427
 428   my $prepay_identifier = '';
 429   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes ) = (0, 0, 0, 0, 0);
 430   my $payby = '';
 431   if ( $self->payby eq 'PREPAY' ) {
 432
 433     $self->payby('BILL');
 434     $prepay_identifier = $self->payinfo;
 435     $self->payinfo('');
 436
 437     warn "  looking up prepaid card $prepay_identifier\n"
 438       if $DEBUG > 1;
 439
 440     my $error = $self->get_prepay( $prepay_identifier,
 441                                    'amount_ref'     => \$amount,
 442                                    'seconds_ref'    => \$seconds,
 443                                    'upbytes_ref'    => \$upbytes,
 444                                    'downbytes_ref'  => \$downbytes,
 445                                    'totalbytes_ref' => \$totalbytes,
 446                                  );
 447     if ( $error ) {
 448       $dbh->rollback if $oldAutoCommit;
 449       #return "error applying prepaid card (transaction rolled back): $error";
 450       return $error;
 451     }
 452
 453     $payby = 'PREP' if $amount;
 454
 455   } elsif ( $self->payby =~ /^(CASH|WEST|MCRD)$/ ) {
 456
 457     $payby = $1;
 458     $self->payby('BILL');
 459     $amount = $self->paid;
 460
 461   }
 462
 463   warn "  inserting $self\n"
 464     if $DEBUG > 1;
 465
 466   $self->signupdate(time) unless $self->signupdate;
 467
 468   $self->auto_agent_custid()
 469     if $conf->config('cust_main-auto_agent_custid') && ! $self->agent_custid;
 470
 471   my $error = $self->SUPER::insert;
 472   if ( $error ) {
 473     $dbh->rollback if $oldAutoCommit;
 474     #return "inserting cust_main record (transaction rolled back): $error";
 475     return $error;
 476   }
 477
 478   warn "  setting invoicing list\n"
 479     if $DEBUG > 1;
 480
 481   if ( $invoicing_list ) {
 482     $error = $self->check_invoicing_list( $invoicing_list );
 483     if ( $error ) {
 484       $dbh->rollback if $oldAutoCommit;
 485       #return "checking invoicing_list (transaction rolled back): $error";
 486       return $error;
 487     }
 488     $self->invoicing_list( $invoicing_list );
 489   }
 490
 491   warn "  setting customer tags\n"
 492     if $DEBUG > 1;
 493
 494   foreach my $tagnum ( @{ $self->tagnum || [] } ) {
 495     my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
 496                                       'custnum' => $self->custnum };
 497     my $error = $cust_tag->insert;
 498     if ( $error ) {
 499       $dbh->rollback if $oldAutoCommit;
 500       return $error;
 501     }
 502   }
 503
 504   my $prospectnum = delete $options{'prospectnum'};
 505   if ( $prospectnum ) {
 506
 507     warn "  moving contacts and locations from prospect $prospectnum\n"
 508       if $DEBUG > 1;
 509
 510     my $prospect_main =
 511       qsearchs('prospect_main', { 'prospectnum' => $prospectnum } );
 512     unless ( $prospect_main ) {
 513       $dbh->rollback if $oldAutoCommit;
 514       return "Unknown prospectnum $prospectnum";
 515     }
 516     $prospect_main->custnum($self->custnum);
 517     $prospect_main->disabled('Y');
 518     my $error = $prospect_main->replace;
 519     if ( $error ) {
 520       $dbh->rollback if $oldAutoCommit;
 521       return $error;
 522     }
 523
 524     my @contact = $prospect_main->contact;
 525     my @cust_location = $prospect_main->cust_location;
 526     my @qual = $prospect_main->qual;
 527
 528     foreach my $r ( @contact, @cust_location, @qual ) {
 529       $r->prospectnum('');
 530       $r->custnum($self->custnum);
 531       my $error = $r->replace;
 532       if ( $error ) {
 533         $dbh->rollback if $oldAutoCommit;
 534         return $error;
 535       }
 536     }
 537
 538   }
 539
 540   warn "  setting cust_main_exemption\n"
 541     if $DEBUG > 1;
 542
 543   my $tax_exemption = delete $options{'tax_exemption'};
 544   if ( $tax_exemption ) {
 545     foreach my $taxname ( @$tax_exemption ) {
 546       my $cust_main_exemption = new FS::cust_main_exemption {
 547         'custnum' => $self->custnum,
 548         'taxname' => $taxname,
 549       };
 550       my $error = $cust_main_exemption->insert;
 551       if ( $error ) {
 552         $dbh->rollback if $oldAutoCommit;
 553         return "inserting cust_main_exemption (transaction rolled back): $error";
 554       }
 555     }
 556   }
 557
 558   if ( $self->can('start_copy_skel') ) {
 559     my $error = $self->start_copy_skel;
 560     if ( $error ) {
 561       $dbh->rollback if $oldAutoCommit;
 562       return $error;
 563     }
 564   }
 565
 566   warn "  ordering packages\n"
 567     if $DEBUG > 1;
 568
 569   $error = $self->order_pkgs( $cust_pkgs,
 570                               %options,
 571                               'seconds_ref'    => \$seconds,
 572                               'upbytes_ref'    => \$upbytes,
 573                               'downbytes_ref'  => \$downbytes,
 574                               'totalbytes_ref' => \$totalbytes,
 575                             );
 576   if ( $error ) {
 577     $dbh->rollback if $oldAutoCommit;
 578     return $error;
 579   }
 580
 581   if ( $seconds ) {
 582     $dbh->rollback if $oldAutoCommit;
 583     return "No svc_acct record to apply pre-paid time";
 584   }
 585   if ( $upbytes || $downbytes || $totalbytes ) {
 586     $dbh->rollback if $oldAutoCommit;
 587     return "No svc_acct record to apply pre-paid data";
 588   }
 589
 590   if ( $amount ) {
 591     warn "  inserting initial $payby payment of $amount\n"
 592       if $DEBUG > 1;
 593     $error = $self->insert_cust_pay($payby, $amount, $prepay_identifier);
 594     if ( $error ) {
 595       $dbh->rollback if $oldAutoCommit;
 596       return "inserting payment (transaction rolled back): $error";
 597     }
 598   }
 599
 600   unless ( $import || $skip_fuzzyfiles ) {
 601     warn "  queueing fuzzyfiles update\n"
 602       if $DEBUG > 1;
 603     $error = $self->queue_fuzzyfiles_update;
 604     if ( $error ) {
 605       $dbh->rollback if $oldAutoCommit;
 606       return "updating fuzzy search cache: $error";
 607     }
 608   }
 609
 610   # cust_main exports!
 611   warn "  exporting\n" if $DEBUG > 1;
 612
 613   my $export_args = $options{'export_args'} || [];
 614
 615   my @part_export =
 616     map qsearch( 'part_export', {exportnum=>$_} ),
 617       $conf->config('cust_main-exports'); #, $agentnum
 618
 619   foreach my $part_export ( @part_export ) {
 620     my $error = $part_export->export_insert($self, @$export_args);
 621     if ( $error ) {
 622       $dbh->rollback if $oldAutoCommit;
 623       return "exporting to ". $part_export->exporttype.
 624              " (transaction rolled back): $error";
 625     }
 626   }
 627
 628   #foreach my $depend_jobnum ( @$depend_jobnums ) {
 629   #    warn "[$me] inserting dependancies on supplied job $depend_jobnum\n"
 630   #      if $DEBUG;
 631   #    foreach my $jobnum ( @jobnums ) {
 632   #      my $queue = qsearchs('queue', { 'jobnum' => $jobnum } );
 633   #      warn "[$me] inserting dependancy for job $jobnum on $depend_jobnum\n"
 634   #        if $DEBUG;
 635   #      my $error = $queue->depend_insert($depend_jobnum);
 636   #      if ( $error ) {
 637   #        $dbh->rollback if $oldAutoCommit;
 638   #        return "error queuing job dependancy: $error";
 639   #      }
 640   #    }
 641   #  }
 642   #
 643   #}
 644   #
 645   #if ( exists $options{'jobnums'} ) {
 646   #  push @{ $options{'jobnums'} }, @jobnums;
 647   #}
 648
 649   warn "  insert complete; committing transaction\n"
 650     if $DEBUG > 1;
 651
 652   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 653   '';
 654
 655 }
 656
 657 use File::CounterFile;
 658 sub auto_agent_custid {
 659   my $self = shift;
 660
 661   my $format = $conf->config('cust_main-auto_agent_custid');
 662   my $agent_custid;
 663   if ( $format eq '1YMMXXXXXXXX' ) {
 664
 665     my $counter = new File::CounterFile 'cust_main.agent_custid';
 666     $counter->lock;
 667
 668     my $ym = 100000000000 + time2str('%y%m00000000', time);
 669     if ( $ym > $counter->value ) {
 670       $counter->{'value'} = $agent_custid = $ym;
 671       $counter->{'updated'} = 1;
 672     } else {
 673       $agent_custid = $counter->inc;
 674     }
 675
 676     $counter->unlock;
 677
 678   } else {
 679     die "Unknown cust_main-auto_agent_custid format: $format";
 680   }
 681
 682   $self->agent_custid($agent_custid);
 683
 684 }
 685
 686 =item PACKAGE METHODS
 687
 688 Documentation on customer package methods has been moved to
 689 L<FS::cust_main::Packages>.
 690
 691 =item recharge_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , AMOUNTREF, SECONDSREF, UPBYTEREF, DOWNBYTEREF ]
 692
 693 Recharges this (existing) customer with the specified prepaid card (see
 694 L<FS::prepay_credit>), specified either by I<identifier> or as an
 695 FS::prepay_credit object.  If there is an error, returns the error, otherwise
 696 returns false.
 697
 698 Optionally, five scalar references can be passed as well.  They will have their
 699 values filled in with the amount, number of seconds, and number of upload,
 700 download, and total bytes applied by this prepaid card.
 701
 702 =cut
 703
 704 #the ref bullshit here should be refactored like get_prepay.  MyAccount.pm is
 705 #the only place that uses these args
 706 sub recharge_prepay {
 707   my( $self, $prepay_credit, $amountref, $secondsref,
 708       $upbytesref, $downbytesref, $totalbytesref ) = @_;
 709
 710   local $SIG{HUP} = 'IGNORE';
 711   local $SIG{INT} = 'IGNORE';
 712   local $SIG{QUIT} = 'IGNORE';
 713   local $SIG{TERM} = 'IGNORE';
 714   local $SIG{TSTP} = 'IGNORE';
 715   local $SIG{PIPE} = 'IGNORE';
 716
 717   my $oldAutoCommit = $FS::UID::AutoCommit;
 718   local $FS::UID::AutoCommit = 0;
 719   my $dbh = dbh;
 720
 721   my( $amount, $seconds, $upbytes, $downbytes, $totalbytes) = ( 0, 0, 0, 0, 0 );
 722
 723   my $error = $self->get_prepay( $prepay_credit,
 724                                  'amount_ref'     => \$amount,
 725                                  'seconds_ref'    => \$seconds,
 726                                  'upbytes_ref'    => \$upbytes,
 727                                  'downbytes_ref'  => \$downbytes,
 728                                  'totalbytes_ref' => \$totalbytes,
 729                                )
 730            || $self->increment_seconds($seconds)
 731            || $self->increment_upbytes($upbytes)
 732            || $self->increment_downbytes($downbytes)
 733            || $self->increment_totalbytes($totalbytes)
 734            || $self->insert_cust_pay_prepay( $amount,
 735                                              ref($prepay_credit)
 736                                                ? $prepay_credit->identifier
 737                                                : $prepay_credit
 738                                            );
 739
 740   if ( $error ) {
 741     $dbh->rollback if $oldAutoCommit;
 742     return $error;
 743   }
 744
 745   if ( defined($amountref)  ) { $$amountref  = $amount;  }
 746   if ( defined($secondsref) ) { $$secondsref = $seconds; }
 747   if ( defined($upbytesref) ) { $$upbytesref = $upbytes; }
 748   if ( defined($downbytesref) ) { $$downbytesref = $downbytes; }
 749   if ( defined($totalbytesref) ) { $$totalbytesref = $totalbytes; }
 750
 751   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 752   '';
 753
 754 }
 755
 756 =item get_prepay IDENTIFIER | PREPAY_CREDIT_OBJ [ , OPTION => VALUE ... ]
 757
 758 Looks up and deletes a prepaid card (see L<FS::prepay_credit>),
 759 specified either by I<identifier> or as an FS::prepay_credit object.
 760
 761 Available options are: I<amount_ref>, I<seconds_ref>, I<upbytes_ref>, I<downbytes_ref>, and I<totalbytes_ref>.  The scalars (provided by references) will be
 762 incremented by the values of the prepaid card.
 763
 764 If the prepaid card specifies an I<agentnum> (see L<FS::agent>), it is used to
 765 check or set this customer's I<agentnum>.
 766
 767 If there is an error, returns the error, otherwise returns false.
 768
 769 =cut
 770
 771
 772 sub get_prepay {
 773   my( $self, $prepay_credit, %opt ) = @_;
 774
 775   local $SIG{HUP} = 'IGNORE';
 776   local $SIG{INT} = 'IGNORE';
 777   local $SIG{QUIT} = 'IGNORE';
 778   local $SIG{TERM} = 'IGNORE';
 779   local $SIG{TSTP} = 'IGNORE';
 780   local $SIG{PIPE} = 'IGNORE';
 781
 782   my $oldAutoCommit = $FS::UID::AutoCommit;
 783   local $FS::UID::AutoCommit = 0;
 784   my $dbh = dbh;
 785
 786   unless ( ref($prepay_credit) ) {
 787
 788     my $identifier = $prepay_credit;
 789
 790     $prepay_credit = qsearchs(
 791       'prepay_credit',
 792       { 'identifier' => $identifier },
 793       '',
 794       'FOR UPDATE'
 795     );
 796
 797     unless ( $prepay_credit ) {
 798       $dbh->rollback if $oldAutoCommit;
 799       return "Invalid prepaid card: ". $identifier;
 800     }
 801
 802   }
 803
 804   if ( $prepay_credit->agentnum ) {
 805     if ( $self->agentnum && $self->agentnum != $prepay_credit->agentnum ) {
 806       $dbh->rollback if $oldAutoCommit;
 807       return "prepaid card not valid for agent ". $self->agentnum;
 808     }
 809     $self->agentnum($prepay_credit->agentnum);
 810   }
 811
 812   my $error = $prepay_credit->delete;
 813   if ( $error ) {
 814     $dbh->rollback if $oldAutoCommit;
 815     return "removing prepay_credit (transaction rolled back): $error";
 816   }
 817
 818   ${ $opt{$_.'_ref'} } += $prepay_credit->$_()
 819     for grep $opt{$_.'_ref'}, qw( amount seconds upbytes downbytes totalbytes );
 820
 821   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 822   '';
 823
 824 }
 825
 826 =item increment_upbytes SECONDS
 827
 828 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 829 the specified number of upbytes.  If there is an error, returns the error,
 830 otherwise returns false.
 831
 832 =cut
 833
 834 sub increment_upbytes {
 835   _increment_column( shift, 'upbytes', @_);
 836 }
 837
 838 =item increment_downbytes SECONDS
 839
 840 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 841 the specified number of downbytes.  If there is an error, returns the error,
 842 otherwise returns false.
 843
 844 =cut
 845
 846 sub increment_downbytes {
 847   _increment_column( shift, 'downbytes', @_);
 848 }
 849
 850 =item increment_totalbytes SECONDS
 851
 852 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 853 the specified number of totalbytes.  If there is an error, returns the error,
 854 otherwise returns false.
 855
 856 =cut
 857
 858 sub increment_totalbytes {
 859   _increment_column( shift, 'totalbytes', @_);
 860 }
 861
 862 =item increment_seconds SECONDS
 863
 864 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 865 the specified number of seconds.  If there is an error, returns the error,
 866 otherwise returns false.
 867
 868 =cut
 869
 870 sub increment_seconds {
 871   _increment_column( shift, 'seconds', @_);
 872 }
 873
 874 =item _increment_column AMOUNT
 875
 876 Updates this customer's single or primary account (see L<FS::svc_acct>) by
 877 the specified number of seconds or bytes.  If there is an error, returns
 878 the error, otherwise returns false.
 879
 880 =cut
 881
 882 sub _increment_column {
 883   my( $self, $column, $amount ) = @_;
 884   warn "$me increment_column called: $column, $amount\n"
 885     if $DEBUG;
 886
 887   return '' unless $amount;
 888
 889   my @cust_pkg = grep { $_->part_pkg->svcpart('svc_acct') }
 890                       $self->ncancelled_pkgs;
 891
 892   if ( ! @cust_pkg ) {
 893     return 'No packages with primary or single services found'.
 894            ' to apply pre-paid time';
 895   } elsif ( scalar(@cust_pkg) > 1 ) {
 896     #maybe have a way to specify the package/account?
 897     return 'Multiple packages found to apply pre-paid time';
 898   }
 899
 900   my $cust_pkg = $cust_pkg[0];
 901   warn "  found package pkgnum ". $cust_pkg->pkgnum. "\n"
 902     if $DEBUG > 1;
 903
 904   my @cust_svc =
 905     $cust_pkg->cust_svc( $cust_pkg->part_pkg->svcpart('svc_acct') );
 906
 907   if ( ! @cust_svc ) {
 908     return 'No account found to apply pre-paid time';
 909   } elsif ( scalar(@cust_svc) > 1 ) {
 910     return 'Multiple accounts found to apply pre-paid time';
 911   }
 912
 913   my $svc_acct = $cust_svc[0]->svc_x;
 914   warn "  found service svcnum ". $svc_acct->pkgnum.
 915        ' ('. $svc_acct->email. ")\n"
 916     if $DEBUG > 1;
 917
 918   $column = "increment_$column";
 919   $svc_acct->$column($amount);
 920
 921 }
 922
 923 =item insert_cust_pay_prepay AMOUNT [ PAYINFO ]
 924
 925 Inserts a prepayment in the specified amount for this customer.  An optional
 926 second argument can specify the prepayment identifier for tracking purposes.
 927 If there is an error, returns the error, otherwise returns false.
 928
 929 =cut
 930
 931 sub insert_cust_pay_prepay {
 932   shift->insert_cust_pay('PREP', @_);
 933 }
 934
 935 =item insert_cust_pay_cash AMOUNT [ PAYINFO ]
 936
 937 Inserts a cash payment in the specified amount for this customer.  An optional
 938 second argument can specify the payment identifier for tracking purposes.
 939 If there is an error, returns the error, otherwise returns false.
 940
 941 =cut
 942
 943 sub insert_cust_pay_cash {
 944   shift->insert_cust_pay('CASH', @_);
 945 }
 946
 947 =item insert_cust_pay_west AMOUNT [ PAYINFO ]
 948
 949 Inserts a Western Union payment in the specified amount for this customer.  An
 950 optional second argument can specify the prepayment identifier for tracking
 951 purposes.  If there is an error, returns the error, otherwise returns false.
 952
 953 =cut
 954
 955 sub insert_cust_pay_west {
 956   shift->insert_cust_pay('WEST', @_);
 957 }
 958
 959 sub insert_cust_pay {
 960   my( $self, $payby, $amount ) = splice(@_, 0, 3);
 961   my $payinfo = scalar(@_) ? shift : '';
 962
 963   my $cust_pay = new FS::cust_pay {
 964     'custnum' => $self->custnum,
 965     'paid'    => sprintf('%.2f', $amount),
 966     #'_date'   => #date the prepaid card was purchased???
 967     'payby'   => $payby,
 968     'payinfo' => $payinfo,
 969   };
 970   $cust_pay->insert;
 971
 972 }
 973
 974 =item reexport
 975
 976 This method is deprecated.  See the I<depend_jobnum> option to the insert and
 977 order_pkgs methods for a better way to defer provisioning.
 978
 979 Re-schedules all exports by calling the B<reexport> method of all associated
 980 packages (see L<FS::cust_pkg>).  If there is an error, returns the error;
 981 otherwise returns false.
 982
 983 =cut
 984
 985 sub reexport {
 986   my $self = shift;
 987
 988   carp "WARNING: FS::cust_main::reexport is deprectated; ".
 989        "use the depend_jobnum option to insert or order_pkgs to delay export";
 990
 991   local $SIG{HUP} = 'IGNORE';
 992   local $SIG{INT} = 'IGNORE';
 993   local $SIG{QUIT} = 'IGNORE';
 994   local $SIG{TERM} = 'IGNORE';
 995   local $SIG{TSTP} = 'IGNORE';
 996   local $SIG{PIPE} = 'IGNORE';
 997
 998   my $oldAutoCommit = $FS::UID::AutoCommit;
 999   local $FS::UID::AutoCommit = 0;
1000   my $dbh = dbh;
1001
1002   foreach my $cust_pkg ( $self->ncancelled_pkgs ) {
1003     my $error = $cust_pkg->reexport;
1004     if ( $error ) {
1005       $dbh->rollback if $oldAutoCommit;
1006       return $error;
1007     }
1008   }
1009
1010   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1011   '';
1012
1013 }
1014
1015 =item delete [ OPTION => VALUE ... ]
1016
1017 This deletes the customer.  If there is an error, returns the error, otherwise
1018 returns false.
1019
1020 This will completely remove all traces of the customer record.  This is not
1021 what you want when a customer cancels service; for that, cancel all of the
1022 customer's packages (see L</cancel>).
1023
1024 If the customer has any uncancelled packages, you need to pass a new (valid)
1025 customer number for those packages to be transferred to, as the "new_customer"
1026 option.  Cancelled packages will be deleted.  Did I mention that this is NOT
1027 what you want when a customer cancels service and that you really should be
1028 looking at L<FS::cust_pkg/cancel>?
1029
1030 You can't delete a customer with invoices (see L<FS::cust_bill>),
1031 statements (see L<FS::cust_statement>), credits (see L<FS::cust_credit>),
1032 payments (see L<FS::cust_pay>) or refunds (see L<FS::cust_refund>), unless you
1033 set the "delete_financials" option to a true value.
1034
1035 =cut
1036
1037 sub delete {
1038   my( $self, %opt ) = @_;
1039
1040   local $SIG{HUP} = 'IGNORE';
1041   local $SIG{INT} = 'IGNORE';
1042   local $SIG{QUIT} = 'IGNORE';
1043   local $SIG{TERM} = 'IGNORE';
1044   local $SIG{TSTP} = 'IGNORE';
1045   local $SIG{PIPE} = 'IGNORE';
1046
1047   my $oldAutoCommit = $FS::UID::AutoCommit;
1048   local $FS::UID::AutoCommit = 0;
1049   my $dbh = dbh;
1050
1051   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1052      $dbh->rollback if $oldAutoCommit;
1053      return "Can't delete a master agent customer";
1054   }
1055
1056   #use FS::access_user
1057   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1058      $dbh->rollback if $oldAutoCommit;
1059      return "Can't delete a master employee customer";
1060   }
1061
1062   tie my %financial_tables, 'Tie::IxHash',
1063     'cust_bill'      => 'invoices',
1064     'cust_statement' => 'statements',
1065     'cust_credit'    => 'credits',
1066     'cust_pay'       => 'payments',
1067     'cust_refund'    => 'refunds',
1068   ;
1069
1070   foreach my $table ( keys %financial_tables ) {
1071
1072     my @records = $self->$table();
1073
1074     if ( @records && ! $opt{'delete_financials'} ) {
1075       $dbh->rollback if $oldAutoCommit;
1076       return "Can't delete a customer with ". $financial_tables{$table};
1077     }
1078
1079     foreach my $record ( @records ) {
1080       my $error = $record->delete;
1081       if ( $error ) {
1082         $dbh->rollback if $oldAutoCommit;
1083         return "Error deleting ". $financial_tables{$table}. ": $error\n";
1084       }
1085     }
1086
1087   }
1088
1089   my @cust_pkg = $self->ncancelled_pkgs;
1090   if ( @cust_pkg ) {
1091     my $new_custnum = $opt{'new_custnum'};
1092     unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1093       $dbh->rollback if $oldAutoCommit;
1094       return "Invalid new customer number: $new_custnum";
1095     }
1096     foreach my $cust_pkg ( @cust_pkg ) {
1097       my %hash = $cust_pkg->hash;
1098       $hash{'custnum'} = $new_custnum;
1099       my $new_cust_pkg = new FS::cust_pkg ( \%hash );
1100       my $error = $new_cust_pkg->replace($cust_pkg,
1101                                          options => { $cust_pkg->options },
1102                                         );
1103       if ( $error ) {
1104         $dbh->rollback if $oldAutoCommit;
1105         return $error;
1106       }
1107     }
1108   }
1109   my @cancelled_cust_pkg = $self->all_pkgs;
1110   foreach my $cust_pkg ( @cancelled_cust_pkg ) {
1111     my $error = $cust_pkg->delete;
1112     if ( $error ) {
1113       $dbh->rollback if $oldAutoCommit;
1114       return $error;
1115     }
1116   }
1117
1118   #cust_tax_adjustment in financials?
1119   #cust_pay_pending?  ouch
1120   #cust_recon?
1121   foreach my $table (qw(
1122     cust_main_invoice cust_main_exemption cust_tag cust_attachment contact
1123     cust_location cust_main_note cust_tax_adjustment
1124     cust_pay_void cust_pay_batch queue cust_tax_exempt
1125   )) {
1126     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1127       my $error = $record->delete;
1128       if ( $error ) {
1129         $dbh->rollback if $oldAutoCommit;
1130         return $error;
1131       }
1132     }
1133   }
1134
1135   my $sth = $dbh->prepare(
1136     'UPDATE cust_main SET referral_custnum = NULL WHERE referral_custnum = ?'
1137   ) or do {
1138     my $errstr = $dbh->errstr;
1139     $dbh->rollback if $oldAutoCommit;
1140     return $errstr;
1141   };
1142   $sth->execute($self->custnum) or do {
1143     my $errstr = $sth->errstr;
1144     $dbh->rollback if $oldAutoCommit;
1145     return $errstr;
1146   };
1147
1148   #tickets
1149
1150   my $ticket_dbh = '';
1151   if ($conf->config('ticket_system') eq 'RT_Internal') {
1152     $ticket_dbh = $dbh;
1153   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1154     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1155     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1156       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1157   }
1158
1159   if ( $ticket_dbh ) {
1160
1161     my $ticket_sth = $ticket_dbh->prepare(
1162       'DELETE FROM Links WHERE Target = ?'
1163     ) or do {
1164       my $errstr = $ticket_dbh->errstr;
1165       $dbh->rollback if $oldAutoCommit;
1166       return $errstr;
1167     };
1168     $ticket_sth->execute('freeside://freeside/cust_main/'.$self->custnum)
1169       or do {
1170         my $errstr = $ticket_sth->errstr;
1171         $dbh->rollback if $oldAutoCommit;
1172         return $errstr;
1173       };
1174
1175     #check and see if the customer is the only link on the ticket, and
1176     #if so, set the ticket to deleted status in RT?
1177     #maybe someday, for now this will at least fix tickets not displaying
1178
1179   }
1180
1181   #delete the customer record
1182
1183   my $error = $self->SUPER::delete;
1184   if ( $error ) {
1185     $dbh->rollback if $oldAutoCommit;
1186     return $error;
1187   }
1188
1189   # cust_main exports!
1190
1191   #my $export_args = $options{'export_args'} || [];
1192
1193   my @part_export =
1194     map qsearch( 'part_export', {exportnum=>$_} ),
1195       $conf->config('cust_main-exports'); #, $agentnum
1196
1197   foreach my $part_export ( @part_export ) {
1198     my $error = $part_export->export_delete( $self ); #, @$export_args);
1199     if ( $error ) {
1200       $dbh->rollback if $oldAutoCommit;
1201       return "exporting to ". $part_export->exporttype.
1202              " (transaction rolled back): $error";
1203     }
1204   }
1205
1206   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1207   '';
1208
1209 }
1210
1211 =item merge NEW_CUSTNUM [ , OPTION => VALUE ... ]
1212
1213 This merges this customer into the provided new custnum, and then deletes the
1214 customer.  If there is an error, returns the error, otherwise returns false.
1215
1216 The source customer's name, company name, phone numbers, agent,
1217 referring customer, customer class, advertising source, order taker, and
1218 billing information (except balance) are discarded.
1219
1220 All packages are moved to the target customer.  Packages with package locations
1221 are preserved.  Packages without package locations are moved to a new package
1222 location with the source customer's service/shipping address.
1223
1224 All invoices, statements, payments, credits and refunds are moved to the target
1225 customer.  The source customer's balance is added to the target customer.
1226
1227 All notes, attachments, tickets and customer tags are moved to the target
1228 customer.
1229
1230 Change history is not currently moved.
1231
1232 =cut
1233
1234 sub merge {
1235   my( $self, $new_custnum, %opt ) = @_;
1236
1237   return "Can't merge a customer into self" if $self->custnum == $new_custnum;
1238
1239   unless ( qsearchs( 'cust_main', { 'custnum' => $new_custnum } ) ) {
1240     return "Invalid new customer number: $new_custnum";
1241   }
1242
1243   local $SIG{HUP} = 'IGNORE';
1244   local $SIG{INT} = 'IGNORE';
1245   local $SIG{QUIT} = 'IGNORE';
1246   local $SIG{TERM} = 'IGNORE';
1247   local $SIG{TSTP} = 'IGNORE';
1248   local $SIG{PIPE} = 'IGNORE';
1249
1250   my $oldAutoCommit = $FS::UID::AutoCommit;
1251   local $FS::UID::AutoCommit = 0;
1252   my $dbh = dbh;
1253
1254   if ( qsearch('agent', { 'agent_custnum' => $self->custnum } ) ) {
1255      $dbh->rollback if $oldAutoCommit;
1256      return "Can't merge a master agent customer";
1257   }
1258
1259   #use FS::access_user
1260   if ( qsearch('access_user', { 'user_custnum' => $self->custnum } ) ) {
1261      $dbh->rollback if $oldAutoCommit;
1262      return "Can't merge a master employee customer";
1263   }
1264
1265   if ( qsearch('cust_pay_pending', { 'custnum' => $self->custnum,
1266                                      'status'  => { op=>'!=', value=>'done' },
1267                                    }
1268               )
1269   ) {
1270      $dbh->rollback if $oldAutoCommit;
1271      return "Can't merge a customer with pending payments";
1272   }
1273
1274   tie my %financial_tables, 'Tie::IxHash',
1275     'cust_bill'      => 'invoices',
1276     'cust_statement' => 'statements',
1277     'cust_credit'    => 'credits',
1278     'cust_pay'       => 'payments',
1279     'cust_pay_void'  => 'voided payments',
1280     'cust_refund'    => 'refunds',
1281   ;
1282
1283   foreach my $table ( keys %financial_tables ) {
1284
1285     my @records = $self->$table();
1286
1287     foreach my $record ( @records ) {
1288       $record->custnum($new_custnum);
1289       my $error = $record->replace;
1290       if ( $error ) {
1291         $dbh->rollback if $oldAutoCommit;
1292         return "Error merging ". $financial_tables{$table}. ": $error\n";
1293       }
1294     }
1295
1296   }
1297
1298   my $name = $self->ship_name;
1299
1300   my $locationnum = '';
1301   foreach my $cust_pkg ( $self->all_pkgs ) {
1302     $cust_pkg->custnum($new_custnum);
1303
1304     unless ( $cust_pkg->locationnum ) {
1305       unless ( $locationnum ) {
1306         my $cust_location = new FS::cust_location {
1307           $self->location_hash,
1308           'custnum' => $new_custnum,
1309         };
1310         my $error = $cust_location->insert;
1311         if ( $error ) {
1312           $dbh->rollback if $oldAutoCommit;
1313           return $error;
1314         }
1315         $locationnum = $cust_location->locationnum;
1316       }
1317       $cust_pkg->locationnum($locationnum);
1318     }
1319
1320     my $error = $cust_pkg->replace;
1321     if ( $error ) {
1322       $dbh->rollback if $oldAutoCommit;
1323       return $error;
1324     }
1325
1326     # add customer (ship) name to svc_phone.phone_name if blank
1327     my @cust_svc = $cust_pkg->cust_svc;
1328     foreach my $cust_svc (@cust_svc) {
1329       my($label, $value, $svcdb) = $cust_svc->label;
1330       next unless $svcdb eq 'svc_phone';
1331       my $svc_phone = $cust_svc->svc_x;
1332       next if $svc_phone->phone_name;
1333       $svc_phone->phone_name($name);
1334       my $error = $svc_phone->replace;
1335       if ( $error ) {
1336         $dbh->rollback if $oldAutoCommit;
1337         return $error;
1338       }
1339     }
1340
1341   }
1342
1343   #not considered:
1344   # cust_tax_exempt (texas tax exemptions)
1345   # cust_recon (some sort of not-well understood thing for OnPac)
1346
1347   #these are moved over
1348   foreach my $table (qw(
1349     cust_tag cust_location contact cust_attachment cust_main_note
1350     cust_tax_adjustment cust_pay_batch queue
1351   )) {
1352     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1353       $record->custnum($new_custnum);
1354       my $error = $record->replace;
1355       if ( $error ) {
1356         $dbh->rollback if $oldAutoCommit;
1357         return $error;
1358       }
1359     }
1360   }
1361
1362   #these aren't preserved
1363   foreach my $table (qw(
1364     cust_main_exemption cust_main_invoice
1365   )) {
1366     foreach my $record ( qsearch( $table, { 'custnum' => $self->custnum } ) ) {
1367       my $error = $record->delete;
1368       if ( $error ) {
1369         $dbh->rollback if $oldAutoCommit;
1370         return $error;
1371       }
1372     }
1373   }
1374
1375
1376   my $sth = $dbh->prepare(
1377     'UPDATE cust_main SET referral_custnum = ? WHERE referral_custnum = ?'
1378   ) or do {
1379     my $errstr = $dbh->errstr;
1380     $dbh->rollback if $oldAutoCommit;
1381     return $errstr;
1382   };
1383   $sth->execute($new_custnum, $self->custnum) or do {
1384     my $errstr = $sth->errstr;
1385     $dbh->rollback if $oldAutoCommit;
1386     return $errstr;
1387   };
1388
1389   #tickets
1390
1391   my $ticket_dbh = '';
1392   if ($conf->config('ticket_system') eq 'RT_Internal') {
1393     $ticket_dbh = $dbh;
1394   } elsif ($conf->config('ticket_system') eq 'RT_External') {
1395     my ($datasrc, $user, $pass) = $conf->config('ticket_system-rt_external_datasrc');
1396     $ticket_dbh = DBI->connect($datasrc, $user, $pass, { 'ChopBlanks' => 1 });
1397       #or die "RT_External DBI->connect error: $DBI::errstr\n";
1398   }
1399
1400   if ( $ticket_dbh ) {
1401
1402     my $ticket_sth = $ticket_dbh->prepare(
1403       'UPDATE Links SET Target = ? WHERE Target = ?'
1404     ) or do {
1405       my $errstr = $ticket_dbh->errstr;
1406       $dbh->rollback if $oldAutoCommit;
1407       return $errstr;
1408     };
1409     $ticket_sth->execute('freeside://freeside/cust_main/'.$new_custnum,
1410                          'freeside://freeside/cust_main/'.$self->custnum)
1411       or do {
1412         my $errstr = $ticket_sth->errstr;
1413         $dbh->rollback if $oldAutoCommit;
1414         return $errstr;
1415       };
1416
1417   }
1418
1419   #delete the customer record
1420
1421   my $error = $self->delete;
1422   if ( $error ) {
1423     $dbh->rollback if $oldAutoCommit;
1424     return $error;
1425   }
1426
1427   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1428   '';
1429
1430 }
1431
1432 =item replace [ OLD_RECORD ] [ INVOICING_LIST_ARYREF ] [ , OPTION => VALUE ... ] ]
1433
1434
1435 Replaces the OLD_RECORD with this one in the database.  If there is an error,
1436 returns the error, otherwise returns false.
1437
1438 INVOICING_LIST_ARYREF: If you pass an arrarref to the insert method, it will
1439 be set as the invoicing list (see L<"invoicing_list">).  Errors return as
1440 expected and rollback the entire transaction; it is not necessary to call
1441 check_invoicing_list first.  Here's an example:
1442
1443   $new_cust_main->replace( $old_cust_main, [ $email, 'POST' ] );
1444
1445 Currently available options are: I<tax_exemption>.
1446
1447 The I<tax_exemption> option can be set to an arrayref of tax names.
1448 FS::cust_main_exemption records will be deleted and inserted as appropriate.
1449
1450 =cut
1451
1452 sub replace {
1453   my $self = shift;
1454
1455   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
1456               ? shift
1457               : $self->replace_old;
1458
1459   my @param = @_;
1460
1461   warn "$me replace called\n"
1462     if $DEBUG;
1463
1464   my $curuser = $FS::CurrentUser::CurrentUser;
1465   if (    $self->payby eq 'COMP'
1466        && $self->payby ne $old->payby
1467        && ! $curuser->access_right('Complimentary customer')
1468      )
1469   {
1470     return "You are not permitted to create complimentary accounts.";
1471   }
1472
1473   if ( $old->get('geocode') && $old->get('geocode') eq $self->get('geocode')
1474        && $conf->exists('enable_taxproducts')
1475      )
1476   {
1477     my $pre = ($conf->exists('tax-ship_address') && $self->ship_zip)
1478                 ? 'ship_' : '';
1479     $self->set('geocode', '')
1480       if $old->get($pre.'zip') ne $self->get($pre.'zip')
1481       && length($self->get($pre.'zip')) >= 10;
1482   }
1483
1484   local($ignore_expired_card) = 1
1485     if $old->payby  =~ /^(CARD|DCRD)$/
1486     && $self->payby =~ /^(CARD|DCRD)$/
1487     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1488
1489   local($ignore_banned_card) = 1
1490     if (    $old->payby  =~ /^(CARD|DCRD)$/ && $self->payby =~ /^(CARD|DCRD)$/
1491          || $old->payby  =~ /^(CHEK|DCHK)$/ && $self->payby =~ /^(CHEK|DCHK)$/ )
1492     && ( $old->payinfo eq $self->payinfo || $old->paymask eq $self->paymask );
1493
1494   local $SIG{HUP} = 'IGNORE';
1495   local $SIG{INT} = 'IGNORE';
1496   local $SIG{QUIT} = 'IGNORE';
1497   local $SIG{TERM} = 'IGNORE';
1498   local $SIG{TSTP} = 'IGNORE';
1499   local $SIG{PIPE} = 'IGNORE';
1500
1501   my $oldAutoCommit = $FS::UID::AutoCommit;
1502   local $FS::UID::AutoCommit = 0;
1503   my $dbh = dbh;
1504
1505   my $error = $self->SUPER::replace($old);
1506
1507   if ( $error ) {
1508     $dbh->rollback if $oldAutoCommit;
1509     return $error;
1510   }
1511
1512   if ( @param && ref($param[0]) eq 'ARRAY' ) { # INVOICING_LIST_ARYREF
1513     my $invoicing_list = shift @param;
1514     $error = $self->check_invoicing_list( $invoicing_list );
1515     if ( $error ) {
1516       $dbh->rollback if $oldAutoCommit;
1517       return $error;
1518     }
1519     $self->invoicing_list( $invoicing_list );
1520   }
1521
1522   if ( $self->exists('tagnum') ) { #so we don't delete these on edit by accident
1523
1524     #this could be more efficient than deleting and re-inserting, if it matters
1525     foreach my $cust_tag (qsearch('cust_tag', {'custnum'=>$self->custnum} )) {
1526       my $error = $cust_tag->delete;
1527       if ( $error ) {
1528         $dbh->rollback if $oldAutoCommit;
1529         return $error;
1530       }
1531     }
1532     foreach my $tagnum ( @{ $self->tagnum || [] } ) {
1533       my $cust_tag = new FS::cust_tag { 'tagnum'  => $tagnum,
1534                                         'custnum' => $self->custnum };
1535       my $error = $cust_tag->insert;
1536       if ( $error ) {
1537         $dbh->rollback if $oldAutoCommit;
1538         return $error;
1539       }
1540     }
1541
1542   }
1543
1544   my %options = @param;
1545
1546   my $tax_exemption = delete $options{'tax_exemption'};
1547   if ( $tax_exemption ) {
1548
1549     my %cust_main_exemption =
1550       map { $_->taxname => $_ }
1551           qsearch('cust_main_exemption', { 'custnum' => $old->custnum } );
1552
1553     foreach my $taxname ( @$tax_exemption ) {
1554
1555       next if delete $cust_main_exemption{$taxname};
1556
1557       my $cust_main_exemption = new FS::cust_main_exemption {
1558         'custnum' => $self->custnum,
1559         'taxname' => $taxname,
1560       };
1561       my $error = $cust_main_exemption->insert;
1562       if ( $error ) {
1563         $dbh->rollback if $oldAutoCommit;
1564         return "inserting cust_main_exemption (transaction rolled back): $error";
1565       }
1566     }
1567
1568     foreach my $cust_main_exemption ( values %cust_main_exemption ) {
1569       my $error = $cust_main_exemption->delete;
1570       if ( $error ) {
1571         $dbh->rollback if $oldAutoCommit;
1572         return "deleting cust_main_exemption (transaction rolled back): $error";
1573       }
1574     }
1575
1576   }
1577
1578   if ( $self->payby =~ /^(CARD|CHEK|LECB)$/
1579        && ( ( $self->get('payinfo') ne $old->get('payinfo')
1580               && $self->get('payinfo') !~ /^99\d{14}$/
1581             )
1582             || grep { $self->get($_) ne $old->get($_) } qw(paydate payname)
1583           )
1584      )
1585   {
1586
1587     # card/check/lec info has changed, want to retry realtime_ invoice events
1588     my $error = $self->retry_realtime;
1589     if ( $error ) {
1590       $dbh->rollback if $oldAutoCommit;
1591       return $error;
1592     }
1593   }
1594
1595   unless ( $import || $skip_fuzzyfiles ) {
1596     $error = $self->queue_fuzzyfiles_update;
1597     if ( $error ) {
1598       $dbh->rollback if $oldAutoCommit;
1599       return "updating fuzzy search cache: $error";
1600     }
1601   }
1602
1603   # cust_main exports!
1604
1605   my $export_args = $options{'export_args'} || [];
1606
1607   my @part_export =
1608     map qsearch( 'part_export', {exportnum=>$_} ),
1609       $conf->config('cust_main-exports'); #, $agentnum
1610
1611   foreach my $part_export ( @part_export ) {
1612     my $error = $part_export->export_replace( $self, $old, @$export_args);
1613     if ( $error ) {
1614       $dbh->rollback if $oldAutoCommit;
1615       return "exporting to ". $part_export->exporttype.
1616              " (transaction rolled back): $error";
1617     }
1618   }
1619
1620   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1621   '';
1622
1623 }
1624
1625 =item queue_fuzzyfiles_update
1626
1627 Used by insert & replace to update the fuzzy search cache
1628
1629 =cut
1630
1631 use FS::cust_main::Search;
1632 sub queue_fuzzyfiles_update {
1633   my $self = shift;
1634
1635   local $SIG{HUP} = 'IGNORE';
1636   local $SIG{INT} = 'IGNORE';
1637   local $SIG{QUIT} = 'IGNORE';
1638   local $SIG{TERM} = 'IGNORE';
1639   local $SIG{TSTP} = 'IGNORE';
1640   local $SIG{PIPE} = 'IGNORE';
1641
1642   my $oldAutoCommit = $FS::UID::AutoCommit;
1643   local $FS::UID::AutoCommit = 0;
1644   my $dbh = dbh;
1645
1646   my $queue = new FS::queue { 'job' => 'FS::cust_main::Search::append_fuzzyfiles' };
1647   my $error = $queue->insert( map $self->getfield($_), @FS::cust_main::Search::fuzzyfields );
1648   if ( $error ) {
1649     $dbh->rollback if $oldAutoCommit;
1650     return "queueing job (transaction rolled back): $error";
1651   }
1652
1653   if ( $self->ship_last ) {
1654     $queue = new FS::queue { 'job' => 'FS::cust_main::Search::append_fuzzyfiles' };
1655     $error = $queue->insert( map $self->getfield("ship_$_"), @FS::cust_main::Search::fuzzyfields );
1656     if ( $error ) {
1657       $dbh->rollback if $oldAutoCommit;
1658       return "queueing job (transaction rolled back): $error";
1659     }
1660   }
1661
1662   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1663   '';
1664
1665 }
1666
1667 =item check
1668
1669 Checks all fields to make sure this is a valid customer record.  If there is
1670 an error, returns the error, otherwise returns false.  Called by the insert
1671 and replace methods.
1672
1673 =cut
1674
1675 sub check {
1676   my $self = shift;
1677
1678   warn "$me check BEFORE: \n". $self->_dump
1679     if $DEBUG > 2;
1680
1681   my $error =
1682     $self->ut_numbern('custnum')
1683     || $self->ut_number('agentnum')
1684     || $self->ut_textn('agent_custid')
1685     || $self->ut_number('refnum')
1686     || $self->ut_foreign_keyn('classnum', 'cust_class', 'classnum')
1687     || $self->ut_textn('custbatch')
1688     || $self->ut_name('last')
1689     || $self->ut_name('first')
1690     || $self->ut_snumbern('birthdate')
1691     || $self->ut_snumbern('signupdate')
1692     || $self->ut_textn('company')
1693     || $self->ut_text('address1')
1694     || $self->ut_textn('address2')
1695     || $self->ut_text('city')
1696     || $self->ut_textn('county')
1697     || $self->ut_textn('state')
1698     || $self->ut_country('country')
1699     || $self->ut_anything('comments')
1700     || $self->ut_numbern('referral_custnum')
1701     || $self->ut_textn('stateid')
1702     || $self->ut_textn('stateid_state')
1703     || $self->ut_textn('invoice_terms')
1704     || $self->ut_alphan('geocode')
1705     || $self->ut_floatn('cdr_termination_percentage')
1706     || $self->ut_floatn('credit_limit')
1707     || $self->ut_numbern('billday')
1708     || $self->ut_enum('edit_subject', [ '', 'Y' ] )
1709     || $self->ut_enum('calling_list_exempt', [ '', 'Y' ] )
1710     || $self->ut_enum('locale', [ '', FS::Locales->locales ])
1711   ;
1712
1713   #barf.  need message catalogs.  i18n.  etc.
1714   $error .= "Please select an advertising source."
1715     if $error =~ /^Illegal or empty \(numeric\) refnum: /;
1716   return $error if $error;
1717
1718   return "Unknown agent"
1719     unless qsearchs( 'agent', { 'agentnum' => $self->agentnum } );
1720
1721   return "Unknown refnum"
1722     unless qsearchs( 'part_referral', { 'refnum' => $self->refnum } );
1723
1724   return "Unknown referring custnum: ". $self->referral_custnum
1725     unless ! $self->referral_custnum
1726            || qsearchs( 'cust_main', { 'custnum' => $self->referral_custnum } );
1727
1728   if ( $self->censustract ne '' ) {
1729     $self->censustract =~ /^\s*(\d{9})\.?(\d{2})\s*$/
1730       or return "Illegal census tract: ". $self->censustract;
1731
1732     $self->censustract("$1.$2");
1733   }
1734
1735   if ( $self->ss eq '' ) {
1736     $self->ss('');
1737   } else {
1738     my $ss = $self->ss;
1739     $ss =~ s/\D//g;
1740     $ss =~ /^(\d{3})(\d{2})(\d{4})$/
1741       or return "Illegal social security number: ". $self->ss;
1742     $self->ss("$1-$2-$3");
1743   }
1744
1745
1746 # bad idea to disable, causes billing to fail because of no tax rates later
1747 # except we don't fail any more
1748   unless ( $import ) {
1749     unless ( qsearch('cust_main_county', {
1750       'country' => $self->country,
1751       'state'   => '',
1752      } ) ) {
1753       return "Unknown state/county/country: ".
1754         $self->state. "/". $self->county. "/". $self->country
1755         unless qsearch('cust_main_county',{
1756           'state'   => $self->state,
1757           'county'  => $self->county,
1758           'country' => $self->country,
1759         } );
1760     }
1761   }
1762
1763   $error =
1764        $self->ut_phonen('daytime', $self->country)
1765     || $self->ut_phonen('night',   $self->country)
1766     || $self->ut_phonen('fax',     $self->country)
1767     || $self->ut_phonen('mobile',  $self->country)
1768   ;
1769   return $error if $error;
1770
1771   unless ( $ignore_illegal_zip ) {
1772     $error = $self->ut_zip('zip', $self->country);
1773     return $error if $error;
1774   }
1775
1776   if ( $conf->exists('cust_main-require_phone')
1777        && ! length($self->daytime) && ! length($self->night) && ! length($self->mobile)
1778      ) {
1779
1780     my $daytime_label = FS::Msgcat::_gettext('daytime') =~ /^(daytime)?$/
1781                           ? 'Day Phone'
1782                           : FS::Msgcat::_gettext('daytime');
1783     my $night_label = FS::Msgcat::_gettext('night') =~ /^(night)?$/
1784                         ? 'Night Phone'
1785                         : FS::Msgcat::_gettext('night');
1786
1787     my $mobile_label = FS::Msgcat::_gettext('mobile') =~ /^(mobile)?$/
1788                         ? 'Mobile Phone'
1789                         : FS::Msgcat::_gettext('mobile');
1790
1791     return "$daytime_label, $night_label or $mobile_label is required"
1792
1793   }
1794
1795   if ( $self->has_ship_address
1796        && scalar ( grep { $self->getfield($_) ne $self->getfield("ship_$_") }
1797                         $self->addr_fields )
1798      )
1799   {
1800     my $error =
1801       $self->ut_name('ship_last')
1802       || $self->ut_name('ship_first')
1803       || $self->ut_textn('ship_company')
1804       || $self->ut_text('ship_address1')
1805       || $self->ut_textn('ship_address2')
1806       || $self->ut_text('ship_city')
1807       || $self->ut_textn('ship_county')
1808       || $self->ut_textn('ship_state')
1809       || $self->ut_country('ship_country')
1810     ;
1811     return $error if $error;
1812
1813     #false laziness with above
1814     unless ( qsearchs('cust_main_county', {
1815       'country' => $self->ship_country,
1816       'state'   => '',
1817      } ) ) {
1818       return "Unknown ship_state/ship_county/ship_country: ".
1819         $self->ship_state. "/". $self->ship_county. "/". $self->ship_country
1820         unless qsearch('cust_main_county',{
1821           'state'   => $self->ship_state,
1822           'county'  => $self->ship_county,
1823           'country' => $self->ship_country,
1824         } );
1825     }
1826     #eofalse
1827
1828     $error =
1829          $self->ut_phonen('ship_daytime', $self->ship_country)
1830       || $self->ut_phonen('ship_night',   $self->ship_country)
1831       || $self->ut_phonen('ship_fax',     $self->ship_country)
1832       || $self->ut_phonen('ship_mobile',  $self->ship_country)
1833     ;
1834     return $error if $error;
1835
1836     unless ( $ignore_illegal_zip ) {
1837       $error = $self->ut_zip('ship_zip', $self->ship_country);
1838       return $error if $error;
1839     }
1840     return "Unit # is required."
1841       if $self->ship_address2 =~ /^\s*$/
1842       && $conf->exists('cust_main-require_address2');
1843
1844   } else { # ship_ info eq billing info, so don't store dup info in database
1845
1846     $self->setfield("ship_$_", '')
1847       foreach $self->addr_fields;
1848
1849     return "Unit # is required."
1850       if $self->address2 =~ /^\s*$/
1851       && $conf->exists('cust_main-require_address2');
1852
1853   }
1854
1855   #$self->payby =~ /^(CARD|DCRD|CHEK|DCHK|LECB|BILL|COMP|PREPAY|CASH|WEST|MCRD)$/
1856   #  or return "Illegal payby: ". $self->payby;
1857   #$self->payby($1);
1858   FS::payby->can_payby($self->table, $self->payby)
1859     or return "Illegal payby: ". $self->payby;
1860
1861   $error =    $self->ut_numbern('paystart_month')
1862            || $self->ut_numbern('paystart_year')
1863            || $self->ut_numbern('payissue')
1864            || $self->ut_textn('paytype')
1865   ;
1866   return $error if $error;
1867
1868   if ( $self->payip eq '' ) {
1869     $self->payip('');
1870   } else {
1871     $error = $self->ut_ip('payip');
1872     return $error if $error;
1873   }
1874
1875   # If it is encrypted and the private key is not availaible then we can't
1876   # check the credit card.
1877   my $check_payinfo = ! $self->is_encrypted($self->payinfo);
1878
1879   if ( $check_payinfo && $self->payby =~ /^(CARD|DCRD)$/ ) {
1880
1881     my $payinfo = $self->payinfo;
1882     $payinfo =~ s/\D//g;
1883     $payinfo =~ /^(\d{13,16}|\d{8,9})$/
1884       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1885     $payinfo = $1;
1886     $self->payinfo($payinfo);
1887     validate($payinfo)
1888       or return gettext('invalid_card'); # . ": ". $self->payinfo;
1889
1890     return gettext('unknown_card_type')
1891       if $self->payinfo !~ /^99\d{14}$/ #token
1892       && cardtype($self->payinfo) eq "Unknown";
1893
1894     unless ( $ignore_banned_card ) {
1895       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1896       if ( $ban ) {
1897         if ( $ban->bantype eq 'warn' ) {
1898           #or others depending on value of $ban->reason ?
1899           return '_duplicate_card'.
1900                  ': disabled from'. time2str('%a %h %o at %r', $ban->_date).
1901                  ' until '.         time2str('%a %h %o at %r', $ban->_end_date).
1902                  ' (ban# '. $ban->bannum. ')'
1903             unless $self->override_ban_warn;
1904         } else {
1905           return 'Banned credit card: banned on '.
1906                  time2str('%a %h %o at %r', $ban->_date).
1907                  ' by '. $ban->otaker.
1908                  ' (ban# '. $ban->bannum. ')';
1909         }
1910       }
1911     }
1912
1913     if (length($self->paycvv) && !$self->is_encrypted($self->paycvv)) {
1914       if ( cardtype($self->payinfo) eq 'American Express card' ) {
1915         $self->paycvv =~ /^(\d{4})$/
1916           or return "CVV2 (CID) for American Express cards is four digits.";
1917         $self->paycvv($1);
1918       } else {
1919         $self->paycvv =~ /^(\d{3})$/
1920           or return "CVV2 (CVC2/CID) is three digits.";
1921         $self->paycvv($1);
1922       }
1923     } else {
1924       $self->paycvv('');
1925     }
1926
1927     my $cardtype = cardtype($payinfo);
1928     if ( $cardtype =~ /^(Switch|Solo)$/i ) {
1929
1930       return "Start date or issue number is required for $cardtype cards"
1931         unless $self->paystart_month && $self->paystart_year or $self->payissue;
1932
1933       return "Start month must be between 1 and 12"
1934         if $self->paystart_month
1935            and $self->paystart_month < 1 || $self->paystart_month > 12;
1936
1937       return "Start year must be 1990 or later"
1938         if $self->paystart_year
1939            and $self->paystart_year < 1990;
1940
1941       return "Issue number must be beween 1 and 99"
1942         if $self->payissue
1943           and $self->payissue < 1 || $self->payissue > 99;
1944
1945     } else {
1946       $self->paystart_month('');
1947       $self->paystart_year('');
1948       $self->payissue('');
1949     }
1950
1951   } elsif ( $check_payinfo && $self->payby =~ /^(CHEK|DCHK)$/ ) {
1952
1953     my $payinfo = $self->payinfo;
1954     $payinfo =~ s/[^\d\@\.]//g;
1955     if ( $conf->exists('cust_main-require-bank-branch') ) {
1956       $payinfo =~ /^(\d+)\@(\d+)\.(\d+)$/ or return 'invalid echeck account@branch.bank';
1957       $payinfo = "$1\@$2.$3";
1958     } elsif ( $conf->exists('echeck-nonus') ) {
1959       $payinfo =~ /^(\d+)\@(\d+)$/ or return 'invalid echeck account@aba';
1960       $payinfo = "$1\@$2";
1961     } else {
1962       $payinfo =~ /^(\d+)\@(\d{9})$/ or return 'invalid echeck account@aba';
1963       $payinfo = "$1\@$2";
1964     }
1965     $self->payinfo($payinfo);
1966     $self->paycvv('');
1967
1968     unless ( $ignore_banned_card ) {
1969       my $ban = FS::banned_pay->ban_search( %{ $self->_banned_pay_hashref } );
1970       if ( $ban ) {
1971         if ( $ban->bantype eq 'warn' ) {
1972           #or others depending on value of $ban->reason ?
1973           return '_duplicate_ach' unless $self->override_ban_warn;
1974         } else {
1975           return 'Banned ACH account: banned on '.
1976                  time2str('%a %h %o at %r', $ban->_date).
1977                  ' by '. $ban->otaker.
1978                  ' (ban# '. $ban->bannum. ')';
1979         }
1980       }
1981     }
1982
1983   } elsif ( $self->payby eq 'LECB' ) {
1984
1985     my $payinfo = $self->payinfo;
1986     $payinfo =~ s/\D//g;
1987     $payinfo =~ /^1?(\d{10})$/ or return 'invalid btn billing telephone number';
1988     $payinfo = $1;
1989     $self->payinfo($payinfo);
1990     $self->paycvv('');
1991
1992   } elsif ( $self->payby eq 'BILL' ) {
1993
1994     $error = $self->ut_textn('payinfo');
1995     return "Illegal P.O. number: ". $self->payinfo if $error;
1996     $self->paycvv('');
1997
1998   } elsif ( $self->payby eq 'COMP' ) {
1999
2000     my $curuser = $FS::CurrentUser::CurrentUser;
2001     if (    ! $self->custnum
2002          && ! $curuser->access_right('Complimentary customer')
2003        )
2004     {
2005       return "You are not permitted to create complimentary accounts."
2006     }
2007
2008     $error = $self->ut_textn('payinfo');
2009     return "Illegal comp account issuer: ". $self->payinfo if $error;
2010     $self->paycvv('');
2011
2012   } elsif ( $self->payby eq 'PREPAY' ) {
2013
2014     my $payinfo = $self->payinfo;
2015     $payinfo =~ s/\W//g; #anything else would just confuse things
2016     $self->payinfo($payinfo);
2017     $error = $self->ut_alpha('payinfo');
2018     return "Illegal prepayment identifier: ". $self->payinfo if $error;
2019     return "Unknown prepayment identifier"
2020       unless qsearchs('prepay_credit', { 'identifier' => $self->payinfo } );
2021     $self->paycvv('');
2022
2023   }
2024
2025   if ( $self->paydate eq '' || $self->paydate eq '-' ) {
2026     return "Expiration date required"
2027       unless $self->payby =~ /^(BILL|PREPAY|CHEK|DCHK|LECB|CASH|WEST|MCRD)$/;
2028     $self->paydate('');
2029   } else {
2030     my( $m, $y );
2031     if ( $self->paydate =~ /^(\d{1,2})[\/\-](\d{2}(\d{2})?)$/ ) {
2032       ( $m, $y ) = ( $1, length($2) == 4 ? $2 : "20$2" );
2033     } elsif ( $self->paydate =~ /^19(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2034       ( $m, $y ) = ( $2, "19$1" );
2035     } elsif ( $self->paydate =~ /^(20)?(\d{2})[\/\-](\d{1,2})[\/\-]\d+$/ ) {
2036       ( $m, $y ) = ( $3, "20$2" );
2037     } else {
2038       return "Illegal expiration date: ". $self->paydate;
2039     }
2040     $m = sprintf('%02d',$m);
2041     $self->paydate("$y-$m-01");
2042     my($nowm,$nowy)=(localtime(time))[4,5]; $nowm++; $nowy+=1900;
2043     return gettext('expired_card')
2044       if !$import
2045       && !$ignore_expired_card
2046       && ( $y<$nowy || ( $y==$nowy && $1<$nowm ) );
2047   }
2048
2049   if ( $self->payname eq '' && $self->payby !~ /^(CHEK|DCHK)$/ &&
2050        ( ! $conf->exists('require_cardname')
2051          || $self->payby !~ /^(CARD|DCRD)$/  )
2052   ) {
2053     $self->payname( $self->first. " ". $self->getfield('last') );
2054   } else {
2055     $self->payname =~ /^([\w \,\.\-\'\&]+)$/
2056       or return gettext('illegal_name'). " payname: ". $self->payname;
2057     $self->payname($1);
2058   }
2059
2060   foreach my $flag (qw( tax spool_cdr squelch_cdr archived email_csv_cdr )) {
2061     $self->$flag() =~ /^(Y?)$/ or return "Illegal $flag: ". $self->$flag();
2062     $self->$flag($1);
2063   }
2064
2065   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
2066
2067   warn "$me check AFTER: \n". $self->_dump
2068     if $DEBUG > 2;
2069
2070   $self->SUPER::check;
2071 }
2072
2073 =item addr_fields
2074
2075 Returns a list of fields which have ship_ duplicates.
2076
2077 =cut
2078
2079 sub addr_fields {
2080   qw( last first company
2081       address1 address2 city county state zip country
2082       daytime night fax mobile
2083     );
2084 }
2085
2086 =item has_ship_address
2087
2088 Returns true if this customer record has a separate shipping address.
2089
2090 =cut
2091
2092 sub has_ship_address {
2093   my $self = shift;
2094   scalar( grep { $self->getfield("ship_$_") ne '' } $self->addr_fields );
2095 }
2096
2097 =item location_hash
2098
2099 Returns a list of key/value pairs, with the following keys: address1, adddress2,
2100 city, county, state, zip, country, and geocode.  The shipping address is used if present.
2101
2102 =cut
2103
2104 =item cust_location
2105
2106 Returns all locations (see L<FS::cust_location>) for this customer.
2107
2108 =cut
2109
2110 sub cust_location {
2111   my $self = shift;
2112   qsearch('cust_location', { 'custnum' => $self->custnum } );
2113 }
2114
2115 =item cust_contact
2116
2117 Returns all contacts (see L<FS::contact>) for this customer.
2118
2119 =cut
2120
2121 #already used :/ sub contact {
2122 sub cust_contact {
2123   my $self = shift;
2124   qsearch('contact', { 'custnum' => $self->custnum } );
2125 }
2126
2127 =item unsuspend
2128
2129 Unsuspends all unflagged suspended packages (see L</unflagged_suspended_pkgs>
2130 and L<FS::cust_pkg>) for this customer.  Always returns a list: an empty list
2131 on success or a list of errors.
2132
2133 =cut
2134
2135 sub unsuspend {
2136   my $self = shift;
2137   grep { $_->unsuspend } $self->suspended_pkgs;
2138 }
2139
2140 =item suspend
2141
2142 Suspends all unsuspended packages (see L<FS::cust_pkg>) for this customer.
2143
2144 Returns a list: an empty list on success or a list of errors.
2145
2146 =cut
2147
2148 sub suspend {
2149   my $self = shift;
2150   grep { $_->suspend(@_) } $self->unsuspended_pkgs;
2151 }
2152
2153 =item suspend_if_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2154
2155 Suspends all unsuspended packages (see L<FS::cust_pkg>) matching the listed
2156 PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref instead
2157 of a list of pkgparts; the hashref has the following keys:
2158
2159 =over 4
2160
2161 =item pkgparts - listref of pkgparts
2162
2163 =item (other options are passed to the suspend method)
2164
2165 =back
2166
2167
2168 Returns a list: an empty list on success or a list of errors.
2169
2170 =cut
2171
2172 sub suspend_if_pkgpart {
2173   my $self = shift;
2174   my (@pkgparts, %opt);
2175   if (ref($_[0]) eq 'HASH'){
2176     @pkgparts = @{$_[0]{pkgparts}};
2177     %opt      = %{$_[0]};
2178   }else{
2179     @pkgparts = @_;
2180   }
2181   grep { $_->suspend(%opt) }
2182     grep { my $pkgpart = $_->pkgpart; grep { $pkgpart eq $_ } @pkgparts }
2183       $self->unsuspended_pkgs;
2184 }
2185
2186 =item suspend_unless_pkgpart HASHREF | PKGPART [ , PKGPART ... ]
2187
2188 Suspends all unsuspended packages (see L<FS::cust_pkg>) unless they match the
2189 given PKGPARTs (see L<FS::part_pkg>).  Preferred usage is to pass a hashref
2190 instead of a list of pkgparts; the hashref has the following keys:
2191
2192 =over 4
2193
2194 =item pkgparts - listref of pkgparts
2195
2196 =item (other options are passed to the suspend method)
2197
2198 =back
2199
2200 Returns a list: an empty list on success or a list of errors.
2201
2202 =cut
2203
2204 sub suspend_unless_pkgpart {
2205   my $self = shift;
2206   my (@pkgparts, %opt);
2207   if (ref($_[0]) eq 'HASH'){
2208     @pkgparts = @{$_[0]{pkgparts}};
2209     %opt      = %{$_[0]};
2210   }else{
2211     @pkgparts = @_;
2212   }
2213   grep { $_->suspend(%opt) }
2214     grep { my $pkgpart = $_->pkgpart; ! grep { $pkgpart eq $_ } @pkgparts }
2215       $self->unsuspended_pkgs;
2216 }
2217
2218 =item cancel [ OPTION => VALUE ... ]
2219
2220 Cancels all uncancelled packages (see L<FS::cust_pkg>) for this customer.
2221
2222 Available options are:
2223
2224 =over 4
2225
2226 =item quiet - can be set true to supress email cancellation notices.
2227
2228 =item reason - can be set to a cancellation reason (see L<FS:reason>), either a reasonnum of an existing reason, or passing a hashref will create a new reason.  The hashref should have the following keys: typenum - Reason type (see L<FS::reason_type>, reason - Text of the new reason.
2229
2230 =item ban - can be set true to ban this customer's credit card or ACH information, if present.
2231
2232 =item nobill - can be set true to skip billing if it might otherwise be done.
2233
2234 =back
2235
2236 Always returns a list: an empty list on success or a list of errors.
2237
2238 =cut
2239
2240 # nb that dates are not specified as valid options to this method
2241
2242 sub cancel {
2243   my( $self, %opt ) = @_;
2244
2245   warn "$me cancel called on customer ". $self->custnum. " with options ".
2246        join(', ', map { "$_: $opt{$_}" } keys %opt ). "\n"
2247     if $DEBUG;
2248
2249   return ( 'access denied' )
2250     unless $FS::CurrentUser::CurrentUser->access_right('Cancel customer');
2251
2252   if ( $opt{'ban'} && $self->payby =~ /^(CARD|DCRD|CHEK|DCHK)$/ ) {
2253
2254     #should try decryption (we might have the private key)
2255     # and if not maybe queue a job for the server that does?
2256     return ( "Can't (yet) ban encrypted credit cards" )
2257       if $self->is_encrypted($self->payinfo);
2258
2259     my $ban = new FS::banned_pay $self->_new_banned_pay_hashref;
2260     my $error = $ban->insert;
2261     return ( $error ) if $error;
2262
2263   }
2264
2265   my @pkgs = $self->ncancelled_pkgs;
2266
2267   if ( !$opt{nobill} && $conf->exists('bill_usage_on_cancel') ) {
2268     $opt{nobill} = 1;
2269     my $error = $self->bill( pkg_list => [ @pkgs ], cancel => 1 );
2270     warn "Error billing during cancel, custnum ". $self->custnum. ": $error"
2271       if $error;
2272   }
2273
2274   warn "$me cancelling ". scalar($self->ncancelled_pkgs). "/".
2275        scalar(@pkgs). " packages for customer ". $self->custnum. "\n"
2276     if $DEBUG;
2277
2278   grep { $_ } map { $_->cancel(%opt) } $self->ncancelled_pkgs;
2279 }
2280
2281 sub _banned_pay_hashref {
2282   my $self = shift;
2283
2284   my %payby2ban = (
2285     'CARD' => 'CARD',
2286     'DCRD' => 'CARD',
2287     'CHEK' => 'CHEK',
2288     'DCHK' => 'CHEK'
2289   );
2290
2291   {
2292     'payby'   => $payby2ban{$self->payby},
2293     'payinfo' => $self->payinfo,
2294     #don't ever *search* on reason! #'reason'  =>
2295   };
2296 }
2297
2298 sub _new_banned_pay_hashref {
2299   my $self = shift;
2300   my $hr = $self->_banned_pay_hashref;
2301   $hr->{payinfo} = md5_base64($hr->{payinfo});
2302   $hr;
2303 }
2304
2305 =item notes
2306
2307 Returns all notes (see L<FS::cust_main_note>) for this customer.
2308
2309 =cut
2310
2311 sub notes {
2312   my($self,$orderby_classnum) = (shift,shift);
2313   my $orderby = "_DATE DESC";
2314   $orderby = "CLASSNUM ASC, $orderby" if $orderby_classnum;
2315   qsearch( 'cust_main_note',
2316            { 'custnum' => $self->custnum },
2317            '',
2318            "ORDER BY $orderby",
2319          );
2320 }
2321
2322 =item agent
2323
2324 Returns the agent (see L<FS::agent>) for this customer.
2325
2326 =cut
2327
2328 sub agent {
2329   my $self = shift;
2330   qsearchs( 'agent', { 'agentnum' => $self->agentnum } );
2331 }
2332
2333 =item agent_name
2334
2335 Returns the agent name (see L<FS::agent>) for this customer.
2336
2337 =cut
2338
2339 sub agent_name {
2340   my $self = shift;
2341   $self->agent->agent;
2342 }
2343
2344 =item cust_tag
2345
2346 Returns any tags associated with this customer, as FS::cust_tag objects,
2347 or an empty list if there are no tags.
2348
2349 =cut
2350
2351 sub cust_tag {
2352   my $self = shift;
2353   qsearch('cust_tag', { 'custnum' => $self->custnum } );
2354 }
2355
2356 =item part_tag
2357
2358 Returns any tags associated with this customer, as FS::part_tag objects,
2359 or an empty list if there are no tags.
2360
2361 =cut
2362
2363 sub part_tag {
2364   my $self = shift;
2365   map $_->part_tag, $self->cust_tag;
2366 }
2367
2368
2369 =item cust_class
2370
2371 Returns the customer class, as an FS::cust_class object, or the empty string
2372 if there is no customer class.
2373
2374 =cut
2375
2376 sub cust_class {
2377   my $self = shift;
2378   if ( $self->classnum ) {
2379     qsearchs('cust_class', { 'classnum' => $self->classnum } );
2380   } else {
2381     return '';
2382   }
2383 }
2384
2385 =item categoryname
2386
2387 Returns the customer category name, or the empty string if there is no customer
2388 category.
2389
2390 =cut
2391
2392 sub categoryname {
2393   my $self = shift;
2394   my $cust_class = $self->cust_class;
2395   $cust_class
2396     ? $cust_class->categoryname
2397     : '';
2398 }
2399
2400 =item classname
2401
2402 Returns the customer class name, or the empty string if there is no customer
2403 class.
2404
2405 =cut
2406
2407 sub classname {
2408   my $self = shift;
2409   my $cust_class = $self->cust_class;
2410   $cust_class
2411     ? $cust_class->classname
2412     : '';
2413 }
2414
2415 =item BILLING METHODS
2416
2417 Documentation on billing methods has been moved to
2418 L<FS::cust_main::Billing>.
2419
2420 =item REALTIME BILLING METHODS
2421
2422 Documentation on realtime billing methods has been moved to
2423 L<FS::cust_main::Billing_Realtime>.
2424
2425 =item remove_cvv
2426
2427 Removes the I<paycvv> field from the database directly.
2428
2429 If there is an error, returns the error, otherwise returns false.
2430
2431 =cut
2432
2433 sub remove_cvv {
2434   my $self = shift;
2435   my $sth = dbh->prepare("UPDATE cust_main SET paycvv = '' WHERE custnum = ?")
2436     or return dbh->errstr;
2437   $sth->execute($self->custnum)
2438     or return $sth->errstr;
2439   $self->paycvv('');
2440   '';
2441 }
2442
2443 =item batch_card OPTION => VALUE...
2444
2445 Adds a payment for this invoice to the pending credit card batch (see
2446 L<FS::cust_pay_batch>), or, if the B<realtime> option is set to a true value,
2447 runs the payment using a realtime gateway.
2448
2449 =cut
2450
2451 sub batch_card {
2452   my ($self, %options) = @_;
2453
2454   my $amount;
2455   if (exists($options{amount})) {
2456     $amount = $options{amount};
2457   }else{
2458     $amount = sprintf("%.2f", $self->balance - $self->in_transit_payments);
2459   }
2460   return '' unless $amount > 0;
2461
2462   my $invnum = delete $options{invnum};
2463   my $payby = $options{payby} || $self->payby;  #still dubious
2464
2465   if ($options{'realtime'}) {
2466     return $self->realtime_bop( FS::payby->payby2bop($self->payby),
2467                                 $amount,
2468                                 %options,
2469                               );
2470   }
2471
2472   my $oldAutoCommit = $FS::UID::AutoCommit;
2473   local $FS::UID::AutoCommit = 0;
2474   my $dbh = dbh;
2475
2476   #this needs to handle mysql as well as Pg, like svc_acct.pm
2477   #(make it into a common function if folks need to do batching with mysql)
2478   $dbh->do("LOCK TABLE pay_batch IN SHARE ROW EXCLUSIVE MODE")
2479     or return "Cannot lock pay_batch: " . $dbh->errstr;
2480
2481   my %pay_batch = (
2482     'status' => 'O',
2483     'payby'  => FS::payby->payby2payment($payby),
2484   );
2485   $pay_batch{agentnum} = $self->agentnum if $conf->exists('batch-spoolagent');
2486
2487   my $pay_batch = qsearchs( 'pay_batch', \%pay_batch );
2488
2489   unless ( $pay_batch ) {
2490     $pay_batch = new FS::pay_batch \%pay_batch;
2491     my $error = $pay_batch->insert;
2492     if ( $error ) {
2493       $dbh->rollback if $oldAutoCommit;
2494       die "error creating new batch: $error\n";
2495     }
2496   }
2497
2498   my $old_cust_pay_batch = qsearchs('cust_pay_batch', {
2499       'batchnum' => $pay_batch->batchnum,
2500       'custnum'  => $self->custnum,
2501   } );
2502
2503   foreach (qw( address1 address2 city state zip country payby payinfo paydate
2504                payname )) {
2505     $options{$_} = '' unless exists($options{$_});
2506   }
2507
2508   my $cust_pay_batch = new FS::cust_pay_batch ( {
2509     'batchnum' => $pay_batch->batchnum,
2510     'invnum'   => $invnum || 0,                    # is there a better value?
2511                                                    # this field should be
2512                                                    # removed...
2513                                                    # cust_bill_pay_batch now
2514     'custnum'  => $self->custnum,
2515     'last'     => $self->getfield('last'),
2516     'first'    => $self->getfield('first'),
2517     'address1' => $options{address1} || $self->address1,
2518     'address2' => $options{address2} || $self->address2,
2519     'city'     => $options{city}     || $self->city,
2520     'state'    => $options{state}    || $self->state,
2521     'zip'      => $options{zip}      || $self->zip,
2522     'country'  => $options{country}  || $self->country,
2523     'payby'    => $options{payby}    || $self->payby,
2524     'payinfo'  => $options{payinfo}  || $self->payinfo,
2525     'exp'      => $options{paydate}  || $self->paydate,
2526     'payname'  => $options{payname}  || $self->payname,
2527     'amount'   => $amount,                         # consolidating
2528   } );
2529
2530   $cust_pay_batch->paybatchnum($old_cust_pay_batch->paybatchnum)
2531     if $old_cust_pay_batch;
2532
2533   my $error;
2534   if ($old_cust_pay_batch) {
2535     $error = $cust_pay_batch->replace($old_cust_pay_batch)
2536   } else {
2537     $error = $cust_pay_batch->insert;
2538   }
2539
2540   if ( $error ) {
2541     $dbh->rollback if $oldAutoCommit;
2542     die $error;
2543   }
2544
2545   my $unapplied =   $self->total_unapplied_credits
2546                   + $self->total_unapplied_payments
2547                   + $self->in_transit_payments;
2548   foreach my $cust_bill ($self->open_cust_bill) {
2549     #$dbh->commit or die $dbh->errstr if $oldAutoCommit;
2550     my $cust_bill_pay_batch = new FS::cust_bill_pay_batch {
2551       'invnum' => $cust_bill->invnum,
2552       'paybatchnum' => $cust_pay_batch->paybatchnum,
2553       'amount' => $cust_bill->owed,
2554       '_date' => time,
2555     };
2556     if ($unapplied >= $cust_bill_pay_batch->amount){
2557       $unapplied -= $cust_bill_pay_batch->amount;
2558       next;
2559     }else{
2560       $cust_bill_pay_batch->amount(sprintf ( "%.2f",
2561                                    $cust_bill_pay_batch->amount - $unapplied ));      $unapplied = 0;
2562     }
2563     $error = $cust_bill_pay_batch->insert;
2564     if ( $error ) {
2565       $dbh->rollback if $oldAutoCommit;
2566       die $error;
2567     }
2568   }
2569
2570   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
2571   '';
2572 }
2573
2574 =item total_owed
2575
2576 Returns the total owed for this customer on all invoices
2577 (see L<FS::cust_bill/owed>).
2578
2579 =cut
2580
2581 sub total_owed {
2582   my $self = shift;
2583   $self->total_owed_date(2145859200); #12/31/2037
2584 }
2585
2586 =item total_owed_date TIME
2587
2588 Returns the total owed for this customer on all invoices with date earlier than
2589 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2590 see L<Time::Local> and L<Date::Parse> for conversion functions.
2591
2592 =cut
2593
2594 sub total_owed_date {
2595   my $self = shift;
2596   my $time = shift;
2597
2598   my $custnum = $self->custnum;
2599
2600   my $owed_sql = FS::cust_bill->owed_sql;
2601
2602   my $sql = "
2603     SELECT SUM($owed_sql) FROM cust_bill
2604       WHERE custnum = $custnum
2605         AND _date <= $time
2606   ";
2607
2608   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2609
2610 }
2611
2612 =item total_owed_pkgnum PKGNUM
2613
2614 Returns the total owed on all invoices for this customer's specific package
2615 when using experimental package balances (see L<FS::cust_bill/owed_pkgnum>).
2616
2617 =cut
2618
2619 sub total_owed_pkgnum {
2620   my( $self, $pkgnum ) = @_;
2621   $self->total_owed_date_pkgnum(2145859200, $pkgnum); #12/31/2037
2622 }
2623
2624 =item total_owed_date_pkgnum TIME PKGNUM
2625
2626 Returns the total owed for this customer's specific package when using
2627 experimental package balances on all invoices with date earlier than
2628 TIME.  TIME is specified as a UNIX timestamp; see L<perlfunc/"time">).  Also
2629 see L<Time::Local> and L<Date::Parse> for conversion functions.
2630
2631 =cut
2632
2633 sub total_owed_date_pkgnum {
2634   my( $self, $time, $pkgnum ) = @_;
2635
2636   my $total_bill = 0;
2637   foreach my $cust_bill (
2638     grep { $_->_date <= $time }
2639       qsearch('cust_bill', { 'custnum' => $self->custnum, } )
2640   ) {
2641     $total_bill += $cust_bill->owed_pkgnum($pkgnum);
2642   }
2643   sprintf( "%.2f", $total_bill );
2644
2645 }
2646
2647 =item total_paid
2648
2649 Returns the total amount of all payments.
2650
2651 =cut
2652
2653 sub total_paid {
2654   my $self = shift;
2655   my $total = 0;
2656   $total += $_->paid foreach $self->cust_pay;
2657   sprintf( "%.2f", $total );
2658 }
2659
2660 =item total_unapplied_credits
2661
2662 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2663 customer.  See L<FS::cust_credit/credited>.
2664
2665 =item total_credited
2666
2667 Old name for total_unapplied_credits.  Don't use.
2668
2669 =cut
2670
2671 sub total_credited {
2672   #carp "total_credited deprecated, use total_unapplied_credits";
2673   shift->total_unapplied_credits(@_);
2674 }
2675
2676 sub total_unapplied_credits {
2677   my $self = shift;
2678
2679   my $custnum = $self->custnum;
2680
2681   my $unapplied_sql = FS::cust_credit->unapplied_sql;
2682
2683   my $sql = "
2684     SELECT SUM($unapplied_sql) FROM cust_credit
2685       WHERE custnum = $custnum
2686   ";
2687
2688   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2689
2690 }
2691
2692 =item total_unapplied_credits_pkgnum PKGNUM
2693
2694 Returns the total outstanding credit (see L<FS::cust_credit>) for this
2695 customer.  See L<FS::cust_credit/credited>.
2696
2697 =cut
2698
2699 sub total_unapplied_credits_pkgnum {
2700   my( $self, $pkgnum ) = @_;
2701   my $total_credit = 0;
2702   $total_credit += $_->credited foreach $self->cust_credit_pkgnum($pkgnum);
2703   sprintf( "%.2f", $total_credit );
2704 }
2705
2706
2707 =item total_unapplied_payments
2708
2709 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer.
2710 See L<FS::cust_pay/unapplied>.
2711
2712 =cut
2713
2714 sub total_unapplied_payments {
2715   my $self = shift;
2716
2717   my $custnum = $self->custnum;
2718
2719   my $unapplied_sql = FS::cust_pay->unapplied_sql;
2720
2721   my $sql = "
2722     SELECT SUM($unapplied_sql) FROM cust_pay
2723       WHERE custnum = $custnum
2724   ";
2725
2726   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2727
2728 }
2729
2730 =item total_unapplied_payments_pkgnum PKGNUM
2731
2732 Returns the total unapplied payments (see L<FS::cust_pay>) for this customer's
2733 specific package when using experimental package balances.  See
2734 L<FS::cust_pay/unapplied>.
2735
2736 =cut
2737
2738 sub total_unapplied_payments_pkgnum {
2739   my( $self, $pkgnum ) = @_;
2740   my $total_unapplied = 0;
2741   $total_unapplied += $_->unapplied foreach $self->cust_pay_pkgnum($pkgnum);
2742   sprintf( "%.2f", $total_unapplied );
2743 }
2744
2745
2746 =item total_unapplied_refunds
2747
2748 Returns the total unrefunded refunds (see L<FS::cust_refund>) for this
2749 customer.  See L<FS::cust_refund/unapplied>.
2750
2751 =cut
2752
2753 sub total_unapplied_refunds {
2754   my $self = shift;
2755   my $custnum = $self->custnum;
2756
2757   my $unapplied_sql = FS::cust_refund->unapplied_sql;
2758
2759   my $sql = "
2760     SELECT SUM($unapplied_sql) FROM cust_refund
2761       WHERE custnum = $custnum
2762   ";
2763
2764   sprintf( "%.2f", $self->scalar_sql($sql) || 0 );
2765
2766 }
2767
2768 =item balance
2769
2770 Returns the balance for this customer (total_owed plus total_unrefunded, minus
2771 total_unapplied_credits minus total_unapplied_payments).
2772
2773 =cut
2774
2775 sub balance {
2776   my $self = shift;
2777   $self->balance_date_range;
2778 }
2779
2780 =item balance_date TIME
2781
2782 Returns the balance for this customer, only considering invoices with date
2783 earlier than TIME (total_owed_date minus total_credited minus
2784 total_unapplied_payments).  TIME is specified as a UNIX timestamp; see
2785 L<perlfunc/"time">).  Also see L<Time::Local> and L<Date::Parse> for conversion
2786 functions.
2787
2788 =cut
2789
2790 sub balance_date {
2791   my $self = shift;
2792   $self->balance_date_range(shift);
2793 }
2794
2795 =item balance_date_range [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
2796
2797 Returns the balance for this customer, optionally considering invoices with
2798 date earlier than START_TIME, and not later than END_TIME
2799 (total_owed_date minus total_unapplied_credits minus total_unapplied_payments).
2800
2801 Times are specified as SQL fragments or numeric
2802 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
2803 L<Date::Parse> for conversion functions.  The empty string can be passed
2804 to disable that time constraint completely.
2805
2806 Available options are:
2807
2808 =over 4
2809
2810 =item unapplied_date
2811
2812 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
2813
2814 =back
2815
2816 =cut
2817
2818 sub balance_date_range {
2819   my $self = shift;
2820   my $sql = 'SELECT SUM('. $self->balance_date_sql(@_).
2821             ') FROM cust_main WHERE custnum='. $self->custnum;
2822   sprintf( '%.2f', $self->scalar_sql($sql) || 0 );
2823 }
2824
2825 =item balance_pkgnum PKGNUM
2826
2827 Returns the balance for this customer's specific package when using
2828 experimental package balances (total_owed plus total_unrefunded, minus
2829 total_unapplied_credits minus total_unapplied_payments)
2830
2831 =cut
2832
2833 sub balance_pkgnum {
2834   my( $self, $pkgnum ) = @_;
2835
2836   sprintf( "%.2f",
2837       $self->total_owed_pkgnum($pkgnum)
2838 # n/a - refunds aren't part of pkg-balances since they don't apply to invoices
2839 #    + $self->total_unapplied_refunds_pkgnum($pkgnum)
2840     - $self->total_unapplied_credits_pkgnum($pkgnum)
2841     - $self->total_unapplied_payments_pkgnum($pkgnum)
2842   );
2843 }
2844
2845 =item in_transit_payments
2846
2847 Returns the total of requests for payments for this customer pending in
2848 batches in transit to the bank.  See L<FS::pay_batch> and L<FS::cust_pay_batch>
2849
2850 =cut
2851
2852 sub in_transit_payments {
2853   my $self = shift;
2854   my $in_transit_payments = 0;
2855   foreach my $pay_batch ( qsearch('pay_batch', {
2856     'status' => 'I',
2857   } ) ) {
2858     foreach my $cust_pay_batch ( qsearch('cust_pay_batch', {
2859       'batchnum' => $pay_batch->batchnum,
2860       'custnum' => $self->custnum,
2861     } ) ) {
2862       $in_transit_payments += $cust_pay_batch->amount;
2863     }
2864   }
2865   sprintf( "%.2f", $in_transit_payments );
2866 }
2867
2868 =item payment_info
2869
2870 Returns a hash of useful information for making a payment.
2871
2872 =over 4
2873
2874 =item balance
2875
2876 Current balance.
2877
2878 =item payby
2879
2880 'CARD' (credit card - automatic), 'DCRD' (credit card - on-demand),
2881 'CHEK' (electronic check - automatic), 'DCHK' (electronic check - on-demand),
2882 'LECB' (Phone bill billing), 'BILL' (billing), or 'COMP' (free).
2883
2884 =back
2885
2886 For credit card transactions:
2887
2888 =over 4
2889
2890 =item card_type 1
2891
2892 =item payname
2893
2894 Exact name on card
2895
2896 =back
2897
2898 For electronic check transactions:
2899
2900 =over 4
2901
2902 =item stateid_state
2903
2904 =back
2905
2906 =cut
2907
2908 sub payment_info {
2909   my $self = shift;
2910
2911   my %return = ();
2912
2913   $return{balance} = $self->balance;
2914
2915   $return{payname} = $self->payname
2916                      || ( $self->first. ' '. $self->get('last') );
2917
2918   $return{$_} = $self->get($_) for qw(address1 address2 city state zip);
2919
2920   $return{payby} = $self->payby;
2921   $return{stateid_state} = $self->stateid_state;
2922
2923   if ( $self->payby =~ /^(CARD|DCRD)$/ ) {
2924     $return{card_type} = cardtype($self->payinfo);
2925     $return{payinfo} = $self->paymask;
2926
2927     @return{'month', 'year'} = $self->paydate_monthyear;
2928
2929   }
2930
2931   if ( $self->payby =~ /^(CHEK|DCHK)$/ ) {
2932     my ($payinfo1, $payinfo2) = split '@', $self->paymask;
2933     $return{payinfo1} = $payinfo1;
2934     $return{payinfo2} = $payinfo2;
2935     $return{paytype}  = $self->paytype;
2936     $return{paystate} = $self->paystate;
2937
2938   }
2939
2940   #doubleclick protection
2941   my $_date = time;
2942   $return{paybatch} = "webui-MyAccount-$_date-$$-". rand() * 2**32;
2943
2944   %return;
2945
2946 }
2947
2948 =item paydate_monthyear
2949
2950 Returns a two-element list consisting of the month and year of this customer's
2951 paydate (credit card expiration date for CARD customers)
2952
2953 =cut
2954
2955 sub paydate_monthyear {
2956   my $self = shift;
2957   if ( $self->paydate  =~ /^(\d{4})-(\d{1,2})-\d{1,2}$/ ) { #Pg date format
2958     ( $2, $1 );
2959   } elsif ( $self->paydate =~ /^(\d{1,2})-(\d{1,2}-)?(\d{4}$)/ ) {
2960     ( $1, $3 );
2961   } else {
2962     ('', '');
2963   }
2964 }
2965
2966 =item paydate_epoch
2967
2968 Returns the exact time in seconds corresponding to the payment method
2969 expiration date.  For CARD/DCRD customers this is the end of the month;
2970 for others (COMP is the only other payby that uses paydate) it's the start.
2971 Returns 0 if the paydate is empty or set to the far future.
2972
2973 =cut
2974
2975 sub paydate_epoch {
2976   my $self = shift;
2977   my ($month, $year) = $self->paydate_monthyear;
2978   return 0 if !$year or $year >= 2037;
2979   if ( $self->payby eq 'CARD' or $self->payby eq 'DCRD' ) {
2980     $month++;
2981     if ( $month == 13 ) {
2982       $month = 1;
2983       $year++;
2984     }
2985     return timelocal(0,0,0,1,$month-1,$year) - 1;
2986   }
2987   else {
2988     return timelocal(0,0,0,1,$month-1,$year);
2989   }
2990 }
2991
2992 =item paydate_epoch_sql
2993
2994 Class method.  Returns an SQL expression to obtain the payment expiration date
2995 as a number of seconds.
2996
2997 =cut
2998
2999 # Special expiration date behavior for non-CARD/DCRD customers has been
3000 # carefully preserved.  Do we really use that?
3001 sub paydate_epoch_sql {
3002   my $class = shift;
3003   my $table = shift || 'cust_main';
3004   my ($case1, $case2);
3005   if ( driver_name eq 'Pg' ) {
3006     $case1 = "EXTRACT( EPOCH FROM CAST( $table.paydate AS TIMESTAMP ) + INTERVAL '1 month') - 1";
3007     $case2 = "EXTRACT( EPOCH FROM CAST( $table.paydate AS TIMESTAMP ) )";
3008   }
3009   elsif ( lc(driver_name) eq 'mysql' ) {
3010     $case1 = "UNIX_TIMESTAMP( DATE_ADD( CAST( $table.paydate AS DATETIME ), INTERVAL 1 month ) ) - 1";
3011     $case2 = "UNIX_TIMESTAMP( CAST( $table.paydate AS DATETIME ) )";
3012   }
3013   else { return '' }
3014   return "CASE WHEN $table.payby IN('CARD','DCRD')
3015   THEN ($case1)
3016   ELSE ($case2)
3017   END"
3018 }
3019
3020 =item tax_exemption TAXNAME
3021
3022 =cut
3023
3024 sub tax_exemption {
3025   my( $self, $taxname ) = @_;
3026
3027   qsearchs( 'cust_main_exemption', { 'custnum' => $self->custnum,
3028                                      'taxname' => $taxname,
3029                                    },
3030           );
3031 }
3032
3033 =item cust_main_exemption
3034
3035 =cut
3036
3037 sub cust_main_exemption {
3038   my $self = shift;
3039   qsearch( 'cust_main_exemption', { 'custnum' => $self->custnum } );
3040 }
3041
3042 =item invoicing_list [ ARRAYREF ]
3043
3044 If an arguement is given, sets these email addresses as invoice recipients
3045 (see L<FS::cust_main_invoice>).  Errors are not fatal and are not reported
3046 (except as warnings), so use check_invoicing_list first.
3047
3048 Returns a list of email addresses (with svcnum entries expanded).
3049
3050 Note: You can clear the invoicing list by passing an empty ARRAYREF.  You can
3051 check it without disturbing anything by passing nothing.
3052
3053 This interface may change in the future.
3054
3055 =cut
3056
3057 sub invoicing_list {
3058   my( $self, $arrayref ) = @_;
3059
3060   if ( $arrayref ) {
3061     my @cust_main_invoice;
3062     if ( $self->custnum ) {
3063       @cust_main_invoice =
3064         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3065     } else {
3066       @cust_main_invoice = ();
3067     }
3068     foreach my $cust_main_invoice ( @cust_main_invoice ) {
3069       #warn $cust_main_invoice->destnum;
3070       unless ( grep { $cust_main_invoice->address eq $_ } @{$arrayref} ) {
3071         #warn $cust_main_invoice->destnum;
3072         my $error = $cust_main_invoice->delete;
3073         warn $error if $error;
3074       }
3075     }
3076     if ( $self->custnum ) {
3077       @cust_main_invoice =
3078         qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3079     } else {
3080       @cust_main_invoice = ();
3081     }
3082     my %seen = map { $_->address => 1 } @cust_main_invoice;
3083     foreach my $address ( @{$arrayref} ) {
3084       next if exists $seen{$address} && $seen{$address};
3085       $seen{$address} = 1;
3086       my $cust_main_invoice = new FS::cust_main_invoice ( {
3087         'custnum' => $self->custnum,
3088         'dest'    => $address,
3089       } );
3090       my $error = $cust_main_invoice->insert;
3091       warn $error if $error;
3092     }
3093   }
3094
3095   if ( $self->custnum ) {
3096     map { $_->address }
3097       qsearch( 'cust_main_invoice', { 'custnum' => $self->custnum } );
3098   } else {
3099     ();
3100   }
3101
3102 }
3103
3104 =item check_invoicing_list ARRAYREF
3105
3106 Checks these arguements as valid input for the invoicing_list method.  If there
3107 is an error, returns the error, otherwise returns false.
3108
3109 =cut
3110
3111 sub check_invoicing_list {
3112   my( $self, $arrayref ) = @_;
3113
3114   foreach my $address ( @$arrayref ) {
3115
3116     if ($address eq 'FAX' and $self->getfield('fax') eq '') {
3117       return 'Can\'t add FAX invoice destination with a blank FAX number.';
3118     }
3119
3120     my $cust_main_invoice = new FS::cust_main_invoice ( {
3121       'custnum' => $self->custnum,
3122       'dest'    => $address,
3123     } );
3124     my $error = $self->custnum
3125                 ? $cust_main_invoice->check
3126                 : $cust_main_invoice->checkdest
3127     ;
3128     return $error if $error;
3129
3130   }
3131
3132   return "Email address required"
3133     if $conf->exists('cust_main-require_invoicing_list_email')
3134     && ! grep { $_ !~ /^([A-Z]+)$/ } @$arrayref;
3135
3136   '';
3137 }
3138
3139 =item set_default_invoicing_list
3140
3141 Sets the invoicing list to all accounts associated with this customer,
3142 overwriting any previous invoicing list.
3143
3144 =cut
3145
3146 sub set_default_invoicing_list {
3147   my $self = shift;
3148   $self->invoicing_list($self->all_emails);
3149 }
3150
3151 =item all_emails
3152
3153 Returns the email addresses of all accounts provisioned for this customer.
3154
3155 =cut
3156
3157 sub all_emails {
3158   my $self = shift;
3159   my %list;
3160   foreach my $cust_pkg ( $self->all_pkgs ) {
3161     my @cust_svc = qsearch('cust_svc', { 'pkgnum' => $cust_pkg->pkgnum } );
3162     my @svc_acct =
3163       map { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3164         grep { qsearchs('svc_acct', { 'svcnum' => $_->svcnum } ) }
3165           @cust_svc;
3166     $list{$_}=1 foreach map { $_->email } @svc_acct;
3167   }
3168   keys %list;
3169 }
3170
3171 =item invoicing_list_addpost
3172
3173 Adds postal invoicing to this customer.  If this customer is already configured
3174 to receive postal invoices, does nothing.
3175
3176 =cut
3177
3178 sub invoicing_list_addpost {
3179   my $self = shift;
3180   return if grep { $_ eq 'POST' } $self->invoicing_list;
3181   my @invoicing_list = $self->invoicing_list;
3182   push @invoicing_list, 'POST';
3183   $self->invoicing_list(\@invoicing_list);
3184 }
3185
3186 =item invoicing_list_emailonly
3187
3188 Returns the list of email invoice recipients (invoicing_list without non-email
3189 destinations such as POST and FAX).
3190
3191 =cut
3192
3193 sub invoicing_list_emailonly {
3194   my $self = shift;
3195   warn "$me invoicing_list_emailonly called"
3196     if $DEBUG;
3197   grep { $_ !~ /^([A-Z]+)$/ } $self->invoicing_list;
3198 }
3199
3200 =item invoicing_list_emailonly_scalar
3201
3202 Returns the list of email invoice recipients (invoicing_list without non-email
3203 destinations such as POST and FAX) as a comma-separated scalar.
3204
3205 =cut
3206
3207 sub invoicing_list_emailonly_scalar {
3208   my $self = shift;
3209   warn "$me invoicing_list_emailonly_scalar called"
3210     if $DEBUG;
3211   join(', ', $self->invoicing_list_emailonly);
3212 }
3213
3214 =item referral_custnum_cust_main
3215
3216 Returns the customer who referred this customer (or the empty string, if
3217 this customer was not referred).
3218
3219 Note the difference with referral_cust_main method: This method,
3220 referral_custnum_cust_main returns the single customer (if any) who referred
3221 this customer, while referral_cust_main returns an array of customers referred
3222 BY this customer.
3223
3224 =cut
3225
3226 sub referral_custnum_cust_main {
3227   my $self = shift;
3228   return '' unless $self->referral_custnum;
3229   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3230 }
3231
3232 =item referral_cust_main [ DEPTH [ EXCLUDE_HASHREF ] ]
3233
3234 Returns an array of customers referred by this customer (referral_custnum set
3235 to this custnum).  If DEPTH is given, recurses up to the given depth, returning
3236 customers referred by customers referred by this customer and so on, inclusive.
3237 The default behavior is DEPTH 1 (no recursion).
3238
3239 Note the difference with referral_custnum_cust_main method: This method,
3240 referral_cust_main, returns an array of customers referred BY this customer,
3241 while referral_custnum_cust_main returns the single customer (if any) who
3242 referred this customer.
3243
3244 =cut
3245
3246 sub referral_cust_main {
3247   my $self = shift;
3248   my $depth = @_ ? shift : 1;
3249   my $exclude = @_ ? shift : {};
3250
3251   my @cust_main =
3252     map { $exclude->{$_->custnum}++; $_; }
3253       grep { ! $exclude->{ $_->custnum } }
3254         qsearch( 'cust_main', { 'referral_custnum' => $self->custnum } );
3255
3256   if ( $depth > 1 ) {
3257     push @cust_main,
3258       map { $_->referral_cust_main($depth-1, $exclude) }
3259         @cust_main;
3260   }
3261
3262   @cust_main;
3263 }
3264
3265 =item referral_cust_main_ncancelled
3266
3267 Same as referral_cust_main, except only returns customers with uncancelled
3268 packages.
3269
3270 =cut
3271
3272 sub referral_cust_main_ncancelled {
3273   my $self = shift;
3274   grep { scalar($_->ncancelled_pkgs) } $self->referral_cust_main;
3275 }
3276
3277 =item referral_cust_pkg [ DEPTH ]
3278
3279 Like referral_cust_main, except returns a flat list of all unsuspended (and
3280 uncancelled) packages for each customer.  The number of items in this list may
3281 be useful for commission calculations (perhaps after a C<grep { my $pkgpart = $_->pkgpart; grep { $_ == $pkgpart } @commission_worthy_pkgparts> } $cust_main-> ).
3282
3283 =cut
3284
3285 sub referral_cust_pkg {
3286   my $self = shift;
3287   my $depth = @_ ? shift : 1;
3288
3289   map { $_->unsuspended_pkgs }
3290     grep { $_->unsuspended_pkgs }
3291       $self->referral_cust_main($depth);
3292 }
3293
3294 =item referring_cust_main
3295
3296 Returns the single cust_main record for the customer who referred this customer
3297 (referral_custnum), or false.
3298
3299 =cut
3300
3301 sub referring_cust_main {
3302   my $self = shift;
3303   return '' unless $self->referral_custnum;
3304   qsearchs('cust_main', { 'custnum' => $self->referral_custnum } );
3305 }
3306
3307 =item credit AMOUNT, REASON [ , OPTION => VALUE ... ]
3308
3309 Applies a credit to this customer.  If there is an error, returns the error,
3310 otherwise returns false.
3311
3312 REASON can be a text string, an FS::reason object, or a scalar reference to
3313 a reasonnum.  If a text string, it will be automatically inserted as a new
3314 reason, and a 'reason_type' option must be passed to indicate the
3315 FS::reason_type for the new reason.
3316
3317 An I<addlinfo> option may be passed to set the credit's I<addlinfo> field.
3318
3319 Any other options are passed to FS::cust_credit::insert.
3320
3321 =cut
3322
3323 sub credit {
3324   my( $self, $amount, $reason, %options ) = @_;
3325
3326   my $cust_credit = new FS::cust_credit {
3327     'custnum' => $self->custnum,
3328     'amount'  => $amount,
3329   };
3330
3331   if ( ref($reason) ) {
3332
3333     if ( ref($reason) eq 'SCALAR' ) {
3334       $cust_credit->reasonnum( $$reason );
3335     } else {
3336       $cust_credit->reasonnum( $reason->reasonnum );
3337     }
3338
3339   } else {
3340     $cust_credit->set('reason', $reason)
3341   }
3342
3343   for (qw( addlinfo eventnum )) {
3344     $cust_credit->$_( delete $options{$_} )
3345       if exists($options{$_});
3346   }
3347
3348   $cust_credit->insert(%options);
3349
3350 }
3351
3352 =item charge HASHREF || AMOUNT [ PKG [ COMMENT [ TAXCLASS ] ] ]
3353
3354 Creates a one-time charge for this customer.  If there is an error, returns
3355 the error, otherwise returns false.
3356
3357 New-style, with a hashref of options:
3358
3359   my $error = $cust_main->charge(
3360                                   {
3361                                     'amount'     => 54.32,
3362                                     'quantity'   => 1,
3363                                     'start_date' => str2time('7/4/2009'),
3364                                     'pkg'        => 'Description',
3365                                     'comment'    => 'Comment',
3366                                     'additional' => [], #extra invoice detail
3367                                     'classnum'   => 1,  #pkg_class
3368
3369                                     'setuptax'   => '', # or 'Y' for tax exempt
3370
3371                                     #internal taxation
3372                                     'taxclass'   => 'Tax class',
3373
3374                                     #vendor taxation
3375                                     'taxproduct' => 2,  #part_pkg_taxproduct
3376                                     'override'   => {}, #XXX describe
3377
3378                                     #will be filled in with the new object
3379                                     'cust_pkg_ref' => \$cust_pkg,
3380
3381                                     #generate an invoice immediately
3382                                     'bill_now' => 0,
3383                                     'invoice_terms' => '', #with these terms
3384                                   }
3385                                 );
3386
3387 Old-style:
3388
3389   my $error = $cust_main->charge( 54.32, 'Description', 'Comment', 'Tax class' );
3390
3391 =cut
3392
3393 sub charge {
3394   my $self = shift;
3395   my ( $amount, $quantity, $start_date, $classnum );
3396   my ( $pkg, $comment, $additional );
3397   my ( $setuptax, $taxclass );   #internal taxes
3398   my ( $taxproduct, $override ); #vendor (CCH) taxes
3399   my $no_auto = '';
3400   my $cust_pkg_ref = '';
3401   my ( $bill_now, $invoice_terms ) = ( 0, '' );
3402   if ( ref( $_[0] ) ) {
3403     $amount     = $_[0]->{amount};
3404     $quantity   = exists($_[0]->{quantity}) ? $_[0]->{quantity} : 1;
3405     $start_date = exists($_[0]->{start_date}) ? $_[0]->{start_date} : '';
3406     $no_auto    = exists($_[0]->{no_auto}) ? $_[0]->{no_auto} : '';
3407     $pkg        = exists($_[0]->{pkg}) ? $_[0]->{pkg} : 'One-time charge';
3408     $comment    = exists($_[0]->{comment}) ? $_[0]->{comment}
3409                                            : '$'. sprintf("%.2f",$amount);
3410     $setuptax   = exists($_[0]->{setuptax}) ? $_[0]->{setuptax} : '';
3411     $taxclass   = exists($_[0]->{taxclass}) ? $_[0]->{taxclass} : '';
3412     $classnum   = exists($_[0]->{classnum}) ? $_[0]->{classnum} : '';
3413     $additional = $_[0]->{additional} || [];
3414     $taxproduct = $_[0]->{taxproductnum};
3415     $override   = { '' => $_[0]->{tax_override} };
3416     $cust_pkg_ref = exists($_[0]->{cust_pkg_ref}) ? $_[0]->{cust_pkg_ref} : '';
3417     $bill_now = exists($_[0]->{bill_now}) ? $_[0]->{bill_now} : '';
3418     $invoice_terms = exists($_[0]->{invoice_terms}) ? $_[0]->{invoice_terms} : '';
3419   } else {
3420     $amount     = shift;
3421     $quantity   = 1;
3422     $start_date = '';
3423     $pkg        = @_ ? shift : 'One-time charge';
3424     $comment    = @_ ? shift : '$'. sprintf("%.2f",$amount);
3425     $setuptax   = '';
3426     $taxclass   = @_ ? shift : '';
3427     $additional = [];
3428   }
3429
3430   local $SIG{HUP} = 'IGNORE';
3431   local $SIG{INT} = 'IGNORE';
3432   local $SIG{QUIT} = 'IGNORE';
3433   local $SIG{TERM} = 'IGNORE';
3434   local $SIG{TSTP} = 'IGNORE';
3435   local $SIG{PIPE} = 'IGNORE';
3436
3437   my $oldAutoCommit = $FS::UID::AutoCommit;
3438   local $FS::UID::AutoCommit = 0;
3439   my $dbh = dbh;
3440
3441   my $part_pkg = new FS::part_pkg ( {
3442     'pkg'           => $pkg,
3443     'comment'       => $comment,
3444     'plan'          => 'flat',
3445     'freq'          => 0,
3446     'disabled'      => 'Y',
3447     'classnum'      => ( $classnum ? $classnum : '' ),
3448     'setuptax'      => $setuptax,
3449     'taxclass'      => $taxclass,
3450     'taxproductnum' => $taxproduct,
3451   } );
3452
3453   my %options = ( ( map { ("additional_info$_" => $additional->[$_] ) }
3454                         ( 0 .. @$additional - 1 )
3455                   ),
3456                   'additional_count' => scalar(@$additional),
3457                   'setup_fee' => $amount,
3458                 );
3459
3460   my $error = $part_pkg->insert( options       => \%options,
3461                                  tax_overrides => $override,
3462                                );
3463   if ( $error ) {
3464     $dbh->rollback if $oldAutoCommit;
3465     return $error;
3466   }
3467
3468   my $pkgpart = $part_pkg->pkgpart;
3469   my %type_pkgs = ( 'typenum' => $self->agent->typenum, 'pkgpart' => $pkgpart );
3470   unless ( qsearchs('type_pkgs', \%type_pkgs ) ) {
3471     my $type_pkgs = new FS::type_pkgs \%type_pkgs;
3472     $error = $type_pkgs->insert;
3473     if ( $error ) {
3474       $dbh->rollback if $oldAutoCommit;
3475       return $error;
3476     }
3477   }
3478
3479   my $cust_pkg = new FS::cust_pkg ( {
3480     'custnum'    => $self->custnum,
3481     'pkgpart'    => $pkgpart,
3482     'quantity'   => $quantity,
3483     'start_date' => $start_date,
3484     'no_auto'    => $no_auto,
3485   } );
3486
3487   $error = $cust_pkg->insert;
3488   if ( $error ) {
3489     $dbh->rollback if $oldAutoCommit;
3490     return $error;
3491   } elsif ( $cust_pkg_ref ) {
3492     ${$cust_pkg_ref} = $cust_pkg;
3493   }
3494
3495   if ( $bill_now ) {
3496     my $error = $self->bill( 'invoice_terms' => $invoice_terms,
3497                              'pkg_list'      => [ $cust_pkg ],
3498                            );
3499     if ( $error ) {
3500       $dbh->rollback if $oldAutoCommit;
3501       return $error;
3502     }
3503   }
3504
3505   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
3506   return '';
3507
3508 }
3509
3510 #=item charge_postal_fee
3511 #
3512 #Applies a one time charge this customer.  If there is an error,
3513 #returns the error, returns the cust_pkg charge object or false
3514 #if there was no charge.
3515 #
3516 #=cut
3517 #
3518 # This should be a customer event.  For that to work requires that bill
3519 # also be a customer event.
3520
3521 sub charge_postal_fee {
3522   my $self = shift;
3523
3524   my $pkgpart = $conf->config('postal_invoice-fee_pkgpart', $self->agentnum);
3525   return '' unless ($pkgpart && grep { $_ eq 'POST' } $self->invoicing_list);
3526
3527   my $cust_pkg = new FS::cust_pkg ( {
3528     'custnum'  => $self->custnum,
3529     'pkgpart'  => $pkgpart,
3530     'quantity' => 1,
3531   } );
3532
3533   my $error = $cust_pkg->insert;
3534   $error ? $error : $cust_pkg;
3535 }
3536
3537 =item cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3538
3539 Returns all the invoices (see L<FS::cust_bill>) for this customer.
3540
3541 Optionally, a list or hashref of additional arguments to the qsearch call can
3542 be passed.
3543
3544 =cut
3545
3546 sub cust_bill {
3547   my $self = shift;
3548   my $opt = ref($_[0]) ? shift : { @_ };
3549
3550   #return $self->num_cust_bill unless wantarray || keys %$opt;
3551
3552   $opt->{'table'} = 'cust_bill';
3553   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3554   $opt->{'hashref'}{'custnum'} = $self->custnum;
3555   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3556
3557   map { $_ } #behavior of sort undefined in scalar context
3558     sort { $a->_date <=> $b->_date }
3559       qsearch($opt);
3560 }
3561
3562 =item open_cust_bill
3563
3564 Returns all the open (owed > 0) invoices (see L<FS::cust_bill>) for this
3565 customer.
3566
3567 =cut
3568
3569 sub open_cust_bill {
3570   my $self = shift;
3571
3572   $self->cust_bill(
3573     'extra_sql' => ' AND '. FS::cust_bill->owed_sql. ' > 0',
3574     #@_
3575   );
3576
3577 }
3578
3579 =item legacy_cust_bill [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3580
3581 Returns all the legacy invoices (see L<FS::legacy_cust_bill>) for this customer.
3582
3583 =cut
3584
3585 sub legacy_cust_bill {
3586   my $self = shift;
3587
3588   #return $self->num_legacy_cust_bill unless wantarray;
3589
3590   map { $_ } #behavior of sort undefined in scalar context
3591     sort { $a->_date <=> $b->_date }
3592       qsearch({ 'table'    => 'legacy_cust_bill',
3593                 'hashref'  => { 'custnum' => $self->custnum, },
3594                 'order_by' => 'ORDER BY _date ASC',
3595              });
3596 }
3597
3598 =item cust_statement [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3599
3600 Returns all the statements (see L<FS::cust_statement>) for this customer.
3601
3602 Optionally, a list or hashref of additional arguments to the qsearch call can
3603 be passed.
3604
3605 =cut
3606
3607 sub cust_statement {
3608   my $self = shift;
3609   my $opt = ref($_[0]) ? shift : { @_ };
3610
3611   #return $self->num_cust_statement unless wantarray || keys %$opt;
3612
3613   $opt->{'table'} = 'cust_statement';
3614   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3615   $opt->{'hashref'}{'custnum'} = $self->custnum;
3616   $opt->{'order_by'} ||= 'ORDER BY _date ASC';
3617
3618   map { $_ } #behavior of sort undefined in scalar context
3619     sort { $a->_date <=> $b->_date }
3620       qsearch($opt);
3621 }
3622
3623 =item cust_credit
3624
3625 Returns all the credits (see L<FS::cust_credit>) for this customer.
3626
3627 =cut
3628
3629 sub cust_credit {
3630   my $self = shift;
3631   map { $_ } #return $self->num_cust_credit unless wantarray;
3632   sort { $a->_date <=> $b->_date }
3633     qsearch( 'cust_credit', { 'custnum' => $self->custnum } )
3634 }
3635
3636 =item cust_credit_pkgnum
3637
3638 Returns all the credits (see L<FS::cust_credit>) for this customer's specific
3639 package when using experimental package balances.
3640
3641 =cut
3642
3643 sub cust_credit_pkgnum {
3644   my( $self, $pkgnum ) = @_;
3645   map { $_ } #return $self->num_cust_credit_pkgnum($pkgnum) unless wantarray;
3646   sort { $a->_date <=> $b->_date }
3647     qsearch( 'cust_credit', { 'custnum' => $self->custnum,
3648                               'pkgnum'  => $pkgnum,
3649                             }
3650     );
3651 }
3652
3653 =item cust_pay
3654
3655 Returns all the payments (see L<FS::cust_pay>) for this customer.
3656
3657 =cut
3658
3659 sub cust_pay {
3660   my $self = shift;
3661   return $self->num_cust_pay unless wantarray;
3662   sort { $a->_date <=> $b->_date }
3663     qsearch( 'cust_pay', { 'custnum' => $self->custnum } )
3664 }
3665
3666 =item num_cust_pay
3667
3668 Returns the number of payments (see L<FS::cust_pay>) for this customer.  Also
3669 called automatically when the cust_pay method is used in a scalar context.
3670
3671 =cut
3672
3673 sub num_cust_pay {
3674   my $self = shift;
3675   my $sql = "SELECT COUNT(*) FROM cust_pay WHERE custnum = ?";
3676   my $sth = dbh->prepare($sql) or die dbh->errstr;
3677   $sth->execute($self->custnum) or die $sth->errstr;
3678   $sth->fetchrow_arrayref->[0];
3679 }
3680
3681 =item cust_pay_pkgnum
3682
3683 Returns all the payments (see L<FS::cust_pay>) for this customer's specific
3684 package when using experimental package balances.
3685
3686 =cut
3687
3688 sub cust_pay_pkgnum {
3689   my( $self, $pkgnum ) = @_;
3690   map { $_ } #return $self->num_cust_pay_pkgnum($pkgnum) unless wantarray;
3691   sort { $a->_date <=> $b->_date }
3692     qsearch( 'cust_pay', { 'custnum' => $self->custnum,
3693                            'pkgnum'  => $pkgnum,
3694                          }
3695     );
3696 }
3697
3698 =item cust_pay_void
3699
3700 Returns all voided payments (see L<FS::cust_pay_void>) for this customer.
3701
3702 =cut
3703
3704 sub cust_pay_void {
3705   my $self = shift;
3706   map { $_ } #return $self->num_cust_pay_void unless wantarray;
3707   sort { $a->_date <=> $b->_date }
3708     qsearch( 'cust_pay_void', { 'custnum' => $self->custnum } )
3709 }
3710
3711 =item cust_pay_batch [ OPTION => VALUE... | EXTRA_QSEARCH_PARAMS_HASHREF ]
3712
3713 Returns all batched payments (see L<FS::cust_pay_void>) for this customer.
3714
3715 Optionally, a list or hashref of additional arguments to the qsearch call can
3716 be passed.
3717
3718 =cut
3719
3720 sub cust_pay_batch {
3721   my $self = shift;
3722   my $opt = ref($_[0]) ? shift : { @_ };
3723
3724   #return $self->num_cust_statement unless wantarray || keys %$opt;
3725
3726   $opt->{'table'} = 'cust_pay_batch';
3727   $opt->{'hashref'} ||= {}; #i guess it would autovivify anyway...
3728   $opt->{'hashref'}{'custnum'} = $self->custnum;
3729   $opt->{'order_by'} ||= 'ORDER BY paybatchnum ASC';
3730
3731   map { $_ } #behavior of sort undefined in scalar context
3732     sort { $a->paybatchnum <=> $b->paybatchnum }
3733       qsearch($opt);
3734 }
3735
3736 =item cust_pay_pending
3737
3738 Returns all pending payments (see L<FS::cust_pay_pending>) for this customer
3739 (without status "done").
3740
3741 =cut
3742
3743 sub cust_pay_pending {
3744   my $self = shift;
3745   return $self->num_cust_pay_pending unless wantarray;
3746   sort { $a->_date <=> $b->_date }
3747     qsearch( 'cust_pay_pending', {
3748                                    'custnum' => $self->custnum,
3749                                    'status'  => { op=>'!=', value=>'done' },
3750                                  },
3751            );
3752 }
3753
3754 =item cust_pay_pending_attempt
3755
3756 Returns all payment attempts / declined payments for this customer, as pending
3757 payments objects (see L<FS::cust_pay_pending>), with status "done" but without
3758 a corresponding payment (see L<FS::cust_pay>).
3759
3760 =cut
3761
3762 sub cust_pay_pending_attempt {
3763   my $self = shift;
3764   return $self->num_cust_pay_pending_attempt unless wantarray;
3765   sort { $a->_date <=> $b->_date }
3766     qsearch( 'cust_pay_pending', {
3767                                    'custnum' => $self->custnum,
3768                                    'status'  => 'done',
3769                                    'paynum'  => '',
3770                                  },
3771            );
3772 }
3773
3774 =item num_cust_pay_pending
3775
3776 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3777 customer (without status "done").  Also called automatically when the
3778 cust_pay_pending method is used in a scalar context.
3779
3780 =cut
3781
3782 sub num_cust_pay_pending {
3783   my $self = shift;
3784   $self->scalar_sql(
3785     " SELECT COUNT(*) FROM cust_pay_pending ".
3786       " WHERE custnum = ? AND status != 'done' ",
3787     $self->custnum
3788   );
3789 }
3790
3791 =item num_cust_pay_pending_attempt
3792
3793 Returns the number of pending payments (see L<FS::cust_pay_pending>) for this
3794 customer, with status "done" but without a corresp.  Also called automatically when the
3795 cust_pay_pending method is used in a scalar context.
3796
3797 =cut
3798
3799 sub num_cust_pay_pending_attempt {
3800   my $self = shift;
3801   $self->scalar_sql(
3802     " SELECT COUNT(*) FROM cust_pay_pending ".
3803       " WHERE custnum = ? AND status = 'done' AND paynum IS NULL",
3804     $self->custnum
3805   );
3806 }
3807
3808 =item cust_refund
3809
3810 Returns all the refunds (see L<FS::cust_refund>) for this customer.
3811
3812 =cut
3813
3814 sub cust_refund {
3815   my $self = shift;
3816   map { $_ } #return $self->num_cust_refund unless wantarray;
3817   sort { $a->_date <=> $b->_date }
3818     qsearch( 'cust_refund', { 'custnum' => $self->custnum } )
3819 }
3820
3821 =item display_custnum
3822
3823 Returns the displayed customer number for this customer: agent_custid if
3824 cust_main-default_agent_custid is set and it has a value, custnum otherwise.
3825
3826 =cut
3827
3828 sub display_custnum {
3829   my $self = shift;
3830   if ( $conf->exists('cust_main-default_agent_custid') && $self->agent_custid ){
3831     return $self->agent_custid;
3832   } elsif ( $conf->config('cust_main-custnum-display_prefix') ) {
3833     return $conf->config('cust_main-custnum-display_prefix').
3834            sprintf('%08d', $self->custnum)
3835   } else {
3836     return $self->custnum;
3837   }
3838 }
3839
3840 =item name
3841
3842 Returns a name string for this customer, either "Company (Last, First)" or
3843 "Last, First".
3844
3845 =cut
3846
3847 sub name {
3848   my $self = shift;
3849   my $name = $self->contact;
3850   $name = $self->company. " ($name)" if $self->company;
3851   $name;
3852 }
3853
3854 =item ship_name
3855
3856 Returns a name string for this (service/shipping) contact, either
3857 "Company (Last, First)" or "Last, First".
3858
3859 =cut
3860
3861 sub ship_name {
3862   my $self = shift;
3863   if ( $self->get('ship_last') ) {
3864     my $name = $self->ship_contact;
3865     $name = $self->ship_company. " ($name)" if $self->ship_company;
3866     $name;
3867   } else {
3868     $self->name;
3869   }
3870 }
3871
3872 =item name_short
3873
3874 Returns a name string for this customer, either "Company" or "First Last".
3875
3876 =cut
3877
3878 sub name_short {
3879   my $self = shift;
3880   $self->company !~ /^\s*$/ ? $self->company : $self->contact_firstlast;
3881 }
3882
3883 =item ship_name_short
3884
3885 Returns a name string for this (service/shipping) contact, either "Company"
3886 or "First Last".
3887
3888 =cut
3889
3890 sub ship_name_short {
3891   my $self = shift;
3892   if ( $self->get('ship_last') ) {
3893     $self->ship_company !~ /^\s*$/
3894       ? $self->ship_company
3895       : $self->ship_contact_firstlast;
3896   } else {
3897     $self->name_company_or_firstlast;
3898   }
3899 }
3900
3901 =item contact
3902
3903 Returns this customer's full (billing) contact name only, "Last, First"
3904
3905 =cut
3906
3907 sub contact {
3908   my $self = shift;
3909   $self->get('last'). ', '. $self->first;
3910 }
3911
3912 =item ship_contact
3913
3914 Returns this customer's full (shipping) contact name only, "Last, First"
3915
3916 =cut
3917
3918 sub ship_contact {
3919   my $self = shift;
3920   $self->get('ship_last')
3921     ? $self->get('ship_last'). ', '. $self->ship_first
3922     : $self->contact;
3923 }
3924
3925 =item contact_firstlast
3926
3927 Returns this customers full (billing) contact name only, "First Last".
3928
3929 =cut
3930
3931 sub contact_firstlast {
3932   my $self = shift;
3933   $self->first. ' '. $self->get('last');
3934 }
3935
3936 =item ship_contact_firstlast
3937
3938 Returns this customer's full (shipping) contact name only, "First Last".
3939
3940 =cut
3941
3942 sub ship_contact_firstlast {
3943   my $self = shift;
3944   $self->get('ship_last')
3945     ? $self->first. ' '. $self->get('ship_last')
3946     : $self->contact_firstlast;
3947 }
3948
3949 =item country_full
3950
3951 Returns this customer's full country name
3952
3953 =cut
3954
3955 sub country_full {
3956   my $self = shift;
3957   code2country($self->country);
3958 }
3959
3960 =item geocode DATA_VENDOR
3961
3962 Returns a value for the customer location as encoded by DATA_VENDOR.
3963 Currently this only makes sense for "CCH" as DATA_VENDOR.
3964
3965 =cut
3966
3967 =item cust_status
3968
3969 =item status
3970
3971 Returns a status string for this customer, currently:
3972
3973 =over 4
3974
3975 =item prospect - No packages have ever been ordered
3976
3977 =item ordered - Recurring packages all are new (not yet billed).
3978
3979 =item active - One or more recurring packages is active
3980
3981 =item inactive - No active recurring packages, but otherwise unsuspended/uncancelled (the inactive status is new - previously inactive customers were mis-identified as cancelled)
3982
3983 =item suspended - All non-cancelled recurring packages are suspended
3984
3985 =item cancelled - All recurring packages are cancelled
3986
3987 =back
3988
3989 Behavior of inactive vs. cancelled edge cases can be adjusted with the
3990 cust_main-status_module configuration option.
3991
3992 =cut
3993
3994 sub status { shift->cust_status(@_); }
3995
3996 sub cust_status {
3997   my $self = shift;
3998   for my $status ( FS::cust_main->statuses() ) {
3999     my $method = $status.'_sql';
4000     my $numnum = ( my $sql = $self->$method() ) =~ s/cust_main\.custnum/?/g;
4001     my $sth = dbh->prepare("SELECT $sql") or die dbh->errstr;
4002     $sth->execute( ($self->custnum) x $numnum )
4003       or die "Error executing 'SELECT $sql': ". $sth->errstr;
4004     return $status if $sth->fetchrow_arrayref->[0];
4005   }
4006 }
4007
4008 =item ucfirst_cust_status
4009
4010 =item ucfirst_status
4011
4012 Returns the status with the first character capitalized.
4013
4014 =cut
4015
4016 sub ucfirst_status { shift->ucfirst_cust_status(@_); }
4017
4018 sub ucfirst_cust_status {
4019   my $self = shift;
4020   ucfirst($self->cust_status);
4021 }
4022
4023 =item statuscolor
4024
4025 Returns a hex triplet color string for this customer's status.
4026
4027 =cut
4028
4029 sub statuscolor { shift->cust_statuscolor(@_); }
4030
4031 sub cust_statuscolor {
4032   my $self = shift;
4033   __PACKAGE__->statuscolors->{$self->cust_status};
4034 }
4035
4036 =item tickets
4037
4038 Returns an array of hashes representing the customer's RT tickets.
4039
4040 =cut
4041
4042 sub tickets {
4043   my $self = shift;
4044
4045   my $num = $conf->config('cust_main-max_tickets') || 10;
4046   my @tickets = ();
4047
4048   if ( $conf->config('ticket_system') ) {
4049     unless ( $conf->config('ticket_system-custom_priority_field') ) {
4050
4051       @tickets = @{ FS::TicketSystem->customer_tickets($self->custnum, $num) };
4052
4053     } else {
4054
4055       foreach my $priority (
4056         $conf->config('ticket_system-custom_priority_field-values'), ''
4057       ) {
4058         last if scalar(@tickets) >= $num;
4059         push @tickets,
4060           @{ FS::TicketSystem->customer_tickets( $self->custnum,
4061                                                  $num - scalar(@tickets),
4062                                                  $priority,
4063                                                )
4064            };
4065       }
4066     }
4067   }
4068   (@tickets);
4069 }
4070
4071 # Return services representing svc_accts in customer support packages
4072 sub support_services {
4073   my $self = shift;
4074   my %packages = map { $_ => 1 } $conf->config('support_packages');
4075
4076   grep { $_->pkg_svc && $_->pkg_svc->primary_svc eq 'Y' }
4077     grep { $_->part_svc->svcdb eq 'svc_acct' }
4078     map { $_->cust_svc }
4079     grep { exists $packages{ $_->pkgpart } }
4080     $self->ncancelled_pkgs;
4081
4082 }
4083
4084 # Return a list of latitude/longitude for one of the services (if any)
4085 sub service_coordinates {
4086   my $self = shift;
4087
4088   my @svc_X =
4089     grep { $_->latitude && $_->longitude }
4090     map { $_->svc_x }
4091     map { $_->cust_svc }
4092     $self->ncancelled_pkgs;
4093
4094   scalar(@svc_X) ? ( $svc_X[0]->latitude, $svc_X[0]->longitude ) : ()
4095 }
4096
4097 =item masked FIELD
4098
4099 Returns a masked version of the named field
4100
4101 =cut
4102
4103 sub masked {
4104 my ($self,$field) = @_;
4105
4106 # Show last four
4107
4108 'x'x(length($self->getfield($field))-4).
4109   substr($self->getfield($field), (length($self->getfield($field))-4));
4110
4111 }
4112
4113 =back
4114
4115 =head1 CLASS METHODS
4116
4117 =over 4
4118
4119 =item statuses
4120
4121 Class method that returns the list of possible status strings for customers
4122 (see L<the status method|/status>).  For example:
4123
4124   @statuses = FS::cust_main->statuses();
4125
4126 =cut
4127
4128 sub statuses {
4129   my $self = shift;
4130   keys %{ $self->statuscolors };
4131 }
4132
4133 =item cust_status_sql
4134
4135 Returns an SQL fragment to determine the status of a cust_main record, as a
4136 string.
4137
4138 =cut
4139
4140 sub cust_status_sql {
4141   my $sql = 'CASE';
4142   for my $status ( FS::cust_main->statuses() ) {
4143     my $method = $status.'_sql';
4144     $sql .= ' WHEN ('.FS::cust_main->$method.") THEN '$status'";
4145   }
4146   $sql .= ' END';
4147   return $sql;
4148 }
4149
4150
4151 =item prospect_sql
4152
4153 Returns an SQL expression identifying prospective cust_main records (customers
4154 with no packages ever ordered)
4155
4156 =cut
4157
4158 use vars qw($select_count_pkgs);
4159 $select_count_pkgs =
4160   "SELECT COUNT(*) FROM cust_pkg
4161     WHERE cust_pkg.custnum = cust_main.custnum";
4162
4163 sub select_count_pkgs_sql {
4164   $select_count_pkgs;
4165 }
4166
4167 sub prospect_sql {
4168   " 0 = ( $select_count_pkgs ) ";
4169 }
4170
4171 =item ordered_sql
4172
4173 Returns an SQL expression identifying ordered cust_main records (customers with
4174 no active packages, but recurring packages not yet setup or one time charges
4175 not yet billed).
4176
4177 =cut
4178
4179 sub ordered_sql {
4180   FS::cust_main->none_active_sql.
4181   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->not_yet_billed_sql. " ) ";
4182 }
4183
4184 =item active_sql
4185
4186 Returns an SQL expression identifying active cust_main records (customers with
4187 active recurring packages).
4188
4189 =cut
4190
4191 sub active_sql {
4192   " 0 < ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4193 }
4194
4195 =item none_active_sql
4196
4197 Returns an SQL expression identifying cust_main records with no active
4198 recurring packages.  This includes customers of status prospect, ordered,
4199 inactive, and suspended.
4200
4201 =cut
4202
4203 sub none_active_sql {
4204   " 0 = ( $select_count_pkgs AND ". FS::cust_pkg->active_sql. " ) ";
4205 }
4206
4207 =item inactive_sql
4208
4209 Returns an SQL expression identifying inactive cust_main records (customers with
4210 no active recurring packages, but otherwise unsuspended/uncancelled).
4211
4212 =cut
4213
4214 sub inactive_sql {
4215   FS::cust_main->none_active_sql.
4216   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->inactive_sql. " ) ";
4217 }
4218
4219 =item susp_sql
4220 =item suspended_sql
4221
4222 Returns an SQL expression identifying suspended cust_main records.
4223
4224 =cut
4225
4226
4227 sub suspended_sql { susp_sql(@_); }
4228 sub susp_sql {
4229   FS::cust_main->none_active_sql.
4230   " AND 0 < ( $select_count_pkgs AND ". FS::cust_pkg->suspended_sql. " ) ";
4231 }
4232
4233 =item cancel_sql
4234 =item cancelled_sql
4235
4236 Returns an SQL expression identifying cancelled cust_main records.
4237
4238 =cut
4239
4240 sub cancel_sql { shift->cancelled_sql(@_); }
4241
4242 =item uncancel_sql
4243 =item uncancelled_sql
4244
4245 Returns an SQL expression identifying un-cancelled cust_main records.
4246
4247 =cut
4248
4249 sub uncancelled_sql { uncancel_sql(@_); }
4250 sub uncancel_sql { "
4251   ( 0 < ( $select_count_pkgs
4252                    AND ( cust_pkg.cancel IS NULL
4253                          OR cust_pkg.cancel = 0
4254                        )
4255         )
4256     OR 0 = ( $select_count_pkgs )
4257   )
4258 "; }
4259
4260 =item balance_sql
4261
4262 Returns an SQL fragment to retreive the balance.
4263
4264 =cut
4265
4266 sub balance_sql { "
4267     ( SELECT COALESCE( SUM(charged), 0 ) FROM cust_bill
4268         WHERE cust_bill.custnum   = cust_main.custnum     )
4269   - ( SELECT COALESCE( SUM(paid),    0 ) FROM cust_pay
4270         WHERE cust_pay.custnum    = cust_main.custnum     )
4271   - ( SELECT COALESCE( SUM(amount),  0 ) FROM cust_credit
4272         WHERE cust_credit.custnum = cust_main.custnum     )
4273   + ( SELECT COALESCE( SUM(refund),  0 ) FROM cust_refund
4274         WHERE cust_refund.custnum = cust_main.custnum     )
4275 "; }
4276
4277 =item balance_date_sql [ START_TIME [ END_TIME [ OPTION => VALUE ... ] ] ]
4278
4279 Returns an SQL fragment to retreive the balance for this customer, optionally
4280 considering invoices with date earlier than START_TIME, and not
4281 later than END_TIME (total_owed_date minus total_unapplied_credits minus
4282 total_unapplied_payments).
4283
4284 Times are specified as SQL fragments or numeric
4285 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4286 L<Date::Parse> for conversion functions.  The empty string can be passed
4287 to disable that time constraint completely.
4288
4289 Available options are:
4290
4291 =over 4
4292
4293 =item unapplied_date
4294
4295 set to true to disregard unapplied credits, payments and refunds outside the specified time period - by default the time period restriction only applies to invoices (useful for reporting, probably a bad idea for event triggering)
4296
4297 =item total
4298
4299 (unused.  obsolete?)
4300 set to true to remove all customer comparison clauses, for totals
4301
4302 =item where
4303
4304 (unused.  obsolete?)
4305 WHERE clause hashref (elements "AND"ed together) (typically used with the total option)
4306
4307 =item join
4308
4309 (unused.  obsolete?)
4310 JOIN clause (typically used with the total option)
4311
4312 =item cutoff
4313
4314 An absolute cutoff time.  Payments, credits, and refunds I<applied> after this
4315 time will be ignored.  Note that START_TIME and END_TIME only limit the date
4316 range for invoices and I<unapplied> payments, credits, and refunds.
4317
4318 =back
4319
4320 =cut
4321
4322 sub balance_date_sql {
4323   my( $class, $start, $end, %opt ) = @_;
4324
4325   my $cutoff = $opt{'cutoff'};
4326
4327   my $owed         = FS::cust_bill->owed_sql($cutoff);
4328   my $unapp_refund = FS::cust_refund->unapplied_sql($cutoff);
4329   my $unapp_credit = FS::cust_credit->unapplied_sql($cutoff);
4330   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4331
4332   my $j = $opt{'join'} || '';
4333
4334   my $owed_wh   = $class->_money_table_where( 'cust_bill',   $start,$end,%opt );
4335   my $refund_wh = $class->_money_table_where( 'cust_refund', $start,$end,%opt );
4336   my $credit_wh = $class->_money_table_where( 'cust_credit', $start,$end,%opt );
4337   my $pay_wh    = $class->_money_table_where( 'cust_pay',    $start,$end,%opt );
4338
4339   "   ( SELECT COALESCE(SUM($owed),         0) FROM cust_bill   $j $owed_wh   )
4340     + ( SELECT COALESCE(SUM($unapp_refund), 0) FROM cust_refund $j $refund_wh )
4341     - ( SELECT COALESCE(SUM($unapp_credit), 0) FROM cust_credit $j $credit_wh )
4342     - ( SELECT COALESCE(SUM($unapp_pay),    0) FROM cust_pay    $j $pay_wh    )
4343   ";
4344
4345 }
4346
4347 =item unapplied_payments_date_sql START_TIME [ END_TIME ]
4348
4349 Returns an SQL fragment to retreive the total unapplied payments for this
4350 customer, only considering payments with date earlier than START_TIME, and
4351 optionally not later than END_TIME.
4352
4353 Times are specified as SQL fragments or numeric
4354 UNIX timestamps; see L<perlfunc/"time">).  Also see L<Time::Local> and
4355 L<Date::Parse> for conversion functions.  The empty string can be passed
4356 to disable that time constraint completely.
4357
4358 Available options are:
4359
4360 =cut
4361
4362 sub unapplied_payments_date_sql {
4363   my( $class, $start, $end, %opt ) = @_;
4364
4365   my $cutoff = $opt{'cutoff'};
4366
4367   my $unapp_pay    = FS::cust_pay->unapplied_sql($cutoff);
4368
4369   my $pay_where = $class->_money_table_where( 'cust_pay', $start, $end,
4370                                                           'unapplied_date'=>1 );
4371
4372   " ( SELECT COALESCE(SUM($unapp_pay), 0) FROM cust_pay $pay_where ) ";
4373 }
4374
4375 =item _money_table_where TABLE START_TIME [ END_TIME [ OPTION => VALUE ... ] ]
4376
4377 Helper method for balance_date_sql; name (and usage) subject to change
4378 (suggestions welcome).
4379
4380 Returns a WHERE clause for the specified monetary TABLE (cust_bill,
4381 cust_refund, cust_credit or cust_pay).
4382
4383 If TABLE is "cust_bill" or the unapplied_date option is true, only
4384 considers records with date earlier than START_TIME, and optionally not
4385 later than END_TIME .
4386
4387 =cut
4388
4389 sub _money_table_where {
4390   my( $class, $table, $start, $end, %opt ) = @_;
4391
4392   my @where = ();
4393   push @where, "cust_main.custnum = $table.custnum" unless $opt{'total'};
4394   if ( $table eq 'cust_bill' || $opt{'unapplied_date'} ) {
4395     push @where, "$table._date <= $start" if defined($start) && length($start);
4396     push @where, "$table._date >  $end"   if defined($end)   && length($end);
4397   }
4398   push @where, @{$opt{'where'}} if $opt{'where'};
4399   my $where = scalar(@where) ? 'WHERE '. join(' AND ', @where ) : '';
4400
4401   $where;
4402
4403 }
4404
4405 #for dyanmic FS::$table->search in httemplate/misc/email_customers.html
4406 use FS::cust_main::Search;
4407 sub search {
4408   my $class = shift;
4409   FS::cust_main::Search->search(@_);
4410 }
4411
4412 =back
4413
4414 =head1 SUBROUTINES
4415
4416 =over 4
4417
4418 =item batch_charge
4419
4420 =cut
4421
4422 sub batch_charge {
4423   my $param = shift;
4424   #warn join('-',keys %$param);
4425   my $fh = $param->{filehandle};
4426   my $agentnum = $param->{agentnum};
4427   my $format = $param->{format};
4428
4429   my $extra_sql = ' AND '. $FS::CurrentUser::CurrentUser->agentnums_sql;
4430
4431   my @fields;
4432   if ( $format eq 'simple' ) {
4433     @fields = qw( custnum agent_custid amount pkg );
4434   } else {
4435     die "unknown format $format";
4436   }
4437
4438   eval "use Text::CSV_XS;";
4439   die $@ if $@;
4440
4441   my $csv = new Text::CSV_XS;
4442   #warn $csv;
4443   #warn $fh;
4444
4445   my $imported = 0;
4446   #my $columns;
4447
4448   local $SIG{HUP} = 'IGNORE';
4449   local $SIG{INT} = 'IGNORE';
4450   local $SIG{QUIT} = 'IGNORE';
4451   local $SIG{TERM} = 'IGNORE';
4452   local $SIG{TSTP} = 'IGNORE';
4453   local $SIG{PIPE} = 'IGNORE';
4454
4455   my $oldAutoCommit = $FS::UID::AutoCommit;
4456   local $FS::UID::AutoCommit = 0;
4457   my $dbh = dbh;
4458
4459   #while ( $columns = $csv->getline($fh) ) {
4460   my $line;
4461   while ( defined($line=<$fh>) ) {
4462
4463     $csv->parse($line) or do {
4464       $dbh->rollback if $oldAutoCommit;
4465       return "can't parse: ". $csv->error_input();
4466     };
4467
4468     my @columns = $csv->fields();
4469     #warn join('-',@columns);
4470
4471     my %row = ();
4472     foreach my $field ( @fields ) {
4473       $row{$field} = shift @columns;
4474     }
4475
4476     if ( $row{custnum} && $row{agent_custid} ) {
4477       dbh->rollback if $oldAutoCommit;
4478       return "can't specify custnum with agent_custid $row{agent_custid}";
4479     }
4480
4481     my %hash = ();
4482     if ( $row{agent_custid} && $agentnum ) {
4483       %hash = ( 'agent_custid' => $row{agent_custid},
4484                 'agentnum'     => $agentnum,
4485               );
4486     }
4487
4488     if ( $row{custnum} ) {
4489       %hash = ( 'custnum' => $row{custnum} );
4490     }
4491
4492     unless ( scalar(keys %hash) ) {
4493       $dbh->rollback if $oldAutoCommit;
4494       return "can't find customer without custnum or agent_custid and agentnum";
4495     }
4496
4497     my $cust_main = qsearchs('cust_main', { %hash } );
4498     unless ( $cust_main ) {
4499       $dbh->rollback if $oldAutoCommit;
4500       my $custnum = $row{custnum} || $row{agent_custid};
4501       return "unknown custnum $custnum";
4502     }
4503
4504     if ( $row{'amount'} > 0 ) {
4505       my $error = $cust_main->charge($row{'amount'}, $row{'pkg'});
4506       if ( $error ) {
4507         $dbh->rollback if $oldAutoCommit;
4508         return $error;
4509       }
4510       $imported++;
4511     } elsif ( $row{'amount'} < 0 ) {
4512       my $error = $cust_main->credit( sprintf( "%.2f", 0-$row{'amount'} ),
4513                                       $row{'pkg'}                         );
4514       if ( $error ) {
4515         $dbh->rollback if $oldAutoCommit;
4516         return $error;
4517       }
4518       $imported++;
4519     } else {
4520       #hmm?
4521     }
4522
4523   }
4524
4525   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
4526
4527   return "Empty file!" unless $imported;
4528
4529   ''; #no error
4530
4531 }
4532
4533 =item notify CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4534
4535 Deprecated.  Use event notification and message templates
4536 (L<FS::msg_template>) instead.
4537
4538 Sends a templated email notification to the customer (see L<Text::Template>).
4539
4540 OPTIONS is a hash and may include
4541
4542 I<from> - the email sender (default is invoice_from)
4543
4544 I<to> - comma-separated scalar or arrayref of recipients
4545    (default is invoicing_list)
4546
4547 I<subject> - The subject line of the sent email notification
4548    (default is "Notice from company_name")
4549
4550 I<extra_fields> - a hashref of name/value pairs which will be substituted
4551    into the template
4552
4553 The following variables are vavailable in the template.
4554
4555 I<$first> - the customer first name
4556 I<$last> - the customer last name
4557 I<$company> - the customer company
4558 I<$payby> - a description of the method of payment for the customer
4559             # would be nice to use FS::payby::shortname
4560 I<$payinfo> - the account information used to collect for this customer
4561 I<$expdate> - the expiration of the customer payment in seconds from epoch
4562
4563 =cut
4564
4565 sub notify {
4566   my ($self, $template, %options) = @_;
4567
4568   return unless $conf->exists($template);
4569
4570   my $from = $conf->config('invoice_from', $self->agentnum)
4571     if $conf->exists('invoice_from', $self->agentnum);
4572   $from = $options{from} if exists($options{from});
4573
4574   my $to = join(',', $self->invoicing_list_emailonly);
4575   $to = $options{to} if exists($options{to});
4576
4577   my $subject = "Notice from " . $conf->config('company_name', $self->agentnum)
4578     if $conf->exists('company_name', $self->agentnum);
4579   $subject = $options{subject} if exists($options{subject});
4580
4581   my $notify_template = new Text::Template (TYPE => 'ARRAY',
4582                                             SOURCE => [ map "$_\n",
4583                                               $conf->config($template)]
4584                                            )
4585     or die "can't create new Text::Template object: Text::Template::ERROR";
4586   $notify_template->compile()
4587     or die "can't compile template: Text::Template::ERROR";
4588
4589   $FS::notify_template::_template::company_name =
4590     $conf->config('company_name', $self->agentnum);
4591   $FS::notify_template::_template::company_address =
4592     join("\n", $conf->config('company_address', $self->agentnum) ). "\n";
4593
4594   my $paydate = $self->paydate || '2037-12-31';
4595   $FS::notify_template::_template::first = $self->first;
4596   $FS::notify_template::_template::last = $self->last;
4597   $FS::notify_template::_template::company = $self->company;
4598   $FS::notify_template::_template::payinfo = $self->mask_payinfo;
4599   my $payby = $self->payby;
4600   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
4601   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
4602
4603   #credit cards expire at the end of the month/year of their exp date
4604   if ($payby eq 'CARD' || $payby eq 'DCRD') {
4605     $FS::notify_template::_template::payby = 'credit card';
4606     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
4607     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
4608     $expire_time--;
4609   }elsif ($payby eq 'COMP') {
4610     $FS::notify_template::_template::payby = 'complimentary account';
4611   }else{
4612     $FS::notify_template::_template::payby = 'current method';
4613   }
4614   $FS::notify_template::_template::expdate = $expire_time;
4615
4616   for (keys %{$options{extra_fields}}){
4617     no strict "refs";
4618     ${"FS::notify_template::_template::$_"} = $options{extra_fields}->{$_};
4619   }
4620
4621   send_email(from => $from,
4622              to => $to,
4623              subject => $subject,
4624              body => $notify_template->fill_in( PACKAGE =>
4625                                                 'FS::notify_template::_template'                                              ),
4626             );
4627
4628 }
4629
4630 =item generate_letter CUSTOMER_OBJECT TEMPLATE_NAME OPTIONS
4631
4632 Generates a templated notification to the customer (see L<Text::Template>).
4633
4634 OPTIONS is a hash and may include
4635
4636 I<extra_fields> - a hashref of name/value pairs which will be substituted
4637    into the template.  These values may override values mentioned below
4638    and those from the customer record.
4639
4640 The following variables are available in the template instead of or in addition
4641 to the fields of the customer record.
4642
4643 I<$payby> - a description of the method of payment for the customer
4644             # would be nice to use FS::payby::shortname
4645 I<$payinfo> - the masked account information used to collect for this customer
4646 I<$expdate> - the expiration of the customer payment method in seconds from epoch
4647 I<$returnaddress> - the return address defaults to invoice_latexreturnaddress or company_address
4648
4649 =cut
4650
4651 # a lot like cust_bill::print_latex
4652 sub generate_letter {
4653   my ($self, $template, %options) = @_;
4654
4655   return unless $conf->exists($template);
4656
4657   my $letter_template = new Text::Template
4658                         ( TYPE       => 'ARRAY',
4659                           SOURCE     => [ map "$_\n", $conf->config($template)],
4660                           DELIMITERS => [ '[@--', '--@]' ],
4661                         )
4662     or die "can't create new Text::Template object: Text::Template::ERROR";
4663
4664   $letter_template->compile()
4665     or die "can't compile template: Text::Template::ERROR";
4666
4667   my %letter_data = map { $_ => $self->$_ } $self->fields;
4668   $letter_data{payinfo} = $self->mask_payinfo;
4669
4670   #my $paydate = $self->paydate || '2037-12-31';
4671   my $paydate = $self->paydate =~ /^\S+$/ ? $self->paydate : '2037-12-31';
4672
4673   my $payby = $self->payby;
4674   my ($payyear,$paymonth,$payday) = split (/-/,$paydate);
4675   my $expire_time = timelocal(0,0,0,$payday,--$paymonth,$payyear);
4676
4677   #credit cards expire at the end of the month/year of their exp date
4678   if ($payby eq 'CARD' || $payby eq 'DCRD') {
4679     $letter_data{payby} = 'credit card';
4680     ($paymonth < 11) ? $paymonth++ : ($paymonth=0, $payyear++);
4681     $expire_time = timelocal(0,0,0,$payday,$paymonth,$payyear);
4682     $expire_time--;
4683   }elsif ($payby eq 'COMP') {
4684     $letter_data{payby} = 'complimentary account';
4685   }else{
4686     $letter_data{payby} = 'current method';
4687   }
4688   $letter_data{expdate} = $expire_time;
4689
4690   for (keys %{$options{extra_fields}}){
4691     $letter_data{$_} = $options{extra_fields}->{$_};
4692   }
4693
4694   unless(exists($letter_data{returnaddress})){
4695     my $retadd = join("\n", $conf->config_orbase( 'invoice_latexreturnaddress',
4696                                                   $self->agent_template)
4697                      );
4698     if ( length($retadd) ) {
4699       $letter_data{returnaddress} = $retadd;
4700     } elsif ( grep /\S/, $conf->config('company_address', $self->agentnum) ) {
4701       $letter_data{returnaddress} =
4702         join( "\n", map { s/( {2,})/'~' x length($1)/eg;
4703                           s/$/\\\\\*/;
4704                           $_;
4705                         }
4706                     ( $conf->config('company_name', $self->agentnum),
4707                       $conf->config('company_address', $self->agentnum),
4708                     )
4709         );
4710     } else {
4711       $letter_data{returnaddress} = '~';
4712     }
4713   }
4714
4715   $letter_data{conf_dir} = "$FS::UID::conf_dir/conf.$FS::UID::datasrc";
4716
4717   $letter_data{company_name} = $conf->config('company_name', $self->agentnum);
4718
4719   my $dir = $FS::UID::conf_dir."/cache.". $FS::UID::datasrc;
4720
4721   my $lh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4722                            DIR      => $dir,
4723                            SUFFIX   => '.eps',
4724                            UNLINK   => 0,
4725                          ) or die "can't open temp file: $!\n";
4726   print $lh $conf->config_binary('logo.eps', $self->agentnum)
4727     or die "can't write temp file: $!\n";
4728   close $lh;
4729   $letter_data{'logo_file'} = $lh->filename;
4730
4731   my $fh = new File::Temp( TEMPLATE => 'letter.'. $self->custnum. '.XXXXXXXX',
4732                            DIR      => $dir,
4733                            SUFFIX   => '.tex',
4734                            UNLINK   => 0,
4735                          ) or die "can't open temp file: $!\n";
4736
4737   $letter_template->fill_in( OUTPUT => $fh, HASH => \%letter_data );
4738   close $fh;
4739   $fh->filename =~ /^(.*).tex$/ or die "unparsable filename: ". $fh->filename;
4740   return ($1, $letter_data{'logo_file'});
4741
4742 }
4743
4744 =item print_ps TEMPLATE
4745
4746 Returns an postscript letter filled in from TEMPLATE, as a scalar.
4747
4748 =cut
4749
4750 sub print_ps {
4751   my $self = shift;
4752   my($file, $lfile) = $self->generate_letter(@_);
4753   my $ps = FS::Misc::generate_ps($file);
4754   unlink($file.'.tex');
4755   unlink($lfile);
4756
4757   $ps;
4758 }
4759
4760 =item print TEMPLATE
4761
4762 Prints the filled in template.
4763
4764 TEMPLATE is the name of a L<Text::Template> to fill in and print.
4765
4766 =cut
4767
4768 sub queueable_print {
4769   my %opt = @_;
4770
4771   my $self = qsearchs('cust_main', { 'custnum' => $opt{custnum} } )
4772     or die "invalid customer number: " . $opt{custvnum};
4773
4774   my $error = $self->print( $opt{template} );
4775   die $error if $error;
4776 }
4777
4778 sub print {
4779   my ($self, $template) = (shift, shift);
4780   do_print [ $self->print_ps($template) ];
4781 }
4782
4783 #these three subs should just go away once agent stuff is all config overrides
4784
4785 sub agent_template {
4786   my $self = shift;
4787   $self->_agent_plandata('agent_templatename');
4788 }
4789
4790 sub agent_invoice_from {
4791   my $self = shift;
4792   $self->_agent_plandata('agent_invoice_from');
4793 }
4794
4795 sub _agent_plandata {
4796   my( $self, $option ) = @_;
4797
4798   #yuck.  this whole thing needs to be reconciled better with 1.9's idea of
4799   #agent-specific Conf
4800
4801   use FS::part_event::Condition;
4802
4803   my $agentnum = $self->agentnum;
4804
4805   my $regexp = regexp_sql();
4806
4807   my $part_event_option =
4808     qsearchs({
4809       'select'    => 'part_event_option.*',
4810       'table'     => 'part_event_option',
4811       'addl_from' => q{
4812         LEFT JOIN part_event USING ( eventpart )
4813         LEFT JOIN part_event_option AS peo_agentnum
4814           ON ( part_event.eventpart = peo_agentnum.eventpart
4815                AND peo_agentnum.optionname = 'agentnum'
4816                AND peo_agentnum.optionvalue }. $regexp. q{ '(^|,)}. $agentnum. q{(,|$)'
4817              )
4818         LEFT JOIN part_event_condition
4819           ON ( part_event.eventpart = part_event_condition.eventpart
4820                AND part_event_condition.conditionname = 'cust_bill_age'
4821              )
4822         LEFT JOIN part_event_condition_option
4823           ON ( part_event_condition.eventconditionnum = part_event_condition_option.eventconditionnum
4824                AND part_event_condition_option.optionname = 'age'
4825              )
4826       },
4827       #'hashref'   => { 'optionname' => $option },
4828       #'hashref'   => { 'part_event_option.optionname' => $option },
4829       'extra_sql' =>
4830         " WHERE part_event_option.optionname = ". dbh->quote($option).
4831         " AND action = 'cust_bill_send_agent' ".
4832         " AND ( disabled IS NULL OR disabled != 'Y' ) ".
4833         " AND peo_agentnum.optionname = 'agentnum' ".
4834         " AND ( agentnum IS NULL OR agentnum = $agentnum ) ".
4835         " ORDER BY
4836            CASE WHEN part_event_condition_option.optionname IS NULL
4837            THEN -1
4838            ELSE ". FS::part_event::Condition->age2seconds_sql('part_event_condition_option.optionvalue').
4839         " END
4840           , part_event.weight".
4841         " LIMIT 1"
4842     });
4843
4844   unless ( $part_event_option ) {
4845     return $self->agent->invoice_template || ''
4846       if $option eq 'agent_templatename';
4847     return '';
4848   }
4849
4850   $part_event_option->optionvalue;
4851
4852 }
4853
4854 =item queued_bill 'custnum' => CUSTNUM [ , OPTION => VALUE ... ]
4855
4856 Subroutine (not a method), designed to be called from the queue.
4857
4858 Takes a list of options and values.
4859
4860 Pulls up the customer record via the custnum option and calls bill_and_collect.
4861
4862 =cut
4863
4864 sub queued_bill {
4865   my (%args) = @_; #, ($time, $invoice_time, $check_freq, $resetup) = @_;
4866
4867   my $cust_main = qsearchs( 'cust_main', { custnum => $args{'custnum'} } );
4868   warn 'bill_and_collect custnum#'. $cust_main->custnum. "\n";#log custnum w/pid
4869
4870   $cust_main->bill_and_collect( %args );
4871 }
4872
4873 sub process_bill_and_collect {
4874   my $job = shift;
4875   my $param = thaw(decode_base64(shift));
4876   my $cust_main = qsearchs( 'cust_main', { custnum => $param->{'custnum'} } )
4877       or die "custnum '$param->{custnum}' not found!\n";
4878   $param->{'job'}   = $job;
4879   $param->{'fatal'} = 1; # runs from job queue, will be caught
4880   $param->{'retry'} = 1;
4881
4882   $cust_main->bill_and_collect( %$param );
4883 }
4884
4885 sub _upgrade_data { #class method
4886   my ($class, %opts) = @_;
4887
4888   my @statements = (
4889     'UPDATE h_cust_main SET paycvv = NULL WHERE paycvv IS NOT NULL',
4890     'UPDATE cust_main SET signupdate = (SELECT signupdate FROM h_cust_main WHERE signupdate IS NOT NULL AND h_cust_main.custnum = cust_main.custnum ORDER BY historynum DESC LIMIT 1) WHERE signupdate IS NULL',
4891   );
4892   # fix yyyy-m-dd formatted paydates
4893   if ( driver_name =~ /^mysql$/i ) {
4894     push @statements,
4895     "UPDATE cust_main SET paydate = CONCAT( SUBSTRING(paydate FROM 1 FOR 5), '0', SUBSTRING(paydate FROM 6) ) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
4896   }
4897   else { # the SQL standard
4898     push @statements,
4899     "UPDATE cust_main SET paydate = SUBSTRING(paydate FROM 1 FOR 5) || '0' || SUBSTRING(paydate FROM 6) WHERE SUBSTRING(paydate FROM 7 FOR 1) = '-'";
4900   }
4901
4902   foreach my $sql ( @statements ) {
4903     my $sth = dbh->prepare($sql) or die dbh->errstr;
4904     $sth->execute or die $sth->errstr;
4905   }
4906
4907   local($ignore_expired_card) = 1;
4908   local($ignore_illegal_zip) = 1;
4909   local($ignore_banned_card) = 1;
4910   local($skip_fuzzyfiles) = 1;
4911   $class->_upgrade_otaker(%opts);
4912
4913 }
4914
4915 =back
4916
4917 =head1 BUGS
4918
4919 The delete method.
4920
4921 The delete method should possibly take an FS::cust_main object reference
4922 instead of a scalar customer number.
4923
4924 Bill and collect options should probably be passed as references instead of a
4925 list.
4926
4927 There should probably be a configuration file with a list of allowed credit
4928 card types.
4929
4930 No multiple currency support (probably a larger project than just this module).
4931
4932 payinfo_masked false laziness with cust_pay.pm and cust_refund.pm
4933
4934 Birthdates rely on negative epoch values.
4935
4936 The payby for card/check batches is broken.  With mixed batching, bad
4937 things will happen.
4938
4939 B<collect> I<invoice_time> should be renamed I<time>, like B<bill>.
4940
4941 =head1 SEE ALSO
4942
4943 L<FS::Record>, L<FS::cust_pkg>, L<FS::cust_bill>, L<FS::cust_credit>
4944 L<FS::agent>, L<FS::part_referral>, L<FS::cust_main_county>,
4945 L<FS::cust_main_invoice>, L<FS::UID>, schema.html from the base documentation.
4946
4947 =cut
4948
4949 1;
4950