FS/FS/cust_bill.pm

   1 package FS::cust_bill;
   2
   3 use strict;
   4 use vars qw( @ISA $conf $money_char );
   5 use vars qw( $lpr $invoice_from $smtpmachine );
   6 use vars qw( $processor );
   7 use vars qw( $xaction $E_NoErr );
   8 use vars qw( $bop_processor $bop_login $bop_password $bop_action @bop_options );
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use Date::Format;
  11 use Mail::Internet;
  12 use Mail::Header;
  13 use Text::Template;
  14 use FS::Record qw( qsearch qsearchs );
  15 use FS::cust_main;
  16 use FS::cust_bill_pkg;
  17 use FS::cust_credit;
  18 use FS::cust_pay;
  19 use FS::cust_pkg;
  20 use FS::cust_credit_bill;
  21 use FS::cust_pay_batch;
  22 use FS::cust_bill_event;
  23
  24 @ISA = qw( FS::Record );
  25
  26 #ask FS::UID to run this stuff for us later
  27 $FS::UID::callback{'FS::cust_bill'} = sub {
  28
  29   $conf = new FS::Conf;
  30
  31   $money_char = $conf->config('money_char') || '$';
  32
  33   $lpr = $conf->config('lpr');
  34   $invoice_from = $conf->config('invoice_from');
  35   $smtpmachine = $conf->config('smtpmachine');
  36
  37   if ( $conf->exists('cybercash3.2') ) {
  38     require CCMckLib3_2;
  39       #qw($MCKversion %Config InitConfig CCError CCDebug CCDebug2);
  40     require CCMckDirectLib3_2;
  41       #qw(SendCC2_1Server);
  42     require CCMckErrno3_2;
  43       #qw(MCKGetErrorMessage $E_NoErr);
  44     import CCMckErrno3_2 qw($E_NoErr);
  45
  46     my $merchant_conf;
  47     ($merchant_conf,$xaction)= $conf->config('cybercash3.2');
  48     my $status = &CCMckLib3_2::InitConfig($merchant_conf);
  49     if ( $status != $E_NoErr ) {
  50       warn "CCMckLib3_2::InitConfig error:\n";
  51       foreach my $key (keys %CCMckLib3_2::Config) {
  52         warn "  $key => $CCMckLib3_2::Config{$key}\n"
  53       }
  54       my($errmsg) = &CCMckErrno3_2::MCKGetErrorMessage($status);
  55       die "CCMckLib3_2::InitConfig fatal error: $errmsg\n";
  56     }
  57     $processor='cybercash3.2';
  58   } elsif ( $conf->exists('business-onlinepayment') ) {
  59     ( $bop_processor,
  60       $bop_login,
  61       $bop_password,
  62       $bop_action,
  63       @bop_options
  64     ) = $conf->config('business-onlinepayment');
  65     $bop_action ||= 'normal authorization';
  66     eval "use Business::OnlinePayment";
  67     $processor="Business::OnlinePayment::$bop_processor";
  68   }
  69
  70 };
  71
  72 =head1 NAME
  73
  74 FS::cust_bill - Object methods for cust_bill records
  75
  76 =head1 SYNOPSIS
  77
  78   use FS::cust_bill;
  79
  80   $record = new FS::cust_bill \%hash;
  81   $record = new FS::cust_bill { 'column' => 'value' };
  82
  83   $error = $record->insert;
  84
  85   $error = $new_record->replace($old_record);
  86
  87   $error = $record->delete;
  88
  89   $error = $record->check;
  90
  91   ( $total_previous_balance, @previous_cust_bill ) = $record->previous;
  92
  93   @cust_bill_pkg_objects = $cust_bill->cust_bill_pkg;
  94
  95   ( $total_previous_credits, @previous_cust_credit ) = $record->cust_credit;
  96
  97   @cust_pay_objects = $cust_bill->cust_pay;
  98
  99   $tax_amount = $record->tax;
 100
 101   @lines = $cust_bill->print_text;
 102   @lines = $cust_bill->print_text $time;
 103
 104 =head1 DESCRIPTION
 105
 106 An FS::cust_bill object represents an invoice; a declaration that a customer
 107 owes you money.  The specific charges are itemized as B<cust_bill_pkg> records
 108 (see L<FS::cust_bill_pkg>).  FS::cust_bill inherits from FS::Record.  The
 109 following fields are currently supported:
 110
 111 =over 4
 112
 113 =item invnum - primary key (assigned automatically for new invoices)
 114
 115 =item custnum - customer (see L<FS::cust_main>)
 116
 117 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 118 L<Time::Local> and L<Date::Parse> for conversion functions.
 119
 120 =item charged - amount of this invoice
 121
 122 =item printed - deprecated
 123
 124 =item closed - books closed flag, empty or `Y'
 125
 126 =back
 127
 128 =head1 METHODS
 129
 130 =over 4
 131
 132 =item new HASHREF
 133
 134 Creates a new invoice.  To add the invoice to the database, see L<"insert">.
 135 Invoices are normally created by calling the bill method of a customer object
 136 (see L<FS::cust_main>).
 137
 138 =cut
 139
 140 sub table { 'cust_bill'; }
 141
 142 =item insert
 143
 144 Adds this invoice to the database ("Posts" the invoice).  If there is an error,
 145 returns the error, otherwise returns false.
 146
 147 =item delete
 148
 149 Currently unimplemented.  I don't remove invoices because there would then be
 150 no record you ever posted this invoice (which is bad, no?)
 151
 152 =cut
 153
 154 sub delete {
 155   my $self = shift;
 156   return "Can't delete closed invoice" if $self->closed =~ /^Y/i;
 157   $self->SUPER::delete(@_);
 158 }
 159
 160 =item replace OLD_RECORD
 161
 162 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 163 returns the error, otherwise returns false.
 164
 165 Only printed may be changed.  printed is normally updated by calling the
 166 collect method of a customer object (see L<FS::cust_main>).
 167
 168 =cut
 169
 170 sub replace {
 171   my( $new, $old ) = ( shift, shift );
 172   return "Can't change custnum!" unless $old->custnum == $new->custnum;
 173   #return "Can't change _date!" unless $old->_date eq $new->_date;
 174   return "Can't change _date!" unless $old->_date == $new->_date;
 175   return "Can't change charged!" unless $old->charged == $new->charged;
 176
 177   $new->SUPER::replace($old);
 178 }
 179
 180 =item check
 181
 182 Checks all fields to make sure this is a valid invoice.  If there is an error,
 183 returns the error, otherwise returns false.  Called by the insert and replace
 184 methods.
 185
 186 =cut
 187
 188 sub check {
 189   my $self = shift;
 190
 191   my $error =
 192     $self->ut_numbern('invnum')
 193     || $self->ut_number('custnum')
 194     || $self->ut_numbern('_date')
 195     || $self->ut_money('charged')
 196     || $self->ut_numbern('printed')
 197     || $self->ut_enum('closed', [ '', 'Y' ])
 198   ;
 199   return $error if $error;
 200
 201   return "Unknown customer"
 202     unless qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 203
 204   $self->_date(time) unless $self->_date;
 205
 206   $self->printed(0) if $self->printed eq '';
 207
 208   ''; #no error
 209 }
 210
 211 =item previous
 212
 213 Returns a list consisting of the total previous balance for this customer,
 214 followed by the previous outstanding invoices (as FS::cust_bill objects also).
 215
 216 =cut
 217
 218 sub previous {
 219   my $self = shift;
 220   my $total = 0;
 221   my @cust_bill = sort { $a->_date <=> $b->_date }
 222     grep { $_->owed != 0 && $_->_date < $self->_date }
 223       qsearch( 'cust_bill', { 'custnum' => $self->custnum } )
 224   ;
 225   foreach ( @cust_bill ) { $total += $_->owed; }
 226   $total, @cust_bill;
 227 }
 228
 229 =item cust_bill_pkg
 230
 231 Returns the line items (see L<FS::cust_bill_pkg>) for this invoice.
 232
 233 =cut
 234
 235 sub cust_bill_pkg {
 236   my $self = shift;
 237   qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum } );
 238 }
 239
 240 =item cust_bill_event
 241
 242 Returns the completed invoice events (see L<FS::cust_bill_event>) for this
 243 invoice.
 244
 245 =cut
 246
 247 sub cust_bill_event {
 248   my $self = shift;
 249   qsearch( 'cust_bill_event', { 'invnum' => $self->invnum } );
 250 }
 251
 252
 253 =item cust_main
 254
 255 Returns the customer (see L<FS::cust_main>) for this invoice.
 256
 257 =cut
 258
 259 sub cust_main {
 260   my $self = shift;
 261   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 262 }
 263
 264 =item cust_credit
 265
 266 Depreciated.  See the cust_credited method.
 267
 268  #Returns a list consisting of the total previous credited (see
 269  #L<FS::cust_credit>) and unapplied for this customer, followed by the previous
 270  #outstanding credits (FS::cust_credit objects).
 271
 272 =cut
 273
 274 sub cust_credit {
 275   use Carp;
 276   croak "FS::cust_bill->cust_credit depreciated; see ".
 277         "FS::cust_bill->cust_credit_bill";
 278   #my $self = shift;
 279   #my $total = 0;
 280   #my @cust_credit = sort { $a->_date <=> $b->_date }
 281   #  grep { $_->credited != 0 && $_->_date < $self->_date }
 282   #    qsearch('cust_credit', { 'custnum' => $self->custnum } )
 283   #;
 284   #foreach (@cust_credit) { $total += $_->credited; }
 285   #$total, @cust_credit;
 286 }
 287
 288 =item cust_pay
 289
 290 Depreciated.  See the cust_bill_pay method.
 291
 292 #Returns all payments (see L<FS::cust_pay>) for this invoice.
 293
 294 =cut
 295
 296 sub cust_pay {
 297   use Carp;
 298   croak "FS::cust_bill->cust_pay depreciated; see FS::cust_bill->cust_bill_pay";
 299   #my $self = shift;
 300   #sort { $a->_date <=> $b->_date }
 301   #  qsearch( 'cust_pay', { 'invnum' => $self->invnum } )
 302   #;
 303 }
 304
 305 =item cust_bill_pay
 306
 307 Returns all payment applications (see L<FS::cust_bill_pay>) for this invoice.
 308
 309 =cut
 310
 311 sub cust_bill_pay {
 312   my $self = shift;
 313   sort { $a->_date <=> $b->_date }
 314     qsearch( 'cust_bill_pay', { 'invnum' => $self->invnum } );
 315 }
 316
 317 =item cust_credited
 318
 319 Returns all applied credits (see L<FS::cust_credit_bill>) for this invoice.
 320
 321 =cut
 322
 323 sub cust_credited {
 324   my $self = shift;
 325   sort { $a->_date <=> $b->_date }
 326     qsearch( 'cust_credit_bill', { 'invnum' => $self->invnum } )
 327   ;
 328 }
 329
 330 =item tax
 331
 332 Returns the tax amount (see L<FS::cust_bill_pkg>) for this invoice.
 333
 334 =cut
 335
 336 sub tax {
 337   my $self = shift;
 338   my $total = 0;
 339   my @taxlines = qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum ,
 340                                              'pkgnum' => 0 } );
 341   foreach (@taxlines) { $total += $_->setup; }
 342   $total;
 343 }
 344
 345 =item owed
 346
 347 Returns the amount owed (still outstanding) on this invoice, which is charged
 348 minus all payment applications (see L<FS::cust_bill_pay>) and credit
 349 applications (see L<FS::cust_credit_bill>).
 350
 351 =cut
 352
 353 sub owed {
 354   my $self = shift;
 355   my $balance = $self->charged;
 356   $balance -= $_->amount foreach ( $self->cust_bill_pay );
 357   $balance -= $_->amount foreach ( $self->cust_credited );
 358   $balance = sprintf( "%.2f", $balance);
 359   $balance =~ s/^\-0\.00$/0.00/; #yay ieee fp
 360   $balance;
 361 }
 362
 363 =item send
 364
 365 Sends this invoice to the destinations configured for this customer: send
 366 emails or print.  See L<FS::cust_main_invoice>.
 367
 368 =cut
 369
 370 sub send {
 371   my($self,$template) = @_;
 372
 373   #my @print_text = $cust_bill->print_text; #( date )
 374   my @invoicing_list = $self->cust_main->invoicing_list;
 375   if ( grep { $_ ne 'POST' } @invoicing_list ) { #email invoice
 376     #false laziness w/FS::cust_pay::delete
 377     #$ENV{SMTPHOSTS} = $smtpmachine;
 378     $ENV{MAILADDRESS} = $invoice_from;
 379     my $header = new Mail::Header ( [
 380       "From: $invoice_from",
 381       "To: ". join(', ', grep { $_ ne 'POST' } @invoicing_list ),
 382       "Sender: $invoice_from",
 383       "Reply-To: $invoice_from",
 384       "Date: ". time2str("%a, %d %b %Y %X %z", time),
 385       "Subject: Invoice",
 386     ] );
 387     my $message = new Mail::Internet (
 388       'Header' => $header,
 389       'Body' => [ $self->print_text('', $template) ], #( date)
 390     );
 391     $!=0;
 392     $message->smtpsend( Host => $smtpmachine )
 393       or $message->smtpsend( Host => $smtpmachine, Debug => 1 )
 394         or return "(customer # ". $self->custnum. ") can't send invoice email".
 395                   " to ". join(', ', grep { $_ ne 'POST' } @invoicing_list ).
 396                   " via server $smtpmachine with SMTP: $!";
 397
 398   #} elsif ( grep { $_ eq 'POST' } @invoicing_list ) {
 399   } elsif ( ! @invoicing_list || grep { $_ eq 'POST' } @invoicing_list ) {
 400     open(LPR, "|$lpr")
 401       or return "Can't open pipe to $lpr: $!";
 402     print LPR $self->print_text; #( date )
 403     close LPR
 404       or return $! ? "Error closing $lpr: $!"
 405                    : "Exit status $? from $lpr";
 406   }
 407
 408   '';
 409
 410 }
 411
 412 =item comp
 413
 414 Pays this invoice with a compliemntary payment.  If there is an error,
 415 returns the error, otherwise returns false.
 416
 417 =cut
 418
 419 sub comp {
 420   my $self = shift;
 421   my $cust_pay = new FS::cust_pay ( {
 422     'invnum'   => $self->invnum,
 423     'paid'     => $self->owed,
 424     '_date'    => '',
 425     'payby'    => 'COMP',
 426     'payinfo'  => $self->cust_main->payinfo,
 427     'paybatch' => '',
 428   } );
 429   $cust_pay->insert;
 430 }
 431
 432 =item realtime_card
 433
 434 Attempts to pay this invoice with a Business::OnlinePayment realtime gateway.
 435 See http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
 436 for supproted processors.
 437
 438 =cut
 439
 440 sub realtime_card {
 441   my $self = shift;
 442   my $cust_main = $self->cust_main;
 443   my $amount = $self->owed;
 444
 445   unless ( $processor =~ /^Business::OnlinePayment::(.*)$/ ) {
 446     return "Real-time card processing not enabled (processor $processor)";
 447   }
 448   my $bop_processor = $1; #hmm?
 449
 450   my $address = $cust_main->address1;
 451   $address .= ", ". $cust_main->address2 if $cust_main->address2;
 452
 453   #fix exp. date
 454   #$cust_main->paydate =~ /^(\d+)\/\d*(\d{2})$/;
 455   $cust_main->paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
 456   my $exp = "$2/$1";
 457
 458   my($payname, $payfirst, $paylast);
 459   if ( $cust_main->payname ) {
 460     $payname = $cust_main->payname;
 461     $payname =~ /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)$/
 462       or do {
 463               #$dbh->rollback if $oldAutoCommit;
 464               return "Illegal payname $payname";
 465             };
 466     ($payfirst, $paylast) = ($1, $2);
 467   } else {
 468     $payfirst = $cust_main->getfield('first');
 469     $paylast = $cust_main->getfield('first');
 470     $payname =  "$payfirst $paylast";
 471   }
 472
 473   my @invoicing_list = grep { $_ ne 'POST' } $cust_main->invoicing_list;
 474   if ( $conf->exists('emailinvoiceauto')
 475        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
 476     push @invoicing_list, $cust_main->default_invoicing_list;
 477   }
 478   my $email = $invoicing_list[0];
 479
 480   my( $action1, $action2 ) = split(/\s*\,\s*/, $bop_action );
 481
 482   my $transaction =
 483     new Business::OnlinePayment( $bop_processor, @bop_options );
 484   $transaction->content(
 485     'type'           => 'CC',
 486     'login'          => $bop_login,
 487     'password'       => $bop_password,
 488     'action'         => $action1,
 489     'description'    => 'Internet Services',
 490     'amount'         => $amount,
 491     'invoice_number' => $self->invnum,
 492     'customer_id'    => $self->custnum,
 493     'last_name'      => $paylast,
 494     'first_name'     => $payfirst,
 495     'name'           => $payname,
 496     'address'        => $address,
 497     'city'           => $cust_main->city,
 498     'state'          => $cust_main->state,
 499     'zip'            => $cust_main->zip,
 500     'country'        => $cust_main->country,
 501     'card_number'    => $cust_main->payinfo,
 502     'expiration'     => $exp,
 503     'referer'        => 'http://cleanwhisker.420.am/',
 504     'email'          => $email,
 505   );
 506   $transaction->submit();
 507
 508   if ( $transaction->is_success() && $action2 ) {
 509     my $auth = $transaction->authorization;
 510     my $ordernum = $transaction->order_number;
 511     #warn "********* $auth ***********\n";
 512     #warn "********* $ordernum ***********\n";
 513     my $capture =
 514       new Business::OnlinePayment( $bop_processor, @bop_options );
 515
 516     $capture->content(
 517       action         => $action2,
 518       login          => $bop_login,
 519       password       => $bop_password,
 520       order_number   => $ordernum,
 521       amount         => $amount,
 522       authorization  => $auth,
 523       description    => 'Internet Services',
 524     );
 525
 526     $capture->submit();
 527
 528     unless ( $capture->is_success ) {
 529       my $e = "Authorization sucessful but capture failed, invnum #".
 530               $self->invnum. ': '.  $capture->result_code.
 531               ": ". $capture->error_message;
 532       warn $e;
 533       return $e;
 534     }
 535
 536   }
 537
 538   if ( $transaction->is_success() ) {
 539
 540     my $cust_pay = new FS::cust_pay ( {
 541        'invnum'   => $self->invnum,
 542        'paid'     => $amount,
 543        '_date'     => '',
 544        'payby'    => 'CARD',
 545        'payinfo'  => $cust_main->payinfo,
 546        'paybatch' => "$processor:". $transaction->authorization,
 547     } );
 548     my $error = $cust_pay->insert;
 549     if ( $error ) {
 550       # gah, even with transactions.
 551       my $e = 'WARNING: Card debited but database not updated - '.
 552               'error applying payment, invnum #' . $self->invnum.
 553               " ($processor): $error";
 554       warn $e;
 555       return $e;
 556     } else {
 557       return '';
 558     }
 559   #} elsif ( $options{'report_badcard'} ) {
 560   } else {
 561     return "$processor error, invnum #". $self->invnum. ': '.
 562            $transaction->result_code. ": ". $transaction->error_message;
 563   }
 564
 565 }
 566
 567 =item realtime_card_cybercash
 568
 569 Attempts to pay this invoice with the CyberCash CashRegister realtime gateway.
 570
 571 =cut
 572
 573 sub realtime_card_cybercash {
 574   my $self = shift;
 575   my $cust_main = $self->cust_main;
 576   my $amount = $self->owed;
 577
 578   return "CyberCash CashRegister real-time card processing not enabled!"
 579     unless $processor eq 'cybercash3.2';
 580
 581   my $address = $cust_main->address1;
 582   $address .= ", ". $cust_main->address2 if $cust_main->address2;
 583
 584   #fix exp. date
 585   #$cust_main->paydate =~ /^(\d+)\/\d*(\d{2})$/;
 586   $cust_main->paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
 587   my $exp = "$2/$1";
 588
 589   #
 590
 591   my $paybatch = $self->invnum.
 592                   '-' . time2str("%y%m%d%H%M%S", time);
 593
 594   my $payname = $cust_main->payname ||
 595                 $cust_main->getfield('first').' '.$cust_main->getfield('last');
 596
 597   my $country = $cust_main->country eq 'US' ? 'USA' : $cust_main->country;
 598
 599   my @full_xaction = ( $xaction,
 600     'Order-ID'     => $paybatch,
 601     'Amount'       => "usd $amount",
 602     'Card-Number'  => $cust_main->getfield('payinfo'),
 603     'Card-Name'    => $payname,
 604     'Card-Address' => $address,
 605     'Card-City'    => $cust_main->getfield('city'),
 606     'Card-State'   => $cust_main->getfield('state'),
 607     'Card-Zip'     => $cust_main->getfield('zip'),
 608     'Card-Country' => $country,
 609     'Card-Exp'     => $exp,
 610   );
 611
 612   my %result;
 613   %result = &CCMckDirectLib3_2::SendCC2_1Server(@full_xaction);
 614
 615   if ( $result{'MStatus'} eq 'success' ) { #cybercash smps v.2 or 3
 616     my $cust_pay = new FS::cust_pay ( {
 617        'invnum'   => $self->invnum,
 618        'paid'     => $amount,
 619        '_date'     => '',
 620        'payby'    => 'CARD',
 621        'payinfo'  => $cust_main->payinfo,
 622        'paybatch' => "$processor:$paybatch",
 623     } );
 624     my $error = $cust_pay->insert;
 625     if ( $error ) {
 626       # gah, even with transactions.
 627       my $e = 'WARNING: Card debited but database not updated - '.
 628               'error applying payment, invnum #' . $self->invnum.
 629               " (CyberCash Order-ID $paybatch): $error";
 630       warn $e;
 631       return $e;
 632     } else {
 633       return '';
 634     }
 635 #  } elsif ( $result{'Mstatus'} ne 'failure-bad-money'
 636 #            || $options{'report_badcard'}
 637 #          ) {
 638   } else {
 639      return 'Cybercash error, invnum #' .
 640        $self->invnum. ':'. $result{'MErrMsg'};
 641   }
 642
 643 }
 644
 645 =item batch_card
 646
 647 Adds a payment for this invoice to the pending credit card batch (see
 648 L<FS::cust_pay_batch>).
 649
 650 =cut
 651
 652 sub batch_card {
 653   my $self = shift;
 654   my $cust_main = $self->cust_main;
 655
 656   my $cust_pay_batch = new FS::cust_pay_batch ( {
 657     'invnum'   => $self->getfield('invnum'),
 658     'custnum'  => $cust_main->getfield('custnum'),
 659     'last'     => $cust_main->getfield('last'),
 660     'first'    => $cust_main->getfield('first'),
 661     'address1' => $cust_main->getfield('address1'),
 662     'address2' => $cust_main->getfield('address2'),
 663     'city'     => $cust_main->getfield('city'),
 664     'state'    => $cust_main->getfield('state'),
 665     'zip'      => $cust_main->getfield('zip'),
 666     'country'  => $cust_main->getfield('country'),
 667     'trancode' => 77,
 668     'cardnum'  => $cust_main->getfield('payinfo'),
 669     'exp'      => $cust_main->getfield('paydate'),
 670     'payname'  => $cust_main->getfield('payname'),
 671     'amount'   => $self->owed,
 672   } );
 673   $cust_pay_batch->insert;
 674
 675 }
 676
 677 =item print_text [TIME];
 678
 679 Returns an text invoice, as a list of lines.
 680
 681 TIME an optional value used to control the printing of overdue messages.  The
 682 default is now.  It isn't the date of the invoice; that's the `_date' field.
 683 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 684 L<Time::Local> and L<Date::Parse> for conversion functions.
 685
 686 =cut
 687
 688 sub print_text {
 689
 690   my( $self, $today, $template ) = @_;
 691   $today ||= time;
 692 #  my $invnum = $self->invnum;
 693   my $cust_main = qsearchs('cust_main', { 'custnum', $self->custnum } );
 694   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
 695     unless $cust_main->payname;
 696
 697   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 698 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 699   #my $balance_due = $self->owed + $pr_total - $cr_total;
 700   my $balance_due = $self->owed + $pr_total;
 701
 702   #my @collect = ();
 703   #my($description,$amount);
 704   @buf = ();
 705
 706   #previous balance
 707   foreach ( @pr_cust_bill ) {
 708     push @buf, [
 709       "Previous Balance, Invoice #". $_->invnum.
 710                  " (". time2str("%x",$_->_date). ")",
 711       $money_char. sprintf("%10.2f",$_->owed)
 712     ];
 713   }
 714   if (@pr_cust_bill) {
 715     push @buf,['','-----------'];
 716     push @buf,[ 'Total Previous Balance',
 717                 $money_char. sprintf("%10.2f",$pr_total ) ];
 718     push @buf,['',''];
 719   }
 720
 721   #new charges
 722   foreach ( $self->cust_bill_pkg ) {
 723
 724     if ( $_->pkgnum ) {
 725
 726       my($cust_pkg)=qsearchs('cust_pkg', { 'pkgnum', $_->pkgnum } );
 727       my($part_pkg)=qsearchs('part_pkg',{'pkgpart'=>$cust_pkg->pkgpart});
 728       my($pkg)=$part_pkg->pkg;
 729
 730       if ( $_->setup != 0 ) {
 731         push @buf, [ "$pkg Setup", $money_char. sprintf("%10.2f",$_->setup) ];
 732         push @buf,
 733           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] } $cust_pkg->labels;
 734       }
 735
 736       if ( $_->recur != 0 ) {
 737         push @buf, [
 738           "$pkg (" . time2str("%x",$_->sdate) . " - " .
 739                                 time2str("%x",$_->edate) . ")",
 740           $money_char. sprintf("%10.2f",$_->recur)
 741         ];
 742         push @buf,
 743           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] } $cust_pkg->labels;
 744       }
 745
 746     } else { #pkgnum Tax
 747       push @buf,["Tax", $money_char. sprintf("%10.2f",$_->setup) ]
 748         if $_->setup != 0;
 749     }
 750   }
 751
 752   push @buf,['','-----------'];
 753   push @buf,['Total New Charges',
 754              $money_char. sprintf("%10.2f",$self->charged) ];
 755   push @buf,['',''];
 756
 757   push @buf,['','-----------'];
 758   push @buf,['Total Charges',
 759              $money_char. sprintf("%10.2f",$self->charged + $pr_total) ];
 760   push @buf,['',''];
 761
 762   #credits
 763   foreach ( $self->cust_credited ) {
 764
 765     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
 766
 767     my $reason = substr($_->cust_credit->reason,0,32);
 768     $reason .= '...' if length($reason) < length($_->cust_credit->reason);
 769     $reason = " ($reason) " if $reason;
 770     push @buf,[
 771       "Credit #". $_->crednum. " (". time2str("%x",$_->cust_credit->_date) .")".
 772         $reason,
 773       $money_char. sprintf("%10.2f",$_->amount)
 774     ];
 775   }
 776   #foreach ( @cr_cust_credit ) {
 777   #  push @buf,[
 778   #    "Credit #". $_->crednum. " (" . time2str("%x",$_->_date) .")",
 779   #    $money_char. sprintf("%10.2f",$_->credited)
 780   #  ];
 781   #}
 782
 783   #get & print payments
 784   foreach ( $self->cust_bill_pay ) {
 785
 786     #something more elaborate if $_->amount ne ->cust_pay->paid ?
 787
 788     push @buf,[
 789       "Payment received ". time2str("%x",$_->cust_pay->_date ),
 790       $money_char. sprintf("%10.2f",$_->amount )
 791     ];
 792   }
 793
 794   #balance due
 795   push @buf,['','-----------'];
 796   push @buf,['Balance Due', $money_char.
 797     sprintf("%10.2f", $balance_due ) ];
 798
 799   #create the template
 800   my $templatefile = 'invoice_template';
 801   $templatefile .= "_$template" if $template;
 802   my @invoice_template = $conf->config($templatefile)
 803   or die "cannot load config file $templatefile";
 804   $invoice_lines = 0;
 805   foreach ( grep /invoice_lines\(\d+\)/, @invoice_template ) { #kludgy
 806     /invoice_lines\((\d+)\)/;
 807     $invoice_lines += $1;
 808   }
 809   die "no invoice_lines() functions in template?" unless $invoice_lines;
 810   my $invoice_template = new Text::Template (
 811     TYPE   => 'ARRAY',
 812     SOURCE => [ map "$_\n", @invoice_template ],
 813   ) or die "can't create new Text::Template object: $Text::Template::ERROR";
 814   $invoice_template->compile()
 815     or die "can't compile template: $Text::Template::ERROR";
 816
 817   #setup template variables
 818   package FS::cust_bill::_template; #!
 819   use vars qw( $invnum $date $page $total_pages @address $overdue @buf );
 820
 821   $invnum = $self->invnum;
 822   $date = $self->_date;
 823   $page = 1;
 824
 825   $total_pages =
 826     int( scalar(@FS::cust_bill::buf) / $FS::cust_bill::invoice_lines );
 827   $total_pages++
 828     if scalar(@FS::cust_bill::buf) % $FS::cust_bill::invoice_lines;
 829
 830
 831   #format address (variable for the template)
 832   my $l = 0;
 833   @address = ( '', '', '', '', '', '' );
 834   package FS::cust_bill; #!
 835   $FS::cust_bill::_template::address[$l++] =
 836     $cust_main->payname.
 837       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
 838         ? " (P.O. #". $cust_main->payinfo. ")"
 839         : ''
 840       )
 841   ;
 842   $FS::cust_bill::_template::address[$l++] = $cust_main->company
 843     if $cust_main->company;
 844   $FS::cust_bill::_template::address[$l++] = $cust_main->address1;
 845   $FS::cust_bill::_template::address[$l++] = $cust_main->address2
 846     if $cust_main->address2;
 847   $FS::cust_bill::_template::address[$l++] =
 848     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 849   $FS::cust_bill::_template::address[$l++] = $cust_main->country
 850     unless $cust_main->country eq 'US';
 851
 852         #  #overdue? (variable for the template)
 853         #  $FS::cust_bill::_template::overdue = (
 854         #    $balance_due > 0
 855         #    && $today > $self->_date
 856         ##    && $self->printed > 1
 857         #    && $self->printed > 0
 858         #  );
 859
 860   #and subroutine for the template
 861
 862   sub FS::cust_bill::_template::invoice_lines {
 863     my $lines = shift;
 864     map {
 865       scalar(@buf) ? shift @buf : [ '', '' ];
 866     }
 867     ( 1 .. $lines );
 868   }
 869
 870
 871   #and fill it in
 872   $FS::cust_bill::_template::page = 1;
 873   my $lines;
 874   my @collect;
 875   while (@buf) {
 876     push @collect, split("\n",
 877       $invoice_template->fill_in( PACKAGE => 'FS::cust_bill::_template' )
 878     );
 879     $FS::cust_bill::_template::page++;
 880   }
 881
 882   map "$_\n", @collect;
 883
 884 }
 885
 886 =back
 887
 888 =head1 VERSION
 889
 890 $Id: cust_bill.pm,v 1.24 2002-03-18 21:40:17 ivan Exp $
 891
 892 =head1 BUGS
 893
 894 The delete method.
 895
 896 print_text formatting (and some logic :/) is in source, but needs to be
 897 slurped in from a file.  Also number of lines ($=).
 898
 899 missing print_ps for a nice postscript copy (maybe HylaFAX-cover-page-style
 900 or something similar so the look can be completely customized?)
 901
 902 =head1 SEE ALSO
 903
 904 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill_pay>, L<FS::cust_pay>,
 905 L<FS::cust_bill_pkg>, L<FS::cust_bill_credit>, schema.html from the base
 906 documentation.
 907
 908 =cut
 909
 910 1;
 911