FS/FS/cdr.pm

   1 package FS::cdr;
   2
   3 use strict;
   4 use vars qw( @ISA @EXPORT_OK $DEBUG $me );
   5 use Exporter;
   6 use Tie::IxHash;
   7 use Date::Parse;
   8 use Date::Format;
   9 use Time::Local;
  10 use FS::UID qw( dbh );
  11 use FS::Conf;
  12 use FS::Record qw( qsearch qsearchs );
  13 use FS::cdr_type;
  14 use FS::cdr_calltype;
  15 use FS::cdr_carrier;
  16 use FS::cdr_batch;
  17 use FS::cdr_termination;
  18
  19 @ISA = qw(FS::Record);
  20 @EXPORT_OK = qw( _cdr_date_parser_maker _cdr_min_parser_maker );
  21
  22 $DEBUG = 0;
  23 $me = '[FS::cdr]';
  24
  25 =head1 NAME
  26
  27 FS::cdr - Object methods for cdr records
  28
  29 =head1 SYNOPSIS
  30
  31   use FS::cdr;
  32
  33   $record = new FS::cdr \%hash;
  34   $record = new FS::cdr { 'column' => 'value' };
  35
  36   $error = $record->insert;
  37
  38   $error = $new_record->replace($old_record);
  39
  40   $error = $record->delete;
  41
  42   $error = $record->check;
  43
  44 =head1 DESCRIPTION
  45
  46 An FS::cdr object represents an Call Data Record, typically from a telephony
  47 system or provider of some sort.  FS::cdr inherits from FS::Record.  The
  48 following fields are currently supported:
  49
  50 =over 4
  51
  52 =item acctid - primary key
  53
  54 =item calldate - Call timestamp (SQL timestamp)
  55
  56 =item clid - Caller*ID with text
  57
  58 =item src - Caller*ID number / Source number
  59
  60 =item dst - Destination extension
  61
  62 =item dcontext - Destination context
  63
  64 =item channel - Channel used
  65
  66 =item dstchannel - Destination channel if appropriate
  67
  68 =item lastapp - Last application if appropriate
  69
  70 =item lastdata - Last application data
  71
  72 =item startdate - Start of call (UNIX-style integer timestamp)
  73
  74 =item answerdate - Answer time of call (UNIX-style integer timestamp)
  75
  76 =item enddate - End time of call (UNIX-style integer timestamp)
  77
  78 =item duration - Total time in system, in seconds
  79
  80 =item billsec - Total time call is up, in seconds
  81
  82 =item disposition - What happened to the call: ANSWERED, NO ANSWER, BUSY
  83
  84 =item amaflags - What flags to use: BILL, IGNORE etc, specified on a per channel basis like accountcode.
  85
  86 =cut
  87
  88   #ignore the "omit" and "documentation" AMAs??
  89   #AMA = Automated Message Accounting.
  90   #default: Sets the system default.
  91   #omit: Do not record calls.
  92   #billing: Mark the entry for billing
  93   #documentation: Mark the entry for documentation.
  94
  95 =item accountcode - CDR account number to use: account
  96
  97 =item uniqueid - Unique channel identifier (Unitel/RSLCOM Event ID)
  98
  99 =item userfield - CDR user-defined field
 100
 101 =item cdr_type - CDR type - see L<FS::cdr_type> (Usage = 1, S&E = 7, OC&C = 8)
 102
 103 =item charged_party - Service number to be billed
 104
 105 =item upstream_currency - Wholesale currency from upstream
 106
 107 =item upstream_price - Wholesale price from upstream
 108
 109 =item upstream_rateplanid - Upstream rate plan ID
 110
 111 =item rated_price - Rated (or re-rated) price
 112
 113 =item distance - km (need units field?)
 114
 115 =item islocal - Local - 1, Non Local = 0
 116
 117 =item calltypenum - Type of call - see L<FS::cdr_calltype>
 118
 119 =item description - Description (cdr_type 7&8 only) (used for cust_bill_pkg.itemdesc)
 120
 121 =item quantity - Number of items (cdr_type 7&8 only)
 122
 123 =item carrierid - Upstream Carrier ID (see L<FS::cdr_carrier>)
 124
 125 =cut
 126
 127 #Telstra =1, Optus = 2, RSL COM = 3
 128
 129 =item upstream_rateid - Upstream Rate ID
 130
 131 =item svcnum - Link to customer service (see L<FS::cust_svc>)
 132
 133 =item freesidestatus - NULL, done (or something)
 134
 135 =item freesiderewritestatus - NULL, done (or something)
 136
 137 =item cdrbatch
 138
 139 =back
 140
 141 =head1 METHODS
 142
 143 =over 4
 144
 145 =item new HASHREF
 146
 147 Creates a new CDR.  To add the CDR to the database, see L<"insert">.
 148
 149 Note that this stores the hash reference, not a distinct copy of the hash it
 150 points to.  You can ask the object for a copy with the I<hash> method.
 151
 152 =cut
 153
 154 # the new method can be inherited from FS::Record, if a table method is defined
 155
 156 sub table { 'cdr'; }
 157
 158 sub table_info {
 159   {
 160     'fields' => {
 161 #XXX fill in some (more) nice names
 162         #'acctid'                => '',
 163         'calldate'              => 'Call date',
 164         'clid'                  => 'Caller ID',
 165         'src'                   => 'Source',
 166         'dst'                   => 'Destination',
 167         'dcontext'              => 'Dest. context',
 168         'channel'               => 'Channel',
 169         'dstchannel'            => 'Destination channel',
 170         #'lastapp'               => '',
 171         #'lastdata'              => '',
 172         'startdate'             => 'Start date',
 173         'answerdate'            => 'Answer date',
 174         'enddate'               => 'End date',
 175         'duration'              => 'Duration',
 176         'billsec'               => 'Billable seconds',
 177         'disposition'           => 'Disposition',
 178         'amaflags'              => 'AMA flags',
 179         'accountcode'           => 'Account code',
 180         #'uniqueid'              => '',
 181         'userfield'             => 'User field',
 182         #'cdrtypenum'            => '',
 183         'charged_party'         => 'Charged party',
 184         #'upstream_currency'     => '',
 185         'upstream_price'        => 'Upstream price',
 186         #'upstream_rateplanid'   => '',
 187         #'ratedetailnum'         => '',
 188         'rated_price'           => 'Rated price',
 189         #'distance'              => '',
 190         #'islocal'               => '',
 191         #'calltypenum'           => '',
 192         #'description'           => '',
 193         #'quantity'              => '',
 194         'carrierid'             => 'Carrier ID',
 195         #'upstream_rateid'       => '',
 196         'svcnum'                => 'Freeside service',
 197         'freesidestatus'        => 'Freeside status',
 198         'freesiderewritestatus' => 'Freeside rewrite status',
 199         'cdrbatch'              => 'Legacy batch',
 200         'cdrbatchnum'           => 'Batch',
 201     },
 202
 203   };
 204
 205 }
 206
 207 =item insert
 208
 209 Adds this record to the database.  If there is an error, returns the error,
 210 otherwise returns false.
 211
 212 =cut
 213
 214 # the insert method can be inherited from FS::Record
 215
 216 =item delete
 217
 218 Delete this record from the database.
 219
 220 =cut
 221
 222 # the delete method can be inherited from FS::Record
 223
 224 =item replace OLD_RECORD
 225
 226 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 227 returns the error, otherwise returns false.
 228
 229 =cut
 230
 231 # the replace method can be inherited from FS::Record
 232
 233 =item check
 234
 235 Checks all fields to make sure this is a valid CDR.  If there is
 236 an error, returns the error, otherwise returns false.  Called by the insert
 237 and replace methods.
 238
 239 Note: Unlike most types of records, we don't want to "reject" a CDR and we want
 240 to process them as quickly as possible, so we allow the database to check most
 241 of the data.
 242
 243 =cut
 244
 245 sub check {
 246   my $self = shift;
 247
 248 # we don't want to "reject" a CDR like other sorts of input...
 249 #  my $error =
 250 #    $self->ut_numbern('acctid')
 251 ##    || $self->ut_('calldate')
 252 #    || $self->ut_text('clid')
 253 #    || $self->ut_text('src')
 254 #    || $self->ut_text('dst')
 255 #    || $self->ut_text('dcontext')
 256 #    || $self->ut_text('channel')
 257 #    || $self->ut_text('dstchannel')
 258 #    || $self->ut_text('lastapp')
 259 #    || $self->ut_text('lastdata')
 260 #    || $self->ut_numbern('startdate')
 261 #    || $self->ut_numbern('answerdate')
 262 #    || $self->ut_numbern('enddate')
 263 #    || $self->ut_number('duration')
 264 #    || $self->ut_number('billsec')
 265 #    || $self->ut_text('disposition')
 266 #    || $self->ut_number('amaflags')
 267 #    || $self->ut_text('accountcode')
 268 #    || $self->ut_text('uniqueid')
 269 #    || $self->ut_text('userfield')
 270 #    || $self->ut_numbern('cdrtypenum')
 271 #    || $self->ut_textn('charged_party')
 272 ##    || $self->ut_n('upstream_currency')
 273 ##    || $self->ut_n('upstream_price')
 274 #    || $self->ut_numbern('upstream_rateplanid')
 275 ##    || $self->ut_n('distance')
 276 #    || $self->ut_numbern('islocal')
 277 #    || $self->ut_numbern('calltypenum')
 278 #    || $self->ut_textn('description')
 279 #    || $self->ut_numbern('quantity')
 280 #    || $self->ut_numbern('carrierid')
 281 #    || $self->ut_numbern('upstream_rateid')
 282 #    || $self->ut_numbern('svcnum')
 283 #    || $self->ut_textn('freesidestatus')
 284 #    || $self->ut_textn('freesiderewritestatus')
 285 #  ;
 286 #  return $error if $error;
 287
 288   for my $f ( grep { $self->$_ =~ /\D/ } qw(startdate answerdate enddate)){
 289     $self->$f( str2time($self->$f) );
 290   }
 291
 292   $self->calldate( $self->startdate_sql )
 293     if !$self->calldate && $self->startdate;
 294
 295   #was just for $format eq 'taqua' but can't see the harm... add something to
 296   #disable if it becomes a problem
 297   if ( $self->duration eq '' && $self->enddate && $self->startdate ) {
 298     $self->duration( $self->enddate - $self->startdate  );
 299   }
 300   if ( $self->billsec eq '' && $self->enddate && $self->answerdate ) {
 301     $self->billsec(  $self->enddate - $self->answerdate );
 302   }
 303
 304   $self->set_charged_party;
 305
 306   #check the foreign keys even?
 307   #do we want to outright *reject* the CDR?
 308   my $error =
 309        $self->ut_numbern('acctid')
 310
 311   #add a config option to turn these back on if someone needs 'em
 312   #
 313   #  #Usage = 1, S&E = 7, OC&C = 8
 314   #  || $self->ut_foreign_keyn('cdrtypenum',  'cdr_type',     'cdrtypenum' )
 315   #
 316   #  #the big list in appendix 2
 317   #  || $self->ut_foreign_keyn('calltypenum', 'cdr_calltype', 'calltypenum' )
 318   #
 319   #  # Telstra =1, Optus = 2, RSL COM = 3
 320   #  || $self->ut_foreign_keyn('carrierid', 'cdr_carrier', 'carrierid' )
 321   ;
 322   return $error if $error;
 323
 324   $self->SUPER::check;
 325 }
 326
 327 =item is_tollfree [ COLUMN ]
 328
 329 Returns true when the cdr represents a toll free number and false otherwise.
 330
 331 By default, inspects the dst field, but an optional column name can be passed
 332 to inspect other field.
 333
 334 =cut
 335
 336 sub is_tollfree {
 337   my $self = shift;
 338   my $field = scalar(@_) ? shift : 'dst';
 339   ( $self->$field() =~ /^(\+?1)?8(8|([02-7])\3)/ ) ? 1 : 0;
 340 }
 341
 342 =item set_charged_party
 343
 344 If the charged_party field is already set, does nothing.  Otherwise:
 345
 346 If the cdr-charged_party-accountcode config option is enabled, sets the
 347 charged_party to the accountcode.
 348
 349 Otherwise sets the charged_party normally: to the src field in most cases,
 350 or to the dst field if it is a toll free number.
 351
 352 =cut
 353
 354 sub set_charged_party {
 355   my $self = shift;
 356
 357   my $conf = new FS::Conf;
 358
 359   unless ( $self->charged_party ) {
 360
 361     if ( $conf->exists('cdr-charged_party-accountcode') && $self->accountcode ){
 362
 363       my $charged_party = $self->accountcode;
 364       $charged_party =~ s/^0+//
 365         if $conf->exists('cdr-charged_party-accountcode-trim_leading_0s');
 366       $self->charged_party( $charged_party );
 367
 368     } elsif ( $conf->exists('cdr-charged_party-field') ) {
 369
 370       my $field = $conf->config('cdr-charged_party-field');
 371       $self->charged_party( $self->$field() );
 372
 373     } else {
 374
 375       if ( $self->is_tollfree ) {
 376         $self->charged_party($self->dst);
 377       } else {
 378         $self->charged_party($self->src);
 379       }
 380
 381     }
 382
 383   }
 384
 385 #  my $prefix = $conf->config('cdr-charged_party-truncate_prefix');
 386 #  my $prefix_len = length($prefix);
 387 #  my $trunc_len = $conf->config('cdr-charged_party-truncate_length');
 388 #
 389 #  $self->charged_party( substr($self->charged_party, 0, $trunc_len) )
 390 #    if $prefix_len && $trunc_len
 391 #    && substr($self->charged_party, 0, $prefix_len) eq $prefix;
 392
 393 }
 394
 395 =item set_status_and_rated_price STATUS [ RATED_PRICE [ SVCNUM ] ]
 396
 397 Sets the status to the provided string.  If there is an error, returns the
 398 error, otherwise returns false.
 399
 400 =cut
 401
 402 sub set_status_and_rated_price {
 403   my($self, $status, $rated_price, $svcnum, %opt) = @_;
 404
 405   if ($opt{'inbound'}) {
 406
 407     my $term = qsearchs('cdr_termination', {
 408         acctid   => $self->acctid,
 409         termpart => 1 # inbound
 410     });
 411     my $error;
 412     if ( $term ) {
 413       warn "replacing existing cdr status (".$self->acctid.")\n" if $term;
 414       $error = $term->delete;
 415       return $error if $error;
 416     }
 417     $term = FS::cdr_termination->new({
 418         acctid      => $self->acctid,
 419         termpart    => 1,
 420         rated_price => $rated_price,
 421         status      => $status,
 422         svcnum      => $svcnum,
 423     });
 424     $term->rated_seconds($opt{rated_seconds}) if exists($opt{rated_seconds});
 425     $term->rated_minutes($opt{rated_minutes}) if exists($opt{rated_minutes});
 426     return $term->insert;
 427
 428   } else {
 429
 430     $self->freesidestatus($status);
 431     $self->rated_price($rated_price);
 432     $self->rated_seconds($opt{rated_seconds}) if exists($opt{rated_seconds});
 433     $self->rated_minutes($opt{rated_minutes}) if exists($opt{rated_minutes});
 434     $self->svcnum($svcnum) if $svcnum;
 435     return $self->replace();
 436
 437   }
 438 }
 439
 440 =item calldate_unix
 441
 442 Parses the calldate in SQL string format and returns a UNIX timestamp.
 443
 444 =cut
 445
 446 sub calldate_unix {
 447   str2time(shift->calldate);
 448 }
 449
 450 =item startdate_sql
 451
 452 Parses the startdate in UNIX timestamp format and returns a string in SQL
 453 format.
 454
 455 =cut
 456
 457 sub startdate_sql {
 458   my($sec,$min,$hour,$mday,$mon,$year) = localtime(shift->startdate);
 459   $mon++;
 460   $year += 1900;
 461   "$year-$mon-$mday $hour:$min:$sec";
 462 }
 463
 464 =item cdr_carrier
 465
 466 Returns the FS::cdr_carrier object associated with this CDR, or false if no
 467 carrierid is defined.
 468
 469 =cut
 470
 471 my %carrier_cache = ();
 472
 473 sub cdr_carrier {
 474   my $self = shift;
 475   return '' unless $self->carrierid;
 476   $carrier_cache{$self->carrierid} ||=
 477     qsearchs('cdr_carrier', { 'carrierid' => $self->carrierid } );
 478 }
 479
 480 =item carriername
 481
 482 Returns the carrier name (see L<FS::cdr_carrier>), or the empty string if
 483 no FS::cdr_carrier object is assocated with this CDR.
 484
 485 =cut
 486
 487 sub carriername {
 488   my $self = shift;
 489   my $cdr_carrier = $self->cdr_carrier;
 490   $cdr_carrier ? $cdr_carrier->carriername : '';
 491 }
 492
 493 =item cdr_calltype
 494
 495 Returns the FS::cdr_calltype object associated with this CDR, or false if no
 496 calltypenum is defined.
 497
 498 =cut
 499
 500 my %calltype_cache = ();
 501
 502 sub cdr_calltype {
 503   my $self = shift;
 504   return '' unless $self->calltypenum;
 505   $calltype_cache{$self->calltypenum} ||=
 506     qsearchs('cdr_calltype', { 'calltypenum' => $self->calltypenum } );
 507 }
 508
 509 =item calltypename
 510
 511 Returns the call type name (see L<FS::cdr_calltype>), or the empty string if
 512 no FS::cdr_calltype object is assocated with this CDR.
 513
 514 =cut
 515
 516 sub calltypename {
 517   my $self = shift;
 518   my $cdr_calltype = $self->cdr_calltype;
 519   $cdr_calltype ? $cdr_calltype->calltypename : '';
 520 }
 521
 522 =item downstream_csv [ OPTION => VALUE, ... ]
 523
 524 =cut
 525
 526 my %export_names = (
 527   'simple'  => {
 528     'name'           => 'Simple',
 529     'invoice_header' => "Date,Time,Name,Destination,Duration,Price",
 530   },
 531   'simple2' => {
 532     'name'           => 'Simple with source',
 533     'invoice_header' => "Date,Time,Called From,Destination,Duration,Price",
 534                        #"Date,Time,Name,Called From,Destination,Duration,Price",
 535   },
 536   'basic' => {
 537     'name'           => 'Basic',
 538     'invoice_header' => "Date/Time,Called Number,Min/Sec,Price",
 539   },
 540   'default' => {
 541     'name'           => 'Default',
 542     'invoice_header' => 'Date,Time,Number,Destination,Duration,Price',
 543   },
 544   'source_default' => {
 545     'name'           => 'Default with source',
 546     'invoice_header' => 'Caller,Date,Time,Number,Destination,Duration,Price',
 547   },
 548   'accountcode_default' => {
 549     'name'           => 'Default plus accountcode',
 550     'invoice_header' => 'Date,Time,Account,Number,Destination,Duration,Price',
 551   },
 552   'description_default' => {
 553     'name'           => 'Default with description field as destination',
 554     'invoice_header' => 'Caller,Date,Time,Number,Destination,Duration,Price',
 555   },
 556 );
 557
 558 my %export_formats = ();
 559 sub export_formats {
 560   #my $self = shift;
 561
 562   return %export_formats if keys %export_formats;
 563
 564   my $conf = new FS::Conf;
 565   my $date_format = $conf->config('date_format') || '%m/%d/%Y';
 566
 567   # call duration in the largest units that accurately reflect the  granularity
 568   my $duration_sub = sub {
 569     my($cdr, %opt) = @_;
 570     my $sec = $opt{seconds} || $cdr->billsec;
 571     if ( defined $opt{granularity} &&
 572          $opt{granularity} == 0 ) { #per call
 573       return '1 call';
 574     }
 575     elsif ( defined $opt{granularity} && $opt{granularity} == 60 ) {#full minutes
 576       my $min = int($sec/60);
 577       $min++ if $sec%60;
 578       return $min.'m';
 579     }
 580     else { #anything else
 581       return sprintf("%dm %ds", $sec/60, $sec%60);
 582     }
 583   };
 584
 585   %export_formats = (
 586     'simple' => [
 587       sub { time2str($date_format, shift->calldate_unix ) },   #DATE
 588       sub { time2str('%r', shift->calldate_unix ) },   #TIME
 589       'userfield',                                     #USER
 590       'dst',                                           #NUMBER_DIALED
 591       $duration_sub,                                   #DURATION
 592       #sub { sprintf('%.3f', shift->upstream_price ) }, #PRICE
 593       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; }, #PRICE
 594     ],
 595     'simple2' => [
 596       sub { time2str($date_format, shift->calldate_unix ) },   #DATE
 597       sub { time2str('%r', shift->calldate_unix ) },   #TIME
 598       #'userfield',                                     #USER
 599       'src',                                           #called from
 600       'dst',                                           #NUMBER_DIALED
 601       $duration_sub,                                   #DURATION
 602       #sub { sprintf('%.3f', shift->upstream_price ) }, #PRICE
 603       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; }, #PRICE
 604     ],
 605     'basic' => [
 606       sub { time2str('%d %b - %I:%M %p', shift->calldate_unix) },
 607       'dst',
 608       $duration_sub,
 609       sub { my($cdr, %opt) = @_; $opt{money_char}. $opt{charge}; }, #PRICE
 610     ],
 611     'default' => [
 612
 613       #DATE
 614       sub { time2str($date_format, shift->calldate_unix ) },
 615             # #time2str("%Y %b %d - %r", $cdr->calldate_unix ),
 616
 617       #TIME
 618       sub { time2str('%r', shift->calldate_unix ) },
 619             # time2str("%c", $cdr->calldate_unix),  #XXX this should probably be a config option dropdown so they can select US vs- rest of world dates or whatnot
 620
 621       #DEST ("Number")
 622       sub { my($cdr, %opt) = @_; $opt{pretty_dst} || $cdr->dst; },
 623
 624       #REGIONNAME ("Destination")
 625       sub { my($cdr, %opt) = @_; $opt{dst_regionname}; },
 626
 627       #DURATION
 628       $duration_sub,
 629
 630       #PRICE
 631       sub { my($cdr, %opt) = @_;
 632         $opt{charge} = '0.00' unless defined $opt{charge};
 633         $opt{money_char}.$opt{charge};
 634       },
 635
 636     ],
 637   );
 638   $export_formats{'source_default'} = [ 'src', @{ $export_formats{'default'} }, ];
 639   $export_formats{'accountcode_default'} =
 640     [ @{ $export_formats{'default'} }[0,1],
 641       'accountcode',
 642       @{ $export_formats{'default'} }[2..5],
 643     ];
 644   my @default = @{ $export_formats{'default'} };
 645   $export_formats{'description_default'} =
 646     [ 'src', @default[0..2],
 647       sub { my($cdr, %opt) = @_; $cdr->description },
 648       @default[4,5] ];
 649
 650   return %export_formats;
 651 }
 652
 653 =item downstream_csv OPTION => VALUE ...
 654
 655 Options:
 656
 657 format
 658
 659 charge
 660
 661 seconds
 662
 663 granularity
 664
 665 =cut
 666
 667 sub downstream_csv {
 668   my( $self, %opt ) = @_;
 669
 670   my $format = $opt{'format'};
 671   my %formats = $self->export_formats;
 672   return "Unknown format $format" unless exists $formats{$format};
 673
 674   #my $conf = new FS::Conf;
 675   #$opt{'money_char'} ||= $conf->config('money_char') || '$';
 676   $opt{'money_char'} ||= FS::Conf->new->config('money_char') || '$';
 677
 678   eval "use Text::CSV_XS;";
 679   die $@ if $@;
 680   my $csv = new Text::CSV_XS;
 681
 682   my @columns =
 683     map {
 684           ref($_) ? &{$_}($self, %opt) : $self->$_();
 685         }
 686     @{ $formats{$format} };
 687
 688   return @columns if defined $opt{'keeparray'};
 689
 690   my $status = $csv->combine(@columns);
 691   die "FS::CDR: error combining ". $csv->error_input(). "into downstream CSV"
 692     unless $status;
 693
 694   $csv->string;
 695
 696 }
 697
 698 =back
 699
 700 =head1 CLASS METHODS
 701
 702 =over 4
 703
 704 =item invoice_formats
 705
 706 Returns an ordered list of key value pairs containing invoice format names
 707 as keys (for use with part_pkg::voip_cdr) and "pretty" format names as values.
 708
 709 =cut
 710
 711 sub invoice_formats {
 712   map { ($_ => $export_names{$_}->{'name'}) }
 713     grep { $export_names{$_}->{'invoice_header'} }
 714     keys %export_names;
 715 }
 716
 717 =item invoice_header FORMAT
 718
 719 Returns a scalar containing the CSV column header for invoice format FORMAT.
 720
 721 =cut
 722
 723 sub invoice_header {
 724   my $format = shift;
 725   $export_names{$format}->{'invoice_header'};
 726 }
 727
 728 =item clear_status
 729
 730 Clears cdr and any associated cdr_termination statuses - used for
 731 CDR reprocessing.
 732
 733 =cut
 734
 735 sub clear_status {
 736   my $self = shift;
 737
 738   local $SIG{HUP} = 'IGNORE';
 739   local $SIG{INT} = 'IGNORE';
 740   local $SIG{QUIT} = 'IGNORE';
 741   local $SIG{TERM} = 'IGNORE';
 742   local $SIG{TSTP} = 'IGNORE';
 743   local $SIG{PIPE} = 'IGNORE';
 744
 745   my $oldAutoCommit = $FS::UID::AutoCommit;
 746   local $FS::UID::AutoCommit = 0;
 747   my $dbh = dbh;
 748
 749   $self->freesidestatus('');
 750   my $error = $self->replace;
 751   if ( $error ) {
 752     $dbh->rollback if $oldAutoCommit;
 753     return $error;
 754   }
 755
 756   my @cdr_termination = qsearch('cdr_termination',
 757                                 { 'acctid' => $self->acctid } );
 758   foreach my $cdr_termination ( @cdr_termination ) {
 759       $cdr_termination->status('');
 760       $error = $cdr_termination->replace;
 761       if ( $error ) {
 762         $dbh->rollback if $oldAutoCommit;
 763         return $error;
 764       }
 765   }
 766
 767   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 768
 769   '';
 770 }
 771
 772 =item import_formats
 773
 774 Returns an ordered list of key value pairs containing import format names
 775 as keys (for use with batch_import) and "pretty" format names as values.
 776
 777 =cut
 778
 779 #false laziness w/part_pkg & part_export
 780
 781 my %cdr_info;
 782 foreach my $INC ( @INC ) {
 783   warn "globbing $INC/FS/cdr/*.pm\n" if $DEBUG;
 784   foreach my $file ( glob("$INC/FS/cdr/*.pm") ) {
 785     warn "attempting to load CDR format info from $file\n" if $DEBUG;
 786     $file =~ /\/(\w+)\.pm$/ or do {
 787       warn "unrecognized file in $INC/FS/cdr/: $file\n";
 788       next;
 789     };
 790     my $mod = $1;
 791     my $info = eval "use FS::cdr::$mod; ".
 792                     "\\%FS::cdr::$mod\::info;";
 793     if ( $@ ) {
 794       die "error using FS::cdr::$mod (skipping): $@\n" if $@;
 795       next;
 796     }
 797     unless ( keys %$info ) {
 798       warn "no %info hash found in FS::cdr::$mod, skipping\n";
 799       next;
 800     }
 801     warn "got CDR format info from FS::cdr::$mod: $info\n" if $DEBUG;
 802     if ( exists($info->{'disabled'}) && $info->{'disabled'} ) {
 803       warn "skipping disabled CDR format FS::cdr::$mod" if $DEBUG;
 804       next;
 805     }
 806     $cdr_info{$mod} = $info;
 807   }
 808 }
 809
 810 tie my %import_formats, 'Tie::IxHash',
 811   map  { $_ => $cdr_info{$_}->{'name'} }
 812   sort { $cdr_info{$a}->{'weight'} <=> $cdr_info{$b}->{'weight'} }
 813   grep { exists($cdr_info{$_}->{'import_fields'}) }
 814   keys %cdr_info;
 815
 816 sub import_formats {
 817   %import_formats;
 818 }
 819
 820 sub _cdr_min_parser_maker {
 821   my $field = shift;
 822   my @fields = ref($field) ? @$field : ($field);
 823   @fields = qw( billsec duration ) unless scalar(@fields) && $fields[0];
 824   return sub {
 825     my( $cdr, $min ) = @_;
 826     my $sec = eval { _cdr_min_parse($min) };
 827     die "error parsing seconds for @fields from $min minutes: $@\n" if $@;
 828     $cdr->$_($sec) foreach @fields;
 829   };
 830 }
 831
 832 sub _cdr_min_parse {
 833   my $min = shift;
 834   sprintf('%.0f', $min * 60 );
 835 }
 836
 837 sub _cdr_date_parser_maker {
 838   my $field = shift;
 839   my %options = @_;
 840   my @fields = ref($field) ? @$field : ($field);
 841   return sub {
 842     my( $cdr, $datestring ) = @_;
 843     my $unixdate = eval { _cdr_date_parse($datestring, %options) };
 844     die "error parsing date for @fields from $datestring: $@\n" if $@;
 845     $cdr->$_($unixdate) foreach @fields;
 846   };
 847 }
 848
 849 sub _cdr_date_parse {
 850   my $date = shift;
 851   my %options = @_;
 852
 853   return '' unless length($date); #that's okay, it becomes NULL
 854   return '' if $date eq 'NA'; #sansay
 855
 856   if ( $date =~ /^([a-z]{3})\s+([a-z]{3})\s+(\d{1,2})\s+(\d{1,2}):(\d{1,2}):(\d{1,2})\s+(\d{4})$/i && $7 > 1970 ) {
 857     my $time = str2time($date);
 858     return $time if $time > 100000; #just in case
 859   }
 860
 861   my($year, $mon, $day, $hour, $min, $sec);
 862
 863   #$date =~ /^\s*(\d{4})[\-\/]\(\d{1,2})[\-\/](\d{1,2})\s+(\d{1,2}):(\d{1,2}):(\d{1,2})\s*$/
 864   #taqua  #2007-10-31 08:57:24.113000000
 865
 866   if ( $date =~ /^\s*(\d{4})\D(\d{1,2})\D(\d{1,2})\D+(\d{1,2})\D(\d{1,2})\D(\d{1,2})(\D|$)/ ) {
 867     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 868   } elsif ( $date  =~ /^\s*(\d{1,2})\D(\d{1,2})\D(\d{4})\s+(\d{1,2})\D(\d{1,2})(?:\D(\d{1,2}))?(\D|$)/ ) {
 869     # 8/26/2010 12:20:01
 870     # optionally without seconds
 871     ($mon, $day, $year, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 872     $sec = 0 if !defined($sec);
 873   } elsif ( $date  =~ /^\s*(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d+\.\d+)(\D|$)/ ) {
 874     # broadsoft: 20081223201938.314
 875     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 876   } elsif ( $date  =~ /^\s*(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})\d+(\D|$)/ ) {
 877     # Taqua OM:  20050422203450943
 878     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 879   } elsif ( $date  =~ /^\s*(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})$/ ) {
 880     # WIP: 20100329121420
 881     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 882   } elsif ( $date =~ /^(\d{4})-(\d{2})-(\d{2})T(\d{2}):(\d{2}):(\d{2})Z$/) {
 883     # Telos
 884     ($year, $mon, $day, $hour, $min, $sec) = ( $1, $2, $3, $4, $5, $6 );
 885     $options{gmt} = 1;
 886   } else {
 887      die "unparsable date: $date"; #maybe we shouldn't die...
 888   }
 889
 890   return '' if ( $year == 1900 || $year == 1970 ) && $mon == 1 && $day == 1
 891             && $hour == 0 && $min == 0 && $sec == 0;
 892
 893   if ($options{gmt}) {
 894     timegm($sec, $min, $hour, $day, $mon-1, $year);
 895   } else {
 896     timelocal($sec, $min, $hour, $day, $mon-1, $year);
 897   }
 898 }
 899
 900 =item batch_import HASHREF
 901
 902 Imports CDR records.  Available options are:
 903
 904 =over 4
 905
 906 =item file
 907
 908 Filename
 909
 910 =item format
 911
 912 =item params
 913
 914 Hash reference of preset fields, typically cdrbatch
 915
 916 =item empty_ok
 917
 918 Set true to prevent throwing an error on empty imports
 919
 920 =back
 921
 922 =cut
 923
 924 my %import_options = (
 925   'table'         => 'cdr',
 926
 927   'batch_keycol'  => 'cdrbatchnum',
 928   'batch_table'   => 'cdr_batch',
 929   'batch_namecol' => 'cdrbatch',
 930
 931   'formats' => { map { $_ => $cdr_info{$_}->{'import_fields'}; }
 932                      keys %cdr_info
 933                },
 934
 935                           #drop the || 'csv' to allow auto xls for csv types?
 936   'format_types' => { map { $_ => lc($cdr_info{$_}->{'type'} || 'csv'); }
 937                           keys %cdr_info
 938                     },
 939
 940   'format_headers' => { map { $_ => ( $cdr_info{$_}->{'header'} || 0 ); }
 941                             keys %cdr_info
 942                       },
 943
 944   'format_sep_chars' => { map { $_ => $cdr_info{$_}->{'sep_char'}; }
 945                               keys %cdr_info
 946                         },
 947
 948   'format_fixedlength_formats' =>
 949     { map { $_ => $cdr_info{$_}->{'fixedlength_format'}; }
 950           keys %cdr_info
 951     },
 952
 953   'format_xml_formats' =>
 954     { map { $_ => $cdr_info{$_}->{'xml_format'}; }
 955           keys %cdr_info
 956     },
 957
 958   'format_row_callbacks' => { map { $_ => $cdr_info{$_}->{'row_callback'}; }
 959                                   keys %cdr_info
 960                             },
 961 );
 962
 963 sub _import_options {
 964   \%import_options;
 965 }
 966
 967 sub batch_import {
 968   my $opt = shift;
 969
 970   my $iopt = _import_options;
 971   $opt->{$_} = $iopt->{$_} foreach keys %$iopt;
 972
 973   if ( defined $opt->{'cdrtypenum'} ) {
 974         $opt->{'preinsert_callback'} = sub {
 975                 my($record,$param) = (shift,shift);
 976                 $record->cdrtypenum($opt->{'cdrtypenum'});
 977                 '';
 978         };
 979   }
 980
 981   FS::Record::batch_import( $opt );
 982
 983 }
 984
 985 =item process_batch_import
 986
 987 =cut
 988
 989 sub process_batch_import {
 990   my $job = shift;
 991
 992   my $opt = _import_options;
 993 #  $opt->{'params'} = [ 'format', 'cdrbatch' ];
 994
 995   FS::Record::process_batch_import( $job, $opt, @_ );
 996
 997 }
 998 #  if ( $format eq 'simple' ) { #should be a callback or opt in FS::cdr::simple
 999 #    @columns = map { s/^ +//; $_; } @columns;
1000 #  }
1001
1002 # _ upgrade_data
1003 #
1004 # Used by FS::Upgrade to migrate to a new database.
1005
1006 sub _upgrade_data {
1007   my ($class, %opts) = @_;
1008
1009   warn "$me upgrading $class\n" if $DEBUG;
1010
1011   my $sth = dbh->prepare(
1012     'SELECT DISTINCT(cdrbatch) FROM cdr WHERE cdrbatch IS NOT NULL'
1013   ) or die dbh->errstr;
1014
1015   $sth->execute or die $sth->errstr;
1016
1017   my %cdrbatchnum = ();
1018   while (my $row = $sth->fetchrow_arrayref) {
1019
1020     my $cdr_batch = qsearchs( 'cdr_batch', { 'cdrbatch' => $row->[0] } );
1021     unless ( $cdr_batch ) {
1022       $cdr_batch = new FS::cdr_batch { 'cdrbatch' => $row->[0] };
1023       my $error = $cdr_batch->insert;
1024       die $error if $error;
1025     }
1026
1027     $cdrbatchnum{$row->[0]} = $cdr_batch->cdrbatchnum;
1028   }
1029
1030   $sth = dbh->prepare('UPDATE cdr SET cdrbatch = NULL, cdrbatchnum = ? WHERE cdrbatch IS NOT NULL AND cdrbatch = ?') or die dbh->errstr;
1031
1032   foreach my $cdrbatch (keys %cdrbatchnum) {
1033     $sth->execute($cdrbatchnum{$cdrbatch}, $cdrbatch) or die $sth->errstr;
1034   }
1035
1036 }
1037
1038 =back
1039
1040 =head1 BUGS
1041
1042 =head1 SEE ALSO
1043
1044 L<FS::Record>, schema.html from the base documentation.
1045
1046 =cut
1047
1048 1;
1049