FS/FS/cust_bill.pm

   1 package FS::cust_bill;
   2
   3 use strict;
   4 use vars qw( @ISA $conf $money_char );
   5 use vars qw( $lpr $invoice_from $smtpmachine );
   6 use vars qw( $processor );
   7 use vars qw( $xaction $E_NoErr );
   8 use vars qw( $bop_processor $bop_login $bop_password $bop_action @bop_options );
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use Date::Format;
  11 use Mail::Internet;
  12 use Mail::Header;
  13 use Text::Template;
  14 use FS::Record qw( qsearch qsearchs );
  15 use FS::cust_main;
  16 use FS::cust_bill_pkg;
  17 use FS::cust_credit;
  18 use FS::cust_pay;
  19 use FS::cust_pkg;
  20 use FS::cust_credit_bill;
  21 use FS::cust_pay_batch;
  22 use FS::cust_bill_event;
  23
  24 @ISA = qw( FS::Record );
  25
  26 #ask FS::UID to run this stuff for us later
  27 $FS::UID::callback{'FS::cust_bill'} = sub {
  28
  29   $conf = new FS::Conf;
  30
  31   $money_char = $conf->config('money_char') || '$';
  32
  33   $lpr = $conf->config('lpr');
  34   $invoice_from = $conf->config('invoice_from');
  35   $smtpmachine = $conf->config('smtpmachine');
  36
  37   if ( $conf->exists('cybercash3.2') ) {
  38     require CCMckLib3_2;
  39       #qw($MCKversion %Config InitConfig CCError CCDebug CCDebug2);
  40     require CCMckDirectLib3_2;
  41       #qw(SendCC2_1Server);
  42     require CCMckErrno3_2;
  43       #qw(MCKGetErrorMessage $E_NoErr);
  44     import CCMckErrno3_2 qw($E_NoErr);
  45
  46     my $merchant_conf;
  47     ($merchant_conf,$xaction)= $conf->config('cybercash3.2');
  48     my $status = &CCMckLib3_2::InitConfig($merchant_conf);
  49     if ( $status != $E_NoErr ) {
  50       warn "CCMckLib3_2::InitConfig error:\n";
  51       foreach my $key (keys %CCMckLib3_2::Config) {
  52         warn "  $key => $CCMckLib3_2::Config{$key}\n"
  53       }
  54       my($errmsg) = &CCMckErrno3_2::MCKGetErrorMessage($status);
  55       die "CCMckLib3_2::InitConfig fatal error: $errmsg\n";
  56     }
  57     $processor='cybercash3.2';
  58   } elsif ( $conf->exists('business-onlinepayment') ) {
  59     ( $bop_processor,
  60       $bop_login,
  61       $bop_password,
  62       $bop_action,
  63       @bop_options
  64     ) = $conf->config('business-onlinepayment');
  65     $bop_action ||= 'normal authorization';
  66     eval "use Business::OnlinePayment";
  67     $processor="Business::OnlinePayment::$bop_processor";
  68   }
  69
  70 };
  71
  72 =head1 NAME
  73
  74 FS::cust_bill - Object methods for cust_bill records
  75
  76 =head1 SYNOPSIS
  77
  78   use FS::cust_bill;
  79
  80   $record = new FS::cust_bill \%hash;
  81   $record = new FS::cust_bill { 'column' => 'value' };
  82
  83   $error = $record->insert;
  84
  85   $error = $new_record->replace($old_record);
  86
  87   $error = $record->delete;
  88
  89   $error = $record->check;
  90
  91   ( $total_previous_balance, @previous_cust_bill ) = $record->previous;
  92
  93   @cust_bill_pkg_objects = $cust_bill->cust_bill_pkg;
  94
  95   ( $total_previous_credits, @previous_cust_credit ) = $record->cust_credit;
  96
  97   @cust_pay_objects = $cust_bill->cust_pay;
  98
  99   $tax_amount = $record->tax;
 100
 101   @lines = $cust_bill->print_text;
 102   @lines = $cust_bill->print_text $time;
 103
 104 =head1 DESCRIPTION
 105
 106 An FS::cust_bill object represents an invoice; a declaration that a customer
 107 owes you money.  The specific charges are itemized as B<cust_bill_pkg> records
 108 (see L<FS::cust_bill_pkg>).  FS::cust_bill inherits from FS::Record.  The
 109 following fields are currently supported:
 110
 111 =over 4
 112
 113 =item invnum - primary key (assigned automatically for new invoices)
 114
 115 =item custnum - customer (see L<FS::cust_main>)
 116
 117 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 118 L<Time::Local> and L<Date::Parse> for conversion functions.
 119
 120 =item charged - amount of this invoice
 121
 122 =item printed - deprecated
 123
 124 =item closed - books closed flag, empty or `Y'
 125
 126 =back
 127
 128 =head1 METHODS
 129
 130 =over 4
 131
 132 =item new HASHREF
 133
 134 Creates a new invoice.  To add the invoice to the database, see L<"insert">.
 135 Invoices are normally created by calling the bill method of a customer object
 136 (see L<FS::cust_main>).
 137
 138 =cut
 139
 140 sub table { 'cust_bill'; }
 141
 142 =item insert
 143
 144 Adds this invoice to the database ("Posts" the invoice).  If there is an error,
 145 returns the error, otherwise returns false.
 146
 147 =item delete
 148
 149 Currently unimplemented.  I don't remove invoices because there would then be
 150 no record you ever posted this invoice (which is bad, no?)
 151
 152 =cut
 153
 154 sub delete {
 155   my $self = shift;
 156   return "Can't delete closed invoice" if $self->closed =~ /^Y/i;
 157   $self->SUPER::delete(@_);
 158 }
 159
 160 =item replace OLD_RECORD
 161
 162 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 163 returns the error, otherwise returns false.
 164
 165 Only printed may be changed.  printed is normally updated by calling the
 166 collect method of a customer object (see L<FS::cust_main>).
 167
 168 =cut
 169
 170 sub replace {
 171   my( $new, $old ) = ( shift, shift );
 172   return "Can't change custnum!" unless $old->custnum == $new->custnum;
 173   #return "Can't change _date!" unless $old->_date eq $new->_date;
 174   return "Can't change _date!" unless $old->_date == $new->_date;
 175   return "Can't change charged!" unless $old->charged == $new->charged;
 176
 177   $new->SUPER::replace($old);
 178 }
 179
 180 =item check
 181
 182 Checks all fields to make sure this is a valid invoice.  If there is an error,
 183 returns the error, otherwise returns false.  Called by the insert and replace
 184 methods.
 185
 186 =cut
 187
 188 sub check {
 189   my $self = shift;
 190
 191   my $error =
 192     $self->ut_numbern('invnum')
 193     || $self->ut_number('custnum')
 194     || $self->ut_numbern('_date')
 195     || $self->ut_money('charged')
 196     || $self->ut_numbern('printed')
 197     || $self->ut_enum('closed', [ '', 'Y' ])
 198   ;
 199   return $error if $error;
 200
 201   return "Unknown customer"
 202     unless qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 203
 204   $self->_date(time) unless $self->_date;
 205
 206   $self->printed(0) if $self->printed eq '';
 207
 208   ''; #no error
 209 }
 210
 211 =item previous
 212
 213 Returns a list consisting of the total previous balance for this customer,
 214 followed by the previous outstanding invoices (as FS::cust_bill objects also).
 215
 216 =cut
 217
 218 sub previous {
 219   my $self = shift;
 220   my $total = 0;
 221   my @cust_bill = sort { $a->_date <=> $b->_date }
 222     grep { $_->owed != 0 && $_->_date < $self->_date }
 223       qsearch( 'cust_bill', { 'custnum' => $self->custnum } )
 224   ;
 225   foreach ( @cust_bill ) { $total += $_->owed; }
 226   $total, @cust_bill;
 227 }
 228
 229 =item cust_bill_pkg
 230
 231 Returns the line items (see L<FS::cust_bill_pkg>) for this invoice.
 232
 233 =cut
 234
 235 sub cust_bill_pkg {
 236   my $self = shift;
 237   qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum } );
 238 }
 239
 240 =item cust_bill_event
 241
 242 Returns the completed invoice events (see L<FS::cust_bill_event>) for this
 243 invoice.
 244
 245 =cut
 246
 247 sub cust_bill_event {
 248   my $self = shift;
 249   qsearch( 'cust_bill_event', { 'invnum' => $self->invnum } );
 250 }
 251
 252
 253 =item cust_main
 254
 255 Returns the customer (see L<FS::cust_main>) for this invoice.
 256
 257 =cut
 258
 259 sub cust_main {
 260   my $self = shift;
 261   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 262 }
 263
 264 =item cust_credit
 265
 266 Depreciated.  See the cust_credited method.
 267
 268  #Returns a list consisting of the total previous credited (see
 269  #L<FS::cust_credit>) and unapplied for this customer, followed by the previous
 270  #outstanding credits (FS::cust_credit objects).
 271
 272 =cut
 273
 274 sub cust_credit {
 275   use Carp;
 276   croak "FS::cust_bill->cust_credit depreciated; see ".
 277         "FS::cust_bill->cust_credit_bill";
 278   #my $self = shift;
 279   #my $total = 0;
 280   #my @cust_credit = sort { $a->_date <=> $b->_date }
 281   #  grep { $_->credited != 0 && $_->_date < $self->_date }
 282   #    qsearch('cust_credit', { 'custnum' => $self->custnum } )
 283   #;
 284   #foreach (@cust_credit) { $total += $_->credited; }
 285   #$total, @cust_credit;
 286 }
 287
 288 =item cust_pay
 289
 290 Depreciated.  See the cust_bill_pay method.
 291
 292 #Returns all payments (see L<FS::cust_pay>) for this invoice.
 293
 294 =cut
 295
 296 sub cust_pay {
 297   use Carp;
 298   croak "FS::cust_bill->cust_pay depreciated; see FS::cust_bill->cust_bill_pay";
 299   #my $self = shift;
 300   #sort { $a->_date <=> $b->_date }
 301   #  qsearch( 'cust_pay', { 'invnum' => $self->invnum } )
 302   #;
 303 }
 304
 305 =item cust_bill_pay
 306
 307 Returns all payment applications (see L<FS::cust_bill_pay>) for this invoice.
 308
 309 =cut
 310
 311 sub cust_bill_pay {
 312   my $self = shift;
 313   sort { $a->_date <=> $b->_date }
 314     qsearch( 'cust_bill_pay', { 'invnum' => $self->invnum } );
 315 }
 316
 317 =item cust_credited
 318
 319 Returns all applied credits (see L<FS::cust_credit_bill>) for this invoice.
 320
 321 =cut
 322
 323 sub cust_credited {
 324   my $self = shift;
 325   sort { $a->_date <=> $b->_date }
 326     qsearch( 'cust_credit_bill', { 'invnum' => $self->invnum } )
 327   ;
 328 }
 329
 330 =item tax
 331
 332 Returns the tax amount (see L<FS::cust_bill_pkg>) for this invoice.
 333
 334 =cut
 335
 336 sub tax {
 337   my $self = shift;
 338   my $total = 0;
 339   my @taxlines = qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum ,
 340                                              'pkgnum' => 0 } );
 341   foreach (@taxlines) { $total += $_->setup; }
 342   $total;
 343 }
 344
 345 =item owed
 346
 347 Returns the amount owed (still outstanding) on this invoice, which is charged
 348 minus all payment applications (see L<FS::cust_bill_pay>) and credit
 349 applications (see L<FS::cust_credit_bill>).
 350
 351 =cut
 352
 353 sub owed {
 354   my $self = shift;
 355   my $balance = $self->charged;
 356   $balance -= $_->amount foreach ( $self->cust_bill_pay );
 357   $balance -= $_->amount foreach ( $self->cust_credited );
 358   $balance = sprintf( "%.2f", $balance);
 359   $balance =~ s/^\-0\.00$/0.00/; #yay ieee fp
 360   $balance;
 361 }
 362
 363 =item send
 364
 365 Sends this invoice to the destinations configured for this customer: send
 366 emails or print.  See L<FS::cust_main_invoice>.
 367
 368 =cut
 369
 370 sub send {
 371   my($self,$template) = @_;
 372
 373   #my @print_text = $cust_bill->print_text; #( date )
 374   my @invoicing_list = $self->cust_main->invoicing_list;
 375   if ( grep { $_ ne 'POST' } @invoicing_list ) { #email invoice
 376     #false laziness w/FS::cust_pay::delete & fs_signup_server && ::realtime_card
 377     #$ENV{SMTPHOSTS} = $smtpmachine;
 378     $ENV{MAILADDRESS} = $invoice_from;
 379     my $header = new Mail::Header ( [
 380       "From: $invoice_from",
 381       "To: ". join(', ', grep { $_ ne 'POST' } @invoicing_list ),
 382       "Sender: $invoice_from",
 383       "Reply-To: $invoice_from",
 384       "Date: ". time2str("%a, %d %b %Y %X %z", time),
 385       "Subject: Invoice",
 386     ] );
 387     my $message = new Mail::Internet (
 388       'Header' => $header,
 389       'Body' => [ $self->print_text('', $template) ], #( date)
 390     );
 391     $!=0;
 392     $message->smtpsend( Host => $smtpmachine )
 393       or $message->smtpsend( Host => $smtpmachine, Debug => 1 )
 394         or return "(customer # ". $self->custnum. ") can't send invoice email".
 395                   " to ". join(', ', grep { $_ ne 'POST' } @invoicing_list ).
 396                   " via server $smtpmachine with SMTP: $!";
 397
 398   #} elsif ( grep { $_ eq 'POST' } @invoicing_list ) {
 399   } elsif ( ! @invoicing_list || grep { $_ eq 'POST' } @invoicing_list ) {
 400     open(LPR, "|$lpr")
 401       or return "Can't open pipe to $lpr: $!";
 402     print LPR $self->print_text; #( date )
 403     close LPR
 404       or return $! ? "Error closing $lpr: $!"
 405                    : "Exit status $? from $lpr";
 406   }
 407
 408   '';
 409
 410 }
 411
 412 =item comp
 413
 414 Pays this invoice with a compliemntary payment.  If there is an error,
 415 returns the error, otherwise returns false.
 416
 417 =cut
 418
 419 sub comp {
 420   my $self = shift;
 421   my $cust_pay = new FS::cust_pay ( {
 422     'invnum'   => $self->invnum,
 423     'paid'     => $self->owed,
 424     '_date'    => '',
 425     'payby'    => 'COMP',
 426     'payinfo'  => $self->cust_main->payinfo,
 427     'paybatch' => '',
 428   } );
 429   $cust_pay->insert;
 430 }
 431
 432 =item realtime_card
 433
 434 Attempts to pay this invoice with a Business::OnlinePayment realtime gateway.
 435 See http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
 436 for supproted processors.
 437
 438 =cut
 439
 440 sub realtime_card {
 441   my $self = shift;
 442   my $cust_main = $self->cust_main;
 443   my $amount = $self->owed;
 444
 445   unless ( $processor =~ /^Business::OnlinePayment::(.*)$/ ) {
 446     return "Real-time card processing not enabled (processor $processor)";
 447   }
 448   my $bop_processor = $1; #hmm?
 449
 450   my $address = $cust_main->address1;
 451   $address .= ", ". $cust_main->address2 if $cust_main->address2;
 452
 453   #fix exp. date
 454   #$cust_main->paydate =~ /^(\d+)\/\d*(\d{2})$/;
 455   $cust_main->paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
 456   my $exp = "$2/$1";
 457
 458   my($payname, $payfirst, $paylast);
 459   if ( $cust_main->payname ) {
 460     $payname = $cust_main->payname;
 461     $payname =~ /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)$/
 462       or do {
 463               #$dbh->rollback if $oldAutoCommit;
 464               return "Illegal payname $payname";
 465             };
 466     ($payfirst, $paylast) = ($1, $2);
 467   } else {
 468     $payfirst = $cust_main->getfield('first');
 469     $paylast = $cust_main->getfield('first');
 470     $payname =  "$payfirst $paylast";
 471   }
 472
 473   my @invoicing_list = grep { $_ ne 'POST' } $cust_main->invoicing_list;
 474   if ( $conf->exists('emailinvoiceauto')
 475        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
 476     push @invoicing_list, $cust_main->default_invoicing_list;
 477   }
 478   my $email = $invoicing_list[0];
 479
 480   my( $action1, $action2 ) = split(/\s*\,\s*/, $bop_action );
 481
 482   my $description = 'Internet Services';
 483   if ( $conf->exists('business-onlinepayment-description') ) {
 484     my $dtempl = $conf->config('business-onlinepayment-description');
 485
 486     my $agent = $cust_main->agent->agent;
 487     my $pkgs = join(', ',
 488       map { $_->cust_pkg->part_pkg->pkg }
 489         grep { $_->pkgnum } $self->cust_bill_pkg
 490     );
 491     $description = eval qq("$dtempl");
 492
 493   }
 494
 495   my $transaction =
 496     new Business::OnlinePayment( $bop_processor, @bop_options );
 497   $transaction->content(
 498     'type'           => 'CC',
 499     'login'          => $bop_login,
 500     'password'       => $bop_password,
 501     'action'         => $action1,
 502     'description'    => $description,
 503     'amount'         => $amount,
 504     'invoice_number' => $self->invnum,
 505     'customer_id'    => $self->custnum,
 506     'last_name'      => $paylast,
 507     'first_name'     => $payfirst,
 508     'name'           => $payname,
 509     'address'        => $address,
 510     'city'           => $cust_main->city,
 511     'state'          => $cust_main->state,
 512     'zip'            => $cust_main->zip,
 513     'country'        => $cust_main->country,
 514     'card_number'    => $cust_main->payinfo,
 515     'expiration'     => $exp,
 516     'referer'        => 'http://cleanwhisker.420.am/',
 517     'email'          => $email,
 518   );
 519   $transaction->submit();
 520
 521   if ( $transaction->is_success() && $action2 ) {
 522     my $auth = $transaction->authorization;
 523     my $ordernum = $transaction->order_number;
 524     #warn "********* $auth ***********\n";
 525     #warn "********* $ordernum ***********\n";
 526     my $capture =
 527       new Business::OnlinePayment( $bop_processor, @bop_options );
 528
 529     $capture->content(
 530       action         => $action2,
 531       login          => $bop_login,
 532       password       => $bop_password,
 533       order_number   => $ordernum,
 534       amount         => $amount,
 535       authorization  => $auth,
 536       description    => $description,
 537     );
 538
 539     $capture->submit();
 540
 541     unless ( $capture->is_success ) {
 542       my $e = "Authorization sucessful but capture failed, invnum #".
 543               $self->invnum. ': '.  $capture->result_code.
 544               ": ". $capture->error_message;
 545       warn $e;
 546       return $e;
 547     }
 548
 549   }
 550
 551   if ( $transaction->is_success() ) {
 552
 553     my $cust_pay = new FS::cust_pay ( {
 554        'invnum'   => $self->invnum,
 555        'paid'     => $amount,
 556        '_date'     => '',
 557        'payby'    => 'CARD',
 558        'payinfo'  => $cust_main->payinfo,
 559        'paybatch' => "$processor:". $transaction->authorization,
 560     } );
 561     my $error = $cust_pay->insert;
 562     if ( $error ) {
 563       # gah, even with transactions.
 564       my $e = 'WARNING: Card debited but database not updated - '.
 565               'error applying payment, invnum #' . $self->invnum.
 566               " ($processor): $error";
 567       warn $e;
 568       return $e;
 569     } else {
 570       return '';
 571     }
 572   #} elsif ( $options{'report_badcard'} ) {
 573   } else {
 574
 575     my $perror = "$processor error, invnum #". $self->invnum. ': '.
 576                  $transaction->result_code. ": ". $transaction->error_message;
 577
 578     if ( $conf->exists('emaildecline')
 579          && grep { $_ ne 'POST' } $cust_main->invoicing_list
 580     ) {
 581       my @templ = $conf->config('declinetemplate');
 582       my $template = new Text::Template (
 583         TYPE   => 'ARRAY',
 584         SOURCE => [ map "$_\n", @templ ],
 585       ) or return "($perror) can't create template: $Text::Template::ERROR";
 586       $template->compile()
 587         or return "($perror) can't compile template: $Text::Template::ERROR";
 588
 589       my $error = $transaction->error_message;
 590
 591       #false laziness w/FS::cust_pay::delete & fs_signup_server && ::send
 592       $ENV{MAILADDRESS} = $invoice_from;
 593       my $header = new Mail::Header ( [
 594         "From: $invoice_from",
 595         "To: ". join(', ', grep { $_ ne 'POST' } $cust_main->invoicing_list ),
 596         "Sender: $invoice_from",
 597         "Reply-To: $invoice_from",
 598         "Date: ". time2str("%a, %d %b %Y %X %z", time),
 599         "Subject: Your credit card could not be processed",
 600       ] );
 601       my $message = new Mail::Internet (
 602         'Header' => $header,
 603         'Body' => [ $template->fill_in() ],
 604       );
 605       $!=0;
 606       $message->smtpsend( Host => $smtpmachine )
 607         or $message->smtpsend( Host => $smtpmachine, Debug => 1 )
 608           or return "($perror) (customer # ". $self->custnum.
 609             ") can't send card decline email to ".
 610             join(', ', grep { $_ ne 'POST' } $cust_main->invoicing_list ).
 611             " via server $smtpmachine with SMTP: $!";
 612     }
 613
 614     return $perror;
 615   }
 616
 617 }
 618
 619 =item realtime_card_cybercash
 620
 621 Attempts to pay this invoice with the CyberCash CashRegister realtime gateway.
 622
 623 =cut
 624
 625 sub realtime_card_cybercash {
 626   my $self = shift;
 627   my $cust_main = $self->cust_main;
 628   my $amount = $self->owed;
 629
 630   return "CyberCash CashRegister real-time card processing not enabled!"
 631     unless $processor eq 'cybercash3.2';
 632
 633   my $address = $cust_main->address1;
 634   $address .= ", ". $cust_main->address2 if $cust_main->address2;
 635
 636   #fix exp. date
 637   #$cust_main->paydate =~ /^(\d+)\/\d*(\d{2})$/;
 638   $cust_main->paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
 639   my $exp = "$2/$1";
 640
 641   #
 642
 643   my $paybatch = $self->invnum.
 644                   '-' . time2str("%y%m%d%H%M%S", time);
 645
 646   my $payname = $cust_main->payname ||
 647                 $cust_main->getfield('first').' '.$cust_main->getfield('last');
 648
 649   my $country = $cust_main->country eq 'US' ? 'USA' : $cust_main->country;
 650
 651   my @full_xaction = ( $xaction,
 652     'Order-ID'     => $paybatch,
 653     'Amount'       => "usd $amount",
 654     'Card-Number'  => $cust_main->getfield('payinfo'),
 655     'Card-Name'    => $payname,
 656     'Card-Address' => $address,
 657     'Card-City'    => $cust_main->getfield('city'),
 658     'Card-State'   => $cust_main->getfield('state'),
 659     'Card-Zip'     => $cust_main->getfield('zip'),
 660     'Card-Country' => $country,
 661     'Card-Exp'     => $exp,
 662   );
 663
 664   my %result;
 665   %result = &CCMckDirectLib3_2::SendCC2_1Server(@full_xaction);
 666
 667   if ( $result{'MStatus'} eq 'success' ) { #cybercash smps v.2 or 3
 668     my $cust_pay = new FS::cust_pay ( {
 669        'invnum'   => $self->invnum,
 670        'paid'     => $amount,
 671        '_date'     => '',
 672        'payby'    => 'CARD',
 673        'payinfo'  => $cust_main->payinfo,
 674        'paybatch' => "$processor:$paybatch",
 675     } );
 676     my $error = $cust_pay->insert;
 677     if ( $error ) {
 678       # gah, even with transactions.
 679       my $e = 'WARNING: Card debited but database not updated - '.
 680               'error applying payment, invnum #' . $self->invnum.
 681               " (CyberCash Order-ID $paybatch): $error";
 682       warn $e;
 683       return $e;
 684     } else {
 685       return '';
 686     }
 687 #  } elsif ( $result{'Mstatus'} ne 'failure-bad-money'
 688 #            || $options{'report_badcard'}
 689 #          ) {
 690   } else {
 691      return 'Cybercash error, invnum #' .
 692        $self->invnum. ':'. $result{'MErrMsg'};
 693   }
 694
 695 }
 696
 697 =item batch_card
 698
 699 Adds a payment for this invoice to the pending credit card batch (see
 700 L<FS::cust_pay_batch>).
 701
 702 =cut
 703
 704 sub batch_card {
 705   my $self = shift;
 706   my $cust_main = $self->cust_main;
 707
 708   my $cust_pay_batch = new FS::cust_pay_batch ( {
 709     'invnum'   => $self->getfield('invnum'),
 710     'custnum'  => $cust_main->getfield('custnum'),
 711     'last'     => $cust_main->getfield('last'),
 712     'first'    => $cust_main->getfield('first'),
 713     'address1' => $cust_main->getfield('address1'),
 714     'address2' => $cust_main->getfield('address2'),
 715     'city'     => $cust_main->getfield('city'),
 716     'state'    => $cust_main->getfield('state'),
 717     'zip'      => $cust_main->getfield('zip'),
 718     'country'  => $cust_main->getfield('country'),
 719     'trancode' => 77,
 720     'cardnum'  => $cust_main->getfield('payinfo'),
 721     'exp'      => $cust_main->getfield('paydate'),
 722     'payname'  => $cust_main->getfield('payname'),
 723     'amount'   => $self->owed,
 724   } );
 725   $cust_pay_batch->insert;
 726
 727 }
 728
 729 =item print_text [TIME];
 730
 731 Returns an text invoice, as a list of lines.
 732
 733 TIME an optional value used to control the printing of overdue messages.  The
 734 default is now.  It isn't the date of the invoice; that's the `_date' field.
 735 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 736 L<Time::Local> and L<Date::Parse> for conversion functions.
 737
 738 =cut
 739
 740 sub print_text {
 741
 742   my( $self, $today, $template ) = @_;
 743   $today ||= time;
 744 #  my $invnum = $self->invnum;
 745   my $cust_main = qsearchs('cust_main', { 'custnum', $self->custnum } );
 746   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
 747     unless $cust_main->payname;
 748
 749   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 750 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 751   #my $balance_due = $self->owed + $pr_total - $cr_total;
 752   my $balance_due = $self->owed + $pr_total;
 753
 754   #my @collect = ();
 755   #my($description,$amount);
 756   @buf = ();
 757
 758   #previous balance
 759   foreach ( @pr_cust_bill ) {
 760     push @buf, [
 761       "Previous Balance, Invoice #". $_->invnum.
 762                  " (". time2str("%x",$_->_date). ")",
 763       $money_char. sprintf("%10.2f",$_->owed)
 764     ];
 765   }
 766   if (@pr_cust_bill) {
 767     push @buf,['','-----------'];
 768     push @buf,[ 'Total Previous Balance',
 769                 $money_char. sprintf("%10.2f",$pr_total ) ];
 770     push @buf,['',''];
 771   }
 772
 773   #new charges
 774   foreach ( $self->cust_bill_pkg ) {
 775
 776     if ( $_->pkgnum ) {
 777
 778       my($cust_pkg)=qsearchs('cust_pkg', { 'pkgnum', $_->pkgnum } );
 779       my($part_pkg)=qsearchs('part_pkg',{'pkgpart'=>$cust_pkg->pkgpart});
 780       my($pkg)=$part_pkg->pkg;
 781
 782       if ( $_->setup != 0 ) {
 783         push @buf, [ "$pkg Setup", $money_char. sprintf("%10.2f",$_->setup) ];
 784         push @buf,
 785           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] } $cust_pkg->labels;
 786       }
 787
 788       if ( $_->recur != 0 ) {
 789         push @buf, [
 790           "$pkg (" . time2str("%x",$_->sdate) . " - " .
 791                                 time2str("%x",$_->edate) . ")",
 792           $money_char. sprintf("%10.2f",$_->recur)
 793         ];
 794         push @buf,
 795           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] } $cust_pkg->labels;
 796       }
 797
 798     } else { #pkgnum Tax
 799       push @buf,["Tax", $money_char. sprintf("%10.2f",$_->setup) ]
 800         if $_->setup != 0;
 801     }
 802   }
 803
 804   push @buf,['','-----------'];
 805   push @buf,['Total New Charges',
 806              $money_char. sprintf("%10.2f",$self->charged) ];
 807   push @buf,['',''];
 808
 809   push @buf,['','-----------'];
 810   push @buf,['Total Charges',
 811              $money_char. sprintf("%10.2f",$self->charged + $pr_total) ];
 812   push @buf,['',''];
 813
 814   #credits
 815   foreach ( $self->cust_credited ) {
 816
 817     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
 818
 819     my $reason = substr($_->cust_credit->reason,0,32);
 820     $reason .= '...' if length($reason) < length($_->cust_credit->reason);
 821     $reason = " ($reason) " if $reason;
 822     push @buf,[
 823       "Credit #". $_->crednum. " (". time2str("%x",$_->cust_credit->_date) .")".
 824         $reason,
 825       $money_char. sprintf("%10.2f",$_->amount)
 826     ];
 827   }
 828   #foreach ( @cr_cust_credit ) {
 829   #  push @buf,[
 830   #    "Credit #". $_->crednum. " (" . time2str("%x",$_->_date) .")",
 831   #    $money_char. sprintf("%10.2f",$_->credited)
 832   #  ];
 833   #}
 834
 835   #get & print payments
 836   foreach ( $self->cust_bill_pay ) {
 837
 838     #something more elaborate if $_->amount ne ->cust_pay->paid ?
 839
 840     push @buf,[
 841       "Payment received ". time2str("%x",$_->cust_pay->_date ),
 842       $money_char. sprintf("%10.2f",$_->amount )
 843     ];
 844   }
 845
 846   #balance due
 847   push @buf,['','-----------'];
 848   push @buf,['Balance Due', $money_char.
 849     sprintf("%10.2f", $balance_due ) ];
 850
 851   #create the template
 852   my $templatefile = 'invoice_template';
 853   $templatefile .= "_$template" if $template;
 854   my @invoice_template = $conf->config($templatefile)
 855   or die "cannot load config file $templatefile";
 856   $invoice_lines = 0;
 857   my $wasfunc = 0;
 858   foreach ( grep /invoice_lines\(\d+\)/, @invoice_template ) { #kludgy
 859     /invoice_lines\((\d+)\)/;
 860     $invoice_lines += $1;
 861     $wasfunc=1;
 862   }
 863   die "no invoice_lines() functions in template?" unless $wasfunc;
 864   my $invoice_template = new Text::Template (
 865     TYPE   => 'ARRAY',
 866     SOURCE => [ map "$_\n", @invoice_template ],
 867   ) or die "can't create new Text::Template object: $Text::Template::ERROR";
 868   $invoice_template->compile()
 869     or die "can't compile template: $Text::Template::ERROR";
 870
 871   #setup template variables
 872   package FS::cust_bill::_template; #!
 873   use vars qw( $invnum $date $page $total_pages @address $overdue @buf );
 874
 875   $invnum = $self->invnum;
 876   $date = $self->_date;
 877   $page = 1;
 878
 879   if ( $FS::cust_bill::invoice_lines ) {
 880     $total_pages =
 881       int( scalar(@FS::cust_bill::buf) / $FS::cust_bill::invoice_lines );
 882     $total_pages++
 883       if scalar(@FS::cust_bill::buf) % $FS::cust_bill::invoice_lines;
 884   } else {
 885     $total_pages = 1;
 886   }
 887
 888   #format address (variable for the template)
 889   my $l = 0;
 890   @address = ( '', '', '', '', '', '' );
 891   package FS::cust_bill; #!
 892   $FS::cust_bill::_template::address[$l++] =
 893     $cust_main->payname.
 894       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
 895         ? " (P.O. #". $cust_main->payinfo. ")"
 896         : ''
 897       )
 898   ;
 899   $FS::cust_bill::_template::address[$l++] = $cust_main->company
 900     if $cust_main->company;
 901   $FS::cust_bill::_template::address[$l++] = $cust_main->address1;
 902   $FS::cust_bill::_template::address[$l++] = $cust_main->address2
 903     if $cust_main->address2;
 904   $FS::cust_bill::_template::address[$l++] =
 905     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
 906   $FS::cust_bill::_template::address[$l++] = $cust_main->country
 907     unless $cust_main->country eq 'US';
 908
 909         #  #overdue? (variable for the template)
 910         #  $FS::cust_bill::_template::overdue = (
 911         #    $balance_due > 0
 912         #    && $today > $self->_date
 913         ##    && $self->printed > 1
 914         #    && $self->printed > 0
 915         #  );
 916
 917   #and subroutine for the template
 918
 919   sub FS::cust_bill::_template::invoice_lines {
 920     my $lines = shift or return @buf;
 921     map {
 922       scalar(@buf) ? shift @buf : [ '', '' ];
 923     }
 924     ( 1 .. $lines );
 925   }
 926
 927
 928   #and fill it in
 929   $FS::cust_bill::_template::page = 1;
 930   my $lines;
 931   my @collect;
 932   while (@buf) {
 933     push @collect, split("\n",
 934       $invoice_template->fill_in( PACKAGE => 'FS::cust_bill::_template' )
 935     );
 936     $FS::cust_bill::_template::page++;
 937   }
 938
 939   map "$_\n", @collect;
 940
 941 }
 942
 943 =back
 944
 945 =head1 VERSION
 946
 947 $Id: cust_bill.pm,v 1.30 2002-04-16 22:38:04 ivan Exp $
 948
 949 =head1 BUGS
 950
 951 The delete method.
 952
 953 print_text formatting (and some logic :/) is in source, but needs to be
 954 slurped in from a file.  Also number of lines ($=).
 955
 956 missing print_ps for a nice postscript copy (maybe HylaFAX-cover-page-style
 957 or something similar so the look can be completely customized?)
 958
 959 =head1 SEE ALSO
 960
 961 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill_pay>, L<FS::cust_pay>,
 962 L<FS::cust_bill_pkg>, L<FS::cust_bill_credit>, schema.html from the base
 963 documentation.
 964
 965 =cut
 966
 967 1;
 968