FS/FS/cdr.pm

   1 package FS::cdr;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $DEBUG $me );
   5 use Exporter;
   6 use Tie::IxHash;
   7 use Date::Parse;
   8 use Date::Format;
   9 use Time::Local;
  10 use FS::UID qw( dbh );
  11 use FS::Conf;
  12 use FS::Record qw( qsearch qsearchs );
  13 use FS::cdr_type;
  14 use FS::cdr_calltype;
  15 use FS::cdr_carrier;
  16 use FS::cdr_batch;
  17 use FS::cdr_termination;
  18
  19 @ISA = qw(FS::Record);
  20 @EXPORT_OK = qw( _cdr_date_parser_maker _cdr_min_parser_maker );
  21
  22 $DEBUG = 0;
  23 $me = '[FS::cdr]';
  24
  25 =head1 NAME
  26
  27 FS::cdr - Object methods for cdr records
  28
  29 =head1 SYNOPSIS
  30
  31   use FS::cdr;
  32
  33   $record = new FS::cdr \%hash;
  34   $record = new FS::cdr { 'column' => 'value' };
  35
  36   $error = $record->insert;
  37
  38   $error = $new_record->replace($old_record);
  39
  40   $error = $record->delete;
  41
  42   $error = $record->check;
  43
  44 =head1 DESCRIPTION
  45
  46 An FS::cdr object represents an Call Data Record, typically from a telephony
  47 system or provider of some sort.  FS::cdr inherits from FS::Record.  The
  48 following fields are currently supported:
  49
  50 =over 4
  51
  52 =item acctid - primary key
  53
  54 =item calldate - Call timestamp (SQL timestamp)
  55
  56 =item clid - Caller*ID with text
  57
  58 =item src - Caller*ID number / Source number
  59
  60 =item dst - Destination extension
  61
  62 =item dcontext - Destination context
  63
  64 =item channel - Channel used
  65
  66 =item dstchannel - Destination channel if appropriate
  67
  68 =item lastapp - Last application if appropriate
  69
  70 =item lastdata - Last application data
  71
  72 =item startdate - Start of call (UNIX-style integer timestamp)
  73
  74 =item answerdate - Answer time of call (UNIX-style integer timestamp)
  75
  76 =item enddate - End time of call (UNIX-style integer timestamp)
  77
  78 =item duration - Total time in system, in seconds
  79
  80 =item billsec - Total time call is up, in seconds
  81
  82 =item disposition - What happened to the call: ANSWERED, NO ANSWER, BUSY
  83
  84 =item amaflags - What flags to use: BILL, IGNORE etc, specified on a per channel basis like accountcode.
  85
  86 =cut
  87
  88   #ignore the "omit" and "documentation" AMAs??
  89   #AMA = Automated Message Accounting.
  90   #default: Sets the system default.
  91   #omit: Do not record calls.
  92   #billing: Mark the entry for billing
  93   #documentation: Mark the entry for documentation.
  94
  95 =item accountcode - CDR account number to use: account
  96
  97 =item uniqueid - Unique channel identifier (Unitel/RSLCOM Event ID)
  98
  99 =item userfield - CDR user-defined field
 100
 101 =item cdr_type - CDR type - see L<FS::cdr_type> (Usage = 1, S&E = 7, OC&C = 8)
 102
 103 =item charged_party - Service number to be billed
 104
 105 =item upstream_currency - Wholesale currency from upstream
 106
 107 =item upstream_price - Wholesale price from upstream
 108
 109 =item upstream_rateplanid - Upstream rate plan ID
 110
 111 =item rated_price - Rated (or re-rated) price
 112
 113 =item distance - km (need units field?)
 114
 115 =item islocal - Local - 1, Non Local = 0
 116
 117 =item calltypenum - Type of call - see L<FS::cdr_calltype>
 118
 119 =item description - Description (cdr_type 7&8 only) (used for cust_bill_pkg.itemdesc)
 120
 121 =item quantity - Number of items (cdr_type 7&8 only)
 122
 123 =item carrierid - Upstream Carrier ID (see L<FS::cdr_carrier>)
 124
 125 =cut
 126
 127 #Telstra =1, Optus = 2, RSL COM = 3
 128
 129 =item upstream_rateid - Upstream Rate ID
 130
 131 =item svcnum - Link to customer service (see L<FS::cust_svc>)
 132
 133 =item freesidestatus - NULL, done (or something)
 134
 135 =item freesiderewritestatus - NULL, done (or something)
 136
 137 =item cdrbatch
 138
 139 =back
 140
 141 =head1 METHODS
 142
 143 =over 4
 144
 145 =item new HASHREF
 146
 147 Creates a new CDR.  To add the CDR to the database, see L<"insert">.
 148
 149 Note that this stores the hash reference, not a distinct copy of the hash it
 150 points to.  You can ask the object for a copy with the I<hash> method.
 151
 152 =cut
 153
 154 # the new method can be inherited from FS::Record, if a table method is defined
 155
 156 sub table { 'cdr'; }
 157
 158 sub table_info {
 159   {
 160     'fields' => {
 161 #XXX fill in some (more) nice names
 162         #'acctid'                => '',
 163         'calldate'              => 'Call date',
 164         'clid'                  => 'Caller ID',
 165         'src'                   => 'Source',
 166         'dst'                   => 'Destination',
 167         'dcontext'              => 'Dest. context',
 168         'channel'               => 'Channel',
 169         'dstchannel'            => 'Destination channel',
 170         #'lastapp'               => '',
 171         #'lastdata'              => '',
 172         'startdate'             => 'Start date',
 173         'answerdate'            => 'Answer date',
 174         'enddate'               => 'End date',
 175         'duration'              => 'Duration',
 176         'billsec'               => 'Billable seconds',
 177         'disposition'           => 'Disposition',
 178         'amaflags'              => 'AMA flags',
 179         'accountcode'           => 'Account code',
 180         #'uniqueid'              => '',
 181         'userfield'             => 'User field',
 182         #'cdrtypenum'            => '',
 183         'charged_party'         => 'Charged party',
 184         #'upstream_currency'     => '',
 185         'upstream_price'        => 'Upstream price',
 186         #'upstream_rateplanid'   => '',
 187         #'ratedetailnum'         => '',
 188         'rated_price'           => 'Rated price',
 189         #'distance'              => '',
 190         #'islocal'               => '',
 191         #'calltypenum'           => '',
 192         #'description'           => '',
 193         #'quantity'              => '',
 194         'carrierid'             => 'Carrier ID',
 195         #'upstream_rateid'       => '',
 196         'svcnum'                => 'Freeside service',
 197         'freesidestatus'        => 'Freeside status',
 198         'freesiderewritestatus' => 'Freeside rewrite status',
 199         'cdrbatch'              => 'Legacy batch',
 200         'cdrbatchnum'           => 'Batch',
 201     },
 202
 203   };
 204
 205 }
 206
 207 =item insert
 208
 209 Adds this record to the database.  If there is an error, returns the error,
 210 otherwise returns false.
 211
 212 =cut
 213
 214 # the insert method can be inherited from FS::Record
 215
 216 =item delete
 217
 218 Delete this record from the database.
 219
 220 =cut
 221
 222 # the delete method can be inherited from FS::Record
 223
 224 =item replace OLD_RECORD
 225
 226 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 227 returns the error, otherwise returns false.
 228
 229 =cut
 230
 231 # the replace method can be inherited from FS::Record
 232
 233 =item check
 234
 235 Checks all fields to make sure this is a valid CDR.  If there is
 236 an error, returns the error, otherwise returns false.  Called by the insert
 237 and replace methods.
 238
 239 Note: Unlike most types of records, we don't want to "reject" a CDR and we want
 240 to process them as quickly as possible, so we allow the database to check most
 241 of the data.
 242
 243 =cut
 244
 245 sub check {
 246   my $self = shift;
 247
 248 # we don't want to "reject" a CDR like other sorts of input...
 249 #  my $error =
 250 #    $self->ut_numbern('acctid')
 251 ##    || $self->ut_('calldate')
 252 #    || $self->ut_text('clid')
 253 #    || $self->ut_text('src')
 254 #    || $self->ut_text('dst')
 255 #    || $self->ut_text('dcontext')
 256 #    || $self->ut_text('channel')
 257 #    || $self->ut_text('dstchannel')
 258 #    || $self->ut_text('lastapp')
 259 #    || $self->ut_text('lastdata')
 260 #    || $self->ut_numbern('startdate')
 261 #    || $self->ut_numbern('answerdate')
 262 #    || $self->ut_numbern('enddate')
 263 #    || $self->ut_number('duration')
 264 #    || $self->ut_number('billsec')
 265 #    || $self->ut_text('disposition')
 266 #    || $self->ut_number('amaflags')
 267 #    || $self->ut_text('accountcode')
 268 #    || $self->ut_text('uniqueid')
 269 #    || $self->ut_text('userfield')
 270 #    || $self->ut_numbern('cdrtypenum')
 271 #    || $self->ut_textn('charged_party')
 272 ##    || $self->ut_n('upstream_currency')
 273 ##    || $self->ut_n('upstream_price')
 274 #    || $self->ut_numbern('upstream_rateplanid')
 275 ##    || $self->ut_n('distance')
 276 #    || $self->ut_numbern('islocal')
 277 #    || $self->ut_numbern('calltypenum')
 278 #    || $self->ut_textn('description')
 279 #    || $self->ut_numbern('quantity')
 280 #    || $self->ut_numbern('carrierid')
 281 #    || $self->ut_numbern('upstream_rateid')
 282 #    || $self->ut_numbern('svcnum')
 283 #    || $self->ut_textn('freesidestatus')
 284 #    || $self->ut_textn('freesiderewritestatus')
 285 #  ;
 286 #  return $error if $error;
 287
 288   for my $f ( grep { $self->$_ =~ /\D/ } qw(startdate answerdate enddate)){
 289     $self->$f( str2time($self->$f) );
 290   }
 291
 292   $self->calldate( $self->startdate_sql )
 293     if !$self->calldate && $self->startdate;
 294
 295   #was just for $format eq 'taqua' but can't see the harm... add something to
 296   #disable if it becomes a problem
 297   if ( $self->duration eq '' && $self->enddate && $self->startdate ) {
 298     $self->duration( $self->enddate - $self->startdate  );
 299   }
 300   if ( $self->billsec eq '' && $self->enddate && $self->answerdate ) {
 301     $self->billsec(  $self->enddate - $self->answerdate );
 302   }
 303
 304   $self->set_charged_party;
 305
 306   #check the foreign keys even?
 307   #do we want to outright *reject* the CDR?
 308   my $error =
 309        $self->ut_numbern('acctid')
 310
 311   #add a config option to turn these back on if someone needs 'em
 312   #
 313   #  #Usage = 1, S&E = 7, OC&C = 8
 314   #  || $self->ut_foreign_keyn('cdrtypenum',  'cdr_type',     'cdrtypenum' )
 315   #
 316   #  #the big list in appendix 2
 317   #  || $self->ut_foreign_keyn('calltypenum', 'cdr_calltype', 'calltypenum' )
 318   #
 319   #  # Telstra =1, Optus = 2, RSL COM = 3
 320   #  || $self->ut_foreign_keyn('carrierid', 'cdr_carrier', 'carrierid' )
 321   ;
 322   return $error if $error;
 323
 324   $self->SUPER::check;
 325 }
 326
 327 =item is_tollfree [ COLUMN ]
 328
 329 Returns true when the cdr represents a toll free number and false otherwise.
 330
 331 By default, inspects the dst field, but an optional column name can be passed
 332 to inspect other field.
 333
 334 =cut
 335
 336 sub is_tollfree {
 337   my $self = shift;
 338   my $field = scalar(@_) ? shift : 'dst';
 339   ( $self->$field() =~ /^(\+?1)?8(8|([02-7])\3)/ ) ? 1 : 0;
 340 }
 341
 342 =item set_charged_party
 343
 344 If the charged_party field is already set, does nothing.  Otherwise:
 345
 346 If the cdr-charged_party-accountcode config option is enabled, sets the
 347 charged_party to the accountcode.
 348
 349 Otherwise sets the charged_party normally: to the src field in most cases,
 350 or to the dst field if it is a toll free number.
 351
 352 =cut
 353
 354 sub set_charged_party {
 355   my $self = shift;
 356
 357   my $conf = new FS::Conf;
 358
 359   unless ( $self->charged_party ) {
 360
 361     if ( $conf->exists('cdr-charged_party-accountcode') && $self->accountcode ){
 362
 363       my $charged_party = $self->accountcode;
 364       $charged_party =~ s/^0+//
 365         if $conf->exists('cdr-charged_party-accountcode-trim_leading_0s');
 366       $self->charged_party( $charged_party );
 367
 368     } elsif ( $conf->exists('cdr-charged_party-field') ) {
 369
 370       my $field = $conf->config('cdr-charged_party-field');
 371       $self->charged_party( $self->$field() );
 372
 373     } else {
 374
 375       if ( $self->is_tollfree ) {
 376         $self->charged_party($self->dst);
 377       } else {
 378         $self->charged_party($self->src);
 379       }
 380
 381     }
 382
 383   }
 384
 385 #  my $prefix = $conf->config('cdr-charged_party-truncate_prefix');
 386 #  my $prefix_len = length($prefix);
 387 #  my $trunc_len = $conf->config('cdr-charged_party-truncate_length');
 388 #
 389 #  $self->charged_party( substr($self->charged_party, 0, $trunc_len) )
 390 #    if $prefix_len && $trunc_len
 391 #    && substr($self->charged_party, 0, $prefix_len) eq $prefix;
 392
 393 }
 394
 395 =item set_status_and_rated_price STATUS [ RATED_PRICE [ SVCNUM ] ]
 396
 397 Sets the status to the provided string.  If there is an error, returns the
 398 error, otherwise returns false.
 399
 400 =cut
 401
 402 sub set_status_and_rated_price {
 403   my($self, $status, $rated_price, $svcnum, %opt) = @_;
 404   if($opt{'inbound'}) {
 405     my $term = qsearchs('cdr_termination', {
 406         acctid   => $self->acctid,
 407         termpart => 1 # inbound
 408     });
 409     my $error;
 410     if($term) {
 411       warn "replacing existing cdr status (".$self->acctid.")\n" if $term;
 412       $error = $term->delete;
 413       return $error if $error;
 414     }
 415     $term = FS::cdr_termination->new({
 416         acctid      => $self->acctid,
 417         termpart    => 1,
 418         rated_price => $rated_price,
 419         status      => $status,
 420         svcnum      => $svcnum,
 421     });
 422     return $term->insert;
 423   }
 424   else {
 425     $self->freesidestatus($status);
 426     $self->rated_price($rated_price);
 427     $self->svcnum($svcnum) if $svcnum;
 428     return $self->replace();
 429   }
 430 }
 431
 432 =item calldate_unix
 433
 434 Parses the calldate in SQL string format and returns a UNIX timestamp.
 435
 436 =cut
 437
 438 sub calldate_unix {
 439   str2time(shift->calldate);
 440 }
 441
 442 =item startdate_sql
 443
 444 Parses the startdate in UNIX timestamp format and returns a string in SQL
 445 format.
 446
 447 =cut
 448
 449 sub startdate_sql {
 450   my($sec,$min,$hour,$mday,$mon,$year) = localtime(shift->startdate);
 451   $mon++;
 452   $year += 1900;
 453   "$year-$mon-$mday $hour:$min:$sec";
 454 }
 455
 456 =item cdr_carrier
 457
 458 Returns the FS::cdr_carrier object associated with this CDR, or false if no
 459 carrierid is defined.
 460
 461 =cut
 462
 463 my %carrier_cache = ();
 464
 465 sub cdr_carrier {
 466   my $self = shift;
 467   return '' unless $self->carrierid;
 468   $carrier_cache{$self->carrierid} ||=
 469     qsearchs('cdr_carrier', { 'carrierid' => $self->carrierid } );
 470 }
 471
 472 =item carriername
 473
 474 Returns the carrier name (see L<FS::cdr_carrier>), or the empty string if
 475 no FS::cdr_carrier object is assocated with this CDR.
 476
 477 =cut
 478
 479 sub carriername {
 480   my $self = shift;
 481   my $cdr_carrier = $self->cdr_carrier;
 482   $cdr_carrier ? $cdr_carrier->carriername : '';
 483 }
 484
 485 =item cdr_calltype
 486
 487 Returns the FS::cdr_calltype object associated with this CDR, or false if no
 488 calltypenum is defined.
 489
 490 =cut
 491
 492 my %calltype_cache = ();
 493
 494 sub cdr_calltype {
 495   my $self = shift;
 496   return '' unless $self->calltypenum;
 497   $calltype_cache{$self->calltypenum} ||=
 498     qsearchs('cdr_calltype', { 'calltypenum' => $self->calltypenum } );
 499 }
 500
 501 =item calltypename
 502
 503 Returns the call type name (see L<FS::cdr_calltype>), or the empty string if
 504 no FS::cdr_calltype object is assocated with this CDR.
 505
 506 =cut
 507
 508 sub calltypename {
 509   my $self = shift;
 510   my $cdr_calltype = $self->cdr_calltype;
 511   $cdr_calltype ? $cdr_calltype->calltypename : '';
 512 }
 513
 514 =item downstream_csv [ OPTION => VALUE, ... ]
 515
 516 =cut
 517
 518 my %export_names = (
 519   'simple'  => {
 520     'name'           => 'Simple',
 521     'invoice_header' => "Date,Time,Name,Destination,Duration,Price",
 522   },
 523   'simple2' => {
 524     'name'           => 'Simple with source',
 525     'invoice_header' => "Date,Time,Called From,Destination,Duration,Price",
 526                        #"Date,Time,Name,Called From,Destination,Duration,Price",
 527   },
 528   'basic' => {
 529     'name'           => 'Basic',
 530     'invoice_header' => "Date/Time,Called Number,Min/Sec,Price",
 531   },
 532   'default' => {
 533     'name'           => 'Default',
 534     'invoice_header' => 'Date,Time,Number,Destination,Duration,Price',
 535   },
 536   'source_default' => {
 537     'name'           => 'Default with source',
 538     'invoice_header' => 'Caller,Date,Time,Number,Destination,Duration,Price',
 539   },
 540   'accountcode_default' => {
 541     'name'           => 'Default plus accountcode',
 542     'invoice_header' => 'Date,Time,Account,Number,Destination,Duration,Price',
 543   },
 544 );
 545
 546 my %export_formats = ();
 547 sub export_formats {
 548   #my $self = shift;
 549
 550   return %export_formats if keys %export_formats;
 551
 552   my $conf = new FS::Conf;
 553   my $date_format = $conf->config('date_format') || '%m/%d/%Y';
 554
 555   # This is now smarter, and shows the call duration in the
 556   # largest units that accurately reflect the granularity.
 557   my $duration_sub = sub {
 558     my($cdr, %opt) = @_;
 559     my $sec = $opt{seconds} || $cdr->billsec;
 560     if ( length($opt{granularity}) &&
 561          $opt{granularity} == 0 ) { #per call
 562       return '1 call';
 563     }
 564     elsif ( $opt{granularity} == 60 ) {#full minutes
 565       return sprintf("%.0fm",$sec/60);
 566     }
 567     else { #anything else
 568       return sprintf("%dm %ds", $sec/60, $sec%60);
 569     }
 570   };
 571
 572   %export_formats = (
 573     'simple' => [
 574       sub { time2str($date_format, shift->calldate_unix ) },   #DATE
 575       sub { time2str('%r', shift->calldate_unix ) },   #TIME
 576       'userfield',                                     #USER
 577       'dst',                                           #NUMBER_DIALED
 578       $duration_sub,                                   #DURATION
 579       #sub { sprintf('%.3f', shift->upstream_price ) }, #PRICE
 580       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; }, #PRICE
 581     ],
 582     'simple2' => [
 583       sub { time2str($date_format, shift->calldate_unix ) },   #DATE
 584       sub { time2str('%r', shift->calldate_unix ) },   #TIME
 585       #'userfield',                                     #USER
 586       'src',                                           #called from
 587       'dst',                                           #NUMBER_DIALED
 588       $duration_sub,                                   #DURATION
 589       #sub { sprintf('%.3f', shift->upstream_price ) }, #PRICE
 590       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; }, #PRICE
 591     ],
 592     'basic' => [
 593       sub { time2str('%d %b - %I:%M %p', shift->calldate_unix) },
 594       'dst',
 595       $duration_sub,
 596       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; }, #PRICE
 597     ],
 598     'default' => [
 599
 600       #DATE
 601       sub { time2str($date_format, shift->calldate_unix ) },
 602             # #time2str("%Y %b %d - %r", $cdr->calldate_unix ),
 603
 604       #TIME
 605       sub { time2str('%r', shift->calldate_unix ) },
 606             # time2str("%c", $cdr->calldate_unix),  #XXX this should probably be a config option dropdown so they can select US vs- rest of world dates or whatnot
 607
 608       #DEST ("Number")
 609       sub { my($cdr, %opt) = @_; $opt{pretty_dst} || $cdr->dst; },
 610
 611       #REGIONNAME ("Destination")
 612       sub { my($cdr, %opt) = @_; $opt{dst_regionname}; },
 613
 614       #DURATION
 615       $duration_sub,
 616
 617       #PRICE
 618       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; },
 619
 620     ],
 621   );
 622   $export_formats{'source_default'} = [ 'src', @{ $export_formats{'default'} }, ];
 623   $export_formats{'accountcode_default'} =
 624     [ @{ $export_formats{'default'} }[0,1],
 625       'accountcode',
 626       @{ $export_formats{'default'} }[2..5],
 627     ];
 628
 629   %export_formats
 630 }
 631
 632 sub downstream_csv {
 633   my( $self, %opt ) = @_;
 634
 635   my $format = $opt{'format'};
 636   my %formats = $self->export_formats;
 637   return "Unknown format $format" unless exists $formats{$format};
 638
 639   #my $conf = new FS::Conf;
 640   #$opt{'money_char'} ||= $conf->config('money_char') || '$';
 641   $opt{'money_char'} ||= FS::Conf->new->config('money_char') || '$';
 642
 643   eval "use Text::CSV_XS;";
 644   die $@ if $@;
 645   my $csv = new Text::CSV_XS;
 646
 647   my @columns =
 648     map {
 649           ref($_) ? &{$_}($self, %opt) : $self->$_();
 650         }
 651     @{ $formats{$format} };
 652
 653   my $status = $csv->combine(@columns);
 654   die "FS::CDR: error combining ". $csv->error_input(). "into downstream CSV"
 655     unless $status;
 656
 657   $csv->string;
 658
 659 }
 660
 661 =back
 662
 663 =head1 CLASS METHODS
 664
 665 =over 4
 666
 667 =item invoice_formats
 668
 669 Returns an ordered list of key value pairs containing invoice format names
 670 as keys (for use with part_pkg::voip_cdr) and "pretty" format names as values.
 671
 672 =cut
 673
 674 sub invoice_formats {
 675   map { ($_ => $export_names{$_}->{'name'}) }
 676     grep { $export_names{$_}->{'invoice_header'} }
 677     keys %export_names;
 678 }
 679
 680 =item invoice_header FORMAT
 681
 682 Returns a scalar containing the CSV column header for invoice format FORMAT.
 683
 684 =cut
 685
 686 sub invoice_header {
 687   my $format = shift;
 688   $export_names{$format}->{'invoice_header'};
 689 }
 690
 691 =item clear_status
 692
 693 Clears cdr and any associated cdr_termination statuses - used for
 694 CDR reprocessing.
 695
 696 =cut
 697
 698 sub clear_status {
 699   my $self = shift;
 700
 701   local $SIG{HUP} = 'IGNORE';
 702   local $SIG{INT} = 'IGNORE';
 703   local $SIG{QUIT} = 'IGNORE';
 704   local $SIG{TERM} = 'IGNORE';
 705   local $SIG{TSTP} = 'IGNORE';
 706   local $SIG{PIPE} = 'IGNORE';
 707
 708   my $oldAutoCommit = $FS::UID::AutoCommit;
 709   local $FS::UID::AutoCommit = 0;
 710   my $dbh = dbh;
 711
 712   $self->freesidestatus('');
 713   my $error = $self->replace;
 714   if ( $error ) {
 715     $dbh->rollback if $oldAutoCommit;
 716     return $error;
 717   }
 718
 719   my @cdr_termination = qsearch('cdr_termination',
 720                                 { 'acctid' => $self->acctid } );
 721   foreach my $cdr_termination ( @cdr_termination ) {
 722       $cdr_termination->status('');
 723       $error = $cdr_termination->replace;
 724       if ( $error ) {
 725         $dbh->rollback if $oldAutoCommit;
 726         return $error;
 727       }
 728   }
 729
 730   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 731
 732   '';
 733 }
 734
 735 =item import_formats
 736
 737 Returns an ordered list of key value pairs containing import format names
 738 as keys (for use with batch_import) and "pretty" format names as values.
 739
 740 =cut
 741
 742 #false laziness w/part_pkg & part_export
 743
 744 my %cdr_info;
 745 foreach my $INC ( @INC ) {
 746   warn "globbing $INC/FS/cdr/*.pm\n" if $DEBUG;
 747   foreach my $file ( glob("$INC/FS/cdr/*.pm") ) {
 748     warn "attempting to load CDR format info from $file\n" if $DEBUG;
 749     $file =~ /\/(\w+)\.pm$/ or do {
 750       warn "unrecognized file in $INC/FS/cdr/: $file\n";
 751       next;
 752     };
 753     my $mod = $1;
 754     my $info = eval "use FS::cdr::$mod; ".
 755                     "\\%FS::cdr::$mod\::info;";
 756     if ( $@ ) {
 757       die "error using FS::cdr::$mod (skipping): $@\n" if $@;
 758       next;
 759     }
 760     unless ( keys %$info ) {
 761       warn "no %info hash found in FS::cdr::$mod, skipping\n";
 762       next;
 763     }
 764     warn "got CDR format info from FS::cdr::$mod: $info\n" if $DEBUG;
 765     if ( exists($info->{'disabled'}) && $info->{'disabled'} ) {
 766       warn "skipping disabled CDR format FS::cdr::$mod" if $DEBUG;
 767       next;
 768     }
 769     $cdr_info{$mod} = $info;
 770   }
 771 }
 772
 773 tie my %import_formats, 'Tie::IxHash',
 774   map  { $_ => $cdr_info{$_}->{'name'} }
 775   sort { $cdr_info{$a}->{'weight'} <=> $cdr_info{$b}->{'weight'} }
 776   grep { exists($cdr_info{$_}->{'import_fields'}) }
 777   keys %cdr_info;
 778
 779 sub import_formats {
 780   %import_formats;
 781 }
 782
 783 sub _cdr_min_parser_maker {
 784   my $field = shift;
 785   my @fields = ref($field) ? @$field : ($field);
 786   @fields = qw( billsec duration ) unless scalar(@fields) && $fields[0];
 787   return sub {
 788     my( $cdr, $min ) = @_;
 789     my $sec = eval { _cdr_min_parse($min) };
 790     die "error parsing seconds for @fields from $min minutes: $@\n" if $@;
 791     $cdr->$_($sec) foreach @fields;
 792   };
 793 }
 794
 795 sub _cdr_min_parse {
 796   my $min = shift;
 797   sprintf('%.0f', $min * 60 );
 798 }
 799
 800 sub _cdr_date_parser_maker {
 801   my $field = shift;
 802   my %options = @_;
 803   my @fields = ref($field) ? @$field : ($field);
 804   return sub {
 805     my( $cdr, $datestring ) = @_;
 806     my $unixdate = eval { _cdr_date_parse($datestring, %options) };
 807     die "error parsing date for @fields from $datestring: $@\n" if $@;
 808     $cdr->$_($unixdate) foreach @fields;
 809   };
 810 }
 811
 812 sub _cdr_date_parse {
 813   my $date = shift;
 814   my %options = @_;
 815
 816   return '' unless length($date); #that's okay, it becomes NULL
 817   return '' if $date eq 'NA'; #sansay
 818
 819   if ( $date =~ /^([a-z]{3})\s+([a-z]{3})\s+(\d{1,2})\s+(\d{1,2}):(\d{1,2}):(\d{1,2})\s+(\d{4})$/i && $7 > 1970 ) {
 820     my $time = str2time($date);
 821     return $time if $time > 100000; #just in case
 822   }
 823
 824   my($year, $mon, $day, $hour, $min, $sec);
 825
 826   #$date =~ /^\s*(\d{4})[\-\/]\(\d{1,2})[\-\/](\d{1,2})\s+(\d{1,2}):(\d{1,2}):(\d{1,2})\s*$/
 827   #taqua  #2007-10-31 08:57:24.113000000
 828
 829   if ( $date =~ /^\s*(\d{4})\D(\d{1,2})\D(\d{1,2})\D+(\d{1,2})\D(\d{1,2})\D(\d{1,2})(\D|$)/ ) {
 830     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 831   } elsif ( $date  =~ /^\s*(\d{1,2})\D(\d{1,2})\D(\d{4})\s+(\d{1,2})\D(\d{1,2})(?:\D(\d{1,2}))?(\D|$)/ ) {
 832     # 8/26/2010 12:20:01
 833     # optionally without seconds
 834     ($mon, $day, $year, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 835     $sec = 0 if !defined($sec);
 836   } elsif ( $date  =~ /^\s*(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d+\.\d+)(\D|$)/ ) {
 837     # broadsoft: 20081223201938.314
 838     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 839   } elsif ( $date  =~ /^\s*(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})\d+(\D|$)/ ) {
 840     # Taqua OM:  20050422203450943
 841     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 842   } elsif ( $date  =~ /^\s*(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})$/ ) {
 843     # WIP: 20100329121420
 844     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 845   } elsif ( $date =~ /^(\d{4})-(\d{2})-(\d{2})T(\d{2}):(\d{2}):(\d{2})Z$/) {
 846     # Telos
 847     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 848     $options{gmt} = 1;
 849   } else {
 850      die "unparsable date: $date"; #maybe we shouldn't die...
 851   }
 852
 853   return '' if ( $year == 1900 || $year == 1970 ) && $mon == 1 && $day == 1
 854             && $hour == 0 && $min == 0 && $sec == 0;
 855
 856   if ($options{gmt}) {
 857     timegm($sec, $min, $hour, $day, $mon-1, $year);
 858   } else {
 859     timelocal($sec, $min, $hour, $day, $mon-1, $year);
 860   }
 861 }
 862
 863 =item batch_import HASHREF
 864
 865 Imports CDR records.  Available options are:
 866
 867 =over 4
 868
 869 =item file
 870
 871 Filename
 872
 873 =item format
 874
 875 =item params
 876
 877 Hash reference of preset fields, typically cdrbatch
 878
 879 =item empty_ok
 880
 881 Set true to prevent throwing an error on empty imports
 882
 883 =back
 884
 885 =cut
 886
 887 my %import_options = (
 888   'table'         => 'cdr',
 889
 890   'batch_keycol'  => 'cdrbatchnum',
 891   'batch_table'   => 'cdr_batch',
 892   'batch_namecol' => 'cdrbatch',
 893
 894   'formats' => { map { $_ => $cdr_info{$_}->{'import_fields'}; }
 895                      keys %cdr_info
 896                },
 897
 898                           #drop the || 'csv' to allow auto xls for csv types?
 899   'format_types' => { map { $_ => ( lc($cdr_info{$_}->{'type'}) || 'csv' ); }
 900                           keys %cdr_info
 901                     },
 902
 903   'format_headers' => { map { $_ => ( $cdr_info{$_}->{'header'} || 0 ); }
 904                             keys %cdr_info
 905                       },
 906
 907   'format_sep_chars' => { map { $_ => $cdr_info{$_}->{'sep_char'}; }
 908                               keys %cdr_info
 909                         },
 910
 911   'format_fixedlength_formats' =>
 912     { map { $_ => $cdr_info{$_}->{'fixedlength_format'}; }
 913           keys %cdr_info
 914     },
 915
 916   'format_xml_formats' =>
 917     { map { $_ => $cdr_info{$_}->{'xml_format'}; }
 918           keys %cdr_info
 919     },
 920
 921   'format_row_callbacks' => { map { $_ => $cdr_info{$_}->{'row_callback'}; }
 922                                   keys %cdr_info
 923                             },
 924 );
 925
 926 sub _import_options {
 927   \%import_options;
 928 }
 929
 930 sub batch_import {
 931   my $opt = shift;
 932
 933   my $iopt = _import_options;
 934   $opt->{$_} = $iopt->{$_} foreach keys %$iopt;
 935
 936   FS::Record::batch_import( $opt );
 937
 938 }
 939
 940 =item process_batch_import
 941
 942 =cut
 943
 944 sub process_batch_import {
 945   my $job = shift;
 946
 947   my $opt = _import_options;
 948 #  $opt->{'params'} = [ 'format', 'cdrbatch' ];
 949
 950   FS::Record::process_batch_import( $job, $opt, @_ );
 951
 952 }
 953 #  if ( $format eq 'simple' ) { #should be a callback or opt in FS::cdr::simple
 954 #    @columns = map { s/^ +//; $_; } @columns;
 955 #  }
 956
 957 # _ upgrade_data
 958 #
 959 # Used by FS::Upgrade to migrate to a new database.
 960
 961 sub _upgrade_data {
 962   my ($class, %opts) = @_;
 963
 964   warn "$me upgrading $class\n" if $DEBUG;
 965
 966   my $sth = dbh->prepare(
 967     'SELECT DISTINCT(cdrbatch) FROM cdr WHERE cdrbatch IS NOT NULL'
 968   ) or die dbh->errstr;
 969
 970   $sth->execute or die $sth->errstr;
 971
 972   my %cdrbatchnum = ();
 973   while (my $row = $sth->fetchrow_arrayref) {
 974
 975     my $cdr_batch = qsearchs( 'cdr_batch', { 'cdrbatch' => $row->[0] } );
 976     unless ( $cdr_batch ) {
 977       $cdr_batch = new FS::cdr_batch { 'cdrbatch' => $row->[0] };
 978       my $error = $cdr_batch->insert;
 979       die $error if $error;
 980     }
 981
 982     $cdrbatchnum{$row->[0]} = $cdr_batch->cdrbatchnum;
 983   }
 984
 985   $sth = dbh->prepare('UPDATE cdr SET cdrbatch = NULL, cdrbatchnum = ? WHERE cdrbatch IS NOT NULL AND cdrbatch = ?') or die dbh->errstr;
 986
 987   foreach my $cdrbatch (keys %cdrbatchnum) {
 988     $sth->execute($cdrbatchnum{$cdrbatch}, $cdrbatch) or die $sth->errstr;
 989   }
 990
 991 }
 992
 993 =back
 994
 995 =head1 BUGS
 996
 997 =head1 SEE ALSO
 998
 999 L<FS::Record>, schema.html from the base documentation.
1000
1001 =cut
1002
1003 1;
1004