FS/FS/cust_credit.pm

   1 package FS::cust_credit;
   2 use base qw( FS::otaker_Mixin FS::cust_main_Mixin FS::reason_Mixin
   3              FS::Record );
   4
   5 use strict;
   6 use vars qw( $conf $unsuspendauto $me $DEBUG
   7              $otaker_upgrade_kludge $ignore_empty_reasonnum
   8            );
   9 use List::Util qw( min );
  10 use Date::Format;
  11 use FS::UID qw( dbh );
  12 use FS::Misc qw(send_email);
  13 use FS::Record qw( qsearch qsearchs dbdef );
  14 use FS::CurrentUser;
  15 use FS::cust_pkg;
  16 use FS::cust_refund;
  17 use FS::cust_credit_bill;
  18 use FS::part_pkg;
  19 use FS::reason_type;
  20 use FS::reason;
  21 use FS::cust_event;
  22 use FS::agent;
  23 use FS::sales;
  24 use FS::cust_credit_void;
  25 use FS::cust_bill_pkg;
  26 use FS::upgrade_journal;
  27
  28 $me = '[ FS::cust_credit ]';
  29 $DEBUG = 0;
  30
  31 $otaker_upgrade_kludge = 0;
  32 $ignore_empty_reasonnum = 0;
  33
  34 #ask FS::UID to run this stuff for us later
  35 $FS::UID::callback{'FS::cust_credit'} = sub {
  36
  37   $conf = new FS::Conf;
  38   $unsuspendauto = $conf->exists('unsuspendauto');
  39
  40 };
  41
  42 our %reasontype_map = ( 'referral_credit_type' => 'Referral Credit',
  43                         'cancel_credit_type'   => 'Cancellation Credit',
  44                         'signup_credit_type'   => 'Self-Service Credit',
  45                       );
  46
  47 =head1 NAME
  48
  49 FS::cust_credit - Object methods for cust_credit records
  50
  51 =head1 SYNOPSIS
  52
  53   use FS::cust_credit;
  54
  55   $record = new FS::cust_credit \%hash;
  56   $record = new FS::cust_credit { 'column' => 'value' };
  57
  58   $error = $record->insert;
  59
  60   $error = $new_record->replace($old_record);
  61
  62   $error = $record->delete;
  63
  64   $error = $record->check;
  65
  66 =head1 DESCRIPTION
  67
  68 An FS::cust_credit object represents a credit; the equivalent of a negative
  69 B<cust_bill> record (see L<FS::cust_bill>).  FS::cust_credit inherits from
  70 FS::Record.  The following fields are currently supported:
  71
  72 =over 4
  73
  74 =item crednum
  75
  76 Primary key (assigned automatically for new credits)
  77
  78 =item custnum
  79
  80 Customer (see L<FS::cust_main>)
  81
  82 =item amount
  83
  84 Amount of the credit
  85
  86 =item _date
  87
  88 Specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  89 L<Time::Local> and L<Date::Parse> for conversion functions.
  90
  91 =item usernum
  92
  93 Order taker (see L<FS::access_user>)
  94
  95 =item reason
  96
  97 Text ( deprecated )
  98
  99 =item reasonnum
 100
 101 Reason (see L<FS::reason>)
 102
 103 =item addlinfo
 104
 105 Text
 106
 107 =item closed
 108
 109 Books closed flag, empty or `Y'
 110
 111 =item pkgnum
 112
 113 Desired pkgnum when using experimental package balances.
 114
 115 =back
 116
 117 =head1 METHODS
 118
 119 =over 4
 120
 121 =item new HASHREF
 122
 123 Creates a new credit.  To add the credit to the database, see L<"insert">.
 124
 125 =cut
 126
 127 sub table { 'cust_credit'; }
 128 sub cust_linked { $_[0]->cust_main_custnum || $_[0]->custnum }
 129 sub cust_unlinked_msg {
 130   my $self = shift;
 131   "WARNING: can't find cust_main.custnum ". $self->custnum.
 132   ' (cust_credit.crednum '. $self->crednum. ')';
 133 }
 134
 135 =item insert [ OPTION => VALUE ... ]
 136
 137 Adds this credit to the database ("Posts" the credit).  If there is an error,
 138 returns the error, otherwise returns false.
 139
 140 Ooptions are passed as a list of keys and values.  Available options:
 141
 142 =over 4
 143
 144 =item reason_type
 145
 146 L<FS::reason_type|Reason> type for newly-inserted reason
 147
 148 =item cust_credit_source_bill_pkg
 149
 150 An arrayref of
 151 L<FS::cust_credit_source_bill_pkg|FS::cust_credit_source_bilL_pkg> objects.
 152 They will have their crednum set and will be inserted along with this credit.
 153
 154 =back
 155
 156 =cut
 157
 158 sub insert {
 159   my ($self, %options) = @_;
 160
 161   local $SIG{HUP} = 'IGNORE';
 162   local $SIG{INT} = 'IGNORE';
 163   local $SIG{QUIT} = 'IGNORE';
 164   local $SIG{TERM} = 'IGNORE';
 165   local $SIG{TSTP} = 'IGNORE';
 166   local $SIG{PIPE} = 'IGNORE';
 167
 168   my $oldAutoCommit = $FS::UID::AutoCommit;
 169   local $FS::UID::AutoCommit = 0;
 170   my $dbh = dbh;
 171
 172   my $cust_main = qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 173   my $old_balance = $cust_main->balance;
 174
 175   if (!$self->reasonnum) {
 176     my $reason_text = $self->get('reason')
 177       or return "reason text or existing reason required";
 178     my $reason_type = $options{'reason_type'}
 179       or return "reason type required";
 180
 181     local $@;
 182     my $reason = FS::reason->new_or_existing(
 183       reason => $reason_text,
 184       type   => $reason_type,
 185       class  => 'R',
 186     );
 187     if ($@) {
 188       $dbh->rollback if $oldAutoCommit;
 189       return "failed to set credit reason: $@";
 190     }
 191     $self->set('reasonnum', $reason->reasonnum);
 192   }
 193
 194   $self->setfield('reason', '');
 195
 196   my $error = $self->SUPER::insert;
 197   if ( $error ) {
 198     $dbh->rollback if $oldAutoCommit;
 199     return "error inserting $self: $error";
 200   }
 201
 202   if ( $options{'cust_credit_source_bill_pkg'} ) {
 203     foreach my $ccsbr ( @{ $options{'cust_credit_source_bill_pkg'} } ) {
 204       $ccsbr->crednum( $self->crednum );
 205       $error = $ccsbr->insert;
 206       if ( $error ) {
 207         $dbh->rollback if $oldAutoCommit;
 208         return "error inserting $ccsbr: $error";
 209       }
 210     }
 211   }
 212
 213   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 214
 215   #false laziness w/ cust_pay::insert
 216   if ( $unsuspendauto && $old_balance && $cust_main->balance <= 0 ) {
 217     my @errors = $cust_main->unsuspend;
 218     #return
 219     # side-fx with nested transactions?  upstack rolls back?
 220     warn "WARNING:Errors unsuspending customer ". $cust_main->custnum. ": ".
 221          join(' / ', @errors)
 222       if @errors;
 223   }
 224   #eslaf
 225
 226   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 227
 228   '';
 229
 230 }
 231
 232 =item delete
 233
 234 Unless the closed flag is set, deletes this credit and all associated
 235 applications (see L<FS::cust_credit_bill>).  In most cases, you want to use
 236 the void method instead to leave a record of the deleted credit.
 237
 238 =cut
 239
 240 # very similar to FS::cust_pay::delete
 241 sub delete {
 242   my $self = shift;
 243   my %opt = @_;
 244
 245   return "Can't delete closed credit" if $self->closed =~ /^Y/i;
 246
 247   local $SIG{HUP} = 'IGNORE';
 248   local $SIG{INT} = 'IGNORE';
 249   local $SIG{QUIT} = 'IGNORE';
 250   local $SIG{TERM} = 'IGNORE';
 251   local $SIG{TSTP} = 'IGNORE';
 252   local $SIG{PIPE} = 'IGNORE';
 253
 254   my $oldAutoCommit = $FS::UID::AutoCommit;
 255   local $FS::UID::AutoCommit = 0;
 256   my $dbh = dbh;
 257
 258   foreach my $cust_credit_bill ( $self->cust_credit_bill ) {
 259     my $error = $cust_credit_bill->delete;
 260     if ( $error ) {
 261       $dbh->rollback if $oldAutoCommit;
 262       return $error;
 263     }
 264   }
 265
 266   foreach my $cust_credit_refund ( $self->cust_credit_refund ) {
 267     my $error = $cust_credit_refund->delete;
 268     if ( $error ) {
 269       $dbh->rollback if $oldAutoCommit;
 270       return $error;
 271     }
 272   }
 273
 274   my $error = $self->SUPER::delete(@_);
 275   if ( $error ) {
 276     $dbh->rollback if $oldAutoCommit;
 277     return $error;
 278   }
 279
 280   if ( !$opt{void} and $conf->config('deletecredits') ne '' ) {
 281
 282     my $cust_main = $self->cust_main;
 283
 284     my $error = send_email(
 285       'from'    => $conf->invoice_from_full($self->cust_main->agentnum),
 286                                  #invoice_from??? well as good as any
 287       'to'      => $conf->config('deletecredits'),
 288       'subject' => 'FREESIDE NOTIFICATION: Credit deleted',
 289       'body'    => [
 290         "This is an automatic message from your Freeside installation\n",
 291         "informing you that the following credit has been deleted:\n",
 292         "\n",
 293         'crednum: '. $self->crednum. "\n",
 294         'custnum: '. $self->custnum.
 295           " (". $cust_main->last. ", ". $cust_main->first. ")\n",
 296         'amount: $'. sprintf("%.2f", $self->amount). "\n",
 297         'date: '. time2str("%a %b %e %T %Y", $self->_date). "\n",
 298         'reason: '. $self->reason. "\n",
 299       ],
 300     );
 301
 302     if ( $error ) {
 303       $dbh->rollback if $oldAutoCommit;
 304       return "can't send credit deletion notification: $error";
 305     }
 306
 307   }
 308
 309   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 310
 311   '';
 312
 313 }
 314
 315 =item replace [ OLD_RECORD ]
 316
 317 You can, but probably shouldn't modify credits...
 318
 319 Replaces the OLD_RECORD with this one in the database, or, if OLD_RECORD is not
 320 supplied, replaces this record.  If there is an error, returns the error,
 321 otherwise returns false.
 322
 323 =cut
 324
 325 sub replace {
 326   my $self = shift;
 327   return "Can't modify closed credit" if $self->closed =~ /^Y/i;
 328   $self->SUPER::replace(@_);
 329 }
 330
 331 =item check
 332
 333 Checks all fields to make sure this is a valid credit.  If there is an error,
 334 returns the error, otherwise returns false.  Called by the insert and replace
 335 methods.
 336
 337 =cut
 338
 339 sub check {
 340   my $self = shift;
 341
 342   $self->usernum($FS::CurrentUser::CurrentUser->usernum) unless $self->usernum;
 343
 344   my $error =
 345     $self->ut_numbern('crednum')
 346     || $self->ut_number('custnum')
 347     || $self->ut_numbern('_date')
 348     || $self->ut_money('amount')
 349     || $self->ut_alphan('otaker')
 350     || $self->ut_textn('reason')
 351     || $self->ut_textn('addlinfo')
 352     || $self->ut_enum('closed', [ '', 'Y' ])
 353     || $self->ut_foreign_keyn('pkgnum', 'cust_pkg', 'pkgnum')
 354     || $self->ut_foreign_keyn('eventnum', 'cust_event', 'eventnum')
 355     || $self->ut_foreign_keyn('commission_agentnum',  'agent', 'agentnum')
 356     || $self->ut_foreign_keyn('commission_salesnum',  'sales', 'salesnum')
 357     || $self->ut_foreign_keyn('commission_pkgnum', 'cust_pkg', 'pkgnum')
 358   ;
 359   return $error if $error;
 360
 361   my $method = $ignore_empty_reasonnum ? 'ut_foreign_keyn' : 'ut_foreign_key';
 362   $error = $self->$method('reasonnum', 'reason', 'reasonnum');
 363   return $error if $error;
 364
 365   return "amount must be > 0 " if $self->amount <= 0;
 366
 367   return "amount must be greater or equal to amount applied"
 368     if $self->unapplied < 0 && ! $otaker_upgrade_kludge;
 369
 370   return "Unknown customer"
 371     unless qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 372
 373   $self->_date(time) unless $self->_date;
 374
 375   $self->SUPER::check;
 376 }
 377
 378 =item void [ REASON ]
 379
 380 Voids this credit: deletes the credit and all associated applications and
 381 adds a record of the voided credit to the cust_credit_void table.
 382
 383 =cut
 384
 385 sub void {
 386   my $self = shift;
 387   my $reason = shift;
 388
 389   unless (ref($reason) || !$reason) {
 390     $reason = FS::reason->new_or_existing(
 391       'class'  => 'X',
 392       'type'   => 'Void credit',
 393       'reason' => $reason
 394     );
 395   }
 396
 397   local $SIG{HUP} = 'IGNORE';
 398   local $SIG{INT} = 'IGNORE';
 399   local $SIG{QUIT} = 'IGNORE';
 400   local $SIG{TERM} = 'IGNORE';
 401   local $SIG{TSTP} = 'IGNORE';
 402   local $SIG{PIPE} = 'IGNORE';
 403
 404   my $oldAutoCommit = $FS::UID::AutoCommit;
 405   local $FS::UID::AutoCommit = 0;
 406   my $dbh = dbh;
 407
 408   my $cust_credit_void = new FS::cust_credit_void ( {
 409       map { $_ => $self->get($_) } $self->fields
 410     } );
 411   $cust_credit_void->set('void_reasonnum', $reason->reasonnum);
 412   my $error = $cust_credit_void->insert;
 413   if ( $error ) {
 414     $dbh->rollback if $oldAutoCommit;
 415     return $error;
 416   }
 417
 418   $error = $self->delete(void => 1); # suppress deletecredits warning
 419   if ( $error ) {
 420     $dbh->rollback if $oldAutoCommit;
 421     return $error;
 422   }
 423
 424   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 425
 426   '';
 427
 428 }
 429
 430 =item cust_credit_refund
 431
 432 Returns all refund applications (see L<FS::cust_credit_refund>) for this credit.
 433
 434 =cut
 435
 436 sub cust_credit_refund {
 437   my $self = shift;
 438   map { $_ } #return $self->num_cust_credit_refund unless wantarray;
 439   sort { $a->_date <=> $b->_date }
 440     qsearch( 'cust_credit_refund', { 'crednum' => $self->crednum } )
 441   ;
 442 }
 443
 444 =item cust_credit_bill
 445
 446 Returns all application to invoices (see L<FS::cust_credit_bill>) for this
 447 credit.
 448
 449 =cut
 450
 451 sub cust_credit_bill {
 452   my $self = shift;
 453   map { $_ } #return $self->num_cust_credit_bill unless wantarray;
 454   sort { $a->_date <=> $b->_date }
 455     qsearch( 'cust_credit_bill', { 'crednum' => $self->crednum } )
 456   ;
 457 }
 458
 459 =item unapplied
 460
 461 Returns the amount of this credit that is still unapplied/outstanding;
 462 amount minus all refund applications (see L<FS::cust_credit_refund>) and
 463 applications to invoices (see L<FS::cust_credit_bill>).
 464
 465 =cut
 466
 467 sub unapplied {
 468   my $self = shift;
 469   my $amount = $self->amount;
 470   $amount -= $_->amount foreach ( $self->cust_credit_refund );
 471   $amount -= $_->amount foreach ( $self->cust_credit_bill );
 472   sprintf( "%.2f", $amount );
 473 }
 474
 475 =item credited
 476
 477 Deprecated name for the unapplied method.
 478
 479 =cut
 480
 481 sub credited {
 482   my $self = shift;
 483   #carp "cust_credit->credited deprecated; use ->unapplied";
 484   $self->unapplied(@_);
 485 }
 486
 487 =item cust_main
 488
 489 Returns the customer (see L<FS::cust_main>) for this credit.
 490
 491 =cut
 492
 493 # _upgrade_data
 494 #
 495 # Used by FS::Upgrade to migrate to a new database.
 496
 497 sub _upgrade_data {  # class method
 498   my ($class, %opts) = @_;
 499
 500   warn "$me upgrading $class\n" if $DEBUG;
 501
 502   $class->_upgrade_reasonnum(%opts);
 503
 504   if (defined dbdef->table($class->table)->column('reason')) {
 505
 506     warn "$me Ensuring existance of auto reasons\n" if $DEBUG;
 507
 508     foreach ( keys %reasontype_map ) {
 509       unless ($conf->config($_)) {       # hmmmm
 510 #       warn "$me Found $_ reason type lacking\n" if $DEBUG;
 511 #       my $hashref = { 'class' => 'R', 'type' => $reasontype_map{$_} };
 512         my $hashref = { 'class' => 'R', 'type' => 'Legacy' };
 513         my $reason_type = qsearchs( 'reason_type', $hashref );
 514         unless ($reason_type) {
 515           $reason_type  = new FS::reason_type( $hashref );
 516           my $error   = $reason_type->insert();
 517           die "$class had error inserting FS::reason_type into database: $error\n"
 518             if $error;
 519         }
 520         $conf->set($_, $reason_type->typenum);
 521       }
 522     }
 523
 524     warn "$me Ensuring commission packages have a reason type\n" if $DEBUG;
 525
 526     my $hashref = { 'class' => 'R', 'type' => 'Legacy' };
 527     my $reason_type = qsearchs( 'reason_type', $hashref );
 528     unless ($reason_type) {
 529       $reason_type  = new FS::reason_type( $hashref );
 530       my $error   = $reason_type->insert();
 531       die "$class had error inserting FS::reason_type into database: $error\n"
 532         if $error;
 533     }
 534
 535     my @plans = qw( flat_comission flat_comission_cust flat_comission_pkg );
 536     foreach my $plan ( @plans ) {
 537       foreach my $pkg ( qsearch('part_pkg', { 'plan' => $plan } ) ) {
 538         unless ($pkg->option('reason_type', 1) ) {
 539           my $plandata = $pkg->plandata.
 540                         "reason_type=". $reason_type->typenum. "\n";
 541           $pkg->plandata($plandata);
 542           my $error =
 543             $pkg->replace( undef,
 544                            'pkg_svc' => { map { $_->svcpart => $_->quantity }
 545                                           $pkg->pkg_svc
 546                                         },
 547                            'primary_svc' => $pkg->svcpart,
 548                          );
 549             die "failed setting reason_type option: $error"
 550               if $error;
 551         }
 552       }
 553     }
 554   }
 555
 556   local($otaker_upgrade_kludge) = 1;
 557   local($ignore_empty_reasonnum) = 1;
 558   $class->_upgrade_otaker(%opts);
 559
 560   if ( !FS::upgrade_journal->is_done('cust_credit__tax_link')
 561       and !$conf->config('tax_data_vendor') ) {
 562     # RT#25458: fix credit line item applications that should refer to a
 563     # specific tax allocation
 564     my @cust_credit_bill_pkg = qsearch({
 565         table     => 'cust_credit_bill_pkg',
 566         select    => 'cust_credit_bill_pkg.*',
 567         addl_from => ' LEFT JOIN cust_bill_pkg USING (billpkgnum)',
 568         extra_sql =>
 569           'WHERE cust_credit_bill_pkg.billpkgtaxlocationnum IS NULL '.
 570           'AND cust_bill_pkg.pkgnum = 0', # is a tax
 571     });
 572     my %tax_items;
 573     my %credits;
 574     foreach (@cust_credit_bill_pkg) {
 575       my $billpkgnum = $_->billpkgnum;
 576       $tax_items{$billpkgnum} ||= FS::cust_bill_pkg->by_key($billpkgnum);
 577       $credits{$billpkgnum} ||= [];
 578       push @{ $credits{$billpkgnum} }, $_;
 579     }
 580     TAX_ITEM: foreach my $tax_item (values %tax_items) {
 581       my $billpkgnum = $tax_item->billpkgnum;
 582       # get all pkg/location/taxrate allocations of this tax line item
 583       my @allocations = sort {$b->amount <=> $a->amount}
 584                         qsearch('cust_bill_pkg_tax_location', {
 585                             billpkgnum => $billpkgnum
 586                         });
 587       # and these are all credit applications to it
 588       my @credits = sort {$b->amount <=> $a->amount}
 589                     @{ $credits{$billpkgnum} };
 590       my $c = shift @credits;
 591       my $a = shift @allocations; # we will NOT modify these
 592       while ($c and $a) {
 593         if ( abs($c->amount - $a->amount) < 0.005 ) {
 594           # by far the most common case: the tax line item is for a single
 595           # tax, so we just fill in the billpkgtaxlocationnum
 596           $c->set('billpkgtaxlocationnum', $a->billpkgtaxlocationnum);
 597           my $error = $c->replace;
 598           if ($error) {
 599             warn "error fixing credit application to tax item #$billpkgnum:\n$error\n";
 600             next TAX_ITEM;
 601           }
 602           $c = shift @credits;
 603           $a = shift @allocations;
 604         } elsif ( $c->amount > $a->amount ) {
 605           # fairly common: the tax line contains tax for multiple packages
 606           # (or multiple taxes) but the credit isn't divided up
 607           my $new_link = FS::cust_credit_bill_pkg->new({
 608               creditbillnum         => $c->creditbillnum,
 609               billpkgnum            => $c->billpkgnum,
 610               billpkgtaxlocationnum => $a->billpkgtaxlocationnum,
 611               amount                => $a->amount,
 612               setuprecur            => 'setup',
 613           });
 614           my $error = $new_link->insert;
 615           if ($error) {
 616             warn "error fixing credit application to tax item #$billpkgnum:\n$error\n";
 617             next TAX_ITEM;
 618           }
 619           $c->set(amount => sprintf('%.2f', $c->amount - $a->amount));
 620           $a = shift @allocations;
 621         } elsif ( $c->amount < 0.005 ) {
 622           # also fairly common; we can delete these with no harm
 623           my $error = $c->delete;
 624           warn "error removing zero-amount credit application (probably harmless):\n$error\n" if $error;
 625           $c = shift @credits;
 626         } elsif ( $c->amount < $a->amount ) {
 627           # should never happen, but if it does, handle it gracefully
 628           $c->set('billpkgtaxlocationnum', $a->billpkgtaxlocationnum);
 629           my $error = $c->replace;
 630           if ($error) {
 631             warn "error fixing credit application to tax item #$billpkgnum:\n$error\n";
 632             next TAX_ITEM;
 633           }
 634           $a->set(amount => $a->amount - $c->amount);
 635           $c = shift @credits;
 636         }
 637       } # while $c and $a
 638       if ( $c ) {
 639         if ( $c->amount < 0.005 ) {
 640           my $error = $c->delete;
 641           warn "error removing zero-amount credit application (probably harmless):\n$error\n" if $error;
 642         } elsif ( $c->modified ) {
 643           # then we've allocated part of it, so reduce the nonspecific
 644           # application by that much
 645           my $error = $c->replace;
 646           warn "error fixing credit application to tax item #$billpkgnum:\n$error\n" if $error;
 647         }
 648         # else there are probably no allocations, i.e. this is a pre-3.x
 649         # record that was never migrated over, so leave it alone
 650       } # if $c
 651     } # foreach $tax_item
 652     FS::upgrade_journal->set_done('cust_credit__tax_link');
 653   }
 654 }
 655
 656 =back
 657
 658 =head1 CLASS METHODS
 659
 660 =over 4
 661
 662 =item unapplied_sql
 663
 664 Returns an SQL fragment to retreive the unapplied amount.
 665
 666 =cut
 667
 668 sub unapplied_sql {
 669   my ($class, $start, $end) = @_;
 670
 671   my $bill_start   = $start ? "AND cust_credit_bill._date <= $start"   : '';
 672   my $bill_end     = $end   ? "AND cust_credit_bill._date > $end"     : '';
 673   my $refund_start = $start ? "AND cust_credit_refund._date <= $start" : '';
 674   my $refund_end   = $end   ? "AND cust_credit_refund._date > $end"   : '';
 675
 676   "amount
 677         - COALESCE(
 678                     ( SELECT SUM(amount) FROM cust_credit_refund
 679                         WHERE cust_credit.crednum = cust_credit_refund.crednum
 680                         $refund_start $refund_end )
 681                     ,0
 682                   )
 683         - COALESCE(
 684                     ( SELECT SUM(amount) FROM cust_credit_bill
 685                         WHERE cust_credit.crednum = cust_credit_bill.crednum
 686                         $bill_start $bill_end )
 687                     ,0
 688                   )
 689   ";
 690
 691 }
 692
 693 =item credited_sql
 694
 695 Deprecated name for the unapplied_sql method.
 696
 697 =cut
 698
 699 sub credited_sql {
 700   #my $class = shift;
 701
 702   #carp "cust_credit->credited_sql deprecated; use ->unapplied_sql";
 703
 704   #$class->unapplied_sql(@_);
 705   unapplied_sql();
 706 }
 707
 708 =item calculate_tax_adjustment PARAMS
 709
 710 Calculate the amount of tax that needs to be credited as part of a lineitem
 711 credit.
 712
 713 PARAMS must include:
 714
 715 - billpkgnums: arrayref identifying the line items to credit
 716 - setuprecurs: arrayref of 'setup' or 'recur', indicating which part of
 717   the lineitem charge is being credited
 718 - amounts: arrayref of the amounts to credit on each line item
 719 - custnum: the customer all of these invoices belong to, for error checking
 720
 721 Returns a hash containing:
 722 - subtotal: the total non-tax amount to be credited (the sum of the 'amounts')
 723 - taxtotal: the total tax amount to be credited
 724 - taxlines: an arrayref of hashrefs for each tax line to be credited, each with:
 725   - table: "cust_bill_pkg_tax_location" or "cust_bill_pkg_tax_rate_location"
 726   - num: the key within that table
 727   - credit: the credit amount to apply to that line
 728
 729 =cut
 730
 731 sub calculate_tax_adjustment {
 732   my ($class, %arg) = @_;
 733
 734   my $error;
 735   my @taxlines;
 736   my $subtotal = 0;
 737   my $taxtotal = 0;
 738
 739   my (%cust_bill_pkg, %cust_bill);
 740
 741   for (my $i = 0; ; $i++) {
 742     my $billpkgnum = $arg{billpkgnums}[$i]
 743       or last;
 744     my $setuprecur = $arg{setuprecurs}[$i];
 745     my $amount = $arg{amounts}[$i];
 746     next if $amount == 0;
 747     $subtotal += $amount;
 748     my $cust_bill_pkg = $cust_bill_pkg{$billpkgnum}
 749                     ||= FS::cust_bill_pkg->by_key($billpkgnum)
 750       or die "lineitem #$billpkgnum not found\n";
 751
 752     my $invnum = $cust_bill_pkg->invnum;
 753     $cust_bill{ $invnum } ||= FS::cust_bill->by_key($invnum);
 754     $cust_bill{ $invnum}->custnum == $arg{custnum}
 755       or die "lineitem #$billpkgnum not found\n";
 756
 757     # calculate credit ratio.
 758     # (First deduct any existing credits applied to this line item, to avoid
 759     # rounding errors.)
 760     my $charged = $cust_bill_pkg->get($setuprecur);
 761     my $previously_credited =
 762       $cust_bill_pkg->credited( '', '', setuprecur => $setuprecur) || 0;
 763
 764     $charged -= $previously_credited;
 765     if ($charged < $amount) {
 766       $error = "invoice #$invnum: tried to credit $amount, but only $charged was charged";
 767       last;
 768     }
 769     my $ratio = $amount / $charged;
 770
 771     # gather taxes that apply to the selected item
 772     foreach my $table (
 773       qw(cust_bill_pkg_tax_location cust_bill_pkg_tax_rate_location)
 774     ) {
 775       foreach my $tax_link (
 776         qsearch($table, { taxable_billpkgnum => $billpkgnum })
 777       ) {
 778         my $tax_amount = $tax_link->amount;
 779         # deduct existing credits applied to the tax, for the same reason as
 780         # above
 781         foreach ($tax_link->cust_credit_bill_pkg) {
 782           $tax_amount -= $_->amount;
 783         }
 784         my $tax_credit = sprintf('%.2f', $tax_amount * $ratio);
 785         my $pkey = $tax_link->get($tax_link->primary_key);
 786         push @taxlines, {
 787           table   => $table,
 788           num     => $pkey,
 789           credit  => $tax_credit,
 790         };
 791         $taxtotal += $tax_credit;
 792
 793       } #foreach cust_bill_pkg_tax_(rate_)?location
 794     }
 795   } # foreach $billpkgnum
 796
 797   return (
 798     subtotal => sprintf('%.2f', $subtotal),
 799     taxtotal => sprintf('%.2f', $taxtotal),
 800     taxlines => \@taxlines,
 801   );
 802 }
 803
 804 =item credit_lineitems
 805
 806 Example:
 807
 808   my $error = FS::cust_credit->credit_lineitems(
 809
 810     #the lineitems to credit
 811     'billpkgnums'       => \@billpkgnums,
 812     'setuprecurs'       => \@setuprecurs,
 813     'amounts'           => \@amounts,
 814     'apply'             => 1, #0 leaves the credit unapplied
 815
 816     #the credit
 817     map { $_ => scalar($cgi->param($_)) }
 818       #fields('cust_credit')
 819       qw( custnum _date amount reasonnum addlinfo ), #pkgnum eventnum
 820
 821   );
 822
 823 =cut
 824
 825 #maybe i should just be an insert with extra args instead of a class method
 826 sub credit_lineitems {
 827   my( $class, %arg ) = @_;
 828   my $curuser = $FS::CurrentUser::CurrentUser;
 829
 830   #some false laziness w/misc/xmlhttp-cust_bill_pkg-calculate_taxes.html
 831
 832   my $cust_main = qsearchs({
 833     'table'     => 'cust_main',
 834     'hashref'   => { 'custnum' => $arg{custnum} },
 835     'extra_sql' => ' AND '. $curuser->agentnums_sql,
 836   }) or return 'unknown customer';
 837
 838
 839   local $SIG{HUP} = 'IGNORE';
 840   local $SIG{INT} = 'IGNORE';
 841   local $SIG{QUIT} = 'IGNORE';
 842   local $SIG{TERM} = 'IGNORE';
 843   local $SIG{TSTP} = 'IGNORE';
 844   local $SIG{PIPE} = 'IGNORE';
 845
 846   my $oldAutoCommit = $FS::UID::AutoCommit;
 847   local $FS::UID::AutoCommit = 0;
 848   my $dbh = dbh;
 849
 850   #my @cust_bill_pkg = qsearch({
 851   #  'select'    => 'cust_bill_pkg.*',
 852   #  'table'     => 'cust_bill_pkg',
 853   #  'addl_from' => ' LEFT JOIN cust_bill USING (invnum)  '.
 854   #                 ' LEFT JOIN cust_main USING (custnum) ',
 855   #  'extra_sql' => ' WHERE custnum = $custnum AND billpkgnum IN ('.
 856   #                     join( ',', @{$arg{billpkgnums}} ). ')',
 857   #  'order_by'  => 'ORDER BY invnum ASC, billpkgnum ASC',
 858   #});
 859
 860   my $error = '';
 861
 862   my $cust_credit = new FS::cust_credit ( {
 863     map { $_ => $arg{$_} }
 864       #fields('cust_credit')
 865       qw( custnum _date amount reasonnum addlinfo ), #pkgnum eventnum
 866   } );
 867   $error = $cust_credit->insert;
 868   if ( $error ) {
 869     $dbh->rollback if $oldAutoCommit;
 870     return "Error inserting credit: $error";
 871   }
 872
 873   unless ( $arg{'apply'} ) {
 874     $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 875     return '';
 876   }
 877
 878   #my $subtotal = 0;
 879   # keys in all of these are invoice numbers
 880   my %cust_credit_bill = ();
 881   my %cust_bill_pkg = ();
 882   my %cust_credit_bill_pkg = ();
 883   my %unapplied_payments = (); #invoice numbers, and then billpaynums
 884
 885   # determine the tax adjustments
 886   my %tax_adjust = $class->calculate_tax_adjustment(%arg);
 887
 888   foreach my $billpkgnum ( @{$arg{billpkgnums}} ) {
 889     my $setuprecur = shift @{$arg{setuprecurs}};
 890     my $amount = shift @{$arg{amounts}};
 891
 892     my $cust_bill_pkg = qsearchs({
 893       'table'     => 'cust_bill_pkg',
 894       'hashref'   => { 'billpkgnum' => $billpkgnum },
 895       'addl_from' => 'LEFT JOIN cust_bill USING (invnum)',
 896       'extra_sql' => 'AND custnum = '. $cust_main->custnum,
 897     }) or die "unknown billpkgnum $billpkgnum";
 898
 899     my $invnum = $cust_bill_pkg->invnum;
 900
 901     push @{$cust_bill_pkg{$invnum}}, $cust_bill_pkg;
 902
 903     $cust_credit_bill{$invnum} += $amount;
 904     push @{ $cust_credit_bill_pkg{$invnum} },
 905       new FS::cust_credit_bill_pkg {
 906         'billpkgnum' => $billpkgnum,
 907         'amount'     => sprintf('%.2f',$amount),
 908         'setuprecur' => $setuprecur,
 909         'sdate'      => $cust_bill_pkg->sdate,
 910         'edate'      => $cust_bill_pkg->edate,
 911       };
 912     # unapply payments (but not other credits) from this line item
 913     foreach my $cust_bill_pay_pkg (
 914       $cust_bill_pkg->cust_bill_pay_pkg($setuprecur)
 915     ) {
 916       $error = $cust_bill_pay_pkg->delete;
 917       if ( $error ) {
 918         $dbh->rollback if $oldAutoCommit;
 919         return "Error unapplying payment: $error";
 920       }
 921       $unapplied_payments{$invnum}{$cust_bill_pay_pkg->billpaynum}
 922         += $cust_bill_pay_pkg->amount;
 923     }
 924   }
 925
 926   # do the same for taxes
 927   foreach my $tax_credit ( @{ $tax_adjust{taxlines} } ) {
 928     my $table = $tax_credit->{table};
 929     my $tax_link = "FS::$table"->by_key( $tax_credit->{num} )
 930       or die "tried to credit $table #$tax_credit->{num} but it doesn't exist";
 931
 932     my $billpkgnum = $tax_link->billpkgnum;
 933     my $cust_bill_pkg = qsearchs({
 934       'table'     => 'cust_bill_pkg',
 935       'hashref'   => { 'billpkgnum' => $billpkgnum },
 936       'addl_from' => 'LEFT JOIN cust_bill USING (invnum)',
 937       'extra_sql' => 'AND custnum = '. $cust_main->custnum,
 938     }) or die "unknown billpkgnum $billpkgnum";
 939
 940     my $invnum = $cust_bill_pkg->invnum;
 941     push @{$cust_bill_pkg{$invnum}}, $cust_bill_pkg;
 942
 943     my $amount = $tax_credit->{credit};
 944     $cust_credit_bill{$invnum} += $amount;
 945
 946     # create a credit application record to the tax line item, earmarked
 947     # to the specific cust_bill_pkg_Xlocation
 948     push @{ $cust_credit_bill_pkg{$invnum} },
 949       new FS::cust_credit_bill_pkg {
 950         'billpkgnum' => $billpkgnum,
 951         'amount'     => sprintf('%.2f', $amount),
 952         'setuprecur' => 'setup',
 953         $tax_link->primary_key, $tax_credit->{num}
 954       };
 955     # unapply any payments from the tax
 956     foreach my $cust_bill_pay_pkg (
 957       $cust_bill_pkg->cust_bill_pay_pkg('setup')
 958     ) {
 959       $error = $cust_bill_pay_pkg->delete;
 960       if ( $error ) {
 961         $dbh->rollback if $oldAutoCommit;
 962         return "Error unapplying payment: $error";
 963       }
 964       $unapplied_payments{$invnum}{$cust_bill_pay_pkg->billpaynum}
 965         += $cust_bill_pay_pkg->amount;
 966     }
 967   }
 968
 969   ###
 970   # now loop through %cust_credit_bill and insert those
 971   ###
 972
 973   # (hack to prevent cust_credit_bill_pkg insertion)
 974   local($FS::cust_bill_ApplicationCommon::skip_apply_to_lineitems_hack) = 1;
 975
 976   foreach my $invnum ( sort { $a <=> $b } keys %cust_credit_bill ) {
 977
 978     # if we unapplied any payments from line items, also unapply that
 979     # amount from the invoice
 980     foreach my $billpaynum (keys %{$unapplied_payments{$invnum}}) {
 981       my $cust_bill_pay = FS::cust_bill_pay->by_key($billpaynum)
 982         or die "broken payment application $billpaynum";
 983       my @subapps = $cust_bill_pay->lineitem_applications;
 984       $error = $cust_bill_pay->delete; # can't replace
 985
 986       my $new_cust_bill_pay = FS::cust_bill_pay->new({
 987           $cust_bill_pay->hash,
 988           billpaynum => '',
 989           amount => sprintf('%.2f',
 990               $cust_bill_pay->amount
 991               - $unapplied_payments{$invnum}{$billpaynum}),
 992       });
 993
 994       if ( $new_cust_bill_pay->amount > 0 ) {
 995         $error ||= $new_cust_bill_pay->insert;
 996         # Also reapply it to everything it was applied to before.
 997         # Note that we've already deleted cust_bill_pay_pkg records for the
 998         # items we're crediting, so they aren't on this list.
 999         foreach my $cust_bill_pay_pkg (@subapps) {
1000           $cust_bill_pay_pkg->billpaypkgnum('');
1001           $cust_bill_pay_pkg->billpaynum($new_cust_bill_pay->billpaynum);
1002           $error ||= $cust_bill_pay_pkg->insert;
1003         }
1004       }
1005       if ( $error ) {
1006         $dbh->rollback if $oldAutoCommit;
1007         return "Error unapplying payment: $error";
1008       }
1009     }
1010     #insert cust_credit_bill
1011
1012     my $cust_credit_bill = new FS::cust_credit_bill {
1013       'crednum' => $cust_credit->crednum,
1014       'invnum'  => $invnum,
1015       'amount'  => sprintf('%.2f', $cust_credit_bill{$invnum}),
1016     };
1017     $error = $cust_credit_bill->insert;
1018     if ( $error ) {
1019       $dbh->rollback if $oldAutoCommit;
1020       return "Error applying credit of $cust_credit_bill{$invnum} ".
1021              " to invoice $invnum: $error";
1022     }
1023
1024     #and then insert cust_credit_bill_pkg for each cust_bill_pkg
1025     foreach my $cust_credit_bill_pkg ( @{$cust_credit_bill_pkg{$invnum}} ) {
1026       $cust_credit_bill_pkg->creditbillnum( $cust_credit_bill->creditbillnum );
1027       $error = $cust_credit_bill_pkg->insert;
1028       if ( $error ) {
1029         $dbh->rollback if $oldAutoCommit;
1030         return "Error applying credit to line item: $error";
1031       }
1032     }
1033
1034   }
1035
1036   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
1037   '';
1038
1039 }
1040
1041 =back
1042
1043 =head1 SUBROUTINES
1044
1045 =over 4
1046
1047 =item process_batch_import
1048
1049 =cut
1050
1051 use List::Util qw( min );
1052 use FS::cust_bill;
1053 use FS::cust_credit_bill;
1054 sub process_batch_import {
1055   my $job = shift;
1056
1057   my $opt = { 'table'   => 'cust_credit',
1058               'params'  => [ '_date', 'credbatch' ],
1059               'formats' => { 'simple' =>
1060                                [ 'custnum', 'amount', 'reasonnum', 'invnum' ],
1061                            },
1062               'default_csv' => 1,
1063               'postinsert_callback' => sub {
1064                 my $cust_credit = shift; #my ($cust_credit, $param ) = @_;
1065
1066                 if ( $cust_credit->invnum ) {
1067
1068                   my $cust_bill = qsearchs('cust_bill', { invnum=>$cust_credit->invnum } );
1069                   my $amount = min( $cust_credit->credited, $cust_bill->owed );
1070
1071                   my $cust_credit_bill = new FS::cust_credit_bill ( {
1072                     'crednum' => $cust_credit->crednum,
1073                     'invnum'  => $cust_bill->invnum,
1074                     'amount'  => $amount,
1075                   } );
1076                   my $error = $cust_credit_bill->insert;
1077                   return '' unless $error;
1078
1079                 }
1080
1081                 #apply_payments_and_credits ?
1082                 $cust_credit->cust_main->apply_credits;
1083
1084                 return '';
1085
1086               },
1087             };
1088
1089   FS::Record::process_batch_import( $job, $opt, @_ );
1090
1091 }
1092
1093 =back
1094
1095 =head1 BUGS
1096
1097 The delete method.  The replace method.
1098
1099 B<credited> and B<credited_sql> are now called B<unapplied> and
1100 B<unapplied_sql>.  The old method names should start to give warnings.
1101
1102 =head1 SEE ALSO
1103
1104 L<FS::Record>, L<FS::cust_credit_refund>, L<FS::cust_refund>,
1105 L<FS::cust_credit_bill> L<FS::cust_bill>, schema.html from the base
1106 documentation.
1107
1108 =cut
1109
1110 1;
1111