FS/FS/cust_event.pm

   1 package FS::cust_event;
   2 use base qw( FS::cust_main_Mixin FS::Record );
   3
   4 use strict;
   5 use vars qw( $DEBUG $me );
   6 use Carp qw( croak confess );
   7 use FS::Record qw( qsearch qsearchs dbdef );
   8 #for cust_X
   9 use FS::cust_main;
  10 use FS::cust_pkg;
  11 use FS::cust_bill;
  12 use FS::cust_pay;
  13 use FS::svc_acct;
  14
  15 $DEBUG = 0;
  16 $me = '[FS::cust_event]';
  17
  18 =head1 NAME
  19
  20 FS::cust_event - Object methods for cust_event records
  21
  22 =head1 SYNOPSIS
  23
  24   use FS::cust_event;
  25
  26   $record = new FS::cust_event \%hash;
  27   $record = new FS::cust_event { 'column' => 'value' };
  28
  29   $error = $record->insert;
  30
  31   $error = $new_record->replace($old_record);
  32
  33   $error = $record->delete;
  34
  35   $error = $record->check;
  36
  37 =head1 DESCRIPTION
  38
  39 An FS::cust_event object represents an completed event.  FS::cust_event
  40 inherits from FS::Record.  The following fields are currently supported:
  41
  42 =over 4
  43
  44 =item eventnum - primary key
  45
  46 =item eventpart - event definition (see L<FS::part_event>)
  47
  48 =item tablenum - customer, package or invoice, depending on the value of part_event.eventtable (see L<FS::cust_main>, L<FS::cust_pkg>, and L<FS::cust_bill>)
  49
  50 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  51 L<Time::Local> and L<Date::Parse> for conversion functions.
  52
  53 =item status - event status: B<new>, B<locked>, B<done> or B<failed>.  Note: B<done> indicates the event is complete and should not be retried (statustext may still be set to an optional message), while B<failed> indicates the event failed and should be retried.
  54
  55 =item statustext - additional status detail (i.e. error or progress message)
  56
  57 =item no_action - 'Y' if the event action wasn't performed. Some actions
  58 contain an internal check to see if the action is going to be impossible (for
  59 example, emailing a notice to a customer who has no email address), and if so,
  60 won't attempt the action. It shouldn't be reported as a failure because
  61 there's no need to retry it. However, the action should set no_action = 'Y'
  62 so that there's a record.
  63
  64 =back
  65
  66 =head1 METHODS
  67
  68 =over 4
  69
  70 =item new HASHREF
  71
  72 Creates a new completed invoice event.  To add the compelted invoice event to
  73 the database, see L<"insert">.
  74
  75 Note that this stores the hash reference, not a distinct copy of the hash it
  76 points to.  You can ask the object for a copy with the I<hash> method.
  77
  78 =cut
  79
  80 # the new method can be inherited from FS::Record, if a table method is defined
  81
  82 sub table { 'cust_event'; }
  83
  84 sub cust_linked { $_[0]->cust_main_custnum || $_[0]->custnum }
  85 sub cust_unlinked_msg {
  86   my $self = shift;
  87   "WARNING: can't find cust_main.custnum ". $self->custnum;
  88   #' (cust_bill.invnum '. $self->invnum. ')';
  89 }
  90 sub custnum {
  91   my $self = shift;
  92   $self->cust_main_custnum(@_) || $self->SUPER::custnum(@_);
  93 }
  94
  95 =item insert
  96
  97 Adds this record to the database.  If there is an error, returns the error,
  98 otherwise returns false.
  99
 100 =cut
 101
 102 # the insert method can be inherited from FS::Record
 103
 104 =item delete
 105
 106 Delete this record from the database.
 107
 108 =cut
 109
 110 # the delete method can be inherited from FS::Record
 111
 112 =item replace OLD_RECORD
 113
 114 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 115 returns the error, otherwise returns false.
 116
 117 =cut
 118
 119 # the replace method can be inherited from FS::Record
 120
 121 =item check
 122
 123 Checks all fields to make sure this is a valid completed invoice event.  If
 124 there is an error, returns the error, otherwise returns false.  Called by the
 125 insert and replace methods.
 126
 127 =cut
 128
 129 # the check method should currently be supplied - FS::Record contains some
 130 # data checking routines
 131
 132 sub check {
 133   my $self = shift;
 134
 135   my $error = $self->ut_numbern('eventnum')
 136     || $self->ut_foreign_key('eventpart', 'part_event', 'eventpart')
 137   ;
 138   return $error if $error;
 139
 140   my $eventtable = $self->part_event->eventtable;
 141   my $dbdef_eventtable = dbdef->table( $eventtable );
 142
 143   $error =
 144        $self->ut_foreign_key( 'tablenum',
 145                               $eventtable,
 146                               $dbdef_eventtable->primary_key
 147                             )
 148     || $self->ut_number('_date')
 149     || $self->ut_enum('status', [qw( new locked done failed initial)])
 150     || $self->ut_anything('statustext')
 151     || $self->ut_flag('no_action')
 152   ;
 153   return $error if $error;
 154
 155   $self->SUPER::check;
 156 }
 157
 158 =item part_event
 159
 160 Returns the event definition (see L<FS::part_event>) for this completed event.
 161
 162 =item cust_X
 163
 164 Returns the customer, package, invoice or batched payment (see
 165 L<FS::cust_main>, L<FS::cust_pkg>, L<FS::cust_bill> or L<FS::cust_pay_batch>)
 166 for this completed invoice event.
 167
 168 =cut
 169
 170 sub cust_bill {
 171   croak "FS::cust_event::cust_bill called";
 172 }
 173
 174 sub cust_X {
 175   my $self = shift;
 176   my $eventtable = $self->part_event->eventtable;
 177   my $dbdef_table = dbdef->table( $eventtable );
 178   my $primary_key = $dbdef_table->primary_key;
 179   qsearchs( $eventtable, { $primary_key => $self->tablenum } );
 180 }
 181
 182 =item test_conditions [ OPTION => VALUE ... ]
 183
 184 Tests conditions for this event, returns true if all conditions are satisfied,
 185 false otherwise.
 186
 187 =cut
 188
 189 sub test_conditions {
 190   my( $self, %opt ) = @_;
 191   my $part_event = $self->part_event;
 192   my $object = $self->cust_X;
 193   my @conditions = $part_event->part_event_condition;
 194   $opt{'cust_event'} = $self;
 195   $opt{'time'} = $self->_date
 196       or die "test_conditions called without cust_event._date\n";
 197     # this MUST be set, or all hell breaks loose in event conditions.
 198     # it MUST be in the same time as in the cust_event object, or
 199     # future time-dependent events will trigger incorrectly.
 200
 201   #no unsatisfied conditions
 202   #! grep ! $_->condition( $object, %opt ), @conditions;
 203   my @unsatisfied = grep ! $_->condition( $object, %opt ), @conditions;
 204
 205   if ( $opt{'stats_hashref'} ) {
 206     foreach my $unsat (@unsatisfied) {
 207       $opt{'stats_hashref'}->{$unsat->conditionname}++;
 208     }
 209   }
 210
 211   ! @unsatisfied;
 212 }
 213
 214 =item do_event
 215
 216 Runs the event action.
 217
 218 =cut
 219
 220 sub do_event {
 221   my $self = shift;
 222   my %opt = @_; # currently only 'time'
 223   my $time = $opt{'time'} || time;
 224
 225   my $part_event = $self->part_event;
 226
 227   my $object = $self->cust_X;
 228   my $obj_pkey = $object->primary_key;
 229   my $for = "for ". $object->table. " ". $object->$obj_pkey();
 230   warn "running cust_event ". $self->eventnum.
 231        " (". $part_event->action. ") $for\n"
 232     if $DEBUG;
 233
 234   my $error;
 235   {
 236     local $SIG{__DIE__}; # don't want Mason __DIE__ handler active
 237     $error = eval { $part_event->do_action($object, $self); };
 238   }
 239
 240   my $status = '';
 241   my $statustext = '';
 242   if ( $@ ) {
 243     $status = 'failed';
 244     #$statustext = $@;
 245     $statustext = "Error running ". $part_event->action. " action: $@";
 246   } elsif ( $error ) {
 247     $status = 'done';
 248     $statustext = $error;
 249   } else {
 250     $status = 'done';
 251   }
 252
 253   #replace or add myself
 254   $self->_date($time);
 255   $self->status($status);
 256   $self->statustext($statustext);
 257
 258   $error = $self->eventnum ? $self->replace : $self->insert;
 259   if ( $error ) {
 260     #this is why we need that locked state...
 261     my $e = 'WARNING: Event run but database not updated - '.
 262             'error replacing or inserting cust_event '. $self->eventnum.
 263             " $for: $error\n";
 264     warn $e;
 265     return $e;
 266   }
 267
 268   '';
 269
 270 }
 271
 272 =item retry
 273
 274 Changes the status of this event from B<done> to B<failed>, allowing it to be
 275 retried.
 276
 277 =cut
 278
 279 sub retry {
 280   my $self = shift;
 281   return '' unless $self->status eq 'done';
 282   my $old = ref($self)->new( { $self->hash } );
 283   $self->status('failed');
 284   $self->replace($old);
 285 }
 286
 287 #=item retryable
 288 #
 289 #Changes the statustext of this event to B<retriable>, rendering it
 290 #retriable (should retry be called).
 291 #
 292 #=cut
 293
 294 sub retriable {
 295   confess "cust_event->retriable called";
 296   my $self = shift;
 297   return '' unless $self->status eq 'done';
 298   my $old = ref($self)->new( { $self->hash } );
 299   $self->statustext('retriable');
 300   $self->replace($old);
 301 }
 302
 303 =item join_sql
 304
 305 =cut
 306
 307 sub join_sql {
 308   #my $class = shift;
 309
 310   "
 311        JOIN part_event USING ( eventpart )
 312   LEFT JOIN cust_bill ON ( eventtable = 'cust_bill' AND tablenum = invnum  )
 313   LEFT JOIN cust_pkg  ON ( eventtable = 'cust_pkg'  AND tablenum = pkgnum  )
 314   LEFT JOIN cust_pay  ON ( eventtable = 'cust_pay'  AND tablenum = paynum  )
 315   LEFT JOIN cust_svc  ON ( eventtable = 'svc_acct'  AND tablenum = svcnum  )
 316   LEFT JOIN cust_pkg AS cust_pkg_for_svc ON ( cust_svc.pkgnum = cust_pkg_for_svc.pkgnum )
 317   LEFT JOIN cust_main ON (
 318        ( eventtable = 'cust_main' AND tablenum = cust_main.custnum )
 319     OR ( eventtable = 'cust_bill' AND cust_bill.custnum = cust_main.custnum )
 320     OR ( eventtable = 'cust_pkg'  AND cust_pkg.custnum  = cust_main.custnum )
 321     OR ( eventtable = 'cust_pay'  AND cust_pay.custnum  = cust_main.custnum )
 322     OR ( eventtable = 'svc_acct'  AND cust_pkg_for_svc.custnum  = cust_main.custnum )
 323   )
 324   ";
 325
 326 }
 327
 328 =item search_sql_where HASHREF
 329
 330 Class method which returns an SQL WHERE fragment to search for parameters
 331 specified in HASHREF.  Valid parameters are
 332
 333 =over 4
 334
 335 =item agentnum
 336
 337 =item custnum
 338
 339 =item invnum
 340
 341 =item pkgnum
 342
 343 =item svcnum
 344
 345 =item failed
 346
 347 =item beginning
 348
 349 =item ending
 350
 351 =back
 352
 353 =cut
 354
 355 #Note: validates all passed-in data; i.e. safe to use with unchecked CGI params.
 356 #sub
 357
 358 sub search_sql_where {
 359   my($class, $param) = @_;
 360   if ( $DEBUG ) {
 361     warn "$me search_sql_where called with params: \n".
 362          join("\n", map { "  $_: ". $param->{$_} } keys %$param ). "\n";
 363   }
 364
 365   my @search = $class->cust_search_sql($param);
 366
 367   #eventpart
 368   my @eventpart = ref($param->{'eventpart'})
 369                     ? @{ $param->{'eventpart'} }
 370                     : split(',', $param->{'eventpart'});
 371   @eventpart = grep /^(\d+)$/, @eventpart;
 372   if ( @eventpart ) {
 373     push @search, 'eventpart IN ('. join(',', @eventpart). ')';
 374   }
 375
 376   if ( $param->{'beginning'} =~ /^(\d+)$/ ) {
 377     push @search, "cust_event._date >= $1";
 378   }
 379   if ( $param->{'ending'} =~ /^(\d+)$/ ) {
 380     push @search, "cust_event._date <= $1";
 381   }
 382
 383   #if ( $param->{'failed'} ) {
 384   #  push @search, "statustext != ''",
 385   #                "statustext IS NOT NULL",
 386   #                "statustext != 'N/A'";
 387   #}
 388   # huh?
 389
 390   if ( $param->{'event_status'} ) {
 391
 392     my @status;
 393     my ($done_Y, $done_N);
 394     foreach (@{ $param->{'event_status'} }) {
 395       if ($_ eq 'done_Y') {
 396         $done_Y = 1;
 397       } elsif ( $_ eq 'done_N' ) {
 398         $done_N = 1;
 399       } else {
 400         push @status, $_;
 401       }
 402     }
 403     if ( $done_Y or $done_N ) {
 404       push @status, 'done';
 405     }
 406     if ( @status ) {
 407       push @search, "cust_event.status IN(" .
 408                     join(',', map "'$_'", @status) .
 409                     ')';
 410     }
 411
 412     if ( $done_Y and not $done_N ) {
 413       push @search, "cust_event.no_action IS NULL";
 414     } elsif ( $done_N and not $done_Y ) {
 415       push @search, "cust_event.no_action = 'Y'";
 416     } # else they're both true, so don't add a constraint, or both false,
 417       # and it doesn't matter.
 418
 419   } # event_status
 420
 421   # always hide initialization
 422   push @search, 'cust_event.status != \'initial\'';
 423
 424   if ( $param->{'custnum'} =~ /^(\d+)$/ ) {
 425     push @search, "cust_main.custnum = '$1'";
 426   }
 427
 428   if ( $param->{'invnum'} =~ /^(\d+)$/ ) {
 429     push @search, "part_event.eventtable = 'cust_bill'",
 430                   "tablenum = '$1'";
 431   }
 432
 433   if ( $param->{'pkgnum'} =~ /^(\d+)$/ ) {
 434     push @search, "part_event.eventtable = 'cust_pkg'",
 435                   "tablenum = '$1'";
 436   }
 437
 438   if ( $param->{'paynum'} =~ /^(\d+)$/ ) {
 439     push @search, "part_event.eventtable = 'cust_pay'",
 440                   "tablenum = '$1'";
 441   }
 442
 443   if ( $param->{'svcnum'} =~ /^(\d+)$/ ) {
 444     push @search, "part_event.eventtable = 'svc_acct'",
 445                   "tablenum = '$1'";
 446   }
 447
 448   my $where = 'WHERE '. join(' AND ', @search );
 449
 450   join(' AND ', @search );
 451
 452 }
 453
 454 =back
 455
 456 =head1 SUBROUTINES
 457
 458 =over 4
 459
 460 =item reprint
 461
 462 =cut
 463
 464 sub process_reprint {
 465   process_re_X('print', @_);
 466 }
 467
 468 =item reemail
 469
 470 =cut
 471
 472 sub process_reemail {
 473   process_re_X('email', @_);
 474 }
 475
 476 =item refax
 477
 478 =cut
 479
 480 sub process_refax {
 481   process_re_X('fax', @_);
 482 }
 483
 484 use Data::Dumper;
 485 sub process_re_X {
 486   my( $method, $job, $param ) = @_;
 487   warn Dumper($param) if $DEBUG;
 488
 489   re_X(
 490     $method,
 491     $param,
 492     $job,
 493   );
 494
 495 }
 496
 497 sub re_X {
 498   my($method, $param, $job) = @_;
 499
 500   my $search_sql = FS::cust_event->search_sql_where($param);
 501
 502   #maybe not...?  we do want the "re-" action to match the search more closely
 503   #            # yuck!  hardcoded *AND* sequential scans!
 504   #my $where = " WHERE action LIKE 'cust_bill_send%' ".
 505   #           ( $search_sql ? " AND $search_sql" : "" );
 506
 507   my $where = ( $search_sql ? " WHERE $search_sql" : "" );
 508
 509   my @cust_event = qsearch({
 510     'table'     => 'cust_event',
 511     'addl_from' => FS::cust_event->join_sql(),
 512     'hashref'   => {},
 513     'extra_sql' => $where,
 514   });
 515
 516   warn "$me re_X found ". scalar(@cust_event). " events\n"
 517     if $DEBUG;
 518
 519   my( $num, $last, $min_sec ) = (0, time, 5); #progresbar foo
 520   foreach my $cust_event ( @cust_event ) {
 521
 522     my $cust_X = $cust_event->cust_X; # cust_bill
 523     next unless $cust_X->can($method);
 524
 525     my $part_event = $cust_event->part_event;
 526     my $template = $part_event->templatename
 527                    || $cust_X->agent_template;
 528     my $modenum = $part_event->option('modenum') || '';
 529     my $invoice_from = $part_event->option('agent_invoice_from') || '';
 530     $cust_X->set('mode' => $modenum);
 531     $cust_X->$method( { template => $template,
 532                         modenum  => $modenum,
 533                         from     => $invoice_from,
 534                     } );
 535
 536     if ( $job ) { #progressbar foo
 537       $num++;
 538       if ( time - $min_sec > $last ) {
 539         my $error = $job->update_statustext(
 540           int( 100 * $num / scalar(@cust_event) )
 541         );
 542         die $error if $error;
 543         $last = time;
 544       }
 545     }
 546
 547   }
 548
 549   #this doesn't work, but it would be nice
 550   #if ( $job ) { #progressbar foo
 551   #  my $error = $job->update_statustext(
 552   #    scalar(@cust_event). " invoices re-${method}ed"
 553   #  );
 554   #  die $error if $error;
 555   #}
 556
 557 }
 558
 559 =back
 560
 561 =head1 SEE ALSO
 562
 563 L<FS::part_event>, L<FS::cust_bill>, L<FS::Record>, schema.html from the
 564 base documentation.
 565
 566 =cut
 567
 568 1;
 569