FS/FS/cust_bill.pm

   1 package FS::cust_bill;
   2
   3 use strict;
   4 use vars qw( @ISA $conf $money_char );
   5 use vars qw( $lpr $invoice_from $smtpmachine );
   6 use vars qw( $processor );
   7 use vars qw( $xaction $E_NoErr );
   8 use vars qw( $bop_processor $bop_login $bop_password $bop_action @bop_options );
   9 use vars qw( $invoice_lines @buf ); #yuck
  10 use Date::Format;
  11 use Mail::Internet 1.44;
  12 use Mail::Header;
  13 use Text::Template;
  14 use FS::UID qw( datasrc );
  15 use FS::Record qw( qsearch qsearchs );
  16 use FS::cust_main;
  17 use FS::cust_bill_pkg;
  18 use FS::cust_credit;
  19 use FS::cust_pay;
  20 use FS::cust_pkg;
  21 use FS::cust_credit_bill;
  22 use FS::cust_pay_batch;
  23 use FS::cust_bill_event;
  24
  25 @ISA = qw( FS::Record );
  26
  27 #ask FS::UID to run this stuff for us later
  28 $FS::UID::callback{'FS::cust_bill'} = sub {
  29
  30   $conf = new FS::Conf;
  31
  32   $money_char = $conf->config('money_char') || '$';
  33
  34   $lpr = $conf->config('lpr');
  35   $invoice_from = $conf->config('invoice_from');
  36   $smtpmachine = $conf->config('smtpmachine');
  37
  38   if ( $conf->exists('cybercash3.2') ) {
  39     require CCMckLib3_2;
  40       #qw($MCKversion %Config InitConfig CCError CCDebug CCDebug2);
  41     require CCMckDirectLib3_2;
  42       #qw(SendCC2_1Server);
  43     require CCMckErrno3_2;
  44       #qw(MCKGetErrorMessage $E_NoErr);
  45     import CCMckErrno3_2 qw($E_NoErr);
  46
  47     my $merchant_conf;
  48     ($merchant_conf,$xaction)= $conf->config('cybercash3.2');
  49     my $status = &CCMckLib3_2::InitConfig($merchant_conf);
  50     if ( $status != $E_NoErr ) {
  51       warn "CCMckLib3_2::InitConfig error:\n";
  52       foreach my $key (keys %CCMckLib3_2::Config) {
  53         warn "  $key => $CCMckLib3_2::Config{$key}\n"
  54       }
  55       my($errmsg) = &CCMckErrno3_2::MCKGetErrorMessage($status);
  56       die "CCMckLib3_2::InitConfig fatal error: $errmsg\n";
  57     }
  58     $processor='cybercash3.2';
  59   } elsif ( $conf->exists('business-onlinepayment') ) {
  60     ( $bop_processor,
  61       $bop_login,
  62       $bop_password,
  63       $bop_action,
  64       @bop_options
  65     ) = $conf->config('business-onlinepayment');
  66     $bop_action ||= 'normal authorization';
  67     eval "use Business::OnlinePayment";
  68     $processor="Business::OnlinePayment::$bop_processor";
  69   }
  70
  71 };
  72
  73 =head1 NAME
  74
  75 FS::cust_bill - Object methods for cust_bill records
  76
  77 =head1 SYNOPSIS
  78
  79   use FS::cust_bill;
  80
  81   $record = new FS::cust_bill \%hash;
  82   $record = new FS::cust_bill { 'column' => 'value' };
  83
  84   $error = $record->insert;
  85
  86   $error = $new_record->replace($old_record);
  87
  88   $error = $record->delete;
  89
  90   $error = $record->check;
  91
  92   ( $total_previous_balance, @previous_cust_bill ) = $record->previous;
  93
  94   @cust_bill_pkg_objects = $cust_bill->cust_bill_pkg;
  95
  96   ( $total_previous_credits, @previous_cust_credit ) = $record->cust_credit;
  97
  98   @cust_pay_objects = $cust_bill->cust_pay;
  99
 100   $tax_amount = $record->tax;
 101
 102   @lines = $cust_bill->print_text;
 103   @lines = $cust_bill->print_text $time;
 104
 105 =head1 DESCRIPTION
 106
 107 An FS::cust_bill object represents an invoice; a declaration that a customer
 108 owes you money.  The specific charges are itemized as B<cust_bill_pkg> records
 109 (see L<FS::cust_bill_pkg>).  FS::cust_bill inherits from FS::Record.  The
 110 following fields are currently supported:
 111
 112 =over 4
 113
 114 =item invnum - primary key (assigned automatically for new invoices)
 115
 116 =item custnum - customer (see L<FS::cust_main>)
 117
 118 =item _date - specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 119 L<Time::Local> and L<Date::Parse> for conversion functions.
 120
 121 =item charged - amount of this invoice
 122
 123 =item printed - deprecated
 124
 125 =item closed - books closed flag, empty or `Y'
 126
 127 =back
 128
 129 =head1 METHODS
 130
 131 =over 4
 132
 133 =item new HASHREF
 134
 135 Creates a new invoice.  To add the invoice to the database, see L<"insert">.
 136 Invoices are normally created by calling the bill method of a customer object
 137 (see L<FS::cust_main>).
 138
 139 =cut
 140
 141 sub table { 'cust_bill'; }
 142
 143 =item insert
 144
 145 Adds this invoice to the database ("Posts" the invoice).  If there is an error,
 146 returns the error, otherwise returns false.
 147
 148 =item delete
 149
 150 Currently unimplemented.  I don't remove invoices because there would then be
 151 no record you ever posted this invoice (which is bad, no?)
 152
 153 =cut
 154
 155 sub delete {
 156   my $self = shift;
 157   return "Can't delete closed invoice" if $self->closed =~ /^Y/i;
 158   $self->SUPER::delete(@_);
 159 }
 160
 161 =item replace OLD_RECORD
 162
 163 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 164 returns the error, otherwise returns false.
 165
 166 Only printed may be changed.  printed is normally updated by calling the
 167 collect method of a customer object (see L<FS::cust_main>).
 168
 169 =cut
 170
 171 sub replace {
 172   my( $new, $old ) = ( shift, shift );
 173   return "Can't change custnum!" unless $old->custnum == $new->custnum;
 174   #return "Can't change _date!" unless $old->_date eq $new->_date;
 175   return "Can't change _date!" unless $old->_date == $new->_date;
 176   return "Can't change charged!" unless $old->charged == $new->charged;
 177
 178   $new->SUPER::replace($old);
 179 }
 180
 181 =item check
 182
 183 Checks all fields to make sure this is a valid invoice.  If there is an error,
 184 returns the error, otherwise returns false.  Called by the insert and replace
 185 methods.
 186
 187 =cut
 188
 189 sub check {
 190   my $self = shift;
 191
 192   my $error =
 193     $self->ut_numbern('invnum')
 194     || $self->ut_number('custnum')
 195     || $self->ut_numbern('_date')
 196     || $self->ut_money('charged')
 197     || $self->ut_numbern('printed')
 198     || $self->ut_enum('closed', [ '', 'Y' ])
 199   ;
 200   return $error if $error;
 201
 202   return "Unknown customer"
 203     unless qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 204
 205   $self->_date(time) unless $self->_date;
 206
 207   $self->printed(0) if $self->printed eq '';
 208
 209   ''; #no error
 210 }
 211
 212 =item previous
 213
 214 Returns a list consisting of the total previous balance for this customer,
 215 followed by the previous outstanding invoices (as FS::cust_bill objects also).
 216
 217 =cut
 218
 219 sub previous {
 220   my $self = shift;
 221   my $total = 0;
 222   my @cust_bill = sort { $a->_date <=> $b->_date }
 223     grep { $_->owed != 0 && $_->_date < $self->_date }
 224       qsearch( 'cust_bill', { 'custnum' => $self->custnum } )
 225   ;
 226   foreach ( @cust_bill ) { $total += $_->owed; }
 227   $total, @cust_bill;
 228 }
 229
 230 =item cust_bill_pkg
 231
 232 Returns the line items (see L<FS::cust_bill_pkg>) for this invoice.
 233
 234 =cut
 235
 236 sub cust_bill_pkg {
 237   my $self = shift;
 238   qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum } );
 239 }
 240
 241 =item cust_bill_event
 242
 243 Returns the completed invoice events (see L<FS::cust_bill_event>) for this
 244 invoice.
 245
 246 =cut
 247
 248 sub cust_bill_event {
 249   my $self = shift;
 250   qsearch( 'cust_bill_event', { 'invnum' => $self->invnum } );
 251 }
 252
 253
 254 =item cust_main
 255
 256 Returns the customer (see L<FS::cust_main>) for this invoice.
 257
 258 =cut
 259
 260 sub cust_main {
 261   my $self = shift;
 262   qsearchs( 'cust_main', { 'custnum' => $self->custnum } );
 263 }
 264
 265 =item cust_credit
 266
 267 Depreciated.  See the cust_credited method.
 268
 269  #Returns a list consisting of the total previous credited (see
 270  #L<FS::cust_credit>) and unapplied for this customer, followed by the previous
 271  #outstanding credits (FS::cust_credit objects).
 272
 273 =cut
 274
 275 sub cust_credit {
 276   use Carp;
 277   croak "FS::cust_bill->cust_credit depreciated; see ".
 278         "FS::cust_bill->cust_credit_bill";
 279   #my $self = shift;
 280   #my $total = 0;
 281   #my @cust_credit = sort { $a->_date <=> $b->_date }
 282   #  grep { $_->credited != 0 && $_->_date < $self->_date }
 283   #    qsearch('cust_credit', { 'custnum' => $self->custnum } )
 284   #;
 285   #foreach (@cust_credit) { $total += $_->credited; }
 286   #$total, @cust_credit;
 287 }
 288
 289 =item cust_pay
 290
 291 Depreciated.  See the cust_bill_pay method.
 292
 293 #Returns all payments (see L<FS::cust_pay>) for this invoice.
 294
 295 =cut
 296
 297 sub cust_pay {
 298   use Carp;
 299   croak "FS::cust_bill->cust_pay depreciated; see FS::cust_bill->cust_bill_pay";
 300   #my $self = shift;
 301   #sort { $a->_date <=> $b->_date }
 302   #  qsearch( 'cust_pay', { 'invnum' => $self->invnum } )
 303   #;
 304 }
 305
 306 =item cust_bill_pay
 307
 308 Returns all payment applications (see L<FS::cust_bill_pay>) for this invoice.
 309
 310 =cut
 311
 312 sub cust_bill_pay {
 313   my $self = shift;
 314   sort { $a->_date <=> $b->_date }
 315     qsearch( 'cust_bill_pay', { 'invnum' => $self->invnum } );
 316 }
 317
 318 =item cust_credited
 319
 320 Returns all applied credits (see L<FS::cust_credit_bill>) for this invoice.
 321
 322 =cut
 323
 324 sub cust_credited {
 325   my $self = shift;
 326   sort { $a->_date <=> $b->_date }
 327     qsearch( 'cust_credit_bill', { 'invnum' => $self->invnum } )
 328   ;
 329 }
 330
 331 =item tax
 332
 333 Returns the tax amount (see L<FS::cust_bill_pkg>) for this invoice.
 334
 335 =cut
 336
 337 sub tax {
 338   my $self = shift;
 339   my $total = 0;
 340   my @taxlines = qsearch( 'cust_bill_pkg', { 'invnum' => $self->invnum ,
 341                                              'pkgnum' => 0 } );
 342   foreach (@taxlines) { $total += $_->setup; }
 343   $total;
 344 }
 345
 346 =item owed
 347
 348 Returns the amount owed (still outstanding) on this invoice, which is charged
 349 minus all payment applications (see L<FS::cust_bill_pay>) and credit
 350 applications (see L<FS::cust_credit_bill>).
 351
 352 =cut
 353
 354 sub owed {
 355   my $self = shift;
 356   my $balance = $self->charged;
 357   $balance -= $_->amount foreach ( $self->cust_bill_pay );
 358   $balance -= $_->amount foreach ( $self->cust_credited );
 359   $balance = sprintf( "%.2f", $balance);
 360   $balance =~ s/^\-0\.00$/0.00/; #yay ieee fp
 361   $balance;
 362 }
 363
 364 =item send
 365
 366 Sends this invoice to the destinations configured for this customer: send
 367 emails or print.  See L<FS::cust_main_invoice>.
 368
 369 =cut
 370
 371 sub send {
 372   my($self,$template) = @_;
 373   my @print_text = $self->print_text('', $template);
 374   my @invoicing_list = $self->cust_main->invoicing_list;
 375
 376   if ( grep { $_ ne 'POST' } @invoicing_list ) { #email invoice
 377     #false laziness w/FS::cust_pay::delete & fs_signup_server && ::realtime_card
 378     #$ENV{SMTPHOSTS} = $smtpmachine;
 379     $ENV{MAILADDRESS} = $invoice_from;
 380     my $header = new Mail::Header ( [
 381       "From: $invoice_from",
 382       "To: ". join(', ', grep { $_ ne 'POST' } @invoicing_list ),
 383       "Sender: $invoice_from",
 384       "Reply-To: $invoice_from",
 385       "Date: ". time2str("%a, %d %b %Y %X %z", time),
 386       "Subject: Invoice",
 387     ] );
 388     my $message = new Mail::Internet (
 389       'Header' => $header,
 390       'Body' => [ @print_text ], #( date)
 391     );
 392     $!=0;
 393     $message->smtpsend( Host => $smtpmachine )
 394       or $message->smtpsend( Host => $smtpmachine, Debug => 1 )
 395         or return "(customer # ". $self->custnum. ") can't send invoice email".
 396                   " to ". join(', ', grep { $_ ne 'POST' } @invoicing_list ).
 397                   " via server $smtpmachine with SMTP: $!";
 398
 399   }
 400
 401   if ( ! @invoicing_list || grep { $_ eq 'POST' } @invoicing_list ) { #postal
 402     open(LPR, "|$lpr")
 403       or return "Can't open pipe to $lpr: $!";
 404     print LPR @print_text;
 405     close LPR
 406       or return $! ? "Error closing $lpr: $!"
 407                    : "Exit status $? from $lpr";
 408   }
 409
 410   '';
 411
 412 }
 413
 414 =item send_csv OPTIONS
 415
 416 Sends invoice as a CSV data-file to a remote host with the specified protocol.
 417
 418 Options are:
 419
 420 protocol - currently only "ftp"
 421 server
 422 username
 423 password
 424 dir
 425
 426 The file will be named "N-YYYYMMDDHHMMSS.csv" where N is the invoice number
 427 and YYMMDDHHMMSS is a timestamp.
 428
 429 The fields of the CSV file is as follows:
 430
 431 record_type, invnum, custnum, _date, charged, first, last, company, address1, address2, city, state, zip, country, pkg, setup, recur, sdate, edate
 432
 433 =over 4
 434
 435 =item record type - B<record_type> is either C<cust_bill> or C<cust_bill_pkg>
 436
 437 If B<record_type> is C<cust_bill>, this is a primary invoice record.  The
 438 last five fields (B<pkg> through B<edate>) are irrelevant, and all other
 439 fields are filled in.
 440
 441 If B<record_type> is C<cust_bill_pkg>, this is a line item record.  Only the
 442 first two fields (B<record_type> and B<invnum>) and the last five fields
 443 (B<pkg> through B<edate>) are filled in.
 444
 445 =item invnum - invoice number
 446 =item custnum - customer number
 447 =item _date - invoice date
 448 =item charged - total invoice amount
 449 =item first - customer first name
 450 =item last - customer first name
 451 =item company - company name
 452 =item address1 - address line 1
 453 =item address2 - address line 1
 454 =item city
 455 =item state
 456 =item zip
 457 =item country
 458
 459 =item pkg - line item description
 460 =item setup - line item setup fee (only or both of B<setup> and B<recur> will be defined)
 461 =item recur - line item recurring fee (only or both of B<setup> and B<recur> will be defined)
 462 =item sdate - start date for recurring fee
 463 =item edate - end date for recurring fee
 464
 465 =back
 466
 467 =cut
 468
 469 sub send_csv {
 470   my($self, %opt) = @_;
 471
 472   #part one: create file
 473
 474   my $spooldir = "/usr/local/etc/freeside/export.". datasrc. "/cust_bill";
 475   mkdir $spooldir, 0700 unless -d $spooldir;
 476
 477   my $file = $spooldir. '/'. $self->invnum. time2str('-%Y%m%d%H%M%S.csv', time);
 478
 479   open(CSV, ">$file") or die "can't open $file: $!";
 480
 481   eval "use Text::CSV_XS";
 482   die $@ if $@;
 483
 484   my $csv = Text::CSV_XS->new({'always_quote'=>1});
 485
 486   my $cust_main = $self->cust_main;
 487
 488   $csv->combine(
 489     'cust_bill',
 490     $self->invnum,
 491     $self->custnum,
 492     time2str("%x", $self->_date),
 493     sprintf("%.2f", $self->charged),
 494     ( map { $cust_main->getfield($_) }
 495         qw( first last company address1 address2 city state zip country ) ),
 496     map { '' } (1..5),
 497   ) or die "can't create csv";
 498   print CSV $csv->string. "\n";
 499
 500   #new charges (false laziness w/print_text)
 501   foreach my $cust_bill_pkg ( $self->cust_bill_pkg ) {
 502
 503     my($pkg, $setup, $recur, $sdate, $edate);
 504     if ( $cust_bill_pkg->pkgnum ) {
 505
 506       ($pkg, $setup, $recur, $sdate, $edate) = (
 507         $cust_bill_pkg->cust_pkg->part_pkg->pkg,
 508         ( $cust_bill_pkg->setup != 0
 509           ? sprintf("%.2f", $cust_bill_pkg->setup )
 510           : '' ),
 511         ( $cust_bill_pkg->recur != 0
 512           ? sprintf("%.2f", $cust_bill_pkg->recur )
 513           : '' ),
 514         time2str("%x", $cust_bill_pkg->sdate),
 515         time2str("%x", $cust_bill_pkg->edate),
 516       );
 517
 518     } else { #pkgnum Tax
 519       next unless $cust_bill_pkg->setup != 0;
 520       ($pkg, $setup, $recur, $sdate, $edate) =
 521         ( 'Tax', sprintf("%10.2f",$cust_bill_pkg->setup), '', '', '' );
 522     }
 523
 524     $csv->combine(
 525       'cust_bill_pkg',
 526       $self->invnum,
 527       ( map { '' } (1..11) ),
 528       ($pkg, $setup, $recur, $sdate, $edate)
 529     ) or die "can't create csv";
 530     print CSV $csv->string. "\n";
 531
 532   }
 533
 534   close CSV or die "can't close CSV: $!";
 535
 536   #part two: upload it
 537
 538   my $net;
 539   if ( $opt{protocol} eq 'ftp' ) {
 540     eval "use Net::FTP;";
 541     die $@ if $@;
 542     $net = Net::FTP->new($opt{server}) or die @$;
 543   } else {
 544     die "unknown protocol: $opt{protocol}";
 545   }
 546
 547   $net->login( $opt{username}, $opt{password} )
 548     or die "can't FTP to $opt{username}\@$opt{server}: login error: $@";
 549
 550   $net->binary or die "can't set binary mode";
 551
 552   $net->cwd($opt{dir}) or die "can't cwd to $opt{dir}";
 553
 554   $net->put($file) or die "can't put $file: $!";
 555
 556   $net->quit;
 557
 558   unlink $file;
 559
 560 }
 561
 562 =item comp
 563
 564 Pays this invoice with a compliemntary payment.  If there is an error,
 565 returns the error, otherwise returns false.
 566
 567 =cut
 568
 569 sub comp {
 570   my $self = shift;
 571   my $cust_pay = new FS::cust_pay ( {
 572     'invnum'   => $self->invnum,
 573     'paid'     => $self->owed,
 574     '_date'    => '',
 575     'payby'    => 'COMP',
 576     'payinfo'  => $self->cust_main->payinfo,
 577     'paybatch' => '',
 578   } );
 579   $cust_pay->insert;
 580 }
 581
 582 =item realtime_card
 583
 584 Attempts to pay this invoice with a Business::OnlinePayment realtime gateway.
 585 See http://search.cpan.org/search?mode=module&query=Business%3A%3AOnlinePayment
 586 for supproted processors.
 587
 588 =cut
 589
 590 sub realtime_card {
 591   my $self = shift;
 592   my $cust_main = $self->cust_main;
 593   my $amount = $self->owed;
 594
 595   unless ( $processor =~ /^Business::OnlinePayment::(.*)$/ ) {
 596     return "Real-time card processing not enabled (processor $processor)";
 597   }
 598   my $bop_processor = $1; #hmm?
 599
 600   my $address = $cust_main->address1;
 601   $address .= ", ". $cust_main->address2 if $cust_main->address2;
 602
 603   #fix exp. date
 604   #$cust_main->paydate =~ /^(\d+)\/\d*(\d{2})$/;
 605   $cust_main->paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
 606   my $exp = "$2/$1";
 607
 608   my($payname, $payfirst, $paylast);
 609   if ( $cust_main->payname ) {
 610     $payname = $cust_main->payname;
 611     $payname =~ /^\s*([\w \,\.\-\']*)?\s+([\w\,\.\-\']+)\s*$/
 612       or do {
 613               #$dbh->rollback if $oldAutoCommit;
 614               return "Illegal payname $payname";
 615             };
 616     ($payfirst, $paylast) = ($1, $2);
 617   } else {
 618     $payfirst = $cust_main->getfield('first');
 619     $paylast = $cust_main->getfield('last');
 620     $payname =  "$payfirst $paylast";
 621   }
 622
 623   my @invoicing_list = grep { $_ ne 'POST' } $cust_main->invoicing_list;
 624   if ( $conf->exists('emailinvoiceauto')
 625        || ( $conf->exists('emailinvoiceonly') && ! @invoicing_list ) ) {
 626     push @invoicing_list, $cust_main->default_invoicing_list;
 627   }
 628   my $email = $invoicing_list[0];
 629
 630   my( $action1, $action2 ) = split(/\s*\,\s*/, $bop_action );
 631
 632   my $description = 'Internet Services';
 633   if ( $conf->exists('business-onlinepayment-description') ) {
 634     my $dtempl = $conf->config('business-onlinepayment-description');
 635
 636     my $agent_obj = $cust_main->agent
 637       or die "can't retreive agent for $cust_main (agentnum ".
 638              $cust_main->agentnum. ")";
 639     my $agent = $agent_obj->agent;
 640     my $pkgs = join(', ',
 641       map { $_->cust_pkg->part_pkg->pkg }
 642         grep { $_->pkgnum } $self->cust_bill_pkg
 643     );
 644     $description = eval qq("$dtempl");
 645
 646   }
 647
 648   my $transaction =
 649     new Business::OnlinePayment( $bop_processor, @bop_options );
 650   $transaction->content(
 651     'type'           => 'CC',
 652     'login'          => $bop_login,
 653     'password'       => $bop_password,
 654     'action'         => $action1,
 655     'description'    => $description,
 656     'amount'         => $amount,
 657     'invoice_number' => $self->invnum,
 658     'customer_id'    => $self->custnum,
 659     'last_name'      => $paylast,
 660     'first_name'     => $payfirst,
 661     'name'           => $payname,
 662     'address'        => $address,
 663     'city'           => $cust_main->city,
 664     'state'          => $cust_main->state,
 665     'zip'            => $cust_main->zip,
 666     'country'        => $cust_main->country,
 667     'card_number'    => $cust_main->payinfo,
 668     'expiration'     => $exp,
 669     'referer'        => 'http://cleanwhisker.420.am/',
 670     'email'          => $email,
 671     'phone'          => $cust_main->daytime || $cust_main->night,
 672   );
 673   $transaction->submit();
 674
 675   if ( $transaction->is_success() && $action2 ) {
 676     my $auth = $transaction->authorization;
 677     my $ordernum = $transaction->order_number;
 678
 679     #warn "********* $auth ***********\n";
 680     #warn "********* $ordernum ***********\n";
 681     my $capture =
 682       new Business::OnlinePayment( $bop_processor, @bop_options );
 683
 684     $capture->content(
 685       action         => $action2,
 686       login          => $bop_login,
 687       password       => $bop_password,
 688       order_number   => $ordernum,
 689       amount         => $amount,
 690       authorization  => $auth,
 691       description    => $description,
 692     );
 693
 694     $capture->submit();
 695
 696     unless ( $capture->is_success ) {
 697       my $e = "Authorization sucessful but capture failed, invnum #".
 698               $self->invnum. ': '.  $capture->result_code.
 699               ": ". $capture->error_message;
 700       warn $e;
 701       return $e;
 702     }
 703
 704   }
 705
 706   if ( $transaction->is_success() ) {
 707
 708     my $cust_pay = new FS::cust_pay ( {
 709        'invnum'   => $self->invnum,
 710        'paid'     => $amount,
 711        '_date'     => '',
 712        'payby'    => 'CARD',
 713        'payinfo'  => $cust_main->payinfo,
 714        'paybatch' => "$processor:". $transaction->authorization,
 715     } );
 716     my $error = $cust_pay->insert;
 717     if ( $error ) {
 718       # gah, even with transactions.
 719       my $e = 'WARNING: Card debited but database not updated - '.
 720               'error applying payment, invnum #' . $self->invnum.
 721               " ($processor): $error";
 722       warn $e;
 723       return $e;
 724     } else {
 725       return '';
 726     }
 727   #} elsif ( $options{'report_badcard'} ) {
 728   } else {
 729
 730     my $perror = "$processor error, invnum #". $self->invnum. ': '.
 731                  $transaction->result_code. ": ". $transaction->error_message;
 732
 733     if ( $conf->exists('emaildecline')
 734          && grep { $_ ne 'POST' } $cust_main->invoicing_list
 735     ) {
 736       my @templ = $conf->config('declinetemplate');
 737       my $template = new Text::Template (
 738         TYPE   => 'ARRAY',
 739         SOURCE => [ map "$_\n", @templ ],
 740       ) or return "($perror) can't create template: $Text::Template::ERROR";
 741       $template->compile()
 742         or return "($perror) can't compile template: $Text::Template::ERROR";
 743
 744       my $templ_hash = { error => $transaction->error_message };
 745
 746       #false laziness w/FS::cust_pay::delete & fs_signup_server && ::send
 747       $ENV{MAILADDRESS} = $invoice_from;
 748       my $header = new Mail::Header ( [
 749         "From: $invoice_from",
 750         "To: ". join(', ', grep { $_ ne 'POST' } $cust_main->invoicing_list ),
 751         "Sender: $invoice_from",
 752         "Reply-To: $invoice_from",
 753         "Date: ". time2str("%a, %d %b %Y %X %z", time),
 754         "Subject: Your credit card could not be processed",
 755       ] );
 756       my $message = new Mail::Internet (
 757         'Header' => $header,
 758         'Body' => [ $template->fill_in(HASH => $templ_hash) ],
 759       );
 760       $!=0;
 761       $message->smtpsend( Host => $smtpmachine )
 762         or $message->smtpsend( Host => $smtpmachine, Debug => 1 )
 763           or return "($perror) (customer # ". $self->custnum.
 764             ") can't send card decline email to ".
 765             join(', ', grep { $_ ne 'POST' } $cust_main->invoicing_list ).
 766             " via server $smtpmachine with SMTP: $!";
 767     }
 768
 769     return $perror;
 770   }
 771
 772 }
 773
 774 =item realtime_card_cybercash
 775
 776 Attempts to pay this invoice with the CyberCash CashRegister realtime gateway.
 777
 778 =cut
 779
 780 sub realtime_card_cybercash {
 781   my $self = shift;
 782   my $cust_main = $self->cust_main;
 783   my $amount = $self->owed;
 784
 785   return "CyberCash CashRegister real-time card processing not enabled!"
 786     unless $processor eq 'cybercash3.2';
 787
 788   my $address = $cust_main->address1;
 789   $address .= ", ". $cust_main->address2 if $cust_main->address2;
 790
 791   #fix exp. date
 792   #$cust_main->paydate =~ /^(\d+)\/\d*(\d{2})$/;
 793   $cust_main->paydate =~ /^\d{2}(\d{2})[\/\-](\d+)[\/\-]\d+$/;
 794   my $exp = "$2/$1";
 795
 796   #
 797
 798   my $paybatch = $self->invnum.
 799                   '-' . time2str("%y%m%d%H%M%S", time);
 800
 801   my $payname = $cust_main->payname ||
 802                 $cust_main->getfield('first').' '.$cust_main->getfield('last');
 803
 804   my $country = $cust_main->country eq 'US' ? 'USA' : $cust_main->country;
 805
 806   my @full_xaction = ( $xaction,
 807     'Order-ID'     => $paybatch,
 808     'Amount'       => "usd $amount",
 809     'Card-Number'  => $cust_main->getfield('payinfo'),
 810     'Card-Name'    => $payname,
 811     'Card-Address' => $address,
 812     'Card-City'    => $cust_main->getfield('city'),
 813     'Card-State'   => $cust_main->getfield('state'),
 814     'Card-Zip'     => $cust_main->getfield('zip'),
 815     'Card-Country' => $country,
 816     'Card-Exp'     => $exp,
 817   );
 818
 819   my %result;
 820   %result = &CCMckDirectLib3_2::SendCC2_1Server(@full_xaction);
 821
 822   if ( $result{'MStatus'} eq 'success' ) { #cybercash smps v.2 or 3
 823     my $cust_pay = new FS::cust_pay ( {
 824        'invnum'   => $self->invnum,
 825        'paid'     => $amount,
 826        '_date'     => '',
 827        'payby'    => 'CARD',
 828        'payinfo'  => $cust_main->payinfo,
 829        'paybatch' => "$processor:$paybatch",
 830     } );
 831     my $error = $cust_pay->insert;
 832     if ( $error ) {
 833       # gah, even with transactions.
 834       my $e = 'WARNING: Card debited but database not updated - '.
 835               'error applying payment, invnum #' . $self->invnum.
 836               " (CyberCash Order-ID $paybatch): $error";
 837       warn $e;
 838       return $e;
 839     } else {
 840       return '';
 841     }
 842 #  } elsif ( $result{'Mstatus'} ne 'failure-bad-money'
 843 #            || $options{'report_badcard'}
 844 #          ) {
 845   } else {
 846      return 'Cybercash error, invnum #' .
 847        $self->invnum. ':'. $result{'MErrMsg'};
 848   }
 849
 850 }
 851
 852 =item batch_card
 853
 854 Adds a payment for this invoice to the pending credit card batch (see
 855 L<FS::cust_pay_batch>).
 856
 857 =cut
 858
 859 sub batch_card {
 860   my $self = shift;
 861   my $cust_main = $self->cust_main;
 862
 863   my $cust_pay_batch = new FS::cust_pay_batch ( {
 864     'invnum'   => $self->getfield('invnum'),
 865     'custnum'  => $cust_main->getfield('custnum'),
 866     'last'     => $cust_main->getfield('last'),
 867     'first'    => $cust_main->getfield('first'),
 868     'address1' => $cust_main->getfield('address1'),
 869     'address2' => $cust_main->getfield('address2'),
 870     'city'     => $cust_main->getfield('city'),
 871     'state'    => $cust_main->getfield('state'),
 872     'zip'      => $cust_main->getfield('zip'),
 873     'country'  => $cust_main->getfield('country'),
 874     'trancode' => 77,
 875     'cardnum'  => $cust_main->getfield('payinfo'),
 876     'exp'      => $cust_main->getfield('paydate'),
 877     'payname'  => $cust_main->getfield('payname'),
 878     'amount'   => $self->owed,
 879   } );
 880   my $error = $cust_pay_batch->insert;
 881   die $error if $error;
 882
 883   '';
 884 }
 885
 886 =item print_text [TIME];
 887
 888 Returns an text invoice, as a list of lines.
 889
 890 TIME an optional value used to control the printing of overdue messages.  The
 891 default is now.  It isn't the date of the invoice; that's the `_date' field.
 892 It is specified as a UNIX timestamp; see L<perlfunc/"time">.  Also see
 893 L<Time::Local> and L<Date::Parse> for conversion functions.
 894
 895 =cut
 896
 897 sub print_text {
 898
 899   my( $self, $today, $template ) = @_;
 900   $today ||= time;
 901 #  my $invnum = $self->invnum;
 902   my $cust_main = qsearchs('cust_main', { 'custnum', $self->custnum } );
 903   $cust_main->payname( $cust_main->first. ' '. $cust_main->getfield('last') )
 904     unless $cust_main->payname;
 905
 906   my( $pr_total, @pr_cust_bill ) = $self->previous; #previous balance
 907 #  my( $cr_total, @cr_cust_credit ) = $self->cust_credit; #credits
 908   #my $balance_due = $self->owed + $pr_total - $cr_total;
 909   my $balance_due = $self->owed + $pr_total;
 910
 911   #my @collect = ();
 912   #my($description,$amount);
 913   @buf = ();
 914
 915   #previous balance
 916   foreach ( @pr_cust_bill ) {
 917     push @buf, [
 918       "Previous Balance, Invoice #". $_->invnum.
 919                  " (". time2str("%x",$_->_date). ")",
 920       $money_char. sprintf("%10.2f",$_->owed)
 921     ];
 922   }
 923   if (@pr_cust_bill) {
 924     push @buf,['','-----------'];
 925     push @buf,[ 'Total Previous Balance',
 926                 $money_char. sprintf("%10.2f",$pr_total ) ];
 927     push @buf,['',''];
 928   }
 929
 930   #new charges
 931   foreach ( $self->cust_bill_pkg ) {
 932
 933     if ( $_->pkgnum ) {
 934
 935       my($cust_pkg)=qsearchs('cust_pkg', { 'pkgnum', $_->pkgnum } );
 936       my($part_pkg)=qsearchs('part_pkg',{'pkgpart'=>$cust_pkg->pkgpart});
 937       my($pkg)=$part_pkg->pkg;
 938
 939       if ( $_->setup != 0 ) {
 940         push @buf, [ "$pkg Setup", $money_char. sprintf("%10.2f",$_->setup) ];
 941         push @buf,
 942           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] } $cust_pkg->labels;
 943       }
 944
 945       if ( $_->recur != 0 ) {
 946         push @buf, [
 947           "$pkg (" . time2str("%x",$_->sdate) . " - " .
 948                                 time2str("%x",$_->edate) . ")",
 949           $money_char. sprintf("%10.2f",$_->recur)
 950         ];
 951         push @buf,
 952           map { [ "  ". $_->[0]. ": ". $_->[1], '' ] } $cust_pkg->labels;
 953       }
 954
 955     } else { #pkgnum Tax
 956       push @buf,["Tax", $money_char. sprintf("%10.2f",$_->setup) ]
 957         if $_->setup != 0;
 958     }
 959   }
 960
 961   push @buf,['','-----------'];
 962   push @buf,['Total New Charges',
 963              $money_char. sprintf("%10.2f",$self->charged) ];
 964   push @buf,['',''];
 965
 966   push @buf,['','-----------'];
 967   push @buf,['Total Charges',
 968              $money_char. sprintf("%10.2f",$self->charged + $pr_total) ];
 969   push @buf,['',''];
 970
 971   #credits
 972   foreach ( $self->cust_credited ) {
 973
 974     #something more elaborate if $_->amount ne $_->cust_credit->credited ?
 975
 976     my $reason = substr($_->cust_credit->reason,0,32);
 977     $reason .= '...' if length($reason) < length($_->cust_credit->reason);
 978     $reason = " ($reason) " if $reason;
 979     push @buf,[
 980       "Credit #". $_->crednum. " (". time2str("%x",$_->cust_credit->_date) .")".
 981         $reason,
 982       $money_char. sprintf("%10.2f",$_->amount)
 983     ];
 984   }
 985   #foreach ( @cr_cust_credit ) {
 986   #  push @buf,[
 987   #    "Credit #". $_->crednum. " (" . time2str("%x",$_->_date) .")",
 988   #    $money_char. sprintf("%10.2f",$_->credited)
 989   #  ];
 990   #}
 991
 992   #get & print payments
 993   foreach ( $self->cust_bill_pay ) {
 994
 995     #something more elaborate if $_->amount ne ->cust_pay->paid ?
 996
 997     push @buf,[
 998       "Payment received ". time2str("%x",$_->cust_pay->_date ),
 999       $money_char. sprintf("%10.2f",$_->amount )
1000     ];
1001   }
1002
1003   #balance due
1004   push @buf,['','-----------'];
1005   push @buf,['Balance Due', $money_char.
1006     sprintf("%10.2f", $balance_due ) ];
1007
1008   #create the template
1009   my $templatefile = 'invoice_template';
1010   $templatefile .= "_$template" if $template;
1011   my @invoice_template = $conf->config($templatefile)
1012   or die "cannot load config file $templatefile";
1013   $invoice_lines = 0;
1014   my $wasfunc = 0;
1015   foreach ( grep /invoice_lines\(\d+\)/, @invoice_template ) { #kludgy
1016     /invoice_lines\((\d+)\)/;
1017     $invoice_lines += $1;
1018     $wasfunc=1;
1019   }
1020   die "no invoice_lines() functions in template?" unless $wasfunc;
1021   my $invoice_template = new Text::Template (
1022     TYPE   => 'ARRAY',
1023     SOURCE => [ map "$_\n", @invoice_template ],
1024   ) or die "can't create new Text::Template object: $Text::Template::ERROR";
1025   $invoice_template->compile()
1026     or die "can't compile template: $Text::Template::ERROR";
1027
1028   #setup template variables
1029   package FS::cust_bill::_template; #!
1030   use vars qw( $invnum $date $page $total_pages @address $overdue @buf );
1031
1032   $invnum = $self->invnum;
1033   $date = $self->_date;
1034   $page = 1;
1035
1036   if ( $FS::cust_bill::invoice_lines ) {
1037     $total_pages =
1038       int( scalar(@FS::cust_bill::buf) / $FS::cust_bill::invoice_lines );
1039     $total_pages++
1040       if scalar(@FS::cust_bill::buf) % $FS::cust_bill::invoice_lines;
1041   } else {
1042     $total_pages = 1;
1043   }
1044
1045   #format address (variable for the template)
1046   my $l = 0;
1047   @address = ( '', '', '', '', '', '' );
1048   package FS::cust_bill; #!
1049   $FS::cust_bill::_template::address[$l++] =
1050     $cust_main->payname.
1051       ( ( $cust_main->payby eq 'BILL' ) && $cust_main->payinfo
1052         ? " (P.O. #". $cust_main->payinfo. ")"
1053         : ''
1054       )
1055   ;
1056   $FS::cust_bill::_template::address[$l++] = $cust_main->company
1057     if $cust_main->company;
1058   $FS::cust_bill::_template::address[$l++] = $cust_main->address1;
1059   $FS::cust_bill::_template::address[$l++] = $cust_main->address2
1060     if $cust_main->address2;
1061   $FS::cust_bill::_template::address[$l++] =
1062     $cust_main->city. ", ". $cust_main->state. "  ".  $cust_main->zip;
1063   $FS::cust_bill::_template::address[$l++] = $cust_main->country
1064     unless $cust_main->country eq 'US';
1065
1066         #  #overdue? (variable for the template)
1067         #  $FS::cust_bill::_template::overdue = (
1068         #    $balance_due > 0
1069         #    && $today > $self->_date
1070         ##    && $self->printed > 1
1071         #    && $self->printed > 0
1072         #  );
1073
1074   #and subroutine for the template
1075
1076   sub FS::cust_bill::_template::invoice_lines {
1077     my $lines = shift or return @buf;
1078     map {
1079       scalar(@buf) ? shift @buf : [ '', '' ];
1080     }
1081     ( 1 .. $lines );
1082   }
1083
1084
1085   #and fill it in
1086   $FS::cust_bill::_template::page = 1;
1087   my $lines;
1088   my @collect;
1089   while (@buf) {
1090     push @collect, split("\n",
1091       $invoice_template->fill_in( PACKAGE => 'FS::cust_bill::_template' )
1092     );
1093     $FS::cust_bill::_template::page++;
1094   }
1095
1096   map "$_\n", @collect;
1097
1098 }
1099
1100 =back
1101
1102 =head1 VERSION
1103
1104 $Id: cust_bill.pm,v 1.40 2002-08-30 23:48:43 ivan Exp $
1105
1106 =head1 BUGS
1107
1108 The delete method.
1109
1110 print_text formatting (and some logic :/) is in source, but needs to be
1111 slurped in from a file.  Also number of lines ($=).
1112
1113 missing print_ps for a nice postscript copy (maybe HylaFAX-cover-page-style
1114 or something similar so the look can be completely customized?)
1115
1116 =head1 SEE ALSO
1117
1118 L<FS::Record>, L<FS::cust_main>, L<FS::cust_bill_pay>, L<FS::cust_pay>,
1119 L<FS::cust_bill_pkg>, L<FS::cust_bill_credit>, schema.html from the base
1120 documentation.
1121
1122 =cut
1123
1124 1;
1125