FS/FS/cust_bill.pm

   1 package FS::cust_bill;
   2
   3 use strict;
   4 use vars qw( @ISA $conf $money_char );
   5 use vars qw( $invoice_lines @buf ); #yuck
   6 use Date::Format;
   7 use Text::Template;
   8 use FS::UID qw( datasrc );
   9 use FS::Record qw( qsearch qsearchs );
  10 use FS::Misc qw( send_email );
  11 use FS::cust_main;
  12 use FS::cust_bill_pkg;
  13 use FS::cust_credit;
  14 use FS::cust_pay;
  15 use FS::cust_pkg;
  16 use FS::cust_credit_bill;
  17 use FS::cust_pay_batch;
  18 use FS::cust_bill_event;
  19
  20 @ISA = qw( FS::Record );
  21
  22 #ask FS::UID to run this stuff for us later
  23 FS::UID->install_callback( sub {
  24   $conf = new FS::Conf;
  25   $money_char = $conf->config('money_char') || '$';
  26 } );
  27
  28 =head1 NAME
  29
  30 FS::cust_bill - Object methods for cust_bill records
  31
  32 =head1 SYNOPSIS
  33
  34   use FS::cust_bill;
  35
  36   $record = new FS::cust_bill \%hash;
  37   $record = new FS::cust_bill { 'column' => 'value' };
  38
  39   $error = $record->insert;
  40
  41   $error = $new_record->replace($old_record);
  42
  43   $error = $record->delete;
  44
  45   $error = $record->check;
  46
  47   ( $total_previous_balance, @previous_cust_bill ) = $record->previous;
  48
  49   @cust_bill_pkg_objects = $cust_bill->cust_bill_pkg;
  50
  51   ( $total_previous_credits, @previous_cust_credit ) = $record->cust_credit;
  52
  53   @cust_pay_objects = $cust_bill->cust_pay;
  54
  55   $tax_amount = $record->tax;
  56
  57   @lines = $cust_bill->print_text;
  58   @lines = $cust_bill->print_text $time;
  59
  60 =head1 DESCRIPTION
  61
  62 An FS::cust_bill object represents an invoice; a declaration that a customer
  63 owes you money.  The specific charges are itemized as B<cust_bill_pkg> records
  64 (see L<FS::cust_bill_pkg>).  FS::cust_bill inherits from FS::Record.  The
  65 following fields are currently supported:
  66
  67 =over 4
  68
  69 =item invnum - primary key (assigned automatically for new invoices)
  70
  71 =item custnum - customer (see L<FS::cust_main>)
  72
  73 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
  74 L<Time::Local> and L<Date::Parse> for conversion functions.
  75
  76 =item charged - amount of this invoice
  77
  78 =item printed - deprecated
  79
  80 =item closed - books closed flag, empty or `Y'
  81
  82 =back
  83
  84 =head1 METHODS
  85
  86 =over 4
  87
  88 =item new HASHREF
  89
  90 Creates a new invoice.  To add the invoice to the database, see L<"insert">.
  91 Invoices are normally created by calling the bill method of a customer object
  92 (see L<FS::cust_main>).
  93
  94 =cut
  95
  96 sub table { 'cust_bill'; }
  97
  98 =item insert
  99
 100 Adds this invoice to the database ("Posts" the invoice).  If there is an error,
 101 returns the error, otherwise returns false.
 102
 103 =item delete
 104
 105 Currently unimplemented.  I don't remove invoices because there would then be
 106 no record you ever posted this invoice (which is bad, no?)
 107
 108 =cut
 109
 110 sub delete {
 111   my $self = shift;
 112   return "Can't delete closed invoice" if $self->closed =~ /^Y/i;
 113   $self->SUPER::delete(@_);
 114 }
 115
 116 =item replace OLD_RECORD
 117
 118 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 119 returns the error, otherwise returns false.
 120
 121 Only printed may be changed.  printed is normally updated by calling the
 122 collect method of a customer object (see L<FS::cust_main>).
 123
 124 =cut
 125
 126 sub replace {
 127   my( $new, $old ) = ( shift, shift );
 128   return "Can't change custnum!" unless $old->custnum == $new->custnum;
 129   #return "Can't change _date!" unless $old->_date eq $new->_date;
 130   return "Can't change _date!" unless $old->_date == $new->_date;
 131   return "Can't change charged!" unless $old->charged == $new->charged;
 132
 133   $new->SUPER::replace($old);
 134 }
 135
 136 =item check
 137
 138 Checks all fields to make sure this is a valid invoice.  If there is an error,
 139 returns the error, otherwise returns false.  Called by the insert and replace
 140 methods.
 141
 142 =cut
 143
 144 sub check {
 145   my $self = shift;
 146
 147   my $error =
 148     $self->ut_numbern('invnum')
 149     || $self->ut_number('custnum')
 150     || $self->ut_numbern('_date')
 151     || $self->ut_money('charged')
 152     || $self->ut_numbern('printed')
 153     || $self->ut_enum('closed', [ '', 'Y' ])
 154   ;
 155   return $error if $error;
 156
 157   return "Unknown customer"
 158     unless qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 159
 160   $self->_date(time) unless $self->_date;
 161
 162   $self->printed(0) if $self->printed eq '';
 163
 164   $self->SUPER::check;
 165 }
 166
 167 =item previous
 168
 169 Returns a list consisting of the total previous balance for this customer,
 170 followed by the previous outstanding invoices (as FS::cust_bill objects also).
 171
 172 =cut
 173
 174 sub previous {
 175   my $self = shift;
 176   my $total = 0;
 177   my @cust_bill = sort { $a->_date <=> $b->_date }
 178     grep { $_->owed != 0 && $_->_date < $self->_date }
 179       qsearch( 'cust_bill', { 'custnum' => $self->custnum } )
 180   ;
 181   foreach ( @cust_bill ) { $total += $_->owed; }
 182   $total, @cust_bill;
 183 }
 184
 185 =item cust_bill_pkg
 186
 187 Returns the line items (see L<FS::cust_bill_pkg>) for this invoice.
 188
 189 =cut
 190
 191 sub cust_bill_pkg {
 192   my $self = shift;
 193   qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum } );
 194 }
 195
 196 =item cust_bill_event
 197
 198 Returns the completed invoice events (see L<FS::cust_bill_event>) for this
 199 invoice.
 200
 201 =cut
 202
 203 sub cust_bill_event {
 204   my $self = shift;
 205   qsearch( 'cust_bill_event', { 'invnum' => $self->invnum } );
 206 }
 207
 208
 209 =item cust_main
 210
 211 Returns the customer (see L<FS::cust_main>) for this invoice.
 212
 213 =cut
 214
 215 sub cust_main {
 216   my $self = shift;
 217   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 218 }
 219
 220 =item cust_credit
 221
 222 Depreciated.  See the cust_credited method.
 223
 224  #Returns a list consisting of the total previous credited (see
 225  #L<FS::cust_credit>) and unapplied for this customer, followed by the previous
 226  #outstanding credits (FS::cust_credit objects).
 227
 228 =cut
 229
 230 sub cust_credit {
 231   use Carp;
 232   croak "FS::cust_bill->cust_credit depreciated; see ".
 233         "FS::cust_bill->cust_credit_bill";
 234   #my $self = shift;
 235   #my $total = 0;
 236   #my @cust_credit = sort { $a->_date <=> $b->_date }
 237   #  grep { $_->credited != 0 && $_->_date < $self->_date }
 238   #    qsearch('cust_credit', { 'custnum' => $self->custnum } )
 239   #;
 240   #foreach (@cust_credit) { $total += $_->credited; }
 241   #$total, @cust_credit;
 242 }
 243
 244 =item cust_pay
 245
 246 Depreciated.  See the cust_bill_pay method.
 247
 248 #Returns all payments (see L<FS::cust_pay>) for this invoice.
 249
 250 =cut
 251
 252 sub cust_pay {
 253   use Carp;
 254   croak "FS::cust_bill->cust_pay depreciated; see FS::cust_bill->cust_bill_pay";
 255   #my $self = shift;
 256   #sort { $a->_date <=> $b->_date }
 257   #  qsearch( 'cust_pay', { 'invnum' => $self->invnum } )
 258   #;
 259 }
 260
 261 =item cust_bill_pay
 262
 263 Returns all payment applications (see L<FS::cust_bill_pay>) for this invoice.
 264
 265 =cut
 266
 267 sub cust_bill_pay {
 268   my $self = shift;
 269   sort { $a->_date <=> $b->_date }
 270     qsearch( 'cust_bill_pay', { 'invnum' => $self->invnum } );
 271 }
 272
 273 =item cust_credited
 274
 275 Returns all applied credits (see L<FS::cust_credit_bill>) for this invoice.
 276
 277 =cut
 278
 279 sub cust_credited {
 280   my $self = shift;
 281   sort { $a->_date <=> $b->_date }
 282     qsearch( 'cust_credit_bill', { 'invnum' => $self->invnum } )
 283   ;
 284 }
 285
 286 =item tax
 287
 288 Returns the tax amount (see L<FS::cust_bill_pkg>) for this invoice.
 289
 290 =cut
 291
 292 sub tax {
 293   my $self = shift;
 294   my $total = 0;
 295   my @taxlines = qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum ,
 296                                              'pkgnum' => 0 } );
 297   foreach (@taxlines) { $total += $_->setup; }
 298   $total;
 299 }
 300
 301 =item owed
 302
 303 Returns the amount owed (still outstanding) on this invoice, which is charged
 304 minus all payment applications (see L<FS::cust_bill_pay>) and credit
 305 applications (see L<FS::cust_credit_bill>).
 306
 307 =cut
 308
 309 sub owed {
 310   my $self = shift;
 311   my $balance = $self->charged;
 312   $balance -= $_->amount foreach ( $self->cust_bill_pay );
 313   $balance -= $_->amount foreach ( $self->cust_credited );
 314   $balance = sprintf( "%.2f", $balance);
 315   $balance =~ s/^\-0\.00$/0.00/; #yay ieee fp
 316   $balance;
 317 }
 318
 319 =item send
 320
 321 Sends this invoice to the destinations configured for this customer: send
 322 emails or print.  See L<FS::cust_main_invoice>.
 323
 324 =cut
 325
 326 sub send {
 327   my($self,$template) = @_;
 328   my @print_text = $self->print_text('', $template);
 329   my @invoicing_list = $self->cust_main->invoicing_list;
 330
 331   if ( grep { $_ ne 'POST' } @invoicing_list or !@invoicing_list  ) { #email
 332
 333     #better to notify this person than silence
 334     @invoicing_list = ($conf->config('invoice_from')) unless @invoicing_list;
 335
 336     my $error = send_email(
 337       'from'    => $conf->config('invoice_from'),
 338       'to'      => [ grep { $_ ne 'POST' } @invoicing_list ],
 339       'subject' => 'Invoice',
 340       'body'    => \@print_text,
 341     );
 342     return "can't send invoice: $error" if $error;
 343
 344   }
 345
 346   if ( grep { $_ eq 'POST' } @invoicing_list ) { #postal
 347     my $lpr = $conf->config('lpr');
 348     open(LPR, "|$lpr")
 349       or return "Can't open pipe to $lpr: $!";
 350     print LPR @print_text;
 351     close LPR
 352       or return $! ? "Error closing $lpr: $!"
 353                    : "Exit status $? from $lpr";
 354   }
 355
 356   '';
 357
 358 }
 359
 360 =item send_csv OPTIONS
 361
 362 Sends invoice as a CSV data-file to a remote host with the specified protocol.
 363
 364 Options are:
 365
 366 protocol - currently only "ftp"
 367 server
 368 username
 369 password
 370 dir
 371
 372 The file will be named "N-YYYYMMDDHHMMSS.csv" where N is the invoice number
 373 and YYMMDDHHMMSS is a timestamp.
 374
 375 The fields of the CSV file is as follows:
 376
 377 record_type, invnum, custnum, _date, charged, first, last, company, address1, address2, city, state, zip, country, pkg, setup, recur, sdate, edate
 378
 379 =over 4
 380
 381 =item record type - B<record_type> is either C<cust_bill> or C<cust_bill_pkg>
 382
 383 If B<record_type> is C<cust_bill>, this is a primary invoice record.  The
 384 last five fields (B<pkg> through B<edate>) are irrelevant, and all other
 385 fields are filled in.
 386
 387 If B<record_type> is C<cust_bill_pkg>, this is a line item record.  Only the
 388 first two fields (B<record_type> and B<invnum>) and the last five fields
 389 (B<pkg> through B<edate>) are filled in.
 390
 391 =item invnum - invoice number
 392
 393 =item custnum - customer number
 394
 395 =item _date - invoice date
 396
 397 =item charged - total invoice amount
 398
 399 =item first - customer first name
 400
 401 =item last - customer first name
 402
 403 =item company - company name
 404
 405 =item address1 - address line 1
 406
 407 =item address2 - address line 1
 408
 409 =item city
 410
 411 =item state
 412
 413 =item zip
 414
 415 =item country
 416
 417 =item pkg - line item description
 418
 419 =item setup - line item setup fee (one or both of B<setup> and B<recur> will be defined)
 420
 421 =item recur - line item recurring fee (one or both of B<setup> and B<recur> will be defined)
 422
 423 =item sdate - start date for recurring fee
 424
 425 =item edate - end date for recurring fee
 426
 427 =back
 428
 429 =cut
 430
 431 sub send_csv {
 432   my($self, %opt) = @_;
 433
 434   #part one: create file
 435
 436   my $spooldir = "/usr/local/etc/freeside/export.". datasrc. "/cust_bill";
 437   mkdir $spooldir, 0700 unless -d $spooldir;
 438
 439   my $file = $spooldir. '/'. $self->invnum. time2str('-%Y%m%d%H%M%S.csv', time);
 440
 441   open(CSV, ">$file") or die "can't open $file: $!";
 442
 443   eval "use Text::CSV_XS";
 444   die $@ if $@;
 445
 446   my $csv = Text::CSV_XS->new({'always_quote'=>1});
 447
 448   my $cust_main = $self->cust_main;
 449
 450   $csv->combine(
 451     'cust_bill',
 452     $self->invnum,
 453     $self->custnum,
 454     time2str("%x", $self->_date),
 455     sprintf("%.2f", $self->charged),
 456     ( map { $cust_main->getfield($_) }
 457         qw( first last company address1 address2 city state zip country ) ),
 458     map { '' } (1..5),
 459   ) or die "can't create csv";
 460   print CSV $csv->string. "\n";
 461
 462   #new charges (false laziness w/print_text)
 463   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 464
 465     my($pkg, $setup, $recur, $sdate, $edate);
 466     if ( $cust_bill_pkg->pkgnum ) {
 467
 468       ($pkg, $setup, $recur, $sdate, $edate) = (
 469         $cust_bill_pkg->cust_pkg->part_pkg->pkg,
 470         ( $cust_bill_pkg->setup != 0
 471           ? sprintf("%.2f", $cust_bill_pkg->setup )
 472           : '' ),
 473         ( $cust_bill_pkg->recur != 0
 474           ? sprintf("%.2f", $cust_bill_pkg->recur )
 475           : '' ),
 476         time2str("%x", $cust_bill_pkg->sdate),
 477         time2str("%x", $cust_bill_pkg->edate),
 478       );
 479
 480     } else { #pkgnum tax
 481       next unless $cust_bill_pkg->setup != 0;
 482       my $itemdesc = defined $cust_bill_pkg->dbdef_table->column('itemdesc')
 483                        ? ( $cust_bill_pkg->itemdesc || 'Tax' )
 484                        : 'Tax';
 485       ($pkg, $setup, $recur, $sdate, $edate) =
 486         ( $itemdesc, sprintf("%10.2f",$cust_bill_pkg->setup), '', '', '' );
 487     }
 488
 489     $csv->combine(
 490       'cust_bill_pkg',
 491       $self->invnum,
 492       ( map { '' } (1..11) ),
 493       ($pkg, $setup, $recur, $sdate, $edate)
 494     ) or die "can't create csv";
 495     print CSV $csv->string. "\n";
 496
 497   }
 498
 499   close CSV or die "can't close CSV: $!";
 500
 501   #part two: upload it
 502
 503   my $net;
 504   if ( $opt{protocol} eq 'ftp' ) {
 505     eval "use Net::FTP;";
 506     die $@ if $@;
 507     $net = Net::FTP->new($opt{server}) or die @$;
 508   } else {
 509     die "unknown protocol: $opt{protocol}";
 510   }
 511
 512   $net->login( $opt{username}, $opt{password} )
 513     or die "can't FTP to $opt{username}\@$opt{server}: login error: $@";
 514
 515   $net->binary or die "can't set binary mode";
 516
 517   $net->cwd($opt{dir}) or die "can't cwd to $opt{dir}";
 518
 519   $net->put($file) or die "can't put $file: $!";
 520
 521   $net->quit;
 522
 523   unlink $file;
 524
 525 }
 526
 527 =item comp
 528
 529 Pays this invoice with a compliemntary payment.  If there is an error,
 530 returns the error, otherwise returns false.
 531
 532 =cut
 533
 534 sub comp {
 535   my $self = shift;
 536   my $cust_pay = new FS::cust_pay ( {
 537     'invnum'   => $self->invnum,
 538     'paid'     => $self->owed,
 539     '_date'    => '',
 540     'payby'    => 'COMP',
 541     'payinfo'  => $self->cust_main->payinfo,
 542     'paybatch' => '',
 543   } );
 544   $cust_pay->insert;
 545 }
 546
 547 =item realtime_card
 548
 549 Attempts to pay this invoice with a credit card payment via a
 550 Business::OnlinePayment realtime gateway.  See
 551 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
 552 for supported processors.
 553
 554 =cut
 555
 556 sub realtime_card {
 557   my $self = shift;
 558   $self->realtime_bop( 'CC', @_ );
 559 }
 560
 561 =item realtime_ach
 562
 563 Attempts to pay this invoice with an electronic check (ACH) payment via a
 564 Business::OnlinePayment realtime gateway.  See
 565 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
 566 for supported processors.
 567
 568 =cut
 569
 570 sub realtime_ach {
 571   my $self = shift;
 572   $self->realtime_bop( 'ECHECK', @_ );
 573 }
 574
 575 =item realtime_lec
 576
 577 Attempts to pay this invoice with phone bill (LEC) payment via a
 578 Business::OnlinePayment realtime gateway.  See
 579 http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
 580 for supported processors.
 581
 582 =cut
 583
 584 sub realtime_lec {
 585   my $self = shift;
 586   $self->realtime_bop( 'LEC', @_ );
 587 }
 588
 589 sub realtime_bop {
 590   my( $self, $method ) = @_;
 591
 592   my $cust_main = $self->cust_main;
 593   my $amount = $self->owed;
 594
 595   my $description = 'Internet Services';
 596   if ( $conf->exists('business-onlinepayment-description') ) {
 597     my $dtempl = $conf->config('business-onlinepayment-description');
 598
 599     my $agent_obj = $cust_main->agent
 600       or die "can't retreive agent for $cust_main (agentnum ".
 601              $cust_main->agentnum. ")";
 602     my $agent = $agent_obj->agent;
 603     my $pkgs = join(', ',
 604       map { $_->cust_pkg->part_pkg->pkg }
 605         grep { $_->pkgnum } $self->cust_bill_pkg
 606     );
 607     $description = eval qq("$dtempl");
 608   }
 609
 610   $cust_main->realtime_bop($method, $amount,
 611     'description' => $description,
 612     'invnum'      => $self->invnum,
 613   );
 614
 615 }
 616
 617 =item batch_card
 618
 619 Adds a payment for this invoice to the pending credit card batch (see
 620 L<FS::cust_pay_batch>).
 621
 622 =cut
 623
 624 sub batch_card {
 625   my $self = shift;
 626   my $cust_main = $self->cust_main;
 627
 628   my $cust_pay_batch = new FS::cust_pay_batch ( {
 629     'invnum'   => $self->getfield('invnum'),
 630     'custnum'  => $cust_main->getfield('custnum'),
 631     'last'     => $cust_main->getfield('last'),
 632     'first'    => $cust_main->getfield('first'),
 633     'address1' => $cust_main->getfield('address1'),
 634     'address2' => $cust_main->getfield('address2'),
 635     'city'     => $cust_main->getfield('city'),
 636     'state'    => $cust_main->getfield('state'),
 637     'zip'      => $cust_main->getfield('zip'),
 638     'country'  => $cust_main->getfield('country'),
 639     'cardnum'  => $cust_main->getfield('payinfo'),
 640     'exp'      => $cust_main->getfield('paydate'),
 641     'payname'  => $cust_main->getfield('payname'),
 642     'amount'   => $self->owed,
 643   } );
 644   my $error = $cust_pay_batch->insert;
 645   die $error if $error;
 646
 647   '';
 648 }
 649
 650 =item print_text [ TIME [ , TEMPLATE ] ]
 651
 652 Returns an text invoice, as a list of lines.
 653
 654 TIME an optional value used to control the printing of overdue messages.  The
 655 default is now.  It isn't the date of the invoice; that's the `_date' field.
 656 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 657 L<Time::Local> and L<Date::Parse> for conversion functions.
 658
 659 =cut
 660
 661 sub print_text {
 662
 663   my( $self, $today, $template ) = @_;
 664   $today ||= time;
 665 #  my $invnum = $self->invnum;
 666   my $cust_main = qsearchs('cust_main', { 'custnum', $self->custnum } );
 667   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
 668     unless $cust_main->payname && $cust_main->payby ne 'CHEK';
 669
 670
 671   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 672 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 673   #my $balance_due = $self->owed + $pr_total - $cr_total;
 674   my $balance_due = $self->owed + $pr_total;
 675
 676   #my @collect = ();
 677   #my($description,$amount);
 678   @buf = ();
 679
 680   #previous balance
 681   foreach ( @pr_cust_bill ) {
 682     push @buf, [
 683       "Previous Balance, Invoice #". $_->invnum.
 684                  " (". time2str("%x",$_->_date). ")",
 685       $money_char. sprintf("%10.2f",$_->owed)
 686     ];
 687   }
 688   if (@pr_cust_bill) {
 689     push @buf,['','-----------'];
 690     push @buf,[ 'Total Previous Balance',
 691                 $money_char. sprintf("%10.2f",$pr_total ) ];
 692     push @buf,['',''];
 693   }
 694
 695   #new charges
 696   foreach my $cust_bill_pkg (
 697     ( grep {   $_->pkgnum } $self->cust_bill_pkg ),  #packages first
 698     ( grep { ! $_->pkgnum } $self->cust_bill_pkg ),  #then taxes
 699   ) {
 700
 701     if ( $cust_bill_pkg->pkgnum ) {
 702
 703       my $cust_pkg = qsearchs('cust_pkg', { pkgnum =>$cust_bill_pkg->pkgnum } );
 704       my $part_pkg = qsearchs('part_pkg', { pkgpart=>$cust_pkg->pkgpart } );
 705       my $pkg = $part_pkg->pkg;
 706
 707       if ( $cust_bill_pkg->setup != 0 ) {
 708         push @buf, [ "$pkg Setup",
 709                      $money_char. sprintf("%10.2f", $cust_bill_pkg->setup) ];
 710         push @buf,
 711           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] } $cust_pkg->labels;
 712       }
 713
 714       if ( $cust_bill_pkg->recur != 0 ) {
 715         push @buf, [
 716           "$pkg (" . time2str("%x", $cust_bill_pkg->sdate) . " - " .
 717                                 time2str("%x", $cust_bill_pkg->edate) . ")",
 718           $money_char. sprintf("%10.2f", $cust_bill_pkg->recur)
 719         ];
 720         push @buf,
 721           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] } $cust_pkg->labels;
 722       }
 723
 724       push @buf, map { [ "  $_", '' ] } $cust_bill_pkg->details;
 725
 726     } else { #pkgnum tax or one-shot line item
 727       my $itemdesc = defined $cust_bill_pkg->dbdef_table->column('itemdesc')
 728                      ? ( $cust_bill_pkg->itemdesc || 'Tax' )
 729                      : 'Tax';
 730       if ( $cust_bill_pkg->setup != 0 ) {
 731         push @buf, [ $itemdesc,
 732                      $money_char. sprintf("%10.2f", $cust_bill_pkg->setup) ];
 733       }
 734       if ( $cust_bill_pkg->recur != 0 ) {
 735         push @buf, [ "$itemdesc (". time2str("%x", $cust_bill_pkg->sdate). " - "
 736                                   . time2str("%x", $cust_bill_pkg->edate). ")",
 737                      $money_char. sprintf("%10.2f", $cust_bill_pkg->recur)
 738                    ];
 739       }
 740     }
 741   }
 742
 743   push @buf,['','-----------'];
 744   push @buf,['Total New Charges',
 745              $money_char. sprintf("%10.2f",$self->charged) ];
 746   push @buf,['',''];
 747
 748   push @buf,['','-----------'];
 749   push @buf,['Total Charges',
 750              $money_char. sprintf("%10.2f",$self->charged + $pr_total) ];
 751   push @buf,['',''];
 752
 753   foreach ( $self->cust_bill_pay ) {
 754
 755     #something more elaborate if $_->amount ne ->cust_pay->paid ?
 756
 757     push @buf,[
 758       "Payment received ". time2str("%x",$_->cust_pay->_date ),
 759       $money_char. sprintf("%10.2f",$_->amount )
 760     ];
 761   }
 762
 763   #balance due
 764   push @buf,['','-----------'];
 765   push @buf,['Balance Due', $money_char.
 766     sprintf("%10.2f", $balance_due ) ];
 767
 768   #create the template
 769   my $templatefile = 'invoice_template';
 770   $templatefile .= "_$template" if $template;
 771   my @invoice_template = $conf->config($templatefile)
 772   or die "cannot load config file $templatefile";
 773   $invoice_lines = 0;
 774   my $wasfunc = 0;
 775   foreach ( grep /invoice_lines\(\d*\)/, @invoice_template ) { #kludgy
 776     /invoice_lines\((\d*)\)/;
 777     $invoice_lines += $1 || scalar(@buf);
 778     $wasfunc=1;
 779   }
 780   die "no invoice_lines() functions in template?" unless $wasfunc;
 781   my $invoice_template = new Text::Template (
 782     TYPE   => 'ARRAY',
 783     SOURCE => [ map "$_\n", @invoice_template ],
 784   ) or die "can't create new Text::Template object: $Text::Template::ERROR";
 785   $invoice_template->compile()
 786     or die "can't compile template: $Text::Template::ERROR";
 787
 788   #setup template variables
 789   package FS::cust_bill::_template; #!
 790   use vars qw( $invnum $date $page $total_pages @address $overdue @buf $agent );
 791
 792   $invnum = $self->invnum;
 793   $date = $self->_date;
 794   $page = 1;
 795   $agent = $self->cust_main->agent->agent;
 796
 797   if ( $FS::cust_bill::invoice_lines ) {
 798     $total_pages =
 799       int( scalar(@FS::cust_bill::buf) / $FS::cust_bill::invoice_lines );
 800     $total_pages++
 801       if scalar(@FS::cust_bill::buf) % $FS::cust_bill::invoice_lines;
 802   } else {
 803     $total_pages = 1;
 804   }
 805
 806   #format address (variable for the template)
 807   my $l = 0;
 808   @address = ( '', '', '', '', '', '' );
 809   package FS::cust_bill; #!
 810   $FS::cust_bill::_template::address[$l++] =
 811     $cust_main->payname.
 812       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
 813         ? " (P.O. #". $cust_main->payinfo. ")"
 814         : ''
 815       )
 816   ;
 817   $FS::cust_bill::_template::address[$l++] = $cust_main->company
 818     if $cust_main->company;
 819   $FS::cust_bill::_template::address[$l++] = $cust_main->address1;
 820   $FS::cust_bill::_template::address[$l++] = $cust_main->address2
 821     if $cust_main->address2;
 822   $FS::cust_bill::_template::address[$l++] =
 823     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 824   $FS::cust_bill::_template::address[$l++] = $cust_main->country
 825     unless $cust_main->country eq 'US';
 826
 827         #  #overdue? (variable for the template)
 828         #  $FS::cust_bill::_template::overdue = (
 829         #    $balance_due > 0
 830         #    && $today > $self->_date
 831         ##    && $self->printed > 1
 832         #    && $self->printed > 0
 833         #  );
 834
 835   #and subroutine for the template
 836   sub FS::cust_bill::_template::invoice_lines {
 837     my $lines = shift || scalar(@buf);
 838     map {
 839       scalar(@buf) ? shift @buf : [ '', '' ];
 840     }
 841     ( 1 .. $lines );
 842   }
 843
 844   #and fill it in
 845   $FS::cust_bill::_template::page = 1;
 846   my $lines;
 847   my @collect;
 848   while (@buf) {
 849     push @collect, split("\n",
 850       $invoice_template->fill_in( PACKAGE => 'FS::cust_bill::_template' )
 851     );
 852     $FS::cust_bill::_template::page++;
 853   }
 854
 855   map "$_\n", @collect;
 856
 857 }
 858
 859 =item print_ps [ TIME [ , TEMPLATE ] ]
 860
 861 Returns an postscript invoice, as a scalar.
 862
 863 TIME an optional value used to control the printing of overdue messages.  The
 864 default is now.  It isn't the date of the invoice; that's the `_date' field.
 865 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 866 L<Time::Local> and L<Date::Parse> for conversion functions.
 867
 868 =cut
 869
 870 #still some false laziness w/print_text
 871 sub print_ps {
 872
 873   my( $self, $today, $template ) = @_;
 874   $today ||= time;
 875
 876 #  my $invnum = $self->invnum;
 877   my $cust_main = $self->cust_main;
 878   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
 879     unless $cust_main->payname && $cust_main->payby ne 'CHEK';
 880
 881   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 882 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 883   #my $balance_due = $self->owed + $pr_total - $cr_total;
 884   my $balance_due = $self->owed + $pr_total;
 885
 886   #my @collect = ();
 887   #my($description,$amount);
 888   @buf = ();
 889
 890   #create the template
 891   my $templatefile = 'invoice_template_latex';
 892   $templatefile .= "_$template" if $template;
 893   my @invoice_template = $conf->config($templatefile)
 894     or die "cannot load config file $templatefile";
 895
 896   my %invoice_data = (
 897     'invnum'   => $self->invnum,
 898     'date'     => time2str('%b %o, %Y', $self->_date),
 899     'agent'    => $cust_main->agent->agent,
 900     'payname'  => $cust_main->payname,
 901     'company'  => $cust_main->company,
 902     'address1' => $cust_main->address1,
 903     'address2' => $cust_main->address2,
 904     'city'     => $cust_main->city,
 905     'state'    => $cust_main->state,
 906     'zip'      => $cust_main->zip,
 907     'country'  => $cust_main->country,
 908     'footer'   => <<'END', #should come from config value
 909 Ivan Kohler\\
 910 1339 Hayes St.\\
 911 San Francisco, CA~~94117\\
 912 ivan@sisd.com~~~~+1 415 462 1624\\
 913 Freeside - open-source billing - http://www.sisd.com/freeside\\
 914 END
 915
 916     'quantity'     => 1,
 917
 918   );
 919
 920   #$invoice_data{'footer'} =~ s/\n+$//;
 921
 922   my $countrydefault = $conf->config('countrydefault') || 'US';
 923   $invoice_data{'country'} = '' if $invoice_data{'country'} eq $countrydefault;
 924
 925   $invoice_data{'po_line'} =
 926     (  $cust_main->payby eq 'BILL' && $cust_main->payinfo )
 927       ? "Purchase Order #". $cust_main->payinfo
 928       : '~';
 929
 930   my @line_item = ();
 931   my @total_item = ();
 932   my @filled_in = ();
 933   while ( @invoice_template ) {
 934     my $line = shift @invoice_template;
 935
 936     if ( $line =~ /^%%Detail\s*$/ ) {
 937
 938       while ( ( my $line_item_line = shift @invoice_template )
 939               !~ /^%%EndDetail\s*$/                            ) {
 940         push @line_item, $line_item_line;
 941       }
 942       #foreach my $line_item ( $self->_items ) {
 943       foreach my $line_item ( $self->_items_pkg ) {
 944         $invoice_data{'ref'} = $line_item->{'pkgnum'};
 945         $invoice_data{'description'} = $line_item->{'description'};
 946         if ( exists $line_item->{'ext_description'} ) {
 947           $invoice_data{'description'} .=
 948             "\\tabularnewline\n~~".
 949             join("\\tabularnewline\n~~", @{$line_item->{'ext_description'}} );
 950         }
 951         $invoice_data{'amount'} = $line_item->{'amount'};
 952         $invoice_data{'product_code'} = $line_item->{'pkgpart'} || 'N/A';
 953         push @filled_in,
 954           map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b } @line_item;
 955       }
 956
 957     } elsif ( $line =~ /^%%TotalDetails\s*$/ ) {
 958
 959       while ( ( my $total_item_line = shift @invoice_template )
 960               !~ /^%%EndTotalDetails\s*$/                      ) {
 961         push @total_item, $total_item_line;
 962       }
 963
 964       my @total_fill = ();
 965
 966       my $taxtotal = 0;
 967       foreach my $tax ( $self->_items_tax ) {
 968         $invoice_data{'total_item'} = $tax->{'description'};
 969         $taxtotal += ( $invoice_data{'total_amount'} = $tax->{'amount'} );
 970         push @total_fill,
 971           map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b }
 972               @total_item;
 973       }
 974
 975       $invoice_data{'total_item'} = '\textbf{Total}';
 976       $invoice_data{'total_amount'} =
 977         '\textbf{\dollar '. sprintf('%.2f', $self->owed ). '}';
 978       push @total_fill,
 979         map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b }
 980             @total_item;
 981
 982       if ( $taxtotal ) {
 983         $invoice_data{'total_item'} = 'Sub-total';
 984         $invoice_data{'total_amount'} =
 985           '\dollar '. sprintf('%.2f', $self->owed - $taxtotal );
 986         unshift @total_fill,
 987           map { my $b=$_; $b =~ s/\$(\w+)/$invoice_data{$1}/eg; $b }
 988               @total_item;
 989       }
 990
 991       push @filled_in, @total_fill;
 992
 993     } else {
 994       #$line =~ s/\$(\w+)/$invoice_data{$1}/eg;
 995       $line =~ s/\$(\w+)/exists($invoice_data{$1}) ? $invoice_data{$1} : nounder($1)/eg;
 996       push @filled_in, $line;
 997     }
 998
 999   }
1000
1001   sub nounder {
1002     my $var = $1;
1003     $var =~ s/_/\-/g;
1004     $var;
1005   }
1006
1007   my $dir = '/tmp'; #! /usr/local/etc/freeside/invoices.datasrc/
1008   my $unique = int(rand(2**31)); #UGH... use File::Temp or something
1009
1010   chdir($dir);
1011   my $file = $self->invnum. ".$unique";
1012
1013   open(TEX,">$file.tex") or die "can't open $file.tex: $!\n";
1014   print TEX join("\n", @filled_in ), "\n";
1015   close TEX;
1016
1017   #error checking!!
1018   system('pslatex', "$file.tex");
1019   system('pslatex', "$file.tex");
1020   #system('dvips', '-t', 'letter', "$file.dvi", "$file.ps");
1021   system('dvips', '-t', 'letter', "$file.dvi" );
1022
1023   open(POSTSCRIPT, "<$file.ps") or die "can't open $file.ps: $!\n";
1024
1025   #rm $file.dvi $file.log $file.aux
1026   #unlink("$file.dvi", "$file.log", "$file.aux", "$file.ps");
1027   unlink("$file.dvi", "$file.log", "$file.aux");
1028
1029   my $ps = '';
1030   while (<POSTSCRIPT>) {
1031     $ps .= $_;
1032   }
1033
1034   close POSTSCRIPT;
1035
1036   return $ps;
1037
1038 }
1039
1040 #utility methods for print_*
1041
1042 sub _items {
1043   my $self = shift;
1044   my @display = scalar(@_)
1045                 ? @_
1046                 : qw( _items_pkg );
1047                 #: qw( _items_previous _items_pkg _items_tax _items_credits _items_payments );
1048   my @b = ();
1049   foreach my $display ( @display ) {
1050     push @b, $self->$display(@_);
1051   }
1052   @b;
1053 }
1054
1055 sub _items_previous {
1056   my $self = shift;
1057   my $cust_main = $self->cust_main;
1058   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
1059   my @b = ();
1060   foreach ( @pr_cust_bill ) {
1061     push @b, [
1062       "Previous Balance, Invoice #". $_->invnum.
1063                  " (". time2str("%x",$_->_date). ")",
1064       $money_char. sprintf("%10.2f",$_->owed)
1065     ];
1066   }
1067   @b;
1068 }
1069
1070 sub _items_pkg {
1071   my $self = shift;
1072   my @cust_bill_pkg = grep { $_->pkgnum } $self->cust_bill_pkg;
1073   $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
1074 }
1075
1076 sub _items_tax {
1077   my $self = shift;
1078   my @cust_bill_pkg = grep { ! $_->pkgnum } $self->cust_bill_pkg;
1079   $self->_items_cust_bill_pkg(\@cust_bill_pkg, @_);
1080 }
1081
1082 sub _items_cust_bill_pkg {
1083   my $self = shift;
1084   my $cust_bill_pkg = shift;
1085
1086   my @b = ();
1087   foreach my $cust_bill_pkg ( @$cust_bill_pkg ) {
1088
1089     if ( $cust_bill_pkg->pkgnum ) {
1090
1091       my $cust_pkg = qsearchs('cust_pkg', { pkgnum =>$cust_bill_pkg->pkgnum } );
1092       my $part_pkg = qsearchs('part_pkg', { pkgpart=>$cust_pkg->pkgpart } );
1093       my $pkg = $part_pkg->pkg;
1094
1095       if ( $cust_bill_pkg->setup != 0 ) {
1096         my @d = ();
1097         @d = $cust_bill_pkg->details if $cust_bill_pkg->recur == 0;
1098         push @b, {
1099           'description'     => "$pkg Setup",
1100           'pkgpart'         => $part_pkg->pkgpart,
1101           'pkgnum'          => $cust_pkg->pkgnum,
1102           'amount'          => sprintf("%10.2f", $cust_bill_pkg->setup),
1103           'ext_description' => [ ( map { $_->[0]. ": ". $_->[1] }
1104                                          $cust_pkg->labels        ),
1105                                  @d,
1106                                ],
1107         };
1108       }
1109
1110       if ( $cust_bill_pkg->recur != 0 ) {
1111         push @b, {
1112           'description'     => "$pkg (" .
1113                                time2str('%x', $cust_bill_pkg->sdate). ' - '.
1114                                time2str('%x', $cust_bill_pkg->edate). ')',
1115           'pkgpart'         => $part_pkg->pkgpart,
1116           'pkgnum'          => $cust_pkg->pkgnum,
1117           'amount'          => sprintf("%10.2f", $cust_bill_pkg->recur),
1118           'ext_description' => [ ( map { $_->[0]. ": ". $_->[1] }
1119                                        $cust_pkg->labels          ),
1120                                  $cust_bill_pkg->details,
1121                                ],
1122         };
1123       }
1124
1125     } else { #pkgnum tax or one-shot line item (??)
1126
1127       my $itemdesc = defined $cust_bill_pkg->dbdef_table->column('itemdesc')
1128                      ? ( $cust_bill_pkg->itemdesc || 'Tax' )
1129                      : 'Tax';
1130       if ( $cust_bill_pkg->setup != 0 ) {
1131         push @b, {
1132           'description' => $itemdesc,
1133           'amount'      => sprintf("%10.2f", $cust_bill_pkg->setup),
1134         };
1135       }
1136       if ( $cust_bill_pkg->recur != 0 ) {
1137         push @b, {
1138           'description' => "$itemdesc (".
1139                            time2str("%x", $cust_bill_pkg->sdate). ' - '.
1140                            time2str("%x", $cust_bill_pkg->edate). ')',
1141           'amount'      => sprintf("%10.2f", $cust_bill_pkg->recur),
1142         };
1143       }
1144
1145     }
1146
1147   }
1148
1149   @b;
1150
1151 }
1152
1153 sub _items_credits {
1154   my $self = shift;
1155
1156   my @b;
1157   #credits
1158   foreach ( $self->cust_credited ) {
1159
1160     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
1161
1162     my $reason = substr($_->cust_credit->reason,0,32);
1163     $reason .= '...' if length($reason) < length($_->cust_credit->reason);
1164     $reason = " ($reason) " if $reason;
1165     push @b,[
1166       "Credit #". $_->crednum. " (". time2str("%x",$_->cust_credit->_date) .")".
1167         $reason,
1168       $money_char. sprintf("%10.2f",$_->amount)
1169     ];
1170   }
1171   #foreach ( @cr_cust_credit ) {
1172   #  push @buf,[
1173   #    "Credit #". $_->crednum. " (" . time2str("%x",$_->_date) .")",
1174   #    $money_char. sprintf("%10.2f",$_->credited)
1175   #  ];
1176   #}
1177
1178   @b;
1179
1180 }
1181
1182 sub _items_payments {
1183   my $self = shift;
1184
1185   my @b;
1186   #get & print payments
1187   foreach ( $self->cust_bill_pay ) {
1188
1189     #something more elaborate if $_->amount ne ->cust_pay->paid ?
1190
1191     push @b,[
1192       "Payment received ". time2str("%x",$_->cust_pay->_date ),
1193       $money_char. sprintf("%10.2f",$_->amount )
1194     ];
1195   }
1196
1197   @b;
1198
1199 }
1200
1201 =back
1202
1203 =head1 BUGS
1204
1205 The delete method.
1206
1207 print_text formatting (and some logic :/) is in source, but needs to be
1208 slurped in from a file.  Also number of lines ($=).
1209
1210 missing print_ps for a nice postscript copy (maybe HylaFAX-cover-page-style
1211 or something similar so the look can be completely customized?)
1212
1213 =head1 SEE ALSO
1214
1215 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill_pay>, L<FS::cust_pay>,
1216 L<FS::cust_bill_pkg>, L<FS::cust_bill_credit>, schema.html from the base
1217 documentation.
1218
1219 =cut
1220
1221 1;
1222